7658c6f1c26ac156142dd2b62a93b84e3108e827
[gnupg.git] / configure.ac
1 dnl Configure.ac script for GnuPG
2 dnl Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 dnl               2003 Free Software Foundation, Inc.
4 dnl
5 dnl This file is part of GnuPG.
6 dnl
7 dnl GnuPG is free software; you can redistribute it and/or modify
8 dnl it under the terms of the GNU General Public License as published by
9 dnl the Free Software Foundation; either version 2 of the License, or
10 dnl (at your option) any later version.
11 dnl 
12 dnl GnuPG is distributed in the hope that it will be useful,
13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 dnl GNU General Public License for more details.
16 dnl 
17 dnl You should have received a copy of the GNU General Public License
18 dnl along with this program; if not, write to the Free Software
19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20 dnl
21 dnl (Process this file with autoconf to produce a configure script.)
22 dnlAC_REVISION($Revision$)dnl
23
24 AC_PREREQ(2.52)
25
26 # Remember to change the version number immediately *after* a release
27 # and remove the "-cvs" or "rc" suffix immediately *before* a release.
28 AC_INIT(gnupg, 1.3.2-cvs, bug-gnupg@gnu.org)
29 # Set development_version to yes if the minor number is odd or you
30 # feel that the default check for a development version is not
31 # sufficient.
32 development_version=yes
33
34 ALL_LINGUAS="de"
35
36 PACKAGE=$PACKAGE_NAME
37 VERSION=$PACKAGE_VERSION
38
39 AC_CONFIG_AUX_DIR(scripts)
40 AC_CONFIG_SRCDIR(g10/g10.c)
41 AC_CANONICAL_TARGET()
42 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
43 AM_CONFIG_HEADER(config.h)
44
45 AC_SUBST(PACKAGE)
46 AC_SUBST(VERSION)
47 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
48 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
49 AC_DEFINE(_GNU_SOURCE,1,[Some tests rely on this (stpcpy) and it should be used for new programs anyway])
50
51 dnl
52 dnl  Check for random module options
53 dnl
54 AC_MSG_CHECKING([which random module to use])
55 AC_ARG_ENABLE(static-rnd,
56     [  --enable-static-rnd=[egd|unix|linux|auto]  ],
57 [use_static_rnd=$enableval], [use_static_rnd=default] )
58
59 if test "$use_static_rnd" = no; then
60     use_static_rnd=default
61 fi
62
63 case "$use_static_rnd" in
64     egd | linux | unix | default )
65       AC_MSG_RESULT($use_static_rnd)
66       ;;
67     auto )
68       AC_MSG_RESULT(automagically selected at runtime)
69       ;;
70     * )
71       AC_MSG_RESULT(invalid argument)
72       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
73       ;;
74 esac
75
76 AC_ARG_WITH(egd-socket,
77     [  --with-egd-socket=NAME  use NAME for the EGD socket],
78             egd_socket_name="$withval", egd_socket_name="" )
79 AC_DEFINE_UNQUOTED(EGD_SOCKET_NAME, "$egd_socket_name",
80                    [Define if you don't want the default EGD socket name.
81                     For details see cipher/rndegd.c])
82
83
84 dnl
85 dnl See whether the user wants to disable checking for /dev/random
86
87 AC_MSG_CHECKING([whether use of /dev/random is requested])
88 AC_ARG_ENABLE(dev-random,
89 [  --disable-dev-random    disable the use of dev random],
90     try_dev_random=$enableval, try_dev_random=yes)
91 AC_MSG_RESULT($try_dev_random)
92
93
94 dnl
95 dnl  Check other options
96 dnl
97
98 AC_MSG_CHECKING([whether assembler modules are requested])
99 AC_ARG_ENABLE(asm,
100 [  --disable-asm           do not use assembler modules],
101      try_asm_modules=$enableval, try_asm_modules=yes)
102 AC_MSG_RESULT($try_asm_modules)
103
104 AC_MSG_CHECKING([whether memory guard is requested])
105 AC_ARG_ENABLE(m-guard,
106     [  --enable-m-guard        enable memory guard facility],
107     use_m_guard=$enableval, use_m_guard=no)
108 AC_MSG_RESULT($use_m_guard)
109 if test "$use_m_guard" = yes ; then
110     AC_DEFINE(M_GUARD,1,[Define to use the (obsolete) malloc guarding feature])
111 fi
112
113 dnl See if we are disabling any algorithms or features for a smaller
114 dnl binary
115
116 try_dynload=no
117
118 use_idea=yes
119 use_cast5=yes
120 use_blowfish=yes
121 use_aes=yes
122 use_twofish=yes
123 use_tiger192=no
124 use_sha256=yes
125 use_sha512=yes
126 use_exec=yes
127
128 AC_ARG_ENABLE(minimal,
129    AC_HELP_STRING([--enable-minimal],[build the smallest gpg binary possible]),
130    use_idea=no
131    use_cast5=no
132    use_blowfish=no
133    use_aes=no
134    use_twofish=no
135    use_sha256=no
136    use_sha512=no
137    use_exec=no)
138
139 AC_MSG_CHECKING([whether to enable the IDEA cipher])
140 AC_ARG_ENABLE(idea,
141    AC_HELP_STRING([--disable-idea],[disable the IDEA cipher]),
142    use_idea=$enableval)
143 AC_MSG_RESULT($use_idea)
144 if test x"$use_idea" = xyes ; then
145    AC_DEFINE(USE_IDEA,1,[Define to include the IDEA cipher])
146
147 # We don't need idea but some people claim that they need it for
148 # research etc., so we allow to place an idea source code into the
149 # cipher directory and statically link it if available, otherwise we
150 # link to a stub.  We don't use AC_CHECK_FILE to avoid caching.
151
152    AC_MSG_CHECKING([for idea cipher module])
153    tmp=""
154    if test -f $srcdir/cipher/idea.c; then 
155       IDEA_O=idea.o
156       tmp=idea
157    else
158       IDEA_O=idea-stub.o
159       tmp=no
160       try_dynload=yes
161    fi
162    AC_SUBST(IDEA_O)
163    AC_MSG_RESULT($tmp)
164 fi
165
166 AC_MSG_CHECKING([whether to enable the CAST5 cipher])
167 AC_ARG_ENABLE(cast5,
168    AC_HELP_STRING([--disable-cast5],[disable the CAST5 cipher]),
169    use_cast5=$enableval)
170 AC_MSG_RESULT($use_cast5)
171 if test x"$use_cast5" = xyes ; then
172    AC_DEFINE(USE_CAST5,1,[Define to include the CAST5 cipher])
173 fi
174
175 AC_MSG_CHECKING([whether to enable the BLOWFISH cipher])
176 AC_ARG_ENABLE(blowfish,
177    AC_HELP_STRING([--disable-blowfish],[disable the BLOWFISH cipher]),
178    use_blowfish=$enableval)
179 AC_MSG_RESULT($use_blowfish)
180 if test x"$use_blowfish" = xyes ; then
181    AC_DEFINE(USE_BLOWFISH,1,[Define to include the BLOWFISH cipher])
182 fi
183
184 AC_MSG_CHECKING([whether to enable the AES ciphers])
185 AC_ARG_ENABLE(aes,
186    AC_HELP_STRING([--disable-aes],[disable the AES, AES192, and AES256 ciphers]),
187    use_aes=$enableval)
188 AC_MSG_RESULT($use_aes)
189 if test x"$use_aes" = xyes ; then
190    AC_DEFINE(USE_AES,1,[Define to include the AES, AES192, and AES256 ciphers])
191 fi
192
193 AC_MSG_CHECKING([whether to enable the TWOFISH cipher])
194 AC_ARG_ENABLE(twofish,
195    AC_HELP_STRING([--disable-twofish],[disable the TWOFISH cipher]),
196    use_twofish=$enableval)
197 AC_MSG_RESULT($use_twofish)
198 if test x"$use_twofish" = xyes ; then
199    AC_DEFINE(USE_TWOFISH,1,[Define to include the TWOFISH cipher])
200 fi
201
202 dnl this is because the stable branch calls it just "tiger".
203 AC_ARG_ENABLE(tiger,,use_tiger192=$enableval)
204
205 dnl TIGER192 is actually defined only after we confirm 64-bit support
206 dnl later
207 AC_MSG_CHECKING([whether to enable the TIGER/192 digest])
208 AC_ARG_ENABLE(tiger192,
209    AC_HELP_STRING([--enable-tiger192],[enable the TIGER/192 digest]),
210    use_tiger192=$enableval)
211 AC_MSG_RESULT($use_tiger192)
212
213 if test x"$use_tiger192" = xyes ; then
214    AC_MSG_WARN([[
215 ***
216 *** The TIGER/192 digest is in the process of being removed from the
217 *** OpenPGP standard.  While it hasn't been removed from GnuPG yet, it
218 *** will be removed in a future version.  For the sake of future
219 *** compatibility, please do not use this digest.
220 ***]])
221 fi
222
223 AC_MSG_CHECKING([whether to enable the SHA-256 digest])
224 AC_ARG_ENABLE(sha256,
225    AC_HELP_STRING([--disable-sha256],[disable the SHA-256 digest]),
226    use_sha256=$enableval)
227 AC_MSG_RESULT($use_sha256)
228 if test x"$use_sha256" = xyes ; then
229    AC_DEFINE(USE_SHA256,1,[Define to include the SHA-256 digest])
230 fi
231
232 dnl SHA512 is defined only after we confirm 64-bit support later
233 AC_MSG_CHECKING([whether to enable the SHA-384 and SHA-512 digests])
234 AC_ARG_ENABLE(sha512,
235    AC_HELP_STRING([--disable-sha512],[disable the SHA-384 and SHA-512 digests]),
236    use_sha512=$enableval)
237 AC_MSG_RESULT($use_sha512)
238
239 AC_MSG_CHECKING([whether to enable external program execution])
240 AC_ARG_ENABLE(exec,
241     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
242     use_exec=$enableval)
243 AC_MSG_RESULT($use_exec)
244 if test "$use_exec" = no ; then
245     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
246 fi
247
248 if test "$use_exec" = yes ; then
249   AC_MSG_CHECKING([whether to enable photo ID viewing])
250   AC_ARG_ENABLE(photo-viewers,
251       [  --disable-photo-viewers disable photo ID viewers],
252       [if test "$enableval" = no ; then
253          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
254       fi],enableval=yes)
255   gnupg_cv_enable_photo_viewers=$enableval
256   AC_MSG_RESULT($enableval)
257
258   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
259     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
260     AC_ARG_WITH(photo-viewer,
261         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
262         [if test "$withval" = yes ; then
263            withval=no
264         elif test "$withval" != no ; then
265            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
266                             [if set, restrict photo-viewer to this])
267         fi],withval=no)
268     AC_MSG_RESULT($withval)
269   fi
270
271   AC_MSG_CHECKING([whether to enable external keyserver helpers])
272   AC_ARG_ENABLE(keyserver-helpers,
273       [  --disable-keyserver-helpers  disable all external keyserver support],
274       [if test "$enableval" = no ; then
275          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
276                   [define to disable keyserver helpers])
277       fi],enableval=yes)
278   gnupg_cv_enable_keyserver_helpers=$enableval
279   AC_MSG_RESULT($enableval)
280
281   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
282     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
283     AC_ARG_ENABLE(ldap,
284     [  --disable-ldap          disable LDAP keyserver interface],
285         try_ldap=$enableval, try_ldap=yes)
286     AC_MSG_RESULT($try_ldap)
287
288     AC_MSG_CHECKING([whether HKP keyserver support is requested])
289     AC_ARG_ENABLE(hkp,
290     [  --disable-hkp           disable HKP keyserver interface],
291         try_hkp=$enableval, try_hkp=yes)
292     AC_MSG_RESULT($try_hkp)
293
294     if test "$try_hkp" = yes ; then
295       AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
296     fi
297
298     AC_MSG_CHECKING([whether email keyserver support is requested])
299     AC_ARG_ENABLE(mailto,
300     [  --disable-mailto        disable email keyserver interface],
301         try_mailto=$enableval, try_mailto=yes)
302     AC_MSG_RESULT($try_mailto)
303     fi
304
305     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
306     AC_ARG_ENABLE(keyserver-path,
307         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
308         [if test "$enableval" = no ; then
309          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
310         fi],enableval=yes)
311     AC_MSG_RESULT($enableval)
312   fi
313
314 AC_MSG_CHECKING([whether the included zlib is requested])
315 AC_ARG_WITH(included-zlib,
316     [  --with-included-zlib    use the zlib code included here],
317 [g10_force_zlib=yes], [g10_force_zlib=no] )
318 AC_MSG_RESULT($g10_force_zlib)
319
320 dnl
321 dnl Check whether we want to use Linux capabilities
322 dnl
323 AC_MSG_CHECKING([whether use of capabilities is requested])
324 AC_ARG_WITH(capabilities,
325     [  --with-capabilities     use linux capabilities [default=no]],
326 [use_capabilities="$withval"],[use_capabilities=no])
327 AC_MSG_RESULT($use_capabilities)
328
329
330 AH_BOTTOM([
331 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
332 #define EXEC_TEMPFILE_ONLY
333 #endif
334
335 #include "g10defs.h"
336 ])
337
338
339 AM_MAINTAINER_MODE
340
341 dnl Checks for programs.
342
343 AC_PROG_MAKE_SET
344 AM_SANITY_CHECK
345 missing_dir=`cd $ac_aux_dir && pwd`
346 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
347 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
348 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
349 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
350 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
351 AC_PROG_CC
352 AC_PROG_CPP
353 AC_PROG_RANLIB
354 AC_CHECK_TOOL(AR, ar, :)
355 AC_PATH_PROG(PERL,"perl")
356 AC_ISC_POSIX
357 AC_SYS_LARGEFILE
358 AC_PROG_INSTALL
359 AC_PROG_AWK
360 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
361 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
362 GNUPG_CHECK_FAQPROG
363 GNUPG_CHECK_DOCBOOK_TO_TEXI
364
365 MPI_OPT_FLAGS=""
366
367
368 try_gettext=yes
369 have_dosish_system=no
370 case "${target}" in
371     *-*-mingw32*)
372         # special stuff for Windoze NT
373         ac_cv_have_dev_random=no
374         AC_DEFINE(USE_ONLY_8DOT3,1,
375                   [set this to limit filenames to the 8.3 format])
376         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
377                   [defined if we must run on a stupid file system])
378         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
379                   [because the Unix gettext has too much overhead on
380                    MingW32 systems and these systems lack Posix functions,
381                    we use a simplified version of gettext])
382         have_dosish_system=yes
383         try_gettext="no"
384         ;;
385     i?86-emx-os2 | i?86-*-os2*emx )
386         # OS/2 with the EMX environment
387         ac_cv_have_dev_random=no
388         AC_DEFINE(HAVE_DRIVE_LETTERS)
389         have_dosish_system=yes
390         try_gettext="no"
391         ;;
392
393     i?86-*-msdosdjgpp*)
394         # DOS with the DJGPP environment
395         ac_cv_have_dev_random=no
396         AC_DEFINE(HAVE_DRIVE_LETTERS)
397         have_dosish_system=yes
398         try_gettext="no"
399         ;;
400
401     *-*-freebsd*)
402        # FreeBSD
403        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
404        LDFLAGS="$LDFLAGS -L/usr/local/lib"
405        ;;
406
407     *-*-hpux*)
408         if test -z "$GCC" ; then
409             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
410         fi
411         ;;
412     *-dec-osf4*)
413         if test -z "$GCC" ; then
414             # Suppress all warnings
415             # to get rid of the unsigned/signed char mismatch warnings.
416             CFLAGS="$CFLAGS -w"
417         fi
418         ;;
419     *-dec-osf5*)
420         if test -z "$GCC" ; then
421             # Use the newer compiler `-msg_disable ptrmismatch' to
422             # get rid of the unsigned/signed char mismatch warnings.
423             # Using this may hide other pointer mismatch warnings, but
424             # it at least lets other warning classes through
425             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
426         fi
427         ;;
428     m68k-atari-mint)
429         ;;
430     *)
431        ;;
432 esac
433
434 if test "$have_dosish_system" = yes; then
435    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
436              [defined if we run on some of the PCDOS like systems 
437               (DOS, Windoze. OS/2) with special properties like
438               no file modes])
439 fi
440 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
441
442 AC_SUBST(MPI_OPT_FLAGS)
443 GNUPG_SYS_SYMBOL_UNDERSCORE
444
445 dnl Must check for network library requirements before doing link tests
446 dnl for ldap, for example. If ldap libs are static (or dynamic and without
447 dnl ELF runtime link paths), then link will fail and LDAP support won't
448 dnl be detected.
449
450 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
451         [NETLIBS="-lnsl $NETLIBS"]))
452 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
453         [NETLIBS="-lsocket $NETLIBS"]))
454
455 dnl Now try for the resolver functions so we can use DNS SRV
456
457 AC_ARG_ENABLE(dns-srv,
458    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
459    use_dns_srv=$enableval,use_dns_srv=yes)
460
461 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
462   _srv_save_libs=$LIBS
463   LIBS=""
464   # the double underscore thing is a glibc-ism?
465   AC_SEARCH_LIBS(res_query,resolv bind,,
466                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
467   AC_SEARCH_LIBS(dn_expand,resolv bind,,
468                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
469   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
470                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
471
472   if test x"$use_dns_srv" = xyes ; then
473      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
474      SRVLIBS=$LIBS
475   else
476      AC_MSG_WARN([Resolver functions not found.  Disabling DNS SRV.])
477   fi
478   LIBS=$_srv_save_libs
479 fi
480
481 AC_SUBST(SRVLIBS)
482
483 # Try and link a LDAP test program to weed out unusable LDAP
484 # libraries.  -lldap [-llber [-lresolv]] is for OpenLDAP.  OpenLDAP in
485 # general is terrible with creating weird dependencies.  If all else
486 # fails, the user can play guess-the-dependency by using something
487 # like ./configure LDAPLIBS="-Lfoo -lbar"
488
489 if test "$try_ldap" = yes ; then
490   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
491     _ldap_save_libs=$LIBS
492     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
493
494     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
495     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
496                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
497     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
498
499     if test $gnupg_cv_func_ldap_init = no; then
500       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
501       AC_TRY_LINK([#include <lber.h>
502 #include <ldap.h>],[ldap_open("foobar",1234);],
503          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
504       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
505     fi
506
507     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
508        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
509     fi
510
511     if test "$gnupg_cv_func_ldap_init" = yes || \
512         test "$gnupg_cv_func_ldaplber_init" = yes ; then
513        LDAPLIBS=$MY_LDAPLIBS
514        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
515
516        AC_MSG_CHECKING([whether LDAP supports ldap_get_option])
517
518        if test "$gnupg_cv_func_ldap_init" = yes ; then
519           AC_TRY_LINK([#include <ldap.h>],
520              [ldap_get_option((void *)0,0,(void *)0);],
521              [gnupg_cv_func_ldap_get_option=yes],
522              [gnupg_cv_func_ldap_get_option=no])
523         else
524           AC_TRY_LINK([#include <lber.h>
525 #include <ldap.h>],[ldap_get_option((void *)0,0,(void *)0);],
526              [gnupg_cv_func_ldap_get_option=yes],
527              [gnupg_cv_func_ldap_get_option=no])
528        fi
529
530        AC_MSG_RESULT([$gnupg_cv_func_ldap_get_option])
531
532        if test "$gnupg_cv_func_ldap_get_option" = yes ; then
533           AC_DEFINE(HAVE_LDAP_GET_OPTION,1,[Define if the LDAP library has ldap_get_option])
534        else
535           AC_MSG_CHECKING([whether LDAP supports ld_errno])
536
537           if test "$gnupg_cv_func_ldap_init" = yes ; then
538             AC_TRY_COMPILE([#include <ldap.h>],
539                [LDAP *ldap; ldap->ld_errno;],
540                [gnupg_cv_func_ldap_ld_errno=yes],
541                [gnupg_cv_func_ldap_ld_errno=no])
542            else
543             AC_TRY_LINK([#include <lber.h>
544 #include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
545                [gnupg_cv_func_ldap_ld_errno=yes],
546                [gnupg_cv_func_ldap_ld_errno=no])
547           fi
548
549           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
550
551           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
552              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
553           fi
554        fi
555     fi
556
557     LIBS=$_ldap_save_libs
558
559     if test "$GPGKEYS_LDAP" != "" ; then break; fi
560   done
561 fi
562
563 AC_SUBST(GPGKEYS_LDAP)
564 AC_SUBST(LDAPLIBS)
565
566 dnl This isn't necessarily sendmail itself, but anything that gives a
567 dnl sendmail-ish interface to the outside world.  That includes qmail,
568 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
569
570 if test "$try_mailto" = yes ; then
571   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
572
573   if test "$with_mailprog" = yes ; then
574     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
575     if test "$ac_cv_path_SENDMAIL" ; then
576       GPGKEYS_MAILTO="gpgkeys_mailto"
577     fi
578   elif test "$with_mailprog" != no ; then
579     AC_MSG_CHECKING([for a mail transport program])
580     AC_SUBST(SENDMAIL,$with_mailprog)
581     AC_MSG_RESULT($with_mailprog)
582     GPGKEYS_MAILTO="gpgkeys_mailto"
583   fi
584 fi
585
586 AC_SUBST(GPGKEYS_MAILTO)
587
588 case "${target}" in
589     *-*-mingw32*)
590         PRINTABLE_OS_NAME="MingW32"
591         ;;
592     *-*-cygwin*)
593         PRINTABLE_OS_NAME="Cygwin"
594         ;;
595     i?86-emx-os2 | i?86-*-os2*emx )
596         PRINTABLE_OS_NAME="OS/2"
597         ;;
598     i?86-*-msdosdjgpp*)
599         PRINTABLE_OS_NAME="MSDOS/DJGPP"
600         try_dynload=no
601         ;;
602     *-linux*)
603         PRINTABLE_OS_NAME="GNU/Linux"
604         ;;
605 dnl let that after linux to avoid gnu-linux problems
606     *-gnu*)
607         PRINTABLE_OS_NAME="GNU/Hurd"
608         ;;
609     *)
610         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
611         ;;
612 esac
613 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
614                    [A human readable text with the name of the OS])
615
616
617 #
618 # 1. Set names of random devices
619 #
620 NAME_OF_DEV_RANDOM="/dev/random"
621 NAME_OF_DEV_URANDOM="/dev/urandom"
622 case "${target}" in
623     *-openbsd*)
624         NAME_OF_DEV_RANDOM="/dev/srandom"
625         NAME_OF_DEV_URANDOM="/dev/urandom"
626         ;;
627 esac
628 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM",
629                    [defined to the name of the strong random device])
630 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM",
631                    [defined to the name of the weaker random device])
632 AC_SUBST(MPI_OPT_FLAGS)
633
634
635 dnl Checks for libraries.
636
637 if test "$try_gettext" = yes; then
638   AM_GNU_GETTEXT
639 else
640   USE_NLS=no
641   USE_INCLUDED_LIBINTL=no
642   BUILD_INCLUDED_LIBINTL=no
643   AC_SUBST(USE_NLS)
644   AC_SUBST(USE_INCLUDED_LIBINTL)
645   AC_SUBST(BUILD_INCLUDED_LIBINTL)
646 fi
647
648
649 if test "$try_dynload" = yes ; then
650   AC_CHECK_LIB(dl,dlopen)
651   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
652     AC_DEFINE(USE_DYNAMIC_LINKING,1,
653               [define to enable the use of extensions])
654     AC_DEFINE(HAVE_DL_DLOPEN,1,
655               [Defined when the dlopen function family is available])
656   else
657     AC_CHECK_FUNCS(dlopen)
658     if test "$ac_cv_func_dlopen" = "yes"; then
659       AC_DEFINE(USE_DYNAMIC_LINKING)
660       AC_DEFINE(HAVE_DL_DLOPEN)
661     fi
662   fi
663 else
664   AC_MSG_CHECKING(for dynamic loading)
665   DYNLINK_LDFLAGS=
666   DYNLINK_MOD_CFLAGS=
667   AC_MSG_RESULT(has been disabled)
668 fi
669
670 dnl Checks for header files.
671 AC_HEADER_STDC
672 AC_CHECK_HEADERS(unistd.h langinfo.h termio.h locale.h)
673
674 dnl Checks for typedefs, structures, and compiler characteristics.
675 AC_C_CONST
676 AC_C_INLINE
677 AC_C_VOLATILE
678 AC_TYPE_SIZE_T
679 AC_TYPE_MODE_T
680 AC_TYPE_SIGNAL
681 AC_DECL_SYS_SIGLIST
682
683 GNUPG_CHECK_ENDIAN
684
685 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
686 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
687 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
688 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
689 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
690
691 AC_CHECK_SIZEOF(unsigned short)
692 AC_CHECK_SIZEOF(unsigned int)
693 AC_CHECK_SIZEOF(unsigned long)
694 AC_CHECK_SIZEOF(unsigned long long)
695 AC_CHECK_SIZEOF(uint64_t)
696
697 if test "$ac_cv_sizeof_unsigned_short" = "0" \
698    || test "$ac_cv_sizeof_unsigned_int" = "0" \
699    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
700     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
701 fi
702
703 dnl Do we have any 64-bit data types?
704 if test "$ac_cv_sizeof_unsigned_int" != "8" \
705    && test "$ac_cv_sizeof_unsigned_long" != "8" \
706    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
707    && test "$ac_cv_sizeof_uint64_t" != "8"; then
708     AC_MSG_WARN([No 64-bit types.  Disabling TIGER/192, SHA-384, and SHA-512])
709 else
710   if test x"$use_tiger192" = xyes ; then
711      AC_SUBST(TIGER_O,tiger.o)
712      AC_DEFINE(USE_TIGER192,1,[Define to include the TIGER/192 digest])
713
714      AC_MSG_CHECKING([whether to enable old-style TIGER/192 digest support])
715      AC_ARG_ENABLE(old-tiger,
716         [  --enable-old-tiger      enable old-style TIGER/192 digest support],
717         old_tiger=$enableval, old_tiger=no)
718      AC_MSG_RESULT($old_tiger)
719      if test "$old_tiger" = yes ; then
720         AC_DEFINE(USE_OLD_TIGER,1,[Define to use the old fake OID for TIGER/192 digest support])
721      fi
722   fi
723   if test x"$use_sha512" = xyes ; then
724      AC_SUBST(SHA512_O,sha512.o)
725      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
726   fi
727 fi
728
729 dnl Checks for library functions.
730 AC_FUNC_FSEEKO
731 AC_FUNC_VPRINTF
732 AC_FUNC_FORK
733 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
734 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid)
735 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
736 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
737 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat)
738 AC_REPLACE_FUNCS(mkdtemp)
739
740 #
741 # check for gethrtime and run a testprogram to see whether
742 # it is broken.  It has been reported that some Solaris and HP UX systems 
743 # raise an SIGILL
744 #
745 AC_CACHE_CHECK([for gethrtime], 
746                [gnupg_cv_func_gethrtime],
747                [AC_TRY_LINK([#include <sys/times.h>],[
748                    hrtime_t tv;
749                    tv = gethrtime();
750                  ],
751                  [gnupg_cv_func_gethrtime=yes],
752                  [gnupg_cv_func_gethrtime=no])
753                ])
754 if test $gnupg_cv_func_gethrtime = yes; then
755      AC_DEFINE([HAVE_GETHRTIME], 1,
756                [Define if you have the `gethrtime(2)' function.])
757      AC_CACHE_CHECK([whether gethrtime is broken], 
758                [gnupg_cv_func_broken_gethrtime],
759                [AC_TRY_RUN([
760                    #include <sys/times.h>
761                    int main () {
762                    hrtime_t tv;
763                    tv = gethrtime(); 
764                  }
765                  ],
766                  [gnupg_cv_func_broken_gethrtime=no],
767                  [gnupg_cv_func_broken_gethrtime=yes],
768                  [gnupg_cv_func_broken_gethrtime=assume-no])
769                 ])
770     if test $gnupg_cv_func_broken_gethrtime = yes; then
771       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
772       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
773     fi
774 fi
775      
776
777 GNUPG_CHECK_MLOCK
778 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
779
780 dnl
781 dnl Check whether we can use Linux capabilities as requested
782 dnl
783 if test "$use_capabilities" = "yes" ; then
784 use_capabilities=no
785 AC_CHECK_HEADERS(sys/capability.h)
786 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
787   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
788   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
789      AC_DEFINE(USE_CAPABILITIES,1,
790                [define if capabilities should be used])
791      AC_SUBST(CAPLIBS,"-lcap")
792      use_capabilities=yes
793   fi
794 fi
795 if test "$use_capabilities" = "no" ; then
796     AC_MSG_WARN([[
797 ***
798 *** The use of capabilities on this system is not possible.
799 *** You need a recent Linux kernel and some patches:
800 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
801 ***   fcap-module-990613.tar.gz     (kernel module)
802 ***   libcap-1.92.tar.gz            (user mode library and utilities)
803 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
804 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
805 ***]])
806 fi
807 fi
808
809
810 GNUPG_CHECK_IPC
811 if test "$ac_cv_header_sys_shm_h" = "yes"; then
812   AC_DEFINE(USE_SHM_COPROCESSING,1,
813             [define if the shared memory interface should be made available])
814 fi
815
816 dnl
817 dnl check whether we have a random device
818 dnl
819 if test "$try_dev_random" = yes ; then
820     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
821     [if test -r "$NAME_OF_DEV_RANDOM" && test -r "$NAME_OF_DEV_URANDOM" ; then
822       ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
823     if test "$ac_cv_have_dev_random" = yes; then
824         AC_DEFINE(HAVE_DEV_RANDOM,1,
825                  [defined if the system supports a random device] )
826     fi
827 else
828     AC_MSG_CHECKING(for random device)
829     ac_cv_have_dev_random=no
830     AC_MSG_RESULT(has been disabled)
831 fi
832
833
834 dnl
835 dnl Figure out the default random module.
836 dnl
837 random_modules=""
838 if test "$use_static_rnd" = default; then
839      if test "$ac_cv_have_dev_random" = yes; then
840         random_modules="rndlinux"
841      else
842          case "${target}" in
843             *-*-mingw32*|*-*-cygwin*)
844                 random_modules="rndw32"
845                 ;;
846             i?86-emx-os2|i?86-*-os2*emx)
847                 random_modules="rndos2"
848                 ;;
849             m68k-atari-mint)
850                 random_modules="rndatari"
851                 ;;
852             i?86-*-msdosdjgpp*)
853                 :
854                 ;;
855             *)
856                 random_modules="rndlinux rndegd rndunix"
857                 AC_DEFINE(USE_ALL_RANDOM_MODULES, 1, 
858                           [Allow to select random modules at runtime.])
859                 ;;
860          esac
861      fi
862 else
863   if test "$use_static_rnd" = auto; then
864      random_modules="rndlinux rndegd rndunix"
865      AC_DEFINE(USE_ALL_RANDOM_MODULES, 1)
866   else
867      random_modules="rnd$use_static_rnd";
868   fi
869 fi
870
871 if test -z "$random_modules"; then
872    AC_MSG_ERROR(no random module available)
873 fi
874 print_egd_warning=no
875 for rndmod in $random_modules "" ; do
876   case "$rndmod" in
877     rndlinux)
878          AC_DEFINE(USE_RNDLINUX,1, 
879                   [Defined if the /dev/random based RNG should be used.])
880          ;;
881     rndunix)
882          AC_DEFINE(USE_RNDUNIX,1, 
883                   [Defined if the default Unix RNG should be used.])
884          print_egd_warning=yes
885           ;;
886     rndegd)
887          AC_DEFINE(USE_RNDEGD,1, 
888                   [Defined if the EGD based RNG should be used.])
889          EGDLIBS=$NETLIBS
890          AC_SUBST(EGDLIBS)
891          ;;
892     rndw32)
893          AC_DEFINE(USE_RNDW32,1, 
894                   [Defined if the Windows specific RNG should be used.])
895         ;;
896    esac
897 done
898
899 dnl setup assembler stuff
900 AC_MSG_CHECKING(for mpi assembler functions)
901 if test -f $srcdir/mpi/config.links ; then
902     . $srcdir/mpi/config.links
903     AC_CONFIG_LINKS("$mpi_ln_list")
904     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
905     ac_cv_mpi_sflags="$mpi_sflags"
906     ac_cv_mpi_config_done="yes"
907     AC_MSG_RESULT(done)
908 else
909     AC_MSG_RESULT(failed)
910     AC_MSG_ERROR([mpi/config.links missing!])
911 fi
912 MPI_EXTRA_ASM_OBJS=""
913 show_extraasm=""
914 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
915 for i in $ac_cv_mpi_extra_asm_modules; do
916     show_extraasm="$show_extraasm $i"
917     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
918 done
919 fi
920 AC_SUBST(MPI_EXTRA_ASM_OBJS)
921 MPI_SFLAGS="$ac_cv_mpi_sflags"
922 AC_SUBST(MPI_SFLAGS)
923
924 # Sanity check regex.  Tests adapted from mutt.
925
926 AC_MSG_CHECKING([whether regular expression support is requested])
927 AC_ARG_ENABLE(regex,
928 [  --disable-regex         do not handle regular expressions in trust sigs],
929      use_regex=$enableval, use_regex=yes)
930 AC_MSG_RESULT($use_regex)
931
932 if test "$use_regex" = yes ; then
933   AC_MSG_CHECKING([whether the included regex lib is requested])
934   AC_ARG_WITH(included-regex,
935       [  --with-included-regex   use the included GNU regex library],
936       [gnupg_cv_included_regex=yes],[gnupg_cv_included_regex=no])
937   AC_MSG_RESULT($gnupg_cv_included_regex)
938
939   if test $gnupg_cv_included_regex = no ; then
940      # Does the system have regex functions at all?
941      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
942                            gnupg_cv_included_regex=yes)
943   fi
944
945   if test $gnupg_cv_included_regex = no ; then
946      AC_CACHE_CHECK([whether your system's regexp library is broken],
947        [gnupg_cv_regex_broken],
948        AC_TRY_RUN([
949 #include <unistd.h>
950 #include <regex.h>
951 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
952        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
953
954      if test $gnupg_cv_regex_broken = yes ; then
955       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
956       gnupg_cv_included_regex=yes
957      fi
958   fi
959
960   if test $gnupg_cv_included_regex = yes; then
961      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
962      AC_SUBST(REGEX_O,regex.o)
963   fi
964 else
965
966   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
967 fi
968
969 dnl Do we have zlib? Must do it here because Solaris failed
970 dnl when compiling a conftest (due to the "-lz" from LIBS).
971 use_local_zlib=yes
972 if test "$g10_force_zlib" = "yes"; then
973   :
974 else
975   _cppflags="${CPPFLAGS}"
976   _ldflags="${LDFLAGS}"
977
978   AC_ARG_WITH(zlib,
979   [  --with-zlib=DIR         use libz in DIR],[
980     if test -d "$withval"; then
981       CPPFLAGS="${CPPFLAGS} -I$withval/include"
982       LDFLAGS="${LDFLAGS} -L$withval/lib"
983     fi
984   ])
985
986   AC_CHECK_HEADER(zlib.h,
987       AC_CHECK_LIB(z, deflateInit2_,
988        use_local_zlib=no
989        LIBS="$LIBS -lz",
990        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
991        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
992 fi
993  
994 if test "$use_local_zlib" = yes ; then
995     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
996     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
997     ZLIBS="../zlib/libzlib.a"
998 else
999     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
1000     ZLIBS=
1001 fi
1002 AC_SUBST(ZLIBS)
1003
1004
1005 # Allow users to append something to the version string without
1006 # flagging it as development version.  The user version parts is
1007 # considered everything after a dash. 
1008 if test "$development_version" != yes; then
1009   changequote(,)dnl
1010   tmp_pat='[a-zA-Z]'
1011   changequote([,])dnl
1012   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1013     development_version=yes
1014   fi
1015 fi
1016 if test "$development_version" = yes; then
1017     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1018             [Defined if this is not a regular release])
1019 fi
1020
1021 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1022
1023 GNUPG_CHECK_GNUMAKE
1024
1025 # add some extra libs here so that previous tests don't fail for
1026 # mysterious reasons - the final link step should bail out. 
1027 case "${target}" in
1028     *-*-mingw32*)
1029         LIBS="$LIBS -lwsock32"
1030         ;;
1031     *)
1032        ;;
1033 esac
1034
1035
1036 if test "$GCC" = yes; then
1037     if test "$USE_MAINTAINER_MODE" = "yes"; then
1038         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1039     else
1040         CFLAGS="$CFLAGS -Wall"
1041     fi
1042 fi
1043
1044 AC_SUBST(NETLIBS)
1045
1046
1047 if test "$print_egd_warning" = yes; then
1048   AC_MSG_WARN([[
1049 ***
1050 *** The performance of the UNIX random gatherer module is not very good
1051 *** and it does not keep the entropy pool over multiple invocations of
1052 *** GnuPG.  The suggested way to overcome this problem is to use the
1053 ***
1054 ***               Entropy Gathering Daemon (EGD)
1055 ***
1056 *** which provides a entropy source for the whole system.  It is written
1057 *** in Perl and available at the GnuPG FTP servers.  For more information
1058 *** consult the GnuPG webpages:
1059 ***
1060 ***           http://www.gnupg.org/download.html#egd
1061 ***
1062 *** You may want to run ./configure with --enable-static-rnd=egd to use it.
1063 ***]])
1064 fi
1065
1066 # Note the \\\\ for backslashes.  Autoconf eats one layer, leaving \\
1067
1068 AC_CONFIG_COMMANDS(g10defs.h,[[
1069 cat >g10defs.tmp <<G10EOF
1070 /* Generated automatically by configure */
1071 #ifdef HAVE_DRIVE_LETTERS
1072   #define G10_LOCALEDIR     "c:\\\\lib\\\\gnupg\\\\locale"
1073   #define GNUPG_LIBDIR      "c:\\\\lib\\\\gnupg"
1074   #define GNUPG_LIBEXECDIR  "c:\\\\lib\\\\gnupg"
1075   #define GNUPG_DATADIR     "c:\\\\lib\\\\gnupg"
1076   #define GNUPG_HOMEDIR     "c:\\\\gnupg"
1077 #else
1078   #define G10_LOCALEDIR     "${datadir}/locale"
1079   #define GNUPG_LIBDIR      "${libdir}/gnupg"
1080   #define GNUPG_DATADIR     "${datadir}/gnupg"
1081   #ifdef __VMS
1082     #define GNUPG_HOMEDIR "/SYS\$LOGIN/gnupg" 
1083   #else
1084     #define GNUPG_HOMEDIR "~/.gnupg" 
1085   #endif
1086 #endif
1087 /* those are here to be redefined by handcrafted g10defs.h.
1088    Please note that the string version must not contain more
1089    than one character because the using code assumes strlen()==1 */
1090 #ifdef HAVE_DOSISH_SYSTEM
1091 #define DIRSEP_C '\\\\'
1092 #define EXTSEP_C '.'
1093 #define DIRSEP_S "\\\\"
1094 #define EXTSEP_S "."
1095 #else
1096 #define DIRSEP_C '/'
1097 #define EXTSEP_C '.'
1098 #define DIRSEP_S "/"
1099 #define EXTSEP_S "."
1100 #endif
1101 G10EOF
1102 cat mpi/mpi-asm-defs.h >>g10defs.tmp 
1103 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
1104     echo "g10defs.h is unchanged"
1105     rm -f g10defs.tmp
1106 else
1107     rm -f g10defs.h
1108     mv g10defs.tmp g10defs.h
1109     echo "g10defs.h created"
1110 fi
1111 ]],[[
1112 prefix=$prefix
1113 exec_prefix=$exec_prefix
1114 libdir=$libdir
1115 libexecdir=$libexecdir
1116 datadir=$datadir
1117 DATADIRNAME=$DATADIRNAME
1118 ]])
1119
1120
1121 AC_CONFIG_FILES([
1122 Makefile
1123 intl/Makefile
1124 po/Makefile.in
1125 util/Makefile
1126 mpi/Makefile
1127 cipher/Makefile
1128 g10/Makefile
1129 keyserver/Makefile
1130 keyserver/gpgkeys_mailto
1131 keyserver/gpgkeys_test
1132 doc/Makefile
1133 tools/Makefile
1134 zlib/Makefile
1135 checks/Makefile
1136 ])
1137 AC_OUTPUT
1138
1139 # Give some feedback
1140 echo
1141 echo   "                Configured for: $PRINTABLE_OS_NAME ($target)"
1142 if test -n "$show_extraasm"; then
1143   echo "  Extra cpu specific functions:$show_extraasm"
1144 fi
1145 echo