More chnages to use estream. Add a way to replace the standard
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005,
3 #               2006, 2007, 2008, 2009 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.10"
23
24 # Remember to change the version number immediately *after* a release.
25 # Set my_issvn to "yes" for non-released code.  Remember to run an
26 # "svn up" and "autogen.sh" right before creating a distribution.
27 m4_define([my_version], [2.1.0])
28 m4_define([my_issvn], [yes])
29
30 m4_define([svn_revision], m4_esyscmd([printf "%d" $(svn info 2>/dev/null \
31           | sed -n '/^Revision:/ s/[^0-9]//gp'|head -1)]))
32 m4_define([git_revision], m4_esyscmd([git branch -v 2>/dev/null \
33           | awk '/^\* / {printf "%s",$3}']))
34 AC_INIT([gnupg], 
35         [my_version[]m4_if(my_issvn,[yes],
36         [m4_if(git_revision,[],[-svn[]svn_revision],[-git[]git_revision])])],
37         [http://bugs.gnupg.org])
38 # Set development_version to yes if the minor number is odd or you
39 # feel that the default check for a development version is not
40 # sufficient.
41 development_version=no
42
43 NEED_GPG_ERROR_VERSION=1.4
44
45 NEED_LIBGCRYPT_API=1
46 NEED_LIBGCRYPT_VERSION=1.4.0
47
48 NEED_LIBASSUAN_API=2
49 NEED_LIBASSUAN_VERSION=2.0.0
50
51 NEED_KSBA_API=1
52 NEED_KSBA_VERSION=1.0.2
53
54
55 PACKAGE=$PACKAGE_NAME
56 PACKAGE_GT=${PACKAGE_NAME}2
57 VERSION=$PACKAGE_VERSION
58
59 AC_CONFIG_AUX_DIR(scripts)
60 AC_CONFIG_SRCDIR(sm/gpgsm.c)
61 AM_CONFIG_HEADER(config.h)
62 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
63 AC_CANONICAL_HOST
64 AB_INIT
65
66 AC_GNU_SOURCE
67
68 # Some status variables.
69 have_gpg_error=no
70 have_libgcrypt=no 
71 have_libassuan=no
72 have_ksba=no
73 have_pth=no
74 have_libusb=no
75 have_adns=no
76
77 use_bzip2=yes
78 use_exec=yes
79 disable_keyserver_path=no
80 use_ccid_driver=yes
81
82 GNUPG_BUILD_PROGRAM(gpg, yes)
83 GNUPG_BUILD_PROGRAM(gpgsm, yes)
84 GNUPG_BUILD_PROGRAM(agent, yes)
85 GNUPG_BUILD_PROGRAM(scdaemon, yes)
86 GNUPG_BUILD_PROGRAM(g13, yes)
87 GNUPG_BUILD_PROGRAM(tools, yes)
88 GNUPG_BUILD_PROGRAM(doc, yes)
89 GNUPG_BUILD_PROGRAM(symcryptrun, no)
90
91 AC_SUBST(PACKAGE)
92 AC_SUBST(PACKAGE_GT)
93 AC_SUBST(VERSION)
94 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
95 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
96                                 [Name of this package for gettext])
97 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
98 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
99                                         [Bug report address])
100 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
101                                        [Required version of Libgcrypt])
102 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
103                                        [Required version of Libksba])
104
105
106
107 # The default is to use the modules from this package and the few
108 # other packages in a standard place; i.e where this package gets
109 # installed.  With these options it is possible to override these
110 # ${prefix} depended values with fixed paths, which can't be replaced
111 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
112 AC_ARG_WITH(agent-pgm,
113     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
114           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
115 AC_SUBST(GNUPG_AGENT_PGM)
116 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
117 show_gnupg_agent_pgm="(default)"
118 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
119
120 AC_ARG_WITH(pinentry-pgm,
121     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
122           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
123 AC_SUBST(GNUPG_PINENTRY_PGM)
124 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
125 show_gnupg_pinentry_pgm="(default)"
126 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
127
128
129 AC_ARG_WITH(scdaemon-pgm,
130     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
131           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
132 AC_SUBST(GNUPG_SCDAEMON_PGM)
133 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
134 show_gnupg_scdaemon_pgm="(default)"
135 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
136
137
138 AC_ARG_WITH(dirmngr-pgm,
139     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
140           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
141 AC_SUBST(GNUPG_DIRMNGR_PGM)
142 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
143 show_gnupg_dirmngr_pgm="(default)"
144 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
145
146 AC_ARG_WITH(protect-tool-pgm,
147     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
148           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
149 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
150 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
151 show_gnupg_protect_tool_pgm="(default)"
152 test -n "$GNUPG_PROTECT_TOOL_PGM" \
153       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
154
155
156 # Some folks want to use only the agent from this packet.  Make it
157 # easier for them by providing the configure option
158 # --enable-only-agent.
159 AC_ARG_ENABLE(agent-only,
160     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
161     build_agent_only=$enableval)
162
163 # SELinux support includes tracking of sensitive files to avoid
164 # leaking their contents through processing these files by gpg itself
165 AC_MSG_CHECKING([whether SELinux support is requested])
166 AC_ARG_ENABLE(selinux-support,
167               AC_HELP_STRING([--enable-selinux-support],
168                              [enable SELinux support]),
169               selinux_support=$enableval, selinux_support=no)
170 AC_MSG_RESULT($selinux_support)
171
172 # Allow disabling of bzib2 support.
173 # It is defined only after we confirm the library is available later
174 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
175 AC_ARG_ENABLE(bzip2,
176    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
177    use_bzip2=$enableval)
178 AC_MSG_RESULT($use_bzip2)
179
180 # Configure option to allow or disallow execution of external
181 # programs, like a photo viewer.
182 AC_MSG_CHECKING([whether to enable external program execution])
183 AC_ARG_ENABLE(exec,
184     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
185     use_exec=$enableval)
186 AC_MSG_RESULT($use_exec)
187 if test "$use_exec" = no ; then
188     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
189 fi
190
191 if test "$use_exec" = yes ; then
192   AC_MSG_CHECKING([whether to enable photo ID viewing])
193   AC_ARG_ENABLE(photo-viewers,
194       [  --disable-photo-viewers disable photo ID viewers],
195       [if test "$enableval" = no ; then
196          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
197       fi],enableval=yes)
198   gnupg_cv_enable_photo_viewers=$enableval
199   AC_MSG_RESULT($enableval)
200
201   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
202     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
203     AC_ARG_WITH(photo-viewer,
204         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
205         [if test "$withval" = yes ; then
206            withval=no
207         elif test "$withval" != no ; then
208            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
209                             [if set, restrict photo-viewer to this])
210         fi],withval=no)
211     AC_MSG_RESULT($withval)
212   fi
213
214   AC_MSG_CHECKING([whether to enable external keyserver helpers])
215   AC_ARG_ENABLE(keyserver-helpers,
216       [  --disable-keyserver-helpers  disable all external keyserver support],
217       [if test "$enableval" = no ; then
218          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
219                   [define to disable keyserver helpers])
220       fi],enableval=yes)
221   gnupg_cv_enable_keyserver_helpers=$enableval
222   AC_MSG_RESULT($enableval)
223
224   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
225     # LDAP is defined only after we confirm the library is available later
226     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
227     AC_ARG_ENABLE(ldap,
228       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
229       try_ldap=$enableval, try_ldap=yes)
230     AC_MSG_RESULT($try_ldap)
231
232     AC_MSG_CHECKING([whether HKP keyserver support is requested])
233     AC_ARG_ENABLE(hkp,
234       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
235       try_hkp=$enableval, try_hkp=yes)
236     AC_MSG_RESULT($try_hkp)
237
238     AC_MSG_CHECKING([whether finger key fetching support is requested])
239     AC_ARG_ENABLE(finger,
240       AC_HELP_STRING([--disable-finger],
241         [disable finger key fetching interface only]),
242       try_finger=$enableval, try_finger=yes)
243     AC_MSG_RESULT($try_finger)
244
245     AC_MSG_CHECKING([whether generic object key fetching support is requested])
246     AC_ARG_ENABLE(generic,
247       AC_HELP_STRING([--disable-generic],
248         [disable generic object key fetching interface only]),
249       try_generic=$enableval, try_generic=yes)
250     AC_MSG_RESULT($try_generic)
251
252     AC_MSG_CHECKING([whether email keyserver support is requested])
253     AC_ARG_ENABLE(mailto,
254       AC_HELP_STRING([--enable-mailto],
255         [enable email keyserver interface only]),
256       try_mailto=$enableval, try_mailto=no)
257     AC_MSG_RESULT($try_mailto)
258     fi
259
260     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
261     AC_ARG_ENABLE(keyserver-path,
262       AC_HELP_STRING([--disable-keyserver-path],
263         [disable the exec-path option for keyserver helpers]),
264       [if test "$enableval" = no ; then
265          disable_keyserver_path=yes
266       fi],enableval=yes)
267     AC_MSG_RESULT($enableval)
268   fi
269
270
271 #
272 # Check for the key/uid cache size.  This can't be zero, but can be
273 # pretty small on embedded systems.  This is used for the gpg part.
274 #
275 AC_MSG_CHECKING([for the size of the key and uid cache])
276 AC_ARG_ENABLE(key-cache,
277         AC_HELP_STRING([--enable-key-cache=SIZE],
278                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
279 if test "$enableval" = "no"; then
280    enableval=5
281 elif test "$enableval" = "yes" || test "$enableval" = ""; then
282    enableval=4096
283 fi
284 changequote(,)dnl
285 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
286 changequote([,])dnl
287 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
288    AC_MSG_ERROR([invalid key-cache size])
289 fi
290 AC_MSG_RESULT($key_cache_size)
291 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
292                   [Size of the key and UID caches])
293
294
295
296 #
297 # Check whether we want to use Linux capabilities
298 #
299 AC_MSG_CHECKING([whether use of capabilities is requested])
300 AC_ARG_WITH(capabilities,
301     [  --with-capabilities     use linux capabilities [default=no]],
302 [use_capabilities="$withval"],[use_capabilities=no])
303 AC_MSG_RESULT($use_capabilities)
304
305
306 #
307 # Allow disabling of internal CCID support.
308 # It is defined only after we confirm the library is available later
309 #
310 AC_MSG_CHECKING([whether to enable the internal CCID driver])
311 AC_ARG_ENABLE(ccid-driver,
312               AC_HELP_STRING([--disable-ccid-driver],
313                              [disable the internal CCID driver]),
314               use_ccid_driver=$enableval)
315 AC_MSG_RESULT($use_ccid_driver)
316
317
318 #
319 # To avoid double inclusion of config.h which might happen at some
320 # places, we add the usual double inclusion protection at the top of
321 # config.h.
322 #
323 AH_TOP([
324 #ifndef GNUPG_CONFIG_H_INCLUDED
325 #define GNUPG_CONFIG_H_INCLUDED
326 ])
327
328 #
329 # Stuff which goes at the bottom of config.h.
330 #
331 AH_BOTTOM([
332 /* This is the major version number of GnuPG so that
333    source included files can test for this.  Note, that
334    we use 2 here even for GnuPG 1.9.x. */
335 #define GNUPG_MAJOR_VERSION 2
336
337 /* Now to separate file name parts.
338    Please note that the string version must not contain more
339    than one character because the code assumes strlen()==1 */
340 #ifdef HAVE_DOSISH_SYSTEM
341 #define DIRSEP_C '\\'
342 #define DIRSEP_S "\\"
343 #define EXTSEP_C '.'
344 #define EXTSEP_S "."
345 #define PATHSEP_C ';'
346 #define PATHSEP_S ";"
347 #define EXEEXT_S ".exe"
348 #else
349 #define DIRSEP_C '/'
350 #define DIRSEP_S "/"
351 #define EXTSEP_C '.'
352 #define EXTSEP_S "."
353 #define PATHSEP_C ':'
354 #define PATHSEP_S ":"
355 #define EXEEXT_S ""
356 #endif
357
358 /* This is the same as VERSION, but should be overridden if the
359    platform cannot handle things like dots '.' in filenames. Set
360    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
361    uses for dots and dashes. */
362 #define SAFE_VERSION VERSION
363 #define SAFE_VERSION_DOT  '.'
364 #define SAFE_VERSION_DASH '-'
365
366 /* Some global constants. */
367 #ifdef HAVE_DRIVE_LETTERS
368 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
369 #elif defined(__VMS)
370 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg" 
371 #else
372 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
373 #endif 
374 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
375
376 /* For some systems (DOS currently), we hardcode the path here.  For
377    POSIX systems the values are constructed by the Makefiles, so that
378    the values may be overridden by the make invocations; this is to
379    comply with the GNU coding standards. */
380 #ifdef HAVE_DRIVE_LETTERS
381  /* FIXME: We need to use a function to determine these values depending 
382     on the actual installation directory. */
383 #define GNUPG_BINDIR      "c:\\gnupg"
384 #define GNUPG_LIBEXECDIR  "c:\\gnupg"
385 #define GNUPG_LIBDIR      "c:\\gnupg"
386 #define GNUPG_DATADIR     "c:\\gnupg"
387 #define GNUPG_SYSCONFDIR  "c:\\gnupg"
388 #endif
389
390 /* Derive some other constants. */
391 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
392 #define EXEC_TEMPFILE_ONLY
393 #endif
394
395
396 /* We didn't define endianness above, so get it from OS macros.  This
397    is intended for making fat binary builds on OS X. */
398 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
399 #if defined(__BIG_ENDIAN__)
400 #define BIG_ENDIAN_HOST 1
401 #elif defined(__LITTLE_ENDIAN__)
402 #define LITTLE_ENDIAN_HOST 1
403 #else
404 #error "No endianness found"
405 #endif
406 #endif
407
408
409 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
410    ldap_start_tls_s because that is the actual symbol used in the
411    library.  winldap.h redefines it to our commonly used value,
412    thus we define our usual macro here.  */
413 #ifdef HAVE_LDAP_START_TLS_SA
414 # ifndef HAVE_LDAP_START_TLS_S
415 #  define HAVE_LDAP_START_TLS_S 1
416 # endif
417 #endif
418
419
420 /* Tell libgcrypt not to use its own libgpg-error implementation. */
421 #define USE_LIBGPG_ERROR 1
422
423 /* We use jnlib, so tell other modules about it.  */
424 #define HAVE_JNLIB_LOGGING 1
425
426 /* Our HTTP code is used in estream mode.  */
427 #define HTTP_USE_ESTREAM 1
428
429 /* Under W32 we do an explicit socket initialization, thus we need to
430    avoid the on-demand initialization which would also install an atexit
431    handler.  */
432 #define HTTP_NO_WSASTARTUP
433
434 /* We always include support for the OpenPGP card.  */
435 #define ENABLE_CARD_SUPPORT 1
436
437 /* We explicitly need to disable PTH's soft mapping as Debian
438    currently enables it by default for no reason. */
439 #define PTH_SYSCALL_SOFT 0
440
441 /* We want to use the libgcrypt provided memory allocation for
442    asprintf.  */
443 #define _ESTREAM_PRINTF_MALLOC        gcry_malloc
444 #define _ESTREAM_PRINTF_FREE          gcry_free
445 #define _ESTREAM_PRINTF_EXTRA_INCLUDE "../common/util.h"
446
447 /* Under Windows we use the gettext code from libgpg-error.  */
448 #define GPG_ERR_ENABLE_GETTEXT_MACROS
449
450 #endif /*GNUPG_CONFIG_H_INCLUDED*/
451 ])
452
453
454 AM_MAINTAINER_MODE
455
456 # Checks for programs.
457 AC_MSG_NOTICE([checking for programs])
458 AC_PROG_MAKE_SET
459 AM_SANITY_CHECK
460 missing_dir=`cd $ac_aux_dir && pwd`
461 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
462 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
463 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
464 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
465 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
466 AC_PROG_AWK
467 AC_PROG_CC
468 AC_PROG_CPP
469 AM_PROG_CC_C_O
470 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
471   AC_MSG_ERROR([[No C-89 compiler found]])
472 fi
473 AC_PROG_INSTALL
474 AC_PROG_LN_S
475 AC_PROG_RANLIB
476 AC_CHECK_TOOL(AR, ar, :)
477 AC_PATH_PROG(PERL,"perl")
478 AC_CHECK_TOOL(WINDRES, windres, :)
479 AC_ISC_POSIX
480 gl_EARLY
481 AC_SYS_LARGEFILE
482 GNUPG_CHECK_FAQPROG
483 GNUPG_CHECK_USTAR
484
485 # We need to compile and run a program on the build machine.  A
486 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
487 # the AC archive is broken for autoconf 2.57.  Given that there is no
488 # newer version of that macro, we assume that it is also broken for
489 # autoconf 2.61 and thus we use a simple but usually sufficient
490 # approach.
491 AC_MSG_CHECKING(for cc for build)
492 if test "$cross_compiling" = "yes"; then
493   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
494 else
495   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
496 fi
497 AC_MSG_RESULT($CC_FOR_BUILD)
498 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
499
500
501
502 try_gettext=yes
503 have_dosish_system=no
504 have_w32_system=no
505 have_w32ce_system=no
506 use_simple_gettext=no
507 case "${host}" in
508     *-mingw32*)
509         # special stuff for Windoze NT
510         ac_cv_have_dev_random=no
511         AC_DEFINE(USE_ONLY_8DOT3,1,
512                   [set this to limit filenames to the 8.3 format])
513         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
514                   [defined if we must run on a stupid file system])
515         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
516                   [because the Unix gettext has too much overhead on
517                    MingW32 systems and these systems lack Posix functions,
518                    we use a simplified version of gettext])
519         disable_keyserver_path=yes
520         have_dosish_system=yes
521         have_w32_system=yes
522         case "${host}" in *-mingw32ce*) have_w32ce_system=yes ;; esac
523         try_gettext="no"
524         use_simple_gettext=yes
525         ;;
526     i?86-emx-os2 | i?86-*-os2*emx )
527         # OS/2 with the EMX environment
528         ac_cv_have_dev_random=no
529         AC_DEFINE(HAVE_DRIVE_LETTERS)
530         have_dosish_system=yes
531         try_gettext="no"
532         ;;
533
534     i?86-*-msdosdjgpp*)
535         # DOS with the DJGPP environment
536         ac_cv_have_dev_random=no
537         AC_DEFINE(HAVE_DRIVE_LETTERS)
538         have_dosish_system=yes
539         try_gettext="no"
540         ;;
541
542     *-*-freebsd*)
543        # FreeBSD
544        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
545        LDFLAGS="$LDFLAGS -L/usr/local/lib"
546        ;;
547
548     *-*-hpux*)
549         if test -z "$GCC" ; then
550             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
551         fi
552         ;;
553     *-dec-osf4*)
554         if test -z "$GCC" ; then
555             # Suppress all warnings
556             # to get rid of the unsigned/signed char mismatch warnings.
557             CFLAGS="$CFLAGS -w"
558         fi
559         ;;
560     *-dec-osf5*)
561         if test -z "$GCC" ; then
562             # Use the newer compiler `-msg_disable ptrmismatch1' to
563             # get rid of the unsigned/signed char mismatch warnings.
564             # Using this may hide other pointer mismatch warnings, but
565             # it at least lets other warning classes through
566             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
567         fi
568         ;;
569     m68k-atari-mint)
570         ;;
571     *)
572        ;;
573 esac
574
575 if test "$have_dosish_system" = yes; then
576    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
577              [Defined if we run on some of the PCDOS like systems 
578               (DOS, Windoze. OS/2) with special properties like
579               no file modes])
580 fi
581 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
582
583 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
584
585 if test "$have_w32_system" = yes; then
586    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
587    if test "$have_w32ce_system" = yes; then
588       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
589    fi
590 fi
591 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
592 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
593
594 if test "$disable_keyserver_path" = yes; then
595     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
596               [Defined to disable exec-path for keyserver helpers])
597 fi
598
599 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
600 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
601
602 if test x"$try_hkp" = xyes ; then
603   AC_SUBST(GPGKEYS_HKP,"gpg2keys_hkp$EXEEXT")
604 fi
605
606 if test x"$try_finger" = xyes ; then
607   AC_SUBST(GPGKEYS_FINGER,"gpg2keys_finger$EXEEXT")
608 fi
609
610
611
612 #
613 # Checks for libraries.
614 #
615 AC_MSG_NOTICE([checking for libraries])
616
617
618 #
619 # libgpg-error is a library with error codes shared between GnuPG
620 # related projects.
621 #
622 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
623                   have_gpg_error=yes,have_gpg_error=no)
624
625
626 #
627 # Libgcrypt is our generic crypto library
628 #
629 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
630         have_libgcrypt=yes,have_libgcrypt=no)
631
632
633 #
634 # libassuan is used for IPC
635 #
636 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
637                   have_libassuan=yes,have_libassuan=no)
638 if test "$have_libassuan" = "yes"; then
639   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
640                      [version of the libassuan library])
641 fi
642
643
644
645 #
646 # libksba is our X.509 support library
647 #
648 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
649
650
651 #
652 # libusb allows us to use the integrated CCID smartcard reader driver.
653 #
654 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
655 if test "$use_ccid_driver" = yes ; then
656   AC_CHECK_LIB(usb, usb_bulk_write,
657                 [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
658                   AC_DEFINE(HAVE_LIBUSB,1,
659                            [defined if libusb is available])
660                   have_libusb=yes
661                ])
662   AC_CHECK_FUNCS(usb_create_match)
663 fi
664 AC_SUBST(LIBUSB_LIBS)
665
666 #
667 # Check wether it is necessary to link against libdl.
668 #
669 gnupg_dlopen_save_libs="$LIBS"
670 LIBS=""
671 AC_SEARCH_LIBS(dlopen, c dl,,,)
672 DL_LIBS=$LIBS
673 AC_SUBST(DL_LIBS)
674 LIBS="$gnupg_dlopen_save_libs"
675
676 # Checks for g13
677
678 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
679 AC_DEFINE_UNQUOTED(ENCFS,
680         "${ENCFS}", [defines the filename of the encfs program])
681
682 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
683 AC_DEFINE_UNQUOTED(FUSERMOUNT,
684         "${FUSERMOUNT}", [defines the filename of the fusermount program])
685
686 #
687 # Checks for symcryptrun:
688 #
689
690 # libutil has openpty() and login_tty().
691 AC_CHECK_LIB(util, openpty,
692               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
693                 AC_DEFINE(HAVE_LIBUTIL,1,
694                          [defined if libutil is available])
695              ])
696 AC_SUBST(LIBUTIL_LIBS)
697
698 # shred is used to clean temporary plain text files.
699 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
700 AC_DEFINE_UNQUOTED(SHRED,
701         "${SHRED}", [defines the filename of the shred program])
702
703
704 #
705 # Check whether the GNU Pth library is available
706 # Note, that we include a Pth emulation for W32.
707 #
708 GNUPG_PATH_PTH
709 if test "$have_pth" = "yes"; then
710   AC_DEFINE(USE_GNU_PTH, 1,
711               [Defined if the GNU Portable Thread Library should be used])
712 else
713   AC_MSG_WARN([[
714 ***
715 *** To support concurrent access to the gpg-agent and the SCdaemon
716 *** we need the support of the GNU Portable Threads Library.
717 *** Download it from ftp://ftp.gnu.org/gnu/pth/
718 *** On a Debian GNU/Linux system you might want to try 
719 ***   apt-get install libpth-dev
720 ***]])
721 fi
722
723
724 AC_MSG_NOTICE([checking for networking options])
725
726 #
727 # Must check for network library requirements before doing link tests
728 # for ldap, for example. If ldap libs are static (or dynamic and without
729 # ELF runtime link paths), then link will fail and LDAP support won't
730 # be detected.
731 #
732 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
733         [NETLIBS="-lnsl $NETLIBS"]))
734 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
735         [NETLIBS="-lsocket $NETLIBS"]))
736
737
738 #
739 # Check for ADNS.
740 #
741 _cppflags="${CPPFLAGS}"
742 _ldflags="${LDFLAGS}"
743 AC_ARG_WITH(adns,
744             AC_HELP_STRING([--with-adns=DIR],
745                            [look for the adns library in DIR]),
746             [if test -d "$withval"; then
747                CPPFLAGS="${CPPFLAGS} -I$withval/include"
748                LDFLAGS="${LDFLAGS} -L$withval/lib"
749              fi])
750 if test "$with_adns" != "no"; then
751   AC_CHECK_HEADERS(adns.h,
752                 AC_CHECK_LIB(adns, adns_init,
753                              [have_adns=yes],
754                              [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}]),
755                 [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}])
756 fi
757 if test "$have_adns" = "yes"; then
758   ADNSLIBS="-ladns" 
759 fi
760 AC_SUBST(ADNSLIBS)
761 # Newer adns versions feature a free function to be used under W32.
762 AC_CHECK_FUNCS(adns_free)
763
764
765
766 #
767 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
768 #
769 if test x"$try_hkp" = xyes || test x"$try_http" = xyes ; then
770   AC_ARG_ENABLE(dns-srv,
771      AC_HELP_STRING([--disable-dns-srv],
772                     [disable the use of DNS SRV in HKP and HTTP]),
773                 use_dns_srv=$enableval,use_dns_srv=yes)
774 fi
775
776 AC_ARG_ENABLE(dns-pka,
777    AC_HELP_STRING([--disable-dns-pka],
778         [disable the use of PKA records in DNS]),
779    use_dns_pka=$enableval,use_dns_pka=yes)
780
781 AC_ARG_ENABLE(dns-cert,
782    AC_HELP_STRING([--disable-dns-cert],
783         [disable the use of CERT records in DNS]),
784    use_dns_cert=$enableval,use_dns_cert=yes)
785
786 if test x"$use_dns_pka" = xyes || test x"$use_dns_srv" = xyes \
787    || test x"$use_dns_cert" = xyes; then
788   _dns_save_libs=$LIBS
789   LIBS=""
790   # the double underscore thing is a glibc-ism?
791   AC_SEARCH_LIBS(res_query,resolv bind,,
792                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
793   AC_SEARCH_LIBS(dn_expand,resolv bind,,
794                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
795   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
796                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
797
798   if test x"$have_resolver" != xno ; then
799
800     # Make sure that the BIND 4 resolver interface is workable before
801     # enabling any code that calls it.  At some point I'll rewrite the
802     # code to use the BIND 8 resolver API.
803     # We might also want to use adns instead.  Problem with ADNS is that
804     # it does not support v6.
805
806     AC_MSG_CHECKING([whether the resolver is usable])
807     AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
808 #include <netinet/in.h>
809 #include <arpa/nameser.h>
810 #include <resolv.h>],
811 [[unsigned char answer[PACKETSZ];
812   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
813   dn_skipname(0,0); 
814   dn_expand(0,0,0,0,0);
815 ]])],have_resolver=yes,have_resolver=no)
816     AC_MSG_RESULT($have_resolver)
817
818     # This is Apple-specific and somewhat bizarre as they changed the
819     # define in bind 8 for some reason.
820
821     if test x"$have_resolver" != xyes ; then
822        AC_MSG_CHECKING(
823              [whether I can make the resolver usable with BIND_8_COMPAT])
824        AC_LINK_IFELSE([AC_LANG_PROGRAM([#define BIND_8_COMPAT
825 #include <sys/types.h>
826 #include <netinet/in.h>
827 #include <arpa/nameser.h>
828 #include <resolv.h>],
829 [[unsigned char answer[PACKETSZ];
830   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
831   dn_skipname(0,0); dn_expand(0,0,0,0,0);
832 ]])],[have_resolver=yes ; need_compat=yes])
833        AC_MSG_RESULT($have_resolver)
834     fi
835   fi
836
837   if test x"$have_resolver" = xyes ; then
838      DNSLIBS=$LIBS
839
840      if test x"$use_dns_srv" = xyes ; then
841         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
842      fi
843
844      if test x"$use_dns_pka" = xyes ; then
845         AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
846      fi
847
848      if test x"$use_dns_cert" = xyes ; then
849         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
850      fi
851
852      if test x"$need_compat" = xyes ; then
853         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
854      fi
855   else
856      # If we have no resolver library but ADNS (e.g. under W32) enable the
857      # code parts which can be used with ADNS.
858      if test x"$have_adns" = xyes ; then
859         DNSLIBS="$ADNSLIBS"
860         AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
861
862         if test x"$use_dns_srv" = xyes ; then
863            AC_DEFINE(USE_DNS_SRV,1)
864         fi
865
866         if test x"$use_dns_pka" = xyes ; then
867            AC_DEFINE(USE_DNS_PKA,1)
868         fi
869
870         if test x"$use_dns_cert" = xyes ; then
871            AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
872         fi
873      else
874         use_dns_srv=no
875         use_dns_pka=no
876         use_dns_cert=no
877      fi
878   fi
879
880   LIBS=$_dns_save_libs
881 fi
882
883 AC_SUBST(DNSLIBS)
884
885 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
886
887
888 #
889 # Check for LDAP
890 #
891 if test "$try_ldap" = yes ; then
892    GNUPG_CHECK_LDAP($NETLIBS)
893 fi
894
895 #
896 # Check for curl.  We fake the curl API if libcurl isn't installed.
897 # We require 7.10 or later as we use curl_version_info().
898 #
899 LIBCURL_CHECK_CONFIG([yes],[7.10],,[fake_curl=yes])
900 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
901
902 # Generic, for us, means curl
903
904 if test x"$try_generic" = xyes ; then
905    AC_SUBST(GPGKEYS_CURL,"gpg2keys_curl$EXEEXT")
906 fi
907
908 #
909 # Check for sendmail
910 #
911 # This isn't necessarily sendmail itself, but anything that gives a
912 # sendmail-ish interface to the outside world.  That includes Exim,
913 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
914 if test "$try_mailto" = yes ; then
915   AC_ARG_WITH(mailprog,
916       AC_HELP_STRING([--with-mailprog=NAME],
917                      [use "NAME -t" for mail transport]),
918              ,with_mailprog=yes)
919
920   if test x"$with_mailprog" = xyes ; then
921     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
922     if test "$ac_cv_path_SENDMAIL" ; then
923       GPGKEYS_MAILTO="gpg2keys_mailto"
924     fi
925   elif test x"$with_mailprog" != xno ; then
926     AC_MSG_CHECKING([for a mail transport program])
927     AC_SUBST(SENDMAIL,$with_mailprog)
928     AC_MSG_RESULT($with_mailprog)
929     GPGKEYS_MAILTO="gpg2keys_mailto"
930   fi
931 fi
932
933 AC_SUBST(GPGKEYS_MAILTO)
934
935 #
936 # Construct a printable name of the OS
937 #
938 case "${host}" in
939     *-mingw32ce*)
940         PRINTABLE_OS_NAME="W32CE"
941         ;;
942     *-mingw32*)
943         PRINTABLE_OS_NAME="MingW32"
944         ;;
945     *-*-cygwin*)
946         PRINTABLE_OS_NAME="Cygwin"
947         ;;
948     i?86-emx-os2 | i?86-*-os2*emx )
949         PRINTABLE_OS_NAME="OS/2"
950         ;;
951     i?86-*-msdosdjgpp*)
952         PRINTABLE_OS_NAME="MSDOS/DJGPP"
953         try_dynload=no
954         ;;
955     *-linux*)
956         PRINTABLE_OS_NAME="GNU/Linux"
957         ;;
958     *)
959         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
960         ;;
961 esac
962 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
963                    [A human readable text with the name of the OS])
964
965
966 #
967 # Checking for iconv
968 #
969 AM_ICONV
970
971
972 #
973 # Check for gettext
974 #
975 # This is "GNU gnupg" - The project-id script from gettext
976 #                       needs this string
977 #
978 AC_MSG_NOTICE([checking for gettext])
979 AM_PO_SUBDIRS
980 AM_GNU_GETTEXT_VERSION([0.17])
981 if test "$try_gettext" = yes; then
982   AM_GNU_GETTEXT([external],[need-ngettext])
983
984   # gettext requires some extra checks.  These really should be part of
985   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
986   # function checks to here.
987
988   AC_CHECK_FUNCS(strchr)
989 else
990   USE_NLS=no
991   USE_INCLUDED_LIBINTL=no
992   BUILD_INCLUDED_LIBINTL=no
993   POSUB=po
994   AC_SUBST(USE_NLS)
995   AC_SUBST(USE_INCLUDED_LIBINTL)
996   AC_SUBST(BUILD_INCLUDED_LIBINTL)
997   AC_SUBST(POSUB)
998 fi
999
1000 # We use HAVE_LANGINFO_CODESET in a couple of places.
1001 AM_LANGINFO_CODESET
1002
1003 # Checks required for our use locales
1004 gt_LC_MESSAGES
1005
1006
1007 #
1008 # SELinux support
1009 #
1010 if test "$selinux_support" = yes ; then
1011   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1012 fi
1013
1014
1015 #
1016 # Checks for header files.
1017 #
1018 AC_MSG_NOTICE([checking for header files])
1019 AC_HEADER_STDC
1020 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1021                   pty.h pwd.h inttypes.h signal.h])
1022 AC_HEADER_TIME
1023
1024
1025 #
1026 # Checks for typedefs, structures, and compiler characteristics.
1027 #
1028 AC_MSG_NOTICE([checking for system characteristics])
1029 AC_C_CONST
1030 AC_C_INLINE
1031 AC_C_VOLATILE
1032 AC_TYPE_SIZE_T
1033 AC_TYPE_MODE_T
1034 AC_TYPE_SIGNAL
1035 AC_DECL_SYS_SIGLIST
1036
1037 gl_HEADER_SYS_SOCKET
1038 gl_TYPE_SOCKLEN_T
1039
1040 AC_ARG_ENABLE(endian-check,
1041               AC_HELP_STRING([--disable-endian-check],
1042               [disable the endian check and trust the OS provided macros]),
1043               endiancheck=$enableval,endiancheck=yes)
1044
1045 if test x"$endiancheck" = xyes ; then
1046   GNUPG_CHECK_ENDIAN
1047 fi
1048
1049 # fixme: we should get rid of the byte type
1050 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1051 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1052 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1053 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1054 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1055
1056 AC_CHECK_SIZEOF(unsigned short)
1057 AC_CHECK_SIZEOF(unsigned int)
1058 AC_CHECK_SIZEOF(unsigned long)
1059 AC_CHECK_SIZEOF(unsigned long long)
1060 AC_CHECK_SIZEOF(time_t,,[[
1061 #include <stdio.h>
1062 #if TIME_WITH_SYS_TIME
1063 # include <sys/time.h>
1064 # include <time.h>
1065 #else
1066 # if HAVE_SYS_TIME_H
1067 #  include <sys/time.h>
1068 # else
1069 #  include <time.h>
1070 # endif
1071 #endif
1072 ]])
1073
1074
1075 # Ensure that we have UINT64_C before we bother to check for uint64_t
1076 # Fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
1077 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
1078    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
1079        uint64_t foo=UINT64_C(42);]),
1080      gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
1081 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
1082    AC_CHECK_SIZEOF(uint64_t)
1083 fi
1084
1085 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1086    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1087    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1088     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1089 fi
1090
1091
1092 #
1093 # Checks for library functions.
1094 #
1095 AC_MSG_NOTICE([checking for library functions])
1096 AC_CHECK_DECLS(getpagesize)
1097 AC_FUNC_FSEEKO
1098 AC_FUNC_VPRINTF
1099 AC_FUNC_FORK
1100 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap])
1101 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r])
1102 AC_CHECK_FUNCS([unsetenv fcntl ftruncate])
1103 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1104 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1105 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe stat getaddrinfo])
1106 AC_CHECK_FUNCS([ttyname rand ftello fsync])
1107
1108 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1109
1110 #
1111 # These are needed by the jnlib parts in common.
1112 # Note:  We already checked pwd.h.
1113 AC_CHECK_HEADERS([signal.h])
1114 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1115                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1116                 flockfile funlockfile fopencookie funopen getpwnam getpwuid \
1117                 getenv ])
1118
1119 #
1120 # gnulib checks
1121 #
1122 gl_SOURCE_BASE([gl])
1123 gl_M4_BASE([gl/m4])
1124 gl_MODULES([setenv mkdtemp xsize strpbrk])
1125 gl_INIT
1126
1127
1128 #
1129 # W32 specific test
1130 #
1131 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1132
1133 #
1134 # Sanity check regex.  Tests adapted from mutt.
1135 #
1136 AC_MSG_CHECKING([whether regular expression support is requested])
1137 AC_ARG_ENABLE(regex,
1138   AC_HELP_STRING([--disable-regex],
1139     [do not handle regular expressions in trust signatures]),
1140   use_regex=$enableval, use_regex=yes)
1141 AC_MSG_RESULT($use_regex)
1142
1143 if test "$use_regex" = yes ; then
1144   _cppflags="${CPPFLAGS}"
1145   _ldflags="${LDFLAGS}"
1146   AC_ARG_WITH(regex,
1147      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1148       [
1149       if test -d "$withval" ; then
1150         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1151         LDFLAGS="${LDFLAGS} -L$withval/lib"
1152       fi
1153       ],withval="")     
1154
1155   # Does the system have regex functions at all?
1156   AC_SEARCH_LIBS([regcomp], [regex])
1157   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1158
1159   if test $gnupg_cv_have_regex = no; then
1160     use_regex=no
1161   else
1162     if test x"$cross_compiling" = xyes; then
1163       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1164     else
1165       AC_CACHE_CHECK([whether your system's regexp library is broken],
1166        [gnupg_cv_regex_broken],
1167        AC_TRY_RUN([
1168 #include <unistd.h>
1169 #include <regex.h>
1170 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1171        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1172
1173       if test $gnupg_cv_regex_broken = yes; then
1174         AC_MSG_WARN([your regex is broken - disabling regex use])
1175         use_regex=no
1176       fi
1177     fi
1178   fi
1179   CPPFLAGS="${_cppflags}"
1180   LDFLAGS="${_ldflags}"
1181 fi
1182
1183 if test "$use_regex" != yes ; then
1184   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1185 fi
1186 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1187
1188
1189
1190 #
1191 # Do we have zlib? Must do it here because Solaris failed
1192 # when compiling a conftest (due to the "-lz" from LIBS).
1193 # Note that we combine zlib and bzlib2 in ZLIBS.
1194 #
1195 _cppflags="${CPPFLAGS}"
1196 _ldflags="${LDFLAGS}"
1197 AC_ARG_WITH(zlib,
1198   [  --with-zlib=DIR         use libz in DIR],[
1199     if test -d "$withval"; then
1200       CPPFLAGS="${CPPFLAGS} -I$withval/include"
1201       LDFLAGS="${LDFLAGS} -L$withval/lib"
1202     fi
1203   ])
1204
1205 AC_CHECK_HEADER(zlib.h,
1206       AC_CHECK_LIB(z, deflateInit2_,
1207        ZLIBS="-lz",
1208        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1209        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1210
1211 #
1212 # Check whether we can support bzip2
1213
1214 if test "$use_bzip2" = yes ; then
1215   _cppflags="${CPPFLAGS}"
1216   _ldflags="${LDFLAGS}"
1217   AC_ARG_WITH(bzip2,
1218      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1219       [
1220       if test -d "$withval" ; then
1221         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1222         LDFLAGS="${LDFLAGS} -L$withval/lib"
1223       fi
1224       ],withval="")
1225
1226   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1227   # required stdio.h to be included before bzlib.h, and Solaris 9 is 
1228   # woefully out of date.
1229   if test "$withval" != no ; then
1230      AC_CHECK_HEADER(bzlib.h,
1231         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1232           [
1233           have_bz2=yes
1234           ZLIBS="$ZLIBS -lbz2"
1235           AC_DEFINE(HAVE_BZIP2,1,
1236                   [Defined if the bz2 compression library is available])
1237           ],
1238           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1239           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1240   fi
1241 fi
1242 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1243 AC_SUBST(ZLIBS)
1244
1245
1246 # Check for readline support
1247 GNUPG_CHECK_READLINE
1248
1249 #
1250 # Allow users to append something to the version string without
1251 # flagging it as development version.  The user version parts is
1252 # considered everything after a dash. 
1253 #
1254 if test "$development_version" != yes; then
1255   changequote(,)dnl
1256   tmp_pat='[a-zA-Z]'
1257   changequote([,])dnl
1258   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1259     development_version=yes
1260   fi
1261 fi
1262 if test "$development_version" = yes; then
1263     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1264             [Defined if this is not a regular release])
1265 fi
1266
1267 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1268
1269 GNUPG_CHECK_GNUMAKE
1270
1271 # Add some extra libs here so that previous tests don't fail for
1272 # mysterious reasons - the final link step should bail out.
1273 # W32SOCKLIBS is also defined so that if can be used for tools not
1274 # requiring any network stuff but linking to code in libcommon which
1275 # tracks in winsock stuff (e.g. init_common_subsystems.
1276 if test "$have_w32_system" = yes; then
1277    W32SOCKLIBS="-lws2_32"
1278    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1279 fi
1280
1281 AC_SUBST(NETLIBS)
1282 AC_SUBST(W32SOCKLIBS)
1283
1284 #
1285 # Setup gcc specific options
1286 #
1287 AC_MSG_NOTICE([checking for cc features])
1288 if test "$GCC" = yes; then
1289     # Note that it is okay to use CFLAGS here because this are just
1290     # warning options and the user should have a chance of overriding
1291     # them.
1292     if test "$USE_MAINTAINER_MODE" = "yes"; then
1293         CFLAGS="$CFLAGS -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1294         CFLAGS="$CFLAGS -Wformat -Wno-format-y2k -Wformat-security"
1295         AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1296         _gcc_cflags_save=$CFLAGS
1297         CFLAGS="-Wno-missing-field-initializers"
1298         AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_wopt=yes,_gcc_wopt=no)
1299         AC_MSG_RESULT($_gcc_wopt)
1300         CFLAGS=$_gcc_cflags_save;
1301         if test x"$_gcc_wopt" = xyes ; then
1302           CFLAGS="$CFLAGS -W -Wno-sign-compare -Wno-missing-field-initializers"
1303         fi
1304         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1305         _gcc_cflags_save=$CFLAGS
1306         CFLAGS="-Wdeclaration-after-statement"
1307         AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_wopt=yes,_gcc_wopt=no)
1308         AC_MSG_RESULT($_gcc_wopt)
1309         CFLAGS=$_gcc_cflags_save;
1310         if test x"$_gcc_wopt" = xyes ; then
1311           CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1312         fi
1313     else
1314         CFLAGS="$CFLAGS -Wall"
1315     fi
1316
1317     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1318     _gcc_cflags_save=$CFLAGS
1319     CFLAGS="-Wno-pointer-sign"
1320     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1321     AC_MSG_RESULT($_gcc_psign)
1322     CFLAGS=$_gcc_cflags_save;
1323     if test x"$_gcc_psign" = xyes ; then
1324        CFLAGS="$CFLAGS -Wno-pointer-sign"
1325     fi
1326
1327     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1328     _gcc_cflags_save=$CFLAGS
1329     CFLAGS="-Wpointer-arith"
1330     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1331     AC_MSG_RESULT($_gcc_psign)
1332     CFLAGS=$_gcc_cflags_save;
1333     if test x"$_gcc_psign" = xyes ; then
1334        CFLAGS="$CFLAGS -Wpointer-arith"
1335     fi
1336 fi
1337
1338
1339 #
1340 # This is handy for debugging so the compiler doesn't rearrange
1341 # things and eliminate variables.
1342 #
1343 AC_ARG_ENABLE(optimization,
1344    AC_HELP_STRING([--disable-optimization],
1345                   [disable compiler optimization]),
1346                   [if test $enableval = no ; then
1347                       CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]]//'`
1348                    fi])
1349
1350 #
1351 # Prepare building of estream
1352 #
1353 estream_INIT
1354
1355
1356 #
1357 # Decide what to build
1358 #
1359 if test "$have_adns" = "yes"; then
1360   AC_SUBST(GPGKEYS_KDNS, "gpg2keys_kdns$EXEEXT")
1361 fi
1362
1363
1364 missing_pth=no
1365 if test $have_ksba = no; then
1366   build_gpgsm=no
1367   build_scdaemon=no
1368 fi
1369
1370 build_agent_threaded=""
1371 if test "$build_agent" = "yes"; then
1372   if test $have_pth = no; then
1373      build_agent_threaded="(not multi-threaded)"
1374      missing_pth=yes
1375   fi
1376 fi
1377
1378 build_scdaemon_extra=""
1379 if test "$build_scdaemon" = "yes"; then
1380   tmp=""
1381   if test $have_pth = no; then
1382      build_scdaemon_extra="not multi-threaded"
1383      tmp=", "
1384      missing_pth=yes
1385   fi
1386   if test $have_libusb = no; then
1387      build_scdaemon_extra="${tmp}without internal CCID driver"
1388      tmp=", "
1389   fi
1390   if test -n "$build_scdaemon_extra"; then
1391      build_scdaemon_extra="(${build_scdaemon_extra})"
1392   fi
1393 fi
1394
1395
1396 if test "$build_agent_only" = "yes" ; then
1397   build_gpg=no
1398   build_gpgsm=no
1399   build_scdaemon=no
1400   build_tools=no
1401   build_doc=no
1402 fi
1403
1404
1405 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1406 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1407 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1408 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1409 AM_CONDITIONAL(BUILD_G13,   test "$build_g13" = "yes")
1410 AM_CONDITIONAL(BUILD_TOOLS, test "$build_tools" = "yes")
1411 AM_CONDITIONAL(BUILD_DOC,   test "$build_doc" = "yes")
1412 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1413
1414 AM_CONDITIONAL(RUN_GPG_TESTS,
1415         test x$cross_compiling = xno -a "$build_gpg" = yes )
1416
1417
1418 #
1419 # Print errors here so that they are visible all
1420 # together and the user can acquire them all together.
1421 #
1422 die=no
1423 if test "$have_gpg_error" = "no"; then
1424    die=yes
1425    AC_MSG_NOTICE([[
1426 ***  
1427 *** You need libgpg-error to build this program.
1428 **  This library is for example available at
1429 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1430 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1431 ***]])
1432 fi
1433 if test "$have_libgcrypt" = "no"; then
1434    die=yes
1435    AC_MSG_NOTICE([[
1436 ***  
1437 *** You need libgcrypt to build this program.
1438 **  This library is for example available at
1439 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1440 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API is required.)
1441 ***]])
1442 fi
1443 if test "$have_libassuan" = "no"; then
1444    die=yes
1445    AC_MSG_NOTICE([[
1446 ***
1447 *** You need libassuan to build this program.
1448 *** This library is for example available at
1449 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1450 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1451 ***]])
1452 fi
1453 if test "$have_ksba" = "no"; then
1454     AC_MSG_NOTICE([[
1455 ***
1456 *** You need libksba to build this program.
1457 *** This library is for example available at
1458 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1459 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1460 ***]])
1461 fi
1462 if test "$missing_pth" = "yes"; then
1463     AC_MSG_NOTICE([[
1464 ***
1465 *** It is now required to build with support for the
1466 *** GNU Portable Threads Library (Pth). Please install this
1467 *** library first.  The library is for example available at
1468 ***   ftp://ftp.gnu.org/gnu/pth/
1469 *** On a Debian GNU/Linux system you can install it using 
1470 ***   apt-get install libpth-dev
1471 *** To build GnuPG for Windows you need to use the W32PTH
1472 *** package; available at:
1473 ***   ftp://ftp.g10code.com/g10code/w32pth/
1474 ***]])
1475    die=yes
1476 fi
1477
1478 if test "$die" = "yes"; then
1479     AC_MSG_ERROR([[
1480 ***
1481 *** Required libraries not found. Please consult the above messages
1482 *** and install them before running configure again.
1483 ***]])
1484 fi
1485
1486
1487
1488 AC_CONFIG_FILES([ m4/Makefile 
1489 Makefile
1490 po/Makefile.in
1491 gl/Makefile
1492 include/Makefile
1493 common/Makefile
1494 kbx/Makefile
1495 g10/Makefile
1496 sm/Makefile
1497 agent/Makefile
1498 scd/Makefile
1499 g13/Makefile
1500 keyserver/Makefile
1501 keyserver/gpg2keys_mailto
1502 keyserver/gpg2keys_test
1503 tools/gpg-zip
1504 tools/Makefile
1505 doc/Makefile
1506 tests/Makefile
1507 tests/openpgp/Makefile
1508 tests/pkits/Makefile
1509 ])
1510 AC_OUTPUT
1511
1512
1513 echo "
1514         GnuPG v${VERSION} has been configured as follows:
1515         
1516         Platform:  $PRINTABLE_OS_NAME ($host)
1517
1518         OpenPGP:   $build_gpg
1519         S/MIME:    $build_gpgsm
1520         Agent:     $build_agent $build_agent_threaded
1521         Smartcard: $build_scdaemon $build_scdaemon_extra
1522         G13:       $build_g13
1523
1524
1525         Protect tool:      $show_gnupg_protect_tool_pgm
1526         Default agent:     $show_gnupg_agent_pgm
1527         Default pinentry:  $show_gnupg_pinentry_pgm
1528         Default scdaemon:  $show_gnupg_scdaemon_pgm
1529         Default dirmngr:   $show_gnupg_dirmngr_pgm
1530 "
1531 if test x"$use_regex" != xyes ; then
1532 echo "
1533         Warning: No regular expression support available.
1534                  OpenPGP trust signatures won't work.
1535                  gpg-check-pattern will not be build.
1536 "
1537 fi