(DLLIBS): Fixed last change.
[gnupg.git] / configure.ac
1 dnl Configure.ac script for GnuPG
2 dnl Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 dnl               2003 Free Software Foundation, Inc.
4 dnl
5 dnl This file is part of GnuPG.
6 dnl
7 dnl GnuPG is free software; you can redistribute it and/or modify
8 dnl it under the terms of the GNU General Public License as published by
9 dnl the Free Software Foundation; either version 2 of the License, or
10 dnl (at your option) any later version.
11 dnl 
12 dnl GnuPG is distributed in the hope that it will be useful,
13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 dnl GNU General Public License for more details.
16 dnl 
17 dnl You should have received a copy of the GNU General Public License
18 dnl along with this program; if not, write to the Free Software
19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20 dnl
21 dnl (Process this file with autoconf to produce a configure script.)
22 dnlAC_REVISION($Revision$)dnl
23
24 AC_PREREQ(2.52)
25
26 # Remember to change the version number immediately *after* a release
27 # and remove the "-cvs" or "rc" suffix immediately *before* a release.
28 AC_INIT(gnupg, 1.3.4-cvs, bug-gnupg@gnu.org)
29 # Set development_version to yes if the minor number is odd or you
30 # feel that the default check for a development version is not
31 # sufficient.
32 development_version=yes
33
34 ALL_LINGUAS="de"
35
36 AC_CONFIG_AUX_DIR(scripts)
37 AC_CONFIG_SRCDIR(g10/g10.c)
38 AC_CANONICAL_TARGET()
39 AM_INIT_AUTOMAKE
40 AM_CONFIG_HEADER(config.h)
41
42 AC_GNU_SOURCE
43
44 dnl
45 dnl  Check for random module options
46 dnl
47 AC_MSG_CHECKING([which random module to use])
48 AC_ARG_ENABLE(static-rnd,
49     [  --enable-static-rnd=[egd|unix|linux|auto]  ],
50 [use_static_rnd=$enableval], [use_static_rnd=default] )
51
52 if test "$use_static_rnd" = no; then
53     use_static_rnd=default
54 fi
55
56 case "$use_static_rnd" in
57     egd | linux | unix | default )
58       AC_MSG_RESULT($use_static_rnd)
59       ;;
60     auto )
61       AC_MSG_RESULT(automagically selected at runtime)
62       ;;
63     * )
64       AC_MSG_RESULT(invalid argument)
65       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
66       ;;
67 esac
68
69 AC_ARG_WITH(egd-socket,
70     [  --with-egd-socket=NAME  use NAME for the EGD socket],
71             egd_socket_name="$withval", egd_socket_name="" )
72 AC_DEFINE_UNQUOTED(EGD_SOCKET_NAME, "$egd_socket_name",
73                    [Define if you don't want the default EGD socket name.
74                     For details see cipher/rndegd.c])
75
76
77 dnl
78 dnl See whether the user wants to disable checking for /dev/random
79
80 AC_MSG_CHECKING([whether use of /dev/random is requested])
81 AC_ARG_ENABLE(dev-random,
82 [  --disable-dev-random    disable the use of dev random],
83     try_dev_random=$enableval, try_dev_random=yes)
84 AC_MSG_RESULT($try_dev_random)
85
86
87 dnl
88 dnl  Check other options
89 dnl
90
91 AC_MSG_CHECKING([whether assembler modules are requested])
92 AC_ARG_ENABLE(asm,
93 [  --disable-asm           do not use assembler modules],
94      try_asm_modules=$enableval, try_asm_modules=yes)
95 AC_MSG_RESULT($try_asm_modules)
96
97 AC_MSG_CHECKING([whether memory guard is requested])
98 AC_ARG_ENABLE(m-guard,
99     [  --enable-m-guard        enable memory guard facility],
100     use_m_guard=$enableval, use_m_guard=no)
101 AC_MSG_RESULT($use_m_guard)
102 if test "$use_m_guard" = yes ; then
103     AC_DEFINE(M_GUARD,1,[Define to use the (obsolete) malloc guarding feature])
104 fi
105
106 AC_MSG_CHECKING([whether OpenPGP card support is requested])
107 AC_ARG_ENABLE(card-support,
108     [  --enable-card-support   enable OpenPGP card support],
109     card_support=$enableval, card_support=no)
110 AC_MSG_RESULT($card_support)
111
112 dnl See if we are disabling any algorithms or features for a smaller
113 dnl binary
114
115 try_extensions=no
116
117 use_idea=yes
118 use_cast5=yes
119 use_blowfish=yes
120 use_aes=yes
121 use_twofish=yes
122 use_sha256=yes
123 use_sha512=yes
124 use_exec=yes
125
126 AC_ARG_ENABLE(minimal,
127    AC_HELP_STRING([--enable-minimal],[build the smallest gpg binary possible]),
128    use_idea=no
129    use_cast5=no
130    use_blowfish=no
131    use_aes=no
132    use_twofish=no
133    use_sha256=no
134    use_sha512=no
135    use_exec=no)
136
137 AC_MSG_CHECKING([whether to enable the IDEA cipher])
138 AC_ARG_ENABLE(idea,
139    AC_HELP_STRING([--disable-idea],[disable the IDEA cipher]),
140    use_idea=$enableval)
141 AC_MSG_RESULT($use_idea)
142 if test x"$use_idea" = xyes ; then
143    AC_DEFINE(USE_IDEA,1,[Define to include the IDEA cipher])
144
145 # We don't need idea but some people claim that they need it for
146 # research etc., so we allow to place an idea source code into the
147 # cipher directory and statically link it if available, otherwise we
148 # link to a stub.  We don't use AC_CHECK_FILE to avoid caching.
149
150    AC_MSG_CHECKING([for idea cipher module])
151    tmp=""
152    if test -f $srcdir/cipher/idea.c; then 
153       IDEA_O=idea.o
154       tmp=idea
155    else
156       IDEA_O=idea-stub.o
157       tmp=no
158       try_extensions=yes
159    fi
160    AC_SUBST(IDEA_O)
161    AC_MSG_RESULT($tmp)
162 fi
163
164 AC_MSG_CHECKING([whether to enable the CAST5 cipher])
165 AC_ARG_ENABLE(cast5,
166    AC_HELP_STRING([--disable-cast5],[disable the CAST5 cipher]),
167    use_cast5=$enableval)
168 AC_MSG_RESULT($use_cast5)
169 if test x"$use_cast5" = xyes ; then
170    AC_DEFINE(USE_CAST5,1,[Define to include the CAST5 cipher])
171 fi
172
173 AC_MSG_CHECKING([whether to enable the BLOWFISH cipher])
174 AC_ARG_ENABLE(blowfish,
175    AC_HELP_STRING([--disable-blowfish],[disable the BLOWFISH cipher]),
176    use_blowfish=$enableval)
177 AC_MSG_RESULT($use_blowfish)
178 if test x"$use_blowfish" = xyes ; then
179    AC_DEFINE(USE_BLOWFISH,1,[Define to include the BLOWFISH cipher])
180 fi
181
182 AC_MSG_CHECKING([whether to enable the AES ciphers])
183 AC_ARG_ENABLE(aes,
184    AC_HELP_STRING([--disable-aes],[disable the AES, AES192, and AES256 ciphers]),
185    use_aes=$enableval)
186 AC_MSG_RESULT($use_aes)
187 if test x"$use_aes" = xyes ; then
188    AC_DEFINE(USE_AES,1,[Define to include the AES, AES192, and AES256 ciphers])
189 fi
190
191 AC_MSG_CHECKING([whether to enable the TWOFISH cipher])
192 AC_ARG_ENABLE(twofish,
193    AC_HELP_STRING([--disable-twofish],[disable the TWOFISH cipher]),
194    use_twofish=$enableval)
195 AC_MSG_RESULT($use_twofish)
196 if test x"$use_twofish" = xyes ; then
197    AC_DEFINE(USE_TWOFISH,1,[Define to include the TWOFISH cipher])
198 fi
199
200 AC_MSG_CHECKING([whether to enable the SHA-256 digest])
201 AC_ARG_ENABLE(sha256,
202    AC_HELP_STRING([--disable-sha256],[disable the SHA-256 digest]),
203    use_sha256=$enableval)
204 AC_MSG_RESULT($use_sha256)
205 if test x"$use_sha256" = xyes ; then
206    AC_DEFINE(USE_SHA256,1,[Define to include the SHA-256 digest])
207 fi
208
209 dnl SHA512 is defined only after we confirm 64-bit support later
210 AC_MSG_CHECKING([whether to enable the SHA-384 and SHA-512 digests])
211 AC_ARG_ENABLE(sha512,
212    AC_HELP_STRING([--disable-sha512],[disable the SHA-384 and SHA-512 digests]),
213    use_sha512=$enableval)
214 AC_MSG_RESULT($use_sha512)
215
216 AC_MSG_CHECKING([whether to enable external program execution])
217 AC_ARG_ENABLE(exec,
218     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
219     use_exec=$enableval)
220 AC_MSG_RESULT($use_exec)
221 if test "$use_exec" = no ; then
222     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
223 fi
224
225 if test "$use_exec" = yes ; then
226   AC_MSG_CHECKING([whether to enable photo ID viewing])
227   AC_ARG_ENABLE(photo-viewers,
228       [  --disable-photo-viewers disable photo ID viewers],
229       [if test "$enableval" = no ; then
230          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
231       fi],enableval=yes)
232   gnupg_cv_enable_photo_viewers=$enableval
233   AC_MSG_RESULT($enableval)
234
235   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
236     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
237     AC_ARG_WITH(photo-viewer,
238         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
239         [if test "$withval" = yes ; then
240            withval=no
241         elif test "$withval" != no ; then
242            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
243                             [if set, restrict photo-viewer to this])
244         fi],withval=no)
245     AC_MSG_RESULT($withval)
246   fi
247
248   AC_MSG_CHECKING([whether to enable external keyserver helpers])
249   AC_ARG_ENABLE(keyserver-helpers,
250       [  --disable-keyserver-helpers  disable all external keyserver support],
251       [if test "$enableval" = no ; then
252          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
253                   [define to disable keyserver helpers])
254       fi],enableval=yes)
255   gnupg_cv_enable_keyserver_helpers=$enableval
256   AC_MSG_RESULT($enableval)
257
258   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
259     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
260     AC_ARG_ENABLE(ldap,
261     [  --disable-ldap          disable LDAP keyserver interface],
262         try_ldap=$enableval, try_ldap=yes)
263     AC_MSG_RESULT($try_ldap)
264
265     AC_MSG_CHECKING([whether HKP keyserver support is requested])
266     AC_ARG_ENABLE(hkp,
267     [  --disable-hkp           disable HKP keyserver interface],
268         try_hkp=$enableval, try_hkp=yes)
269     AC_MSG_RESULT($try_hkp)
270
271     AC_MSG_CHECKING([whether email keyserver support is requested])
272     AC_ARG_ENABLE(mailto,
273     [  --disable-mailto        disable email keyserver interface],
274         try_mailto=$enableval, try_mailto=yes)
275     AC_MSG_RESULT($try_mailto)
276     fi
277
278     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
279     AC_ARG_ENABLE(keyserver-path,
280         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
281         [if test "$enableval" = no ; then
282          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
283         fi],enableval=yes)
284     AC_MSG_RESULT($enableval)
285   fi
286
287 AC_MSG_CHECKING([whether the included zlib is requested])
288 AC_ARG_WITH(included-zlib,
289     [  --with-included-zlib    use the zlib code included here],
290 [g10_force_zlib=yes], [g10_force_zlib=no] )
291 AC_MSG_RESULT($g10_force_zlib)
292
293 dnl
294 dnl Check whether we want to use Linux capabilities
295 dnl
296 AC_MSG_CHECKING([whether use of capabilities is requested])
297 AC_ARG_WITH(capabilities,
298     [  --with-capabilities     use linux capabilities [default=no]],
299 [use_capabilities="$withval"],[use_capabilities=no])
300 AC_MSG_RESULT($use_capabilities)
301
302
303 AH_BOTTOM([
304 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
305 #define EXEC_TEMPFILE_ONLY
306 #endif
307
308 /* This is the major version number of GnuPG so that
309    source included files can test for this. */
310 #define GNUPG_MAJOR_VERSION 1
311
312 #include "g10defs.h"
313 ])
314
315
316 AM_MAINTAINER_MODE
317
318 dnl Checks for programs.
319
320 AC_PROG_MAKE_SET
321 AM_SANITY_CHECK
322 missing_dir=`cd $ac_aux_dir && pwd`
323 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
324 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
325 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
326 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
327 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
328 AC_PROG_CC
329 AC_PROG_CPP
330 AC_PROG_RANLIB
331 AC_CHECK_TOOL(AR, ar, :)
332 AC_PATH_PROG(PERL,"perl")
333 AC_ISC_POSIX
334 AC_SYS_LARGEFILE
335 AC_PROG_INSTALL
336 AC_PROG_AWK
337 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
338 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
339 GNUPG_CHECK_FAQPROG
340 GNUPG_CHECK_DOCBOOK_TO_TEXI
341
342 MPI_OPT_FLAGS=""
343
344
345 try_gettext=yes
346 have_dosish_system=no
347 no_need_for_dlopen=no
348 case "${target}" in
349     *-*-mingw32*)
350         # special stuff for Windoze NT
351         ac_cv_have_dev_random=no
352         AC_DEFINE(USE_ONLY_8DOT3,1,
353                   [set this to limit filenames to the 8.3 format])
354         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
355                   [defined if we must run on a stupid file system])
356         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
357                   [because the Unix gettext has too much overhead on
358                    MingW32 systems and these systems lack Posix functions,
359                    we use a simplified version of gettext])
360         have_dosish_system=yes
361         no_need_for_dlopen=yes
362         try_gettext="no"
363         ;;
364     i?86-emx-os2 | i?86-*-os2*emx )
365         # OS/2 with the EMX environment
366         ac_cv_have_dev_random=no
367         AC_DEFINE(HAVE_DRIVE_LETTERS)
368         have_dosish_system=yes
369         try_gettext="no"
370         ;;
371
372     i?86-*-msdosdjgpp*)
373         # DOS with the DJGPP environment
374         ac_cv_have_dev_random=no
375         AC_DEFINE(HAVE_DRIVE_LETTERS)
376         have_dosish_system=yes
377         try_gettext="no"
378         ;;
379
380     *-*-freebsd*)
381        # FreeBSD
382        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
383        LDFLAGS="$LDFLAGS -L/usr/local/lib"
384        ;;
385
386     *-*-hpux*)
387         if test -z "$GCC" ; then
388             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
389         fi
390         ;;
391     *-dec-osf4*)
392         if test -z "$GCC" ; then
393             # Suppress all warnings
394             # to get rid of the unsigned/signed char mismatch warnings.
395             CFLAGS="$CFLAGS -w"
396         fi
397         ;;
398     *-dec-osf5*)
399         if test -z "$GCC" ; then
400             # Use the newer compiler `-msg_disable ptrmismatch' to
401             # get rid of the unsigned/signed char mismatch warnings.
402             # Using this may hide other pointer mismatch warnings, but
403             # it at least lets other warning classes through
404             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
405         fi
406         ;;
407     m68k-atari-mint)
408         ;;
409     *)
410        ;;
411 esac
412
413 if test "$have_dosish_system" = yes; then
414    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
415              [defined if we run on some of the PCDOS like systems 
416               (DOS, Windoze. OS/2) with special properties like
417               no file modes])
418 fi
419 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
420
421 AC_SUBST(MPI_OPT_FLAGS)
422 GNUPG_SYS_SYMBOL_UNDERSCORE
423
424 dnl This needs to go after AC_PROG_CC so that $EXEEXT is defined
425 if test "$try_hkp" = yes ; then
426   AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
427 fi
428
429 dnl Must check for network library requirements before doing link tests
430 dnl for ldap, for example. If ldap libs are static (or dynamic and without
431 dnl ELF runtime link paths), then link will fail and LDAP support won't
432 dnl be detected.
433
434 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
435         [NETLIBS="-lnsl $NETLIBS"]))
436 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
437         [NETLIBS="-lsocket $NETLIBS"]))
438
439 dnl Now try for the resolver functions so we can use DNS SRV
440
441 AC_ARG_ENABLE(dns-srv,
442    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
443    use_dns_srv=$enableval,use_dns_srv=yes)
444
445 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
446   _srv_save_libs=$LIBS
447   LIBS=""
448   # the double underscore thing is a glibc-ism?
449   AC_SEARCH_LIBS(res_query,resolv bind,,
450                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
451   AC_SEARCH_LIBS(dn_expand,resolv bind,,
452                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
453   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
454                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
455
456   if test x"$use_dns_srv" = xyes ; then
457      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
458      SRVLIBS=$LIBS
459   else
460      AC_MSG_WARN([Resolver functions not found.  Disabling DNS SRV.])
461   fi
462   LIBS=$_srv_save_libs
463 fi
464
465 AC_SUBST(SRVLIBS)
466
467 # Try and link a LDAP test program to weed out unusable LDAP
468 # libraries.  -lldap [-llber [-lresolv]] is for OpenLDAP.  OpenLDAP in
469 # general is terrible with creating weird dependencies.  If all else
470 # fails, the user can play guess-the-dependency by using something
471 # like ./configure LDAPLIBS="-Lfoo -lbar"
472
473 if test "$try_ldap" = yes ; then
474   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
475     _ldap_save_libs=$LIBS
476     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
477
478     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
479     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
480                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
481     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
482
483     if test $gnupg_cv_func_ldap_init = no; then
484       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
485       AC_TRY_LINK([#include <lber.h>
486 #include <ldap.h>],[ldap_open("foobar",1234);],
487          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
488       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
489     fi
490
491     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
492        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
493     fi
494
495     if test "$gnupg_cv_func_ldap_init" = yes || \
496         test "$gnupg_cv_func_ldaplber_init" = yes ; then
497        LDAPLIBS=$MY_LDAPLIBS
498        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
499
500        AC_MSG_CHECKING([whether LDAP supports ldap_get_option])
501
502        if test "$gnupg_cv_func_ldap_init" = yes ; then
503           AC_TRY_LINK([#include <ldap.h>],
504              [ldap_get_option((void *)0,0,(void *)0);],
505              [gnupg_cv_func_ldap_get_option=yes],
506              [gnupg_cv_func_ldap_get_option=no])
507         else
508           AC_TRY_LINK([#include <lber.h>
509 #include <ldap.h>],[ldap_get_option((void *)0,0,(void *)0);],
510              [gnupg_cv_func_ldap_get_option=yes],
511              [gnupg_cv_func_ldap_get_option=no])
512        fi
513
514        AC_MSG_RESULT([$gnupg_cv_func_ldap_get_option])
515
516        if test "$gnupg_cv_func_ldap_get_option" = yes ; then
517           AC_DEFINE(HAVE_LDAP_GET_OPTION,1,[Define if the LDAP library has ldap_get_option])
518        else
519           AC_MSG_CHECKING([whether LDAP supports ld_errno])
520
521           if test "$gnupg_cv_func_ldap_init" = yes ; then
522             AC_TRY_COMPILE([#include <ldap.h>],
523                [LDAP *ldap; ldap->ld_errno;],
524                [gnupg_cv_func_ldap_ld_errno=yes],
525                [gnupg_cv_func_ldap_ld_errno=no])
526            else
527             AC_TRY_LINK([#include <lber.h>
528 #include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
529                [gnupg_cv_func_ldap_ld_errno=yes],
530                [gnupg_cv_func_ldap_ld_errno=no])
531           fi
532
533           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
534
535           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
536              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
537           fi
538        fi
539     fi
540
541     LIBS=$_ldap_save_libs
542
543     if test "$GPGKEYS_LDAP" != "" ; then break; fi
544   done
545 fi
546
547 AC_SUBST(GPGKEYS_LDAP)
548 AC_SUBST(LDAPLIBS)
549
550 dnl This isn't necessarily sendmail itself, but anything that gives a
551 dnl sendmail-ish interface to the outside world.  That includes qmail,
552 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
553
554 if test "$try_mailto" = yes ; then
555   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
556
557   if test "$with_mailprog" = yes ; then
558     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
559     if test "$ac_cv_path_SENDMAIL" ; then
560       GPGKEYS_MAILTO="gpgkeys_mailto"
561     fi
562   elif test "$with_mailprog" != no ; then
563     AC_MSG_CHECKING([for a mail transport program])
564     AC_SUBST(SENDMAIL,$with_mailprog)
565     AC_MSG_RESULT($with_mailprog)
566     GPGKEYS_MAILTO="gpgkeys_mailto"
567   fi
568 fi
569
570 AC_SUBST(GPGKEYS_MAILTO)
571
572 case "${target}" in
573     *-*-mingw32*)
574         PRINTABLE_OS_NAME="MingW32"
575         ;;
576     *-*-cygwin*)
577         PRINTABLE_OS_NAME="Cygwin"
578         ;;
579     i?86-emx-os2 | i?86-*-os2*emx )
580         PRINTABLE_OS_NAME="OS/2"
581         ;;
582     i?86-*-msdosdjgpp*)
583         PRINTABLE_OS_NAME="MSDOS/DJGPP"
584         try_extensions=no
585         ;;
586     *-linux*)
587         PRINTABLE_OS_NAME="GNU/Linux"
588         ;;
589     *)
590         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
591         ;;
592 esac
593 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
594                    [A human readable text with the name of the OS])
595
596
597 #
598 # 1. Set names of random devices
599 #
600 NAME_OF_DEV_RANDOM="/dev/random"
601 NAME_OF_DEV_URANDOM="/dev/urandom"
602 case "${target}" in
603     *-openbsd*)
604         NAME_OF_DEV_RANDOM="/dev/srandom"
605         NAME_OF_DEV_URANDOM="/dev/urandom"
606         ;;
607 esac
608 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM",
609                    [defined to the name of the strong random device])
610 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM",
611                    [defined to the name of the weaker random device])
612 AC_SUBST(MPI_OPT_FLAGS)
613
614
615 dnl Checks for libraries.
616
617 if test "$try_gettext" = yes; then
618   AM_GNU_GETTEXT(,[need-ngettext])
619
620   # gettext requires some extra checks.  These really should be part of
621   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
622   # function checks to here.
623
624   AC_CHECK_FUNCS(strchr)
625 else
626   USE_NLS=no
627   USE_INCLUDED_LIBINTL=no
628   BUILD_INCLUDED_LIBINTL=no
629   AC_SUBST(USE_NLS)
630   AC_SUBST(USE_INCLUDED_LIBINTL)
631   AC_SUBST(BUILD_INCLUDED_LIBINTL)
632 fi
633
634 if test "$try_extensions" = yes || test x"$card_support" = xyes ; then
635   if test "$no_need_for_dlopen" = yes; then
636     AC_SUBST(DLLIBS,"")
637   else
638     AC_CHECK_FUNC(dlopen,,AC_CHECK_LIB(dl,dlopen,found_dlopen=yes))
639     if test x"$found_dlopen" = "xyes" ; then
640       AC_DEFINE(HAVE_DL_DLOPEN,1,
641                 [Defined when the dlopen function family is available])
642       AC_SUBST(DLLIBS,"-ldl")
643       if test "$try_extensions" = yes ; then
644          AC_DEFINE(USE_DYNAMIC_LINKING,1,
645                  [define to enable the use of extensions])
646       fi
647     else
648       if test "$try_extensions" = yes ; then
649          AC_MSG_WARN([dlopen not found.  Disabling extensions.])
650       fi
651   
652       if test "$card_support" = yes ; then
653          AC_MSG_WARN([dlopen not found.  Disabling OpenPGP card support.])
654          card_support=no
655       fi
656     fi
657   fi
658 fi
659 if test "$card_support" = yes ; then
660   AC_DEFINE(ENABLE_CARD_SUPPORT,1,
661             [Define to include the OpenPGP card support])
662 fi
663
664 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
665
666 dnl Checks for header files.
667 AC_HEADER_STDC
668 AC_CHECK_HEADERS(unistd.h langinfo.h termio.h locale.h getopt.h)
669
670 dnl Checks for typedefs, structures, and compiler characteristics.
671 AC_C_CONST
672 AC_C_INLINE
673 AC_C_VOLATILE
674 AC_TYPE_SIZE_T
675 AC_TYPE_MODE_T
676 AC_TYPE_SIGNAL
677 AC_DECL_SYS_SIGLIST
678
679 GNUPG_CHECK_ENDIAN
680
681 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
682 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
683 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
684 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
685 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
686
687 AC_CHECK_SIZEOF(unsigned short)
688 AC_CHECK_SIZEOF(unsigned int)
689 AC_CHECK_SIZEOF(unsigned long)
690 AC_CHECK_SIZEOF(unsigned long long)
691
692 # Ensure that we have UINT64_C before we bother to check for uint64_t
693 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
694    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
695 uint64_t foo=UINT64_C(42);]),gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
696
697 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
698    AC_CHECK_SIZEOF(uint64_t)
699 fi
700
701 if test "$ac_cv_sizeof_unsigned_short" = "0" \
702    || test "$ac_cv_sizeof_unsigned_int" = "0" \
703    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
704     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
705 fi
706
707 dnl Do we have any 64-bit data types?
708 if test "$ac_cv_sizeof_unsigned_int" != "8" \
709    && test "$ac_cv_sizeof_unsigned_long" != "8" \
710    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
711    && test x"$ac_cv_sizeof_uint64_t" != "x8"; then
712     AC_MSG_WARN([No 64-bit types.  Disabling SHA-384 and SHA-512])
713 else
714   if test x"$use_sha512" = xyes ; then
715      AC_SUBST(SHA512_O,sha512.o)
716      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
717   fi
718 fi
719
720 dnl Checks for library functions.
721 AC_FUNC_FSEEKO
722 AC_FUNC_VPRINTF
723 AC_FUNC_FORK
724 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
725 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times)
726 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
727 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
728 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat getaddrinfo)
729 AC_REPLACE_FUNCS(mkdtemp)
730 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
731
732 # See if getopt is in libiberty.  This is of course not optimal since
733 # it might be somewhere other than libiberty, but does cover the
734 # mingw32 case.
735
736 AC_CHECK_FUNC(getopt,,AC_CHECK_LIB(iberty,getopt,AC_SUBST(GETOPT,"-liberty")))
737
738 #
739 # check for gethrtime and run a testprogram to see whether
740 # it is broken.  It has been reported that some Solaris and HP UX systems 
741 # raise an SIGILL
742 #
743 AC_CACHE_CHECK([for gethrtime], 
744                [gnupg_cv_func_gethrtime],
745                [AC_TRY_LINK([#include <sys/times.h>],[
746                    hrtime_t tv;
747                    tv = gethrtime();
748                  ],
749                  [gnupg_cv_func_gethrtime=yes],
750                  [gnupg_cv_func_gethrtime=no])
751                ])
752 if test $gnupg_cv_func_gethrtime = yes; then
753      AC_DEFINE([HAVE_GETHRTIME], 1,
754                [Define if you have the `gethrtime(2)' function.])
755      AC_CACHE_CHECK([whether gethrtime is broken], 
756                [gnupg_cv_func_broken_gethrtime],
757                [AC_TRY_RUN([
758                    #include <sys/times.h>
759                    int main () {
760                    hrtime_t tv;
761                    tv = gethrtime(); 
762                  }
763                  ],
764                  [gnupg_cv_func_broken_gethrtime=no],
765                  [gnupg_cv_func_broken_gethrtime=yes],
766                  [gnupg_cv_func_broken_gethrtime=assume-no])
767                 ])
768     if test $gnupg_cv_func_broken_gethrtime = yes; then
769       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
770       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
771     fi
772 fi
773      
774
775 GNUPG_CHECK_MLOCK
776 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
777
778 dnl
779 dnl Check whether we can use Linux capabilities as requested
780 dnl
781 if test "$use_capabilities" = "yes" ; then
782 use_capabilities=no
783 AC_CHECK_HEADERS(sys/capability.h)
784 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
785   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
786   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
787      AC_DEFINE(USE_CAPABILITIES,1,
788                [define if capabilities should be used])
789      AC_SUBST(CAPLIBS,"-lcap")
790      use_capabilities=yes
791   fi
792 fi
793 if test "$use_capabilities" = "no" ; then
794     AC_MSG_WARN([[
795 ***
796 *** The use of capabilities on this system is not possible.
797 *** You need a recent Linux kernel and some patches:
798 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
799 ***   fcap-module-990613.tar.gz     (kernel module)
800 ***   libcap-1.92.tar.gz            (user mode library and utilities)
801 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
802 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
803 ***]])
804 fi
805 fi
806
807
808 GNUPG_CHECK_IPC
809 if test "$ac_cv_header_sys_shm_h" = "yes"; then
810   AC_DEFINE(USE_SHM_COPROCESSING,1,
811             [define if the shared memory interface should be made available])
812 fi
813
814 dnl
815 dnl check whether we have a random device
816 dnl
817 if test "$try_dev_random" = yes ; then
818     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
819     [if test -r "$NAME_OF_DEV_RANDOM" && test -r "$NAME_OF_DEV_URANDOM" ; then
820       ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
821     if test "$ac_cv_have_dev_random" = yes; then
822         AC_DEFINE(HAVE_DEV_RANDOM,1,
823                  [defined if the system supports a random device] )
824     fi
825 else
826     AC_MSG_CHECKING(for random device)
827     ac_cv_have_dev_random=no
828     AC_MSG_RESULT(has been disabled)
829 fi
830
831
832 dnl
833 dnl Figure out the default random module.
834 dnl
835 random_modules=""
836 if test "$use_static_rnd" = default; then
837      if test "$ac_cv_have_dev_random" = yes; then
838         random_modules="rndlinux"
839      else
840          case "${target}" in
841             *-*-mingw32*|*-*-cygwin*)
842                 random_modules="rndw32"
843                 ;;
844             i?86-emx-os2|i?86-*-os2*emx)
845                 random_modules="rndos2"
846                 ;;
847             m68k-atari-mint)
848                 random_modules="rndatari"
849                 ;;
850             i?86-*-msdosdjgpp*)
851                 :
852                 ;;
853             *)
854                 random_modules="rndlinux rndegd rndunix"
855                 AC_DEFINE(USE_ALL_RANDOM_MODULES, 1, 
856                           [Allow to select random modules at runtime.])
857                 ;;
858          esac
859      fi
860 else
861   if test "$use_static_rnd" = auto; then
862      random_modules="rndlinux rndegd rndunix"
863      AC_DEFINE(USE_ALL_RANDOM_MODULES, 1)
864   else
865      random_modules="rnd$use_static_rnd";
866   fi
867 fi
868
869 if test -z "$random_modules"; then
870    AC_MSG_ERROR(no random module available)
871 fi
872 print_egd_warning=no
873 for rndmod in $random_modules "" ; do
874   case "$rndmod" in
875     rndlinux)
876          AC_DEFINE(USE_RNDLINUX,1, 
877                   [Defined if the /dev/random based RNG should be used.])
878          ;;
879     rndunix)
880          AC_DEFINE(USE_RNDUNIX,1, 
881                   [Defined if the default Unix RNG should be used.])
882          print_egd_warning=yes
883           ;;
884     rndegd)
885          AC_DEFINE(USE_RNDEGD,1, 
886                   [Defined if the EGD based RNG should be used.])
887          ;;
888     rndw32)
889          AC_DEFINE(USE_RNDW32,1, 
890                   [Defined if the Windows specific RNG should be used.])
891         ;;
892    esac
893 done
894
895 dnl setup assembler stuff
896 AC_MSG_CHECKING(for mpi assembler functions)
897 if test -f $srcdir/mpi/config.links ; then
898     . $srcdir/mpi/config.links
899     AC_CONFIG_LINKS("$mpi_ln_list")
900     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
901     ac_cv_mpi_sflags="$mpi_sflags"
902     ac_cv_mpi_config_done="yes"
903     AC_MSG_RESULT(done)
904 else
905     AC_MSG_RESULT(failed)
906     AC_MSG_ERROR([mpi/config.links missing!])
907 fi
908 MPI_EXTRA_ASM_OBJS=""
909 show_extraasm=""
910 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
911 for i in $ac_cv_mpi_extra_asm_modules; do
912     show_extraasm="$show_extraasm $i"
913     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
914 done
915 fi
916 AC_SUBST(MPI_EXTRA_ASM_OBJS)
917 MPI_SFLAGS="$ac_cv_mpi_sflags"
918 AC_SUBST(MPI_SFLAGS)
919
920 # Sanity check regex.  Tests adapted from mutt.
921
922 AC_MSG_CHECKING([whether regular expression support is requested])
923 AC_ARG_ENABLE(regex,
924 [  --disable-regex         do not handle regular expressions in trust sigs],
925      use_regex=$enableval, use_regex=yes)
926 AC_MSG_RESULT($use_regex)
927
928 if test "$use_regex" = yes ; then
929   AC_MSG_CHECKING([whether the included regex lib is requested])
930   AC_ARG_WITH(included-regex,
931       [  --with-included-regex   use the included GNU regex library],
932       [gnupg_cv_included_regex=yes],[gnupg_cv_included_regex=no])
933   AC_MSG_RESULT($gnupg_cv_included_regex)
934
935   if test $gnupg_cv_included_regex = no ; then
936      # Does the system have regex functions at all?
937      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
938                            gnupg_cv_included_regex=yes)
939   fi
940
941   if test $gnupg_cv_included_regex = no ; then
942      AC_CACHE_CHECK([whether your system's regexp library is broken],
943        [gnupg_cv_regex_broken],
944        AC_TRY_RUN([
945 #include <unistd.h>
946 #include <regex.h>
947 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
948        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
949
950      if test $gnupg_cv_regex_broken = yes ; then
951       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
952       gnupg_cv_included_regex=yes
953      fi
954   fi
955
956   if test $gnupg_cv_included_regex = yes; then
957      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
958      AC_SUBST(REGEX_O,regex.o)
959   fi
960 else
961
962   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
963 fi
964
965 dnl Do we have zlib? Must do it here because Solaris failed
966 dnl when compiling a conftest (due to the "-lz" from LIBS).
967 use_local_zlib=yes
968 if test "$g10_force_zlib" = "yes"; then
969   :
970 else
971   _cppflags="${CPPFLAGS}"
972   _ldflags="${LDFLAGS}"
973
974   AC_ARG_WITH(zlib,
975   [  --with-zlib=DIR         use libz in DIR],[
976     if test -d "$withval"; then
977       CPPFLAGS="${CPPFLAGS} -I$withval/include"
978       LDFLAGS="${LDFLAGS} -L$withval/lib"
979     fi
980   ])
981
982   AC_CHECK_HEADER(zlib.h,
983       AC_CHECK_LIB(z, deflateInit2_,
984        use_local_zlib=no
985        ZLIBS="-lz",
986        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
987        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
988 fi
989
990 if test "$use_local_zlib" = yes ; then
991     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
992     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
993     ZLIBS="../zlib/libzlib.a"
994 else
995     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
996 fi
997 AC_SUBST(ZLIBS)
998
999
1000 #
1001 # libusb allows us to use the integrated CCID smartcard reader driver.
1002 #
1003 # Note, that we need the CVS (unstable) version. 
1004 #
1005 LIBUSB_LIBS=""
1006 if test "$card_support" = yes; then
1007     AC_CHECK_LIB(usb, usb_find_device,
1008                  [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
1009                    AC_DEFINE(HAVE_LIBUSB,1,
1010                    [defined if libusb is available])
1011                  ])
1012 fi
1013 AC_SUBST(LIBUSB_LIBS)
1014
1015
1016
1017 # Allow users to append something to the version string without
1018 # flagging it as development version.  The user version parts is
1019 # considered everything after a dash. 
1020 if test "$development_version" != yes; then
1021   changequote(,)dnl
1022   tmp_pat='[a-zA-Z]'
1023   changequote([,])dnl
1024   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1025     development_version=yes
1026   fi
1027 fi
1028 if test "$development_version" = yes; then
1029     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1030             [Defined if this is not a regular release])
1031 fi
1032
1033 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1034
1035 GNUPG_CHECK_GNUMAKE
1036
1037 # add some extra libs here so that previous tests don't fail for
1038 # mysterious reasons - the final link step should bail out. 
1039 case "${target}" in
1040     *-*-mingw32*)
1041 dnl      NETLIBS="$NETLIBS -lwsock32"
1042         W32LIBS="-lwsock32"
1043         ;;
1044     *)
1045        ;;
1046 esac
1047
1048 AC_SUBST(NETLIBS)
1049 AC_SUBST(W32LIBS)
1050
1051 if test "$GCC" = yes; then
1052     if test "$USE_MAINTAINER_MODE" = "yes"; then
1053         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1054     else
1055         CFLAGS="$CFLAGS -Wall"
1056     fi
1057 fi
1058
1059
1060 if test "$print_egd_warning" = yes; then
1061   AC_MSG_WARN([[
1062 ***
1063 *** The performance of the UNIX random gatherer module is not very good
1064 *** and it does not keep the entropy pool over multiple invocations of
1065 *** GnuPG.  The suggested way to overcome this problem is to use the
1066 ***
1067 ***               Entropy Gathering Daemon (EGD)
1068 ***
1069 *** which provides a entropy source for the whole system.  It is written
1070 *** in Perl and available at the GnuPG FTP servers.  For more information
1071 *** consult the GnuPG webpages:
1072 ***
1073 ***           http://www.gnupg.org/download/#EGD
1074 ***
1075 *** You may want to run ./configure with --enable-static-rnd=egd or
1076 *** --enable-static-rnd=auto to use it.
1077 ***]])
1078 fi
1079
1080 # Note the \\\\ for backslashes.  Autoconf eats one layer, leaving \\
1081
1082 AC_CONFIG_COMMANDS(g10defs.h,[[
1083 cat >g10defs.tmp <<G10EOF
1084 /* Generated automatically by configure */
1085 #ifdef HAVE_DRIVE_LETTERS
1086 #define G10_LOCALEDIR     "c:\\\\lib\\\\gnupg\\\\locale"
1087 #define GNUPG_LIBDIR      "c:\\\\lib\\\\gnupg"
1088 #define GNUPG_LIBEXECDIR  "c:\\\\lib\\\\gnupg"
1089 #define GNUPG_DATADIR     "c:\\\\lib\\\\gnupg"
1090 #define GNUPG_HOMEDIR     "c:\\\\gnupg"
1091 #else
1092 #define G10_LOCALEDIR     "${datadir}/locale"
1093 #define GNUPG_LIBDIR      "${libdir}/gnupg"
1094 #define GNUPG_DATADIR     "${datadir}/gnupg"
1095 #ifdef __VMS
1096 #define GNUPG_HOMEDIR "/SYS\$LOGIN/gnupg" 
1097 #else
1098 #define GNUPG_HOMEDIR "~/.gnupg" 
1099 #endif
1100 #endif
1101 /* those are here to be redefined by handcrafted g10defs.h.
1102    Please note that the string version must not contain more
1103    than one character because the using code assumes strlen()==1 */
1104 #ifdef HAVE_DOSISH_SYSTEM
1105 #define DIRSEP_C '\\\\'
1106 #define EXTSEP_C '.'
1107 #define DIRSEP_S "\\\\"
1108 #define EXTSEP_S "."
1109 #else
1110 #define DIRSEP_C '/'
1111 #define EXTSEP_C '.'
1112 #define DIRSEP_S "/"
1113 #define EXTSEP_S "."
1114 #endif
1115 /* This is the same as VERSION, but should be overridden if the
1116    platform cannot handle things like dots '.' in filenames. */
1117 #define SAFE_VERSION VERSION
1118 G10EOF
1119 cat mpi/mpi-asm-defs.h >>g10defs.tmp 
1120 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
1121     echo "g10defs.h is unchanged"
1122     rm -f g10defs.tmp
1123 else
1124     rm -f g10defs.h
1125     mv g10defs.tmp g10defs.h
1126     echo "g10defs.h created"
1127 fi
1128 ]],[[
1129 prefix=$prefix
1130 exec_prefix=$exec_prefix
1131 libdir=$libdir
1132 libexecdir=$libexecdir
1133 datadir=$datadir
1134 DATADIRNAME=$DATADIRNAME
1135 ]])
1136
1137
1138 AC_CONFIG_FILES([
1139 Makefile
1140 intl/Makefile
1141 po/Makefile.in
1142 util/Makefile
1143 mpi/Makefile
1144 cipher/Makefile
1145 g10/Makefile
1146 keyserver/Makefile
1147 keyserver/gpgkeys_mailto
1148 keyserver/gpgkeys_test
1149 doc/Makefile
1150 tools/Makefile
1151 zlib/Makefile
1152 checks/Makefile
1153 ])
1154 AC_OUTPUT
1155
1156 # Give some feedback
1157 echo
1158 echo   "                Configured for: $PRINTABLE_OS_NAME ($target)"
1159 if test -n "$show_extraasm"; then
1160   echo "  Extra cpu specific functions:$show_extraasm"
1161 fi
1162 echo