common: Change log_clock to printf style.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998-2017 Free Software Foundation, Inc.
3 # Copyright (C) 1998-2017 Werner Koch
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <https://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.14"
23
24 # To build a release you need to create a tag with the version number
25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
26 # bump the version number immediately *after* the release and do
27 # another commit and push so that the git magic is able to work.
28 m4_define([mym4_package],[gnupg])
29 m4_define([mym4_major], [2])
30 m4_define([mym4_minor], [3])
31 m4_define([mym4_micro], [0])
32
33 # To start a new development series, i.e a new major or minor number
34 # you need to mark an arbitrary commit before the first beta release
35 # with an annotated tag.  For example the 2.1 branch starts off with
36 # the tag "gnupg-2.1-base".  This is used as the base for counting
37 # beta numbers before the first release of a series.
38
39 # Below is m4 magic to extract and compute the git revision number,
40 # the decimalized short revision number, a beta version string and a
41 # flag indicating a development version (mym4_isbeta).  Note that the
42 # m4 processing is done by autoconf and not during the configure run.
43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
49 m4_esyscmd([echo ]mym4_version[>VERSION])
50 AC_INIT([mym4_package],[mym4_version], [https://bugs.gnupg.org])
51
52 # When changing the SWDB tag please also adjust the hard coded tags in
53 # build-aux/speedo.mk and Makefile.am
54 AC_DEFINE_UNQUOTED(GNUPG_SWDB_TAG, "gnupg22", [swdb tag for this branch])
55
56 NEED_GPG_ERROR_VERSION=1.24
57
58 NEED_LIBGCRYPT_API=1
59 NEED_LIBGCRYPT_VERSION=1.7.0
60
61 NEED_LIBASSUAN_API=2
62 NEED_LIBASSUAN_VERSION=2.4.3
63
64 NEED_KSBA_API=1
65 NEED_KSBA_VERSION=1.3.4
66
67 NEED_NTBTLS_API=1
68 NEED_NTBTLS_VERSION=0.1.0
69
70 NEED_NPTH_API=1
71 NEED_NPTH_VERSION=1.2
72
73
74 NEED_GNUTLS_VERSION=3.0
75
76 NEED_SQLITE_VERSION=3.7
77
78 development_version=mym4_isbeta
79 PACKAGE=$PACKAGE_NAME
80 PACKAGE_GT=${PACKAGE_NAME}2
81 VERSION=$PACKAGE_VERSION
82
83 AC_CONFIG_AUX_DIR([build-aux])
84 AC_CONFIG_SRCDIR([sm/gpgsm.c])
85 AC_CONFIG_HEADER([config.h])
86 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
87 AC_CANONICAL_HOST
88 AB_INIT
89
90 AC_GNU_SOURCE
91
92
93 # Some status variables.
94 have_gpg_error=no
95 have_libgcrypt=no
96 have_libassuan=no
97 have_ksba=no
98 have_ntbtls=no
99 have_gnutls=no
100 have_sqlite=no
101 have_npth=no
102 have_libusb=no
103 have_system_resolver=no
104 gnupg_have_ldap="n/a"
105
106 use_zip=yes
107 use_bzip2=yes
108 use_exec=yes
109 use_trust_models=yes
110 use_tofu=yes
111 use_libdns=yes
112 card_support=yes
113 use_ccid_driver=auto
114 dirmngr_auto_start=yes
115 use_tls_library=no
116 large_secmem=no
117 show_tor_support=no
118
119 # gpg is a required part and can't be disabled anymore.
120 build_gpg=yes
121 GNUPG_BUILD_PROGRAM(gpgsm, yes)
122 # The agent is a required part and can't be disabled anymore.
123 build_agent=yes
124 GNUPG_BUILD_PROGRAM(scdaemon, yes)
125 GNUPG_BUILD_PROGRAM(g13, no)
126 GNUPG_BUILD_PROGRAM(dirmngr, yes)
127 GNUPG_BUILD_PROGRAM(doc, yes)
128 GNUPG_BUILD_PROGRAM(symcryptrun, no)
129 # We use gpgtar to unpack test data, hence we always build it.  If the
130 # user opts out, we simply don't install it.
131 GNUPG_BUILD_PROGRAM(gpgtar, yes)
132 GNUPG_BUILD_PROGRAM(wks-tools, no)
133
134 AC_SUBST(PACKAGE)
135 AC_SUBST(PACKAGE_GT)
136 AC_SUBST(VERSION)
137 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
138 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
139                                 [Name of this package for gettext])
140 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
141 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
142                                         [Bug report address])
143 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
144                                        [Required version of Libgcrypt])
145 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
146                                        [Required version of Libksba])
147 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
148                                        [Required version of NTBTLS])
149
150
151
152 # The default is to use the modules from this package and the few
153 # other packages in a standard place; i.e where this package gets
154 # installed.  With these options it is possible to override these
155 # ${prefix} depended values with fixed paths, which can't be replaced
156 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
157 AC_ARG_WITH(agent-pgm,
158     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
159           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
160 AC_SUBST(GNUPG_AGENT_PGM)
161 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
162 show_gnupg_agent_pgm="(default)"
163 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
164
165 AC_ARG_WITH(pinentry-pgm,
166     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
167           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
168 AC_SUBST(GNUPG_PINENTRY_PGM)
169 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
170 show_gnupg_pinentry_pgm="(default)"
171 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
172
173
174 AC_ARG_WITH(scdaemon-pgm,
175     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
176           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
177 AC_SUBST(GNUPG_SCDAEMON_PGM)
178 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
179 show_gnupg_scdaemon_pgm="(default)"
180 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
181
182
183 AC_ARG_WITH(dirmngr-pgm,
184     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
185           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
186 AC_SUBST(GNUPG_DIRMNGR_PGM)
187 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
188 show_gnupg_dirmngr_pgm="(default)"
189 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
190
191 AC_ARG_WITH(protect-tool-pgm,
192     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
193           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
194 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
195 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
196 show_gnupg_protect_tool_pgm="(default)"
197 test -n "$GNUPG_PROTECT_TOOL_PGM" \
198       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
199
200 AC_ARG_WITH(dirmngr-ldap-pgm,
201     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmngr ldap wrapper)],
202           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
203 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
204 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
205 show_gnupg_dirmngr_ldap_pgm="(default)"
206 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
207       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
208
209
210 #
211 # For a long time gpg 2.x was installed as gpg2.  This changed with
212 # 2.2.  This option can be used to install gpg under the name gpg2.
213 #
214 AC_ARG_ENABLE(gpg-is-gpg2,
215     AC_HELP_STRING([--enable-gpg-is-gpg2],[Set installed name of gpg to gpg2]),
216     gpg_is_gpg2=$enableval)
217 if test "$gpg_is_gpg2" = "yes"; then
218    AC_DEFINE(USE_GPG2_HACK, 1, [Define to install gpg as gpg2])
219 fi
220 AM_CONDITIONAL(USE_GPG2_HACK, test "$gpg_is_gpg2" = "yes")
221
222
223 # SELinux support includes tracking of sensitive files to avoid
224 # leaking their contents through processing these files by gpg itself
225 AC_MSG_CHECKING([whether SELinux support is requested])
226 AC_ARG_ENABLE(selinux-support,
227               AC_HELP_STRING([--enable-selinux-support],
228                              [enable SELinux support]),
229               selinux_support=$enableval, selinux_support=no)
230 AC_MSG_RESULT($selinux_support)
231
232
233 AC_MSG_CHECKING([whether to allocate extra secure memory])
234 AC_ARG_ENABLE(large-secmem,
235               AC_HELP_STRING([--enable-large-secmem],
236                              [allocate extra secure memory]),
237               large_secmem=$enableval, large_secmem=no)
238 AC_MSG_RESULT($large_secmem)
239 if test "$large_secmem" = yes ; then
240    SECMEM_BUFFER_SIZE=65536
241 else
242    SECMEM_BUFFER_SIZE=32768
243 fi
244 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
245                    [Size of secure memory buffer])
246
247 AC_MSG_CHECKING([calibrated passphrase-stretching (s2k) duration])
248 AC_ARG_WITH(agent-s2k-calibration,
249               AC_HELP_STRING([--with-agent-s2k-calibration=MSEC],
250                              [calibrate passphrase stretching (s2k) to MSEC milliseconds]),
251               agent_s2k_calibration=$withval, agent_s2k_calibration=100)
252 AC_MSG_RESULT($agent_s2k_calibration milliseconds)
253 AC_DEFINE_UNQUOTED(AGENT_S2K_CALIBRATION, $agent_s2k_calibration,
254                    [Agent s2k calibration time (ms)])
255
256 AC_MSG_CHECKING([whether to enable trust models])
257 AC_ARG_ENABLE(trust-models,
258               AC_HELP_STRING([--disable-trust-models],
259                              [disable all trust models except "always"]),
260               use_trust_models=$enableval)
261 AC_MSG_RESULT($use_trust_models)
262 if test "$use_trust_models" = no ; then
263     AC_DEFINE(NO_TRUST_MODELS, 1,
264              [Define to include only trust-model always])
265 fi
266
267 AC_MSG_CHECKING([whether to enable TOFU])
268 AC_ARG_ENABLE(tofu,
269                 AC_HELP_STRING([--disable-tofu],
270                                [disable the TOFU trust model]),
271               use_tofu=$enableval, use_tofu=$use_trust_models)
272 AC_MSG_RESULT($use_tofu)
273 if test "$use_trust_models" = no && test "$use_tofu" = yes; then
274     AC_MSG_ERROR([both --disable-trust-models and --enable-tofu given])
275 fi
276
277 AC_MSG_CHECKING([whether to enable libdns])
278 AC_ARG_ENABLE(libdns,
279                 AC_HELP_STRING([--disable-libdns],
280                                [do not build with libdns support]),
281               use_libdns=$enableval, use_libdns=yes)
282 AC_MSG_RESULT($use_libdns)
283 if test x"$use_libdns" = xyes ; then
284     AC_DEFINE(USE_LIBDNS, 1, [Build with integrated libdns support])
285 fi
286 AM_CONDITIONAL(USE_LIBDNS, test "$use_libdns" = yes)
287
288
289 #
290 # Options to disable algorithm
291 #
292
293 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
294 # Elgamal is a MUST algorithm
295 # DSA is a MUST algorithm
296 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
297 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
298 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
299
300 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
301 # 3DES is a MUST algorithm
302 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
303 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
304 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
305 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
306 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
307 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
308 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
309 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
310 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
311
312 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
313 # SHA1 is a MUST algorithm
314 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
315 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
316 # SHA256 is a MUST algorithm for GnuPG.
317 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
318 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
319
320
321 # Allow disabling of zip support.
322 # This is in general not a good idea because according to rfc4880 OpenPGP
323 # implementations SHOULD support ZLIB.
324 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
325 AC_ARG_ENABLE(zip,
326    AC_HELP_STRING([--disable-zip],
327                   [disable the ZIP and ZLIB compression algorithm]),
328    use_zip=$enableval)
329 AC_MSG_RESULT($use_zip)
330
331 # Allow disabling of bzib2 support.
332 # It is defined only after we confirm the library is available later
333 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
334 AC_ARG_ENABLE(bzip2,
335    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
336    use_bzip2=$enableval)
337 AC_MSG_RESULT($use_bzip2)
338
339 # Configure option to allow or disallow execution of external
340 # programs, like a photo viewer.
341 AC_MSG_CHECKING([whether to enable external program execution])
342 AC_ARG_ENABLE(exec,
343     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
344     use_exec=$enableval)
345 AC_MSG_RESULT($use_exec)
346 if test "$use_exec" = no ; then
347     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
348 fi
349
350 if test "$use_exec" = yes ; then
351   AC_MSG_CHECKING([whether to enable photo ID viewing])
352   AC_ARG_ENABLE(photo-viewers,
353       [  --disable-photo-viewers disable photo ID viewers],
354       [if test "$enableval" = no ; then
355          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
356       fi],enableval=yes)
357   gnupg_cv_enable_photo_viewers=$enableval
358   AC_MSG_RESULT($enableval)
359
360   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
361     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
362     AC_ARG_WITH(photo-viewer,
363         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
364         [if test "$withval" = yes ; then
365            withval=no
366         elif test "$withval" != no ; then
367            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
368                             [if set, restrict photo-viewer to this])
369         fi],withval=no)
370     AC_MSG_RESULT($withval)
371   fi
372 fi
373
374
375 #
376 # Check for the key/uid cache size.  This can't be zero, but can be
377 # pretty small on embedded systems.  This is used for the gpg part.
378 #
379 AC_MSG_CHECKING([for the size of the key and uid cache])
380 AC_ARG_ENABLE(key-cache,
381         AC_HELP_STRING([--enable-key-cache=SIZE],
382                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
383 if test "$enableval" = "no"; then
384    enableval=5
385 elif test "$enableval" = "yes" || test "$enableval" = ""; then
386    enableval=4096
387 fi
388 changequote(,)dnl
389 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
390 changequote([,])dnl
391 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
392    AC_MSG_ERROR([invalid key-cache size])
393 fi
394 AC_MSG_RESULT($key_cache_size)
395 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
396                   [Size of the key and UID caches])
397
398
399
400 #
401 # Check whether we want to use Linux capabilities
402 #
403 AC_MSG_CHECKING([whether use of capabilities is requested])
404 AC_ARG_WITH(capabilities,
405     [  --with-capabilities     use linux capabilities [default=no]],
406 [use_capabilities="$withval"],[use_capabilities=no])
407 AC_MSG_RESULT($use_capabilities)
408
409 #
410 # Check whether to disable the card support
411 AC_MSG_CHECKING([whether smartcard support is requested])
412 AC_ARG_ENABLE(card-support,
413               AC_HELP_STRING([--disable-card-support],
414                              [disable smartcard support]),
415               card_support=$enableval)
416 AC_MSG_RESULT($card_support)
417 if test "$card_support" = yes ; then
418   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
419 else
420   build_scdaemon=no
421 fi
422
423 #
424 # Allow disabling of internal CCID support.
425 # It is defined only after we confirm the library is available later
426 #
427 AC_MSG_CHECKING([whether to enable the internal CCID driver])
428 AC_ARG_ENABLE(ccid-driver,
429               AC_HELP_STRING([--disable-ccid-driver],
430                              [disable the internal CCID driver]),
431               use_ccid_driver=$enableval)
432 AC_MSG_RESULT($use_ccid_driver)
433
434 AC_MSG_CHECKING([whether to auto start dirmngr])
435 AC_ARG_ENABLE(dirmngr-auto-start,
436               AC_HELP_STRING([--disable-dirmngr-auto-start],
437                              [disable auto starting of the dirmngr]),
438               dirmngr_auto_start=$enableval)
439 AC_MSG_RESULT($dirmngr_auto_start)
440 if test "$dirmngr_auto_start" = yes ; then
441     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
442               [Define to enable auto starting of the dirmngr])
443 fi
444
445
446 #
447 # To avoid double inclusion of config.h which might happen at some
448 # places, we add the usual double inclusion protection at the top of
449 # config.h.
450 #
451 AH_TOP([
452 #ifndef GNUPG_CONFIG_H_INCLUDED
453 #define GNUPG_CONFIG_H_INCLUDED
454 ])
455
456 #
457 # Stuff which goes at the bottom of config.h.
458 #
459 AH_BOTTOM([
460 /* This is the major version number of GnuPG so that
461    source included files can test for this.  Note, that
462    we use 2 here even for GnuPG 1.9.x. */
463 #define GNUPG_MAJOR_VERSION 2
464
465 /* Now to separate file name parts.
466    Please note that the string version must not contain more
467    than one character because the code assumes strlen()==1 */
468 #ifdef HAVE_DOSISH_SYSTEM
469 #define DIRSEP_C '\\'
470 #define DIRSEP_S "\\"
471 #define EXTSEP_C '.'
472 #define EXTSEP_S "."
473 #define PATHSEP_C ';'
474 #define PATHSEP_S ";"
475 #define EXEEXT_S ".exe"
476 #else
477 #define DIRSEP_C '/'
478 #define DIRSEP_S "/"
479 #define EXTSEP_C '.'
480 #define EXTSEP_S "."
481 #define PATHSEP_C ':'
482 #define PATHSEP_S ":"
483 #define EXEEXT_S ""
484 #endif
485
486 /* This is the same as VERSION, but should be overridden if the
487    platform cannot handle things like dots '.' in filenames. Set
488    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
489    uses for dots and dashes. */
490 #define SAFE_VERSION VERSION
491 #define SAFE_VERSION_DOT  '.'
492 #define SAFE_VERSION_DASH '-'
493
494 /* Some global constants.
495  * Note that the homedir must not end in a slash.  */
496 #ifdef HAVE_DOSISH_SYSTEM
497 # ifdef HAVE_DRIVE_LETTERS
498 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
499 # else
500 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
501 # endif
502 #elif defined(__VMS)
503 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
504 #else
505 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
506 #endif
507 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
508 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
509
510 /* For some systems (DOS currently), we hardcode the path here.  For
511    POSIX systems the values are constructed by the Makefiles, so that
512    the values may be overridden by the make invocations; this is to
513    comply with the GNU coding standards.  Note that these values are
514    only defaults.  */
515 #ifdef HAVE_DOSISH_SYSTEM
516 # ifdef HAVE_DRIVE_LETTERS
517 #  define GNUPG_BINDIR      "c:\\gnupg"
518 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
519 #  define GNUPG_LIBDIR      "c:\\gnupg"
520 #  define GNUPG_DATADIR     "c:\\gnupg"
521 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
522 # else
523 #  define GNUPG_BINDIR      "\\gnupg"
524 #  define GNUPG_LIBEXECDIR  "\\gnupg"
525 #  define GNUPG_LIBDIR      "\\gnupg"
526 #  define GNUPG_DATADIR     "\\gnupg"
527 #  define GNUPG_SYSCONFDIR  "\\gnupg"
528 # endif
529 #endif
530
531 /* Derive some other constants. */
532 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
533 #define EXEC_TEMPFILE_ONLY
534 #endif
535
536
537 /* We didn't define endianness above, so get it from OS macros.  This
538    is intended for making fat binary builds on OS X. */
539 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
540 #if defined(__BIG_ENDIAN__)
541 #define BIG_ENDIAN_HOST 1
542 #elif defined(__LITTLE_ENDIAN__)
543 #define LITTLE_ENDIAN_HOST 1
544 #else
545 #error "No endianness found"
546 #endif
547 #endif
548
549
550 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
551    ldap_start_tls_s because that is the actual symbol used in the
552    library.  winldap.h redefines it to our commonly used value,
553    thus we define our usual macro here.  */
554 #ifdef HAVE_LDAP_START_TLS_SA
555 # ifndef HAVE_LDAP_START_TLS_S
556 #  define HAVE_LDAP_START_TLS_S 1
557 # endif
558 #endif
559
560 /* Provide the es_ macro for estream.  */
561 #define GPGRT_ENABLE_ES_MACROS 1
562
563 /* Tell libgcrypt not to use its own libgpg-error implementation. */
564 #define USE_LIBGPG_ERROR 1
565
566 /* Tell Libgcrypt not to include deprecated definitions.  */
567 #define GCRYPT_NO_DEPRECATED 1
568
569 /* Our HTTP code is used in estream mode.  */
570 #define HTTP_USE_ESTREAM 1
571
572 /* Under W32 we do an explicit socket initialization, thus we need to
573    avoid the on-demand initialization which would also install an atexit
574    handler.  */
575 #define HTTP_NO_WSASTARTUP
576
577 /* Under Windows we use the gettext code from libgpg-error.  */
578 #define GPG_ERR_ENABLE_GETTEXT_MACROS
579
580 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
581 #define GPG_ERR_ENABLE_ERRNO_MACROS
582
583 #endif /*GNUPG_CONFIG_H_INCLUDED*/
584 ])
585
586
587 AM_MAINTAINER_MODE
588 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
589
590 # Checks for programs.
591 AC_MSG_NOTICE([checking for programs])
592 AC_PROG_MAKE_SET
593 AM_SANITY_CHECK
594 missing_dir=`cd $ac_aux_dir && pwd`
595 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
596 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
597 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
598 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
599 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
600 AM_SILENT_RULES
601 AC_PROG_AWK
602 AC_PROG_CC
603 AC_PROG_CPP
604 AM_PROG_CC_C_O
605 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
606   AC_MSG_ERROR([[No C-89 compiler found]])
607 fi
608 AC_PROG_INSTALL
609 AC_PROG_LN_S
610 AC_PROG_RANLIB
611 AC_CHECK_TOOL(AR, ar, :)
612 AC_PATH_PROG(PERL,"perl")
613 AC_CHECK_TOOL(WINDRES, windres, :)
614 AC_PATH_PROG(YAT2M, "yat2m", "./yat2m" )
615 AC_ARG_VAR(YAT2M, [tool to convert texi to man pages])
616 AC_ISC_POSIX
617 AC_SYS_LARGEFILE
618 GNUPG_CHECK_USTAR
619
620
621 # We need to compile and run a program on the build machine.  A
622 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
623 # the AC archive is broken for autoconf 2.57.  Given that there is no
624 # newer version of that macro, we assume that it is also broken for
625 # autoconf 2.61 and thus we use a simple but usually sufficient
626 # approach.
627 AC_MSG_CHECKING(for cc for build)
628 if test "$cross_compiling" = "yes"; then
629   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
630 else
631   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
632 fi
633 AC_MSG_RESULT($CC_FOR_BUILD)
634 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
635
636 # We need to call this macro because other pkg-config macros are
637 # not always used.
638 PKG_PROG_PKG_CONFIG
639
640
641 try_gettext=yes
642 require_iconv=yes
643 have_dosish_system=no
644 have_w32_system=no
645 have_w32ce_system=no
646 have_android_system=no
647 use_simple_gettext=no
648 use_ldapwrapper=yes
649 mmap_needed=yes
650 case "${host}" in
651     *-mingw32*)
652         # special stuff for Windoze NT
653         ac_cv_have_dev_random=no
654         AC_DEFINE(USE_ONLY_8DOT3,1,
655                   [Set this to limit filenames to the 8.3 format])
656         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
657                   [Because the Unix gettext has too much overhead on
658                    MingW32 systems and these systems lack Posix functions,
659                    we use a simplified version of gettext])
660         have_dosish_system=yes
661         have_w32_system=yes
662         require_iconv=no
663         use_ldapwrapper=no  # Fixme: Do this only for CE.
664         case "${host}" in
665           *-mingw32ce*)
666             have_w32ce_system=yes
667             ;;
668           *)
669             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
670                       [Defined if the OS supports drive letters.])
671             ;;
672         esac
673         try_gettext="no"
674         use_simple_gettext=yes
675         mmap_needed=no
676         ;;
677     i?86-emx-os2 | i?86-*-os2*emx )
678         # OS/2 with the EMX environment
679         ac_cv_have_dev_random=no
680         AC_DEFINE(HAVE_DRIVE_LETTERS)
681         have_dosish_system=yes
682         try_gettext="no"
683         ;;
684
685     i?86-*-msdosdjgpp*)
686         # DOS with the DJGPP environment
687         ac_cv_have_dev_random=no
688         AC_DEFINE(HAVE_DRIVE_LETTERS)
689         have_dosish_system=yes
690         try_gettext="no"
691         ;;
692
693     *-*-hpux*)
694         if test -z "$GCC" ; then
695             CFLAGS="-Ae -D_HPUX_SOURCE $CFLAGS"
696         fi
697         ;;
698     *-dec-osf4*)
699         if test -z "$GCC" ; then
700             # Suppress all warnings
701             # to get rid of the unsigned/signed char mismatch warnings.
702             CFLAGS="-w $CFLAGS"
703         fi
704         ;;
705     *-dec-osf5*)
706         if test -z "$GCC" ; then
707             # Use the newer compiler `-msg_disable ptrmismatch1' to
708             # get rid of the unsigned/signed char mismatch warnings.
709             # Using this may hide other pointer mismatch warnings, but
710             # it at least lets other warning classes through
711             CFLAGS="-msg_disable ptrmismatch1 $CFLAGS"
712         fi
713         ;;
714     m68k-atari-mint)
715         ;;
716     *-linux-android*)
717         have_android_system=yes
718         # Android is fully utf-8 and we do not want to use iconv to
719         # keeps things simple
720         require_iconv=no
721         ;;
722     *-apple-darwin*)
723         AC_DEFINE(_DARWIN_C_SOURCE, 900000L,
724                   Expose all libc features (__DARWIN_C_FULL).)
725         ;;
726     *)
727        ;;
728 esac
729
730 if test "$have_dosish_system" = yes; then
731    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
732              [Defined if we run on some of the PCDOS like systems
733               (DOS, Windoze. OS/2) with special properties like
734               no file modes, case insensitive file names and preferred
735               use of backslashes as directory name separators.])
736 fi
737 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
738
739 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
740
741 if test "$have_w32_system" = yes; then
742    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
743    if test "$have_w32ce_system" = yes; then
744       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
745    fi
746 fi
747 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
748 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
749
750 if test "$have_android_system" = yes; then
751    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
752 fi
753 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
754
755
756 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
757 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
758
759
760 #
761 # Checks for libraries.
762 #
763 AC_MSG_NOTICE([checking for libraries])
764
765
766 #
767 # libgpg-error is a library with error codes shared between GnuPG
768 # related projects.
769 #
770 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
771                   have_gpg_error=yes,have_gpg_error=no)
772
773
774 #
775 # Libgcrypt is our generic crypto library
776 #
777 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
778         have_libgcrypt=yes,have_libgcrypt=no)
779
780
781 #
782 # libassuan is used for IPC
783 #
784 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
785                   have_libassuan=yes,have_libassuan=no)
786 if test "$have_libassuan" = "yes"; then
787   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
788                      [version of the libassuan library])
789   show_tor_support="only .onion"
790 fi
791
792
793 #
794 # libksba is our X.509 support library
795 #
796 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
797
798
799 #
800 # libusb allows us to use the integrated CCID smartcard reader driver.
801 #
802 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
803 if test "$use_ccid_driver" = auto || test "$use_ccid_driver" = yes; then
804    case "${host}" in
805      *-mingw32*)
806        LIBUSB_NAME=
807        LIBUSB_LIBS=
808        LIBUSB_CPPFLAGS=
809        ;;
810      *-*-darwin*)
811        LIBUSB_NAME=usb-1.0
812        LIBUSB_LIBS="-Wl,-framework,CoreFoundation -Wl,-framework,IOKit"
813        ;;
814      *-*-freebsd*)
815        # FreeBSD has a native 1.0 compatible library by -lusb.
816        LIBUSB_NAME=usb
817        LIBUSB_LIBS=
818        ;;
819      *)
820        LIBUSB_NAME=usb-1.0
821        LIBUSB_LIBS=
822        ;;
823    esac
824 fi
825 if test x"$LIBUSB_NAME" != x ; then
826    AC_CHECK_LIB($LIBUSB_NAME, libusb_init,
827                 [ LIBUSB_LIBS="-l$LIBUSB_NAME $LIBUSB_LIBS"
828                   have_libusb=yes ])
829    AC_MSG_CHECKING([libusb include dir])
830    usb_incdir_found="no"
831    for _incdir in "" "/usr/include/libusb-1.0" "/usr/local/include/libusb-1.0"; do
832      _libusb_save_cppflags=$CPPFLAGS
833      if test -n "${_incdir}"; then
834        CPPFLAGS="-I${_incdir} ${CPPFLAGS}"
835      fi
836      AC_PREPROC_IFELSE([AC_LANG_SOURCE([[@%:@include <libusb.h>]])],
837      [usb_incdir=${_incdir}; usb_incdir_found="yes"], [])
838      CPPFLAGS=${_libusb_save_cppflags}
839      if test "$usb_incdir_found" = "yes"; then
840        break
841      fi
842    done
843    if test "$usb_incdir_found" = "yes"; then
844      AC_MSG_RESULT([${usb_incdir}])
845    else
846      AC_MSG_RESULT([not found])
847      usb_incdir=""
848      have_libusb=no
849      if test "$use_ccid_driver" != yes; then
850        use_ccid_driver=no
851      fi
852      LIBUSB_LIBS=""
853    fi
854
855    if test "$have_libusb" = yes; then
856      AC_DEFINE(HAVE_LIBUSB,1, [defined if libusb is available])
857    fi
858    if test x"$usb_incdir" = x; then
859      LIBUSB_CPPFLAGS=""
860    else
861      LIBUSB_CPPFLAGS="-I${usb_incdir}"
862    fi
863 fi
864 AC_SUBST(LIBUSB_LIBS)
865 AC_SUBST(LIBUSB_CPPFLAGS)
866
867 #
868 # Check whether it is necessary to link against libdl.
869 # (For example to load libpcsclite)
870 #
871 gnupg_dlopen_save_libs="$LIBS"
872 LIBS=""
873 AC_SEARCH_LIBS(dlopen, c dl,,,)
874 DL_LIBS=$LIBS
875 AC_SUBST(DL_LIBS)
876 LIBS="$gnupg_dlopen_save_libs"
877
878
879 # Checks for g10
880
881 AC_ARG_ENABLE(sqlite,
882                 AC_HELP_STRING([--disable-sqlite],
883                                [disable the use of SQLITE]),
884               try_sqlite=$enableval, try_sqlite=yes)
885
886 if test x"$use_tofu" = xyes ; then
887   if test x"$try_sqlite" = xyes ; then
888     PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $NEED_SQLITE_VERSION],
889                                  [have_sqlite=yes],
890                                  [have_sqlite=no])
891   fi
892   if test "$have_sqlite" = "yes"; then
893     :
894     AC_SUBST([SQLITE3_CFLAGS])
895     AC_SUBST([SQLITE3_LIBS])
896   else
897     use_tofu=no
898     tmp=$(echo "$SQLITE3_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
899     AC_MSG_WARN([[
900 ***
901 *** Building without SQLite support - TOFU disabled
902 ***
903 *** $tmp]])
904   fi
905 fi
906
907 AM_CONDITIONAL(SQLITE3, test "$have_sqlite" = "yes")
908
909 if test x"$use_tofu" = xyes ; then
910     AC_DEFINE(USE_TOFU, 1, [Enable to build the TOFU code])
911 fi
912
913
914 # Checks for g13
915
916 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
917 AC_DEFINE_UNQUOTED(ENCFS,
918         "${ENCFS}", [defines the filename of the encfs program])
919
920 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
921 AC_DEFINE_UNQUOTED(FUSERMOUNT,
922         "${FUSERMOUNT}", [defines the filename of the fusermount program])
923
924
925 # Checks for dirmngr
926
927
928 #
929 # Checks for symcryptrun:
930 #
931
932 # libutil has openpty() and login_tty().
933 AC_CHECK_LIB(util, openpty,
934               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
935                 AC_DEFINE(HAVE_LIBUTIL,1,
936                          [defined if libutil is available])
937              ])
938 AC_SUBST(LIBUTIL_LIBS)
939
940 # shred is used to clean temporary plain text files.
941 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
942 AC_DEFINE_UNQUOTED(SHRED,
943         "${SHRED}", [defines the filename of the shred program])
944
945
946 #
947 # Check whether the nPth library is available
948 #
949 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
950 if test "$have_npth" = "yes"; then
951   AC_DEFINE(HAVE_NPTH, 1,
952               [Defined if the New Portable Thread Library is available])
953   AC_DEFINE(USE_NPTH, 1,
954               [Defined if support for nPth is requested and nPth is available])
955 else
956   AC_MSG_WARN([[
957 ***
958 *** To support concurrent access for example in gpg-agent and the SCdaemon
959 *** we need the support of the New Portable Threads Library.
960 ***]])
961 fi
962
963
964 #
965 # NTBTLS is our TLS library.  If it is not available fallback to
966 # GNUTLS.
967 #
968 AC_ARG_ENABLE(ntbtls,
969               AC_HELP_STRING([--disable-ntbtls],
970                              [disable the use of NTBTLS as TLS library]),
971               try_ntbtls=$enableval, try_ntbtls=yes)
972 if test x"$try_ntbtls" = xyes ; then
973   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
974                  [have_ntbtls=yes],[have_ntbtls=no])
975 fi
976 if test "$have_ntbtls" = yes ; then
977    use_tls_library=ntbtls
978    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
979 else
980   AC_ARG_ENABLE(gnutls,
981                 AC_HELP_STRING([--disable-gnutls],
982                                [disable GNUTLS as fallback TLS library]),
983                 try_gnutls=$enableval, try_gnutls=yes)
984   if test x"$try_gnutls" = xyes ; then
985     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
986                                    [have_gnutls=yes],
987                                    [have_gnutls=no])
988   fi
989   if test "$have_gnutls" = "yes"; then
990     AC_SUBST([LIBGNUTLS_CFLAGS])
991     AC_SUBST([LIBGNUTLS_LIBS])
992     use_tls_library=gnutls
993     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
994   else
995     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
996     AC_MSG_WARN([[
997 ***
998 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
999 ***
1000 *** $tmp]])
1001   fi
1002 fi
1003
1004 #
1005 # Allow to set a fixed trust store file for system provided certificates.
1006 #
1007 AC_ARG_WITH([default-trust-store-file],
1008             [AC_HELP_STRING([--with-default-trust-store-file=FILE],
1009                             [Use FILE as system trust store])],
1010             default_trust_store_file="$withval",
1011             default_trust_store_file="")
1012 if test x"$default_trust_store_file" = xno;then
1013   default_trust_store_file=""
1014 fi
1015 if test x"$default_trust_store_file" != x ; then
1016   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
1017     ["$default_trust_store_file"], [Use as default system trust store file])
1018 fi
1019
1020
1021 AC_MSG_NOTICE([checking for networking options])
1022
1023 #
1024 # Must check for network library requirements before doing link tests
1025 # for ldap, for example. If ldap libs are static (or dynamic and without
1026 # ELF runtime link paths), then link will fail and LDAP support won't
1027 # be detected.
1028 #
1029 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
1030         [NETLIBS="-lnsl $NETLIBS"]))
1031 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
1032         [NETLIBS="-lsocket $NETLIBS"]))
1033
1034
1035 #
1036 # Check standard resolver functions.
1037 #
1038 if test "$build_dirmngr" = "yes"; then
1039   _dns_save_libs=$LIBS
1040   LIBS=""
1041
1042   # Find the system resolver which can always be enabled with
1043   # the dirmngr option --standard-resolver.
1044
1045   # the double underscore thing is a glibc-ism?
1046   AC_SEARCH_LIBS(res_query,resolv bind,,
1047                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
1048   AC_SEARCH_LIBS(dn_expand,resolv bind,,
1049                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
1050
1051   # macOS renames dn_skipname into res_9_dn_skipname in <resolv.h>,
1052   # and for some reason fools us into believing we don't need
1053   # -lresolv even if we do.  Since the test program checking for the
1054   # symbol does not include <resolv.h>, we need to check for the
1055   # renamed symbol explicitly.
1056   AC_SEARCH_LIBS(res_9_dn_skipname,resolv bind,,
1057       AC_SEARCH_LIBS(dn_skipname,resolv bind,,
1058           AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no)))
1059
1060   if test x"$have_resolver" != xno ; then
1061
1062       # Make sure that the BIND 4 resolver interface is workable before
1063       # enabling any code that calls it.  At some point I'll rewrite the
1064       # code to use the BIND 8 resolver API.
1065       # We might also want to use libdns instead.
1066
1067     AC_MSG_CHECKING([whether the resolver is usable])
1068     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1069 #include <netinet/in.h>
1070 #include <arpa/nameser.h>
1071 #include <resolv.h>]],
1072 [[unsigned char answer[PACKETSZ];
1073   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1074   dn_skipname(0,0);
1075   dn_expand(0,0,0,0,0);
1076 ]])],have_resolver=yes,have_resolver=no)
1077     AC_MSG_RESULT($have_resolver)
1078
1079     # This is Apple-specific and somewhat bizarre as they changed the
1080     # define in bind 8 for some reason.
1081
1082     if test x"$have_resolver" != xyes ; then
1083       AC_MSG_CHECKING(
1084            [whether I can make the resolver usable with BIND_8_COMPAT])
1085       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
1086 #include <sys/types.h>
1087 #include <netinet/in.h>
1088 #include <arpa/nameser.h>
1089 #include <resolv.h>]],
1090 [[unsigned char answer[PACKETSZ];
1091   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1092   dn_skipname(0,0); dn_expand(0,0,0,0,0);
1093 ]])],[have_resolver=yes ; need_compat=yes])
1094       AC_MSG_RESULT($have_resolver)
1095     fi
1096   fi
1097
1098   if test x"$have_resolver" = xyes ; then
1099     AC_DEFINE(HAVE_SYSTEM_RESOLVER,1,[The system's resolver is usable.])
1100     DNSLIBS="$DNSLIBS $LIBS"
1101     if test x"$need_compat" = xyes ; then
1102       AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
1103     fi
1104     if test "$use_libdns" = yes; then
1105      show_tor_support=yes
1106     fi
1107   elif test "$use_libdns" = yes; then
1108     show_tor_support=yes
1109   else
1110     AC_MSG_WARN([[
1111 ***
1112 *** The system's DNS resolver is not usable.
1113 *** Dirmngr functionality is limited.
1114 ***]])
1115     show_tor_support="${show_tor_support} (no system resolver)"
1116   fi
1117
1118   if test "$have_w32_system" = yes; then
1119     if test "$use_libdns" = yes; then
1120       DNSLIBS="$DNSLIBS -liphlpapi"
1121     fi
1122   fi
1123
1124   LIBS=$_dns_save_libs
1125 fi
1126
1127 AC_SUBST(DNSLIBS)
1128
1129
1130 #
1131 # Check for LDAP
1132 #
1133 # Note that running the check changes the variable
1134 # gnupg_have_ldap from "n/a" to "no" or "yes".
1135
1136 AC_ARG_ENABLE(ldap,
1137     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1138     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1139
1140 if test "$gnupg_have_ldap" != "no" ; then
1141   if test "$build_dirmngr" = "yes" ; then
1142      GNUPG_CHECK_LDAP($NETLIBS)
1143      AC_CHECK_LIB(lber, ber_free,
1144                   [ LBER_LIBS="$LBER_LIBS -llber"
1145                     AC_DEFINE(HAVE_LBER,1,
1146                              [defined if liblber is available])
1147                     have_lber=yes
1148                  ])
1149   fi
1150 fi
1151 AC_SUBST(LBER_LIBS)
1152 if test "$gnupg_have_ldap" = "no"; then
1153     AC_MSG_WARN([[
1154 ***
1155 *** Building without LDAP support.
1156 *** No CRL access or X.509 certificate search available.
1157 ***]])
1158 fi
1159
1160 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1161 if test "$gnupg_have_ldap" = yes ; then
1162   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1163 else
1164  use_ldapwrapper=no
1165 fi
1166
1167 if test "$use_ldapwrapper" = yes; then
1168    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1169 fi
1170 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1171
1172
1173
1174
1175 #
1176 # Check for sendmail
1177 #
1178 # This isn't necessarily sendmail itself, but anything that gives a
1179 # sendmail-ish interface to the outside world.  That includes Exim,
1180 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1181 AC_ARG_WITH(mailprog,
1182       AC_HELP_STRING([--with-mailprog=NAME],
1183                      [use "NAME -t" for mail transport]),
1184              ,with_mailprog=yes)
1185 if test x"$with_mailprog" = xyes ; then
1186     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1187 elif test x"$with_mailprog" != xno ; then
1188     AC_MSG_CHECKING([for a mail transport program])
1189     AC_SUBST(SENDMAIL,$with_mailprog)
1190     AC_MSG_RESULT($with_mailprog)
1191 fi
1192
1193
1194 #
1195 # Construct a printable name of the OS
1196 #
1197 case "${host}" in
1198     *-mingw32ce*)
1199         PRINTABLE_OS_NAME="W32CE"
1200         ;;
1201     *-mingw32*)
1202         PRINTABLE_OS_NAME="MingW32"
1203         ;;
1204     *-*-cygwin*)
1205         PRINTABLE_OS_NAME="Cygwin"
1206         ;;
1207     i?86-emx-os2 | i?86-*-os2*emx )
1208         PRINTABLE_OS_NAME="OS/2"
1209         ;;
1210     i?86-*-msdosdjgpp*)
1211         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1212         try_dynload=no
1213         ;;
1214     *-linux*)
1215         PRINTABLE_OS_NAME="GNU/Linux"
1216         ;;
1217     *)
1218         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1219         ;;
1220 esac
1221 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1222                    [A human readable text with the name of the OS])
1223
1224
1225 #
1226 # Checking for iconv
1227 #
1228 if test "$require_iconv" = yes; then
1229   AM_ICONV
1230 else
1231   LIBICONV=
1232   LTLIBICONV=
1233   AC_SUBST(LIBICONV)
1234   AC_SUBST(LTLIBICONV)
1235 fi
1236
1237
1238 #
1239 # Check for gettext
1240 #
1241 # This is "GNU gnupg" - The project-id script from gettext
1242 #                       needs this string
1243 #
1244 AC_MSG_NOTICE([checking for gettext])
1245 AM_PO_SUBDIRS
1246 AM_GNU_GETTEXT_VERSION([0.17])
1247 if test "$try_gettext" = yes; then
1248   AM_GNU_GETTEXT([external],[need-ngettext])
1249
1250   # gettext requires some extra checks.  These really should be part of
1251   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1252   # function checks to here.
1253
1254   AC_CHECK_FUNCS(strchr)
1255 else
1256   USE_NLS=no
1257   USE_INCLUDED_LIBINTL=no
1258   BUILD_INCLUDED_LIBINTL=no
1259   POSUB=po
1260   AC_SUBST(USE_NLS)
1261   AC_SUBST(USE_INCLUDED_LIBINTL)
1262   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1263   AC_SUBST(POSUB)
1264 fi
1265
1266 # We use HAVE_LANGINFO_CODESET in a couple of places.
1267 AM_LANGINFO_CODESET
1268
1269 # Checks required for our use of locales
1270 gt_LC_MESSAGES
1271
1272
1273 #
1274 # SELinux support
1275 #
1276 if test "$selinux_support" = yes ; then
1277   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1278 fi
1279
1280
1281 #
1282 # Checks for header files.
1283 #
1284 AC_MSG_NOTICE([checking for header files])
1285 AC_HEADER_STDC
1286 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1287                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h     \
1288                   stdint.h signal.h util.h libutil.h termios.h \
1289                   ucred.h sys/sysmacros.h sys/mkdev.h])
1290
1291 AC_HEADER_TIME
1292
1293
1294 #
1295 # Checks for typedefs, structures, and compiler characteristics.
1296 #
1297 AC_MSG_NOTICE([checking for system characteristics])
1298 AC_C_CONST
1299 AC_C_INLINE
1300 AC_C_VOLATILE
1301 AC_TYPE_SIZE_T
1302 AC_TYPE_MODE_T
1303 AC_TYPE_SIGNAL
1304 AC_DECL_SYS_SIGLIST
1305
1306 gl_HEADER_SYS_SOCKET
1307 gl_TYPE_SOCKLEN_T
1308
1309 AC_SEARCH_LIBS([inet_addr], [nsl])
1310
1311 AC_ARG_ENABLE(endian-check,
1312               AC_HELP_STRING([--disable-endian-check],
1313               [disable the endian check and trust the OS provided macros]),
1314               endiancheck=$enableval,endiancheck=yes)
1315
1316 if test x"$endiancheck" = xyes ; then
1317   GNUPG_CHECK_ENDIAN
1318 fi
1319
1320 # fixme: we should get rid of the byte type
1321 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1322 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1323 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1324 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1325 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1326
1327 AC_CHECK_SIZEOF(unsigned short)
1328 AC_CHECK_SIZEOF(unsigned int)
1329 AC_CHECK_SIZEOF(unsigned long)
1330 AC_CHECK_SIZEOF(unsigned long long)
1331 AC_HEADER_TIME
1332 AC_CHECK_SIZEOF(time_t,,[[
1333 #include <stdio.h>
1334 #if TIME_WITH_SYS_TIME
1335 # include <sys/time.h>
1336 # include <time.h>
1337 #else
1338 # if HAVE_SYS_TIME_H
1339 #  include <sys/time.h>
1340 # else
1341 #  include <time.h>
1342 # endif
1343 #endif
1344 ]])
1345 GNUPG_TIME_T_UNSIGNED
1346
1347
1348 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1349    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1350    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1351     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1352 fi
1353
1354
1355 #
1356 # Checks for library functions.
1357 #
1358 AC_MSG_NOTICE([checking for library functions])
1359 AC_CHECK_DECLS(getpagesize)
1360 AC_FUNC_FSEEKO
1361 AC_FUNC_VPRINTF
1362 AC_FUNC_FORK
1363 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1364 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1365 AC_CHECK_FUNCS([setenv unsetenv fcntl ftruncate inet_ntop])
1366 AC_CHECK_FUNCS([canonicalize_file_name])
1367 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1368 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1369 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1370 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1371 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1372                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1373                 flockfile funlockfile getpwnam getpwuid \
1374                 getenv inet_pton strpbrk])
1375
1376 # On some systems (e.g. Solaris) nanosleep requires linking to librl.
1377 # Given that we use nanosleep only as an optimization over a select
1378 # based wait function we want it only if it is available in libc.
1379 _save_libs="$LIBS"
1380 AC_SEARCH_LIBS([nanosleep], [],
1381                [AC_DEFINE(HAVE_NANOSLEEP,1,
1382                 [Define to 1 if you have the `nanosleep' function in libc.])])
1383 LIBS="$_save_libs"
1384
1385
1386 # See whether libc supports the Linux inotify interface
1387 case "${host}" in
1388     *-*-linux*)
1389         AC_CHECK_FUNCS([inotify_init])
1390         ;;
1391 esac
1392
1393
1394 if test "$have_android_system" = yes; then
1395    # On Android ttyname is a stub but prints an error message.
1396    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1397              [Defined if ttyname does not work properly])
1398 fi
1399
1400 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1401
1402 # Dirmngr requires mmap on Unix systems.
1403 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1404   AC_MSG_ERROR([[Sorry, the current implementation requires mmap.]])
1405 fi
1406
1407
1408 #
1409 # Check for the getsockopt SO_PEERCRED, etc.
1410 #
1411 AC_CHECK_MEMBERS([struct ucred.pid, struct ucred.cr_pid, struct sockpeercred.pid], [], [], [#include <sys/types.h>
1412 #include <sys/socket.h> ])
1413
1414 # (Open)Solaris
1415 AC_CHECK_FUNCS([getpeerucred])
1416
1417
1418 #
1419 # W32 specific test
1420 #
1421 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1422
1423 #
1424 # Sanity check regex.  Tests adapted from mutt.
1425 #
1426 AC_MSG_CHECKING([whether regular expression support is requested])
1427 AC_ARG_ENABLE(regex,
1428   AC_HELP_STRING([--disable-regex],
1429     [do not handle regular expressions in trust signatures]),
1430   use_regex=$enableval, use_regex=yes)
1431 AC_MSG_RESULT($use_regex)
1432
1433 if test "$use_regex" = yes ; then
1434   _cppflags="${CPPFLAGS}"
1435   _ldflags="${LDFLAGS}"
1436   AC_ARG_WITH(regex,
1437      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1438       [
1439       if test -d "$withval" ; then
1440         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1441         LDFLAGS="${LDFLAGS} -L$withval/lib"
1442       fi
1443       ],withval="")
1444
1445   # Does the system have regex functions at all?
1446   AC_SEARCH_LIBS([regcomp], [regex])
1447   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1448
1449   if test $gnupg_cv_have_regex = no; then
1450     use_regex=no
1451   else
1452     if test x"$cross_compiling" = xyes; then
1453       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1454     else
1455       AC_CACHE_CHECK([whether your system's regexp library is broken],
1456        [gnupg_cv_regex_broken],
1457        AC_TRY_RUN([
1458 #include <unistd.h>
1459 #include <regex.h>
1460 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1461        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1462
1463       if test $gnupg_cv_regex_broken = yes; then
1464         AC_MSG_WARN([your regex is broken - disabling regex use])
1465         use_regex=no
1466       fi
1467     fi
1468   fi
1469   CPPFLAGS="${_cppflags}"
1470   LDFLAGS="${_ldflags}"
1471 fi
1472
1473 if test "$use_regex" != yes ; then
1474   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1475 fi
1476 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1477
1478
1479
1480 #
1481 # Do we have zlib? Must do it here because Solaris failed
1482 # when compiling a conftest (due to the "-lz" from LIBS).
1483 # Note that we combine zlib and bzlib2 in ZLIBS.
1484 #
1485 if test "$use_zip" = yes ; then
1486   _cppflags="${CPPFLAGS}"
1487   _ldflags="${LDFLAGS}"
1488   AC_ARG_WITH(zlib,
1489     [  --with-zlib=DIR         use libz in DIR],[
1490       if test -d "$withval"; then
1491         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1492         LDFLAGS="${LDFLAGS} -L$withval/lib"
1493       fi
1494     ])
1495
1496   AC_CHECK_HEADER(zlib.h,
1497      AC_CHECK_LIB(z, deflateInit2_,
1498        [
1499        ZLIBS="-lz"
1500        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1501        ],
1502        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1503        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1504 fi
1505
1506
1507 #
1508 # Check whether we can support bzip2
1509 #
1510 if test "$use_bzip2" = yes ; then
1511   _cppflags="${CPPFLAGS}"
1512   _ldflags="${LDFLAGS}"
1513   AC_ARG_WITH(bzip2,
1514      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1515       [
1516       if test -d "$withval" ; then
1517         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1518         LDFLAGS="${LDFLAGS} -L$withval/lib"
1519       fi
1520       ],withval="")
1521
1522   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1523   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1524   # woefully out of date.
1525   if test "$withval" != no ; then
1526      AC_CHECK_HEADER(bzlib.h,
1527         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1528           [
1529           have_bz2=yes
1530           ZLIBS="$ZLIBS -lbz2"
1531           AC_DEFINE(HAVE_BZIP2,1,
1532                   [Defined if the bz2 compression library is available])
1533           ],
1534           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1535           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1536   fi
1537 fi
1538 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1539 AC_SUBST(ZLIBS)
1540
1541
1542 # Check for readline support
1543 GNUPG_CHECK_READLINE
1544
1545
1546 if test "$development_version" = yes; then
1547     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1548             [Defined if this is not a regular release])
1549 fi
1550
1551 if test "$USE_MAINTAINER_MODE" = "yes"; then
1552     AC_DEFINE(MAINTAINER_MODE,1,
1553             [Defined if this build is in maintainer mode])
1554 fi
1555
1556 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1557
1558 GNUPG_CHECK_GNUMAKE
1559
1560 # Add some extra libs here so that previous tests don't fail for
1561 # mysterious reasons - the final link step should bail out.
1562 # W32SOCKLIBS is also defined so that if can be used for tools not
1563 # requiring any network stuff but linking to code in libcommon which
1564 # tracks in winsock stuff (e.g. init_common_subsystems).
1565 if test "$have_w32_system" = yes; then
1566    if test "$have_w32ce_system" = yes; then
1567      W32SOCKLIBS="-lws2"
1568    else
1569      W32SOCKLIBS="-lws2_32"
1570    fi
1571    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1572 fi
1573
1574 AC_SUBST(NETLIBS)
1575 AC_SUBST(W32SOCKLIBS)
1576
1577 #
1578 # Setup gcc specific options
1579 #
1580 USE_C99_CFLAGS=
1581 AC_MSG_NOTICE([checking for cc features])
1582 if test "$GCC" = yes; then
1583     mycflags=
1584     mycflags_save=$CFLAGS
1585
1586     # Check whether gcc does not emit a diagnositc for unknown -Wno-*
1587     # options.  This is the case for gcc >= 4.6
1588     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1589     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1590 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1591 #kickerror
1592 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1593     AC_MSG_RESULT($_gcc_silent_wno)
1594
1595     # Note that it is okay to use CFLAGS here because these are just
1596     # warning options and the user should have a chance of overriding
1597     # them.
1598     if test "$USE_MAINTAINER_MODE" = "yes"; then
1599         mycflags="$mycflags -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1600         mycflags="$mycflags -Wformat -Wno-format-y2k -Wformat-security"
1601         if test x"$_gcc_silent_wno" = xyes ; then
1602           _gcc_wopt=yes
1603         else
1604           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1605           CFLAGS="-Wno-missing-field-initializers"
1606           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1607                             [_gcc_wopt=yes],[_gcc_wopt=no])
1608           AC_MSG_RESULT($_gcc_wopt)
1609         fi
1610         if test x"$_gcc_wopt" = xyes ; then
1611           mycflags="$mycflags -W -Wno-sign-compare"
1612           mycflags="$mycflags -Wno-missing-field-initializers"
1613         fi
1614
1615         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1616         CFLAGS="-Wdeclaration-after-statement"
1617         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1618         AC_MSG_RESULT($_gcc_wopt)
1619         if test x"$_gcc_wopt" = xyes ; then
1620           mycflags="$mycflags -Wdeclaration-after-statement"
1621         fi
1622
1623         AC_MSG_CHECKING([if gcc supports -Wlogical-op and -Wvla])
1624         CFLAGS="-Wlogical-op -Wvla"
1625         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1626         AC_MSG_RESULT($_gcc_wopt)
1627         if test x"$_gcc_wopt" = xyes ; then
1628           mycflags="$mycflags -Wlogical-op -Wvla"
1629         fi
1630
1631     else
1632         mycflags="$mycflags -Wall"
1633     fi
1634
1635     if test x"$_gcc_silent_wno" = xyes ; then
1636       _gcc_psign=yes
1637     else
1638       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1639       CFLAGS="-Wno-pointer-sign"
1640       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1641                         [_gcc_psign=yes],[_gcc_psign=no])
1642       AC_MSG_RESULT($_gcc_psign)
1643     fi
1644     if test x"$_gcc_psign" = xyes ; then
1645        mycflags="$mycflags -Wno-pointer-sign"
1646     fi
1647
1648     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1649     CFLAGS="-Wpointer-arith"
1650     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1651     AC_MSG_RESULT($_gcc_psign)
1652     if test x"$_gcc_psign" = xyes ; then
1653        mycflags="$mycflags -Wpointer-arith"
1654     fi
1655
1656     CFLAGS="$mycflags $mycflags_save"
1657     if test "$use_libdns" = yes; then
1658        # dirmngr/dns.{c,h} require C99 and GNU extensions.  */
1659        USE_C99_CFLAGS="-std=gnu99"
1660     fi
1661 fi
1662
1663 AC_SUBST(USE_C99_CFLAGS)
1664
1665
1666 #
1667 # This is handy for debugging so the compiler doesn't rearrange
1668 # things and eliminate variables.
1669 #
1670 AC_ARG_ENABLE(optimization,
1671    AC_HELP_STRING([--disable-optimization],
1672                   [disable compiler optimization]),
1673                   [if test $enableval = no ; then
1674                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1675                    fi])
1676
1677 #
1678 # log_debug has certain requirements which might hamper portability.
1679 # Thus we use an option to enable it.
1680 #
1681 AC_MSG_CHECKING([whether to enable log_clock])
1682 AC_ARG_ENABLE(log_clock,
1683               AC_HELP_STRING([--enable-log-clock],
1684                              [enable log_clock timestamps]),
1685               enable_log_clock=$enableval, enable_log_clock=no)
1686 AC_MSG_RESULT($enable_log_clock)
1687 if test "$enable_log_clock" = yes ; then
1688   AC_DEFINE(ENABLE_LOG_CLOCK,1,[Defined to use log_clock timestamps])
1689 fi
1690
1691 # Add -Werror to CFLAGS.  This hack can be used to avoid problems with
1692 # misbehaving autoconf tests in case the user supplied -Werror.
1693 #
1694 AC_ARG_ENABLE(werror,
1695    AC_HELP_STRING([--enable-werror],
1696                   [append -Werror to CFLAGS]),
1697                   [if test $enableval = yes ; then
1698                       CFLAGS="$CFLAGS -Werror"
1699                    fi])
1700
1701 #
1702 # Configure option --enable-all-tests
1703 #
1704 AC_MSG_CHECKING([whether "make check" shall run all tests])
1705 AC_ARG_ENABLE(all-tests,
1706               AC_HELP_STRING([--enable-all-tests],
1707                              [let "make check" run all tests]),
1708               run_all_tests=$enableval, run_all_tests=no)
1709 AC_MSG_RESULT($run_all_tests)
1710 if test "$run_all_tests" = "yes"; then
1711     AC_DEFINE(RUN_ALL_TESTS,1,
1712             [Defined if "make check" shall run all tests])
1713 fi
1714
1715 #
1716 # We do not want support for the GNUPG_BUILDDIR environment variable
1717 # in a released version.  However, our regression tests suite requires
1718 # this and thus we build with support for it during "make distcheck".
1719 # This configure option implements this along with the top Makefile's
1720 # AM_DISTCHECK_CONFIGURE_FLAGS.
1721 #
1722 gnupg_builddir_envvar=no
1723 AC_ARG_ENABLE(gnupg-builddir-envvar,,
1724               gnupg_builddir_envvar=$enableval)
1725 if test x"$gnupg_builddir_envvar" = x"yes"; then
1726    AC_DEFINE(ENABLE_GNUPG_BUILDDIR_ENVVAR, 1,
1727       [This is only used with "make distcheck"])
1728 fi
1729
1730 #
1731 # Decide what to build
1732 #
1733
1734 build_scdaemon_extra=""
1735 if test "$build_scdaemon" = "yes"; then
1736   if test $have_libusb = no; then
1737      build_scdaemon_extra="without internal CCID driver"
1738   fi
1739   if test -n "$build_scdaemon_extra"; then
1740      build_scdaemon_extra="(${build_scdaemon_extra})"
1741   fi
1742 fi
1743
1744
1745 #
1746 # Set variables for use by automake makefiles.
1747 #
1748 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1749 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1750 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1751 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1752 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1753 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1754 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1755 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1756 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1757 AM_CONDITIONAL(BUILD_WKS_TOOLS,   test "$build_wks_tools" = "yes")
1758
1759 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1760 AM_CONDITIONAL(NO_TRUST_MODELS,     test "$use_trust_models" = no)
1761 AM_CONDITIONAL(USE_TOFU,            test "$use_tofu" = yes)
1762
1763 #
1764 # Set some defines for use gpgconf.
1765 #
1766 if test "$build_gpg" = yes ; then
1767     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1768 fi
1769 if test "$build_gpgsm" = yes ; then
1770     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1771 fi
1772 if test "$build_agent" = yes ; then
1773     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1774 fi
1775 if test "$build_scdaemon" = yes ; then
1776     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1777 fi
1778 if test "$build_dirmngr" = yes ; then
1779     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if DIRMNGR is to be build])
1780 fi
1781 if test "$build_g13" = yes ; then
1782     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1783 fi
1784
1785
1786 #
1787 # Define Name strings
1788 #
1789 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1790
1791 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1792 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1793
1794 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1795 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1796
1797 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1798 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1799                                         [The displayed name of gpg-agent])
1800
1801 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1802 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1803                                        [The displayed name of scdaemon])
1804
1805 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1806 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1807                                       [The displayed name of dirmngr])
1808
1809 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1810 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1811
1812 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1813 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1814                                       [The displayed name of gpgconf])
1815
1816 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1817
1818 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1819                    [The name of the agent socket])
1820 AC_DEFINE_UNQUOTED(GPG_AGENT_EXTRA_SOCK_NAME, "S.gpg-agent.extra",
1821                    [The name of the agent socket for remote access])
1822 AC_DEFINE_UNQUOTED(GPG_AGENT_BROWSER_SOCK_NAME, "S.gpg-agent.browser",
1823                    [The name of the agent socket for browsers])
1824 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1825                    [The name of the agent socket for ssh])
1826 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1827                    [The name of the dirmngr info envvar])
1828 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1829                    [The name of the SCdaemon socket])
1830 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1831                    [The name of the dirmngr socket])
1832 AC_DEFINE_UNQUOTED(DIRMNGR_DEFAULT_KEYSERVER,
1833                    "hkps://hkps.pool.sks-keyservers.net",
1834       [The default keyserver for dirmngr to use, if none is explicitly given])
1835
1836 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1837
1838 if test "$have_w32_system" = yes; then
1839   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "\\\\Software\\\\GNU\\\\GnuPG",
1840                      [The directory part of the W32 registry keys])
1841 fi
1842
1843
1844 #
1845 # Provide information about the build.
1846 #
1847 BUILD_REVISION="mym4_revision"
1848 AC_SUBST(BUILD_REVISION)
1849 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1850                    [GIT commit id revision used to build this package])
1851
1852 changequote(,)dnl
1853 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1854 changequote([,])dnl
1855 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1856 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1857 AC_SUBST(BUILD_VERSION)
1858 AC_SUBST(BUILD_FILEVERSION)
1859
1860 AC_ARG_ENABLE([build-timestamp],
1861   AC_HELP_STRING([--enable-build-timestamp],
1862                  [set an explicit build timestamp for reproducibility.
1863                   (default is the current time in ISO-8601 format)]),
1864      [if test "$enableval" = "yes"; then
1865         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1866       else
1867         BUILD_TIMESTAMP="$enableval"
1868       fi
1869       BUILD_HOSTNAME="$ac_hostname"],
1870      [BUILD_TIMESTAMP="<none>"
1871       BUILD_HOSTNAME="<anon>"])
1872 AC_SUBST(BUILD_TIMESTAMP)
1873 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1874                    [The time this package was configured for a build])
1875 AC_SUBST(BUILD_HOSTNAME)
1876
1877
1878 #
1879 # Print errors here so that they are visible all
1880 # together and the user can acquire them all together.
1881 #
1882 die=no
1883 if test "$have_gpg_error" = "no"; then
1884    die=yes
1885    AC_MSG_NOTICE([[
1886 ***
1887 *** You need libgpg-error to build this program.
1888 **  This library is for example available at
1889 ***   https://gnupg.org/ftp/gcrypt/libgpg-error
1890 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1891 ***]])
1892 fi
1893 if test "$have_libgcrypt" = "no"; then
1894    die=yes
1895    AC_MSG_NOTICE([[
1896 ***
1897 *** You need libgcrypt to build this program.
1898 **  This library is for example available at
1899 ***   https://gnupg.org/ftp/gcrypt/libgcrypt/
1900 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1901 ***]])
1902 fi
1903 if test "$have_libassuan" = "no"; then
1904    die=yes
1905    AC_MSG_NOTICE([[
1906 ***
1907 *** You need libassuan to build this program.
1908 *** This library is for example available at
1909 ***   https://gnupg.org/ftp/gcrypt/libassuan/
1910 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1911 ***]])
1912 fi
1913 if test "$have_ksba" = "no"; then
1914     die=yes
1915     AC_MSG_NOTICE([[
1916 ***
1917 *** You need libksba to build this program.
1918 *** This library is for example available at
1919 ***   https://gnupg.org/ftp/gcrypt/libksba/
1920 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1921 ***]])
1922 fi
1923 if test "$gnupg_have_ldap" = yes; then
1924   if test "$have_w32ce_system" = yes; then
1925     AC_MSG_NOTICE([[
1926 *** Note that CeGCC might be broken, a package fixing this is:
1927 ***    http://files.kolab.org/local/windows-ce/
1928 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1929 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1930 ***]])
1931    fi
1932 fi
1933 if test "$have_npth" = "no"; then
1934     die=yes
1935     AC_MSG_NOTICE([[
1936 ***
1937 *** It is now required to build with support for the
1938 *** New Portable Threads Library (nPth). Please install this
1939 *** library first.  The library is for example available at
1940 ***   https://gnupg.org/ftp/gcrypt/npth/
1941 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1942 ***]])
1943 fi
1944
1945 if test "$require_iconv" = yes; then
1946   if test "$am_func_iconv" != yes; then
1947     die=yes
1948     AC_MSG_NOTICE([[
1949 ***
1950 *** The system does not provide a working iconv function.  Please
1951 *** install a suitable library; for example GNU Libiconv which is
1952 *** available at:
1953 ***   https://ftp.gnu.org/gnu/libiconv/
1954 ***]])
1955   fi
1956 fi
1957
1958 if test "$use_ccid_driver" = yes; then
1959   if test "$have_libusb" != yes; then
1960     die=yes
1961     AC_MSG_NOTICE([[
1962 ***
1963 *** You need libusb to build the internal ccid driver.  Please
1964 *** install a libusb suitable for your system.
1965 ***]])
1966   fi
1967 fi
1968
1969 if test "$die" = "yes"; then
1970     AC_MSG_ERROR([[
1971 ***
1972 *** Required libraries not found. Please consult the above messages
1973 *** and install them before running configure again.
1974 ***]])
1975 fi
1976
1977
1978
1979 AC_CONFIG_FILES([ m4/Makefile
1980 Makefile
1981 po/Makefile.in
1982 common/Makefile
1983 common/w32info-rc.h
1984 kbx/Makefile
1985 g10/Makefile
1986 sm/Makefile
1987 agent/Makefile
1988 scd/Makefile
1989 g13/Makefile
1990 dirmngr/Makefile
1991 tools/gpg-zip
1992 tools/Makefile
1993 doc/Makefile
1994 tests/Makefile
1995 tests/gpgscm/Makefile
1996 tests/openpgp/Makefile
1997 tests/migrations/Makefile
1998 tests/gpgsm/Makefile
1999 tests/gpgme/Makefile
2000 tests/pkits/Makefile
2001 g10/gpg.w32-manifest
2002 ])
2003
2004
2005 AC_OUTPUT
2006
2007
2008 echo "
2009         GnuPG v${VERSION} has been configured as follows:
2010
2011         Revision:  mym4_revision  (mym4_revision_dec)
2012         Platform:  $PRINTABLE_OS_NAME ($host)
2013
2014         OpenPGP:   $build_gpg
2015         S/MIME:    $build_gpgsm
2016         Agent:     $build_agent
2017         Smartcard: $build_scdaemon $build_scdaemon_extra
2018         G13:       $build_g13
2019         Dirmngr:   $build_dirmngr
2020         Gpgtar:    $build_gpgtar
2021         WKS tools: $build_wks_tools
2022
2023         Protect tool:      $show_gnupg_protect_tool_pgm
2024         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
2025         Default agent:     $show_gnupg_agent_pgm
2026         Default pinentry:  $show_gnupg_pinentry_pgm
2027         Default scdaemon:  $show_gnupg_scdaemon_pgm
2028         Default dirmngr:   $show_gnupg_dirmngr_pgm
2029
2030         Dirmngr auto start:  $dirmngr_auto_start
2031         Readline support:    $gnupg_cv_have_readline
2032         LDAP support:        $gnupg_have_ldap
2033         TLS support:         $use_tls_library
2034         TOFU support:        $use_tofu
2035         Tor support:         $show_tor_support
2036 "
2037 if test x"$use_regex" != xyes ; then
2038 echo "
2039         Warning: No regular expression support available.
2040                  OpenPGP trust signatures won't work.
2041                  gpg-check-pattern will not be built.
2042 "
2043 fi
2044 if test "x${gpg_config_script_warn}" != x; then
2045 cat <<G10EOF
2046         Warning: Mismatches between the target platform and the
2047                  to be used libraries have been detected for:
2048                   ${gpg_config_script_warn}
2049                  Please check above for more warning messages.
2050
2051 G10EOF
2052 fi