2006-08-28 Marcus Brinkmann <marcus@g10code.de>
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 1.9
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 #               2003, 2004, 2005, 2006 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 2 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, write to the Free Software
19 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301,
20 # USA.
21
22 # Process this file with autoconf to produce a configure script.
23 AC_PREREQ(2.52)
24 min_automake_version="1.9.3"
25
26 # Remember to change the version number immediately *after* a release.
27 # Set my_issvn to "yes" for non-released code.  Remember to run an
28 # "svn up" and "autogen.sh" right before creating a distribution.
29 m4_define([my_version], [1.9.23])
30 m4_define([my_issvn], [yes])
31
32
33 m4_define([svn_revision], m4_esyscmd([echo -n $((svn info 2>/dev/null \
34             || echo 'Revision: 0')|sed -n '/^Revision:/ {s/[^0-9]//gp;q}')]))
35 AC_INIT([gnupg], my_version[]m4_if(my_issvn,[yes],[-svn[]svn_revision]),
36         [bug-gnupg@gnupg.org])
37 # Set development_version to yes if the minor number is odd or you
38 # feel that the default check for a development version is not
39 # sufficient.
40 development_version=yes
41
42 NEED_GPG_ERROR_VERSION=1.2
43
44 NEED_LIBGCRYPT_API=1
45 NEED_LIBGCRYPT_VERSION=1.1.94
46
47 NEED_LIBASSUAN_VERSION=0.6.10
48
49 NEED_KSBA_VERSION=0.9.16
50
51
52 PACKAGE=$PACKAGE_NAME
53 PACKAGE_GT=${PACKAGE_NAME}2
54 VERSION=$PACKAGE_VERSION
55
56 AC_CONFIG_AUX_DIR(scripts)
57 AC_CONFIG_SRCDIR(sm/gpgsm.c)
58 AM_CONFIG_HEADER(config.h)
59 AC_CANONICAL_TARGET()
60 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
61 AB_INIT
62
63 AC_GNU_SOURCE
64
65 # Some status variables.
66 have_gpg_error=no
67 have_libgcrypt=no 
68 have_libassuan=no
69 have_ksba=no
70 have_pth=no
71
72 use_bzip2=yes
73 use_exec=yes
74 disable_keyserver_path=no
75
76
77 GNUPG_BUILD_PROGRAM(gpg, no)
78 GNUPG_BUILD_PROGRAM(gpgsm, yes)
79 GNUPG_BUILD_PROGRAM(agent, yes)
80 GNUPG_BUILD_PROGRAM(scdaemon, yes)
81 GNUPG_BUILD_PROGRAM(symcryptrun, no)
82
83 AC_SUBST(PACKAGE)
84 AC_SUBST(PACKAGE_GT)
85 AC_SUBST(VERSION)
86 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
87 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
88                                 [Name of this package for gettext])
89 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
90 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
91                                         [Bug report address])
92 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
93                                        [Required version of Libgcrypt])
94 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
95                                        [Required version of Libksba])
96
97
98
99 # The default is to use the modules from this package and the few
100 # other packages in a standard place; i.e where this package gets
101 # installed.  With these options it is possible to override these
102 # ${prefix} depended values with fixed paths, which can't be replaced
103 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
104 AC_ARG_WITH(agent-pgm,
105     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
106           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
107 AC_SUBST(GNUPG_AGENT_PGM)
108 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
109 show_gnupg_agent_pgm="(default)"
110 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
111
112 AC_ARG_WITH(pinentry-pgm,
113     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
114           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
115 AC_SUBST(GNUPG_PINENTRY_PGM)
116 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
117 show_gnupg_pinentry_pgm="(default)"
118 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
119
120
121 AC_ARG_WITH(scdaemon-pgm,
122     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
123           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
124 AC_SUBST(GNUPG_SCDAEMON_PGM)
125 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
126 show_gnupg_scdaemon_pgm="(default)"
127 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
128
129
130 AC_ARG_WITH(dirmngr-pgm,
131     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
132           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
133 AC_SUBST(GNUPG_DIRMNGR_PGM)
134 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
135 show_gnupg_dirmngr_pgm="(default)"
136 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
137
138 AC_ARG_WITH(protect-tool-pgm,
139     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
140           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
141 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
142 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
143 show_gnupg_protect_tool_pgm="(default)"
144 test -n "$GNUPG_PROTECT_TOOL_PGM" \
145       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
146
147
148 # Some folks want to use only the agent from this packet.  Make it
149 # easier for them by providing the configure option
150 # --enable-only-agent.
151 AC_ARG_ENABLE(agent-only,
152     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
153     build_agent_only=$enableval)
154
155
156 # SELinux support includes tracking of sensitive files to avoid
157 # leaking their contents through processing these files by gpg itself
158 AC_MSG_CHECKING([whether SELinux support is requested])
159 AC_ARG_ENABLE(selinux-support,
160               AC_HELP_STRING([--enable-selinux-support],
161                              [enable SELinux support]),
162               selinux_support=$enableval, selinux_support=no)
163 AC_MSG_RESULT($selinux_support)
164
165 # Allow disabling of bzib2 support.
166 # It is defined only after we confirm the library is available later
167 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
168 AC_ARG_ENABLE(bzip2,
169    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
170    use_bzip2=$enableval)
171 AC_MSG_RESULT($use_bzip2)
172
173
174 # Configure option to allow or disallow execution of external
175 # programs, like a photo viewer.
176 AC_MSG_CHECKING([whether to enable external program execution])
177 AC_ARG_ENABLE(exec,
178     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
179     use_exec=$enableval)
180 AC_MSG_RESULT($use_exec)
181 if test "$use_exec" = no ; then
182     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
183 fi
184
185 if test "$use_exec" = yes ; then
186   AC_MSG_CHECKING([whether to enable photo ID viewing])
187   AC_ARG_ENABLE(photo-viewers,
188       [  --disable-photo-viewers disable photo ID viewers],
189       [if test "$enableval" = no ; then
190          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
191       fi],enableval=yes)
192   gnupg_cv_enable_photo_viewers=$enableval
193   AC_MSG_RESULT($enableval)
194
195   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
196     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
197     AC_ARG_WITH(photo-viewer,
198         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
199         [if test "$withval" = yes ; then
200            withval=no
201         elif test "$withval" != no ; then
202            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
203                             [if set, restrict photo-viewer to this])
204         fi],withval=no)
205     AC_MSG_RESULT($withval)
206   fi
207
208   AC_MSG_CHECKING([whether to enable external keyserver helpers])
209   AC_ARG_ENABLE(keyserver-helpers,
210       [  --disable-keyserver-helpers  disable all external keyserver support],
211       [if test "$enableval" = no ; then
212          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
213                   [define to disable keyserver helpers])
214       fi],enableval=yes)
215   gnupg_cv_enable_keyserver_helpers=$enableval
216   AC_MSG_RESULT($enableval)
217
218   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
219     # LDAP is defined only after we confirm the library is available later
220     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
221     AC_ARG_ENABLE(ldap,
222       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
223       try_ldap=$enableval, try_ldap=yes)
224     AC_MSG_RESULT($try_ldap)
225
226     AC_MSG_CHECKING([whether HKP keyserver support is requested])
227     AC_ARG_ENABLE(hkp,
228       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
229       try_hkp=$enableval, try_hkp=yes)
230     AC_MSG_RESULT($try_hkp)
231
232     AC_MSG_CHECKING([whether finger key fetching support is requested])
233     AC_ARG_ENABLE(finger,
234       AC_HELP_STRING([--disable-finger],
235         [disable finger key fetching interface only]),
236       try_finger=$enableval, try_finger=yes)
237     AC_MSG_RESULT($try_finger)
238
239     AC_MSG_CHECKING([whether generic object key fetching support is requested])
240     AC_ARG_ENABLE(generic,
241       AC_HELP_STRING([--disable-generic],
242         [disable generic object key fetching interface only]),
243       try_generic=$enableval, try_generic=yes)
244     AC_MSG_RESULT($try_generic)
245
246     AC_MSG_CHECKING([whether email keyserver support is requested])
247     AC_ARG_ENABLE(mailto,
248       AC_HELP_STRING([--enable-mailto],
249         [enable email keyserver interface only]),
250       try_mailto=$enableval, try_mailto=no)
251     AC_MSG_RESULT($try_mailto)
252     fi
253
254     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
255     AC_ARG_ENABLE(keyserver-path,
256       AC_HELP_STRING([--disable-keyserver-path],
257         [disable the exec-path option for keyserver helpers]),
258       [if test "$enableval" = no ; then
259          disable_keyserver_path=yes
260       fi],enableval=yes)
261     AC_MSG_RESULT($enableval)
262   fi
263
264
265 #
266 # Check for the key/uid cache size.  This can't be zero, but can be
267 # pretty small on embedded systems.  This is used for the gpg part.
268 #
269 AC_MSG_CHECKING([for the size of the key and uid cache])
270 AC_ARG_ENABLE(key-cache,
271         AC_HELP_STRING([--enable-key-cache=SIZE],
272                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
273 if test "$enableval" = "no"; then
274    enableval=5
275 elif test "$enableval" = "yes" || test "$enableval" = ""; then
276    enableval=4096
277 fi
278 changequote(,)dnl
279 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
280 changequote([,])dnl
281 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
282    AC_MSG_ERROR([invalid key-cache size])
283 fi
284 AC_MSG_RESULT($key_cache_size)
285 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
286                   [Size of the key and UID caches])
287
288
289
290 #
291 # Check whether we want to use Linux capabilities
292 #
293 AC_MSG_CHECKING([whether use of capabilities is requested])
294 AC_ARG_WITH(capabilities,
295     [  --with-capabilities     use linux capabilities [default=no]],
296 [use_capabilities="$withval"],[use_capabilities=no])
297 AC_MSG_RESULT($use_capabilities)
298
299 #
300 # To avoid double inclusion of config.h which might happen at some
301 # places, we add the usual double inclusion protection at the top of
302 # config.h.
303 #
304 AH_TOP([
305 #ifndef GNUPG_CONFIG_H_INCLUDED
306 #define GNUPG_CONFIG_H_INCLUDED
307 ])
308
309 #
310 # Stuff which goes at the bottom of config.h.
311 #
312 AH_BOTTOM([
313 /* This is the major version number of GnuPG so that
314    source included files can test for this.  Note, that
315    we use 2 here even for GnuPG 1.9.x. */
316 #define GNUPG_MAJOR_VERSION 2
317
318 /* Now to separate file name parts.
319    Please note that the string version must not contain more
320    than one character because the code assumes strlen()==1 */
321 #ifdef HAVE_DOSISH_SYSTEM
322 #define DIRSEP_C '\\'
323 #define DIRSEP_S "\\"
324 #define EXTSEP_C '.'
325 #define EXTSEP_S "."
326 #define PATHSEP_C ';'
327 #define PATHSEP_S ";"
328 #define EXEEXT_S ".exe"
329 #else
330 #define DIRSEP_C '/'
331 #define DIRSEP_S "/"
332 #define EXTSEP_C '.'
333 #define EXTSEP_S "."
334 #define PATHSEP_C ':'
335 #define PATHSEP_S ":"
336 #define EXEEXT_S ""
337 #endif
338
339 /* This is the same as VERSION, but should be overridden if the
340    platform cannot handle things like dots '.' in filenames. Set
341    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
342    uses for dots and dashes. */
343 #define SAFE_VERSION VERSION
344 #define SAFE_VERSION_DOT  '.'
345 #define SAFE_VERSION_DASH '-'
346
347 /* Some global constants. */
348 #ifdef HAVE_DRIVE_LETTERS
349 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
350 #elif defined(__VMS)
351 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg" 
352 #else
353 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
354 #endif 
355 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
356
357 /* For some systems (DOS currently), we hardcode the path here.  For
358    POSIX systems the values are constructed by the Makefiles, so that
359    the values may be overridden by the make invocations; this is to
360    comply with the GNU coding standards. */
361 #ifdef HAVE_DRIVE_LETTERS
362 #define GNUPG_BINDIR      "c:\\gnupg"
363 #define GNUPG_LIBEXECDIR  "c:\\gnupg"
364 #define GNUPG_LIBDIR      "c:\\gnupg"
365 #define GNUPG_DATADIR     "c:\\gnupg"
366 #endif
367
368 /* Setup the hardwired names of modules. */
369 #ifndef GNUPG_DEFAULT_AGENT
370 #define GNUPG_DEFAULT_AGENT    ( GNUPG_BINDIR DIRSEP_S "gpg-agent" EXEEXT_S )
371 #endif
372 #ifndef GNUPG_DEFAULT_PINENTRY
373 #define GNUPG_DEFAULT_PINENTRY ( GNUPG_BINDIR DIRSEP_S "pinentry" EXEEXT_S )
374 #endif
375 #ifndef GNUPG_DEFAULT_SCDAEMON
376 #define GNUPG_DEFAULT_SCDAEMON ( GNUPG_BINDIR DIRSEP_S "scdaemon" EXEEXT_S )
377 #endif
378 #ifndef GNUPG_DEFAULT_DIRMNGR
379 #define GNUPG_DEFAULT_DIRMNGR  ( GNUPG_BINDIR DIRSEP_S "dirmngr" EXEEXT_S )
380 #endif
381 #ifndef GNUPG_DEFAULT_PROTECT_TOOL
382 #define GNUPG_DEFAULT_PROTECT_TOOL \
383                     ( GNUPG_LIBEXECDIR DIRSEP_S "gpg-protect-tool" EXEEXT_S )
384 #endif
385
386
387 /* Derive some other constants. */
388 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
389 #define EXEC_TEMPFILE_ONLY
390 #endif
391
392
393 /* We didn't define endianness above, so get it from OS macros.  This
394    is intended for making fat binary builds on OS X. */
395 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
396 #if defined(__BIG_ENDIAN__)
397 #define BIG_ENDIAN_HOST 1
398 #elif defined(__LITTLE_ENDIAN__)
399 #define LITTLE_ENDIAN_HOST 1
400 #else
401 #error "No endianness found"
402 #endif
403 #endif
404
405
406 /* Tell libgcrypt not to use its own libgpg-error implementation. */
407 #define USE_LIBGPG_ERROR 1
408
409 /* We use jnlib, so tell other modules about it.  */
410 #define HAVE_JNLIB_LOGGING 1
411
412 /* Our HTTP code is used in estream mode.  */
413 #define HTTP_USE_ESTREAM 1
414
415 /* We always include support for the OpenPGP card.  */
416 #define ENABLE_CARD_SUPPORT 1
417
418
419 #endif /*GNUPG_CONFIG_H_INCLUDED*/
420 ])
421
422
423 AM_MAINTAINER_MODE
424
425 # Checks for programs.
426 AC_PROG_MAKE_SET
427 AM_SANITY_CHECK
428 missing_dir=`cd $ac_aux_dir && pwd`
429 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
430 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
431 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
432 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
433 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
434 AC_PROG_AWK
435 AC_PROG_CC
436 AC_PROG_CPP
437 AC_PROG_INSTALL
438 AC_PROG_LN_S
439 AC_PROG_RANLIB
440 AC_CHECK_TOOL(AR, ar, :)
441 AC_PATH_PROG(PERL,"perl")
442 AC_ISC_POSIX
443 gl_EARLY
444 AC_SYS_LARGEFILE
445 GNUPG_CHECK_FAQPROG
446 GNUPG_CHECK_USTAR
447
448
449 try_gettext=yes
450 have_dosish_system=no
451 have_w32_system=no
452 use_simple_gettext=no
453 case "${host}" in
454     *-mingw32*)
455         # special stuff for Windoze NT
456         ac_cv_have_dev_random=no
457         AC_DEFINE(USE_ONLY_8DOT3,1,
458                   [set this to limit filenames to the 8.3 format])
459         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
460                   [defined if we must run on a stupid file system])
461         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
462                   [because the Unix gettext has too much overhead on
463                    MingW32 systems and these systems lack Posix functions,
464                    we use a simplified version of gettext])
465         disable_keyserver_path=yes
466         have_dosish_system=yes
467         have_w32_system=yes
468         try_gettext="no"
469         use_simple_gettext=yes
470         ;;
471     i?86-emx-os2 | i?86-*-os2*emx )
472         # OS/2 with the EMX environment
473         ac_cv_have_dev_random=no
474         AC_DEFINE(HAVE_DRIVE_LETTERS)
475         have_dosish_system=yes
476         try_gettext="no"
477         ;;
478
479     i?86-*-msdosdjgpp*)
480         # DOS with the DJGPP environment
481         ac_cv_have_dev_random=no
482         AC_DEFINE(HAVE_DRIVE_LETTERS)
483         have_dosish_system=yes
484         try_gettext="no"
485         ;;
486
487     *-*-freebsd*)
488        # FreeBSD
489        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
490        LDFLAGS="$LDFLAGS -L/usr/local/lib"
491        ;;
492
493     *-*-hpux*)
494         if test -z "$GCC" ; then
495             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
496         fi
497         ;;
498     *-dec-osf4*)
499         if test -z "$GCC" ; then
500             # Suppress all warnings
501             # to get rid of the unsigned/signed char mismatch warnings.
502             CFLAGS="$CFLAGS -w"
503         fi
504         ;;
505     *-dec-osf5*)
506         if test -z "$GCC" ; then
507             # Use the newer compiler `-msg_disable ptrmismatch1' to
508             # get rid of the unsigned/signed char mismatch warnings.
509             # Using this may hide other pointer mismatch warnings, but
510             # it at least lets other warning classes through
511             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
512         fi
513         ;;
514     m68k-atari-mint)
515         ;;
516     *)
517        ;;
518 esac
519
520 if test "$have_dosish_system" = yes; then
521    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
522              [Defined if we run on some of the PCDOS like systems 
523               (DOS, Windoze. OS/2) with special properties like
524               no file modes])
525 fi
526 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
527
528 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
529
530 if test "$have_w32_system" = yes; then
531    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
532 fi
533 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
534
535 if test "$disable_keyserver_path" = yes; then
536     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
537               [Defined to disable exec-path for keyserver helpers])
538 fi
539
540 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
541 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
542
543 if test x"$try_hkp" = xyes ; then
544   AC_SUBST(GPGKEYS_HKP,"gpg2keys_hkp$EXEEXT")
545 fi
546
547 if test x"$try_finger" = xyes ; then
548   AC_SUBST(GPGKEYS_FINGER,"gpg2keys_finger$EXEEXT")
549 fi
550
551
552
553 #
554 # Checks for libraries.
555 #
556
557
558 #
559 # libgpg-error is a library with error codes shared between GnuPG
560 # related projects.
561 #
562 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
563                   have_gpg_error=yes,have_gpg_error=no)
564 _tmp_gpg_error_save_cflags="$CFLAGS"
565 CFLAGS="$CFLAGS $GPG_ERROR_CFLAGS"
566 AC_CHECK_DECLS(GPG_ERR_LOCKED,,,[#include <gpg-error.h>])
567 CFLAGS="${_tmp_gpg_error_save_cflags}"
568
569
570 #
571 # Libgcrypt is our generic crypto library
572 #
573 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
574         have_libgcrypt=yes,have_libgcrypt=no)
575
576
577 #
578 # libassuan is used for IPC
579 #
580 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_VERSION",
581                   have_libassuan=yes,have_libassuan=no)
582
583
584 #
585 # libksba is our X.509 support library
586 #
587 AM_PATH_KSBA("$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
588
589
590 #
591 # libusb allows us to use the integrated CCID smartcard reader driver.
592 #
593 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
594 AC_CHECK_LIB(usb, usb_bulk_write,
595               [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
596                 AC_DEFINE(HAVE_LIBUSB,1,
597                          [defined if libusb is available])
598              ])
599 AC_SUBST(LIBUSB_LIBS)
600 AC_CHECK_FUNCS(usb_create_match)
601
602 #
603 # Check wether it is necessary to link against libdl.
604 #
605 LIBS=""
606 AC_SEARCH_LIBS(dlopen, c dl,,,)
607 DL_LIBS=$LIBS
608 AC_SUBST(DL_LIBS)
609
610 #
611 # Checks for symcryptrun:
612 #
613
614 # libutil has openpty() and login_tty().
615 AC_CHECK_LIB(util, openpty,
616               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
617                 AC_DEFINE(HAVE_LIBUTIL,1,
618                          [defined if libutil is available])
619              ])
620 AC_SUBST(LIBUTIL_LIBS)
621
622 # shred is used to clean temporary plain text files.
623 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
624 AC_DEFINE_UNQUOTED(SHRED,
625         "${SHRED}", [defines the filename of the shred program])
626
627
628
629 #
630 # Check whether the GNU Pth library is available
631 # Note, that we include a Pth emulation for W32.
632 #
633 AC_ARG_WITH(pth-prefix,
634             AC_HELP_STRING([--with-pth-prefix=PFX],
635                            [prefix where GNU Pth is installed (optional)]),
636      pth_config_prefix="$withval", pth_config_prefix="")
637 if test x$pth_config_prefix != x ; then
638    PTH_CONFIG="$pth_config_prefix/bin/pth-config"
639 fi
640 AC_PATH_PROG(PTH_CONFIG, pth-config, no)
641 if test "$have_w32_system" = no; then
642  if test "$PTH_CONFIG" = "no"; then
643     AC_MSG_WARN([[
644 ***
645 *** To support concurrent access to the gpg-agent and the SCdaemon
646 *** we need the support of the GNU Portable Threads Library.
647 *** Download it from ftp://ftp.gnu.org/gnu/pth/
648 *** On a Debian GNU/Linux system you might want to try 
649 ***   apt-get install libpth-dev
650 ***]])
651  else
652   GNUPG_PTH_VERSION_CHECK(1.3.7)
653   if test $have_pth = yes; then      
654      PTH_CFLAGS=`$PTH_CONFIG --cflags`
655      PTH_LIBS=`$PTH_CONFIG --ldflags`
656      PTH_LIBS="$PTH_LIBS `$PTH_CONFIG --libs --all`"
657      AC_DEFINE(USE_GNU_PTH, 1,
658               [Defined if the GNU Portable Thread Library should be used])
659      AC_DEFINE(HAVE_PTH, 1,
660               [Defined if the GNU Pth is available])
661   fi
662  fi
663 else 
664  have_pth=yes
665  PTH_CFLAGS=""
666  PTH_LIBS=""
667  AC_DEFINE(USE_GNU_PTH, 1)
668  AC_DEFINE(HAVE_PTH, 1)
669 fi
670 AC_SUBST(PTH_CFLAGS)
671 AC_SUBST(PTH_LIBS)
672
673
674 #
675 # Must check for network library requirements before doing link tests
676 # for ldap, for example. If ldap libs are static (or dynamic and without
677 # ELF runtime link paths), then link will fail and LDAP support won't
678 # be detected.
679 #
680 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
681         [NETLIBS="-lnsl $NETLIBS"]))
682 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
683         [NETLIBS="-lsocket $NETLIBS"]))
684
685 #
686 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
687 #
688 if test x"$try_hkp" = xyes || test x"$try_http" = xyes ; then
689   AC_ARG_ENABLE(dns-srv,
690      AC_HELP_STRING([--disable-dns-srv],
691                     [disable the use of DNS SRV in HKP and HTTP]),
692                 use_dns_srv=$enableval,use_dns_srv=yes)
693 fi
694
695 AC_ARG_ENABLE(dns-pka,
696    AC_HELP_STRING([--disable-dns-pka],
697         [disable the use of PKA records in DNS]),
698    use_dns_pka=$enableval,use_dns_pka=yes)
699
700 AC_ARG_ENABLE(dns-cert,
701    AC_HELP_STRING([--disable-dns-cert],
702         [disable the use of CERT records in DNS]),
703    use_dns_cert=$enableval,use_dns_cert=yes)
704
705 if test x"$use_dns_pka" = xyes || test x"$use_dns_srv" = xyes \
706    || test x"$use_dns_cert" = xyes; then
707   _dns_save_libs=$LIBS
708   LIBS=""
709   # the double underscore thing is a glibc-ism?
710   AC_SEARCH_LIBS(res_query,resolv bind,,
711                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
712   AC_SEARCH_LIBS(dn_expand,resolv bind,,
713                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
714   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
715                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
716
717   if test x"$have_resolver" != xno ; then
718
719     # Make sure that the BIND 4 resolver interface is workable before
720     # enabling any code that calls it.  At some point I'll rewrite the
721     # code to use the BIND 8 resolver API.
722
723     AC_MSG_CHECKING([whether the resolver is usable])
724     AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
725 #include <netinet/in.h>
726 #include <arpa/nameser.h>
727 #include <resolv.h>],
728 [[unsigned char answer[PACKETSZ];
729   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
730   dn_skipname(0,0); 
731   dn_expand(0,0,0,0,0);
732 ]])],have_resolver=yes,have_resolver=no)
733     AC_MSG_RESULT($have_resolver)
734
735     # This is Apple-specific and somewhat bizarre as they changed the
736     # define in bind 8 for some reason.
737
738     if test x"$have_resolver" != xyes ; then
739        AC_MSG_CHECKING(
740              [whether I can make the resolver usable with BIND_8_COMPAT])
741        AC_LINK_IFELSE([AC_LANG_PROGRAM([#define BIND_8_COMPAT
742 #include <sys/types.h>
743 #include <netinet/in.h>
744 #include <arpa/nameser.h>
745 #include <resolv.h>],
746 [[unsigned char answer[PACKETSZ];
747   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
748   dn_skipname(0,0); dn_expand(0,0,0,0,0);
749 ]])],[have_resolver=yes ; need_compat=yes])
750        AC_MSG_RESULT($have_resolver)
751     fi
752   fi
753
754   if test x"$have_resolver" = xyes ; then
755      DNSLIBS=$LIBS
756
757      if test x"$use_dns_srv" = xyes ; then
758         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
759      fi
760
761      if test x"$use_dns_pka" = xyes ; then
762         AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
763      fi
764
765      if test x"$use_dns_cert" = xyes ; then
766         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
767      fi
768
769      if test x"$need_compat" = xyes ; then
770         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
771      fi
772   else
773      use_dns_srv=no
774      use_dns_pka=no
775      use_dns_cert=no
776   fi
777
778   LIBS=$_dns_save_libs
779 fi
780
781 AC_SUBST(DNSLIBS)
782
783 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
784
785 #
786 # Check for LDAP
787 #
788 if test "$try_ldap" = yes ; then
789    GNUPG_CHECK_LDAP($NETLIBS)
790 fi
791
792 #
793 # Check for curl.  We fake the curl API if libcurl isn't installed.
794 #
795 LIBCURL_CHECK_CONFIG([yes],,,[fake_curl=yes])
796 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
797
798 # Generic, for us, means curl
799
800 if test x"$try_generic" = xyes ; then
801    AC_SUBST(GPGKEYS_CURL,"gpg2keys_curl$EXEEXT")
802 fi
803
804 #
805 # Check for sendmail
806 #
807 # This isn't necessarily sendmail itself, but anything that gives a
808 # sendmail-ish interface to the outside world.  That includes Exim,
809 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
810 if test "$try_mailto" = yes ; then
811   AC_ARG_WITH(mailprog,
812       AC_HELP_STRING([--with-mailprog=NAME],
813                      [use "NAME -t" for mail transport]),
814              ,with_mailprog=yes)
815
816   if test x"$with_mailprog" = xyes ; then
817     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
818     if test "$ac_cv_path_SENDMAIL" ; then
819       GPGKEYS_MAILTO="gpg2keys_mailto"
820     fi
821   elif test x"$with_mailprog" != xno ; then
822     AC_MSG_CHECKING([for a mail transport program])
823     AC_SUBST(SENDMAIL,$with_mailprog)
824     AC_MSG_RESULT($with_mailprog)
825     GPGKEYS_MAILTO="gpg2keys_mailto"
826   fi
827 fi
828
829 AC_SUBST(GPGKEYS_MAILTO)
830
831 #
832 # Construct a printable name of the OS
833 #
834 case "${host}" in
835     *-mingw32*)
836         PRINTABLE_OS_NAME="MingW32"
837         ;;
838     *-*-cygwin*)
839         PRINTABLE_OS_NAME="Cygwin"
840         ;;
841     i?86-emx-os2 | i?86-*-os2*emx )
842         PRINTABLE_OS_NAME="OS/2"
843         ;;
844     i?86-*-msdosdjgpp*)
845         PRINTABLE_OS_NAME="MSDOS/DJGPP"
846         try_dynload=no
847         ;;
848     *-linux*)
849         PRINTABLE_OS_NAME="GNU/Linux"
850         ;;
851     *)
852         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
853         ;;
854 esac
855 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
856                    [A human readable text with the name of the OS])
857
858
859 #
860 # Check for gettext
861 #
862 AM_GNU_GETTEXT_VERSION(0.14.1)
863 if test "$try_gettext" = yes; then
864   AM_GNU_GETTEXT(,[need-ngettext])
865
866   # gettext requires some extra checks.  These really should be part of
867   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
868   # function checks to here.
869
870   AC_CHECK_FUNCS(strchr)
871 else
872   USE_NLS=no
873   USE_INCLUDED_LIBINTL=no
874   BUILD_INCLUDED_LIBINTL=no
875   AC_SUBST(USE_NLS)
876   AC_SUBST(USE_INCLUDED_LIBINTL)
877   AC_SUBST(BUILD_INCLUDED_LIBINTL)
878   AM_PO_SUBDIRS
879 fi
880
881
882 #
883 # SELinux support
884 #
885 if test "$selinux_support" = yes ; then
886   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
887 fi
888
889
890 #
891 # Checks for header files.
892 #
893 AC_HEADER_STDC
894 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h])
895 AC_CHECK_HEADERS([pwd.h inttypes.h])
896 # Note that we do not check for iconv here because this is done anyway
897 # by the gettext checks and thus it allows us to disable the use of
898 # iconv by using --disable-nls.
899
900
901 #
902 # Checks for typedefs, structures, and compiler characteristics.
903 #
904 AC_C_CONST
905 AC_C_INLINE
906 AC_C_VOLATILE
907 AC_TYPE_SIZE_T
908 AC_TYPE_MODE_T
909 AC_TYPE_SIGNAL
910 AC_DECL_SYS_SIGLIST
911
912 AC_ARG_ENABLE(endian-check,
913               AC_HELP_STRING([--disable-endian-check],
914               [disable the endian check and trust the OS provided macros]),
915               endiancheck=$enableval,endiancheck=yes)
916
917 if test x"$endiancheck" = xyes ; then
918   GNUPG_CHECK_ENDIAN
919 fi
920
921 # fixme: we should get rid of the byte type
922 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
923 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
924 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
925 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
926 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
927
928 AC_CHECK_SIZEOF(unsigned short)
929 AC_CHECK_SIZEOF(unsigned int)
930 AC_CHECK_SIZEOF(unsigned long)
931 AC_CHECK_SIZEOF(unsigned long long)
932 # Ensure that we have UINT64_C before we bother to check for uint64_t
933 # Fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
934 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
935    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
936        uint64_t foo=UINT64_C(42);]),
937      gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
938 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
939    AC_CHECK_SIZEOF(uint64_t)
940 fi
941
942 if test "$ac_cv_sizeof_unsigned_short" = "0" \
943    || test "$ac_cv_sizeof_unsigned_int" = "0" \
944    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
945     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
946 fi
947
948 #
949 # fixme: do we really need this - it should be encapsulated in libassuan
950 #
951 GNUPG_SYS_SO_PEERCRED
952
953
954 #
955 # Checks for library functions.
956 #
957 AC_CHECK_DECLS(getpagesize)
958 AC_FUNC_FSEEKO
959 AC_FUNC_VPRINTF
960 AC_FUNC_FORK
961 AC_CHECK_FUNCS([strerror stpcpy strsep strlwr tcgetattr strtoul mmap])
962 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times timegm gmtime_r])
963 AC_CHECK_FUNCS([unsetenv getpwnam getpwuid fcntl ftruncate])
964 AC_CHECK_FUNCS([memmove gettimeofday getrusage setrlimit clock_gettime])
965 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
966 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe stat getaddrinfo])
967 AC_CHECK_FUNCS([ttyname isascii memrchr rand ftello])
968
969 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
970
971 #
972 # gnulib checks
973 #
974 gl_SOURCE_BASE(gl)
975 gl_M4_BASE(gl/m4)
976 gl_MODULES(setenv strsep mkdtemp vasprintf xsize)
977 gl_INIT
978
979
980 #
981 # These are needed by libjnlib - fixme: we should have macros for them
982 #
983 AC_CHECK_FUNCS([memicmp stpcpy strlwr strtoul memmove stricmp strtol])
984 AC_CHECK_FUNCS([getrusage setrlimit stat setlocale])
985 AC_CHECK_FUNCS([flockfile funlockfile fopencookie funopen])
986
987
988 #
989 # W32 specific test
990 #
991 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
992
993
994 #
995 # Sanity check regex.  Tests adapted from mutt.
996 # FIXME: We should use the the regex from gnulib
997 #
998 AC_MSG_CHECKING([whether regular expression support is requested])
999 AC_ARG_ENABLE(regex,
1000   AC_HELP_STRING([--disable-regex],
1001     [do not handle regular expressions in trust signatures]),
1002   use_regex=$enableval, use_regex=yes)
1003 AC_MSG_RESULT($use_regex)
1004
1005 if test "$use_regex" = yes ; then
1006   AC_MSG_CHECKING([whether the included regex lib is requested])
1007   AC_ARG_WITH(included-regex,
1008       [  --with-included-regex   use the included GNU regex library],
1009       [gnupg_cv_included_regex="$withval"],[gnupg_cv_included_regex=no])
1010   AC_MSG_RESULT($gnupg_cv_included_regex)
1011
1012   if test $gnupg_cv_included_regex = no ; then
1013      # Does the system have regex functions at all?
1014      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
1015                            gnupg_cv_included_regex=yes)
1016   fi
1017
1018   if test $gnupg_cv_included_regex = no ; then
1019      AC_CACHE_CHECK([whether your system's regexp library is broken],
1020        [gnupg_cv_regex_broken],
1021        AC_TRY_RUN([
1022 #include <unistd.h>
1023 #include <regex.h>
1024 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1025        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1026
1027      if test $gnupg_cv_regex_broken = yes ; then
1028       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
1029       gnupg_cv_included_regex=yes
1030      fi
1031   fi
1032
1033   if test $gnupg_cv_included_regex = yes; then
1034      AC_DEFINE(USE_INTERNAL_REGEX,1,[ Define if you want to use the included regex lib ])
1035   fi
1036 else
1037   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
1038 fi
1039
1040 AM_CONDITIONAL(USE_INTERNAL_REGEX, test x"$gnupg_cv_included_regex" = xyes)
1041
1042
1043
1044 #
1045 # Do we have zlib? Must do it here because Solaris failed
1046 # when compiling a conftest (due to the "-lz" from LIBS).
1047 # Note that we combine zlib and bzlib2 in ZLIBS.
1048 #
1049 _cppflags="${CPPFLAGS}"
1050 _ldflags="${LDFLAGS}"
1051 AC_ARG_WITH(zlib,
1052   [  --with-zlib=DIR         use libz in DIR],[
1053     if test -d "$withval"; then
1054       CPPFLAGS="${CPPFLAGS} -I$withval/include"
1055       LDFLAGS="${LDFLAGS} -L$withval/lib"
1056     fi
1057   ])
1058
1059 AC_CHECK_HEADER(zlib.h,
1060       AC_CHECK_LIB(z, deflateInit2_,
1061        ZLIBS="-lz",
1062        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1063        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1064
1065 #
1066 # Check whether we can support bzip2
1067
1068 if test "$use_bzip2" = yes ; then
1069   _cppflags="${CPPFLAGS}"
1070   _ldflags="${LDFLAGS}"
1071   AC_ARG_WITH(bzip2,
1072      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1073       [
1074       if test -d "$withval" ; then
1075         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1076         LDFLAGS="${LDFLAGS} -L$withval/lib"
1077       fi
1078       ],withval="")
1079
1080   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1081   # required stdio.h to be included before bzlib.h, and Solaris 9 is 
1082   # woefully out of date.
1083   if test "$withval" != no ; then
1084      AC_CHECK_HEADER(bzlib.h,
1085         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1086           [
1087           have_bz2=yes
1088           ZLIBS="$ZLIBS -lbz2"
1089           AC_DEFINE(HAVE_BZIP2,1,
1090                   [Defined if the bz2 compression library is available])
1091           ],
1092           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1093           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1094   fi
1095 fi
1096 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1097 AC_SUBST(ZLIBS)
1098
1099
1100 # Check for readline support
1101 GNUPG_CHECK_READLINE
1102
1103 # See wether we want to run the long test suite.
1104 AC_ARG_WITH(pkits-tests,
1105     AC_HELP_STRING([--with-pkits-tests],[run the PKITS based tests]),
1106     [run_pkits_tests=$withval], [run_pkits_tests=no])
1107 AM_CONDITIONAL(RUN_PKITS_TESTS, test "$run_pkits_tests" = "yes")
1108
1109 #
1110 # Allow users to append something to the version string without
1111 # flagging it as development version.  The user version parts is
1112 # considered everything after a dash. 
1113 #
1114 if test "$development_version" != yes; then
1115   changequote(,)dnl
1116   tmp_pat='[a-zA-Z]'
1117   changequote([,])dnl
1118   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1119     development_version=yes
1120   fi
1121 fi
1122 if test "$development_version" = yes; then
1123     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1124             [Defined if this is not a regular release])
1125 fi
1126
1127 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1128
1129 GNUPG_CHECK_GNUMAKE
1130
1131 # Add some extra libs here so that previous tests don't fail for
1132 # mysterious reasons - the final link step should bail out. 
1133 if test "$have_w32_system" = yes; then
1134    W32LIBS="-lwsock32"
1135 fi
1136
1137 AC_SUBST(NETLIBS)
1138 AC_SUBST(W32LIBS)
1139
1140
1141 #
1142 # Setup gcc specific options
1143 #
1144 if test "$GCC" = yes; then
1145     # Note that it is okay to use CFLAGS here because this are just
1146     # warning options and the user should have a chance of overriding
1147     # them.
1148     if test "$USE_MAINTAINER_MODE" = "yes"; then
1149         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1150         CFLAGS="$CFLAGS -Wno-format-y2k -Wformat-security -Wformat-nonliteral"
1151     else
1152         CFLAGS="$CFLAGS -Wall"
1153     fi
1154
1155     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1156     _gcc_cflags_save=$CFLAGS
1157     CFLAGS="-Wno-pointer-sign"
1158     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1159     AC_MSG_RESULT($_gcc_psign)
1160     CFLAGS=$_gcc_cflags_save;
1161     if test x"$_gcc_psign" = xyes ; then
1162        CFLAGS="$CFLAGS -Wno-pointer-sign"
1163     fi
1164 fi
1165
1166
1167 #
1168 # This is handy for debugging so the compiler doesn't rearrange
1169 # things and eliminate variables.
1170 #
1171 AC_ARG_ENABLE(optimization,
1172    AC_HELP_STRING([--disable-optimization],
1173                   [disable compiler optimization]),
1174                   [if test $enableval = no ; then
1175                       CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]]//'`
1176                    fi])
1177
1178 #
1179 # For W32 we need to use our Pth emulation code
1180 #
1181 if test "$have_w32_system" = yes; then
1182   AC_CONFIG_LINKS(pth.h:jnlib/w32-pth.h)
1183 fi
1184
1185
1186 #
1187 # Decide what to build
1188 #
1189 missing_pth=no
1190 if test $have_ksba = no; then
1191   build_gpgsm=no
1192   build_scdaemon=no
1193 fi
1194
1195 build_agent_threaded=""
1196 if test "$build_agent" = "yes"; then
1197   if test $have_pth = no; then
1198      build_agent_threaded="(not multi-threaded)"
1199      missing_pth=yes
1200   fi
1201 fi
1202
1203 build_scdaemon_extra=""
1204 if test "$build_scdaemon" = "yes"; then
1205   tmp=""
1206   if test $have_pth = no; then
1207      build_scdaemon_extra="not multi-threaded"
1208      tmp=", "
1209      missing_pth=yes
1210   fi
1211   if test -n "$build_scdaemon_extra"; then
1212      build_scdaemon_extra="(${build_scdaemon_extra})"
1213   fi
1214 fi
1215
1216
1217 if test "$build_agent_only" = "yes" ; then
1218   build_gpg=no
1219   build_gpgsm=no
1220   build_scdaemon=no
1221 fi
1222
1223
1224 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1225 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1226 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1227 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1228 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1229
1230
1231
1232 #
1233 # Print errors here so that they are visible all
1234 # together and the user can acquire them all together.
1235 #
1236 die=no
1237 if test "$have_gpg_error" = "no"; then
1238    die=yes
1239    AC_MSG_NOTICE([[
1240 ***  
1241 *** You need libgpg-error to build this program.
1242 **  This library is for example available at
1243 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1244 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1245 ***]])
1246 fi
1247 if test "$have_libgcrypt" = "no"; then
1248    die=yes
1249    AC_MSG_NOTICE([[
1250 ***  
1251 *** You need libgcrypt to build this program.
1252 **  This library is for example available at
1253 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1254 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API) is required.)
1255 ***]])
1256 fi
1257 if test "$have_libassuan" = "no"; then
1258    die=yes
1259    AC_MSG_NOTICE([[
1260 ***
1261 *** You need libassuan to build this program.
1262 *** This library is for example available at
1263 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libassuan/
1264 *** (at least version $NEED_LIBASSUAN_VERSION is required).
1265 ***]])
1266 fi
1267 if test "$have_ksba" = "no"; then
1268     AC_MSG_NOTICE([[
1269 ***
1270 *** You need libksba to build this program.
1271 *** This library is for example available at
1272 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libksba/
1273 *** (at least version $NEED_KSBA_VERSION is required).
1274 ***]])
1275 fi
1276 if test "$missing_pth" = "yes"; then
1277     AC_MSG_NOTICE([[
1278 ***
1279 *** It is now required to build with support for the
1280 *** GNU Portable Threads Library (Pth). Please install this
1281 *** library first.  The library is for example available at
1282 ***   ftp://ftp.gnu.org/gnu/pth/
1283 *** On a Debian GNU/Linux system you can install it using 
1284 ***   apt-get install libpth-dev
1285 ***]])
1286    die=yes
1287 fi
1288
1289 if test "$die" = "yes"; then
1290     AC_MSG_ERROR([[
1291 ***
1292 *** Required libraries not found. Please consult the above messages
1293 *** and install them before running configure again.
1294 ***]])
1295 fi
1296
1297
1298
1299 AC_CONFIG_FILES([ m4/Makefile 
1300 Makefile
1301 po/Makefile.in
1302 intl/Makefile
1303 gl/Makefile
1304 jnlib/Makefile
1305 common/Makefile
1306 kbx/Makefile
1307 g10/Makefile
1308 sm/Makefile
1309 agent/Makefile
1310 scd/Makefile
1311 keyserver/Makefile
1312 keyserver/gpgkeys_mailto
1313 keyserver/gpgkeys_test
1314 tools/gpg-zip
1315 tools/Makefile
1316 doc/Makefile
1317 tests/Makefile
1318 tests/openpgp/Makefile
1319 ])
1320 AC_OUTPUT
1321
1322 #tests/pkits/Makefile
1323
1324
1325
1326
1327 echo "
1328         GnuPG v${VERSION} has been configured as follows:
1329         
1330         Platform:  $PRINTABLE_OS_NAME ($host)
1331
1332         OpenPGP:   $build_gpg
1333         S/MIME:    $build_gpgsm
1334         Agent:     $build_agent $build_agent_threaded
1335         Smartcard: $build_scdaemon $build_scdaemon_extra
1336
1337         Protect tool:      $show_gnupg_protect_tool_pgm
1338         Default agent:     $show_gnupg_agent_pgm
1339         Default pinentry:  $show_gnupg_pinentry_pgm
1340         Default scdaemon:  $show_gnupg_scdaemon_pgm
1341         Default dirmngr:   $show_gnupg_dirmngr_pgm
1342
1343         PKITS based tests: $run_pkits_tests
1344 "
1345