configure.ac

   1 # configure.ac - for GnuPG 2.1
   2 # Copyright (C) 1998-2017 Free Software Foundation, Inc.
   3 # Copyright (C) 1998-2017 Werner Koch
   4 #
   5 # This file is part of GnuPG.
   6 #
   7 # GnuPG is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # GnuPG is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, see <https://www.gnu.org/licenses/>.
  19
  20 # Process this file with autoconf to produce a configure script.
  21 AC_PREREQ(2.61)
  22 min_automake_version="1.14"
  23
  24 # To build a release you need to create a tag with the version number
  25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
  26 # bump the version number immediately *after* the release and do
  27 # another commit and push so that the git magic is able to work.
  28 m4_define([mym4_package],[gnupg])
  29 m4_define([mym4_major], [2])
  30 m4_define([mym4_minor], [1])
  31 m4_define([mym4_micro], [23])
  32
  33 # To start a new development series, i.e a new major or minor number
  34 # you need to mark an arbitrary commit before the first beta release
  35 # with an annotated tag.  For example the 2.1 branch starts off with
  36 # the tag "gnupg-2.1-base".  This is used as the base for counting
  37 # beta numbers before the first release of a series.
  38
  39 # Below is m4 magic to extract and compute the git revision number,
  40 # the decimalized short revision number, a beta version string and a
  41 # flag indicating a development version (mym4_isbeta).  Note that the
  42 # m4 processing is done by autoconf and not during the configure run.
  43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
  44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
  45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
  46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
  47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
  48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
  49 m4_esyscmd([echo ]mym4_version[>VERSION])
  50 AC_INIT([mym4_package],[mym4_version], [https://bugs.gnupg.org])
  51
  52 NEED_GPG_ERROR_VERSION=1.24
  53
  54 NEED_LIBGCRYPT_API=1
  55 NEED_LIBGCRYPT_VERSION=1.7.0
  56
  57 NEED_LIBASSUAN_API=2
  58 NEED_LIBASSUAN_VERSION=2.4.3
  59
  60 NEED_KSBA_API=1
  61 NEED_KSBA_VERSION=1.3.4
  62
  63 NEED_NTBTLS_API=1
  64 NEED_NTBTLS_VERSION=0.1.0
  65
  66 NEED_NPTH_API=1
  67 NEED_NPTH_VERSION=1.2
  68
  69
  70 NEED_GNUTLS_VERSION=3.0
  71
  72 NEED_SQLITE_VERSION=3.7
  73
  74 development_version=mym4_isbeta
  75 PACKAGE=$PACKAGE_NAME
  76 PACKAGE_GT=${PACKAGE_NAME}2
  77 VERSION=$PACKAGE_VERSION
  78
  79 AC_CONFIG_AUX_DIR([build-aux])
  80 AC_CONFIG_SRCDIR([sm/gpgsm.c])
  81 AC_CONFIG_HEADER([config.h])
  82 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
  83 AC_CANONICAL_HOST
  84 AB_INIT
  85
  86 AC_GNU_SOURCE
  87
  88 # Before we do anything with the C compiler, we first save the user's
  89 # CFLAGS (they are restored at the end of the configure script).  This
  90 # is because some configure checks don't work with -Werror, but we'd
  91 # like to use -Werror with our build.
  92 CFLAGS_orig=$CFLAGS
  93 CFLAGS=
  94
  95 # Some status variables.
  96 have_gpg_error=no
  97 have_libgcrypt=no
  98 have_libassuan=no
  99 have_ksba=no
 100 have_ntbtls=no
 101 have_gnutls=no
 102 have_sqlite=no
 103 have_npth=no
 104 have_libusb=no
 105 have_system_resolver=no
 106 gnupg_have_ldap="n/a"
 107
 108 use_zip=yes
 109 use_bzip2=yes
 110 use_exec=yes
 111 use_trust_models=yes
 112 use_tofu=yes
 113 use_libdns=yes
 114 card_support=yes
 115 use_ccid_driver=auto
 116 dirmngr_auto_start=yes
 117 use_tls_library=no
 118 large_secmem=no
 119 show_tor_support=no
 120
 121
 122 GNUPG_BUILD_PROGRAM(gpg, yes)
 123 GNUPG_BUILD_PROGRAM(gpgsm, yes)
 124 # The agent is a required part and can't be disabled anymore.
 125 build_agent=yes
 126 GNUPG_BUILD_PROGRAM(scdaemon, yes)
 127 GNUPG_BUILD_PROGRAM(g13, no)
 128 GNUPG_BUILD_PROGRAM(dirmngr, yes)
 129 GNUPG_BUILD_PROGRAM(doc, yes)
 130 GNUPG_BUILD_PROGRAM(symcryptrun, no)
 131 # We use gpgtar to unpack test data, hence we always build it.  If the
 132 # user opts out, we simply don't install it.
 133 GNUPG_BUILD_PROGRAM(gpgtar, yes)
 134 GNUPG_BUILD_PROGRAM(wks-tools, no)
 135
 136 AC_SUBST(PACKAGE)
 137 AC_SUBST(PACKAGE_GT)
 138 AC_SUBST(VERSION)
 139 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
 140 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
 141                                 [Name of this package for gettext])
 142 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
 143 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
 144                                         [Bug report address])
 145 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
 146                                        [Required version of Libgcrypt])
 147 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
 148                                        [Required version of Libksba])
 149 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
 150                                        [Required version of NTBTLS])
 151
 152
 153
 154 # The default is to use the modules from this package and the few
 155 # other packages in a standard place; i.e where this package gets
 156 # installed.  With these options it is possible to override these
 157 # ${prefix} depended values with fixed paths, which can't be replaced
 158 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
 159 AC_ARG_WITH(agent-pgm,
 160     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
 161           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
 162 AC_SUBST(GNUPG_AGENT_PGM)
 163 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
 164 show_gnupg_agent_pgm="(default)"
 165 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
 166
 167 AC_ARG_WITH(pinentry-pgm,
 168     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
 169           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
 170 AC_SUBST(GNUPG_PINENTRY_PGM)
 171 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
 172 show_gnupg_pinentry_pgm="(default)"
 173 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
 174
 175
 176 AC_ARG_WITH(scdaemon-pgm,
 177     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
 178           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
 179 AC_SUBST(GNUPG_SCDAEMON_PGM)
 180 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
 181 show_gnupg_scdaemon_pgm="(default)"
 182 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
 183
 184
 185 AC_ARG_WITH(dirmngr-pgm,
 186     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
 187           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
 188 AC_SUBST(GNUPG_DIRMNGR_PGM)
 189 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
 190 show_gnupg_dirmngr_pgm="(default)"
 191 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
 192
 193 AC_ARG_WITH(protect-tool-pgm,
 194     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
 195           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
 196 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
 197 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
 198 show_gnupg_protect_tool_pgm="(default)"
 199 test -n "$GNUPG_PROTECT_TOOL_PGM" \
 200       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
 201
 202 AC_ARG_WITH(dirmngr-ldap-pgm,
 203     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmngr ldap wrapper)],
 204           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
 205 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
 206 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
 207 show_gnupg_dirmngr_ldap_pgm="(default)"
 208 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
 209       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
 210
 211
 212 #
 213 # For a long time gpg 2.x was installed as gpg2.  This changed with
 214 # 2.2.  This option can be used to install gpg under the name gpg2.
 215 #
 216 AC_ARG_ENABLE(gpg-is-gpg2,
 217     AC_HELP_STRING([--enable-gpg-is-gpg2],[Set installed name of gpg to gpg2]),
 218     gpg_is_gpg2=$enableval)
 219 if test "$gpg_is_gpg2" = "yes"; then
 220    AC_DEFINE(USE_GPG2_HACK, 1, [Define to install gpg as gpg2])
 221 fi
 222 AM_CONDITIONAL(USE_GPG2_HACK, test "$gpg_is_gpg2" = "yes")
 223
 224
 225 # SELinux support includes tracking of sensitive files to avoid
 226 # leaking their contents through processing these files by gpg itself
 227 AC_MSG_CHECKING([whether SELinux support is requested])
 228 AC_ARG_ENABLE(selinux-support,
 229               AC_HELP_STRING([--enable-selinux-support],
 230                              [enable SELinux support]),
 231               selinux_support=$enableval, selinux_support=no)
 232 AC_MSG_RESULT($selinux_support)
 233
 234
 235 AC_MSG_CHECKING([whether to allocate extra secure memory])
 236 AC_ARG_ENABLE(large-secmem,
 237               AC_HELP_STRING([--enable-large-secmem],
 238                              [allocate extra secure memory]),
 239               large_secmem=$enableval, large_secmem=no)
 240 AC_MSG_RESULT($large_secmem)
 241 if test "$large_secmem" = yes ; then
 242    SECMEM_BUFFER_SIZE=65536
 243 else
 244    SECMEM_BUFFER_SIZE=32768
 245 fi
 246 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
 247                    [Size of secure memory buffer])
 248
 249 AC_MSG_CHECKING([whether to enable trust models])
 250 AC_ARG_ENABLE(trust-models,
 251               AC_HELP_STRING([--disable-trust-models],
 252                              [disable all trust models except "always"]),
 253               use_trust_models=$enableval)
 254 AC_MSG_RESULT($use_trust_models)
 255 if test "$use_trust_models" = no ; then
 256     AC_DEFINE(NO_TRUST_MODELS, 1,
 257              [Define to include only trust-model always])
 258 fi
 259
 260 AC_MSG_CHECKING([whether to enable TOFU])
 261 AC_ARG_ENABLE(tofu,
 262                 AC_HELP_STRING([--disable-tofu],
 263                                [disable the TOFU trust model]),
 264               use_tofu=$enableval, use_tofu=$use_trust_models)
 265 AC_MSG_RESULT($use_tofu)
 266 if test "$use_trust_models" = no && test "$use_tofu" = yes; then
 267     AC_MSG_ERROR([both --disable-trust-models and --enable-tofu given])
 268 fi
 269
 270 AC_MSG_CHECKING([whether to enable libdns])
 271 AC_ARG_ENABLE(libdns,
 272                 AC_HELP_STRING([--disable-libdns],
 273                                [do not build with libdns support]),
 274               use_libdns=$enableval, use_libdns=yes)
 275 AC_MSG_RESULT($use_libdns)
 276 if test x"$use_libdns" = xyes ; then
 277     AC_DEFINE(USE_LIBDNS, 1, [Build with integrated libdns support])
 278 fi
 279 AM_CONDITIONAL(USE_LIBDNS, test "$use_libdns" = yes)
 280
 281
 282 #
 283 # Options to disable algorithm
 284 #
 285
 286 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
 287 # Elgamal is a MUST algorithm
 288 # DSA is a MUST algorithm
 289 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
 290 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
 291 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
 292
 293 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
 294 # 3DES is a MUST algorithm
 295 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
 296 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
 297 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
 298 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
 299 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
 300 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
 301 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
 302 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
 303 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
 304
 305 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
 306 # SHA1 is a MUST algorithm
 307 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
 308 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
 309 # SHA256 is a MUST algorithm for GnuPG.
 310 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
 311 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
 312
 313
 314 # Allow disabling of zip support.
 315 # This is in general not a good idea because according to rfc4880 OpenPGP
 316 # implementations SHOULD support ZLIB.
 317 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
 318 AC_ARG_ENABLE(zip,
 319    AC_HELP_STRING([--disable-zip],
 320                   [disable the ZIP and ZLIB compression algorithm]),
 321    use_zip=$enableval)
 322 AC_MSG_RESULT($use_zip)
 323
 324 # Allow disabling of bzib2 support.
 325 # It is defined only after we confirm the library is available later
 326 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
 327 AC_ARG_ENABLE(bzip2,
 328    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
 329    use_bzip2=$enableval)
 330 AC_MSG_RESULT($use_bzip2)
 331
 332 # Configure option to allow or disallow execution of external
 333 # programs, like a photo viewer.
 334 AC_MSG_CHECKING([whether to enable external program execution])
 335 AC_ARG_ENABLE(exec,
 336     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
 337     use_exec=$enableval)
 338 AC_MSG_RESULT($use_exec)
 339 if test "$use_exec" = no ; then
 340     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
 341 fi
 342
 343 if test "$use_exec" = yes ; then
 344   AC_MSG_CHECKING([whether to enable photo ID viewing])
 345   AC_ARG_ENABLE(photo-viewers,
 346       [  --disable-photo-viewers disable photo ID viewers],
 347       [if test "$enableval" = no ; then
 348          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
 349       fi],enableval=yes)
 350   gnupg_cv_enable_photo_viewers=$enableval
 351   AC_MSG_RESULT($enableval)
 352
 353   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
 354     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
 355     AC_ARG_WITH(photo-viewer,
 356         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
 357         [if test "$withval" = yes ; then
 358            withval=no
 359         elif test "$withval" != no ; then
 360            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
 361                             [if set, restrict photo-viewer to this])
 362         fi],withval=no)
 363     AC_MSG_RESULT($withval)
 364   fi
 365 fi
 366
 367
 368 #
 369 # Check for the key/uid cache size.  This can't be zero, but can be
 370 # pretty small on embedded systems.  This is used for the gpg part.
 371 #
 372 AC_MSG_CHECKING([for the size of the key and uid cache])
 373 AC_ARG_ENABLE(key-cache,
 374         AC_HELP_STRING([--enable-key-cache=SIZE],
 375                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
 376 if test "$enableval" = "no"; then
 377    enableval=5
 378 elif test "$enableval" = "yes" || test "$enableval" = ""; then
 379    enableval=4096
 380 fi
 381 changequote(,)dnl
 382 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
 383 changequote([,])dnl
 384 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
 385    AC_MSG_ERROR([invalid key-cache size])
 386 fi
 387 AC_MSG_RESULT($key_cache_size)
 388 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
 389                   [Size of the key and UID caches])
 390
 391
 392
 393 #
 394 # Check whether we want to use Linux capabilities
 395 #
 396 AC_MSG_CHECKING([whether use of capabilities is requested])
 397 AC_ARG_WITH(capabilities,
 398     [  --with-capabilities     use linux capabilities [default=no]],
 399 [use_capabilities="$withval"],[use_capabilities=no])
 400 AC_MSG_RESULT($use_capabilities)
 401
 402 #
 403 # Check whether to disable the card support
 404 AC_MSG_CHECKING([whether smartcard support is requested])
 405 AC_ARG_ENABLE(card-support,
 406               AC_HELP_STRING([--disable-card-support],
 407                              [disable smartcard support]),
 408               card_support=$enableval)
 409 AC_MSG_RESULT($card_support)
 410 if test "$card_support" = yes ; then
 411   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
 412 else
 413   build_scdaemon=no
 414 fi
 415
 416 #
 417 # Allow disabling of internal CCID support.
 418 # It is defined only after we confirm the library is available later
 419 #
 420 AC_MSG_CHECKING([whether to enable the internal CCID driver])
 421 AC_ARG_ENABLE(ccid-driver,
 422               AC_HELP_STRING([--disable-ccid-driver],
 423                              [disable the internal CCID driver]),
 424               use_ccid_driver=$enableval)
 425 AC_MSG_RESULT($use_ccid_driver)
 426
 427 AC_MSG_CHECKING([whether to auto start dirmngr])
 428 AC_ARG_ENABLE(dirmngr-auto-start,
 429               AC_HELP_STRING([--disable-dirmngr-auto-start],
 430                              [disable auto starting of the dirmngr]),
 431               dirmngr_auto_start=$enableval)
 432 AC_MSG_RESULT($dirmngr_auto_start)
 433 if test "$dirmngr_auto_start" = yes ; then
 434     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
 435               [Define to enable auto starting of the dirmngr])
 436 fi
 437
 438
 439 #
 440 # To avoid double inclusion of config.h which might happen at some
 441 # places, we add the usual double inclusion protection at the top of
 442 # config.h.
 443 #
 444 AH_TOP([
 445 #ifndef GNUPG_CONFIG_H_INCLUDED
 446 #define GNUPG_CONFIG_H_INCLUDED
 447 ])
 448
 449 #
 450 # Stuff which goes at the bottom of config.h.
 451 #
 452 AH_BOTTOM([
 453 /* This is the major version number of GnuPG so that
 454    source included files can test for this.  Note, that
 455    we use 2 here even for GnuPG 1.9.x. */
 456 #define GNUPG_MAJOR_VERSION 2
 457
 458 /* Now to separate file name parts.
 459    Please note that the string version must not contain more
 460    than one character because the code assumes strlen()==1 */
 461 #ifdef HAVE_DOSISH_SYSTEM
 462 #define DIRSEP_C '\\'
 463 #define DIRSEP_S "\\"
 464 #define EXTSEP_C '.'
 465 #define EXTSEP_S "."
 466 #define PATHSEP_C ';'
 467 #define PATHSEP_S ";"
 468 #define EXEEXT_S ".exe"
 469 #else
 470 #define DIRSEP_C '/'
 471 #define DIRSEP_S "/"
 472 #define EXTSEP_C '.'
 473 #define EXTSEP_S "."
 474 #define PATHSEP_C ':'
 475 #define PATHSEP_S ":"
 476 #define EXEEXT_S ""
 477 #endif
 478
 479 /* This is the same as VERSION, but should be overridden if the
 480    platform cannot handle things like dots '.' in filenames. Set
 481    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
 482    uses for dots and dashes. */
 483 #define SAFE_VERSION VERSION
 484 #define SAFE_VERSION_DOT  '.'
 485 #define SAFE_VERSION_DASH '-'
 486
 487 /* Some global constants.
 488  * Note that the homedir must not end in a slash.  */
 489 #ifdef HAVE_DOSISH_SYSTEM
 490 # ifdef HAVE_DRIVE_LETTERS
 491 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
 492 # else
 493 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
 494 # endif
 495 #elif defined(__VMS)
 496 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
 497 #else
 498 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
 499 #endif
 500 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
 501 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
 502
 503 /* For some systems (DOS currently), we hardcode the path here.  For
 504    POSIX systems the values are constructed by the Makefiles, so that
 505    the values may be overridden by the make invocations; this is to
 506    comply with the GNU coding standards.  Note that these values are
 507    only defaults.  */
 508 #ifdef HAVE_DOSISH_SYSTEM
 509 # ifdef HAVE_DRIVE_LETTERS
 510 #  define GNUPG_BINDIR      "c:\\gnupg"
 511 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
 512 #  define GNUPG_LIBDIR      "c:\\gnupg"
 513 #  define GNUPG_DATADIR     "c:\\gnupg"
 514 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
 515 # else
 516 #  define GNUPG_BINDIR      "\\gnupg"
 517 #  define GNUPG_LIBEXECDIR  "\\gnupg"
 518 #  define GNUPG_LIBDIR      "\\gnupg"
 519 #  define GNUPG_DATADIR     "\\gnupg"
 520 #  define GNUPG_SYSCONFDIR  "\\gnupg"
 521 # endif
 522 #endif
 523
 524 /* Derive some other constants. */
 525 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
 526 #define EXEC_TEMPFILE_ONLY
 527 #endif
 528
 529
 530 /* We didn't define endianness above, so get it from OS macros.  This
 531    is intended for making fat binary builds on OS X. */
 532 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
 533 #if defined(__BIG_ENDIAN__)
 534 #define BIG_ENDIAN_HOST 1
 535 #elif defined(__LITTLE_ENDIAN__)
 536 #define LITTLE_ENDIAN_HOST 1
 537 #else
 538 #error "No endianness found"
 539 #endif
 540 #endif
 541
 542
 543 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
 544    ldap_start_tls_s because that is the actual symbol used in the
 545    library.  winldap.h redefines it to our commonly used value,
 546    thus we define our usual macro here.  */
 547 #ifdef HAVE_LDAP_START_TLS_SA
 548 # ifndef HAVE_LDAP_START_TLS_S
 549 #  define HAVE_LDAP_START_TLS_S 1
 550 # endif
 551 #endif
 552
 553 /* Provide the es_ macro for estream.  */
 554 #define GPGRT_ENABLE_ES_MACROS 1
 555
 556 /* Tell libgcrypt not to use its own libgpg-error implementation. */
 557 #define USE_LIBGPG_ERROR 1
 558
 559 /* Tell Libgcrypt not to include deprecated definitions.  */
 560 #define GCRYPT_NO_DEPRECATED 1
 561
 562 /* Our HTTP code is used in estream mode.  */
 563 #define HTTP_USE_ESTREAM 1
 564
 565 /* Under W32 we do an explicit socket initialization, thus we need to
 566    avoid the on-demand initialization which would also install an atexit
 567    handler.  */
 568 #define HTTP_NO_WSASTARTUP
 569
 570 /* Under Windows we use the gettext code from libgpg-error.  */
 571 #define GPG_ERR_ENABLE_GETTEXT_MACROS
 572
 573 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
 574 #define GPG_ERR_ENABLE_ERRNO_MACROS
 575
 576 #endif /*GNUPG_CONFIG_H_INCLUDED*/
 577 ])
 578
 579
 580 AM_MAINTAINER_MODE
 581 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
 582
 583 # Checks for programs.
 584 AC_MSG_NOTICE([checking for programs])
 585 AC_PROG_MAKE_SET
 586 AM_SANITY_CHECK
 587 missing_dir=`cd $ac_aux_dir && pwd`
 588 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 589 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 590 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
 591 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 592 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
 593 AM_SILENT_RULES
 594 AC_PROG_AWK
 595 AC_PROG_CC
 596 AC_PROG_CPP
 597 AM_PROG_CC_C_O
 598 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
 599   AC_MSG_ERROR([[No C-89 compiler found]])
 600 fi
 601 AC_PROG_INSTALL
 602 AC_PROG_LN_S
 603 AC_PROG_RANLIB
 604 AC_CHECK_TOOL(AR, ar, :)
 605 AC_PATH_PROG(PERL,"perl")
 606 AC_CHECK_TOOL(WINDRES, windres, :)
 607 AC_PATH_PROG(YAT2M, "yat2m", "./yat2m" )
 608 AC_ARG_VAR(YAT2M, [tool to convert texi to man pages])
 609 AC_ISC_POSIX
 610 AC_SYS_LARGEFILE
 611 GNUPG_CHECK_USTAR
 612
 613
 614 # We need to compile and run a program on the build machine.  A
 615 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
 616 # the AC archive is broken for autoconf 2.57.  Given that there is no
 617 # newer version of that macro, we assume that it is also broken for
 618 # autoconf 2.61 and thus we use a simple but usually sufficient
 619 # approach.
 620 AC_MSG_CHECKING(for cc for build)
 621 if test "$cross_compiling" = "yes"; then
 622   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
 623 else
 624   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
 625 fi
 626 AC_MSG_RESULT($CC_FOR_BUILD)
 627 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
 628
 629 # We need to call this macro because other pkg-config macros are
 630 # not always used.
 631 PKG_PROG_PKG_CONFIG
 632
 633
 634 try_gettext=yes
 635 require_iconv=yes
 636 have_dosish_system=no
 637 have_w32_system=no
 638 have_w32ce_system=no
 639 have_android_system=no
 640 use_simple_gettext=no
 641 use_ldapwrapper=yes
 642 mmap_needed=yes
 643 case "${host}" in
 644     *-mingw32*)
 645         # special stuff for Windoze NT
 646         ac_cv_have_dev_random=no
 647         AC_DEFINE(USE_ONLY_8DOT3,1,
 648                   [Set this to limit filenames to the 8.3 format])
 649         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
 650                   [Because the Unix gettext has too much overhead on
 651                    MingW32 systems and these systems lack Posix functions,
 652                    we use a simplified version of gettext])
 653         have_dosish_system=yes
 654         have_w32_system=yes
 655         require_iconv=no
 656         use_ldapwrapper=no  # Fixme: Do this only for CE.
 657         case "${host}" in
 658           *-mingw32ce*)
 659             have_w32ce_system=yes
 660             ;;
 661           *)
 662             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
 663                       [Defined if the OS supports drive letters.])
 664             ;;
 665         esac
 666         try_gettext="no"
 667         use_simple_gettext=yes
 668         mmap_needed=no
 669         ;;
 670     i?86-emx-os2 | i?86-*-os2*emx )
 671         # OS/2 with the EMX environment
 672         ac_cv_have_dev_random=no
 673         AC_DEFINE(HAVE_DRIVE_LETTERS)
 674         have_dosish_system=yes
 675         try_gettext="no"
 676         ;;
 677
 678     i?86-*-msdosdjgpp*)
 679         # DOS with the DJGPP environment
 680         ac_cv_have_dev_random=no
 681         AC_DEFINE(HAVE_DRIVE_LETTERS)
 682         have_dosish_system=yes
 683         try_gettext="no"
 684         ;;
 685
 686     *-*-hpux*)
 687         if test -z "$GCC" ; then
 688             CFLAGS="-Ae -D_HPUX_SOURCE $CFLAGS"
 689         fi
 690         ;;
 691     *-dec-osf4*)
 692         if test -z "$GCC" ; then
 693             # Suppress all warnings
 694             # to get rid of the unsigned/signed char mismatch warnings.
 695             CFLAGS="-w $CFLAGS"
 696         fi
 697         ;;
 698     *-dec-osf5*)
 699         if test -z "$GCC" ; then
 700             # Use the newer compiler `-msg_disable ptrmismatch1' to
 701             # get rid of the unsigned/signed char mismatch warnings.
 702             # Using this may hide other pointer mismatch warnings, but
 703             # it at least lets other warning classes through
 704             CFLAGS="-msg_disable ptrmismatch1 $CFLAGS"
 705         fi
 706         ;;
 707     m68k-atari-mint)
 708         ;;
 709     *-linux-android*)
 710         have_android_system=yes
 711         # Android is fully utf-8 and we do not want to use iconv to
 712         # keeps things simple
 713         require_iconv=no
 714         ;;
 715     *-apple-darwin*)
 716         AC_DEFINE(_DARWIN_C_SOURCE, 900000L,
 717                   Expose all libc features (__DARWIN_C_FULL).)
 718         ;;
 719     *)
 720        ;;
 721 esac
 722
 723 if test "$have_dosish_system" = yes; then
 724    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
 725              [Defined if we run on some of the PCDOS like systems
 726               (DOS, Windoze. OS/2) with special properties like
 727               no file modes, case insensitive file names and preferred
 728               use of backslashes as directory name separators.])
 729 fi
 730 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
 731
 732 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
 733
 734 if test "$have_w32_system" = yes; then
 735    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
 736    if test "$have_w32ce_system" = yes; then
 737       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
 738    fi
 739 fi
 740 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
 741 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
 742
 743 if test "$have_android_system" = yes; then
 744    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
 745 fi
 746 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
 747
 748
 749 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
 750 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
 751
 752
 753 #
 754 # Checks for libraries.
 755 #
 756 AC_MSG_NOTICE([checking for libraries])
 757
 758
 759 #
 760 # libgpg-error is a library with error codes shared between GnuPG
 761 # related projects.
 762 #
 763 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
 764                   have_gpg_error=yes,have_gpg_error=no)
 765
 766
 767 #
 768 # Libgcrypt is our generic crypto library
 769 #
 770 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
 771         have_libgcrypt=yes,have_libgcrypt=no)
 772
 773
 774 #
 775 # libassuan is used for IPC
 776 #
 777 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
 778                   have_libassuan=yes,have_libassuan=no)
 779 if test "$have_libassuan" = "yes"; then
 780   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
 781                      [version of the libassuan library])
 782   show_tor_support="only .onion"
 783 fi
 784
 785
 786 #
 787 # libksba is our X.509 support library
 788 #
 789 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
 790
 791
 792 #
 793 # libusb allows us to use the integrated CCID smartcard reader driver.
 794 #
 795 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
 796 if test "$use_ccid_driver" = auto || test "$use_ccid_driver" = yes; then
 797    case "${host}" in
 798      *-mingw32*)
 799        LIBUSB_NAME=
 800        LIBUSB_LIBS=
 801        LIBUSB_CPPFLAGS=
 802        ;;
 803      *-*-darwin*)
 804        LIBUSB_NAME=usb-1.0
 805        LIBUSB_LIBS="-Wl,-framework,CoreFoundation -Wl,-framework,IOKit"
 806        ;;
 807      *-*-freebsd*)
 808        # FreeBSD has a native 1.0 compatible library by -lusb.
 809        LIBUSB_NAME=usb
 810        LIBUSB_LIBS=
 811        ;;
 812      *)
 813        LIBUSB_NAME=usb-1.0
 814        LIBUSB_LIBS=
 815        ;;
 816    esac
 817 fi
 818 if test x"$LIBUSB_NAME" != x ; then
 819    AC_CHECK_LIB($LIBUSB_NAME, libusb_init,
 820                 [ LIBUSB_LIBS="-l$LIBUSB_NAME $LIBUSB_LIBS"
 821                   have_libusb=yes ])
 822    AC_MSG_CHECKING([libusb include dir])
 823    usb_incdir_found="no"
 824    for _incdir in "" "/usr/include/libusb-1.0" "/usr/local/include/libusb-1.0"; do
 825      _libusb_save_cppflags=$CPPFLAGS
 826      if test -n "${_incdir}"; then
 827        CPPFLAGS="-I${_incdir} ${CPPFLAGS}"
 828      fi
 829      AC_PREPROC_IFELSE([AC_LANG_SOURCE([[@%:@include <libusb.h>]])],
 830      [usb_incdir=${_incdir}; usb_incdir_found="yes"], [])
 831      CPPFLAGS=${_libusb_save_cppflags}
 832      if test "$usb_incdir_found" = "yes"; then
 833        break
 834      fi
 835    done
 836    if test "$usb_incdir_found" = "yes"; then
 837      AC_MSG_RESULT([${usb_incdir}])
 838    else
 839      AC_MSG_RESULT([not found])
 840      usb_incdir=""
 841      have_libusb=no
 842      if test "$use_ccid_driver" != yes; then
 843        use_ccid_driver=no
 844      fi
 845      LIBUSB_LIBS=""
 846    fi
 847
 848    if test "$have_libusb" = yes; then
 849      AC_DEFINE(HAVE_LIBUSB,1, [defined if libusb is available])
 850    fi
 851    if test x"$usb_incdir" = x; then
 852      LIBUSB_CPPFLAGS=""
 853    else
 854      LIBUSB_CPPFLAGS="-I${usb_incdir}"
 855    fi
 856 fi
 857 AC_SUBST(LIBUSB_LIBS)
 858 AC_SUBST(LIBUSB_CPPFLAGS)
 859
 860 #
 861 # Check whether it is necessary to link against libdl.
 862 # (For example to load libpcsclite)
 863 #
 864 gnupg_dlopen_save_libs="$LIBS"
 865 LIBS=""
 866 AC_SEARCH_LIBS(dlopen, c dl,,,)
 867 DL_LIBS=$LIBS
 868 AC_SUBST(DL_LIBS)
 869 LIBS="$gnupg_dlopen_save_libs"
 870
 871
 872 # Checks for g10
 873
 874 AC_ARG_ENABLE(sqlite,
 875                 AC_HELP_STRING([--disable-sqlite],
 876                                [disable the use of SQLITE]),
 877               try_sqlite=$enableval, try_sqlite=yes)
 878
 879 if test x"$use_tofu" = xyes ; then
 880   if test x"$try_sqlite" = xyes ; then
 881     PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $NEED_SQLITE_VERSION],
 882                                  [have_sqlite=yes],
 883                                  [have_sqlite=no])
 884   fi
 885   if test "$have_sqlite" = "yes"; then
 886     :
 887     AC_SUBST([SQLITE3_CFLAGS])
 888     AC_SUBST([SQLITE3_LIBS])
 889   else
 890     use_tofu=no
 891     tmp=$(echo "$SQLITE3_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
 892     AC_MSG_WARN([[
 893 ***
 894 *** Building without SQLite support - TOFU disabled
 895 ***
 896 *** $tmp]])
 897   fi
 898 fi
 899
 900 AM_CONDITIONAL(SQLITE3, test "$have_sqlite" = "yes")
 901
 902 if test x"$use_tofu" = xyes ; then
 903     AC_DEFINE(USE_TOFU, 1, [Enable to build the TOFU code])
 904 fi
 905
 906
 907 # Checks for g13
 908
 909 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
 910 AC_DEFINE_UNQUOTED(ENCFS,
 911         "${ENCFS}", [defines the filename of the encfs program])
 912
 913 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
 914 AC_DEFINE_UNQUOTED(FUSERMOUNT,
 915         "${FUSERMOUNT}", [defines the filename of the fusermount program])
 916
 917
 918 # Checks for dirmngr
 919
 920
 921 #
 922 # Checks for symcryptrun:
 923 #
 924
 925 # libutil has openpty() and login_tty().
 926 AC_CHECK_LIB(util, openpty,
 927               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
 928                 AC_DEFINE(HAVE_LIBUTIL,1,
 929                          [defined if libutil is available])
 930              ])
 931 AC_SUBST(LIBUTIL_LIBS)
 932
 933 # shred is used to clean temporary plain text files.
 934 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
 935 AC_DEFINE_UNQUOTED(SHRED,
 936         "${SHRED}", [defines the filename of the shred program])
 937
 938
 939 #
 940 # Check whether the nPth library is available
 941 #
 942 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
 943 if test "$have_npth" = "yes"; then
 944   AC_DEFINE(HAVE_NPTH, 1,
 945               [Defined if the New Portable Thread Library is available])
 946   AC_DEFINE(USE_NPTH, 1,
 947               [Defined if support for nPth is requested and nPth is available])
 948 else
 949   AC_MSG_WARN([[
 950 ***
 951 *** To support concurrent access for example in gpg-agent and the SCdaemon
 952 *** we need the support of the New Portable Threads Library.
 953 ***]])
 954 fi
 955
 956
 957 #
 958 # NTBTLS is our TLS library.  If it is not available fallback to
 959 # GNUTLS.
 960 #
 961 AC_ARG_ENABLE(ntbtls,
 962               AC_HELP_STRING([--disable-ntbtls],
 963                              [disable the use of NTBTLS as TLS library]),
 964               try_ntbtls=$enableval, try_ntbtls=yes)
 965 if test x"$try_ntbtls" = xyes ; then
 966   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
 967                  [have_ntbtls=yes],[have_ntbtls=no])
 968 fi
 969 if test "$have_ntbtls" = yes ; then
 970    use_tls_library=ntbtls
 971    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
 972 else
 973   AC_ARG_ENABLE(gnutls,
 974                 AC_HELP_STRING([--disable-gnutls],
 975                                [disable GNUTLS as fallback TLS library]),
 976                 try_gnutls=$enableval, try_gnutls=yes)
 977   if test x"$try_gnutls" = xyes ; then
 978     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
 979                                    [have_gnutls=yes],
 980                                    [have_gnutls=no])
 981   fi
 982   if test "$have_gnutls" = "yes"; then
 983     AC_SUBST([LIBGNUTLS_CFLAGS])
 984     AC_SUBST([LIBGNUTLS_LIBS])
 985     use_tls_library=gnutls
 986     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
 987   else
 988     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
 989     AC_MSG_WARN([[
 990 ***
 991 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
 992 ***
 993 *** $tmp]])
 994   fi
 995 fi
 996
 997 #
 998 # Allow to set a fixed trust store file for system provided certificates.
 999 #
