w32: Change default Windows install dir and add bin to PATH.
[gnupg.git] / build-aux / speedo / w32 / inst.nsi
1 # inst.nsi - Installer for GnuPG on Windows.      -*- coding: latin-1; -*-
2 # Copyright (C) 2005, 2014 g10 Code GmbH
3 #
4 # This file is part of GnuPG.
5 #
6 # GnuPG is free software; you can redistribute it and/or modify
7 # it under the terms of the GNU General Public License as published by
8 # the Free Software Foundation; either version 3 of the License, or
9 # (at your option) any later version.
10 #
11 # GnuPG is distributed in the hope that it will be useful,
12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 # GNU General Public License for more details.
15 #
16 # You should have received a copy of the GNU General Public License
17 # along with this program; if not, see <http://www.gnu.org/licenses/>.
18
19 # Macros to provide for invocation:
20 #  INST_DIR
21 #  INST6_DIR
22 #  BUILD_DIR
23 #  TOP_SRCDIR
24 #  W32_SRCDIR
25 #  BUILD_ISODATE   - the build date, e.g. "2014-10-31"
26 #  BUILD_DATESTR   - ditto w/o '-',  e.g. "20141031"
27 #  NAME
28 #  VERSION
29 #  PROD_VERSION
30 #
31 #  WITH_GUI        - Include the GPA GUI
32
33 !cd "${INST_DIR}"
34 !addincludedir "${W32_SRCDIR}"
35 !addplugindir "${BUILD_DIR}"
36
37 # The package name and version.  PRETTY_PACKAGE is a user visible name
38 # only while PACKAGE is useful for filenames etc.  PROD_VERSION is the
39 # product version and needs to be in the format "MAJ.MIN.MIC.BUILDNR".
40 !define PACKAGE "gnupg"
41 !define PACKAGE_SHORT "gnupg"
42 !define PRETTY_PACKAGE "GNU Privacy Guard"
43 !define PRETTY_PACKAGE_SHORT "GnuPG"
44 !define COMPANY "The GnuPG Project"
45 !define COPYRIGHT "Copyright (C) 2015 The GnuPG Project"
46 !define DESCRIPTION "GnuPG: The GNU Privacy Guard for Windows"
47
48 !define INSTALL_DIR "GnuPG"
49
50 !define WELCOME_TITLE_ENGLISH \
51  "Welcome to the installation of GnuPG"
52
53 !define WELCOME_TITLE_GERMAN \
54  "Willkommen bei der Installation von GnuPG"
55
56 !define ABOUT_ENGLISH \
57  "GnuPG is the mostly used software for mail and data encryption. \
58   GnuPG can be used to encrypt data and to create digital signatures. \
59   GnuPG includes an advanced key management facility and is compliant \
60   with the OpenPGP Internet standard as described in RFC-4880. \
61   \r\n\r\n$_CLICK \
62   \r\n\r\n\r\n\r\n\r\nThis is GnuPG version ${VERSION}.\r\n\
63   File version: ${PROD_VERSION}\r\n\
64   Release date: ${BUILD_ISODATE}"
65 !define ABOUT_GERMAN \
66  "GnuPG is die häufigst verwendete Software zur Mail- und Datenverschlüsselung.\
67    \r\n\r\n$_CLICK \
68    \r\n\r\n\r\n\r\n\r\nDies ist GnuPG Version ${VERSION}.\r\n\
69    Dateiversion: ${PROD_VERSION}\r\n\
70    Releasedatum: ${BUILD_ISODATE}"
71
72
73 # The copyright license of the package.  Define only one of these.
74 !define LICENSE_GPL
75
76 # Select the best compression algorithm available.  The dictionary
77 # size is the default (8 MB).
78 !ifndef SOURCES
79 SetCompressor lzma
80 # SetCompressorDictSize 8
81 !endif
82
83 # Include the generic parts.
84 !define HAVE_STARTMENU
85
86 # We use the modern UI.
87 !include "MUI.nsh"
88
89 # Some helper some
90 !include "LogicLib.nsh"
91 !include "x64.nsh"
92
93 # Set the package name.  Note that this name should not be suffixed
94 # with the version because this would get displayed in the start menu.
95 # Given that a slash in the name troubles Windows startmenu creation
96 # we set the Startmenu explicit below.
97 Name "${PRETTY_PACKAGE}"
98
99 # Set the output filename.
100 OutFile "${NAME}-${VERSION}_${BUILD_DATESTR}.exe"
101
102 #Fixme: Do we need a logo?
103 #Icon "${TOP_SRCDIR}/doc/logo/gnupg-logo-icon.ico"
104 #UninstallIcon "${TOP_SRCDIR}/doc/logo/gnupg-logo-icon.ico"
105
106 # Set the installation directory.
107 !ifndef INSTALL_DIR
108 !define INSTALL_DIR "GnuPG"
109 !endif
110 InstallDir "$PROGRAMFILES\${INSTALL_DIR}"
111
112 InstallDirRegKey HKLM "Software\${PACKAGE_SHORT}" "Install Directory"
113
114
115 # Add version information to the file properties.
116 VIProductVersion "${PROD_VERSION}"
117 VIAddVersionKey "ProductName" "${PRETTY_PACKAGE_SHORT} (${VERSION})"
118 VIAddVersionKey "Comments" \
119    "GnuPG is Free Software; you can redistribute it  \
120     and/or modify it under the terms of the GNU General Public License.  \
121     You should have received a copy of the GNU General Public License  \
122     along with this software; if not, write to the Free Software  \
123     Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,  \
124     MA 02110-1301, USA"
125 VIAddVersionKey "CompanyName" "${COMPANY}"
126 VIAddVersionKey "LegalTrademarks" ""
127 VIAddVersionKey "LegalCopyright" "${COPYRIGHT}"
128 VIAddVersionKey "FileDescription" "${DESCRIPTION}"
129 VIAddVersionKey "FileVersion" "${PROD_VERSION}"
130
131 # Interface Settings
132
133 # !define MUI_ABORTWARNING
134 !define MUI_FINISHPAGE_NOAUTOCLOSE
135 !define MUI_UNFINISHPAGE_NOAUTOCLOSE
136
137 !define MUI_HEADERIMAGE
138 !define MUI_HEADERIMAGE_BITMAP "${W32_SRCDIR}\gnupg-logo-150x57.bmp"
139 !define MUI_WELCOMEFINISHPAGE_BITMAP "${W32_SRCDIR}\gnupg-logo-164x314.bmp"
140
141 # Remember the installer language
142 !define MUI_LANGDLL_REGISTRY_ROOT "HKCU"
143 !define MUI_LANGDLL_REGISTRY_KEY "Software\GnuPG"
144 !define MUI_LANGDLL_REGISTRY_VALUENAME "Installer Language"
145
146 #
147 # The list of wizard pages.
148 #
149 !define MUI_WELCOMEPAGE_TITLE "$(T_WelcomeTitle)"
150 !define MUI_WELCOMEPAGE_TEXT  "$(T_About)"
151 !insertmacro MUI_PAGE_WELCOME
152
153 !define MUI_LICENSEPAGE_BUTTON "$(^NextBtn)"
154 !define MUI_PAGE_HEADER_SUBTEXT "$(T_GPLHeader)"
155 !define MUI_LICENSEPAGE_TEXT_BOTTOM "$(T_GPLShort)"
156 !insertmacro MUI_PAGE_LICENSE "${TOP_SRCDIR}/COPYING"
157
158 !define MUI_PAGE_CUSTOMFUNCTION_SHOW PrintNonAdminWarning
159 !insertmacro MUI_PAGE_COMPONENTS
160
161 !define MUI_PAGE_CUSTOMFUNCTION_LEAVE CheckExistingVersion
162 !insertmacro MUI_PAGE_DIRECTORY
163
164 !ifdef HAVE_STARTMENU
165
166 Page custom CustomPageOptions
167
168 Var STARTMENU_FOLDER
169
170 !define MUI_PAGE_CUSTOMFUNCTION_PRE CheckIfStartMenuWanted
171 !define MUI_STARTMENUPAGE_NODISABLE
172 !define MUI_STARTMENUPAGE_REGISTRY_ROOT "HKCU"
173 !define MUI_STARTMENUPAGE_REGISTRY_KEY "Software\GnuPG"
174 !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "Start Menu Folder"
175 # We need to set the Startmenu name explicitly because a slash in the
176 # name is not possible.
177 !define MUI_STARTMENUPAGE_DEFAULTFOLDER "GnuPG"
178
179 !insertmacro MUI_PAGE_STARTMENU Application $STARTMENU_FOLDER
180
181 !endif
182
183 !define MUI_PAGE_CUSTOMFUNCTION_PRE PrintCloseOtherApps
184 !insertmacro MUI_PAGE_INSTFILES
185
186 #!define MUI_PAGE_CUSTOMFUNCTION_PRE ShowFinalWarnings
187 !define MUI_FINISHPAGE_SHOWREADME "README.txt"
188 !define MUI_FINISHPAGE_SHOWREADME_TEXT "$(T_ShowReadme)"
189 #!define MUI_FINISHPAGE_RUN
190 #!define MUI_FINISHPAGE_RUN_FUNCTION RunOnFinish
191 #!define MUI_FINISHPAGE_RUN_TEXT "$(T_RunKeyManager)"
192 #!define MUI_FINISHPAGE_RUN_NOTCHECKED
193 !define MUI_FINISHPAGE_LINK "$(T_MoreInfo)"
194 !define MUI_FINISHPAGE_LINK_LOCATION "$(T_MoreInfoURL)"
195 !insertmacro MUI_PAGE_FINISH
196
197
198 # Uninstaller pages.
199
200 !insertmacro MUI_UNPAGE_CONFIRM
201 !insertmacro MUI_UNPAGE_INSTFILES
202
203
204 #Page license
205 #Page components
206 #Page directory
207 #Page instfiles
208 #UninstPage uninstConfirm
209 #UninstPage instfiles
210
211
212 # Language support.  This has to be done after defining the pages, but
213 # before defining the translation strings.  Confusing.
214
215 !insertmacro MUI_LANGUAGE "English"
216 !insertmacro MUI_LANGUAGE "German"
217
218 !insertmacro MUI_RESERVEFILE_LANGDLL
219 !insertmacro MUI_RESERVEFILE_INSTALLOPTIONS
220 ReserveFile "${BUILD_DIR}\g4wihelp.dll"
221 ReserveFile "${W32_SRCDIR}\gnupg-logo-150x57.bmp"
222 ReserveFile "${W32_SRCDIR}\gnupg-logo-164x314.bmp"
223 ReserveFile "${TOP_SRCDIR}\COPYING"
224 ReserveFile "${W32_SRCDIR}\inst-options.ini"
225
226 # Language support
227
228 LangString T_LangCode ${LANG_ENGLISH} "en"
229 LangString T_LangCode ${LANG_GERMAN}  "de"
230
231
232 # The WelcomeTitle is displayed on the first page.
233 LangString T_WelcomeTitle ${LANG_ENGLISH} "${WELCOME_TITLE_ENGLISH}"
234 LangString T_WelcomeTitle ${LANG_GERMAN} "${WELCOME_TITLE_GERMAN}"
235
236 # The About string as displayed on the first page.
237 LangString T_About ${LANG_ENGLISH} "${ABOUT_ENGLISH}"
238 LangString T_About ${LANG_GERMAN} "${ABOUT_GERMAN}"
239
240 # Startup page
241 LangString T_GPLHeader ${LANG_ENGLISH} \
242   "This software is licensed under the terms of the GNU General Public \
243    License (GNU GPL)."
244 LangString T_GPLHeader ${LANG_GERMAN}} \
245   "Diese Software ist unter der GNU General Public License \
246    (GNU GPL) lizensiert."
247
248 LangString T_GPLShort ${LANG_ENGLISH} \
249   "In short: You are allowed to run this software for any purpose. \
250    You may distribute it as long as you give the recipients the same \
251    rights you have received."
252 LangString T_GPLShort ${LANG_GERMAN} \
253   "In aller Kürze: Sie haben das Recht, die Software zu jedem Zweck \
254    einzusetzen.  Sie können die Software weitergeben, sofern Sie dem \
255    Empfänger dieselben Rechte einräumen, die auch Sie erhalten haben."
256
257 LangString T_RunKeyManager ${LANG_ENGLISH} \
258    "Run the key manager"
259 LangString T_RunKeyManager ${LANG_GERMAN} \
260    "Die Schlüsselverwaltung aufrufen"
261
262 LangString T_MoreInfo ${LANG_ENGLISH} \
263    "Click here for GnuPG's website"
264 LangString T_MoreInfo ${LANG_GERMAN} \
265    "Hier klicken um zur GnuPG Homepage zu gelangen"
266 LangString T_MoreInfoURL ${LANG_ENGLISH} "https://gnupg.org"
267 LangString T_MoreInfoURL ${LANG_GERMAN}  "https://gnupg.org"
268
269 LangString T_ShowReadme ${LANG_ENGLISH} \
270    "Show the README file"
271 LangString T_ShowReadme ${LANG_GERMAN} \
272    "Die README Datei anzeigen"
273
274 LangString T_NoKeyManager ${LANG_ENGLISH} \
275    "No key manager has been installed, thus we can't run one now."
276 LangString T_NoKeyManager ${LANG_GERMAN} \
277    "Es wurde keine Schlüsselverwaltung installiert. \
278     Deswegen kann sie jetzt auch nicht ausgeführt werden."
279
280 # Functions
281
282 # Custom functions and macros for this installer.
283 LangString T_AlreadyRunning ${LANG_ENGLISH} \
284    "An instance of this installer is already running."
285 LangString T_AlreadyRunning ${LANG_GERMAN} \
286    "Ein Exemplar dieses Installers läuft bereits."
287
288 Function G4wRunOnce
289   Push $R0
290   StrCpy $R0 "gnupg"
291   g4wihelp::runonce
292   StrCmp $R0 0 +3
293      MessageBox MB_OK $(T_AlreadyRunning)
294      Abort
295   Pop $R0
296 FunctionEnd
297
298 #
299 # Control function for the Custom page to select special
300 # install options.
301 #
302 Function CustomPageOptions
303   !insertmacro MUI_HEADER_TEXT "$(T_InstallOptions)" "$(T_InstallOptLinks)"
304
305   # Note, that the default selection is done in the ini file
306   !insertmacro MUI_INSTALLOPTIONS_WRITE "${W32_SRCDIR}/inst-options.ini" \
307         "Field 1" "Text"  "$(T_InstOptLabelA)"
308   !insertmacro MUI_INSTALLOPTIONS_WRITE "${W32_SRCDIR}/inst-options.ini" \
309         "Field 2" "Text"  "$(T_InstOptFieldA)"
310   !insertmacro MUI_INSTALLOPTIONS_WRITE "${W32_SRCDIR}/inst-options.ini" \
311         "Field 3" "Text"  "$(T_InstOptFieldB)"
312   !insertmacro MUI_INSTALLOPTIONS_WRITE "${W32_SRCDIR}/inst-options.ini" \
313         "Field 4" "Text"  "$(T_InstOptFieldC)"
314   !insertmacro MUI_INSTALLOPTIONS_WRITE "${W32_SRCDIR}/inst-options.ini" \
315         "Field 5" "Text"  "$(T_InstOptLabelB)"
316
317   !insertmacro MUI_INSTALLOPTIONS_DISPLAY "${W32_SRCDIR}/inst-options.ini"
318 FunctionEnd
319
320
321 # Check whether GnuPG has already been installed.  This is called as
322 # a leave function from the directory page.  A call to abort will get
323 # back to the directory selection.
324 Function CheckExistingVersion
325   ClearErrors
326   FileOpen $0 "$INSTDIR\VERSION" r
327   IfErrors nexttest
328   FileRead $0 $R0
329   FileRead $0 $R1
330   FileClose $0
331
332   Push $R1
333   Call TrimNewLines
334   Pop $R1
335
336   MessageBox MB_YESNO "$(T_FoundExistingVersion)" IDYES leave
337   Abort
338
339  nexttest:
340   ClearErrors
341   ReadRegStr $0 HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\GnuPG" "DisplayVersion"
342   IfErrors leave 0
343      MessageBox MB_YESNO "$(T_FoundExistingVersionB)" IDYES leave
344      Abort
345
346  leave:
347 FunctionEnd
348
349
350
351 # PrintNonAdminWarning
352
353 # Check whether the current user is in the Administrator group or an
354 # OS version without the need for an Administrator is in use.  Print a
355 # diagnostic if this is not the case and abort installation.
356 Function PrintNonAdminWarning
357   ClearErrors
358   UserInfo::GetName
359   IfErrors leave
360   Pop $0
361   UserInfo::GetAccountType
362   Pop $1
363   StrCmp $1 "Admin" leave +1
364   MessageBox MB_OK "$(T_AdminNeeded)"
365   Quit
366
367  leave:
368 FunctionEnd
369
370
371 # Check whether the start menu is actually wanted.
372
373 Function CheckIfStartMenuWanted
374   !insertmacro MUI_INSTALLOPTIONS_READ $R0 "${W32_SRCDIR}/inst-options.ini" \
375         "Field 2" "State"
376   IntCmp $R0 1 +2
377     Abort
378 FunctionEnd
379
380
381 # Check whether this is a reinstall and popup a message box to explain
382 # that it is better to close other apps before continuing
383 Function PrintCloseOtherApps
384     IfFileExists $INSTDIR\bin\gpg.exe print_warning
385     IfFileExists $INSTDIR\bin\gpa.exe print_warning
386     Return
387    print_warning:
388     MessageBox MB_OK|MB_ICONEXCLAMATION "$(T_CloseOtherApps)"
389
390 FunctionEnd
391
392 # Called right before the final page to show more warnings.
393 #Function ShowFinalWarnings
394 #   leave:
395 #FunctionEnd
396
397 #-----------------------------------------------
398 # Strings pertaining to the install options page
399 #-----------------------------------------------
400
401 # Installation options title
402 LangString T_InstallOptions ${LANG_ENGLISH} "Install Options"
403 LangString T_InstallOptions ${LANG_GERMAN}  "Installationsoptionen"
404
405 # Installation options subtitle 1
406 LangString T_InstallOptLinks ${LANG_ENGLISH} "Start links"
407 LangString T_InstallOptLinks ${LANG_GERMAN}  "Startlinks"
408
409 LangString T_InstOptLabelA  ${LANG_ENGLISH} \
410      "Please select where GnuPG shall install links:"
411 LangString T_InstOptLabelA  ${LANG_GERMAN} \
412      "Bitte wählen Sie, welche Verknüpfungen angelegt werden sollen:"
413
414 LangString T_InstOptLabelB  ${LANG_ENGLISH} \
415      "(Only programs will be linked into the quick launch bar.)"
416 LangString T_InstOptLabelB  ${LANG_GERMAN} \
417      "(In die Schnellstartleiste werden nur Verknüpfungen für \
418       Programme angelegt.) "
419
420 LangString T_InstOptFieldA  ${LANG_ENGLISH} \
421      "Start Menu"
422 LangString T_InstOptFieldA  ${LANG_GERMAN} \
423      "Startmenü"
424
425 LangString T_InstOptFieldB  ${LANG_ENGLISH} \
426      "Desktop"
427 LangString T_InstOptFieldB  ${LANG_GERMAN} \
428      "Arbeitsfläche"
429
430 LangString T_InstOptFieldC  ${LANG_ENGLISH} \
431      "Quick Launch Bar"
432 LangString T_InstOptFieldC  ${LANG_GERMAN} \
433      "Schnellstartleiste"
434
435 #------------------------------------------------
436 # String pertaining to the existing version check
437 #------------------------------------------------
438 LangString T_FoundExistingVersion ${LANG_ENGLISH} \
439      "Version $R1 has already been installed.  $\r$\n\
440       Do you want to overwrite it with version ${VERSION}?"
441 LangString T_FoundExistingVersion ${LANG_GERMAN} \
442      "Version $R1 ist hier bereits installiert. $\r$\n\
443       Möchten Sie diese mit Version ${VERSION} überschreiben? $\r$\n\
444        $\r$\n\
445       (Sie können in jedem Fall mit JA antworten, falls es sich um \
446        eine neuere oder dieselbe Version handelt.)"
447 LangString T_FoundExistingVersionB ${LANG_ENGLISH} \
448      "A version of GnuPG has already been installed on the system. \
449       There will be no problem installing and thus overwriting this \
450       Version. $\r$\n\
451        $\r$\n\
452       Do you want to continue installing GnuPG?"
453 LangString T_FoundExistingVersionB ${LANG_GERMAN} \
454      "Eine Version von GnuPG ist hier bereits installiert. \
455       Es ist problemlos möglich, die Installation fortzuführen.  $\r$\n\
456         $\r$\n\
457       Möchten die die Installation von GnuPG fortführen?"
458
459
460
461 # From Function PrintNonAdminWarning
462 LangString T_AdminNeeded ${LANG_ENGLISH} \
463    "Warning: Administrator permissions required for a successful installation"
464 LangString T_AdminNeeded ${LANG_GERMAN} \
465    "Achtung: Für eine erfolgreiche Installation werden \
466     Administratorrechte benötigt."
467
468 # From Function PrintCloseOtherApps
469 LangString T_CloseOtherApps ${LANG_ENGLISH} \
470    "Please make sure that other applications are not running. \
471     GnuPG will try to install anyway but a reboot may be required."
472 LangString T_CloseOtherApps ${LANG_GERMAN} \
473    "Bitte stellen Sie sicher, daß alle anderen Anwendugen geschlossen \
474     sind.  GnuPG wird auf jeden Fall versuchen, eine Installation \
475     durchzuführen; es ist dann aber u.U. notwendig, das System neu zu starten."
476
477
478 # TrimNewlines  - taken from the NSIS reference
479 # input, top of stack  (e.g. whatever$\r$\n)
480 # output, top of stack (replaces, with e.g. whatever)
481 # modifies no other variables.
482 Function TrimNewlines
483    Exch $R0
484    Push $R1
485    Push $R2
486    StrCpy $R1 0
487
488  loop:
489    IntOp $R1 $R1 - 1
490    StrCpy $R2 $R0 1 $R1
491    StrCmp $R2 "$\r" loop
492    StrCmp $R2 "$\n" loop
493    IntOp $R1 $R1 + 1
494    IntCmp $R1 0 no_trim_needed
495    StrCpy $R0 $R0 $R1
496
497  no_trim_needed:
498    Pop $R2
499    Pop $R1
500    Exch $R0
501 FunctionEnd
502
503
504 # AddToPath - Adds the given dir to the search path.
505 #        Input - head of the stack
506 Function AddToPath
507   Exch $0
508   g4wihelp::path_add "$0"
509   StrCmp $R5 "0" add_to_path_done
510   SendMessage ${HWND_BROADCAST} ${WM_WININICHANGE} 0 "STR:Environment" /TIMEOUT=5000
511   add_to_path_done:
512   Pop $0
513 FunctionEnd
514
515
516 # RemoveFromPath - Remove a given dir from the path
517 #     Input: head of the stack
518 Function un.RemoveFromPath
519   Exch $0
520   g4wihelp::path_remove "$0"
521   StrCmp $R5 "0" remove_from_path_done
522   SendMessage ${HWND_BROADCAST} ${WM_WININICHANGE} 0 "STR:Environment" /TIMEOUT=5000
523   remove_from_path_done:
524   Pop $0
525 FunctionEnd
526
527
528 #
529 # Define the installer sections.
530 #
531
532 Section "-gnupginst"
533   SetOutPath "$INSTDIR"
534
535   File "${BUILD_DIR}/README.txt"
536
537   # Write a version file.
538   FileOpen $0 "$INSTDIR\VERSION" w
539   FileWrite $0 "${PACKAGE}$\r$\n"
540   FileWrite $0 "${VERSION}$\r$\n"
541   FileClose $0
542
543   WriteRegStr HKLM "Software\GnuPG" "Install Directory" $INSTDIR
544
545   # If we are reinstalling, try to kill a possible running gpa using
546   # an already installed gpa.
547   ifFileExists "$INSTDIR\bin\launch-gpa.exe"  0 no_uiserver
548     ExecWait '"$INSTDIR\bin\launch-gpa" --stop-server'
549
550   no_uiserver:
551
552   # If we are reinstalling, try to kill a possible running agent using
553   # an already installed gpgconf.
554   ifFileExists "$INSTDIR\bin\gpgconf.exe"  0 no_gpgconf
555     ExecWait '"$INSTDIR\bin\gpgconf" --kill dirmngr'
556     ExecWait '"$INSTDIR\bin\gpgconf" --kill gpg-agent'
557
558   no_gpgconf:
559
560   # Add the bin directory to the PATH
561   Push "$INSTDIR\bin"
562   Call AddToPath
563   DetailPrint "Added $INSTDIR\bin to PATH"
564 SectionEnd
565
566 LangString DESC_Menu_gnupg_readme ${LANG_ENGLISH} \
567    "General information on GnuPG"
568 LangString DESC_Menu_gnupg_readme ${LANG_GERMAN} \
569    "Allgemeine Informationen zu GnuPG"
570
571
572 Section "GnuPG" SEC_gnupg
573   SectionIn RO
574
575   SetOutPath "$INSTDIR\bin"
576   File /oname=gpg.exe "bin/gpg2.exe"
577   File /oname=gpgv.exe "bin/gpgv2.exe"
578   File "bin/gpgsm.exe"
579   File "bin/gpgconf.exe"
580   File "bin/gpg-connect-agent.exe"
581   File "bin/gpgtar.exe"
582
583   ClearErrors
584   SetOverwrite try
585   File "bin/gpg-agent.exe"
586   SetOverwrite lastused
587   ifErrors 0 +3
588       File /oname=gpg-agent.exe.tmp "bin/gpg-agent.exe"
589       Rename /REBOOTOK gpg-agent.exe.tmp gpg-agent.exe
590
591   ClearErrors
592   SetOverwrite try
593   File "bin/dirmngr.exe"
594   SetOverwrite lastused
595   ifErrors 0 +3
596       File /oname=dirmngr.exe.tmp "bin/dirmngr.exe"
597       Rename /REBOOTOK dirmngr.exe.tmp dirmngr.exe
598
599   ClearErrors
600   SetOverwrite try
601   File "libexec/scdaemon.exe"
602   SetOverwrite lastused
603   ifErrors 0 +3
604       File /oname=scdaemon.exe.tmp "libexec/scdaemon.exe"
605       Rename /REBOOTOK scdaemon.exe.tmp scdaemon.exe
606
607   SetOutPath "$INSTDIR\share\gnupg"
608   File "share/gnupg/gpg-conf.skel"
609 SectionEnd
610
611
612 LangString DESC_SEC_gnupg ${LANG_ENGLISH} \
613    "The GnuPG Core is the actual encrypt core and a set of command \
614     line utilities."
615 LangString DESC_SEC_gnupg ${LANG_GERMAN} \
616    "Der GnuPG Core ist, wie der Name schon sagt, der Kernbestandteil \
617     dieser Software.  Der GnuPG Core stellt die eigentliche \
618     Verschlüsselung sowie die Verwaltung der Schlüssel bereit."
619
620 LangString DESC_Menu_gnupg_manual ${LANG_ENGLISH} \
621    "Show the manual for the GnuPG Core"
622 LangString DESC_Menu_gnupg_manual ${LANG_GERMAN} \
623    "Das Handbuch zum GnuPG Kern anzeigen"
624
625 Section "-libgpg-error" SEC_libgpg_error
626   SetOutPath "$INSTDIR\bin"
627   File bin/libgpg-error-0.dll
628   SetOutPath "$INSTDIR\lib"
629   File /oname=libgpg-error.imp lib/libgpg-error.dll.a
630   SetOutPath "$INSTDIR\include"
631   File include/gpg-error.h
632 SectionEnd
633
634 Section "-libiconv" SEC_libiconv
635   SetOutPath "$INSTDIR\bin"
636   File bin/libiconv-2.dll
637 SectionEnd
638
639 Section "-zlib" SEC_zlib
640   SetOutPath "$INSTDIR\bin"
641   File bin/zlib1.dll
642 SectionEnd
643
644 Section "-adns" SEC_adns
645   SetOutPath "$INSTDIR\bin"
646   File bin/libadns-1.dll
647   SetOutPath "$INSTDIR\lib"
648   File /oname=libadns.imp lib/libadns.dll.a
649   SetOutPath "$INSTDIR\include"
650   File include/adns.h
651 SectionEnd
652
653 Section "-npth" SEC_npth
654   SetOutPath "$INSTDIR\bin"
655   File bin/libnpth-0.dll
656   SetOutPath "$INSTDIR\lib"
657   File /oname=libnpth.imp lib/libnpth.dll.a
658   SetOutPath "$INSTDIR\include"
659   File include/npth.h
660 SectionEnd
661
662 Section "-gcrypt" SEC_gcrypt
663   SetOutPath "$INSTDIR\bin"
664   File bin/libgcrypt-20.dll
665   SetOutPath "$INSTDIR\lib"
666   File /oname=libgcrypt.imp lib/libgcrypt.dll.a
667   SetOutPath "$INSTDIR\include"
668   File include/gcrypt.h
669 SectionEnd
670
671 Section "-assuan" SEC_assuan
672   SetOutPath "$INSTDIR\bin"
673   File bin/libassuan-0.dll
674   SetOutPath "$INSTDIR\lib"
675   File /oname=libassuan.imp lib/libassuan.dll.a
676   SetOutPath "$INSTDIR\include"
677   File include/assuan.h
678 SectionEnd
679
680 Section "-ksba" SEC_ksba
681   SetOutPath "$INSTDIR\bin"
682   File bin/libksba-8.dll
683   SetOutPath "$INSTDIR\lib"
684   File /oname=libksba.imp lib/libksba.dll.a
685   SetOutPath "$INSTDIR\include"
686   File include/ksba.h
687 SectionEnd
688
689 Section "-gpgme" SEC_gpgme
690   SetOutPath "$INSTDIR\bin"
691   File bin/libgpgme-11.dll
692   File /nonfatal bin/libgpgme-glib-11.dll
693   File libexec/gpgme-w32spawn.exe
694   SetOutPath "$INSTDIR\lib"
695   File /oname=libgpgme.imp      lib/libgpgme.dll.a
696   File /nonfatal /oname=libgpgme-glib.imp lib/libgpgme-glib.dll.a
697   SetOutPath "$INSTDIR\include"
698   File include/gpgme.h
699 SectionEnd
700
701 !ifdef WITH_GUI
702 Section "-gettext" SEC_gettext
703   SetOutPath "$INSTDIR\bin"
704   File bin/libintl-8.dll
705 SectionEnd
706
707 Section "-glib" SEC_glib
708   SetOutPath "$INSTDIR\bin"
709   File bin/libgio-2.0-0.dll
710   File bin/libglib-2.0-0.dll
711   File bin/libgmodule-2.0-0.dll
712   File bin/libgobject-2.0-0.dll
713   File bin/libgthread-2.0-0.dll
714   File bin/gspawn-win32-helper.exe
715   File bin/gspawn-win32-helper-console.exe
716
717   File bin/libffi-6.dll
718 SectionEnd
719
720 Section "-libpng" SEC_libpng
721   SetOutPath "$INSTDIR\bin"
722   File bin/libpng14-14.dll
723 SectionEnd
724
725 #Section "-jpeg" SEC_jpeg
726 #  SetOutPath "$INSTDIR"
727 #  File bin/jpeg62.dll
728 #SectionEnd
729
730 Section "-cairo" SEC_cairo
731   SetOutPath "$INSTDIR\bin"
732   File bin/libcairo-gobject-2.dll
733   File bin/libpangocairo-1.0-0.dll
734   File bin/libcairo-2.dll
735   File bin/libcairo-script-interpreter-2.dll
736 SectionEnd
737
738 Section "-pixman" SEC_pixman
739   SetOutPath "$INSTDIR\bin"
740   File bin/libpixman-1-0.dll
741 SectionEnd
742
743 Section "-pango" SEC_pango
744   SetOutPath "$INSTDIR\bin"
745   File bin/pango-querymodules.exe
746   File bin/libpango-1.0-0.dll
747   File bin/libpangowin32-1.0-0.dll
748
749   SetOutPath "$INSTDIR\lib\pango\1.6.0\modules"
750   File lib/pango/1.6.0/modules/pango-basic-win32.dll
751   File lib/pango/1.6.0/modules/pango-arabic-lang.dll
752   File lib/pango/1.6.0/modules/pango-indic-lang.dll
753
754   SetOutPath "$INSTDIR\etc\pango"
755   File ${W32_SRCDIR}/pango.modules
756 SectionEnd
757
758 Section "-atk" SEC_atk
759   SetOutPath "$INSTDIR\bin"
760   File bin/libatk-1.0-0.dll
761 SectionEnd
762
763 Section "-gtk+" SEC_gtk_
764   SetOutPath "$INSTDIR\bin"
765   File bin/libgdk_pixbuf-2.0-0.dll
766   File bin/libgdk-win32-2.0-0.dll
767   File bin/libgtk-win32-2.0-0.dll
768
769   SetOutPath "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0"
770   File /oname=loaders.cache ${W32_SRCDIR}/gdk-pixbuf-loaders.cache
771   SetOutPath "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders"
772   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-ani.dll
773   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-gdip-bmp.dll
774   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-gdip-emf.dll
775   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-gdip-gif.dll
776   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-gdip-ico.dll
777   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-gdip-jpeg.dll
778   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-gdip-tiff.dll
779   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-gdip-wmf.dll
780   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-icns.dll
781   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-pcx.dll
782   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-png.dll
783   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-pnm.dll
784   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-qtif.dll
785   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-ras.dll
786   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-tga.dll
787   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-wbmp.dll
788   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-xbm.dll
789   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-xpm.dll
790
791   SetOutPath "$INSTDIR\lib\gtk-2.0\2.10.0\engines"
792   File lib/gtk-2.0/2.10.0/engines/libwimp.dll
793   File lib/gtk-2.0/2.10.0/engines/libpixmap.dll
794
795   SetOutPath "$INSTDIR\lib\gtk-2.0\2.10.0\immodules"
796   File lib/gtk-2.0/2.10.0/immodules/im-thai.dll
797   File lib/gtk-2.0/2.10.0/immodules/im-cyrillic-translit.dll
798   File lib/gtk-2.0/2.10.0/immodules/im-multipress.dll
799   File lib/gtk-2.0/2.10.0/immodules/im-ti-er.dll
800   File lib/gtk-2.0/2.10.0/immodules/im-am-et.dll
801   File lib/gtk-2.0/2.10.0/immodules/im-cedilla.dll
802   File lib/gtk-2.0/2.10.0/immodules/im-inuktitut.dll
803   File lib/gtk-2.0/2.10.0/immodules/im-viqr.dll
804   File lib/gtk-2.0/2.10.0/immodules/im-ti-et.dll
805   File lib/gtk-2.0/2.10.0/immodules/im-ipa.dll
806   File lib/gtk-2.0/2.10.0/immodules/im-ime.dll
807
808   SetOutPath "$INSTDIR\share\themes\Default\gtk-2.0-key"
809   File share/themes/Default/gtk-2.0-key/gtkrc
810
811   SetOutPath "$INSTDIR\share\themes\MS-Windows\gtk-2.0"
812   File share/themes/MS-Windows/gtk-2.0/gtkrc
813
814   SetOutPath "$INSTDIR\etc\gtk-2.0"
815   File etc/gtk-2.0/im-multipress.conf
816 SectionEnd
817 !endif
818
819 !ifdef WITH_GUI
820 Section "-pinentry" SEC_pinentry
821   SetOutPath "$INSTDIR\bin"
822   File /oname=pinentry.exe "bin/pinentry-gtk-2.exe"
823 SectionEnd
824 !endif
825
826 !ifdef WITH_GUI
827 Section "gpa" SEC_gpa
828   SectionIn RO
829   SetOutPath "$INSTDIR\bin"
830   File bin/gpa.exe
831   File bin/launch-gpa.exe
832 SectionEnd
833
834 LangString DESC_SEC_gpa ${LANG_ENGLISH} \
835    "The GnuPG Assistant is the graphical interface of GnuPG"
836 LangString DESC_SEC_gpa ${LANG_GERMAN} \
837    "Der GnuPG Assistent ist die graphische Oberfläche von GnuPG."
838
839 LangString DESC_Menu_gpa ${LANG_ENGLISH} \
840    "Run the GnuGP Assistant."
841 LangString DESC_Menu_gpa ${LANG_GERMAN} \
842    "Den GnuPG Assistenten starten."
843
844 Section "gpgex" SEC_gpgex
845   SetOutPath "$INSTDIR\bin"
846
847   ClearErrors
848   SetOverwrite try
849   File bin/gpgex.dll
850   SetOverwrite lastused
851   ifErrors 0 do_reg
852       File /oname=gpgex.dll.tmp bin/gpgex.dll
853       Rename /REBOOTOK gpgex.dll.tmp gpgex.dll
854
855  do_reg:
856   ClearErrors
857   RegDLL "$INSTDIR\bin\gpgex.dll"
858   ifErrors 0 +2
859      MessageBox MB_OK "$(T_GPGEX_RegFailed)"
860
861 ${If} ${RunningX64}
862   # Install the 64 bit version of the plugin.
863   # Note that we install this in addition to the 32 bit version so that
864   # the 32 bit version can be used by file dialogs of 32 bit programs.
865   ClearErrors
866   SetOverwrite try
867   File /oname=gpgex6.dll "${INST6_DIR}/bin/gpgex.dll"
868   SetOverwrite lastused
869   ifErrors 0 do_reg64
870       File /oname=gpgex6.dll.tmp "${INST6_DIR}/bin/gpgex.dll"
871       Rename /REBOOTOK gpgex6.dll.tmp gpgex6.dll
872
873  do_reg64:
874   # Register the DLL. We need to register both versions.  However
875   # RegDLL can't be used for 64 bit and InstallLib seems to be a
876   # registry hack.
877   ClearErrors
878   ExecWait '"$SYSDIR\regsvr32" /s "$INSTDIR\bin\gpgex6.dll"'
879   ifErrors 0 +2
880      MessageBox MB_OK "$(T_GPGEX_RegFailed) (64 bit)"
881
882   # Note: There is no need to install the help an mo files because
883   # they are identical to those installed by the 32 bit version.
884 ${EndIf}
885 SectionEnd
886
887 LangString T_GPGEX_RegFailed ${LANG_ENGLISH} \
888    "Warning: Registration of the Explorer plugin failed."
889
890 LangString DESC_SEC_gpgex ${LANG_ENGLISH} \
891    "GnuPG Explorer Extension"
892
893 !endif
894
895
896 Section "-gnupglast" SEC_gnupglast
897   SetOutPath "$INSTDIR"
898 SectionEnd
899
900
901 #
902 # Define the uninstaller sections.
903 #
904 # (reverse order of the installer sections!)
905 #
906
907 Section "-un.gnupglast"
908   ifFileExists "$INSTDIR\bin\launch-gpa.exe"  0 no_uiserver
909     ExecWait '"$INSTDIR\bin\launch-gpa" --stop-server'
910   no_uiserver:
911   ifFileExists "$INSTDIR\bin\gpgconf.exe"  0 no_gpgconf
912     ExecWait '"$INSTDIR\bin\gpgconf" --kill gpg-agent'
913   no_gpgconf:
914 SectionEnd
915
916 Section "-un.gpgex"
917   UnRegDLL "$INSTDIR\bin\gpgex.dll"
918
919   Delete /REBOOTOK "$INSTDIR\bin\gpgex.dll"
920
921 ${If} ${RunningX64}
922   ExecWait '"$SYSDIR\regsvr32" /u /s "$INSTDIR\bin\gpgex6.dll"'
923   Delete /REBOOTOK "$INSTDIR\bin\gpgex6.dll"
924 ${EndIf}
925 SectionEnd
926
927 !ifdef WITH_GUI
928 Section "-un.gpa"
929   Delete "$INSTDIR\bin\gpa.exe"
930   Delete "$INSTDIR\bin\launch-gpa.exe"
931
932   RMDir "$INSTDIR\share\gpa"
933 SectionEnd
934 !endif
935
936 !ifdef WITH_GUI
937 Section "-un.pinentry"
938   Delete "$INSTDIR\bin\pinentry.exe"
939 SectionEnd
940 !endif
941
942 !ifdef WITH_GUI
943 Section "-un.gtk+"
944   Delete "$INSTDIR\bin\libgdk_pixbuf-2.0-0.dll"
945   Delete "$INSTDIR\bin\libgdk-win32-2.0-0.dll"
946   Delete "$INSTDIR\bin\libgtk-win32-2.0-0.dll"
947
948   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders.cache"
949
950   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-ani.dll"
951   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-gdip-bmp.dll"
952   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-gdip-emf.dll"
953   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-gdip-gif.dll"
954   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-gdip-ico.dll"
955   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-gdip-jpeg.dll"
956   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-gdip-tiff.dll"
957   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-gdip-wmf.dll"
958   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-icns.dll"
959   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-pcx.dll"
960   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-png.dll"
961   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-pnm.dll"
962   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-qtif.dll"
963   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-ras.dll"
964   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-tga.dll"
965   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-wbmp.dll"
966   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-xbm.dll"
967   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-xpm.dll"
968   RMDir  "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders"
969   RMDir  "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0"
970   RMDir  "$INSTDIR\lib\gdk-pixbuf-2.0"
971
972   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\engines\libwimp.dll"
973   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\engines\libpixmap.dll"
974   RMDir  "$INSTDIR\lib\gtk-2.0\2.10.0\engines"
975
976   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-thai.dll"
977   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-cyrillic-translit.dll"
978   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-multipress.dll"
979   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-ti-er.dll"
980   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-am-et.dll"
981   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-cedilla.dll"
982   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-inuktitut.dll"
983   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-viqr.dll"
984   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-ti-et.dll"
985   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-ipa.dll"
986   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-ime.dll"
987   RMDir  "$INSTDIR\lib\gtk-2.0\2.10.0\immodules"
988
989   RMDir  "$INSTDIR\lib\gtk-2.0\2.10.0"
990   RMDir  "$INSTDIR\lib\gtk-2.0"
991
992   Delete "$INSTDIR\share\themes\Default\gtk-2.0-key\gtkrc"
993   RMDir  "$INSTDIR\share\themes\Default\gtk-2.0-key"
994   RMDir  "$INSTDIR\share\themes\Default"
995
996   Delete "$INSTDIR\share\themes\MS-Windows\gtk-2.0\gtkrc"
997   RMDir  "$INSTDIR\share\themes\MS-Windows\gtk-2.0"
998   RMDir  "$INSTDIR\share\themes\MS-Windows"
999
1000   RMDir  "$INSTDIR\share\themes"
1001
1002   Delete "$INSTDIR\etc\gtk-2.0\im-multipress.conf"
1003   RMDir  "$INSTDIR\etc\gtk-2.0"
1004 SectionEnd
1005
1006 Section "-un.atk"
1007   Delete "$INSTDIR\bin\libatk-1.0-0.dll"
1008 SectionEnd
1009
1010 Section "-un.pango"
1011   Delete "$INSTDIR\bin\pango-querymodules.exe"
1012   Delete "$INSTDIR\bin\libpango-1.0-0.dll"
1013   Delete "$INSTDIR\bin\libpangowin32-1.0-0.dll"
1014
1015   Delete "$INSTDIR\lib\pango\1.6.0\modules\pango-basic-win32.dll"
1016   Delete "$INSTDIR\lib\pango\1.6.0\modules\pango-arabic-lang.dll"
1017   Delete "$INSTDIR\lib\pango\1.6.0\modules\pango-indic-lang.dll"
1018   RMDir  "$INSTDIR\lib\pango\1.6.0\modules"
1019   RMDir  "$INSTDIR\lib\pango\1.6.0"
1020   RMDir  "$INSTDIR\lib\pango"
1021
1022   Delete "$INSTDIR\etc\pango\pango.modules"
1023   RMDir  "$INSTDIR\etc\pango"
1024 SectionEnd
1025
1026 Section "-un.pixman"
1027   Delete "$INSTDIR\bin\libpixman-1-0.dll"
1028 SectionEnd
1029
1030 Section "-un.cairo"
1031   Delete "$INSTDIR\bin\libcairo-gobject-2.dll"
1032   Delete "$INSTDIR\bin\libpangocairo-1.0-0.dll"
1033   Delete "$INSTDIR\bin\libcairo-2.dll"
1034   Delete "$INSTDIR\bin\libcairo-script-interpreter-2.dll"
1035 SectionEnd
1036
1037 Section "-un.libpng"
1038   Delete "$INSTDIR\bin\libpng14-14.dll"
1039 SectionEnd
1040
1041 Section "-un.glib"
1042   Delete "$INSTDIR\bin\libgio-2.0-0.dll"
1043   Delete "$INSTDIR\bin\libglib-2.0-0.dll"
1044   Delete "$INSTDIR\bin\libgmodule-2.0-0.dll"
1045   Delete "$INSTDIR\bin\libgobject-2.0-0.dll"
1046   Delete "$INSTDIR\bin\libgthread-2.0-0.dll"
1047   Delete "$INSTDIR\bin\gspawn-win32-helper.exe"
1048   Delete "$INSTDIR\bin\gspawn-win32-helper-console.exe"
1049   Delete "$INSTDIR\bin\libffi-6.dll"
1050 SectionEnd
1051 !endif
1052
1053
1054 Section "-un.gettext"
1055   Delete "$INSTDIR\bin\libintl-8.dll"
1056 SectionEnd
1057
1058 Section "-un.gpgme"
1059   Delete "$INSTDIR\bin\libgpgme-11.dll"
1060   Delete "$INSTDIR\bin\libgpgme-glib-11.dll"
1061   Delete "$INSTDIR\bin\gpgme-w32spawn.exe"
1062   Delete "$INSTDIR\lib\libgpgme.imp"
1063   Delete "$INSTDIR\lib\libgpgme-glib.imp"
1064   Delete "$INSTDIR\include\gpgme.h"
1065 SectionEnd
1066
1067 Section "-un.ksba"
1068   Delete "$INSTDIR\bin\libksba-8.dll"
1069   Delete "$INSTDIR\lib\libksba.imp"
1070   Delete "$INSTDIR\include\ksba.h"
1071 SectionEnd
1072
1073 Section "-un.assuan"
1074   Delete "$INSTDIR\bin\libassuan-0.dll"
1075   Delete "$INSTDIR\lib\libassuan.imp"
1076   Delete "$INSTDIR\include\assuan.h"
1077 SectionEnd
1078
1079 Section "-un.gcrypt"
1080   Delete "$INSTDIR\bin\libgcrypt-20.dll"
1081   Delete "$INSTDIR\lib\libgcrypt.imp"
1082   Delete "$INSTDIR\include\gcrypt.h"
1083 SectionEnd
1084
1085 Section "-un.npth"
1086   Delete "$INSTDIR\bin\libnpth-0.dll"
1087   Delete "$INSTDIR\lib\libnpth.imp"
1088   Delete "$INSTDIR\include\npth.h"
1089 SectionEnd
1090
1091 Section "-un.adns"
1092   Delete "$INSTDIR\bin\libadns-1.dll"
1093   Delete "$INSTDIR\lib\libadns.imp"
1094   Delete "$INSTDIR\include\adns.h"
1095 SectionEnd
1096
1097 Section "-un.zlib"
1098   Delete "$INSTDIR\bin\zlib1.dll"
1099 SectionEnd
1100
1101 Section "-un.libiconv"
1102   Delete "$INSTDIR\bin\libiconv-2.dll"
1103 SectionEnd
1104
1105 Section "-un.libgpg-error"
1106   Delete "$INSTDIR\bin\libgpg-error-0.dll"
1107   Delete "$INSTDIR\lib\libgpg-error.imp"
1108   Delete "$INSTDIR\include\gpg-error.h"
1109 SectionEnd
1110
1111 Section "-un.gnupg"
1112   Delete "$INSTDIR\bin\gpg.exe"
1113   Delete "$INSTDIR\bin\gpgv.exe"
1114   Delete "$INSTDIR\bin\gpgsm.exe"
1115   Delete "$INSTDIR\bin\gpg-agent.exe"
1116   Delete "$INSTDIR\bin\scdaemon.exe"
1117   Delete "$INSTDIR\bin\dirmngr.exe"
1118   Delete "$INSTDIR\bin\gpgconf.exe"
1119   Delete "$INSTDIR\bin\gpg-connect-agent.exe"
1120   Delete "$INSTDIR\bin\gpgtar.exe"
1121
1122   Delete "$INSTDIR\share\gnupg\gpg-conf.skel"
1123   RMDir  "$INSTDIR\share\gnupg"
1124 SectionEnd
1125
1126 Section "-un.gnupginst"
1127   # Delete standard stuff.
1128   Delete "$INSTDIR\README.txt"
1129
1130   Delete "$INSTDIR\VERSION"
1131
1132   # Remove the bin directory from the PATH
1133   Push "$INSTDIR\bin"
1134   Call un.RemoveFromPath
1135
1136   # Try to remove the top level directories.
1137   RMDir "$INSTDIR\bin"
1138   RMDir "$INSTDIR\lib"
1139   RMDir "$INSTDIR\include"
1140   RMDir "$INSTDIR\share"
1141   RMDir "$INSTDIR\etc"
1142   RMDir "$INSTDIR"
1143
1144   # Clean the registry.
1145   DeleteRegValue HKLM "Software\GNU\GnuPG" "Install Directory"
1146 SectionEnd
1147
1148
1149 Function .onInit
1150   ;;!define MUI_LANGDLL_ALWAYSSHOW
1151   !insertmacro MUI_LANGDLL_DISPLAY
1152
1153   Call G4wRunOnce
1154
1155   SetOutPath $TEMP
1156 #!ifdef SOURCES
1157 #  File /oname=gpgspltmp.bmp "${TOP_SRCDIR}/doc/logo/gnupg-logo-400px.bmp"
1158 #  # We play the tune only for the soruce installer
1159 #  File /oname=gpgspltmp.wav "${TOP_SRCDIR}/src/gnupg-splash.wav"
1160 #  g4wihelp::playsound $TEMP\gpgspltmp.wav
1161 #  g4wihelp::showsplash 2500 $TEMP\gpgspltmp.bmp
1162
1163 #  Delete $TEMP\gpgspltmp.bmp
1164 #  # Note that we delete gpgspltmp.wav in .onInst{Failed,Success}
1165 #!endif
1166
1167   # We can't use TOP_SRCDIR dir as the name of the file needs to be
1168   # the same while building and running the installer.  Thus we
1169   # generate the file from a template.
1170   !insertmacro MUI_INSTALLOPTIONS_EXTRACT "${W32_SRCDIR}/inst-options.ini"
1171
1172   #Call CalcDepends
1173 FunctionEnd
1174
1175
1176 #Function .onInstFailed
1177 #  Delete $TEMP\gpgspltmp.wav
1178 #FunctionEnd
1179
1180 #Function .onInstSuccess
1181 #  Delete $TEMP\gpgspltmp.wav
1182 #FunctionEnd
1183
1184 #Function .onSelChange
1185 #  Call CalcDepends
1186 #FunctionEnd
1187
1188
1189 # This must be in a central place.  Urgs.
1190
1191 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
1192 !insertmacro MUI_DESCRIPTION_TEXT ${SEC_gnupg} $(DESC_SEC_gnupg)
1193 !insertmacro MUI_DESCRIPTION_TEXT ${SEC_gpa}   $(DESC_SEC_gpa)
1194 !insertmacro MUI_DESCRIPTION_TEXT ${SEC_gpgex} $(DESC_SEC_gpgex)
1195 !insertmacro MUI_FUNCTION_DESCRIPTION_END
1196
1197
1198 # This also must be in a central place.  Also Urgs.
1199
1200 !ifdef WITH_GUI
1201 Section "-startmenu"
1202
1203 !ifdef HAVE_STARTMENU
1204   # Make sure that the context of the automatic variables has been set to
1205   # the "all users" shell folder.  This guarantees that the menu gets written
1206   # for all users.  We have already checked that we are running as Admin; or
1207   # we printed a warning that installation will not succeed.
1208   SetShellVarContext all
1209
1210   # Check if the start menu entries where requested.
1211   !insertmacro MUI_INSTALLOPTIONS_READ $R0 "${W32_SRCDIR}/inst-options.ini" \
1212         "Field 2" "State"
1213   IntCmp $R0 0 no_start_menu
1214
1215 !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
1216     CreateDirectory "$SMPROGRAMS\$STARTMENU_FOLDER"
1217
1218     SectionGetFlags ${SEC_gpa} $R0
1219     IntOp $R0 $R0 & ${SF_SELECTED}
1220     IntCmp $R0 ${SF_SELECTED} 0 no_gpa_menu
1221     CreateShortCut "$SMPROGRAMS\$STARTMENU_FOLDER\GPA.lnk" \
1222         "$INSTDIR\bin\launch-gpa.exe" \
1223         "" "" "" SW_SHOWNORMAL "" $(DESC_Menu_gpa)
1224   no_gpa_menu:
1225
1226
1227     CreateShortCut "$SMPROGRAMS\$STARTMENU_FOLDER\GnuPG Manual.lnk" \
1228                    "$INSTDIR\share\gnupg\gnupg.html" \
1229                    "" "" "" SW_SHOWNORMAL "" $(DESC_Menu_gnupg_manual)
1230
1231     CreateShortCut "$SMPROGRAMS\$STARTMENU_FOLDER\GnuPG README.lnk" \
1232                    "$INSTDIR\README.txt" \
1233                    "" "" "" SW_SHOWNORMAL "" $(DESC_Menu_gnupg_readme)
1234
1235 !insertmacro MUI_STARTMENU_WRITE_END
1236
1237
1238
1239 no_start_menu:
1240
1241
1242   # Check if the desktop entries where requested.
1243   !insertmacro MUI_INSTALLOPTIONS_READ $R0 "${W32_SRCDIR}/inst-options.ini" \
1244         "Field 3" "State"
1245   IntCmp $R0 0 no_desktop
1246
1247     SectionGetFlags ${SEC_gpa} $R0
1248     IntOp $R0 $R0 & ${SF_SELECTED}
1249     IntCmp $R0 ${SF_SELECTED} 0 no_gpa_desktop
1250     CreateShortCut "$DESKTOP\GPA.lnk" \
1251         "$INSTDIR\bin\launch-gpa.exe" \
1252         "" "" "" SW_SHOWNORMAL "" $(DESC_Menu_gpa)
1253   no_gpa_desktop:
1254
1255
1256     CreateShortCut "$DESKTOP\GPA Manual.lnk" \
1257                    "$INSTDIR\share\gpa\gpa.html" \
1258                    "" "" "" SW_SHOWNORMAL "" $(DESC_Menu_gpa_manual)
1259
1260 no_desktop:
1261
1262
1263   # Check if the quick launch bar entries where requested.
1264   !insertmacro MUI_INSTALLOPTIONS_READ $R0 "${W32_SRCDIR}/inst-options.ini" \
1265         "Field 4" "State"
1266   IntCmp $R0 0 no_quick_launch
1267   StrCmp $QUICKLAUNCH $TEMP no_quick_launch
1268
1269     SectionGetFlags ${SEC_gpa} $R0
1270     IntOp $R0 $R0 & ${SF_SELECTED}
1271     IntCmp $R0 ${SF_SELECTED} 0 no_gpa_quicklaunch
1272     CreateShortCut "$QUICKLAUNCH\GPA.lnk" \
1273         "$INSTDIR\bin\launch-gpa.exe" \
1274         "" "" "" SW_SHOWNORMAL "" $(DESC_Menu_gpa)
1275 no_gpa_quicklaunch:
1276
1277
1278 no_quick_launch:
1279
1280
1281 !endif
1282 SectionEnd
1283 !endif
1284
1285
1286 #
1287 # Now for the generic parts to end the installation.
1288 #
1289 Var MYTMP
1290
1291 # Last section is a hidden one.
1292 Section
1293   WriteUninstaller "$INSTDIR\gnupg-uninstall.exe"
1294
1295   # Windows Add/Remove Programs support
1296   StrCpy $MYTMP "Software\Microsoft\Windows\CurrentVersion\Uninstall\GnuPG"
1297   WriteRegExpandStr HKLM $MYTMP "UninstallString" '"$INSTDIR\gnupg-uninstall.exe"'
1298   WriteRegExpandStr HKLM $MYTMP "InstallLocation" "$INSTDIR"
1299   WriteRegStr       HKLM $MYTMP "DisplayName"     "${PRETTY_PACKAGE}"
1300 !ifdef WITH_GUI
1301   WriteRegStr       HKLM $MYTMP "DisplayIcon"     "$INSTDIR\bin\gpa.exe,0"
1302 !endif
1303   WriteRegStr       HKLM $MYTMP "DisplayVersion"  "${VERSION}"
1304   WriteRegStr       HKLM $MYTMP "Publisher"       "The GnuPG Project"
1305   WriteRegStr       HKLM $MYTMP "URLInfoAbout"    "https://gnupg.org"
1306   WriteRegDWORD     HKLM $MYTMP "NoModify"        "1"
1307   WriteRegDWORD     HKLM $MYTMP "NoRepair"        "1"
1308 SectionEnd
1309
1310
1311 Section Uninstall
1312
1313 !ifdef WITH_GUI
1314 !ifdef HAVE_STARTMENU
1315   # Make sure that the context of the automatic variables has been set to
1316   # the "all users" shell folder.  This guarantees that the menu gets written
1317   # for all users.  We have already checked that we are running as Admin; or
1318   # we printed a warning that installation will not succeed.
1319   SetShellVarContext all
1320
1321   #---------------------------------------------------
1322   # Delete the menu entries and any empty parent menus
1323   #---------------------------------------------------
1324   !insertmacro MUI_STARTMENU_GETFOLDER Application $MYTMP
1325   Delete "$SMPROGRAMS\$MYTMP\GPA.lnk"
1326   Delete "$SMPROGRAMS\$MYTMP\GnuPG Manual.lnk"
1327   Delete "$SMPROGRAMS\$MYTMP\GnuPG README.lnk"
1328   Delete "$SMPROGRAMS\$MYTMP\*.lnk"
1329   StrCpy $MYTMP "$SMPROGRAMS\$MYTMP"
1330   startMenuDeleteLoop:
1331     ClearErrors
1332     RMDir $MYTMP
1333     GetFullPathName $MYTMP "$MYTMP\.."
1334     IfErrors startMenuDeleteLoopDone
1335     StrCmp $MYTMP $SMPROGRAMS startMenuDeleteLoopDone startMenuDeleteLoop
1336   startMenuDeleteLoopDone:
1337
1338   DeleteRegValue HKLM "Software\GNU\GnuPG" "Start Menu Folder"
1339
1340   # Delete Desktop links.
1341   Delete "$DESKTOP\GPA.lnk"
1342   Delete "$DESKTOP\GnuPG Manual.lnk"
1343   Delete "$DESKTOP\GnuPG README.lnk"
1344
1345   # Delete Quick Launch Bar links.
1346   StrCmp $QUICKLAUNCH $TEMP no_quick_launch_uninstall
1347   Delete "$QUICKLAUNCH\GPA.lnk"
1348 no_quick_launch_uninstall:
1349
1350 !endif
1351 !endif
1352
1353   Delete "$INSTDIR\gnupg-uninstall.exe"
1354   RMDir "$INSTDIR"
1355
1356   # Clean the registry.
1357   DeleteRegValue HKLM "Software\GnuPG" "Install Directory"
1358   DeleteRegKey /ifempty HKLM "Software\GnuPG"
1359   # Remove Windows Add/Remove Programs support.
1360   DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\GnuPG"
1361 SectionEnd