Include bzip2 code to ease building for W32.
[gnupg.git] / configure.ac
1 # configure.ac script for GnuPG
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007,
3 #               2008, 2009, 2010, 2012 Free Software Foundation, Inc.
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
19 #
20 # (Process this file with autoconf to produce a configure script.)
21
22 AC_PREREQ(2.59)
23 min_automake_version="1.9.3"
24
25 # Remember to change the version number immediately *after* a release.
26 # Set my_issvn to "yes" for non-released code.  Remember to run an
27 # "svn up" and "autogen.sh --force" right before creating a distribution.
28 m4_define([my_version], [1.4.12])
29 m4_define([my_issvn], [yes])
30
31 m4_define([svn_revision], m4_esyscmd([printf "%d" $(svn info 2>/dev/null \
32           | sed -n '/^Revision:/ s/[^0-9]//gp'|head -1)]))
33 m4_define([git_revision], m4_esyscmd([git branch -v 2>/dev/null \
34           | awk '/^\* / {printf "%s",$3}']))
35 m4_define([my_full_version], [my_version[]m4_if(my_issvn,[yes],
36           [m4_if(git_revision,[],[-svn[]svn_revision],[-git[]git_revision])])])
37
38 AC_INIT([gnupg],[my_full_version],[http://bugs.gnupg.org])
39 # Set development_version to yes if the minor number is odd or you
40 # feel that the default check for a development version is not
41 # sufficient.
42 development_version=no
43
44 AC_CONFIG_AUX_DIR(scripts)
45 AC_CONFIG_SRCDIR(g10/gpg.c)
46 AC_CANONICAL_HOST
47 AM_INIT_AUTOMAKE([std-options])
48 AB_INIT
49 AM_CONFIG_HEADER(config.h)
50
51 AC_GNU_SOURCE
52
53 dnl
54 dnl  Check for random module options
55 dnl
56 AC_MSG_CHECKING([which random module to use])
57 AC_ARG_ENABLE(static-rnd,
58     AC_HELP_STRING([[--enable-static-rnd=[egd|unix|linux|auto]]],
59                    [specify a random number source]),
60     [use_static_rnd=$enableval], [use_static_rnd=default])
61
62 if test "$use_static_rnd" = no; then
63     use_static_rnd=default
64 fi
65
66 case "$use_static_rnd" in
67     egd | linux | unix | default )
68       AC_MSG_RESULT($use_static_rnd)
69       ;;
70     auto )
71       AC_MSG_RESULT(automagically selected at runtime)
72       ;;
73     * )
74       AC_MSG_RESULT(invalid argument)
75       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
76       ;;
77 esac
78
79 AC_ARG_WITH(egd-socket,
80     AC_HELP_STRING([--with-egd-socket=NAME],[use NAME for the EGD socket]),
81             egd_socket_name="$withval", egd_socket_name="" )
82 AC_DEFINE_UNQUOTED(EGD_SOCKET_NAME, "$egd_socket_name",
83                    [Define if you don't want the default EGD socket name.
84                     For details see cipher/rndegd.c])
85
86
87 dnl
88 dnl See whether the user wants to disable checking for /dev/random
89
90 AC_MSG_CHECKING([whether use of /dev/random is requested])
91 AC_ARG_ENABLE(dev-random,
92    AC_HELP_STRING([--disable-dev-random],[disable the use of dev random]),
93    try_dev_random=$enableval, try_dev_random=yes)
94 AC_MSG_RESULT($try_dev_random)
95
96
97 dnl
98 dnl  Check other options
99 dnl
100
101 AC_MSG_CHECKING([whether assembler modules are requested])
102 AC_ARG_ENABLE(asm,
103    AC_HELP_STRING([--disable-asm],[do not use assembler modules]),
104      try_asm_modules=$enableval, try_asm_modules=yes)
105 AC_MSG_RESULT($try_asm_modules)
106
107 dnl AC_MSG_CHECKING([whether memory guard is requested])
108 dnl AC_ARG_ENABLE(m-guard,
109 dnl     [  --enable-m-guard        enable memory guard facility],
110 dnl     use_m_guard=$enableval, use_m_guard=no)
111 dnl AC_MSG_RESULT($use_m_guard)
112 dnl if test "$use_m_guard" = yes ; then
113 dnl     AC_DEFINE(M_GUARD,1,[Define to use the (obsolete) malloc guarding feature])
114 dnl fi
115
116 # SELinux support includes tracking of sensitive files to avoid
117 # leaking their contents through processing these files by gpg itself
118 AC_MSG_CHECKING([whether SELinux support is requested])
119 AC_ARG_ENABLE(selinux-support,
120               AC_HELP_STRING([--enable-selinux-support],
121                              [enable SELinux support]),
122               selinux_support=$enableval, selinux_support=no)
123 AC_MSG_RESULT($selinux_support)
124
125
126 AC_MSG_CHECKING([whether the new iconv based code is requested])
127 AC_ARG_ENABLE(gnupg-iconv,
128               AC_HELP_STRING([--disable-gnupg-iconv],
129                              [disable the new iconv code]),
130               gnupg_use_iconv=$enableval, gnupg_use_iconv=yes)
131 AC_MSG_RESULT($gnupg_use_iconv)
132
133 dnl See if we are disabling any algorithms or features for a smaller
134 dnl binary
135
136 try_extensions=no
137
138 try_gettext=yes
139 try_dns=yes
140 use_rsa=yes
141 use_idea=yes
142 use_cast5=yes
143 use_blowfish=yes
144 use_aes=yes
145 use_twofish=yes
146 use_camellia=yes
147 use_sha256=yes
148 use_sha512=yes
149 use_bzip2=yes
150 use_exec=yes
151 card_support=yes
152 agent_support=yes
153 disable_keyserver_path=no
154
155 AC_ARG_ENABLE(minimal,
156    AC_HELP_STRING([--enable-minimal],[build the smallest gpg binary possible]),
157    try_dns=no
158    use_rsa=no
159    use_idea=no
160    use_cast5=no
161    use_blowfish=no
162    use_aes=no
163    use_twofish=no
164    use_camellia=no
165    use_sha256=no
166    use_sha512=no
167    use_bzip2=no
168    use_exec=no
169    card_support=no
170    agent_support=no)
171
172
173 AC_MSG_CHECKING([whether OpenPGP card support is requested])
174 AC_ARG_ENABLE(card-support,
175               AC_HELP_STRING([--disable-card-support],
176                              [disable OpenPGP card support]),
177               card_support=$enableval)
178 AC_MSG_RESULT($card_support)
179
180
181 # Note that we may later disable the agent support based on the platform.
182 AC_MSG_CHECKING([whether gpg-agent support is requested])
183 AC_ARG_ENABLE(agent-support,
184               AC_HELP_STRING([--disable-agent-support],
185                              [disable gpg-agent support]),
186               agent_support=$enableval)
187 AC_MSG_RESULT($agent_support)
188
189
190 AC_MSG_CHECKING([whether to enable the RSA public key algorithm])
191 AC_ARG_ENABLE(rsa,
192    AC_HELP_STRING([--disable-rsa],[disable the RSA public key algorithm]),
193    use_rsa=$enableval)
194 AC_MSG_RESULT($use_rsa)
195 if test x"$use_rsa" = xyes ; then
196    AC_DEFINE(USE_RSA,1,[Define to include the RSA public key algorithm])
197 fi
198
199 AC_MSG_CHECKING([whether to enable the IDEA cipher])
200 AC_ARG_ENABLE(idea,
201    AC_HELP_STRING([--disable-idea],[disable the IDEA cipher]),
202    use_idea=$enableval)
203 AC_MSG_RESULT($use_idea)
204 if test x"$use_idea" = xyes ; then
205    AC_DEFINE(USE_IDEA,1,[Define to include the IDEA cipher])
206
207 # We don't need idea but some people claim that they need it for
208 # research etc., so we allow to place an idea source code into the
209 # cipher directory and statically link it if available, otherwise we
210 # link to a stub.  We don't use AC_CHECK_FILE to avoid caching.
211
212    AC_MSG_CHECKING([for idea cipher module])
213    tmp=""
214    if test -f $srcdir/cipher/idea.c; then
215       IDEA_O=idea.o
216       tmp=idea
217    else
218       IDEA_O=idea-stub.o
219       tmp=no
220       try_extensions=yes
221    fi
222    AC_SUBST(IDEA_O)
223    AC_MSG_RESULT($tmp)
224 fi
225
226 AC_MSG_CHECKING([whether to enable the CAST5 cipher])
227 AC_ARG_ENABLE(cast5,
228    AC_HELP_STRING([--disable-cast5],[disable the CAST5 cipher]),
229    use_cast5=$enableval)
230 AC_MSG_RESULT($use_cast5)
231 if test x"$use_cast5" = xyes ; then
232    AC_DEFINE(USE_CAST5,1,[Define to include the CAST5 cipher])
233 fi
234
235 AC_MSG_CHECKING([whether to enable the BLOWFISH cipher])
236 AC_ARG_ENABLE(blowfish,
237    AC_HELP_STRING([--disable-blowfish],[disable the BLOWFISH cipher]),
238    use_blowfish=$enableval)
239 AC_MSG_RESULT($use_blowfish)
240 if test x"$use_blowfish" = xyes ; then
241    AC_DEFINE(USE_BLOWFISH,1,[Define to include the BLOWFISH cipher])
242 fi
243
244 AC_MSG_CHECKING([whether to enable the AES ciphers])
245 AC_ARG_ENABLE(aes,
246    AC_HELP_STRING([--disable-aes],[disable the AES, AES192, and AES256 ciphers]),
247    use_aes=$enableval)
248 AC_MSG_RESULT($use_aes)
249 if test x"$use_aes" = xyes ; then
250    AC_DEFINE(USE_AES,1,[Define to include the AES, AES192, and AES256 ciphers])
251 fi
252
253 AC_MSG_CHECKING([whether to enable the TWOFISH cipher])
254 AC_ARG_ENABLE(twofish,
255    AC_HELP_STRING([--disable-twofish],[disable the TWOFISH cipher]),
256    use_twofish=$enableval)
257 AC_MSG_RESULT($use_twofish)
258 if test x"$use_twofish" = xyes ; then
259    AC_DEFINE(USE_TWOFISH,1,[Define to include the TWOFISH cipher])
260 fi
261
262 AC_MSG_CHECKING([whether to enable the CAMELLIA cipher])
263 AC_ARG_ENABLE(camellia,
264    AC_HELP_STRING([--enable-camellia],[enable the CAMELLIA cipher]),
265    use_camellia=$enableval)
266 AC_MSG_RESULT($use_camellia)
267 if test x"$use_camellia" = xyes ; then
268    AC_DEFINE(USE_CAMELLIA,1,[Define to include the CAMELLIA cipher])
269 fi
270
271 AC_MSG_CHECKING([whether to enable the SHA-224 and SHA-256 digests])
272 AC_ARG_ENABLE(sha256,
273    AC_HELP_STRING([--disable-sha256],[disable the SHA-224 and SHA-256 digests]),
274    use_sha256=$enableval)
275 AC_MSG_RESULT($use_sha256)
276 if test x"$use_sha256" = xyes ; then
277    AC_DEFINE(USE_SHA256,1,[Define to include the SHA-224 and SHA-256 digests])
278 fi
279
280 dnl SHA512 is defined only after we confirm 64-bit support later
281 AC_MSG_CHECKING([whether to enable the SHA-384 and SHA-512 digests])
282 AC_ARG_ENABLE(sha512,
283    AC_HELP_STRING([--disable-sha512],[disable the SHA-384 and SHA-512 digests]),
284    use_sha512=$enableval)
285 AC_MSG_RESULT($use_sha512)
286
287 dnl BZLIB is defined only after we confirm the library is available later
288 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
289 AC_ARG_ENABLE(bzip2,
290    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
291    use_bzip2=$enableval)
292 AC_MSG_RESULT($use_bzip2)
293
294 AC_MSG_CHECKING([whether to enable external program execution])
295 AC_ARG_ENABLE(exec,
296     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
297     use_exec=$enableval)
298 AC_MSG_RESULT($use_exec)
299 if test "$use_exec" = no ; then
300     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
301 fi
302
303 if test "$use_exec" = yes ; then
304   AC_MSG_CHECKING([whether to enable photo ID viewing])
305   AC_ARG_ENABLE(photo-viewers,
306       AC_HELP_STRING([--disable-photo-viewers],[disable photo ID viewers]),
307       [if test "$enableval" = no ; then
308          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
309       fi],enableval=yes)
310   gnupg_cv_enable_photo_viewers=$enableval
311   AC_MSG_RESULT($enableval)
312
313   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
314     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
315     AC_ARG_WITH(photo-viewer,
316         AC_HELP_STRING([--with-photo-viewer=FIXED_VIEWER],
317                        [set a fixed photo ID viewer]),
318         [if test "$withval" = yes ; then
319            withval=no
320         elif test "$withval" != no ; then
321            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
322                             [if set, restrict photo-viewer to this])
323         fi],withval=no)
324     AC_MSG_RESULT($withval)
325   fi
326
327   AC_MSG_CHECKING([whether to enable external keyserver helpers])
328   AC_ARG_ENABLE(keyserver-helpers,
329       AC_HELP_STRING([--disable-keyserver-helpers],
330                      [disable all external keyserver support]),
331       [if test "$enableval" = no ; then
332          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
333                   [define to disable keyserver helpers])
334       fi],enableval=yes)
335   gnupg_cv_enable_keyserver_helpers=$enableval
336   AC_MSG_RESULT($enableval)
337
338   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
339 dnl LDAP is defined only after we confirm the library is available later
340     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
341     AC_ARG_ENABLE(ldap,
342       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
343       try_ldap=$enableval, try_ldap=yes)
344     AC_MSG_RESULT($try_ldap)
345
346     AC_MSG_CHECKING([whether HKP keyserver support is requested])
347     AC_ARG_ENABLE(hkp,
348       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
349       try_hkp=$enableval, try_hkp=yes)
350     AC_MSG_RESULT($try_hkp)
351
352     AC_MSG_CHECKING([whether finger key fetching support is requested])
353     AC_ARG_ENABLE(finger,
354       AC_HELP_STRING([--disable-finger],
355         [disable finger key fetching interface only]),
356       try_finger=$enableval, try_finger=yes)
357     AC_MSG_RESULT($try_finger)
358
359     AC_MSG_CHECKING([whether generic object key fetching support is requested])
360     AC_ARG_ENABLE(generic,
361       AC_HELP_STRING([--disable-generic],
362         [disable generic object key fetching interface only]),
363       try_generic=$enableval, try_generic=yes)
364     AC_MSG_RESULT($try_generic)
365
366     AC_MSG_CHECKING([whether email keyserver support is requested])
367     AC_ARG_ENABLE(mailto,
368       AC_HELP_STRING([--enable-mailto],
369         [enable email keyserver interface only]),
370       try_mailto=$enableval, try_mailto=no)
371     AC_MSG_RESULT($try_mailto)
372   fi
373
374   AC_MSG_CHECKING([whether keyserver exec-path is enabled])
375   AC_ARG_ENABLE(keyserver-path,
376     AC_HELP_STRING([--disable-keyserver-path],
377       [disable the exec-path option for keyserver helpers]),
378     [if test "$enableval" = no ; then
379        disable_keyserver_path=yes
380     fi],enableval=yes)
381   AC_MSG_RESULT($enableval)
382 fi
383
384 AC_MSG_CHECKING([whether the included zlib is requested])
385 AC_ARG_WITH(included-zlib,
386     AC_HELP_STRING([--with-included-zlib],[use the zlib code included here]),
387 [g10_force_zlib="$withval"], [g10_force_zlib=no] )
388 AC_MSG_RESULT($g10_force_zlib)
389
390 dnl
391 dnl Check for the key/uid cache size.  This can't be zero, but can be
392 dnl pretty small on embedded systems.
393 dnl
394 AC_MSG_CHECKING([for the size of the key and uid cache])
395 AC_ARG_ENABLE(key-cache,
396         AC_HELP_STRING([--enable-key-cache=SIZE],[Set key cache to SIZE (default 4096)]),,enableval=4096)
397
398 if test "$enableval" = "no"; then
399    enableval=5
400 elif test "$enableval" = "yes" || test "$enableval" = ""; then
401    enableval=4096
402 fi
403
404 changequote(,)dnl
405 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
406 changequote([,])dnl
407
408 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
409    AC_MSG_ERROR([invalid key-cache size])
410 fi
411
412 AC_MSG_RESULT($key_cache_size)
413 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,[Size of the key and UID caches])
414
415 dnl
416 dnl Check whether we want to use Linux capabilities
417 dnl
418 AC_MSG_CHECKING([whether use of capabilities is requested])
419 AC_ARG_WITH(capabilities,
420     AC_HELP_STRING([--with-capabilities],
421                    [use linux capabilities [default=no]]),
422 [use_capabilities="$withval"],[use_capabilities=no])
423 AC_MSG_RESULT($use_capabilities)
424
425 # To avoid double inclusion of config.h which might happen at some
426 # places, we add the usual double inclusion protection.
427 AH_TOP([
428 #ifndef GNUPG_CONFIG_H_INCLUDED
429 #define GNUPG_CONFIG_H_INCLUDED
430 ])
431
432 AH_BOTTOM([
433 /* We didn't define endianness above, so get it from OS macros.  This
434 is intended for making fat binary builds on OS X. */
435 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
436 # if defined(__BIG_ENDIAN__)
437 #  define BIG_ENDIAN_HOST 1
438 # elif defined(__LITTLE_ENDIAN__)
439 #  define LITTLE_ENDIAN_HOST 1
440 # else
441 #  error "No endianness found"
442 # endif
443 #endif
444
445 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
446 # define EXEC_TEMPFILE_ONLY
447 #endif
448
449 /* A macro to help checking the GCC version.  */
450 #ifdef __GNUC__
451 # define GNUPG_GCC_VERSION (__GNUC__ * 10000       \
452                             + __GNUC_MINOR__ * 100 \
453                             + __GNUC_PATCHLEVEL__)
454 #endif /*__GNUC__*/
455
456 /* Please note that the string version must not contain more
457    than one character because the using code assumes strlen()==1 */
458 #ifdef HAVE_DOSISH_SYSTEM
459 # define DIRSEP_C '\\'
460 # define EXTSEP_C '.'
461 # define DIRSEP_S "\\"
462 # define EXTSEP_S "."
463 # define PATHSEP_C ';'
464 # define PATHSEP_S ";"
465 #else
466 # define DIRSEP_C '/'
467 # define EXTSEP_C '.'
468 # define DIRSEP_S "/"
469 # define EXTSEP_S "."
470 # define PATHSEP_C ':'
471 # define PATHSEP_S ":"
472 #endif
473
474 #ifdef __VMS
475 # define GNUPG_BAK_SFX "_bak"
476 # define GNUPG_TMP_SFX "_tmp"
477 #else /*!def __VMS */
478 # define GNUPG_BAK_SFX "~"
479 # define GNUPG_TMP_SFX EXTSEP_S "tmp"
480 #endif /* def __VMS [else] */
481
482
483 /* For some OSes we need to use fixed strings for certain directories.  */
484 #ifdef HAVE_DRIVE_LETTERS
485 # define LOCALEDIR         "c:\\\\lib\\\\gnupg\\\\locale"
486 # define GNUPG_LIBDIR      "c:\\\\lib\\\\gnupg"
487 # define GNUPG_LIBEXECDIR  "c:\\\\lib\\\\gnupg"
488 # define GNUPG_DATADIR     "c:\\\\lib\\\\gnupg"
489 # define GNUPG_HOMEDIR     "c:\\\\gnupg"
490 #else
491 # ifdef __VMS
492 #  define GNUPG_DATADIR     "/SYS$MANAGER/gnupg_share"
493 #  define GNUPG_HOMEDIR     "/SYS$LOGIN/gnupg"
494 #  define GNUPG_LIBDIR      "/SYS$MANAGER/gnupg_share"
495 #  define GNUPG_LIBEXECDIR  ""
496 # else
497 #  define GNUPG_HOMEDIR "~/.gnupg"
498 # endif
499 #endif
500
501 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
502    ldap_start_tls_s because that is the actual symbol used in the
503    library.  winldap.h redefines it to our commonly used value,
504    thus we define our usual macro here.  */
505 #ifdef HAVE_LDAP_START_TLS_SA
506 # ifndef HAVE_LDAP_START_TLS_S
507 #  define HAVE_LDAP_START_TLS_S 1
508 # endif
509 #endif
510
511 /* This is the major version number of GnuPG so that
512    source included files can test for this. */
513 #define GNUPG_MAJOR_VERSION 1
514
515 /* This is the same as VERSION, but should be overridden if the
516    platform cannot handle things like dots'.' in filenames.  Set
517    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
518    uses for dots and dashes. */
519 #define SAFE_VERSION      VERSION
520 #define SAFE_VERSION_DOT  '.'
521 #define SAFE_VERSION_DASH '-'
522
523 /* We want to use our memory allocator for estream-printf.  */
524 #define _ESTREAM_PRINTF_MALLOC        xtrymalloc
525 #define _ESTREAM_PRINTF_FREE          xfree
526 #define _ESTREAM_PRINTF_EXTRA_INCLUDE "memory.h"
527
528 #endif /*GNUPG_CONFIG_H_INCLUDED*/
529 ])
530
531 AM_MAINTAINER_MODE
532
533 dnl Checks for programs.
534
535 AC_PROG_MAKE_SET
536 AM_SANITY_CHECK
537 missing_dir=`cd $ac_aux_dir && pwd`
538 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
539 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
540 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
541 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
542 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
543 AC_PROG_CC
544 AM_PROG_CC_C_O
545 AC_PROG_CPP
546 AC_PROG_RANLIB
547 AC_CHECK_TOOL(AR, ar, :)
548 AC_PATH_PROG(PERL,"perl")
549 AC_ISC_POSIX
550 AC_SYS_LARGEFILE
551 AC_PROG_INSTALL
552 AC_PROG_AWK
553 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
554 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
555 GNUPG_CHECK_USTAR
556
557
558 # According to a comment by Marcus Brinkman in libgpg-error, the
559 # AC_PROG_CC_FOR_BUILD macro in the AC archive is broken for autoconf
560 # 2.57.  Thus we use a simply use "cc" if we are cross-compiling.
561 AC_MSG_CHECKING(for cc for build)
562 if test "$cross_compiling" = "yes"; then
563   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
564 else
565   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
566 fi
567 AC_MSG_RESULT($CC_FOR_BUILD)
568 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
569
570
571
572 MPI_OPT_FLAGS=""
573
574 have_dosish_system=no
575 need_dlopen=yes
576 case "${host}" in
577     *-mingw32*)
578         # special stuff for Windoze NT
579         ac_cv_have_dev_random=no
580         AC_DEFINE(USE_ONLY_8DOT3,1,
581                   [set this to limit filenames to the 8.3 format])
582         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
583                   [defined if we must run on a stupid file system])
584         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
585                   [because the Unix gettext has too much overhead on
586                    MingW32 systems and these systems lack Posix functions,
587                    we use a simplified version of gettext])
588         AC_DEFINE(HAVE_W32_SYSTEM,1,
589                   [Defined if we run on a W32 API based system])
590         disable_keyserver_path=yes
591         have_dosish_system=yes
592         need_dlopen=no
593         try_gettext="no"
594         agent_support=no
595         use_simple_gettext=yes
596         have_w32_system=yes
597         ;;
598     i?86-emx-os2 | i?86-*-os2*emx )
599         # OS/2 with the EMX environment
600         ac_cv_have_dev_random=no
601         AC_DEFINE(HAVE_DRIVE_LETTERS)
602         have_dosish_system=yes
603         try_gettext="no"
604         agent_support=no
605         ;;
606
607     i?86-*-msdosdjgpp*)
608         # DOS with the DJGPP environment
609         ac_cv_have_dev_random=no
610         AC_DEFINE(HAVE_DRIVE_LETTERS)
611         have_dosish_system=yes
612         try_gettext="no"
613         agent_support=no
614         ;;
615
616     *-*-hpux*)
617         if test -z "$GCC" ; then
618             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
619         fi
620         ;;
621     *-dec-osf4*)
622         if test -z "$GCC" ; then
623             # Suppress all warnings
624             # to get rid of the unsigned/signed char mismatch warnings.
625             CFLAGS="$CFLAGS -w"
626         fi
627         ;;
628     *-dec-osf5*)
629         if test -z "$GCC" ; then
630             # Use the newer compiler `-msg_disable ptrmismatch1' to
631             # get rid of the unsigned/signed char mismatch warnings.
632             # Using this may hide other pointer mismatch warnings, but
633             # it at least lets other warning classes through
634             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
635         fi
636         ;;
637     m68k-atari-mint)
638         ;;
639     *)
640        ;;
641 esac
642
643 if test "$have_dosish_system" = yes; then
644    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
645              [defined if we run on some of the PCDOS like systems
646               (DOS, Windoze. OS/2) with special properties like
647               no file modes])
648 fi
649 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
650
651 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
652 AM_CONDITIONAL(HAVE_W32_SYSTEM, test x"$have_w32_system" = xyes)
653
654 if test "$disable_keyserver_path" = yes; then
655     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
656               [define to disable exec-path for keyserver helpers])
657 fi
658
659 AC_SUBST(MPI_OPT_FLAGS)
660 GNUPG_SYS_SYMBOL_UNDERSCORE
661
662 dnl These need to go after AC_PROG_CC so that $EXEEXT is defined
663
664 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
665
666 if test x"$try_hkp" = xyes ; then
667   AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
668 fi
669
670 if test x"$try_finger" = xyes ; then
671   AC_SUBST(GPGKEYS_FINGER,"gpgkeys_finger$EXEEXT")
672 fi
673
674 dnl Must check for network library requirements before doing link tests
675 dnl for ldap, for example. If ldap libs are static (or dynamic and without
676 dnl ELF runtime link paths), then link will fail and LDAP support won't
677 dnl be detected.
678
679 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
680         [NETLIBS="-lnsl $NETLIBS"]))
681 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
682         [NETLIBS="-lsocket $NETLIBS"]))
683
684 dnl Now try for the resolver functions so we can use DNS for SRV, PKA,
685 dnl and CERT.
686
687 if test x"$try_dns" = xyes ; then
688    if test x"$try_hkp" = xyes || test x"$try_http" = xyes ; then
689       AC_ARG_ENABLE(dns-srv,
690          AC_HELP_STRING([--disable-dns-srv],
691         [disable the use of DNS SRV in HKP and HTTP]),
692          use_dns_srv=$enableval,use_dns_srv=yes)
693    fi
694
695    AC_ARG_ENABLE(dns-pka,
696       AC_HELP_STRING([--disable-dns-pka],
697         [disable the use of PKA records in DNS]),
698       use_dns_pka=$enableval,use_dns_pka=yes)
699
700    AC_ARG_ENABLE(dns-cert,
701       AC_HELP_STRING([--disable-dns-cert],
702         [disable the use of CERT records in DNS]),
703       use_dns_cert=$enableval,use_dns_cert=yes)
704 fi
705
706 if test x"$use_dns_pka" = xyes || test x"$use_dns_srv" = xyes || test x"$use_dns_cert" = xyes; then
707   _dns_save_libs=$LIBS
708   LIBS=""
709   # the double underscore thing is a glibc-ism?
710   AC_SEARCH_LIBS(res_query,resolv bind socket,,
711             AC_SEARCH_LIBS(__res_query,resolv bind socket,,have_resolver=no))
712   AC_SEARCH_LIBS(dn_expand,resolv bind socket,,
713             AC_SEARCH_LIBS(__dn_expand,resolv bind socket,,have_resolver=no))
714   AC_SEARCH_LIBS(dn_skipname,resolv bind socket,,
715             AC_SEARCH_LIBS(__dn_skipname,resolv bind socket,,have_resolver=no))
716
717   if test x"$have_resolver" != xno ; then
718
719     # Make sure that the BIND 4 resolver interface is workable before
720     # enabling any code that calls it.  At some point I'll rewrite the
721     # code to use the BIND 8 resolver API.
722
723     AC_MSG_CHECKING([whether the resolver is usable])
724     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
725 #include <netinet/in.h>
726 #include <arpa/nameser.h>
727 #include <resolv.h>]],
728 [[unsigned char answer[PACKETSZ]; res_query("foo.bar",C_IN,T_A,answer,PACKETSZ); dn_skipname(0,0); dn_expand(0,0,0,0,0);]])],have_resolver=yes,have_resolver=no)
729     AC_MSG_RESULT($have_resolver)
730
731     # This is Apple-specific and somewhat bizarre as they changed the
732     # define in bind 8 for some reason.
733
734     if test x"$have_resolver" != xyes ; then
735        AC_MSG_CHECKING([whether I can make the resolver usable with BIND_8_COMPAT])
736        AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
737 #include <sys/types.h>
738 #include <netinet/in.h>
739 #include <arpa/nameser.h>
740 #include <resolv.h>]],
741 [[unsigned char answer[PACKETSZ]; res_query("foo.bar",C_IN,T_A,answer,PACKETSZ); dn_skipname(0,0); dn_expand(0,0,0,0,0);]])],[have_resolver=yes ; need_compat=yes])
742        AC_MSG_RESULT($have_resolver)
743     fi
744   fi
745
746   if test x"$have_resolver" = xyes ; then
747      DNSLIBS=$LIBS
748
749      if test x"$use_dns_srv" = xyes ; then
750         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
751      fi
752
753      if test x"$use_dns_pka" = xyes ; then
754         AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
755      fi
756
757      if test x"$use_dns_cert" = xyes ; then
758         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
759      fi
760
761      if test x"$need_compat" = xyes ; then
762         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
763      fi
764   else
765      use_dns_srv=no
766      use_dns_pka=no
767      use_dns_cert=no
768   fi
769
770   LIBS=$_dns_save_libs
771 fi
772
773 AC_SUBST(DNSLIBS)
774
775 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
776
777 # Check for LDAP
778
779 if test "$try_ldap" = yes ; then
780    GNUPG_CHECK_LDAP($NETLIBS)
781 fi
782
783 # Check for curl.  We fake the curl API if libcurl isn't installed.
784 # We require 7.10 or better as we use curl_version_info().
785
786 LIBCURL_CHECK_CONFIG([yes],[7.10],,[fake_curl=yes])
787 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
788
789 # Generic, for us, means curl
790
791 if test x"$try_generic" = xyes ; then
792    AC_SUBST(GPGKEYS_CURL,"gpgkeys_curl$EXEEXT")
793 fi
794
795 dnl This isn't necessarily sendmail itself, but anything that gives a
796 dnl sendmail-ish interface to the outside world.  That includes qmail,
797 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
798
799 if test "$try_mailto" = yes ; then
800   AC_ARG_WITH(mailprog,
801      AC_HELP_STRING([--with-mailprog=NAME],
802                     [use "NAME -t" for mail transport]),,with_mailprog=yes)
803
804   if test "$with_mailprog" = yes ; then
805     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
806     if test "$ac_cv_path_SENDMAIL" ; then
807       GPGKEYS_MAILTO="gpgkeys_mailto"
808     fi
809   elif test "$with_mailprog" != no ; then
810     AC_MSG_CHECKING([for a mail transport program])
811     AC_SUBST(SENDMAIL,$with_mailprog)
812     AC_MSG_RESULT($with_mailprog)
813     GPGKEYS_MAILTO="gpgkeys_mailto"
814   fi
815 fi
816
817 AC_SUBST(GPGKEYS_MAILTO)
818
819 case "${host}" in
820     *-mingw32*)
821         PRINTABLE_OS_NAME="MingW32"
822         ;;
823     *-*-cygwin*)
824         PRINTABLE_OS_NAME="Cygwin"
825         ;;
826     i?86-emx-os2 | i?86-*-os2*emx )
827         PRINTABLE_OS_NAME="OS/2"
828         ;;
829     i?86-*-msdosdjgpp*)
830         PRINTABLE_OS_NAME="MSDOS/DJGPP"
831         try_extensions=no
832         ;;
833     *-linux*)
834         PRINTABLE_OS_NAME="GNU/Linux"
835         ;;
836     *)
837         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
838         ;;
839 esac
840 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
841                    [A human readable text with the name of the OS])
842
843
844 #
845 # 1. Set names of random devices
846 #
847 NAME_OF_DEV_RANDOM="/dev/random"
848 NAME_OF_DEV_URANDOM="/dev/urandom"
849 case "${host}" in
850     *-openbsd*)
851         NAME_OF_DEV_RANDOM="/dev/srandom"
852         NAME_OF_DEV_URANDOM="/dev/urandom"
853         ;;
854 esac
855 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM",
856                    [defined to the name of the strong random device])
857 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM",
858                    [defined to the name of the weaker random device])
859 AC_SUBST(MPI_OPT_FLAGS)
860
861
862 dnl Checks for libraries.
863
864 AM_PO_SUBDIRS
865 AM_GNU_GETTEXT_VERSION([0.16.1])
866 if test "$try_gettext" = yes; then
867   AM_GNU_GETTEXT(,[need-ngettext])
868   # gettext requires some extra checks.  These really should be part of
869   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
870   # function checks to here.
871   AC_CHECK_FUNCS(strchr)
872 else
873   enable_nls=no
874   USE_NLS=no
875   USE_INCLUDED_LIBINTL=no
876   BUILD_INCLUDED_LIBINTL=no
877   POSUB=po
878   AC_SUBST(USE_NLS)
879   AC_SUBST(USE_INCLUDED_LIBINTL)
880   AC_SUBST(BUILD_INCLUDED_LIBINTL)
881   AC_SUBST(POSUB)
882 fi
883
884
885 if test "$try_extensions" = yes || test x"$card_support" = xyes ; then
886   if test "$need_dlopen" = yes; then
887     _dl_save_libs=$LIBS
888     LIBS=""
889     AC_SEARCH_LIBS(dlopen,dl,found_dlopen=yes)
890     if test x"$found_dlopen" = "xyes" ; then
891       AC_DEFINE(HAVE_DL_DLOPEN,1,
892                 [Defined when the dlopen function family is available])
893       DLLIBS=$LIBS
894     else
895       if test "$try_extensions" = yes ; then
896          AC_MSG_NOTICE([dlopen not found.  Disabling extensions.])
897          try_extensions=no
898       fi
899
900       if test "$card_support" = yes ; then
901          AC_MSG_WARN([dlopen not found.  Disabling OpenPGP card support.])
902          card_support=no
903       fi
904     fi
905     LIBS=$_dl_save_libs
906   fi
907 fi
908
909 AC_SUBST(DLLIBS)
910
911 if test "$card_support" = yes ; then
912   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include OpenPGP card support])
913 fi
914
915 if test "$agent_support" = yes ; then
916   AC_DEFINE(ENABLE_AGENT_SUPPORT,1,[Define to include gpg-agent support])
917 fi
918
919 if test "$try_extensions" = yes ; then
920   AC_DEFINE(USE_DYNAMIC_LINKING,1,[Define to enable the use of extensions])
921 fi
922
923 if test "$selinux_support" = yes ; then
924   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
925 fi
926
927 if test "$gnupg_use_iconv" = yes ; then
928   AC_DEFINE(USE_GNUPG_ICONV,1,[Define to use the new iconv based code])
929 fi
930
931 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
932 AM_CONDITIONAL(ENABLE_AGENT_SUPPORT, test "$agent_support" = yes)
933
934 dnl Checks for header files.
935 AC_HEADER_STDC
936 AC_CHECK_HEADERS([unistd.h langinfo.h termio.h locale.h getopt.h pwd.h \
937                   signal.h])
938
939 # Note that we do not check for iconv here because this is done anyway
940 # by the gettext checks and thus it allows us to disable the use of
941 # iconv by using --disable-nls.
942
943 dnl Checks for typedefs, structures, and compiler characteristics.
944 AC_C_CONST
945 AC_C_INLINE
946 AC_C_VOLATILE
947 AC_TYPE_SIZE_T
948 AC_TYPE_MODE_T
949 AC_TYPE_SIGNAL
950 AC_DECL_SYS_SIGLIST
951
952 AC_ARG_ENABLE(endian-check,
953               AC_HELP_STRING([--disable-endian-check],
954               [disable the endian check and trust the OS provided macros]),
955               endiancheck=$enableval,endiancheck=yes)
956
957 if test x"$endiancheck" = xyes ; then
958    GNUPG_CHECK_ENDIAN
959 fi
960
961 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
962 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
963 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
964 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
965 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
966
967 AC_CHECK_SIZEOF(unsigned short)
968 AC_CHECK_SIZEOF(unsigned int)
969 AC_CHECK_SIZEOF(unsigned long)
970 AC_CHECK_SIZEOF(unsigned long long)
971 AC_HEADER_TIME
972 AC_CHECK_SIZEOF(time_t,,[[
973 #include <stdio.h>
974 #if TIME_WITH_SYS_TIME
975 # include <sys/time.h>
976 # include <time.h>
977 #else
978 # if HAVE_SYS_TIME_H
979 #  include <sys/time.h>
980 # else
981 #  include <time.h>
982 # endif
983 #endif
984 ]])
985 GNUPG_TIME_T_UNSIGNED
986
987 # Ensure that we have UINT64_C before we bother to check for uint64_t
988 AC_CHECK_HEADERS([inttypes.h])
989 AC_CACHE_CHECK([for UINT64_C], [gnupg_cv_uint64_c_works],
990                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <inttypes.h>]],[[
991 uint64_t foo=UINT64_C(42);]])],gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
992
993 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
994    AC_CHECK_SIZEOF(uint64_t)
995 fi
996
997 if test "$ac_cv_sizeof_unsigned_short" = "0" \
998    || test "$ac_cv_sizeof_unsigned_int" = "0" \
999    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1000     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1001 fi
1002
1003 dnl Do we have any 64-bit data types?
1004 if test x"$use_sha512" = xyes \
1005    && test "$ac_cv_sizeof_unsigned_int" != "8" \
1006    && test "$ac_cv_sizeof_unsigned_long" != "8" \
1007    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
1008    && test x"$ac_cv_sizeof_uint64_t" != "x8"; then
1009     AC_MSG_NOTICE([No 64-bit types.  Disabling SHA-384 and SHA-512.])
1010     use_sha512=no
1011 fi
1012
1013 if test x"$use_sha512" = xyes ; then
1014     AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
1015 fi
1016
1017 AM_CONDITIONAL(USE_SHA512, test x"$use_sha512" = xyes)
1018
1019 dnl Checks for library functions.
1020 AC_CHECK_DECLS(getpagesize)
1021 AC_FUNC_FSEEKO
1022 AC_FUNC_VPRINTF
1023 AC_FUNC_FORK
1024 AC_CHECK_FUNCS(strerror stpcpy strlwr tcgetattr strtoul mmap sysconf)
1025 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times unsetenv getpwnam getpwuid)
1026 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
1027 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
1028 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat getaddrinfo)
1029 AC_CHECK_FUNCS(fcntl ftruncate)
1030 AC_REPLACE_FUNCS(mkdtemp timegm isascii memrchr strsep)
1031
1032 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1033
1034 # See if getopt is in libiberty.  This is of course not optimal since
1035 # it might be somewhere other than libiberty, but does cover the
1036 # mingw32 case.
1037
1038 AC_CHECK_FUNC(getopt,,AC_CHECK_LIB(iberty,getopt,AC_SUBST(GETOPT,"-liberty")))
1039
1040 #
1041 # check for gethrtime and run a testprogram to see whether
1042 # it is broken.  It has been reported that some Solaris and HP UX systems
1043 # raise an SIGILL
1044 #
1045 AC_CACHE_CHECK([for gethrtime],
1046                [gnupg_cv_func_gethrtime],
1047                [AC_TRY_LINK([#include <sys/times.h>],[
1048                    hrtime_t tv;
1049                    tv = gethrtime();
1050                  ],
1051                  [gnupg_cv_func_gethrtime=yes],
1052                  [gnupg_cv_func_gethrtime=no])
1053                ])
1054 if test $gnupg_cv_func_gethrtime = yes; then
1055      AC_DEFINE([HAVE_GETHRTIME], 1,
1056                [Define if you have the `gethrtime(2)' function.])
1057      AC_CACHE_CHECK([whether gethrtime is broken],
1058                [gnupg_cv_func_broken_gethrtime],
1059                [AC_TRY_RUN([
1060                    #include <sys/times.h>
1061                    int main () {
1062                    hrtime_t tv;
1063                    tv = gethrtime();
1064                  }
1065                  ],
1066                  [gnupg_cv_func_broken_gethrtime=no],
1067                  [gnupg_cv_func_broken_gethrtime=yes],
1068                  [gnupg_cv_func_broken_gethrtime=assume-no])
1069                 ])
1070     if test $gnupg_cv_func_broken_gethrtime = yes; then
1071       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
1072       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
1073     fi
1074 fi
1075
1076
1077 GNUPG_CHECK_MLOCK
1078 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1079
1080 #
1081 # Prepare building of estream-printf
1082 #
1083 estream_PRINTF_INIT
1084
1085
1086 dnl
1087 dnl Check whether we can use Linux capabilities as requested
1088 dnl
1089 if test "$use_capabilities" = "yes" ; then
1090
1091 AC_MSG_WARN([[
1092 ***
1093 *** WARNING: using capabilities with GnuPG is experimental code!
1094 ***]])
1095
1096 use_capabilities=no
1097 AC_CHECK_HEADERS(sys/capability.h)
1098 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
1099   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
1100   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
1101      AC_DEFINE(USE_CAPABILITIES,1,
1102                [define if capabilities should be used])
1103      AC_SUBST(CAPLIBS,"-lcap")
1104      use_capabilities=yes
1105   fi
1106 fi
1107 if test "$use_capabilities" = "no" ; then
1108     AC_MSG_WARN([[
1109 ***
1110 *** The use of capabilities on this system is not possible.
1111 *** You need a recent Linux kernel and some patches:
1112 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
1113 ***   fcap-module-990613.tar.gz     (kernel module)
1114 ***   libcap-1.92.tar.gz            (user mode library and utilities)
1115 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
1116 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
1117 ***]])
1118 fi
1119 fi
1120
1121
1122 GNUPG_CHECK_IPC
1123 if test "$ac_cv_header_sys_shm_h" = "yes"; then
1124   AC_DEFINE(USE_SHM_COPROCESSING,1,
1125             [define if the shared memory interface should be made available])
1126 fi
1127
1128 AM_CONDITIONAL(HAVE_SHM, test "$ac_cv_header_sys_shm_h" = yes)
1129
1130 dnl
1131 dnl check whether we have a random device
1132 dnl
1133 if test "$try_dev_random" = yes ; then
1134     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
1135     [if test -r "$NAME_OF_DEV_RANDOM" && test -r "$NAME_OF_DEV_URANDOM" ; then
1136       ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
1137     if test "$ac_cv_have_dev_random" = yes; then
1138         AC_DEFINE(HAVE_DEV_RANDOM,1,
1139                  [defined if the system supports a random device] )
1140     fi
1141 else
1142     AC_MSG_CHECKING(for random device)
1143     ac_cv_have_dev_random=no
1144     AC_MSG_RESULT(has been disabled)
1145 fi
1146
1147
1148 dnl
1149 dnl Figure out the default random module.
1150 dnl
1151 random_modules=""
1152 if test "$use_static_rnd" = default; then
1153      if test "$ac_cv_have_dev_random" = yes; then
1154         random_modules="rndlinux"
1155      else
1156          case "${host}" in
1157             *-mingw32*|*-*-cygwin*)
1158                 random_modules="rndw32"
1159                 ;;
1160             i?86-emx-os2|i?86-*-os2*emx)
1161                 random_modules="rndos2"
1162                 ;;
1163             m68k-atari-mint)
1164                 random_modules="rndatari"
1165                 ;;
1166             i?86-*-msdosdjgpp*)
1167                 :
1168                 ;;
1169             *)
1170                 random_modules="rndlinux rndegd rndunix"
1171                 AC_DEFINE(USE_ALL_RANDOM_MODULES, 1,
1172                           [Allow to select random modules at runtime.])
1173                 ;;
1174          esac
1175      fi
1176 else
1177   if test "$use_static_rnd" = auto; then
1178      random_modules="rndlinux rndegd rndunix"
1179      AC_DEFINE(USE_ALL_RANDOM_MODULES, 1)
1180   else
1181      random_modules="rnd$use_static_rnd";
1182   fi
1183 fi
1184
1185 if test -z "$random_modules"; then
1186    AC_MSG_ERROR(no random module available)
1187 fi
1188 print_egd_warning=no
1189 for rndmod in $random_modules "" ; do
1190   case "$rndmod" in
1191     rndlinux)
1192          AC_DEFINE(USE_RNDLINUX,1,
1193                   [Defined if the /dev/random based RNG should be used.])
1194          use_rndlinux=yes
1195          ;;
1196     rndunix)
1197          AC_DEFINE(USE_RNDUNIX,1,
1198                   [Defined if the default Unix RNG should be used.])
1199          print_egd_warning=yes
1200          use_rndunix=yes
1201           ;;
1202     rndegd)
1203          AC_DEFINE(USE_RNDEGD,1,
1204                   [Defined if the EGD based RNG should be used.])
1205          use_rndegd=yes
1206          ;;
1207     rndw32)
1208          AC_DEFINE(USE_RNDW32,1,
1209                   [Defined if the Windows specific RNG should be used.])
1210          use_rndw32=yes
1211         ;;
1212    esac
1213 done
1214
1215 AM_CONDITIONAL(USE_RNDLINUX, test "$use_rndlinux" = yes)
1216 AM_CONDITIONAL(USE_RNDUNIX,  test "$use_rndunix" = yes)
1217 AM_CONDITIONAL(USE_RNDEGD,   test "$use_rndegd" = yes)
1218 AM_CONDITIONAL(USE_RNDW32,   test "$use_rndw32" = yes)
1219
1220 dnl setup assembler stuff
1221 AC_MSG_CHECKING(for mpi assembler functions)
1222 if test -f $srcdir/mpi/config.links ; then
1223     . $srcdir/mpi/config.links
1224     AC_CONFIG_LINKS("$mpi_ln_list")
1225     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
1226     ac_cv_mpi_sflags="$mpi_sflags"
1227     ac_cv_mpi_config_done="yes"
1228     AC_MSG_RESULT(done)
1229 else
1230     AC_MSG_RESULT(failed)
1231     AC_MSG_ERROR([mpi/config.links missing!])
1232 fi
1233 MPI_EXTRA_ASM_OBJS=""
1234 show_extraasm=""
1235 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
1236 for i in $ac_cv_mpi_extra_asm_modules; do
1237     show_extraasm="$show_extraasm $i"
1238     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
1239 done
1240 fi
1241 AC_SUBST(MPI_EXTRA_ASM_OBJS)
1242 MPI_SFLAGS="$ac_cv_mpi_sflags"
1243 AC_SUBST(MPI_SFLAGS)
1244
1245 # Sanity check regex.  Tests adapted from mutt.
1246
1247 AC_MSG_CHECKING([whether regular expression support is requested])
1248 AC_ARG_ENABLE(regex,
1249   AC_HELP_STRING([--disable-regex],
1250     [do not handle regular expressions in trust signatures]),
1251   use_regex=$enableval, use_regex=yes)
1252 AC_MSG_RESULT($use_regex)
1253
1254 if test "$use_regex" = yes ; then
1255   AC_MSG_CHECKING([whether the included regex lib is requested])
1256   AC_ARG_WITH(included-regex,
1257       AC_HELP_STRING([--with-included-regex],
1258                      [use the included GNU regex library]),
1259       [gnupg_cv_included_regex="$withval"],[gnupg_cv_included_regex=no])
1260   AC_MSG_RESULT($gnupg_cv_included_regex)
1261
1262   if test $gnupg_cv_included_regex = no ; then
1263      # Does the system have regex functions at all?
1264      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
1265                            gnupg_cv_included_regex=yes)
1266   fi
1267
1268   if test $gnupg_cv_included_regex = no ; then
1269      AC_CACHE_CHECK([whether your system's regexp library is broken],
1270        [gnupg_cv_regex_broken],
1271        AC_TRY_RUN([
1272 #include <unistd.h>
1273 #include <regex.h>
1274 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1275        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1276
1277      if test $gnupg_cv_regex_broken = yes ; then
1278       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
1279       gnupg_cv_included_regex=yes
1280      fi
1281   fi
1282
1283   if test $gnupg_cv_included_regex = yes; then
1284      AC_DEFINE(USE_INTERNAL_REGEX,1,[ Define if you want to use the included regex lib ])
1285   fi
1286 else
1287   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
1288 fi
1289
1290 AM_CONDITIONAL(USE_INTERNAL_REGEX, test x"$gnupg_cv_included_regex" = xyes)
1291
1292 dnl Do we have zlib? Must do it here because Solaris failed
1293 dnl when compiling a conftest (due to the "-lz" from LIBS).
1294 use_local_zlib=yes
1295 if test "$g10_force_zlib" = "yes"; then
1296   :
1297 else
1298   _cppflags="${CPPFLAGS}"
1299   _ldflags="${LDFLAGS}"
1300
1301   AC_ARG_WITH(zlib,
1302      AC_HELP_STRING([--with-zlib=DIR],[use libz in DIR]),[
1303     if test -d "$withval"; then
1304       CPPFLAGS="${CPPFLAGS} -I$withval/include"
1305       LDFLAGS="${LDFLAGS} -L$withval/lib"
1306     fi
1307   ])
1308
1309   AC_CHECK_HEADER(zlib.h,
1310       AC_CHECK_LIB(z, deflateInit2_,
1311        use_local_zlib=no
1312        ZLIBS="-lz",
1313        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1314        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1315 fi
1316
1317 if test "$use_local_zlib" = yes ; then
1318     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
1319     ZLIBS="../zlib/libzlib.a"
1320 fi
1321
1322 AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, test "$use_local_zlib" = yes)
1323
1324
1325 # Under W32 we force the use ofthe included bzip2 code.
1326 if test x"$have_w32_system" = xyes ; then
1327     have_bz2=yes
1328     AC_DEFINE(HAVE_BZIP2,1,
1329               [Defined if the bz2 compression library is available])
1330     AC_CONFIG_LINKS(bzlib.h:bzlib/bzlib.h)
1331     ZLIBS="$ZLIBS ../bzlib/libbz2.a"
1332 else
1333  if test "$use_bzip2" = yes ; then
1334   _cppflags="${CPPFLAGS}"
1335   _ldflags="${LDFLAGS}"
1336   AC_ARG_WITH(bzip2,
1337      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1338       [
1339       if test -d "$withval" ; then
1340         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1341         LDFLAGS="${LDFLAGS} -L$withval/lib"
1342       fi
1343       ],withval="")
1344
1345 # Checking alongside stdio.h as an early version of bzip2 (1.0)
1346 # required stdio.h to be included before bzlib.h, and Solaris 9 is
1347 # woefully out of date.
1348
1349   if test "$withval" != no ; then
1350      AC_CHECK_HEADER(bzlib.h,
1351         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1352           [
1353           have_bz2=yes
1354           ZLIBS="$ZLIBS -lbz2"
1355           AC_DEFINE(HAVE_BZIP2,1)
1356           ],
1357           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1358           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1359   fi
1360  fi
1361 fi
1362
1363 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1364 AC_SUBST(ZLIBS)
1365
1366 # libusb allows us to use the integrated CCID smartcard reader driver.
1367 # We don't need it if we don't have card support though.
1368 if test "$card_support" = yes ; then
1369    GNUPG_CHECK_LIBUSB
1370 fi
1371
1372 # Check for readline support
1373 GNUPG_CHECK_READLINE
1374
1375 # Allow users to append something to the version string without
1376 # flagging it as development version.  The user version parts is
1377 # considered everything after a dash.
1378 if test "$development_version" != yes; then
1379   changequote(,)dnl
1380   tmp_pat='[a-zA-Z]'
1381   changequote([,])dnl
1382   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1383     development_version=yes
1384   fi
1385 fi
1386 if test "$development_version" = yes; then
1387     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1388             [Defined if this is not a regular release])
1389 fi
1390
1391 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1392
1393
1394 # add some extra libs here so that previous tests don't fail for
1395 # mysterious reasons - the final link step should bail out.
1396 case "${host}" in
1397     *-mingw32*)
1398 dnl      NETLIBS="$NETLIBS -lwsock32"
1399         W32LIBS="-lwsock32"
1400         ;;
1401     *)
1402        ;;
1403 esac
1404
1405 AC_SUBST(NETLIBS)
1406 AC_SUBST(W32LIBS)
1407
1408 # Special options used with gcc.
1409 if test "$GCC" = yes; then
1410     # Note that it is okay to use CFLAGS here because this are just
1411     # warning options and the user should have a chance of overriding
1412     #them.
1413     if test "$USE_MAINTAINER_MODE" = "yes"; then
1414         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1415         CFLAGS="$CFLAGS -Wformat-nonliteral"
1416     else
1417         CFLAGS="$CFLAGS -Wall"
1418     fi
1419
1420     # This is handy for debugging so the compiler doesn't rearrange
1421     # things and eliminate variables.
1422     AC_ARG_ENABLE(optimization,
1423        AC_HELP_STRING([--disable-optimization],
1424                       [disable compiler optimization]),
1425                       [if test $enableval = no ; then
1426                          CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]]//'`
1427                        fi])
1428
1429     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1430
1431     _gcc_cflags_save=$CFLAGS
1432     CFLAGS="-Wno-pointer-sign"
1433
1434     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],_gcc_psign=yes,_gcc_psign=no)
1435     AC_MSG_RESULT($_gcc_psign)
1436
1437     CFLAGS=$_gcc_cflags_save;
1438
1439     if test x"$_gcc_psign" = xyes ; then
1440        CFLAGS="$CFLAGS -Wno-pointer-sign"
1441     fi
1442 fi
1443
1444 CL_AS_NOEXECSTACK
1445
1446 if test "$print_egd_warning" = yes; then
1447   AC_MSG_WARN([[
1448 ***
1449 *** The performance of the UNIX random gatherer module is not very good
1450 *** and it does not keep the entropy pool over multiple invocations of
1451 *** GnuPG.  The suggested way to overcome this problem is to use the
1452 ***
1453 ***               Entropy Gathering Daemon (EGD)
1454 ***
1455 *** which provides a entropy source for the whole system.  It is written
1456 *** in Perl and available at the GnuPG FTP servers.  For more information
1457 *** consult the GnuPG webpages:
1458 ***
1459 ***           http://www.gnupg.org/download/#EGD
1460 ***
1461 *** You may want to run ./configure with --enable-static-rnd=egd or
1462 *** --enable-static-rnd=auto to use it.
1463 ***]])
1464 fi
1465
1466 AC_CONFIG_FILES([
1467 Makefile
1468 m4/Makefile
1469 intl/Makefile
1470 po/Makefile.in
1471 util/Makefile
1472 mpi/Makefile
1473 cipher/Makefile
1474 g10/Makefile
1475 keyserver/Makefile
1476 keyserver/gpgkeys_mailto
1477 keyserver/gpgkeys_test
1478 doc/Makefile
1479 tools/Makefile
1480 tools/gpg-zip
1481 zlib/Makefile
1482 bzlib/Makefile
1483 checks/Makefile
1484 ])
1485 AC_OUTPUT
1486
1487 # Give some feedback
1488 echo
1489 echo   "                Version info:   $PACKAGE_STRING"
1490 echo   "                Configured for: $PRINTABLE_OS_NAME ($host)"
1491 if test -n "$show_extraasm"; then
1492   echo "  Extra cpu specific functions:$show_extraasm"
1493 fi
1494 echo