build: Update m4 scripts
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.0
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005,
3 #               2006, 2007, 2008, 2010, 2011,
4 #               2012 Free Software Foundation, Inc.
5 #
6 # This file is part of GnuPG.
7 #
8 # GnuPG is free software; you can redistribute it and/or modify
9 # it under the terms of the GNU General Public License as published by
10 # the Free Software Foundation; either version 3 of the License, or
11 # (at your option) any later version.
12 #
13 # GnuPG is distributed in the hope that it will be useful,
14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 # GNU General Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, see <http://www.gnu.org/licenses/>.
20
21 # Process this file with autoconf to produce a configure script.
22 AC_PREREQ(2.61)
23 min_automake_version="1.10"
24
25 # To build a release you need to create a tag with the version number
26 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
27 # bump the version number immediately *after* the release and do
28 # another commit and push so that the git magic is able to work.
29 m4_define([mym4_version], [2.0.27])
30
31 # Below is m4 magic to extract and compute the git revision number,
32 # the decimalized short revision number, a beta version string and a
33 # flag indicating a development version (mym4_isgit).  Note that the
34 # m4 processing is done by autoconf and not during the configure run.
35 m4_define([mym4_revision],
36           m4_esyscmd([git rev-parse --short HEAD | tr -d '\n\r']))
37 m4_define([mym4_revision_dec],
38           m4_esyscmd_s([echo $((0x$(echo ]mym4_revision[|head -c 4)))]))
39 m4_define([mym4_betastring],
40           m4_esyscmd_s([git describe --match 'gnupg-2.[0-9].*[0-9]' --long|\
41                         awk -F- '$3!=0{print"-beta"$3}']))
42 m4_define([mym4_isgit],m4_if(mym4_betastring,[],[no],[yes]))
43 m4_define([mym4_full_version],[mym4_version[]mym4_betastring])
44
45 AC_INIT([gnupg],[mym4_full_version], [http://bugs.gnupg.org])
46
47 NEED_GPG_ERROR_VERSION=1.11
48
49 NEED_LIBGCRYPT_API=1
50 NEED_LIBGCRYPT_VERSION=1.4.0
51
52 NEED_LIBASSUAN_API=2
53 NEED_LIBASSUAN_VERSION=2.0.0
54
55 NEED_KSBA_API=1
56 NEED_KSBA_VERSION=1.0.7
57
58 development_version=mym4_isgit
59 PACKAGE=$PACKAGE_NAME
60 PACKAGE_GT=${PACKAGE_NAME}2
61 VERSION=$PACKAGE_VERSION
62
63 AC_CONFIG_AUX_DIR(scripts)
64 AC_CONFIG_SRCDIR(sm/gpgsm.c)
65 AM_CONFIG_HEADER(config.h)
66 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
67 AC_CANONICAL_HOST
68 AB_INIT
69
70 AC_GNU_SOURCE
71
72 # Some status variables.
73 have_gpg_error=no
74 have_libgcrypt=no
75 have_libassuan=no
76 have_ksba=no
77 have_pth=no
78 have_libusb=no
79 have_adns=no
80
81 use_bzip2=yes
82 use_exec=yes
83 disable_keyserver_path=no
84 use_ccid_driver=yes
85 use_standard_socket=no
86
87 GNUPG_BUILD_PROGRAM(gpg, yes)
88 GNUPG_BUILD_PROGRAM(gpgsm, yes)
89 GNUPG_BUILD_PROGRAM(agent, yes)
90 GNUPG_BUILD_PROGRAM(scdaemon, yes)
91 GNUPG_BUILD_PROGRAM(tools, yes)
92 GNUPG_BUILD_PROGRAM(doc, yes)
93 GNUPG_BUILD_PROGRAM(symcryptrun, no)
94 GNUPG_BUILD_PROGRAM(gpgtar, no)
95
96
97 AC_SUBST(PACKAGE)
98 AC_SUBST(PACKAGE_GT)
99 AC_SUBST(VERSION)
100 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
101 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
102                                 [Name of this package for gettext])
103 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
104 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
105                                         [Bug report address])
106 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
107                                        [Required version of Libgcrypt])
108 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
109                                        [Required version of Libksba])
110
111
112 # The default is to use the modules from this package and the few
113 # other packages in a standard place; i.e where this package gets
114 # installed.  With these options it is possible to override these
115 # ${prefix} depended values with fixed paths, which can't be replaced
116 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
117 AC_ARG_WITH(agent-pgm,
118     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
119           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
120 AC_SUBST(GNUPG_AGENT_PGM)
121 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
122 show_gnupg_agent_pgm="(default)"
123 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
124
125 AC_ARG_WITH(pinentry-pgm,
126     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
127           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
128 AC_SUBST(GNUPG_PINENTRY_PGM)
129 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
130 show_gnupg_pinentry_pgm="(default)"
131 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
132
133
134 AC_ARG_WITH(scdaemon-pgm,
135     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
136           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
137 AC_SUBST(GNUPG_SCDAEMON_PGM)
138 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
139 show_gnupg_scdaemon_pgm="(default)"
140 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
141
142
143 AC_ARG_WITH(dirmngr-pgm,
144     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
145           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
146 AC_SUBST(GNUPG_DIRMNGR_PGM)
147 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
148 show_gnupg_dirmngr_pgm="(default)"
149 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
150
151 AC_ARG_WITH(protect-tool-pgm,
152     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
153           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
154 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
155 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
156 show_gnupg_protect_tool_pgm="(default)"
157 test -n "$GNUPG_PROTECT_TOOL_PGM" \
158       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
159
160
161 # Some folks want to use only the agent from this packet.  Make it
162 # easier for them by providing the configure option
163 # --enable-only-agent.
164 AC_ARG_ENABLE(agent-only,
165     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
166     build_agent_only=$enableval)
167
168 # SELinux support includes tracking of sensitive files to avoid
169 # leaking their contents through processing these files by gpg itself
170 AC_MSG_CHECKING([whether SELinux support is requested])
171 AC_ARG_ENABLE(selinux-support,
172               AC_HELP_STRING([--enable-selinux-support],
173                              [enable SELinux support]),
174               selinux_support=$enableval, selinux_support=no)
175 AC_MSG_RESULT($selinux_support)
176
177 # Allow disabling of bzib2 support.
178 # It is defined only after we confirm the library is available later
179 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
180 AC_ARG_ENABLE(bzip2,
181    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
182    use_bzip2=$enableval)
183 AC_MSG_RESULT($use_bzip2)
184
185 # Configure option to allow or disallow execution of external
186 # programs, like a photo viewer.
187 AC_MSG_CHECKING([whether to enable external program execution])
188 AC_ARG_ENABLE(exec,
189     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
190     use_exec=$enableval)
191 AC_MSG_RESULT($use_exec)
192 if test "$use_exec" = no ; then
193     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
194 fi
195
196 if test "$use_exec" = yes ; then
197   AC_MSG_CHECKING([whether to enable photo ID viewing])
198   AC_ARG_ENABLE(photo-viewers,
199       [  --disable-photo-viewers disable photo ID viewers],
200       [if test "$enableval" = no ; then
201          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
202       fi],enableval=yes)
203   gnupg_cv_enable_photo_viewers=$enableval
204   AC_MSG_RESULT($enableval)
205
206   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
207     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
208     AC_ARG_WITH(photo-viewer,
209         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
210         [if test "$withval" = yes ; then
211            withval=no
212         elif test "$withval" != no ; then
213            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
214                             [if set, restrict photo-viewer to this])
215         fi],withval=no)
216     AC_MSG_RESULT($withval)
217   fi
218
219   AC_MSG_CHECKING([whether to enable external keyserver helpers])
220   AC_ARG_ENABLE(keyserver-helpers,
221       [  --disable-keyserver-helpers  disable all external keyserver support],
222       [if test "$enableval" = no ; then
223          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
224                   [define to disable keyserver helpers])
225       fi],enableval=yes)
226   gnupg_cv_enable_keyserver_helpers=$enableval
227   AC_MSG_RESULT($enableval)
228
229   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
230     # LDAP is defined only after we confirm the library is available later
231     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
232     AC_ARG_ENABLE(ldap,
233       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
234       try_ldap=$enableval, try_ldap=yes)
235     AC_MSG_RESULT($try_ldap)
236
237     AC_MSG_CHECKING([whether HKP keyserver support is requested])
238     AC_ARG_ENABLE(hkp,
239       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
240       try_hkp=$enableval, try_hkp=yes)
241     AC_MSG_RESULT($try_hkp)
242
243     AC_MSG_CHECKING([whether finger key fetching support is requested])
244     AC_ARG_ENABLE(finger,
245       AC_HELP_STRING([--disable-finger],
246         [disable finger key fetching interface only]),
247       try_finger=$enableval, try_finger=yes)
248     AC_MSG_RESULT($try_finger)
249
250     AC_MSG_CHECKING([whether generic object key fetching support is requested])
251     AC_ARG_ENABLE(generic,
252       AC_HELP_STRING([--disable-generic],
253         [disable generic object key fetching interface only]),
254       try_generic=$enableval, try_generic=yes)
255     AC_MSG_RESULT($try_generic)
256
257     AC_MSG_CHECKING([whether email keyserver support is requested])
258     AC_ARG_ENABLE(mailto,
259       AC_HELP_STRING([--enable-mailto],
260         [enable email keyserver interface only]),
261       try_mailto=$enableval, try_mailto=no)
262     AC_MSG_RESULT($try_mailto)
263   fi
264
265   AC_MSG_CHECKING([whether keyserver exec-path is enabled])
266   AC_ARG_ENABLE(keyserver-path,
267       AC_HELP_STRING([--disable-keyserver-path],
268            [disable the exec-path option for keyserver helpers]),
269            [if test "$enableval" = no ; then
270               disable_keyserver_path=yes
271            fi],enableval=yes)
272   AC_MSG_RESULT($enableval)
273 fi
274
275
276 #
277 # Check for the key/uid cache size.  This can't be zero, but can be
278 # pretty small on embedded systems.  This is used for the gpg part.
279 #
280 AC_MSG_CHECKING([for the size of the key and uid cache])
281 AC_ARG_ENABLE(key-cache,
282         AC_HELP_STRING([--enable-key-cache=SIZE],
283                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
284 if test "$enableval" = "no"; then
285    enableval=5
286 elif test "$enableval" = "yes" || test "$enableval" = ""; then
287    enableval=4096
288 fi
289 changequote(,)dnl
290 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
291 changequote([,])dnl
292 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
293    AC_MSG_ERROR([invalid key-cache size])
294 fi
295 AC_MSG_RESULT($key_cache_size)
296 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
297                   [Size of the key and UID caches])
298
299
300
301 #
302 # Check whether we want to use Linux capabilities
303 #
304 AC_MSG_CHECKING([whether use of capabilities is requested])
305 AC_ARG_WITH(capabilities,
306     [  --with-capabilities     use linux capabilities [default=no]],
307 [use_capabilities="$withval"],[use_capabilities=no])
308 AC_MSG_RESULT($use_capabilities)
309
310
311 #
312 # Allow disabling of internal CCID support.
313 # It is defined only after we confirm the library is available later
314 #
315 AC_MSG_CHECKING([whether to enable the internal CCID driver])
316 AC_ARG_ENABLE(ccid-driver,
317               AC_HELP_STRING([--disable-ccid-driver],
318                              [disable the internal CCID driver]),
319               use_ccid_driver=$enableval)
320 AC_MSG_RESULT($use_ccid_driver)
321
322
323 #
324 # To avoid double inclusion of config.h which might happen at some
325 # places, we add the usual double inclusion protection at the top of
326 # config.h.
327 #
328 AH_TOP([
329 #ifndef GNUPG_CONFIG_H_INCLUDED
330 #define GNUPG_CONFIG_H_INCLUDED
331 ])
332
333 #
334 # Stuff which goes at the bottom of config.h.
335 #
336 AH_BOTTOM([
337 /* This is the major version number of GnuPG so that
338    source included files can test for this.  Note, that
339    we use 2 here even for GnuPG 1.9.x. */
340 #define GNUPG_MAJOR_VERSION 2
341
342 /* Now to separate file name parts.
343    Please note that the string version must not contain more
344    than one character because the code assumes strlen()==1 */
345 #ifdef HAVE_DOSISH_SYSTEM
346 #define DIRSEP_C '\\'
347 #define DIRSEP_S "\\"
348 #define EXTSEP_C '.'
349 #define EXTSEP_S "."
350 #define PATHSEP_C ';'
351 #define PATHSEP_S ";"
352 #define EXEEXT_S ".exe"
353 #else
354 #define DIRSEP_C '/'
355 #define DIRSEP_S "/"
356 #define EXTSEP_C '.'
357 #define EXTSEP_S "."
358 #define PATHSEP_C ':'
359 #define PATHSEP_S ":"
360 #define EXEEXT_S ""
361 #endif
362
363 /* This is the same as VERSION, but should be overridden if the
364    platform cannot handle things like dots '.' in filenames. Set
365    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
366    uses for dots and dashes. */
367 #define SAFE_VERSION VERSION
368 #define SAFE_VERSION_DOT  '.'
369 #define SAFE_VERSION_DASH '-'
370
371 /* Some global constants. */
372 #ifdef HAVE_DRIVE_LETTERS
373 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
374 #elif defined(__VMS)
375 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg"
376 #else
377 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
378 #endif
379 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
380
381 /* For some systems (DOS currently), we hardcode the path here.  For
382    POSIX systems the values are constructed by the Makefiles, so that
383    the values may be overridden by the make invocations; this is to
384    comply with the GNU coding standards. */
385 #ifdef HAVE_DRIVE_LETTERS
386  /* FIXME: We need to use a function to determine these values depending
387     on the actual installation directory. */
388 #define GNUPG_BINDIR      "c:\\gnupg"
389 #define GNUPG_LIBEXECDIR  "c:\\gnupg"
390 #define GNUPG_LIBDIR      "c:\\gnupg"
391 #define GNUPG_DATADIR     "c:\\gnupg"
392 #define GNUPG_SYSCONFDIR  "c:\\gnupg"
393 #endif
394
395 /* Derive some other constants. */
396 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
397 #define EXEC_TEMPFILE_ONLY
398 #endif
399
400
401 /* We didn't define endianness above, so get it from OS macros.  This
402    is intended for making fat binary builds on OS X. */
403 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
404 #if defined(__BIG_ENDIAN__)
405 #define BIG_ENDIAN_HOST 1
406 #elif defined(__LITTLE_ENDIAN__)
407 #define LITTLE_ENDIAN_HOST 1
408 #else
409 #error "No endianness found"
410 #endif
411 #endif
412
413
414 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
415    ldap_start_tls_s because that is the actual symbol used in the
416    library.  winldap.h redefines it to our commonly used value,
417    thus we define our usual macro here.  */
418 #ifdef HAVE_LDAP_START_TLS_SA
419 # ifndef HAVE_LDAP_START_TLS_S
420 #  define HAVE_LDAP_START_TLS_S 1
421 # endif
422 #endif
423
424
425 /* Tell libgcrypt not to use its own libgpg-error implementation. */
426 #define USE_LIBGPG_ERROR 1
427
428 /* We use jnlib, so tell other modules about it.  */
429 #define HAVE_JNLIB_LOGGING 1
430
431 /* Our HTTP code is used in estream mode.  */
432 #define HTTP_USE_ESTREAM 1
433
434 /* Under W32 we do an explicit socket initialization, thus we need to
435    avoid the on-demand initialization which would also install an atexit
436    handler.  */
437 #define HTTP_NO_WSASTARTUP
438
439 /* We always include support for the OpenPGP card.  */
440 #define ENABLE_CARD_SUPPORT 1
441
442 /* We don't want the old assuan codes anymore. */
443 #define _ASSUAN_ONLY_GPG_ERRORS 1
444
445 /* We don't need any of the old gcrypt functions.  */
446 #define GCRYPT_NO_DEPRECATED 1
447
448 /* We explicitly need to disable PTH's soft mapping as Debian
449    currently enables it by default for no reason. */
450 #define PTH_SYSCALL_SOFT 0
451
452 /* We want to use the libgcrypt provided memory allocation for
453    asprintf.  */
454 #define _ESTREAM_PRINTF_MALLOC        gcry_malloc
455 #define _ESTREAM_PRINTF_FREE          gcry_free
456 #define _ESTREAM_PRINTF_EXTRA_INCLUDE "util.h"
457
458 #endif /*GNUPG_CONFIG_H_INCLUDED*/
459 ])
460
461
462 AM_MAINTAINER_MODE
463 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
464
465 # Checks for programs.
466 AC_MSG_NOTICE([checking for programs])
467 AC_PROG_MAKE_SET
468 AM_SANITY_CHECK
469 missing_dir=`cd $ac_aux_dir && pwd`
470 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
471 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
472 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
473 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
474 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
475 AC_PROG_AWK
476 AC_PROG_CC
477 AC_PROG_CPP
478 AM_PROG_CC_C_O
479 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
480   AC_MSG_ERROR([[No C-89 compiler found]])
481 fi
482 AC_PROG_INSTALL
483 AC_PROG_LN_S
484 AC_PROG_RANLIB
485 AC_CHECK_TOOL(AR, ar, :)
486 AC_PATH_PROG(PERL,"perl")
487 AC_CHECK_TOOL(WINDRES, windres, :)
488 AC_ISC_POSIX
489 gl_EARLY
490 AC_SYS_LARGEFILE
491 GNUPG_CHECK_FAQPROG
492 GNUPG_CHECK_USTAR
493
494 # We need to compile and run a program on the build machine.  A
495 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
496 # the AC archive is broken for autoconf 2.57.  Given that tehre is no
497 # newer version of that macro, we assume that it is also broken for
498 # autoconf 2.61 and thus we use a simple but usually sufficient
499 # approach.
500 AC_MSG_CHECKING(for cc for build)
501 if test "$cross_compiling" = "yes"; then
502   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
503 else
504   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
505 fi
506 AC_MSG_RESULT($CC_FOR_BUILD)
507 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
508
509
510
511 try_gettext=yes
512 have_dosish_system=no
513 have_w32_system=no
514 use_simple_gettext=no
515 case "${host}" in
516     *-mingw32*)
517         # special stuff for Windoze NT
518         ac_cv_have_dev_random=no
519         AC_DEFINE(USE_ONLY_8DOT3,1,
520                   [set this to limit filenames to the 8.3 format])
521         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
522                   [defined if we must run on a stupid file system])
523         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
524                   [because the Unix gettext has too much overhead on
525                    MingW32 systems and these systems lack Posix functions,
526                    we use a simplified version of gettext])
527         disable_keyserver_path=yes
528         have_dosish_system=yes
529         have_w32_system=yes
530         try_gettext="no"
531         use_simple_gettext=yes
532         ;;
533     i?86-emx-os2 | i?86-*-os2*emx )
534         # OS/2 with the EMX environment
535         ac_cv_have_dev_random=no
536         AC_DEFINE(HAVE_DRIVE_LETTERS)
537         have_dosish_system=yes
538         try_gettext="no"
539         ;;
540
541     i?86-*-msdosdjgpp*)
542         # DOS with the DJGPP environment
543         ac_cv_have_dev_random=no
544         AC_DEFINE(HAVE_DRIVE_LETTERS)
545         have_dosish_system=yes
546         try_gettext="no"
547         ;;
548
549     *-*-freebsd*)
550        # FreeBSD
551        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
552        LDFLAGS="$LDFLAGS -L/usr/local/lib"
553        ;;
554
555     *-*-hpux*)
556         if test -z "$GCC" ; then
557             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
558         fi
559         ;;
560     *-dec-osf4*)
561         if test -z "$GCC" ; then
562             # Suppress all warnings
563             # to get rid of the unsigned/signed char mismatch warnings.
564             CFLAGS="$CFLAGS -w"
565         fi
566         ;;
567     *-dec-osf5*)
568         if test -z "$GCC" ; then
569             # Use the newer compiler `-msg_disable ptrmismatch1' to
570             # get rid of the unsigned/signed char mismatch warnings.
571             # Using this may hide other pointer mismatch warnings, but
572             # it at least lets other warning classes through
573             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
574         fi
575         ;;
576     m68k-atari-mint)
577         ;;
578     *)
579        ;;
580 esac
581
582 if test "$have_dosish_system" = yes; then
583    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
584              [Defined if we run on some of the PCDOS like systems
585               (DOS, Windoze. OS/2) with special properties like
586               no file modes])
587 fi
588 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
589
590 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
591
592 if test "$have_w32_system" = yes; then
593    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
594 fi
595 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
596
597 if test "$disable_keyserver_path" = yes; then
598     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
599               [Defined to disable exec-path for keyserver helpers])
600 fi
601
602 #
603 # Allows enabling the use of a standard socket by default This is
604 # gpg-agent's option --[no-]use-standard-socket.  For Windows we force
605 # the use of this.
606 #
607 AC_MSG_CHECKING([whether to use a standard socket by default])
608 AC_ARG_ENABLE(standard-socket,
609               AC_HELP_STRING([--enable-standard-socket],
610                              [use a standard socket for the agent by default]),
611               use_standard_socket=$enableval)
612 tmp=""
613 if test "$use_standard_socket" != yes; then
614   if test "$have_w32_system" = yes; then
615     use_standard_socket=yes
616     tmp=" (forced)"
617   fi
618 fi
619 AC_MSG_RESULT($use_standard_socket$tmp)
620 if test "$use_standard_socket" = yes; then
621   AC_DEFINE(USE_STANDARD_SOCKET,1,
622             [Use a standard socket for the agent by default])
623 fi
624
625
626 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
627 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
628
629 if test x"$try_hkp" = xyes ; then
630   AC_SUBST(GPGKEYS_HKP,"gpg2keys_hkp$EXEEXT")
631 fi
632
633 if test x"$try_finger" = xyes ; then
634   AC_SUBST(GPGKEYS_FINGER,"gpg2keys_finger$EXEEXT")
635 fi
636
637
638
639 #
640 # Checks for libraries.
641 #
642 AC_MSG_NOTICE([checking for libraries])
643
644
645 #
646 # libgpg-error is a library with error codes shared between GnuPG
647 # related projects.
648 #
649 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
650                   have_gpg_error=yes,have_gpg_error=no)
651
652
653 #
654 # Libgcrypt is our generic crypto library
655 #
656 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
657         have_libgcrypt=yes,have_libgcrypt=no)
658
659
660 #
661 # libassuan is used for IPC
662 #
663 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
664                   have_libassuan=yes,have_libassuan=no)
665 if test "$have_libassuan" = "yes"; then
666   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
667             [version of the libbassuan library])
668 fi
669
670
671
672 #
673 # libksba is our X.509 support library
674 #
675 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
676
677
678 #
679 # libusb allows us to use the integrated CCID smartcard reader driver.
680 #
681 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
682 if test "$use_ccid_driver" = yes ; then
683   AC_CHECK_LIB(usb, usb_bulk_write,
684                 [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
685                   AC_DEFINE(HAVE_LIBUSB,1,
686                            [defined if libusb is available])
687                   have_libusb=yes
688                ])
689   AC_CHECK_FUNCS(usb_create_match)
690 fi
691 AC_SUBST(LIBUSB_LIBS)
692
693 #
694 # Check wether it is necessary to link against libdl.
695 #
696 gnupg_dlopen_save_libs="$LIBS"
697 LIBS=""
698 AC_SEARCH_LIBS(dlopen, c dl,,,)
699 DL_LIBS=$LIBS
700 AC_SUBST(DL_LIBS)
701 LIBS="$gnupg_dlopen_save_libs"
702
703 #
704 # Checks for symcryptrun:
705 #
706
707 # libutil has openpty() and login_tty().
708 AC_CHECK_LIB(util, openpty,
709               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
710                 AC_DEFINE(HAVE_LIBUTIL,1,
711                          [defined if libutil is available])
712              ])
713 AC_SUBST(LIBUTIL_LIBS)
714
715 # shred is used to clean temporary plain text files.
716 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
717 AC_DEFINE_UNQUOTED(SHRED,
718         "${SHRED}", [defines the filename of the shred program])
719
720
721
722 #
723 # Check whether the GNU Pth library is available
724 # Note, that we include a Pth emulation for W32.
725 #
726 GNUPG_PATH_PTH
727 if test "$have_pth" = "yes"; then
728   AC_DEFINE(USE_GNU_PTH, 1,
729               [Defined if the GNU Portable Thread Library should be used])
730 else
731   AC_MSG_WARN([[
732 ***
733 *** To support concurrent access to the gpg-agent and the SCdaemon
734 *** we need the support of the GNU Portable Threads Library.
735 *** Download it from ftp://ftp.gnu.org/gnu/pth/
736 *** On a Debian GNU/Linux system you might want to try
737 ***   apt-get install libpth-dev
738 ***]])
739 fi
740
741
742 AC_MSG_NOTICE([checking for networking options])
743
744 #
745 # Must check for network library requirements before doing link tests
746 # for ldap, for example. If ldap libs are static (or dynamic and without
747 # ELF runtime link paths), then link will fail and LDAP support won't
748 # be detected.
749 #
750 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
751         [NETLIBS="-lnsl $NETLIBS"]))
752 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
753         [NETLIBS="-lsocket $NETLIBS"]))
754
755
756 #
757 # Check for ADNS.
758 #
759 _cppflags="${CPPFLAGS}"
760 _ldflags="${LDFLAGS}"
761 AC_ARG_WITH(adns,
762             AC_HELP_STRING([--with-adns=DIR],
763                            [look for the adns library in DIR]),
764             [if test -d "$withval"; then
765                CPPFLAGS="${CPPFLAGS} -I$withval/include"
766                LDFLAGS="${LDFLAGS} -L$withval/lib"
767              fi])
768 if test "$with_adns" != "no"; then
769   AC_CHECK_HEADERS(adns.h,
770                 AC_CHECK_LIB(adns, adns_init,
771                              [have_adns=yes],
772                              [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}]),
773                 [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}])
774 fi
775 if test "$have_adns" = "yes"; then
776   ADNSLIBS="-ladns"
777 fi
778 AC_SUBST(ADNSLIBS)
779 # Newer adns versions feature a free function to be used under W32.
780 AC_CHECK_FUNCS(adns_free)
781
782
783 #
784 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
785 #
786 if test x"$try_hkp" = xyes || test x"$try_http" = xyes ; then
787   AC_ARG_ENABLE(dns-srv,
788      AC_HELP_STRING([--disable-dns-srv],
789                     [disable the use of DNS SRV in HKP and HTTP]),
790                 use_dns_srv=$enableval,use_dns_srv=yes)
791 fi
792
793 AC_ARG_ENABLE(dns-pka,
794    AC_HELP_STRING([--disable-dns-pka],
795         [disable the use of PKA records in DNS]),
796    use_dns_pka=$enableval,use_dns_pka=yes)
797
798 AC_ARG_ENABLE(dns-cert,
799    AC_HELP_STRING([--disable-dns-cert],
800         [disable the use of CERT records in DNS]),
801    use_dns_cert=$enableval,use_dns_cert=yes)
802
803 if test x"$use_dns_pka" = xyes || test x"$use_dns_srv" = xyes \
804    || test x"$use_dns_cert" = xyes; then
805   _dns_save_libs=$LIBS
806   LIBS=""
807   # the double underscore thing is a glibc-ism?
808   AC_SEARCH_LIBS(res_query,resolv bind,,
809                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
810   AC_SEARCH_LIBS(dn_expand,resolv bind,,
811                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
812   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
813                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
814
815   if test x"$have_resolver" != xno ; then
816
817     # Make sure that the BIND 4 resolver interface is workable before
818     # enabling any code that calls it.  At some point I'll rewrite the
819     # code to use the BIND 8 resolver API.
820     # We might also want to use adns instead.  Problem with ADNS is that
821     # it does not support v6.
822
823     AC_MSG_CHECKING([whether the resolver is usable])
824     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
825 #include <netinet/in.h>
826 #include <arpa/nameser.h>
827 #include <resolv.h>]],
828 [[unsigned char answer[PACKETSZ];
829   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
830   dn_skipname(0,0);
831   dn_expand(0,0,0,0,0);
832 ]])],have_resolver=yes,have_resolver=no)
833     AC_MSG_RESULT($have_resolver)
834
835     # This is Apple-specific and somewhat bizarre as they changed the
836     # define in bind 8 for some reason.
837
838     if test x"$have_resolver" != xyes ; then
839        AC_MSG_CHECKING(
840              [whether I can make the resolver usable with BIND_8_COMPAT])
841        AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
842 #include <sys/types.h>
843 #include <netinet/in.h>
844 #include <arpa/nameser.h>
845 #include <resolv.h>]],
846 [[unsigned char answer[PACKETSZ];
847   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
848   dn_skipname(0,0); dn_expand(0,0,0,0,0);
849 ]])],[have_resolver=yes ; need_compat=yes])
850        AC_MSG_RESULT($have_resolver)
851     fi
852   fi
853
854   if test x"$have_resolver" = xyes ; then
855      DNSLIBS=$LIBS
856
857      if test x"$use_dns_srv" = xyes ; then
858         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
859      fi
860
861      if test x"$use_dns_pka" = xyes ; then
862         AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
863      fi
864
865      if test x"$use_dns_cert" = xyes ; then
866         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
867      fi
868
869      if test x"$need_compat" = xyes ; then
870         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
871      fi
872   else
873      # If we have no resolver library but ADNS (e.g. under W32) enable the
874      # code parts which can be used with ADNS.
875      if test x"$have_adns" = xyes ; then
876         DNSLIBS="$ADNSLIBS"
877         AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
878
879         if test x"$use_dns_srv" = xyes ; then
880            AC_DEFINE(USE_DNS_SRV,1)
881         fi
882
883         if test x"$use_dns_pka" = xyes ; then
884            AC_DEFINE(USE_DNS_PKA,1)
885         fi
886
887         if test x"$use_dns_cert" = xyes ; then
888            AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
889         fi
890      else
891         use_dns_srv=no
892         use_dns_pka=no
893         use_dns_cert=no
894      fi
895   fi
896
897   LIBS=$_dns_save_libs
898 fi
899
900 AC_SUBST(DNSLIBS)
901
902 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
903
904
905 #
906 # Check for LDAP
907 #
908 if test "$try_ldap" = yes ; then
909    GNUPG_CHECK_LDAP($NETLIBS)
910 fi
911
912 #
913 # Check for curl.  We fake the curl API if libcurl isn't installed.
914 # We require 7.10 or later as we use curl_version_info().
915 #
916 LIBCURL_CHECK_CONFIG([yes],[7.10],,[fake_curl=yes])
917 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
918
919 # Generic, for us, means curl
920
921 if test x"$try_generic" = xyes ; then
922    AC_SUBST(GPGKEYS_CURL,"gpg2keys_curl$EXEEXT")
923 fi
924
925 #
926 # Check for sendmail
927 #
928 # This isn't necessarily sendmail itself, but anything that gives a
929 # sendmail-ish interface to the outside world.  That includes Exim,
930 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
931 if test "$try_mailto" = yes ; then
932   AC_ARG_WITH(mailprog,
933       AC_HELP_STRING([--with-mailprog=NAME],
934                      [use "NAME -t" for mail transport]),
935              ,with_mailprog=yes)
936
937   if test x"$with_mailprog" = xyes ; then
938     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
939     if test "$ac_cv_path_SENDMAIL" ; then
940       GPGKEYS_MAILTO="gpg2keys_mailto"
941     fi
942   elif test x"$with_mailprog" != xno ; then
943     AC_MSG_CHECKING([for a mail transport program])
944     AC_SUBST(SENDMAIL,$with_mailprog)
945     AC_MSG_RESULT($with_mailprog)
946     GPGKEYS_MAILTO="gpg2keys_mailto"
947   fi
948 fi
949
950 AC_SUBST(GPGKEYS_MAILTO)
951
952 #
953 # Construct a printable name of the OS
954 #
955 case "${host}" in
956     *-mingw32*)
957         PRINTABLE_OS_NAME="MingW32"
958         ;;
959     *-*-cygwin*)
960         PRINTABLE_OS_NAME="Cygwin"
961         ;;
962     i?86-emx-os2 | i?86-*-os2*emx )
963         PRINTABLE_OS_NAME="OS/2"
964         ;;
965     i?86-*-msdosdjgpp*)
966         PRINTABLE_OS_NAME="MSDOS/DJGPP"
967         try_dynload=no
968         ;;
969     *-linux*)
970         PRINTABLE_OS_NAME="GNU/Linux"
971         ;;
972     *)
973         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
974         ;;
975 esac
976 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
977                    [A human readable text with the name of the OS])
978
979
980 #
981 # Checking for iconv
982 #
983 missing_iconv=no
984 AM_ICONV
985 if test "$am_cv_func_iconv" != yes; then
986    missing_iconv=yes
987 fi
988
989
990 #
991 # Check for gettext
992 #
993 # This is "GNU gnupg" - The project-id script from gettext
994 #                       needs this string
995 #
996 AC_MSG_NOTICE([checking for gettext])
997 AM_PO_SUBDIRS
998 AM_GNU_GETTEXT_VERSION([0.17])
999 if test "$try_gettext" = yes; then
1000   AM_GNU_GETTEXT([external],[need-ngettext])
1001
1002   # gettext requires some extra checks.  These really should be part of
1003   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1004   # function checks to here.
1005
1006   AC_CHECK_FUNCS(strchr)
1007 else
1008   USE_NLS=no
1009   USE_INCLUDED_LIBINTL=no
1010   BUILD_INCLUDED_LIBINTL=no
1011   POSUB=po
1012   AC_SUBST(USE_NLS)
1013   AC_SUBST(USE_INCLUDED_LIBINTL)
1014   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1015   AC_SUBST(POSUB)
1016 fi
1017
1018 # We use HAVE_LANGINFO_CODESET in a couple of places.
1019 AM_LANGINFO_CODESET
1020
1021 # Checks required for our use locales
1022 gt_LC_MESSAGES
1023
1024
1025 #
1026 # SELinux support
1027 #
1028 if test "$selinux_support" = yes ; then
1029   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1030 fi
1031
1032
1033 #
1034 # Checks for header files.
1035 #
1036 AC_MSG_NOTICE([checking for header files])
1037 AC_HEADER_STDC
1038 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h])
1039 AC_CHECK_HEADERS([pty.h utmp.h pwd.h inttypes.h])
1040 AC_HEADER_TIME
1041
1042
1043 #
1044 # Checks for typedefs, structures, and compiler characteristics.
1045 #
1046 AC_MSG_NOTICE([checking for system characteristics])
1047 AC_C_CONST
1048 AC_C_INLINE
1049 AC_C_VOLATILE
1050 AC_TYPE_SIZE_T
1051 AC_TYPE_MODE_T
1052 AC_TYPE_SIGNAL
1053 AC_DECL_SYS_SIGLIST
1054
1055 gl_HEADER_SYS_SOCKET
1056 gl_TYPE_SOCKLEN_T
1057
1058 AC_ARG_ENABLE(endian-check,
1059               AC_HELP_STRING([--disable-endian-check],
1060               [disable the endian check and trust the OS provided macros]),
1061               endiancheck=$enableval,endiancheck=yes)
1062
1063 if test x"$endiancheck" = xyes ; then
1064   GNUPG_CHECK_ENDIAN
1065 fi
1066
1067 # fixme: we should get rid of the byte type
1068 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1069 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1070 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1071 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1072 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1073
1074 AC_CHECK_SIZEOF(unsigned short)
1075 AC_CHECK_SIZEOF(unsigned int)
1076 AC_CHECK_SIZEOF(unsigned long)
1077 AC_CHECK_SIZEOF(unsigned long long)
1078 AC_CHECK_SIZEOF(time_t,,[[
1079 #include <stdio.h>
1080 #if TIME_WITH_SYS_TIME
1081 # include <sys/time.h>
1082 # include <time.h>
1083 #else
1084 # if HAVE_SYS_TIME_H
1085 #  include <sys/time.h>
1086 # else
1087 #  include <time.h>
1088 # endif
1089 #endif
1090 ]])
1091
1092
1093 # Ensure that we have UINT64_C before we bother to check for uint64_t
1094 # Fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
1095 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
1096    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <inttypes.h>]],
1097                                       [[uint64_t foo=UINT64_C(42);]])],
1098                                       [gnupg_cv_uint64_c_works=yes],
1099                                       [gnupg_cv_uint64_c_works=no]   ))
1100 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
1101    AC_CHECK_SIZEOF(uint64_t)
1102 fi
1103
1104 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1105    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1106    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1107     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1108 fi
1109
1110
1111 #
1112 # Checks for library functions.
1113 #
1114 AC_MSG_NOTICE([checking for library functions])
1115 AC_CHECK_DECLS(getpagesize)
1116 AC_FUNC_FSEEKO
1117 AC_FUNC_VPRINTF
1118 AC_FUNC_FORK
1119 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap])
1120 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r])
1121 AC_CHECK_FUNCS([unsetenv fcntl ftruncate inet_ntop])
1122 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1123 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1124 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe stat getaddrinfo])
1125 AC_CHECK_FUNCS([ttyname rand ftello fsync stat])
1126
1127 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1128
1129 #
1130 # These are needed by libjnlib - fixme: we should use a jnlib.m4
1131 # Note:  We already checked pwd.h.
1132 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol])
1133 AC_CHECK_FUNCS([memrchr isascii timegm getrusage setrlimit stat setlocale])
1134 AC_CHECK_FUNCS([flockfile funlockfile fopencookie funopen getpwnam getpwuid])
1135
1136 #
1137 # gnulib checks
1138 #
1139 gl_SOURCE_BASE([gl])
1140 gl_M4_BASE([gl/m4])
1141 gl_MODULES([setenv mkdtemp xsize strpbrk])
1142 gl_INIT
1143
1144
1145 #
1146 # W32 specific test
1147 #
1148 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1149
1150 #
1151 # Sanity check regex.  Tests adapted from mutt.
1152 #
1153 AC_MSG_CHECKING([whether regular expression support is requested])
1154 AC_ARG_ENABLE(regex,
1155   AC_HELP_STRING([--disable-regex],
1156     [do not handle regular expressions in trust signatures]),
1157   use_regex=$enableval, use_regex=yes)
1158 AC_MSG_RESULT($use_regex)
1159
1160 if test "$use_regex" = yes ; then
1161   _cppflags="${CPPFLAGS}"
1162   _ldflags="${LDFLAGS}"
1163   AC_ARG_WITH(regex,
1164      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1165       [
1166       if test -d "$withval" ; then
1167         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1168         LDFLAGS="${LDFLAGS} -L$withval/lib"
1169       fi
1170       ],withval="")
1171
1172   # Does the system have regex functions at all?
1173   AC_SEARCH_LIBS([regcomp], [regex])
1174   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1175
1176   if test $gnupg_cv_have_regex = no; then
1177     use_regex=no
1178   else
1179     if test x"$cross_compiling" = xyes; then
1180       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1181     else
1182       AC_CACHE_CHECK([whether your system's regexp library is broken],
1183        [gnupg_cv_regex_broken],
1184        AC_TRY_RUN([
1185 #include <unistd.h>
1186 #include <regex.h>
1187 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1188        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1189
1190       if test $gnupg_cv_regex_broken = yes; then
1191         AC_MSG_WARN([your regex is broken - disabling regex use])
1192         use_regex=no
1193       fi
1194     fi
1195   fi
1196   CPPFLAGS="${_cppflags}"
1197   LDFLAGS="${_ldflags}"
1198 fi
1199
1200 if test "$use_regex" != yes ; then
1201   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1202 fi
1203 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1204
1205
1206
1207 #
1208 # Do we have zlib? Must do it here because Solaris failed
1209 # when compiling a conftest (due to the "-lz" from LIBS).
1210 # Note that we combine zlib and bzlib2 in ZLIBS.
1211 #
1212 missing_zlib=yes
1213 _cppflags="${CPPFLAGS}"
1214 _ldflags="${LDFLAGS}"
1215 AC_ARG_WITH(zlib,
1216   [  --with-zlib=DIR         use libz in DIR],[
1217     if test -d "$withval"; then
1218       CPPFLAGS="${CPPFLAGS} -I$withval/include"
1219       LDFLAGS="${LDFLAGS} -L$withval/lib"
1220     fi
1221   ])
1222
1223 AC_CHECK_HEADER(zlib.h,
1224       AC_CHECK_LIB(z, deflateInit2_,
1225        [
1226        ZLIBS="-lz"
1227        missing_zlib=no
1228        ],
1229        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1230        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1231
1232 #
1233 # Check whether we can support bzip2
1234 #
1235 if test "$use_bzip2" = yes ; then
1236   _cppflags="${CPPFLAGS}"
1237   _ldflags="${LDFLAGS}"
1238   AC_ARG_WITH(bzip2,
1239      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1240       [
1241       if test -d "$withval" ; then
1242         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1243         LDFLAGS="${LDFLAGS} -L$withval/lib"
1244       fi
1245       ],withval="")
1246
1247   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1248   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1249   # woefully out of date.
1250   if test "$withval" != no ; then
1251      AC_CHECK_HEADER(bzlib.h,
1252         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1253           [
1254           have_bz2=yes
1255           ZLIBS="$ZLIBS -lbz2"
1256           AC_DEFINE(HAVE_BZIP2,1,
1257                   [Defined if the bz2 compression library is available])
1258           ],
1259           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1260           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1261   fi
1262 fi
1263 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1264 AC_SUBST(ZLIBS)
1265
1266
1267 # Check for readline support
1268 GNUPG_CHECK_READLINE
1269
1270
1271 if test "$development_version" = yes; then
1272     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1273             [Defined if this is not a regular release])
1274 fi
1275
1276 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1277
1278 GNUPG_CHECK_GNUMAKE
1279
1280 # Add some extra libs here so that previous tests don't fail for
1281 # mysterious reasons - the final link step should bail out.
1282 # W32SOCKLIBS is also defined so that if can be used for tools not
1283 # requiring any network stuff but linking to code in libcommon which
1284 # tracks in winsock stuff (e.g. init_common_subsystems.
1285 if test "$have_w32_system" = yes; then
1286    W32SOCKLIBS="-lws2_32"
1287    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1288 fi
1289
1290 AC_SUBST(NETLIBS)
1291 AC_SUBST(W32SOCKLIBS)
1292
1293 #
1294 # Setup gcc specific options
1295 #
1296 AC_MSG_NOTICE([checking for cc features])
1297 if test "$GCC" = yes; then
1298     # Check whether gcc does not emit a diagnositc for unknow -Wno-*
1299     # options.  This is the case for gcc >= 4.6
1300     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1301     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1302 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1303 #kickerror
1304 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1305     AC_MSG_RESULT($_gcc_silent_wno)
1306
1307     # Note that it is okay to use CFLAGS here because this are just
1308     # warning options and the user should have a chance of overriding
1309     # them.
1310     if test "$USE_MAINTAINER_MODE" = "yes"; then
1311         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1312         CFLAGS="$CFLAGS -Wformat -Wno-format-y2k -Wformat-security"
1313         if test x"$_gcc_silent_wno" = xyes ; then
1314           _gcc_wopt=yes
1315         else
1316           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1317           _gcc_cflags_save=$CFLAGS
1318           CFLAGS="-Wno-missing-field-initializers"
1319           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1320                             [_gcc_wopt=yes],[_gcc_wopt=no])
1321           AC_MSG_RESULT($_gcc_wopt)
1322           CFLAGS=$_gcc_cflags_save;
1323         fi
1324         if test x"$_gcc_wopt" = xyes ; then
1325           CFLAGS="$CFLAGS -W -Wno-sign-compare -Wno-missing-field-initializers"
1326         fi
1327
1328         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1329         _gcc_cflags_save=$CFLAGS
1330         CFLAGS="-Wdeclaration-after-statement"
1331         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1332                           [_gcc_wopt=yes],[_gcc_wopt=no])
1333         AC_MSG_RESULT($_gcc_wopt)
1334         CFLAGS=$_gcc_cflags_save;
1335         if test x"$_gcc_wopt" = xyes ; then
1336           CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1337         fi
1338     else
1339         CFLAGS="$CFLAGS -Wall"
1340     fi
1341
1342     if test x"$_gcc_silent_wno" = xyes ; then
1343       _gcc_psign=yes
1344     else
1345       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1346       _gcc_cflags_save=$CFLAGS
1347       CFLAGS="-Wno-pointer-sign"
1348       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1349                         [_gcc_psign=yes],[_gcc_psign=no])
1350       AC_MSG_RESULT($_gcc_psign)
1351       CFLAGS=$_gcc_cflags_save;
1352     fi
1353     if test x"$_gcc_psign" = xyes ; then
1354        CFLAGS="$CFLAGS -Wno-pointer-sign"
1355     fi
1356
1357     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1358     _gcc_cflags_save=$CFLAGS
1359     CFLAGS="-Wpointer-arith"
1360     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],[_gcc_psign=yes],[_gcc_psign=no])
1361     AC_MSG_RESULT($_gcc_psign)
1362     CFLAGS=$_gcc_cflags_save;
1363     if test x"$_gcc_psign" = xyes ; then
1364        CFLAGS="$CFLAGS -Wpointer-arith"
1365     fi
1366
1367     # The undocumented option -Wno-psabi suppresses the annoying
1368     #   "the ABI of passing union with long double has changed in GCC 4.4"
1369     # which is emitted in estream-printf.c but entirely irrelvant
1370     # because that union is local to the file.
1371     if test x"$_gcc_silent_wno" = xyes ; then
1372        CFLAGS="$CFLAGS -Wno-psabi"
1373     fi
1374 fi
1375
1376
1377 #
1378 # This is handy for debugging so the compiler doesn't rearrange
1379 # things and eliminate variables.
1380 #
1381 AC_ARG_ENABLE(optimization,
1382    AC_HELP_STRING([--disable-optimization],
1383                   [disable compiler optimization]),
1384                   [if test $enableval = no ; then
1385                       CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]]//'`
1386                    fi])
1387
1388 #
1389 # Prepare building of estream
1390 #
1391 estream_INIT
1392
1393
1394 #
1395 # Decide what to build
1396 #
1397 if test "$have_adns" = "yes"; then
1398   AC_SUBST(GPGKEYS_KDNS, "gpg2keys_kdns$EXEEXT")
1399 fi
1400
1401
1402 missing_pth=no
1403 if test $have_ksba = no; then
1404   build_gpgsm=no
1405   build_scdaemon=no
1406 fi
1407
1408 build_agent_threaded=""
1409 if test "$build_agent" = "yes"; then
1410   if test $have_pth = no; then
1411      build_agent_threaded="(not multi-threaded)"
1412      missing_pth=yes
1413   fi
1414 fi
1415
1416 build_scdaemon_extra=""
1417 if test "$build_scdaemon" = "yes"; then
1418   tmp=""
1419   if test $have_pth = no; then
1420      build_scdaemon_extra="not multi-threaded"
1421      tmp=", "
1422      missing_pth=yes
1423   fi
1424   if test $have_libusb = no; then
1425      build_scdaemon_extra="${tmp}without internal CCID driver"
1426      tmp=", "
1427   fi
1428   if test -n "$build_scdaemon_extra"; then
1429      build_scdaemon_extra="(${build_scdaemon_extra})"
1430   fi
1431 fi
1432
1433
1434 if test "$build_agent_only" = "yes" ; then
1435   build_gpg=no
1436   build_gpgsm=no
1437   build_scdaemon=no
1438   build_tools=no
1439   build_doc=no
1440 fi
1441
1442
1443 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1444 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1445 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1446 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1447 AM_CONDITIONAL(BUILD_TOOLS, test "$build_tools" = "yes")
1448 AM_CONDITIONAL(BUILD_DOC,   test "$build_doc" = "yes")
1449 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1450 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1451
1452 AM_CONDITIONAL(RUN_GPG_TESTS,
1453         test x$cross_compiling = xno -a "$build_gpg" = yes )
1454
1455
1456 #
1457 # Provide information about the build.
1458 #
1459 BUILD_REVISION="mym4_revision"
1460 AC_SUBST(BUILD_REVISION)
1461 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1462                    [GIT commit id revision used to build this package])
1463
1464 changequote(,)dnl
1465 BUILD_FILEVERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./;s/\./,/g'`
1466 changequote([,])dnl
1467 BUILD_FILEVERSION="${BUILD_FILEVERSION}mym4_revision_dec"
1468 AC_SUBST(BUILD_FILEVERSION)
1469
1470 BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1471 AC_SUBST(BUILD_TIMESTAMP)
1472 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1473                    [The time this package was configured for a build])
1474 BUILD_HOSTNAME="$ac_hostname"
1475 AC_SUBST(BUILD_HOSTNAME)
1476
1477
1478 #
1479 # Print errors here so that they are visible all
1480 # together and the user can acquire them all together.
1481 #
1482 die=no
1483 if test "$have_gpg_error" = "no"; then
1484    die=yes
1485    AC_MSG_NOTICE([[
1486 ***
1487 *** You need libgpg-error to build this program.
1488 **  This library is for example available at
1489 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1490 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1491 ***]])
1492 fi
1493 if test "$have_libgcrypt" = "no"; then
1494    die=yes
1495    AC_MSG_NOTICE([[
1496 ***
1497 *** You need libgcrypt to build this program.
1498 **  This library is for example available at
1499 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1500 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API is required.)
1501 ***]])
1502 fi
1503 if test "$have_libassuan" = "no"; then
1504    die=yes
1505    AC_MSG_NOTICE([[
1506 ***
1507 *** You need libassuan to build this program.
1508 *** This library is for example available at
1509 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1510 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1511 ***]])
1512 fi
1513 if test "$have_ksba" = "no"; then
1514     AC_MSG_NOTICE([[
1515 ***
1516 *** You need libksba to build this program.
1517 *** This library is for example available at
1518 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1519 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1520 ***]])
1521 fi
1522 if test "$missing_pth" = "yes"; then
1523     AC_MSG_NOTICE([[
1524 ***
1525 *** It is now required to build with support for the
1526 *** GNU Portable Threads Library (Pth). Please install this
1527 *** library first.  The library is for example available at
1528 ***   ftp://ftp.gnu.org/gnu/pth/
1529 *** On a Debian GNU/Linux system you can install it using
1530 ***   apt-get install libpth-dev
1531 *** To build GnuPG for Windows you need to use the W32PTH
1532 *** package; available at:
1533 ***   ftp://ftp.g10code.com/g10code/w32pth/
1534 ***]])
1535    die=yes
1536 fi
1537 if test "$missing_zlib" = "yes"; then
1538     AC_MSG_NOTICE([[
1539 ***
1540 *** The zlib compression library is required.
1541 *** Please install a suitable development package
1542 *** (e.g. Debian package zlib1g-dev) or download
1543 *** it from http://zlib.net and build yourself.
1544 ***]])
1545    die=yes
1546 fi
1547 if test "$missing_iconv" = "yes"; then
1548     AC_MSG_NOTICE([[
1549 ***
1550 *** It is now required to build with support for iconv
1551 *** Please install a suitable iconv implementation.
1552 ***]])
1553    die=yes
1554 fi
1555
1556 if test "$die" = "yes"; then
1557     AC_MSG_ERROR([[
1558 ***
1559 *** Required libraries not found. Please consult the above messages
1560 *** and install them before running configure again.
1561 ***]])
1562 fi
1563
1564
1565
1566 AC_CONFIG_FILES([ m4/Makefile
1567 Makefile
1568 po/Makefile.in
1569 gl/Makefile
1570 include/Makefile
1571 jnlib/Makefile
1572 common/Makefile
1573 common/w32info-rc.h
1574 kbx/Makefile
1575 g10/Makefile
1576 sm/Makefile
1577 agent/Makefile
1578 scd/Makefile
1579 keyserver/Makefile
1580 keyserver/gpg2keys_mailto
1581 keyserver/gpg2keys_test
1582 tools/gpg-zip
1583 tools/Makefile
1584 doc/Makefile
1585 tests/Makefile
1586 tests/openpgp/Makefile
1587 tests/pkits/Makefile
1588 ])
1589 AC_OUTPUT
1590
1591
1592 echo "
1593         GnuPG v${VERSION} has been configured as follows:
1594
1595         Revision:  mym4_revision  (mym4_revision_dec)
1596         Platform:  $PRINTABLE_OS_NAME ($host)
1597
1598         OpenPGP:   $build_gpg
1599         S/MIME:    $build_gpgsm
1600         Agent:     $build_agent $build_agent_threaded
1601         Smartcard: $build_scdaemon $build_scdaemon_extra
1602         Gpgtar:    $build_gpgtar
1603
1604         Protect tool:      $show_gnupg_protect_tool_pgm
1605         Default agent:     $show_gnupg_agent_pgm
1606         Default pinentry:  $show_gnupg_pinentry_pgm
1607         Default scdaemon:  $show_gnupg_scdaemon_pgm
1608         Default dirmngr:   $show_gnupg_dirmngr_pgm
1609 "
1610 if test x"$use_regex" != xyes ; then
1611 echo "
1612         Warning: No regular expression support available.
1613                  OpenPGP trust signatures won't work.
1614                  gpg-check-pattern will not be build.
1615 "
1616 fi
1617 if test "x${gpg_config_script_warn}" != x; then
1618 cat <<G10EOF
1619         Warning: Mismatches between the target platform and the
1620                  to be used libraries have been detected for:
1621                   ${gpg_config_script_warn}
1622                  Please check above for more warning messages.
1623
1624 G10EOF
1625 fi