speedo,w32: Install a native pinentry.
[gnupg.git] / build-aux / speedo / w32 / inst.nsi
1 # inst.nsi - Installer for GnuPG on Windows.      -*- coding: latin-1; -*-
2 # Copyright (C) 2005, 2014 g10 Code GmbH
3 #
4 # This file is part of GnuPG.
5 #
6 # GnuPG is free software; you can redistribute it and/or modify
7 # it under the terms of the GNU General Public License as published by
8 # the Free Software Foundation; either version 3 of the License, or
9 # (at your option) any later version.
10 #
11 # GnuPG is distributed in the hope that it will be useful,
12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 # GNU General Public License for more details.
15 #
16 # You should have received a copy of the GNU General Public License
17 # along with this program; if not, see <http://www.gnu.org/licenses/>.
18
19 # Macros to provide for invocation:
20 #  INST_DIR
21 #  INST6_DIR
22 #  BUILD_DIR
23 #  TOP_SRCDIR
24 #  W32_SRCDIR
25 #  BUILD_ISODATE   - the build date, e.g. "2014-10-31"
26 #  BUILD_DATESTR   - ditto w/o '-',  e.g. "20141031"
27 #  NAME
28 #  VERSION
29 #  PROD_VERSION
30 #
31 #  WITH_GUI        - Include the GPA GUI
32
33 !cd "${INST_DIR}"
34 !addincludedir "${W32_SRCDIR}"
35 !addplugindir "${BUILD_DIR}"
36
37 # The package name and version.  PRETTY_PACKAGE is a user visible name
38 # only while PACKAGE is useful for filenames etc.  PROD_VERSION is the
39 # product version and needs to be in the format "MAJ.MIN.MIC.BUILDNR".
40 !define PACKAGE "gnupg"
41 !define PACKAGE_SHORT "gnupg"
42 !define PRETTY_PACKAGE "GNU Privacy Guard"
43 !define PRETTY_PACKAGE_SHORT "GnuPG"
44 !define COMPANY "The GnuPG Project"
45 !define COPYRIGHT "Copyright (C) 2015 The GnuPG Project"
46 !define DESCRIPTION "GnuPG: The GNU Privacy Guard for Windows"
47
48 !define INSTALL_DIR "GnuPG"
49
50 !define WELCOME_TITLE_ENGLISH \
51  "Welcome to the installation of GnuPG"
52
53 !define WELCOME_TITLE_GERMAN \
54  "Willkommen bei der Installation von GnuPG"
55
56 !define ABOUT_ENGLISH \
57  "GnuPG is the mostly used software for mail and data encryption. \
58   GnuPG can be used to encrypt data and to create digital signatures. \
59   GnuPG includes an advanced key management facility and is compliant \
60   with the OpenPGP Internet standard as described in RFC-4880. \
61   \r\n\r\n$_CLICK \
62   \r\n\r\n\r\n\r\n\r\nThis is GnuPG version ${VERSION}.\r\n\
63   File version: ${PROD_VERSION}\r\n\
64   Release date: ${BUILD_ISODATE}"
65 !define ABOUT_GERMAN \
66  "GnuPG is die häufigst verwendete Software zur Mail- und Datenverschlüsselung.\
67    \r\n\r\n$_CLICK \
68    \r\n\r\n\r\n\r\n\r\nDies ist GnuPG Version ${VERSION}.\r\n\
69    Dateiversion: ${PROD_VERSION}\r\n\
70    Releasedatum: ${BUILD_ISODATE}"
71
72
73 # The copyright license of the package.  Define only one of these.
74 !define LICENSE_GPL
75
76 # Select the best compression algorithm available.  The dictionary
77 # size is the default (8 MB).
78 !ifndef SOURCES
79 SetCompressor lzma
80 # SetCompressorDictSize 8
81 !endif
82
83 # Include the generic parts.
84 !define HAVE_STARTMENU
85
86 # We use the modern UI.
87 !include "MUI.nsh"
88
89 # Some helper some
90 !include "LogicLib.nsh"
91 !include "x64.nsh"
92
93 # Set the package name.  Note that this name should not be suffixed
94 # with the version because this would get displayed in the start menu.
95 # Given that a slash in the name troubles Windows startmenu creation
96 # we set the Startmenu explicit below.
97 Name "${PRETTY_PACKAGE}"
98
99 # Set the output filename.
100 OutFile "${NAME}-${VERSION}_${BUILD_DATESTR}.exe"
101
102 #Fixme: Do we need a logo?
103 #Icon "${TOP_SRCDIR}/doc/logo/gnupg-logo-icon.ico"
104 #UninstallIcon "${TOP_SRCDIR}/doc/logo/gnupg-logo-icon.ico"
105
106 # Set the installation directory.
107 !ifndef INSTALL_DIR
108 !define INSTALL_DIR "GnuPG"
109 !endif
110 InstallDir "$PROGRAMFILES\${INSTALL_DIR}"
111
112 InstallDirRegKey HKLM "Software\${PACKAGE_SHORT}" "Install Directory"
113
114
115 # Add version information to the file properties.
116 VIProductVersion "${PROD_VERSION}"
117 VIAddVersionKey "ProductName" "${PRETTY_PACKAGE_SHORT} (${VERSION})"
118 VIAddVersionKey "Comments" \
119    "GnuPG is Free Software; you can redistribute it  \
120     and/or modify it under the terms of the GNU General Public License.  \
121     You should have received a copy of the GNU General Public License  \
122     along with this software; if not, write to the Free Software  \
123     Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,  \
124     MA 02110-1301, USA"
125 VIAddVersionKey "CompanyName" "${COMPANY}"
126 VIAddVersionKey "LegalTrademarks" ""
127 VIAddVersionKey "LegalCopyright" "${COPYRIGHT}"
128 VIAddVersionKey "FileDescription" "${DESCRIPTION}"
129 VIAddVersionKey "FileVersion" "${PROD_VERSION}"
130
131 # Interface Settings
132
133 # !define MUI_ABORTWARNING
134 !define MUI_FINISHPAGE_NOAUTOCLOSE
135 !define MUI_UNFINISHPAGE_NOAUTOCLOSE
136
137 !define MUI_HEADERIMAGE
138 !define MUI_HEADERIMAGE_BITMAP "${W32_SRCDIR}\gnupg-logo-150x57.bmp"
139 !define MUI_WELCOMEFINISHPAGE_BITMAP "${W32_SRCDIR}\gnupg-logo-164x314.bmp"
140
141 # Remember the installer language
142 !define MUI_LANGDLL_REGISTRY_ROOT "HKCU"
143 !define MUI_LANGDLL_REGISTRY_KEY "Software\GnuPG"
144 !define MUI_LANGDLL_REGISTRY_VALUENAME "Installer Language"
145
146 #
147 # The list of wizard pages.
148 #
149 !define MUI_WELCOMEPAGE_TITLE "$(T_WelcomeTitle)"
150 !define MUI_WELCOMEPAGE_TEXT  "$(T_About)"
151 !insertmacro MUI_PAGE_WELCOME
152
153 !define MUI_LICENSEPAGE_BUTTON "$(^NextBtn)"
154 !define MUI_PAGE_HEADER_SUBTEXT "$(T_GPLHeader)"
155 !define MUI_LICENSEPAGE_TEXT_BOTTOM "$(T_GPLShort)"
156 !insertmacro MUI_PAGE_LICENSE "${TOP_SRCDIR}/COPYING"
157
158 !define MUI_PAGE_CUSTOMFUNCTION_SHOW PrintNonAdminWarning
159 !insertmacro MUI_PAGE_COMPONENTS
160
161 !define MUI_PAGE_CUSTOMFUNCTION_LEAVE CheckExistingVersion
162 !insertmacro MUI_PAGE_DIRECTORY
163
164 !ifdef HAVE_STARTMENU
165
166 Page custom CustomPageOptions
167
168 Var STARTMENU_FOLDER
169
170 !define MUI_PAGE_CUSTOMFUNCTION_PRE CheckIfStartMenuWanted
171 !define MUI_STARTMENUPAGE_NODISABLE
172 !define MUI_STARTMENUPAGE_REGISTRY_ROOT "HKCU"
173 !define MUI_STARTMENUPAGE_REGISTRY_KEY "Software\GnuPG"
174 !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "Start Menu Folder"
175 # We need to set the Startmenu name explicitly because a slash in the
176 # name is not possible.
177 !define MUI_STARTMENUPAGE_DEFAULTFOLDER "GnuPG"
178
179 !insertmacro MUI_PAGE_STARTMENU Application $STARTMENU_FOLDER
180
181 !endif
182
183 !define MUI_PAGE_CUSTOMFUNCTION_PRE PrintCloseOtherApps
184 !insertmacro MUI_PAGE_INSTFILES
185
186 #!define MUI_PAGE_CUSTOMFUNCTION_PRE ShowFinalWarnings
187 !define MUI_FINISHPAGE_SHOWREADME "README.txt"
188 !define MUI_FINISHPAGE_SHOWREADME_TEXT "$(T_ShowReadme)"
189 #!define MUI_FINISHPAGE_RUN
190 #!define MUI_FINISHPAGE_RUN_FUNCTION RunOnFinish
191 #!define MUI_FINISHPAGE_RUN_TEXT "$(T_RunKeyManager)"
192 #!define MUI_FINISHPAGE_RUN_NOTCHECKED
193 !define MUI_FINISHPAGE_LINK "$(T_MoreInfo)"
194 !define MUI_FINISHPAGE_LINK_LOCATION "$(T_MoreInfoURL)"
195 !insertmacro MUI_PAGE_FINISH
196
197
198 # Uninstaller pages.
199
200 !insertmacro MUI_UNPAGE_CONFIRM
201 !insertmacro MUI_UNPAGE_INSTFILES
202
203
204 #Page license
205 #Page components
206 #Page directory
207 #Page instfiles
208 #UninstPage uninstConfirm
209 #UninstPage instfiles
210
211
212 # Language support.  This has to be done after defining the pages, but
213 # before defining the translation strings.  Confusing.
214
215 !insertmacro MUI_LANGUAGE "English"
216 !insertmacro MUI_LANGUAGE "German"
217
218 !insertmacro MUI_RESERVEFILE_LANGDLL
219 !insertmacro MUI_RESERVEFILE_INSTALLOPTIONS
220 ReserveFile "${BUILD_DIR}\g4wihelp.dll"
221 ReserveFile "${W32_SRCDIR}\gnupg-logo-150x57.bmp"
222 ReserveFile "${W32_SRCDIR}\gnupg-logo-164x314.bmp"
223 ReserveFile "${TOP_SRCDIR}\COPYING"
224 ReserveFile "${W32_SRCDIR}\inst-options.ini"
225
226 # Language support
227
228 LangString T_LangCode ${LANG_ENGLISH} "en"
229 LangString T_LangCode ${LANG_GERMAN}  "de"
230
231
232 # The WelcomeTitle is displayed on the first page.
233 LangString T_WelcomeTitle ${LANG_ENGLISH} "${WELCOME_TITLE_ENGLISH}"
234 LangString T_WelcomeTitle ${LANG_GERMAN} "${WELCOME_TITLE_GERMAN}"
235
236 # The About string as displayed on the first page.
237 LangString T_About ${LANG_ENGLISH} "${ABOUT_ENGLISH}"
238 LangString T_About ${LANG_GERMAN} "${ABOUT_GERMAN}"
239
240 # Startup page
241 LangString T_GPLHeader ${LANG_ENGLISH} \
242   "This software is licensed under the terms of the GNU General Public \
243    License (GNU GPL)."
244 LangString T_GPLHeader ${LANG_GERMAN}} \
245   "Diese Software ist unter der GNU General Public License \
246    (GNU GPL) lizensiert."
247
248 LangString T_GPLShort ${LANG_ENGLISH} \
249   "In short: You are allowed to run this software for any purpose. \
250    You may distribute it as long as you give the recipients the same \
251    rights you have received."
252 LangString T_GPLShort ${LANG_GERMAN} \
253   "In aller Kürze: Sie haben das Recht, die Software zu jedem Zweck \
254    einzusetzen.  Sie können die Software weitergeben, sofern Sie dem \
255    Empfänger dieselben Rechte einräumen, die auch Sie erhalten haben."
256
257 LangString T_RunKeyManager ${LANG_ENGLISH} \
258    "Run the key manager"
259 LangString T_RunKeyManager ${LANG_GERMAN} \
260    "Die Schlüsselverwaltung aufrufen"
261
262 LangString T_MoreInfo ${LANG_ENGLISH} \
263    "Click here for GnuPG's website"
264 LangString T_MoreInfo ${LANG_GERMAN} \
265    "Hier klicken um zur GnuPG Homepage zu gelangen"
266 LangString T_MoreInfoURL ${LANG_ENGLISH} "https://gnupg.org"
267 LangString T_MoreInfoURL ${LANG_GERMAN}  "https://gnupg.org"
268
269 LangString T_ShowReadme ${LANG_ENGLISH} \
270    "Show the README file"
271 LangString T_ShowReadme ${LANG_GERMAN} \
272    "Die README Datei anzeigen"
273
274 LangString T_NoKeyManager ${LANG_ENGLISH} \
275    "No key manager has been installed, thus we can't run one now."
276 LangString T_NoKeyManager ${LANG_GERMAN} \
277    "Es wurde keine Schlüsselverwaltung installiert. \
278     Deswegen kann sie jetzt auch nicht ausgeführt werden."
279
280 # Functions
281
282 # Custom functions and macros for this installer.
283 LangString T_AlreadyRunning ${LANG_ENGLISH} \
284    "An instance of this installer is already running."
285 LangString T_AlreadyRunning ${LANG_GERMAN} \
286    "Ein Exemplar dieses Installers läuft bereits."
287
288 Function G4wRunOnce
289   Push $R0
290   StrCpy $R0 "gnupg"
291   g4wihelp::runonce
292   StrCmp $R0 0 +3
293      MessageBox MB_OK $(T_AlreadyRunning)
294      Abort
295   Pop $R0
296 FunctionEnd
297
298 #
299 # Control function for the Custom page to select special
300 # install options.
301 #
302 Function CustomPageOptions
303   !insertmacro MUI_HEADER_TEXT "$(T_InstallOptions)" "$(T_InstallOptLinks)"
304
305   # Note, that the default selection is done in the ini file
306   !insertmacro MUI_INSTALLOPTIONS_WRITE "${W32_SRCDIR}/inst-options.ini" \
307         "Field 1" "Text"  "$(T_InstOptLabelA)"
308   !insertmacro MUI_INSTALLOPTIONS_WRITE "${W32_SRCDIR}/inst-options.ini" \
309         "Field 2" "Text"  "$(T_InstOptFieldA)"
310   !insertmacro MUI_INSTALLOPTIONS_WRITE "${W32_SRCDIR}/inst-options.ini" \
311         "Field 3" "Text"  "$(T_InstOptFieldB)"
312   !insertmacro MUI_INSTALLOPTIONS_WRITE "${W32_SRCDIR}/inst-options.ini" \
313         "Field 4" "Text"  "$(T_InstOptFieldC)"
314   !insertmacro MUI_INSTALLOPTIONS_WRITE "${W32_SRCDIR}/inst-options.ini" \
315         "Field 5" "Text"  "$(T_InstOptLabelB)"
316
317   !insertmacro MUI_INSTALLOPTIONS_DISPLAY "${W32_SRCDIR}/inst-options.ini"
318 FunctionEnd
319
320
321 # Check whether GnuPG has already been installed.  This is called as
322 # a leave function from the directory page.  A call to abort will get
323 # back to the directory selection.
324 Function CheckExistingVersion
325   ClearErrors
326   FileOpen $0 "$INSTDIR\VERSION" r
327   IfErrors nexttest
328   FileRead $0 $R0
329   FileRead $0 $R1
330   FileClose $0
331
332   Push $R1
333   Call TrimNewLines
334   Pop $R1
335
336   MessageBox MB_YESNO "$(T_FoundExistingVersion)" IDYES leave
337   Abort
338
339  nexttest:
340   ClearErrors
341   ReadRegStr $0 HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\GnuPG" "DisplayVersion"
342   IfErrors leave 0
343      MessageBox MB_YESNO "$(T_FoundExistingVersionB)" IDYES leave
344      Abort
345
346  leave:
347 FunctionEnd
348
349
350
351 # PrintNonAdminWarning
352
353 # Check whether the current user is in the Administrator group or an
354 # OS version without the need for an Administrator is in use.  Print a
355 # diagnostic if this is not the case and abort installation.
356 Function PrintNonAdminWarning
357   ClearErrors
358   UserInfo::GetName
359   IfErrors leave
360   Pop $0
361   UserInfo::GetAccountType
362   Pop $1
363   StrCmp $1 "Admin" leave +1
364   MessageBox MB_OK "$(T_AdminNeeded)"
365   Quit
366
367  leave:
368 FunctionEnd
369
370
371 # Check whether the start menu is actually wanted.
372
373 Function CheckIfStartMenuWanted
374   !insertmacro MUI_INSTALLOPTIONS_READ $R0 "${W32_SRCDIR}/inst-options.ini" \
375         "Field 2" "State"
376   IntCmp $R0 1 +2
377     Abort
378 FunctionEnd
379
380
381 # Check whether this is a reinstall and popup a message box to explain
382 # that it is better to close other apps before continuing
383 Function PrintCloseOtherApps
384     IfFileExists $INSTDIR\bin\gpg.exe print_warning
385     IfFileExists $INSTDIR\bin\gpa.exe print_warning
386     Return
387    print_warning:
388     MessageBox MB_OK|MB_ICONEXCLAMATION "$(T_CloseOtherApps)"
389
390 FunctionEnd
391
392 # Called right before the final page to show more warnings.
393 #Function ShowFinalWarnings
394 #   leave:
395 #FunctionEnd
396
397 #-----------------------------------------------
398 # Strings pertaining to the install options page
399 #-----------------------------------------------
400
401 # Installation options title
402 LangString T_InstallOptions ${LANG_ENGLISH} "Install Options"
403 LangString T_InstallOptions ${LANG_GERMAN}  "Installationsoptionen"
404
405 # Installation options subtitle 1
406 LangString T_InstallOptLinks ${LANG_ENGLISH} "Start links"
407 LangString T_InstallOptLinks ${LANG_GERMAN}  "Startlinks"
408
409 LangString T_InstOptLabelA  ${LANG_ENGLISH} \
410      "Please select where GnuPG shall install links:"
411 LangString T_InstOptLabelA  ${LANG_GERMAN} \
412      "Bitte wählen Sie, welche Verknüpfungen angelegt werden sollen:"
413
414 LangString T_InstOptLabelB  ${LANG_ENGLISH} \
415      "(Only programs will be linked into the quick launch bar.)"
416 LangString T_InstOptLabelB  ${LANG_GERMAN} \
417      "(In die Schnellstartleiste werden nur Verknüpfungen für \
418       Programme angelegt.) "
419
420 LangString T_InstOptFieldA  ${LANG_ENGLISH} \
421      "Start Menu"
422 LangString T_InstOptFieldA  ${LANG_GERMAN} \
423      "Startmenü"
424
425 LangString T_InstOptFieldB  ${LANG_ENGLISH} \
426      "Desktop"
427 LangString T_InstOptFieldB  ${LANG_GERMAN} \
428      "Arbeitsfläche"
429
430 LangString T_InstOptFieldC  ${LANG_ENGLISH} \
431      "Quick Launch Bar"
432 LangString T_InstOptFieldC  ${LANG_GERMAN} \
433      "Schnellstartleiste"
434
435 #------------------------------------------------
436 # String pertaining to the existing version check
437 #------------------------------------------------
438 LangString T_FoundExistingVersion ${LANG_ENGLISH} \
439      "Version $R1 has already been installed.  $\r$\n\
440       Do you want to overwrite it with version ${VERSION}?"
441 LangString T_FoundExistingVersion ${LANG_GERMAN} \
442      "Version $R1 ist hier bereits installiert. $\r$\n\
443       Möchten Sie diese mit Version ${VERSION} überschreiben? $\r$\n\
444        $\r$\n\
445       (Sie können in jedem Fall mit JA antworten, falls es sich um \
446        eine neuere oder dieselbe Version handelt.)"
447 LangString T_FoundExistingVersionB ${LANG_ENGLISH} \
448      "A version of GnuPG has already been installed on the system. \
449       There will be no problem installing and thus overwriting this \
450       Version. $\r$\n\
451        $\r$\n\
452       Do you want to continue installing GnuPG?"
453 LangString T_FoundExistingVersionB ${LANG_GERMAN} \
454      "Eine Version von GnuPG ist hier bereits installiert. \
455       Es ist problemlos möglich, die Installation fortzuführen.  $\r$\n\
456         $\r$\n\
457       Möchten die die Installation von GnuPG fortführen?"
458
459
460
461 # From Function PrintNonAdminWarning
462 LangString T_AdminNeeded ${LANG_ENGLISH} \
463    "Warning: Administrator permissions required for a successful installation"
464 LangString T_AdminNeeded ${LANG_GERMAN} \
465    "Achtung: Für eine erfolgreiche Installation werden \
466     Administratorrechte benötigt."
467
468 # From Function PrintCloseOtherApps
469 LangString T_CloseOtherApps ${LANG_ENGLISH} \
470    "Please make sure that other applications are not running. \
471     GnuPG will try to install anyway but a reboot may be required."
472 LangString T_CloseOtherApps ${LANG_GERMAN} \
473    "Bitte stellen Sie sicher, daß alle anderen Anwendugen geschlossen \
474     sind.  GnuPG wird auf jeden Fall versuchen, eine Installation \
475     durchzuführen; es ist dann aber u.U. notwendig, das System neu zu starten."
476
477
478 # TrimNewlines  - taken from the NSIS reference
479 # input, top of stack  (e.g. whatever$\r$\n)
480 # output, top of stack (replaces, with e.g. whatever)
481 # modifies no other variables.
482 Function TrimNewlines
483    Exch $R0
484    Push $R1
485    Push $R2
486    StrCpy $R1 0
487
488  loop:
489    IntOp $R1 $R1 - 1
490    StrCpy $R2 $R0 1 $R1
491    StrCmp $R2 "$\r" loop
492    StrCmp $R2 "$\n" loop
493    IntOp $R1 $R1 + 1
494    IntCmp $R1 0 no_trim_needed
495    StrCpy $R0 $R0 $R1
496
497  no_trim_needed:
498    Pop $R2
499    Pop $R1
500    Exch $R0
501 FunctionEnd
502
503
504 # AddToPath - Adds the given dir to the search path.
505 #        Input - head of the stack
506 Function AddToPath
507   Exch $0
508   g4wihelp::path_add "$0"
509   StrCmp $R5 "0" add_to_path_done
510   SendMessage ${HWND_BROADCAST} ${WM_WININICHANGE} 0 "STR:Environment" /TIMEOUT=5000
511   add_to_path_done:
512   Pop $0
513 FunctionEnd
514
515
516 # RemoveFromPath - Remove a given dir from the path
517 #     Input: head of the stack
518 Function un.RemoveFromPath
519   Exch $0
520   g4wihelp::path_remove "$0"
521   StrCmp $R5 "0" remove_from_path_done
522   SendMessage ${HWND_BROADCAST} ${WM_WININICHANGE} 0 "STR:Environment" /TIMEOUT=5000
523   remove_from_path_done:
524   Pop $0
525 FunctionEnd
526
527
528 #
529 # Define the installer sections.
530 #
531
532 Section "-gnupginst"
533   SetOutPath "$INSTDIR"
534
535   File "${BUILD_DIR}/README.txt"
536
537   # Write a version file.
538   FileOpen $0 "$INSTDIR\VERSION" w
539   FileWrite $0 "${PACKAGE}$\r$\n"
540   FileWrite $0 "${VERSION}$\r$\n"
541   FileClose $0
542
543   WriteRegStr HKLM "Software\GnuPG" "Install Directory" $INSTDIR
544
545   # If we are reinstalling, try to kill a possible running gpa using
546   # an already installed gpa.
547   ifFileExists "$INSTDIR\bin\launch-gpa.exe"  0 no_uiserver
548     ExecWait '"$INSTDIR\bin\launch-gpa" --stop-server'
549
550   no_uiserver:
551
552   # If we are reinstalling, try to kill a possible running agent using
553   # an already installed gpgconf.
554   ifFileExists "$INSTDIR\bin\gpgconf.exe"  0 no_gpgconf
555     ExecWait '"$INSTDIR\bin\gpgconf" --kill dirmngr'
556     ExecWait '"$INSTDIR\bin\gpgconf" --kill gpg-agent'
557
558   no_gpgconf:
559
560   # Add the bin directory to the PATH
561   Push "$INSTDIR\bin"
562   Call AddToPath
563   DetailPrint "Added $INSTDIR\bin to PATH"
564 SectionEnd
565
566 LangString DESC_Menu_gnupg_readme ${LANG_ENGLISH} \
567    "General information on GnuPG"
568 LangString DESC_Menu_gnupg_readme ${LANG_GERMAN} \
569    "Allgemeine Informationen zu GnuPG"
570
571
572 Section "GnuPG" SEC_gnupg
573   SectionIn RO
574
575   SetOutPath "$INSTDIR\bin"
576   File /oname=gpg.exe "bin/gpg2.exe"
577   File /oname=gpgv.exe "bin/gpgv2.exe"
578   File "bin/gpgsm.exe"
579   File "bin/gpgconf.exe"
580   File "bin/gpg-connect-agent.exe"
581   File "bin/gpgtar.exe"
582
583   ClearErrors
584   SetOverwrite try
585   File "bin/gpg-agent.exe"
586   SetOverwrite lastused
587   ifErrors 0 +3
588       File /oname=gpg-agent.exe.tmp "bin/gpg-agent.exe"
589       Rename /REBOOTOK gpg-agent.exe.tmp gpg-agent.exe
590
591   ClearErrors
592   SetOverwrite try
593   File "bin/dirmngr.exe"
594   SetOverwrite lastused
595   ifErrors 0 +3
596       File /oname=dirmngr.exe.tmp "bin/dirmngr.exe"
597       Rename /REBOOTOK dirmngr.exe.tmp dirmngr.exe
598
599   ClearErrors
600   SetOverwrite try
601   File "libexec/scdaemon.exe"
602   SetOverwrite lastused
603   ifErrors 0 +3
604       File /oname=scdaemon.exe.tmp "libexec/scdaemon.exe"
605       Rename /REBOOTOK scdaemon.exe.tmp scdaemon.exe
606
607   SetOutPath "$INSTDIR\share\gnupg"
608   File "share/gnupg/gpg-conf.skel"
609 SectionEnd
610
611
612 LangString DESC_SEC_gnupg ${LANG_ENGLISH} \
613    "The GnuPG Core is the actual encrypt core and a set of command \
614     line utilities."
615 LangString DESC_SEC_gnupg ${LANG_GERMAN} \
616    "Der GnuPG Core ist, wie der Name schon sagt, der Kernbestandteil \
617     dieser Software.  Der GnuPG Core stellt die eigentliche \
618     Verschlüsselung sowie die Verwaltung der Schlüssel bereit."
619
620 LangString DESC_Menu_gnupg_manual ${LANG_ENGLISH} \
621    "Show the manual for the GnuPG Core"
622 LangString DESC_Menu_gnupg_manual ${LANG_GERMAN} \
623    "Das Handbuch zum GnuPG Kern anzeigen"
624
625 Section "-libgpg-error" SEC_libgpg_error
626   SetOutPath "$INSTDIR\bin"
627   File bin/libgpg-error-0.dll
628   SetOutPath "$INSTDIR\lib"
629   File /oname=libgpg-error.imp lib/libgpg-error.dll.a
630   SetOutPath "$INSTDIR\include"
631   File include/gpg-error.h
632 SectionEnd
633
634 Section "-libiconv" SEC_libiconv
635   SetOutPath "$INSTDIR\bin"
636   File bin/libiconv-2.dll
637 SectionEnd
638
639 Section "-zlib" SEC_zlib
640   SetOutPath "$INSTDIR\bin"
641   File bin/zlib1.dll
642 SectionEnd
643
644 Section "-adns" SEC_adns
645   SetOutPath "$INSTDIR\bin"
646   File bin/libadns-1.dll
647   SetOutPath "$INSTDIR\lib"
648   File /oname=libadns.imp lib/libadns.dll.a
649   SetOutPath "$INSTDIR\include"
650   File include/adns.h
651 SectionEnd
652
653 Section "-npth" SEC_npth
654   SetOutPath "$INSTDIR\bin"
655   File bin/libnpth-0.dll
656   SetOutPath "$INSTDIR\lib"
657   File /oname=libnpth.imp lib/libnpth.dll.a
658   SetOutPath "$INSTDIR\include"
659   File include/npth.h
660 SectionEnd
661
662 Section "-gcrypt" SEC_gcrypt
663   SetOutPath "$INSTDIR\bin"
664   File bin/libgcrypt-20.dll
665   SetOutPath "$INSTDIR\lib"
666   File /oname=libgcrypt.imp lib/libgcrypt.dll.a
667   SetOutPath "$INSTDIR\include"
668   File include/gcrypt.h
669 SectionEnd
670
671 Section "-assuan" SEC_assuan
672   SetOutPath "$INSTDIR\bin"
673   File bin/libassuan-0.dll
674   SetOutPath "$INSTDIR\lib"
675   File /oname=libassuan.imp lib/libassuan.dll.a
676   SetOutPath "$INSTDIR\include"
677   File include/assuan.h
678 SectionEnd
679
680 Section "-ksba" SEC_ksba
681   SetOutPath "$INSTDIR\bin"
682   File bin/libksba-8.dll
683   SetOutPath "$INSTDIR\lib"
684   File /oname=libksba.imp lib/libksba.dll.a
685   SetOutPath "$INSTDIR\include"
686   File include/ksba.h
687 SectionEnd
688
689 Section "-gpgme" SEC_gpgme
690   SetOutPath "$INSTDIR\bin"
691   File bin/libgpgme-11.dll
692   File /nonfatal bin/libgpgme-glib-11.dll
693   File libexec/gpgme-w32spawn.exe
694   SetOutPath "$INSTDIR\lib"
695   File /oname=libgpgme.imp      lib/libgpgme.dll.a
696   File /nonfatal /oname=libgpgme-glib.imp lib/libgpgme-glib.dll.a
697   SetOutPath "$INSTDIR\include"
698   File include/gpgme.h
699 SectionEnd
700
701 !ifdef WITH_GUI
702 Section "-gettext" SEC_gettext
703   SetOutPath "$INSTDIR\bin"
704   File bin/libintl-8.dll
705 SectionEnd
706
707 Section "-glib" SEC_glib
708   SetOutPath "$INSTDIR\bin"
709   File bin/libgio-2.0-0.dll
710   File bin/libglib-2.0-0.dll
711   File bin/libgmodule-2.0-0.dll
712   File bin/libgobject-2.0-0.dll
713   File bin/libgthread-2.0-0.dll
714   File bin/gspawn-win32-helper.exe
715   File bin/gspawn-win32-helper-console.exe
716
717   File bin/libffi-6.dll
718 SectionEnd
719
720 Section "-libpng" SEC_libpng
721   SetOutPath "$INSTDIR\bin"
722   File bin/libpng14-14.dll
723 SectionEnd
724
725 #Section "-jpeg" SEC_jpeg
726 #  SetOutPath "$INSTDIR"
727 #  File bin/jpeg62.dll
728 #SectionEnd
729
730 Section "-cairo" SEC_cairo
731   SetOutPath "$INSTDIR\bin"
732   File bin/libcairo-gobject-2.dll
733   File bin/libpangocairo-1.0-0.dll
734   File bin/libcairo-2.dll
735   File bin/libcairo-script-interpreter-2.dll
736 SectionEnd
737
738 Section "-pixman" SEC_pixman
739   SetOutPath "$INSTDIR\bin"
740   File bin/libpixman-1-0.dll
741 SectionEnd
742
743 Section "-pango" SEC_pango
744   SetOutPath "$INSTDIR\bin"
745   File bin/pango-querymodules.exe
746   File bin/libpango-1.0-0.dll
747   File bin/libpangowin32-1.0-0.dll
748
749   SetOutPath "$INSTDIR\lib\pango\1.6.0\modules"
750   File lib/pango/1.6.0/modules/pango-basic-win32.dll
751   File lib/pango/1.6.0/modules/pango-arabic-lang.dll
752   File lib/pango/1.6.0/modules/pango-indic-lang.dll
753
754   SetOutPath "$INSTDIR\etc\pango"
755   File ${W32_SRCDIR}/pango.modules
756 SectionEnd
757
758 Section "-atk" SEC_atk
759   SetOutPath "$INSTDIR\bin"
760   File bin/libatk-1.0-0.dll
761 SectionEnd
762
763 Section "-gtk+" SEC_gtk_
764   SetOutPath "$INSTDIR\bin"
765   File bin/libgdk_pixbuf-2.0-0.dll
766   File bin/libgdk-win32-2.0-0.dll
767   File bin/libgtk-win32-2.0-0.dll
768
769   SetOutPath "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0"
770   File /oname=loaders.cache ${W32_SRCDIR}/gdk-pixbuf-loaders.cache
771   SetOutPath "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders"
772   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-ani.dll
773   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-gdip-bmp.dll
774   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-gdip-emf.dll
775   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-gdip-gif.dll
776   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-gdip-ico.dll
777   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-gdip-jpeg.dll
778   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-gdip-tiff.dll
779   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-gdip-wmf.dll
780   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-icns.dll
781   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-pcx.dll
782   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-png.dll
783   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-pnm.dll
784   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-qtif.dll
785   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-ras.dll
786   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-tga.dll
787   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-wbmp.dll
788   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-xbm.dll
789   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-xpm.dll
790
791   SetOutPath "$INSTDIR\lib\gtk-2.0\2.10.0\engines"
792   File lib/gtk-2.0/2.10.0/engines/libwimp.dll
793   File lib/gtk-2.0/2.10.0/engines/libpixmap.dll
794
795   SetOutPath "$INSTDIR\lib\gtk-2.0\2.10.0\immodules"
796   File lib/gtk-2.0/2.10.0/immodules/im-thai.dll
797   File lib/gtk-2.0/2.10.0/immodules/im-cyrillic-translit.dll
798   File lib/gtk-2.0/2.10.0/immodules/im-multipress.dll
799   File lib/gtk-2.0/2.10.0/immodules/im-ti-er.dll
800   File lib/gtk-2.0/2.10.0/immodules/im-am-et.dll
801   File lib/gtk-2.0/2.10.0/immodules/im-cedilla.dll
802   File lib/gtk-2.0/2.10.0/immodules/im-inuktitut.dll
803   File lib/gtk-2.0/2.10.0/immodules/im-viqr.dll
804   File lib/gtk-2.0/2.10.0/immodules/im-ti-et.dll
805   File lib/gtk-2.0/2.10.0/immodules/im-ipa.dll
806   File lib/gtk-2.0/2.10.0/immodules/im-ime.dll
807
808   SetOutPath "$INSTDIR\share\themes\Default\gtk-2.0-key"
809   File share/themes/Default/gtk-2.0-key/gtkrc
810
811   SetOutPath "$INSTDIR\share\themes\MS-Windows\gtk-2.0"
812   File share/themes/MS-Windows/gtk-2.0/gtkrc
813
814   SetOutPath "$INSTDIR\etc\gtk-2.0"
815   File etc/gtk-2.0/im-multipress.conf
816 SectionEnd
817 !endif
818
819 Section "-pinentry" SEC_pinentry
820   SetOutPath "$INSTDIR\bin"
821   File /oname=pinentry-basic.exe "bin/pinentry-w32.exe"
822 SectionEnd
823
824 !ifdef WITH_GUI
825 Section "gpa" SEC_gpa
826   SectionIn RO
827   SetOutPath "$INSTDIR\bin"
828   File bin/gpa.exe
829   File bin/launch-gpa.exe
830 SectionEnd
831
832 LangString DESC_SEC_gpa ${LANG_ENGLISH} \
833    "The GnuPG Assistant is the graphical interface of GnuPG"
834 LangString DESC_SEC_gpa ${LANG_GERMAN} \
835    "Der GnuPG Assistent ist die graphische Oberfläche von GnuPG."
836
837 LangString DESC_Menu_gpa ${LANG_ENGLISH} \
838    "Run the GnuGP Assistant."
839 LangString DESC_Menu_gpa ${LANG_GERMAN} \
840    "Den GnuPG Assistenten starten."
841
842 Section "gpgex" SEC_gpgex
843   SetOutPath "$INSTDIR\bin"
844
845   ClearErrors
846   SetOverwrite try
847   File bin/gpgex.dll
848   SetOverwrite lastused
849   ifErrors 0 do_reg
850       File /oname=gpgex.dll.tmp bin/gpgex.dll
851       Rename /REBOOTOK gpgex.dll.tmp gpgex.dll
852
853  do_reg:
854   ClearErrors
855   RegDLL "$INSTDIR\bin\gpgex.dll"
856   ifErrors 0 +2
857      MessageBox MB_OK "$(T_GPGEX_RegFailed)"
858
859 ${If} ${RunningX64}
860   # Install the 64 bit version of the plugin.
861   # Note that we install this in addition to the 32 bit version so that
862   # the 32 bit version can be used by file dialogs of 32 bit programs.
863   ClearErrors
864   SetOverwrite try
865   File /oname=gpgex6.dll "${INST6_DIR}/bin/gpgex.dll"
866   SetOverwrite lastused
867   ifErrors 0 do_reg64
868       File /oname=gpgex6.dll.tmp "${INST6_DIR}/bin/gpgex.dll"
869       Rename /REBOOTOK gpgex6.dll.tmp gpgex6.dll
870
871  do_reg64:
872   # Register the DLL. We need to register both versions.  However
873   # RegDLL can't be used for 64 bit and InstallLib seems to be a
874   # registry hack.
875   ClearErrors
876   ExecWait '"$SYSDIR\regsvr32" /s "$INSTDIR\bin\gpgex6.dll"'
877   ifErrors 0 +2
878      MessageBox MB_OK "$(T_GPGEX_RegFailed) (64 bit)"
879
880   # Note: There is no need to install the help an mo files because
881   # they are identical to those installed by the 32 bit version.
882 ${EndIf}
883 SectionEnd
884
885 LangString T_GPGEX_RegFailed ${LANG_ENGLISH} \
886    "Warning: Registration of the Explorer plugin failed."
887
888 LangString DESC_SEC_gpgex ${LANG_ENGLISH} \
889    "GnuPG Explorer Extension"
890
891 !endif
892
893
894 Section "-gnupglast" SEC_gnupglast
895   SetOutPath "$INSTDIR"
896 SectionEnd
897
898
899 #
900 # Define the uninstaller sections.
901 #
902 # (reverse order of the installer sections!)
903 #
904
905 Section "-un.gnupglast"
906   ifFileExists "$INSTDIR\bin\launch-gpa.exe"  0 no_uiserver
907     ExecWait '"$INSTDIR\bin\launch-gpa" --stop-server'
908   no_uiserver:
909   ifFileExists "$INSTDIR\bin\gpgconf.exe"  0 no_gpgconf
910     ExecWait '"$INSTDIR\bin\gpgconf" --kill gpg-agent'
911   no_gpgconf:
912 SectionEnd
913
914 Section "-un.gpgex"
915   UnRegDLL "$INSTDIR\bin\gpgex.dll"
916
917   Delete /REBOOTOK "$INSTDIR\bin\gpgex.dll"
918
919 ${If} ${RunningX64}
920   ExecWait '"$SYSDIR\regsvr32" /u /s "$INSTDIR\bin\gpgex6.dll"'
921   Delete /REBOOTOK "$INSTDIR\bin\gpgex6.dll"
922 ${EndIf}
923 SectionEnd
924
925 !ifdef WITH_GUI
926 Section "-un.gpa"
927   Delete "$INSTDIR\bin\gpa.exe"
928   Delete "$INSTDIR\bin\launch-gpa.exe"
929
930   RMDir "$INSTDIR\share\gpa"
931 SectionEnd
932 !endif
933
934 Section "-un.pinentry"
935   Delete "$INSTDIR\bin\pinentry-basic.exe"
936 SectionEnd
937
938 !ifdef WITH_GUI
939 Section "-un.gtk+"
940   Delete "$INSTDIR\bin\libgdk_pixbuf-2.0-0.dll"
941   Delete "$INSTDIR\bin\libgdk-win32-2.0-0.dll"
942   Delete "$INSTDIR\bin\libgtk-win32-2.0-0.dll"
943
944   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders.cache"
945
946   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-ani.dll"
947   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-gdip-bmp.dll"
948   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-gdip-emf.dll"
949   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-gdip-gif.dll"
950   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-gdip-ico.dll"
951   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-gdip-jpeg.dll"
952   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-gdip-tiff.dll"
953   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-gdip-wmf.dll"
954   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-icns.dll"
955   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-pcx.dll"
956   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-png.dll"
957   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-pnm.dll"
958   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-qtif.dll"
959   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-ras.dll"
960   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-tga.dll"
961   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-wbmp.dll"
962   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-xbm.dll"
963   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-xpm.dll"
964   RMDir  "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders"
965   RMDir  "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0"
966   RMDir  "$INSTDIR\lib\gdk-pixbuf-2.0"
967
968   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\engines\libwimp.dll"
969   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\engines\libpixmap.dll"
970   RMDir  "$INSTDIR\lib\gtk-2.0\2.10.0\engines"
971
972   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-thai.dll"
973   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-cyrillic-translit.dll"
974   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-multipress.dll"
975   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-ti-er.dll"
976   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-am-et.dll"
977   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-cedilla.dll"
978   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-inuktitut.dll"
979   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-viqr.dll"
980   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-ti-et.dll"
981   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-ipa.dll"
982   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-ime.dll"
983   RMDir  "$INSTDIR\lib\gtk-2.0\2.10.0\immodules"
984
985   RMDir  "$INSTDIR\lib\gtk-2.0\2.10.0"
986   RMDir  "$INSTDIR\lib\gtk-2.0"
987
988   Delete "$INSTDIR\share\themes\Default\gtk-2.0-key\gtkrc"
989   RMDir  "$INSTDIR\share\themes\Default\gtk-2.0-key"
990   RMDir  "$INSTDIR\share\themes\Default"
991
992   Delete "$INSTDIR\share\themes\MS-Windows\gtk-2.0\gtkrc"
993   RMDir  "$INSTDIR\share\themes\MS-Windows\gtk-2.0"
994   RMDir  "$INSTDIR\share\themes\MS-Windows"
995
996   RMDir  "$INSTDIR\share\themes"
997
998   Delete "$INSTDIR\etc\gtk-2.0\im-multipress.conf"
999   RMDir  "$INSTDIR\etc\gtk-2.0"
1000 SectionEnd
1001
1002 Section "-un.atk"
1003   Delete "$INSTDIR\bin\libatk-1.0-0.dll"
1004 SectionEnd
1005
1006 Section "-un.pango"
1007   Delete "$INSTDIR\bin\pango-querymodules.exe"
1008   Delete "$INSTDIR\bin\libpango-1.0-0.dll"
1009   Delete "$INSTDIR\bin\libpangowin32-1.0-0.dll"
1010
1011   Delete "$INSTDIR\lib\pango\1.6.0\modules\pango-basic-win32.dll"
1012   Delete "$INSTDIR\lib\pango\1.6.0\modules\pango-arabic-lang.dll"
1013   Delete "$INSTDIR\lib\pango\1.6.0\modules\pango-indic-lang.dll"
1014   RMDir  "$INSTDIR\lib\pango\1.6.0\modules"
1015   RMDir  "$INSTDIR\lib\pango\1.6.0"
1016   RMDir  "$INSTDIR\lib\pango"
1017
1018   Delete "$INSTDIR\etc\pango\pango.modules"
1019   RMDir  "$INSTDIR\etc\pango"
1020 SectionEnd
1021
1022 Section "-un.pixman"
1023   Delete "$INSTDIR\bin\libpixman-1-0.dll"
1024 SectionEnd
1025
1026 Section "-un.cairo"
1027   Delete "$INSTDIR\bin\libcairo-gobject-2.dll"
1028   Delete "$INSTDIR\bin\libpangocairo-1.0-0.dll"
1029   Delete "$INSTDIR\bin\libcairo-2.dll"
1030   Delete "$INSTDIR\bin\libcairo-script-interpreter-2.dll"
1031 SectionEnd
1032
1033 Section "-un.libpng"
1034   Delete "$INSTDIR\bin\libpng14-14.dll"
1035 SectionEnd
1036
1037 Section "-un.glib"
1038   Delete "$INSTDIR\bin\libgio-2.0-0.dll"
1039   Delete "$INSTDIR\bin\libglib-2.0-0.dll"
1040   Delete "$INSTDIR\bin\libgmodule-2.0-0.dll"
1041   Delete "$INSTDIR\bin\libgobject-2.0-0.dll"
1042   Delete "$INSTDIR\bin\libgthread-2.0-0.dll"
1043   Delete "$INSTDIR\bin\gspawn-win32-helper.exe"
1044   Delete "$INSTDIR\bin\gspawn-win32-helper-console.exe"
1045   Delete "$INSTDIR\bin\libffi-6.dll"
1046 SectionEnd
1047 !endif
1048
1049
1050 Section "-un.gettext"
1051   Delete "$INSTDIR\bin\libintl-8.dll"
1052 SectionEnd
1053
1054 Section "-un.gpgme"
1055   Delete "$INSTDIR\bin\libgpgme-11.dll"
1056   Delete "$INSTDIR\bin\libgpgme-glib-11.dll"
1057   Delete "$INSTDIR\bin\gpgme-w32spawn.exe"
1058   Delete "$INSTDIR\lib\libgpgme.imp"
1059   Delete "$INSTDIR\lib\libgpgme-glib.imp"
1060   Delete "$INSTDIR\include\gpgme.h"
1061 SectionEnd
1062
1063 Section "-un.ksba"
1064   Delete "$INSTDIR\bin\libksba-8.dll"
1065   Delete "$INSTDIR\lib\libksba.imp"
1066   Delete "$INSTDIR\include\ksba.h"
1067 SectionEnd
1068
1069 Section "-un.assuan"
1070   Delete "$INSTDIR\bin\libassuan-0.dll"
1071   Delete "$INSTDIR\lib\libassuan.imp"
1072   Delete "$INSTDIR\include\assuan.h"
1073 SectionEnd
1074
1075 Section "-un.gcrypt"
1076   Delete "$INSTDIR\bin\libgcrypt-20.dll"
1077   Delete "$INSTDIR\lib\libgcrypt.imp"
1078   Delete "$INSTDIR\include\gcrypt.h"
1079 SectionEnd
1080
1081 Section "-un.npth"
1082   Delete "$INSTDIR\bin\libnpth-0.dll"
1083   Delete "$INSTDIR\lib\libnpth.imp"
1084   Delete "$INSTDIR\include\npth.h"
1085 SectionEnd
1086
1087 Section "-un.adns"
1088   Delete "$INSTDIR\bin\libadns-1.dll"
1089   Delete "$INSTDIR\lib\libadns.imp"
1090   Delete "$INSTDIR\include\adns.h"
1091 SectionEnd
1092
1093 Section "-un.zlib"
1094   Delete "$INSTDIR\bin\zlib1.dll"
1095 SectionEnd
1096
1097 Section "-un.libiconv"
1098   Delete "$INSTDIR\bin\libiconv-2.dll"
1099 SectionEnd
1100
1101 Section "-un.libgpg-error"
1102   Delete "$INSTDIR\bin\libgpg-error-0.dll"
1103   Delete "$INSTDIR\lib\libgpg-error.imp"
1104   Delete "$INSTDIR\include\gpg-error.h"
1105 SectionEnd
1106
1107 Section "-un.gnupg"
1108   Delete "$INSTDIR\bin\gpg.exe"
1109   Delete "$INSTDIR\bin\gpgv.exe"
1110   Delete "$INSTDIR\bin\gpgsm.exe"
1111   Delete "$INSTDIR\bin\gpg-agent.exe"
1112   Delete "$INSTDIR\bin\scdaemon.exe"
1113   Delete "$INSTDIR\bin\dirmngr.exe"
1114   Delete "$INSTDIR\bin\gpgconf.exe"
1115   Delete "$INSTDIR\bin\gpg-connect-agent.exe"
1116   Delete "$INSTDIR\bin\gpgtar.exe"
1117
1118   Delete "$INSTDIR\share\gnupg\gpg-conf.skel"
1119   RMDir  "$INSTDIR\share\gnupg"
1120 SectionEnd
1121
1122 Section "-un.gnupginst"
1123   # Delete standard stuff.
1124   Delete "$INSTDIR\README.txt"
1125
1126   Delete "$INSTDIR\VERSION"
1127
1128   # Remove the bin directory from the PATH
1129   Push "$INSTDIR\bin"
1130   Call un.RemoveFromPath
1131
1132   # Try to remove the top level directories.
1133   RMDir "$INSTDIR\bin"
1134   RMDir "$INSTDIR\lib"
1135   RMDir "$INSTDIR\include"
1136   RMDir "$INSTDIR\share"
1137   RMDir "$INSTDIR\etc"
1138   RMDir "$INSTDIR"
1139
1140   # Clean the registry.
1141   DeleteRegValue HKLM "Software\GNU\GnuPG" "Install Directory"
1142 SectionEnd
1143
1144
1145 Function .onInit
1146   ;;!define MUI_LANGDLL_ALWAYSSHOW
1147   !insertmacro MUI_LANGDLL_DISPLAY
1148
1149   Call G4wRunOnce
1150
1151   SetOutPath $TEMP
1152 #!ifdef SOURCES
1153 #  File /oname=gpgspltmp.bmp "${TOP_SRCDIR}/doc/logo/gnupg-logo-400px.bmp"
1154 #  # We play the tune only for the soruce installer
1155 #  File /oname=gpgspltmp.wav "${TOP_SRCDIR}/src/gnupg-splash.wav"
1156 #  g4wihelp::playsound $TEMP\gpgspltmp.wav
1157 #  g4wihelp::showsplash 2500 $TEMP\gpgspltmp.bmp
1158
1159 #  Delete $TEMP\gpgspltmp.bmp
1160 #  # Note that we delete gpgspltmp.wav in .onInst{Failed,Success}
1161 #!endif
1162
1163   # We can't use TOP_SRCDIR dir as the name of the file needs to be
1164   # the same while building and running the installer.  Thus we
1165   # generate the file from a template.
1166   !insertmacro MUI_INSTALLOPTIONS_EXTRACT "${W32_SRCDIR}/inst-options.ini"
1167
1168   #Call CalcDepends
1169 FunctionEnd
1170
1171
1172 #Function .onInstFailed
1173 #  Delete $TEMP\gpgspltmp.wav
1174 #FunctionEnd
1175
1176 #Function .onInstSuccess
1177 #  Delete $TEMP\gpgspltmp.wav
1178 #FunctionEnd
1179
1180 #Function .onSelChange
1181 #  Call CalcDepends
1182 #FunctionEnd
1183
1184
1185 # This must be in a central place.  Urgs.
1186
1187 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
1188 !insertmacro MUI_DESCRIPTION_TEXT ${SEC_gnupg} $(DESC_SEC_gnupg)
1189 !insertmacro MUI_DESCRIPTION_TEXT ${SEC_gpa}   $(DESC_SEC_gpa)
1190 !insertmacro MUI_DESCRIPTION_TEXT ${SEC_gpgex} $(DESC_SEC_gpgex)
1191 !insertmacro MUI_FUNCTION_DESCRIPTION_END
1192
1193
1194 # This also must be in a central place.  Also Urgs.
1195
1196 !ifdef WITH_GUI
1197 Section "-startmenu"
1198
1199 !ifdef HAVE_STARTMENU
1200   # Make sure that the context of the automatic variables has been set to
1201   # the "all users" shell folder.  This guarantees that the menu gets written
1202   # for all users.  We have already checked that we are running as Admin; or
1203   # we printed a warning that installation will not succeed.
1204   SetShellVarContext all
1205
1206   # Check if the start menu entries where requested.
1207   !insertmacro MUI_INSTALLOPTIONS_READ $R0 "${W32_SRCDIR}/inst-options.ini" \
1208         "Field 2" "State"
1209   IntCmp $R0 0 no_start_menu
1210
1211 !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
1212     CreateDirectory "$SMPROGRAMS\$STARTMENU_FOLDER"
1213
1214     SectionGetFlags ${SEC_gpa} $R0
1215     IntOp $R0 $R0 & ${SF_SELECTED}
1216     IntCmp $R0 ${SF_SELECTED} 0 no_gpa_menu
1217     CreateShortCut "$SMPROGRAMS\$STARTMENU_FOLDER\GPA.lnk" \
1218         "$INSTDIR\bin\launch-gpa.exe" \
1219         "" "" "" SW_SHOWNORMAL "" $(DESC_Menu_gpa)
1220   no_gpa_menu:
1221
1222
1223     CreateShortCut "$SMPROGRAMS\$STARTMENU_FOLDER\GnuPG Manual.lnk" \
1224                    "$INSTDIR\share\gnupg\gnupg.html" \
1225                    "" "" "" SW_SHOWNORMAL "" $(DESC_Menu_gnupg_manual)
1226
1227     CreateShortCut "$SMPROGRAMS\$STARTMENU_FOLDER\GnuPG README.lnk" \
1228                    "$INSTDIR\README.txt" \
1229                    "" "" "" SW_SHOWNORMAL "" $(DESC_Menu_gnupg_readme)
1230
1231 !insertmacro MUI_STARTMENU_WRITE_END
1232
1233
1234
1235 no_start_menu:
1236
1237
1238   # Check if the desktop entries where requested.
1239   !insertmacro MUI_INSTALLOPTIONS_READ $R0 "${W32_SRCDIR}/inst-options.ini" \
1240         "Field 3" "State"
1241   IntCmp $R0 0 no_desktop
1242
1243     SectionGetFlags ${SEC_gpa} $R0
1244     IntOp $R0 $R0 & ${SF_SELECTED}
1245     IntCmp $R0 ${SF_SELECTED} 0 no_gpa_desktop
1246     CreateShortCut "$DESKTOP\GPA.lnk" \
1247         "$INSTDIR\bin\launch-gpa.exe" \
1248         "" "" "" SW_SHOWNORMAL "" $(DESC_Menu_gpa)
1249   no_gpa_desktop:
1250
1251
1252     CreateShortCut "$DESKTOP\GPA Manual.lnk" \
1253                    "$INSTDIR\share\gpa\gpa.html" \
1254                    "" "" "" SW_SHOWNORMAL "" $(DESC_Menu_gpa_manual)
1255
1256 no_desktop:
1257
1258
1259   # Check if the quick launch bar entries where requested.
1260   !insertmacro MUI_INSTALLOPTIONS_READ $R0 "${W32_SRCDIR}/inst-options.ini" \
1261         "Field 4" "State"
1262   IntCmp $R0 0 no_quick_launch
1263   StrCmp $QUICKLAUNCH $TEMP no_quick_launch
1264
1265     SectionGetFlags ${SEC_gpa} $R0
1266     IntOp $R0 $R0 & ${SF_SELECTED}
1267     IntCmp $R0 ${SF_SELECTED} 0 no_gpa_quicklaunch
1268     CreateShortCut "$QUICKLAUNCH\GPA.lnk" \
1269         "$INSTDIR\bin\launch-gpa.exe" \
1270         "" "" "" SW_SHOWNORMAL "" $(DESC_Menu_gpa)
1271 no_gpa_quicklaunch:
1272
1273
1274 no_quick_launch:
1275
1276
1277 !endif
1278 SectionEnd
1279 !endif
1280
1281
1282 #
1283 # Now for the generic parts to end the installation.
1284 #
1285 Var MYTMP
1286
1287 # Last section is a hidden one.
1288 Section
1289   WriteUninstaller "$INSTDIR\gnupg-uninstall.exe"
1290
1291   # Windows Add/Remove Programs support
1292   StrCpy $MYTMP "Software\Microsoft\Windows\CurrentVersion\Uninstall\GnuPG"
1293   WriteRegExpandStr HKLM $MYTMP "UninstallString" '"$INSTDIR\gnupg-uninstall.exe"'
1294   WriteRegExpandStr HKLM $MYTMP "InstallLocation" "$INSTDIR"
1295   WriteRegStr       HKLM $MYTMP "DisplayName"     "${PRETTY_PACKAGE}"
1296 !ifdef WITH_GUI
1297   WriteRegStr       HKLM $MYTMP "DisplayIcon"     "$INSTDIR\bin\gpa.exe,0"
1298 !endif
1299   WriteRegStr       HKLM $MYTMP "DisplayVersion"  "${VERSION}"
1300   WriteRegStr       HKLM $MYTMP "Publisher"       "The GnuPG Project"
1301   WriteRegStr       HKLM $MYTMP "URLInfoAbout"    "https://gnupg.org"
1302   WriteRegDWORD     HKLM $MYTMP "NoModify"        "1"
1303   WriteRegDWORD     HKLM $MYTMP "NoRepair"        "1"
1304 SectionEnd
1305
1306
1307 Section Uninstall
1308
1309 !ifdef WITH_GUI
1310 !ifdef HAVE_STARTMENU
1311   # Make sure that the context of the automatic variables has been set to
1312   # the "all users" shell folder.  This guarantees that the menu gets written
1313   # for all users.  We have already checked that we are running as Admin; or
1314   # we printed a warning that installation will not succeed.
1315   SetShellVarContext all
1316
1317   #---------------------------------------------------
1318   # Delete the menu entries and any empty parent menus
1319   #---------------------------------------------------
1320   !insertmacro MUI_STARTMENU_GETFOLDER Application $MYTMP
1321   Delete "$SMPROGRAMS\$MYTMP\GPA.lnk"
1322   Delete "$SMPROGRAMS\$MYTMP\GnuPG Manual.lnk"
1323   Delete "$SMPROGRAMS\$MYTMP\GnuPG README.lnk"
1324   Delete "$SMPROGRAMS\$MYTMP\*.lnk"
1325   StrCpy $MYTMP "$SMPROGRAMS\$MYTMP"
1326   startMenuDeleteLoop:
1327     ClearErrors
1328     RMDir $MYTMP
1329     GetFullPathName $MYTMP "$MYTMP\.."
1330     IfErrors startMenuDeleteLoopDone
1331     StrCmp $MYTMP $SMPROGRAMS startMenuDeleteLoopDone startMenuDeleteLoop
1332   startMenuDeleteLoopDone:
1333
1334   DeleteRegValue HKLM "Software\GNU\GnuPG" "Start Menu Folder"
1335
1336   # Delete Desktop links.
1337   Delete "$DESKTOP\GPA.lnk"
1338   Delete "$DESKTOP\GnuPG Manual.lnk"
1339   Delete "$DESKTOP\GnuPG README.lnk"
1340
1341   # Delete Quick Launch Bar links.
1342   StrCmp $QUICKLAUNCH $TEMP no_quick_launch_uninstall
1343   Delete "$QUICKLAUNCH\GPA.lnk"
1344 no_quick_launch_uninstall:
1345
1346 !endif
1347 !endif
1348
1349   Delete "$INSTDIR\gnupg-uninstall.exe"
1350   RMDir "$INSTDIR"
1351
1352   # Clean the registry.
1353   DeleteRegValue HKLM "Software\GnuPG" "Install Directory"
1354   DeleteRegKey /ifempty HKLM "Software\GnuPG"
1355   # Remove Windows Add/Remove Programs support.
1356   DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\GnuPG"
1357 SectionEnd