1000 AC_ARG_WITH([default-trust-store-file],
1001             [AC_HELP_STRING([--with-default-trust-store-file=FILE],
1002                             [Use FILE as system trust store])],
1003             default_trust_store_file="$withval",
1004             default_trust_store_file="")
1005 if test x"$default_trust_store_file" = xno;then
1006   default_trust_store_file=""
1007 fi
1008 if test x"$default_trust_store_file" != x ; then
1009   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
1010     ["$default_trust_store_file"], [Use as default system trust store file])
1011 fi
1012
1013
1014 AC_MSG_NOTICE([checking for networking options])
1015
1016 #
1017 # Must check for network library requirements before doing link tests
1018 # for ldap, for example. If ldap libs are static (or dynamic and without
1019 # ELF runtime link paths), then link will fail and LDAP support won't
1020 # be detected.
1021 #
1022 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
1023         [NETLIBS="-lnsl $NETLIBS"]))
1024 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
1025         [NETLIBS="-lsocket $NETLIBS"]))
1026
1027
1028 #
1029 # Check standard resolver functions.
1030 #
1031 if test "$build_dirmngr" = "yes"; then
1032   _dns_save_libs=$LIBS
1033   LIBS=""
1034
1035   # Find the system resolver which can always be enabled with
1036   # the dirmngr option --standard-resolver.
1037
1038   # the double underscore thing is a glibc-ism?
1039   AC_SEARCH_LIBS(res_query,resolv bind,,
1040                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
1041   AC_SEARCH_LIBS(dn_expand,resolv bind,,
1042                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
1043
1044   # macOS renames dn_skipname into res_9_dn_skipname in <resolv.h>,
1045   # and for some reason fools us into believing we don't need
1046   # -lresolv even if we do.  Since the test program checking for the
1047   # symbol does not include <resolv.h>, we need to check for the
1048   # renamed symbol explicitly.
1049   AC_SEARCH_LIBS(res_9_dn_skipname,resolv bind,,
1050       AC_SEARCH_LIBS(dn_skipname,resolv bind,,
1051           AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no)))
1052
1053   if test x"$have_resolver" != xno ; then
1054
1055       # Make sure that the BIND 4 resolver interface is workable before
1056       # enabling any code that calls it.  At some point I'll rewrite the
1057       # code to use the BIND 8 resolver API.
1058       # We might also want to use libdns instead.
1059
1060     AC_MSG_CHECKING([whether the resolver is usable])
1061     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1062 #include <netinet/in.h>
1063 #include <arpa/nameser.h>
1064 #include <resolv.h>]],
1065 [[unsigned char answer[PACKETSZ];
1066   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1067   dn_skipname(0,0);
1068   dn_expand(0,0,0,0,0);
1069 ]])],have_resolver=yes,have_resolver=no)
1070     AC_MSG_RESULT($have_resolver)
1071
1072     # This is Apple-specific and somewhat bizarre as they changed the
1073     # define in bind 8 for some reason.
1074
1075     if test x"$have_resolver" != xyes ; then
1076       AC_MSG_CHECKING(
1077            [whether I can make the resolver usable with BIND_8_COMPAT])
1078       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
1079 #include <sys/types.h>
1080 #include <netinet/in.h>
1081 #include <arpa/nameser.h>
1082 #include <resolv.h>]],
1083 [[unsigned char answer[PACKETSZ];
1084   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1085   dn_skipname(0,0); dn_expand(0,0,0,0,0);
1086 ]])],[have_resolver=yes ; need_compat=yes])
1087       AC_MSG_RESULT($have_resolver)
1088     fi
1089   fi
1090
1091   if test x"$have_resolver" = xyes ; then
1092     AC_DEFINE(HAVE_SYSTEM_RESOLVER,1,[The system's resolver is usable.])
1093     DNSLIBS="$DNSLIBS $LIBS"
1094     if test x"$need_compat" = xyes ; then
1095       AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
1096     fi
1097     if test "$use_libdns" = yes; then
1098      show_tor_support=yes
1099     fi
1100   elif test "$use_libdns" = yes; then
1101     show_tor_support=yes
1102   else
1103     AC_MSG_WARN([[
1104 ***
1105 *** The system's DNS resolver is not usable.
1106 *** Dirmngr functionality is limited.
1107 ***]])
1108     show_tor_support="${show_tor_support} (no system resolver)"
1109   fi
1110
1111   if test "$have_w32_system" = yes; then
1112     if test "$use_libdns" = yes; then
1113       DNSLIBS="$DNSLIBS -liphlpapi"
1114     fi
1115   fi
1116
1117   LIBS=$_dns_save_libs
1118 fi
1119
1120 AC_SUBST(DNSLIBS)
1121
1122
1123 #
1124 # Check for LDAP
1125 #
1126 # Note that running the check changes the variable
1127 # gnupg_have_ldap from "n/a" to "no" or "yes".
1128
1129 AC_ARG_ENABLE(ldap,
1130     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1131     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1132
1133 if test "$gnupg_have_ldap" != "no" ; then
1134   if test "$build_dirmngr" = "yes" ; then
1135      GNUPG_CHECK_LDAP($NETLIBS)
1136      AC_CHECK_LIB(lber, ber_free,
1137                   [ LBER_LIBS="$LBER_LIBS -llber"
1138                     AC_DEFINE(HAVE_LBER,1,
1139                              [defined if liblber is available])
1140                     have_lber=yes
1141                  ])
1142   fi
1143 fi
1144 AC_SUBST(LBER_LIBS)
1145 if test "$gnupg_have_ldap" = "no"; then
1146     AC_MSG_WARN([[
1147 ***
1148 *** Building without LDAP support.
1149 *** No CRL access or X.509 certificate search available.
1150 ***]])
1151 fi
1152
1153 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1154 if test "$gnupg_have_ldap" = yes ; then
1155   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1156 else
1157  use_ldapwrapper=no
1158 fi
1159
1160 if test "$use_ldapwrapper" = yes; then
1161    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1162 fi
1163 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1164
1165
1166
1167
1168 #
1169 # Check for sendmail
1170 #
1171 # This isn't necessarily sendmail itself, but anything that gives a
1172 # sendmail-ish interface to the outside world.  That includes Exim,
1173 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1174 AC_ARG_WITH(mailprog,
1175       AC_HELP_STRING([--with-mailprog=NAME],
1176                      [use "NAME -t" for mail transport]),
1177              ,with_mailprog=yes)
1178 if test x"$with_mailprog" = xyes ; then
1179     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1180 elif test x"$with_mailprog" != xno ; then
1181     AC_MSG_CHECKING([for a mail transport program])
1182     AC_SUBST(SENDMAIL,$with_mailprog)
1183     AC_MSG_RESULT($with_mailprog)
1184 fi
1185
1186
1187 #
1188 # Construct a printable name of the OS
1189 #
1190 case "${host}" in
1191     *-mingw32ce*)
1192         PRINTABLE_OS_NAME="W32CE"
1193         ;;
1194     *-mingw32*)
1195         PRINTABLE_OS_NAME="MingW32"
1196         ;;
1197     *-*-cygwin*)
1198         PRINTABLE_OS_NAME="Cygwin"
1199         ;;
1200     i?86-emx-os2 | i?86-*-os2*emx )
1201         PRINTABLE_OS_NAME="OS/2"
1202         ;;
1203     i?86-*-msdosdjgpp*)
1204         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1205         try_dynload=no
1206         ;;
1207     *-linux*)
1208         PRINTABLE_OS_NAME="GNU/Linux"
1209         ;;
1210     *)
1211         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1212         ;;
1213 esac
1214 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1215                    [A human readable text with the name of the OS])
1216
1217
1218 #
1219 # Checking for iconv
1220 #
1221 if test "$require_iconv" = yes; then
1222   AM_ICONV
1223 else
1224   LIBICONV=
1225   LTLIBICONV=
1226   AC_SUBST(LIBICONV)
1227   AC_SUBST(LTLIBICONV)
1228 fi
1229
1230
1231 #
1232 # Check for gettext
1233 #
1234 # This is "GNU gnupg" - The project-id script from gettext
1235 #                       needs this string
1236 #
1237 AC_MSG_NOTICE([checking for gettext])
1238 AM_PO_SUBDIRS
1239 AM_GNU_GETTEXT_VERSION([0.17])
1240 if test "$try_gettext" = yes; then
1241   AM_GNU_GETTEXT([external],[need-ngettext])
1242
1243   # gettext requires some extra checks.  These really should be part of
1244   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1245   # function checks to here.
1246
1247   AC_CHECK_FUNCS(strchr)
1248 else
1249   USE_NLS=no
1250   USE_INCLUDED_LIBINTL=no
1251   BUILD_INCLUDED_LIBINTL=no
1252   POSUB=po
1253   AC_SUBST(USE_NLS)
1254   AC_SUBST(USE_INCLUDED_LIBINTL)
1255   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1256   AC_SUBST(POSUB)
1257 fi
1258
1259 # We use HAVE_LANGINFO_CODESET in a couple of places.
1260 AM_LANGINFO_CODESET
1261
1262 # Checks required for our use of locales
1263 gt_LC_MESSAGES
1264
1265
1266 #
1267 # SELinux support
1268 #
1269 if test "$selinux_support" = yes ; then
1270   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1271 fi
1272
1273
1274 #
1275 # Checks for header files.
1276 #
1277 AC_MSG_NOTICE([checking for header files])
1278 AC_HEADER_STDC
1279 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1280                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h     \
1281                   stdint.h signal.h util.h libutil.h termios.h \
1282                   ucred.h sys/sysmacros.h sys/mkdev.h])
1283
1284 AC_HEADER_TIME
1285
1286
1287 #
1288 # Checks for typedefs, structures, and compiler characteristics.
1289 #
1290 AC_MSG_NOTICE([checking for system characteristics])
1291 AC_C_CONST
1292 AC_C_INLINE
1293 AC_C_VOLATILE
1294 AC_TYPE_SIZE_T
1295 AC_TYPE_MODE_T
1296 AC_TYPE_SIGNAL
1297 AC_DECL_SYS_SIGLIST
1298
1299 gl_HEADER_SYS_SOCKET
1300 gl_TYPE_SOCKLEN_T
1301
1302 AC_SEARCH_LIBS([inet_addr], [nsl])
1303
1304 AC_ARG_ENABLE(endian-check,
1305               AC_HELP_STRING([--disable-endian-check],
1306               [disable the endian check and trust the OS provided macros]),
1307               endiancheck=$enableval,endiancheck=yes)
1308
1309 if test x"$endiancheck" = xyes ; then
1310   GNUPG_CHECK_ENDIAN
1311 fi
1312
1313 # fixme: we should get rid of the byte type
1314 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1315 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1316 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1317 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1318 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1319
1320 AC_CHECK_SIZEOF(unsigned short)
1321 AC_CHECK_SIZEOF(unsigned int)
1322 AC_CHECK_SIZEOF(unsigned long)
1323 AC_CHECK_SIZEOF(unsigned long long)
1324 AC_HEADER_TIME
1325 AC_CHECK_SIZEOF(time_t,,[[
1326 #include <stdio.h>
1327 #if TIME_WITH_SYS_TIME
1328 # include <sys/time.h>
1329 # include <time.h>
1330 #else
1331 # if HAVE_SYS_TIME_H
1332 #  include <sys/time.h>
1333 # else
1334 #  include <time.h>
1335 # endif
1336 #endif
1337 ]])
1338 GNUPG_TIME_T_UNSIGNED
1339
1340
1341 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1342    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1343    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1344     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1345 fi
1346
1347
1348 #
1349 # Checks for library functions.
1350 #
1351 AC_MSG_NOTICE([checking for library functions])
1352 AC_CHECK_DECLS(getpagesize)
1353 AC_FUNC_FSEEKO
1354 AC_FUNC_VPRINTF
1355 AC_FUNC_FORK
1356 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1357 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1358 AC_CHECK_FUNCS([setenv unsetenv fcntl ftruncate inet_ntop])
1359 AC_CHECK_FUNCS([canonicalize_file_name])
1360 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1361 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1362 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1363 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1364 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1365                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1366                 flockfile funlockfile getpwnam getpwuid \
1367                 getenv inet_pton strpbrk])
1368
1369 # On some systems (e.g. Solaris) nanosleep requires linking to librl.
1370 # Given that we use nanosleep only as an optimization over a select
1371 # based wait function we want it only if it is available in libc.
1372 _save_libs="$LIBS"
1373 AC_SEARCH_LIBS([nanosleep], [],
1374                [AC_DEFINE(HAVE_NANOSLEEP,1,
1375                 [Define to 1 if you have the `nanosleep' function in libc.])])
1376 LIBS="$_save_libs"
1377
1378
1379 # See whether libc supports the Linux inotify interface
1380 case "${host}" in
1381     *-*-linux*)
1382         AC_CHECK_FUNCS([inotify_init])
1383         ;;
1384 esac
1385
1386
1387 if test "$have_android_system" = yes; then
1388    # On Android ttyname is a stub but prints an error message.
1389    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1390              [Defined if ttyname does not work properly])
1391 fi
1392
1393 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1394
1395 # Dirmngr requires mmap on Unix systems.
1396 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1397   AC_MSG_ERROR([[Sorry, the current implementation requires mmap.]])
1398 fi
1399
1400
1401 #
1402 # Check for the getsockopt SO_PEERCRED, etc.
1403 #
1404 AC_CHECK_MEMBERS([struct ucred.pid, struct ucred.cr_pid, struct sockpeercred.pid], [], [], [#include <sys/types.h>
1405 #include <sys/socket.h> ])
1406
1407 # (Open)Solaris
1408 AC_CHECK_FUNCS([getpeerucred])
1409
1410
1411 #
1412 # W32 specific test
1413 #
1414 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1415
1416 #
1417 # Sanity check regex.  Tests adapted from mutt.
1418 #
1419 AC_MSG_CHECKING([whether regular expression support is requested])
1420 AC_ARG_ENABLE(regex,
1421   AC_HELP_STRING([--disable-regex],
1422     [do not handle regular expressions in trust signatures]),
1423   use_regex=$enableval, use_regex=yes)
1424 AC_MSG_RESULT($use_regex)
1425
1426 if test "$use_regex" = yes ; then
1427   _cppflags="${CPPFLAGS}"
1428   _ldflags="${LDFLAGS}"
1429   AC_ARG_WITH(regex,
1430      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1431       [
1432       if test -d "$withval" ; then
1433         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1434         LDFLAGS="${LDFLAGS} -L$withval/lib"
1435       fi
1436       ],withval="")
1437
1438   # Does the system have regex functions at all?
1439   AC_SEARCH_LIBS([regcomp], [regex])
1440   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1441
1442   if test $gnupg_cv_have_regex = no; then
1443     use_regex=no
1444   else
1445     if test x"$cross_compiling" = xyes; then
1446       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1447     else
1448       AC_CACHE_CHECK([whether your system's regexp library is broken],
1449        [gnupg_cv_regex_broken],
1450        AC_TRY_RUN([
1451 #include <unistd.h>
1452 #include <regex.h>
1453 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1454        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1455
1456       if test $gnupg_cv_regex_broken = yes; then
1457         AC_MSG_WARN([your regex is broken - disabling regex use])
1458         use_regex=no
1459       fi
1460     fi
1461   fi
1462   CPPFLAGS="${_cppflags}"
1463   LDFLAGS="${_ldflags}"
1464 fi
1465
1466 if test "$use_regex" != yes ; then
1467   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1468 fi
1469 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1470
1471
1472
1473 #
1474 # Do we have zlib? Must do it here because Solaris failed
1475 # when compiling a conftest (due to the "-lz" from LIBS).
1476 # Note that we combine zlib and bzlib2 in ZLIBS.
1477 #
1478 if test "$use_zip" = yes ; then
1479   _cppflags="${CPPFLAGS}"
1480   _ldflags="${LDFLAGS}"
1481   AC_ARG_WITH(zlib,
1482     [  --with-zlib=DIR         use libz in DIR],[
1483       if test -d "$withval"; then
1484         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1485         LDFLAGS="${LDFLAGS} -L$withval/lib"
1486       fi
1487     ])
1488
1489   AC_CHECK_HEADER(zlib.h,
1490      AC_CHECK_LIB(z, deflateInit2_,
1491        [
1492        ZLIBS="-lz"
1493        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1494        ],
1495        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1496        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1497 fi
1498
1499
1500 #
1501 # Check whether we can support bzip2
1502 #
1503 if test "$use_bzip2" = yes ; then
1504   _cppflags="${CPPFLAGS}"
1505   _ldflags="${LDFLAGS}"
1506   AC_ARG_WITH(bzip2,
1507      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1508       [
1509       if test -d "$withval" ; then
1510         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1511         LDFLAGS="${LDFLAGS} -L$withval/lib"
1512       fi
1513       ],withval="")
1514
1515   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1516   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1517   # woefully out of date.
1518   if test "$withval" != no ; then
1519      AC_CHECK_HEADER(bzlib.h,
1520         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1521           [
1522           have_bz2=yes
1523           ZLIBS="$ZLIBS -lbz2"
1524           AC_DEFINE(HAVE_BZIP2,1,
1525                   [Defined if the bz2 compression library is available])
1526           ],
1527           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1528           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1529   fi
1530 fi
1531 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1532 AC_SUBST(ZLIBS)
1533
1534
1535 # Check for readline support
1536 GNUPG_CHECK_READLINE
1537
1538
1539 if test "$development_version" = yes; then
1540     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1541             [Defined if this is not a regular release])
1542 fi
1543
1544 if test "$USE_MAINTAINER_MODE" = "yes"; then
1545     AC_DEFINE(MAINTAINER_MODE,1,
1546             [Defined if this build is in maintainer mode])
1547 fi
1548
1549 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1550
1551 GNUPG_CHECK_GNUMAKE
1552
1553 # Add some extra libs here so that previous tests don't fail for
1554 # mysterious reasons - the final link step should bail out.
1555 # W32SOCKLIBS is also defined so that if can be used for tools not
1556 # requiring any network stuff but linking to code in libcommon which
1557 # tracks in winsock stuff (e.g. init_common_subsystems).
1558 if test "$have_w32_system" = yes; then
1559    if test "$have_w32ce_system" = yes; then
1560      W32SOCKLIBS="-lws2"
1561    else
1562      W32SOCKLIBS="-lws2_32"
1563    fi
1564    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1565 fi
1566
1567 AC_SUBST(NETLIBS)
1568 AC_SUBST(W32SOCKLIBS)
1569
1570 #
1571 # Setup gcc specific options
1572 #
1573 USE_C99_CFLAGS=
1574 AC_MSG_NOTICE([checking for cc features])
1575 if test "$GCC" = yes; then
1576     mycflags=
1577     mycflags_save=$CFLAGS
1578
1579     # Check whether gcc does not emit a diagnositc for unknown -Wno-*
1580     # options.  This is the case for gcc >= 4.6
1581     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1582     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1583 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1584 #kickerror
1585 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1586     AC_MSG_RESULT($_gcc_silent_wno)
1587
1588     # Note that it is okay to use CFLAGS here because these are just
1589     # warning options and the user should have a chance of overriding
1590     # them.
1591     if test "$USE_MAINTAINER_MODE" = "yes"; then
1592         mycflags="$mycflags -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1593         mycflags="$mycflags -Wformat -Wno-format-y2k -Wformat-security"
1594         if test x"$_gcc_silent_wno" = xyes ; then
1595           _gcc_wopt=yes
1596         else
1597           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1598           CFLAGS="-Wno-missing-field-initializers"
1599           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1600                             [_gcc_wopt=yes],[_gcc_wopt=no])
1601           AC_MSG_RESULT($_gcc_wopt)
1602         fi
1603         if test x"$_gcc_wopt" = xyes ; then
1604           mycflags="$mycflags -W -Wno-sign-compare"
1605           mycflags="$mycflags -Wno-missing-field-initializers"
1606         fi
1607
1608         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1609         CFLAGS="-Wdeclaration-after-statement"
1610         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1611         AC_MSG_RESULT($_gcc_wopt)
1612         if test x"$_gcc_wopt" = xyes ; then
1613           mycflags="$mycflags -Wdeclaration-after-statement"
1614         fi
1615
1616         AC_MSG_CHECKING([if gcc supports -Wlogical-op and -Wvla])
1617         CFLAGS="-Wlogical-op -Wvla"
1618         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1619         AC_MSG_RESULT($_gcc_wopt)
1620         if test x"$_gcc_wopt" = xyes ; then
1621           mycflags="$mycflags -Wlogical-op -Wvla"
1622         fi
1623
1624     else
1625         mycflags="$mycflags -Wall"
1626     fi
1627
1628     if test x"$_gcc_silent_wno" = xyes ; then
1629       _gcc_psign=yes
1630     else
1631       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1632       CFLAGS="-Wno-pointer-sign"
1633       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1634                         [_gcc_psign=yes],[_gcc_psign=no])
1635       AC_MSG_RESULT($_gcc_psign)
1636     fi
1637     if test x"$_gcc_psign" = xyes ; then
1638        mycflags="$mycflags -Wno-pointer-sign"
1639     fi
1640
1641     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1642     CFLAGS="-Wpointer-arith"
1643     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1644     AC_MSG_RESULT($_gcc_psign)
1645     if test x"$_gcc_psign" = xyes ; then
1646        mycflags="$mycflags -Wpointer-arith"
1647     fi
1648
1649     CFLAGS="$mycflags $mycflags_save"
1650     if test "$use_libdns" = yes; then
1651        # dirmngr/dns.{c,h} require C99 and GNU extensions.  */
1652        USE_C99_CFLAGS="-std=gnu99"
1653     fi
1654 fi
1655
1656 AC_SUBST(USE_C99_CFLAGS)
1657
1658
1659 #
1660 # This is handy for debugging so the compiler doesn't rearrange
1661 # things and eliminate variables.
1662 #
1663 AC_ARG_ENABLE(optimization,
1664    AC_HELP_STRING([--disable-optimization],
1665                   [disable compiler optimization]),
1666                   [if test $enableval = no ; then
1667                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1668                    fi])
1669
1670 #
1671 # We do not want support for the GNUPG_BUILDDIR environment variable
1672 # in a released version.  However, our regression tests suite requires
1673 # this and thus we build with support for it during "make distcheck".
1674 # This configure option implements this along with the top Makefile's
1675 # AM_DISTCHECK_CONFIGURE_FLAGS.
1676 #
1677 gnupg_builddir_envvar=no
1678 AC_ARG_ENABLE(gnupg-builddir-envvar,,
1679               gnupg_builddir_envvar=$enableval)
1680 if test x"$gnupg_builddir_envvar" = x"yes"; then
1681    AC_DEFINE(ENABLE_GNUPG_BUILDDIR_ENVVAR, 1,
1682       [This is only used with "make distcheck"])
1683 fi
1684
1685 #
1686 # Add user CFLAGS.
1687 #
1688 CFLAGS="$CFLAGS $CFLAGS_orig"
1689
1690 #
1691 # Decide what to build
1692 #
1693
1694 build_scdaemon_extra=""
1695 if test "$build_scdaemon" = "yes"; then
1696   if test $have_libusb = no; then
1697      build_scdaemon_extra="without internal CCID driver"
1698   fi
1699   if test -n "$build_scdaemon_extra"; then
1700      build_scdaemon_extra="(${build_scdaemon_extra})"
1701   fi
1702 fi
1703
1704
1705 #
1706 # Set variables for use by automake makefiles.
1707 #
1708 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1709 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1710 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1711 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1712 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1713 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1714 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1715 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1716 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1717 AM_CONDITIONAL(BUILD_WKS_TOOLS,   test "$build_wks_tools" = "yes")
1718
1719 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1720 AM_CONDITIONAL(NO_TRUST_MODELS,     test "$use_trust_models" = no)
1721 AM_CONDITIONAL(USE_TOFU,            test "$use_tofu" = yes)
1722
1723 #
1724 # Set some defines for use gpgconf.
1725 #
1726 if test "$build_gpg" = yes ; then
1727     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1728 fi
1729 if test "$build_gpgsm" = yes ; then
1730     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1731 fi
1732 if test "$build_agent" = yes ; then
1733     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1734 fi
1735 if test "$build_scdaemon" = yes ; then
1736     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1737 fi
1738 if test "$build_dirmngr" = yes ; then
1739     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if SCDAEMON is to be build])
1740 fi
1741 if test "$build_g13" = yes ; then
1742     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1743 fi
1744
1745
1746 #
1747 # Define Name strings
1748 #
1749 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1750
1751 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1752 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1753
1754 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1755 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1756
1757 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1758 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1759                                         [The displayed name of gpg-agent])
1760
1761 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1762 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1763                                        [The displayed name of scdaemon])
1764
1765 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1766 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1767                                       [The displayed name of dirmngr])
1768
1769 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1770 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1771
1772 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1773 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1774                                       [The displayed name of gpgconf])
1775
1776 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1777
1778 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1779                    [The name of the agent socket])
1780 AC_DEFINE_UNQUOTED(GPG_AGENT_EXTRA_SOCK_NAME, "S.gpg-agent.extra",
1781                    [The name of the agent socket for remote access])
1782 AC_DEFINE_UNQUOTED(GPG_AGENT_BROWSER_SOCK_NAME, "S.gpg-agent.browser",
1783                    [The name of the agent socket for browsers])
1784 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1785                    [The name of the agent socket for ssh])
1786 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1787                    [The name of the dirmngr info envvar])
1788 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1789                    [The name of the SCdaemon socket])
1790 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1791                    [The name of the dirmngr socket])
1792 AC_DEFINE_UNQUOTED(DIRMNGR_DEFAULT_KEYSERVER,
1793                    "hkps://hkps.pool.sks-keyservers.net",
1794       [The default keyserver for dirmngr to use, if none is explicitly given])
1795
1796 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1797
1798 if test "$have_w32_system" = yes; then
1799   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "\\\\Software\\\\GNU\\\\GnuPG",
1800                      [The directory part of the W32 registry keys])
1801 fi
1802
1803
1804 #
1805 # Provide information about the build.
1806 #
1807 BUILD_REVISION="mym4_revision"
1808 AC_SUBST(BUILD_REVISION)
1809 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1810                    [GIT commit id revision used to build this package])
1811
1812 changequote(,)dnl
1813 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1814 changequote([,])dnl
1815 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1816 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1817 AC_SUBST(BUILD_VERSION)
1818 AC_SUBST(BUILD_FILEVERSION)
1819
1820 AC_ARG_ENABLE([build-timestamp],
1821   AC_HELP_STRING([--enable-build-timestamp],
1822                  [set an explicit build timestamp for reproducibility.
1823                   (default is the current time in ISO-8601 format)]),
1824      [if test "$enableval" = "yes"; then
1825         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1826       else
1827         BUILD_TIMESTAMP="$enableval"
1828       fi
1829       BUILD_HOSTNAME="$ac_hostname"],
1830      [BUILD_TIMESTAMP="<none>"
1831       BUILD_HOSTNAME="<anon>"])
1832 AC_SUBST(BUILD_TIMESTAMP)
1833 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1834                    [The time this package was configured for a build])
1835 AC_SUBST(BUILD_HOSTNAME)
1836
1837
1838 #
1839 # Print errors here so that they are visible all
1840 # together and the user can acquire them all together.
1841 #
1842 die=no
1843 if test "$have_gpg_error" = "no"; then
1844    die=yes
1845    AC_MSG_NOTICE([[
1846 ***
1847 *** You need libgpg-error to build this program.
1848 **  This library is for example available at
1849 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1850 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1851 ***]])
1852 fi
1853 if test "$have_libgcrypt" = "no"; then
1854    die=yes
1855    AC_MSG_NOTICE([[
1856 ***
1857 *** You need libgcrypt to build this program.
1858 **  This library is for example available at
1859 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1860 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1861 ***]])
1862 fi
1863 if test "$have_libassuan" = "no"; then
1864    die=yes
1865    AC_MSG_NOTICE([[
1866 ***
1867 *** You need libassuan to build this program.
1868 *** This library is for example available at
1869 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1870 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1871 ***]])
1872 fi
1873 if test "$have_ksba" = "no"; then
1874     die=yes
1875     AC_MSG_NOTICE([[
1876 ***
1877 *** You need libksba to build this program.
1878 *** This library is for example available at
1879 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1880 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1881 ***]])
1882 fi
1883 if test "$gnupg_have_ldap" = yes; then
1884   if test "$have_w32ce_system" = yes; then
1885     AC_MSG_NOTICE([[
1886 *** Note that CeGCC might be broken, a package fixing this is:
1887 ***    http://files.kolab.org/local/windows-ce/
1888 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1889 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1890 ***]])
1891    fi
1892 fi
1893 if test "$have_npth" = "no"; then
1894     die=yes
1895     AC_MSG_NOTICE([[
1896 ***
1897 *** It is now required to build with support for the
1898 *** New Portable Threads Library (nPth). Please install this
1899 *** library first.  The library is for example available at
1900 ***   ftp://ftp.gnupg.org/gcrypt/npth/
1901 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1902 ***]])
1903 fi
1904
1905 if test "$require_iconv" = yes; then
1906   if test "$am_func_iconv" != yes; then
1907     die=yes
1908     AC_MSG_NOTICE([[
1909 ***
1910 *** The system does not provide a working iconv function.  Please
1911 *** install a suitable library; for example GNU Libiconv which is
1912 *** available at:
1913 ***   http://ftp.gnu.org/gnu/libiconv/
1914 ***]])
1915   fi
1916 fi
1917
1918 if test "$use_ccid_driver" = yes; then
1919   if test "$have_libusb" != yes; then
1920     die=yes
1921     AC_MSG_NOTICE([[
1922 ***
1923 *** You need libusb to build the internal ccid driver.  Please
1924 *** install a libusb suitable for your system.
1925 ***]])
1926   fi
1927 fi
1928
1929 if test "$die" = "yes"; then
1930     AC_MSG_ERROR([[
1931 ***
1932 *** Required libraries not found. Please consult the above messages
1933 *** and install them before running configure again.
1934 ***]])
1935 fi
1936
1937
1938
1939 AC_CONFIG_FILES([ m4/Makefile
1940 Makefile
1941 po/Makefile.in
1942 common/Makefile
1943 common/w32info-rc.h
1944 kbx/Makefile
1945 g10/Makefile
1946 sm/Makefile
1947 agent/Makefile
1948 scd/Makefile
1949 g13/Makefile
1950 dirmngr/Makefile
1951 tools/gpg-zip
1952 tools/Makefile
1953 doc/Makefile
1954 tests/Makefile
1955 tests/gpgscm/Makefile
1956 tests/openpgp/Makefile
1957 tests/migrations/Makefile
1958 tests/gpgsm/Makefile
1959 tests/gpgme/Makefile
1960 tests/pkits/Makefile
1961 g10/gpg.w32-manifest
1962 ])
1963
1964
1965 AC_OUTPUT
1966
1967
1968 echo "
1969         GnuPG v${VERSION} has been configured as follows:
1970
1971         Revision:  mym4_revision  (mym4_revision_dec)
1972         Platform:  $PRINTABLE_OS_NAME ($host)
1973
1974         OpenPGP:   $build_gpg
1975         S/MIME:    $build_gpgsm
1976         Agent:     $build_agent
1977         Smartcard: $build_scdaemon $build_scdaemon_extra
1978         G13:       $build_g13
1979         Dirmngr:   $build_dirmngr
1980         Gpgtar:    $build_gpgtar
1981         WKS tools: $build_wks_tools
1982
1983         Protect tool:      $show_gnupg_protect_tool_pgm
1984         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
1985         Default agent:     $show_gnupg_agent_pgm
1986         Default pinentry:  $show_gnupg_pinentry_pgm
1987         Default scdaemon:  $show_gnupg_scdaemon_pgm
1988         Default dirmngr:   $show_gnupg_dirmngr_pgm
1989
1990         Dirmngr auto start:  $dirmngr_auto_start
1991         Readline support:    $gnupg_cv_have_readline
1992         LDAP support:        $gnupg_have_ldap
1993         TLS support:         $use_tls_library
1994         TOFU support:        $use_tofu
1995         Tor support:         $show_tor_support
1996 "
1997 if test x"$use_regex" != xyes ; then
1998 echo "
1999         Warning: No regular expression support available.
2000                  OpenPGP trust signatures won't work.
2001                  gpg-check-pattern will not be built.
2002 "
2003 fi
2004 if test "x${gpg_config_script_warn}" != x; then
2005 cat <<G10EOF
2006         Warning: Mismatches between the target platform and the
2007                  to be used libraries have been detected for:
2008                   ${gpg_config_script_warn}
2009                  Please check above for more warning messages.
2010
2011 G10EOF
2012 fi