7050f4dfcdb639187e157f5d24465f7814dc229c
[gnupg.git] / configure.ac
1 dnl Configure.ac script for GnuPG
2 dnl Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 dnl               2003 Free Software Foundation, Inc.
4 dnl
5 dnl This file is part of GnuPG.
6 dnl
7 dnl GnuPG is free software; you can redistribute it and/or modify
8 dnl it under the terms of the GNU General Public License as published by
9 dnl the Free Software Foundation; either version 2 of the License, or
10 dnl (at your option) any later version.
11 dnl 
12 dnl GnuPG is distributed in the hope that it will be useful,
13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 dnl GNU General Public License for more details.
16 dnl 
17 dnl You should have received a copy of the GNU General Public License
18 dnl along with this program; if not, write to the Free Software
19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20 dnl
21 dnl (Process this file with autoconf to produce a configure script.)
22 dnlAC_REVISION($Revision$)dnl
23
24 AC_PREREQ(2.52)
25
26 # Remember to change the version number immediately *after* a release
27 # and remove the "-cvs" or "rc" suffix immediately *before* a release.
28 AC_INIT(gnupg, 1.3.4-cvs, bug-gnupg@gnu.org)
29 # Set development_version to yes if the minor number is odd or you
30 # feel that the default check for a development version is not
31 # sufficient.
32 development_version=yes
33
34 ALL_LINGUAS="de"
35
36 AC_CONFIG_AUX_DIR(scripts)
37 AC_CONFIG_SRCDIR(g10/g10.c)
38 AC_CANONICAL_TARGET()
39 AM_INIT_AUTOMAKE
40 AM_CONFIG_HEADER(config.h)
41
42 AC_GNU_SOURCE
43
44 dnl
45 dnl  Check for random module options
46 dnl
47 AC_MSG_CHECKING([which random module to use])
48 AC_ARG_ENABLE(static-rnd,
49     [  --enable-static-rnd=[egd|unix|linux|auto]  ],
50 [use_static_rnd=$enableval], [use_static_rnd=default] )
51
52 if test "$use_static_rnd" = no; then
53     use_static_rnd=default
54 fi
55
56 case "$use_static_rnd" in
57     egd | linux | unix | default )
58       AC_MSG_RESULT($use_static_rnd)
59       ;;
60     auto )
61       AC_MSG_RESULT(automagically selected at runtime)
62       ;;
63     * )
64       AC_MSG_RESULT(invalid argument)
65       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
66       ;;
67 esac
68
69 AC_ARG_WITH(egd-socket,
70     [  --with-egd-socket=NAME  use NAME for the EGD socket],
71             egd_socket_name="$withval", egd_socket_name="" )
72 AC_DEFINE_UNQUOTED(EGD_SOCKET_NAME, "$egd_socket_name",
73                    [Define if you don't want the default EGD socket name.
74                     For details see cipher/rndegd.c])
75
76
77 dnl
78 dnl See whether the user wants to disable checking for /dev/random
79
80 AC_MSG_CHECKING([whether use of /dev/random is requested])
81 AC_ARG_ENABLE(dev-random,
82 [  --disable-dev-random    disable the use of dev random],
83     try_dev_random=$enableval, try_dev_random=yes)
84 AC_MSG_RESULT($try_dev_random)
85
86
87 dnl
88 dnl  Check other options
89 dnl
90
91 AC_MSG_CHECKING([whether assembler modules are requested])
92 AC_ARG_ENABLE(asm,
93 [  --disable-asm           do not use assembler modules],
94      try_asm_modules=$enableval, try_asm_modules=yes)
95 AC_MSG_RESULT($try_asm_modules)
96
97 AC_MSG_CHECKING([whether memory guard is requested])
98 AC_ARG_ENABLE(m-guard,
99     [  --enable-m-guard        enable memory guard facility],
100     use_m_guard=$enableval, use_m_guard=no)
101 AC_MSG_RESULT($use_m_guard)
102 if test "$use_m_guard" = yes ; then
103     AC_DEFINE(M_GUARD,1,[Define to use the (obsolete) malloc guarding feature])
104 fi
105
106 AC_MSG_CHECKING([whether OpenPGP card support is requested])
107 AC_ARG_ENABLE(card-support,
108     [  --enable-card-support   enable OpenPGP card support],
109     card_support=$enableval, card_support=no)
110 AC_MSG_RESULT($card_support)
111
112 dnl See if we are disabling any algorithms or features for a smaller
113 dnl binary
114
115 try_extensions=no
116
117 use_idea=yes
118 use_cast5=yes
119 use_blowfish=yes
120 use_aes=yes
121 use_twofish=yes
122 use_sha256=yes
123 use_sha512=yes
124 use_exec=yes
125
126 AC_ARG_ENABLE(minimal,
127    AC_HELP_STRING([--enable-minimal],[build the smallest gpg binary possible]),
128    use_idea=no
129    use_cast5=no
130    use_blowfish=no
131    use_aes=no
132    use_twofish=no
133    use_sha256=no
134    use_sha512=no
135    use_exec=no)
136
137 AC_MSG_CHECKING([whether to enable the IDEA cipher])
138 AC_ARG_ENABLE(idea,
139    AC_HELP_STRING([--disable-idea],[disable the IDEA cipher]),
140    use_idea=$enableval)
141 AC_MSG_RESULT($use_idea)
142 if test x"$use_idea" = xyes ; then
143    AC_DEFINE(USE_IDEA,1,[Define to include the IDEA cipher])
144
145 # We don't need idea but some people claim that they need it for
146 # research etc., so we allow to place an idea source code into the
147 # cipher directory and statically link it if available, otherwise we
148 # link to a stub.  We don't use AC_CHECK_FILE to avoid caching.
149
150    AC_MSG_CHECKING([for idea cipher module])
151    tmp=""
152    if test -f $srcdir/cipher/idea.c; then 
153       IDEA_O=idea.o
154       tmp=idea
155    else
156       IDEA_O=idea-stub.o
157       tmp=no
158       try_extensions=yes
159    fi
160    AC_SUBST(IDEA_O)
161    AC_MSG_RESULT($tmp)
162 fi
163
164 AC_MSG_CHECKING([whether to enable the CAST5 cipher])
165 AC_ARG_ENABLE(cast5,
166    AC_HELP_STRING([--disable-cast5],[disable the CAST5 cipher]),
167    use_cast5=$enableval)
168 AC_MSG_RESULT($use_cast5)
169 if test x"$use_cast5" = xyes ; then
170    AC_DEFINE(USE_CAST5,1,[Define to include the CAST5 cipher])
171 fi
172
173 AC_MSG_CHECKING([whether to enable the BLOWFISH cipher])
174 AC_ARG_ENABLE(blowfish,
175    AC_HELP_STRING([--disable-blowfish],[disable the BLOWFISH cipher]),
176    use_blowfish=$enableval)
177 AC_MSG_RESULT($use_blowfish)
178 if test x"$use_blowfish" = xyes ; then
179    AC_DEFINE(USE_BLOWFISH,1,[Define to include the BLOWFISH cipher])
180 fi
181
182 AC_MSG_CHECKING([whether to enable the AES ciphers])
183 AC_ARG_ENABLE(aes,
184    AC_HELP_STRING([--disable-aes],[disable the AES, AES192, and AES256 ciphers]),
185    use_aes=$enableval)
186 AC_MSG_RESULT($use_aes)
187 if test x"$use_aes" = xyes ; then
188    AC_DEFINE(USE_AES,1,[Define to include the AES, AES192, and AES256 ciphers])
189 fi
190
191 AC_MSG_CHECKING([whether to enable the TWOFISH cipher])
192 AC_ARG_ENABLE(twofish,
193    AC_HELP_STRING([--disable-twofish],[disable the TWOFISH cipher]),
194    use_twofish=$enableval)
195 AC_MSG_RESULT($use_twofish)
196 if test x"$use_twofish" = xyes ; then
197    AC_DEFINE(USE_TWOFISH,1,[Define to include the TWOFISH cipher])
198 fi
199
200 AC_MSG_CHECKING([whether to enable the SHA-256 digest])
201 AC_ARG_ENABLE(sha256,
202    AC_HELP_STRING([--disable-sha256],[disable the SHA-256 digest]),
203    use_sha256=$enableval)
204 AC_MSG_RESULT($use_sha256)
205 if test x"$use_sha256" = xyes ; then
206    AC_DEFINE(USE_SHA256,1,[Define to include the SHA-256 digest])
207 fi
208
209 dnl SHA512 is defined only after we confirm 64-bit support later
210 AC_MSG_CHECKING([whether to enable the SHA-384 and SHA-512 digests])
211 AC_ARG_ENABLE(sha512,
212    AC_HELP_STRING([--disable-sha512],[disable the SHA-384 and SHA-512 digests]),
213    use_sha512=$enableval)
214 AC_MSG_RESULT($use_sha512)
215
216 AC_MSG_CHECKING([whether to enable external program execution])
217 AC_ARG_ENABLE(exec,
218     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
219     use_exec=$enableval)
220 AC_MSG_RESULT($use_exec)
221 if test "$use_exec" = no ; then
222     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
223 fi
224
225 if test "$use_exec" = yes ; then
226   AC_MSG_CHECKING([whether to enable photo ID viewing])
227   AC_ARG_ENABLE(photo-viewers,
228       [  --disable-photo-viewers disable photo ID viewers],
229       [if test "$enableval" = no ; then
230          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
231       fi],enableval=yes)
232   gnupg_cv_enable_photo_viewers=$enableval
233   AC_MSG_RESULT($enableval)
234
235   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
236     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
237     AC_ARG_WITH(photo-viewer,
238         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
239         [if test "$withval" = yes ; then
240            withval=no
241         elif test "$withval" != no ; then
242            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
243                             [if set, restrict photo-viewer to this])
244         fi],withval=no)
245     AC_MSG_RESULT($withval)
246   fi
247
248   AC_MSG_CHECKING([whether to enable external keyserver helpers])
249   AC_ARG_ENABLE(keyserver-helpers,
250       [  --disable-keyserver-helpers  disable all external keyserver support],
251       [if test "$enableval" = no ; then
252          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
253                   [define to disable keyserver helpers])
254       fi],enableval=yes)
255   gnupg_cv_enable_keyserver_helpers=$enableval
256   AC_MSG_RESULT($enableval)
257
258   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
259     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
260     AC_ARG_ENABLE(ldap,
261     [  --disable-ldap          disable LDAP keyserver interface],
262         try_ldap=$enableval, try_ldap=yes)
263     AC_MSG_RESULT($try_ldap)
264
265     AC_MSG_CHECKING([whether HKP keyserver support is requested])
266     AC_ARG_ENABLE(hkp,
267     [  --disable-hkp           disable HKP keyserver interface],
268         try_hkp=$enableval, try_hkp=yes)
269     AC_MSG_RESULT($try_hkp)
270
271     AC_MSG_CHECKING([whether email keyserver support is requested])
272     AC_ARG_ENABLE(mailto,
273     [  --disable-mailto        disable email keyserver interface],
274         try_mailto=$enableval, try_mailto=yes)
275     AC_MSG_RESULT($try_mailto)
276     fi
277
278     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
279     AC_ARG_ENABLE(keyserver-path,
280         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
281         [if test "$enableval" = no ; then
282          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
283         fi],enableval=yes)
284     AC_MSG_RESULT($enableval)
285   fi
286
287 AC_MSG_CHECKING([whether the included zlib is requested])
288 AC_ARG_WITH(included-zlib,
289     [  --with-included-zlib    use the zlib code included here],
290 [g10_force_zlib=yes], [g10_force_zlib=no] )
291 AC_MSG_RESULT($g10_force_zlib)
292
293 dnl
294 dnl Check whether we want to use Linux capabilities
295 dnl
296 AC_MSG_CHECKING([whether use of capabilities is requested])
297 AC_ARG_WITH(capabilities,
298     [  --with-capabilities     use linux capabilities [default=no]],
299 [use_capabilities="$withval"],[use_capabilities=no])
300 AC_MSG_RESULT($use_capabilities)
301
302
303 AH_BOTTOM([
304 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
305 #define EXEC_TEMPFILE_ONLY
306 #endif
307
308 /* This is the major version number of GnuPG so that
309    source included files can test for this. */
310 #define GNUPG_MAJOR_VERSION 1
311
312 #include "g10defs.h"
313 ])
314
315
316 AM_MAINTAINER_MODE
317
318 dnl Checks for programs.
319
320 AC_PROG_MAKE_SET
321 AM_SANITY_CHECK
322 missing_dir=`cd $ac_aux_dir && pwd`
323 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
324 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
325 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
326 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
327 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
328 AC_PROG_CC
329 AC_PROG_CPP
330 AC_PROG_RANLIB
331 AC_CHECK_TOOL(AR, ar, :)
332 AC_PATH_PROG(PERL,"perl")
333 AC_ISC_POSIX
334 AC_SYS_LARGEFILE
335 AC_PROG_INSTALL
336 AC_PROG_AWK
337 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
338 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
339 GNUPG_CHECK_FAQPROG
340 GNUPG_CHECK_DOCBOOK_TO_TEXI
341
342 MPI_OPT_FLAGS=""
343
344
345 try_gettext=yes
346 have_dosish_system=no
347 case "${target}" in
348     *-*-mingw32*)
349         # special stuff for Windoze NT
350         ac_cv_have_dev_random=no
351         AC_DEFINE(USE_ONLY_8DOT3,1,
352                   [set this to limit filenames to the 8.3 format])
353         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
354                   [defined if we must run on a stupid file system])
355         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
356                   [because the Unix gettext has too much overhead on
357                    MingW32 systems and these systems lack Posix functions,
358                    we use a simplified version of gettext])
359         have_dosish_system=yes
360         try_gettext="no"
361         ;;
362     i?86-emx-os2 | i?86-*-os2*emx )
363         # OS/2 with the EMX environment
364         ac_cv_have_dev_random=no
365         AC_DEFINE(HAVE_DRIVE_LETTERS)
366         have_dosish_system=yes
367         try_gettext="no"
368         ;;
369
370     i?86-*-msdosdjgpp*)
371         # DOS with the DJGPP environment
372         ac_cv_have_dev_random=no
373         AC_DEFINE(HAVE_DRIVE_LETTERS)
374         have_dosish_system=yes
375         try_gettext="no"
376         ;;
377
378     *-*-freebsd*)
379        # FreeBSD
380        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
381        LDFLAGS="$LDFLAGS -L/usr/local/lib"
382        ;;
383
384     *-*-hpux*)
385         if test -z "$GCC" ; then
386             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
387         fi
388         ;;
389     *-dec-osf4*)
390         if test -z "$GCC" ; then
391             # Suppress all warnings
392             # to get rid of the unsigned/signed char mismatch warnings.
393             CFLAGS="$CFLAGS -w"
394         fi
395         ;;
396     *-dec-osf5*)
397         if test -z "$GCC" ; then
398             # Use the newer compiler `-msg_disable ptrmismatch' to
399             # get rid of the unsigned/signed char mismatch warnings.
400             # Using this may hide other pointer mismatch warnings, but
401             # it at least lets other warning classes through
402             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
403         fi
404         ;;
405     m68k-atari-mint)
406         ;;
407     *)
408        ;;
409 esac
410
411 if test "$have_dosish_system" = yes; then
412    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
413              [defined if we run on some of the PCDOS like systems 
414               (DOS, Windoze. OS/2) with special properties like
415               no file modes])
416 fi
417 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
418
419 AC_SUBST(MPI_OPT_FLAGS)
420 GNUPG_SYS_SYMBOL_UNDERSCORE
421
422 dnl This needs to go after AC_PROG_CC so that $EXEEXT is defined
423 if test "$try_hkp" = yes ; then
424   AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
425 fi
426
427 dnl Must check for network library requirements before doing link tests
428 dnl for ldap, for example. If ldap libs are static (or dynamic and without
429 dnl ELF runtime link paths), then link will fail and LDAP support won't
430 dnl be detected.
431
432 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
433         [NETLIBS="-lnsl $NETLIBS"]))
434 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
435         [NETLIBS="-lsocket $NETLIBS"]))
436
437 dnl Now try for the resolver functions so we can use DNS SRV
438
439 AC_ARG_ENABLE(dns-srv,
440    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
441    use_dns_srv=$enableval,use_dns_srv=yes)
442
443 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
444   _srv_save_libs=$LIBS
445   LIBS=""
446   # the double underscore thing is a glibc-ism?
447   AC_SEARCH_LIBS(res_query,resolv bind,,
448                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
449   AC_SEARCH_LIBS(dn_expand,resolv bind,,
450                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
451   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
452                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
453
454   if test x"$use_dns_srv" = xyes ; then
455      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
456      SRVLIBS=$LIBS
457   else
458      AC_MSG_WARN([Resolver functions not found.  Disabling DNS SRV.])
459   fi
460   LIBS=$_srv_save_libs
461 fi
462
463 AC_SUBST(SRVLIBS)
464
465 # Try and link a LDAP test program to weed out unusable LDAP
466 # libraries.  -lldap [-llber [-lresolv]] is for OpenLDAP.  OpenLDAP in
467 # general is terrible with creating weird dependencies.  If all else
468 # fails, the user can play guess-the-dependency by using something
469 # like ./configure LDAPLIBS="-Lfoo -lbar"
470
471 if test "$try_ldap" = yes ; then
472   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
473     _ldap_save_libs=$LIBS
474     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
475
476     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
477     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
478                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
479     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
480
481     if test $gnupg_cv_func_ldap_init = no; then
482       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
483       AC_TRY_LINK([#include <lber.h>
484 #include <ldap.h>],[ldap_open("foobar",1234);],
485          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
486       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
487     fi
488
489     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
490        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
491     fi
492
493     if test "$gnupg_cv_func_ldap_init" = yes || \
494         test "$gnupg_cv_func_ldaplber_init" = yes ; then
495        LDAPLIBS=$MY_LDAPLIBS
496        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
497
498        AC_MSG_CHECKING([whether LDAP supports ldap_get_option])
499
500        if test "$gnupg_cv_func_ldap_init" = yes ; then
501           AC_TRY_LINK([#include <ldap.h>],
502              [ldap_get_option((void *)0,0,(void *)0);],
503              [gnupg_cv_func_ldap_get_option=yes],
504              [gnupg_cv_func_ldap_get_option=no])
505         else
506           AC_TRY_LINK([#include <lber.h>
507 #include <ldap.h>],[ldap_get_option((void *)0,0,(void *)0);],
508              [gnupg_cv_func_ldap_get_option=yes],
509              [gnupg_cv_func_ldap_get_option=no])
510        fi
511
512        AC_MSG_RESULT([$gnupg_cv_func_ldap_get_option])
513
514        if test "$gnupg_cv_func_ldap_get_option" = yes ; then
515           AC_DEFINE(HAVE_LDAP_GET_OPTION,1,[Define if the LDAP library has ldap_get_option])
516        else
517           AC_MSG_CHECKING([whether LDAP supports ld_errno])
518
519           if test "$gnupg_cv_func_ldap_init" = yes ; then
520             AC_TRY_COMPILE([#include <ldap.h>],
521                [LDAP *ldap; ldap->ld_errno;],
522                [gnupg_cv_func_ldap_ld_errno=yes],
523                [gnupg_cv_func_ldap_ld_errno=no])
524            else
525             AC_TRY_LINK([#include <lber.h>
526 #include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
527                [gnupg_cv_func_ldap_ld_errno=yes],
528                [gnupg_cv_func_ldap_ld_errno=no])
529           fi
530
531           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
532
533           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
534              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
535           fi
536        fi
537     fi
538
539     LIBS=$_ldap_save_libs
540
541     if test "$GPGKEYS_LDAP" != "" ; then break; fi
542   done
543 fi
544
545 AC_SUBST(GPGKEYS_LDAP)
546 AC_SUBST(LDAPLIBS)
547
548 dnl This isn't necessarily sendmail itself, but anything that gives a
549 dnl sendmail-ish interface to the outside world.  That includes qmail,
550 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
551
552 if test "$try_mailto" = yes ; then
553   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
554
555   if test "$with_mailprog" = yes ; then
556     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
557     if test "$ac_cv_path_SENDMAIL" ; then
558       GPGKEYS_MAILTO="gpgkeys_mailto"
559     fi
560   elif test "$with_mailprog" != no ; then
561     AC_MSG_CHECKING([for a mail transport program])
562     AC_SUBST(SENDMAIL,$with_mailprog)
563     AC_MSG_RESULT($with_mailprog)
564     GPGKEYS_MAILTO="gpgkeys_mailto"
565   fi
566 fi
567
568 AC_SUBST(GPGKEYS_MAILTO)
569
570 case "${target}" in
571     *-*-mingw32*)
572         PRINTABLE_OS_NAME="MingW32"
573         ;;
574     *-*-cygwin*)
575         PRINTABLE_OS_NAME="Cygwin"
576         ;;
577     i?86-emx-os2 | i?86-*-os2*emx )
578         PRINTABLE_OS_NAME="OS/2"
579         ;;
580     i?86-*-msdosdjgpp*)
581         PRINTABLE_OS_NAME="MSDOS/DJGPP"
582         try_extensions=no
583         ;;
584     *-linux*)
585         PRINTABLE_OS_NAME="GNU/Linux"
586         ;;
587     *)
588         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
589         ;;
590 esac
591 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
592                    [A human readable text with the name of the OS])
593
594
595 #
596 # 1. Set names of random devices
597 #
598 NAME_OF_DEV_RANDOM="/dev/random"
599 NAME_OF_DEV_URANDOM="/dev/urandom"
600 case "${target}" in
601     *-openbsd*)
602         NAME_OF_DEV_RANDOM="/dev/srandom"
603         NAME_OF_DEV_URANDOM="/dev/urandom"
604         ;;
605 esac
606 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM",
607                    [defined to the name of the strong random device])
608 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM",
609                    [defined to the name of the weaker random device])
610 AC_SUBST(MPI_OPT_FLAGS)
611
612
613 dnl Checks for libraries.
614
615 if test "$try_gettext" = yes; then
616   AM_GNU_GETTEXT(,[need-ngettext])
617
618   # gettext requires some extra checks.  These really should be part of
619   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
620   # function checks to here.
621
622   AC_CHECK_FUNCS(strchr)
623 else
624   USE_NLS=no
625   USE_INCLUDED_LIBINTL=no
626   BUILD_INCLUDED_LIBINTL=no
627   AC_SUBST(USE_NLS)
628   AC_SUBST(USE_INCLUDED_LIBINTL)
629   AC_SUBST(BUILD_INCLUDED_LIBINTL)
630 fi
631
632 if test "$try_extensions" = yes || test x"$card_support" = xyes ; then
633   AC_CHECK_FUNC(dlopen,,AC_CHECK_LIB(dl,dlopen,found_dlopen=yes))
634   if test x"$found_dlopen" = "xyes" ; then
635     AC_DEFINE(HAVE_DL_DLOPEN,1,
636               [Defined when the dlopen function family is available])
637     AC_SUBST(DLLIBS,"-ldl")
638
639     if test "$try_extensions" = yes ; then
640        AC_DEFINE(USE_DYNAMIC_LINKING,1,
641                  [define to enable the use of extensions])
642     fi
643
644     if test "$card_support" = yes ; then
645        AC_DEFINE(ENABLE_CARD_SUPPORT,1,
646                  [Define to include the OpenPGP card support])
647     fi
648   else
649     if test "$try_extensions" = yes ; then
650        AC_MSG_WARN([dlopen not found.  Disabling extensions.])
651     fi
652
653     if test "$card_support" = yes ; then
654        AC_MSG_WARN([dlopen not found.  Disabling OpenPGP card support.])
655        card_support=no
656     fi
657   fi
658 fi
659
660 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
661
662 dnl Checks for header files.
663 AC_HEADER_STDC
664 AC_CHECK_HEADERS(unistd.h langinfo.h termio.h locale.h getopt.h)
665
666 dnl Checks for typedefs, structures, and compiler characteristics.
667 AC_C_CONST
668 AC_C_INLINE
669 AC_C_VOLATILE
670 AC_TYPE_SIZE_T
671 AC_TYPE_MODE_T
672 AC_TYPE_SIGNAL
673 AC_DECL_SYS_SIGLIST
674
675 GNUPG_CHECK_ENDIAN
676
677 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
678 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
679 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
680 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
681 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
682
683 AC_CHECK_SIZEOF(unsigned short)
684 AC_CHECK_SIZEOF(unsigned int)
685 AC_CHECK_SIZEOF(unsigned long)
686 AC_CHECK_SIZEOF(unsigned long long)
687
688 # Ensure that we have UINT64_C before we bother to check for uint64_t
689 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
690    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
691 uint64_t foo=UINT64_C(42);]),gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
692
693 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
694    AC_CHECK_SIZEOF(uint64_t)
695 fi
696
697 if test "$ac_cv_sizeof_unsigned_short" = "0" \
698    || test "$ac_cv_sizeof_unsigned_int" = "0" \
699    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
700     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
701 fi
702
703 dnl Do we have any 64-bit data types?
704 if test "$ac_cv_sizeof_unsigned_int" != "8" \
705    && test "$ac_cv_sizeof_unsigned_long" != "8" \
706    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
707    && test x"$ac_cv_sizeof_uint64_t" != "x8"; then
708     AC_MSG_WARN([No 64-bit types.  Disabling SHA-384 and SHA-512])
709 else
710   if test x"$use_sha512" = xyes ; then
711      AC_SUBST(SHA512_O,sha512.o)
712      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
713   fi
714 fi
715
716 dnl Checks for library functions.
717 AC_FUNC_FSEEKO
718 AC_FUNC_VPRINTF
719 AC_FUNC_FORK
720 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
721 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times)
722 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
723 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
724 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat getaddrinfo)
725 AC_REPLACE_FUNCS(mkdtemp)
726 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
727
728 # See if getopt is in libiberty.  This is of course not optimal since
729 # it might be somewhere other than libiberty, but does cover the
730 # mingw32 case.
731
732 AC_CHECK_FUNC(getopt,,AC_CHECK_LIB(iberty,getopt,AC_SUBST(GETOPT,"-liberty")))
733
734 #
735 # check for gethrtime and run a testprogram to see whether
736 # it is broken.  It has been reported that some Solaris and HP UX systems 
737 # raise an SIGILL
738 #
739 AC_CACHE_CHECK([for gethrtime], 
740                [gnupg_cv_func_gethrtime],
741                [AC_TRY_LINK([#include <sys/times.h>],[
742                    hrtime_t tv;
743                    tv = gethrtime();
744                  ],
745                  [gnupg_cv_func_gethrtime=yes],
746                  [gnupg_cv_func_gethrtime=no])
747                ])
748 if test $gnupg_cv_func_gethrtime = yes; then
749      AC_DEFINE([HAVE_GETHRTIME], 1,
750                [Define if you have the `gethrtime(2)' function.])
751      AC_CACHE_CHECK([whether gethrtime is broken], 
752                [gnupg_cv_func_broken_gethrtime],
753                [AC_TRY_RUN([
754                    #include <sys/times.h>
755                    int main () {
756                    hrtime_t tv;
757                    tv = gethrtime(); 
758                  }
759                  ],
760                  [gnupg_cv_func_broken_gethrtime=no],
761                  [gnupg_cv_func_broken_gethrtime=yes],
762                  [gnupg_cv_func_broken_gethrtime=assume-no])
763                 ])
764     if test $gnupg_cv_func_broken_gethrtime = yes; then
765       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
766       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
767     fi
768 fi
769      
770
771 GNUPG_CHECK_MLOCK
772 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
773
774 dnl
775 dnl Check whether we can use Linux capabilities as requested
776 dnl
777 if test "$use_capabilities" = "yes" ; then
778 use_capabilities=no
779 AC_CHECK_HEADERS(sys/capability.h)
780 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
781   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
782   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
783      AC_DEFINE(USE_CAPABILITIES,1,
784                [define if capabilities should be used])
785      AC_SUBST(CAPLIBS,"-lcap")
786      use_capabilities=yes
787   fi
788 fi
789 if test "$use_capabilities" = "no" ; then
790     AC_MSG_WARN([[
791 ***
792 *** The use of capabilities on this system is not possible.
793 *** You need a recent Linux kernel and some patches:
794 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
795 ***   fcap-module-990613.tar.gz     (kernel module)
796 ***   libcap-1.92.tar.gz            (user mode library and utilities)
797 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
798 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
799 ***]])
800 fi
801 fi
802
803
804 GNUPG_CHECK_IPC
805 if test "$ac_cv_header_sys_shm_h" = "yes"; then
806   AC_DEFINE(USE_SHM_COPROCESSING,1,
807             [define if the shared memory interface should be made available])
808 fi
809
810 dnl
811 dnl check whether we have a random device
812 dnl
813 if test "$try_dev_random" = yes ; then
814     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
815     [if test -r "$NAME_OF_DEV_RANDOM" && test -r "$NAME_OF_DEV_URANDOM" ; then
816       ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
817     if test "$ac_cv_have_dev_random" = yes; then
818         AC_DEFINE(HAVE_DEV_RANDOM,1,
819                  [defined if the system supports a random device] )
820     fi
821 else
822     AC_MSG_CHECKING(for random device)
823     ac_cv_have_dev_random=no
824     AC_MSG_RESULT(has been disabled)
825 fi
826
827
828 dnl
829 dnl Figure out the default random module.
830 dnl
831 random_modules=""
832 if test "$use_static_rnd" = default; then
833      if test "$ac_cv_have_dev_random" = yes; then
834         random_modules="rndlinux"
835      else
836          case "${target}" in
837             *-*-mingw32*|*-*-cygwin*)
838                 random_modules="rndw32"
839                 ;;
840             i?86-emx-os2|i?86-*-os2*emx)
841                 random_modules="rndos2"
842                 ;;
843             m68k-atari-mint)
844                 random_modules="rndatari"
845                 ;;
846             i?86-*-msdosdjgpp*)
847                 :
848                 ;;
849             *)
850                 random_modules="rndlinux rndegd rndunix"
851                 AC_DEFINE(USE_ALL_RANDOM_MODULES, 1, 
852                           [Allow to select random modules at runtime.])
853                 ;;
854          esac
855      fi
856 else
857   if test "$use_static_rnd" = auto; then
858      random_modules="rndlinux rndegd rndunix"
859      AC_DEFINE(USE_ALL_RANDOM_MODULES, 1)
860   else
861      random_modules="rnd$use_static_rnd";
862   fi
863 fi
864
865 if test -z "$random_modules"; then
866    AC_MSG_ERROR(no random module available)
867 fi
868 print_egd_warning=no
869 for rndmod in $random_modules "" ; do
870   case "$rndmod" in
871     rndlinux)
872          AC_DEFINE(USE_RNDLINUX,1, 
873                   [Defined if the /dev/random based RNG should be used.])
874          ;;
875     rndunix)
876          AC_DEFINE(USE_RNDUNIX,1, 
877                   [Defined if the default Unix RNG should be used.])
878          print_egd_warning=yes
879           ;;
880     rndegd)
881          AC_DEFINE(USE_RNDEGD,1, 
882                   [Defined if the EGD based RNG should be used.])
883          ;;
884     rndw32)
885          AC_DEFINE(USE_RNDW32,1, 
886                   [Defined if the Windows specific RNG should be used.])
887         ;;
888    esac
889 done
890
891 dnl setup assembler stuff
892 AC_MSG_CHECKING(for mpi assembler functions)
893 if test -f $srcdir/mpi/config.links ; then
894     . $srcdir/mpi/config.links
895     AC_CONFIG_LINKS("$mpi_ln_list")
896     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
897     ac_cv_mpi_sflags="$mpi_sflags"
898     ac_cv_mpi_config_done="yes"
899     AC_MSG_RESULT(done)
900 else
901     AC_MSG_RESULT(failed)
902     AC_MSG_ERROR([mpi/config.links missing!])
903 fi
904 MPI_EXTRA_ASM_OBJS=""
905 show_extraasm=""
906 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
907 for i in $ac_cv_mpi_extra_asm_modules; do
908     show_extraasm="$show_extraasm $i"
909     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
910 done
911 fi
912 AC_SUBST(MPI_EXTRA_ASM_OBJS)
913 MPI_SFLAGS="$ac_cv_mpi_sflags"
914 AC_SUBST(MPI_SFLAGS)
915
916 # Sanity check regex.  Tests adapted from mutt.
917
918 AC_MSG_CHECKING([whether regular expression support is requested])
919 AC_ARG_ENABLE(regex,
920 [  --disable-regex         do not handle regular expressions in trust sigs],
921      use_regex=$enableval, use_regex=yes)
922 AC_MSG_RESULT($use_regex)
923
924 if test "$use_regex" = yes ; then
925   AC_MSG_CHECKING([whether the included regex lib is requested])
926   AC_ARG_WITH(included-regex,
927       [  --with-included-regex   use the included GNU regex library],
928       [gnupg_cv_included_regex=yes],[gnupg_cv_included_regex=no])
929   AC_MSG_RESULT($gnupg_cv_included_regex)
930
931   if test $gnupg_cv_included_regex = no ; then
932      # Does the system have regex functions at all?
933      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
934                            gnupg_cv_included_regex=yes)
935   fi
936
937   if test $gnupg_cv_included_regex = no ; then
938      AC_CACHE_CHECK([whether your system's regexp library is broken],
939        [gnupg_cv_regex_broken],
940        AC_TRY_RUN([
941 #include <unistd.h>
942 #include <regex.h>
943 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
944        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
945
946      if test $gnupg_cv_regex_broken = yes ; then
947       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
948       gnupg_cv_included_regex=yes
949      fi
950   fi
951
952   if test $gnupg_cv_included_regex = yes; then
953      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
954      AC_SUBST(REGEX_O,regex.o)
955   fi
956 else
957
958   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
959 fi
960
961 dnl Do we have zlib? Must do it here because Solaris failed
962 dnl when compiling a conftest (due to the "-lz" from LIBS).
963 use_local_zlib=yes
964 if test "$g10_force_zlib" = "yes"; then
965   :
966 else
967   _cppflags="${CPPFLAGS}"
968   _ldflags="${LDFLAGS}"
969
970   AC_ARG_WITH(zlib,
971   [  --with-zlib=DIR         use libz in DIR],[
972     if test -d "$withval"; then
973       CPPFLAGS="${CPPFLAGS} -I$withval/include"
974       LDFLAGS="${LDFLAGS} -L$withval/lib"
975     fi
976   ])
977
978   AC_CHECK_HEADER(zlib.h,
979       AC_CHECK_LIB(z, deflateInit2_,
980        use_local_zlib=no
981        ZLIBS="-lz",
982        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
983        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
984 fi
985
986 if test "$use_local_zlib" = yes ; then
987     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
988     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
989     ZLIBS="../zlib/libzlib.a"
990 else
991     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
992 fi
993 AC_SUBST(ZLIBS)
994
995
996 #
997 # libusb allows us to use the integrated CCID smartcard reader driver.
998 #
999 # Note, that we need the CVS (unstable) version. 
1000 #
1001 LIBUSB_LIBS=""
1002 if test "$card_support" = yes; then
1003     AC_CHECK_LIB(usb, usb_find_device,
1004                  [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
1005                    AC_DEFINE(HAVE_LIBUSB,1,
1006                    [defined if libusb is available])
1007                  ])
1008 fi
1009 AC_SUBST(LIBUSB_LIBS)
1010
1011
1012
1013 # Allow users to append something to the version string without
1014 # flagging it as development version.  The user version parts is
1015 # considered everything after a dash. 
1016 if test "$development_version" != yes; then
1017   changequote(,)dnl
1018   tmp_pat='[a-zA-Z]'
1019   changequote([,])dnl
1020   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1021     development_version=yes
1022   fi
1023 fi
1024 if test "$development_version" = yes; then
1025     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1026             [Defined if this is not a regular release])
1027 fi
1028
1029 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1030
1031 GNUPG_CHECK_GNUMAKE
1032
1033 # add some extra libs here so that previous tests don't fail for
1034 # mysterious reasons - the final link step should bail out. 
1035 case "${target}" in
1036     *-*-mingw32*)
1037 dnl      NETLIBS="$NETLIBS -lwsock32"
1038         W32LIBS="-lwsock32"
1039         ;;
1040     *)
1041        ;;
1042 esac
1043
1044 AC_SUBST(NETLIBS)
1045 AC_SUBST(W32LIBS)
1046
1047 if test "$GCC" = yes; then
1048     if test "$USE_MAINTAINER_MODE" = "yes"; then
1049         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1050     else
1051         CFLAGS="$CFLAGS -Wall"
1052     fi
1053 fi
1054
1055
1056 if test "$print_egd_warning" = yes; then
1057   AC_MSG_WARN([[
1058 ***
1059 *** The performance of the UNIX random gatherer module is not very good
1060 *** and it does not keep the entropy pool over multiple invocations of
1061 *** GnuPG.  The suggested way to overcome this problem is to use the
1062 ***
1063 ***               Entropy Gathering Daemon (EGD)
1064 ***
1065 *** which provides a entropy source for the whole system.  It is written
1066 *** in Perl and available at the GnuPG FTP servers.  For more information
1067 *** consult the GnuPG webpages:
1068 ***
1069 ***           http://www.gnupg.org/download/#EGD
1070 ***
1071 *** You may want to run ./configure with --enable-static-rnd=egd or
1072 *** --enable-static-rnd=auto to use it.
1073 ***]])
1074 fi
1075
1076 # Note the \\\\ for backslashes.  Autoconf eats one layer, leaving \\
1077
1078 AC_CONFIG_COMMANDS(g10defs.h,[[
1079 cat >g10defs.tmp <<G10EOF
1080 /* Generated automatically by configure */
1081 #ifdef HAVE_DRIVE_LETTERS
1082 #define G10_LOCALEDIR     "c:\\\\lib\\\\gnupg\\\\locale"
1083 #define GNUPG_LIBDIR      "c:\\\\lib\\\\gnupg"
1084 #define GNUPG_LIBEXECDIR  "c:\\\\lib\\\\gnupg"
1085 #define GNUPG_DATADIR     "c:\\\\lib\\\\gnupg"
1086 #define GNUPG_HOMEDIR     "c:\\\\gnupg"
1087 #else
1088 #define G10_LOCALEDIR     "${datadir}/locale"
1089 #define GNUPG_LIBDIR      "${libdir}/gnupg"
1090 #define GNUPG_DATADIR     "${datadir}/gnupg"
1091 #ifdef __VMS
1092 #define GNUPG_HOMEDIR "/SYS\$LOGIN/gnupg" 
1093 #else
1094 #define GNUPG_HOMEDIR "~/.gnupg" 
1095 #endif
1096 #endif
1097 /* those are here to be redefined by handcrafted g10defs.h.
1098    Please note that the string version must not contain more
1099    than one character because the using code assumes strlen()==1 */
1100 #ifdef HAVE_DOSISH_SYSTEM
1101 #define DIRSEP_C '\\\\'
1102 #define EXTSEP_C '.'
1103 #define DIRSEP_S "\\\\"
1104 #define EXTSEP_S "."
1105 #else
1106 #define DIRSEP_C '/'
1107 #define EXTSEP_C '.'
1108 #define DIRSEP_S "/"
1109 #define EXTSEP_S "."
1110 #endif
1111 /* This is the same as VERSION, but should be overridden if the
1112    platform cannot handle things like dots '.' in filenames. */
1113 #define SAFE_VERSION VERSION
1114 G10EOF
1115 cat mpi/mpi-asm-defs.h >>g10defs.tmp 
1116 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
1117     echo "g10defs.h is unchanged"
1118     rm -f g10defs.tmp
1119 else
1120     rm -f g10defs.h
1121     mv g10defs.tmp g10defs.h
1122     echo "g10defs.h created"
1123 fi
1124 ]],[[
1125 prefix=$prefix
1126 exec_prefix=$exec_prefix
1127 libdir=$libdir
1128 libexecdir=$libexecdir
1129 datadir=$datadir
1130 DATADIRNAME=$DATADIRNAME
1131 ]])
1132
1133
1134 AC_CONFIG_FILES([
1135 Makefile
1136 intl/Makefile
1137 po/Makefile.in
1138 util/Makefile
1139 mpi/Makefile
1140 cipher/Makefile
1141 g10/Makefile
1142 keyserver/Makefile
1143 keyserver/gpgkeys_mailto
1144 keyserver/gpgkeys_test
1145 doc/Makefile
1146 tools/Makefile
1147 zlib/Makefile
1148 checks/Makefile
1149 ])
1150 AC_OUTPUT
1151
1152 # Give some feedback
1153 echo
1154 echo   "                Configured for: $PRINTABLE_OS_NAME ($target)"
1155 if test -n "$show_extraasm"; then
1156   echo "  Extra cpu specific functions:$show_extraasm"
1157 fi
1158 echo