Add missing m4/libtool.m4.
[ntbtls.git] / m4 / libtool.m4
1 # libtool.m4 - Configure libtool for the host system. -*-Autoconf-*-
2 #
3 #   Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2003, 2004, 2005,
4 #                 2006, 2007, 2008, 2009, 2010, 2011 Free Software
5 #                 Foundation, Inc.
6 #   Written by Gordon Matzigkeit, 1996
7 #
8 # This file is free software; the Free Software Foundation gives
9 # unlimited permission to copy and/or distribute it, with or without
10 # modifications, as long as this notice is preserved.
11
12 m4_define([_LT_COPYING], [dnl
13 #   Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2003, 2004, 2005,
14 #                 2006, 2007, 2008, 2009, 2010, 2011 Free Software
15 #                 Foundation, Inc.
16 #   Written by Gordon Matzigkeit, 1996
17 #
18 #   This file is part of GNU Libtool.
19 #
20 # GNU Libtool is free software; you can redistribute it and/or
21 # modify it under the terms of the GNU General Public License as
22 # published by the Free Software Foundation; either version 2 of
23 # the License, or (at your option) any later version.
24 #
25 # As a special exception to the GNU General Public License,
26 # if you distribute this file as part of a program or library that
27 # is built using GNU Libtool, you may include this file under the
28 # same distribution terms that you use for the rest of that program.
29 #
30 # GNU Libtool is distributed in the hope that it will be useful,
31 # but WITHOUT ANY WARRANTY; without even the implied warranty of
32 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
33 # GNU General Public License for more details.
34 #
35 # You should have received a copy of the GNU General Public License
36 # along with GNU Libtool; see the file COPYING.  If not, a copy
37 # can be downloaded from http://www.gnu.org/licenses/gpl.html, or
38 # obtained by writing to the Free Software Foundation, Inc.,
39 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
40 ])
41
42 # serial 57 LT_INIT
43
44
45 # LT_PREREQ(VERSION)
46 # ------------------
47 # Complain and exit if this libtool version is less that VERSION.
48 m4_defun([LT_PREREQ],
49 [m4_if(m4_version_compare(m4_defn([LT_PACKAGE_VERSION]), [$1]), -1,
50        [m4_default([$3],
51                    [m4_fatal([Libtool version $1 or higher is required],
52                              63)])],
53        [$2])])
54
55
56 # _LT_CHECK_BUILDDIR
57 # ------------------
58 # Complain if the absolute build directory name contains unusual characters
59 m4_defun([_LT_CHECK_BUILDDIR],
60 [case `pwd` in
61   *\ * | *\     *)
62     AC_MSG_WARN([Libtool does not cope well with whitespace in `pwd`]) ;;
63 esac
64 ])
65
66
67 # LT_INIT([OPTIONS])
68 # ------------------
69 AC_DEFUN([LT_INIT],
70 [AC_PREREQ([2.58])dnl We use AC_INCLUDES_DEFAULT
71 AC_REQUIRE([AC_CONFIG_AUX_DIR_DEFAULT])dnl
72 AC_BEFORE([$0], [LT_LANG])dnl
73 AC_BEFORE([$0], [LT_OUTPUT])dnl
74 AC_BEFORE([$0], [LTDL_INIT])dnl
75 m4_require([_LT_CHECK_BUILDDIR])dnl
76
77 dnl Autoconf doesn't catch unexpanded LT_ macros by default:
78 m4_pattern_forbid([^_?LT_[A-Z_]+$])dnl
79 m4_pattern_allow([^(_LT_EOF|LT_DLGLOBAL|LT_DLLAZY_OR_NOW|LT_MULTI_MODULE)$])dnl
80 dnl aclocal doesn't pull ltoptions.m4, ltsugar.m4, or ltversion.m4
81 dnl unless we require an AC_DEFUNed macro:
82 AC_REQUIRE([LTOPTIONS_VERSION])dnl
83 AC_REQUIRE([LTSUGAR_VERSION])dnl
84 AC_REQUIRE([LTVERSION_VERSION])dnl
85 AC_REQUIRE([LTOBSOLETE_VERSION])dnl
86 m4_require([_LT_PROG_LTMAIN])dnl
87
88 _LT_SHELL_INIT([SHELL=${CONFIG_SHELL-/bin/sh}])
89
90 dnl Parse OPTIONS
91 _LT_SET_OPTIONS([$0], [$1])
92
93 # This can be used to rebuild libtool when needed
94 LIBTOOL_DEPS="$ltmain"
95
96 # Always use our own libtool.
97 LIBTOOL='$(SHELL) $(top_builddir)/libtool'
98 AC_SUBST(LIBTOOL)dnl
99
100 _LT_SETUP
101
102 # Only expand once:
103 m4_define([LT_INIT])
104 ])# LT_INIT
105
106 # Old names:
107 AU_ALIAS([AC_PROG_LIBTOOL], [LT_INIT])
108 AU_ALIAS([AM_PROG_LIBTOOL], [LT_INIT])
109 dnl aclocal-1.4 backwards compatibility:
110 dnl AC_DEFUN([AC_PROG_LIBTOOL], [])
111 dnl AC_DEFUN([AM_PROG_LIBTOOL], [])
112
113
114 # _LT_CC_BASENAME(CC)
115 # -------------------
116 # Calculate cc_basename.  Skip known compiler wrappers and cross-prefix.
117 m4_defun([_LT_CC_BASENAME],
118 [for cc_temp in $1""; do
119   case $cc_temp in
120     compile | *[[\\/]]compile | ccache | *[[\\/]]ccache ) ;;
121     distcc | *[[\\/]]distcc | purify | *[[\\/]]purify ) ;;
122     \-*) ;;
123     *) break;;
124   esac
125 done
126 cc_basename=`$ECHO "$cc_temp" | $SED "s%.*/%%; s%^$host_alias-%%"`
127 ])
128
129
130 # _LT_FILEUTILS_DEFAULTS
131 # ----------------------
132 # It is okay to use these file commands and assume they have been set
133 # sensibly after `m4_require([_LT_FILEUTILS_DEFAULTS])'.
134 m4_defun([_LT_FILEUTILS_DEFAULTS],
135 [: ${CP="cp -f"}
136 : ${MV="mv -f"}
137 : ${RM="rm -f"}
138 ])# _LT_FILEUTILS_DEFAULTS
139
140
141 # _LT_SETUP
142 # ---------
143 m4_defun([_LT_SETUP],
144 [AC_REQUIRE([AC_CANONICAL_HOST])dnl
145 AC_REQUIRE([AC_CANONICAL_BUILD])dnl
146 AC_REQUIRE([_LT_PREPARE_SED_QUOTE_VARS])dnl
147 AC_REQUIRE([_LT_PROG_ECHO_BACKSLASH])dnl
148
149 _LT_DECL([], [PATH_SEPARATOR], [1], [The PATH separator for the build system])dnl
150 dnl
151 _LT_DECL([], [host_alias], [0], [The host system])dnl
152 _LT_DECL([], [host], [0])dnl
153 _LT_DECL([], [host_os], [0])dnl
154 dnl
155 _LT_DECL([], [build_alias], [0], [The build system])dnl
156 _LT_DECL([], [build], [0])dnl
157 _LT_DECL([], [build_os], [0])dnl
158 dnl
159 AC_REQUIRE([AC_PROG_CC])dnl
160 AC_REQUIRE([LT_PATH_LD])dnl
161 AC_REQUIRE([LT_PATH_NM])dnl
162 dnl
163 AC_REQUIRE([AC_PROG_LN_S])dnl
164 test -z "$LN_S" && LN_S="ln -s"
165 _LT_DECL([], [LN_S], [1], [Whether we need soft or hard links])dnl
166 dnl
167 AC_REQUIRE([LT_CMD_MAX_LEN])dnl
168 _LT_DECL([objext], [ac_objext], [0], [Object file suffix (normally "o")])dnl
169 _LT_DECL([], [exeext], [0], [Executable file suffix (normally "")])dnl
170 dnl
171 m4_require([_LT_FILEUTILS_DEFAULTS])dnl
172 m4_require([_LT_CHECK_SHELL_FEATURES])dnl
173 m4_require([_LT_PATH_CONVERSION_FUNCTIONS])dnl
174 m4_require([_LT_CMD_RELOAD])dnl
175 m4_require([_LT_CHECK_MAGIC_METHOD])dnl
176 m4_require([_LT_CHECK_SHAREDLIB_FROM_LINKLIB])dnl
177 m4_require([_LT_CMD_OLD_ARCHIVE])dnl
178 m4_require([_LT_CMD_GLOBAL_SYMBOLS])dnl
179 m4_require([_LT_WITH_SYSROOT])dnl
180
181 _LT_CONFIG_LIBTOOL_INIT([
182 # See if we are running on zsh, and set the options which allow our
183 # commands through without removal of \ escapes INIT.
184 if test -n "\${ZSH_VERSION+set}" ; then
185    setopt NO_GLOB_SUBST
186 fi
187 ])
188 if test -n "${ZSH_VERSION+set}" ; then
189    setopt NO_GLOB_SUBST
190 fi
191
192 _LT_CHECK_OBJDIR
193
194 m4_require([_LT_TAG_COMPILER])dnl
195
196 case $host_os in
197 aix3*)
198   # AIX sometimes has problems with the GCC collect2 program.  For some
199   # reason, if we set the COLLECT_NAMES environment variable, the problems
200   # vanish in a puff of smoke.
201   if test "X${COLLECT_NAMES+set}" != Xset; then
202     COLLECT_NAMES=
203     export COLLECT_NAMES
204   fi
205   ;;
206 esac
207
208 # Global variables:
209 ofile=libtool
210 can_build_shared=yes
211
212 # All known linkers require a `.a' archive for static linking (except MSVC,
213 # which needs '.lib').
214 libext=a
215
216 with_gnu_ld="$lt_cv_prog_gnu_ld"
217
218 old_CC="$CC"
219 old_CFLAGS="$CFLAGS"
220
221 # Set sane defaults for various variables
222 test -z "$CC" && CC=cc
223 test -z "$LTCC" && LTCC=$CC
224 test -z "$LTCFLAGS" && LTCFLAGS=$CFLAGS
225 test -z "$LD" && LD=ld
226 test -z "$ac_objext" && ac_objext=o
227
228 _LT_CC_BASENAME([$compiler])
229
230 # Only perform the check for file, if the check method requires it
231 test -z "$MAGIC_CMD" && MAGIC_CMD=file
232 case $deplibs_check_method in
233 file_magic*)
234   if test "$file_magic_cmd" = '$MAGIC_CMD'; then
235     _LT_PATH_MAGIC
236   fi
237   ;;
238 esac
239
240 # Use C for the default configuration in the libtool script
241 LT_SUPPORTED_TAG([CC])
242 _LT_LANG_C_CONFIG
243 _LT_LANG_DEFAULT_CONFIG
244 _LT_CONFIG_COMMANDS
245 ])# _LT_SETUP
246
247
248 # _LT_PREPARE_SED_QUOTE_VARS
249 # --------------------------
250 # Define a few sed substitution that help us do robust quoting.
251 m4_defun([_LT_PREPARE_SED_QUOTE_VARS],
252 [# Backslashify metacharacters that are still active within
253 # double-quoted strings.
254 sed_quote_subst='s/\([["`$\\]]\)/\\\1/g'
255
256 # Same as above, but do not quote variable references.
257 double_quote_subst='s/\([["`\\]]\)/\\\1/g'
258
259 # Sed substitution to delay expansion of an escaped shell variable in a
260 # double_quote_subst'ed string.
261 delay_variable_subst='s/\\\\\\\\\\\$/\\\\\\$/g'
262
263 # Sed substitution to delay expansion of an escaped single quote.
264 delay_single_quote_subst='s/'\''/'\'\\\\\\\'\''/g'
265
266 # Sed substitution to avoid accidental globbing in evaled expressions
267 no_glob_subst='s/\*/\\\*/g'
268 ])
269
270 # _LT_PROG_LTMAIN
271 # ---------------
272 # Note that this code is called both from `configure', and `config.status'
273 # now that we use AC_CONFIG_COMMANDS to generate libtool.  Notably,
274 # `config.status' has no value for ac_aux_dir unless we are using Automake,
275 # so we pass a copy along to make sure it has a sensible value anyway.
276 m4_defun([_LT_PROG_LTMAIN],
277 [m4_ifdef([AC_REQUIRE_AUX_FILE], [AC_REQUIRE_AUX_FILE([ltmain.sh])])dnl
278 _LT_CONFIG_LIBTOOL_INIT([ac_aux_dir='$ac_aux_dir'])
279 ltmain="$ac_aux_dir/ltmain.sh"
280 ])# _LT_PROG_LTMAIN
281
282
283 ## ------------------------------------- ##
284 ## Accumulate code for creating libtool. ##
285 ## ------------------------------------- ##
286
287 # So that we can recreate a full libtool script including additional
288 # tags, we accumulate the chunks of code to send to AC_CONFIG_COMMANDS
289 # in macros and then make a single call at the end using the `libtool'
290 # label.
291
292
293 # _LT_CONFIG_LIBTOOL_INIT([INIT-COMMANDS])
294 # ----------------------------------------
295 # Register INIT-COMMANDS to be passed to AC_CONFIG_COMMANDS later.
296 m4_define([_LT_CONFIG_LIBTOOL_INIT],
297 [m4_ifval([$1],
298           [m4_append([_LT_OUTPUT_LIBTOOL_INIT],
299                      [$1
300 ])])])
301
302 # Initialize.
303 m4_define([_LT_OUTPUT_LIBTOOL_INIT])
304
305
306 # _LT_CONFIG_LIBTOOL([COMMANDS])
307 # ------------------------------
308 # Register COMMANDS to be passed to AC_CONFIG_COMMANDS later.
309 m4_define([_LT_CONFIG_LIBTOOL],
310 [m4_ifval([$1],
311           [m4_append([_LT_OUTPUT_LIBTOOL_COMMANDS],
312                      [$1
313 ])])])
314
315 # Initialize.
316 m4_define([_LT_OUTPUT_LIBTOOL_COMMANDS])
317
318
319 # _LT_CONFIG_SAVE_COMMANDS([COMMANDS], [INIT_COMMANDS])
320 # -----------------------------------------------------
321 m4_defun([_LT_CONFIG_SAVE_COMMANDS],
322 [_LT_CONFIG_LIBTOOL([$1])
323 _LT_CONFIG_LIBTOOL_INIT([$2])
324 ])
325
326
327 # _LT_FORMAT_COMMENT([COMMENT])
328 # -----------------------------
329 # Add leading comment marks to the start of each line, and a trailing
330 # full-stop to the whole comment if one is not present already.
331 m4_define([_LT_FORMAT_COMMENT],
332 [m4_ifval([$1], [
333 m4_bpatsubst([m4_bpatsubst([$1], [^ *], [# ])],
334               [['`$\]], [\\\&])]m4_bmatch([$1], [[!?.]$], [], [.])
335 )])
336
337
338
339 ## ------------------------ ##
340 ## FIXME: Eliminate VARNAME ##
341 ## ------------------------ ##
342
343
344 # _LT_DECL([CONFIGNAME], VARNAME, VALUE, [DESCRIPTION], [IS-TAGGED?])
345 # -------------------------------------------------------------------
346 # CONFIGNAME is the name given to the value in the libtool script.
347 # VARNAME is the (base) name used in the configure script.
348 # VALUE may be 0, 1 or 2 for a computed quote escaped value based on
349 # VARNAME.  Any other value will be used directly.
350 m4_define([_LT_DECL],
351 [lt_if_append_uniq([lt_decl_varnames], [$2], [, ],
352     [lt_dict_add_subkey([lt_decl_dict], [$2], [libtool_name],
353         [m4_ifval([$1], [$1], [$2])])
354     lt_dict_add_subkey([lt_decl_dict], [$2], [value], [$3])
355     m4_ifval([$4],
356         [lt_dict_add_subkey([lt_decl_dict], [$2], [description], [$4])])
357     lt_dict_add_subkey([lt_decl_dict], [$2],
358         [tagged?], [m4_ifval([$5], [yes], [no])])])
359 ])
360
361
362 # _LT_TAGDECL([CONFIGNAME], VARNAME, VALUE, [DESCRIPTION])
363 # --------------------------------------------------------
364 m4_define([_LT_TAGDECL], [_LT_DECL([$1], [$2], [$3], [$4], [yes])])
365
366
367 # lt_decl_tag_varnames([SEPARATOR], [VARNAME1...])
368 # ------------------------------------------------
369 m4_define([lt_decl_tag_varnames],
370 [_lt_decl_filter([tagged?], [yes], $@)])
371
372
373 # _lt_decl_filter(SUBKEY, VALUE, [SEPARATOR], [VARNAME1..])
374 # ---------------------------------------------------------
375 m4_define([_lt_decl_filter],
376 [m4_case([$#],
377   [0], [m4_fatal([$0: too few arguments: $#])],
378   [1], [m4_fatal([$0: too few arguments: $#: $1])],
379   [2], [lt_dict_filter([lt_decl_dict], [$1], [$2], [], lt_decl_varnames)],
380   [3], [lt_dict_filter([lt_decl_dict], [$1], [$2], [$3], lt_decl_varnames)],
381   [lt_dict_filter([lt_decl_dict], $@)])[]dnl
382 ])
383
384
385 # lt_decl_quote_varnames([SEPARATOR], [VARNAME1...])
386 # --------------------------------------------------
387 m4_define([lt_decl_quote_varnames],
388 [_lt_decl_filter([value], [1], $@)])
389
390
391 # lt_decl_dquote_varnames([SEPARATOR], [VARNAME1...])
392 # ---------------------------------------------------
393 m4_define([lt_decl_dquote_varnames],
394 [_lt_decl_filter([value], [2], $@)])
395
396
397 # lt_decl_varnames_tagged([SEPARATOR], [VARNAME1...])
398 # ---------------------------------------------------
399 m4_define([lt_decl_varnames_tagged],
400 [m4_assert([$# <= 2])dnl
401 _$0(m4_quote(m4_default([$1], [[, ]])),
402     m4_ifval([$2], [[$2]], [m4_dquote(lt_decl_tag_varnames)]),
403     m4_split(m4_normalize(m4_quote(_LT_TAGS)), [ ]))])
404 m4_define([_lt_decl_varnames_tagged],
405 [m4_ifval([$3], [lt_combine([$1], [$2], [_], $3)])])
406
407
408 # lt_decl_all_varnames([SEPARATOR], [VARNAME1...])
409 # ------------------------------------------------
410 m4_define([lt_decl_all_varnames],
411 [_$0(m4_quote(m4_default([$1], [[, ]])),
412      m4_if([$2], [],
413            m4_quote(lt_decl_varnames),
414         m4_quote(m4_shift($@))))[]dnl
415 ])
416 m4_define([_lt_decl_all_varnames],
417 [lt_join($@, lt_decl_varnames_tagged([$1],
418                         lt_decl_tag_varnames([[, ]], m4_shift($@))))dnl
419 ])
420
421
422 # _LT_CONFIG_STATUS_DECLARE([VARNAME])
423 # ------------------------------------
424 # Quote a variable value, and forward it to `config.status' so that its
425 # declaration there will have the same value as in `configure'.  VARNAME
426 # must have a single quote delimited value for this to work.
427 m4_define([_LT_CONFIG_STATUS_DECLARE],
428 [$1='`$ECHO "$][$1" | $SED "$delay_single_quote_subst"`'])
429
430
431 # _LT_CONFIG_STATUS_DECLARATIONS
432 # ------------------------------
433 # We delimit libtool config variables with single quotes, so when
434 # we write them to config.status, we have to be sure to quote all
435 # embedded single quotes properly.  In configure, this macro expands
436 # each variable declared with _LT_DECL (and _LT_TAGDECL) into:
437 #
438 #    <var>='`$ECHO "$<var>" | $SED "$delay_single_quote_subst"`'
439 m4_defun([_LT_CONFIG_STATUS_DECLARATIONS],
440 [m4_foreach([_lt_var], m4_quote(lt_decl_all_varnames),
441     [m4_n([_LT_CONFIG_STATUS_DECLARE(_lt_var)])])])
442
443
444 # _LT_LIBTOOL_TAGS
445 # ----------------
446 # Output comment and list of tags supported by the script
447 m4_defun([_LT_LIBTOOL_TAGS],
448 [_LT_FORMAT_COMMENT([The names of the tagged configurations supported by this script])dnl
449 available_tags="_LT_TAGS"dnl
450 ])
451
452
453 # _LT_LIBTOOL_DECLARE(VARNAME, [TAG])
454 # -----------------------------------
455 # Extract the dictionary values for VARNAME (optionally with TAG) and
456 # expand to a commented shell variable setting:
457 #
458 #    # Some comment about what VAR is for.
459 #    visible_name=$lt_internal_name
460 m4_define([_LT_LIBTOOL_DECLARE],
461 [_LT_FORMAT_COMMENT(m4_quote(lt_dict_fetch([lt_decl_dict], [$1],
462                                            [description])))[]dnl
463 m4_pushdef([_libtool_name],
464     m4_quote(lt_dict_fetch([lt_decl_dict], [$1], [libtool_name])))[]dnl
465 m4_case(m4_quote(lt_dict_fetch([lt_decl_dict], [$1], [value])),
466     [0], [_libtool_name=[$]$1],
467     [1], [_libtool_name=$lt_[]$1],
468     [2], [_libtool_name=$lt_[]$1],
469     [_libtool_name=lt_dict_fetch([lt_decl_dict], [$1], [value])])[]dnl
470 m4_ifval([$2], [_$2])[]m4_popdef([_libtool_name])[]dnl
471 ])
472
473
474 # _LT_LIBTOOL_CONFIG_VARS
475 # -----------------------
476 # Produce commented declarations of non-tagged libtool config variables
477 # suitable for insertion in the LIBTOOL CONFIG section of the `libtool'
478 # script.  Tagged libtool config variables (even for the LIBTOOL CONFIG
479 # section) are produced by _LT_LIBTOOL_TAG_VARS.
480 m4_defun([_LT_LIBTOOL_CONFIG_VARS],
481 [m4_foreach([_lt_var],
482     m4_quote(_lt_decl_filter([tagged?], [no], [], lt_decl_varnames)),
483     [m4_n([_LT_LIBTOOL_DECLARE(_lt_var)])])])
484
485
486 # _LT_LIBTOOL_TAG_VARS(TAG)
487 # -------------------------
488 m4_define([_LT_LIBTOOL_TAG_VARS],
489 [m4_foreach([_lt_var], m4_quote(lt_decl_tag_varnames),
490     [m4_n([_LT_LIBTOOL_DECLARE(_lt_var, [$1])])])])
491
492
493 # _LT_TAGVAR(VARNAME, [TAGNAME])
494 # ------------------------------
495 m4_define([_LT_TAGVAR], [m4_ifval([$2], [$1_$2], [$1])])
496
497
498 # _LT_CONFIG_COMMANDS
499 # -------------------
500 # Send accumulated output to $CONFIG_STATUS.  Thanks to the lists of
501 # variables for single and double quote escaping we saved from calls
502 # to _LT_DECL, we can put quote escaped variables declarations
503 # into `config.status', and then the shell code to quote escape them in
504 # for loops in `config.status'.  Finally, any additional code accumulated
505 # from calls to _LT_CONFIG_LIBTOOL_INIT is expanded.
506 m4_defun([_LT_CONFIG_COMMANDS],
507 [AC_PROVIDE_IFELSE([LT_OUTPUT],
508         dnl If the libtool generation code has been placed in $CONFIG_LT,
509         dnl instead of duplicating it all over again into config.status,
510         dnl then we will have config.status run $CONFIG_LT later, so it
511         dnl needs to know what name is stored there:
512         [AC_CONFIG_COMMANDS([libtool],
513             [$SHELL $CONFIG_LT || AS_EXIT(1)], [CONFIG_LT='$CONFIG_LT'])],
514     dnl If the libtool generation code is destined for config.status,
515     dnl expand the accumulated commands and init code now:
516     [AC_CONFIG_COMMANDS([libtool],
517         [_LT_OUTPUT_LIBTOOL_COMMANDS], [_LT_OUTPUT_LIBTOOL_COMMANDS_INIT])])
518 ])#_LT_CONFIG_COMMANDS
519
520
521 # Initialize.
522 m4_define([_LT_OUTPUT_LIBTOOL_COMMANDS_INIT],
523 [
524
525 # The HP-UX ksh and POSIX shell print the target directory to stdout
526 # if CDPATH is set.
527 (unset CDPATH) >/dev/null 2>&1 && unset CDPATH
528
529 sed_quote_subst='$sed_quote_subst'
530 double_quote_subst='$double_quote_subst'
531 delay_variable_subst='$delay_variable_subst'
532 _LT_CONFIG_STATUS_DECLARATIONS
533 LTCC='$LTCC'
534 LTCFLAGS='$LTCFLAGS'
535 compiler='$compiler_DEFAULT'
536
537 # A function that is used when there is no print builtin or printf.
538 func_fallback_echo ()
539 {
540   eval 'cat <<_LTECHO_EOF
541 \$[]1
542 _LTECHO_EOF'
543 }
544
545 # Quote evaled strings.
546 for var in lt_decl_all_varnames([[ \
547 ]], lt_decl_quote_varnames); do
548     case \`eval \\\\\$ECHO \\\\""\\\\\$\$var"\\\\"\` in
549     *[[\\\\\\\`\\"\\\$]]*)
550       eval "lt_\$var=\\\\\\"\\\`\\\$ECHO \\"\\\$\$var\\" | \\\$SED \\"\\\$sed_quote_subst\\"\\\`\\\\\\""
551       ;;
552     *)
553       eval "lt_\$var=\\\\\\"\\\$\$var\\\\\\""
554       ;;
555     esac
556 done
557
558 # Double-quote double-evaled strings.
559 for var in lt_decl_all_varnames([[ \
560 ]], lt_decl_dquote_varnames); do
561     case \`eval \\\\\$ECHO \\\\""\\\\\$\$var"\\\\"\` in
562     *[[\\\\\\\`\\"\\\$]]*)
563       eval "lt_\$var=\\\\\\"\\\`\\\$ECHO \\"\\\$\$var\\" | \\\$SED -e \\"\\\$double_quote_subst\\" -e \\"\\\$sed_quote_subst\\" -e \\"\\\$delay_variable_subst\\"\\\`\\\\\\""
564       ;;
565     *)
566       eval "lt_\$var=\\\\\\"\\\$\$var\\\\\\""
567       ;;
568     esac
569 done
570
571 _LT_OUTPUT_LIBTOOL_INIT
572 ])
573
574 # _LT_GENERATED_FILE_INIT(FILE, [COMMENT])
575 # ------------------------------------
576 # Generate a child script FILE with all initialization necessary to
577 # reuse the environment learned by the parent script, and make the
578 # file executable.  If COMMENT is supplied, it is inserted after the
579 # `#!' sequence but before initialization text begins.  After this
580 # macro, additional text can be appended to FILE to form the body of
581 # the child script.  The macro ends with non-zero status if the
582 # file could not be fully written (such as if the disk is full).
583 m4_ifdef([AS_INIT_GENERATED],
584 [m4_defun([_LT_GENERATED_FILE_INIT],[AS_INIT_GENERATED($@)])],
585 [m4_defun([_LT_GENERATED_FILE_INIT],
586 [m4_require([AS_PREPARE])]dnl
587 [m4_pushdef([AS_MESSAGE_LOG_FD])]dnl
588 [lt_write_fail=0
589 cat >$1 <<_ASEOF || lt_write_fail=1
590 #! $SHELL
591 # Generated by $as_me.
592 $2
593 SHELL=\${CONFIG_SHELL-$SHELL}
594 export SHELL
595 _ASEOF
596 cat >>$1 <<\_ASEOF || lt_write_fail=1
597 AS_SHELL_SANITIZE
598 _AS_PREPARE
599 exec AS_MESSAGE_FD>&1
600 _ASEOF
601 test $lt_write_fail = 0 && chmod +x $1[]dnl
602 m4_popdef([AS_MESSAGE_LOG_FD])])])# _LT_GENERATED_FILE_INIT
603
604 # LT_OUTPUT
605 # ---------
606 # This macro allows early generation of the libtool script (before
607 # AC_OUTPUT is called), incase it is used in configure for compilation
608 # tests.
609 AC_DEFUN([LT_OUTPUT],
610 [: ${CONFIG_LT=./config.lt}
611 AC_MSG_NOTICE([creating $CONFIG_LT])
612 _LT_GENERATED_FILE_INIT(["$CONFIG_LT"],
613 [# Run this file to recreate a libtool stub with the current configuration.])
614
615 cat >>"$CONFIG_LT" <<\_LTEOF
616 lt_cl_silent=false
617 exec AS_MESSAGE_LOG_FD>>config.log
618 {
619   echo
620   AS_BOX([Running $as_me.])
621 } >&AS_MESSAGE_LOG_FD
622
623 lt_cl_help="\
624 \`$as_me' creates a local libtool stub from the current configuration,
625 for use in further configure time tests before the real libtool is
626 generated.
627
628 Usage: $[0] [[OPTIONS]]
629
630   -h, --help      print this help, then exit
631   -V, --version   print version number, then exit
632   -q, --quiet     do not print progress messages
633   -d, --debug     don't remove temporary files
634
635 Report bugs to <bug-libtool@gnu.org>."
636
637 lt_cl_version="\
638 m4_ifset([AC_PACKAGE_NAME], [AC_PACKAGE_NAME ])config.lt[]dnl
639 m4_ifset([AC_PACKAGE_VERSION], [ AC_PACKAGE_VERSION])
640 configured by $[0], generated by m4_PACKAGE_STRING.
641
642 Copyright (C) 2011 Free Software Foundation, Inc.
643 This config.lt script is free software; the Free Software Foundation
644 gives unlimited permision to copy, distribute and modify it."
645
646 while test $[#] != 0
647 do
648   case $[1] in
649     --version | --v* | -V )
650       echo "$lt_cl_version"; exit 0 ;;
651     --help | --h* | -h )
652       echo "$lt_cl_help"; exit 0 ;;
653     --debug | --d* | -d )
654       debug=: ;;
655     --quiet | --q* | --silent | --s* | -q )
656       lt_cl_silent=: ;;
657
658     -*) AC_MSG_ERROR([unrecognized option: $[1]
659 Try \`$[0] --help' for more information.]) ;;
660
661     *) AC_MSG_ERROR([unrecognized argument: $[1]
662 Try \`$[0] --help' for more information.]) ;;
663   esac
664   shift
665 done
666
667 if $lt_cl_silent; then
668   exec AS_MESSAGE_FD>/dev/null
669 fi
670 _LTEOF
671
672 cat >>"$CONFIG_LT" <<_LTEOF
673 _LT_OUTPUT_LIBTOOL_COMMANDS_INIT
674 _LTEOF
675
676 cat >>"$CONFIG_LT" <<\_LTEOF
677 AC_MSG_NOTICE([creating $ofile])
678 _LT_OUTPUT_LIBTOOL_COMMANDS
679 AS_EXIT(0)
680 _LTEOF
681 chmod +x "$CONFIG_LT"
682
683 # configure is writing to config.log, but config.lt does its own redirection,
684 # appending to config.log, which fails on DOS, as config.log is still kept
685 # open by configure.  Here we exec the FD to /dev/null, effectively closing
686 # config.log, so it can be properly (re)opened and appended to by config.lt.
687 lt_cl_success=:
688 test "$silent" = yes &&
689   lt_config_lt_args="$lt_config_lt_args --quiet"
690 exec AS_MESSAGE_LOG_FD>/dev/null
691 $SHELL "$CONFIG_LT" $lt_config_lt_args || lt_cl_success=false
692 exec AS_MESSAGE_LOG_FD>>config.log
693 $lt_cl_success || AS_EXIT(1)
694 ])# LT_OUTPUT
695
696
697 # _LT_CONFIG(TAG)
698 # ---------------
699 # If TAG is the built-in tag, create an initial libtool script with a
700 # default configuration from the untagged config vars.  Otherwise add code
701 # to config.status for appending the configuration named by TAG from the
702 # matching tagged config vars.
703 m4_defun([_LT_CONFIG],
704 [m4_require([_LT_FILEUTILS_DEFAULTS])dnl
705 _LT_CONFIG_SAVE_COMMANDS([
706   m4_define([_LT_TAG], m4_if([$1], [], [C], [$1]))dnl
707   m4_if(_LT_TAG, [C], [
708     # See if we are running on zsh, and set the options which allow our
709     # commands through without removal of \ escapes.
710     if test -n "${ZSH_VERSION+set}" ; then
711       setopt NO_GLOB_SUBST
712     fi
713
714     cfgfile="${ofile}T"
715     trap "$RM \"$cfgfile\"; exit 1" 1 2 15
716     $RM "$cfgfile"
717
718     cat <<_LT_EOF >> "$cfgfile"
719 #! $SHELL
720
721 # `$ECHO "$ofile" | sed 's%^.*/%%'` - Provide generalized library-building support services.
722 # Generated automatically by $as_me ($PACKAGE$TIMESTAMP) $VERSION
723 # Libtool was configured on host `(hostname || uname -n) 2>/dev/null | sed 1q`:
724 # NOTE: Changes made to this file will be lost: look at ltmain.sh.
725 #
726 _LT_COPYING
727 _LT_LIBTOOL_TAGS
728
729 # ### BEGIN LIBTOOL CONFIG
730 _LT_LIBTOOL_CONFIG_VARS
731 _LT_LIBTOOL_TAG_VARS
732 # ### END LIBTOOL CONFIG
733
734 _LT_EOF
735
736   case $host_os in
737   aix3*)
738     cat <<\_LT_EOF >> "$cfgfile"
739 # AIX sometimes has problems with the GCC collect2 program.  For some
740 # reason, if we set the COLLECT_NAMES environment variable, the problems
741 # vanish in a puff of smoke.
742 if test "X${COLLECT_NAMES+set}" != Xset; then
743   COLLECT_NAMES=
744   export COLLECT_NAMES
745 fi
746 _LT_EOF
747     ;;
748   esac
749
750   _LT_PROG_LTMAIN
751
752   # We use sed instead of cat because bash on DJGPP gets confused if
753   # if finds mixed CR/LF and LF-only lines.  Since sed operates in
754   # text mode, it properly converts lines to CR/LF.  This bash problem
755   # is reportedly fixed, but why not run on old versions too?
756   sed '$q' "$ltmain" >> "$cfgfile" \
757      || (rm -f "$cfgfile"; exit 1)
758
759   _LT_PROG_REPLACE_SHELLFNS
760
761    mv -f "$cfgfile" "$ofile" ||
762     (rm -f "$ofile" && cp "$cfgfile" "$ofile" && rm -f "$cfgfile")
763   chmod +x "$ofile"
764 ],
765 [cat <<_LT_EOF >> "$ofile"
766
767 dnl Unfortunately we have to use $1 here, since _LT_TAG is not expanded
768 dnl in a comment (ie after a #).
769 # ### BEGIN LIBTOOL TAG CONFIG: $1
770 _LT_LIBTOOL_TAG_VARS(_LT_TAG)
771 # ### END LIBTOOL TAG CONFIG: $1
772 _LT_EOF
773 ])dnl /m4_if
774 ],
775 [m4_if([$1], [], [
776     PACKAGE='$PACKAGE'
777     VERSION='$VERSION'
778     TIMESTAMP='$TIMESTAMP'
779     RM='$RM'
780     ofile='$ofile'], [])
781 ])dnl /_LT_CONFIG_SAVE_COMMANDS
782 ])# _LT_CONFIG
783
784
785 # LT_SUPPORTED_TAG(TAG)
786 # ---------------------
787 # Trace this macro to discover what tags are supported by the libtool
788 # --tag option, using:
789 #    autoconf --trace 'LT_SUPPORTED_TAG:$1'
790 AC_DEFUN([LT_SUPPORTED_TAG], [])
791
792
793 # C support is built-in for now
794 m4_define([_LT_LANG_C_enabled], [])
795 m4_define([_LT_TAGS], [])
796
797
798 # LT_LANG(LANG)
799 # -------------
800 # Enable libtool support for the given language if not already enabled.
801 AC_DEFUN([LT_LANG],
802 [AC_BEFORE([$0], [LT_OUTPUT])dnl
803 m4_case([$1],
804   [C],                  [_LT_LANG(C)],
805   [C++],                [_LT_LANG(CXX)],
806   [Go],                 [_LT_LANG(GO)],
807   [Java],               [_LT_LANG(GCJ)],
808   [Fortran 77],         [_LT_LANG(F77)],
809   [Fortran],            [_LT_LANG(FC)],
810   [Windows Resource],   [_LT_LANG(RC)],
811   [m4_ifdef([_LT_LANG_]$1[_CONFIG],
812     [_LT_LANG($1)],
813     [m4_fatal([$0: unsupported language: "$1"])])])dnl
814 ])# LT_LANG
815
816
817 # _LT_LANG(LANGNAME)
818 # ------------------
819 m4_defun([_LT_LANG],
820 [m4_ifdef([_LT_LANG_]$1[_enabled], [],
821   [LT_SUPPORTED_TAG([$1])dnl
822   m4_append([_LT_TAGS], [$1 ])dnl
823   m4_define([_LT_LANG_]$1[_enabled], [])dnl
824   _LT_LANG_$1_CONFIG($1)])dnl
825 ])# _LT_LANG
826
827
828 m4_ifndef([AC_PROG_GO], [
829 ############################################################
830 # NOTE: This macro has been submitted for inclusion into   #
831 #  GNU Autoconf as AC_PROG_GO.  When it is available in    #
832 #  a released version of Autoconf we should remove this    #
833 #  macro and use it instead.                               #
834 ############################################################
835 m4_defun([AC_PROG_GO],
836 [AC_LANG_PUSH(Go)dnl
837 AC_ARG_VAR([GOC],     [Go compiler command])dnl
838 AC_ARG_VAR([GOFLAGS], [Go compiler flags])dnl
839 _AC_ARG_VAR_LDFLAGS()dnl
840 AC_CHECK_TOOL(GOC, gccgo)
841 if test -z "$GOC"; then
842   if test -n "$ac_tool_prefix"; then
843     AC_CHECK_PROG(GOC, [${ac_tool_prefix}gccgo], [${ac_tool_prefix}gccgo])
844   fi
845 fi
846 if test -z "$GOC"; then
847   AC_CHECK_PROG(GOC, gccgo, gccgo, false)
848 fi
849 ])#m4_defun
850 ])#m4_ifndef
851
852
853 # _LT_LANG_DEFAULT_CONFIG
854 # -----------------------
855 m4_defun([_LT_LANG_DEFAULT_CONFIG],
856 [AC_PROVIDE_IFELSE([AC_PROG_CXX],
857   [LT_LANG(CXX)],
858   [m4_define([AC_PROG_CXX], defn([AC_PROG_CXX])[LT_LANG(CXX)])])
859
860 AC_PROVIDE_IFELSE([AC_PROG_F77],
861   [LT_LANG(F77)],
862   [m4_define([AC_PROG_F77], defn([AC_PROG_F77])[LT_LANG(F77)])])
863
864 AC_PROVIDE_IFELSE([AC_PROG_FC],
865   [LT_LANG(FC)],
866   [m4_define([AC_PROG_FC], defn([AC_PROG_FC])[LT_LANG(FC)])])
867
868 dnl The call to [A][M_PROG_GCJ] is quoted like that to stop aclocal
869 dnl pulling things in needlessly.
870 AC_PROVIDE_IFELSE([AC_PROG_GCJ],
871   [LT_LANG(GCJ)],
872   [AC_PROVIDE_IFELSE([A][M_PROG_GCJ],
873     [LT_LANG(GCJ)],
874     [AC_PROVIDE_IFELSE([LT_PROG_GCJ],
875       [LT_LANG(GCJ)],
876       [m4_ifdef([AC_PROG_GCJ],
877         [m4_define([AC_PROG_GCJ], defn([AC_PROG_GCJ])[LT_LANG(GCJ)])])
878        m4_ifdef([A][M_PROG_GCJ],
879         [m4_define([A][M_PROG_GCJ], defn([A][M_PROG_GCJ])[LT_LANG(GCJ)])])
880        m4_ifdef([LT_PROG_GCJ],
881         [m4_define([LT_PROG_GCJ], defn([LT_PROG_GCJ])[LT_LANG(GCJ)])])])])])
882
883 AC_PROVIDE_IFELSE([AC_PROG_GO],
884   [LT_LANG(GO)],
885   [m4_define([AC_PROG_GO], defn([AC_PROG_GO])[LT_LANG(GO)])])
886
887 AC_PROVIDE_IFELSE([LT_PROG_RC],
888   [LT_LANG(RC)],
889   [m4_define([LT_PROG_RC], defn([LT_PROG_RC])[LT_LANG(RC)])])
890 ])# _LT_LANG_DEFAULT_CONFIG
891
892 # Obsolete macros:
893 AU_DEFUN([AC_LIBTOOL_CXX], [LT_LANG(C++)])
894 AU_DEFUN([AC_LIBTOOL_F77], [LT_LANG(Fortran 77)])
895 AU_DEFUN([AC_LIBTOOL_FC], [LT_LANG(Fortran)])
896 AU_DEFUN([AC_LIBTOOL_GCJ], [LT_LANG(Java)])
897 AU_DEFUN([AC_LIBTOOL_RC], [LT_LANG(Windows Resource)])
898 dnl aclocal-1.4 backwards compatibility:
899 dnl AC_DEFUN([AC_LIBTOOL_CXX], [])
900 dnl AC_DEFUN([AC_LIBTOOL_F77], [])
901 dnl AC_DEFUN([AC_LIBTOOL_FC], [])
902 dnl AC_DEFUN([AC_LIBTOOL_GCJ], [])
903 dnl AC_DEFUN([AC_LIBTOOL_RC], [])
904
905
906 # _LT_TAG_COMPILER
907 # ----------------
908 m4_defun([_LT_TAG_COMPILER],
909 [AC_REQUIRE([AC_PROG_CC])dnl
910
911 _LT_DECL([LTCC], [CC], [1], [A C compiler])dnl
912 _LT_DECL([LTCFLAGS], [CFLAGS], [1], [LTCC compiler flags])dnl
913 _LT_TAGDECL([CC], [compiler], [1], [A language specific compiler])dnl
914 _LT_TAGDECL([with_gcc], [GCC], [0], [Is the compiler the GNU compiler?])dnl
915
916 # If no C compiler was specified, use CC.
917 LTCC=${LTCC-"$CC"}
918
919 # If no C compiler flags were specified, use CFLAGS.
920 LTCFLAGS=${LTCFLAGS-"$CFLAGS"}
921
922 # Allow CC to be a program name with arguments.
923 compiler=$CC
924 ])# _LT_TAG_COMPILER
925
926
927 # _LT_COMPILER_BOILERPLATE
928 # ------------------------
929 # Check for compiler boilerplate output or warnings with
930 # the simple compiler test code.
931 m4_defun([_LT_COMPILER_BOILERPLATE],
932 [m4_require([_LT_DECL_SED])dnl
933 ac_outfile=conftest.$ac_objext
934 echo "$lt_simple_compile_test_code" >conftest.$ac_ext
935 eval "$ac_compile" 2>&1 >/dev/null | $SED '/^$/d; /^ *+/d' >conftest.err
936 _lt_compiler_boilerplate=`cat conftest.err`
937 $RM conftest*
938 ])# _LT_COMPILER_BOILERPLATE
939
940
941 # _LT_LINKER_BOILERPLATE
942 # ----------------------
943 # Check for linker boilerplate output or warnings with
944 # the simple link test code.
945 m4_defun([_LT_LINKER_BOILERPLATE],
946 [m4_require([_LT_DECL_SED])dnl
947 ac_outfile=conftest.$ac_objext
948 echo "$lt_simple_link_test_code" >conftest.$ac_ext
949 eval "$ac_link" 2>&1 >/dev/null | $SED '/^$/d; /^ *+/d' >conftest.err
950 _lt_linker_boilerplate=`cat conftest.err`
951 $RM -r conftest*
952 ])# _LT_LINKER_BOILERPLATE
953
954 # _LT_REQUIRED_DARWIN_CHECKS
955 # -------------------------
956 m4_defun_once([_LT_REQUIRED_DARWIN_CHECKS],[
957   case $host_os in
958     rhapsody* | darwin*)
959     AC_CHECK_TOOL([DSYMUTIL], [dsymutil], [:])
960     AC_CHECK_TOOL([NMEDIT], [nmedit], [:])
961     AC_CHECK_TOOL([LIPO], [lipo], [:])
962     AC_CHECK_TOOL([OTOOL], [otool], [:])
963     AC_CHECK_TOOL([OTOOL64], [otool64], [:])
964     _LT_DECL([], [DSYMUTIL], [1],
965       [Tool to manipulate archived DWARF debug symbol files on Mac OS X])
966     _LT_DECL([], [NMEDIT], [1],
967       [Tool to change global to local symbols on Mac OS X])
968     _LT_DECL([], [LIPO], [1],
969       [Tool to manipulate fat objects and archives on Mac OS X])
970     _LT_DECL([], [OTOOL], [1],
971       [ldd/readelf like tool for Mach-O binaries on Mac OS X])
972     _LT_DECL([], [OTOOL64], [1],
973       [ldd/readelf like tool for 64 bit Mach-O binaries on Mac OS X 10.4])
974
975     AC_CACHE_CHECK([for -single_module linker flag],[lt_cv_apple_cc_single_mod],
976       [lt_cv_apple_cc_single_mod=no
977       if test -z "${LT_MULTI_MODULE}"; then
978         # By default we will add the -single_module flag. You can override
979         # by either setting the environment variable LT_MULTI_MODULE
980         # non-empty at configure time, or by adding -multi_module to the
981         # link flags.
982         rm -rf libconftest.dylib*
983         echo "int foo(void){return 1;}" > conftest.c
984         echo "$LTCC $LTCFLAGS $LDFLAGS -o libconftest.dylib \
985 -dynamiclib -Wl,-single_module conftest.c" >&AS_MESSAGE_LOG_FD
986         $LTCC $LTCFLAGS $LDFLAGS -o libconftest.dylib \
987           -dynamiclib -Wl,-single_module conftest.c 2>conftest.err
988         _lt_result=$?
989         # If there is a non-empty error log, and "single_module"
990         # appears in it, assume the flag caused a linker warning
991         if test -s conftest.err && $GREP single_module conftest.err; then
992           cat conftest.err >&AS_MESSAGE_LOG_FD
993         # Otherwise, if the output was created with a 0 exit code from
994         # the compiler, it worked.
995         elif test -f libconftest.dylib && test $_lt_result -eq 0; then
996           lt_cv_apple_cc_single_mod=yes
997         else
998           cat conftest.err >&AS_MESSAGE_LOG_FD
999         fi
1000         rm -rf libconftest.dylib*
1001         rm -f conftest.*
1002       fi])
1003
1004     AC_CACHE_CHECK([for -exported_symbols_list linker flag],
1005       [lt_cv_ld_exported_symbols_list],
1006       [lt_cv_ld_exported_symbols_list=no
1007       save_LDFLAGS=$LDFLAGS
1008       echo "_main" > conftest.sym
1009       LDFLAGS="$LDFLAGS -Wl,-exported_symbols_list,conftest.sym"
1010       AC_LINK_IFELSE([AC_LANG_PROGRAM([],[])],
1011         [lt_cv_ld_exported_symbols_list=yes],
1012         [lt_cv_ld_exported_symbols_list=no])
1013         LDFLAGS="$save_LDFLAGS"
1014     ])
1015
1016     AC_CACHE_CHECK([for -force_load linker flag],[lt_cv_ld_force_load],
1017       [lt_cv_ld_force_load=no
1018       cat > conftest.c << _LT_EOF
1019 int forced_loaded() { return 2;}
1020 _LT_EOF
1021       echo "$LTCC $LTCFLAGS -c -o conftest.o conftest.c" >&AS_MESSAGE_LOG_FD
1022       $LTCC $LTCFLAGS -c -o conftest.o conftest.c 2>&AS_MESSAGE_LOG_FD
1023       echo "$AR cru libconftest.a conftest.o" >&AS_MESSAGE_LOG_FD
1024       $AR cru libconftest.a conftest.o 2>&AS_MESSAGE_LOG_FD
1025       echo "$RANLIB libconftest.a" >&AS_MESSAGE_LOG_FD
1026       $RANLIB libconftest.a 2>&AS_MESSAGE_LOG_FD
1027       cat > conftest.c << _LT_EOF
1028 int main() { return 0;}
1029 _LT_EOF
1030       echo "$LTCC $LTCFLAGS $LDFLAGS -o conftest conftest.c -Wl,-force_load,./libconftest.a" >&AS_MESSAGE_LOG_FD
1031       $LTCC $LTCFLAGS $LDFLAGS -o conftest conftest.c -Wl,-force_load,./libconftest.a 2>conftest.err
1032       _lt_result=$?
1033       if test -s conftest.err && $GREP force_load conftest.err; then
1034         cat conftest.err >&AS_MESSAGE_LOG_FD
1035       elif test -f conftest && test $_lt_result -eq 0 && $GREP forced_load conftest >/dev/null 2>&1 ; then
1036         lt_cv_ld_force_load=yes
1037       else
1038         cat conftest.err >&AS_MESSAGE_LOG_FD
1039       fi
1040         rm -f conftest.err libconftest.a conftest conftest.c
1041         rm -rf conftest.dSYM
1042     ])
1043     case $host_os in
1044     rhapsody* | darwin1.[[012]])
1045       _lt_dar_allow_undefined='${wl}-undefined ${wl}suppress' ;;
1046     darwin1.*)
1047       _lt_dar_allow_undefined='${wl}-flat_namespace ${wl}-undefined ${wl}suppress' ;;
1048     darwin*) # darwin 5.x on
1049       # if running on 10.5 or later, the deployment target defaults
1050       # to the OS version, if on x86, and 10.4, the deployment
1051       # target defaults to 10.4. Don't you love it?
1052       case ${MACOSX_DEPLOYMENT_TARGET-10.0},$host in
1053         10.0,*86*-darwin8*|10.0,*-darwin[[91]]*)
1054           _lt_dar_allow_undefined='${wl}-undefined ${wl}dynamic_lookup' ;;
1055         10.[[012]]*)
1056           _lt_dar_allow_undefined='${wl}-flat_namespace ${wl}-undefined ${wl}suppress' ;;
1057         10.*)
1058           _lt_dar_allow_undefined='${wl}-undefined ${wl}dynamic_lookup' ;;
1059       esac
1060     ;;
1061   esac
1062     if test "$lt_cv_apple_cc_single_mod" = "yes"; then
1063       _lt_dar_single_mod='$single_module'
1064     fi
1065     if test "$lt_cv_ld_exported_symbols_list" = "yes"; then
1066       _lt_dar_export_syms=' ${wl}-exported_symbols_list,$output_objdir/${libname}-symbols.expsym'
1067     else
1068       _lt_dar_export_syms='~$NMEDIT -s $output_objdir/${libname}-symbols.expsym ${lib}'
1069     fi
1070     if test "$DSYMUTIL" != ":" && test "$lt_cv_ld_force_load" = "no"; then
1071       _lt_dsymutil='~$DSYMUTIL $lib || :'
1072     else
1073       _lt_dsymutil=
1074     fi
1075     ;;
1076   esac
1077 ])
1078
1079
1080 # _LT_DARWIN_LINKER_FEATURES([TAG])
1081 # ---------------------------------
1082 # Checks for linker and compiler features on darwin
1083 m4_defun([_LT_DARWIN_LINKER_FEATURES],
1084 [
1085   m4_require([_LT_REQUIRED_DARWIN_CHECKS])
1086   _LT_TAGVAR(archive_cmds_need_lc, $1)=no
1087   _LT_TAGVAR(hardcode_direct, $1)=no
1088   _LT_TAGVAR(hardcode_automatic, $1)=yes
1089   _LT_TAGVAR(hardcode_shlibpath_var, $1)=unsupported
1090   if test "$lt_cv_ld_force_load" = "yes"; then
1091     _LT_TAGVAR(whole_archive_flag_spec, $1)='`for conv in $convenience\"\"; do test  -n \"$conv\" && new_convenience=\"$new_convenience ${wl}-force_load,$conv\"; done; func_echo_all \"$new_convenience\"`'
1092     m4_case([$1], [F77], [_LT_TAGVAR(compiler_needs_object, $1)=yes],
1093                   [FC],  [_LT_TAGVAR(compiler_needs_object, $1)=yes])
1094   else
1095     _LT_TAGVAR(whole_archive_flag_spec, $1)=''
1096   fi
1097   _LT_TAGVAR(link_all_deplibs, $1)=yes
1098   _LT_TAGVAR(allow_undefined_flag, $1)="$_lt_dar_allow_undefined"
1099   case $cc_basename in
1100      ifort*) _lt_dar_can_shared=yes ;;
1101      *) _lt_dar_can_shared=$GCC ;;
1102   esac
1103   if test "$_lt_dar_can_shared" = "yes"; then
1104     output_verbose_link_cmd=func_echo_all
1105     _LT_TAGVAR(archive_cmds, $1)="\$CC -dynamiclib \$allow_undefined_flag -o \$lib \$libobjs \$deplibs \$compiler_flags -install_name \$rpath/\$soname \$verstring $_lt_dar_single_mod${_lt_dsymutil}"
1106     _LT_TAGVAR(module_cmds, $1)="\$CC \$allow_undefined_flag -o \$lib -bundle \$libobjs \$deplibs \$compiler_flags${_lt_dsymutil}"
1107     _LT_TAGVAR(archive_expsym_cmds, $1)="sed 's,^,_,' < \$export_symbols > \$output_objdir/\${libname}-symbols.expsym~\$CC -dynamiclib \$allow_undefined_flag -o \$lib \$libobjs \$deplibs \$compiler_flags -install_name \$rpath/\$soname \$verstring ${_lt_dar_single_mod}${_lt_dar_export_syms}${_lt_dsymutil}"
1108     _LT_TAGVAR(module_expsym_cmds, $1)="sed -e 's,^,_,' < \$export_symbols > \$output_objdir/\${libname}-symbols.expsym~\$CC \$allow_undefined_flag -o \$lib -bundle \$libobjs \$deplibs \$compiler_flags${_lt_dar_export_syms}${_lt_dsymutil}"
1109     m4_if([$1], [CXX],
1110 [   if test "$lt_cv_apple_cc_single_mod" != "yes"; then
1111       _LT_TAGVAR(archive_cmds, $1)="\$CC -r -keep_private_externs -nostdlib -o \${lib}-master.o \$libobjs~\$CC -dynamiclib \$allow_undefined_flag -o \$lib \${lib}-master.o \$deplibs \$compiler_flags -install_name \$rpath/\$soname \$verstring${_lt_dsymutil}"
1112       _LT_TAGVAR(archive_expsym_cmds, $1)="sed 's,^,_,' < \$export_symbols > \$output_objdir/\${libname}-symbols.expsym~\$CC -r -keep_private_externs -nostdlib -o \${lib}-master.o \$libobjs~\$CC -dynamiclib \$allow_undefined_flag -o \$lib \${lib}-master.o \$deplibs \$compiler_flags -install_name \$rpath/\$soname \$verstring${_lt_dar_export_syms}${_lt_dsymutil}"
1113     fi
1114 ],[])
1115   else
1116   _LT_TAGVAR(ld_shlibs, $1)=no
1117   fi
1118 ])
1119
1120 # _LT_SYS_MODULE_PATH_AIX([TAGNAME])
1121 # ----------------------------------
1122 # Links a minimal program and checks the executable
1123 # for the system default hardcoded library path. In most cases,
1124 # this is /usr/lib:/lib, but when the MPI compilers are used
1125 # the location of the communication and MPI libs are included too.
1126 # If we don't find anything, use the default library path according
1127 # to the aix ld manual.
1128 # Store the results from the different compilers for each TAGNAME.
1129 # Allow to override them for all tags through lt_cv_aix_libpath.
1130 m4_defun([_LT_SYS_MODULE_PATH_AIX],
1131 [m4_require([_LT_DECL_SED])dnl
1132 if test "${lt_cv_aix_libpath+set}" = set; then
1133   aix_libpath=$lt_cv_aix_libpath
1134 else
1135   AC_CACHE_VAL([_LT_TAGVAR([lt_cv_aix_libpath_], [$1])],
1136   [AC_LINK_IFELSE([AC_LANG_PROGRAM],[
1137   lt_aix_libpath_sed='[
1138       /Import File Strings/,/^$/ {
1139           /^0/ {
1140               s/^0  *\([^ ]*\) *$/\1/
1141               p
1142           }
1143       }]'
1144   _LT_TAGVAR([lt_cv_aix_libpath_], [$1])=`dump -H conftest$ac_exeext 2>/dev/null | $SED -n -e "$lt_aix_libpath_sed"`
1145   # Check for a 64-bit object if we didn't find anything.
1146   if test -z "$_LT_TAGVAR([lt_cv_aix_libpath_], [$1])"; then
1147     _LT_TAGVAR([lt_cv_aix_libpath_], [$1])=`dump -HX64 conftest$ac_exeext 2>/dev/null | $SED -n -e "$lt_aix_libpath_sed"`
1148   fi],[])
1149   if test -z "$_LT_TAGVAR([lt_cv_aix_libpath_], [$1])"; then
1150     _LT_TAGVAR([lt_cv_aix_libpath_], [$1])="/usr/lib:/lib"
1151   fi
1152   ])
1153   aix_libpath=$_LT_TAGVAR([lt_cv_aix_libpath_], [$1])
1154 fi
1155 ])# _LT_SYS_MODULE_PATH_AIX
1156
1157
1158 # _LT_SHELL_INIT(ARG)
1159 # -------------------
1160 m4_define([_LT_SHELL_INIT],
1161 [m4_divert_text([M4SH-INIT], [$1
1162 ])])# _LT_SHELL_INIT
1163
1164
1165
1166 # _LT_PROG_ECHO_BACKSLASH
1167 # -----------------------
1168 # Find how we can fake an echo command that does not interpret backslash.
1169 # In particular, with Autoconf 2.60 or later we add some code to the start
1170 # of the generated configure script which will find a shell with a builtin
1171 # printf (which we can use as an echo command).
1172 m4_defun([_LT_PROG_ECHO_BACKSLASH],
1173 [ECHO='\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\'
1174 ECHO=$ECHO$ECHO$ECHO$ECHO$ECHO
1175 ECHO=$ECHO$ECHO$ECHO$ECHO$ECHO$ECHO
1176
1177 AC_MSG_CHECKING([how to print strings])
1178 # Test print first, because it will be a builtin if present.
1179 if test "X`( print -r -- -n ) 2>/dev/null`" = X-n && \
1180    test "X`print -r -- $ECHO 2>/dev/null`" = "X$ECHO"; then
1181   ECHO='print -r --'
1182 elif test "X`printf %s $ECHO 2>/dev/null`" = "X$ECHO"; then
1183   ECHO='printf %s\n'
1184 else
1185   # Use this function as a fallback that always works.
1186   func_fallback_echo ()
1187   {
1188     eval 'cat <<_LTECHO_EOF
1189 $[]1
1190 _LTECHO_EOF'
1191   }
1192   ECHO='func_fallback_echo'
1193 fi
1194
1195 # func_echo_all arg...
1196 # Invoke $ECHO with all args, space-separated.
1197 func_echo_all ()
1198 {
1199     $ECHO "$*"
1200 }
1201
1202 case "$ECHO" in
1203   printf*) AC_MSG_RESULT([printf]) ;;
1204   print*) AC_MSG_RESULT([print -r]) ;;
1205   *) AC_MSG_RESULT([cat]) ;;
1206 esac
1207
1208 m4_ifdef([_AS_DETECT_SUGGESTED],
1209 [_AS_DETECT_SUGGESTED([
1210   test -n "${ZSH_VERSION+set}${BASH_VERSION+set}" || (
1211     ECHO='\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\'
1212     ECHO=$ECHO$ECHO$ECHO$ECHO$ECHO
1213     ECHO=$ECHO$ECHO$ECHO$ECHO$ECHO$ECHO
1214     PATH=/empty FPATH=/empty; export PATH FPATH
1215     test "X`printf %s $ECHO`" = "X$ECHO" \
1216       || test "X`print -r -- $ECHO`" = "X$ECHO" )])])
1217
1218 _LT_DECL([], [SHELL], [1], [Shell to use when invoking shell scripts])
1219 _LT_DECL([], [ECHO], [1], [An echo program that protects backslashes])
1220 ])# _LT_PROG_ECHO_BACKSLASH
1221
1222
1223 # _LT_WITH_SYSROOT
1224 # ----------------
1225 AC_DEFUN([_LT_WITH_SYSROOT],
1226 [AC_MSG_CHECKING([for sysroot])
1227 AC_ARG_WITH([sysroot],
1228 [  --with-sysroot[=DIR] Search for dependent libraries within DIR
1229                         (or the compiler's sysroot if not specified).],
1230 [], [with_sysroot=no])
1231
1232 dnl lt_sysroot will always be passed unquoted.  We quote it here
1233 dnl in case the user passed a directory name.
1234 lt_sysroot=
1235 case ${with_sysroot} in #(
1236  yes)
1237    if test "$GCC" = yes; then
1238      lt_sysroot=`$CC --print-sysroot 2>/dev/null`
1239    fi
1240    ;; #(
1241  /*)
1242    lt_sysroot=`echo "$with_sysroot" | sed -e "$sed_quote_subst"`
1243    ;; #(
1244  no|'')
1245    ;; #(
1246  *)
1247    AC_MSG_RESULT([${with_sysroot}])
1248    AC_MSG_ERROR([The sysroot must be an absolute path.])
1249    ;;
1250 esac
1251
1252  AC_MSG_RESULT([${lt_sysroot:-no}])
1253 _LT_DECL([], [lt_sysroot], [0], [The root where to search for ]dnl
1254 [dependent libraries, and in which our libraries should be installed.])])
1255
1256 # _LT_ENABLE_LOCK
1257 # ---------------
1258 m4_defun([_LT_ENABLE_LOCK],
1259 [AC_ARG_ENABLE([libtool-lock],
1260   [AS_HELP_STRING([--disable-libtool-lock],
1261     [avoid locking (might break parallel builds)])])
1262 test "x$enable_libtool_lock" != xno && enable_libtool_lock=yes
1263
1264 # Some flags need to be propagated to the compiler or linker for good
1265 # libtool support.
1266 case $host in
1267 ia64-*-hpux*)
1268   # Find out which ABI we are using.
1269   echo 'int i;' > conftest.$ac_ext
1270   if AC_TRY_EVAL(ac_compile); then
1271     case `/usr/bin/file conftest.$ac_objext` in
1272       *ELF-32*)
1273         HPUX_IA64_MODE="32"
1274         ;;
1275       *ELF-64*)
1276         HPUX_IA64_MODE="64"
1277         ;;
1278     esac
1279   fi
1280   rm -rf conftest*
1281   ;;
1282 *-*-irix6*)
1283   # Find out which ABI we are using.
1284   echo '[#]line '$LINENO' "configure"' > conftest.$ac_ext
1285   if AC_TRY_EVAL(ac_compile); then
1286     if test "$lt_cv_prog_gnu_ld" = yes; then
1287       case `/usr/bin/file conftest.$ac_objext` in
1288         *32-bit*)
1289           LD="${LD-ld} -melf32bsmip"
1290           ;;
1291         *N32*)
1292           LD="${LD-ld} -melf32bmipn32"
1293           ;;
1294         *64-bit*)
1295           LD="${LD-ld} -melf64bmip"
1296         ;;
1297       esac
1298     else
1299       case `/usr/bin/file conftest.$ac_objext` in
1300         *32-bit*)
1301           LD="${LD-ld} -32"
1302           ;;
1303         *N32*)
1304           LD="${LD-ld} -n32"
1305           ;;
1306         *64-bit*)
1307           LD="${LD-ld} -64"
1308           ;;
1309       esac
1310     fi
1311   fi
1312   rm -rf conftest*
1313   ;;
1314
1315 x86_64-*kfreebsd*-gnu|x86_64-*linux*|ppc*-*linux*|powerpc*-*linux*| \
1316 s390*-*linux*|s390*-*tpf*|sparc*-*linux*)
1317   # Find out which ABI we are using.
1318   echo 'int i;' > conftest.$ac_ext
1319   if AC_TRY_EVAL(ac_compile); then
1320     case `/usr/bin/file conftest.o` in
1321       *32-bit*)
1322         case $host in
1323           x86_64-*kfreebsd*-gnu)
1324             LD="${LD-ld} -m elf_i386_fbsd"
1325             ;;
1326           x86_64-*linux*)
1327             LD="${LD-ld} -m elf_i386"
1328             ;;
1329          powerpc64le-*)
1330            LD="${LD-ld} -m elf32lppclinux"
1331            ;;
1332          powerpc64-*)
1333             LD="${LD-ld} -m elf32ppclinux"
1334             ;;
1335           s390x-*linux*)
1336             LD="${LD-ld} -m elf_s390"
1337             ;;
1338           sparc64-*linux*)
1339             LD="${LD-ld} -m elf32_sparc"
1340             ;;
1341         esac
1342         ;;
1343       *64-bit*)
1344         case $host in
1345           x86_64-*kfreebsd*-gnu)
1346             LD="${LD-ld} -m elf_x86_64_fbsd"
1347             ;;
1348           x86_64-*linux*)
1349             LD="${LD-ld} -m elf_x86_64"
1350             ;;
1351          powerpcle-*)
1352            LD="${LD-ld} -m elf64lppc"
1353            ;;
1354          powerpc-*)
1355             LD="${LD-ld} -m elf64ppc"
1356             ;;
1357           s390*-*linux*|s390*-*tpf*)
1358             LD="${LD-ld} -m elf64_s390"
1359             ;;
1360           sparc*-*linux*)
1361             LD="${LD-ld} -m elf64_sparc"
1362             ;;
1363         esac
1364         ;;
1365     esac
1366   fi
1367   rm -rf conftest*
1368   ;;
1369
1370 *-*-sco3.2v5*)
1371   # On SCO OpenServer 5, we need -belf to get full-featured binaries.
1372   SAVE_CFLAGS="$CFLAGS"
1373   CFLAGS="$CFLAGS -belf"
1374   AC_CACHE_CHECK([whether the C compiler needs -belf], lt_cv_cc_needs_belf,
1375     [AC_LANG_PUSH(C)
1376      AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],[[]])],[lt_cv_cc_needs_belf=yes],[lt_cv_cc_needs_belf=no])
1377      AC_LANG_POP])
1378   if test x"$lt_cv_cc_needs_belf" != x"yes"; then
1379     # this is probably gcc 2.8.0, egcs 1.0 or newer; no need for -belf
1380     CFLAGS="$SAVE_CFLAGS"
1381   fi
1382   ;;
1383 *-*solaris*)
1384   # Find out which ABI we are using.
1385   echo 'int i;' > conftest.$ac_ext
1386   if AC_TRY_EVAL(ac_compile); then
1387     case `/usr/bin/file conftest.o` in
1388     *64-bit*)
1389       case $lt_cv_prog_gnu_ld in
1390       yes*)
1391         case $host in
1392         i?86-*-solaris*)
1393           LD="${LD-ld} -m elf_x86_64"
1394           ;;
1395         sparc*-*-solaris*)
1396           LD="${LD-ld} -m elf64_sparc"
1397           ;;
1398         esac
1399         # GNU ld 2.21 introduced _sol2 emulations.  Use them if available.
1400         if ${LD-ld} -V | grep _sol2 >/dev/null 2>&1; then
1401           LD="${LD-ld}_sol2"
1402         fi
1403         ;;
1404       *)
1405         if ${LD-ld} -64 -r -o conftest2.o conftest.o >/dev/null 2>&1; then
1406           LD="${LD-ld} -64"
1407         fi
1408         ;;
1409       esac
1410       ;;
1411     esac
1412   fi
1413   rm -rf conftest*
1414   ;;
1415 esac
1416
1417 need_locks="$enable_libtool_lock"
1418 ])# _LT_ENABLE_LOCK
1419
1420
1421 # _LT_PROG_AR
1422 # -----------
1423 m4_defun([_LT_PROG_AR],
1424 [AC_CHECK_TOOLS(AR, [ar], false)
1425 : ${AR=ar}
1426 : ${AR_FLAGS=cru}
1427 _LT_DECL([], [AR], [1], [The archiver])
1428 _LT_DECL([], [AR_FLAGS], [1], [Flags to create an archive])
1429
1430 AC_CACHE_CHECK([for archiver @FILE support], [lt_cv_ar_at_file],
1431   [lt_cv_ar_at_file=no
1432    AC_COMPILE_IFELSE([AC_LANG_PROGRAM],
1433      [echo conftest.$ac_objext > conftest.lst
1434       lt_ar_try='$AR $AR_FLAGS libconftest.a @conftest.lst >&AS_MESSAGE_LOG_FD'
1435       AC_TRY_EVAL([lt_ar_try])
1436       if test "$ac_status" -eq 0; then
1437         # Ensure the archiver fails upon bogus file names.
1438         rm -f conftest.$ac_objext libconftest.a
1439         AC_TRY_EVAL([lt_ar_try])
1440         if test "$ac_status" -ne 0; then
1441           lt_cv_ar_at_file=@
1442         fi
1443       fi
1444       rm -f conftest.* libconftest.a
1445      ])
1446   ])
1447
1448 if test "x$lt_cv_ar_at_file" = xno; then
1449   archiver_list_spec=
1450 else
1451   archiver_list_spec=$lt_cv_ar_at_file
1452 fi
1453 _LT_DECL([], [archiver_list_spec], [1],
1454   [How to feed a file listing to the archiver])
1455 ])# _LT_PROG_AR
1456
1457
1458 # _LT_CMD_OLD_ARCHIVE
1459 # -------------------
1460 m4_defun([_LT_CMD_OLD_ARCHIVE],
1461 [_LT_PROG_AR
1462
1463 AC_CHECK_TOOL(STRIP, strip, :)
1464 test -z "$STRIP" && STRIP=:
1465 _LT_DECL([], [STRIP], [1], [A symbol stripping program])
1466
1467 AC_CHECK_TOOL(RANLIB, ranlib, :)
1468 test -z "$RANLIB" && RANLIB=:
1469 _LT_DECL([], [RANLIB], [1],
1470     [Commands used to install an old-style archive])
1471
1472 # Determine commands to create old-style static archives.
1473 old_archive_cmds='$AR $AR_FLAGS $oldlib$oldobjs'
1474 old_postinstall_cmds='chmod 644 $oldlib'
1475 old_postuninstall_cmds=
1476
1477 if test -n "$RANLIB"; then
1478   case $host_os in
1479   openbsd*)
1480     old_postinstall_cmds="$old_postinstall_cmds~\$RANLIB -t \$tool_oldlib"
1481     ;;
1482   *)
1483     old_postinstall_cmds="$old_postinstall_cmds~\$RANLIB \$tool_oldlib"
1484     ;;
1485   esac
1486   old_archive_cmds="$old_archive_cmds~\$RANLIB \$tool_oldlib"
1487 fi
1488
1489 case $host_os in
1490   darwin*)
1491     lock_old_archive_extraction=yes ;;
1492   *)
1493     lock_old_archive_extraction=no ;;
1494 esac
1495 _LT_DECL([], [old_postinstall_cmds], [2])
1496 _LT_DECL([], [old_postuninstall_cmds], [2])
1497 _LT_TAGDECL([], [old_archive_cmds], [2],
1498     [Commands used to build an old-style archive])
1499 _LT_DECL([], [lock_old_archive_extraction], [0],
1500     [Whether to use a lock for old archive extraction])
1501 ])# _LT_CMD_OLD_ARCHIVE
1502
1503
1504 # _LT_COMPILER_OPTION(MESSAGE, VARIABLE-NAME, FLAGS,
1505 #               [OUTPUT-FILE], [ACTION-SUCCESS], [ACTION-FAILURE])
1506 # ----------------------------------------------------------------
1507 # Check whether the given compiler option works
1508 AC_DEFUN([_LT_COMPILER_OPTION],
1509 [m4_require([_LT_FILEUTILS_DEFAULTS])dnl
1510 m4_require([_LT_DECL_SED])dnl
1511 AC_CACHE_CHECK([$1], [$2],
1512   [$2=no
1513    m4_if([$4], , [ac_outfile=conftest.$ac_objext], [ac_outfile=$4])
1514    echo "$lt_simple_compile_test_code" > conftest.$ac_ext
1515    lt_compiler_flag="$3"
1516    # Insert the option either (1) after the last *FLAGS variable, or
1517    # (2) before a word containing "conftest.", or (3) at the end.
1518    # Note that $ac_compile itself does not contain backslashes and begins
1519    # with a dollar sign (not a hyphen), so the echo should work correctly.
1520    # The option is referenced via a variable to avoid confusing sed.
1521    lt_compile=`echo "$ac_compile" | $SED \
1522    -e 's:.*FLAGS}\{0,1\} :&$lt_compiler_flag :; t' \
1523    -e 's: [[^ ]]*conftest\.: $lt_compiler_flag&:; t' \
1524    -e 's:$: $lt_compiler_flag:'`
1525    (eval echo "\"\$as_me:$LINENO: $lt_compile\"" >&AS_MESSAGE_LOG_FD)
1526    (eval "$lt_compile" 2>conftest.err)
1527    ac_status=$?
1528    cat conftest.err >&AS_MESSAGE_LOG_FD
1529    echo "$as_me:$LINENO: \$? = $ac_status" >&AS_MESSAGE_LOG_FD
1530    if (exit $ac_status) && test -s "$ac_outfile"; then
1531      # The compiler can only warn and ignore the option if not recognized
1532      # So say no if there are warnings other than the usual output.
1533      $ECHO "$_lt_compiler_boilerplate" | $SED '/^$/d' >conftest.exp
1534      $SED '/^$/d; /^ *+/d' conftest.err >conftest.er2
1535      if test ! -s conftest.er2 || diff conftest.exp conftest.er2 >/dev/null; then
1536        $2=yes
1537      fi
1538    fi
1539    $RM conftest*
1540 ])
1541
1542 if test x"[$]$2" = xyes; then
1543     m4_if([$5], , :, [$5])
1544 else
1545     m4_if([$6], , :, [$6])
1546 fi
1547 ])# _LT_COMPILER_OPTION
1548
1549 # Old name:
1550 AU_ALIAS([AC_LIBTOOL_COMPILER_OPTION], [_LT_COMPILER_OPTION])
1551 dnl aclocal-1.4 backwards compatibility:
1552 dnl AC_DEFUN([AC_LIBTOOL_COMPILER_OPTION], [])
1553
1554
1555 # _LT_LINKER_OPTION(MESSAGE, VARIABLE-NAME, FLAGS,
1556 #                  [ACTION-SUCCESS], [ACTION-FAILURE])
1557 # ----------------------------------------------------
1558 # Check whether the given linker option works
1559 AC_DEFUN([_LT_LINKER_OPTION],
1560 [m4_require([_LT_FILEUTILS_DEFAULTS])dnl
1561 m4_require([_LT_DECL_SED])dnl
1562 AC_CACHE_CHECK([$1], [$2],
1563   [$2=no
1564    save_LDFLAGS="$LDFLAGS"
1565    LDFLAGS="$LDFLAGS $3"
1566    echo "$lt_simple_link_test_code" > conftest.$ac_ext
1567    if (eval $ac_link 2>conftest.err) && test -s conftest$ac_exeext; then
1568      # The linker can only warn and ignore the option if not recognized
1569      # So say no if there are warnings
1570      if test -s conftest.err; then
1571        # Append any errors to the config.log.
1572        cat conftest.err 1>&AS_MESSAGE_LOG_FD
1573        $ECHO "$_lt_linker_boilerplate" | $SED '/^$/d' > conftest.exp
1574        $SED '/^$/d; /^ *+/d' conftest.err >conftest.er2
1575        if diff conftest.exp conftest.er2 >/dev/null; then
1576          $2=yes
1577        fi
1578      else
1579        $2=yes
1580      fi
1581    fi
1582    $RM -r conftest*
1583    LDFLAGS="$save_LDFLAGS"
1584 ])
1585
1586 if test x"[$]$2" = xyes; then
1587     m4_if([$4], , :, [$4])
1588 else
1589     m4_if([$5], , :, [$5])
1590 fi
1591 ])# _LT_LINKER_OPTION
1592
1593 # Old name:
1594 AU_ALIAS([AC_LIBTOOL_LINKER_OPTION], [_LT_LINKER_OPTION])
1595 dnl aclocal-1.4 backwards compatibility:
1596 dnl AC_DEFUN([AC_LIBTOOL_LINKER_OPTION], [])
1597
1598
1599 # LT_CMD_MAX_LEN
1600 #---------------
1601 AC_DEFUN([LT_CMD_MAX_LEN],
1602 [AC_REQUIRE([AC_CANONICAL_HOST])dnl
1603 # find the maximum length of command line arguments
1604 AC_MSG_CHECKING([the maximum length of command line arguments])
1605 AC_CACHE_VAL([lt_cv_sys_max_cmd_len], [dnl
1606   i=0
1607   teststring="ABCD"
1608
1609   case $build_os in
1610   msdosdjgpp*)
1611     # On DJGPP, this test can blow up pretty badly due to problems in libc
1612     # (any single argument exceeding 2000 bytes causes a buffer overrun
1613     # during glob expansion).  Even if it were fixed, the result of this
1614     # check would be larger than it should be.
1615     lt_cv_sys_max_cmd_len=12288;    # 12K is about right
1616     ;;
1617
1618   gnu*)
1619     # Under GNU Hurd, this test is not required because there is
1620     # no limit to the length of command line arguments.
1621     # Libtool will interpret -1 as no limit whatsoever
1622     lt_cv_sys_max_cmd_len=-1;
1623     ;;
1624
1625   cygwin* | mingw* | cegcc*)
1626     # On Win9x/ME, this test blows up -- it succeeds, but takes
1627     # about 5 minutes as the teststring grows exponentially.
1628     # Worse, since 9x/ME are not pre-emptively multitasking,
1629     # you end up with a "frozen" computer, even though with patience
1630     # the test eventually succeeds (with a max line length of 256k).
1631     # Instead, let's just punt: use the minimum linelength reported by
1632     # all of the supported platforms: 8192 (on NT/2K/XP).
1633     lt_cv_sys_max_cmd_len=8192;
1634     ;;
1635
1636   mint*)
1637     # On MiNT this can take a long time and run out of memory.
1638     lt_cv_sys_max_cmd_len=8192;
1639     ;;
1640
1641   amigaos*)
1642     # On AmigaOS with pdksh, this test takes hours, literally.
1643     # So we just punt and use a minimum line length of 8192.
1644     lt_cv_sys_max_cmd_len=8192;
1645     ;;
1646
1647   netbsd* | freebsd* | openbsd* | darwin* | dragonfly*)
1648     # This has been around since 386BSD, at least.  Likely further.
1649     if test -x /sbin/sysctl; then
1650       lt_cv_sys_max_cmd_len=`/sbin/sysctl -n kern.argmax`
1651     elif test -x /usr/sbin/sysctl; then
1652       lt_cv_sys_max_cmd_len=`/usr/sbin/sysctl -n kern.argmax`
1653     else
1654       lt_cv_sys_max_cmd_len=65536       # usable default for all BSDs
1655     fi
1656     # And add a safety zone
1657     lt_cv_sys_max_cmd_len=`expr $lt_cv_sys_max_cmd_len \/ 4`
1658     lt_cv_sys_max_cmd_len=`expr $lt_cv_sys_max_cmd_len \* 3`
1659     ;;
1660
1661   interix*)
1662     # We know the value 262144 and hardcode it with a safety zone (like BSD)
1663     lt_cv_sys_max_cmd_len=196608
1664     ;;
1665
1666   os2*)
1667     # The test takes a long time on OS/2.
1668     lt_cv_sys_max_cmd_len=8192
1669     ;;
1670
1671   osf*)
1672     # Dr. Hans Ekkehard Plesser reports seeing a kernel panic running configure
1673     # due to this test when exec_disable_arg_limit is 1 on Tru64. It is not
1674     # nice to cause kernel panics so lets avoid the loop below.
1675     # First set a reasonable default.
1676     lt_cv_sys_max_cmd_len=16384
1677     #
1678     if test -x /sbin/sysconfig; then
1679       case `/sbin/sysconfig -q proc exec_disable_arg_limit` in
1680         *1*) lt_cv_sys_max_cmd_len=-1 ;;
1681       esac
1682     fi
1683     ;;
1684   sco3.2v5*)
1685     lt_cv_sys_max_cmd_len=102400
1686     ;;
1687   sysv5* | sco5v6* | sysv4.2uw2*)
1688     kargmax=`grep ARG_MAX /etc/conf/cf.d/stune 2>/dev/null`
1689     if test -n "$kargmax"; then
1690       lt_cv_sys_max_cmd_len=`echo $kargmax | sed 's/.*[[         ]]//'`
1691     else
1692       lt_cv_sys_max_cmd_len=32768
1693     fi
1694     ;;
1695   *)
1696     lt_cv_sys_max_cmd_len=`(getconf ARG_MAX) 2> /dev/null`
1697     if test -n "$lt_cv_sys_max_cmd_len"; then
1698       lt_cv_sys_max_cmd_len=`expr $lt_cv_sys_max_cmd_len \/ 4`
1699       lt_cv_sys_max_cmd_len=`expr $lt_cv_sys_max_cmd_len \* 3`
1700     else
1701       # Make teststring a little bigger before we do anything with it.
1702       # a 1K string should be a reasonable start.
1703       for i in 1 2 3 4 5 6 7 8 ; do
1704         teststring=$teststring$teststring
1705       done
1706       SHELL=${SHELL-${CONFIG_SHELL-/bin/sh}}
1707       # If test is not a shell built-in, we'll probably end up computing a
1708       # maximum length that is only half of the actual maximum length, but
1709       # we can't tell.
1710       while { test "X"`env echo "$teststring$teststring" 2>/dev/null` \
1711                  = "X$teststring$teststring"; } >/dev/null 2>&1 &&
1712               test $i != 17 # 1/2 MB should be enough
1713       do
1714         i=`expr $i + 1`
1715         teststring=$teststring$teststring
1716       done
1717       # Only check the string length outside the loop.
1718       lt_cv_sys_max_cmd_len=`expr "X$teststring" : ".*" 2>&1`
1719       teststring=
1720       # Add a significant safety factor because C++ compilers can tack on
1721       # massive amounts of additional arguments before passing them to the
1722       # linker.  It appears as though 1/2 is a usable value.
1723       lt_cv_sys_max_cmd_len=`expr $lt_cv_sys_max_cmd_len \/ 2`
1724     fi
1725     ;;
1726   esac
1727 ])
1728 if test -n $lt_cv_sys_max_cmd_len ; then
1729   AC_MSG_RESULT($lt_cv_sys_max_cmd_len)
1730 else
1731   AC_MSG_RESULT(none)
1732 fi
1733 max_cmd_len=$lt_cv_sys_max_cmd_len
1734 _LT_DECL([], [max_cmd_len], [0],
1735     [What is the maximum length of a command?])
1736 ])# LT_CMD_MAX_LEN
1737
1738 # Old name:
1739 AU_ALIAS([AC_LIBTOOL_SYS_MAX_CMD_LEN], [LT_CMD_MAX_LEN])
1740 dnl aclocal-1.4 backwards compatibility:
1741 dnl AC_DEFUN([AC_LIBTOOL_SYS_MAX_CMD_LEN], [])
1742
1743
1744 # _LT_HEADER_DLFCN
1745 # ----------------
1746 m4_defun([_LT_HEADER_DLFCN],
1747 [AC_CHECK_HEADERS([dlfcn.h], [], [], [AC_INCLUDES_DEFAULT])dnl
1748 ])# _LT_HEADER_DLFCN
1749
1750
1751 # _LT_TRY_DLOPEN_SELF (ACTION-IF-TRUE, ACTION-IF-TRUE-W-USCORE,
1752 #                      ACTION-IF-FALSE, ACTION-IF-CROSS-COMPILING)
1753 # ----------------------------------------------------------------
1754 m4_defun([_LT_TRY_DLOPEN_SELF],
1755 [m4_require([_LT_HEADER_DLFCN])dnl
1756 if test "$cross_compiling" = yes; then :
1757   [$4]
1758 else
1759   lt_dlunknown=0; lt_dlno_uscore=1; lt_dlneed_uscore=2
1760   lt_status=$lt_dlunknown
1761   cat > conftest.$ac_ext <<_LT_EOF
1762 [#line $LINENO "configure"
1763 #include "confdefs.h"
1764
1765 #if HAVE_DLFCN_H
1766 #include <dlfcn.h>
1767 #endif
1768
1769 #include <stdio.h>
1770
1771 #ifdef RTLD_GLOBAL
1772 #  define LT_DLGLOBAL           RTLD_GLOBAL
1773 #else
1774 #  ifdef DL_GLOBAL
1775 #    define LT_DLGLOBAL         DL_GLOBAL
1776 #  else
1777 #    define LT_DLGLOBAL         0
1778 #  endif
1779 #endif
1780
1781 /* We may have to define LT_DLLAZY_OR_NOW in the command line if we
1782    find out it does not work in some platform. */
1783 #ifndef LT_DLLAZY_OR_NOW
1784 #  ifdef RTLD_LAZY
1785 #    define LT_DLLAZY_OR_NOW            RTLD_LAZY
1786 #  else
1787 #    ifdef DL_LAZY
1788 #      define LT_DLLAZY_OR_NOW          DL_LAZY
1789 #    else
1790 #      ifdef RTLD_NOW
1791 #        define LT_DLLAZY_OR_NOW        RTLD_NOW
1792 #      else
1793 #        ifdef DL_NOW
1794 #          define LT_DLLAZY_OR_NOW      DL_NOW
1795 #        else
1796 #          define LT_DLLAZY_OR_NOW      0
1797 #        endif
1798 #      endif
1799 #    endif
1800 #  endif
1801 #endif
1802
1803 /* When -fvisbility=hidden is used, assume the code has been annotated
1804    correspondingly for the symbols needed.  */
1805 #if defined(__GNUC__) && (((__GNUC__ == 3) && (__GNUC_MINOR__ >= 3)) || (__GNUC__ > 3))
1806 int fnord () __attribute__((visibility("default")));
1807 #endif
1808
1809 int fnord () { return 42; }
1810 int main ()
1811 {
1812   void *self = dlopen (0, LT_DLGLOBAL|LT_DLLAZY_OR_NOW);
1813   int status = $lt_dlunknown;
1814
1815   if (self)
1816     {
1817       if (dlsym (self,"fnord"))       status = $lt_dlno_uscore;
1818       else
1819         {
1820           if (dlsym( self,"_fnord"))  status = $lt_dlneed_uscore;
1821           else puts (dlerror ());
1822         }
1823       /* dlclose (self); */
1824     }
1825   else
1826     puts (dlerror ());
1827
1828   return status;
1829 }]
1830 _LT_EOF
1831   if AC_TRY_EVAL(ac_link) && test -s conftest${ac_exeext} 2>/dev/null; then
1832     (./conftest; exit; ) >&AS_MESSAGE_LOG_FD 2>/dev/null
1833     lt_status=$?
1834     case x$lt_status in
1835       x$lt_dlno_uscore) $1 ;;
1836       x$lt_dlneed_uscore) $2 ;;
1837       x$lt_dlunknown|x*) $3 ;;
1838     esac
1839   else :
1840     # compilation failed
1841     $3
1842   fi
1843 fi
1844 rm -fr conftest*
1845 ])# _LT_TRY_DLOPEN_SELF
1846
1847
1848 # LT_SYS_DLOPEN_SELF
1849 # ------------------
1850 AC_DEFUN([LT_SYS_DLOPEN_SELF],
1851 [m4_require([_LT_HEADER_DLFCN])dnl
1852 if test "x$enable_dlopen" != xyes; then
1853   enable_dlopen=unknown
1854   enable_dlopen_self=unknown
1855   enable_dlopen_self_static=unknown
1856 else
1857   lt_cv_dlopen=no
1858   lt_cv_dlopen_libs=
1859
1860   case $host_os in
1861   beos*)
1862     lt_cv_dlopen="load_add_on"
1863     lt_cv_dlopen_libs=
1864     lt_cv_dlopen_self=yes
1865     ;;
1866
1867   mingw* | pw32* | cegcc*)
1868     lt_cv_dlopen="LoadLibrary"
1869     lt_cv_dlopen_libs=
1870     ;;
1871
1872   cygwin*)
1873     lt_cv_dlopen="dlopen"
1874     lt_cv_dlopen_libs=
1875     ;;
1876
1877   darwin*)
1878   # if libdl is installed we need to link against it
1879     AC_CHECK_LIB([dl], [dlopen],
1880                 [lt_cv_dlopen="dlopen" lt_cv_dlopen_libs="-ldl"],[
1881     lt_cv_dlopen="dyld"
1882     lt_cv_dlopen_libs=
1883     lt_cv_dlopen_self=yes
1884     ])
1885     ;;
1886
1887   *)
1888     AC_CHECK_FUNC([shl_load],
1889           [lt_cv_dlopen="shl_load"],
1890       [AC_CHECK_LIB([dld], [shl_load],
1891             [lt_cv_dlopen="shl_load" lt_cv_dlopen_libs="-ldld"],
1892         [AC_CHECK_FUNC([dlopen],
1893               [lt_cv_dlopen="dlopen"],
1894           [AC_CHECK_LIB([dl], [dlopen],
1895                 [lt_cv_dlopen="dlopen" lt_cv_dlopen_libs="-ldl"],
1896             [AC_CHECK_LIB([svld], [dlopen],
1897                   [lt_cv_dlopen="dlopen" lt_cv_dlopen_libs="-lsvld"],
1898               [AC_CHECK_LIB([dld], [dld_link],
1899                     [lt_cv_dlopen="dld_link" lt_cv_dlopen_libs="-ldld"])
1900               ])
1901             ])
1902           ])
1903         ])
1904       ])
1905     ;;
1906   esac
1907
1908   if test "x$lt_cv_dlopen" != xno; then
1909     enable_dlopen=yes
1910   else
1911     enable_dlopen=no
1912   fi
1913
1914   case $lt_cv_dlopen in
1915   dlopen)
1916     save_CPPFLAGS="$CPPFLAGS"
1917     test "x$ac_cv_header_dlfcn_h" = xyes && CPPFLAGS="$CPPFLAGS -DHAVE_DLFCN_H"
1918
1919     save_LDFLAGS="$LDFLAGS"
1920     wl=$lt_prog_compiler_wl eval LDFLAGS=\"\$LDFLAGS $export_dynamic_flag_spec\"
1921
1922     save_LIBS="$LIBS"
1923     LIBS="$lt_cv_dlopen_libs $LIBS"
1924
1925     AC_CACHE_CHECK([whether a program can dlopen itself],
1926           lt_cv_dlopen_self, [dnl
1927           _LT_TRY_DLOPEN_SELF(
1928             lt_cv_dlopen_self=yes, lt_cv_dlopen_self=yes,
1929             lt_cv_dlopen_self=no, lt_cv_dlopen_self=cross)
1930     ])
1931
1932     if test "x$lt_cv_dlopen_self" = xyes; then
1933       wl=$lt_prog_compiler_wl eval LDFLAGS=\"\$LDFLAGS $lt_prog_compiler_static\"
1934       AC_CACHE_CHECK([whether a statically linked program can dlopen itself],
1935           lt_cv_dlopen_self_static, [dnl
1936           _LT_TRY_DLOPEN_SELF(
1937             lt_cv_dlopen_self_static=yes, lt_cv_dlopen_self_static=yes,
1938             lt_cv_dlopen_self_static=no,  lt_cv_dlopen_self_static=cross)
1939       ])
1940     fi
1941
1942     CPPFLAGS="$save_CPPFLAGS"
1943     LDFLAGS="$save_LDFLAGS"
1944     LIBS="$save_LIBS"
1945     ;;
1946   esac
1947
1948   case $lt_cv_dlopen_self in
1949   yes|no) enable_dlopen_self=$lt_cv_dlopen_self ;;
1950   *) enable_dlopen_self=unknown ;;
1951   esac
1952
1953   case $lt_cv_dlopen_self_static in
1954   yes|no) enable_dlopen_self_static=$lt_cv_dlopen_self_static ;;
1955   *) enable_dlopen_self_static=unknown ;;
1956   esac
1957 fi
1958 _LT_DECL([dlopen_support], [enable_dlopen], [0],
1959          [Whether dlopen is supported])
1960 _LT_DECL([dlopen_self], [enable_dlopen_self], [0],
1961          [Whether dlopen of programs is supported])
1962 _LT_DECL([dlopen_self_static], [enable_dlopen_self_static], [0],
1963          [Whether dlopen of statically linked programs is supported])
1964 ])# LT_SYS_DLOPEN_SELF
1965
1966 # Old name:
1967 AU_ALIAS([AC_LIBTOOL_DLOPEN_SELF], [LT_SYS_DLOPEN_SELF])
1968 dnl aclocal-1.4 backwards compatibility:
1969 dnl AC_DEFUN([AC_LIBTOOL_DLOPEN_SELF], [])
1970
1971
1972 # _LT_COMPILER_C_O([TAGNAME])
1973 # ---------------------------
1974 # Check to see if options -c and -o are simultaneously supported by compiler.
1975 # This macro does not hard code the compiler like AC_PROG_CC_C_O.
1976 m4_defun([_LT_COMPILER_C_O],
1977 [m4_require([_LT_DECL_SED])dnl
1978 m4_require([_LT_FILEUTILS_DEFAULTS])dnl
1979 m4_require([_LT_TAG_COMPILER])dnl
1980 AC_CACHE_CHECK([if $compiler supports -c -o file.$ac_objext],
1981   [_LT_TAGVAR(lt_cv_prog_compiler_c_o, $1)],
1982   [_LT_TAGVAR(lt_cv_prog_compiler_c_o, $1)=no
1983    $RM -r conftest 2>/dev/null
1984    mkdir conftest
1985    cd conftest
1986    mkdir out
1987    echo "$lt_simple_compile_test_code" > conftest.$ac_ext
1988
1989    lt_compiler_flag="-o out/conftest2.$ac_objext"
1990    # Insert the option either (1) after the last *FLAGS variable, or
1991    # (2) before a word containing "conftest.", or (3) at the end.
1992    # Note that $ac_compile itself does not contain backslashes and begins
1993    # with a dollar sign (not a hyphen), so the echo should work correctly.
1994    lt_compile=`echo "$ac_compile" | $SED \
1995    -e 's:.*FLAGS}\{0,1\} :&$lt_compiler_flag :; t' \
1996    -e 's: [[^ ]]*conftest\.: $lt_compiler_flag&:; t' \
1997    -e 's:$: $lt_compiler_flag:'`
1998    (eval echo "\"\$as_me:$LINENO: $lt_compile\"" >&AS_MESSAGE_LOG_FD)
1999    (eval "$lt_compile" 2>out/conftest.err)
2000    ac_status=$?
2001    cat out/conftest.err >&AS_MESSAGE_LOG_FD
2002    echo "$as_me:$LINENO: \$? = $ac_status" >&AS_MESSAGE_LOG_FD
2003    if (exit $ac_status) && test -s out/conftest2.$ac_objext
2004    then
2005      # The compiler can only warn and ignore the option if not recognized
2006      # So say no if there are warnings
2007      $ECHO "$_lt_compiler_boilerplate" | $SED '/^$/d' > out/conftest.exp
2008      $SED '/^$/d; /^ *+/d' out/conftest.err >out/conftest.er2
2009      if test ! -s out/conftest.er2 || diff out/conftest.exp out/conftest.er2 >/dev/null; then
2010        _LT_TAGVAR(lt_cv_prog_compiler_c_o, $1)=yes
2011      fi
2012    fi
2013    chmod u+w . 2>&AS_MESSAGE_LOG_FD
2014    $RM conftest*
2015    # SGI C++ compiler will create directory out/ii_files/ for
2016    # template instantiation
2017    test -d out/ii_files && $RM out/ii_files/* && rmdir out/ii_files
2018    $RM out/* && rmdir out
2019    cd ..
2020    $RM -r conftest
2021    $RM conftest*
2022 ])
2023 _LT_TAGDECL([compiler_c_o], [lt_cv_prog_compiler_c_o], [1],
2024         [Does compiler simultaneously support -c and -o options?])
2025 ])# _LT_COMPILER_C_O
2026
2027
2028 # _LT_COMPILER_FILE_LOCKS([TAGNAME])
2029 # ----------------------------------
2030 # Check to see if we can do hard links to lock some files if needed
2031 m4_defun([_LT_COMPILER_FILE_LOCKS],
2032 [m4_require([_LT_ENABLE_LOCK])dnl
2033 m4_require([_LT_FILEUTILS_DEFAULTS])dnl
2034 _LT_COMPILER_C_O([$1])
2035
2036 hard_links="nottested"
2037 if test "$_LT_TAGVAR(lt_cv_prog_compiler_c_o, $1)" = no && test "$need_locks" != no; then
2038   # do not overwrite the value of need_locks provided by the user
2039   AC_MSG_CHECKING([if we can lock with hard links])
2040   hard_links=yes
2041   $RM conftest*
2042   ln conftest.a conftest.b 2>/dev/null && hard_links=no
2043   touch conftest.a
2044   ln conftest.a conftest.b 2>&5 || hard_links=no
2045   ln conftest.a conftest.b 2>/dev/null && hard_links=no
2046   AC_MSG_RESULT([$hard_links])
2047   if test "$hard_links" = no; then
2048     AC_MSG_WARN([`$CC' does not support `-c -o', so `make -j' may be unsafe])
2049     need_locks=warn
2050   fi
2051 else
2052   need_locks=no
2053 fi
2054 _LT_DECL([], [need_locks], [1], [Must we lock files when doing compilation?])
2055 ])# _LT_COMPILER_FILE_LOCKS
2056
2057
2058 # _LT_CHECK_OBJDIR
2059 # ----------------
2060 m4_defun([_LT_CHECK_OBJDIR],
2061 [AC_CACHE_CHECK([for objdir], [lt_cv_objdir],
2062 [rm -f .libs 2>/dev/null
2063 mkdir .libs 2>/dev/null
2064 if test -d .libs; then
2065   lt_cv_objdir=.libs
2066 else
2067   # MS-DOS does not allow filenames that begin with a dot.
2068   lt_cv_objdir=_libs
2069 fi
2070 rmdir .libs 2>/dev/null])
2071 objdir=$lt_cv_objdir
2072 _LT_DECL([], [objdir], [0],
2073          [The name of the directory that contains temporary libtool files])dnl
2074 m4_pattern_allow([LT_OBJDIR])dnl
2075 AC_DEFINE_UNQUOTED(LT_OBJDIR, "$lt_cv_objdir/",
2076   [Define to the sub-directory in which libtool stores uninstalled libraries.])
2077 ])# _LT_CHECK_OBJDIR
2078
2079
2080 # _LT_LINKER_HARDCODE_LIBPATH([TAGNAME])
2081 # --------------------------------------
2082 # Check hardcoding attributes.
2083 m4_defun([_LT_LINKER_HARDCODE_LIBPATH],
2084 [AC_MSG_CHECKING([how to hardcode library paths into programs])
2085 _LT_TAGVAR(hardcode_action, $1)=
2086 if test -n "$_LT_TAGVAR(hardcode_libdir_flag_spec, $1)" ||
2087    test -n "$_LT_TAGVAR(runpath_var, $1)" ||
2088    test "X$_LT_TAGVAR(hardcode_automatic, $1)" = "Xyes" ; then
2089
2090   # We can hardcode non-existent directories.
2091   if test "$_LT_TAGVAR(hardcode_direct, $1)" != no &&
2092      # If the only mechanism to avoid hardcoding is shlibpath_var, we
2093      # have to relink, otherwise we might link with an installed library
2094      # when we should be linking with a yet-to-be-installed one
2095      ## test "$_LT_TAGVAR(hardcode_shlibpath_var, $1)" != no &&
2096      test "$_LT_TAGVAR(hardcode_minus_L, $1)" != no; then
2097     # Linking always hardcodes the temporary library directory.
2098     _LT_TAGVAR(hardcode_action, $1)=relink
2099   else
2100     # We can link without hardcoding, and we can hardcode nonexisting dirs.
2101     _LT_TAGVAR(hardcode_action, $1)=immediate
2102   fi
2103 else
2104   # We cannot hardcode anything, or else we can only hardcode existing
2105   # directories.
2106   _LT_TAGVAR(hardcode_action, $1)=unsupported
2107 fi
2108 AC_MSG_RESULT([$_LT_TAGVAR(hardcode_action, $1)])
2109
2110 if test "$_LT_TAGVAR(hardcode_action, $1)" = relink ||
2111    test "$_LT_TAGVAR(inherit_rpath, $1)" = yes; then
2112   # Fast installation is not supported
2113   enable_fast_install=no
2114 elif test "$shlibpath_overrides_runpath" = yes ||
2115      test "$enable_shared" = no; then
2116   # Fast installation is not necessary
2117   enable_fast_install=needless
2118 fi
2119 _LT_TAGDECL([], [hardcode_action], [0],
2120     [How to hardcode a shared library path into an executable])
2121 ])# _LT_LINKER_HARDCODE_LIBPATH
2122
2123
2124 # _LT_CMD_STRIPLIB
2125 # ----------------
2126 m4_defun([_LT_CMD_STRIPLIB],
2127 [m4_require([_LT_DECL_EGREP])
2128 striplib=
2129 old_striplib=
2130 AC_MSG_CHECKING([whether stripping libraries is possible])
2131 if test -n "$STRIP" && $STRIP -V 2>&1 | $GREP "GNU strip" >/dev/null; then
2132   test -z "$old_striplib" && old_striplib="$STRIP --strip-debug"
2133   test -z "$striplib" && striplib="$STRIP --strip-unneeded"
2134   AC_MSG_RESULT([yes])
2135 else
2136 # FIXME - insert some real tests, host_os isn't really good enough
2137   case $host_os in
2138   darwin*)
2139     if test -n "$STRIP" ; then
2140       striplib="$STRIP -x"
2141       old_striplib="$STRIP -S"
2142       AC_MSG_RESULT([yes])
2143     else
2144       AC_MSG_RESULT([no])
2145     fi
2146     ;;
2147   *)
2148     AC_MSG_RESULT([no])
2149     ;;
2150   esac
2151 fi
2152 _LT_DECL([], [old_striplib], [1], [Commands to strip libraries])
2153 _LT_DECL([], [striplib], [1])
2154 ])# _LT_CMD_STRIPLIB
2155
2156
2157 # _LT_SYS_DYNAMIC_LINKER([TAG])
2158 # -----------------------------
2159 # PORTME Fill in your ld.so characteristics
2160 m4_defun([_LT_SYS_DYNAMIC_LINKER],
2161 [AC_REQUIRE([AC_CANONICAL_HOST])dnl
2162 m4_require([_LT_DECL_EGREP])dnl
2163 m4_require([_LT_FILEUTILS_DEFAULTS])dnl
2164 m4_require([_LT_DECL_OBJDUMP])dnl
2165 m4_require([_LT_DECL_SED])dnl
2166 m4_require([_LT_CHECK_SHELL_FEATURES])dnl
2167 AC_MSG_CHECKING([dynamic linker characteristics])
2168 m4_if([$1],
2169         [], [
2170 if test "$GCC" = yes; then
2171   case $host_os in
2172     darwin*) lt_awk_arg="/^libraries:/,/LR/" ;;
2173     *) lt_awk_arg="/^libraries:/" ;;
2174   esac
2175   case $host_os in
2176     mingw* | cegcc*) lt_sed_strip_eq="s,=\([[A-Za-z]]:\),\1,g" ;;
2177     *) lt_sed_strip_eq="s,=/,/,g" ;;
2178   esac
2179   lt_search_path_spec=`$CC -print-search-dirs | awk $lt_awk_arg | $SED -e "s/^libraries://" -e $lt_sed_strip_eq`
2180   case $lt_search_path_spec in
2181   *\;*)
2182     # if the path contains ";" then we assume it to be the separator
2183     # otherwise default to the standard path separator (i.e. ":") - it is
2184     # assumed that no part of a normal pathname contains ";" but that should
2185     # okay in the real world where ";" in dirpaths is itself problematic.
2186     lt_search_path_spec=`$ECHO "$lt_search_path_spec" | $SED 's/;/ /g'`
2187     ;;
2188   *)
2189     lt_search_path_spec=`$ECHO "$lt_search_path_spec" | $SED "s/$PATH_SEPARATOR/ /g"`
2190     ;;
2191   esac
2192   # Ok, now we have the path, separated by spaces, we can step through it
2193   # and add multilib dir if necessary.
2194   lt_tmp_lt_search_path_spec=
2195   lt_multi_os_dir=`$CC $CPPFLAGS $CFLAGS $LDFLAGS -print-multi-os-directory 2>/dev/null`
2196   for lt_sys_path in $lt_search_path_spec; do
2197     if test -d "$lt_sys_path/$lt_multi_os_dir"; then
2198       lt_tmp_lt_search_path_spec="$lt_tmp_lt_search_path_spec $lt_sys_path/$lt_multi_os_dir"
2199     else
2200       test -d "$lt_sys_path" && \
2201         lt_tmp_lt_search_path_spec="$lt_tmp_lt_search_path_spec $lt_sys_path"
2202     fi
2203   done
2204   lt_search_path_spec=`$ECHO "$lt_tmp_lt_search_path_spec" | awk '
2205 BEGIN {RS=" "; FS="/|\n";} {
2206   lt_foo="";
2207   lt_count=0;
2208   for (lt_i = NF; lt_i > 0; lt_i--) {
2209     if ($lt_i != "" && $lt_i != ".") {
2210       if ($lt_i == "..") {
2211         lt_count++;
2212       } else {
2213         if (lt_count == 0) {
2214           lt_foo="/" $lt_i lt_foo;
2215         } else {
2216           lt_count--;
2217         }
2218       }
2219     }
2220   }
2221   if (lt_foo != "") { lt_freq[[lt_foo]]++; }
2222   if (lt_freq[[lt_foo]] == 1) { print lt_foo; }
2223 }'`
2224   # AWK program above erroneously prepends '/' to C:/dos/paths
2225   # for these hosts.
2226   case $host_os in
2227     mingw* | cegcc*) lt_search_path_spec=`$ECHO "$lt_search_path_spec" |\
2228       $SED 's,/\([[A-Za-z]]:\),\1,g'` ;;
2229   esac
2230   sys_lib_search_path_spec=`$ECHO "$lt_search_path_spec" | $lt_NL2SP`
2231 else
2232   sys_lib_search_path_spec="/lib /usr/lib /usr/local/lib"
2233 fi])
2234 library_names_spec=
2235 libname_spec='lib$name'
2236 soname_spec=
2237 shrext_cmds=".so"
2238 postinstall_cmds=
2239 postuninstall_cmds=
2240 finish_cmds=
2241 finish_eval=
2242 shlibpath_var=
2243 shlibpath_overrides_runpath=unknown
2244 version_type=none
2245 dynamic_linker="$host_os ld.so"
2246 sys_lib_dlsearch_path_spec="/lib /usr/lib"
2247 need_lib_prefix=unknown
2248 hardcode_into_libs=no
2249
2250 # when you set need_version to no, make sure it does not cause -set_version
2251 # flags to be left without arguments
2252 need_version=unknown
2253
2254 case $host_os in
2255 aix3*)
2256   version_type=linux # correct to gnu/linux during the next big refactor
2257   library_names_spec='${libname}${release}${shared_ext}$versuffix $libname.a'
2258   shlibpath_var=LIBPATH
2259
2260   # AIX 3 has no versioning support, so we append a major version to the name.
2261   soname_spec='${libname}${release}${shared_ext}$major'
2262   ;;
2263
2264 aix[[4-9]]*)
2265   version_type=linux # correct to gnu/linux during the next big refactor
2266   need_lib_prefix=no
2267   need_version=no
2268   hardcode_into_libs=yes
2269   if test "$host_cpu" = ia64; then
2270     # AIX 5 supports IA64
2271     library_names_spec='${libname}${release}${shared_ext}$major ${libname}${release}${shared_ext}$versuffix $libname${shared_ext}'
2272     shlibpath_var=LD_LIBRARY_PATH
2273   else
2274     # With GCC up to 2.95.x, collect2 would create an import file
2275     # for dependence libraries.  The import file would start with
2276     # the line `#! .'.  This would cause the generated library to
2277     # depend on `.', always an invalid library.  This was fixed in
2278     # development snapshots of GCC prior to 3.0.
2279     case $host_os in
2280       aix4 | aix4.[[01]] | aix4.[[01]].*)
2281       if { echo '#if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 97)'
2282            echo ' yes '
2283            echo '#endif'; } | ${CC} -E - | $GREP yes > /dev/null; then
2284         :
2285       else
2286         can_build_shared=no
2287       fi
2288       ;;
2289     esac
2290     # AIX (on Power*) has no versioning support, so currently we can not hardcode correct
2291     # soname into executable. Probably we can add versioning support to
2292     # collect2, so additional links can be useful in future.
2293     if test "$aix_use_runtimelinking" = yes; then
2294       # If using run time linking (on AIX 4.2 or later) use lib<name>.so
2295       # instead of lib<name>.a to let people know that these are not
2296       # typical AIX shared libraries.
2297       library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
2298     else
2299       # We preserve .a as extension for shared libraries through AIX4.2
2300       # and later when we are not doing run time linking.
2301       library_names_spec='${libname}${release}.a $libname.a'
2302       soname_spec='${libname}${release}${shared_ext}$major'
2303     fi
2304     shlibpath_var=LIBPATH
2305   fi
2306   ;;
2307
2308 amigaos*)
2309   case $host_cpu in
2310   powerpc)
2311     # Since July 2007 AmigaOS4 officially supports .so libraries.
2312     # When compiling the executable, add -use-dynld -Lsobjs: to the compileline.
2313     library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
2314     ;;
2315   m68k)
2316     library_names_spec='$libname.ixlibrary $libname.a'
2317     # Create ${libname}_ixlibrary.a entries in /sys/libs.
2318     finish_eval='for lib in `ls $libdir/*.ixlibrary 2>/dev/null`; do libname=`func_echo_all "$lib" | $SED '\''s%^.*/\([[^/]]*\)\.ixlibrary$%\1%'\''`; test $RM /sys/libs/${libname}_ixlibrary.a; $show "cd /sys/libs && $LN_S $lib ${libname}_ixlibrary.a"; cd /sys/libs && $LN_S $lib ${libname}_ixlibrary.a || exit 1; done'
2319     ;;
2320   esac
2321   ;;
2322
2323 beos*)
2324   library_names_spec='${libname}${shared_ext}'
2325   dynamic_linker="$host_os ld.so"
2326   shlibpath_var=LIBRARY_PATH
2327   ;;
2328
2329 bsdi[[45]]*)
2330   version_type=linux # correct to gnu/linux during the next big refactor
2331   need_version=no
2332   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
2333   soname_spec='${libname}${release}${shared_ext}$major'
2334   finish_cmds='PATH="\$PATH:/sbin" ldconfig $libdir'
2335   shlibpath_var=LD_LIBRARY_PATH
2336   sys_lib_search_path_spec="/shlib /usr/lib /usr/X11/lib /usr/contrib/lib /lib /usr/local/lib"
2337   sys_lib_dlsearch_path_spec="/shlib /usr/lib /usr/local/lib"
2338   # the default ld.so.conf also contains /usr/contrib/lib and
2339   # /usr/X11R6/lib (/usr/X11 is a link to /usr/X11R6), but let us allow
2340   # libtool to hard-code these into programs
2341   ;;
2342
2343 cygwin* | mingw* | pw32* | cegcc*)
2344   version_type=windows
2345   shrext_cmds=".dll"
2346   need_version=no
2347   need_lib_prefix=no
2348
2349   case $GCC,$cc_basename in
2350   yes,*)
2351     # gcc
2352     library_names_spec='$libname.dll.a'
2353     # DLL is installed to $(libdir)/../bin by postinstall_cmds
2354     postinstall_cmds='base_file=`basename \${file}`~
2355       dlpath=`$SHELL 2>&1 -c '\''. $dir/'\''\${base_file}'\''i; echo \$dlname'\''`~
2356       dldir=$destdir/`dirname \$dlpath`~
2357       test -d \$dldir || mkdir -p \$dldir~
2358       $install_prog $dir/$dlname \$dldir/$dlname~
2359       chmod a+x \$dldir/$dlname~
2360       if test -n '\''$stripme'\'' && test -n '\''$striplib'\''; then
2361         eval '\''$striplib \$dldir/$dlname'\'' || exit \$?;
2362       fi'
2363     postuninstall_cmds='dldll=`$SHELL 2>&1 -c '\''. $file; echo \$dlname'\''`~
2364       dlpath=$dir/\$dldll~
2365        $RM \$dlpath'
2366     shlibpath_overrides_runpath=yes
2367
2368     case $host_os in
2369     cygwin*)
2370       # Cygwin DLLs use 'cyg' prefix rather than 'lib'
2371       soname_spec='`echo ${libname} | sed -e 's/^lib/cyg/'``echo ${release} | $SED -e 's/[[.]]/-/g'`${versuffix}${shared_ext}'
2372 m4_if([$1], [],[
2373       sys_lib_search_path_spec="$sys_lib_search_path_spec /usr/lib/w32api"])
2374       ;;
2375     mingw* | cegcc*)
2376       # MinGW DLLs use traditional 'lib' prefix
2377       soname_spec='${libname}`echo ${release} | $SED -e 's/[[.]]/-/g'`${versuffix}${shared_ext}'
2378       ;;
2379     pw32*)
2380       # pw32 DLLs use 'pw' prefix rather than 'lib'
2381       library_names_spec='`echo ${libname} | sed -e 's/^lib/pw/'``echo ${release} | $SED -e 's/[[.]]/-/g'`${versuffix}${shared_ext}'
2382       ;;
2383     esac
2384     dynamic_linker='Win32 ld.exe'
2385     ;;
2386
2387   *,cl*)
2388     # Native MSVC
2389     libname_spec='$name'
2390     soname_spec='${libname}`echo ${release} | $SED -e 's/[[.]]/-/g'`${versuffix}${shared_ext}'
2391     library_names_spec='${libname}.dll.lib'
2392
2393     case $build_os in
2394     mingw*)
2395       sys_lib_search_path_spec=
2396       lt_save_ifs=$IFS
2397       IFS=';'
2398       for lt_path in $LIB
2399       do
2400         IFS=$lt_save_ifs
2401         # Let DOS variable expansion print the short 8.3 style file name.
2402         lt_path=`cd "$lt_path" 2>/dev/null && cmd //C "for %i in (".") do @echo %~si"`
2403         sys_lib_search_path_spec="$sys_lib_search_path_spec $lt_path"
2404       done
2405       IFS=$lt_save_ifs
2406       # Convert to MSYS style.
2407       sys_lib_search_path_spec=`$ECHO "$sys_lib_search_path_spec" | sed -e 's|\\\\|/|g' -e 's| \\([[a-zA-Z]]\\):| /\\1|g' -e 's|^ ||'`
2408       ;;
2409     cygwin*)
2410       # Convert to unix form, then to dos form, then back to unix form
2411       # but this time dos style (no spaces!) so that the unix form looks
2412       # like /cygdrive/c/PROGRA~1:/cygdr...
2413       sys_lib_search_path_spec=`cygpath --path --unix "$LIB"`
2414       sys_lib_search_path_spec=`cygpath --path --dos "$sys_lib_search_path_spec" 2>/dev/null`
2415       sys_lib_search_path_spec=`cygpath --path --unix "$sys_lib_search_path_spec" | $SED -e "s/$PATH_SEPARATOR/ /g"`
2416       ;;
2417     *)
2418       sys_lib_search_path_spec="$LIB"
2419       if $ECHO "$sys_lib_search_path_spec" | [$GREP ';[c-zC-Z]:/' >/dev/null]; then
2420         # It is most probably a Windows format PATH.
2421         sys_lib_search_path_spec=`$ECHO "$sys_lib_search_path_spec" | $SED -e 's/;/ /g'`
2422       else
2423         sys_lib_search_path_spec=`$ECHO "$sys_lib_search_path_spec" | $SED -e "s/$PATH_SEPARATOR/ /g"`
2424       fi
2425       # FIXME: find the short name or the path components, as spaces are
2426       # common. (e.g. "Program Files" -> "PROGRA~1")
2427       ;;
2428     esac
2429
2430     # DLL is installed to $(libdir)/../bin by postinstall_cmds
2431     postinstall_cmds='base_file=`basename \${file}`~
2432       dlpath=`$SHELL 2>&1 -c '\''. $dir/'\''\${base_file}'\''i; echo \$dlname'\''`~
2433       dldir=$destdir/`dirname \$dlpath`~
2434       test -d \$dldir || mkdir -p \$dldir~
2435       $install_prog $dir/$dlname \$dldir/$dlname'
2436     postuninstall_cmds='dldll=`$SHELL 2>&1 -c '\''. $file; echo \$dlname'\''`~
2437       dlpath=$dir/\$dldll~
2438        $RM \$dlpath'
2439     shlibpath_overrides_runpath=yes
2440     dynamic_linker='Win32 link.exe'
2441     ;;
2442
2443   *)
2444     # Assume MSVC wrapper
2445     library_names_spec='${libname}`echo ${release} | $SED -e 's/[[.]]/-/g'`${versuffix}${shared_ext} $libname.lib'
2446     dynamic_linker='Win32 ld.exe'
2447     ;;
2448   esac
2449   # FIXME: first we should search . and the directory the executable is in
2450   shlibpath_var=PATH
2451   ;;
2452
2453 darwin* | rhapsody*)
2454   dynamic_linker="$host_os dyld"
2455   version_type=darwin
2456   need_lib_prefix=no
2457   need_version=no
2458   library_names_spec='${libname}${release}${major}$shared_ext ${libname}$shared_ext'
2459   soname_spec='${libname}${release}${major}$shared_ext'
2460   shlibpath_overrides_runpath=yes
2461   shlibpath_var=DYLD_LIBRARY_PATH
2462   shrext_cmds='`test .$module = .yes && echo .so || echo .dylib`'
2463 m4_if([$1], [],[
2464   sys_lib_search_path_spec="$sys_lib_search_path_spec /usr/local/lib"])
2465   sys_lib_dlsearch_path_spec='/usr/local/lib /lib /usr/lib'
2466   ;;
2467
2468 dgux*)
2469   version_type=linux # correct to gnu/linux during the next big refactor
2470   need_lib_prefix=no
2471   need_version=no
2472   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname$shared_ext'
2473   soname_spec='${libname}${release}${shared_ext}$major'
2474   shlibpath_var=LD_LIBRARY_PATH
2475   ;;
2476
2477 freebsd* | dragonfly*)
2478   # DragonFly does not have aout.  When/if they implement a new
2479   # versioning mechanism, adjust this.
2480   if test -x /usr/bin/objformat; then
2481     objformat=`/usr/bin/objformat`
2482   else
2483     case $host_os in
2484     freebsd[[23]].*) objformat=aout ;;
2485     *) objformat=elf ;;
2486     esac
2487   fi
2488   version_type=freebsd-$objformat
2489   case $version_type in
2490     freebsd-elf*)
2491       library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext} $libname${shared_ext}'
2492       need_version=no
2493       need_lib_prefix=no
2494       ;;
2495     freebsd-*)
2496       library_names_spec='${libname}${release}${shared_ext}$versuffix $libname${shared_ext}$versuffix'
2497       need_version=yes
2498       ;;
2499   esac
2500   shlibpath_var=LD_LIBRARY_PATH
2501   case $host_os in
2502   freebsd2.*)
2503     shlibpath_overrides_runpath=yes
2504     ;;
2505   freebsd3.[[01]]* | freebsdelf3.[[01]]*)
2506     shlibpath_overrides_runpath=yes
2507     hardcode_into_libs=yes
2508     ;;
2509   freebsd3.[[2-9]]* | freebsdelf3.[[2-9]]* | \
2510   freebsd4.[[0-5]] | freebsdelf4.[[0-5]] | freebsd4.1.1 | freebsdelf4.1.1)
2511     shlibpath_overrides_runpath=no
2512     hardcode_into_libs=yes
2513     ;;
2514   *) # from 4.6 on, and DragonFly
2515     shlibpath_overrides_runpath=yes
2516     hardcode_into_libs=yes
2517     ;;
2518   esac
2519   ;;
2520
2521 gnu*)
2522   version_type=linux # correct to gnu/linux during the next big refactor
2523   need_lib_prefix=no
2524   need_version=no
2525   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}${major} ${libname}${shared_ext}'
2526   soname_spec='${libname}${release}${shared_ext}$major'
2527   shlibpath_var=LD_LIBRARY_PATH
2528   shlibpath_overrides_runpath=no
2529   hardcode_into_libs=yes
2530   ;;
2531
2532 haiku*)
2533   version_type=linux # correct to gnu/linux during the next big refactor
2534   need_lib_prefix=no
2535   need_version=no
2536   dynamic_linker="$host_os runtime_loader"
2537   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}${major} ${libname}${shared_ext}'
2538   soname_spec='${libname}${release}${shared_ext}$major'
2539   shlibpath_var=LIBRARY_PATH
2540   shlibpath_overrides_runpath=yes
2541   sys_lib_dlsearch_path_spec='/boot/home/config/lib /boot/common/lib /boot/system/lib'
2542   hardcode_into_libs=yes
2543   ;;
2544
2545 hpux9* | hpux10* | hpux11*)
2546   # Give a soname corresponding to the major version so that dld.sl refuses to
2547   # link against other versions.
2548   version_type=sunos
2549   need_lib_prefix=no
2550   need_version=no
2551   case $host_cpu in
2552   ia64*)
2553     shrext_cmds='.so'
2554     hardcode_into_libs=yes
2555     dynamic_linker="$host_os dld.so"
2556     shlibpath_var=LD_LIBRARY_PATH
2557     shlibpath_overrides_runpath=yes # Unless +noenvvar is specified.
2558     library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
2559     soname_spec='${libname}${release}${shared_ext}$major'
2560     if test "X$HPUX_IA64_MODE" = X32; then
2561       sys_lib_search_path_spec="/usr/lib/hpux32 /usr/local/lib/hpux32 /usr/local/lib"
2562     else
2563       sys_lib_search_path_spec="/usr/lib/hpux64 /usr/local/lib/hpux64"
2564     fi
2565     sys_lib_dlsearch_path_spec=$sys_lib_search_path_spec
2566     ;;
2567   hppa*64*)
2568     shrext_cmds='.sl'
2569     hardcode_into_libs=yes
2570     dynamic_linker="$host_os dld.sl"
2571     shlibpath_var=LD_LIBRARY_PATH # How should we handle SHLIB_PATH
2572     shlibpath_overrides_runpath=yes # Unless +noenvvar is specified.
2573     library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
2574     soname_spec='${libname}${release}${shared_ext}$major'
2575     sys_lib_search_path_spec="/usr/lib/pa20_64 /usr/ccs/lib/pa20_64"
2576     sys_lib_dlsearch_path_spec=$sys_lib_search_path_spec
2577     ;;
2578   *)
2579     shrext_cmds='.sl'
2580     dynamic_linker="$host_os dld.sl"
2581     shlibpath_var=SHLIB_PATH
2582     shlibpath_overrides_runpath=no # +s is required to enable SHLIB_PATH
2583     library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
2584     soname_spec='${libname}${release}${shared_ext}$major'
2585     ;;
2586   esac
2587   # HP-UX runs *really* slowly unless shared libraries are mode 555, ...
2588   postinstall_cmds='chmod 555 $lib'
2589   # or fails outright, so override atomically:
2590   install_override_mode=555
2591   ;;
2592
2593 interix[[3-9]]*)
2594   version_type=linux # correct to gnu/linux during the next big refactor
2595   need_lib_prefix=no
2596   need_version=no
2597   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major ${libname}${shared_ext}'
2598   soname_spec='${libname}${release}${shared_ext}$major'
2599   dynamic_linker='Interix 3.x ld.so.1 (PE, like ELF)'
2600   shlibpath_var=LD_LIBRARY_PATH
2601   shlibpath_overrides_runpath=no
2602   hardcode_into_libs=yes
2603   ;;
2604
2605 irix5* | irix6* | nonstopux*)
2606   case $host_os in
2607     nonstopux*) version_type=nonstopux ;;
2608     *)
2609         if test "$lt_cv_prog_gnu_ld" = yes; then
2610                 version_type=linux # correct to gnu/linux during the next big refactor
2611         else
2612                 version_type=irix
2613         fi ;;
2614   esac
2615   need_lib_prefix=no
2616   need_version=no
2617   soname_spec='${libname}${release}${shared_ext}$major'
2618   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major ${libname}${release}${shared_ext} $libname${shared_ext}'
2619   case $host_os in
2620   irix5* | nonstopux*)
2621     libsuff= shlibsuff=
2622     ;;
2623   *)
2624     case $LD in # libtool.m4 will add one of these switches to LD
2625     *-32|*"-32 "|*-melf32bsmip|*"-melf32bsmip ")
2626       libsuff= shlibsuff= libmagic=32-bit;;
2627     *-n32|*"-n32 "|*-melf32bmipn32|*"-melf32bmipn32 ")
2628       libsuff=32 shlibsuff=N32 libmagic=N32;;
2629     *-64|*"-64 "|*-melf64bmip|*"-melf64bmip ")
2630       libsuff=64 shlibsuff=64 libmagic=64-bit;;
2631     *) libsuff= shlibsuff= libmagic=never-match;;
2632     esac
2633     ;;
2634   esac
2635   shlibpath_var=LD_LIBRARY${shlibsuff}_PATH
2636   shlibpath_overrides_runpath=no
2637   sys_lib_search_path_spec="/usr/lib${libsuff} /lib${libsuff} /usr/local/lib${libsuff}"
2638   sys_lib_dlsearch_path_spec="/usr/lib${libsuff} /lib${libsuff}"
2639   hardcode_into_libs=yes
2640   ;;
2641
2642 # No shared lib support for Linux oldld, aout, or coff.
2643 linux*oldld* | linux*aout* | linux*coff*)
2644   dynamic_linker=no
2645   ;;
2646
2647 linux*android*)
2648   version_type=none # Android doesn't support versioned libraries.
2649   need_lib_prefix=no
2650   need_version=no
2651   library_names_spec='$libname$release$shared_ext'
2652   soname_spec='$libname$release$shared_ext'
2653   finish_cmds=
2654   shlibpath_var=LD_LIBRARY_PATH
2655   shlibpath_overrides_runpath=yes
2656
2657   # This implies no fast_install, which is unacceptable.
2658   # Some rework will be needed to allow for fast_install
2659   # before this can be enabled.
2660   hardcode_into_libs=yes
2661
2662   dynamic_linker='Android linker'
2663   # Don't embed -rpath directories since the linker doesn't support them.
2664   _LT_TAGVAR(hardcode_libdir_flag_spec, $1)='-L$libdir'
2665   ;;
2666
2667 # This must be glibc/ELF.
2668 linux* | k*bsd*-gnu | kopensolaris*-gnu)
2669   version_type=linux # correct to gnu/linux during the next big refactor
2670   need_lib_prefix=no
2671   need_version=no
2672   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
2673   soname_spec='${libname}${release}${shared_ext}$major'
2674   finish_cmds='PATH="\$PATH:/sbin" ldconfig -n $libdir'
2675   shlibpath_var=LD_LIBRARY_PATH
2676   shlibpath_overrides_runpath=no
2677
2678   # Some binutils ld are patched to set DT_RUNPATH
2679   AC_CACHE_VAL([lt_cv_shlibpath_overrides_runpath],
2680     [lt_cv_shlibpath_overrides_runpath=no
2681     save_LDFLAGS=$LDFLAGS
2682     save_libdir=$libdir
2683     eval "libdir=/foo; wl=\"$_LT_TAGVAR(lt_prog_compiler_wl, $1)\"; \
2684          LDFLAGS=\"\$LDFLAGS $_LT_TAGVAR(hardcode_libdir_flag_spec, $1)\""
2685     AC_LINK_IFELSE([AC_LANG_PROGRAM([],[])],
2686       [AS_IF([ ($OBJDUMP -p conftest$ac_exeext) 2>/dev/null | grep "RUNPATH.*$libdir" >/dev/null],
2687          [lt_cv_shlibpath_overrides_runpath=yes])])
2688     LDFLAGS=$save_LDFLAGS
2689     libdir=$save_libdir
2690     ])
2691   shlibpath_overrides_runpath=$lt_cv_shlibpath_overrides_runpath
2692
2693   # This implies no fast_install, which is unacceptable.
2694   # Some rework will be needed to allow for fast_install
2695   # before this can be enabled.
2696   hardcode_into_libs=yes
2697
2698   # Append ld.so.conf contents to the search path
2699   if test -f /etc/ld.so.conf; then
2700     lt_ld_extra=`awk '/^include / { system(sprintf("cd /etc; cat %s 2>/dev/null", \[$]2)); skip = 1; } { if (!skip) print \[$]0; skip = 0; }' < /etc/ld.so.conf | $SED -e 's/#.*//;/^[   ]*hwcap[        ]/d;s/[:,      ]/ /g;s/=[^=]*$//;s/=[^= ]* / /g;s/"//g;/^$/d' | tr '\n' ' '`
2701     sys_lib_dlsearch_path_spec="/lib /usr/lib $lt_ld_extra"
2702   fi
2703
2704   # We used to test for /lib/ld.so.1 and disable shared libraries on
2705   # powerpc, because MkLinux only supported shared libraries with the
2706   # GNU dynamic linker.  Since this was broken with cross compilers,
2707   # most powerpc-linux boxes support dynamic linking these days and
2708   # people can always --disable-shared, the test was removed, and we
2709   # assume the GNU/Linux dynamic linker is in use.
2710   dynamic_linker='GNU/Linux ld.so'
2711   ;;
2712
2713 netbsdelf*-gnu)
2714   version_type=linux
2715   need_lib_prefix=no
2716   need_version=no
2717   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major ${libname}${shared_ext}'
2718   soname_spec='${libname}${release}${shared_ext}$major'
2719   shlibpath_var=LD_LIBRARY_PATH
2720   shlibpath_overrides_runpath=no
2721   hardcode_into_libs=yes
2722   dynamic_linker='NetBSD ld.elf_so'
2723   ;;
2724
2725 netbsd*)
2726   version_type=sunos
2727   need_lib_prefix=no
2728   need_version=no
2729   if echo __ELF__ | $CC -E - | $GREP __ELF__ >/dev/null; then
2730     library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${shared_ext}$versuffix'
2731     finish_cmds='PATH="\$PATH:/sbin" ldconfig -m $libdir'
2732     dynamic_linker='NetBSD (a.out) ld.so'
2733   else
2734     library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major ${libname}${shared_ext}'
2735     soname_spec='${libname}${release}${shared_ext}$major'
2736     dynamic_linker='NetBSD ld.elf_so'
2737   fi
2738   shlibpath_var=LD_LIBRARY_PATH
2739   shlibpath_overrides_runpath=yes
2740   hardcode_into_libs=yes
2741   ;;
2742
2743 newsos6)
2744   version_type=linux # correct to gnu/linux during the next big refactor
2745   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
2746   shlibpath_var=LD_LIBRARY_PATH
2747   shlibpath_overrides_runpath=yes
2748   ;;
2749
2750 *nto* | *qnx*)
2751   version_type=qnx
2752   need_lib_prefix=no
2753   need_version=no
2754   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
2755   soname_spec='${libname}${release}${shared_ext}$major'
2756   shlibpath_var=LD_LIBRARY_PATH
2757   shlibpath_overrides_runpath=no
2758   hardcode_into_libs=yes
2759   dynamic_linker='ldqnx.so'
2760   ;;
2761
2762 openbsd*)
2763   version_type=sunos
2764   sys_lib_dlsearch_path_spec="/usr/lib"
2765   need_lib_prefix=no
2766   # Some older versions of OpenBSD (3.3 at least) *do* need versioned libs.
2767   case $host_os in
2768     openbsd3.3 | openbsd3.3.*)  need_version=yes ;;
2769     *)                          need_version=no  ;;
2770   esac
2771   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${shared_ext}$versuffix'
2772   finish_cmds='PATH="\$PATH:/sbin" ldconfig -m $libdir'
2773   shlibpath_var=LD_LIBRARY_PATH
2774   if test -z "`echo __ELF__ | $CC -E - | $GREP __ELF__`" || test "$host_os-$host_cpu" = "openbsd2.8-powerpc"; then
2775     case $host_os in
2776       openbsd2.[[89]] | openbsd2.[[89]].*)
2777         shlibpath_overrides_runpath=no
2778         ;;
2779       *)
2780         shlibpath_overrides_runpath=yes
2781         ;;
2782       esac
2783   else
2784     shlibpath_overrides_runpath=yes
2785   fi
2786   ;;
2787
2788 os2*)
2789   libname_spec='$name'
2790   shrext_cmds=".dll"
2791   need_lib_prefix=no
2792   library_names_spec='$libname${shared_ext} $libname.a'
2793   dynamic_linker='OS/2 ld.exe'
2794   shlibpath_var=LIBPATH
2795   ;;
2796
2797 osf3* | osf4* | osf5*)
2798   version_type=osf
2799   need_lib_prefix=no
2800   need_version=no
2801   soname_spec='${libname}${release}${shared_ext}$major'
2802   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
2803   shlibpath_var=LD_LIBRARY_PATH
2804   sys_lib_search_path_spec="/usr/shlib /usr/ccs/lib /usr/lib/cmplrs/cc /usr/lib /usr/local/lib /var/shlib"
2805   sys_lib_dlsearch_path_spec="$sys_lib_search_path_spec"
2806   ;;
2807
2808 rdos*)
2809   dynamic_linker=no
2810   ;;
2811
2812 solaris*)
2813   version_type=linux # correct to gnu/linux during the next big refactor
2814   need_lib_prefix=no
2815   need_version=no
2816   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
2817   soname_spec='${libname}${release}${shared_ext}$major'
2818   shlibpath_var=LD_LIBRARY_PATH
2819   shlibpath_overrides_runpath=yes
2820   hardcode_into_libs=yes
2821   # ldd complains unless libraries are executable
2822   postinstall_cmds='chmod +x $lib'
2823   ;;
2824
2825 sunos4*)
2826   version_type=sunos
2827   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${shared_ext}$versuffix'
2828   finish_cmds='PATH="\$PATH:/usr/etc" ldconfig $libdir'
2829   shlibpath_var=LD_LIBRARY_PATH
2830   shlibpath_overrides_runpath=yes
2831   if test "$with_gnu_ld" = yes; then
2832     need_lib_prefix=no
2833   fi
2834   need_version=yes
2835   ;;
2836
2837 sysv4 | sysv4.3*)
2838   version_type=linux # correct to gnu/linux during the next big refactor
2839   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
2840   soname_spec='${libname}${release}${shared_ext}$major'
2841   shlibpath_var=LD_LIBRARY_PATH
2842   case $host_vendor in
2843     sni)
2844       shlibpath_overrides_runpath=no
2845       need_lib_prefix=no
2846       runpath_var=LD_RUN_PATH
2847       ;;
2848     siemens)
2849       need_lib_prefix=no
2850       ;;
2851     motorola)
2852       need_lib_prefix=no
2853       need_version=no
2854       shlibpath_overrides_runpath=no
2855       sys_lib_search_path_spec='/lib /usr/lib /usr/ccs/lib'
2856       ;;
2857   esac
2858   ;;
2859
2860 sysv4*MP*)
2861   if test -d /usr/nec ;then
2862     version_type=linux # correct to gnu/linux during the next big refactor
2863     library_names_spec='$libname${shared_ext}.$versuffix $libname${shared_ext}.$major $libname${shared_ext}'
2864     soname_spec='$libname${shared_ext}.$major'
2865     shlibpath_var=LD_LIBRARY_PATH
2866   fi
2867   ;;
2868
2869 sysv5* | sco3.2v5* | sco5v6* | unixware* | OpenUNIX* | sysv4*uw2*)
2870   version_type=freebsd-elf
2871   need_lib_prefix=no
2872   need_version=no
2873   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext} $libname${shared_ext}'
2874   soname_spec='${libname}${release}${shared_ext}$major'
2875   shlibpath_var=LD_LIBRARY_PATH
2876   shlibpath_overrides_runpath=yes
2877   hardcode_into_libs=yes
2878   if test "$with_gnu_ld" = yes; then
2879     sys_lib_search_path_spec='/usr/local/lib /usr/gnu/lib /usr/ccs/lib /usr/lib /lib'
2880   else
2881     sys_lib_search_path_spec='/usr/ccs/lib /usr/lib'
2882     case $host_os in
2883       sco3.2v5*)
2884         sys_lib_search_path_spec="$sys_lib_search_path_spec /lib"
2885         ;;
2886     esac
2887   fi
2888   sys_lib_dlsearch_path_spec='/usr/lib'
2889   ;;
2890
2891 tpf*)
2892   # TPF is a cross-target only.  Preferred cross-host = GNU/Linux.
2893   version_type=linux # correct to gnu/linux during the next big refactor
2894   need_lib_prefix=no
2895   need_version=no
2896   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
2897   shlibpath_var=LD_LIBRARY_PATH
2898   shlibpath_overrides_runpath=no
2899   hardcode_into_libs=yes
2900   ;;
2901
2902 uts4*)
2903   version_type=linux # correct to gnu/linux during the next big refactor
2904   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
2905   soname_spec='${libname}${release}${shared_ext}$major'
2906   shlibpath_var=LD_LIBRARY_PATH
2907   ;;
2908
2909 *)
2910   dynamic_linker=no
2911   ;;
2912 esac
2913 AC_MSG_RESULT([$dynamic_linker])
2914 test "$dynamic_linker" = no && can_build_shared=no
2915
2916 variables_saved_for_relink="PATH $shlibpath_var $runpath_var"
2917 if test "$GCC" = yes; then
2918   variables_saved_for_relink="$variables_saved_for_relink GCC_EXEC_PREFIX COMPILER_PATH LIBRARY_PATH"
2919 fi
2920
2921 if test "${lt_cv_sys_lib_search_path_spec+set}" = set; then
2922   sys_lib_search_path_spec="$lt_cv_sys_lib_search_path_spec"
2923 fi
2924 if test "${lt_cv_sys_lib_dlsearch_path_spec+set}" = set; then
2925   sys_lib_dlsearch_path_spec="$lt_cv_sys_lib_dlsearch_path_spec"
2926 fi
2927
2928 _LT_DECL([], [variables_saved_for_relink], [1],
2929     [Variables whose values should be saved in libtool wrapper scripts and
2930     restored at link time])
2931 _LT_DECL([], [need_lib_prefix], [0],
2932     [Do we need the "lib" prefix for modules?])
2933 _LT_DECL([], [need_version], [0], [Do we need a version for libraries?])
2934 _LT_DECL([], [version_type], [0], [Library versioning type])
2935 _LT_DECL([], [runpath_var], [0],  [Shared library runtime path variable])
2936 _LT_DECL([], [shlibpath_var], [0],[Shared library path variable])
2937 _LT_DECL([], [shlibpath_overrides_runpath], [0],
2938     [Is shlibpath searched before the hard-coded library search path?])
2939 _LT_DECL([], [libname_spec], [1], [Format of library name prefix])
2940 _LT_DECL([], [library_names_spec], [1],
2941     [[List of archive names.  First name is the real one, the rest are links.
2942     The last name is the one that the linker finds with -lNAME]])
2943 _LT_DECL([], [soname_spec], [1],
2944     [[The coded name of the library, if different from the real name]])
2945 _LT_DECL([], [install_override_mode], [1],
2946     [Permission mode override for installation of shared libraries])
2947 _LT_DECL([], [postinstall_cmds], [2],
2948     [Command to use after installation of a shared archive])
2949 _LT_DECL([], [postuninstall_cmds], [2],
2950     [Command to use after uninstallation of a shared archive])
2951 _LT_DECL([], [finish_cmds], [2],
2952     [Commands used to finish a libtool library installation in a directory])
2953 _LT_DECL([], [finish_eval], [1],
2954     [[As "finish_cmds", except a single script fragment to be evaled but
2955     not shown]])
2956 _LT_DECL([], [hardcode_into_libs], [0],
2957     [Whether we should hardcode library paths into libraries])
2958 _LT_DECL([], [sys_lib_search_path_spec], [2],
2959     [Compile-time system search path for libraries])
2960 _LT_DECL([], [sys_lib_dlsearch_path_spec], [2],
2961     [Run-time system search path for libraries])
2962 ])# _LT_SYS_DYNAMIC_LINKER
2963
2964
2965 # _LT_PATH_TOOL_PREFIX(TOOL)
2966 # --------------------------
2967 # find a file program which can recognize shared library
2968 AC_DEFUN([_LT_PATH_TOOL_PREFIX],
2969 [m4_require([_LT_DECL_EGREP])dnl
2970 AC_MSG_CHECKING([for $1])
2971 AC_CACHE_VAL(lt_cv_path_MAGIC_CMD,
2972 [case $MAGIC_CMD in
2973 [[\\/*] |  ?:[\\/]*])
2974   lt_cv_path_MAGIC_CMD="$MAGIC_CMD" # Let the user override the test with a path.
2975   ;;
2976 *)
2977   lt_save_MAGIC_CMD="$MAGIC_CMD"
2978   lt_save_ifs="$IFS"; IFS=$PATH_SEPARATOR
2979 dnl $ac_dummy forces splitting on constant user-supplied paths.
2980 dnl POSIX.2 word splitting is done only on the output of word expansions,
2981 dnl not every word.  This closes a longstanding sh security hole.
2982   ac_dummy="m4_if([$2], , $PATH, [$2])"
2983   for ac_dir in $ac_dummy; do
2984     IFS="$lt_save_ifs"
2985     test -z "$ac_dir" && ac_dir=.
2986     if test -f $ac_dir/$1; then
2987       lt_cv_path_MAGIC_CMD="$ac_dir/$1"
2988       if test -n "$file_magic_test_file"; then
2989         case $deplibs_check_method in
2990         "file_magic "*)
2991           file_magic_regex=`expr "$deplibs_check_method" : "file_magic \(.*\)"`
2992           MAGIC_CMD="$lt_cv_path_MAGIC_CMD"
2993           if eval $file_magic_cmd \$file_magic_test_file 2> /dev/null |
2994             $EGREP "$file_magic_regex" > /dev/null; then
2995             :
2996           else
2997             cat <<_LT_EOF 1>&2
2998
2999 *** Warning: the command libtool uses to detect shared libraries,
3000 *** $file_magic_cmd, produces output that libtool cannot recognize.
3001 *** The result is that libtool may fail to recognize shared libraries
3002 *** as such.  This will affect the creation of libtool libraries that
3003 *** depend on shared libraries, but programs linked with such libtool
3004 *** libraries will work regardless of this problem.  Nevertheless, you
3005 *** may want to report the problem to your system manager and/or to
3006 *** bug-libtool@gnu.org
3007
3008 _LT_EOF
3009           fi ;;
3010         esac
3011       fi
3012       break
3013     fi
3014   done
3015   IFS="$lt_save_ifs"
3016   MAGIC_CMD="$lt_save_MAGIC_CMD"
3017   ;;
3018 esac])
3019 MAGIC_CMD="$lt_cv_path_MAGIC_CMD"
3020 if test -n "$MAGIC_CMD"; then
3021   AC_MSG_RESULT($MAGIC_CMD)
3022 else
3023   AC_MSG_RESULT(no)
3024 fi
3025 _LT_DECL([], [MAGIC_CMD], [0],
3026          [Used to examine libraries when file_magic_cmd begins with "file"])dnl
3027 ])# _LT_PATH_TOOL_PREFIX
3028
3029 # Old name:
3030 AU_ALIAS([AC_PATH_TOOL_PREFIX], [_LT_PATH_TOOL_PREFIX])
3031 dnl aclocal-1.4 backwards compatibility:
3032 dnl AC_DEFUN([AC_PATH_TOOL_PREFIX], [])
3033
3034
3035 # _LT_PATH_MAGIC
3036 # --------------
3037 # find a file program which can recognize a shared library
3038 m4_defun([_LT_PATH_MAGIC],
3039 [_LT_PATH_TOOL_PREFIX(${ac_tool_prefix}file, /usr/bin$PATH_SEPARATOR$PATH)
3040 if test -z "$lt_cv_path_MAGIC_CMD"; then
3041   if test -n "$ac_tool_prefix"; then
3042     _LT_PATH_TOOL_PREFIX(file, /usr/bin$PATH_SEPARATOR$PATH)
3043   else
3044     MAGIC_CMD=:
3045   fi
3046 fi
3047 ])# _LT_PATH_MAGIC
3048
3049
3050 # LT_PATH_LD
3051 # ----------
3052 # find the pathname to the GNU or non-GNU linker
3053 AC_DEFUN([LT_PATH_LD],
3054 [AC_REQUIRE([AC_PROG_CC])dnl
3055 AC_REQUIRE([AC_CANONICAL_HOST])dnl
3056 AC_REQUIRE([AC_CANONICAL_BUILD])dnl
3057 m4_require([_LT_DECL_SED])dnl
3058 m4_require([_LT_DECL_EGREP])dnl
3059 m4_require([_LT_PROG_ECHO_BACKSLASH])dnl
3060
3061 AC_ARG_WITH([gnu-ld],
3062     [AS_HELP_STRING([--with-gnu-ld],
3063         [assume the C compiler uses GNU ld @<:@default=no@:>@])],
3064     [test "$withval" = no || with_gnu_ld=yes],
3065     [with_gnu_ld=no])dnl
3066
3067 ac_prog=ld
3068 if test "$GCC" = yes; then
3069   # Check if gcc -print-prog-name=ld gives a path.
3070   AC_MSG_CHECKING([for ld used by $CC])
3071   case $host in
3072   *-*-mingw*)
3073     # gcc leaves a trailing carriage return which upsets mingw
3074     ac_prog=`($CC -print-prog-name=ld) 2>&5 | tr -d '\015'` ;;
3075   *)
3076     ac_prog=`($CC -print-prog-name=ld) 2>&5` ;;
3077   esac
3078   case $ac_prog in
3079     # Accept absolute paths.
3080     [[\\/]]* | ?:[[\\/]]*)
3081       re_direlt='/[[^/]][[^/]]*/\.\./'
3082       # Canonicalize the pathname of ld
3083       ac_prog=`$ECHO "$ac_prog"| $SED 's%\\\\%/%g'`
3084       while $ECHO "$ac_prog" | $GREP "$re_direlt" > /dev/null 2>&1; do
3085         ac_prog=`$ECHO $ac_prog| $SED "s%$re_direlt%/%"`
3086       done
3087       test -z "$LD" && LD="$ac_prog"
3088       ;;
3089   "")
3090     # If it fails, then pretend we aren't using GCC.
3091     ac_prog=ld
3092     ;;
3093   *)
3094     # If it is relative, then search for the first ld in PATH.
3095     with_gnu_ld=unknown
3096     ;;
3097   esac
3098 elif test "$with_gnu_ld" = yes; then
3099   AC_MSG_CHECKING([for GNU ld])
3100 else
3101   AC_MSG_CHECKING([for non-GNU ld])
3102 fi
3103 AC_CACHE_VAL(lt_cv_path_LD,
3104 [if test -z "$LD"; then
3105   lt_save_ifs="$IFS"; IFS=$PATH_SEPARATOR
3106   for ac_dir in $PATH; do
3107     IFS="$lt_save_ifs"
3108     test -z "$ac_dir" && ac_dir=.
3109     if test -f "$ac_dir/$ac_prog" || test -f "$ac_dir/$ac_prog$ac_exeext"; then
3110       lt_cv_path_LD="$ac_dir/$ac_prog"
3111       # Check to see if the program is GNU ld.  I'd rather use --version,
3112       # but apparently some variants of GNU ld only accept -v.
3113       # Break only if it was the GNU/non-GNU ld that we prefer.
3114       case `"$lt_cv_path_LD" -v 2>&1 </dev/null` in
3115       *GNU* | *'with BFD'*)
3116         test "$with_gnu_ld" != no && break
3117         ;;
3118       *)
3119         test "$with_gnu_ld" != yes && break
3120         ;;
3121       esac
3122     fi
3123   done
3124   IFS="$lt_save_ifs"
3125 else
3126   lt_cv_path_LD="$LD" # Let the user override the test with a path.
3127 fi])
3128 LD="$lt_cv_path_LD"
3129 if test -n "$LD"; then
3130   AC_MSG_RESULT($LD)
3131 else
3132   AC_MSG_RESULT(no)
3133 fi
3134 test -z "$LD" && AC_MSG_ERROR([no acceptable ld found in \$PATH])
3135 _LT_PATH_LD_GNU
3136 AC_SUBST([LD])
3137
3138 _LT_TAGDECL([], [LD], [1], [The linker used to build libraries])
3139 ])# LT_PATH_LD
3140
3141 # Old names:
3142 AU_ALIAS([AM_PROG_LD], [LT_PATH_LD])
3143 AU_ALIAS([AC_PROG_LD], [LT_PATH_LD])
3144 dnl aclocal-1.4 backwards compatibility:
3145 dnl AC_DEFUN([AM_PROG_LD], [])
3146 dnl AC_DEFUN([AC_PROG_LD], [])
3147
3148
3149 # _LT_PATH_LD_GNU
3150 #- --------------
3151 m4_defun([_LT_PATH_LD_GNU],
3152 [AC_CACHE_CHECK([if the linker ($LD) is GNU ld], lt_cv_prog_gnu_ld,
3153 [# I'd rather use --version here, but apparently some GNU lds only accept -v.
3154 case `$LD -v 2>&1 </dev/null` in
3155 *GNU* | *'with BFD'*)
3156   lt_cv_prog_gnu_ld=yes
3157   ;;
3158 *)
3159   lt_cv_prog_gnu_ld=no
3160   ;;
3161 esac])
3162 with_gnu_ld=$lt_cv_prog_gnu_ld
3163 ])# _LT_PATH_LD_GNU
3164
3165
3166 # _LT_CMD_RELOAD
3167 # --------------
3168 # find reload flag for linker
3169 #   -- PORTME Some linkers may need a different reload flag.
3170 m4_defun([_LT_CMD_RELOAD],
3171 [AC_CACHE_CHECK([for $LD option to reload object files],
3172   lt_cv_ld_reload_flag,
3173   [lt_cv_ld_reload_flag='-r'])
3174 reload_flag=$lt_cv_ld_reload_flag
3175 case $reload_flag in
3176 "" | " "*) ;;
3177 *) reload_flag=" $reload_flag" ;;
3178 esac
3179 reload_cmds='$LD$reload_flag -o $output$reload_objs'
3180 case $host_os in
3181   cygwin* | mingw* | pw32* | cegcc*)
3182     if test "$GCC" != yes; then
3183       reload_cmds=false
3184     fi
3185     ;;
3186   darwin*)
3187     if test "$GCC" = yes; then
3188       reload_cmds='$LTCC $LTCFLAGS -nostdlib ${wl}-r -o $output$reload_objs'
3189     else
3190       reload_cmds='$LD$reload_flag -o $output$reload_objs'
3191     fi
3192     ;;
3193 esac
3194 _LT_TAGDECL([], [reload_flag], [1], [How to create reloadable object files])dnl
3195 _LT_TAGDECL([], [reload_cmds], [2])dnl
3196 ])# _LT_CMD_RELOAD
3197
3198
3199 # _LT_CHECK_MAGIC_METHOD
3200 # ----------------------
3201 # how to check for library dependencies
3202 #  -- PORTME fill in with the dynamic library characteristics
3203 m4_defun([_LT_CHECK_MAGIC_METHOD],
3204 [m4_require([_LT_DECL_EGREP])
3205 m4_require([_LT_DECL_OBJDUMP])
3206 AC_CACHE_CHECK([how to recognize dependent libraries],
3207 lt_cv_deplibs_check_method,
3208 [lt_cv_file_magic_cmd='$MAGIC_CMD'
3209 lt_cv_file_magic_test_file=
3210 lt_cv_deplibs_check_method='unknown'
3211 # Need to set the preceding variable on all platforms that support
3212 # interlibrary dependencies.
3213 # 'none' -- dependencies not supported.
3214 # `unknown' -- same as none, but documents that we really don't know.
3215 # 'pass_all' -- all dependencies passed with no checks.
3216 # 'test_compile' -- check by making test program.
3217 # 'file_magic [[regex]]' -- check by looking for files in library path
3218 # which responds to the $file_magic_cmd with a given extended regex.
3219 # If you have `file' or equivalent on your system and you're not sure
3220 # whether `pass_all' will *always* work, you probably want this one.
3221
3222 case $host_os in
3223 aix[[4-9]]*)
3224   lt_cv_deplibs_check_method=pass_all
3225   ;;
3226
3227 beos*)
3228   lt_cv_deplibs_check_method=pass_all
3229   ;;
3230
3231 bsdi[[45]]*)
3232   lt_cv_deplibs_check_method='file_magic ELF [[0-9]][[0-9]]*-bit [[ML]]SB (shared object|dynamic lib)'
3233   lt_cv_file_magic_cmd='/usr/bin/file -L'
3234   lt_cv_file_magic_test_file=/shlib/libc.so
3235   ;;
3236
3237 cygwin*)
3238   # func_win32_libid is a shell function defined in ltmain.sh
3239   lt_cv_deplibs_check_method='file_magic ^x86 archive import|^x86 DLL'
3240   lt_cv_file_magic_cmd='func_win32_libid'
3241   ;;
3242
3243 mingw* | pw32*)
3244   # Base MSYS/MinGW do not provide the 'file' command needed by
3245   # func_win32_libid shell function, so use a weaker test based on 'objdump',
3246   # unless we find 'file', for example because we are cross-compiling.
3247   # func_win32_libid assumes BSD nm, so disallow it if using MS dumpbin.
3248   if ( test "$lt_cv_nm_interface" = "BSD nm" && file / ) >/dev/null 2>&1; then
3249     lt_cv_deplibs_check_method='file_magic ^x86 archive import|^x86 DLL'
3250     lt_cv_file_magic_cmd='func_win32_libid'
3251   else
3252     # Keep this pattern in sync with the one in func_win32_libid.
3253     lt_cv_deplibs_check_method='file_magic file format (pei*-i386(.*architecture: i386)?|pe-arm-wince|pe-x86-64)'
3254     lt_cv_file_magic_cmd='$OBJDUMP -f'
3255   fi
3256   ;;
3257
3258 cegcc*)
3259   # use the weaker test based on 'objdump'. See mingw*.
3260   lt_cv_deplibs_check_method='file_magic file format pe-arm-.*little(.*architecture: arm)?'
3261   lt_cv_file_magic_cmd='$OBJDUMP -f'
3262   ;;
3263
3264 darwin* | rhapsody*)
3265   lt_cv_deplibs_check_method=pass_all
3266   ;;
3267
3268 freebsd* | dragonfly*)
3269   if echo __ELF__ | $CC -E - | $GREP __ELF__ > /dev/null; then
3270     case $host_cpu in
3271     i*86 )
3272       # Not sure whether the presence of OpenBSD here was a mistake.
3273       # Let's accept both of them until this is cleared up.
3274       lt_cv_deplibs_check_method='file_magic (FreeBSD|OpenBSD|DragonFly)/i[[3-9]]86 (compact )?demand paged shared library'
3275       lt_cv_file_magic_cmd=/usr/bin/file
3276       lt_cv_file_magic_test_file=`echo /usr/lib/libc.so.*`
3277       ;;
3278     esac
3279   else
3280     lt_cv_deplibs_check_method=pass_all
3281   fi
3282   ;;
3283
3284 gnu*)
3285   lt_cv_deplibs_check_method=pass_all
3286   ;;
3287
3288 haiku*)
3289   lt_cv_deplibs_check_method=pass_all
3290   ;;
3291
3292 hpux10.20* | hpux11*)
3293   lt_cv_file_magic_cmd=/usr/bin/file
3294   case $host_cpu in
3295   ia64*)
3296     lt_cv_deplibs_check_method='file_magic (s[[0-9]][[0-9]][[0-9]]|ELF-[[0-9]][[0-9]]) shared object file - IA64'
3297     lt_cv_file_magic_test_file=/usr/lib/hpux32/libc.so
3298     ;;
3299   hppa*64*)
3300     [lt_cv_deplibs_check_method='file_magic (s[0-9][0-9][0-9]|ELF[ -][0-9][0-9])(-bit)?( [LM]SB)? shared object( file)?[, -]* PA-RISC [0-9]\.[0-9]']
3301     lt_cv_file_magic_test_file=/usr/lib/pa20_64/libc.sl
3302     ;;
3303   *)
3304     lt_cv_deplibs_check_method='file_magic (s[[0-9]][[0-9]][[0-9]]|PA-RISC[[0-9]]\.[[0-9]]) shared library'
3305     lt_cv_file_magic_test_file=/usr/lib/libc.sl
3306     ;;
3307   esac
3308   ;;
3309
3310 interix[[3-9]]*)
3311   # PIC code is broken on Interix 3.x, that's why |\.a not |_pic\.a here
3312   lt_cv_deplibs_check_method='match_pattern /lib[[^/]]+(\.so|\.a)$'
3313   ;;
3314
3315 irix5* | irix6* | nonstopux*)
3316   case $LD in
3317   *-32|*"-32 ") libmagic=32-bit;;
3318   *-n32|*"-n32 ") libmagic=N32;;
3319   *-64|*"-64 ") libmagic=64-bit;;
3320   *) libmagic=never-match;;
3321   esac
3322   lt_cv_deplibs_check_method=pass_all
3323   ;;
3324
3325 # This must be glibc/ELF.
3326 linux* | k*bsd*-gnu | kopensolaris*-gnu)
3327   lt_cv_deplibs_check_method=pass_all
3328   ;;
3329
3330 netbsd* | netbsdelf*-gnu)
3331   if echo __ELF__ | $CC -E - | $GREP __ELF__ > /dev/null; then
3332     lt_cv_deplibs_check_method='match_pattern /lib[[^/]]+(\.so\.[[0-9]]+\.[[0-9]]+|_pic\.a)$'
3333   else
3334     lt_cv_deplibs_check_method='match_pattern /lib[[^/]]+(\.so|_pic\.a)$'
3335   fi
3336   ;;
3337
3338 newos6*)
3339   lt_cv_deplibs_check_method='file_magic ELF [[0-9]][[0-9]]*-bit [[ML]]SB (executable|dynamic lib)'
3340   lt_cv_file_magic_cmd=/usr/bin/file
3341   lt_cv_file_magic_test_file=/usr/lib/libnls.so
3342   ;;
3343
3344 *nto* | *qnx*)
3345   lt_cv_deplibs_check_method=pass_all
3346   ;;
3347
3348 openbsd*)
3349   if test -z "`echo __ELF__ | $CC -E - | $GREP __ELF__`" || test "$host_os-$host_cpu" = "openbsd2.8-powerpc"; then
3350     lt_cv_deplibs_check_method='match_pattern /lib[[^/]]+(\.so\.[[0-9]]+\.[[0-9]]+|\.so|_pic\.a)$'
3351   else
3352     lt_cv_deplibs_check_method='match_pattern /lib[[^/]]+(\.so\.[[0-9]]+\.[[0-9]]+|_pic\.a)$'
3353   fi
3354   ;;
3355
3356 osf3* | osf4* | osf5*)
3357   lt_cv_deplibs_check_method=pass_all
3358   ;;
3359
3360 rdos*)
3361   lt_cv_deplibs_check_method=pass_all
3362   ;;
3363
3364 solaris*)
3365   lt_cv_deplibs_check_method=pass_all
3366   ;;
3367
3368 sysv5* | sco3.2v5* | sco5v6* | unixware* | OpenUNIX* | sysv4*uw2*)
3369   lt_cv_deplibs_check_method=pass_all
3370   ;;
3371
3372 sysv4 | sysv4.3*)
3373   case $host_vendor in
3374   motorola)
3375     lt_cv_deplibs_check_method='file_magic ELF [[0-9]][[0-9]]*-bit [[ML]]SB (shared object|dynamic lib) M[[0-9]][[0-9]]* Version [[0-9]]'
3376     lt_cv_file_magic_test_file=`echo /usr/lib/libc.so*`
3377     ;;
3378   ncr)
3379     lt_cv_deplibs_check_method=pass_all
3380     ;;
3381   sequent)
3382     lt_cv_file_magic_cmd='/bin/file'
3383     lt_cv_deplibs_check_method='file_magic ELF [[0-9]][[0-9]]*-bit [[LM]]SB (shared object|dynamic lib )'
3384     ;;
3385   sni)
3386     lt_cv_file_magic_cmd='/bin/file'
3387     lt_cv_deplibs_check_method="file_magic ELF [[0-9]][[0-9]]*-bit [[LM]]SB dynamic lib"
3388     lt_cv_file_magic_test_file=/lib/libc.so
3389     ;;
3390   siemens)
3391     lt_cv_deplibs_check_method=pass_all
3392     ;;
3393   pc)
3394     lt_cv_deplibs_check_method=pass_all
3395     ;;
3396   esac
3397   ;;
3398
3399 tpf*)
3400   lt_cv_deplibs_check_method=pass_all
3401   ;;
3402 esac
3403 ])
3404
3405 file_magic_glob=
3406 want_nocaseglob=no
3407 if test "$build" = "$host"; then
3408   case $host_os in
3409   mingw* | pw32*)
3410     if ( shopt | grep nocaseglob ) >/dev/null 2>&1; then
3411       want_nocaseglob=yes
3412     else
3413       file_magic_glob=`echo aAbBcCdDeEfFgGhHiIjJkKlLmMnNoOpPqQrRsStTuUvVwWxXyYzZ | $SED -e "s/\(..\)/s\/[[\1]]\/[[\1]]\/g;/g"`
3414     fi
3415     ;;
3416   esac
3417 fi
3418
3419 file_magic_cmd=$lt_cv_file_magic_cmd
3420 deplibs_check_method=$lt_cv_deplibs_check_method
3421 test -z "$deplibs_check_method" && deplibs_check_method=unknown
3422
3423 _LT_DECL([], [deplibs_check_method], [1],
3424     [Method to check whether dependent libraries are shared objects])
3425 _LT_DECL([], [file_magic_cmd], [1],
3426     [Command to use when deplibs_check_method = "file_magic"])
3427 _LT_DECL([], [file_magic_glob], [1],
3428     [How to find potential files when deplibs_check_method = "file_magic"])
3429 _LT_DECL([], [want_nocaseglob], [1],
3430     [Find potential files using nocaseglob when deplibs_check_method = "file_magic"])
3431 ])# _LT_CHECK_MAGIC_METHOD
3432
3433
3434 # LT_PATH_NM
3435 # ----------
3436 # find the pathname to a BSD- or MS-compatible name lister
3437 AC_DEFUN([LT_PATH_NM],
3438 [AC_REQUIRE([AC_PROG_CC])dnl
3439 AC_CACHE_CHECK([for BSD- or MS-compatible name lister (nm)], lt_cv_path_NM,
3440 [if test -n "$NM"; then
3441   # Let the user override the test.
3442   lt_cv_path_NM="$NM"
3443 else
3444   lt_nm_to_check="${ac_tool_prefix}nm"
3445   if test -n "$ac_tool_prefix" && test "$build" = "$host"; then
3446     lt_nm_to_check="$lt_nm_to_check nm"
3447   fi
3448   for lt_tmp_nm in $lt_nm_to_check; do
3449     lt_save_ifs="$IFS"; IFS=$PATH_SEPARATOR
3450     for ac_dir in $PATH /usr/ccs/bin/elf /usr/ccs/bin /usr/ucb /bin; do
3451       IFS="$lt_save_ifs"
3452       test -z "$ac_dir" && ac_dir=.
3453       tmp_nm="$ac_dir/$lt_tmp_nm"
3454       if test -f "$tmp_nm" || test -f "$tmp_nm$ac_exeext" ; then
3455         # Check to see if the nm accepts a BSD-compat flag.
3456         # Adding the `sed 1q' prevents false positives on HP-UX, which says:
3457         #   nm: unknown option "B" ignored
3458         # Tru64's nm complains that /dev/null is an invalid object file
3459         case `"$tmp_nm" -B /dev/null 2>&1 | sed '1q'` in
3460         */dev/null* | *'Invalid file or object type'*)
3461           lt_cv_path_NM="$tmp_nm -B"
3462           break
3463           ;;
3464         *)
3465           case `"$tmp_nm" -p /dev/null 2>&1 | sed '1q'` in
3466           */dev/null*)
3467             lt_cv_path_NM="$tmp_nm -p"
3468             break
3469             ;;
3470           *)
3471             lt_cv_path_NM=${lt_cv_path_NM="$tmp_nm"} # keep the first match, but
3472             continue # so that we can try to find one that supports BSD flags
3473             ;;
3474           esac
3475           ;;
3476         esac
3477       fi
3478     done
3479     IFS="$lt_save_ifs"
3480   done
3481   : ${lt_cv_path_NM=no}
3482 fi])
3483 if test "$lt_cv_path_NM" != "no"; then
3484   NM="$lt_cv_path_NM"
3485 else
3486   # Didn't find any BSD compatible name lister, look for dumpbin.
3487   if test -n "$DUMPBIN"; then :
3488     # Let the user override the test.
3489   else
3490     AC_CHECK_TOOLS(DUMPBIN, [dumpbin "link -dump"], :)
3491     case `$DUMPBIN -symbols /dev/null 2>&1 | sed '1q'` in
3492     *COFF*)
3493       DUMPBIN="$DUMPBIN -symbols"
3494       ;;
3495     *)
3496       DUMPBIN=:
3497       ;;
3498     esac
3499   fi
3500   AC_SUBST([DUMPBIN])
3501   if test "$DUMPBIN" != ":"; then
3502     NM="$DUMPBIN"
3503   fi
3504 fi
3505 test -z "$NM" && NM=nm
3506 AC_SUBST([NM])
3507 _LT_DECL([], [NM], [1], [A BSD- or MS-compatible name lister])dnl
3508
3509 AC_CACHE_CHECK([the name lister ($NM) interface], [lt_cv_nm_interface],
3510   [lt_cv_nm_interface="BSD nm"
3511   echo "int some_variable = 0;" > conftest.$ac_ext
3512   (eval echo "\"\$as_me:$LINENO: $ac_compile\"" >&AS_MESSAGE_LOG_FD)
3513   (eval "$ac_compile" 2>conftest.err)
3514   cat conftest.err >&AS_MESSAGE_LOG_FD
3515   (eval echo "\"\$as_me:$LINENO: $NM \\\"conftest.$ac_objext\\\"\"" >&AS_MESSAGE_LOG_FD)
3516   (eval "$NM \"conftest.$ac_objext\"" 2>conftest.err > conftest.out)
3517   cat conftest.err >&AS_MESSAGE_LOG_FD
3518   (eval echo "\"\$as_me:$LINENO: output\"" >&AS_MESSAGE_LOG_FD)
3519   cat conftest.out >&AS_MESSAGE_LOG_FD
3520   if $GREP 'External.*some_variable' conftest.out > /dev/null; then
3521     lt_cv_nm_interface="MS dumpbin"
3522   fi
3523   rm -f conftest*])
3524 ])# LT_PATH_NM
3525
3526 # Old names:
3527 AU_ALIAS([AM_PROG_NM], [LT_PATH_NM])
3528 AU_ALIAS([AC_PROG_NM], [LT_PATH_NM])
3529 dnl aclocal-1.4 backwards compatibility:
3530 dnl AC_DEFUN([AM_PROG_NM], [])
3531 dnl AC_DEFUN([AC_PROG_NM], [])
3532
3533 # _LT_CHECK_SHAREDLIB_FROM_LINKLIB
3534 # --------------------------------
3535 # how to determine the name of the shared library
3536 # associated with a specific link library.
3537 #  -- PORTME fill in with the dynamic library characteristics
3538 m4_defun([_LT_CHECK_SHAREDLIB_FROM_LINKLIB],
3539 [m4_require([_LT_DECL_EGREP])
3540 m4_require([_LT_DECL_OBJDUMP])
3541 m4_require([_LT_DECL_DLLTOOL])
3542 AC_CACHE_CHECK([how to associate runtime and link libraries],
3543 lt_cv_sharedlib_from_linklib_cmd,
3544 [lt_cv_sharedlib_from_linklib_cmd='unknown'
3545
3546 case $host_os in
3547 cygwin* | mingw* | pw32* | cegcc*)
3548   # two different shell functions defined in ltmain.sh
3549   # decide which to use based on capabilities of $DLLTOOL
3550   case `$DLLTOOL --help 2>&1` in
3551   *--identify-strict*)
3552     lt_cv_sharedlib_from_linklib_cmd=func_cygming_dll_for_implib
3553     ;;
3554   *)
3555     lt_cv_sharedlib_from_linklib_cmd=func_cygming_dll_for_implib_fallback
3556     ;;
3557   esac
3558   ;;
3559 *)
3560   # fallback: assume linklib IS sharedlib
3561   lt_cv_sharedlib_from_linklib_cmd="$ECHO"
3562   ;;
3563 esac
3564 ])
3565 sharedlib_from_linklib_cmd=$lt_cv_sharedlib_from_linklib_cmd
3566 test -z "$sharedlib_from_linklib_cmd" && sharedlib_from_linklib_cmd=$ECHO
3567
3568 _LT_DECL([], [sharedlib_from_linklib_cmd], [1],
3569     [Command to associate shared and link libraries])
3570 ])# _LT_CHECK_SHAREDLIB_FROM_LINKLIB
3571
3572
3573 # _LT_PATH_MANIFEST_TOOL
3574 # ----------------------
3575 # locate the manifest tool
3576 m4_defun([_LT_PATH_MANIFEST_TOOL],
3577 [AC_CHECK_TOOL(MANIFEST_TOOL, mt, :)
3578 test -z "$MANIFEST_TOOL" && MANIFEST_TOOL=mt
3579 AC_CACHE_CHECK([if $MANIFEST_TOOL is a manifest tool], [lt_cv_path_mainfest_tool],
3580   [lt_cv_path_mainfest_tool=no
3581   echo "$as_me:$LINENO: $MANIFEST_TOOL '-?'" >&AS_MESSAGE_LOG_FD
3582   $MANIFEST_TOOL '-?' 2>conftest.err > conftest.out
3583   cat conftest.err >&AS_MESSAGE_LOG_FD
3584   if $GREP 'Manifest Tool' conftest.out > /dev/null; then
3585     lt_cv_path_mainfest_tool=yes
3586   fi
3587   rm -f conftest*])
3588 if test "x$lt_cv_path_mainfest_tool" != xyes; then
3589   MANIFEST_TOOL=:
3590 fi
3591 _LT_DECL([], [MANIFEST_TOOL], [1], [Manifest tool])dnl
3592 ])# _LT_PATH_MANIFEST_TOOL
3593
3594
3595 # LT_LIB_M
3596 # --------
3597 # check for math library
3598 AC_DEFUN([LT_LIB_M],
3599 [AC_REQUIRE([AC_CANONICAL_HOST])dnl
3600 LIBM=
3601 case $host in
3602 *-*-beos* | *-*-cegcc* | *-*-cygwin* | *-*-haiku* | *-*-pw32* | *-*-darwin*)
3603   # These system don't have libm, or don't need it
3604   ;;
3605 *-ncr-sysv4.3*)
3606   AC_CHECK_LIB(mw, _mwvalidcheckl, LIBM="-lmw")
3607   AC_CHECK_LIB(m, cos, LIBM="$LIBM -lm")
3608   ;;
3609 *)
3610   AC_CHECK_LIB(m, cos, LIBM="-lm")
3611   ;;
3612 esac
3613 AC_SUBST([LIBM])
3614 ])# LT_LIB_M
3615
3616 # Old name:
3617 AU_ALIAS([AC_CHECK_LIBM], [LT_LIB_M])
3618 dnl aclocal-1.4 backwards compatibility:
3619 dnl AC_DEFUN([AC_CHECK_LIBM], [])
3620
3621
3622 # _LT_COMPILER_NO_RTTI([TAGNAME])
3623 # -------------------------------
3624 m4_defun([_LT_COMPILER_NO_RTTI],
3625 [m4_require([_LT_TAG_COMPILER])dnl
3626
3627 _LT_TAGVAR(lt_prog_compiler_no_builtin_flag, $1)=
3628
3629 if test "$GCC" = yes; then
3630   case $cc_basename in
3631   nvcc*)
3632     _LT_TAGVAR(lt_prog_compiler_no_builtin_flag, $1)=' -Xcompiler -fno-builtin' ;;
3633   *)
3634     _LT_TAGVAR(lt_prog_compiler_no_builtin_flag, $1)=' -fno-builtin' ;;
3635   esac
3636
3637   _LT_COMPILER_OPTION([if $compiler supports -fno-rtti -fno-exceptions],
3638     lt_cv_prog_compiler_rtti_exceptions,
3639     [-fno-rtti -fno-exceptions], [],
3640     [_LT_TAGVAR(lt_prog_compiler_no_builtin_flag, $1)="$_LT_TAGVAR(lt_prog_compiler_no_builtin_flag, $1) -fno-rtti -fno-exceptions"])
3641 fi
3642 _LT_TAGDECL([no_builtin_flag], [lt_prog_compiler_no_builtin_flag], [1],
3643         [Compiler flag to turn off builtin functions])
3644 ])# _LT_COMPILER_NO_RTTI
3645
3646
3647 # _LT_CMD_GLOBAL_SYMBOLS
3648 # ----------------------
3649 m4_defun([_LT_CMD_GLOBAL_SYMBOLS],
3650 [AC_REQUIRE([AC_CANONICAL_HOST])dnl
3651 AC_REQUIRE([AC_PROG_CC])dnl
3652 AC_REQUIRE([AC_PROG_AWK])dnl
3653 AC_REQUIRE([LT_PATH_NM])dnl
3654 AC_REQUIRE([LT_PATH_LD])dnl
3655 m4_require([_LT_DECL_SED])dnl
3656 m4_require([_LT_DECL_EGREP])dnl
3657 m4_require([_LT_TAG_COMPILER])dnl
3658
3659 # Check for command to grab the raw symbol name followed by C symbol from nm.
3660 AC_MSG_CHECKING([command to parse $NM output from $compiler object])
3661 AC_CACHE_VAL([lt_cv_sys_global_symbol_pipe],
3662 [
3663 # These are sane defaults that work on at least a few old systems.
3664 # [They come from Ultrix.  What could be older than Ultrix?!! ;)]
3665
3666 # Character class describing NM global symbol codes.
3667 symcode='[[BCDEGRST]]'
3668
3669 # Regexp to match symbols that can be accessed directly from C.
3670 sympat='\([[_A-Za-z]][[_A-Za-z0-9]]*\)'
3671
3672 # Define system-specific variables.
3673 case $host_os in
3674 aix*)
3675   symcode='[[BCDT]]'
3676   ;;
3677 cygwin* | mingw* | pw32* | cegcc*)
3678   symcode='[[ABCDGISTW]]'
3679   ;;
3680 hpux*)
3681   if test "$host_cpu" = ia64; then
3682     symcode='[[ABCDEGRST]]'
3683   fi
3684   ;;
3685 irix* | nonstopux*)
3686   symcode='[[BCDEGRST]]'
3687   ;;
3688 osf*)
3689   symcode='[[BCDEGQRST]]'
3690   ;;
3691 solaris*)
3692   symcode='[[BDRT]]'
3693   ;;
3694 sco3.2v5*)
3695   symcode='[[DT]]'
3696   ;;
3697 sysv4.2uw2*)
3698   symcode='[[DT]]'
3699   ;;
3700 sysv5* | sco5v6* | unixware* | OpenUNIX*)
3701   symcode='[[ABDT]]'
3702   ;;
3703 sysv4)
3704   symcode='[[DFNSTU]]'
3705   ;;
3706 esac
3707
3708 # If we're using GNU nm, then use its standard symbol codes.
3709 case `$NM -V 2>&1` in
3710 *GNU* | *'with BFD'*)
3711   symcode='[[ABCDGIRSTW]]' ;;
3712 esac
3713
3714 # Transform an extracted symbol line into a proper C declaration.
3715 # Some systems (esp. on ia64) link data and code symbols differently,
3716 # so use this general approach.
3717 lt_cv_sys_global_symbol_to_cdecl="sed -n -e 's/^T .* \(.*\)$/extern int \1();/p' -e 's/^$symcode* .* \(.*\)$/extern char \1;/p'"
3718
3719 # Transform an extracted symbol line into symbol name and symbol address
3720 lt_cv_sys_global_symbol_to_c_name_address="sed -n -e 's/^: \([[^ ]]*\)[[ ]]*$/  {\\\"\1\\\", (void *) 0},/p' -e 's/^$symcode* \([[^ ]]*\) \([[^ ]]*\)$/  {\"\2\", (void *) \&\2},/p'"
3721 lt_cv_sys_global_symbol_to_c_name_address_lib_prefix="sed -n -e 's/^: \([[^ ]]*\)[[ ]]*$/  {\\\"\1\\\", (void *) 0},/p' -e 's/^$symcode* \([[^ ]]*\) \(lib[[^ ]]*\)$/  {\"\2\", (void *) \&\2},/p' -e 's/^$symcode* \([[^ ]]*\) \([[^ ]]*\)$/  {\"lib\2\", (void *) \&\2},/p'"
3722
3723 # Handle CRLF in mingw tool chain
3724 opt_cr=
3725 case $build_os in
3726 mingw*)
3727   opt_cr=`$ECHO 'x\{0,1\}' | tr x '\015'` # option cr in regexp
3728   ;;
3729 esac
3730
3731 # Try without a prefix underscore, then with it.
3732 for ac_symprfx in "" "_"; do
3733
3734   # Transform symcode, sympat, and symprfx into a raw symbol and a C symbol.
3735   symxfrm="\\1 $ac_symprfx\\2 \\2"
3736
3737   # Write the raw and C identifiers.
3738   if test "$lt_cv_nm_interface" = "MS dumpbin"; then
3739     # Fake it for dumpbin and say T for any non-static function
3740     # and D for any global variable.
3741     # Also find C++ and __fastcall symbols from MSVC++,
3742     # which start with @ or ?.
3743     lt_cv_sys_global_symbol_pipe="$AWK ['"\
3744 "     {last_section=section; section=\$ 3};"\
3745 "     /^COFF SYMBOL TABLE/{for(i in hide) delete hide[i]};"\
3746 "     /Section length .*#relocs.*(pick any)/{hide[last_section]=1};"\
3747 "     \$ 0!~/External *\|/{next};"\
3748 "     / 0+ UNDEF /{next}; / UNDEF \([^|]\)*()/{next};"\
3749 "     {if(hide[section]) next};"\
3750 "     {f=0}; \$ 0~/\(\).*\|/{f=1}; {printf f ? \"T \" : \"D \"};"\
3751 "     {split(\$ 0, a, /\||\r/); split(a[2], s)};"\
3752 "     s[1]~/^[@?]/{print s[1], s[1]; next};"\
3753 "     s[1]~prfx {split(s[1],t,\"@\"); print t[1], substr(t[1],length(prfx))}"\
3754 "     ' prfx=^$ac_symprfx]"
3755   else
3756     lt_cv_sys_global_symbol_pipe="sed -n -e 's/^.*[[     ]]\($symcode$symcode*\)[[       ]][[    ]]*$ac_symprfx$sympat$opt_cr$/$symxfrm/p'"
3757   fi
3758   lt_cv_sys_global_symbol_pipe="$lt_cv_sys_global_symbol_pipe | sed '/ __gnu_lto/d'"
3759
3760   # Check to see that the pipe works correctly.
3761   pipe_works=no
3762
3763   rm -f conftest*
3764   cat > conftest.$ac_ext <<_LT_EOF
3765 #ifdef __cplusplus
3766 extern "C" {
3767 #endif
3768 char nm_test_var;
3769 void nm_test_func(void);
3770 void nm_test_func(void){}
3771 #ifdef __cplusplus
3772 }
3773 #endif
3774 int main(){nm_test_var='a';nm_test_func();return(0);}
3775 _LT_EOF
3776
3777   if AC_TRY_EVAL(ac_compile); then
3778     # Now try to grab the symbols.
3779     nlist=conftest.nm
3780     if AC_TRY_EVAL(NM conftest.$ac_objext \| "$lt_cv_sys_global_symbol_pipe" \> $nlist) && test -s "$nlist"; then
3781       # Try sorting and uniquifying the output.
3782       if sort "$nlist" | uniq > "$nlist"T; then
3783         mv -f "$nlist"T "$nlist"