Fix comment of configure.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998-2017 Free Software Foundation, Inc.
3 # Copyright (C) 1998-2017 Werner Koch
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <https://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.14"
23
24 # To build a release you need to create a tag with the version number
25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
26 # bump the version number immediately *after* the release and do
27 # another commit and push so that the git magic is able to work.
28 m4_define([mym4_package],[gnupg])
29 m4_define([mym4_major], [2])
30 m4_define([mym4_minor], [3])
31 m4_define([mym4_micro], [0])
32
33 # To start a new development series, i.e a new major or minor number
34 # you need to mark an arbitrary commit before the first beta release
35 # with an annotated tag.  For example the 2.1 branch starts off with
36 # the tag "gnupg-2.1-base".  This is used as the base for counting
37 # beta numbers before the first release of a series.
38
39 # Below is m4 magic to extract and compute the git revision number,
40 # the decimalized short revision number, a beta version string and a
41 # flag indicating a development version (mym4_isbeta).  Note that the
42 # m4 processing is done by autoconf and not during the configure run.
43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
49 m4_esyscmd([echo ]mym4_version[>VERSION])
50 AC_INIT([mym4_package],[mym4_version], [https://bugs.gnupg.org])
51
52 # When changing the SWDB tag please also adjust the hard coded tags in
53 # build-aux/speedo.mk and Makefile.am
54 AC_DEFINE_UNQUOTED(GNUPG_SWDB_TAG, "gnupg22", [swdb tag for this branch])
55
56 NEED_GPG_ERROR_VERSION=1.24
57
58 NEED_LIBGCRYPT_API=1
59 NEED_LIBGCRYPT_VERSION=1.7.0
60
61 NEED_LIBASSUAN_API=2
62 NEED_LIBASSUAN_VERSION=2.4.3
63
64 NEED_KSBA_API=1
65 NEED_KSBA_VERSION=1.3.4
66
67 NEED_NTBTLS_API=1
68 NEED_NTBTLS_VERSION=0.1.0
69
70 NEED_NPTH_API=1
71 NEED_NPTH_VERSION=1.2
72
73
74 NEED_GNUTLS_VERSION=3.0
75
76 NEED_SQLITE_VERSION=3.7
77
78 development_version=mym4_isbeta
79 PACKAGE=$PACKAGE_NAME
80 PACKAGE_GT=${PACKAGE_NAME}2
81 VERSION=$PACKAGE_VERSION
82
83 AC_CONFIG_AUX_DIR([build-aux])
84 AC_CONFIG_SRCDIR([sm/gpgsm.c])
85 AC_CONFIG_HEADER([config.h])
86 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
87 AC_CANONICAL_HOST
88 AB_INIT
89
90 AC_GNU_SOURCE
91
92 # Before we do anything with the C compiler, we first save the user's
93 # CFLAGS (they are restored at the end of the configure script).  This
94 # is because some configure checks don't work with -Werror, but we'd
95 # like to use -Werror with our build.
96 CFLAGS_orig=$CFLAGS
97 CFLAGS=
98
99 # Some status variables.
100 have_gpg_error=no
101 have_libgcrypt=no
102 have_libassuan=no
103 have_ksba=no
104 have_ntbtls=no
105 have_gnutls=no
106 have_sqlite=no
107 have_npth=no
108 have_libusb=no
109 have_system_resolver=no
110 gnupg_have_ldap="n/a"
111
112 use_zip=yes
113 use_bzip2=yes
114 use_exec=yes
115 use_trust_models=yes
116 use_tofu=yes
117 use_libdns=yes
118 card_support=yes
119 use_ccid_driver=auto
120 dirmngr_auto_start=yes
121 use_tls_library=no
122 large_secmem=no
123 show_tor_support=no
124
125 GNUPG_BUILD_PROGRAM(gpg, yes)
126 GNUPG_BUILD_PROGRAM(gpgsm, yes)
127 # The agent is a required part and can't be disabled anymore.
128 build_agent=yes
129 GNUPG_BUILD_PROGRAM(scdaemon, yes)
130 GNUPG_BUILD_PROGRAM(g13, no)
131 GNUPG_BUILD_PROGRAM(dirmngr, yes)
132 GNUPG_BUILD_PROGRAM(doc, yes)
133 GNUPG_BUILD_PROGRAM(symcryptrun, no)
134 # We use gpgtar to unpack test data, hence we always build it.  If the
135 # user opts out, we simply don't install it.
136 GNUPG_BUILD_PROGRAM(gpgtar, yes)
137 GNUPG_BUILD_PROGRAM(wks-tools, no)
138
139 AC_SUBST(PACKAGE)
140 AC_SUBST(PACKAGE_GT)
141 AC_SUBST(VERSION)
142 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
143 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
144                                 [Name of this package for gettext])
145 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
146 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
147                                         [Bug report address])
148 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
149                                        [Required version of Libgcrypt])
150 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
151                                        [Required version of Libksba])
152 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
153                                        [Required version of NTBTLS])
154
155
156
157 # The default is to use the modules from this package and the few
158 # other packages in a standard place; i.e where this package gets
159 # installed.  With these options it is possible to override these
160 # ${prefix} depended values with fixed paths, which can't be replaced
161 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
162 AC_ARG_WITH(agent-pgm,
163     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
164           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
165 AC_SUBST(GNUPG_AGENT_PGM)
166 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
167 show_gnupg_agent_pgm="(default)"
168 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
169
170 AC_ARG_WITH(pinentry-pgm,
171     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
172           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
173 AC_SUBST(GNUPG_PINENTRY_PGM)
174 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
175 show_gnupg_pinentry_pgm="(default)"
176 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
177
178
179 AC_ARG_WITH(scdaemon-pgm,
180     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
181           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
182 AC_SUBST(GNUPG_SCDAEMON_PGM)
183 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
184 show_gnupg_scdaemon_pgm="(default)"
185 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
186
187
188 AC_ARG_WITH(dirmngr-pgm,
189     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
190           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
191 AC_SUBST(GNUPG_DIRMNGR_PGM)
192 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
193 show_gnupg_dirmngr_pgm="(default)"
194 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
195
196 AC_ARG_WITH(protect-tool-pgm,
197     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
198           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
199 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
200 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
201 show_gnupg_protect_tool_pgm="(default)"
202 test -n "$GNUPG_PROTECT_TOOL_PGM" \
203       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
204
205 AC_ARG_WITH(dirmngr-ldap-pgm,
206     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmngr ldap wrapper)],
207           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
208 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
209 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
210 show_gnupg_dirmngr_ldap_pgm="(default)"
211 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
212       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
213
214
215 #
216 # For a long time gpg 2.x was installed as gpg2.  This changed with
217 # 2.2.  This option can be used to install gpg under the name gpg2.
218 #
219 AC_ARG_ENABLE(gpg-is-gpg2,
220     AC_HELP_STRING([--enable-gpg-is-gpg2],[Set installed name of gpg to gpg2]),
221     gpg_is_gpg2=$enableval)
222 if test "$gpg_is_gpg2" = "yes"; then
223    AC_DEFINE(USE_GPG2_HACK, 1, [Define to install gpg as gpg2])
224 fi
225 AM_CONDITIONAL(USE_GPG2_HACK, test "$gpg_is_gpg2" = "yes")
226
227
228 # SELinux support includes tracking of sensitive files to avoid
229 # leaking their contents through processing these files by gpg itself
230 AC_MSG_CHECKING([whether SELinux support is requested])
231 AC_ARG_ENABLE(selinux-support,
232               AC_HELP_STRING([--enable-selinux-support],
233                              [enable SELinux support]),
234               selinux_support=$enableval, selinux_support=no)
235 AC_MSG_RESULT($selinux_support)
236
237
238 AC_MSG_CHECKING([whether to allocate extra secure memory])
239 AC_ARG_ENABLE(large-secmem,
240               AC_HELP_STRING([--enable-large-secmem],
241                              [allocate extra secure memory]),
242               large_secmem=$enableval, large_secmem=no)
243 AC_MSG_RESULT($large_secmem)
244 if test "$large_secmem" = yes ; then
245    SECMEM_BUFFER_SIZE=65536
246 else
247    SECMEM_BUFFER_SIZE=32768
248 fi
249 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
250                    [Size of secure memory buffer])
251
252 AC_MSG_CHECKING([calibrated passphrase-stretching (s2k) duration])
253 AC_ARG_WITH(agent-s2k-calibration,
254               AC_HELP_STRING([--with-agent-s2k-calibration=MSEC],
255                              [calibrate passphrase stretching (s2k) to MSEC milliseconds]),
256               agent_s2k_calibration=$withval, agent_s2k_calibration=100)
257 AC_MSG_RESULT($agent_s2k_calibration milliseconds)
258 AC_DEFINE_UNQUOTED(AGENT_S2K_CALIBRATION, $agent_s2k_calibration,
259                    [Agent s2k calibration time (ms)])
260
261 AC_MSG_CHECKING([whether to enable trust models])
262 AC_ARG_ENABLE(trust-models,
263               AC_HELP_STRING([--disable-trust-models],
264                              [disable all trust models except "always"]),
265               use_trust_models=$enableval)
266 AC_MSG_RESULT($use_trust_models)
267 if test "$use_trust_models" = no ; then
268     AC_DEFINE(NO_TRUST_MODELS, 1,
269              [Define to include only trust-model always])
270 fi
271
272 AC_MSG_CHECKING([whether to enable TOFU])
273 AC_ARG_ENABLE(tofu,
274                 AC_HELP_STRING([--disable-tofu],
275                                [disable the TOFU trust model]),
276               use_tofu=$enableval, use_tofu=$use_trust_models)
277 AC_MSG_RESULT($use_tofu)
278 if test "$use_trust_models" = no && test "$use_tofu" = yes; then
279     AC_MSG_ERROR([both --disable-trust-models and --enable-tofu given])
280 fi
281
282 AC_MSG_CHECKING([whether to enable libdns])
283 AC_ARG_ENABLE(libdns,
284                 AC_HELP_STRING([--disable-libdns],
285                                [do not build with libdns support]),
286               use_libdns=$enableval, use_libdns=yes)
287 AC_MSG_RESULT($use_libdns)
288 if test x"$use_libdns" = xyes ; then
289     AC_DEFINE(USE_LIBDNS, 1, [Build with integrated libdns support])
290 fi
291 AM_CONDITIONAL(USE_LIBDNS, test "$use_libdns" = yes)
292
293
294 #
295 # Options to disable algorithm
296 #
297
298 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
299 # Elgamal is a MUST algorithm
300 # DSA is a MUST algorithm
301 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
302 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
303 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
304
305 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
306 # 3DES is a MUST algorithm
307 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
308 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
309 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
310 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
311 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
312 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
313 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
314 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
315 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
316
317 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
318 # SHA1 is a MUST algorithm
319 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
320 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
321 # SHA256 is a MUST algorithm for GnuPG.
322 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
323 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
324
325
326 # Allow disabling of zip support.
327 # This is in general not a good idea because according to rfc4880 OpenPGP
328 # implementations SHOULD support ZLIB.
329 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
330 AC_ARG_ENABLE(zip,
331    AC_HELP_STRING([--disable-zip],
332                   [disable the ZIP and ZLIB compression algorithm]),
333    use_zip=$enableval)
334 AC_MSG_RESULT($use_zip)
335
336 # Allow disabling of bzib2 support.
337 # It is defined only after we confirm the library is available later
338 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
339 AC_ARG_ENABLE(bzip2,
340    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
341    use_bzip2=$enableval)
342 AC_MSG_RESULT($use_bzip2)
343
344 # Configure option to allow or disallow execution of external
345 # programs, like a photo viewer.
346 AC_MSG_CHECKING([whether to enable external program execution])
347 AC_ARG_ENABLE(exec,
348     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
349     use_exec=$enableval)
350 AC_MSG_RESULT($use_exec)
351 if test "$use_exec" = no ; then
352     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
353 fi
354
355 if test "$use_exec" = yes ; then
356   AC_MSG_CHECKING([whether to enable photo ID viewing])
357   AC_ARG_ENABLE(photo-viewers,
358       [  --disable-photo-viewers disable photo ID viewers],
359       [if test "$enableval" = no ; then
360          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
361       fi],enableval=yes)
362   gnupg_cv_enable_photo_viewers=$enableval
363   AC_MSG_RESULT($enableval)
364
365   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
366     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
367     AC_ARG_WITH(photo-viewer,
368         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
369         [if test "$withval" = yes ; then
370            withval=no
371         elif test "$withval" != no ; then
372            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
373                             [if set, restrict photo-viewer to this])
374         fi],withval=no)
375     AC_MSG_RESULT($withval)
376   fi
377 fi
378
379
380 #
381 # Check for the key/uid cache size.  This can't be zero, but can be
382 # pretty small on embedded systems.  This is used for the gpg part.
383 #
384 AC_MSG_CHECKING([for the size of the key and uid cache])
385 AC_ARG_ENABLE(key-cache,
386         AC_HELP_STRING([--enable-key-cache=SIZE],
387                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
388 if test "$enableval" = "no"; then
389    enableval=5
390 elif test "$enableval" = "yes" || test "$enableval" = ""; then
391    enableval=4096
392 fi
393 changequote(,)dnl
394 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
395 changequote([,])dnl
396 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
397    AC_MSG_ERROR([invalid key-cache size])
398 fi
399 AC_MSG_RESULT($key_cache_size)
400 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
401                   [Size of the key and UID caches])
402
403
404
405 #
406 # Check whether we want to use Linux capabilities
407 #
408 AC_MSG_CHECKING([whether use of capabilities is requested])
409 AC_ARG_WITH(capabilities,
410     [  --with-capabilities     use linux capabilities [default=no]],
411 [use_capabilities="$withval"],[use_capabilities=no])
412 AC_MSG_RESULT($use_capabilities)
413
414 #
415 # Check whether to disable the card support
416 AC_MSG_CHECKING([whether smartcard support is requested])
417 AC_ARG_ENABLE(card-support,
418               AC_HELP_STRING([--disable-card-support],
419                              [disable smartcard support]),
420               card_support=$enableval)
421 AC_MSG_RESULT($card_support)
422 if test "$card_support" = yes ; then
423   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
424 else
425   build_scdaemon=no
426 fi
427
428 #
429 # Allow disabling of internal CCID support.
430 # It is defined only after we confirm the library is available later
431 #
432 AC_MSG_CHECKING([whether to enable the internal CCID driver])
433 AC_ARG_ENABLE(ccid-driver,
434               AC_HELP_STRING([--disable-ccid-driver],
435                              [disable the internal CCID driver]),
436               use_ccid_driver=$enableval)
437 AC_MSG_RESULT($use_ccid_driver)
438
439 AC_MSG_CHECKING([whether to auto start dirmngr])
440 AC_ARG_ENABLE(dirmngr-auto-start,
441               AC_HELP_STRING([--disable-dirmngr-auto-start],
442                              [disable auto starting of the dirmngr]),
443               dirmngr_auto_start=$enableval)
444 AC_MSG_RESULT($dirmngr_auto_start)
445 if test "$dirmngr_auto_start" = yes ; then
446     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
447               [Define to enable auto starting of the dirmngr])
448 fi
449
450
451 #
452 # To avoid double inclusion of config.h which might happen at some
453 # places, we add the usual double inclusion protection at the top of
454 # config.h.
455 #
456 AH_TOP([
457 #ifndef GNUPG_CONFIG_H_INCLUDED
458 #define GNUPG_CONFIG_H_INCLUDED
459 ])
460
461 #
462 # Stuff which goes at the bottom of config.h.
463 #
464 AH_BOTTOM([
465 /* This is the major version number of GnuPG so that
466    source included files can test for this.  Note, that
467    we use 2 here even for GnuPG 1.9.x. */
468 #define GNUPG_MAJOR_VERSION 2
469
470 /* Now to separate file name parts.
471    Please note that the string version must not contain more
472    than one character because the code assumes strlen()==1 */
473 #ifdef HAVE_DOSISH_SYSTEM
474 #define DIRSEP_C '\\'
475 #define DIRSEP_S "\\"
476 #define EXTSEP_C '.'
477 #define EXTSEP_S "."
478 #define PATHSEP_C ';'
479 #define PATHSEP_S ";"
480 #define EXEEXT_S ".exe"
481 #else
482 #define DIRSEP_C '/'
483 #define DIRSEP_S "/"
484 #define EXTSEP_C '.'
485 #define EXTSEP_S "."
486 #define PATHSEP_C ':'
487 #define PATHSEP_S ":"
488 #define EXEEXT_S ""
489 #endif
490
491 /* This is the same as VERSION, but should be overridden if the
492    platform cannot handle things like dots '.' in filenames. Set
493    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
494    uses for dots and dashes. */
495 #define SAFE_VERSION VERSION
496 #define SAFE_VERSION_DOT  '.'
497 #define SAFE_VERSION_DASH '-'
498
499 /* Some global constants.
500  * Note that the homedir must not end in a slash.  */
501 #ifdef HAVE_DOSISH_SYSTEM
502 # ifdef HAVE_DRIVE_LETTERS
503 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
504 # else
505 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
506 # endif
507 #elif defined(__VMS)
508 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
509 #else
510 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
511 #endif
512 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
513 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
514
515 /* For some systems (DOS currently), we hardcode the path here.  For
516    POSIX systems the values are constructed by the Makefiles, so that
517    the values may be overridden by the make invocations; this is to
518    comply with the GNU coding standards.  Note that these values are
519    only defaults.  */
520 #ifdef HAVE_DOSISH_SYSTEM
521 # ifdef HAVE_DRIVE_LETTERS
522 #  define GNUPG_BINDIR      "c:\\gnupg"
523 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
524 #  define GNUPG_LIBDIR      "c:\\gnupg"
525 #  define GNUPG_DATADIR     "c:\\gnupg"
526 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
527 # else
528 #  define GNUPG_BINDIR      "\\gnupg"
529 #  define GNUPG_LIBEXECDIR  "\\gnupg"
530 #  define GNUPG_LIBDIR      "\\gnupg"
531 #  define GNUPG_DATADIR     "\\gnupg"
532 #  define GNUPG_SYSCONFDIR  "\\gnupg"
533 # endif
534 #endif
535
536 /* Derive some other constants. */
537 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
538 #define EXEC_TEMPFILE_ONLY
539 #endif
540
541
542 /* We didn't define endianness above, so get it from OS macros.  This
543    is intended for making fat binary builds on OS X. */
544 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
545 #if defined(__BIG_ENDIAN__)
546 #define BIG_ENDIAN_HOST 1
547 #elif defined(__LITTLE_ENDIAN__)
548 #define LITTLE_ENDIAN_HOST 1
549 #else
550 #error "No endianness found"
551 #endif
552 #endif
553
554
555 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
556    ldap_start_tls_s because that is the actual symbol used in the
557    library.  winldap.h redefines it to our commonly used value,
558    thus we define our usual macro here.  */
559 #ifdef HAVE_LDAP_START_TLS_SA
560 # ifndef HAVE_LDAP_START_TLS_S
561 #  define HAVE_LDAP_START_TLS_S 1
562 # endif
563 #endif
564
565 /* Provide the es_ macro for estream.  */
566 #define GPGRT_ENABLE_ES_MACROS 1
567
568 /* Tell libgcrypt not to use its own libgpg-error implementation. */
569 #define USE_LIBGPG_ERROR 1
570
571 /* Tell Libgcrypt not to include deprecated definitions.  */
572 #define GCRYPT_NO_DEPRECATED 1
573
574 /* Our HTTP code is used in estream mode.  */
575 #define HTTP_USE_ESTREAM 1
576
577 /* Under W32 we do an explicit socket initialization, thus we need to
578    avoid the on-demand initialization which would also install an atexit
579    handler.  */
580 #define HTTP_NO_WSASTARTUP
581
582 /* Under Windows we use the gettext code from libgpg-error.  */
583 #define GPG_ERR_ENABLE_GETTEXT_MACROS
584
585 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
586 #define GPG_ERR_ENABLE_ERRNO_MACROS
587
588 #endif /*GNUPG_CONFIG_H_INCLUDED*/
589 ])
590
591
592 AM_MAINTAINER_MODE
593 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
594
595 # Checks for programs.
596 AC_MSG_NOTICE([checking for programs])
597 AC_PROG_MAKE_SET
598 AM_SANITY_CHECK
599 missing_dir=`cd $ac_aux_dir && pwd`
600 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
601 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
602 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
603 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
604 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
605 AM_SILENT_RULES
606 AC_PROG_AWK
607 AC_PROG_CC
608 AC_PROG_CPP
609 AM_PROG_CC_C_O
610 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
611   AC_MSG_ERROR([[No C-89 compiler found]])
612 fi
613 AC_PROG_INSTALL
614 AC_PROG_LN_S
615 AC_PROG_RANLIB
616 AC_CHECK_TOOL(AR, ar, :)
617 AC_PATH_PROG(PERL,"perl")
618 AC_CHECK_TOOL(WINDRES, windres, :)
619 AC_PATH_PROG(YAT2M, "yat2m", "./yat2m" )
620 AC_ARG_VAR(YAT2M, [tool to convert texi to man pages])
621 AC_ISC_POSIX
622 AC_SYS_LARGEFILE
623 GNUPG_CHECK_USTAR
624
625
626 # We need to compile and run a program on the build machine.  A
627 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
628 # the AC archive is broken for autoconf 2.57.  Given that there is no
629 # newer version of that macro, we assume that it is also broken for
630 # autoconf 2.61 and thus we use a simple but usually sufficient
631 # approach.
632 AC_MSG_CHECKING(for cc for build)
633 if test "$cross_compiling" = "yes"; then
634   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
635 else
636   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
637 fi
638 AC_MSG_RESULT($CC_FOR_BUILD)
639 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
640
641 # We need to call this macro because other pkg-config macros are
642 # not always used.
643 PKG_PROG_PKG_CONFIG
644
645
646 try_gettext=yes
647 require_iconv=yes
648 have_dosish_system=no
649 have_w32_system=no
650 have_w32ce_system=no
651 have_android_system=no
652 use_simple_gettext=no
653 use_ldapwrapper=yes
654 mmap_needed=yes
655 case "${host}" in
656     *-mingw32*)
657         # special stuff for Windoze NT
658         ac_cv_have_dev_random=no
659         AC_DEFINE(USE_ONLY_8DOT3,1,
660                   [Set this to limit filenames to the 8.3 format])
661         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
662                   [Because the Unix gettext has too much overhead on
663                    MingW32 systems and these systems lack Posix functions,
664                    we use a simplified version of gettext])
665         have_dosish_system=yes
666         have_w32_system=yes
667         require_iconv=no
668         use_ldapwrapper=no  # Fixme: Do this only for CE.
669         case "${host}" in
670           *-mingw32ce*)
671             have_w32ce_system=yes
672             ;;
673           *)
674             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
675                       [Defined if the OS supports drive letters.])
676             ;;
677         esac
678         try_gettext="no"
679         use_simple_gettext=yes
680         mmap_needed=no
681         ;;
682     i?86-emx-os2 | i?86-*-os2*emx )
683         # OS/2 with the EMX environment
684         ac_cv_have_dev_random=no
685         AC_DEFINE(HAVE_DRIVE_LETTERS)
686         have_dosish_system=yes
687         try_gettext="no"
688         ;;
689
690     i?86-*-msdosdjgpp*)
691         # DOS with the DJGPP environment
692         ac_cv_have_dev_random=no
693         AC_DEFINE(HAVE_DRIVE_LETTERS)
694         have_dosish_system=yes
695         try_gettext="no"
696         ;;
697
698     *-*-hpux*)
699         if test -z "$GCC" ; then
700             CFLAGS="-Ae -D_HPUX_SOURCE $CFLAGS"
701         fi
702         ;;
703     *-dec-osf4*)
704         if test -z "$GCC" ; then
705             # Suppress all warnings
706             # to get rid of the unsigned/signed char mismatch warnings.
707             CFLAGS="-w $CFLAGS"
708         fi
709         ;;
710     *-dec-osf5*)
711         if test -z "$GCC" ; then
712             # Use the newer compiler `-msg_disable ptrmismatch1' to
713             # get rid of the unsigned/signed char mismatch warnings.
714             # Using this may hide other pointer mismatch warnings, but
715             # it at least lets other warning classes through
716             CFLAGS="-msg_disable ptrmismatch1 $CFLAGS"
717         fi
718         ;;
719     m68k-atari-mint)
720         ;;
721     *-linux-android*)
722         have_android_system=yes
723         # Android is fully utf-8 and we do not want to use iconv to
724         # keeps things simple
725         require_iconv=no
726         ;;
727     *-apple-darwin*)
728         AC_DEFINE(_DARWIN_C_SOURCE, 900000L,
729                   Expose all libc features (__DARWIN_C_FULL).)
730         ;;
731     *)
732        ;;
733 esac
734
735 if test "$have_dosish_system" = yes; then
736    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
737              [Defined if we run on some of the PCDOS like systems
738               (DOS, Windoze. OS/2) with special properties like
739               no file modes, case insensitive file names and preferred
740               use of backslashes as directory name separators.])
741 fi
742 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
743
744 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
745
746 if test "$have_w32_system" = yes; then
747    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
748    if test "$have_w32ce_system" = yes; then
749       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
750    fi
751 fi
752 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
753 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
754
755 if test "$have_android_system" = yes; then
756    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
757 fi
758 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
759
760
761 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
762 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
763
764
765 #
766 # Checks for libraries.
767 #
768 AC_MSG_NOTICE([checking for libraries])
769
770
771 #
772 # libgpg-error is a library with error codes shared between GnuPG
773 # related projects.
774 #
775 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
776                   have_gpg_error=yes,have_gpg_error=no)
777
778
779 #
780 # Libgcrypt is our generic crypto library
781 #
782 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
783         have_libgcrypt=yes,have_libgcrypt=no)
784
785
786 #
787 # libassuan is used for IPC
788 #
789 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
790                   have_libassuan=yes,have_libassuan=no)
791 if test "$have_libassuan" = "yes"; then
792   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
793                      [version of the libassuan library])
794   show_tor_support="only .onion"
795 fi
796
797
798 #
799 # libksba is our X.509 support library
800 #
801 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
802
803
804 #
805 # libusb allows us to use the integrated CCID smartcard reader driver.
806 #
807 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
808 if test "$use_ccid_driver" = auto || test "$use_ccid_driver" = yes; then
809    case "${host}" in
810      *-mingw32*)
811        LIBUSB_NAME=
812        LIBUSB_LIBS=
813        LIBUSB_CPPFLAGS=
814        ;;
815      *-*-darwin*)
816        LIBUSB_NAME=usb-1.0
817        LIBUSB_LIBS="-Wl,-framework,CoreFoundation -Wl,-framework,IOKit"
818        ;;
819      *-*-freebsd*)
820        # FreeBSD has a native 1.0 compatible library by -lusb.
821        LIBUSB_NAME=usb
822        LIBUSB_LIBS=
823        ;;
824      *)
825        LIBUSB_NAME=usb-1.0
826        LIBUSB_LIBS=
827        ;;
828    esac
829 fi
830 if test x"$LIBUSB_NAME" != x ; then
831    AC_CHECK_LIB($LIBUSB_NAME, libusb_init,
832                 [ LIBUSB_LIBS="-l$LIBUSB_NAME $LIBUSB_LIBS"
833                   have_libusb=yes ])
834    AC_MSG_CHECKING([libusb include dir])
835    usb_incdir_found="no"
836    for _incdir in "" "/usr/include/libusb-1.0" "/usr/local/include/libusb-1.0"; do
837      _libusb_save_cppflags=$CPPFLAGS
838      if test -n "${_incdir}"; then
839        CPPFLAGS="-I${_incdir} ${CPPFLAGS}"
840      fi
841      AC_PREPROC_IFELSE([AC_LANG_SOURCE([[@%:@include <libusb.h>]])],
842      [usb_incdir=${_incdir}; usb_incdir_found="yes"], [])
843      CPPFLAGS=${_libusb_save_cppflags}
844      if test "$usb_incdir_found" = "yes"; then
845        break
846      fi
847    done
848    if test "$usb_incdir_found" = "yes"; then
849      AC_MSG_RESULT([${usb_incdir}])
850    else
851      AC_MSG_RESULT([not found])
852      usb_incdir=""
853      have_libusb=no
854      if test "$use_ccid_driver" != yes; then
855        use_ccid_driver=no
856      fi
857      LIBUSB_LIBS=""
858    fi
859
860    if test "$have_libusb" = yes; then
861      AC_DEFINE(HAVE_LIBUSB,1, [defined if libusb is available])
862    fi
863    if test x"$usb_incdir" = x; then
864      LIBUSB_CPPFLAGS=""
865    else
866      LIBUSB_CPPFLAGS="-I${usb_incdir}"
867    fi
868 fi
869 AC_SUBST(LIBUSB_LIBS)
870 AC_SUBST(LIBUSB_CPPFLAGS)
871
872 #
873 # Check whether it is necessary to link against libdl.
874 # (For example to load libpcsclite)
875 #
876 gnupg_dlopen_save_libs="$LIBS"
877 LIBS=""
878 AC_SEARCH_LIBS(dlopen, c dl,,,)
879 DL_LIBS=$LIBS
880 AC_SUBST(DL_LIBS)
881 LIBS="$gnupg_dlopen_save_libs"
882
883
884 # Checks for g10
885
886 AC_ARG_ENABLE(sqlite,
887                 AC_HELP_STRING([--disable-sqlite],
888                                [disable the use of SQLITE]),
889               try_sqlite=$enableval, try_sqlite=yes)
890
891 if test x"$use_tofu" = xyes ; then
892   if test x"$try_sqlite" = xyes ; then
893     PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $NEED_SQLITE_VERSION],
894                                  [have_sqlite=yes],
895                                  [have_sqlite=no])
896   fi
897   if test "$have_sqlite" = "yes"; then
898     :
899     AC_SUBST([SQLITE3_CFLAGS])
900     AC_SUBST([SQLITE3_LIBS])
901   else
902     use_tofu=no
903     tmp=$(echo "$SQLITE3_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
904     AC_MSG_WARN([[
905 ***
906 *** Building without SQLite support - TOFU disabled
907 ***
908 *** $tmp]])
909   fi
910 fi
911
912 AM_CONDITIONAL(SQLITE3, test "$have_sqlite" = "yes")
913
914 if test x"$use_tofu" = xyes ; then
915     AC_DEFINE(USE_TOFU, 1, [Enable to build the TOFU code])
916 fi
917
918
919 # Checks for g13
920
921 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
922 AC_DEFINE_UNQUOTED(ENCFS,
923         "${ENCFS}", [defines the filename of the encfs program])
924
925 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
926 AC_DEFINE_UNQUOTED(FUSERMOUNT,
927         "${FUSERMOUNT}", [defines the filename of the fusermount program])
928
929
930 # Checks for dirmngr
931
932
933 #
934 # Checks for symcryptrun:
935 #
936
937 # libutil has openpty() and login_tty().
938 AC_CHECK_LIB(util, openpty,
939               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
940                 AC_DEFINE(HAVE_LIBUTIL,1,
941                          [defined if libutil is available])
942              ])
943 AC_SUBST(LIBUTIL_LIBS)
944
945 # shred is used to clean temporary plain text files.
946 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
947 AC_DEFINE_UNQUOTED(SHRED,
948         "${SHRED}", [defines the filename of the shred program])
949
950
951 #
952 # Check whether the nPth library is available
953 #
954 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
955 if test "$have_npth" = "yes"; then
956   AC_DEFINE(HAVE_NPTH, 1,
957               [Defined if the New Portable Thread Library is available])
958   AC_DEFINE(USE_NPTH, 1,
959               [Defined if support for nPth is requested and nPth is available])
960 else
961   AC_MSG_WARN([[
962 ***
963 *** To support concurrent access for example in gpg-agent and the SCdaemon
964 *** we need the support of the New Portable Threads Library.
965 ***]])
966 fi
967
968
969 #
970 # NTBTLS is our TLS library.  If it is not available fallback to
971 # GNUTLS.
972 #
973 AC_ARG_ENABLE(ntbtls,
974               AC_HELP_STRING([--disable-ntbtls],
975                              [disable the use of NTBTLS as TLS library]),
976               try_ntbtls=$enableval, try_ntbtls=yes)
977 if test x"$try_ntbtls" = xyes ; then
978   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
979                  [have_ntbtls=yes],[have_ntbtls=no])
980 fi
981 if test "$have_ntbtls" = yes ; then
982    use_tls_library=ntbtls
983    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
984 else
985   AC_ARG_ENABLE(gnutls,
986                 AC_HELP_STRING([--disable-gnutls],
987                                [disable GNUTLS as fallback TLS library]),
988                 try_gnutls=$enableval, try_gnutls=yes)
989   if test x"$try_gnutls" = xyes ; then
990     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
991                                    [have_gnutls=yes],
992                                    [have_gnutls=no])
993   fi
994   if test "$have_gnutls" = "yes"; then
995     AC_SUBST([LIBGNUTLS_CFLAGS])
996     AC_SUBST([LIBGNUTLS_LIBS])
997     use_tls_library=gnutls
998     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
999   else
1000     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
1001     AC_MSG_WARN([[
1002 ***
1003 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
1004 ***
1005 *** $tmp]])
1006   fi
1007 fi
1008
1009 #
1010 # Allow to set a fixed trust store file for system provided certificates.
1011 #
1012 AC_ARG_WITH([default-trust-store-file],
1013             [AC_HELP_STRING([--with-default-trust-store-file=FILE],
1014                             [Use FILE as system trust store])],
1015             default_trust_store_file="$withval",
1016             default_trust_store_file="")
1017 if test x"$default_trust_store_file" = xno;then
1018   default_trust_store_file=""
1019 fi
1020 if test x"$default_trust_store_file" != x ; then
1021   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
1022     ["$default_trust_store_file"], [Use as default system trust store file])
1023 fi
1024
1025
1026 AC_MSG_NOTICE([checking for networking options])
1027
1028 #
1029 # Must check for network library requirements before doing link tests
1030 # for ldap, for example. If ldap libs are static (or dynamic and without
1031 # ELF runtime link paths), then link will fail and LDAP support won't
1032 # be detected.
1033 #
1034 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
1035         [NETLIBS="-lnsl $NETLIBS"]))
1036 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
1037         [NETLIBS="-lsocket $NETLIBS"]))
1038
1039
1040 #
1041 # Check standard resolver functions.
1042 #
1043 if test "$build_dirmngr" = "yes"; then
1044   _dns_save_libs=$LIBS
1045   LIBS=""
1046
1047   # Find the system resolver which can always be enabled with
1048   # the dirmngr option --standard-resolver.
1049
1050   # the double underscore thing is a glibc-ism?
1051   AC_SEARCH_LIBS(res_query,resolv bind,,
1052                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
1053   AC_SEARCH_LIBS(dn_expand,resolv bind,,
1054                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
1055
1056   # macOS renames dn_skipname into res_9_dn_skipname in <resolv.h>,
1057   # and for some reason fools us into believing we don't need
1058   # -lresolv even if we do.  Since the test program checking for the
1059   # symbol does not include <resolv.h>, we need to check for the
1060   # renamed symbol explicitly.
1061   AC_SEARCH_LIBS(res_9_dn_skipname,resolv bind,,
1062       AC_SEARCH_LIBS(dn_skipname,resolv bind,,
1063           AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no)))
1064
1065   if test x"$have_resolver" != xno ; then
1066
1067       # Make sure that the BIND 4 resolver interface is workable before
1068       # enabling any code that calls it.  At some point I'll rewrite the
1069       # code to use the BIND 8 resolver API.
1070       # We might also want to use libdns instead.
1071
1072     AC_MSG_CHECKING([whether the resolver is usable])
1073     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1074 #include <netinet/in.h>
1075 #include <arpa/nameser.h>
1076 #include <resolv.h>]],
1077 [[unsigned char answer[PACKETSZ];
1078   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1079   dn_skipname(0,0);
1080   dn_expand(0,0,0,0,0);
1081 ]])],have_resolver=yes,have_resolver=no)
1082     AC_MSG_RESULT($have_resolver)
1083
1084     # This is Apple-specific and somewhat bizarre as they changed the
1085     # define in bind 8 for some reason.
1086
1087     if test x"$have_resolver" != xyes ; then
1088       AC_MSG_CHECKING(
1089            [whether I can make the resolver usable with BIND_8_COMPAT])
1090       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
1091 #include <sys/types.h>
1092 #include <netinet/in.h>
1093 #include <arpa/nameser.h>
1094 #include <resolv.h>]],
1095 [[unsigned char answer[PACKETSZ];
1096   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1097   dn_skipname(0,0); dn_expand(0,0,0,0,0);
1098 ]])],[have_resolver=yes ; need_compat=yes])
1099       AC_MSG_RESULT($have_resolver)
1100     fi
1101   fi
1102
1103   if test x"$have_resolver" = xyes ; then
1104     AC_DEFINE(HAVE_SYSTEM_RESOLVER,1,[The system's resolver is usable.])
1105     DNSLIBS="$DNSLIBS $LIBS"
1106     if test x"$need_compat" = xyes ; then
1107       AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
1108     fi
1109     if test "$use_libdns" = yes; then
1110      show_tor_support=yes
1111     fi
1112   elif test "$use_libdns" = yes; then
1113     show_tor_support=yes
1114   else
1115     AC_MSG_WARN([[
1116 ***
1117 *** The system's DNS resolver is not usable.
1118 *** Dirmngr functionality is limited.
1119 ***]])
1120     show_tor_support="${show_tor_support} (no system resolver)"
1121   fi
1122
1123   if test "$have_w32_system" = yes; then
1124     if test "$use_libdns" = yes; then
1125       DNSLIBS="$DNSLIBS -liphlpapi"
1126     fi
1127   fi
1128
1129   LIBS=$_dns_save_libs
1130 fi
1131
1132 AC_SUBST(DNSLIBS)
1133
1134
1135 #
1136 # Check for LDAP
1137 #
1138 # Note that running the check changes the variable
1139 # gnupg_have_ldap from "n/a" to "no" or "yes".
1140
1141 AC_ARG_ENABLE(ldap,
1142     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1143     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1144
1145 if test "$gnupg_have_ldap" != "no" ; then
1146   if test "$build_dirmngr" = "yes" ; then
1147      GNUPG_CHECK_LDAP($NETLIBS)
1148      AC_CHECK_LIB(lber, ber_free,
1149                   [ LBER_LIBS="$LBER_LIBS -llber"
1150                     AC_DEFINE(HAVE_LBER,1,
1151                              [defined if liblber is available])
1152                     have_lber=yes
1153                  ])
1154   fi
1155 fi
1156 AC_SUBST(LBER_LIBS)
1157 if test "$gnupg_have_ldap" = "no"; then
1158     AC_MSG_WARN([[
1159 ***
1160 *** Building without LDAP support.
1161 *** No CRL access or X.509 certificate search available.
1162 ***]])
1163 fi
1164
1165 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1166 if test "$gnupg_have_ldap" = yes ; then
1167   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1168 else
1169  use_ldapwrapper=no
1170 fi
1171
1172 if test "$use_ldapwrapper" = yes; then
1173    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1174 fi
1175 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1176
1177
1178
1179
1180 #
1181 # Check for sendmail
1182 #
1183 # This isn't necessarily sendmail itself, but anything that gives a
1184 # sendmail-ish interface to the outside world.  That includes Exim,
1185 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1186 AC_ARG_WITH(mailprog,
1187       AC_HELP_STRING([--with-mailprog=NAME],
1188                      [use "NAME -t" for mail transport]),
1189              ,with_mailprog=yes)
1190 if test x"$with_mailprog" = xyes ; then
1191     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1192 elif test x"$with_mailprog" != xno ; then
1193     AC_MSG_CHECKING([for a mail transport program])
1194     AC_SUBST(SENDMAIL,$with_mailprog)
1195     AC_MSG_RESULT($with_mailprog)
1196 fi
1197
1198
1199 #
1200 # Construct a printable name of the OS
1201 #
1202 case "${host}" in
1203     *-mingw32ce*)
1204         PRINTABLE_OS_NAME="W32CE"
1205         ;;
1206     *-mingw32*)
1207         PRINTABLE_OS_NAME="MingW32"
1208         ;;
1209     *-*-cygwin*)
1210         PRINTABLE_OS_NAME="Cygwin"
1211         ;;
1212     i?86-emx-os2 | i?86-*-os2*emx )
1213         PRINTABLE_OS_NAME="OS/2"
1214         ;;
1215     i?86-*-msdosdjgpp*)
1216         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1217         try_dynload=no
1218         ;;
1219     *-linux*)
1220         PRINTABLE_OS_NAME="GNU/Linux"
1221         ;;
1222     *)
1223         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1224         ;;
1225 esac
1226 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1227                    [A human readable text with the name of the OS])
1228
1229
1230 #
1231 # Checking for iconv
1232 #
1233 if test "$require_iconv" = yes; then
1234   AM_ICONV
1235 else
1236   LIBICONV=
1237   LTLIBICONV=
1238   AC_SUBST(LIBICONV)
1239   AC_SUBST(LTLIBICONV)
1240 fi
1241
1242
1243 #
1244 # Check for gettext
1245 #
1246 # This is "GNU gnupg" - The project-id script from gettext
1247 #                       needs this string
1248 #
1249 AC_MSG_NOTICE([checking for gettext])
1250 AM_PO_SUBDIRS
1251 AM_GNU_GETTEXT_VERSION([0.17])
1252 if test "$try_gettext" = yes; then
1253   AM_GNU_GETTEXT([external],[need-ngettext])
1254
1255   # gettext requires some extra checks.  These really should be part of
1256   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1257   # function checks to here.
1258
1259   AC_CHECK_FUNCS(strchr)
1260 else
1261   USE_NLS=no
1262   USE_INCLUDED_LIBINTL=no
1263   BUILD_INCLUDED_LIBINTL=no
1264   POSUB=po
1265   AC_SUBST(USE_NLS)
1266   AC_SUBST(USE_INCLUDED_LIBINTL)
1267   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1268   AC_SUBST(POSUB)
1269 fi
1270
1271 # We use HAVE_LANGINFO_CODESET in a couple of places.
1272 AM_LANGINFO_CODESET
1273
1274 # Checks required for our use of locales
1275 gt_LC_MESSAGES
1276
1277
1278 #
1279 # SELinux support
1280 #
1281 if test "$selinux_support" = yes ; then
1282   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1283 fi
1284
1285
1286 #
1287 # Checks for header files.
1288 #
1289 AC_MSG_NOTICE([checking for header files])
1290 AC_HEADER_STDC
1291 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1292                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h     \
1293                   stdint.h signal.h util.h libutil.h termios.h \
1294                   ucred.h sys/sysmacros.h sys/mkdev.h])
1295
1296 AC_HEADER_TIME
1297
1298
1299 #
1300 # Checks for typedefs, structures, and compiler characteristics.
1301 #
1302 AC_MSG_NOTICE([checking for system characteristics])
1303 AC_C_CONST
1304 AC_C_INLINE
1305 AC_C_VOLATILE
1306 AC_TYPE_SIZE_T
1307 AC_TYPE_MODE_T
1308 AC_TYPE_SIGNAL
1309 AC_DECL_SYS_SIGLIST
1310
1311 gl_HEADER_SYS_SOCKET
1312 gl_TYPE_SOCKLEN_T
1313
1314 AC_SEARCH_LIBS([inet_addr], [nsl])
1315
1316 AC_ARG_ENABLE(endian-check,
1317               AC_HELP_STRING([--disable-endian-check],
1318               [disable the endian check and trust the OS provided macros]),
1319               endiancheck=$enableval,endiancheck=yes)
1320
1321 if test x"$endiancheck" = xyes ; then
1322   GNUPG_CHECK_ENDIAN
1323 fi
1324
1325 # fixme: we should get rid of the byte type
1326 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1327 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1328 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1329 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1330 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1331
1332 AC_CHECK_SIZEOF(unsigned short)
1333 AC_CHECK_SIZEOF(unsigned int)
1334 AC_CHECK_SIZEOF(unsigned long)
1335 AC_CHECK_SIZEOF(unsigned long long)
1336 AC_HEADER_TIME
1337 AC_CHECK_SIZEOF(time_t,,[[
1338 #include <stdio.h>
1339 #if TIME_WITH_SYS_TIME
1340 # include <sys/time.h>
1341 # include <time.h>
1342 #else
1343 # if HAVE_SYS_TIME_H
1344 #  include <sys/time.h>
1345 # else
1346 #  include <time.h>
1347 # endif
1348 #endif
1349 ]])
1350 GNUPG_TIME_T_UNSIGNED
1351
1352
1353 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1354    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1355    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1356     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1357 fi
1358
1359
1360 #
1361 # Checks for library functions.
1362 #
1363 AC_MSG_NOTICE([checking for library functions])
1364 AC_CHECK_DECLS(getpagesize)
1365 AC_FUNC_FSEEKO
1366 AC_FUNC_VPRINTF
1367 AC_FUNC_FORK
1368 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1369 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1370 AC_CHECK_FUNCS([setenv unsetenv fcntl ftruncate inet_ntop])
1371 AC_CHECK_FUNCS([canonicalize_file_name])
1372 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1373 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1374 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1375 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1376 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1377                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1378                 flockfile funlockfile getpwnam getpwuid \
1379                 getenv inet_pton strpbrk])
1380
1381 # On some systems (e.g. Solaris) nanosleep requires linking to librl.
1382 # Given that we use nanosleep only as an optimization over a select
1383 # based wait function we want it only if it is available in libc.
1384 _save_libs="$LIBS"
1385 AC_SEARCH_LIBS([nanosleep], [],
1386                [AC_DEFINE(HAVE_NANOSLEEP,1,
1387                 [Define to 1 if you have the `nanosleep' function in libc.])])
1388 LIBS="$_save_libs"
1389
1390
1391 # See whether libc supports the Linux inotify interface
1392 case "${host}" in
1393     *-*-linux*)
1394         AC_CHECK_FUNCS([inotify_init])
1395         ;;
1396 esac
1397
1398
1399 if test "$have_android_system" = yes; then
1400    # On Android ttyname is a stub but prints an error message.
1401    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1402              [Defined if ttyname does not work properly])
1403 fi
1404
1405 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1406
1407 # Dirmngr requires mmap on Unix systems.
1408 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1409   AC_MSG_ERROR([[Sorry, the current implementation requires mmap.]])
1410 fi
1411
1412
1413 #
1414 # Check for the getsockopt SO_PEERCRED, etc.
1415 #
1416 AC_CHECK_MEMBERS([struct ucred.pid, struct ucred.cr_pid, struct sockpeercred.pid], [], [], [#include <sys/types.h>
1417 #include <sys/socket.h> ])
1418
1419 # (Open)Solaris
1420 AC_CHECK_FUNCS([getpeerucred])
1421
1422
1423 #
1424 # W32 specific test
1425 #
1426 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1427
1428 #
1429 # Sanity check regex.  Tests adapted from mutt.
1430 #
1431 AC_MSG_CHECKING([whether regular expression support is requested])
1432 AC_ARG_ENABLE(regex,
1433   AC_HELP_STRING([--disable-regex],
1434     [do not handle regular expressions in trust signatures]),
1435   use_regex=$enableval, use_regex=yes)
1436 AC_MSG_RESULT($use_regex)
1437
1438 if test "$use_regex" = yes ; then
1439   _cppflags="${CPPFLAGS}"
1440   _ldflags="${LDFLAGS}"
1441   AC_ARG_WITH(regex,
1442      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1443       [
1444       if test -d "$withval" ; then
1445         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1446         LDFLAGS="${LDFLAGS} -L$withval/lib"
1447       fi
1448       ],withval="")
1449
1450   # Does the system have regex functions at all?
1451   AC_SEARCH_LIBS([regcomp], [regex])
1452   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1453
1454   if test $gnupg_cv_have_regex = no; then
1455     use_regex=no
1456   else
1457     if test x"$cross_compiling" = xyes; then
1458       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1459     else
1460       AC_CACHE_CHECK([whether your system's regexp library is broken],
1461        [gnupg_cv_regex_broken],
1462        AC_TRY_RUN([
1463 #include <unistd.h>
1464 #include <regex.h>
1465 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1466        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1467
1468       if test $gnupg_cv_regex_broken = yes; then
1469         AC_MSG_WARN([your regex is broken - disabling regex use])
1470         use_regex=no
1471       fi
1472     fi
1473   fi
1474   CPPFLAGS="${_cppflags}"
1475   LDFLAGS="${_ldflags}"
1476 fi
1477
1478 if test "$use_regex" != yes ; then
1479   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1480 fi
1481 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1482
1483
1484
1485 #
1486 # Do we have zlib? Must do it here because Solaris failed
1487 # when compiling a conftest (due to the "-lz" from LIBS).
1488 # Note that we combine zlib and bzlib2 in ZLIBS.
1489 #
1490 if test "$use_zip" = yes ; then
1491   _cppflags="${CPPFLAGS}"
1492   _ldflags="${LDFLAGS}"
1493   AC_ARG_WITH(zlib,
1494     [  --with-zlib=DIR         use libz in DIR],[
1495       if test -d "$withval"; then
1496         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1497         LDFLAGS="${LDFLAGS} -L$withval/lib"
1498       fi
1499     ])
1500
1501   AC_CHECK_HEADER(zlib.h,
1502      AC_CHECK_LIB(z, deflateInit2_,
1503        [
1504        ZLIBS="-lz"
1505        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1506        ],
1507        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1508        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1509 fi
1510
1511
1512 #
1513 # Check whether we can support bzip2
1514 #
1515 if test "$use_bzip2" = yes ; then
1516   _cppflags="${CPPFLAGS}"
1517   _ldflags="${LDFLAGS}"
1518   AC_ARG_WITH(bzip2,
1519      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1520       [
1521       if test -d "$withval" ; then
1522         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1523         LDFLAGS="${LDFLAGS} -L$withval/lib"
1524       fi
1525       ],withval="")
1526
1527   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1528   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1529   # woefully out of date.
1530   if test "$withval" != no ; then
1531      AC_CHECK_HEADER(bzlib.h,
1532         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1533           [
1534           have_bz2=yes
1535           ZLIBS="$ZLIBS -lbz2"
1536           AC_DEFINE(HAVE_BZIP2,1,
1537                   [Defined if the bz2 compression library is available])
1538           ],
1539           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1540           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1541   fi
1542 fi
1543 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1544 AC_SUBST(ZLIBS)
1545
1546
1547 # Check for readline support
1548 GNUPG_CHECK_READLINE
1549
1550
1551 if test "$development_version" = yes; then
1552     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1553             [Defined if this is not a regular release])
1554 fi
1555
1556 if test "$USE_MAINTAINER_MODE" = "yes"; then
1557     AC_DEFINE(MAINTAINER_MODE,1,
1558             [Defined if this build is in maintainer mode])
1559 fi
1560
1561 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1562
1563 GNUPG_CHECK_GNUMAKE
1564
1565 # Add some extra libs here so that previous tests don't fail for
1566 # mysterious reasons - the final link step should bail out.
1567 # W32SOCKLIBS is also defined so that if can be used for tools not
1568 # requiring any network stuff but linking to code in libcommon which
1569 # tracks in winsock stuff (e.g. init_common_subsystems).
1570 if test "$have_w32_system" = yes; then
1571    if test "$have_w32ce_system" = yes; then
1572      W32SOCKLIBS="-lws2"
1573    else
1574      W32SOCKLIBS="-lws2_32"
1575    fi
1576    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1577 fi
1578
1579 AC_SUBST(NETLIBS)
1580 AC_SUBST(W32SOCKLIBS)
1581
1582 #
1583 # Setup gcc specific options
1584 #
1585 USE_C99_CFLAGS=
1586 AC_MSG_NOTICE([checking for cc features])
1587 if test "$GCC" = yes; then
1588     mycflags=
1589     mycflags_save=$CFLAGS
1590
1591     # Check whether gcc does not emit a diagnositc for unknown -Wno-*
1592     # options.  This is the case for gcc >= 4.6
1593     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1594     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1595 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1596 #kickerror
1597 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1598     AC_MSG_RESULT($_gcc_silent_wno)
1599
1600     # Note that it is okay to use CFLAGS here because these are just
1601     # warning options and the user should have a chance of overriding
1602     # them.
1603     if test "$USE_MAINTAINER_MODE" = "yes"; then
1604         mycflags="$mycflags -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1605         mycflags="$mycflags -Wformat -Wno-format-y2k -Wformat-security"
1606         if test x"$_gcc_silent_wno" = xyes ; then
1607           _gcc_wopt=yes
1608         else
1609           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1610           CFLAGS="-Wno-missing-field-initializers"
1611           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1612                             [_gcc_wopt=yes],[_gcc_wopt=no])
1613           AC_MSG_RESULT($_gcc_wopt)
1614         fi
1615         if test x"$_gcc_wopt" = xyes ; then
1616           mycflags="$mycflags -W -Wno-sign-compare"
1617           mycflags="$mycflags -Wno-missing-field-initializers"
1618         fi
1619
1620         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1621         CFLAGS="-Wdeclaration-after-statement"
1622         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1623         AC_MSG_RESULT($_gcc_wopt)
1624         if test x"$_gcc_wopt" = xyes ; then
1625           mycflags="$mycflags -Wdeclaration-after-statement"
1626         fi
1627
1628         AC_MSG_CHECKING([if gcc supports -Wlogical-op and -Wvla])
1629         CFLAGS="-Wlogical-op -Wvla"
1630         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1631         AC_MSG_RESULT($_gcc_wopt)
1632         if test x"$_gcc_wopt" = xyes ; then
1633           mycflags="$mycflags -Wlogical-op -Wvla"
1634         fi
1635
1636     else
1637         mycflags="$mycflags -Wall"
1638     fi
1639
1640     if test x"$_gcc_silent_wno" = xyes ; then
1641       _gcc_psign=yes
1642     else
1643       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1644       CFLAGS="-Wno-pointer-sign"
1645       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1646                         [_gcc_psign=yes],[_gcc_psign=no])
1647       AC_MSG_RESULT($_gcc_psign)
1648     fi
1649     if test x"$_gcc_psign" = xyes ; then
1650        mycflags="$mycflags -Wno-pointer-sign"
1651     fi
1652
1653     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1654     CFLAGS="-Wpointer-arith"
1655     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1656     AC_MSG_RESULT($_gcc_psign)
1657     if test x"$_gcc_psign" = xyes ; then
1658        mycflags="$mycflags -Wpointer-arith"
1659     fi
1660
1661     CFLAGS="$mycflags $mycflags_save"
1662     if test "$use_libdns" = yes; then
1663        # dirmngr/dns.{c,h} require C99 and GNU extensions.  */
1664        USE_C99_CFLAGS="-std=gnu99"
1665     fi
1666 fi
1667
1668 AC_SUBST(USE_C99_CFLAGS)
1669
1670
1671 #
1672 # This is handy for debugging so the compiler doesn't rearrange
1673 # things and eliminate variables.
1674 #
1675 AC_ARG_ENABLE(optimization,
1676    AC_HELP_STRING([--disable-optimization],
1677                   [disable compiler optimization]),
1678                   [if test $enableval = no ; then
1679                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1680                    fi])
1681
1682 #
1683 # log_debug has certain requirements which might hamper portability.
1684 # Thus we use an option to enable it.
1685 #
1686 AC_MSG_CHECKING([whether to enable log_clock])
1687 AC_ARG_ENABLE(log_clock,
1688               AC_HELP_STRING([--enable-log-clock],
1689                              [enable log_clock timestamps]),
1690               enable_log_clock=$enableval, enable_log_clock=no)
1691 AC_MSG_RESULT($enable_log_clock)
1692 if test "$enable_log_clock" = yes ; then
1693   AC_DEFINE(ENABLE_LOG_CLOCK,1,[Defined to use log_clock timestamps])
1694 fi
1695
1696
1697 #
1698 # Configure option --enable-all-tests
1699 #
1700 AC_MSG_CHECKING([whether "make check" shall run all tests])
1701 AC_ARG_ENABLE(all-tests,
1702               AC_HELP_STRING([--enable-all-tests],
1703                              [let "make check" run all tests]),
1704               run_all_tests=$enableval, run_all_tests=no)
1705 AC_MSG_RESULT($run_all_tests)
1706 if test "$run_all_tests" = "yes"; then
1707     AC_DEFINE(RUN_ALL_TESTS,1,
1708             [Defined if "make check" shall run all tests])
1709 fi
1710
1711 #
1712 # We do not want support for the GNUPG_BUILDDIR environment variable
1713 # in a released version.  However, our regression tests suite requires
1714 # this and thus we build with support for it during "make distcheck".
1715 # This configure option implements this along with the top Makefile's
1716 # AM_DISTCHECK_CONFIGURE_FLAGS.
1717 #
1718 gnupg_builddir_envvar=no
1719 AC_ARG_ENABLE(gnupg-builddir-envvar,,
1720               gnupg_builddir_envvar=$enableval)
1721 if test x"$gnupg_builddir_envvar" = x"yes"; then
1722    AC_DEFINE(ENABLE_GNUPG_BUILDDIR_ENVVAR, 1,
1723       [This is only used with "make distcheck"])
1724 fi
1725
1726 #
1727 # Add user CFLAGS.
1728 #
1729 CFLAGS="$CFLAGS $CFLAGS_orig"
1730
1731 #
1732 # Decide what to build
1733 #
1734
1735 build_scdaemon_extra=""
1736 if test "$build_scdaemon" = "yes"; then
1737   if test $have_libusb = no; then
1738      build_scdaemon_extra="without internal CCID driver"
1739   fi
1740   if test -n "$build_scdaemon_extra"; then
1741      build_scdaemon_extra="(${build_scdaemon_extra})"
1742   fi
1743 fi
1744
1745
1746 #
1747 # Set variables for use by automake makefiles.
1748 #
1749 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1750 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1751 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1752 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1753 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1754 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1755 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1756 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1757 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1758 AM_CONDITIONAL(BUILD_WKS_TOOLS,   test "$build_wks_tools" = "yes")
1759
1760 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1761 AM_CONDITIONAL(NO_TRUST_MODELS,     test "$use_trust_models" = no)
1762 AM_CONDITIONAL(USE_TOFU,            test "$use_tofu" = yes)
1763
1764 #
1765 # Set some defines for use gpgconf.
1766 #
1767 if test "$build_gpg" = yes ; then
1768     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1769 fi
1770 if test "$build_gpgsm" = yes ; then
1771     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1772 fi
1773 if test "$build_agent" = yes ; then
1774     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1775 fi
1776 if test "$build_scdaemon" = yes ; then
1777     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1778 fi
1779 if test "$build_dirmngr" = yes ; then
1780     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if DIRMNGR is to be build])
1781 fi
1782 if test "$build_g13" = yes ; then
1783     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1784 fi
1785
1786
1787 #
1788 # Define Name strings
1789 #
1790 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1791
1792 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1793 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1794
1795 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1796 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1797
1798 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1799 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1800                                         [The displayed name of gpg-agent])
1801
1802 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1803 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1804                                        [The displayed name of scdaemon])
1805
1806 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1807 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1808                                       [The displayed name of dirmngr])
1809
1810 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1811 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1812
1813 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1814 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1815                                       [The displayed name of gpgconf])
1816
1817 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1818
1819 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1820                    [The name of the agent socket])
1821 AC_DEFINE_UNQUOTED(GPG_AGENT_EXTRA_SOCK_NAME, "S.gpg-agent.extra",
1822                    [The name of the agent socket for remote access])
1823 AC_DEFINE_UNQUOTED(GPG_AGENT_BROWSER_SOCK_NAME, "S.gpg-agent.browser",
1824                    [The name of the agent socket for browsers])
1825 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1826                    [The name of the agent socket for ssh])
1827 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1828                    [The name of the dirmngr info envvar])
1829 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1830                    [The name of the SCdaemon socket])
1831 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1832                    [The name of the dirmngr socket])
1833 AC_DEFINE_UNQUOTED(DIRMNGR_DEFAULT_KEYSERVER,
1834                    "hkps://hkps.pool.sks-keyservers.net",
1835       [The default keyserver for dirmngr to use, if none is explicitly given])
1836
1837 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1838
1839 if test "$have_w32_system" = yes; then
1840   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "\\\\Software\\\\GNU\\\\GnuPG",
1841                      [The directory part of the W32 registry keys])
1842 fi
1843
1844
1845 #
1846 # Provide information about the build.
1847 #
1848 BUILD_REVISION="mym4_revision"
1849 AC_SUBST(BUILD_REVISION)
1850 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1851                    [GIT commit id revision used to build this package])
1852
1853 changequote(,)dnl
1854 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1855 changequote([,])dnl
1856 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1857 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1858 AC_SUBST(BUILD_VERSION)
1859 AC_SUBST(BUILD_FILEVERSION)
1860
1861 AC_ARG_ENABLE([build-timestamp],
1862   AC_HELP_STRING([--enable-build-timestamp],
1863                  [set an explicit build timestamp for reproducibility.
1864                   (default is the current time in ISO-8601 format)]),
1865      [if test "$enableval" = "yes"; then
1866         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1867       else
1868         BUILD_TIMESTAMP="$enableval"
1869       fi
1870       BUILD_HOSTNAME="$ac_hostname"],
1871      [BUILD_TIMESTAMP="<none>"
1872       BUILD_HOSTNAME="<anon>"])
1873 AC_SUBST(BUILD_TIMESTAMP)
1874 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1875                    [The time this package was configured for a build])
1876 AC_SUBST(BUILD_HOSTNAME)
1877
1878
1879 #
1880 # Print errors here so that they are visible all
1881 # together and the user can acquire them all together.
1882 #
1883 die=no
1884 if test "$have_gpg_error" = "no"; then
1885    die=yes
1886    AC_MSG_NOTICE([[
1887 ***
1888 *** You need libgpg-error to build this program.
1889 **  This library is for example available at
1890 ***   https://gnupg.org/ftp/gcrypt/libgpg-error
1891 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1892 ***]])
1893 fi
1894 if test "$have_libgcrypt" = "no"; then
1895    die=yes
1896    AC_MSG_NOTICE([[
1897 ***
1898 *** You need libgcrypt to build this program.
1899 **  This library is for example available at
1900 ***   https://gnupg.org/ftp/gcrypt/libgcrypt/
1901 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1902 ***]])
1903 fi
1904 if test "$have_libassuan" = "no"; then
1905    die=yes
1906    AC_MSG_NOTICE([[
1907 ***
1908 *** You need libassuan to build this program.
1909 *** This library is for example available at
1910 ***   https://gnupg.org/ftp/gcrypt/libassuan/
1911 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1912 ***]])
1913 fi
1914 if test "$have_ksba" = "no"; then
1915     die=yes
1916     AC_MSG_NOTICE([[
1917 ***
1918 *** You need libksba to build this program.
1919 *** This library is for example available at
1920 ***   https://gnupg.org/ftp/gcrypt/libksba/
1921 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1922 ***]])
1923 fi
1924 if test "$gnupg_have_ldap" = yes; then
1925   if test "$have_w32ce_system" = yes; then
1926     AC_MSG_NOTICE([[
1927 *** Note that CeGCC might be broken, a package fixing this is:
1928 ***    http://files.kolab.org/local/windows-ce/
1929 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1930 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1931 ***]])
1932    fi
1933 fi
1934 if test "$have_npth" = "no"; then
1935     die=yes
1936     AC_MSG_NOTICE([[
1937 ***
1938 *** It is now required to build with support for the
1939 *** New Portable Threads Library (nPth). Please install this
1940 *** library first.  The library is for example available at
1941 ***   https://gnupg.org/ftp/gcrypt/npth/
1942 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1943 ***]])
1944 fi
1945
1946 if test "$require_iconv" = yes; then
1947   if test "$am_func_iconv" != yes; then
1948     die=yes
1949     AC_MSG_NOTICE([[
1950 ***
1951 *** The system does not provide a working iconv function.  Please
1952 *** install a suitable library; for example GNU Libiconv which is
1953 *** available at:
1954 ***   https://ftp.gnu.org/gnu/libiconv/
1955 ***]])
1956   fi
1957 fi
1958
1959 if test "$use_ccid_driver" = yes; then
1960   if test "$have_libusb" != yes; then
1961     die=yes
1962     AC_MSG_NOTICE([[
1963 ***
1964 *** You need libusb to build the internal ccid driver.  Please
1965 *** install a libusb suitable for your system.
1966 ***]])
1967   fi
1968 fi
1969
1970 if test "$die" = "yes"; then
1971     AC_MSG_ERROR([[
1972 ***
1973 *** Required libraries not found. Please consult the above messages
1974 *** and install them before running configure again.
1975 ***]])
1976 fi
1977
1978
1979
1980 AC_CONFIG_FILES([ m4/Makefile
1981 Makefile
1982 po/Makefile.in
1983 common/Makefile
1984 common/w32info-rc.h
1985 kbx/Makefile
1986 g10/Makefile
1987 sm/Makefile
1988 agent/Makefile
1989 scd/Makefile
1990 g13/Makefile
1991 dirmngr/Makefile
1992 tools/gpg-zip
1993 tools/Makefile
1994 doc/Makefile
1995 tests/Makefile
1996 tests/gpgscm/Makefile
1997 tests/openpgp/Makefile
1998 tests/migrations/Makefile
1999 tests/gpgsm/Makefile
2000 tests/gpgme/Makefile
2001 tests/pkits/Makefile
2002 g10/gpg.w32-manifest
2003 ])
2004
2005
2006 AC_OUTPUT
2007
2008
2009 echo "
2010         GnuPG v${VERSION} has been configured as follows:
2011
2012         Revision:  mym4_revision  (mym4_revision_dec)
2013         Platform:  $PRINTABLE_OS_NAME ($host)
2014
2015         OpenPGP:   $build_gpg
2016         S/MIME:    $build_gpgsm
2017         Agent:     $build_agent
2018         Smartcard: $build_scdaemon $build_scdaemon_extra
2019         G13:       $build_g13
2020         Dirmngr:   $build_dirmngr
2021         Gpgtar:    $build_gpgtar
2022         WKS tools: $build_wks_tools
2023
2024         Protect tool:      $show_gnupg_protect_tool_pgm
2025         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
2026         Default agent:     $show_gnupg_agent_pgm
2027         Default pinentry:  $show_gnupg_pinentry_pgm
2028         Default scdaemon:  $show_gnupg_scdaemon_pgm
2029         Default dirmngr:   $show_gnupg_dirmngr_pgm
2030
2031         Dirmngr auto start:  $dirmngr_auto_start
2032         Readline support:    $gnupg_cv_have_readline
2033         LDAP support:        $gnupg_have_ldap
2034         TLS support:         $use_tls_library
2035         TOFU support:        $use_tofu
2036         Tor support:         $show_tor_support
2037 "
2038 if test x"$use_regex" != xyes ; then
2039 echo "
2040         Warning: No regular expression support available.
2041                  OpenPGP trust signatures won't work.
2042                  gpg-check-pattern will not be built.
2043 "
2044 fi
2045 if test "x${gpg_config_script_warn}" != x; then
2046 cat <<G10EOF
2047         Warning: Mismatches between the target platform and the
2048                  to be used libraries have been detected for:
2049                   ${gpg_config_script_warn}
2050                  Please check above for more warning messages.
2051
2052 G10EOF
2053 fi