7d502746d6fb1088b6111f724f16c93a3bbac652
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998-2017 Free Software Foundation, Inc.
3 # Copyright (C) 1998-2017 Werner Koch
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <https://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.14"
23
24 # To build a release you need to create a tag with the version number
25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
26 # bump the version number immediately *after* the release and do
27 # another commit and push so that the git magic is able to work.
28 m4_define([mym4_package],[gnupg])
29 m4_define([mym4_major], [2])
30 m4_define([mym4_minor], [1])
31 m4_define([mym4_micro], [23])
32
33 # To start a new development series, i.e a new major or minor number
34 # you need to mark an arbitrary commit before the first beta release
35 # with an annotated tag.  For example the 2.1 branch starts off with
36 # the tag "gnupg-2.1-base".  This is used as the base for counting
37 # beta numbers before the first release of a series.
38
39 # Below is m4 magic to extract and compute the git revision number,
40 # the decimalized short revision number, a beta version string and a
41 # flag indicating a development version (mym4_isbeta).  Note that the
42 # m4 processing is done by autoconf and not during the configure run.
43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
49 m4_esyscmd([echo ]mym4_version[>VERSION])
50 AC_INIT([mym4_package],[mym4_version], [https://bugs.gnupg.org])
51
52 NEED_GPG_ERROR_VERSION=1.24
53
54 NEED_LIBGCRYPT_API=1
55 NEED_LIBGCRYPT_VERSION=1.7.0
56
57 NEED_LIBASSUAN_API=2
58 NEED_LIBASSUAN_VERSION=2.4.3
59
60 NEED_KSBA_API=1
61 NEED_KSBA_VERSION=1.3.4
62
63 NEED_NTBTLS_API=1
64 NEED_NTBTLS_VERSION=0.1.0
65
66 NEED_NPTH_API=1
67 NEED_NPTH_VERSION=1.2
68
69
70 NEED_GNUTLS_VERSION=3.0
71
72 NEED_SQLITE_VERSION=3.7
73
74 development_version=mym4_isbeta
75 PACKAGE=$PACKAGE_NAME
76 PACKAGE_GT=${PACKAGE_NAME}2
77 VERSION=$PACKAGE_VERSION
78
79 AC_CONFIG_AUX_DIR([build-aux])
80 AC_CONFIG_SRCDIR([sm/gpgsm.c])
81 AC_CONFIG_HEADER([config.h])
82 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
83 AC_CANONICAL_HOST
84 AB_INIT
85
86 AC_GNU_SOURCE
87
88 # Before we do anything with the C compiler, we first save the user's
89 # CFLAGS (they are restored at the end of the configure script).  This
90 # is because some configure checks don't work with -Werror, but we'd
91 # like to use -Werror with our build.
92 CFLAGS_orig=$CFLAGS
93 CFLAGS=
94
95 # Some status variables.
96 have_gpg_error=no
97 have_libgcrypt=no
98 have_libassuan=no
99 have_ksba=no
100 have_ntbtls=no
101 have_gnutls=no
102 have_sqlite=no
103 have_npth=no
104 have_libusb=no
105 have_system_resolver=no
106 gnupg_have_ldap="n/a"
107
108 use_zip=yes
109 use_bzip2=yes
110 use_exec=yes
111 use_trust_models=yes
112 use_tofu=yes
113 use_libdns=yes
114 card_support=yes
115 use_ccid_driver=auto
116 dirmngr_auto_start=yes
117 use_tls_library=no
118 large_secmem=no
119 show_tor_support=no
120
121
122 GNUPG_BUILD_PROGRAM(gpg, yes)
123 GNUPG_BUILD_PROGRAM(gpgsm, yes)
124 # The agent is a required part and can't be disabled anymore.
125 build_agent=yes
126 GNUPG_BUILD_PROGRAM(scdaemon, yes)
127 GNUPG_BUILD_PROGRAM(g13, no)
128 GNUPG_BUILD_PROGRAM(dirmngr, yes)
129 GNUPG_BUILD_PROGRAM(doc, yes)
130 GNUPG_BUILD_PROGRAM(symcryptrun, no)
131 # We use gpgtar to unpack test data, hence we always build it.  If the
132 # user opts out, we simply don't install it.
133 GNUPG_BUILD_PROGRAM(gpgtar, yes)
134 GNUPG_BUILD_PROGRAM(wks-tools, no)
135
136 AC_SUBST(PACKAGE)
137 AC_SUBST(PACKAGE_GT)
138 AC_SUBST(VERSION)
139 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
140 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
141                                 [Name of this package for gettext])
142 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
143 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
144                                         [Bug report address])
145 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
146                                        [Required version of Libgcrypt])
147 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
148                                        [Required version of Libksba])
149 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
150                                        [Required version of NTBTLS])
151
152
153
154 # The default is to use the modules from this package and the few
155 # other packages in a standard place; i.e where this package gets
156 # installed.  With these options it is possible to override these
157 # ${prefix} depended values with fixed paths, which can't be replaced
158 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
159 AC_ARG_WITH(agent-pgm,
160     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
161           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
162 AC_SUBST(GNUPG_AGENT_PGM)
163 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
164 show_gnupg_agent_pgm="(default)"
165 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
166
167 AC_ARG_WITH(pinentry-pgm,
168     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
169           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
170 AC_SUBST(GNUPG_PINENTRY_PGM)
171 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
172 show_gnupg_pinentry_pgm="(default)"
173 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
174
175
176 AC_ARG_WITH(scdaemon-pgm,
177     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
178           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
179 AC_SUBST(GNUPG_SCDAEMON_PGM)
180 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
181 show_gnupg_scdaemon_pgm="(default)"
182 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
183
184
185 AC_ARG_WITH(dirmngr-pgm,
186     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
187           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
188 AC_SUBST(GNUPG_DIRMNGR_PGM)
189 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
190 show_gnupg_dirmngr_pgm="(default)"
191 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
192
193 AC_ARG_WITH(protect-tool-pgm,
194     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
195           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
196 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
197 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
198 show_gnupg_protect_tool_pgm="(default)"
199 test -n "$GNUPG_PROTECT_TOOL_PGM" \
200       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
201
202 AC_ARG_WITH(dirmngr-ldap-pgm,
203     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmngr ldap wrapper)],
204           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
205 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
206 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
207 show_gnupg_dirmngr_ldap_pgm="(default)"
208 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
209       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
210
211 #
212 # On some platforms gpg2 is usually installed as gpg without using a
213 # symlink.  For correct operation of gpgconf it needs to know the
214 # installed name of gpg.  This option sets "gpg2"'s installed name to
215 # just "gpg".  Note that it might be required to rename gpg2 to gpg
216 # manually after the build process.
217 #
218 AC_ARG_ENABLE(gpg2-is-gpg,
219     AC_HELP_STRING([--enable-gpg2-is-gpg],[Set installed name of gpg2 to gpg]),
220     gpg2_is_gpg=$enableval)
221 if test "$gpg2_is_gpg" != "yes"; then
222    AC_DEFINE(USE_GPG2_HACK, 1, [Define to install gpg as gpg2])
223 fi
224 AM_CONDITIONAL(USE_GPG2_HACK, test "$gpg2_is_gpg" != "yes")
225
226
227 # SELinux support includes tracking of sensitive files to avoid
228 # leaking their contents through processing these files by gpg itself
229 AC_MSG_CHECKING([whether SELinux support is requested])
230 AC_ARG_ENABLE(selinux-support,
231               AC_HELP_STRING([--enable-selinux-support],
232                              [enable SELinux support]),
233               selinux_support=$enableval, selinux_support=no)
234 AC_MSG_RESULT($selinux_support)
235
236
237 AC_MSG_CHECKING([whether to allocate extra secure memory])
238 AC_ARG_ENABLE(large-secmem,
239               AC_HELP_STRING([--enable-large-secmem],
240                              [allocate extra secure memory]),
241               large_secmem=$enableval, large_secmem=no)
242 AC_MSG_RESULT($large_secmem)
243 if test "$large_secmem" = yes ; then
244    SECMEM_BUFFER_SIZE=65536
245 else
246    SECMEM_BUFFER_SIZE=32768
247 fi
248 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
249                    [Size of secure memory buffer])
250
251 AC_MSG_CHECKING([whether to enable trust models])
252 AC_ARG_ENABLE(trust-models,
253               AC_HELP_STRING([--disable-trust-models],
254                              [disable all trust models except "always"]),
255               use_trust_models=$enableval)
256 AC_MSG_RESULT($use_trust_models)
257 if test "$use_trust_models" = no ; then
258     AC_DEFINE(NO_TRUST_MODELS, 1,
259              [Define to include only trust-model always])
260 fi
261
262 AC_MSG_CHECKING([whether to enable TOFU])
263 AC_ARG_ENABLE(tofu,
264                 AC_HELP_STRING([--disable-tofu],
265                                [disable the TOFU trust model]),
266               use_tofu=$enableval, use_tofu=$use_trust_models)
267 AC_MSG_RESULT($use_tofu)
268 if test "$use_trust_models" = no && test "$use_tofu" = yes; then
269     AC_MSG_ERROR([both --disable-trust-models and --enable-tofu given])
270 fi
271
272 AC_MSG_CHECKING([whether to enable libdns])
273 AC_ARG_ENABLE(libdns,
274                 AC_HELP_STRING([--disable-libdns],
275                                [do not build with libdns support]),
276               use_libdns=$enableval, use_libdns=yes)
277 AC_MSG_RESULT($use_libdns)
278 if test x"$use_libdns" = xyes ; then
279     AC_DEFINE(USE_LIBDNS, 1, [Build with integrated libdns support])
280 fi
281 AM_CONDITIONAL(USE_LIBDNS, test "$use_libdns" = yes)
282
283
284 #
285 # Options to disable algorithm
286 #
287
288 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
289 # Elgamal is a MUST algorithm
290 # DSA is a MUST algorithm
291 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
292 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
293 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
294
295 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
296 # 3DES is a MUST algorithm
297 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
298 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
299 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
300 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
301 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
302 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
303 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
304 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
305 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
306
307 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
308 # SHA1 is a MUST algorithm
309 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
310 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
311 # SHA256 is a MUST algorithm for GnuPG.
312 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
313 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
314
315
316 # Allow disabling of zip support.
317 # This is in general not a good idea because according to rfc4880 OpenPGP
318 # implementations SHOULD support ZLIB.
319 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
320 AC_ARG_ENABLE(zip,
321    AC_HELP_STRING([--disable-zip],
322                   [disable the ZIP and ZLIB compression algorithm]),
323    use_zip=$enableval)
324 AC_MSG_RESULT($use_zip)
325
326 # Allow disabling of bzib2 support.
327 # It is defined only after we confirm the library is available later
328 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
329 AC_ARG_ENABLE(bzip2,
330    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
331    use_bzip2=$enableval)
332 AC_MSG_RESULT($use_bzip2)
333
334 # Configure option to allow or disallow execution of external
335 # programs, like a photo viewer.
336 AC_MSG_CHECKING([whether to enable external program execution])
337 AC_ARG_ENABLE(exec,
338     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
339     use_exec=$enableval)
340 AC_MSG_RESULT($use_exec)
341 if test "$use_exec" = no ; then
342     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
343 fi
344
345 if test "$use_exec" = yes ; then
346   AC_MSG_CHECKING([whether to enable photo ID viewing])
347   AC_ARG_ENABLE(photo-viewers,
348       [  --disable-photo-viewers disable photo ID viewers],
349       [if test "$enableval" = no ; then
350          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
351       fi],enableval=yes)
352   gnupg_cv_enable_photo_viewers=$enableval
353   AC_MSG_RESULT($enableval)
354
355   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
356     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
357     AC_ARG_WITH(photo-viewer,
358         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
359         [if test "$withval" = yes ; then
360            withval=no
361         elif test "$withval" != no ; then
362            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
363                             [if set, restrict photo-viewer to this])
364         fi],withval=no)
365     AC_MSG_RESULT($withval)
366   fi
367 fi
368
369
370 #
371 # Check for the key/uid cache size.  This can't be zero, but can be
372 # pretty small on embedded systems.  This is used for the gpg part.
373 #
374 AC_MSG_CHECKING([for the size of the key and uid cache])
375 AC_ARG_ENABLE(key-cache,
376         AC_HELP_STRING([--enable-key-cache=SIZE],
377                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
378 if test "$enableval" = "no"; then
379    enableval=5
380 elif test "$enableval" = "yes" || test "$enableval" = ""; then
381    enableval=4096
382 fi
383 changequote(,)dnl
384 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
385 changequote([,])dnl
386 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
387    AC_MSG_ERROR([invalid key-cache size])
388 fi
389 AC_MSG_RESULT($key_cache_size)
390 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
391                   [Size of the key and UID caches])
392
393
394
395 #
396 # Check whether we want to use Linux capabilities
397 #
398 AC_MSG_CHECKING([whether use of capabilities is requested])
399 AC_ARG_WITH(capabilities,
400     [  --with-capabilities     use linux capabilities [default=no]],
401 [use_capabilities="$withval"],[use_capabilities=no])
402 AC_MSG_RESULT($use_capabilities)
403
404 #
405 # Check whether to disable the card support
406 AC_MSG_CHECKING([whether smartcard support is requested])
407 AC_ARG_ENABLE(card-support,
408               AC_HELP_STRING([--disable-card-support],
409                              [disable smartcard support]),
410               card_support=$enableval)
411 AC_MSG_RESULT($card_support)
412 if test "$card_support" = yes ; then
413   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
414 else
415   build_scdaemon=no
416 fi
417
418 #
419 # Allow disabling of internal CCID support.
420 # It is defined only after we confirm the library is available later
421 #
422 AC_MSG_CHECKING([whether to enable the internal CCID driver])
423 AC_ARG_ENABLE(ccid-driver,
424               AC_HELP_STRING([--disable-ccid-driver],
425                              [disable the internal CCID driver]),
426               use_ccid_driver=$enableval)
427 AC_MSG_RESULT($use_ccid_driver)
428
429 AC_MSG_CHECKING([whether to auto start dirmngr])
430 AC_ARG_ENABLE(dirmngr-auto-start,
431               AC_HELP_STRING([--disable-dirmngr-auto-start],
432                              [disable auto starting of the dirmngr]),
433               dirmngr_auto_start=$enableval)
434 AC_MSG_RESULT($dirmngr_auto_start)
435 if test "$dirmngr_auto_start" = yes ; then
436     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
437               [Define to enable auto starting of the dirmngr])
438 fi
439
440
441 #
442 # To avoid double inclusion of config.h which might happen at some
443 # places, we add the usual double inclusion protection at the top of
444 # config.h.
445 #
446 AH_TOP([
447 #ifndef GNUPG_CONFIG_H_INCLUDED
448 #define GNUPG_CONFIG_H_INCLUDED
449 ])
450
451 #
452 # Stuff which goes at the bottom of config.h.
453 #
454 AH_BOTTOM([
455 /* This is the major version number of GnuPG so that
456    source included files can test for this.  Note, that
457    we use 2 here even for GnuPG 1.9.x. */
458 #define GNUPG_MAJOR_VERSION 2
459
460 /* Now to separate file name parts.
461    Please note that the string version must not contain more
462    than one character because the code assumes strlen()==1 */
463 #ifdef HAVE_DOSISH_SYSTEM
464 #define DIRSEP_C '\\'
465 #define DIRSEP_S "\\"
466 #define EXTSEP_C '.'
467 #define EXTSEP_S "."
468 #define PATHSEP_C ';'
469 #define PATHSEP_S ";"
470 #define EXEEXT_S ".exe"
471 #else
472 #define DIRSEP_C '/'
473 #define DIRSEP_S "/"
474 #define EXTSEP_C '.'
475 #define EXTSEP_S "."
476 #define PATHSEP_C ':'
477 #define PATHSEP_S ":"
478 #define EXEEXT_S ""
479 #endif
480
481 /* This is the same as VERSION, but should be overridden if the
482    platform cannot handle things like dots '.' in filenames. Set
483    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
484    uses for dots and dashes. */
485 #define SAFE_VERSION VERSION
486 #define SAFE_VERSION_DOT  '.'
487 #define SAFE_VERSION_DASH '-'
488
489 /* Some global constants.
490  * Note that the homedir must not end in a slash.  */
491 #ifdef HAVE_DOSISH_SYSTEM
492 # ifdef HAVE_DRIVE_LETTERS
493 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
494 # else
495 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
496 # endif
497 #elif defined(__VMS)
498 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
499 #else
500 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
501 #endif
502 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
503 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
504
505 /* For some systems (DOS currently), we hardcode the path here.  For
506    POSIX systems the values are constructed by the Makefiles, so that
507    the values may be overridden by the make invocations; this is to
508    comply with the GNU coding standards.  Note that these values are
509    only defaults.  */
510 #ifdef HAVE_DOSISH_SYSTEM
511 # ifdef HAVE_DRIVE_LETTERS
512 #  define GNUPG_BINDIR      "c:\\gnupg"
513 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
514 #  define GNUPG_LIBDIR      "c:\\gnupg"
515 #  define GNUPG_DATADIR     "c:\\gnupg"
516 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
517 # else
518 #  define GNUPG_BINDIR      "\\gnupg"
519 #  define GNUPG_LIBEXECDIR  "\\gnupg"
520 #  define GNUPG_LIBDIR      "\\gnupg"
521 #  define GNUPG_DATADIR     "\\gnupg"
522 #  define GNUPG_SYSCONFDIR  "\\gnupg"
523 # endif
524 #endif
525
526 /* Derive some other constants. */
527 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
528 #define EXEC_TEMPFILE_ONLY
529 #endif
530
531
532 /* We didn't define endianness above, so get it from OS macros.  This
533    is intended for making fat binary builds on OS X. */
534 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
535 #if defined(__BIG_ENDIAN__)
536 #define BIG_ENDIAN_HOST 1
537 #elif defined(__LITTLE_ENDIAN__)
538 #define LITTLE_ENDIAN_HOST 1
539 #else
540 #error "No endianness found"
541 #endif
542 #endif
543
544
545 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
546    ldap_start_tls_s because that is the actual symbol used in the
547    library.  winldap.h redefines it to our commonly used value,
548    thus we define our usual macro here.  */
549 #ifdef HAVE_LDAP_START_TLS_SA
550 # ifndef HAVE_LDAP_START_TLS_S
551 #  define HAVE_LDAP_START_TLS_S 1
552 # endif
553 #endif
554
555 /* Provide the es_ macro for estream.  */
556 #define GPGRT_ENABLE_ES_MACROS 1
557
558 /* Tell libgcrypt not to use its own libgpg-error implementation. */
559 #define USE_LIBGPG_ERROR 1
560
561 /* Tell Libgcrypt not to include deprecated definitions.  */
562 #define GCRYPT_NO_DEPRECATED 1
563
564 /* Our HTTP code is used in estream mode.  */
565 #define HTTP_USE_ESTREAM 1
566
567 /* Under W32 we do an explicit socket initialization, thus we need to
568    avoid the on-demand initialization which would also install an atexit
569    handler.  */
570 #define HTTP_NO_WSASTARTUP
571
572 /* Under Windows we use the gettext code from libgpg-error.  */
573 #define GPG_ERR_ENABLE_GETTEXT_MACROS
574
575 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
576 #define GPG_ERR_ENABLE_ERRNO_MACROS
577
578 #endif /*GNUPG_CONFIG_H_INCLUDED*/
579 ])
580
581
582 AM_MAINTAINER_MODE
583 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
584
585 # Checks for programs.
586 AC_MSG_NOTICE([checking for programs])
587 AC_PROG_MAKE_SET
588 AM_SANITY_CHECK
589 missing_dir=`cd $ac_aux_dir && pwd`
590 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
591 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
592 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
593 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
594 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
595 AM_SILENT_RULES
596 AC_PROG_AWK
597 AC_PROG_CC
598 AC_PROG_CPP
599 AM_PROG_CC_C_O
600 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
601   AC_MSG_ERROR([[No C-89 compiler found]])
602 fi
603 AC_PROG_INSTALL
604 AC_PROG_LN_S
605 AC_PROG_RANLIB
606 AC_CHECK_TOOL(AR, ar, :)
607 AC_PATH_PROG(PERL,"perl")
608 AC_CHECK_TOOL(WINDRES, windres, :)
609 AC_PATH_PROG(YAT2M, "yat2m", "./yat2m" )
610 AC_ARG_VAR(YAT2M, [tool to convert texi to man pages])
611 AC_ISC_POSIX
612 AC_SYS_LARGEFILE
613 GNUPG_CHECK_USTAR
614
615
616 # We need to compile and run a program on the build machine.  A
617 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
618 # the AC archive is broken for autoconf 2.57.  Given that there is no
619 # newer version of that macro, we assume that it is also broken for
620 # autoconf 2.61 and thus we use a simple but usually sufficient
621 # approach.
622 AC_MSG_CHECKING(for cc for build)
623 if test "$cross_compiling" = "yes"; then
624   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
625 else
626   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
627 fi
628 AC_MSG_RESULT($CC_FOR_BUILD)
629 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
630
631 # We need to call this macro because other pkg-config macros are
632 # not always used.
633 PKG_PROG_PKG_CONFIG
634
635
636 try_gettext=yes
637 require_iconv=yes
638 have_dosish_system=no
639 have_w32_system=no
640 have_w32ce_system=no
641 have_android_system=no
642 use_simple_gettext=no
643 use_ldapwrapper=yes
644 mmap_needed=yes
645 case "${host}" in
646     *-mingw32*)
647         # special stuff for Windoze NT
648         ac_cv_have_dev_random=no
649         AC_DEFINE(USE_ONLY_8DOT3,1,
650                   [Set this to limit filenames to the 8.3 format])
651         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
652                   [Because the Unix gettext has too much overhead on
653                    MingW32 systems and these systems lack Posix functions,
654                    we use a simplified version of gettext])
655         have_dosish_system=yes
656         have_w32_system=yes
657         require_iconv=no
658         use_ldapwrapper=no  # Fixme: Do this only for CE.
659         case "${host}" in
660           *-mingw32ce*)
661             have_w32ce_system=yes
662             ;;
663           *)
664             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
665                       [Defined if the OS supports drive letters.])
666             ;;
667         esac
668         try_gettext="no"
669         use_simple_gettext=yes
670         mmap_needed=no
671         ;;
672     i?86-emx-os2 | i?86-*-os2*emx )
673         # OS/2 with the EMX environment
674         ac_cv_have_dev_random=no
675         AC_DEFINE(HAVE_DRIVE_LETTERS)
676         have_dosish_system=yes
677         try_gettext="no"
678         ;;
679
680     i?86-*-msdosdjgpp*)
681         # DOS with the DJGPP environment
682         ac_cv_have_dev_random=no
683         AC_DEFINE(HAVE_DRIVE_LETTERS)
684         have_dosish_system=yes
685         try_gettext="no"
686         ;;
687
688     *-*-hpux*)
689         if test -z "$GCC" ; then
690             CFLAGS="-Ae -D_HPUX_SOURCE $CFLAGS"
691         fi
692         ;;
693     *-dec-osf4*)
694         if test -z "$GCC" ; then
695             # Suppress all warnings
696             # to get rid of the unsigned/signed char mismatch warnings.
697             CFLAGS="-w $CFLAGS"
698         fi
699         ;;
700     *-dec-osf5*)
701         if test -z "$GCC" ; then
702             # Use the newer compiler `-msg_disable ptrmismatch1' to
703             # get rid of the unsigned/signed char mismatch warnings.
704             # Using this may hide other pointer mismatch warnings, but
705             # it at least lets other warning classes through
706             CFLAGS="-msg_disable ptrmismatch1 $CFLAGS"
707         fi
708         ;;
709     m68k-atari-mint)
710         ;;
711     *-linux-android*)
712         have_android_system=yes
713         # Android is fully utf-8 and we do not want to use iconv to
714         # keeps things simple
715         require_iconv=no
716         ;;
717     *-apple-darwin*)
718         AC_DEFINE(_DARWIN_C_SOURCE, 900000L,
719                   Expose all libc features (__DARWIN_C_FULL).)
720         ;;
721     *)
722        ;;
723 esac
724
725 if test "$have_dosish_system" = yes; then
726    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
727              [Defined if we run on some of the PCDOS like systems
728               (DOS, Windoze. OS/2) with special properties like
729               no file modes, case insensitive file names and preferred
730               use of backslashes as directory name separators.])
731 fi
732 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
733
734 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
735
736 if test "$have_w32_system" = yes; then
737    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
738    if test "$have_w32ce_system" = yes; then
739       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
740    fi
741 fi
742 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
743 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
744
745 if test "$have_android_system" = yes; then
746    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
747 fi
748 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
749
750
751 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
752 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
753
754
755 #
756 # Checks for libraries.
757 #
758 AC_MSG_NOTICE([checking for libraries])
759
760
761 #
762 # libgpg-error is a library with error codes shared between GnuPG
763 # related projects.
764 #
765 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
766                   have_gpg_error=yes,have_gpg_error=no)
767
768
769 #
770 # Libgcrypt is our generic crypto library
771 #
772 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
773         have_libgcrypt=yes,have_libgcrypt=no)
774
775
776 #
777 # libassuan is used for IPC
778 #
779 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
780                   have_libassuan=yes,have_libassuan=no)
781 if test "$have_libassuan" = "yes"; then
782   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
783                      [version of the libassuan library])
784   show_tor_support="only .onion"
785 fi
786
787
788 #
789 # libksba is our X.509 support library
790 #
791 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
792
793
794 #
795 # libusb allows us to use the integrated CCID smartcard reader driver.
796 #
797 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
798 if test "$use_ccid_driver" = auto || test "$use_ccid_driver" = yes; then
799    case "${host}" in
800      *-mingw32*)
801        LIBUSB_NAME=
802        LIBUSB_LIBS=
803        LIBUSB_CPPFLAGS=
804        ;;
805      *-*-darwin*)
806        LIBUSB_NAME=usb-1.0
807        LIBUSB_LIBS="-Wl,-framework,CoreFoundation -Wl,-framework,IOKit"
808        ;;
809      *-*-freebsd*)
810        # FreeBSD has a native 1.0 compatible library by -lusb.
811        LIBUSB_NAME=usb
812        LIBUSB_LIBS=
813        ;;
814      *)
815        LIBUSB_NAME=usb-1.0
816        LIBUSB_LIBS=
817        ;;
818    esac
819 fi
820 if test x"$LIBUSB_NAME" != x ; then
821    AC_CHECK_LIB($LIBUSB_NAME, libusb_init,
822                 [ LIBUSB_LIBS="-l$LIBUSB_NAME $LIBUSB_LIBS"
823                   have_libusb=yes ])
824    AC_MSG_CHECKING([libusb include dir])
825    usb_incdir_found="no"
826    for _incdir in "" "/usr/include/libusb-1.0" "/usr/local/include/libusb-1.0"; do
827      _libusb_save_cppflags=$CPPFLAGS
828      if test -n "${_incdir}"; then
829        CPPFLAGS="-I${_incdir} ${CPPFLAGS}"
830      fi
831      AC_PREPROC_IFELSE([AC_LANG_SOURCE([[@%:@include <libusb.h>]])],
832      [usb_incdir=${_incdir}; usb_incdir_found="yes"], [])
833      CPPFLAGS=${_libusb_save_cppflags}
834      if test "$usb_incdir_found" = "yes"; then
835        break
836      fi
837    done
838    if test "$usb_incdir_found" = "yes"; then
839      AC_MSG_RESULT([${usb_incdir}])
840    else
841      AC_MSG_RESULT([not found])
842      usb_incdir=""
843      have_libusb=no
844      if test "$use_ccid_driver" != yes; then
845        use_ccid_driver=no
846      fi
847      LIBUSB_LIBS=""
848    fi
849
850    if test "$have_libusb" = yes; then
851      AC_DEFINE(HAVE_LIBUSB,1, [defined if libusb is available])
852    fi
853    if test x"$usb_incdir" = x; then
854      LIBUSB_CPPFLAGS=""
855    else
856      LIBUSB_CPPFLAGS="-I${usb_incdir}"
857    fi
858 fi
859 AC_SUBST(LIBUSB_LIBS)
860 AC_SUBST(LIBUSB_CPPFLAGS)
861
862 #
863 # Check whether it is necessary to link against libdl.
864 # (For example to load libpcsclite)
865 #
866 gnupg_dlopen_save_libs="$LIBS"
867 LIBS=""
868 AC_SEARCH_LIBS(dlopen, c dl,,,)
869 DL_LIBS=$LIBS
870 AC_SUBST(DL_LIBS)
871 LIBS="$gnupg_dlopen_save_libs"
872
873
874 # Checks for g10
875
876 AC_ARG_ENABLE(sqlite,
877                 AC_HELP_STRING([--disable-sqlite],
878                                [disable the use of SQLITE]),
879               try_sqlite=$enableval, try_sqlite=yes)
880
881 if test x"$use_tofu" = xyes ; then
882   if test x"$try_sqlite" = xyes ; then
883     PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $NEED_SQLITE_VERSION],
884                                  [have_sqlite=yes],
885                                  [have_sqlite=no])
886   fi
887   if test "$have_sqlite" = "yes"; then
888     :
889     AC_SUBST([SQLITE3_CFLAGS])
890     AC_SUBST([SQLITE3_LIBS])
891   else
892     use_tofu=no
893     tmp=$(echo "$SQLITE3_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
894     AC_MSG_WARN([[
895 ***
896 *** Building without SQLite support - TOFU disabled
897 ***
898 *** $tmp]])
899   fi
900 fi
901
902 AM_CONDITIONAL(SQLITE3, test "$have_sqlite" = "yes")
903
904 if test x"$use_tofu" = xyes ; then
905     AC_DEFINE(USE_TOFU, 1, [Enable to build the TOFU code])
906 fi
907
908
909 # Checks for g13
910
911 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
912 AC_DEFINE_UNQUOTED(ENCFS,
913         "${ENCFS}", [defines the filename of the encfs program])
914
915 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
916 AC_DEFINE_UNQUOTED(FUSERMOUNT,
917         "${FUSERMOUNT}", [defines the filename of the fusermount program])
918
919
920 # Checks for dirmngr
921
922
923 #
924 # Checks for symcryptrun:
925 #
926
927 # libutil has openpty() and login_tty().
928 AC_CHECK_LIB(util, openpty,
929               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
930                 AC_DEFINE(HAVE_LIBUTIL,1,
931                          [defined if libutil is available])
932              ])
933 AC_SUBST(LIBUTIL_LIBS)
934
935 # shred is used to clean temporary plain text files.
936 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
937 AC_DEFINE_UNQUOTED(SHRED,
938         "${SHRED}", [defines the filename of the shred program])
939
940
941 #
942 # Check whether the nPth library is available
943 #
944 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
945 if test "$have_npth" = "yes"; then
946   AC_DEFINE(HAVE_NPTH, 1,
947               [Defined if the New Portable Thread Library is available])
948   AC_DEFINE(USE_NPTH, 1,
949               [Defined if support for nPth is requested and nPth is available])
950 else
951   AC_MSG_WARN([[
952 ***
953 *** To support concurrent access for example in gpg-agent and the SCdaemon
954 *** we need the support of the New Portable Threads Library.
955 ***]])
956 fi
957
958
959 #
960 # NTBTLS is our TLS library.  If it is not available fallback to
961 # GNUTLS.
962 #
963 AC_ARG_ENABLE(ntbtls,
964               AC_HELP_STRING([--disable-ntbtls],
965                              [disable the use of NTBTLS as TLS library]),
966               try_ntbtls=$enableval, try_ntbtls=yes)
967 if test x"$try_ntbtls" = xyes ; then
968   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
969                  [have_ntbtls=yes],[have_ntbtls=no])
970 fi
971 if test "$have_ntbtls" = yes ; then
972    use_tls_library=ntbtls
973    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
974 else
975   AC_ARG_ENABLE(gnutls,
976                 AC_HELP_STRING([--disable-gnutls],
977                                [disable GNUTLS as fallback TLS library]),
978                 try_gnutls=$enableval, try_gnutls=yes)
979   if test x"$try_gnutls" = xyes ; then
980     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
981                                    [have_gnutls=yes],
982                                    [have_gnutls=no])
983   fi
984   if test "$have_gnutls" = "yes"; then
985     AC_SUBST([LIBGNUTLS_CFLAGS])
986     AC_SUBST([LIBGNUTLS_LIBS])
987     use_tls_library=gnutls
988     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
989   else
990     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
991     AC_MSG_WARN([[
992 ***
993 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
994 ***
995 *** $tmp]])
996   fi
997 fi
998
999 #
1000 # Allow to set a fixed trust store file for system provided certificates.
1001 #
1002 AC_ARG_WITH([default-trust-store-file],
1003             [AC_HELP_STRING([--with-default-trust-store-file=FILE],
1004                             [Use FILE as system trust store])],
1005             default_trust_store_file="$withval",
1006             default_trust_store_file="")
1007 if test x"$default_trust_store_file" = xno;then
1008   default_trust_store_file=""
1009 fi
1010 if test x"$default_trust_store_file" != x ; then
1011   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
1012     ["$default_trust_store_file"], [Use as default system trust store file])
1013 fi
1014
1015
1016 AC_MSG_NOTICE([checking for networking options])
1017
1018 #
1019 # Must check for network library requirements before doing link tests
1020 # for ldap, for example. If ldap libs are static (or dynamic and without
1021 # ELF runtime link paths), then link will fail and LDAP support won't
1022 # be detected.
1023 #
1024 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
1025         [NETLIBS="-lnsl $NETLIBS"]))
1026 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
1027         [NETLIBS="-lsocket $NETLIBS"]))
1028
1029
1030 #
1031 # Check standard resolver functions.
1032 #
1033 if test "$build_dirmngr" = "yes"; then
1034   _dns_save_libs=$LIBS
1035   LIBS=""
1036
1037   # Find the system resolver which can always be enabled with
1038   # the dirmngr option --standard-resolver.
1039
1040   # the double underscore thing is a glibc-ism?
1041   AC_SEARCH_LIBS(res_query,resolv bind,,
1042                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
1043   AC_SEARCH_LIBS(dn_expand,resolv bind,,
1044                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
1045
1046   # macOS renames dn_skipname into res_9_dn_skipname in <resolv.h>,
1047   # and for some reason fools us into believing we don't need
1048   # -lresolv even if we do.  Since the test program checking for the
1049   # symbol does not include <resolv.h>, we need to check for the
1050   # renamed symbol explicitly.
1051   AC_SEARCH_LIBS(res_9_dn_skipname,resolv bind,,
1052       AC_SEARCH_LIBS(dn_skipname,resolv bind,,
1053           AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no)))
1054
1055   if test x"$have_resolver" != xno ; then
1056
1057       # Make sure that the BIND 4 resolver interface is workable before
1058       # enabling any code that calls it.  At some point I'll rewrite the
1059       # code to use the BIND 8 resolver API.
1060       # We might also want to use libdns instead.
1061
1062     AC_MSG_CHECKING([whether the resolver is usable])
1063     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1064 #include <netinet/in.h>
1065 #include <arpa/nameser.h>
1066 #include <resolv.h>]],
1067 [[unsigned char answer[PACKETSZ];
1068   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1069   dn_skipname(0,0);
1070   dn_expand(0,0,0,0,0);
1071 ]])],have_resolver=yes,have_resolver=no)
1072     AC_MSG_RESULT($have_resolver)
1073
1074     # This is Apple-specific and somewhat bizarre as they changed the
1075     # define in bind 8 for some reason.
1076
1077     if test x"$have_resolver" != xyes ; then
1078       AC_MSG_CHECKING(
1079            [whether I can make the resolver usable with BIND_8_COMPAT])
1080       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
1081 #include <sys/types.h>
1082 #include <netinet/in.h>
1083 #include <arpa/nameser.h>
1084 #include <resolv.h>]],
1085 [[unsigned char answer[PACKETSZ];
1086   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1087   dn_skipname(0,0); dn_expand(0,0,0,0,0);
1088 ]])],[have_resolver=yes ; need_compat=yes])
1089       AC_MSG_RESULT($have_resolver)
1090     fi
1091   fi
1092
1093   if test x"$have_resolver" = xyes ; then
1094     AC_DEFINE(HAVE_SYSTEM_RESOLVER,1,[The system's resolver is usable.])
1095     DNSLIBS="$DNSLIBS $LIBS"
1096     if test x"$need_compat" = xyes ; then
1097       AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
1098     fi
1099     if test "$use_libdns" = yes; then
1100      show_tor_support=yes
1101     fi
1102   elif test "$use_libdns" = yes; then
1103     show_tor_support=yes
1104   else
1105     AC_MSG_WARN([[
1106 ***
1107 *** The system's DNS resolver is not usable.
1108 *** Dirmngr functionality is limited.
1109 ***]])
1110     show_tor_support="${show_tor_support} (no system resolver)"
1111   fi
1112
1113   if test "$have_w32_system" = yes; then
1114     if test "$use_libdns" = yes; then
1115       DNSLIBS="$DNSLIBS -liphlpapi"
1116     fi
1117   fi
1118
1119   LIBS=$_dns_save_libs
1120 fi
1121
1122 AC_SUBST(DNSLIBS)
1123
1124
1125 #
1126 # Check for LDAP
1127 #
1128 # Note that running the check changes the variable
1129 # gnupg_have_ldap from "n/a" to "no" or "yes".
1130
1131 AC_ARG_ENABLE(ldap,
1132     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1133     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1134
1135 if test "$gnupg_have_ldap" != "no" ; then
1136   if test "$build_dirmngr" = "yes" ; then
1137      GNUPG_CHECK_LDAP($NETLIBS)
1138      AC_CHECK_LIB(lber, ber_free,
1139                   [ LBER_LIBS="$LBER_LIBS -llber"
1140                     AC_DEFINE(HAVE_LBER,1,
1141                              [defined if liblber is available])
1142                     have_lber=yes
1143                  ])
1144   fi
1145 fi
1146 AC_SUBST(LBER_LIBS)
1147 if test "$gnupg_have_ldap" = "no"; then
1148     AC_MSG_WARN([[
1149 ***
1150 *** Building without LDAP support.
1151 *** No CRL access or X.509 certificate search available.
1152 ***]])
1153 fi
1154
1155 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1156 if test "$gnupg_have_ldap" = yes ; then
1157   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1158 else
1159  use_ldapwrapper=no
1160 fi
1161
1162 if test "$use_ldapwrapper" = yes; then
1163    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1164 fi
1165 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1166
1167
1168
1169
1170 #
1171 # Check for sendmail
1172 #
1173 # This isn't necessarily sendmail itself, but anything that gives a
1174 # sendmail-ish interface to the outside world.  That includes Exim,
1175 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1176 AC_ARG_WITH(mailprog,
1177       AC_HELP_STRING([--with-mailprog=NAME],
1178                      [use "NAME -t" for mail transport]),
1179              ,with_mailprog=yes)
1180 if test x"$with_mailprog" = xyes ; then
1181     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1182 elif test x"$with_mailprog" != xno ; then
1183     AC_MSG_CHECKING([for a mail transport program])
1184     AC_SUBST(SENDMAIL,$with_mailprog)
1185     AC_MSG_RESULT($with_mailprog)
1186 fi
1187
1188
1189 #
1190 # Construct a printable name of the OS
1191 #
1192 case "${host}" in
1193     *-mingw32ce*)
1194         PRINTABLE_OS_NAME="W32CE"
1195         ;;
1196     *-mingw32*)
1197         PRINTABLE_OS_NAME="MingW32"
1198         ;;
1199     *-*-cygwin*)
1200         PRINTABLE_OS_NAME="Cygwin"
1201         ;;
1202     i?86-emx-os2 | i?86-*-os2*emx )
1203         PRINTABLE_OS_NAME="OS/2"
1204         ;;
1205     i?86-*-msdosdjgpp*)
1206         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1207         try_dynload=no
1208         ;;
1209     *-linux*)
1210         PRINTABLE_OS_NAME="GNU/Linux"
1211         ;;
1212     *)
1213         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1214         ;;
1215 esac
1216 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1217                    [A human readable text with the name of the OS])
1218
1219
1220 #
1221 # Checking for iconv
1222 #
1223 if test "$require_iconv" = yes; then
1224   AM_ICONV
1225 else
1226   LIBICONV=
1227   LTLIBICONV=
1228   AC_SUBST(LIBICONV)
1229   AC_SUBST(LTLIBICONV)
1230 fi
1231
1232
1233 #
1234 # Check for gettext
1235 #
1236 # This is "GNU gnupg" - The project-id script from gettext
1237 #                       needs this string
1238 #
1239 AC_MSG_NOTICE([checking for gettext])
1240 AM_PO_SUBDIRS
1241 AM_GNU_GETTEXT_VERSION([0.17])
1242 if test "$try_gettext" = yes; then
1243   AM_GNU_GETTEXT([external],[need-ngettext])
1244
1245   # gettext requires some extra checks.  These really should be part of
1246   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1247   # function checks to here.
1248
1249   AC_CHECK_FUNCS(strchr)
1250 else
1251   USE_NLS=no
1252   USE_INCLUDED_LIBINTL=no
1253   BUILD_INCLUDED_LIBINTL=no
1254   POSUB=po
1255   AC_SUBST(USE_NLS)
1256   AC_SUBST(USE_INCLUDED_LIBINTL)
1257   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1258   AC_SUBST(POSUB)
1259 fi
1260
1261 # We use HAVE_LANGINFO_CODESET in a couple of places.
1262 AM_LANGINFO_CODESET
1263
1264 # Checks required for our use of locales
1265 gt_LC_MESSAGES
1266
1267
1268 #
1269 # SELinux support
1270 #
1271 if test "$selinux_support" = yes ; then
1272   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1273 fi
1274
1275
1276 #
1277 # Checks for header files.
1278 #
1279 AC_MSG_NOTICE([checking for header files])
1280 AC_HEADER_STDC
1281 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1282                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h     \
1283                   stdint.h signal.h util.h libutil.h termios.h \
1284                   ucred.h sys/sysmacros.h sys/mkdev.h])
1285
1286 AC_HEADER_TIME
1287
1288
1289 #
1290 # Checks for typedefs, structures, and compiler characteristics.
1291 #
1292 AC_MSG_NOTICE([checking for system characteristics])
1293 AC_C_CONST
1294 AC_C_INLINE
1295 AC_C_VOLATILE
1296 AC_TYPE_SIZE_T
1297 AC_TYPE_MODE_T
1298 AC_TYPE_SIGNAL
1299 AC_DECL_SYS_SIGLIST
1300
1301 gl_HEADER_SYS_SOCKET
1302 gl_TYPE_SOCKLEN_T
1303
1304 AC_SEARCH_LIBS([inet_addr], [nsl])
1305
1306 AC_ARG_ENABLE(endian-check,
1307               AC_HELP_STRING([--disable-endian-check],
1308               [disable the endian check and trust the OS provided macros]),
1309               endiancheck=$enableval,endiancheck=yes)
1310
1311 if test x"$endiancheck" = xyes ; then
1312   GNUPG_CHECK_ENDIAN
1313 fi
1314
1315 # fixme: we should get rid of the byte type
1316 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1317 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1318 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1319 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1320 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1321
1322 AC_CHECK_SIZEOF(unsigned short)
1323 AC_CHECK_SIZEOF(unsigned int)
1324 AC_CHECK_SIZEOF(unsigned long)
1325 AC_CHECK_SIZEOF(unsigned long long)
1326 AC_HEADER_TIME
1327 AC_CHECK_SIZEOF(time_t,,[[
1328 #include <stdio.h>
1329 #if TIME_WITH_SYS_TIME
1330 # include <sys/time.h>
1331 # include <time.h>
1332 #else
1333 # if HAVE_SYS_TIME_H
1334 #  include <sys/time.h>
1335 # else
1336 #  include <time.h>
1337 # endif
1338 #endif
1339 ]])
1340 GNUPG_TIME_T_UNSIGNED
1341
1342
1343 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1344    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1345    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1346     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1347 fi
1348
1349
1350 #
1351 # Checks for library functions.
1352 #
1353 AC_MSG_NOTICE([checking for library functions])
1354 AC_CHECK_DECLS(getpagesize)
1355 AC_FUNC_FSEEKO
1356 AC_FUNC_VPRINTF
1357 AC_FUNC_FORK
1358 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1359 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1360 AC_CHECK_FUNCS([setenv unsetenv fcntl ftruncate inet_ntop])
1361 AC_CHECK_FUNCS([canonicalize_file_name])
1362 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1363 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1364 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1365 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1366 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1367                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1368                 flockfile funlockfile getpwnam getpwuid \
1369                 getenv inet_pton strpbrk])
1370
1371 # On some systems (e.g. Solaris) nanosleep requires linking to librl.
1372 # Given that we use nanosleep only as an optimization over a select
1373 # based wait function we want it only if it is available in libc.
1374 _save_libs="$LIBS"
1375 AC_SEARCH_LIBS([nanosleep], [],
1376                [AC_DEFINE(HAVE_NANOSLEEP,1,
1377                 [Define to 1 if you have the `nanosleep' function in libc.])])
1378 LIBS="$_save_libs"
1379
1380
1381 # See whether libc supports the Linux inotify interface
1382 case "${host}" in
1383     *-*-linux*)
1384         AC_CHECK_FUNCS([inotify_init])
1385         ;;
1386 esac
1387
1388
1389 if test "$have_android_system" = yes; then
1390    # On Android ttyname is a stub but prints an error message.
1391    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1392              [Defined if ttyname does not work properly])
1393 fi
1394
1395 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1396
1397 # Dirmngr requires mmap on Unix systems.
1398 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1399   AC_MSG_ERROR([[Sorry, the current implementation requires mmap.]])
1400 fi
1401
1402
1403 #
1404 # Check for the getsockopt SO_PEERCRED, etc.
1405 #
1406 AC_CHECK_MEMBERS([struct ucred.pid, struct ucred.cr_pid, struct sockpeercred.pid], [], [], [#include <sys/types.h>
1407 #include <sys/socket.h> ])
1408
1409 # (Open)Solaris
1410 AC_CHECK_FUNCS([getpeerucred])
1411
1412
1413 #
1414 # W32 specific test
1415 #
1416 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1417
1418 #
1419 # Sanity check regex.  Tests adapted from mutt.
1420 #
1421 AC_MSG_CHECKING([whether regular expression support is requested])
1422 AC_ARG_ENABLE(regex,
1423   AC_HELP_STRING([--disable-regex],
1424     [do not handle regular expressions in trust signatures]),
1425   use_regex=$enableval, use_regex=yes)
1426 AC_MSG_RESULT($use_regex)
1427
1428 if test "$use_regex" = yes ; then
1429   _cppflags="${CPPFLAGS}"
1430   _ldflags="${LDFLAGS}"
1431   AC_ARG_WITH(regex,
1432      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1433       [
1434       if test -d "$withval" ; then
1435         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1436         LDFLAGS="${LDFLAGS} -L$withval/lib"
1437       fi
1438       ],withval="")
1439
1440   # Does the system have regex functions at all?
1441   AC_SEARCH_LIBS([regcomp], [regex])
1442   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1443
1444   if test $gnupg_cv_have_regex = no; then
1445     use_regex=no
1446   else
1447     if test x"$cross_compiling" = xyes; then
1448       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1449     else
1450       AC_CACHE_CHECK([whether your system's regexp library is broken],
1451        [gnupg_cv_regex_broken],
1452        AC_TRY_RUN([
1453 #include <unistd.h>
1454 #include <regex.h>
1455 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1456        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1457
1458       if test $gnupg_cv_regex_broken = yes; then
1459         AC_MSG_WARN([your regex is broken - disabling regex use])
1460         use_regex=no
1461       fi
1462     fi
1463   fi
1464   CPPFLAGS="${_cppflags}"
1465   LDFLAGS="${_ldflags}"
1466 fi
1467
1468 if test "$use_regex" != yes ; then
1469   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1470 fi
1471 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1472
1473
1474
1475 #
1476 # Do we have zlib? Must do it here because Solaris failed
1477 # when compiling a conftest (due to the "-lz" from LIBS).
1478 # Note that we combine zlib and bzlib2 in ZLIBS.
1479 #
1480 if test "$use_zip" = yes ; then
1481   _cppflags="${CPPFLAGS}"
1482   _ldflags="${LDFLAGS}"
1483   AC_ARG_WITH(zlib,
1484     [  --with-zlib=DIR         use libz in DIR],[
1485       if test -d "$withval"; then
1486         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1487         LDFLAGS="${LDFLAGS} -L$withval/lib"
1488       fi
1489     ])
1490
1491   AC_CHECK_HEADER(zlib.h,
1492      AC_CHECK_LIB(z, deflateInit2_,
1493        [
1494        ZLIBS="-lz"
1495        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1496        ],
1497        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1498        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1499 fi
1500
1501
1502 #
1503 # Check whether we can support bzip2
1504 #
1505 if test "$use_bzip2" = yes ; then
1506   _cppflags="${CPPFLAGS}"
1507   _ldflags="${LDFLAGS}"
1508   AC_ARG_WITH(bzip2,
1509      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1510       [
1511       if test -d "$withval" ; then
1512         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1513         LDFLAGS="${LDFLAGS} -L$withval/lib"
1514       fi
1515       ],withval="")
1516
1517   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1518   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1519   # woefully out of date.
1520   if test "$withval" != no ; then
1521      AC_CHECK_HEADER(bzlib.h,
1522         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1523           [
1524           have_bz2=yes
1525           ZLIBS="$ZLIBS -lbz2"
1526           AC_DEFINE(HAVE_BZIP2,1,
1527                   [Defined if the bz2 compression library is available])
1528           ],
1529           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1530           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1531   fi
1532 fi
1533 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1534 AC_SUBST(ZLIBS)
1535
1536
1537 # Check for readline support
1538 GNUPG_CHECK_READLINE
1539
1540
1541 if test "$development_version" = yes; then
1542     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1543             [Defined if this is not a regular release])
1544 fi
1545
1546 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1547
1548 GNUPG_CHECK_GNUMAKE
1549
1550 # Add some extra libs here so that previous tests don't fail for
1551 # mysterious reasons - the final link step should bail out.
1552 # W32SOCKLIBS is also defined so that if can be used for tools not
1553 # requiring any network stuff but linking to code in libcommon which
1554 # tracks in winsock stuff (e.g. init_common_subsystems).
1555 if test "$have_w32_system" = yes; then
1556    if test "$have_w32ce_system" = yes; then
1557      W32SOCKLIBS="-lws2"
1558    else
1559      W32SOCKLIBS="-lws2_32"
1560    fi
1561    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1562 fi
1563
1564 AC_SUBST(NETLIBS)
1565 AC_SUBST(W32SOCKLIBS)
1566
1567 #
1568 # Setup gcc specific options
1569 #
1570 USE_C99_CFLAGS=
1571 AC_MSG_NOTICE([checking for cc features])
1572 if test "$GCC" = yes; then
1573     mycflags=
1574     mycflags_save=$CFLAGS
1575
1576     # Check whether gcc does not emit a diagnositc for unknown -Wno-*
1577     # options.  This is the case for gcc >= 4.6
1578     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1579     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1580 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1581 #kickerror
1582 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1583     AC_MSG_RESULT($_gcc_silent_wno)
1584
1585     # Note that it is okay to use CFLAGS here because these are just
1586     # warning options and the user should have a chance of overriding
1587     # them.
1588     if test "$USE_MAINTAINER_MODE" = "yes"; then
1589         mycflags="$mycflags -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1590         mycflags="$mycflags -Wformat -Wno-format-y2k -Wformat-security"
1591         if test x"$_gcc_silent_wno" = xyes ; then
1592           _gcc_wopt=yes
1593         else
1594           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1595           CFLAGS="-Wno-missing-field-initializers"
1596           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1597                             [_gcc_wopt=yes],[_gcc_wopt=no])
1598           AC_MSG_RESULT($_gcc_wopt)
1599         fi
1600         if test x"$_gcc_wopt" = xyes ; then
1601           mycflags="$mycflags -W -Wno-sign-compare"
1602           mycflags="$mycflags -Wno-missing-field-initializers"
1603         fi
1604
1605         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1606         CFLAGS="-Wdeclaration-after-statement"
1607         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1608         AC_MSG_RESULT($_gcc_wopt)
1609         if test x"$_gcc_wopt" = xyes ; then
1610           mycflags="$mycflags -Wdeclaration-after-statement"
1611         fi
1612
1613         AC_MSG_CHECKING([if gcc supports -Wlogical-op and -Wvla])
1614         CFLAGS="-Wlogical-op -Wvla"
1615         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1616         AC_MSG_RESULT($_gcc_wopt)
1617         if test x"$_gcc_wopt" = xyes ; then
1618           mycflags="$mycflags -Wlogical-op -Wvla"
1619         fi
1620
1621     else
1622         mycflags="$mycflags -Wall"
1623     fi
1624
1625     if test x"$_gcc_silent_wno" = xyes ; then
1626       _gcc_psign=yes
1627     else
1628       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1629       CFLAGS="-Wno-pointer-sign"
1630       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1631                         [_gcc_psign=yes],[_gcc_psign=no])
1632       AC_MSG_RESULT($_gcc_psign)
1633     fi
1634     if test x"$_gcc_psign" = xyes ; then
1635        mycflags="$mycflags -Wno-pointer-sign"
1636     fi
1637
1638     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1639     CFLAGS="-Wpointer-arith"
1640     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1641     AC_MSG_RESULT($_gcc_psign)
1642     if test x"$_gcc_psign" = xyes ; then
1643        mycflags="$mycflags -Wpointer-arith"
1644     fi
1645
1646     CFLAGS="$mycflags $mycflags_save"
1647     if test "$use_libdns" = yes; then
1648        # dirmngr/dns.{c,h} require C99 and GNU extensions.  */
1649        USE_C99_CFLAGS="-std=gnu99"
1650     fi
1651 fi
1652
1653 AC_SUBST(USE_C99_CFLAGS)
1654
1655
1656 #
1657 # This is handy for debugging so the compiler doesn't rearrange
1658 # things and eliminate variables.
1659 #
1660 AC_ARG_ENABLE(optimization,
1661    AC_HELP_STRING([--disable-optimization],
1662                   [disable compiler optimization]),
1663                   [if test $enableval = no ; then
1664                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1665                    fi])
1666
1667 #
1668 # We do not want support for the GNUPG_BUILDDIR environment variable
1669 # in a released version.  However, our regression tests suite requires
1670 # this and thus we build with support for it during "make distcheck".
1671 # This configure option implements this along with the top Makefile's
1672 # AM_DISTCHECK_CONFIGURE_FLAGS.
1673 #
1674 gnupg_builddir_envvar=no
1675 AC_ARG_ENABLE(gnupg-builddir-envvar,,
1676               gnupg_builddir_envvar=$enableval)
1677 if test x"$gnupg_builddir_envvar" = x"yes"; then
1678    AC_DEFINE(ENABLE_GNUPG_BUILDDIR_ENVVAR, 1,
1679       [This is only used with "make distcheck"])
1680 fi
1681
1682 #
1683 # Add user CFLAGS.
1684 #
1685 CFLAGS="$CFLAGS $CFLAGS_orig"
1686
1687 #
1688 # Decide what to build
1689 #
1690
1691 build_scdaemon_extra=""
1692 if test "$build_scdaemon" = "yes"; then
1693   if test $have_libusb = no; then
1694      build_scdaemon_extra="without internal CCID driver"
1695   fi
1696   if test -n "$build_scdaemon_extra"; then
1697      build_scdaemon_extra="(${build_scdaemon_extra})"
1698   fi
1699 fi
1700
1701
1702 #
1703 # Set variables for use by automake makefiles.
1704 #
1705 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1706 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1707 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1708 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1709 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1710 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1711 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1712 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1713 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1714 AM_CONDITIONAL(BUILD_WKS_TOOLS,   test "$build_wks_tools" = "yes")
1715
1716 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1717 AM_CONDITIONAL(NO_TRUST_MODELS,     test "$use_trust_models" = no)
1718 AM_CONDITIONAL(USE_TOFU,            test "$use_tofu" = yes)
1719
1720 #
1721 # Set some defines for use gpgconf.
1722 #
1723 if test "$build_gpg" = yes ; then
1724     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1725 fi
1726 if test "$build_gpgsm" = yes ; then
1727     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1728 fi
1729 if test "$build_agent" = yes ; then
1730     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1731 fi
1732 if test "$build_scdaemon" = yes ; then
1733     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1734 fi
1735 if test "$build_dirmngr" = yes ; then
1736     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if SCDAEMON is to be build])
1737 fi
1738 if test "$build_g13" = yes ; then
1739     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1740 fi
1741
1742
1743 #
1744 # Define Name strings
1745 #
1746 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1747
1748 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1749 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1750
1751 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1752 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1753
1754 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1755 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1756                                         [The displayed name of gpg-agent])
1757
1758 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1759 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1760                                        [The displayed name of scdaemon])
1761
1762 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1763 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1764                                       [The displayed name of dirmngr])
1765
1766 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1767 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1768
1769 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1770 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1771                                       [The displayed name of gpgconf])
1772
1773 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1774
1775 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1776                    [The name of the agent socket])
1777 AC_DEFINE_UNQUOTED(GPG_AGENT_EXTRA_SOCK_NAME, "S.gpg-agent.extra",
1778                    [The name of the agent socket for remote access])
1779 AC_DEFINE_UNQUOTED(GPG_AGENT_BROWSER_SOCK_NAME, "S.gpg-agent.browser",
1780                    [The name of the agent socket for browsers])
1781 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1782                    [The name of the agent socket for ssh])
1783 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1784                    [The name of the dirmngr info envvar])
1785 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1786                    [The name of the SCdaemon socket])
1787 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1788                    [The name of the dirmngr socket])
1789 AC_DEFINE_UNQUOTED(DIRMNGR_DEFAULT_KEYSERVER,
1790                    "hkps://hkps.pool.sks-keyservers.net",
1791       [The default keyserver for dirmngr to use, if none is explicitly given])
1792
1793 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1794
1795 if test "$have_w32_system" = yes; then
1796   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "\\\\Software\\\\GNU\\\\GnuPG",
1797                      [The directory part of the W32 registry keys])
1798 fi
1799
1800
1801 #
1802 # Provide information about the build.
1803 #
1804 BUILD_REVISION="mym4_revision"
1805 AC_SUBST(BUILD_REVISION)
1806 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1807                    [GIT commit id revision used to build this package])
1808
1809 changequote(,)dnl
1810 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1811 changequote([,])dnl
1812 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1813 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1814 AC_SUBST(BUILD_VERSION)
1815 AC_SUBST(BUILD_FILEVERSION)
1816
1817 AC_ARG_ENABLE([build-timestamp],
1818   AC_HELP_STRING([--enable-build-timestamp],
1819                  [set an explicit build timestamp for reproducibility.
1820                   (default is the current time in ISO-8601 format)]),
1821      [if test "$enableval" = "yes"; then
1822         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1823       else
1824         BUILD_TIMESTAMP="$enableval"
1825       fi
1826       BUILD_HOSTNAME="$ac_hostname"],
1827      [BUILD_TIMESTAMP="<none>"
1828       BUILD_HOSTNAME="<anon>"])
1829 AC_SUBST(BUILD_TIMESTAMP)
1830 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1831                    [The time this package was configured for a build])
1832 AC_SUBST(BUILD_HOSTNAME)
1833
1834
1835 #
1836 # Print errors here so that they are visible all
1837 # together and the user can acquire them all together.
1838 #
1839 die=no
1840 if test "$have_gpg_error" = "no"; then
1841    die=yes
1842    AC_MSG_NOTICE([[
1843 ***
1844 *** You need libgpg-error to build this program.
1845 **  This library is for example available at
1846 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1847 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1848 ***]])
1849 fi
1850 if test "$have_libgcrypt" = "no"; then
1851    die=yes
1852    AC_MSG_NOTICE([[
1853 ***
1854 *** You need libgcrypt to build this program.
1855 **  This library is for example available at
1856 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1857 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1858 ***]])
1859 fi
1860 if test "$have_libassuan" = "no"; then
1861    die=yes
1862    AC_MSG_NOTICE([[
1863 ***
1864 *** You need libassuan to build this program.
1865 *** This library is for example available at
1866 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1867 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1868 ***]])
1869 fi
1870 if test "$have_ksba" = "no"; then
1871     die=yes
1872     AC_MSG_NOTICE([[
1873 ***
1874 *** You need libksba to build this program.
1875 *** This library is for example available at
1876 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1877 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1878 ***]])
1879 fi
1880 if test "$gnupg_have_ldap" = yes; then
1881   if test "$have_w32ce_system" = yes; then
1882     AC_MSG_NOTICE([[
1883 *** Note that CeGCC might be broken, a package fixing this is:
1884 ***    http://files.kolab.org/local/windows-ce/
1885 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1886 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1887 ***]])
1888    fi
1889 fi
1890 if test "$have_npth" = "no"; then
1891     die=yes
1892     AC_MSG_NOTICE([[
1893 ***
1894 *** It is now required to build with support for the
1895 *** New Portable Threads Library (nPth). Please install this
1896 *** library first.  The library is for example available at
1897 ***   ftp://ftp.gnupg.org/gcrypt/npth/
1898 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1899 ***]])
1900 fi
1901
1902 if test "$require_iconv" = yes; then
1903   if test "$am_func_iconv" != yes; then
1904     die=yes
1905     AC_MSG_NOTICE([[
1906 ***
1907 *** The system does not provide a working iconv function.  Please
1908 *** install a suitable library; for example GNU Libiconv which is
1909 *** available at:
1910 ***   http://ftp.gnu.org/gnu/libiconv/
1911 ***]])
1912   fi
1913 fi
1914
1915 if test "$use_ccid_driver" = yes; then
1916   if test "$have_libusb" != yes; then
1917     die=yes
1918     AC_MSG_NOTICE([[
1919 ***
1920 *** You need libusb to build the internal ccid driver.  Please
1921 *** install a libusb suitable for your system.
1922 ***]])
1923   fi
1924 fi
1925
1926 if test "$die" = "yes"; then
1927     AC_MSG_ERROR([[
1928 ***
1929 *** Required libraries not found. Please consult the above messages
1930 *** and install them before running configure again.
1931 ***]])
1932 fi
1933
1934
1935
1936 AC_CONFIG_FILES([ m4/Makefile
1937 Makefile
1938 po/Makefile.in
1939 common/Makefile
1940 common/w32info-rc.h
1941 kbx/Makefile
1942 g10/Makefile
1943 sm/Makefile
1944 agent/Makefile
1945 scd/Makefile
1946 g13/Makefile
1947 dirmngr/Makefile
1948 tools/gpg-zip
1949 tools/Makefile
1950 doc/Makefile
1951 tests/Makefile
1952 tests/gpgscm/Makefile
1953 tests/openpgp/Makefile
1954 tests/migrations/Makefile
1955 tests/gpgsm/Makefile
1956 tests/gpgme/Makefile
1957 tests/pkits/Makefile
1958 g10/gpg.w32-manifest
1959 ])
1960
1961
1962 AC_OUTPUT
1963
1964
1965 echo "
1966         GnuPG v${VERSION} has been configured as follows:
1967
1968         Revision:  mym4_revision  (mym4_revision_dec)
1969         Platform:  $PRINTABLE_OS_NAME ($host)
1970
1971         OpenPGP:   $build_gpg
1972         S/MIME:    $build_gpgsm
1973         Agent:     $build_agent
1974         Smartcard: $build_scdaemon $build_scdaemon_extra
1975         G13:       $build_g13
1976         Dirmngr:   $build_dirmngr
1977         Gpgtar:    $build_gpgtar
1978         WKS tools: $build_wks_tools
1979
1980         Protect tool:      $show_gnupg_protect_tool_pgm
1981         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
1982         Default agent:     $show_gnupg_agent_pgm
1983         Default pinentry:  $show_gnupg_pinentry_pgm
1984         Default scdaemon:  $show_gnupg_scdaemon_pgm
1985         Default dirmngr:   $show_gnupg_dirmngr_pgm
1986
1987         Dirmngr auto start:  $dirmngr_auto_start
1988         Readline support:    $gnupg_cv_have_readline
1989         LDAP support:        $gnupg_have_ldap
1990         TLS support:         $use_tls_library
1991         TOFU support:        $use_tofu
1992         Tor support:         $show_tor_support
1993 "
1994 if test x"$use_regex" != xyes ; then
1995 echo "
1996         Warning: No regular expression support available.
1997                  OpenPGP trust signatures won't work.
1998                  gpg-check-pattern will not be built.
1999 "
2000 fi
2001 if test "x${gpg_config_script_warn}" != x; then
2002 cat <<G10EOF
2003         Warning: Mismatches between the target platform and the
2004                  to be used libraries have been detected for:
2005                   ${gpg_config_script_warn}
2006                  Please check above for more warning messages.
2007
2008 G10EOF
2009 fi