ff29554a07867fb50b3390796b523ab3d7e125bb
[npth.git] / npth.m4
1 # npth.m4 - autoconf macro to detect NPTH.
2 # Copyright (C) 2002, 2003, 2004, 2011, 2018 g10 Code GmbH
3 #
4 # This file is free software; as a special exception the author gives
5 # unlimited permission to copy and/or distribute it, with or without
6 # modifications, as long as this notice is preserved.
7 #
8 # This file is distributed in the hope that it will be useful, but
9 # WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
10 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
11
12 AC_DEFUN([_AM_PATH_NPTH_CONFIG],
13 [ AC_ARG_WITH(npth-prefix,
14             AC_HELP_STRING([--with-npth-prefix=PFX],
15                            [prefix where NPTH is installed (optional)]),
16      npth_config_prefix="$withval", npth_config_prefix="")
17   if test "x$npth_config_prefix" != x ; then
18       NPTH_CONFIG="$npth_config_prefix/bin/npth-config"
19   fi
20
21   use_gpgrt_config=""
22   if test x"$NPTH_CONFIG" != x -a x"$GPGRT_CONFIG" != x -a "$GPGRT_CONFIG" != "no"; then
23     if CC=$CC $GPGRT_CONFIG npth >/dev/null 2>&1; then
24       NPTH_CONFIG="$GPGRT_CONFIG npth"
25       use_gpgrt_config=yes
26     fi
27   fi
28   if test -z "$use_gpgrt_config"; then
29     AC_PATH_PROG(NPTH_CONFIG, npth-config, no)
30   fi
31
32   if test "$NPTH_CONFIG" != "no" ; then
33     if test -z "$use_gpgrt_config"; then
34       npth_version=`CC=$CC $NPTH_CONFIG --version`
35     else
36       npth_version=`CC=$CC $NPTH_CONFIG --modversion`
37     fi
38   fi
39   npth_version_major=`echo $npth_version | \
40                sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
41   npth_version_minor=`echo $npth_version | \
42                sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
43 ])
44
45 dnl AM_PATH_NPTH([MINIMUM-VERSION,
46 dnl               [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND ]]])
47 dnl Test for libnpth and define NPTH_CFLAGS and NPTH_LIBS.
48 dnl
49 AC_DEFUN([AM_PATH_NPTH],
50 [ AC_REQUIRE([_AM_PATH_NPTH_CONFIG])dnl
51   tmp=ifelse([$1], ,1:0.91,$1)
52   if echo "$tmp" | grep ':' >/dev/null 2>/dev/null ; then
53      req_npth_api=`echo "$tmp"     | sed 's/\(.*\):\(.*\)/\1/'`
54      min_npth_version=`echo "$tmp" | sed 's/\(.*\):\(.*\)/\2/'`
55   else
56      req_npth_api=1
57      min_npth_version="$tmp"
58   fi
59
60   AC_MSG_CHECKING(for NPTH - version >= $min_npth_version)
61   ok=no
62   if test "$NPTH_CONFIG" != "no" ; then
63     req_major=`echo $min_npth_version | \
64                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
65     req_minor=`echo $min_npth_version | \
66                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
67     if test "$npth_version_major" -gt "$req_major"; then
68         ok=yes
69     else
70         if test "$npth_version_major" -eq "$req_major"; then
71             if test "$npth_version_minor" -gt "$req_minor"; then
72                ok=yes
73             else
74                if test "$npth_version_minor" -eq "$req_minor"; then
75                   ok=yes
76                fi
77             fi
78         fi
79     fi
80   fi
81   if test $ok = yes; then
82     AC_MSG_RESULT([yes ($npth_version)])
83   else
84     AC_MSG_RESULT(no)
85   fi
86   if test $ok = yes; then
87     # If we have a recent NPTH, we should also check that the
88     # API is compatible.
89     if test "$req_npth_api" -gt 0 ; then
90       if test -z "$use_gpgrt_config"; then
91         tmp=`CC=$CC $NPTH_CONFIG --api-version 2>/dev/null || echo 0`
92       else
93         tmp=`CC=$CC $NPTH_CONFIG --variable=api_version 2>/dev/null || echo 0`
94       fi
95       if test "$tmp" -gt 0 ; then
96         AC_MSG_CHECKING([NPTH API version])
97         if test "$req_npth_api" -eq "$tmp" ; then
98           AC_MSG_RESULT([okay])
99         else
100           ok=no
101           AC_MSG_RESULT([does not match. want=$req_npth_api got=$tmp])
102         fi
103       fi
104     fi
105   fi
106   if test $ok = yes; then
107     NPTH_CFLAGS=`CC=$CC $NPTH_CONFIG --cflags`
108     NPTH_LIBS=`CC=$CC $NPTH_CONFIG --libs`
109     ifelse([$2], , :, [$2])
110     if test -z "$use_gpgrt_config"; then
111       npth_config_host=`CC=$CC $NPTH_CONFIG --host 2>/dev/null || echo none`
112     else
113       npth_config_host=`CC=$CC $NPTH_CONFIG --variable=host 2>/dev/null || echo none`
114     fi
115     if test x"$npth_config_host" != xnone ; then
116       if test x"$npth_config_host" != x"$host" ; then
117         AC_MSG_WARN([[
118 ***
119 *** The config script "$NPTH_CONFIG" was
120 *** built for $npth_config_host and thus may not match the
121 *** used host $host.
122 *** You may want to use the configure option --with-npth-prefix
123 *** to specify a matching config script.
124 ***]])
125       fi
126     fi
127   else
128     NPTH_CFLAGS=""
129     NPTH_LIBS=""
130     ifelse([$3], , :, [$3])
131   fi
132   AC_SUBST(NPTH_CFLAGS)
133   AC_SUBST(NPTH_LIBS)
134 ])