01530e06cd28cc929a734e6571263daa588f1acd
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007,
3 #               2008, 2009, 2010, 2011, 2012 Free Software Foundation, Inc.
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.10"
23
24 # To build a release you need to create a tag with the version number
25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
26 # bump the version number immediately *after* the release and do
27 # another commit and push so that the git magic is able to work.
28 m4_define([mym4_version], [2.1.0])
29
30 # Below is m4 magic to extract and compute the git revision number,
31 # the decimalized short revision number, a beta version string and a
32 # flag indicating a development version (mym4_isgit).  Note that the
33 # m4 processing is done by autoconf and not during the configure run.
34 m4_define([mym4_revision],
35           m4_esyscmd([git rev-parse --short HEAD | tr -d '\n\r']))
36 m4_define([mym4_revision_dec],
37           m4_esyscmd_s([echo $((0x$(echo ]mym4_revision[|head -c 4)))]))
38 m4_define([mym4_betastring],
39           m4_esyscmd_s([git describe --match 'gnupg-2.[0-9].*[0-9]' --long|\
40                         awk -F- '$3!=0{print"-beta"$3}']))
41 m4_define([mym4_isgit],m4_if(mym4_betastring,[],[no],[yes]))
42 m4_define([mym4_full_version],[mym4_version[]mym4_betastring])
43
44 AC_INIT([gnupg],[mym4_full_version], [http://bugs.gnupg.org])
45
46 NEED_GPG_ERROR_VERSION=1.11
47
48 NEED_LIBGCRYPT_API=1
49 NEED_LIBGCRYPT_VERSION=1.5.0
50
51 NEED_LIBASSUAN_API=2
52 NEED_LIBASSUAN_VERSION=2.1.0
53
54 NEED_KSBA_API=1
55 NEED_KSBA_VERSION=1.2.0
56
57 NEED_NPTH_API=1
58 NEED_NPTH_VERSION=0.91
59
60
61 development_version=mym4_isgit
62 PACKAGE=$PACKAGE_NAME
63 PACKAGE_GT=${PACKAGE_NAME}2
64 VERSION=$PACKAGE_VERSION
65
66 AC_CONFIG_AUX_DIR([scripts])
67 AC_CONFIG_SRCDIR([sm/gpgsm.c])
68 AC_CONFIG_HEADER([config.h])
69 # Note: For automake 1.13 add the option
70 #          serial-tests
71 AM_INIT_AUTOMAKE([dist-bzip2 no-dist-gzip])
72 AC_CANONICAL_HOST
73 AB_INIT
74
75 AC_GNU_SOURCE
76
77 # Some status variables.
78 have_gpg_error=no
79 have_libgcrypt=no
80 have_libassuan=no
81 have_ksba=no
82 have_npth=no
83 have_libusb=no
84 have_adns=no
85
86 use_zip=yes
87 use_bzip2=yes
88 use_exec=yes
89 disable_keyserver_path=no
90 use_ccid_driver=yes
91 use_standard_socket=yes
92 dirmngr_auto_start=no
93
94 try_ks_ldap=no
95
96 GNUPG_BUILD_PROGRAM(gpg, yes)
97 GNUPG_BUILD_PROGRAM(gpgsm, yes)
98 GNUPG_BUILD_PROGRAM(agent, yes)
99 GNUPG_BUILD_PROGRAM(scdaemon, yes)
100 GNUPG_BUILD_PROGRAM(g13, yes)
101 GNUPG_BUILD_PROGRAM(dirmngr, yes)
102 GNUPG_BUILD_PROGRAM(tools, yes)
103 GNUPG_BUILD_PROGRAM(doc, yes)
104 GNUPG_BUILD_PROGRAM(symcryptrun, no)
105 GNUPG_BUILD_PROGRAM(gpgtar, no)
106
107 AC_SUBST(PACKAGE)
108 AC_SUBST(PACKAGE_GT)
109 AC_SUBST(VERSION)
110 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
111 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
112                                 [Name of this package for gettext])
113 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
114 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
115                                         [Bug report address])
116 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
117                                        [Required version of Libgcrypt])
118 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
119                                        [Required version of Libksba])
120
121
122
123 # The default is to use the modules from this package and the few
124 # other packages in a standard place; i.e where this package gets
125 # installed.  With these options it is possible to override these
126 # ${prefix} depended values with fixed paths, which can't be replaced
127 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
128 AC_ARG_WITH(agent-pgm,
129     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
130           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
131 AC_SUBST(GNUPG_AGENT_PGM)
132 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
133 show_gnupg_agent_pgm="(default)"
134 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
135
136 AC_ARG_WITH(pinentry-pgm,
137     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
138           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
139 AC_SUBST(GNUPG_PINENTRY_PGM)
140 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
141 show_gnupg_pinentry_pgm="(default)"
142 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
143
144
145 AC_ARG_WITH(scdaemon-pgm,
146     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
147           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
148 AC_SUBST(GNUPG_SCDAEMON_PGM)
149 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
150 show_gnupg_scdaemon_pgm="(default)"
151 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
152
153
154 AC_ARG_WITH(dirmngr-pgm,
155     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
156           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
157 AC_SUBST(GNUPG_DIRMNGR_PGM)
158 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
159 show_gnupg_dirmngr_pgm="(default)"
160 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
161
162 AC_ARG_WITH(protect-tool-pgm,
163     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
164           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
165 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
166 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
167 show_gnupg_protect_tool_pgm="(default)"
168 test -n "$GNUPG_PROTECT_TOOL_PGM" \
169       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
170
171 AC_ARG_WITH(dirmngr-ldap-pgm,
172     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmnge ldap wrapper)],
173           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
174 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
175 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
176 show_gnupg_dirmngr_ldap_pgm="(default)"
177 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
178       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
179
180 #
181 # On some platforms gpg2 is usually installed as gpg without using a
182 # symlink.  For correct operation of gpgconf it needs to know the
183 # installed name of gpg.  This option sets "gpg2"'s installed name to
184 # just "gpg".  Note that it might be required to rename gpg2 to gpg
185 # manually after the build process.
186 #
187 AC_ARG_ENABLE(gpg2-is-gpg,
188     AC_HELP_STRING([--enable-gpg2-is-gpg],[Set installed name of gpg2 to gpg]),
189     gpg2_is_gpg=$enableval)
190 if test "$gpg2_is_gpg" = "yes"; then
191    name_of_installed_gpg=gpg
192 else
193    name_of_installed_gpg=gpg2
194 fi
195 AC_DEFINE_UNQUOTED(NAME_OF_INSTALLED_GPG, "$name_of_installed_gpg",
196                    [The name of the installed GPG tool])
197
198
199 # Some folks want to use only the agent from this packet.  Make it
200 # easier for them by providing the configure option
201 # --enable-only-agent.
202 AC_ARG_ENABLE(agent-only,
203     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
204     build_agent_only=$enableval)
205
206 # SELinux support includes tracking of sensitive files to avoid
207 # leaking their contents through processing these files by gpg itself
208 AC_MSG_CHECKING([whether SELinux support is requested])
209 AC_ARG_ENABLE(selinux-support,
210               AC_HELP_STRING([--enable-selinux-support],
211                              [enable SELinux support]),
212               selinux_support=$enableval, selinux_support=no)
213 AC_MSG_RESULT($selinux_support)
214
215 # Allow disabling of zip support.
216 # This is in general not a good idea because according to rfc4880 OpenPGP
217 # implementations SHOULD support ZLIB.
218 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
219 AC_ARG_ENABLE(zip,
220    AC_HELP_STRING([--disable-zip],
221                   [disable the ZIP and ZLIB compression algorithm]),
222    use_zip=$enableval)
223 AC_MSG_RESULT($use_zip)
224
225 # Allow disabling of bzib2 support.
226 # It is defined only after we confirm the library is available later
227 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
228 AC_ARG_ENABLE(bzip2,
229    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
230    use_bzip2=$enableval)
231 AC_MSG_RESULT($use_bzip2)
232
233 # Configure option to allow or disallow execution of external
234 # programs, like a photo viewer.
235 AC_MSG_CHECKING([whether to enable external program execution])
236 AC_ARG_ENABLE(exec,
237     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
238     use_exec=$enableval)
239 AC_MSG_RESULT($use_exec)
240 if test "$use_exec" = no ; then
241     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
242 fi
243
244 if test "$use_exec" = yes ; then
245   AC_MSG_CHECKING([whether to enable photo ID viewing])
246   AC_ARG_ENABLE(photo-viewers,
247       [  --disable-photo-viewers disable photo ID viewers],
248       [if test "$enableval" = no ; then
249          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
250       fi],enableval=yes)
251   gnupg_cv_enable_photo_viewers=$enableval
252   AC_MSG_RESULT($enableval)
253
254   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
255     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
256     AC_ARG_WITH(photo-viewer,
257         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
258         [if test "$withval" = yes ; then
259            withval=no
260         elif test "$withval" != no ; then
261            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
262                             [if set, restrict photo-viewer to this])
263         fi],withval=no)
264     AC_MSG_RESULT($withval)
265   fi
266
267   AC_MSG_CHECKING([whether to enable external keyserver helpers])
268   AC_ARG_ENABLE(keyserver-helpers,
269       [  --disable-keyserver-helpers  disable all external keyserver support],
270       [if test "$enableval" = no ; then
271          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
272                   [define to disable keyserver helpers])
273       fi],enableval=yes)
274   gnupg_cv_enable_keyserver_helpers=$enableval
275   AC_MSG_RESULT($enableval)
276
277   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
278     # LDAP is defined only after we confirm the library is available later
279     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
280     AC_ARG_ENABLE(ldap,
281       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
282       try_ks_ldap=$enableval, try_ks_ldap=yes)
283     AC_MSG_RESULT($try_ks_ldap)
284
285     AC_MSG_CHECKING([whether HKP keyserver support is requested])
286     AC_ARG_ENABLE(hkp,
287       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
288       try_hkp=$enableval, try_hkp=yes)
289     AC_MSG_RESULT($try_hkp)
290
291     AC_MSG_CHECKING([whether finger key fetching support is requested])
292     AC_ARG_ENABLE(finger,
293       AC_HELP_STRING([--disable-finger],
294         [disable finger key fetching interface only]),
295       try_finger=$enableval, try_finger=yes)
296     AC_MSG_RESULT($try_finger)
297
298     AC_MSG_CHECKING([whether generic object key fetching support is requested])
299     AC_ARG_ENABLE(generic,
300       AC_HELP_STRING([--disable-generic],
301         [disable generic object key fetching interface only]),
302       try_generic=$enableval, try_generic=yes)
303     AC_MSG_RESULT($try_generic)
304
305     AC_MSG_CHECKING([whether email keyserver support is requested])
306     AC_ARG_ENABLE(mailto,
307       AC_HELP_STRING([--enable-mailto],
308         [enable email keyserver interface only]),
309       try_mailto=$enableval, try_mailto=no)
310     AC_MSG_RESULT($try_mailto)
311   fi
312
313   AC_MSG_CHECKING([whether keyserver exec-path is enabled])
314   AC_ARG_ENABLE(keyserver-path,
315       AC_HELP_STRING([--disable-keyserver-path],
316         [disable the exec-path option for keyserver helpers]),
317       [if test "$enableval" = no ; then
318          disable_keyserver_path=yes
319       fi],enableval=yes)
320   AC_MSG_RESULT($enableval)
321 fi
322
323
324 #
325 # Check for the key/uid cache size.  This can't be zero, but can be
326 # pretty small on embedded systems.  This is used for the gpg part.
327 #
328 AC_MSG_CHECKING([for the size of the key and uid cache])
329 AC_ARG_ENABLE(key-cache,
330         AC_HELP_STRING([--enable-key-cache=SIZE],
331                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
332 if test "$enableval" = "no"; then
333    enableval=5
334 elif test "$enableval" = "yes" || test "$enableval" = ""; then
335    enableval=4096
336 fi
337 changequote(,)dnl
338 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
339 changequote([,])dnl
340 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
341    AC_MSG_ERROR([invalid key-cache size])
342 fi
343 AC_MSG_RESULT($key_cache_size)
344 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
345                   [Size of the key and UID caches])
346
347
348
349 #
350 # Check whether we want to use Linux capabilities
351 #
352 AC_MSG_CHECKING([whether use of capabilities is requested])
353 AC_ARG_WITH(capabilities,
354     [  --with-capabilities     use linux capabilities [default=no]],
355 [use_capabilities="$withval"],[use_capabilities=no])
356 AC_MSG_RESULT($use_capabilities)
357
358
359 #
360 # Allow disabling of internal CCID support.
361 # It is defined only after we confirm the library is available later
362 #
363 AC_MSG_CHECKING([whether to enable the internal CCID driver])
364 AC_ARG_ENABLE(ccid-driver,
365               AC_HELP_STRING([--disable-ccid-driver],
366                              [disable the internal CCID driver]),
367               use_ccid_driver=$enableval)
368 AC_MSG_RESULT($use_ccid_driver)
369
370 #
371 # Dirmngr is nowadays a system service and thus it usually does no
372 # make sense to start it as needed.  However on some systems this is
373 # possible; this option enable the feature.
374 #
375 AC_MSG_CHECKING([whether to auto start dirmngr])
376 AC_ARG_ENABLE(dirmngr-auto-start,
377               AC_HELP_STRING([--enable-dirmngr-auto-start],
378                              [enable auto starting of the dirmngr]),
379               dirmngr_auto_start=$enableval)
380 AC_MSG_RESULT($dirmngr_auto_start)
381 if test "$dirmngr_auto_start" = yes ; then
382     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
383               [Define to enable auto starting of the dirmngr])
384 fi
385
386
387 #
388 # To avoid double inclusion of config.h which might happen at some
389 # places, we add the usual double inclusion protection at the top of
390 # config.h.
391 #
392 AH_TOP([
393 #ifndef GNUPG_CONFIG_H_INCLUDED
394 #define GNUPG_CONFIG_H_INCLUDED
395 ])
396
397 #
398 # Stuff which goes at the bottom of config.h.
399 #
400 AH_BOTTOM([
401 /* This is the major version number of GnuPG so that
402    source included files can test for this.  Note, that
403    we use 2 here even for GnuPG 1.9.x. */
404 #define GNUPG_MAJOR_VERSION 2
405
406 /* Now to separate file name parts.
407    Please note that the string version must not contain more
408    than one character because the code assumes strlen()==1 */
409 #ifdef HAVE_DOSISH_SYSTEM
410 #define DIRSEP_C '\\'
411 #define DIRSEP_S "\\"
412 #define EXTSEP_C '.'
413 #define EXTSEP_S "."
414 #define PATHSEP_C ';'
415 #define PATHSEP_S ";"
416 #define EXEEXT_S ".exe"
417 #else
418 #define DIRSEP_C '/'
419 #define DIRSEP_S "/"
420 #define EXTSEP_C '.'
421 #define EXTSEP_S "."
422 #define PATHSEP_C ':'
423 #define PATHSEP_S ":"
424 #define EXEEXT_S ""
425 #endif
426
427 /* This is the same as VERSION, but should be overridden if the
428    platform cannot handle things like dots '.' in filenames. Set
429    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
430    uses for dots and dashes. */
431 #define SAFE_VERSION VERSION
432 #define SAFE_VERSION_DOT  '.'
433 #define SAFE_VERSION_DASH '-'
434
435 /* Some global constants. */
436 #ifdef HAVE_DOSISH_SYSTEM
437 # ifdef HAVE_DRIVE_LETTERS
438 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
439 # else
440 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
441 # endif
442 #elif defined(__VMS)
443 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
444 #else
445 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
446 #endif
447 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
448
449 /* For some systems (DOS currently), we hardcode the path here.  For
450    POSIX systems the values are constructed by the Makefiles, so that
451    the values may be overridden by the make invocations; this is to
452    comply with the GNU coding standards.  Note that these values are
453    only defaults.  */
454 #ifdef HAVE_DOSISH_SYSTEM
455 # ifdef HAVE_DRIVE_LETTERS
456 #  define GNUPG_BINDIR      "c:\\gnupg"
457 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
458 #  define GNUPG_LIBDIR      "c:\\gnupg"
459 #  define GNUPG_DATADIR     "c:\\gnupg"
460 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
461 # else
462 #  define GNUPG_BINDIR      "\\gnupg"
463 #  define GNUPG_LIBEXECDIR  "\\gnupg"
464 #  define GNUPG_LIBDIR      "\\gnupg"
465 #  define GNUPG_DATADIR     "\\gnupg"
466 #  define GNUPG_SYSCONFDIR  "\\gnupg"
467 # endif
468 #endif
469
470 /* Derive some other constants. */
471 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
472 #define EXEC_TEMPFILE_ONLY
473 #endif
474
475
476 /* We didn't define endianness above, so get it from OS macros.  This
477    is intended for making fat binary builds on OS X. */
478 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
479 #if defined(__BIG_ENDIAN__)
480 #define BIG_ENDIAN_HOST 1
481 #elif defined(__LITTLE_ENDIAN__)
482 #define LITTLE_ENDIAN_HOST 1
483 #else
484 #error "No endianness found"
485 #endif
486 #endif
487
488
489 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
490    ldap_start_tls_s because that is the actual symbol used in the
491    library.  winldap.h redefines it to our commonly used value,
492    thus we define our usual macro here.  */
493 #ifdef HAVE_LDAP_START_TLS_SA
494 # ifndef HAVE_LDAP_START_TLS_S
495 #  define HAVE_LDAP_START_TLS_S 1
496 # endif
497 #endif
498
499
500 /* Tell libgcrypt not to use its own libgpg-error implementation. */
501 #define USE_LIBGPG_ERROR 1
502
503 /* We use jnlib, so tell other modules about it.  */
504 #define HAVE_JNLIB_LOGGING 1
505
506 /* Our HTTP code is used in estream mode.  */
507 #define HTTP_USE_ESTREAM 1
508
509 /* Under W32 we do an explicit socket initialization, thus we need to
510    avoid the on-demand initialization which would also install an atexit
511    handler.  */
512 #define HTTP_NO_WSASTARTUP
513
514 /* We always include support for the OpenPGP card.  */
515 #define ENABLE_CARD_SUPPORT 1
516
517 /* We want to use the libgcrypt provided memory allocation for
518    asprintf.  */
519 #define _ESTREAM_PRINTF_REALLOC       gcry_realloc
520 #define _ESTREAM_PRINTF_EXTRA_INCLUDE "../common/util.h"
521
522 /* Under Windows we use the gettext code from libgpg-error.  */
523 #define GPG_ERR_ENABLE_GETTEXT_MACROS
524
525 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
526 #define GPG_ERR_ENABLE_ERRNO_MACROS
527
528 #endif /*GNUPG_CONFIG_H_INCLUDED*/
529 ])
530
531
532 AM_MAINTAINER_MODE
533
534 # Checks for programs.
535 AC_MSG_NOTICE([checking for programs])
536 AC_PROG_MAKE_SET
537 AM_SANITY_CHECK
538 missing_dir=`cd $ac_aux_dir && pwd`
539 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
540 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
541 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
542 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
543 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
544 AC_PROG_AWK
545 AC_PROG_CC
546 AC_PROG_CPP
547 AM_PROG_CC_C_O
548 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
549   AC_MSG_ERROR([[No C-89 compiler found]])
550 fi
551 AC_PROG_INSTALL
552 AC_PROG_LN_S
553 AC_PROG_RANLIB
554 AC_CHECK_TOOL(AR, ar, :)
555 AC_PATH_PROG(PERL,"perl")
556 AC_CHECK_TOOL(WINDRES, windres, :)
557 AC_ISC_POSIX
558 gl_EARLY
559 AC_SYS_LARGEFILE
560 GNUPG_CHECK_USTAR
561
562 # We need to compile and run a program on the build machine.  A
563 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
564 # the AC archive is broken for autoconf 2.57.  Given that there is no
565 # newer version of that macro, we assume that it is also broken for
566 # autoconf 2.61 and thus we use a simple but usually sufficient
567 # approach.
568 AC_MSG_CHECKING(for cc for build)
569 if test "$cross_compiling" = "yes"; then
570   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
571 else
572   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
573 fi
574 AC_MSG_RESULT($CC_FOR_BUILD)
575 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
576
577
578
579 try_gettext=yes
580 have_dosish_system=no
581 have_w32_system=no
582 have_w32ce_system=no
583 have_android_system=no
584 run_tests=yes
585 use_simple_gettext=no
586 use_ldapwrapper=yes
587 mmap_needed=yes
588 case "${host}" in
589     *-mingw32*)
590         # special stuff for Windoze NT
591         ac_cv_have_dev_random=no
592         AC_DEFINE(USE_ONLY_8DOT3,1,
593                   [Set this to limit filenames to the 8.3 format])
594         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
595                   [Because the Unix gettext has too much overhead on
596                    MingW32 systems and these systems lack Posix functions,
597                    we use a simplified version of gettext])
598         disable_keyserver_path=yes
599         have_dosish_system=yes
600         have_w32_system=yes
601         run_tests=no
602         use_ldapwrapper=no  # Fixme: Do this only for CE.
603         case "${host}" in
604           *-mingw32ce*)
605             have_w32ce_system=yes
606             ;;
607           *)
608             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
609                       [Defined if the OS supports drive letters.])
610             ;;
611         esac
612         try_gettext="no"
613         use_simple_gettext=yes
614         mmap_needed=no
615         ;;
616     i?86-emx-os2 | i?86-*-os2*emx )
617         # OS/2 with the EMX environment
618         ac_cv_have_dev_random=no
619         AC_DEFINE(HAVE_DRIVE_LETTERS)
620         have_dosish_system=yes
621         try_gettext="no"
622         ;;
623
624     i?86-*-msdosdjgpp*)
625         # DOS with the DJGPP environment
626         ac_cv_have_dev_random=no
627         AC_DEFINE(HAVE_DRIVE_LETTERS)
628         have_dosish_system=yes
629         try_gettext="no"
630         ;;
631
632     *-*-hpux*)
633         if test -z "$GCC" ; then
634             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
635         fi
636         ;;
637     *-dec-osf4*)
638         if test -z "$GCC" ; then
639             # Suppress all warnings
640             # to get rid of the unsigned/signed char mismatch warnings.
641             CFLAGS="$CFLAGS -w"
642         fi
643         ;;
644     *-dec-osf5*)
645         if test -z "$GCC" ; then
646             # Use the newer compiler `-msg_disable ptrmismatch1' to
647             # get rid of the unsigned/signed char mismatch warnings.
648             # Using this may hide other pointer mismatch warnings, but
649             # it at least lets other warning classes through
650             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
651         fi
652         ;;
653     m68k-atari-mint)
654         ;;
655     *-linux-androideabi)
656         have_android_system=yes
657         run_tests=no
658         ;;
659     *)
660        ;;
661 esac
662
663 if test "$have_dosish_system" = yes; then
664    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
665              [Defined if we run on some of the PCDOS like systems
666               (DOS, Windoze. OS/2) with special properties like
667               no file modes, case insensitive file names and preferred
668               use of backslashes as directory name separators.])
669 fi
670 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
671
672 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
673
674 if test "$have_w32_system" = yes; then
675    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
676    if test "$have_w32ce_system" = yes; then
677       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
678    fi
679 fi
680 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
681 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
682
683 if test "$have_android_system" = yes; then
684    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
685 fi
686 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
687
688 if test "$run_tests" = yes; then
689    AC_DEFINE(RUN_TESTS,1, [Defined if we should run the tests])
690 fi
691 AM_CONDITIONAL(RUN_TESTS, test "$run_tests" = yes)
692
693 if test "$use_ldapwrapper" = yes; then
694    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
695 fi
696 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
697
698 if test "$disable_keyserver_path" = yes; then
699     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
700               [Defined to disable exec-path for keyserver helpers])
701 fi
702
703 #
704 # Allows enabling the use of a standard socket by default This is
705 # gpg-agent's option --[no-]use-standard-socket.  For Windows we force
706 # the use of this.
707 #
708 AC_MSG_CHECKING([whether to use a standard socket by default])
709 AC_ARG_ENABLE(standard-socket,
710               AC_HELP_STRING([--disable-standard-socket],
711                              [don't use a standard socket by default]),
712               use_standard_socket=$enableval)
713 tmp=""
714 if test "$use_standard_socket" != yes; then
715   if test "$have_w32_system" = yes; then
716     use_standard_socket=yes
717     tmp=" (forced)"
718   fi
719 fi
720 AC_MSG_RESULT($use_standard_socket$tmp)
721 if test "$use_standard_socket" = yes; then
722   AC_DEFINE(USE_STANDARD_SOCKET,1,
723             [Use the standard socket for the agent by default])
724 fi
725
726
727 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
728 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
729
730 if test x"$try_hkp" = xyes ; then
731   AC_SUBST(GPGKEYS_HKP,"gpg2keys_hkp$EXEEXT")
732 fi
733
734 if test x"$try_finger" = xyes ; then
735   AC_SUBST(GPGKEYS_FINGER,"gpg2keys_finger$EXEEXT")
736 fi
737
738
739
740 #
741 # Checks for libraries.
742 #
743 AC_MSG_NOTICE([checking for libraries])
744
745
746 #
747 # libgpg-error is a library with error codes shared between GnuPG
748 # related projects.
749 #
750 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
751                   have_gpg_error=yes,have_gpg_error=no)
752
753
754 #
755 # Libgcrypt is our generic crypto library
756 #
757 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
758         have_libgcrypt=yes,have_libgcrypt=no)
759
760
761 #
762 # libassuan is used for IPC
763 #
764 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
765                   have_libassuan=yes,have_libassuan=no)
766 if test "$have_libassuan" = "yes"; then
767   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
768                      [version of the libassuan library])
769 fi
770
771
772
773 #
774 # libksba is our X.509 support library
775 #
776 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
777
778
779 #
780 # libusb allows us to use the integrated CCID smartcard reader driver.
781 #
782 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
783 if test "$use_ccid_driver" = yes ; then
784   AC_CHECK_LIB(usb, usb_bulk_write,
785                 [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
786                   AC_DEFINE(HAVE_LIBUSB,1,
787                            [defined if libusb is available])
788                   have_libusb=yes
789                ])
790   AC_CHECK_FUNCS(usb_create_match)
791 fi
792 AC_SUBST(LIBUSB_LIBS)
793
794 #
795 # Check wether it is necessary to link against libdl.
796 #
797 gnupg_dlopen_save_libs="$LIBS"
798 LIBS=""
799 AC_SEARCH_LIBS(dlopen, c dl,,,)
800 DL_LIBS=$LIBS
801 AC_SUBST(DL_LIBS)
802 LIBS="$gnupg_dlopen_save_libs"
803
804 # Checks for g13
805
806 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
807 AC_DEFINE_UNQUOTED(ENCFS,
808         "${ENCFS}", [defines the filename of the encfs program])
809
810 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
811 AC_DEFINE_UNQUOTED(FUSERMOUNT,
812         "${FUSERMOUNT}", [defines the filename of the fusermount program])
813
814
815 # Checks for dirmngr
816
817
818 #
819 # Checks for symcryptrun:
820 #
821
822 # libutil has openpty() and login_tty().
823 AC_CHECK_LIB(util, openpty,
824               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
825                 AC_DEFINE(HAVE_LIBUTIL,1,
826                          [defined if libutil is available])
827              ])
828 AC_SUBST(LIBUTIL_LIBS)
829
830 # shred is used to clean temporary plain text files.
831 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
832 AC_DEFINE_UNQUOTED(SHRED,
833         "${SHRED}", [defines the filename of the shred program])
834
835
836 #
837 # Check whether the nPth library is available
838 #
839 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
840 if test "$have_npth" = "yes"; then
841   # We define this macro because some code parts require it.
842   AC_DEFINE(USE_NPTH, 1,
843               [Defined if the New Portable Thread Library is available])
844 else
845   AC_MSG_WARN([[
846 ***
847 *** To support concurrent access for example in gpg-agent and the SCdaemon
848 *** we need the support of the New Portable Threads Library.
849 ***]])
850 fi
851
852
853 AC_MSG_NOTICE([checking for networking options])
854
855 #
856 # Must check for network library requirements before doing link tests
857 # for ldap, for example. If ldap libs are static (or dynamic and without
858 # ELF runtime link paths), then link will fail and LDAP support won't
859 # be detected.
860 #
861 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
862         [NETLIBS="-lnsl $NETLIBS"]))
863 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
864         [NETLIBS="-lsocket $NETLIBS"]))
865
866
867 #
868 # Check for ADNS.
869 #
870 _cppflags="${CPPFLAGS}"
871 _ldflags="${LDFLAGS}"
872 AC_ARG_WITH(adns,
873             AC_HELP_STRING([--with-adns=DIR],
874                            [look for the adns library in DIR]),
875             [if test -d "$withval"; then
876                CPPFLAGS="${CPPFLAGS} -I$withval/include"
877                LDFLAGS="${LDFLAGS} -L$withval/lib"
878              fi])
879 if test "$with_adns" != "no"; then
880   AC_CHECK_HEADERS(adns.h,
881                 AC_CHECK_LIB(adns, adns_init,
882                              [have_adns=yes],
883                              [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}]),
884                 [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}])
885 fi
886 if test "$have_adns" = "yes"; then
887   ADNSLIBS="-ladns"
888 fi
889 AC_SUBST(ADNSLIBS)
890 # Newer adns versions feature a free function to be used under W32.
891 AC_CHECK_FUNCS(adns_free)
892
893
894
895 #
896 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
897 #
898 if test x"$try_hkp" = xyes || test x"$try_http" = xyes ; then
899   AC_ARG_ENABLE(dns-srv,
900      AC_HELP_STRING([--disable-dns-srv],
901                     [disable the use of DNS SRV in HKP and HTTP]),
902                 use_dns_srv=$enableval,use_dns_srv=yes)
903 fi
904
905 AC_ARG_ENABLE(dns-pka,
906    AC_HELP_STRING([--disable-dns-pka],
907         [disable the use of PKA records in DNS]),
908    use_dns_pka=$enableval,use_dns_pka=yes)
909
910 AC_ARG_ENABLE(dns-cert,
911    AC_HELP_STRING([--disable-dns-cert],
912         [disable the use of CERT records in DNS]),
913    use_dns_cert=$enableval,use_dns_cert=yes)
914
915 if test x"$use_dns_pka" = xyes || test x"$use_dns_srv" = xyes \
916    || test x"$use_dns_cert" = xyes; then
917   _dns_save_libs=$LIBS
918   LIBS=""
919   # the double underscore thing is a glibc-ism?
920   AC_SEARCH_LIBS(res_query,resolv bind,,
921                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
922   AC_SEARCH_LIBS(dn_expand,resolv bind,,
923                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
924   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
925                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
926
927   if test x"$have_resolver" != xno ; then
928
929     # Make sure that the BIND 4 resolver interface is workable before
930     # enabling any code that calls it.  At some point I'll rewrite the
931     # code to use the BIND 8 resolver API.
932     # We might also want to use adns instead.  Problem with ADNS is that
933     # it does not support v6.
934
935     AC_MSG_CHECKING([whether the resolver is usable])
936     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
937 #include <netinet/in.h>
938 #include <arpa/nameser.h>
939 #include <resolv.h>]],
940 [[unsigned char answer[PACKETSZ];
941   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
942   dn_skipname(0,0);
943   dn_expand(0,0,0,0,0);
944 ]])],have_resolver=yes,have_resolver=no)
945     AC_MSG_RESULT($have_resolver)
946
947     # This is Apple-specific and somewhat bizarre as they changed the
948     # define in bind 8 for some reason.
949
950     if test x"$have_resolver" != xyes ; then
951        AC_MSG_CHECKING(
952              [whether I can make the resolver usable with BIND_8_COMPAT])
953        AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
954 #include <sys/types.h>
955 #include <netinet/in.h>
956 #include <arpa/nameser.h>
957 #include <resolv.h>]],
958 [[unsigned char answer[PACKETSZ];
959   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
960   dn_skipname(0,0); dn_expand(0,0,0,0,0);
961 ]])],[have_resolver=yes ; need_compat=yes])
962        AC_MSG_RESULT($have_resolver)
963     fi
964   fi
965
966   if test x"$have_resolver" = xyes ; then
967      DNSLIBS=$LIBS
968
969      if test x"$use_dns_srv" = xyes ; then
970         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
971      fi
972
973      if test x"$use_dns_pka" = xyes ; then
974         AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
975      fi
976
977      if test x"$use_dns_cert" = xyes ; then
978         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
979      fi
980
981      if test x"$need_compat" = xyes ; then
982         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
983      fi
984   else
985      # If we have no resolver library but ADNS (e.g. under W32) enable the
986      # code parts which can be used with ADNS.
987      if test x"$have_adns" = xyes ; then
988         DNSLIBS="$ADNSLIBS"
989         AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
990
991         if test x"$use_dns_srv" = xyes ; then
992            AC_DEFINE(USE_DNS_SRV,1)
993         fi
994
995         if test x"$use_dns_pka" = xyes ; then
996            AC_DEFINE(USE_DNS_PKA,1)
997         fi
998
999         if test x"$use_dns_cert" = xyes ; then
1000            AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
1001         fi
1002      else
1003         use_dns_srv=no
1004         use_dns_pka=no
1005         use_dns_cert=no
1006      fi
1007   fi
1008
1009   LIBS=$_dns_save_libs
1010 fi
1011
1012 AC_SUBST(DNSLIBS)
1013
1014 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
1015
1016
1017 #
1018 # Check for LDAP
1019 #
1020 if test "$try_ks_ldap" = yes || test "$build_dirmngr" = "yes" ; then
1021    GNUPG_CHECK_LDAP($NETLIBS)
1022    AC_CHECK_LIB(lber, ber_free,
1023                 [ LBER_LIBS="$LBER_LIBS -llber"
1024                   AC_DEFINE(HAVE_LBER,1,
1025                            [defined if liblber is available])
1026                   have_lber=yes
1027                ])
1028 fi
1029 AC_SUBST(LBER_LIBS)
1030
1031 #
1032 # Check for curl.  We fake the curl API if libcurl isn't installed.
1033 # We require 7.10 or later as we use curl_version_info().
1034 #
1035 LIBCURL_CHECK_CONFIG([yes],[7.10],,[fake_curl=yes])
1036 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
1037
1038 # Generic, for us, means curl
1039
1040 if test x"$try_generic" = xyes ; then
1041    AC_SUBST(GPGKEYS_CURL,"gpg2keys_curl$EXEEXT")
1042 fi
1043
1044 #
1045 # Check for sendmail
1046 #
1047 # This isn't necessarily sendmail itself, but anything that gives a
1048 # sendmail-ish interface to the outside world.  That includes Exim,
1049 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1050 if test "$try_mailto" = yes ; then
1051   AC_ARG_WITH(mailprog,
1052       AC_HELP_STRING([--with-mailprog=NAME],
1053                      [use "NAME -t" for mail transport]),
1054              ,with_mailprog=yes)
1055
1056   if test x"$with_mailprog" = xyes ; then
1057     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1058     if test "$ac_cv_path_SENDMAIL" ; then
1059       GPGKEYS_MAILTO="gpg2keys_mailto"
1060     fi
1061   elif test x"$with_mailprog" != xno ; then
1062     AC_MSG_CHECKING([for a mail transport program])
1063     AC_SUBST(SENDMAIL,$with_mailprog)
1064     AC_MSG_RESULT($with_mailprog)
1065     GPGKEYS_MAILTO="gpg2keys_mailto"
1066   fi
1067 fi
1068
1069 AC_SUBST(GPGKEYS_MAILTO)
1070
1071 #
1072 # Construct a printable name of the OS
1073 #
1074 case "${host}" in
1075     *-mingw32ce*)
1076         PRINTABLE_OS_NAME="W32CE"
1077         ;;
1078     *-mingw32*)
1079         PRINTABLE_OS_NAME="MingW32"
1080         ;;
1081     *-*-cygwin*)
1082         PRINTABLE_OS_NAME="Cygwin"
1083         ;;
1084     i?86-emx-os2 | i?86-*-os2*emx )
1085         PRINTABLE_OS_NAME="OS/2"
1086         ;;
1087     i?86-*-msdosdjgpp*)
1088         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1089         try_dynload=no
1090         ;;
1091     *-linux*)
1092         PRINTABLE_OS_NAME="GNU/Linux"
1093         ;;
1094     *)
1095         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1096         ;;
1097 esac
1098 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1099                    [A human readable text with the name of the OS])
1100
1101
1102 #
1103 # Checking for iconv
1104 #
1105 AM_ICONV
1106
1107
1108 #
1109 # Check for gettext
1110 #
1111 # This is "GNU gnupg" - The project-id script from gettext
1112 #                       needs this string
1113 #
1114 AC_MSG_NOTICE([checking for gettext])
1115 AM_PO_SUBDIRS
1116 AM_GNU_GETTEXT_VERSION([0.17])
1117 if test "$try_gettext" = yes; then
1118   AM_GNU_GETTEXT([external],[need-ngettext])
1119
1120   # gettext requires some extra checks.  These really should be part of
1121   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1122   # function checks to here.
1123
1124   AC_CHECK_FUNCS(strchr)
1125 else
1126   USE_NLS=no
1127   USE_INCLUDED_LIBINTL=no
1128   BUILD_INCLUDED_LIBINTL=no
1129   POSUB=po
1130   AC_SUBST(USE_NLS)
1131   AC_SUBST(USE_INCLUDED_LIBINTL)
1132   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1133   AC_SUBST(POSUB)
1134 fi
1135
1136 # We use HAVE_LANGINFO_CODESET in a couple of places.
1137 AM_LANGINFO_CODESET
1138
1139 # Checks required for our use locales
1140 gt_LC_MESSAGES
1141
1142
1143 #
1144 # SELinux support
1145 #
1146 if test "$selinux_support" = yes ; then
1147   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1148 fi
1149
1150
1151 #
1152 # Checks for header files.
1153 #
1154 AC_MSG_NOTICE([checking for header files])
1155 AC_HEADER_STDC
1156 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1157                   pty.h utmp.h pwd.h inttypes.h signal.h])
1158 AC_HEADER_TIME
1159
1160
1161 #
1162 # Checks for typedefs, structures, and compiler characteristics.
1163 #
1164 AC_MSG_NOTICE([checking for system characteristics])
1165 AC_C_CONST
1166 AC_C_INLINE
1167 AC_C_VOLATILE
1168 AC_TYPE_SIZE_T
1169 AC_TYPE_MODE_T
1170 AC_TYPE_SIGNAL
1171 AC_DECL_SYS_SIGLIST
1172
1173 gl_HEADER_SYS_SOCKET
1174 gl_TYPE_SOCKLEN_T
1175
1176 AC_SEARCH_LIBS([inet_addr], [nsl])
1177
1178 AC_ARG_ENABLE(endian-check,
1179               AC_HELP_STRING([--disable-endian-check],
1180               [disable the endian check and trust the OS provided macros]),
1181               endiancheck=$enableval,endiancheck=yes)
1182
1183 if test x"$endiancheck" = xyes ; then
1184   GNUPG_CHECK_ENDIAN
1185 fi
1186
1187 # fixme: we should get rid of the byte type
1188 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1189 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1190 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1191 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1192 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1193
1194 AC_CHECK_SIZEOF(unsigned short)
1195 AC_CHECK_SIZEOF(unsigned int)
1196 AC_CHECK_SIZEOF(unsigned long)
1197 AC_CHECK_SIZEOF(unsigned long long)
1198 AC_HEADER_TIME
1199 AC_CHECK_SIZEOF(time_t,,[[
1200 #include <stdio.h>
1201 #if TIME_WITH_SYS_TIME
1202 # include <sys/time.h>
1203 # include <time.h>
1204 #else
1205 # if HAVE_SYS_TIME_H
1206 #  include <sys/time.h>
1207 # else
1208 #  include <time.h>
1209 # endif
1210 #endif
1211 ]])
1212 GNUPG_TIME_T_UNSIGNED
1213
1214
1215 # Ensure that we have UINT64_C before we bother to check for uint64_t
1216 # Fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
1217 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
1218    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <inttypes.h>]],
1219        [[uint64_t foo=UINT64_C(42);]])],
1220      gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
1221 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
1222    AC_CHECK_SIZEOF(uint64_t)
1223 fi
1224
1225 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1226    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1227    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1228     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1229 fi
1230
1231
1232 #
1233 # Checks for library functions.
1234 #
1235 AC_MSG_NOTICE([checking for library functions])
1236 AC_CHECK_DECLS(getpagesize)
1237 AC_FUNC_FSEEKO
1238 AC_FUNC_VPRINTF
1239 AC_FUNC_FORK
1240 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1241 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1242 AC_CHECK_FUNCS([unsetenv fcntl ftruncate canonicalize_file_name])
1243 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1244 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1245 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1246 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1247
1248 if test "$have_android_system" = yes; then
1249    # On Android ttyname is a stub but prints an error message.
1250    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1251              [Defined if ttyname does not work properly])
1252 fi
1253
1254 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1255
1256 # Dirmngr requires mmap on Unix systems.
1257 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1258   AC_MSG_ERROR([[Sorry, the current implemenation requires mmap.]])
1259 fi
1260
1261 #
1262 # These are needed by the jnlib parts in common.
1263 # Note:  We already checked pwd.h.
1264 AC_CHECK_HEADERS([signal.h])
1265 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1266                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1267                 flockfile funlockfile fopencookie funopen getpwnam getpwuid \
1268                 getenv inet_pton])
1269 # end jnlib checks.
1270
1271
1272
1273 #
1274 # gnulib checks
1275 #
1276 gl_SOURCE_BASE([gl])
1277 gl_M4_BASE([gl/m4])
1278 gl_MODULES([setenv mkdtemp xsize strpbrk])
1279 gl_INIT
1280
1281
1282 #
1283 # W32 specific test
1284 #
1285 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1286
1287 #
1288 # Sanity check regex.  Tests adapted from mutt.
1289 #
1290 AC_MSG_CHECKING([whether regular expression support is requested])
1291 AC_ARG_ENABLE(regex,
1292   AC_HELP_STRING([--disable-regex],
1293     [do not handle regular expressions in trust signatures]),
1294   use_regex=$enableval, use_regex=yes)
1295 AC_MSG_RESULT($use_regex)
1296
1297 if test "$use_regex" = yes ; then
1298   _cppflags="${CPPFLAGS}"
1299   _ldflags="${LDFLAGS}"
1300   AC_ARG_WITH(regex,
1301      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1302       [
1303       if test -d "$withval" ; then
1304         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1305         LDFLAGS="${LDFLAGS} -L$withval/lib"
1306       fi
1307       ],withval="")
1308
1309   # Does the system have regex functions at all?
1310   AC_SEARCH_LIBS([regcomp], [regex])
1311   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1312
1313   if test $gnupg_cv_have_regex = no; then
1314     use_regex=no
1315   else
1316     if test x"$cross_compiling" = xyes; then
1317       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1318     else
1319       AC_CACHE_CHECK([whether your system's regexp library is broken],
1320        [gnupg_cv_regex_broken],
1321        AC_TRY_RUN([
1322 #include <unistd.h>
1323 #include <regex.h>
1324 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1325        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1326
1327       if test $gnupg_cv_regex_broken = yes; then
1328         AC_MSG_WARN([your regex is broken - disabling regex use])
1329         use_regex=no
1330       fi
1331     fi
1332   fi
1333   CPPFLAGS="${_cppflags}"
1334   LDFLAGS="${_ldflags}"
1335 fi
1336
1337 if test "$use_regex" != yes ; then
1338   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1339 fi
1340 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1341
1342
1343
1344 #
1345 # Do we have zlib? Must do it here because Solaris failed
1346 # when compiling a conftest (due to the "-lz" from LIBS).
1347 # Note that we combine zlib and bzlib2 in ZLIBS.
1348 #
1349 if test "$use_zip" = yes ; then
1350   _cppflags="${CPPFLAGS}"
1351   _ldflags="${LDFLAGS}"
1352   AC_ARG_WITH(zlib,
1353     [  --with-zlib=DIR         use libz in DIR],[
1354       if test -d "$withval"; then
1355         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1356         LDFLAGS="${LDFLAGS} -L$withval/lib"
1357       fi
1358     ])
1359
1360   AC_CHECK_HEADER(zlib.h,
1361         AC_CHECK_LIB(z, deflateInit2_,
1362          ZLIBS="-lz",
1363          CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1364          CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1365
1366   AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1367 fi
1368
1369
1370 #
1371 # Check whether we can support bzip2
1372 #
1373 if test "$use_bzip2" = yes ; then
1374   _cppflags="${CPPFLAGS}"
1375   _ldflags="${LDFLAGS}"
1376   AC_ARG_WITH(bzip2,
1377      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1378       [
1379       if test -d "$withval" ; then
1380         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1381         LDFLAGS="${LDFLAGS} -L$withval/lib"
1382       fi
1383       ],withval="")
1384
1385   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1386   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1387   # woefully out of date.
1388   if test "$withval" != no ; then
1389      AC_CHECK_HEADER(bzlib.h,
1390         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1391           [
1392           have_bz2=yes
1393           ZLIBS="$ZLIBS -lbz2"
1394           AC_DEFINE(HAVE_BZIP2,1,
1395                   [Defined if the bz2 compression library is available])
1396           ],
1397           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1398           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1399   fi
1400 fi
1401 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1402 AC_SUBST(ZLIBS)
1403
1404
1405 # Check for readline support
1406 GNUPG_CHECK_READLINE
1407
1408
1409 if test "$development_version" = yes; then
1410     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1411             [Defined if this is not a regular release])
1412 fi
1413
1414 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1415
1416 GNUPG_CHECK_GNUMAKE
1417
1418 # Add some extra libs here so that previous tests don't fail for
1419 # mysterious reasons - the final link step should bail out.
1420 # W32SOCKLIBS is also defined so that if can be used for tools not
1421 # requiring any network stuff but linking to code in libcommon which
1422 # tracks in winsock stuff (e.g. init_common_subsystems).
1423 if test "$have_w32_system" = yes; then
1424    if test "$have_w32ce_system" = yes; then
1425      W32SOCKLIBS="-lws2"
1426    else
1427      W32SOCKLIBS="-lws2_32"
1428    fi
1429    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1430 fi
1431
1432 AC_SUBST(NETLIBS)
1433 AC_SUBST(W32SOCKLIBS)
1434
1435 #
1436 # Setup gcc specific options
1437 #
1438 AC_MSG_NOTICE([checking for cc features])
1439 if test "$GCC" = yes; then
1440     # Note that it is okay to use CFLAGS here because this are just
1441     # warning options and the user should have a chance of overriding
1442     # them.
1443     if test "$USE_MAINTAINER_MODE" = "yes"; then
1444         CFLAGS="$CFLAGS -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1445         CFLAGS="$CFLAGS -Wformat -Wno-format-y2k -Wformat-security"
1446         AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1447         _gcc_cflags_save=$CFLAGS
1448         CFLAGS="-Wno-missing-field-initializers"
1449         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1450         AC_MSG_RESULT($_gcc_wopt)
1451         CFLAGS=$_gcc_cflags_save;
1452         if test x"$_gcc_wopt" = xyes ; then
1453           CFLAGS="$CFLAGS -W -Wno-sign-compare -Wno-missing-field-initializers"
1454         fi
1455         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1456         _gcc_cflags_save=$CFLAGS
1457         CFLAGS="-Wdeclaration-after-statement"
1458         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1459         AC_MSG_RESULT($_gcc_wopt)
1460         CFLAGS=$_gcc_cflags_save;
1461         if test x"$_gcc_wopt" = xyes ; then
1462           CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1463         fi
1464     else
1465         CFLAGS="$CFLAGS -Wall"
1466     fi
1467
1468     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1469     _gcc_cflags_save=$CFLAGS
1470     CFLAGS="-Wno-pointer-sign"
1471     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1472     AC_MSG_RESULT($_gcc_psign)
1473     CFLAGS=$_gcc_cflags_save;
1474     if test x"$_gcc_psign" = xyes ; then
1475        CFLAGS="$CFLAGS -Wno-pointer-sign"
1476     fi
1477
1478     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1479     _gcc_cflags_save=$CFLAGS
1480     CFLAGS="-Wpointer-arith"
1481     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1482     AC_MSG_RESULT($_gcc_psign)
1483     CFLAGS=$_gcc_cflags_save;
1484     if test x"$_gcc_psign" = xyes ; then
1485        CFLAGS="$CFLAGS -Wpointer-arith"
1486     fi
1487 fi
1488
1489
1490 #
1491 # This is handy for debugging so the compiler doesn't rearrange
1492 # things and eliminate variables.
1493 #
1494 AC_ARG_ENABLE(optimization,
1495    AC_HELP_STRING([--disable-optimization],
1496                   [disable compiler optimization]),
1497                   [if test $enableval = no ; then
1498                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1499                    fi])
1500
1501 #
1502 # Prepare building of estream
1503 #
1504 estream_INIT
1505
1506
1507 #
1508 # Decide what to build
1509 #
1510 if test "$have_adns" = "yes"; then
1511   AC_SUBST(GPGKEYS_KDNS, "gpg2keys_kdns$EXEEXT")
1512 fi
1513
1514
1515 build_scdaemon_extra=""
1516 if test "$build_scdaemon" = "yes"; then
1517   if test $have_libusb = no; then
1518      build_scdaemon_extra="without internal CCID driver"
1519   fi
1520   if test -n "$build_scdaemon_extra"; then
1521      build_scdaemon_extra="(${build_scdaemon_extra})"
1522   fi
1523 fi
1524
1525
1526 if test "$build_agent_only" = "yes" ; then
1527   build_gpg=no
1528   build_gpgsm=no
1529   build_scdaemon=no
1530   build_tools=no
1531   build_doc=no
1532 fi
1533
1534 #
1535 # Set variables for use by th automake makefile.
1536 #
1537 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1538 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1539 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1540 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1541 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1542 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1543 AM_CONDITIONAL(BUILD_TOOLS,       test "$build_tools" = "yes")
1544 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1545 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1546 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1547
1548 AM_CONDITIONAL(RUN_GPG_TESTS,
1549                test x$cross_compiling = xno -a "$build_gpg" = yes )
1550
1551 #
1552 # Set some defines for use gpgconf.
1553 #
1554 if test "$build_gpg" = yes ; then
1555     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1556 fi
1557 if test "$build_gpgsm" = yes ; then
1558     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1559 fi
1560 if test "$build_agent" = yes ; then
1561     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1562 fi
1563 if test "$build_scdaemon" = yes ; then
1564     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1565 fi
1566 if test "$build_dirmngr" = yes ; then
1567     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if SCDAEMON is to be build])
1568 fi
1569 if test "$build_g13" = yes ; then
1570     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1571 fi
1572
1573
1574
1575 #
1576 # Provide information about the build.
1577 #
1578 BUILD_REVISION="mym4_revision"
1579 AC_SUBST(BUILD_REVISION)
1580 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1581                    [GIT commit id revision used to build this package])
1582
1583 changequote(,)dnl
1584 BUILD_FILEVERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./;s/\./,/g'`
1585 changequote([,])dnl
1586 BUILD_FILEVERSION="${BUILD_FILEVERSION}mym4_revision_dec"
1587 AC_SUBST(BUILD_FILEVERSION)
1588
1589 BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1590 AC_SUBST(BUILD_TIMESTAMP)
1591 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1592                    [The time this package was configured for a build])
1593 BUILD_HOSTNAME="$ac_hostname"
1594 AC_SUBST(BUILD_HOSTNAME)
1595
1596
1597 #
1598 # Print errors here so that they are visible all
1599 # together and the user can acquire them all together.
1600 #
1601 die=no
1602 if test "$have_gpg_error" = "no"; then
1603    die=yes
1604    AC_MSG_NOTICE([[
1605 ***
1606 *** You need libgpg-error to build this program.
1607 **  This library is for example available at
1608 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1609 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1610 ***]])
1611 fi
1612 if test "$have_libgcrypt" = "no"; then
1613    die=yes
1614    AC_MSG_NOTICE([[
1615 ***
1616 *** You need libgcrypt to build this program.
1617 **  This library is for example available at
1618 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1619 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1620 ***]])
1621 fi
1622 if test "$have_libassuan" = "no"; then
1623    die=yes
1624    AC_MSG_NOTICE([[
1625 ***
1626 *** You need libassuan to build this program.
1627 *** This library is for example available at
1628 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1629 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1630 ***]])
1631 fi
1632 if test "$have_ksba" = "no"; then
1633     die=yes
1634     AC_MSG_NOTICE([[
1635 ***
1636 *** You need libksba to build this program.
1637 *** This library is for example available at
1638 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1639 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1640 ***]])
1641 fi
1642 if test "$gnupg_have_ldap" = "no"; then
1643     die=yes
1644     AC_MSG_NOTICE([[
1645 ***
1646 *** You need a LDAP library to build this program.
1647 *** Check out
1648 ***    http://www.openldap.org
1649 *** for a suitable implementation.
1650 ***]])
1651    if test "$have_w32ce_system" = yes; then
1652     AC_MSG_NOTICE([[
1653 *** Note that CeGCC might be broken, a package fixing this is:
1654 ***    http://files.kolab.org/local/windows-ce/
1655 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1656 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1657 ***]])
1658    fi
1659 fi
1660 if test "$have_npth" = "no"; then
1661     die=yes
1662     AC_MSG_NOTICE([[
1663 ***
1664 *** It is now required to build with support for the
1665 *** New Portable Threads Library (nPth). Please install this
1666 *** library first.  The library is for example available at
1667 ***   ftp://ftp.gnupg.org/gcrypt/npth/
1668 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1669 ***]])
1670 fi
1671
1672 if test "$die" = "yes"; then
1673     AC_MSG_ERROR([[
1674 ***
1675 *** Required libraries not found. Please consult the above messages
1676 *** and install them before running configure again.
1677 ***]])
1678 fi
1679
1680
1681
1682 AC_CONFIG_FILES([ m4/Makefile
1683 Makefile
1684 po/Makefile.in
1685 gl/Makefile
1686 include/Makefile
1687 common/Makefile
1688 common/w32info-rc.h
1689 kbx/Makefile
1690 g10/Makefile
1691 sm/Makefile
1692 agent/Makefile
1693 scd/Makefile
1694 g13/Makefile
1695 dirmngr/Makefile
1696 tools/gpg-zip
1697 tools/Makefile
1698 doc/Makefile
1699 tests/Makefile
1700 tests/openpgp/Makefile
1701 tests/pkits/Makefile
1702 ])
1703 #keyserver/Makefile
1704 #keyserver/gpg2keys_mailto
1705 #keyserver/gpg2keys_test
1706
1707
1708 AC_OUTPUT
1709
1710
1711 echo "
1712         GnuPG v${VERSION} has been configured as follows:
1713
1714         Revision:  mym4_revision  (mym4_revision_dec)
1715         Platform:  $PRINTABLE_OS_NAME ($host)
1716
1717         OpenPGP:   $build_gpg
1718         S/MIME:    $build_gpgsm
1719         Agent:     $build_agent
1720         Smartcard: $build_scdaemon $build_scdaemon_extra
1721         G13:       $build_g13
1722         Dirmngr:   $build_dirmngr
1723         Gpgtar:    $build_gpgtar
1724
1725         Protect tool:      $show_gnupg_protect_tool_pgm
1726         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
1727         Default agent:     $show_gnupg_agent_pgm
1728         Default pinentry:  $show_gnupg_pinentry_pgm
1729         Default scdaemon:  $show_gnupg_scdaemon_pgm
1730         Default dirmngr:   $show_gnupg_dirmngr_pgm
1731
1732         Use standard socket: $use_standard_socket
1733         Dirmngr auto start:  $dirmngr_auto_start
1734 "
1735 if test x"$use_regex" != xyes ; then
1736 echo "
1737         Warning: No regular expression support available.
1738                  OpenPGP trust signatures won't work.
1739                  gpg-check-pattern will not be build.
1740 "
1741 fi