8c167f9e2722b8d19e018426a9f80196144b8c44
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 1.9
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 #               2003, 2004 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 2 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, write to the Free Software
19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20
21 # Process this file with autoconf to produce a configure script.
22 AC_PREREQ(2.52)
23 min_automake_version="1.7.6"
24
25 # Version number: Remember to change it immediately *after* a release.
26 #                 Add a "-cvs" prefix for non-released code.
27 AC_INIT(gnupg, 1.9.7-cvs, gnupg-devel@gnupg.org)
28 # Set development_version to yes if the minor number is odd or you
29 # feel that the default check for a development version is not
30 # sufficient.
31 development_version=yes
32 NEED_GPG_ERROR_VERSION=0.7
33
34 NEED_LIBGCRYPT_API=1
35 NEED_LIBGCRYPT_VERSION=1.1.94
36
37 NEED_LIBASSUAN_VERSION=0.6.4
38
39 NEED_KSBA_VERSION=0.9.4
40
41 NEED_OPENSC_VERSION=0.8.0
42
43
44
45 PACKAGE=$PACKAGE_NAME
46 PACKAGE_GT=${PACKAGE_NAME}2
47 VERSION=$PACKAGE_VERSION
48
49 AC_CONFIG_AUX_DIR(scripts)
50 AC_CONFIG_SRCDIR(sm/gpgsm.c)
51 AM_CONFIG_HEADER(config.h)
52 AC_CANONICAL_TARGET()
53 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
54
55 AC_GNU_SOURCE
56
57 # Some status variables to give feedback at the end of a configure run
58 have_gpg_error=no
59 have_libgcrypt=no 
60 have_libassuan=no
61 have_ksba=no
62 have_opensc=no
63 have_pth=no
64
65 GNUPG_BUILD_PROGRAM(gpg, yes)
66 GNUPG_BUILD_PROGRAM(gpgsm, yes)
67 GNUPG_BUILD_PROGRAM(agent, yes)
68 GNUPG_BUILD_PROGRAM(scdaemon, yes)
69
70
71 AC_SUBST(PACKAGE)
72 AC_SUBST(PACKAGE_GT)
73 AC_SUBST(VERSION)
74 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
75 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
76                                 [Name of this package for gettext])
77 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
78 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
79                                         [Bug report address])
80 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
81                                        [Required version of Libgcrypt])
82 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
83                                        [Required version of Libksba])
84
85
86
87 # The default is to use the modules from this package and the few
88 # other packages in a standard place; i.e where this package gets
89 # installed.  With these options it is possible to override these
90 # ${prefix} depended values with fixed paths, which can't be replaced
91 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
92 AC_ARG_WITH(agent-pgm,
93     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
94           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
95 AC_SUBST(GNUPG_AGENT_PGM)
96 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
97 show_gnupg_agent_pgm="(default)"
98 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
99
100 AC_ARG_WITH(pinentry-pgm,
101     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
102           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
103 AC_SUBST(GNUPG_PINENTRY_PGM)
104 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
105 show_gnupg_pinentry_pgm="(default)"
106 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
107
108
109 AC_ARG_WITH(scdaemon-pgm,
110     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
111           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
112 AC_SUBST(GNUPG_SCDAEMON_PGM)
113 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
114 show_gnupg_scdaemon_pgm="(default)"
115 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
116
117
118 AC_ARG_WITH(dirmngr-pgm,
119     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
120           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
121 AC_SUBST(GNUPG_DIRMNGR_PGM)
122 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
123 show_gnupg_dirmngr_pgm="(default)"
124 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
125
126 AC_ARG_WITH(protect-tool-pgm,
127     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
128           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
129 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
130 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
131 show_gnupg_protect_tool_pgm="(default)"
132 test -n "$GNUPG_PROTECT_TOOL_PGM" \
133       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
134
135
136
137 # Configure option to allow ot disallow execution of external
138 # programs, like a photo viewer.
139 AC_MSG_CHECKING([whether to enable external program execution])
140 AC_ARG_ENABLE(exec,
141     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
142     use_exec=$enableval)
143 AC_MSG_RESULT($use_exec)
144 if test "$use_exec" = no ; then
145     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
146 fi
147
148 if test "$use_exec" = yes ; then
149   AC_MSG_CHECKING([whether to enable photo ID viewing])
150   AC_ARG_ENABLE(photo-viewers,
151       [  --disable-photo-viewers disable photo ID viewers],
152       [if test "$enableval" = no ; then
153          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
154       fi],enableval=yes)
155   gnupg_cv_enable_photo_viewers=$enableval
156   AC_MSG_RESULT($enableval)
157
158   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
159     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
160     AC_ARG_WITH(photo-viewer,
161         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
162         [if test "$withval" = yes ; then
163            withval=no
164         elif test "$withval" != no ; then
165            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
166                             [if set, restrict photo-viewer to this])
167         fi],withval=no)
168     AC_MSG_RESULT($withval)
169   fi
170
171   AC_MSG_CHECKING([whether to enable external keyserver helpers])
172   AC_ARG_ENABLE(keyserver-helpers,
173       [  --disable-keyserver-helpers  disable all external keyserver support],
174       [if test "$enableval" = no ; then
175          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
176                   [define to disable keyserver helpers])
177       fi],enableval=yes)
178   gnupg_cv_enable_keyserver_helpers=$enableval
179   AC_MSG_RESULT($enableval)
180
181   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
182     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
183     AC_ARG_ENABLE(ldap,
184     [  --disable-ldap          disable LDAP keyserver interface],
185         try_ldap=$enableval, try_ldap=yes)
186     AC_MSG_RESULT($try_ldap)
187
188     AC_MSG_CHECKING([whether HKP keyserver support is requested])
189     AC_ARG_ENABLE(hkp,
190     [  --disable-hkp           disable HKP keyserver interface],
191         try_hkp=$enableval, try_hkp=yes)
192     AC_MSG_RESULT($try_hkp)
193
194     if test "$try_hkp" = yes ; then
195       AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
196     fi
197
198     AC_MSG_CHECKING([whether email keyserver support is requested])
199     AC_ARG_ENABLE(mailto,
200     [  --disable-mailto        disable email keyserver interface],
201         try_mailto=$enableval, try_mailto=yes)
202     AC_MSG_RESULT($try_mailto)
203     fi
204
205     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
206     AC_ARG_ENABLE(keyserver-path,
207         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
208         [if test "$enableval" = no ; then
209          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
210         fi],enableval=yes)
211     AC_MSG_RESULT($enableval)
212   fi
213
214 AC_MSG_CHECKING([whether the included zlib is requested])
215 AC_ARG_WITH(included-zlib,
216     [  --with-included-zlib    use the zlib code included here],
217 [g10_force_zlib=yes], [g10_force_zlib=no] )
218 AC_MSG_RESULT($g10_force_zlib)
219
220 dnl
221 dnl Check whether we want to use Linux capabilities
222 dnl
223 AC_MSG_CHECKING([whether use of capabilities is requested])
224 AC_ARG_WITH(capabilities,
225     [  --with-capabilities     use linux capabilities [default=no]],
226 [use_capabilities="$withval"],[use_capabilities=no])
227 AC_MSG_RESULT($use_capabilities)
228
229
230 AH_BOTTOM([
231 /* Some global constants. */
232 #ifdef HAVE_DRIVE_LETTERS
233 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
234 #elif defined(__VMS)
235 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg" 
236 #else
237 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
238 #endif 
239 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
240
241 /* Tell libgcrypt not to use its own libgpg-error implementation. */
242 #define USE_LIBGPG_ERROR 1
243
244 /* This is the major version number of GnuPG so that
245    source included files can test for this.  Note, that\
246    we use 2 here even for GnuPG 1.9.x. */
247 #define GNUPG_MAJOR_VERSION 2
248
249 /* Now to separate file name parts.
250    Please note that the string version must not contain more
251    than one character because the code assumes strlen()==1 */
252 #ifdef HAVE_DOSISH_SYSTEM
253 #define DIRSEP_C '\\'
254 #define EXTSEP_C '.'
255 #define DIRSEP_S "\\"
256 #define EXTSEP_S "."
257 #else
258 #define DIRSEP_C '/'
259 #define EXTSEP_C '.'
260 #define DIRSEP_S "/"
261 #define EXTSEP_S "."
262 #endif
263
264 /* This is the same as VERSION, but should be overridden if the
265    platform cannot handle things like dots '.' in filenames. Set
266    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
267    uses for dots and dashes. */
268 #define SAFE_VERSION VERSION
269 #define SAFE_VERSION_DOT  '.'
270 #define SAFE_VERSION_DASH '-'
271
272 /* For some systems (DOS currently), we hardcode the path here.  For
273    POSIX systems the values are constructed by the Makefiles, so that
274    the values may be overridden by the make invocations; this is to
275    comply with the GNU coding standards. */
276 #ifdef HAVE_DRIVE_LETTERS
277 #define GNUPG_BINDIR      "c:\\gnupg"
278 #define GNUPG_LIBEXECDIR  "c:\\lib\\gnupg"
279 #define GNUPG_LIBDIR      "c:\\lib\\gnupg"
280 #define GNUPG_DATADIR     "c:\\lib\\gnupg"
281 #endif
282
283 /* Setup the hardwired names of modules. */
284 #ifndef GNUPG_DEFAULT_AGENT
285 #define GNUPG_DEFAULT_AGENT    ( GNUPG_BINDIR DIRSEP_S "gpg-agent" )
286 #endif
287 #ifndef GNUPG_DEFAULT_PINENTRY
288 #define GNUPG_DEFAULT_PINENTRY ( GNUPG_BINDIR DIRSEP_S "pinentry" )
289 #endif
290 #ifndef GNUPG_DEFAULT_SCDAEMON
291 #define GNUPG_DEFAULT_SCDAEMON ( GNUPG_BINDIR DIRSEP_S "scdaemon" )
292 #endif
293 #ifndef GNUPG_DEFAULT_DIRMNGR
294 #define GNUPG_DEFAULT_DIRMNGR  ( GNUPG_BINDIR DIRSEP_S "dirmngr" )
295 #endif
296 #ifndef GNUPG_DEFAULT_PROTECT_TOOL
297 #define GNUPG_DEFAULT_PROTECT_TOOL \
298                     ( GNUPG_LIBEXECDIR DIRSEP_S "gpg-protect-tool" )
299 #endif
300
301
302 /* Derive some other constants. */
303 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
304 #define EXEC_TEMPFILE_ONLY
305 #endif
306
307 ])
308
309 AM_MAINTAINER_MODE
310
311 # Checks for programs.
312 AC_PROG_MAKE_SET
313 AM_SANITY_CHECK
314 missing_dir=`cd $ac_aux_dir && pwd`
315 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
316 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
317 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
318 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
319 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
320 AC_PROG_AWK
321 AC_PROG_CC
322 AC_PROG_CPP
323 AC_PROG_INSTALL
324 AC_PROG_LN_S
325 AC_PROG_MAKE_SET
326 AC_PROG_RANLIB
327 AC_CHECK_TOOL(AR, ar, :)
328 AC_PATH_PROG(PERL,"perl")
329 AC_ISC_POSIX
330 AC_SYS_LARGEFILE
331 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
332 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
333 GNUPG_CHECK_FAQPROG
334 GNUPG_CHECK_DOCBOOK_TO_TEXI
335
336
337 try_gettext=yes
338 have_dosish_system=no
339 case "${target}" in
340     *-*-mingw32*)
341         # special stuff for Windoze NT
342         ac_cv_have_dev_random=no
343         AC_DEFINE(USE_ONLY_8DOT3,1,
344                   [set this to limit filenames to the 8.3 format])
345         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
346                   [defined if we must run on a stupid file system])
347         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
348                   [because the Unix gettext has too much overhead on
349                    MingW32 systems and these systems lack Posix functions,
350                    we use a simplified version of gettext])
351         have_dosish_system=yes
352         try_gettext="no"
353         ;;
354     i?86-emx-os2 | i?86-*-os2*emx )
355         # OS/2 with the EMX environment
356         ac_cv_have_dev_random=no
357         AC_DEFINE(HAVE_DRIVE_LETTERS)
358         have_dosish_system=yes
359         try_gettext="no"
360         ;;
361
362     i?86-*-msdosdjgpp*)
363         # DOS with the DJGPP environment
364         ac_cv_have_dev_random=no
365         AC_DEFINE(HAVE_DRIVE_LETTERS)
366         have_dosish_system=yes
367         try_gettext="no"
368         ;;
369
370     *-*-freebsd*)
371        # FreeBSD
372        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
373        LDFLAGS="$LDFLAGS -L/usr/local/lib"
374        ;;
375
376     *-*-hpux*)
377         if test -z "$GCC" ; then
378             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
379         fi
380         ;;
381     *-dec-osf4*)
382         if test -z "$GCC" ; then
383             # Suppress all warnings
384             # to get rid of the unsigned/signed char mismatch warnings.
385             CFLAGS="$CFLAGS -w"
386         fi
387         ;;
388     *-dec-osf5*)
389         if test -z "$GCC" ; then
390             # Use the newer compiler `-msg_disable ptrmismatch' to
391             # get rid of the unsigned/signed char mismatch warnings.
392             # Using this may hide other pointer mismatch warnings, but
393             # it at least lets other warning classes through
394             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
395         fi
396         ;;
397     m68k-atari-mint)
398         ;;
399     *)
400        ;;
401 esac
402
403 if test "$have_dosish_system" = yes; then
404    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
405              [defined if we run on some of the PCDOS like systems 
406               (DOS, Windoze. OS/2) with special properties like
407               no file modes])
408 fi
409 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
410
411
412 #
413 # Checks for libraries.
414 #
415
416
417 #
418 # libgpg-error is a library with error codes shared between GnuPG
419 # related projects.
420 #
421 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
422                   have_gpg_error=yes,have_gpg_error=no)
423
424
425 #
426 # Libgcrypt is our generic crypto library
427 #
428 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
429         have_libgcrypt=yes,have_libgcrypt=no)
430
431
432 #
433 # libassuan is used for IPC
434 #
435 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_VERSION",
436                   have_libassuan=yes,have_libassuan=no)
437
438
439 #
440 # libksba is our X.509 support library
441 #
442 AM_PATH_KSBA("$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
443
444 #
445 # libusb allows us to use the integrated CCID smartcard reader driver.
446 #
447 # Note, that we need the CVS version.  FIXME: libusb should have a
448 # regular check as the other libraries do.
449 #
450 AC_CHECK_LIB(usb, usb_find_device,
451               [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
452                 AC_DEFINE(HAVE_LIBUSB,1,
453                          [defined if libusb is available])
454              ])
455 AC_SUBST(LIBUSB_LIBS)
456
457
458 #
459 # OpenSC is needed by the SCdaemon - if it is not availbale we can only
460 # build a limited SCdaemon
461 #
462 AM_PATH_OPENSC("$NEED_OPENSC_VERSION",have_opensc=yes,have_opensc=no)
463 if test $have_opensc = yes; then
464   AC_DEFINE(HAVE_OPENSC,1,
465             [defined if the OpenSC library is available])
466 fi
467
468 #
469 # Check whether the (highly desirable) GNU Pth library is available
470 #
471 AC_ARG_WITH(pth-prefix,
472             AC_HELP_STRING([--with-pth-prefix=PFX],
473                            [prefix where GNU Pth is installed (optional)]),
474      pth_config_prefix="$withval", pth_config_prefix="")
475 if test x$pth_config_prefix != x ; then
476    PTH_CONFIG="$pth_config_prefix/bin/pth-config"
477 fi
478 AC_PATH_PROG(PTH_CONFIG, pth-config, no)
479 if test "$PTH_CONFIG" = "no"; then
480     AC_MSG_WARN([[
481 ***
482 *** To support concurrent access to the gpg-agent and the SCdaemon
483 *** we need the support of the GNU Portable Threads Library.
484 *** Download it from ftp://ftp.gnu.org/gnu/pth/
485 *** On a Debian GNU/Linux system you might want to try 
486 ***   apt-get install libpth-dev
487 ***]])
488 else
489   GNUPG_PTH_VERSION_CHECK(1.3.7)
490   if test $have_pth = yes; then      
491      PTH_CFLAGS=`$PTH_CONFIG --cflags`
492      PTH_LIBS=`$PTH_CONFIG --ldflags`
493      PTH_LIBS="$PTH_LIBS `$PTH_CONFIG --libs`"
494      AC_DEFINE(USE_GNU_PTH, 1,
495               [Defined if the GNU Portable Thread Library should be used])
496   fi
497 fi
498 AC_SUBST(PTH_CFLAGS)
499 AC_SUBST(PTH_LIBS)
500
501 AC_ARG_ENABLE(threads,
502     AC_HELP_STRING([--disable-threads],[allow building without Pth support]);
503     
504 )
505
506
507 dnl Must check for network library requirements before doing link tests
508 dnl for ldap, for example. If ldap libs are static (or dynamic and without
509 dnl ELF runtime link paths), then link will fail and LDAP support won't
510 dnl be detected.
511
512 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
513         [NETLIBS="-lnsl $NETLIBS"]))
514 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
515         [NETLIBS="-lsocket $NETLIBS"]))
516
517 dnl Now try for the resolver functions so we can use DNS SRV
518
519 AC_ARG_ENABLE(dns-srv,
520    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
521    use_dns_srv=$enableval,use_dns_srv=yes)
522
523 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
524   _srv_save_libs=$LIBS
525   LIBS=""
526   # the double underscore thing is a glibc-ism?
527   AC_SEARCH_LIBS(res_query,resolv bind,,
528                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
529   AC_SEARCH_LIBS(dn_expand,resolv bind,,
530                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
531   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
532                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
533
534   if test x"$use_dns_srv" = xyes ; then
535      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
536      SRVLIBS=$LIBS
537   else
538      AC_MSG_WARN([Resolver functions not found.  Disabling DNS SRV.])
539   fi
540   LIBS=$_srv_save_libs
541 fi
542
543 AC_SUBST(SRVLIBS)
544
545 # Try and link a LDAP test program to weed out unusable LDAP
546 # libraries.  -lldap [-llber [-lresolv]] is for OpenLDAP.  OpenLDAP in
547 # general is terrible with creating weird dependencies.  If all else
548 # fails, the user can play guess-the-dependency by using something
549 # like ./configure LDAPLIBS="-Lfoo -lbar"
550
551 if test "$try_ldap" = yes ; then
552   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
553     _ldap_save_libs=$LIBS
554     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
555
556     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
557     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
558                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
559     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
560
561     if test $gnupg_cv_func_ldap_init = no; then
562       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
563       AC_TRY_LINK([#include <lber.h>
564 #include <ldap.h>],[ldap_open("foobar",1234);],
565          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
566       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
567     fi
568
569     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
570        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
571     fi
572
573     if test "$gnupg_cv_func_ldap_init" = yes || \
574         test "$gnupg_cv_func_ldaplber_init" = yes ; then
575        LDAPLIBS=$MY_LDAPLIBS
576        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
577
578        AC_MSG_CHECKING([whether LDAP supports ldap_get_option])
579
580        if test "$gnupg_cv_func_ldap_init" = yes ; then
581           AC_TRY_LINK([#include <ldap.h>],
582              [ldap_get_option((void *)0,0,(void *)0);],
583              [gnupg_cv_func_ldap_get_option=yes],
584              [gnupg_cv_func_ldap_get_option=no])
585         else
586           AC_TRY_LINK([#include <lber.h>
587 #include <ldap.h>],[ldap_get_option((void *)0,0,(void *)0);],
588              [gnupg_cv_func_ldap_get_option=yes],
589              [gnupg_cv_func_ldap_get_option=no])
590        fi
591
592        AC_MSG_RESULT([$gnupg_cv_func_ldap_get_option])
593
594        if test "$gnupg_cv_func_ldap_get_option" = yes ; then
595           AC_DEFINE(HAVE_LDAP_GET_OPTION,1,[Define if the LDAP library has ldap_get_option])
596        else
597           AC_MSG_CHECKING([whether LDAP supports ld_errno])
598
599           if test "$gnupg_cv_func_ldap_init" = yes ; then
600             AC_TRY_COMPILE([#include <ldap.h>],
601                [LDAP *ldap; ldap->ld_errno;],
602                [gnupg_cv_func_ldap_ld_errno=yes],
603                [gnupg_cv_func_ldap_ld_errno=no])
604            else
605             AC_TRY_LINK([#include <lber.h>
606 #include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
607                [gnupg_cv_func_ldap_ld_errno=yes],
608                [gnupg_cv_func_ldap_ld_errno=no])
609           fi
610
611           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
612
613           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
614              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
615           fi
616        fi
617     fi
618
619     LIBS=$_ldap_save_libs
620
621     if test "$GPGKEYS_LDAP" != "" ; then break; fi
622   done
623 fi
624
625 AC_SUBST(GPGKEYS_LDAP)
626 AC_SUBST(LDAPLIBS)
627
628 dnl This isn't necessarily sendmail itself, but anything that gives a
629 dnl sendmail-ish interface to the outside world.  That includes qmail,
630 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
631
632 if test "$try_mailto" = yes ; then
633   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
634
635   if test "$with_mailprog" = yes ; then
636     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
637     if test "$ac_cv_path_SENDMAIL" ; then
638       GPGKEYS_MAILTO="gpgkeys_mailto"
639     fi
640   elif test "$with_mailprog" != no ; then
641     AC_MSG_CHECKING([for a mail transport program])
642     AC_SUBST(SENDMAIL,$with_mailprog)
643     AC_MSG_RESULT($with_mailprog)
644     GPGKEYS_MAILTO="gpgkeys_mailto"
645   fi
646 fi
647
648 AC_SUBST(GPGKEYS_MAILTO)
649
650 case "${target}" in
651     *-*-mingw32*)
652         PRINTABLE_OS_NAME="MingW32"
653         ;;
654     *-*-cygwin*)
655         PRINTABLE_OS_NAME="Cygwin"
656         ;;
657     i?86-emx-os2 | i?86-*-os2*emx )
658         PRINTABLE_OS_NAME="OS/2"
659         ;;
660     i?86-*-msdosdjgpp*)
661         PRINTABLE_OS_NAME="MSDOS/DJGPP"
662         try_dynload=no
663         ;;
664     *-linux*)
665         PRINTABLE_OS_NAME="GNU/Linux"
666         ;;
667     *)
668         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
669         ;;
670 esac
671 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
672                    [A human readable text with the name of the OS])
673
674
675 AM_GNU_GETTEXT_VERSION(0.12.1)
676 if test "$try_gettext" = yes; then
677   AM_GNU_GETTEXT(,[need-ngettext])
678
679   # gettext requires some extra checks.  These really should be part of
680   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
681   # function checks to here.
682
683   AC_CHECK_FUNCS(strchr)
684 else
685   USE_NLS=no
686   USE_INCLUDED_LIBINTL=no
687   BUILD_INCLUDED_LIBINTL=no
688   AC_SUBST(USE_NLS)
689   AC_SUBST(USE_INCLUDED_LIBINTL)
690   AC_SUBST(BUILD_INCLUDED_LIBINTL)
691 fi
692
693 # Checks for header files.
694 AC_HEADER_STDC
695 AC_CHECK_HEADERS(string.h unistd.h langinfo.h termio.h locale.h)
696
697 # Checks for typedefs, structures, and compiler characteristics.
698 AC_C_CONST
699 AC_C_INLINE
700 AC_TYPE_SIZE_T
701 AC_TYPE_SIGNAL
702 AC_DECL_SYS_SIGLIST
703
704 GNUPG_CHECK_ENDIAN
705
706 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
707 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
708 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
709 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
710 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
711
712 AC_CHECK_SIZEOF(unsigned short)
713 AC_CHECK_SIZEOF(unsigned int)
714 AC_CHECK_SIZEOF(unsigned long)
715 AC_CHECK_SIZEOF(unsigned long long)
716 # Ensure that we have UINT64_C before we bother to check for uint64_t
717 # fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
718 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
719    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
720 uint64_t foo=UINT64_C(42);]),gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
721 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
722    AC_CHECK_SIZEOF(uint64_t)
723 fi
724  
725
726
727
728 if test "$ac_cv_sizeof_unsigned_short" = "0" \
729    || test "$ac_cv_sizeof_unsigned_int" = "0" \
730    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
731     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
732 fi
733
734 dnl Do we have any 64-bit data types?
735 if test "$ac_cv_sizeof_unsigned_int" != "8" \
736    && test "$ac_cv_sizeof_unsigned_long" != "8" \
737    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
738    && test "$ac_cv_sizeof_uint64_t" != "8"; then
739     AC_MSG_WARN([No 64-bit types.  Disabling SHA-384, and SHA-512])
740 else
741   if test x"$use_sha512" = xyes ; then
742      AC_SUBST(SHA512_O,sha512.o)
743      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
744   fi
745 fi
746
747 GNUPG_SYS_SO_PEERCRED
748
749 # Checks for library functions.
750 AC_FUNC_FSEEKO
751 AC_FUNC_VPRINTF
752 AC_FUNC_FORK
753 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
754 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times gmtime_r)
755 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
756 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
757 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat getaddrinfo)
758
759 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
760
761 # These are needed by libjnlib - fixme: we should have macros for them
762 AC_CHECK_FUNCS(memicmp stpcpy strlwr strtoul memmove stricmp strtol)
763 AC_CHECK_FUNCS(getrusage setrlimit stat setlocale)
764 AC_CHECK_FUNCS(flockfile funlockfile fopencookie funopen)
765
766 AC_REPLACE_FUNCS(vasprintf)
767 AC_REPLACE_FUNCS(fopencookie)
768 AC_REPLACE_FUNCS(mkdtemp)
769 AC_REPLACE_FUNCS(fseeko ftello)
770 AC_REPLACE_FUNCS(isascii)
771 AC_REPLACE_FUNCS(putc_unlocked)
772
773
774
775
776 #
777 # check for gethrtime and run a testprogram to see whether
778 # it is broken.  It has been reported that some Solaris and HP UX systems 
779 # raise an SIGILL
780 #
781 AC_CACHE_CHECK([for gethrtime], 
782                [gnupg_cv_func_gethrtime],
783                [AC_TRY_LINK([#include <sys/times.h>],[
784                    hrtime_t tv;
785                    tv = gethrtime();
786                  ],
787                  [gnupg_cv_func_gethrtime=yes],
788                  [gnupg_cv_func_gethrtime=no])
789                ])
790 if test $gnupg_cv_func_gethrtime = yes; then
791      AC_DEFINE([HAVE_GETHRTIME], 1,
792                [Define if you have the `gethrtime(2)' function.])
793      AC_CACHE_CHECK([whether gethrtime is broken], 
794                [gnupg_cv_func_broken_gethrtime],
795                [AC_TRY_RUN([
796                    #include <sys/times.h>
797                    int main () {
798                    hrtime_t tv;
799                    tv = gethrtime(); 
800                  }
801                  ],
802                  [gnupg_cv_func_broken_gethrtime=no],
803                  [gnupg_cv_func_broken_gethrtime=yes],
804                  [gnupg_cv_func_broken_gethrtime=assume-no])
805                 ])
806     if test $gnupg_cv_func_broken_gethrtime = yes; then
807       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
808       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
809     fi
810 fi
811      
812
813 GNUPG_CHECK_MLOCK
814 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
815
816 dnl
817 dnl Check whether we can use Linux capabilities as requested
818 dnl
819 if test "$use_capabilities" = "yes" ; then
820 use_capabilities=no
821 AC_CHECK_HEADERS(sys/capability.h)
822 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
823   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
824   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
825      AC_DEFINE(USE_CAPABILITIES,1,
826                [define if capabilities should be used])
827      AC_SUBST(CAPLIBS,"-lcap")
828      use_capabilities=yes
829   fi
830 fi
831 if test "$use_capabilities" = "no" ; then
832     AC_MSG_WARN([[
833 ***
834 *** The use of capabilities on this system is not possible.
835 *** You need a recent Linux kernel and some patches:
836 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
837 ***   fcap-module-990613.tar.gz     (kernel module)
838 ***   libcap-1.92.tar.gz            (user mode library and utilities)
839 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
840 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
841 ***]])
842 fi
843 fi
844
845
846 # Sanity check regex.  Tests adapted from mutt.
847
848 AC_MSG_CHECKING([whether regular expression support is requested])
849 AC_ARG_ENABLE(regex,
850 [  --disable-regex         do not handle regular expressions in trust sigs],
851      use_regex=$enableval, use_regex=yes)
852 AC_MSG_RESULT($use_regex)
853
854 if test "$use_regex" = yes ; then
855   AC_MSG_CHECKING([whether the included regex lib is requested])
856   AC_ARG_WITH(included-regex,
857       [  --with-included-regex   use the included GNU regex library],
858       [gnupg_cv_included_regex=yes],[gnupg_cv_included_regex=no])
859   AC_MSG_RESULT($gnupg_cv_included_regex)
860
861   if test $gnupg_cv_included_regex = no ; then
862      # Does the system have regex functions at all?
863      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
864                            gnupg_cv_included_regex=yes)
865   fi
866
867   if test $gnupg_cv_included_regex = no ; then
868      AC_CACHE_CHECK([whether your system's regexp library is broken],
869        [gnupg_cv_regex_broken],
870        AC_TRY_RUN([
871 #include <unistd.h>
872 #include <regex.h>
873 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
874        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
875
876      if test $gnupg_cv_regex_broken = yes ; then
877       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
878       gnupg_cv_included_regex=yes
879      fi
880   fi
881
882   if test $gnupg_cv_included_regex = yes; then
883      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
884      AC_SUBST(REGEX_O,regex.o)
885   fi
886 else
887
888   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
889 fi
890
891 dnl Do we have zlib? Must do it here because Solaris failed
892 dnl when compiling a conftest (due to the "-lz" from LIBS).
893 use_local_zlib=yes
894 if test "$g10_force_zlib" = "yes"; then
895   :
896 else
897   _cppflags="${CPPFLAGS}"
898   _ldflags="${LDFLAGS}"
899
900   AC_ARG_WITH(zlib,
901   [  --with-zlib=DIR         use libz in DIR],[
902     if test -d "$withval"; then
903       CPPFLAGS="${CPPFLAGS} -I$withval/include"
904       LDFLAGS="${LDFLAGS} -L$withval/lib"
905     fi
906   ])
907
908   AC_CHECK_HEADER(zlib.h,
909       AC_CHECK_LIB(z, deflateInit2_,
910        use_local_zlib=no
911        LIBS="$LIBS -lz",
912        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
913        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
914 fi
915  
916 if test "$use_local_zlib" = yes ; then
917     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
918     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
919     ZLIBS="../zlib/libzlib.a"
920 else
921     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
922     ZLIBS=
923 fi
924 AC_SUBST(ZLIBS)
925
926 # Allow users to append something to the version string without
927 # flagging it as development version.  The user version parts is
928 # considered everything after a dash. 
929 if test "$development_version" != yes; then
930   changequote(,)dnl
931   tmp_pat='[a-zA-Z]'
932   changequote([,])dnl
933   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
934     development_version=yes
935   fi
936 fi
937 if test "$development_version" = yes; then
938     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
939             [Defined if this is not a regular release])
940 fi
941
942 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
943
944 GNUPG_CHECK_GNUMAKE
945
946 # add some extra libs here so that previous tests don't fail for
947 # mysterious reasons - the final link step should bail out. 
948 case "${target}" in
949     *-*-mingw32*)
950         W32LIBS="-lwsock32"
951         ;;
952     *)
953        ;;
954 esac
955
956
957 if test "$GCC" = yes; then
958     if test "$USE_MAINTAINER_MODE" = "yes"; then
959         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
960         CFLAGS="$CFLAGS -Wformat-nonliteral"
961     else
962         CFLAGS="$CFLAGS -Wall"
963     fi
964 fi
965
966 AC_SUBST(NETLIBS)
967 AC_SUBST(W32LIBS)
968
969
970 # We use jnlib, so tell other modules about it
971 AC_DEFINE(HAVE_JNLIB_LOGGING, 1,
972         [Defined if jnlib style logging fucntions are available])
973
974
975
976 #
977 # Decide what to build
978 #
979 missing_pth=no
980 if test $have_ksba = no; then
981   build_gpgsm=no
982   build_scdaemon=no
983 fi
984
985 build_agent_threaded=""
986 if test "$build_agent" = "yes"; then
987   if test $have_pth = no; then
988      build_agent_threaded="(not multi-threaded)"
989      missing_pth=yes
990   fi
991 fi
992
993 build_scdaemon_extra=""
994 if test "$build_scdaemon" = "yes"; then
995   tmp=""
996   if test $have_pth = no; then
997      build_scdaemon_extra="not multi-threaded"
998      tmp=", "
999      missing_pth=yes
1000   fi
1001   if test $have_opensc = no; then
1002      build_scdaemon_extra="${build_scdaemon_extra}${tmp}no pkcs#15"
1003      tmp=", "
1004   fi      
1005   if test -n "$build_scdaemon_extra"; then
1006      build_scdaemon_extra="(${build_scdaemon_extra})"
1007   fi
1008 fi
1009
1010 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1011 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1012 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1013 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1014
1015
1016
1017 #
1018 # Print errors here so that they are visible all
1019 # together and the user can acquire them all together.
1020 #
1021 die=no
1022 if test "$have_gpg_error" = "no"; then
1023    die=yes
1024    AC_MSG_NOTICE([[
1025 ***  
1026 *** You need libgpg-error to build this program.
1027 **  This library is for example available at
1028 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libgpg-error
1029 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1030 ***]])
1031 fi
1032 if test "$have_libgcrypt" = "no"; then
1033    die=yes
1034    AC_MSG_NOTICE([[
1035 ***  
1036 *** You need libgcrypt to build this program.
1037 **  This library is for example available at
1038 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libgcrypt/
1039 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API) is required.)
1040 ***]])
1041 fi
1042 if test "$have_libassuan" = "no"; then
1043    die=yes
1044    AC_MSG_NOTICE([[
1045 ***
1046 *** You need libassuan to build this program.
1047 *** This library is for example available at
1048 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libassuan/
1049 *** (at least version $NEED_LIBASSUAN_VERSION is required).
1050 ***]])
1051 fi
1052 if test "$have_ksba" = "no"; then
1053    die=yes
1054     AC_MSG_NOTICE([[
1055 ***
1056 *** You need libksba to build this program.
1057 *** This library is for example available at
1058 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libksba/
1059 *** (at least version $NEED_KSBA_VERSION is required).
1060 ***]])
1061 fi
1062 if test "$missing_pth" = "yes"; then
1063     AC_MSG_NOTICE([[
1064 ***
1065 *** It is strongly suggested to build with support for the
1066 *** GNU Portable Threads Library (Pth). Please install this
1067 *** library first or use --disable-threads to allow building
1068 *** anyway.  The library is for example available at
1069 ***   ftp://ftp.gnu.org/gnu/pth/
1070 *** On a Debian GNU/Linux system you can install it using 
1071 ***   apt-get install libpth-dev
1072 ***]])
1073   if test "$enable_threads" != "no"; then
1074      die=yes
1075   fi
1076 fi
1077
1078 if test "$die" = "yes"; then
1079     AC_MSG_ERROR([[
1080 ***
1081 *** Required libraries not found. Please consult the above messages
1082 *** and install them before running configure again.
1083 ***]])
1084 fi
1085
1086
1087
1088 AC_CONFIG_FILES([ m4/Makefile 
1089 Makefile
1090 po/Makefile.in
1091 intl/Makefile
1092 jnlib/Makefile
1093 common/Makefile
1094 kbx/Makefile
1095 g10/Makefile
1096 sm/Makefile
1097 agent/Makefile
1098 scd/Makefile
1099 tools/Makefile
1100 doc/Makefile
1101 tests/Makefile
1102 ])
1103 AC_OUTPUT
1104
1105
1106
1107
1108 echo "
1109         GnuPG v${VERSION} has been configured as follows:
1110         
1111         Platform:  $PRINTABLE_OS_NAME ($target)
1112
1113         OpenPGP:   $build_gpg
1114         S/MIME:    $build_gpgsm
1115         Agent:     $build_agent $build_agent_threaded
1116         Smartcard: $build_scdaemon $build_scdaemon_extra
1117
1118         Protect tool:     $show_gnupg_protect_tool_pgm
1119         Default agent:    $show_gnupg_agent_pgm
1120         Default pinentry: $show_gnupg_pinentry_pgm
1121         Default scdaemon: $show_gnupg_scdaemon_pgm
1122         Default dirmngr:  $show_gnupg_dirmngr_pgm
1123 "
1124