* card-util.c (print_name): Fixed bad format string usage.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 1.9
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 #               2003 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 2 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, write to the Free Software
19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20
21 # Process this file with autoconf to produce a configure script.
22 AC_PREREQ(2.52)
23 min_automake_version="1.7.6"
24
25 # Version number: Remember to change it immediately *after* a release.
26 #                 Add a "-cvs" prefix for non-released code.
27 AC_INIT(gnupg, 1.9.3-cvs, gnupg-devel@gnupg.org)
28 # Set development_version to yes if the minor number is odd or you
29 # feel that the default check for a development version is not
30 # sufficient.
31 development_version=yes
32 NEED_GPG_ERROR_VERSION=0.6
33 NEED_LIBGCRYPT_VERSION=1.1.90
34 NEED_LIBASSUAN_VERSION=0.6.1
35 NEED_KSBA_VERSION=0.9.0
36 NEED_OPENSC_VERSION=0.8.0
37
38
39 PACKAGE=$PACKAGE_NAME
40 VERSION=$PACKAGE_VERSION
41
42 AC_CONFIG_AUX_DIR(scripts)
43 AC_CONFIG_SRCDIR(sm/gpgsm.c)
44 AM_CONFIG_HEADER(config.h)
45 AC_CANONICAL_TARGET()
46 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
47
48 AC_GNU_SOURCE
49
50 # Some status variables to give feedback at the end of a configure run
51 have_gpg_error=no
52 have_libgcrypt=no 
53 have_libassuan=no
54 have_ksba=no
55 have_opensc=no
56 have_pth=no
57
58 GNUPG_BUILD_PROGRAM(gpg, yes)
59 GNUPG_BUILD_PROGRAM(gpgsm, yes)
60 GNUPG_BUILD_PROGRAM(agent, yes)
61 GNUPG_BUILD_PROGRAM(scdaemon, yes)
62
63
64 AC_SUBST(PACKAGE)
65 AC_SUBST(VERSION)
66 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
67 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
68 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
69                                         [Bug report address])
70 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
71                                        [Required version of Libgcrypt])
72 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
73                                        [Required version of Libksba])
74
75
76
77
78 # I know that it is in general not a good idea to evaluate bindir in
79 # the configuration but we want to hard code the defaults into some of
80 # the programs and doing this during a make install is not a good
81 # idea.  We also have the problem that 2 of the programs are included
82 # in the package but the others are distributed in other packages.
83 eval my_default_bindir=${exec_prefix}
84 test "x${my_default_bindir}" = xNONE && my_default_bindir=${ac_default_prefix}
85 my_default_bindir=${my_default_bindir}/bin
86
87 # Same goes for the pkglibdir which is used to call the gpg-protect-tool.
88 eval my_default_pkglibdir=${exec_prefix}
89 test "x${my_default_pkglibdir}" = xNONE && my_default_pkglibdir=${ac_default_prefix}
90 my_default_pkglibdir=${my_default_pkglibdir}/lib/${PACKAGE_NAME}
91
92 AC_ARG_WITH(agent-pgm,
93     [  --with-agent-pgm=PATH  Use PATH as the default for the gpg-agent)],
94           gnupg_agent_pgm="$withval",
95           gnupg_agent_pgm="${my_default_bindir}/gpg-agent" )
96 AC_DEFINE_UNQUOTED(GNUPG_DEFAULT_AGENT, "$gnupg_agent_pgm",
97                    [Default location of the gpg-agent program])
98 AC_ARG_WITH(pinentry-pgm,
99     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
100           gnupg_pinentry_pgm="$withval", gnupg_pinentry_pgm="" )
101 if test -z "$gnupg_pinentry_pgm"; then
102   gnupg_pinentry_pgm=${my_default_bindir}/pinentry
103 fi
104 AC_DEFINE_UNQUOTED(GNUPG_DEFAULT_PINENTRY, "$gnupg_pinentry_pgm",
105                    [Default location of the pinentry program])
106 AC_ARG_WITH(scdaemon-pgm,
107     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
108           gnupg_scdaemon_pgm="$withval", gnupg_scdaemon_pgm="" )
109 if test -z "$gnupg_scdaemon_pgm"; then
110   gnupg_scdaemon_pgm=${my_default_bindir}/scdaemon
111 fi
112 AC_DEFINE_UNQUOTED(GNUPG_DEFAULT_SCDAEMON, "$gnupg_scdaemon_pgm",
113                    [Default location of the scdaemon program])
114 AC_ARG_WITH(dirmngr-pgm,
115     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
116           gnupg_dirmngr_pgm="$withval", gnupg_dirmngr_pgm="" )
117 if test -z "$gnupg_dirmngr_pgm"; then
118   gnupg_dirmngr_pgm=${my_default_bindir}/dirmngr
119 fi
120 AC_DEFINE_UNQUOTED(GNUPG_DEFAULT_DIRMNGR, "$gnupg_dirmngr_pgm",
121                    [Default location of the dirmngr program])
122
123 AC_ARG_WITH(protect-tool,
124     [  --with-protect-tool=PATH  Use PATH as the protect-tool)],
125           gnupg_protect_tool="$withval", gnupg_protect_tool="" )
126 if test -z "$gnupg_protect_tool"; then
127   gnupg_protect_tool=${my_default_pkglibdir}/gpg-protect-tool
128 fi
129 AC_DEFINE_UNQUOTED(GNUPG_PROTECT_TOOL, "$gnupg_protect_tool",
130                    [Name of the protect tool program])
131
132
133
134 AC_MSG_CHECKING([whether to enable external program execution])
135 AC_ARG_ENABLE(exec,
136     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
137     use_exec=$enableval)
138 AC_MSG_RESULT($use_exec)
139 if test "$use_exec" = no ; then
140     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
141 fi
142
143 if test "$use_exec" = yes ; then
144   AC_MSG_CHECKING([whether to enable photo ID viewing])
145   AC_ARG_ENABLE(photo-viewers,
146       [  --disable-photo-viewers disable photo ID viewers],
147       [if test "$enableval" = no ; then
148          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
149       fi],enableval=yes)
150   gnupg_cv_enable_photo_viewers=$enableval
151   AC_MSG_RESULT($enableval)
152
153   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
154     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
155     AC_ARG_WITH(photo-viewer,
156         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
157         [if test "$withval" = yes ; then
158            withval=no
159         elif test "$withval" != no ; then
160            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
161                             [if set, restrict photo-viewer to this])
162         fi],withval=no)
163     AC_MSG_RESULT($withval)
164   fi
165
166   AC_MSG_CHECKING([whether to enable external keyserver helpers])
167   AC_ARG_ENABLE(keyserver-helpers,
168       [  --disable-keyserver-helpers  disable all external keyserver support],
169       [if test "$enableval" = no ; then
170          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
171                   [define to disable keyserver helpers])
172       fi],enableval=yes)
173   gnupg_cv_enable_keyserver_helpers=$enableval
174   AC_MSG_RESULT($enableval)
175
176   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
177     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
178     AC_ARG_ENABLE(ldap,
179     [  --disable-ldap          disable LDAP keyserver interface],
180         try_ldap=$enableval, try_ldap=yes)
181     AC_MSG_RESULT($try_ldap)
182
183     AC_MSG_CHECKING([whether HKP keyserver support is requested])
184     AC_ARG_ENABLE(hkp,
185     [  --disable-hkp           disable HKP keyserver interface],
186         try_hkp=$enableval, try_hkp=yes)
187     AC_MSG_RESULT($try_hkp)
188
189     if test "$try_hkp" = yes ; then
190       AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
191     fi
192
193     AC_MSG_CHECKING([whether email keyserver support is requested])
194     AC_ARG_ENABLE(mailto,
195     [  --disable-mailto        disable email keyserver interface],
196         try_mailto=$enableval, try_mailto=yes)
197     AC_MSG_RESULT($try_mailto)
198     fi
199
200     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
201     AC_ARG_ENABLE(keyserver-path,
202         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
203         [if test "$enableval" = no ; then
204          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
205         fi],enableval=yes)
206     AC_MSG_RESULT($enableval)
207   fi
208
209 AC_MSG_CHECKING([whether the included zlib is requested])
210 AC_ARG_WITH(included-zlib,
211     [  --with-included-zlib    use the zlib code included here],
212 [g10_force_zlib=yes], [g10_force_zlib=no] )
213 AC_MSG_RESULT($g10_force_zlib)
214
215 dnl
216 dnl Check whether we want to use Linux capabilities
217 dnl
218 AC_MSG_CHECKING([whether use of capabilities is requested])
219 AC_ARG_WITH(capabilities,
220     [  --with-capabilities     use linux capabilities [default=no]],
221 [use_capabilities="$withval"],[use_capabilities=no])
222 AC_MSG_RESULT($use_capabilities)
223
224
225 AH_BOTTOM([
226 /* Some global constants. */
227 #ifdef HAVE_DRIVE_LETTERS
228 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
229 #else
230 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
231 #endif 
232 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
233
234 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
235 #define EXEC_TEMPFILE_ONLY
236 #endif
237
238 /* Tell libgcrypt not to use its own libgpg-error implementation. */
239 #define USE_LIBGPG_ERROR 1
240
241 /* This is the major version number of GnuPG so that
242    source included files can test for this.  Note, that\
243    we use 2 here even for GnuPG 1.9.x. */
244 #define GNUPG_MAJOR_VERSION 2
245
246 #include "g10defs.h"
247
248 ])
249
250 AM_MAINTAINER_MODE
251
252 # Checks for programs.
253 AC_PROG_MAKE_SET
254 AM_SANITY_CHECK
255 missing_dir=`cd $ac_aux_dir && pwd`
256 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
257 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
258 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
259 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
260 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
261 AC_PROG_AWK
262 AC_PROG_CC
263 AC_PROG_CPP
264 AC_PROG_INSTALL
265 AC_PROG_LN_S
266 AC_PROG_MAKE_SET
267 AC_PROG_RANLIB
268 AC_CHECK_TOOL(AR, ar, :)
269 AC_PATH_PROG(PERL,"perl")
270 AC_ISC_POSIX
271 AC_SYS_LARGEFILE
272 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
273 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
274 GNUPG_CHECK_FAQPROG
275 GNUPG_CHECK_DOCBOOK_TO_TEXI
276
277
278 try_gettext=yes
279 have_dosish_system=no
280 case "${target}" in
281     *-*-mingw32*)
282         # special stuff for Windoze NT
283         ac_cv_have_dev_random=no
284         AC_DEFINE(USE_ONLY_8DOT3,1,
285                   [set this to limit filenames to the 8.3 format])
286         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
287                   [defined if we must run on a stupid file system])
288         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
289                   [because the Unix gettext has too much overhead on
290                    MingW32 systems and these systems lack Posix functions,
291                    we use a simplified version of gettext])
292         have_dosish_system=yes
293         try_gettext="no"
294         ;;
295     i?86-emx-os2 | i?86-*-os2*emx )
296         # OS/2 with the EMX environment
297         ac_cv_have_dev_random=no
298         AC_DEFINE(HAVE_DRIVE_LETTERS)
299         have_dosish_system=yes
300         try_gettext="no"
301         ;;
302
303     i?86-*-msdosdjgpp*)
304         # DOS with the DJGPP environment
305         ac_cv_have_dev_random=no
306         AC_DEFINE(HAVE_DRIVE_LETTERS)
307         have_dosish_system=yes
308         try_gettext="no"
309         ;;
310
311     *-*-freebsd*)
312        # FreeBSD
313        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
314        LDFLAGS="$LDFLAGS -L/usr/local/lib"
315        ;;
316
317     *-*-hpux*)
318         if test -z "$GCC" ; then
319             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
320         fi
321         ;;
322     *-dec-osf4*)
323         if test -z "$GCC" ; then
324             # Suppress all warnings
325             # to get rid of the unsigned/signed char mismatch warnings.
326             CFLAGS="$CFLAGS -w"
327         fi
328         ;;
329     *-dec-osf5*)
330         if test -z "$GCC" ; then
331             # Use the newer compiler `-msg_disable ptrmismatch' to
332             # get rid of the unsigned/signed char mismatch warnings.
333             # Using this may hide other pointer mismatch warnings, but
334             # it at least lets other warning classes through
335             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
336         fi
337         ;;
338     m68k-atari-mint)
339         ;;
340     *)
341        ;;
342 esac
343
344 if test "$have_dosish_system" = yes; then
345    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
346              [defined if we run on some of the PCDOS like systems 
347               (DOS, Windoze. OS/2) with special properties like
348               no file modes])
349 fi
350 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
351
352
353 #
354 # Checks for libraries.
355 #
356
357
358 #
359 # libgpg-error is a library with error codes shared between GnuPG
360 # related projects.
361 #
362 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
363                   have_gpg_error=yes,have_gpg_error=no)
364
365
366 #
367 # Libgcrypt is our generic crypto library
368 #
369 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_VERSION",
370         have_libgcrypt=yes,have_libgcrypt=no)
371
372
373 #
374 # libassuan is used for IPC
375 #
376 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_VERSION",
377                   have_libassuan=yes,have_libassuan=no)
378
379
380 #
381 # libksba is our X.509 support library
382 #
383 AM_PATH_KSBA("$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
384
385 #
386 # libusb allows us to use the integrated CCID smartcard reader driver.
387 #
388 # Note, that we need the CVS version.  FIXME: libusb should have a
389 # regular check as the other libraries do.
390 #
391 AC_CHECK_LIB(usb, usb_find_device,
392               [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
393                 AC_DEFINE(HAVE_LIBUSB,1,
394                          [defined if libusb is available])
395              ])
396 AC_SUBST(LIBUSB_LIBS)
397
398
399 #
400 # OpenSC is needed by the SCdaemon - if it is not availbale we can only
401 # build a limited SCdaemon
402 #
403 AM_PATH_OPENSC("$NEED_OPENSC_VERSION",have_opensc=yes,have_opensc=no)
404 if test $have_opensc = yes; then
405   AC_DEFINE(HAVE_OPENSC,1,
406             [defined if the OpenSC library is available])
407 fi
408
409
410 #
411 # Check whether the (highly desirable) GNU Pth library is available
412 #
413 AC_ARG_WITH(pth-prefix,
414             AC_HELP_STRING([--with-pth-prefix=PFX],
415                            [prefix where GNU Pth is installed (optional)]),
416      pth_config_prefix="$withval", pth_config_prefix="")
417 if test x$pth_config_prefix != x ; then
418    PTH_CONFIG="$pth_config_prefix/bin/pth-config"
419 fi
420 AC_PATH_PROG(PTH_CONFIG, pth-config, no)
421 if test "$PTH_CONFIG" = "no"; then
422     AC_MSG_WARN([[
423 ***
424 *** To support concurrent access to the gpg-agent and the SCdaemon
425 *** we need the support of the GNU Portable Threads Library.
426 *** Download it from ftp://ftp.gnu.org/gnu/pth/
427 *** On a Debian GNU/Linux system you might want to try 
428 ***   apt-get install libpth-dev
429 ***]])
430 else
431   GNUPG_PTH_VERSION_CHECK(1.3.7)
432   if test $have_pth = yes; then      
433      PTH_CFLAGS=`$PTH_CONFIG --cflags`
434      PTH_LIBS=`$PTH_CONFIG --ldflags`
435      PTH_LIBS="$PTH_LIBS `$PTH_CONFIG --libs`"
436      AC_DEFINE(USE_GNU_PTH, 1,
437               [Defined if the GNU Portable Thread Library should be used])
438   fi
439 fi
440 AC_SUBST(PTH_CFLAGS)
441 AC_SUBST(PTH_LIBS)
442
443
444 dnl Must check for network library requirements before doing link tests
445 dnl for ldap, for example. If ldap libs are static (or dynamic and without
446 dnl ELF runtime link paths), then link will fail and LDAP support won't
447 dnl be detected.
448
449 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
450         [NETLIBS="-lnsl $NETLIBS"]))
451 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
452         [NETLIBS="-lsocket $NETLIBS"]))
453
454 dnl Now try for the resolver functions so we can use DNS SRV
455
456 AC_ARG_ENABLE(dns-srv,
457    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
458    use_dns_srv=$enableval,use_dns_srv=yes)
459
460 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
461   _srv_save_libs=$LIBS
462   LIBS=""
463   # the double underscore thing is a glibc-ism?
464   AC_SEARCH_LIBS(res_query,resolv bind,,
465                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
466   AC_SEARCH_LIBS(dn_expand,resolv bind,,
467                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
468   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
469                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
470
471   if test x"$use_dns_srv" = xyes ; then
472      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
473      SRVLIBS=$LIBS
474   else
475      AC_MSG_WARN([Resolver functions not found.  Disabling DNS SRV.])
476   fi
477   LIBS=$_srv_save_libs
478 fi
479
480 AC_SUBST(SRVLIBS)
481
482 # Try and link a LDAP test program to weed out unusable LDAP
483 # libraries.  -lldap [-llber [-lresolv]] is for OpenLDAP.  OpenLDAP in
484 # general is terrible with creating weird dependencies.  If all else
485 # fails, the user can play guess-the-dependency by using something
486 # like ./configure LDAPLIBS="-Lfoo -lbar"
487
488 if test "$try_ldap" = yes ; then
489   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
490     _ldap_save_libs=$LIBS
491     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
492
493     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
494     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
495                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
496     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
497
498     if test $gnupg_cv_func_ldap_init = no; then
499       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
500       AC_TRY_LINK([#include <lber.h>
501 #include <ldap.h>],[ldap_open("foobar",1234);],
502          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
503       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
504     fi
505
506     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
507        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
508     fi
509
510     if test "$gnupg_cv_func_ldap_init" = yes || \
511         test "$gnupg_cv_func_ldaplber_init" = yes ; then
512        LDAPLIBS=$MY_LDAPLIBS
513        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
514
515        AC_MSG_CHECKING([whether LDAP supports ldap_get_option])
516
517        if test "$gnupg_cv_func_ldap_init" = yes ; then
518           AC_TRY_LINK([#include <ldap.h>],
519              [ldap_get_option((void *)0,0,(void *)0);],
520              [gnupg_cv_func_ldap_get_option=yes],
521              [gnupg_cv_func_ldap_get_option=no])
522         else
523           AC_TRY_LINK([#include <lber.h>
524 #include <ldap.h>],[ldap_get_option((void *)0,0,(void *)0);],
525              [gnupg_cv_func_ldap_get_option=yes],
526              [gnupg_cv_func_ldap_get_option=no])
527        fi
528
529        AC_MSG_RESULT([$gnupg_cv_func_ldap_get_option])
530
531        if test "$gnupg_cv_func_ldap_get_option" = yes ; then
532           AC_DEFINE(HAVE_LDAP_GET_OPTION,1,[Define if the LDAP library has ldap_get_option])
533        else
534           AC_MSG_CHECKING([whether LDAP supports ld_errno])
535
536           if test "$gnupg_cv_func_ldap_init" = yes ; then
537             AC_TRY_COMPILE([#include <ldap.h>],
538                [LDAP *ldap; ldap->ld_errno;],
539                [gnupg_cv_func_ldap_ld_errno=yes],
540                [gnupg_cv_func_ldap_ld_errno=no])
541            else
542             AC_TRY_LINK([#include <lber.h>
543 #include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
544                [gnupg_cv_func_ldap_ld_errno=yes],
545                [gnupg_cv_func_ldap_ld_errno=no])
546           fi
547
548           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
549
550           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
551              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
552           fi
553        fi
554     fi
555
556     LIBS=$_ldap_save_libs
557
558     if test "$GPGKEYS_LDAP" != "" ; then break; fi
559   done
560 fi
561
562 AC_SUBST(GPGKEYS_LDAP)
563 AC_SUBST(LDAPLIBS)
564
565 dnl This isn't necessarily sendmail itself, but anything that gives a
566 dnl sendmail-ish interface to the outside world.  That includes qmail,
567 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
568
569 if test "$try_mailto" = yes ; then
570   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
571
572   if test "$with_mailprog" = yes ; then
573     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
574     if test "$ac_cv_path_SENDMAIL" ; then
575       GPGKEYS_MAILTO="gpgkeys_mailto"
576     fi
577   elif test "$with_mailprog" != no ; then
578     AC_MSG_CHECKING([for a mail transport program])
579     AC_SUBST(SENDMAIL,$with_mailprog)
580     AC_MSG_RESULT($with_mailprog)
581     GPGKEYS_MAILTO="gpgkeys_mailto"
582   fi
583 fi
584
585 AC_SUBST(GPGKEYS_MAILTO)
586
587 case "${target}" in
588     *-*-mingw32*)
589         PRINTABLE_OS_NAME="MingW32"
590         ;;
591     *-*-cygwin*)
592         PRINTABLE_OS_NAME="Cygwin"
593         ;;
594     i?86-emx-os2 | i?86-*-os2*emx )
595         PRINTABLE_OS_NAME="OS/2"
596         ;;
597     i?86-*-msdosdjgpp*)
598         PRINTABLE_OS_NAME="MSDOS/DJGPP"
599         try_dynload=no
600         ;;
601     *-linux*)
602         PRINTABLE_OS_NAME="GNU/Linux"
603         ;;
604     *)
605         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
606         ;;
607 esac
608 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
609                    [A human readable text with the name of the OS])
610
611
612 AM_GNU_GETTEXT_VERSION(0.12.1)
613 if test "$try_gettext" = yes; then
614   AM_GNU_GETTEXT(,[need-ngettext])
615
616   # gettext requires some extra checks.  These really should be part of
617   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
618   # function checks to here.
619
620   AC_CHECK_FUNCS(strchr)
621 else
622   USE_NLS=no
623   USE_INCLUDED_LIBINTL=no
624   BUILD_INCLUDED_LIBINTL=no
625   AC_SUBST(USE_NLS)
626   AC_SUBST(USE_INCLUDED_LIBINTL)
627   AC_SUBST(BUILD_INCLUDED_LIBINTL)
628 fi
629
630 # Checks for header files.
631 AC_HEADER_STDC
632 AC_CHECK_HEADERS(string.h unistd.h langinfo.h termio.h locale.h)
633
634 # Checks for typedefs, structures, and compiler characteristics.
635 AC_C_CONST
636 AC_C_INLINE
637 AC_TYPE_SIZE_T
638 AC_TYPE_SIGNAL
639 AC_DECL_SYS_SIGLIST
640
641 GNUPG_CHECK_ENDIAN
642
643 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
644 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
645 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
646 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
647 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
648
649 AC_CHECK_SIZEOF(unsigned short)
650 AC_CHECK_SIZEOF(unsigned int)
651 AC_CHECK_SIZEOF(unsigned long)
652 AC_CHECK_SIZEOF(unsigned long long)
653 # Ensure that we have UINT64_C before we bother to check for uint64_t
654 # fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
655 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
656    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
657 uint64_t foo=UINT64_C(42);]),gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
658 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
659    AC_CHECK_SIZEOF(uint64_t)
660 fi
661  
662
663
664
665 if test "$ac_cv_sizeof_unsigned_short" = "0" \
666    || test "$ac_cv_sizeof_unsigned_int" = "0" \
667    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
668     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
669 fi
670
671 dnl Do we have any 64-bit data types?
672 if test "$ac_cv_sizeof_unsigned_int" != "8" \
673    && test "$ac_cv_sizeof_unsigned_long" != "8" \
674    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
675    && test "$ac_cv_sizeof_uint64_t" != "8"; then
676     AC_MSG_WARN([No 64-bit types.  Disabling SHA-384, and SHA-512])
677 else
678   if test x"$use_sha512" = xyes ; then
679      AC_SUBST(SHA512_O,sha512.o)
680      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
681   fi
682 fi
683
684 GNUPG_SYS_SO_PEERCRED
685
686 # Checks for library functions.
687 AC_FUNC_FSEEKO
688 AC_FUNC_VPRINTF
689 AC_FUNC_FORK
690 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
691 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times gmtime_r)
692 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
693 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
694 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat getaddrinfo)
695
696 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
697
698 # These are needed by libjnlib - fixme: we should have macros for them
699 AC_CHECK_FUNCS(memicmp stpcpy strlwr strtoul memmove stricmp strtol)
700 AC_CHECK_FUNCS(getrusage setrlimit stat setlocale)
701 AC_CHECK_FUNCS(flockfile funlockfile fopencookie funopen)
702
703 AC_REPLACE_FUNCS(vasprintf)
704 AC_REPLACE_FUNCS(fopencookie)
705 AC_REPLACE_FUNCS(mkdtemp)
706 AC_REPLACE_FUNCS(fseeko ftello)
707 AC_REPLACE_FUNCS(isascii)
708 AC_REPLACE_FUNCS(putc_unlocked)
709
710
711
712
713 #
714 # check for gethrtime and run a testprogram to see whether
715 # it is broken.  It has been reported that some Solaris and HP UX systems 
716 # raise an SIGILL
717 #
718 AC_CACHE_CHECK([for gethrtime], 
719                [gnupg_cv_func_gethrtime],
720                [AC_TRY_LINK([#include <sys/times.h>],[
721                    hrtime_t tv;
722                    tv = gethrtime();
723                  ],
724                  [gnupg_cv_func_gethrtime=yes],
725                  [gnupg_cv_func_gethrtime=no])
726                ])
727 if test $gnupg_cv_func_gethrtime = yes; then
728      AC_DEFINE([HAVE_GETHRTIME], 1,
729                [Define if you have the `gethrtime(2)' function.])
730      AC_CACHE_CHECK([whether gethrtime is broken], 
731                [gnupg_cv_func_broken_gethrtime],
732                [AC_TRY_RUN([
733                    #include <sys/times.h>
734                    int main () {
735                    hrtime_t tv;
736                    tv = gethrtime(); 
737                  }
738                  ],
739                  [gnupg_cv_func_broken_gethrtime=no],
740                  [gnupg_cv_func_broken_gethrtime=yes],
741                  [gnupg_cv_func_broken_gethrtime=assume-no])
742                 ])
743     if test $gnupg_cv_func_broken_gethrtime = yes; then
744       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
745       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
746     fi
747 fi
748      
749
750 GNUPG_CHECK_MLOCK
751 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
752
753 dnl
754 dnl Check whether we can use Linux capabilities as requested
755 dnl
756 if test "$use_capabilities" = "yes" ; then
757 use_capabilities=no
758 AC_CHECK_HEADERS(sys/capability.h)
759 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
760   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
761   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
762      AC_DEFINE(USE_CAPABILITIES,1,
763                [define if capabilities should be used])
764      AC_SUBST(CAPLIBS,"-lcap")
765      use_capabilities=yes
766   fi
767 fi
768 if test "$use_capabilities" = "no" ; then
769     AC_MSG_WARN([[
770 ***
771 *** The use of capabilities on this system is not possible.
772 *** You need a recent Linux kernel and some patches:
773 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
774 ***   fcap-module-990613.tar.gz     (kernel module)
775 ***   libcap-1.92.tar.gz            (user mode library and utilities)
776 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
777 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
778 ***]])
779 fi
780 fi
781
782
783 # Sanity check regex.  Tests adapted from mutt.
784
785 AC_MSG_CHECKING([whether regular expression support is requested])
786 AC_ARG_ENABLE(regex,
787 [  --disable-regex         do not handle regular expressions in trust sigs],
788      use_regex=$enableval, use_regex=yes)
789 AC_MSG_RESULT($use_regex)
790
791 if test "$use_regex" = yes ; then
792   AC_MSG_CHECKING([whether the included regex lib is requested])
793   AC_ARG_WITH(included-regex,
794       [  --with-included-regex   use the included GNU regex library],
795       [gnupg_cv_included_regex=yes],[gnupg_cv_included_regex=no])
796   AC_MSG_RESULT($gnupg_cv_included_regex)
797
798   if test $gnupg_cv_included_regex = no ; then
799      # Does the system have regex functions at all?
800      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
801                            gnupg_cv_included_regex=yes)
802   fi
803
804   if test $gnupg_cv_included_regex = no ; then
805      AC_CACHE_CHECK([whether your system's regexp library is broken],
806        [gnupg_cv_regex_broken],
807        AC_TRY_RUN([
808 #include <unistd.h>
809 #include <regex.h>
810 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
811        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
812
813      if test $gnupg_cv_regex_broken = yes ; then
814       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
815       gnupg_cv_included_regex=yes
816      fi
817   fi
818
819   if test $gnupg_cv_included_regex = yes; then
820      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
821      AC_SUBST(REGEX_O,regex.o)
822   fi
823 else
824
825   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
826 fi
827
828 dnl Do we have zlib? Must do it here because Solaris failed
829 dnl when compiling a conftest (due to the "-lz" from LIBS).
830 use_local_zlib=yes
831 if test "$g10_force_zlib" = "yes"; then
832   :
833 else
834   _cppflags="${CPPFLAGS}"
835   _ldflags="${LDFLAGS}"
836
837   AC_ARG_WITH(zlib,
838   [  --with-zlib=DIR         use libz in DIR],[
839     if test -d "$withval"; then
840       CPPFLAGS="${CPPFLAGS} -I$withval/include"
841       LDFLAGS="${LDFLAGS} -L$withval/lib"
842     fi
843   ])
844
845   AC_CHECK_HEADER(zlib.h,
846       AC_CHECK_LIB(z, deflateInit2_,
847        use_local_zlib=no
848        LIBS="$LIBS -lz",
849        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
850        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
851 fi
852  
853 if test "$use_local_zlib" = yes ; then
854     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
855     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
856     ZLIBS="../zlib/libzlib.a"
857 else
858     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
859     ZLIBS=
860 fi
861 AC_SUBST(ZLIBS)
862
863 # Allow users to append something to the version string without
864 # flagging it as development version.  The user version parts is
865 # considered everything after a dash. 
866 if test "$development_version" != yes; then
867   changequote(,)dnl
868   tmp_pat='[a-zA-Z]'
869   changequote([,])dnl
870   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
871     development_version=yes
872   fi
873 fi
874 if test "$development_version" = yes; then
875     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
876             [Defined if this is not a regular release])
877 fi
878
879 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
880
881 GNUPG_CHECK_GNUMAKE
882
883 # add some extra libs here so that previous tests don't fail for
884 # mysterious reasons - the final link step should bail out. 
885 case "${target}" in
886     *-*-mingw32*)
887         W32LIBS="-lwsock32"
888         ;;
889     *)
890        ;;
891 esac
892
893
894 if test "$GCC" = yes; then
895     if test "$USE_MAINTAINER_MODE" = "yes"; then
896         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
897     else
898         CFLAGS="$CFLAGS -Wall"
899     fi
900 fi
901
902 AC_SUBST(NETLIBS)
903 AC_SUBST(W32LIBS)
904
905
906 # We use jnlib, so tell other modules about it
907 AC_DEFINE(HAVE_JNLIB_LOGGING, 1,
908         [Defined if jnlib style logging fucntions are available])
909
910
911
912
913 #
914 # Print errors here so that they are visible all
915 # together and the user can acquire them all together.
916 #
917 die=no
918 if test "$have_gpg_error" = "no"; then
919    die=yes
920    AC_MSG_NOTICE([[
921 ***  
922 *** You need libgpg-error to build this program.
923 **  This library is for example available at
924 ***   ftp://ftp.gnupg.org/pub/gcrypt/alpha/libgpg-error
925 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
926 ***]])
927 fi
928 if test "$have_libgcrypt" = "no"; then
929    die=yes
930    AC_MSG_NOTICE([[
931 ***  
932 *** You need libgcrypt to build this program.
933 **  This library is for example available at
934 ***   ftp://ftp.gnupg.org/pub/gcrypt/alpha/libgcrypt/
935 *** (at least version $NEED_LIBGCRYPT_VERSION is required.)
936 ***]])
937 fi
938 if test "$have_libassuan" = "no"; then
939    die=yes
940    AC_MSG_NOTICE([[
941 ***
942 *** You need libassuan to build this program.
943 *** This library is for example available at
944 ***   ftp://ftp.gnupg.org/pub/gcrypt/alpha/libassuan/
945 *** (at least version $NEED_LIBASSUAN_VERSION is required).
946 ***]])
947 fi
948 if test "$have_ksba" = "no"; then
949    die=yes
950     AC_MSG_NOTICE([[
951 ***
952 *** You need libksba to build this program.
953 *** This library is for example available at
954 ***   ftp://ftp.gnupg.org/pub/gcrypt/alpha/libksba/
955 *** (at least version $NEED_KSBA_VERSION is required).
956 ***]])
957 fi
958
959 if test "$die" = "yes"; then
960     AC_MSG_ERROR([[
961 ***
962 *** Required libraries not found. Please consult the above messages
963 *** and install them before running configure again.
964 ***]])
965 fi
966
967
968 #
969 # Decide what to build
970 #
971 if test $have_ksba = no; then
972   build_gpgsm=no
973   build_scdaemon=no
974 fi
975
976 build_agent_threaded=""
977 if test "$build_agent" = "yes"; then
978   if test $have_pth = no; then
979      build_agent_threaded="(not multi-threaded)"
980   fi
981 fi
982
983 build_scdaemon_extra=""
984 if test "$build_scdaemon" = "yes"; then
985   tmp=""
986   if test $have_pth = no; then
987      build_scdaemon_extra="not multi-threaded"
988      tmp=", "
989   fi
990   if test $have_opensc = no; then
991      build_scdaemon_extra="${build_scdaemon_extra}${tmp}no pkcs#15"
992      tmp=", "
993   fi      
994   if test -n "$build_scdaemon_extra"; then
995      build_scdaemon_extra="(${build_scdaemon_extra})"
996   fi
997 fi
998
999
1000 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1001 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1002 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1003 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1004
1005
1006 AC_CONFIG_COMMANDS(g10defs.h,[[
1007 cat >g10defs.tmp <<G10EOF
1008 /* Generated automatically by configure */
1009 /* FIXME: Shouldn't we replace GNUPG_HOMEDIR by GNUPG_DEFAULT_HOMEDIR
1010    and we propably can get rid of g10defs.h */
1011 #ifdef HAVE_DRIVE_LETTERS
1012 /*#define G10_LOCALEDIR     "c:\\\\lib\\\\gnupg\\\\locale"*/
1013 #define GNUPG_LIBDIR      "c:\\\\lib\\\\gnupg"
1014 #define GNUPG_LIBEXECDIR  "c:\\\\lib\\\\gnupg"
1015 #define GNUPG_DATADIR     "c:\\\\lib\\\\gnupg"
1016 #define GNUPG_HOMEDIR     "c:\\\\gnupg"
1017 #else
1018 /*#define G10_LOCALEDIR     "${datadir}/locale"*/
1019 #define GNUPG_LIBDIR      "${libdir}/gnupg"
1020 #define GNUPG_DATADIR     "${datadir}/gnupg"
1021 #ifdef __VMS
1022 #define GNUPG_HOMEDIR "/SYS\$LOGIN/gnupg" 
1023 #else
1024 #define GNUPG_HOMEDIR "~/.gnupg" 
1025 #endif
1026 #endif
1027 /* those are here to be redefined by handcrafted g10defs.h.
1028    Please note that the string version must not contain more
1029    than one character because the using code assumes strlen()==1 */
1030 #ifdef HAVE_DOSISH_SYSTEM
1031 #define DIRSEP_C '\\\\'
1032 #define EXTSEP_C '.'
1033 #define DIRSEP_S "\\\\"
1034 #define EXTSEP_S "."
1035 #else
1036 #define DIRSEP_C '/'
1037 #define EXTSEP_C '.'
1038 #define DIRSEP_S "/"
1039 #define EXTSEP_S "."
1040 #endif
1041 /* This is the same as VERSION, but should be overridden if the
1042    platform cannot handle things like dots '.' in filenames. */
1043 #define SAFE_VERSION VERSION
1044 G10EOF
1045 ## Do we really need the following?  It defines BYTES_PER-MPI_LIMB
1046 ## cat mpi/mpi-asm-defs.h >>g10defs.tmp 
1047 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
1048     echo "g10defs.h is unchanged"
1049     rm -f g10defs.tmp
1050 else
1051     rm -f g10defs.h
1052     mv g10defs.tmp g10defs.h
1053     echo "g10defs.h created"
1054 fi
1055 ]],[[
1056 prefix=$prefix
1057 exec_prefix=$exec_prefix
1058 libdir=$libdir
1059 libexecdir=$libexecdir
1060 datadir=$datadir
1061 DATADIRNAME=$DATADIRNAME
1062 ]])
1063
1064 AC_CONFIG_FILES([ m4/Makefile 
1065 Makefile
1066 po/Makefile.in
1067 intl/Makefile
1068 jnlib/Makefile
1069 common/Makefile
1070 kbx/Makefile
1071 g10/Makefile
1072 sm/Makefile
1073 agent/Makefile
1074 scd/Makefile
1075 doc/Makefile
1076 ])
1077 AC_OUTPUT
1078 #tests/Makefile
1079
1080
1081 echo "
1082         GnuPG v${VERSION} has been configured as follows:
1083         
1084         Platform:  $PRINTABLE_OS_NAME ($target)
1085
1086         OpenPGP:   $build_gpg
1087         S/MIME:    $build_gpgsm
1088         Agent:     $build_agent $build_agent_threaded
1089         Smartcard: $build_scdaemon $build_scdaemon_extra
1090
1091         Protect tool:     $gnupg_protect_tool
1092         Default agent:    $gnupg_agent_pgm
1093         Default pinentry: $gnupg_pinentry_pgm
1094         Default scdaemon: $gnupg_scdaemon_pgm
1095         Default dirmngr:  $gnupg_dirmngr_pgm
1096 "
1097