Use passphrase caching for import and genkey.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005,
3 #               2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.10"
23
24 # Remember to change the version number immediately *after* a release.
25 # Set my_issvn to "yes" for non-released code.  Remember to run an
26 # "svn up" and "autogen.sh" right before creating a distribution.
27 m4_define([my_version], [2.1.0])
28 m4_define([my_issvn], [yes])
29
30 m4_define([svn_revision], m4_esyscmd([printf "%d" $(svn info 2>/dev/null \
31           | sed -n '/^Revision:/ s/[^0-9]//gp'|head -1)]))
32 m4_define([git_revision], m4_esyscmd([git branch -v 2>/dev/null \
33           | awk '/^\* / {printf "%s",$3}']))
34 AC_INIT([gnupg], 
35         [my_version[]m4_if(my_issvn,[yes],
36         [m4_if(git_revision,[],[-svn[]svn_revision],[-git[]git_revision])])],
37         [http://bugs.gnupg.org])
38 # Set development_version to yes if the minor number is odd or you
39 # feel that the default check for a development version is not
40 # sufficient.
41 development_version=no
42
43 NEED_GPG_ERROR_VERSION=1.8
44
45 NEED_LIBGCRYPT_API=1
46 NEED_LIBGCRYPT_VERSION=1.4.0
47
48 NEED_LIBASSUAN_API=2
49 NEED_LIBASSUAN_VERSION=2.0.0
50
51 NEED_KSBA_API=1
52 NEED_KSBA_VERSION=1.1.0
53
54
55 PACKAGE=$PACKAGE_NAME
56 PACKAGE_GT=${PACKAGE_NAME}2
57 VERSION=$PACKAGE_VERSION
58
59 AC_CONFIG_AUX_DIR(scripts)
60 AC_CONFIG_SRCDIR(sm/gpgsm.c)
61 AM_CONFIG_HEADER(config.h)
62 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
63 AC_CANONICAL_HOST
64 AB_INIT
65
66 AC_GNU_SOURCE
67
68 # Some status variables.
69 have_gpg_error=no
70 have_libgcrypt=no 
71 have_libassuan=no
72 have_ksba=no
73 have_pth=no
74 have_libusb=no
75 have_adns=no
76
77 use_zip=yes
78 use_bzip2=yes
79 use_exec=yes
80 disable_keyserver_path=no
81 use_ccid_driver=yes
82 use_standard_socket=no
83
84 try_ks_ldap=no
85
86 GNUPG_BUILD_PROGRAM(gpg, yes)
87 GNUPG_BUILD_PROGRAM(gpgsm, yes)
88 GNUPG_BUILD_PROGRAM(agent, yes)
89 GNUPG_BUILD_PROGRAM(scdaemon, yes)
90 GNUPG_BUILD_PROGRAM(g13, yes)
91 GNUPG_BUILD_PROGRAM(dirmngr, yes)
92 GNUPG_BUILD_PROGRAM(tools, yes)
93 GNUPG_BUILD_PROGRAM(doc, yes)
94 GNUPG_BUILD_PROGRAM(symcryptrun, no)
95 GNUPG_BUILD_PROGRAM(gpgtar, no)
96
97 AC_SUBST(PACKAGE)
98 AC_SUBST(PACKAGE_GT)
99 AC_SUBST(VERSION)
100 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
101 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
102                                 [Name of this package for gettext])
103 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
104 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
105                                         [Bug report address])
106 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
107                                        [Required version of Libgcrypt])
108 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
109                                        [Required version of Libksba])
110
111
112
113 # The default is to use the modules from this package and the few
114 # other packages in a standard place; i.e where this package gets
115 # installed.  With these options it is possible to override these
116 # ${prefix} depended values with fixed paths, which can't be replaced
117 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
118 AC_ARG_WITH(agent-pgm,
119     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
120           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
121 AC_SUBST(GNUPG_AGENT_PGM)
122 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
123 show_gnupg_agent_pgm="(default)"
124 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
125
126 AC_ARG_WITH(pinentry-pgm,
127     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
128           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
129 AC_SUBST(GNUPG_PINENTRY_PGM)
130 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
131 show_gnupg_pinentry_pgm="(default)"
132 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
133
134
135 AC_ARG_WITH(scdaemon-pgm,
136     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
137           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
138 AC_SUBST(GNUPG_SCDAEMON_PGM)
139 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
140 show_gnupg_scdaemon_pgm="(default)"
141 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
142
143
144 AC_ARG_WITH(dirmngr-pgm,
145     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
146           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
147 AC_SUBST(GNUPG_DIRMNGR_PGM)
148 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
149 show_gnupg_dirmngr_pgm="(default)"
150 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
151
152 AC_ARG_WITH(protect-tool-pgm,
153     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
154           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
155 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
156 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
157 show_gnupg_protect_tool_pgm="(default)"
158 test -n "$GNUPG_PROTECT_TOOL_PGM" \
159       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
160
161 AC_ARG_WITH(dirmngr-ldap-pgm,
162     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmnge ldap wrapper)],
163           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
164 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
165 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
166 show_gnupg_dirmngr_ldap_pgm="(default)"
167 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
168       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
169
170
171 # Some folks want to use only the agent from this packet.  Make it
172 # easier for them by providing the configure option
173 # --enable-only-agent.
174 AC_ARG_ENABLE(agent-only,
175     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
176     build_agent_only=$enableval)
177
178 # SELinux support includes tracking of sensitive files to avoid
179 # leaking their contents through processing these files by gpg itself
180 AC_MSG_CHECKING([whether SELinux support is requested])
181 AC_ARG_ENABLE(selinux-support,
182               AC_HELP_STRING([--enable-selinux-support],
183                              [enable SELinux support]),
184               selinux_support=$enableval, selinux_support=no)
185 AC_MSG_RESULT($selinux_support)
186
187 # Allow disabling of zip support.
188 # This is in general not a good idea because according to rfc4880 OpenPGP
189 # implementations SHOULD support ZLIB.
190 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
191 AC_ARG_ENABLE(zip,
192    AC_HELP_STRING([--disable-zip],
193                   [disable the ZIP and ZLIB compression algorithm]),
194    use_zip=$enableval)
195 AC_MSG_RESULT($use_zip)
196
197 # Allow disabling of bzib2 support.
198 # It is defined only after we confirm the library is available later
199 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
200 AC_ARG_ENABLE(bzip2,
201    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
202    use_bzip2=$enableval)
203 AC_MSG_RESULT($use_bzip2)
204
205 # Configure option to allow or disallow execution of external
206 # programs, like a photo viewer.
207 AC_MSG_CHECKING([whether to enable external program execution])
208 AC_ARG_ENABLE(exec,
209     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
210     use_exec=$enableval)
211 AC_MSG_RESULT($use_exec)
212 if test "$use_exec" = no ; then
213     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
214 fi
215
216 if test "$use_exec" = yes ; then
217   AC_MSG_CHECKING([whether to enable photo ID viewing])
218   AC_ARG_ENABLE(photo-viewers,
219       [  --disable-photo-viewers disable photo ID viewers],
220       [if test "$enableval" = no ; then
221          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
222       fi],enableval=yes)
223   gnupg_cv_enable_photo_viewers=$enableval
224   AC_MSG_RESULT($enableval)
225
226   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
227     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
228     AC_ARG_WITH(photo-viewer,
229         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
230         [if test "$withval" = yes ; then
231            withval=no
232         elif test "$withval" != no ; then
233            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
234                             [if set, restrict photo-viewer to this])
235         fi],withval=no)
236     AC_MSG_RESULT($withval)
237   fi
238
239   AC_MSG_CHECKING([whether to enable external keyserver helpers])
240   AC_ARG_ENABLE(keyserver-helpers,
241       [  --disable-keyserver-helpers  disable all external keyserver support],
242       [if test "$enableval" = no ; then
243          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
244                   [define to disable keyserver helpers])
245       fi],enableval=yes)
246   gnupg_cv_enable_keyserver_helpers=$enableval
247   AC_MSG_RESULT($enableval)
248
249   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
250     # LDAP is defined only after we confirm the library is available later
251     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
252     AC_ARG_ENABLE(ldap,
253       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
254       try_ks_ldap=$enableval, try_ks_ldap=yes)
255     AC_MSG_RESULT($try_ks_ldap)
256
257     AC_MSG_CHECKING([whether HKP keyserver support is requested])
258     AC_ARG_ENABLE(hkp,
259       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
260       try_hkp=$enableval, try_hkp=yes)
261     AC_MSG_RESULT($try_hkp)
262
263     AC_MSG_CHECKING([whether finger key fetching support is requested])
264     AC_ARG_ENABLE(finger,
265       AC_HELP_STRING([--disable-finger],
266         [disable finger key fetching interface only]),
267       try_finger=$enableval, try_finger=yes)
268     AC_MSG_RESULT($try_finger)
269
270     AC_MSG_CHECKING([whether generic object key fetching support is requested])
271     AC_ARG_ENABLE(generic,
272       AC_HELP_STRING([--disable-generic],
273         [disable generic object key fetching interface only]),
274       try_generic=$enableval, try_generic=yes)
275     AC_MSG_RESULT($try_generic)
276
277     AC_MSG_CHECKING([whether email keyserver support is requested])
278     AC_ARG_ENABLE(mailto,
279       AC_HELP_STRING([--enable-mailto],
280         [enable email keyserver interface only]),
281       try_mailto=$enableval, try_mailto=no)
282     AC_MSG_RESULT($try_mailto)
283   fi
284
285   AC_MSG_CHECKING([whether keyserver exec-path is enabled])
286   AC_ARG_ENABLE(keyserver-path,
287       AC_HELP_STRING([--disable-keyserver-path],
288         [disable the exec-path option for keyserver helpers]),
289       [if test "$enableval" = no ; then
290          disable_keyserver_path=yes
291       fi],enableval=yes)
292   AC_MSG_RESULT($enableval)
293 fi
294
295
296 #
297 # Check for the key/uid cache size.  This can't be zero, but can be
298 # pretty small on embedded systems.  This is used for the gpg part.
299 #
300 AC_MSG_CHECKING([for the size of the key and uid cache])
301 AC_ARG_ENABLE(key-cache,
302         AC_HELP_STRING([--enable-key-cache=SIZE],
303                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
304 if test "$enableval" = "no"; then
305    enableval=5
306 elif test "$enableval" = "yes" || test "$enableval" = ""; then
307    enableval=4096
308 fi
309 changequote(,)dnl
310 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
311 changequote([,])dnl
312 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
313    AC_MSG_ERROR([invalid key-cache size])
314 fi
315 AC_MSG_RESULT($key_cache_size)
316 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
317                   [Size of the key and UID caches])
318
319
320
321 #
322 # Check whether we want to use Linux capabilities
323 #
324 AC_MSG_CHECKING([whether use of capabilities is requested])
325 AC_ARG_WITH(capabilities,
326     [  --with-capabilities     use linux capabilities [default=no]],
327 [use_capabilities="$withval"],[use_capabilities=no])
328 AC_MSG_RESULT($use_capabilities)
329
330
331 #
332 # Allow disabling of internal CCID support.
333 # It is defined only after we confirm the library is available later
334 #
335 AC_MSG_CHECKING([whether to enable the internal CCID driver])
336 AC_ARG_ENABLE(ccid-driver,
337               AC_HELP_STRING([--disable-ccid-driver],
338                              [disable the internal CCID driver]),
339               use_ccid_driver=$enableval)
340 AC_MSG_RESULT($use_ccid_driver)
341
342
343 #
344 # To avoid double inclusion of config.h which might happen at some
345 # places, we add the usual double inclusion protection at the top of
346 # config.h.
347 #
348 AH_TOP([
349 #ifndef GNUPG_CONFIG_H_INCLUDED
350 #define GNUPG_CONFIG_H_INCLUDED
351 ])
352
353 #
354 # Stuff which goes at the bottom of config.h.
355 #
356 AH_BOTTOM([
357 /* This is the major version number of GnuPG so that
358    source included files can test for this.  Note, that
359    we use 2 here even for GnuPG 1.9.x. */
360 #define GNUPG_MAJOR_VERSION 2
361
362 /* Now to separate file name parts.
363    Please note that the string version must not contain more
364    than one character because the code assumes strlen()==1 */
365 #ifdef HAVE_DOSISH_SYSTEM
366 #define DIRSEP_C '\\'
367 #define DIRSEP_S "\\"
368 #define EXTSEP_C '.'
369 #define EXTSEP_S "."
370 #define PATHSEP_C ';'
371 #define PATHSEP_S ";"
372 #define EXEEXT_S ".exe"
373 #else
374 #define DIRSEP_C '/'
375 #define DIRSEP_S "/"
376 #define EXTSEP_C '.'
377 #define EXTSEP_S "."
378 #define PATHSEP_C ':'
379 #define PATHSEP_S ":"
380 #define EXEEXT_S ""
381 #endif
382
383 /* This is the same as VERSION, but should be overridden if the
384    platform cannot handle things like dots '.' in filenames. Set
385    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
386    uses for dots and dashes. */
387 #define SAFE_VERSION VERSION
388 #define SAFE_VERSION_DOT  '.'
389 #define SAFE_VERSION_DASH '-'
390
391 /* Some global constants. */
392 #ifdef HAVE_DOSISH_SYSTEM
393 # ifdef HAVE_DRIVE_LETTERS
394 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
395 # else
396 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
397 # endif
398 #elif defined(__VMS)
399 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg" 
400 #else
401 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
402 #endif 
403 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
404
405 /* For some systems (DOS currently), we hardcode the path here.  For
406    POSIX systems the values are constructed by the Makefiles, so that
407    the values may be overridden by the make invocations; this is to
408    comply with the GNU coding standards.  Note that these values are
409    only defaults.  */
410 #ifdef HAVE_DOSISH_SYSTEM
411 # ifdef HAVE_DRIVE_LETTERS
412 #  define GNUPG_BINDIR      "c:\\gnupg"
413 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
414 #  define GNUPG_LIBDIR      "c:\\gnupg"
415 #  define GNUPG_DATADIR     "c:\\gnupg"
416 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
417 # else
418 #  define GNUPG_BINDIR      "\\gnupg"
419 #  define GNUPG_LIBEXECDIR  "\\gnupg"
420 #  define GNUPG_LIBDIR      "\\gnupg"
421 #  define GNUPG_DATADIR     "\\gnupg"
422 #  define GNUPG_SYSCONFDIR  "\\gnupg"
423 # endif
424 #endif
425
426 /* Derive some other constants. */
427 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
428 #define EXEC_TEMPFILE_ONLY
429 #endif
430
431
432 /* We didn't define endianness above, so get it from OS macros.  This
433    is intended for making fat binary builds on OS X. */
434 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
435 #if defined(__BIG_ENDIAN__)
436 #define BIG_ENDIAN_HOST 1
437 #elif defined(__LITTLE_ENDIAN__)
438 #define LITTLE_ENDIAN_HOST 1
439 #else
440 #error "No endianness found"
441 #endif
442 #endif
443
444
445 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
446    ldap_start_tls_s because that is the actual symbol used in the
447    library.  winldap.h redefines it to our commonly used value,
448    thus we define our usual macro here.  */
449 #ifdef HAVE_LDAP_START_TLS_SA
450 # ifndef HAVE_LDAP_START_TLS_S
451 #  define HAVE_LDAP_START_TLS_S 1
452 # endif
453 #endif
454
455
456 /* Tell libgcrypt not to use its own libgpg-error implementation. */
457 #define USE_LIBGPG_ERROR 1
458
459 /* We use jnlib, so tell other modules about it.  */
460 #define HAVE_JNLIB_LOGGING 1
461
462 /* Our HTTP code is used in estream mode.  */
463 #define HTTP_USE_ESTREAM 1
464
465 /* Under W32 we do an explicit socket initialization, thus we need to
466    avoid the on-demand initialization which would also install an atexit
467    handler.  */
468 #define HTTP_NO_WSASTARTUP
469
470 /* We always include support for the OpenPGP card.  */
471 /* Disabled for now ENABLE_CARD_SUPPORT 1 */
472
473 /* We explicitly need to disable PTH's soft mapping as Debian
474    currently enables it by default for no reason. */
475 #define PTH_SYSCALL_SOFT 0
476
477 /* We want to use the libgcrypt provided memory allocation for
478    asprintf.  */
479 #define _ESTREAM_PRINTF_MALLOC        gcry_malloc
480 #define _ESTREAM_PRINTF_FREE          gcry_free
481 #define _ESTREAM_PRINTF_EXTRA_INCLUDE "../common/util.h"
482
483 /* Under Windows we use the gettext code from libgpg-error.  */
484 #define GPG_ERR_ENABLE_GETTEXT_MACROS
485
486 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
487 #define GPG_ERR_ENABLE_ERRNO_MACROS
488
489 #endif /*GNUPG_CONFIG_H_INCLUDED*/
490 ])
491
492
493 AM_MAINTAINER_MODE
494
495 # Checks for programs.
496 AC_MSG_NOTICE([checking for programs])
497 AC_PROG_MAKE_SET
498 AM_SANITY_CHECK
499 missing_dir=`cd $ac_aux_dir && pwd`
500 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
501 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
502 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
503 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
504 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
505 AC_PROG_AWK
506 AC_PROG_CC
507 AC_PROG_CPP
508 AM_PROG_CC_C_O
509 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
510   AC_MSG_ERROR([[No C-89 compiler found]])
511 fi
512 AC_PROG_INSTALL
513 AC_PROG_LN_S
514 AC_PROG_RANLIB
515 AC_CHECK_TOOL(AR, ar, :)
516 AC_PATH_PROG(PERL,"perl")
517 AC_CHECK_TOOL(WINDRES, windres, :)
518 AC_ISC_POSIX
519 gl_EARLY
520 AC_SYS_LARGEFILE
521 GNUPG_CHECK_FAQPROG
522 GNUPG_CHECK_USTAR
523
524 # We need to compile and run a program on the build machine.  A
525 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
526 # the AC archive is broken for autoconf 2.57.  Given that there is no
527 # newer version of that macro, we assume that it is also broken for
528 # autoconf 2.61 and thus we use a simple but usually sufficient
529 # approach.
530 AC_MSG_CHECKING(for cc for build)
531 if test "$cross_compiling" = "yes"; then
532   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
533 else
534   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
535 fi
536 AC_MSG_RESULT($CC_FOR_BUILD)
537 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
538
539
540
541 try_gettext=yes
542 have_dosish_system=no
543 have_w32_system=no
544 have_w32ce_system=no
545 use_simple_gettext=no
546 use_ldapwrapper=yes
547 mmap_needed=yes
548 case "${host}" in
549     *-mingw32*)
550         # special stuff for Windoze NT
551         ac_cv_have_dev_random=no
552         AC_DEFINE(USE_ONLY_8DOT3,1,
553                   [Set this to limit filenames to the 8.3 format])
554         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
555                   [Because the Unix gettext has too much overhead on
556                    MingW32 systems and these systems lack Posix functions,
557                    we use a simplified version of gettext])
558         disable_keyserver_path=yes
559         have_dosish_system=yes
560         have_w32_system=yes
561         use_ldapwrapper=no  # Fixme: Do this only for CE.
562         case "${host}" in 
563           *-mingw32ce*)
564             have_w32ce_system=yes
565             ;;
566           *)
567             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
568                       [Defined if the OS supports drive letters.])
569             ;;
570         esac
571         try_gettext="no"
572         use_simple_gettext=yes
573         mmap_needed=no
574         ;;
575     i?86-emx-os2 | i?86-*-os2*emx )
576         # OS/2 with the EMX environment
577         ac_cv_have_dev_random=no
578         AC_DEFINE(HAVE_DRIVE_LETTERS)
579         have_dosish_system=yes
580         try_gettext="no"
581         ;;
582
583     i?86-*-msdosdjgpp*)
584         # DOS with the DJGPP environment
585         ac_cv_have_dev_random=no
586         AC_DEFINE(HAVE_DRIVE_LETTERS)
587         have_dosish_system=yes
588         try_gettext="no"
589         ;;
590
591     *-*-freebsd*)
592        # FreeBSD
593        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
594        LDFLAGS="$LDFLAGS -L/usr/local/lib"
595        ;;
596
597     *-*-hpux*)
598         if test -z "$GCC" ; then
599             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
600         fi
601         ;;
602     *-dec-osf4*)
603         if test -z "$GCC" ; then
604             # Suppress all warnings
605             # to get rid of the unsigned/signed char mismatch warnings.
606             CFLAGS="$CFLAGS -w"
607         fi
608         ;;
609     *-dec-osf5*)
610         if test -z "$GCC" ; then
611             # Use the newer compiler `-msg_disable ptrmismatch1' to
612             # get rid of the unsigned/signed char mismatch warnings.
613             # Using this may hide other pointer mismatch warnings, but
614             # it at least lets other warning classes through
615             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
616         fi
617         ;;
618     m68k-atari-mint)
619         ;;
620     *)
621        ;;
622 esac
623
624 if test "$have_dosish_system" = yes; then
625    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
626              [Defined if we run on some of the PCDOS like systems 
627               (DOS, Windoze. OS/2) with special properties like
628               no file modes, case insensitive file names and preferred
629               use of backslashes as directory name separators.])
630 fi
631 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
632
633 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
634
635 if test "$have_w32_system" = yes; then
636    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
637    if test "$have_w32ce_system" = yes; then
638       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
639    fi
640 fi
641 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
642 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
643
644 if test "$use_ldapwrapper" = yes; then
645    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
646 fi
647 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
648
649 if test "$disable_keyserver_path" = yes; then
650     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
651               [Defined to disable exec-path for keyserver helpers])
652 fi
653
654 #
655 # Allows enabling the use of a standard socket by default This is
656 # gpg-agent's option --[no-]use-standard-socket.  For Windows we force
657 # the use of this.
658 #
659 AC_MSG_CHECKING([whether to use a standard socket by default])
660 AC_ARG_ENABLE(standard-socket,
661               AC_HELP_STRING([--enable-standard-socket],
662                              [use a standard socket for the agent by default]),
663               use_standard_socket=$enableval)
664 tmp=""
665 if test "$use_standard_socket" != yes; then
666   if test "$have_w32_system" = yes; then
667     use_standard_socket=yes
668     tmp=" (forced)"
669   fi
670 fi
671 AC_MSG_RESULT($use_standard_socket$tmp)
672 if test "$use_standard_socket" = yes; then
673   AC_DEFINE(USE_STANDARD_SOCKET,1,
674             [Use the standard socket for the agent by default])
675 fi
676
677
678 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
679 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
680
681 if test x"$try_hkp" = xyes ; then
682   AC_SUBST(GPGKEYS_HKP,"gpg2keys_hkp$EXEEXT")
683 fi
684
685 if test x"$try_finger" = xyes ; then
686   AC_SUBST(GPGKEYS_FINGER,"gpg2keys_finger$EXEEXT")
687 fi
688
689
690
691 #
692 # Checks for libraries.
693 #
694 AC_MSG_NOTICE([checking for libraries])
695
696
697 #
698 # libgpg-error is a library with error codes shared between GnuPG
699 # related projects.
700 #
701 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
702                   have_gpg_error=yes,have_gpg_error=no)
703
704
705 #
706 # Libgcrypt is our generic crypto library
707 #
708 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
709         have_libgcrypt=yes,have_libgcrypt=no)
710
711
712 #
713 # libassuan is used for IPC
714 #
715 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
716                   have_libassuan=yes,have_libassuan=no)
717 if test "$have_libassuan" = "yes"; then
718   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
719                      [version of the libassuan library])
720 fi
721
722
723
724 #
725 # libksba is our X.509 support library
726 #
727 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
728
729
730 #
731 # libusb allows us to use the integrated CCID smartcard reader driver.
732 #
733 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
734 if test "$use_ccid_driver" = yes ; then
735   AC_CHECK_LIB(usb, usb_bulk_write,
736                 [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
737                   AC_DEFINE(HAVE_LIBUSB,1,
738                            [defined if libusb is available])
739                   have_libusb=yes
740                ])
741   AC_CHECK_FUNCS(usb_create_match)
742 fi
743 AC_SUBST(LIBUSB_LIBS)
744
745 #
746 # Check wether it is necessary to link against libdl.
747 #
748 gnupg_dlopen_save_libs="$LIBS"
749 LIBS=""
750 AC_SEARCH_LIBS(dlopen, c dl,,,)
751 DL_LIBS=$LIBS
752 AC_SUBST(DL_LIBS)
753 LIBS="$gnupg_dlopen_save_libs"
754
755 # Checks for g13
756
757 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
758 AC_DEFINE_UNQUOTED(ENCFS,
759         "${ENCFS}", [defines the filename of the encfs program])
760
761 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
762 AC_DEFINE_UNQUOTED(FUSERMOUNT,
763         "${FUSERMOUNT}", [defines the filename of the fusermount program])
764
765
766 # Checks for dirmngr
767
768
769 #
770 # Checks for symcryptrun:
771 #
772
773 # libutil has openpty() and login_tty().
774 AC_CHECK_LIB(util, openpty,
775               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
776                 AC_DEFINE(HAVE_LIBUTIL,1,
777                          [defined if libutil is available])
778              ])
779 AC_SUBST(LIBUTIL_LIBS)
780
781 # shred is used to clean temporary plain text files.
782 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
783 AC_DEFINE_UNQUOTED(SHRED,
784         "${SHRED}", [defines the filename of the shred program])
785
786
787 #
788 # Check whether the GNU Pth library is available
789 # Note, that we include a Pth emulation for W32.
790 #
791 if test "$have_w32_system" = yes; then
792   GNUPG_PATH_PTH([2.0.4])
793 else
794   GNUPG_PATH_PTH
795 fi
796 if test "$have_pth" = "yes"; then
797   AC_DEFINE(USE_GNU_PTH, 1,
798               [Defined if the GNU Portable Thread Library should be used])
799 else
800   AC_MSG_WARN([[
801 ***
802 *** To support concurrent access to the gpg-agent and the SCdaemon
803 *** we need the support of the GNU Portable Threads Library.
804 *** Download it from ftp://ftp.gnu.org/gnu/pth/
805 *** On a Debian GNU/Linux system you might want to try 
806 ***   apt-get install libpth-dev
807 ***]])
808 fi
809
810
811 AC_MSG_NOTICE([checking for networking options])
812
813 #
814 # Must check for network library requirements before doing link tests
815 # for ldap, for example. If ldap libs are static (or dynamic and without
816 # ELF runtime link paths), then link will fail and LDAP support won't
817 # be detected.
818 #
819 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
820         [NETLIBS="-lnsl $NETLIBS"]))
821 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
822         [NETLIBS="-lsocket $NETLIBS"]))
823
824
825 #
826 # Check for ADNS.
827 #
828 _cppflags="${CPPFLAGS}"
829 _ldflags="${LDFLAGS}"
830 AC_ARG_WITH(adns,
831             AC_HELP_STRING([--with-adns=DIR],
832                            [look for the adns library in DIR]),
833             [if test -d "$withval"; then
834                CPPFLAGS="${CPPFLAGS} -I$withval/include"
835                LDFLAGS="${LDFLAGS} -L$withval/lib"
836              fi])
837 if test "$with_adns" != "no"; then
838   AC_CHECK_HEADERS(adns.h,
839                 AC_CHECK_LIB(adns, adns_init,
840                              [have_adns=yes],
841                              [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}]),
842                 [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}])
843 fi
844 if test "$have_adns" = "yes"; then
845   ADNSLIBS="-ladns" 
846 fi
847 AC_SUBST(ADNSLIBS)
848 # Newer adns versions feature a free function to be used under W32.
849 AC_CHECK_FUNCS(adns_free)
850
851
852
853 #
854 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
855 #
856 if test x"$try_hkp" = xyes || test x"$try_http" = xyes ; then
857   AC_ARG_ENABLE(dns-srv,
858      AC_HELP_STRING([--disable-dns-srv],
859                     [disable the use of DNS SRV in HKP and HTTP]),
860                 use_dns_srv=$enableval,use_dns_srv=yes)
861 fi
862
863 AC_ARG_ENABLE(dns-pka,
864    AC_HELP_STRING([--disable-dns-pka],
865         [disable the use of PKA records in DNS]),
866    use_dns_pka=$enableval,use_dns_pka=yes)
867
868 AC_ARG_ENABLE(dns-cert,
869    AC_HELP_STRING([--disable-dns-cert],
870         [disable the use of CERT records in DNS]),
871    use_dns_cert=$enableval,use_dns_cert=yes)
872
873 if test x"$use_dns_pka" = xyes || test x"$use_dns_srv" = xyes \
874    || test x"$use_dns_cert" = xyes; then
875   _dns_save_libs=$LIBS
876   LIBS=""
877   # the double underscore thing is a glibc-ism?
878   AC_SEARCH_LIBS(res_query,resolv bind,,
879                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
880   AC_SEARCH_LIBS(dn_expand,resolv bind,,
881                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
882   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
883                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
884
885   if test x"$have_resolver" != xno ; then
886
887     # Make sure that the BIND 4 resolver interface is workable before
888     # enabling any code that calls it.  At some point I'll rewrite the
889     # code to use the BIND 8 resolver API.
890     # We might also want to use adns instead.  Problem with ADNS is that
891     # it does not support v6.
892
893     AC_MSG_CHECKING([whether the resolver is usable])
894     AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
895 #include <netinet/in.h>
896 #include <arpa/nameser.h>
897 #include <resolv.h>],
898 [[unsigned char answer[PACKETSZ];
899   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
900   dn_skipname(0,0); 
901   dn_expand(0,0,0,0,0);
902 ]])],have_resolver=yes,have_resolver=no)
903     AC_MSG_RESULT($have_resolver)
904
905     # This is Apple-specific and somewhat bizarre as they changed the
906     # define in bind 8 for some reason.
907
908     if test x"$have_resolver" != xyes ; then
909        AC_MSG_CHECKING(
910              [whether I can make the resolver usable with BIND_8_COMPAT])
911        AC_LINK_IFELSE([AC_LANG_PROGRAM([#define BIND_8_COMPAT
912 #include <sys/types.h>
913 #include <netinet/in.h>
914 #include <arpa/nameser.h>
915 #include <resolv.h>],
916 [[unsigned char answer[PACKETSZ];
917   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
918   dn_skipname(0,0); dn_expand(0,0,0,0,0);
919 ]])],[have_resolver=yes ; need_compat=yes])
920        AC_MSG_RESULT($have_resolver)
921     fi
922   fi
923
924   if test x"$have_resolver" = xyes ; then
925      DNSLIBS=$LIBS
926
927      if test x"$use_dns_srv" = xyes ; then
928         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
929      fi
930
931      if test x"$use_dns_pka" = xyes ; then
932         AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
933      fi
934
935      if test x"$use_dns_cert" = xyes ; then
936         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
937      fi
938
939      if test x"$need_compat" = xyes ; then
940         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
941      fi
942   else
943      # If we have no resolver library but ADNS (e.g. under W32) enable the
944      # code parts which can be used with ADNS.
945      if test x"$have_adns" = xyes ; then
946         DNSLIBS="$ADNSLIBS"
947         AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
948
949         if test x"$use_dns_srv" = xyes ; then
950            AC_DEFINE(USE_DNS_SRV,1)
951         fi
952
953         if test x"$use_dns_pka" = xyes ; then
954            AC_DEFINE(USE_DNS_PKA,1)
955         fi
956
957         if test x"$use_dns_cert" = xyes ; then
958            AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
959         fi
960      else
961         use_dns_srv=no
962         use_dns_pka=no
963         use_dns_cert=no
964      fi
965   fi
966
967   LIBS=$_dns_save_libs
968 fi
969
970 AC_SUBST(DNSLIBS)
971
972 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
973
974
975 #
976 # Check for LDAP
977 #
978 if test "$try_ks_ldap" = yes || test "$build_dirmngr" = "yes" ; then
979    GNUPG_CHECK_LDAP($NETLIBS)
980 fi
981
982 #
983 # Check for curl.  We fake the curl API if libcurl isn't installed.
984 # We require 7.10 or later as we use curl_version_info().
985 #
986 LIBCURL_CHECK_CONFIG([yes],[7.10],,[fake_curl=yes])
987 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
988
989 # Generic, for us, means curl
990
991 if test x"$try_generic" = xyes ; then
992    AC_SUBST(GPGKEYS_CURL,"gpg2keys_curl$EXEEXT")
993 fi
994
995 #
996 # Check for sendmail
997 #
998 # This isn't necessarily sendmail itself, but anything that gives a
999 # sendmail-ish interface to the outside world.  That includes Exim,
1000 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1001 if test "$try_mailto" = yes ; then
1002   AC_ARG_WITH(mailprog,
1003       AC_HELP_STRING([--with-mailprog=NAME],
1004                      [use "NAME -t" for mail transport]),
1005              ,with_mailprog=yes)
1006
1007   if test x"$with_mailprog" = xyes ; then
1008     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1009     if test "$ac_cv_path_SENDMAIL" ; then
1010       GPGKEYS_MAILTO="gpg2keys_mailto"
1011     fi
1012   elif test x"$with_mailprog" != xno ; then
1013     AC_MSG_CHECKING([for a mail transport program])
1014     AC_SUBST(SENDMAIL,$with_mailprog)
1015     AC_MSG_RESULT($with_mailprog)
1016     GPGKEYS_MAILTO="gpg2keys_mailto"
1017   fi
1018 fi
1019
1020 AC_SUBST(GPGKEYS_MAILTO)
1021
1022 #
1023 # Construct a printable name of the OS
1024 #
1025 case "${host}" in
1026     *-mingw32ce*)
1027         PRINTABLE_OS_NAME="W32CE"
1028         ;;
1029     *-mingw32*)
1030         PRINTABLE_OS_NAME="MingW32"
1031         ;;
1032     *-*-cygwin*)
1033         PRINTABLE_OS_NAME="Cygwin"
1034         ;;
1035     i?86-emx-os2 | i?86-*-os2*emx )
1036         PRINTABLE_OS_NAME="OS/2"
1037         ;;
1038     i?86-*-msdosdjgpp*)
1039         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1040         try_dynload=no
1041         ;;
1042     *-linux*)
1043         PRINTABLE_OS_NAME="GNU/Linux"
1044         ;;
1045     *)
1046         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1047         ;;
1048 esac
1049 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1050                    [A human readable text with the name of the OS])
1051
1052
1053 #
1054 # Checking for iconv
1055 #
1056 AM_ICONV
1057
1058
1059 #
1060 # Check for gettext
1061 #
1062 # This is "GNU gnupg" - The project-id script from gettext
1063 #                       needs this string
1064 #
1065 AC_MSG_NOTICE([checking for gettext])
1066 AM_PO_SUBDIRS
1067 AM_GNU_GETTEXT_VERSION([0.17])
1068 if test "$try_gettext" = yes; then
1069   AM_GNU_GETTEXT([external],[need-ngettext])
1070
1071   # gettext requires some extra checks.  These really should be part of
1072   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1073   # function checks to here.
1074
1075   AC_CHECK_FUNCS(strchr)
1076 else
1077   USE_NLS=no
1078   USE_INCLUDED_LIBINTL=no
1079   BUILD_INCLUDED_LIBINTL=no
1080   POSUB=po
1081   AC_SUBST(USE_NLS)
1082   AC_SUBST(USE_INCLUDED_LIBINTL)
1083   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1084   AC_SUBST(POSUB)
1085 fi
1086
1087 # We use HAVE_LANGINFO_CODESET in a couple of places.
1088 AM_LANGINFO_CODESET
1089
1090 # Checks required for our use locales
1091 gt_LC_MESSAGES
1092
1093
1094 #
1095 # SELinux support
1096 #
1097 if test "$selinux_support" = yes ; then
1098   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1099 fi
1100
1101
1102 #
1103 # Checks for header files.
1104 #
1105 AC_MSG_NOTICE([checking for header files])
1106 AC_HEADER_STDC
1107 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1108                   pty.h pwd.h inttypes.h signal.h])
1109 AC_HEADER_TIME
1110
1111
1112 #
1113 # Checks for typedefs, structures, and compiler characteristics.
1114 #
1115 AC_MSG_NOTICE([checking for system characteristics])
1116 AC_C_CONST
1117 AC_C_INLINE
1118 AC_C_VOLATILE
1119 AC_TYPE_SIZE_T
1120 AC_TYPE_MODE_T
1121 AC_TYPE_SIGNAL
1122 AC_DECL_SYS_SIGLIST
1123
1124 gl_HEADER_SYS_SOCKET
1125 gl_TYPE_SOCKLEN_T
1126
1127 AC_ARG_ENABLE(endian-check,
1128               AC_HELP_STRING([--disable-endian-check],
1129               [disable the endian check and trust the OS provided macros]),
1130               endiancheck=$enableval,endiancheck=yes)
1131
1132 if test x"$endiancheck" = xyes ; then
1133   GNUPG_CHECK_ENDIAN
1134 fi
1135
1136 # fixme: we should get rid of the byte type
1137 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1138 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1139 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1140 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1141 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1142
1143 AC_CHECK_SIZEOF(unsigned short)
1144 AC_CHECK_SIZEOF(unsigned int)
1145 AC_CHECK_SIZEOF(unsigned long)
1146 AC_CHECK_SIZEOF(unsigned long long)
1147 AC_CHECK_SIZEOF(time_t,,[[
1148 #include <stdio.h>
1149 #if TIME_WITH_SYS_TIME
1150 # include <sys/time.h>
1151 # include <time.h>
1152 #else
1153 # if HAVE_SYS_TIME_H
1154 #  include <sys/time.h>
1155 # else
1156 #  include <time.h>
1157 # endif
1158 #endif
1159 ]])
1160
1161
1162 # Ensure that we have UINT64_C before we bother to check for uint64_t
1163 # Fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
1164 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
1165    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
1166        uint64_t foo=UINT64_C(42);]),
1167      gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
1168 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
1169    AC_CHECK_SIZEOF(uint64_t)
1170 fi
1171
1172 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1173    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1174    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1175     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1176 fi
1177
1178
1179 #
1180 # Checks for library functions.
1181 #
1182 AC_MSG_NOTICE([checking for library functions])
1183 AC_CHECK_DECLS(getpagesize)
1184 AC_FUNC_FSEEKO
1185 AC_FUNC_VPRINTF
1186 AC_FUNC_FORK
1187 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1188 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1189 AC_CHECK_FUNCS([unsetenv fcntl ftruncate canonicalize_file_name])
1190 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1191 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1192 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1193 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1194
1195 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1196
1197 # Dirmngr requires mmap on Unix systems.
1198 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1199   AC_MSG_ERROR([[Sorry, the current implemenation requires mmap.]])
1200 fi
1201
1202 #
1203 # These are needed by the jnlib parts in common.
1204 # Note:  We already checked pwd.h.
1205 AC_CHECK_HEADERS([signal.h])
1206 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1207                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1208                 flockfile funlockfile fopencookie funopen getpwnam getpwuid \
1209                 getenv inet_pton])
1210 # end jnlib checks.
1211
1212
1213
1214 #
1215 # gnulib checks
1216 #
1217 gl_SOURCE_BASE([gl])
1218 gl_M4_BASE([gl/m4])
1219 gl_MODULES([setenv mkdtemp xsize strpbrk])
1220 gl_INIT
1221
1222
1223 #
1224 # W32 specific test
1225 #
1226 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1227
1228 #
1229 # Sanity check regex.  Tests adapted from mutt.
1230 #
1231 AC_MSG_CHECKING([whether regular expression support is requested])
1232 AC_ARG_ENABLE(regex,
1233   AC_HELP_STRING([--disable-regex],
1234     [do not handle regular expressions in trust signatures]),
1235   use_regex=$enableval, use_regex=yes)
1236 AC_MSG_RESULT($use_regex)
1237
1238 if test "$use_regex" = yes ; then
1239   _cppflags="${CPPFLAGS}"
1240   _ldflags="${LDFLAGS}"
1241   AC_ARG_WITH(regex,
1242      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1243       [
1244       if test -d "$withval" ; then
1245         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1246         LDFLAGS="${LDFLAGS} -L$withval/lib"
1247       fi
1248       ],withval="")     
1249
1250   # Does the system have regex functions at all?
1251   AC_SEARCH_LIBS([regcomp], [regex])
1252   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1253
1254   if test $gnupg_cv_have_regex = no; then
1255     use_regex=no
1256   else
1257     if test x"$cross_compiling" = xyes; then
1258       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1259     else
1260       AC_CACHE_CHECK([whether your system's regexp library is broken],
1261        [gnupg_cv_regex_broken],
1262        AC_TRY_RUN([
1263 #include <unistd.h>
1264 #include <regex.h>
1265 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1266        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1267
1268       if test $gnupg_cv_regex_broken = yes; then
1269         AC_MSG_WARN([your regex is broken - disabling regex use])
1270         use_regex=no
1271       fi
1272     fi
1273   fi
1274   CPPFLAGS="${_cppflags}"
1275   LDFLAGS="${_ldflags}"
1276 fi
1277
1278 if test "$use_regex" != yes ; then
1279   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1280 fi
1281 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1282
1283
1284
1285 #
1286 # Do we have zlib? Must do it here because Solaris failed
1287 # when compiling a conftest (due to the "-lz" from LIBS).
1288 # Note that we combine zlib and bzlib2 in ZLIBS.
1289 #
1290 if test "$use_zip" = yes ; then
1291   _cppflags="${CPPFLAGS}"
1292   _ldflags="${LDFLAGS}"
1293   AC_ARG_WITH(zlib,
1294     [  --with-zlib=DIR         use libz in DIR],[
1295       if test -d "$withval"; then
1296         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1297         LDFLAGS="${LDFLAGS} -L$withval/lib"
1298       fi
1299     ])
1300   
1301   AC_CHECK_HEADER(zlib.h,
1302         AC_CHECK_LIB(z, deflateInit2_,
1303          ZLIBS="-lz",
1304          CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1305          CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1306          
1307   AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1308 fi
1309
1310
1311 #
1312 # Check whether we can support bzip2
1313
1314 if test "$use_bzip2" = yes ; then
1315   _cppflags="${CPPFLAGS}"
1316   _ldflags="${LDFLAGS}"
1317   AC_ARG_WITH(bzip2,
1318      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1319       [
1320       if test -d "$withval" ; then
1321         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1322         LDFLAGS="${LDFLAGS} -L$withval/lib"
1323       fi
1324       ],withval="")
1325
1326   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1327   # required stdio.h to be included before bzlib.h, and Solaris 9 is 
1328   # woefully out of date.
1329   if test "$withval" != no ; then
1330      AC_CHECK_HEADER(bzlib.h,
1331         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1332           [
1333           have_bz2=yes
1334           ZLIBS="$ZLIBS -lbz2"
1335           AC_DEFINE(HAVE_BZIP2,1,
1336                   [Defined if the bz2 compression library is available])
1337           ],
1338           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1339           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1340   fi
1341 fi
1342 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1343 AC_SUBST(ZLIBS)
1344
1345
1346 # Check for readline support
1347 GNUPG_CHECK_READLINE
1348
1349 #
1350 # Allow users to append something to the version string without
1351 # flagging it as development version.  The user version parts is
1352 # considered everything after a dash. 
1353 #
1354 if test "$development_version" != yes; then
1355   changequote(,)dnl
1356   tmp_pat='[a-zA-Z]'
1357   changequote([,])dnl
1358   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1359     development_version=yes
1360   fi
1361 fi
1362 if test "$development_version" = yes; then
1363     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1364             [Defined if this is not a regular release])
1365 fi
1366
1367 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1368
1369 GNUPG_CHECK_GNUMAKE
1370
1371 # Add some extra libs here so that previous tests don't fail for
1372 # mysterious reasons - the final link step should bail out.
1373 # W32SOCKLIBS is also defined so that if can be used for tools not
1374 # requiring any network stuff but linking to code in libcommon which
1375 # tracks in winsock stuff (e.g. init_common_subsystems).
1376 if test "$have_w32_system" = yes; then
1377    if test "$have_w32ce_system" = yes; then
1378      W32SOCKLIBS="-lws2"
1379    else
1380      W32SOCKLIBS="-lws2_32"
1381    fi
1382    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1383 fi
1384
1385 AC_SUBST(NETLIBS)
1386 AC_SUBST(W32SOCKLIBS)
1387
1388 #
1389 # Setup gcc specific options
1390 #
1391 AC_MSG_NOTICE([checking for cc features])
1392 if test "$GCC" = yes; then
1393     # Note that it is okay to use CFLAGS here because this are just
1394     # warning options and the user should have a chance of overriding
1395     # them.
1396     if test "$USE_MAINTAINER_MODE" = "yes"; then
1397         CFLAGS="$CFLAGS -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1398         CFLAGS="$CFLAGS -Wformat -Wno-format-y2k -Wformat-security"
1399         AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1400         _gcc_cflags_save=$CFLAGS
1401         CFLAGS="-Wno-missing-field-initializers"
1402         AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_wopt=yes,_gcc_wopt=no)
1403         AC_MSG_RESULT($_gcc_wopt)
1404         CFLAGS=$_gcc_cflags_save;
1405         if test x"$_gcc_wopt" = xyes ; then
1406           CFLAGS="$CFLAGS -W -Wno-sign-compare -Wno-missing-field-initializers"
1407         fi
1408         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1409         _gcc_cflags_save=$CFLAGS
1410         CFLAGS="-Wdeclaration-after-statement"
1411         AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_wopt=yes,_gcc_wopt=no)
1412         AC_MSG_RESULT($_gcc_wopt)
1413         CFLAGS=$_gcc_cflags_save;
1414         if test x"$_gcc_wopt" = xyes ; then
1415           CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1416         fi
1417     else
1418         CFLAGS="$CFLAGS -Wall"
1419     fi
1420
1421     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1422     _gcc_cflags_save=$CFLAGS
1423     CFLAGS="-Wno-pointer-sign"
1424     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1425     AC_MSG_RESULT($_gcc_psign)
1426     CFLAGS=$_gcc_cflags_save;
1427     if test x"$_gcc_psign" = xyes ; then
1428        CFLAGS="$CFLAGS -Wno-pointer-sign"
1429     fi
1430
1431     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1432     _gcc_cflags_save=$CFLAGS
1433     CFLAGS="-Wpointer-arith"
1434     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1435     AC_MSG_RESULT($_gcc_psign)
1436     CFLAGS=$_gcc_cflags_save;
1437     if test x"$_gcc_psign" = xyes ; then
1438        CFLAGS="$CFLAGS -Wpointer-arith"
1439     fi
1440 fi
1441
1442
1443 #
1444 # This is handy for debugging so the compiler doesn't rearrange
1445 # things and eliminate variables.
1446 #
1447 AC_ARG_ENABLE(optimization,
1448    AC_HELP_STRING([--disable-optimization],
1449                   [disable compiler optimization]),
1450                   [if test $enableval = no ; then
1451                       CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]]//'`
1452                    fi])
1453
1454 #
1455 # Prepare building of estream
1456 #
1457 estream_INIT
1458
1459
1460 #
1461 # Decide what to build
1462 #
1463 if test "$have_adns" = "yes"; then
1464   AC_SUBST(GPGKEYS_KDNS, "gpg2keys_kdns$EXEEXT")
1465 fi
1466
1467
1468 missing_pth=no
1469 if test $have_ksba = no; then
1470   build_gpgsm=no
1471   build_scdaemon=no
1472 fi
1473
1474 build_agent_threaded=""
1475 if test "$build_agent" = "yes"; then
1476   if test $have_pth = no; then
1477      build_agent_threaded="(not multi-threaded)"
1478      missing_pth=yes
1479   fi
1480 fi
1481
1482 build_scdaemon_extra=""
1483 if test "$build_scdaemon" = "yes"; then
1484   tmp=""
1485   if test $have_pth = no; then
1486      build_scdaemon_extra="not multi-threaded"
1487      tmp=", "
1488      missing_pth=yes
1489   fi
1490   if test $have_libusb = no; then
1491      build_scdaemon_extra="${tmp}without internal CCID driver"
1492      tmp=", "
1493   fi
1494   if test -n "$build_scdaemon_extra"; then
1495      build_scdaemon_extra="(${build_scdaemon_extra})"
1496   fi
1497 fi
1498
1499
1500 if test "$build_agent_only" = "yes" ; then
1501   build_gpg=no
1502   build_gpgsm=no
1503   build_scdaemon=no
1504   build_tools=no
1505   build_doc=no
1506 fi
1507
1508
1509 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1510 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1511 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1512 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1513 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1514 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1515 AM_CONDITIONAL(BUILD_TOOLS,       test "$build_tools" = "yes")
1516 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1517 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1518 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1519
1520 AM_CONDITIONAL(RUN_GPG_TESTS,
1521                test x$cross_compiling = xno -a "$build_gpg" = yes )
1522
1523
1524 #
1525 # Print errors here so that they are visible all
1526 # together and the user can acquire them all together.
1527 #
1528 die=no
1529 if test "$have_gpg_error" = "no"; then
1530    die=yes
1531    AC_MSG_NOTICE([[
1532 ***  
1533 *** You need libgpg-error to build this program.
1534 **  This library is for example available at
1535 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1536 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1537 ***]])
1538 fi
1539 if test "$have_libgcrypt" = "no"; then
1540    die=yes
1541    AC_MSG_NOTICE([[
1542 ***  
1543 *** You need libgcrypt to build this program.
1544 **  This library is for example available at
1545 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1546 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API is required.)
1547 ***]])
1548 fi
1549 if test "$have_libassuan" = "no"; then
1550    die=yes
1551    AC_MSG_NOTICE([[
1552 ***
1553 *** You need libassuan to build this program.
1554 *** This library is for example available at
1555 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1556 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1557 ***]])
1558 fi
1559 if test "$have_ksba" = "no"; then
1560     AC_MSG_NOTICE([[
1561 ***
1562 *** You need libksba to build this program.
1563 *** This library is for example available at
1564 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1565 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1566 ***]])
1567 fi
1568 if test "$gnupg_have_ldap" = "no"; then
1569     die=yes
1570     AC_MSG_NOTICE([[
1571 ***
1572 *** You need a LDAP library to build this program.
1573 *** Check out 
1574 ***    http://www.openldap.org 
1575 *** for a suitable implementation.
1576 ***]])
1577    if test "$have_w32ce_system" = yes; then
1578     AC_MSG_NOTICE([[
1579 *** Note that CeGCC might be broken, a package fixing this is:
1580 ***    http://files.kolab.org/local/windows-ce/ 
1581 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1582 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1583 ***]])
1584    fi
1585 fi
1586 if test "$missing_pth" = "yes"; then
1587     AC_MSG_NOTICE([[
1588 ***
1589 *** It is now required to build with support for the
1590 *** GNU Portable Threads Library (Pth). Please install this
1591 *** library first.  The library is for example available at
1592 ***   ftp://ftp.gnu.org/gnu/pth/
1593 *** On a Debian GNU/Linux system you can install it using 
1594 ***   apt-get install libpth-dev
1595 *** To build GnuPG for Windows you need to use the W32PTH
1596 *** package; available at:
1597 ***   ftp://ftp.g10code.com/g10code/w32pth/
1598 ***]])
1599    die=yes
1600 fi
1601
1602 if test "$die" = "yes"; then
1603     AC_MSG_ERROR([[
1604 ***
1605 *** Required libraries not found. Please consult the above messages
1606 *** and install them before running configure again.
1607 ***]])
1608 fi
1609
1610
1611
1612 AC_CONFIG_FILES([ m4/Makefile 
1613 Makefile
1614 po/Makefile.in
1615 gl/Makefile
1616 include/Makefile
1617 common/Makefile
1618 kbx/Makefile
1619 g10/Makefile
1620 sm/Makefile
1621 agent/Makefile
1622 scd/Makefile
1623 g13/Makefile
1624 dirmngr/Makefile
1625 keyserver/Makefile
1626 keyserver/gpg2keys_mailto
1627 keyserver/gpg2keys_test
1628 tools/gpg-zip
1629 tools/Makefile
1630 doc/Makefile
1631 tests/Makefile
1632 tests/openpgp/Makefile
1633 tests/pkits/Makefile
1634 ])
1635 AC_OUTPUT
1636
1637
1638 echo "
1639         GnuPG v${VERSION} has been configured as follows:
1640         
1641         Platform:  $PRINTABLE_OS_NAME ($host)
1642
1643         OpenPGP:   $build_gpg
1644         S/MIME:    $build_gpgsm
1645         Agent:     $build_agent $build_agent_threaded
1646         Smartcard: $build_scdaemon $build_scdaemon_extra
1647         G13:       $build_g13
1648         Dirmngr:   $build_dirmngr
1649         Gpgtar:    $build_gpgtar
1650
1651         Protect tool:      $show_gnupg_protect_tool_pgm
1652         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
1653         Default agent:     $show_gnupg_agent_pgm
1654         Default pinentry:  $show_gnupg_pinentry_pgm
1655         Default scdaemon:  $show_gnupg_scdaemon_pgm
1656         Default dirmngr:   $show_gnupg_dirmngr_pgm
1657
1658         Use standard socket: $use_standard_socket
1659 "
1660 if test x"$use_regex" != xyes ; then
1661 echo "
1662         Warning: No regular expression support available.
1663                  OpenPGP trust signatures won't work.
1664                  gpg-check-pattern will not be build.
1665 "
1666 fi