60e4e4651d996f5f8f9750befc8e83be87deb5e9
[gnupg.git] / configure.ac
1 dnl Configure.ac script for GnuPG
2 dnl Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003
3 dnl               2004 Free Software Foundation, Inc.
4 dnl
5 dnl This file is part of GnuPG.
6 dnl
7 dnl GnuPG is free software; you can redistribute it and/or modify
8 dnl it under the terms of the GNU General Public License as published by
9 dnl the Free Software Foundation; either version 2 of the License, or
10 dnl (at your option) any later version.
11 dnl 
12 dnl GnuPG is distributed in the hope that it will be useful,
13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 dnl GNU General Public License for more details.
16 dnl 
17 dnl You should have received a copy of the GNU General Public License
18 dnl along with this program; if not, write to the Free Software
19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20 dnl
21 dnl (Process this file with autoconf to produce a configure script.)
22 dnlAC_REVISION($Revision$)dnl
23
24 AC_PREREQ(2.57)
25
26 # Remember to change the version number immediately *after* a release
27 # and remove the "-cvs" or "rc" suffix immediately *before* a release.
28 AC_INIT(gnupg, 1.3.5-cvs, bug-gnupg@gnu.org)
29 # Set development_version to yes if the minor number is odd or you
30 # feel that the default check for a development version is not
31 # sufficient.
32 development_version=yes
33
34 AC_CONFIG_AUX_DIR(scripts)
35 AC_CONFIG_SRCDIR(g10/g10.c)
36 AC_CANONICAL_TARGET
37 AM_INIT_AUTOMAKE
38 AM_CONFIG_HEADER(config.h)
39
40 AC_GNU_SOURCE
41
42 dnl
43 dnl  Check for random module options
44 dnl
45 AC_MSG_CHECKING([which random module to use])
46 AC_ARG_ENABLE(static-rnd,
47     [  --enable-static-rnd=[egd|unix|linux|auto]  ],
48 [use_static_rnd=$enableval], [use_static_rnd=default] )
49
50 if test "$use_static_rnd" = no; then
51     use_static_rnd=default
52 fi
53
54 case "$use_static_rnd" in
55     egd | linux | unix | default )
56       AC_MSG_RESULT($use_static_rnd)
57       ;;
58     auto )
59       AC_MSG_RESULT(automagically selected at runtime)
60       ;;
61     * )
62       AC_MSG_RESULT(invalid argument)
63       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
64       ;;
65 esac
66
67 AC_ARG_WITH(egd-socket,
68     [  --with-egd-socket=NAME  use NAME for the EGD socket],
69             egd_socket_name="$withval", egd_socket_name="" )
70 AC_DEFINE_UNQUOTED(EGD_SOCKET_NAME, "$egd_socket_name",
71                    [Define if you don't want the default EGD socket name.
72                     For details see cipher/rndegd.c])
73
74
75 dnl
76 dnl See whether the user wants to disable checking for /dev/random
77
78 AC_MSG_CHECKING([whether use of /dev/random is requested])
79 AC_ARG_ENABLE(dev-random,
80 [  --disable-dev-random    disable the use of dev random],
81     try_dev_random=$enableval, try_dev_random=yes)
82 AC_MSG_RESULT($try_dev_random)
83
84
85 dnl
86 dnl  Check other options
87 dnl
88
89 AC_MSG_CHECKING([whether assembler modules are requested])
90 AC_ARG_ENABLE(asm,
91 [  --disable-asm           do not use assembler modules],
92      try_asm_modules=$enableval, try_asm_modules=yes)
93 AC_MSG_RESULT($try_asm_modules)
94
95 AC_MSG_CHECKING([whether memory guard is requested])
96 AC_ARG_ENABLE(m-guard,
97     [  --enable-m-guard        enable memory guard facility],
98     use_m_guard=$enableval, use_m_guard=no)
99 AC_MSG_RESULT($use_m_guard)
100 if test "$use_m_guard" = yes ; then
101     AC_DEFINE(M_GUARD,1,[Define to use the (obsolete) malloc guarding feature])
102 fi
103
104 AC_MSG_CHECKING([whether OpenPGP card support is requested])
105 AC_ARG_ENABLE(card-support,
106     [  --enable-card-support   enable OpenPGP card support],
107     card_support=$enableval, card_support=no)
108 AC_MSG_RESULT($card_support)
109
110 dnl See if we are disabling any algorithms or features for a smaller
111 dnl binary
112
113 try_extensions=no
114
115 use_rsa=yes
116 use_idea=yes
117 use_cast5=yes
118 use_blowfish=yes
119 use_aes=yes
120 use_twofish=yes
121 use_sha256=yes
122 use_sha512=yes
123 use_bzip2=yes
124 use_exec=yes
125
126 AC_ARG_ENABLE(minimal,
127    AC_HELP_STRING([--enable-minimal],[build the smallest gpg binary possible]),
128    use_rsa=no
129    use_idea=no
130    use_cast5=no
131    use_blowfish=no
132    use_aes=no
133    use_twofish=no
134    use_sha256=no
135    use_sha512=no
136    use_bzip2=no
137    use_exec=no)
138
139 AC_MSG_CHECKING([whether to enable the RSA public key algorithm])
140 AC_ARG_ENABLE(rsa,
141    AC_HELP_STRING([--disable-rsa],[disable the RSA public key algorithm]),
142    use_rsa=$enableval)
143 AC_MSG_RESULT($use_rsa)
144 if test x"$use_rsa" = xyes ; then
145    AC_DEFINE(USE_RSA,1,[Define to include the RSA public key algorithm])
146 fi
147
148 AC_MSG_CHECKING([whether to enable the IDEA cipher])
149 AC_ARG_ENABLE(idea,
150    AC_HELP_STRING([--disable-idea],[disable the IDEA cipher]),
151    use_idea=$enableval)
152 AC_MSG_RESULT($use_idea)
153 if test x"$use_idea" = xyes ; then
154    AC_DEFINE(USE_IDEA,1,[Define to include the IDEA cipher])
155
156 # We don't need idea but some people claim that they need it for
157 # research etc., so we allow to place an idea source code into the
158 # cipher directory and statically link it if available, otherwise we
159 # link to a stub.  We don't use AC_CHECK_FILE to avoid caching.
160
161    AC_MSG_CHECKING([for idea cipher module])
162    tmp=""
163    if test -f $srcdir/cipher/idea.c; then 
164       IDEA_O=idea.o
165       tmp=idea
166    else
167       IDEA_O=idea-stub.o
168       tmp=no
169       try_extensions=yes
170    fi
171    AC_SUBST(IDEA_O)
172    AC_MSG_RESULT($tmp)
173 fi
174
175 AC_MSG_CHECKING([whether to enable the CAST5 cipher])
176 AC_ARG_ENABLE(cast5,
177    AC_HELP_STRING([--disable-cast5],[disable the CAST5 cipher]),
178    use_cast5=$enableval)
179 AC_MSG_RESULT($use_cast5)
180 if test x"$use_cast5" = xyes ; then
181    AC_DEFINE(USE_CAST5,1,[Define to include the CAST5 cipher])
182 fi
183
184 AC_MSG_CHECKING([whether to enable the BLOWFISH cipher])
185 AC_ARG_ENABLE(blowfish,
186    AC_HELP_STRING([--disable-blowfish],[disable the BLOWFISH cipher]),
187    use_blowfish=$enableval)
188 AC_MSG_RESULT($use_blowfish)
189 if test x"$use_blowfish" = xyes ; then
190    AC_DEFINE(USE_BLOWFISH,1,[Define to include the BLOWFISH cipher])
191 fi
192
193 AC_MSG_CHECKING([whether to enable the AES ciphers])
194 AC_ARG_ENABLE(aes,
195    AC_HELP_STRING([--disable-aes],[disable the AES, AES192, and AES256 ciphers]),
196    use_aes=$enableval)
197 AC_MSG_RESULT($use_aes)
198 if test x"$use_aes" = xyes ; then
199    AC_DEFINE(USE_AES,1,[Define to include the AES, AES192, and AES256 ciphers])
200 fi
201
202 AC_MSG_CHECKING([whether to enable the TWOFISH cipher])
203 AC_ARG_ENABLE(twofish,
204    AC_HELP_STRING([--disable-twofish],[disable the TWOFISH cipher]),
205    use_twofish=$enableval)
206 AC_MSG_RESULT($use_twofish)
207 if test x"$use_twofish" = xyes ; then
208    AC_DEFINE(USE_TWOFISH,1,[Define to include the TWOFISH cipher])
209 fi
210
211 AC_MSG_CHECKING([whether to enable the SHA-256 digest])
212 AC_ARG_ENABLE(sha256,
213    AC_HELP_STRING([--disable-sha256],[disable the SHA-256 digest]),
214    use_sha256=$enableval)
215 AC_MSG_RESULT($use_sha256)
216 if test x"$use_sha256" = xyes ; then
217    AC_DEFINE(USE_SHA256,1,[Define to include the SHA-256 digest])
218 fi
219
220 dnl SHA512 is defined only after we confirm 64-bit support later
221 AC_MSG_CHECKING([whether to enable the SHA-384 and SHA-512 digests])
222 AC_ARG_ENABLE(sha512,
223    AC_HELP_STRING([--disable-sha512],[disable the SHA-384 and SHA-512 digests]),
224    use_sha512=$enableval)
225 AC_MSG_RESULT($use_sha512)
226
227 dnl BZLIB is defined only after we confirm the library is available later
228 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
229 AC_ARG_ENABLE(bzip2,
230    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
231    use_bzip2=$enableval)
232 AC_MSG_RESULT($use_bzip2)
233
234 AC_MSG_CHECKING([whether to enable external program execution])
235 AC_ARG_ENABLE(exec,
236     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
237     use_exec=$enableval)
238 AC_MSG_RESULT($use_exec)
239 if test "$use_exec" = no ; then
240     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
241 fi
242
243 if test "$use_exec" = yes ; then
244   AC_MSG_CHECKING([whether to enable photo ID viewing])
245   AC_ARG_ENABLE(photo-viewers,
246       [  --disable-photo-viewers disable photo ID viewers],
247       [if test "$enableval" = no ; then
248          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
249       fi],enableval=yes)
250   gnupg_cv_enable_photo_viewers=$enableval
251   AC_MSG_RESULT($enableval)
252
253   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
254     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
255     AC_ARG_WITH(photo-viewer,
256         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
257         [if test "$withval" = yes ; then
258            withval=no
259         elif test "$withval" != no ; then
260            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
261                             [if set, restrict photo-viewer to this])
262         fi],withval=no)
263     AC_MSG_RESULT($withval)
264   fi
265
266   AC_MSG_CHECKING([whether to enable external keyserver helpers])
267   AC_ARG_ENABLE(keyserver-helpers,
268       [  --disable-keyserver-helpers  disable all external keyserver support],
269       [if test "$enableval" = no ; then
270          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
271                   [define to disable keyserver helpers])
272       fi],enableval=yes)
273   gnupg_cv_enable_keyserver_helpers=$enableval
274   AC_MSG_RESULT($enableval)
275
276   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
277     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
278     AC_ARG_ENABLE(ldap,
279     [  --disable-ldap          disable LDAP keyserver interface],
280         try_ldap=$enableval, try_ldap=yes)
281     AC_MSG_RESULT($try_ldap)
282
283     AC_MSG_CHECKING([whether HKP keyserver support is requested])
284     AC_ARG_ENABLE(hkp,
285     [  --disable-hkp           disable HKP keyserver interface],
286         try_hkp=$enableval, try_hkp=yes)
287     AC_MSG_RESULT($try_hkp)
288
289     AC_MSG_CHECKING([whether email keyserver support is requested])
290     AC_ARG_ENABLE(mailto,
291     [  --disable-mailto        disable email keyserver interface],
292         try_mailto=$enableval, try_mailto=yes)
293     AC_MSG_RESULT($try_mailto)
294     fi
295
296     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
297     AC_ARG_ENABLE(keyserver-path,
298         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
299         [if test "$enableval" = no ; then
300          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
301         fi],enableval=yes)
302     AC_MSG_RESULT($enableval)
303   fi
304
305 AC_MSG_CHECKING([whether the included zlib is requested])
306 AC_ARG_WITH(included-zlib,
307     [  --with-included-zlib    use the zlib code included here],
308 [g10_force_zlib=yes], [g10_force_zlib=no] )
309 AC_MSG_RESULT($g10_force_zlib)
310
311 dnl
312 dnl Check for the key/uid cache size.  This can't be zero, but can be
313 dnl pretty small on embedded systems.
314 dnl
315 AC_MSG_CHECKING([for the size of the key and uid cache])
316 AC_ARG_ENABLE(key-cache,
317         AC_HELP_STRING([--enable-key-cache=SIZE],[Set key cache to SIZE (default 4096)]),,enableval=4096)
318
319 if test "$enableval" = "no"; then
320    enableval=5
321 elif test "$enableval" = "yes" || test "$enableval" = ""; then
322    enableval=4096
323 fi
324
325 changequote(,)dnl
326 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
327 changequote([,])dnl
328
329 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
330    AC_MSG_ERROR([invalid key-cache size])
331 fi
332
333 AC_MSG_RESULT($key_cache_size)
334 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,[Size of the key and UID caches])
335
336 dnl
337 dnl Check whether we want to use Linux capabilities
338 dnl
339 AC_MSG_CHECKING([whether use of capabilities is requested])
340 AC_ARG_WITH(capabilities,
341     [  --with-capabilities     use linux capabilities [default=no]],
342 [use_capabilities="$withval"],[use_capabilities=no])
343 AC_MSG_RESULT($use_capabilities)
344
345
346 AH_BOTTOM([
347 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
348 #define EXEC_TEMPFILE_ONLY
349 #endif
350
351 /* This is the major version number of GnuPG so that
352    source included files can test for this. */
353 #define GNUPG_MAJOR_VERSION 1
354
355 #include "g10defs.h"
356 ])
357
358
359 AM_MAINTAINER_MODE
360
361 dnl Checks for programs.
362
363 AC_PROG_MAKE_SET
364 AM_SANITY_CHECK
365 missing_dir=`cd $ac_aux_dir && pwd`
366 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
367 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
368 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
369 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
370 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
371 AC_PROG_CC
372 AC_PROG_CPP
373 AC_PROG_RANLIB
374 AC_CHECK_TOOL(AR, ar, :)
375 AC_PATH_PROG(PERL,"perl")
376 AC_ISC_POSIX
377 AC_SYS_LARGEFILE
378 AC_PROG_INSTALL
379 AC_PROG_AWK
380 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
381 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
382 GNUPG_CHECK_FAQPROG
383 GNUPG_CHECK_DOCBOOK_TO_TEXI
384
385 MPI_OPT_FLAGS=""
386
387
388 try_gettext=yes
389 have_dosish_system=no
390 need_dlopen=yes
391 case "${target}" in
392     *-*-mingw32*)
393         # special stuff for Windoze NT
394         ac_cv_have_dev_random=no
395         AC_DEFINE(USE_ONLY_8DOT3,1,
396                   [set this to limit filenames to the 8.3 format])
397         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
398                   [defined if we must run on a stupid file system])
399         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
400                   [because the Unix gettext has too much overhead on
401                    MingW32 systems and these systems lack Posix functions,
402                    we use a simplified version of gettext])
403         have_dosish_system=yes
404         need_dlopen=no
405         try_gettext="no"
406         ;;
407     i?86-emx-os2 | i?86-*-os2*emx )
408         # OS/2 with the EMX environment
409         ac_cv_have_dev_random=no
410         AC_DEFINE(HAVE_DRIVE_LETTERS)
411         have_dosish_system=yes
412         try_gettext="no"
413         ;;
414
415     i?86-*-msdosdjgpp*)
416         # DOS with the DJGPP environment
417         ac_cv_have_dev_random=no
418         AC_DEFINE(HAVE_DRIVE_LETTERS)
419         have_dosish_system=yes
420         try_gettext="no"
421         ;;
422
423     *-*-freebsd*)
424        # FreeBSD
425        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
426        LDFLAGS="$LDFLAGS -L/usr/local/lib"
427        ;;
428
429     *-*-hpux*)
430         if test -z "$GCC" ; then
431             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
432         fi
433         ;;
434     *-dec-osf4*)
435         if test -z "$GCC" ; then
436             # Suppress all warnings
437             # to get rid of the unsigned/signed char mismatch warnings.
438             CFLAGS="$CFLAGS -w"
439         fi
440         ;;
441     *-dec-osf5*)
442         if test -z "$GCC" ; then
443             # Use the newer compiler `-msg_disable ptrmismatch' to
444             # get rid of the unsigned/signed char mismatch warnings.
445             # Using this may hide other pointer mismatch warnings, but
446             # it at least lets other warning classes through
447             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
448         fi
449         ;;
450     m68k-atari-mint)
451         ;;
452     *)
453        ;;
454 esac
455
456 if test "$have_dosish_system" = yes; then
457    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
458              [defined if we run on some of the PCDOS like systems 
459               (DOS, Windoze. OS/2) with special properties like
460               no file modes])
461 fi
462 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
463
464 AC_SUBST(MPI_OPT_FLAGS)
465 GNUPG_SYS_SYMBOL_UNDERSCORE
466
467 dnl This needs to go after AC_PROG_CC so that $EXEEXT is defined
468 if test "$try_hkp" = yes ; then
469   AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
470 fi
471
472 dnl Must check for network library requirements before doing link tests
473 dnl for ldap, for example. If ldap libs are static (or dynamic and without
474 dnl ELF runtime link paths), then link will fail and LDAP support won't
475 dnl be detected.
476
477 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
478         [NETLIBS="-lnsl $NETLIBS"]))
479 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
480         [NETLIBS="-lsocket $NETLIBS"]))
481
482 dnl Now try for the resolver functions so we can use DNS SRV
483
484 AC_ARG_ENABLE(dns-srv,
485    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
486    use_dns_srv=$enableval,use_dns_srv=yes)
487
488 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
489   _srv_save_libs=$LIBS
490   LIBS=""
491   # the double underscore thing is a glibc-ism?
492   AC_SEARCH_LIBS(res_query,resolv bind,,
493                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
494   AC_SEARCH_LIBS(dn_expand,resolv bind,,
495                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
496   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
497                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
498
499   if test x"$use_dns_srv" = xyes ; then
500
501     # Make sure that the BIND 4 resolver interface is workable before
502     # enabling SRVs.  At some point I'll rewrite the code to use the
503     # BIND 8 resolver API.
504
505     AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
506 #include <netinet/in.h>
507 #include <arpa/nameser.h>
508 #include <resolv.h>],
509 [[unsigned char answer[PACKETSZ]; res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);]])],,use_dns_srv=no)
510   fi
511
512   if test x"$use_dns_srv" = xyes ; then
513      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
514      SRVLIBS=$LIBS
515   else
516      AC_MSG_NOTICE([Resolver functions not found or not usable.  Disabling DNS SRV.])
517   fi
518   LIBS=$_srv_save_libs
519 fi
520
521 AC_SUBST(SRVLIBS)
522
523 # Try and link a LDAP test program to weed out unusable LDAP
524 # libraries.  -lldap [-llber [-lresolv]] is for older OpenLDAPs.
525 # OpenLDAP, circa 1999, was terrible with creating weird dependencies.
526 # This seems to have all been resolved, so I'm simplifying this code
527 # significantly.  If all else fails, the user can play
528 # guess-the-dependency by using something like ./configure
529 # LDAPLIBS="-Lfoo -lbar"
530
531 if test "$try_ldap" = yes ; then
532   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
533     _ldap_save_libs=$LIBS
534     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
535
536     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
537     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
538                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
539     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
540
541     if test "$gnupg_cv_func_ldap_init" = yes ; then
542        LDAPLIBS=$MY_LDAPLIBS
543        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
544
545        AC_CHECK_FUNCS(ldap_get_option ldap_set_option ldap_start_tls_s)
546
547        if test "$ac_cv_func_ldap_get_option" != yes ; then
548           AC_MSG_CHECKING([whether LDAP supports ld_errno])
549           AC_TRY_LINK([#include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
550              [gnupg_cv_func_ldap_ld_errno=yes],
551              [gnupg_cv_func_ldap_ld_errno=no])
552           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
553
554           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
555              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
556           fi
557        fi
558     fi
559
560     LIBS=$_ldap_save_libs
561
562     if test "$GPGKEYS_LDAP" != "" ; then break; fi
563   done
564 fi
565
566 AC_SUBST(GPGKEYS_LDAP)
567 AC_SUBST(LDAPLIBS)
568
569 dnl This isn't necessarily sendmail itself, but anything that gives a
570 dnl sendmail-ish interface to the outside world.  That includes qmail,
571 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
572
573 if test "$try_mailto" = yes ; then
574   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
575
576   if test "$with_mailprog" = yes ; then
577     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
578     if test "$ac_cv_path_SENDMAIL" ; then
579       GPGKEYS_MAILTO="gpgkeys_mailto"
580     fi
581   elif test "$with_mailprog" != no ; then
582     AC_MSG_CHECKING([for a mail transport program])
583     AC_SUBST(SENDMAIL,$with_mailprog)
584     AC_MSG_RESULT($with_mailprog)
585     GPGKEYS_MAILTO="gpgkeys_mailto"
586   fi
587 fi
588
589 AC_SUBST(GPGKEYS_MAILTO)
590
591 case "${target}" in
592     *-*-mingw32*)
593         PRINTABLE_OS_NAME="MingW32"
594         ;;
595     *-*-cygwin*)
596         PRINTABLE_OS_NAME="Cygwin"
597         ;;
598     i?86-emx-os2 | i?86-*-os2*emx )
599         PRINTABLE_OS_NAME="OS/2"
600         ;;
601     i?86-*-msdosdjgpp*)
602         PRINTABLE_OS_NAME="MSDOS/DJGPP"
603         try_extensions=no
604         ;;
605     *-linux*)
606         PRINTABLE_OS_NAME="GNU/Linux"
607         ;;
608     *)
609         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
610         ;;
611 esac
612 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
613                    [A human readable text with the name of the OS])
614
615
616 #
617 # 1. Set names of random devices
618 #
619 NAME_OF_DEV_RANDOM="/dev/random"
620 NAME_OF_DEV_URANDOM="/dev/urandom"
621 case "${target}" in
622     *-openbsd*)
623         NAME_OF_DEV_RANDOM="/dev/srandom"
624         NAME_OF_DEV_URANDOM="/dev/urandom"
625         ;;
626 esac
627 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM",
628                    [defined to the name of the strong random device])
629 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM",
630                    [defined to the name of the weaker random device])
631 AC_SUBST(MPI_OPT_FLAGS)
632
633
634 dnl Checks for libraries.
635
636 if test "$try_gettext" = yes; then
637   AM_GNU_GETTEXT(,[need-ngettext])
638
639   # gettext requires some extra checks.  These really should be part of
640   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
641   # function checks to here.
642
643   AC_CHECK_FUNCS(strchr)
644 else
645   USE_NLS=no
646   USE_INCLUDED_LIBINTL=no
647   BUILD_INCLUDED_LIBINTL=no
648   AC_SUBST(USE_NLS)
649   AC_SUBST(USE_INCLUDED_LIBINTL)
650   AC_SUBST(BUILD_INCLUDED_LIBINTL)
651 fi
652
653 if test "$try_extensions" = yes || test x"$card_support" = xyes ; then
654   if test "$need_dlopen" = yes; then
655     _dl_save_libs=$LIBS
656     LIBS=""
657     AC_SEARCH_LIBS(dlopen,dl,found_dlopen=yes)
658     if test x"$found_dlopen" = "xyes" ; then
659       AC_DEFINE(HAVE_DL_DLOPEN,1,
660                 [Defined when the dlopen function family is available])
661       DLLIBS=$LIBS
662     else
663       if test "$try_extensions" = yes ; then
664          AC_MSG_NOTICE([dlopen not found.  Disabling extensions.])
665          try_extensions=no
666       fi
667   
668       if test "$card_support" = yes ; then
669          AC_MSG_WARN([dlopen not found.  Disabling OpenPGP card support.])
670          card_support=no
671       fi
672     fi
673     LIBS=$_dl_save_libs
674   fi
675 fi
676
677 AC_SUBST(DLLIBS)
678
679 if test "$card_support" = yes ; then
680   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include OpenPGP card support])
681 fi
682
683 if test "$try_extensions" = yes ; then
684   AC_DEFINE(USE_DYNAMIC_LINKING,1,[Define to enable the use of extensions])
685 fi
686
687 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
688
689 dnl Checks for header files.
690 AC_HEADER_STDC
691 AC_CHECK_HEADERS(unistd.h langinfo.h termio.h locale.h getopt.h)
692
693 dnl Checks for typedefs, structures, and compiler characteristics.
694 AC_C_CONST
695 AC_C_INLINE
696 AC_C_VOLATILE
697 AC_TYPE_SIZE_T
698 AC_TYPE_MODE_T
699 AC_TYPE_SIGNAL
700 AC_DECL_SYS_SIGLIST
701
702 GNUPG_CHECK_ENDIAN
703
704 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
705 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
706 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
707 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
708 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
709
710 AC_CHECK_SIZEOF(unsigned short)
711 AC_CHECK_SIZEOF(unsigned int)
712 AC_CHECK_SIZEOF(unsigned long)
713 AC_CHECK_SIZEOF(unsigned long long)
714
715 # Ensure that we have UINT64_C before we bother to check for uint64_t
716 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
717    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
718 uint64_t foo=UINT64_C(42);]),gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
719
720 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
721    AC_CHECK_SIZEOF(uint64_t)
722 fi
723
724 if test "$ac_cv_sizeof_unsigned_short" = "0" \
725    || test "$ac_cv_sizeof_unsigned_int" = "0" \
726    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
727     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
728 fi
729
730 dnl Do we have any 64-bit data types?
731 if test "$ac_cv_sizeof_unsigned_int" != "8" \
732    && test "$ac_cv_sizeof_unsigned_long" != "8" \
733    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
734    && test x"$ac_cv_sizeof_uint64_t" != "x8"; then
735     AC_MSG_NOTICE([No 64-bit types.  Disabling SHA-384 and SHA-512.])
736 else
737   if test x"$use_sha512" = xyes ; then
738      AC_SUBST(SHA512_O,sha512.o)
739      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
740   fi
741 fi
742
743 dnl Checks for library functions.
744 AC_FUNC_FSEEKO
745 AC_FUNC_VPRINTF
746 AC_FUNC_FORK
747 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
748 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times)
749 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
750 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
751 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat getaddrinfo)
752 AC_REPLACE_FUNCS(mkdtemp)
753 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
754
755 # See if getopt is in libiberty.  This is of course not optimal since
756 # it might be somewhere other than libiberty, but does cover the
757 # mingw32 case.
758
759 AC_CHECK_FUNC(getopt,,AC_CHECK_LIB(iberty,getopt,AC_SUBST(GETOPT,"-liberty")))
760
761 #
762 # check for gethrtime and run a testprogram to see whether
763 # it is broken.  It has been reported that some Solaris and HP UX systems 
764 # raise an SIGILL
765 #
766 AC_CACHE_CHECK([for gethrtime], 
767                [gnupg_cv_func_gethrtime],
768                [AC_TRY_LINK([#include <sys/times.h>],[
769                    hrtime_t tv;
770                    tv = gethrtime();
771                  ],
772                  [gnupg_cv_func_gethrtime=yes],
773                  [gnupg_cv_func_gethrtime=no])
774                ])
775 if test $gnupg_cv_func_gethrtime = yes; then
776      AC_DEFINE([HAVE_GETHRTIME], 1,
777                [Define if you have the `gethrtime(2)' function.])
778      AC_CACHE_CHECK([whether gethrtime is broken], 
779                [gnupg_cv_func_broken_gethrtime],
780                [AC_TRY_RUN([
781                    #include <sys/times.h>
782                    int main () {
783                    hrtime_t tv;
784                    tv = gethrtime(); 
785                  }
786                  ],
787                  [gnupg_cv_func_broken_gethrtime=no],
788                  [gnupg_cv_func_broken_gethrtime=yes],
789                  [gnupg_cv_func_broken_gethrtime=assume-no])
790                 ])
791     if test $gnupg_cv_func_broken_gethrtime = yes; then
792       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
793       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
794     fi
795 fi
796      
797
798 GNUPG_CHECK_MLOCK
799 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
800
801 dnl
802 dnl Check whether we can use Linux capabilities as requested
803 dnl
804 if test "$use_capabilities" = "yes" ; then
805 use_capabilities=no
806 AC_CHECK_HEADERS(sys/capability.h)
807 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
808   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
809   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
810      AC_DEFINE(USE_CAPABILITIES,1,
811                [define if capabilities should be used])
812      AC_SUBST(CAPLIBS,"-lcap")
813      use_capabilities=yes
814   fi
815 fi
816 if test "$use_capabilities" = "no" ; then
817     AC_MSG_WARN([[
818 ***
819 *** The use of capabilities on this system is not possible.
820 *** You need a recent Linux kernel and some patches:
821 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
822 ***   fcap-module-990613.tar.gz     (kernel module)
823 ***   libcap-1.92.tar.gz            (user mode library and utilities)
824 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
825 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
826 ***]])
827 fi
828 fi
829
830
831 GNUPG_CHECK_IPC
832 if test "$ac_cv_header_sys_shm_h" = "yes"; then
833   AC_DEFINE(USE_SHM_COPROCESSING,1,
834             [define if the shared memory interface should be made available])
835 fi
836
837 dnl
838 dnl check whether we have a random device
839 dnl
840 if test "$try_dev_random" = yes ; then
841     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
842     [if test -r "$NAME_OF_DEV_RANDOM" && test -r "$NAME_OF_DEV_URANDOM" ; then
843       ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
844     if test "$ac_cv_have_dev_random" = yes; then
845         AC_DEFINE(HAVE_DEV_RANDOM,1,
846                  [defined if the system supports a random device] )
847     fi
848 else
849     AC_MSG_CHECKING(for random device)
850     ac_cv_have_dev_random=no
851     AC_MSG_RESULT(has been disabled)
852 fi
853
854
855 dnl
856 dnl Figure out the default random module.
857 dnl
858 random_modules=""
859 if test "$use_static_rnd" = default; then
860      if test "$ac_cv_have_dev_random" = yes; then
861         random_modules="rndlinux"
862      else
863          case "${target}" in
864             *-*-mingw32*|*-*-cygwin*)
865                 random_modules="rndw32"
866                 ;;
867             i?86-emx-os2|i?86-*-os2*emx)
868                 random_modules="rndos2"
869                 ;;
870             m68k-atari-mint)
871                 random_modules="rndatari"
872                 ;;
873             i?86-*-msdosdjgpp*)
874                 :
875                 ;;
876             *)
877                 random_modules="rndlinux rndegd rndunix"
878                 AC_DEFINE(USE_ALL_RANDOM_MODULES, 1, 
879                           [Allow to select random modules at runtime.])
880                 ;;
881          esac
882      fi
883 else
884   if test "$use_static_rnd" = auto; then
885      random_modules="rndlinux rndegd rndunix"
886      AC_DEFINE(USE_ALL_RANDOM_MODULES, 1)
887   else
888      random_modules="rnd$use_static_rnd";
889   fi
890 fi
891
892 if test -z "$random_modules"; then
893    AC_MSG_ERROR(no random module available)
894 fi
895 print_egd_warning=no
896 for rndmod in $random_modules "" ; do
897   case "$rndmod" in
898     rndlinux)
899          AC_DEFINE(USE_RNDLINUX,1, 
900                   [Defined if the /dev/random based RNG should be used.])
901          ;;
902     rndunix)
903          AC_DEFINE(USE_RNDUNIX,1, 
904                   [Defined if the default Unix RNG should be used.])
905          print_egd_warning=yes
906           ;;
907     rndegd)
908          AC_DEFINE(USE_RNDEGD,1, 
909                   [Defined if the EGD based RNG should be used.])
910          ;;
911     rndw32)
912          AC_DEFINE(USE_RNDW32,1, 
913                   [Defined if the Windows specific RNG should be used.])
914         ;;
915    esac
916 done
917
918 dnl setup assembler stuff
919 AC_MSG_CHECKING(for mpi assembler functions)
920 if test -f $srcdir/mpi/config.links ; then
921     . $srcdir/mpi/config.links
922     AC_CONFIG_LINKS("$mpi_ln_list")
923     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
924     ac_cv_mpi_sflags="$mpi_sflags"
925     ac_cv_mpi_config_done="yes"
926     AC_MSG_RESULT(done)
927 else
928     AC_MSG_RESULT(failed)
929     AC_MSG_ERROR([mpi/config.links missing!])
930 fi
931 MPI_EXTRA_ASM_OBJS=""
932 show_extraasm=""
933 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
934 for i in $ac_cv_mpi_extra_asm_modules; do
935     show_extraasm="$show_extraasm $i"
936     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
937 done
938 fi
939 AC_SUBST(MPI_EXTRA_ASM_OBJS)
940 MPI_SFLAGS="$ac_cv_mpi_sflags"
941 AC_SUBST(MPI_SFLAGS)
942
943 # Sanity check regex.  Tests adapted from mutt.
944
945 AC_MSG_CHECKING([whether regular expression support is requested])
946 AC_ARG_ENABLE(regex,
947 [  --disable-regex         do not handle regular expressions in trust sigs],
948      use_regex=$enableval, use_regex=yes)
949 AC_MSG_RESULT($use_regex)
950
951 if test "$use_regex" = yes ; then
952   AC_MSG_CHECKING([whether the included regex lib is requested])
953   AC_ARG_WITH(included-regex,
954       [  --with-included-regex   use the included GNU regex library],
955       [gnupg_cv_included_regex=yes],[gnupg_cv_included_regex=no])
956   AC_MSG_RESULT($gnupg_cv_included_regex)
957
958   if test $gnupg_cv_included_regex = no ; then
959      # Does the system have regex functions at all?
960      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
961                            gnupg_cv_included_regex=yes)
962   fi
963
964   if test $gnupg_cv_included_regex = no ; then
965      AC_CACHE_CHECK([whether your system's regexp library is broken],
966        [gnupg_cv_regex_broken],
967        AC_TRY_RUN([
968 #include <unistd.h>
969 #include <regex.h>
970 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
971        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
972
973      if test $gnupg_cv_regex_broken = yes ; then
974       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
975       gnupg_cv_included_regex=yes
976      fi
977   fi
978
979   if test $gnupg_cv_included_regex = yes; then
980      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
981      AC_SUBST(REGEX_O,regex.o)
982   fi
983 else
984
985   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
986 fi
987
988 dnl Do we have zlib? Must do it here because Solaris failed
989 dnl when compiling a conftest (due to the "-lz" from LIBS).
990 use_local_zlib=yes
991 if test "$g10_force_zlib" = "yes"; then
992   :
993 else
994   _cppflags="${CPPFLAGS}"
995   _ldflags="${LDFLAGS}"
996
997   AC_ARG_WITH(zlib,
998   [  --with-zlib=DIR         use libz in DIR],[
999     if test -d "$withval"; then
1000       CPPFLAGS="${CPPFLAGS} -I$withval/include"
1001       LDFLAGS="${LDFLAGS} -L$withval/lib"
1002     fi
1003   ])
1004
1005   AC_CHECK_HEADER(zlib.h,
1006       AC_CHECK_LIB(z, deflateInit2_,
1007        use_local_zlib=no
1008        ZLIBS="-lz",
1009        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1010        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1011 fi
1012
1013 if test "$use_local_zlib" = yes ; then
1014     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
1015     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
1016     ZLIBS="../zlib/libzlib.a"
1017 else
1018     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
1019 fi
1020
1021 if test "$use_bzip2" = yes ; then
1022   _cppflags="${CPPFLAGS}"
1023   _ldflags="${LDFLAGS}"
1024   AC_ARG_WITH(bzip2,
1025      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1026       [
1027       if test -d "$withval" ; then
1028         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1029         LDFLAGS="${LDFLAGS} -L$withval/lib"
1030       fi
1031       ],withval="")
1032
1033 # Checking alongside stdio.h as an early version of bzip2 (1.0)
1034 # required stdio.h to be included before bzlib.h, and Solaris 9 is
1035 # woefully out of date.
1036
1037   if test "$withval" != no ; then
1038      AC_CHECK_HEADER(bzlib.h,
1039         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1040           [
1041           have_bz2=yes
1042           ZLIBS="$ZLIBS -lbz2"
1043           AC_DEFINE(HAVE_BZIP2,1,
1044                   [Defined if the bz2 compression library is available])
1045           ],
1046           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1047           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1048   fi
1049 fi
1050
1051 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1052 AC_SUBST(ZLIBS)
1053
1054
1055 #
1056 # libusb allows us to use the integrated CCID smartcard reader driver.
1057 #
1058 # Note, that we need the CVS (unstable) version. 
1059 #
1060 LIBUSB_LIBS=""
1061 if test "$card_support" = yes; then
1062     AC_CHECK_LIB(usb, usb_find_device,
1063                  [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
1064                    AC_DEFINE(HAVE_LIBUSB,1,
1065                    [defined if libusb is available])
1066                  ])
1067 fi
1068 AC_SUBST(LIBUSB_LIBS)
1069
1070
1071
1072 # Allow users to append something to the version string without
1073 # flagging it as development version.  The user version parts is
1074 # considered everything after a dash. 
1075 if test "$development_version" != yes; then
1076   changequote(,)dnl
1077   tmp_pat='[a-zA-Z]'
1078   changequote([,])dnl
1079   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1080     development_version=yes
1081   fi
1082 fi
1083 if test "$development_version" = yes; then
1084     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1085             [Defined if this is not a regular release])
1086 fi
1087
1088 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1089
1090 GNUPG_CHECK_GNUMAKE
1091
1092 # add some extra libs here so that previous tests don't fail for
1093 # mysterious reasons - the final link step should bail out. 
1094 case "${target}" in
1095     *-*-mingw32*)
1096 dnl      NETLIBS="$NETLIBS -lwsock32"
1097         W32LIBS="-lwsock32"
1098         ;;
1099     *)
1100        ;;
1101 esac
1102
1103 AC_SUBST(NETLIBS)
1104 AC_SUBST(W32LIBS)
1105
1106 if test "$GCC" = yes; then
1107     if test "$USE_MAINTAINER_MODE" = "yes"; then
1108         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1109         CFLAGS="$CFLAGS -Wformat-nonliteral"
1110     else
1111         CFLAGS="$CFLAGS -Wall"
1112     fi
1113 fi
1114
1115
1116 if test "$print_egd_warning" = yes; then
1117   AC_MSG_WARN([[
1118 ***
1119 *** The performance of the UNIX random gatherer module is not very good
1120 *** and it does not keep the entropy pool over multiple invocations of
1121 *** GnuPG.  The suggested way to overcome this problem is to use the
1122 ***
1123 ***               Entropy Gathering Daemon (EGD)
1124 ***
1125 *** which provides a entropy source for the whole system.  It is written
1126 *** in Perl and available at the GnuPG FTP servers.  For more information
1127 *** consult the GnuPG webpages:
1128 ***
1129 ***           http://www.gnupg.org/download/#EGD
1130 ***
1131 *** You may want to run ./configure with --enable-static-rnd=egd or
1132 *** --enable-static-rnd=auto to use it.
1133 ***]])
1134 fi
1135
1136 # Note the \\\\ for backslashes.  Autoconf eats one layer, leaving \\
1137
1138 AC_CONFIG_COMMANDS(g10defs.h,[[
1139 cat >g10defs.tmp <<G10EOF
1140 /* Generated automatically by configure */
1141 #ifdef HAVE_DRIVE_LETTERS
1142 #define G10_LOCALEDIR     "c:\\\\lib\\\\gnupg\\\\locale"
1143 #define GNUPG_LIBDIR      "c:\\\\lib\\\\gnupg"
1144 #define GNUPG_LIBEXECDIR  "c:\\\\lib\\\\gnupg"
1145 #define GNUPG_DATADIR     "c:\\\\lib\\\\gnupg"
1146 #define GNUPG_HOMEDIR     "c:\\\\gnupg"
1147 #else
1148 #define G10_LOCALEDIR     "${datadir}/locale"
1149 #define GNUPG_LIBDIR      "${libdir}/gnupg"
1150 #define GNUPG_DATADIR     "${datadir}/gnupg"
1151 #ifdef __VMS
1152 #define GNUPG_HOMEDIR "/SYS\$LOGIN/gnupg" 
1153 #else
1154 #define GNUPG_HOMEDIR "~/.gnupg" 
1155 #endif
1156 #endif
1157 /* those are here to be redefined by handcrafted g10defs.h.
1158    Please note that the string version must not contain more
1159    than one character because the using code assumes strlen()==1 */
1160 #ifdef HAVE_DOSISH_SYSTEM
1161 #define DIRSEP_C '\\\\'
1162 #define EXTSEP_C '.'
1163 #define DIRSEP_S "\\\\"
1164 #define EXTSEP_S "."
1165 #else
1166 #define DIRSEP_C '/'
1167 #define EXTSEP_C '.'
1168 #define DIRSEP_S "/"
1169 #define EXTSEP_S "."
1170 #endif
1171 /* This is the same as VERSION, but should be overridden if the
1172    platform cannot handle things like dots'.' in filenames.  Set
1173    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
1174    uses for dots and dashes. */
1175 #define SAFE_VERSION      VERSION
1176 #define SAFE_VERSION_DOT  '.'
1177 #define SAFE_VERSION_DASH '-'
1178 G10EOF
1179 cat mpi/mpi-asm-defs.h >>g10defs.tmp 
1180 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
1181     echo "g10defs.h is unchanged"
1182     rm -f g10defs.tmp
1183 else
1184     rm -f g10defs.h
1185     mv g10defs.tmp g10defs.h
1186     echo "g10defs.h created"
1187 fi
1188 ]],[[
1189 prefix=$prefix
1190 exec_prefix=$exec_prefix
1191 libdir=$libdir
1192 libexecdir=$libexecdir
1193 datadir=$datadir
1194 DATADIRNAME=$DATADIRNAME
1195 ]])
1196
1197
1198 AC_CONFIG_FILES([
1199 Makefile
1200 m4/Makefile
1201 intl/Makefile
1202 po/Makefile.in
1203 util/Makefile
1204 mpi/Makefile
1205 cipher/Makefile
1206 g10/Makefile
1207 keyserver/Makefile
1208 keyserver/gpgkeys_mailto
1209 keyserver/gpgkeys_test
1210 doc/Makefile
1211 tools/Makefile
1212 zlib/Makefile
1213 checks/Makefile
1214 ])
1215 AC_OUTPUT
1216
1217 # Give some feedback
1218 echo
1219 echo   "                Configured for: $PRINTABLE_OS_NAME ($target)"
1220 if test -n "$show_extraasm"; then
1221   echo "  Extra cpu specific functions:$show_extraasm"
1222 fi
1223 echo