* gpg.sgml: Add rebuild-keydb-caches.
[gnupg.git] / configure.ac
1 dnl Configure.ac script for GnuPG
2 dnl Copyright (C) 1998, 1999, 2000, 2001, 2002 Free Software Foundation, Inc.
3 dnl
4 dnl This file is part of GnuPG.
5 dnl
6 dnl GnuPG is free software; you can redistribute it and/or modify
7 dnl it under the terms of the GNU General Public License as published by
8 dnl the Free Software Foundation; either version 2 of the License, or
9 dnl (at your option) any later version.
10 dnl 
11 dnl GnuPG is distributed in the hope that it will be useful,
12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 dnl GNU General Public License for more details.
15 dnl 
16 dnl You should have received a copy of the GNU General Public License
17 dnl along with this program; if not, write to the Free Software
18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
19 dnl
20 dnl (Process this file with autoconf to produce a configure script.)
21 dnlAC_REVISION($Revision$)dnl
22
23 AC_PREREQ(2.52)
24
25 # Remember to change the version number immediately *after* a release.
26 # Set development_version to yes if the minor number is odd or you
27 # feel that the default check for a development version is not
28 # sufficient.
29 AC_INIT(gnupg, 1.3, bug-gnupg@gnu.org)
30 development_version=yes
31
32 ALL_LINGUAS="ca cs da de eo el es et fr gl id it ja nl pl pt_BR pt sv tr"
33
34 PACKAGE=$PACKAGE_NAME
35 VERSION=$PACKAGE_VERSION
36
37 AC_CONFIG_AUX_DIR(scripts)
38 AC_CONFIG_SRCDIR(g10/g10.c)
39 AC_CANONICAL_TARGET()
40 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
41 AM_CONFIG_HEADER(config.h)
42
43 AC_SUBST(PACKAGE)
44 AC_SUBST(VERSION)
45 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
46 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
47 AC_DEFINE(_GNU_SOURCE,1,[Some tests rely on this (stpcpy) and it should be used for new programs anyway])
48
49 dnl
50 dnl  Check for random module options
51 dnl
52 AC_MSG_CHECKING([which random module to use])
53 AC_ARG_ENABLE(static-rnd,
54     [  --enable-static-rnd=[egd|unix|linux|auto]  ],
55 [use_static_rnd=$enableval], [use_static_rnd=default] )
56
57 if test "$use_static_rnd" = no; then
58     use_static_rnd=default
59 fi
60
61 case "$use_static_rnd" in
62     egd | linux | unix | default )
63       AC_MSG_RESULT($use_static_rnd)
64       ;;
65     auto )
66       AC_MSG_RESULT(automagically selected at runtime)
67       ;;
68     * )
69       AC_MSG_RESULT(invalid argument)
70       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
71       ;;
72 esac
73
74 AC_ARG_WITH(egd-socket,
75     [  --with-egd-socket=NAME  use NAME for the EGD socket],
76             egd_socket_name="$withval", egd_socket_name="" )
77 AC_DEFINE_UNQUOTED(EGD_SOCKET_NAME, "$egd_socket_name",
78                    [Define if you don't want the default EGD socket name.
79                     For details see cipher/rndegd.c])
80
81
82 dnl
83 dnl See whether the user wants to disable checking for /dev/random
84
85 AC_MSG_CHECKING([whether use of /dev/random is requested])
86 AC_ARG_ENABLE(dev-random,
87 [  --disable-dev-random    disable the use of dev random],
88     try_dev_random=$enableval, try_dev_random=yes)
89 AC_MSG_RESULT($try_dev_random)
90
91
92 dnl
93 dnl  Check other options
94 dnl
95
96 # We don't need idea but some people claim that they need it for
97 # research etc., so we allow to place an idea source code into the
98 # cipher directory and statically link it if available, otherwise we
99 # link to a stub.  We don't use AC_CHECK_FILE to avoid caching.
100 AC_MSG_CHECKING(for extra cipher modules)
101 tmp=""
102 if test -f $srcdir/cipher/idea.c; then 
103    IDEA_O=idea.o
104    tmp=idea
105 else
106    IDEA_O=idea-stub.o
107    tmp=no
108 fi
109 AC_SUBST(IDEA_O)
110 AC_MSG_RESULT($tmp)
111
112 # if the static idea is present, disable dynload.
113 if test "$IDEA_O" = idea-stub.o ; then
114   AC_MSG_CHECKING([whether use of extensions is requested])
115   AC_ARG_ENABLE(dynload,
116   [  --disable-dynload       disable use of extensions],
117       try_dynload=$enableval, try_dynload=yes)
118   AC_MSG_RESULT($try_dynload)
119 else
120   try_dynload=no
121 fi
122
123 AC_MSG_CHECKING([whether assembler modules are requested])
124 AC_ARG_ENABLE(asm,
125 [  --disable-asm           do not use assembler modules],
126      try_asm_modules=$enableval, try_asm_modules=yes)
127 AC_MSG_RESULT($try_asm_modules)
128
129 AC_MSG_CHECKING([whether memory guard is requested])
130 AC_ARG_ENABLE(m-guard,
131     [  --enable-m-guard        enable memory guard facility],
132     use_m_guard=$enableval, use_m_guard=no)
133 AC_MSG_RESULT($use_m_guard)
134 if test "$use_m_guard" = yes ; then
135     AC_DEFINE(M_GUARD,1,[Define to use the (obsolete) malloc guarding feature])
136 fi
137
138 AC_MSG_CHECKING([whether to enable experimental TIGER digest support])
139 AC_ARG_ENABLE(tiger,
140     [  --enable-tiger          enable experimental TIGER digest support],
141     use_tiger=$enableval, use_tiger=no)
142 AC_MSG_RESULT($use_tiger)
143 if test "$use_tiger" = yes ; then
144     AC_SUBST(TIGER_O,tiger.o)
145     AC_DEFINE(USE_TIGER,1,[Define to include experimental TIGER digest support])
146 fi
147
148 AC_MSG_CHECKING([whether to enable external program execution])
149 AC_ARG_ENABLE(exec,
150     [  --disable-exec          disable all external program execution],
151     use_exec=$enableval, use_exec=yes)
152 AC_MSG_RESULT($use_exec)
153 if test "$use_exec" = no ; then
154     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
155 fi
156
157 if test "$use_exec" = yes ; then
158   AC_MSG_CHECKING([whether to enable photo ID viewing])
159   AC_ARG_ENABLE(photo-viewers,
160       [  --disable-photo-viewers disable photo ID viewers],
161       [if test "$enableval" = no ; then
162          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
163       fi],enableval=yes)
164   gnupg_cv_enable_photo_viewers=$enableval
165   AC_MSG_RESULT($enableval)
166
167   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
168     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
169     AC_ARG_WITH(photo-viewer,
170         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
171         [if test "$withval" = yes ; then
172            withval=no
173         elif test "$withval" != no ; then
174            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
175                             [if set, restrict photo-viewer to this])
176         fi],withval=no)
177     AC_MSG_RESULT($withval)
178   fi
179
180   AC_MSG_CHECKING([whether to enable external keyserver helpers])
181   AC_ARG_ENABLE(keyserver-helpers,
182       [  --disable-keyserver-helpers  disable all external keyserver support],
183       [if test "$enableval" = no ; then
184          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
185                   [define to disable keyserver helpers])
186       fi],enableval=yes)
187   gnupg_cv_enable_keyserver_helpers=$enableval
188   AC_MSG_RESULT($enableval)
189
190   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
191     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
192     AC_ARG_ENABLE(ldap,
193     [  --disable-ldap          disable LDAP keyserver interface],
194         try_ldap=$enableval, try_ldap=yes)
195     AC_MSG_RESULT($try_ldap)
196
197     AC_MSG_CHECKING([whether HKP keyserver support is requested])
198     AC_ARG_ENABLE(hkp,
199     [  --disable-hkp           disable HKP keyserver interface],
200         try_hkp=$enableval, try_hkp=yes)
201     AC_MSG_RESULT($try_hkp)
202
203     if test "$try_hkp" = yes ; then
204       AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp")
205     fi
206
207     AC_MSG_CHECKING([whether email keyserver support is requested])
208     AC_ARG_ENABLE(mailto,
209     [  --disable-mailto        disable email keyserver interface],
210         try_mailto=$enableval, try_mailto=yes)
211     AC_MSG_RESULT($try_mailto)
212     fi
213
214     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
215     AC_ARG_ENABLE(keyserver-path,
216         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
217         [if test "$enableval" = no ; then
218          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
219         fi],enableval=yes)
220     AC_MSG_RESULT($enableval)
221   fi
222
223 AC_MSG_CHECKING([whether included zlib is requested])
224 AC_ARG_WITH(included-zlib,
225     [  --with-included-zlib    use the zlib code included here],
226 [g10_force_zlib=yes], [g10_force_zlib=no] )
227 AC_MSG_RESULT($g10_force_zlib)
228
229
230 dnl
231 dnl Check whether we want to use Linux capabilities
232 dnl
233 AC_MSG_CHECKING([whether use of capabilities is requested])
234 AC_ARG_WITH(capabilities,
235     [  --with-capabilities     use linux capabilities [default=no]],
236 [use_capabilities="$withval"],[use_capabilities=no])
237 AC_MSG_RESULT($use_capabilities)
238
239
240 AH_BOTTOM([
241 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
242 #define EXEC_TEMPFILE_ONLY
243 #endif
244
245 #include "g10defs.h"
246 ])
247
248
249 AM_MAINTAINER_MODE
250
251 dnl Checks for programs.
252
253 AC_PROG_MAKE_SET
254 AM_SANITY_CHECK
255 missing_dir=`cd $ac_aux_dir && pwd`
256 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
257 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
258 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
259 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
260 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
261 AC_PROG_CC
262 AC_PROG_CPP
263 AC_PATH_PROG(PERL,"perl")
264 AC_ISC_POSIX
265 AC_SYS_LARGEFILE
266 AC_PROG_INSTALL
267 AC_PROG_AWK
268 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
269 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
270 GNUPG_CHECK_FAQPROG
271 GNUPG_CHECK_DOCBOOK_TO_TEXI
272
273 MPI_OPT_FLAGS=""
274
275
276 try_gettext=yes
277 case "${target}" in
278     *-*-mingw32*|*-*-cygwin*)
279         # special stuff for Windoze NT
280         ac_cv_have_dev_random=no
281         AC_DEFINE(USE_ONLY_8DOT3,1,
282                   [set this to limit filenames to the 8.3 format])
283         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
284                   [defined if we must run on a stupid file system])
285         AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
286                   [defined if we run on some of the PCDOS like systems 
287                    (DOS, Windoze. OS/2) with special properties like
288                     no file modes])
289         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
290                   [because the Unix gettext has too much overhead on
291                    MingW32 systems and these systems lack Posix functions,
292                    we use a simplified version of gettext])
293         try_gettext="no"
294         ;;
295     i?86-emx-os2 | i?86-*-os2*emx )
296         # OS/2 with the EMX environment
297         ac_cv_have_dev_random=no
298         AC_DEFINE(HAVE_DRIVE_LETTERS)
299         AC_DEFINE(HAVE_DOSISH_SYSTEM)
300         try_gettext="no"
301         ;;
302
303     i?86-*-msdosdjgpp*)
304         # DOS with the DJGPP environment
305         ac_cv_have_dev_random=no
306         AC_DEFINE(HAVE_DRIVE_LETTERS)
307         AC_DEFINE(HAVE_DOSISH_SYSTEM)
308         try_gettext="no"
309         ;;
310
311     *-*-freebsd*)
312        # FreeBSD
313        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
314        LDFLAGS="$LDFLAGS -L/usr/local/lib"
315        ;;
316
317     *-*-hpux*)
318         if test -z "$GCC" ; then
319             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
320         fi
321         ;;
322     *-dec-osf4*)
323         if test -z "$GCC" ; then
324             # Suppress all warnings
325             # to get rid of the unsigned/signed char mismatch warnings.
326             CFLAGS="$CFLAGS -w"
327         fi
328         ;;
329     *-dec-osf5*)
330         if test -z "$GCC" ; then
331             # Use the newer compiler `-msg_disable ptrmismatch' to
332             # get rid of the unsigned/signed char mismatch warnings.
333             # Using this may hide other pointer mismatch warnings, but
334             # it at least lets other warning classes through
335             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
336         fi
337         ;;
338     m68k-atari-mint)
339         ;;
340     *)
341        ;;
342 esac
343
344 AC_SUBST(MPI_OPT_FLAGS)
345 GNUPG_SYS_SYMBOL_UNDERSCORE
346
347 dnl Must check for network library requirements before doing link tests
348 dnl for ldap, for example. If ldap libs are static (or dynamic and without
349 dnl ELF runtime link paths), then link will fail and LDAP support won't
350 dnl be detected.
351
352 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
353         [NETLIBS="-lnsl $NETLIBS"]))
354 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
355         [NETLIBS="-lsocket $NETLIBS"]))
356
357 # Try and link a LDAP test program to weed out unusable LDAP
358 # libraries.  -lldap -llber [-lresolv] is for OpenLDAP.  -lldapssl41
359 # is for Mozilla LDAP.
360
361 if test "$try_ldap" = yes ; then
362   for LDAPLIBS in "-lldap -llber -lresolv" "-lldap -llber" "-lldapssl41"; do
363     _ldap_save_libs=$LIBS
364     LIBS="$LDAPLIBS $NETLIBS $LIBS"
365
366     AC_MSG_CHECKING([whether LDAP via \"$LDAPLIBS\" is present and sane])
367     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
368                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
369     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
370
371     if test $gnupg_cv_func_ldap_init = no; then
372       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
373       AC_TRY_LINK([#include <lber.h>
374 #include <ldap.h>],[ldap_open("foobar",1234);],
375          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
376       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
377     fi
378
379     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
380        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
381     fi
382
383     if test "$gnupg_cv_func_ldap_init" = yes || \
384         test "$gnupg_cv_func_ldaplber_init" = yes ; then
385        GPGKEYS_LDAP="gpgkeys_ldap"
386     fi
387
388     LIBS=$_ldap_save_libs
389
390     if test "$GPGKEYS_LDAP" != "" ; then break; fi
391   done
392 fi
393
394 AC_SUBST(GPGKEYS_LDAP)
395 AC_SUBST(LDAPLIBS)
396
397 dnl This isn't necessarily sendmail itself, but anything that gives a
398 dnl sendmail-ish interface to the outside world.  That includes qmail,
399 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
400
401 if test "$try_mailto" = yes ; then
402   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
403
404   if test "$with_mailprog" = yes ; then
405     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
406     if test "$ac_cv_path_SENDMAIL" ; then
407       GPGKEYS_MAILTO="gpgkeys_mailto"
408     fi
409   elif test "$with_mailprog" != no ; then
410     AC_MSG_CHECKING([for a mail transport program])
411     AC_SUBST(SENDMAIL,$with_mailprog)
412     AC_MSG_RESULT($with_mailprog)
413     GPGKEYS_MAILTO="gpgkeys_mailto"
414   fi
415 fi
416
417 AC_SUBST(GPGKEYS_MAILTO)
418
419 case "${target}" in
420     *-*-mingw32*)
421         PRINTABLE_OS_NAME="MingW32"
422         ;;
423     *-*-cygwin*)
424         PRINTABLE_OS_NAME="Cygwin32"
425         ;;
426     i?86-emx-os2 | i?86-*-os2*emx )
427         PRINTABLE_OS_NAME="OS/2"
428         ;;
429     i?86-*-msdosdjgpp*)
430         PRINTABLE_OS_NAME="MSDOS/DJGPP"
431         try_dynload=no
432         ;;
433     *-linux*)
434         PRINTABLE_OS_NAME="GNU/Linux"
435         ;;
436 dnl let that after linux to avoid gnu-linux problems
437     *-gnu*)
438         PRINTABLE_OS_NAME="GNU/Hurd"
439         ;;
440     *)
441         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
442         ;;
443 esac
444 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
445                    [A human readable text with the name of the OS])
446
447
448 #
449 # 1. Set names of random devices
450 #
451 NAME_OF_DEV_RANDOM="/dev/random"
452 NAME_OF_DEV_URANDOM="/dev/urandom"
453 case "${target}" in
454     *-openbsd* | *-netbsd*)
455         NAME_OF_DEV_RANDOM="/dev/srandom"
456         NAME_OF_DEV_URANDOM="/dev/urandom"
457         ;;
458 esac
459 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM",
460                    [defined to the name of the strong random device])
461 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM",
462                    [defined to the name of the weaker random device])
463 AC_SUBST(MPI_OPT_FLAGS)
464
465
466 dnl Checks for libraries.
467
468 if test "$try_gettext" = yes; then
469   AM_GNU_GETTEXT
470 else
471   USE_NLS=no
472   USE_INCLUDED_LIBINTL=no
473   BUILD_INCLUDED_LIBINTL=no
474   AC_SUBST(USE_NLS)
475   AC_SUBST(USE_INCLUDED_LIBINTL)
476   AC_SUBST(BUILD_INCLUDED_LIBINTL)
477 fi
478
479
480 if test "$try_dynload" = yes ; then
481   AC_CHECK_LIB(dl,dlopen)
482   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
483     AC_DEFINE(USE_DYNAMIC_LINKING,1,
484               [define to enable the use of extensions])
485     AC_DEFINE(HAVE_DL_DLOPEN,1,
486               [Defined when the dlopen function family is available])
487   else
488     AC_CHECK_FUNCS(dlopen)
489     if test "$ac_cv_func_dlopen" = "yes"; then
490       AC_DEFINE(USE_DYNAMIC_LINKING)
491       AC_DEFINE(HAVE_DL_DLOPEN)
492     fi
493   fi
494 else
495   AC_MSG_CHECKING(for dynamic loading)
496   DYNLINK_LDFLAGS=
497   DYNLINK_MOD_CFLAGS=
498   AC_MSG_RESULT(has been disabled)
499 fi
500
501 dnl Checks for header files.
502 AC_HEADER_STDC
503 AC_CHECK_HEADERS(unistd.h langinfo.h termio.h locale.h)
504
505 dnl Checks for typedefs, structures, and compiler characteristics.
506 AC_C_CONST
507 AC_C_INLINE
508 AC_TYPE_SIZE_T
509 AC_TYPE_MODE_T
510 AC_TYPE_SIGNAL
511 AC_DECL_SYS_SIGLIST
512
513 GNUPG_CHECK_ENDIAN
514
515
516 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
517 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
518 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
519 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
520 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
521
522 AC_CHECK_SIZEOF(unsigned short, 2)
523 AC_CHECK_SIZEOF(unsigned int, 4)
524 AC_CHECK_SIZEOF(unsigned long, 4)
525 AC_CHECK_SIZEOF(unsigned long long, 0)
526
527 if test "$ac_cv_sizeof_unsigned_short" = "0" \
528    || test "$ac_cv_sizeof_unsigned_int" = "0" \
529    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
530     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
531 fi
532
533 dnl Checks for library functions.
534 AC_FUNC_FSEEKO
535 AC_FUNC_VPRINTF
536 AC_FUNC_FORK
537 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
538 AC_CHECK_FUNCS(strcasecmp strncasecmp)
539 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
540 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
541 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat)
542 AC_REPLACE_FUNCS(mkdtemp)
543
544 #
545 # check for gethrtime and run a testprogram to see whether
546 # it is broken.  It has been reported that some Solaris and HP UX systems 
547 # raise an SIGILL
548 #
549 AC_CACHE_CHECK([for gethrtime], 
550                [gnupg_cv_func_gethrtime],
551                [AC_TRY_LINK([#include <sys/times.h>],[
552                    hrtime_t tv;
553                    tv = gethrtime();
554                  ],
555                  [gnupg_cv_func_gethrtime=yes],
556                  [gnupg_cv_func_gethrtime=no])
557                ])
558 if test $gnupg_cv_func_gethrtime = yes; then
559      AC_DEFINE([HAVE_GETHRTIME], 1,
560                [Define if you have the `gethrtime(2)' function.])
561      AC_CACHE_CHECK([whether gethrtime is broken], 
562                [gnupg_cv_func_broken_gethrtime],
563                [AC_TRY_RUN([
564                    #include <sys/times.h>
565                    int main () {
566                    hrtime_t tv;
567                    tv = gethrtime(); 
568                  }
569                  ],
570                  [gnupg_cv_func_broken_gethrtime=no],
571                  [gnupg_cv_func_broken_gethrtime=yes],
572                  [gnupg_cv_func_broken_gethrtime=assume-no])
573                 ])
574     if test $gnupg_cv_func_broken_gethrtime = yes; then
575       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
576       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
577     fi
578 fi
579      
580
581 GNUPG_CHECK_MLOCK
582 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
583
584 dnl
585 dnl Check whether we can use Linux capabilities as requested
586 dnl
587 if test "$use_capabilities" = "yes" ; then
588 use_capabilities=no
589 AC_CHECK_HEADERS(sys/capability.h)
590 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
591   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
592   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
593      AC_DEFINE(USE_CAPABILITIES,1,
594                [define if capabilities should be used])
595      LIBS="$LIBS -lcap"
596      use_capabilities=yes
597   fi
598 fi
599 if test "$use_capabilities" = "no" ; then
600     AC_MSG_WARN([[
601 ***
602 *** The use of capabilities on this system is not possible.
603 *** You need a recent Linux kernel and some patches:
604 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
605 ***   fcap-module-990613.tar.gz     (kernel module)
606 ***   libcap-1.92.tar.gz            (user mode library and utilities)
607 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
608 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
609 ***]])
610 fi
611 fi
612
613
614 GNUPG_CHECK_IPC
615 if test "$ac_cv_header_sys_shm_h" = "yes"; then
616   AC_DEFINE(USE_SHM_COPROCESSING,1,
617             [define if the shared memory interface should be made available])
618 fi
619
620 dnl
621 dnl check whether we have a random device
622 dnl
623 if test "$try_dev_random" = yes ; then
624     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
625     [if test -r "$NAME_OF_DEV_RANDOM" && test -r "$NAME_OF_DEV_URANDOM" ; then
626       ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
627     if test "$ac_cv_have_dev_random" = yes; then
628         AC_DEFINE(HAVE_DEV_RANDOM,1,
629                  [defined if the system supports a random device] )
630     fi
631 else
632     AC_MSG_CHECKING(for random device)
633     ac_cv_have_dev_random=no
634     AC_MSG_RESULT(has been disabled)
635 fi
636
637
638 dnl
639 dnl Figure out the default random module.
640 dnl
641 random_modules=""
642 if test "$use_static_rnd" = default; then
643      if test "$ac_cv_have_dev_random" = yes; then
644         random_modules="rndlinux"
645      else
646          case "${target}" in
647             *-*-mingw32*|*-*-cygwin*)
648                 random_modules="rndw32"
649                 ;;
650             i?86-emx-os2|i?86-*-os2*emx)
651                 random_modules="rndos2"
652                 ;;
653             m68k-atari-mint)
654                 random_modules="rndatari"
655                 ;;
656             i?86-*-msdosdjgpp*)
657                 :
658                 ;;
659             *)
660                 random_modules="rndlinux rndegd rndunix"
661                 AC_DEFINE(USE_ALL_RANDOM_MODULES, 1, 
662                           [Allow to select random modules at runtime.])
663                 ;;
664          esac
665      fi
666 else
667   if test "$use_static_rnd" = auto; then
668      random_modules="rndlinux rndegd rndunix"
669      AC_DEFINE(USE_ALL_RANDOM_MODULES, 1)
670   else
671      random_modules="rnd$use_static_rnd";
672   fi
673 fi
674
675 if test -z "$random_modules"; then
676    AC_MSG_ERROR(no random module available)
677 fi
678 print_egd_warning=no
679 for rndmod in $random_modules "" ; do
680   case "$rndmod" in
681     rndlinux)
682          AC_DEFINE(USE_RNDLINUX,1, 
683                   [Defined if the /dev/random based RNG should be used.])
684          ;;
685     rndunix)
686          AC_DEFINE(USE_RNDUNIX,1, 
687                   [Defined if the default Unix RNG should be used.])
688          print_egd_warning=yes
689           ;;
690     rndegd)
691          AC_DEFINE(USE_RNDEGD,1, 
692                   [Defined if the EGD based RNG should be used.])
693          ;;
694     rndw32)
695          AC_DEFINE(USE_RNDW32,1, 
696                   [Defined if the Windows specific RNG should be used.])
697         ;;
698    esac
699 done
700
701 dnl setup assembler stuff
702 AC_MSG_CHECKING(for mpi assembler functions)
703 if test -f $srcdir/mpi/config.links ; then
704     . $srcdir/mpi/config.links
705     AC_CONFIG_LINKS("$mpi_ln_list")
706     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
707     ac_cv_mpi_sflags="$mpi_sflags"
708     ac_cv_mpi_config_done="yes"
709     AC_MSG_RESULT(done)
710 else
711     AC_MSG_RESULT(failed)
712     AC_MSG_ERROR([mpi/config.links missing!])
713 fi
714 MPI_EXTRA_ASM_OBJS=""
715 show_extraasm=""
716 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
717 for i in $ac_cv_mpi_extra_asm_modules; do
718     show_extraasm="$show_extraasm $i"
719     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
720 done
721 fi
722 AC_SUBST(MPI_EXTRA_ASM_OBJS)
723 MPI_SFLAGS="$ac_cv_mpi_sflags"
724 AC_SUBST(MPI_SFLAGS)
725
726 dnl Do we have zlib? Must do it here because Solaris failed
727 dnl when compiling a conftest (due to the "-lz" from LIBS).
728 use_local_zlib=yes
729 if test "$g10_force_zlib" = "yes"; then
730   :
731 else
732   _cppflags="${CPPFLAGS}"
733   _ldflags="${LDFLAGS}"
734
735   AC_ARG_WITH(zlib,
736   [  --with-zlib=DIR         use libz in DIR],[
737     if test -d "$withval"; then
738       CPPFLAGS="${CPPFLAGS} -I$withval/include"
739       LDFLAGS="${LDFLAGS} -L$withval/lib"
740     fi
741   ])
742
743   AC_CHECK_HEADER(zlib.h,
744       AC_CHECK_LIB(z, deflateInit2_,
745        use_local_zlib=no
746        LIBS="$LIBS -lz",
747        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
748        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
749 fi
750  
751 if test "$use_local_zlib" = yes ; then
752     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
753     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
754     ZLIBS="../zlib/libzlib.a"
755 else
756     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
757     ZLIBS=
758 fi
759 AC_SUBST(ZLIBS)
760
761
762 # Allow users to append something to the version string without
763 # flagging it as development version.  The user version parts is
764 # considered everything after a dash. 
765 if test "$development_version" != yes; then
766   changequote(,)dnl
767   tmp_pat='[a-zA-Z]'
768   changequote([,])dnl
769   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
770     development_version=yes
771   fi
772 fi
773 if test "$development_version" = yes; then
774     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
775             [Defined if this is not a regular release])
776 fi
777
778 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
779
780 GNUPG_CHECK_GNUMAKE
781
782 # add some extra libs here so that previous tests don't fail for
783 # mysterious reasons - the final link step should bail out. 
784 case "${target}" in
785     *-*-mingw32*)
786         LIBS="$LIBS -lwsock32"
787         ;;
788     *)
789        ;;
790 esac
791
792
793 if test "$GCC" = yes; then
794     if test "$USE_MAINTAINER_MODE" = "yes"; then
795         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
796     else
797         CFLAGS="$CFLAGS -Wall"
798     fi
799 fi
800
801 AC_SUBST(NETLIBS)
802
803
804 if test "$print_egd_warning" = yes; then
805   AC_MSG_WARN([[
806 ***
807 *** The performance of the UNIX random gatherer module is not very good
808 *** and it does not keep the entropy pool over multiple invocations of
809 *** GnuPG.  The suggested way to overcome this problem is to use the
810 ***
811 ***               Entropy Gathering Daemon (EGD)
812 ***
813 *** which provides a entropy source for the whole system.  It is written
814 *** in Perl and available at the GnuPG FTP servers.  For more information
815 *** consult the GnuPG webpages:
816 ***
817 ***           http://www.gnupg.org/download.html#egd
818 ***
819 *** You may want to run ./configure with --enable-static-rnd=egd to use it.
820 ***]])
821 fi
822
823
824
825 # Note the \\\\ for backslashes.  Autoconf eats one layer, leaving \\
826
827 AC_SUBST(GNUPG_LIBEXECDIR,"${libexecdir}/gnupg")
828
829 AC_CONFIG_COMMANDS(g10defs.h,[[
830 cat >g10defs.tmp <<G10EOF
831 /* Generated automatically by configure */
832 #ifdef HAVE_DRIVE_LETTERS
833   #define G10_LOCALEDIR     "c:\\\\lib\\\\gnupg\\\\locale"
834   #define GNUPG_LIBDIR      "c:\\\\lib\\\\gnupg"
835   #define GNUPG_LIBEXECDIR  "c:\\\\lib\\\\gnupg"
836   #define GNUPG_DATADIR     "c:\\\\lib\\\\gnupg"
837   #define GNUPG_HOMEDIR     "c:\\\\gnupg"
838 #else
839   #define G10_LOCALEDIR     "${datadir}/locale"
840   #define GNUPG_LIBDIR      "${libdir}/gnupg"
841   #define GNUPG_LIBEXECDIR  "${libexecdir}/gnupg"
842   #define GNUPG_DATADIR     "${datadir}/gnupg"
843   #ifdef __VMS
844     #define GNUPG_HOMEDIR "/SYS\$LOGIN/gnupg" 
845   #else
846     #define GNUPG_HOMEDIR "~/.gnupg" 
847   #endif
848 #endif
849 /* those are here to be redefined by handcrafted g10defs.h.
850    Please note that the string version must not contain more
851    than one character because the using code assumes strlen()==1 */
852 #ifdef HAVE_DOSISH_SYSTEM
853 #define DIRSEP_C '\\\\'
854 #define EXTSEP_C '.'
855 #define DIRSEP_S "\\\\"
856 #define EXTSEP_S "."
857 #else
858 #define DIRSEP_C '/'
859 #define EXTSEP_C '.'
860 #define DIRSEP_S "/"
861 #define EXTSEP_S "."
862 #endif
863 G10EOF
864 cat mpi/mpi-asm-defs.h >>g10defs.tmp 
865 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
866     echo "g10defs.h is unchanged"
867     rm -f g10defs.tmp
868 else
869     rm -f g10defs.h
870     mv g10defs.tmp g10defs.h
871     echo "g10defs.h created"
872 fi
873 ]],[[
874 prefix=$prefix
875 exec_prefix=$exec_prefix
876 libdir=$libdir
877 libexecdir=$libexecdir
878 datadir=$datadir
879 DATADIRNAME=$DATADIRNAME
880 ]])
881
882
883 AC_CONFIG_FILES([
884 Makefile
885 intl/Makefile
886 po/Makefile.in
887 util/Makefile
888 mpi/Makefile
889 cipher/Makefile
890 g10/Makefile
891 keyserver/Makefile
892 keyserver/gpgkeys_mailto
893 keyserver/gpgkeys_test
894 doc/Makefile
895 tools/Makefile
896 zlib/Makefile
897 checks/Makefile
898 ])
899 AC_OUTPUT
900
901 # Give some feedback
902 echo
903 echo   "                Configured for: $PRINTABLE_OS_NAME ($target)"
904 if test -n "$show_extraasm"; then
905   echo "  Extra cpu specific functions:$show_extraasm"
906 fi
907 echo