d36c39d91408296fbe7f26fdac947bb25b0c9fa0
[npth.git] / npth.m4
1 # npth.m4 - autoconf macro to detect NPTH.
2 # Copyright (C) 2002, 2003, 2004, 2011, 2018 g10 Code GmbH
3 #
4 # This file is free software; as a special exception the author gives
5 # unlimited permission to copy and/or distribute it, with or without
6 # modifications, as long as this notice is preserved.
7 #
8 # This file is distributed in the hope that it will be useful, but
9 # WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
10 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
11
12 AC_DEFUN([_AM_PATH_NPTH_CONFIG],
13 [ AC_ARG_WITH(npth-prefix,
14             AC_HELP_STRING([--with-npth-prefix=PFX],
15                            [prefix where NPTH is installed (optional)]),
16      npth_config_prefix="$withval", npth_config_prefix="")
17   if test "x$npth_config_prefix" != x ; then
18       NPTH_CONFIG="$npth_config_prefix/bin/npth-config"
19   fi
20
21   use_gpgrt_config=""
22   if test x"$NPTH_CONFIG" != x -a x"$GPGRT_CONFIG" != x -a "$GPGRT_CONFIG" != "no"; then
23     if CC=$CC $GPGRT_CONFIG npth >/dev/null 2>&1; then
24       NPTH_CONFIG="$GPGRT_CONFIG npth"
25       use_gpgrt_config=yes
26     fi
27   fi
28   if test -z "$use_gpgrt_config"; then
29     AC_PATH_PROG(NPTH_CONFIG, npth-config, no)
30   fi
31
32   if test "$NPTH_CONFIG" != "no" ; then
33     npth_version=`CC=$CC $NPTH_CONFIG --modversion`
34   fi
35   npth_version_major=`echo $npth_version | \
36                sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
37   npth_version_minor=`echo $npth_version | \
38                sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
39 ])
40
41 dnl AM_PATH_NPTH([MINIMUM-VERSION,
42 dnl               [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND ]]])
43 dnl Test for libnpth and define NPTH_CFLAGS and NPTH_LIBS.
44 dnl
45 AC_DEFUN([AM_PATH_NPTH],
46 [ AC_REQUIRE([_AM_PATH_NPTH_CONFIG])dnl
47   tmp=ifelse([$1], ,1:0.91,$1)
48   if echo "$tmp" | grep ':' >/dev/null 2>/dev/null ; then
49      req_npth_api=`echo "$tmp"     | sed 's/\(.*\):\(.*\)/\1/'`
50      min_npth_version=`echo "$tmp" | sed 's/\(.*\):\(.*\)/\2/'`
51   else
52      req_npth_api=1
53      min_npth_version="$tmp"
54   fi
55
56   AC_MSG_CHECKING(for NPTH - version >= $min_npth_version)
57   ok=no
58   if test "$NPTH_CONFIG" != "no" ; then
59     req_major=`echo $min_npth_version | \
60                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
61     req_minor=`echo $min_npth_version | \
62                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
63     if test "$npth_version_major" -gt "$req_major"; then
64         ok=yes
65     else
66         if test "$npth_version_major" -eq "$req_major"; then
67             if test "$npth_version_minor" -gt "$req_minor"; then
68                ok=yes
69             else
70                if test "$npth_version_minor" -eq "$req_minor"; then
71                   ok=yes
72                fi
73             fi
74         fi
75     fi
76   fi
77   if test $ok = yes; then
78     AC_MSG_RESULT([yes ($npth_version)])
79   else
80     AC_MSG_RESULT(no)
81   fi
82   if test $ok = yes; then
83      # If we have a recent NPTH, we should also check that the
84      # API is compatible.
85      if test "$req_npth_api" -gt 0 ; then
86         tmp=`CC=$CC $NPTH_CONFIG --variable=api_version 2>/dev/null || echo 0`
87         if test "$tmp" -gt 0 ; then
88            AC_MSG_CHECKING([NPTH API version])
89            if test "$req_npth_api" -eq "$tmp" ; then
90              AC_MSG_RESULT([okay])
91            else
92              ok=no
93              AC_MSG_RESULT([does not match. want=$req_npth_api got=$tmp])
94            fi
95         fi
96      fi
97   fi
98   if test $ok = yes; then
99     NPTH_CFLAGS=`CC=$CC $NPTH_CONFIG --cflags`
100     NPTH_LIBS=`CC=$CC $NPTH_CONFIG --libs`
101     ifelse([$2], , :, [$2])
102     npth_config_host=`CC=$CC $NPTH_CONFIG --variable=host 2>/dev/null || echo none`
103     if test x"$npth_config_host" != xnone ; then
104       if test x"$npth_config_host" != x"$host" ; then
105         AC_MSG_WARN([[
106 ***
107 *** The config script "$NPTH_CONFIG" was
108 *** built for $npth_config_host and thus may not match the
109 *** used host $host.
110 *** You may want to use the configure option --with-npth-prefix
111 *** to specify a matching config script.
112 ***]])
113       fi
114     fi
115   else
116     NPTH_CFLAGS=""
117     NPTH_LIBS=""
118     ifelse([$3], , :, [$3])
119   fi
120   AC_SUBST(NPTH_CFLAGS)
121   AC_SUBST(NPTH_LIBS)
122 ])