ssh: Rewrite a function for better maintainability
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.0
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005,
3 #               2006, 2007, 2008, 2010, 2011,
4 #               2012 Free Software Foundation, Inc.
5 #
6 # This file is part of GnuPG.
7 #
8 # GnuPG is free software; you can redistribute it and/or modify
9 # it under the terms of the GNU General Public License as published by
10 # the Free Software Foundation; either version 3 of the License, or
11 # (at your option) any later version.
12 #
13 # GnuPG is distributed in the hope that it will be useful,
14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 # GNU General Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, see <http://www.gnu.org/licenses/>.
20
21 # Process this file with autoconf to produce a configure script.
22 AC_PREREQ(2.61)
23 min_automake_version="1.10"
24
25 # To build a release you need to create a tag with the version number
26 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
27 # bump the version number immediately *after* the release and do
28 # another commit and push so that the git magic is able to work.
29 m4_define([mym4_version], [2.0.21])
30
31 # Below is m4 magic to extract and compute the git revision number,
32 # the decimalized short revision number, a beta version string and a
33 # flag indicating a development version (mym4_isgit).  Note that the
34 # m4 processing is done by autoconf and not during the configure run.
35 m4_define([mym4_revision],
36           m4_esyscmd([git rev-parse --short HEAD | tr -d '\n\r']))
37 m4_define([mym4_revision_dec],
38           m4_esyscmd_s([echo $((0x$(echo ]mym4_revision[|head -c 4)))]))
39 m4_define([mym4_betastring],
40           m4_esyscmd_s([git describe --match 'gnupg-2.[0-9].*[0-9]' --long|\
41                         awk -F- '$3!=0{print"-beta"$3}']))
42 m4_define([mym4_isgit],m4_if(mym4_betastring,[],[no],[yes]))
43 m4_define([mym4_full_version],[mym4_version[]mym4_betastring])
44
45 AC_INIT([gnupg],[mym4_full_version], [http://bugs.gnupg.org])
46
47 NEED_GPG_ERROR_VERSION=1.7
48
49 NEED_LIBGCRYPT_API=1
50 NEED_LIBGCRYPT_VERSION=1.4.0
51
52 NEED_LIBASSUAN_API=2
53 NEED_LIBASSUAN_VERSION=2.0.0
54
55 NEED_KSBA_API=1
56 NEED_KSBA_VERSION=1.0.7
57
58 development_version=mym4_isgit
59 PACKAGE=$PACKAGE_NAME
60 PACKAGE_GT=${PACKAGE_NAME}2
61 VERSION=$PACKAGE_VERSION
62
63 AC_CONFIG_AUX_DIR(scripts)
64 AC_CONFIG_SRCDIR(sm/gpgsm.c)
65 AM_CONFIG_HEADER(config.h)
66 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
67 AC_CANONICAL_HOST
68 AB_INIT
69
70 AC_GNU_SOURCE
71
72 # Some status variables.
73 have_gpg_error=no
74 have_libgcrypt=no
75 have_libassuan=no
76 have_ksba=no
77 have_pth=no
78 have_libusb=no
79 have_adns=no
80
81 use_bzip2=yes
82 use_exec=yes
83 disable_keyserver_path=no
84 use_ccid_driver=yes
85 use_standard_socket=no
86
87 GNUPG_BUILD_PROGRAM(gpg, yes)
88 GNUPG_BUILD_PROGRAM(gpgsm, yes)
89 GNUPG_BUILD_PROGRAM(agent, yes)
90 GNUPG_BUILD_PROGRAM(scdaemon, yes)
91 GNUPG_BUILD_PROGRAM(tools, yes)
92 GNUPG_BUILD_PROGRAM(doc, yes)
93 GNUPG_BUILD_PROGRAM(symcryptrun, no)
94 GNUPG_BUILD_PROGRAM(gpgtar, no)
95
96
97 AC_SUBST(PACKAGE)
98 AC_SUBST(PACKAGE_GT)
99 AC_SUBST(VERSION)
100 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
101 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
102                                 [Name of this package for gettext])
103 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
104 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
105                                         [Bug report address])
106 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
107                                        [Required version of Libgcrypt])
108 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
109                                        [Required version of Libksba])
110
111
112 # The default is to use the modules from this package and the few
113 # other packages in a standard place; i.e where this package gets
114 # installed.  With these options it is possible to override these
115 # ${prefix} depended values with fixed paths, which can't be replaced
116 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
117 AC_ARG_WITH(agent-pgm,
118     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
119           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
120 AC_SUBST(GNUPG_AGENT_PGM)
121 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
122 show_gnupg_agent_pgm="(default)"
123 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
124
125 AC_ARG_WITH(pinentry-pgm,
126     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
127           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
128 AC_SUBST(GNUPG_PINENTRY_PGM)
129 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
130 show_gnupg_pinentry_pgm="(default)"
131 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
132
133
134 AC_ARG_WITH(scdaemon-pgm,
135     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
136           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
137 AC_SUBST(GNUPG_SCDAEMON_PGM)
138 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
139 show_gnupg_scdaemon_pgm="(default)"
140 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
141
142
143 AC_ARG_WITH(dirmngr-pgm,
144     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
145           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
146 AC_SUBST(GNUPG_DIRMNGR_PGM)
147 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
148 show_gnupg_dirmngr_pgm="(default)"
149 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
150
151 AC_ARG_WITH(protect-tool-pgm,
152     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
153           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
154 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
155 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
156 show_gnupg_protect_tool_pgm="(default)"
157 test -n "$GNUPG_PROTECT_TOOL_PGM" \
158       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
159
160
161 # Some folks want to use only the agent from this packet.  Make it
162 # easier for them by providing the configure option
163 # --enable-only-agent.
164 AC_ARG_ENABLE(agent-only,
165     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
166     build_agent_only=$enableval)
167
168 # SELinux support includes tracking of sensitive files to avoid
169 # leaking their contents through processing these files by gpg itself
170 AC_MSG_CHECKING([whether SELinux support is requested])
171 AC_ARG_ENABLE(selinux-support,
172               AC_HELP_STRING([--enable-selinux-support],
173                              [enable SELinux support]),
174               selinux_support=$enableval, selinux_support=no)
175 AC_MSG_RESULT($selinux_support)
176
177 # Allow disabling of bzib2 support.
178 # It is defined only after we confirm the library is available later
179 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
180 AC_ARG_ENABLE(bzip2,
181    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
182    use_bzip2=$enableval)
183 AC_MSG_RESULT($use_bzip2)
184
185 # Configure option to allow or disallow execution of external
186 # programs, like a photo viewer.
187 AC_MSG_CHECKING([whether to enable external program execution])
188 AC_ARG_ENABLE(exec,
189     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
190     use_exec=$enableval)
191 AC_MSG_RESULT($use_exec)
192 if test "$use_exec" = no ; then
193     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
194 fi
195
196 if test "$use_exec" = yes ; then
197   AC_MSG_CHECKING([whether to enable photo ID viewing])
198   AC_ARG_ENABLE(photo-viewers,
199       [  --disable-photo-viewers disable photo ID viewers],
200       [if test "$enableval" = no ; then
201          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
202       fi],enableval=yes)
203   gnupg_cv_enable_photo_viewers=$enableval
204   AC_MSG_RESULT($enableval)
205
206   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
207     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
208     AC_ARG_WITH(photo-viewer,
209         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
210         [if test "$withval" = yes ; then
211            withval=no
212         elif test "$withval" != no ; then
213            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
214                             [if set, restrict photo-viewer to this])
215         fi],withval=no)
216     AC_MSG_RESULT($withval)
217   fi
218
219   AC_MSG_CHECKING([whether to enable external keyserver helpers])
220   AC_ARG_ENABLE(keyserver-helpers,
221       [  --disable-keyserver-helpers  disable all external keyserver support],
222       [if test "$enableval" = no ; then
223          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
224                   [define to disable keyserver helpers])
225       fi],enableval=yes)
226   gnupg_cv_enable_keyserver_helpers=$enableval
227   AC_MSG_RESULT($enableval)
228
229   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
230     # LDAP is defined only after we confirm the library is available later
231     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
232     AC_ARG_ENABLE(ldap,
233       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
234       try_ldap=$enableval, try_ldap=yes)
235     AC_MSG_RESULT($try_ldap)
236
237     AC_MSG_CHECKING([whether HKP keyserver support is requested])
238     AC_ARG_ENABLE(hkp,
239       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
240       try_hkp=$enableval, try_hkp=yes)
241     AC_MSG_RESULT($try_hkp)
242
243     AC_MSG_CHECKING([whether finger key fetching support is requested])
244     AC_ARG_ENABLE(finger,
245       AC_HELP_STRING([--disable-finger],
246         [disable finger key fetching interface only]),
247       try_finger=$enableval, try_finger=yes)
248     AC_MSG_RESULT($try_finger)
249
250     AC_MSG_CHECKING([whether generic object key fetching support is requested])
251     AC_ARG_ENABLE(generic,
252       AC_HELP_STRING([--disable-generic],
253         [disable generic object key fetching interface only]),
254       try_generic=$enableval, try_generic=yes)
255     AC_MSG_RESULT($try_generic)
256
257     AC_MSG_CHECKING([whether email keyserver support is requested])
258     AC_ARG_ENABLE(mailto,
259       AC_HELP_STRING([--enable-mailto],
260         [enable email keyserver interface only]),
261       try_mailto=$enableval, try_mailto=no)
262     AC_MSG_RESULT($try_mailto)
263   fi
264
265   AC_MSG_CHECKING([whether keyserver exec-path is enabled])
266   AC_ARG_ENABLE(keyserver-path,
267       AC_HELP_STRING([--disable-keyserver-path],
268            [disable the exec-path option for keyserver helpers]),
269            [if test "$enableval" = no ; then
270               disable_keyserver_path=yes
271            fi],enableval=yes)
272   AC_MSG_RESULT($enableval)
273 fi
274
275
276 #
277 # Check for the key/uid cache size.  This can't be zero, but can be
278 # pretty small on embedded systems.  This is used for the gpg part.
279 #
280 AC_MSG_CHECKING([for the size of the key and uid cache])
281 AC_ARG_ENABLE(key-cache,
282         AC_HELP_STRING([--enable-key-cache=SIZE],
283                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
284 if test "$enableval" = "no"; then
285    enableval=5
286 elif test "$enableval" = "yes" || test "$enableval" = ""; then
287    enableval=4096
288 fi
289 changequote(,)dnl
290 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
291 changequote([,])dnl
292 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
293    AC_MSG_ERROR([invalid key-cache size])
294 fi
295 AC_MSG_RESULT($key_cache_size)
296 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
297                   [Size of the key and UID caches])
298
299
300
301 #
302 # Check whether we want to use Linux capabilities
303 #
304 AC_MSG_CHECKING([whether use of capabilities is requested])
305 AC_ARG_WITH(capabilities,
306     [  --with-capabilities     use linux capabilities [default=no]],
307 [use_capabilities="$withval"],[use_capabilities=no])
308 AC_MSG_RESULT($use_capabilities)
309
310
311 #
312 # Allow disabling of internal CCID support.
313 # It is defined only after we confirm the library is available later
314 #
315 AC_MSG_CHECKING([whether to enable the internal CCID driver])
316 AC_ARG_ENABLE(ccid-driver,
317               AC_HELP_STRING([--disable-ccid-driver],
318                              [disable the internal CCID driver]),
319               use_ccid_driver=$enableval)
320 AC_MSG_RESULT($use_ccid_driver)
321
322
323 #
324 # To avoid double inclusion of config.h which might happen at some
325 # places, we add the usual double inclusion protection at the top of
326 # config.h.
327 #
328 AH_TOP([
329 #ifndef GNUPG_CONFIG_H_INCLUDED
330 #define GNUPG_CONFIG_H_INCLUDED
331 ])
332
333 #
334 # Stuff which goes at the bottom of config.h.
335 #
336 AH_BOTTOM([
337 /* This is the major version number of GnuPG so that
338    source included files can test for this.  Note, that
339    we use 2 here even for GnuPG 1.9.x. */
340 #define GNUPG_MAJOR_VERSION 2
341
342 /* Now to separate file name parts.
343    Please note that the string version must not contain more
344    than one character because the code assumes strlen()==1 */
345 #ifdef HAVE_DOSISH_SYSTEM
346 #define DIRSEP_C '\\'
347 #define DIRSEP_S "\\"
348 #define EXTSEP_C '.'
349 #define EXTSEP_S "."
350 #define PATHSEP_C ';'
351 #define PATHSEP_S ";"
352 #define EXEEXT_S ".exe"
353 #else
354 #define DIRSEP_C '/'
355 #define DIRSEP_S "/"
356 #define EXTSEP_C '.'
357 #define EXTSEP_S "."
358 #define PATHSEP_C ':'
359 #define PATHSEP_S ":"
360 #define EXEEXT_S ""
361 #endif
362
363 /* This is the same as VERSION, but should be overridden if the
364    platform cannot handle things like dots '.' in filenames. Set
365    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
366    uses for dots and dashes. */
367 #define SAFE_VERSION VERSION
368 #define SAFE_VERSION_DOT  '.'
369 #define SAFE_VERSION_DASH '-'
370
371 /* Some global constants. */
372 #ifdef HAVE_DRIVE_LETTERS
373 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
374 #elif defined(__VMS)
375 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg"
376 #else
377 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
378 #endif
379 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
380
381 /* For some systems (DOS currently), we hardcode the path here.  For
382    POSIX systems the values are constructed by the Makefiles, so that
383    the values may be overridden by the make invocations; this is to
384    comply with the GNU coding standards. */
385 #ifdef HAVE_DRIVE_LETTERS
386  /* FIXME: We need to use a function to determine these values depending
387     on the actual installation directory. */
388 #define GNUPG_BINDIR      "c:\\gnupg"
389 #define GNUPG_LIBEXECDIR  "c:\\gnupg"
390 #define GNUPG_LIBDIR      "c:\\gnupg"
391 #define GNUPG_DATADIR     "c:\\gnupg"
392 #define GNUPG_SYSCONFDIR  "c:\\gnupg"
393 #endif
394
395 /* Derive some other constants. */
396 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
397 #define EXEC_TEMPFILE_ONLY
398 #endif
399
400
401 /* We didn't define endianness above, so get it from OS macros.  This
402    is intended for making fat binary builds on OS X. */
403 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
404 #if defined(__BIG_ENDIAN__)
405 #define BIG_ENDIAN_HOST 1
406 #elif defined(__LITTLE_ENDIAN__)
407 #define LITTLE_ENDIAN_HOST 1
408 #else
409 #error "No endianness found"
410 #endif
411 #endif
412
413
414 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
415    ldap_start_tls_s because that is the actual symbol used in the
416    library.  winldap.h redefines it to our commonly used value,
417    thus we define our usual macro here.  */
418 #ifdef HAVE_LDAP_START_TLS_SA
419 # ifndef HAVE_LDAP_START_TLS_S
420 #  define HAVE_LDAP_START_TLS_S 1
421 # endif
422 #endif
423
424
425 /* Tell libgcrypt not to use its own libgpg-error implementation. */
426 #define USE_LIBGPG_ERROR 1
427
428 /* We use jnlib, so tell other modules about it.  */
429 #define HAVE_JNLIB_LOGGING 1
430
431 /* Our HTTP code is used in estream mode.  */
432 #define HTTP_USE_ESTREAM 1
433
434 /* Under W32 we do an explicit socket initialization, thus we need to
435    avoid the on-demand initialization which would also install an atexit
436    handler.  */
437 #define HTTP_NO_WSASTARTUP
438
439 /* We always include support for the OpenPGP card.  */
440 #define ENABLE_CARD_SUPPORT 1
441
442 /* We don't want the old assuan codes anymore. */
443 #define _ASSUAN_ONLY_GPG_ERRORS 1
444
445 /* We explicitly need to disable PTH's soft mapping as Debian
446    currently enables it by default for no reason. */
447 #define PTH_SYSCALL_SOFT 0
448
449 /* We want to use the libgcrypt provided memory allocation for
450    asprintf.  */
451 #define _ESTREAM_PRINTF_MALLOC        gcry_malloc
452 #define _ESTREAM_PRINTF_FREE          gcry_free
453 #define _ESTREAM_PRINTF_EXTRA_INCLUDE "util.h"
454
455 #endif /*GNUPG_CONFIG_H_INCLUDED*/
456 ])
457
458
459 AM_MAINTAINER_MODE
460
461 # Checks for programs.
462 AC_MSG_NOTICE([checking for programs])
463 AC_PROG_MAKE_SET
464 AM_SANITY_CHECK
465 missing_dir=`cd $ac_aux_dir && pwd`
466 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
467 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
468 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
469 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
470 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
471 AC_PROG_AWK
472 AC_PROG_CC
473 AC_PROG_CPP
474 AM_PROG_CC_C_O
475 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
476   AC_MSG_ERROR([[No C-89 compiler found]])
477 fi
478 AC_PROG_INSTALL
479 AC_PROG_LN_S
480 AC_PROG_RANLIB
481 AC_CHECK_TOOL(AR, ar, :)
482 AC_PATH_PROG(PERL,"perl")
483 AC_CHECK_TOOL(WINDRES, windres, :)
484 AC_ISC_POSIX
485 gl_EARLY
486 AC_SYS_LARGEFILE
487 GNUPG_CHECK_FAQPROG
488 GNUPG_CHECK_USTAR
489
490 # We need to compile and run a program on the build machine.  A
491 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
492 # the AC archive is broken for autoconf 2.57.  Given that tehre is no
493 # newer version of that macro, we assume that it is also broken for
494 # autoconf 2.61 and thus we use a simple but usually sufficient
495 # approach.
496 AC_MSG_CHECKING(for cc for build)
497 if test "$cross_compiling" = "yes"; then
498   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
499 else
500   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
501 fi
502 AC_MSG_RESULT($CC_FOR_BUILD)
503 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
504
505
506
507 try_gettext=yes
508 have_dosish_system=no
509 have_w32_system=no
510 use_simple_gettext=no
511 case "${host}" in
512     *-mingw32*)
513         # special stuff for Windoze NT
514         ac_cv_have_dev_random=no
515         AC_DEFINE(USE_ONLY_8DOT3,1,
516                   [set this to limit filenames to the 8.3 format])
517         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
518                   [defined if we must run on a stupid file system])
519         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
520                   [because the Unix gettext has too much overhead on
521                    MingW32 systems and these systems lack Posix functions,
522                    we use a simplified version of gettext])
523         disable_keyserver_path=yes
524         have_dosish_system=yes
525         have_w32_system=yes
526         try_gettext="no"
527         use_simple_gettext=yes
528         ;;
529     i?86-emx-os2 | i?86-*-os2*emx )
530         # OS/2 with the EMX environment
531         ac_cv_have_dev_random=no
532         AC_DEFINE(HAVE_DRIVE_LETTERS)
533         have_dosish_system=yes
534         try_gettext="no"
535         ;;
536
537     i?86-*-msdosdjgpp*)
538         # DOS with the DJGPP environment
539         ac_cv_have_dev_random=no
540         AC_DEFINE(HAVE_DRIVE_LETTERS)
541         have_dosish_system=yes
542         try_gettext="no"
543         ;;
544
545     *-*-freebsd*)
546        # FreeBSD
547        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
548        LDFLAGS="$LDFLAGS -L/usr/local/lib"
549        ;;
550
551     *-*-hpux*)
552         if test -z "$GCC" ; then
553             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
554         fi
555         ;;
556     *-dec-osf4*)
557         if test -z "$GCC" ; then
558             # Suppress all warnings
559             # to get rid of the unsigned/signed char mismatch warnings.
560             CFLAGS="$CFLAGS -w"
561         fi
562         ;;
563     *-dec-osf5*)
564         if test -z "$GCC" ; then
565             # Use the newer compiler `-msg_disable ptrmismatch1' to
566             # get rid of the unsigned/signed char mismatch warnings.
567             # Using this may hide other pointer mismatch warnings, but
568             # it at least lets other warning classes through
569             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
570         fi
571         ;;
572     m68k-atari-mint)
573         ;;
574     *)
575        ;;
576 esac
577
578 if test "$have_dosish_system" = yes; then
579    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
580              [Defined if we run on some of the PCDOS like systems
581               (DOS, Windoze. OS/2) with special properties like
582               no file modes])
583 fi
584 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
585
586 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
587
588 if test "$have_w32_system" = yes; then
589    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
590 fi
591 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
592
593 if test "$disable_keyserver_path" = yes; then
594     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
595               [Defined to disable exec-path for keyserver helpers])
596 fi
597
598 #
599 # Allows enabling the use of a standard socket by default This is
600 # gpg-agent's option --[no-]use-standard-socket.  For Windows we force
601 # the use of this.
602 #
603 AC_MSG_CHECKING([whether to use a standard socket by default])
604 AC_ARG_ENABLE(standard-socket,
605               AC_HELP_STRING([--enable-standard-socket],
606                              [use a standard socket for the agent by default]),
607               use_standard_socket=$enableval)
608 tmp=""
609 if test "$use_standard_socket" != yes; then
610   if test "$have_w32_system" = yes; then
611     use_standard_socket=yes
612     tmp=" (forced)"
613   fi
614 fi
615 AC_MSG_RESULT($use_standard_socket$tmp)
616 if test "$use_standard_socket" = yes; then
617   AC_DEFINE(USE_STANDARD_SOCKET,1,
618             [Use a standard socket for the agent by default])
619 fi
620
621
622 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
623 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
624
625 if test x"$try_hkp" = xyes ; then
626   AC_SUBST(GPGKEYS_HKP,"gpg2keys_hkp$EXEEXT")
627 fi
628
629 if test x"$try_finger" = xyes ; then
630   AC_SUBST(GPGKEYS_FINGER,"gpg2keys_finger$EXEEXT")
631 fi
632
633
634
635 #
636 # Checks for libraries.
637 #
638 AC_MSG_NOTICE([checking for libraries])
639
640
641 #
642 # libgpg-error is a library with error codes shared between GnuPG
643 # related projects.
644 #
645 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
646                   have_gpg_error=yes,have_gpg_error=no)
647
648
649 #
650 # Libgcrypt is our generic crypto library
651 #
652 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
653         have_libgcrypt=yes,have_libgcrypt=no)
654
655
656 #
657 # libassuan is used for IPC
658 #
659 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
660                   have_libassuan=yes,have_libassuan=no)
661 if test "$have_libassuan" = "yes"; then
662   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
663             [version of the libbassuan library])
664 fi
665
666
667
668 #
669 # libksba is our X.509 support library
670 #
671 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
672
673
674 #
675 # libusb allows us to use the integrated CCID smartcard reader driver.
676 #
677 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
678 if test "$use_ccid_driver" = yes ; then
679   AC_CHECK_LIB(usb, usb_bulk_write,
680                 [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
681                   AC_DEFINE(HAVE_LIBUSB,1,
682                            [defined if libusb is available])
683                   have_libusb=yes
684                ])
685   AC_CHECK_FUNCS(usb_create_match)
686 fi
687 AC_SUBST(LIBUSB_LIBS)
688
689 #
690 # Check wether it is necessary to link against libdl.
691 #
692 gnupg_dlopen_save_libs="$LIBS"
693 LIBS=""
694 AC_SEARCH_LIBS(dlopen, c dl,,,)
695 DL_LIBS=$LIBS
696 AC_SUBST(DL_LIBS)
697 LIBS="$gnupg_dlopen_save_libs"
698
699 #
700 # Checks for symcryptrun:
701 #
702
703 # libutil has openpty() and login_tty().
704 AC_CHECK_LIB(util, openpty,
705               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
706                 AC_DEFINE(HAVE_LIBUTIL,1,
707                          [defined if libutil is available])
708              ])
709 AC_SUBST(LIBUTIL_LIBS)
710
711 # shred is used to clean temporary plain text files.
712 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
713 AC_DEFINE_UNQUOTED(SHRED,
714         "${SHRED}", [defines the filename of the shred program])
715
716
717
718 #
719 # Check whether the GNU Pth library is available
720 # Note, that we include a Pth emulation for W32.
721 #
722 GNUPG_PATH_PTH
723 if test "$have_pth" = "yes"; then
724   AC_DEFINE(USE_GNU_PTH, 1,
725               [Defined if the GNU Portable Thread Library should be used])
726 else
727   AC_MSG_WARN([[
728 ***
729 *** To support concurrent access to the gpg-agent and the SCdaemon
730 *** we need the support of the GNU Portable Threads Library.
731 *** Download it from ftp://ftp.gnu.org/gnu/pth/
732 *** On a Debian GNU/Linux system you might want to try
733 ***   apt-get install libpth-dev
734 ***]])
735 fi
736
737
738 AC_MSG_NOTICE([checking for networking options])
739
740 #
741 # Must check for network library requirements before doing link tests
742 # for ldap, for example. If ldap libs are static (or dynamic and without
743 # ELF runtime link paths), then link will fail and LDAP support won't
744 # be detected.
745 #
746 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
747         [NETLIBS="-lnsl $NETLIBS"]))
748 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
749         [NETLIBS="-lsocket $NETLIBS"]))
750
751
752 #
753 # Check for ADNS.
754 #
755 _cppflags="${CPPFLAGS}"
756 _ldflags="${LDFLAGS}"
757 AC_ARG_WITH(adns,
758             AC_HELP_STRING([--with-adns=DIR],
759                            [look for the adns library in DIR]),
760             [if test -d "$withval"; then
761                CPPFLAGS="${CPPFLAGS} -I$withval/include"
762                LDFLAGS="${LDFLAGS} -L$withval/lib"
763              fi])
764 if test "$with_adns" != "no"; then
765   AC_CHECK_HEADERS(adns.h,
766                 AC_CHECK_LIB(adns, adns_init,
767                              [have_adns=yes],
768                              [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}]),
769                 [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}])
770 fi
771 if test "$have_adns" = "yes"; then
772   ADNSLIBS="-ladns"
773 fi
774 AC_SUBST(ADNSLIBS)
775 # Newer adns versions feature a free function to be used under W32.
776 AC_CHECK_FUNCS(adns_free)
777
778
779 #
780 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
781 #
782 if test x"$try_hkp" = xyes || test x"$try_http" = xyes ; then
783   AC_ARG_ENABLE(dns-srv,
784      AC_HELP_STRING([--disable-dns-srv],
785                     [disable the use of DNS SRV in HKP and HTTP]),
786                 use_dns_srv=$enableval,use_dns_srv=yes)
787 fi
788
789 AC_ARG_ENABLE(dns-pka,
790    AC_HELP_STRING([--disable-dns-pka],
791         [disable the use of PKA records in DNS]),
792    use_dns_pka=$enableval,use_dns_pka=yes)
793
794 AC_ARG_ENABLE(dns-cert,
795    AC_HELP_STRING([--disable-dns-cert],
796         [disable the use of CERT records in DNS]),
797    use_dns_cert=$enableval,use_dns_cert=yes)
798
799 if test x"$use_dns_pka" = xyes || test x"$use_dns_srv" = xyes \
800    || test x"$use_dns_cert" = xyes; then
801   _dns_save_libs=$LIBS
802   LIBS=""
803   # the double underscore thing is a glibc-ism?
804   AC_SEARCH_LIBS(res_query,resolv bind,,
805                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
806   AC_SEARCH_LIBS(dn_expand,resolv bind,,
807                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
808   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
809                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
810
811   if test x"$have_resolver" != xno ; then
812
813     # Make sure that the BIND 4 resolver interface is workable before
814     # enabling any code that calls it.  At some point I'll rewrite the
815     # code to use the BIND 8 resolver API.
816     # We might also want to use adns instead.  Problem with ADNS is that
817     # it does not support v6.
818
819     AC_MSG_CHECKING([whether the resolver is usable])
820     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
821 #include <netinet/in.h>
822 #include <arpa/nameser.h>
823 #include <resolv.h>]],
824 [[unsigned char answer[PACKETSZ];
825   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
826   dn_skipname(0,0);
827   dn_expand(0,0,0,0,0);
828 ]])],have_resolver=yes,have_resolver=no)
829     AC_MSG_RESULT($have_resolver)
830
831     # This is Apple-specific and somewhat bizarre as they changed the
832     # define in bind 8 for some reason.
833
834     if test x"$have_resolver" != xyes ; then
835        AC_MSG_CHECKING(
836              [whether I can make the resolver usable with BIND_8_COMPAT])
837        AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
838 #include <sys/types.h>
839 #include <netinet/in.h>
840 #include <arpa/nameser.h>
841 #include <resolv.h>]],
842 [[unsigned char answer[PACKETSZ];
843   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
844   dn_skipname(0,0); dn_expand(0,0,0,0,0);
845 ]])],[have_resolver=yes ; need_compat=yes])
846        AC_MSG_RESULT($have_resolver)
847     fi
848   fi
849
850   if test x"$have_resolver" = xyes ; then
851      DNSLIBS=$LIBS
852
853      if test x"$use_dns_srv" = xyes ; then
854         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
855      fi
856
857      if test x"$use_dns_pka" = xyes ; then
858         AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
859      fi
860
861      if test x"$use_dns_cert" = xyes ; then
862         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
863      fi
864
865      if test x"$need_compat" = xyes ; then
866         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
867      fi
868   else
869      # If we have no resolver library but ADNS (e.g. under W32) enable the
870      # code parts which can be used with ADNS.
871      if test x"$have_adns" = xyes ; then
872         DNSLIBS="$ADNSLIBS"
873         AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
874
875         if test x"$use_dns_srv" = xyes ; then
876            AC_DEFINE(USE_DNS_SRV,1)
877         fi
878
879         if test x"$use_dns_pka" = xyes ; then
880            AC_DEFINE(USE_DNS_PKA,1)
881         fi
882
883         if test x"$use_dns_cert" = xyes ; then
884            AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
885         fi
886      else
887         use_dns_srv=no
888         use_dns_pka=no
889         use_dns_cert=no
890      fi
891   fi
892
893   LIBS=$_dns_save_libs
894 fi
895
896 AC_SUBST(DNSLIBS)
897
898 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
899
900
901 #
902 # Check for LDAP
903 #
904 if test "$try_ldap" = yes ; then
905    GNUPG_CHECK_LDAP($NETLIBS)
906 fi
907
908 #
909 # Check for curl.  We fake the curl API if libcurl isn't installed.
910 # We require 7.10 or later as we use curl_version_info().
911 #
912 LIBCURL_CHECK_CONFIG([yes],[7.10],,[fake_curl=yes])
913 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
914
915 # Generic, for us, means curl
916
917 if test x"$try_generic" = xyes ; then
918    AC_SUBST(GPGKEYS_CURL,"gpg2keys_curl$EXEEXT")
919 fi
920
921 #
922 # Check for sendmail
923 #
924 # This isn't necessarily sendmail itself, but anything that gives a
925 # sendmail-ish interface to the outside world.  That includes Exim,
926 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
927 if test "$try_mailto" = yes ; then
928   AC_ARG_WITH(mailprog,
929       AC_HELP_STRING([--with-mailprog=NAME],
930                      [use "NAME -t" for mail transport]),
931              ,with_mailprog=yes)
932
933   if test x"$with_mailprog" = xyes ; then
934     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
935     if test "$ac_cv_path_SENDMAIL" ; then
936       GPGKEYS_MAILTO="gpg2keys_mailto"
937     fi
938   elif test x"$with_mailprog" != xno ; then
939     AC_MSG_CHECKING([for a mail transport program])
940     AC_SUBST(SENDMAIL,$with_mailprog)
941     AC_MSG_RESULT($with_mailprog)
942     GPGKEYS_MAILTO="gpg2keys_mailto"
943   fi
944 fi
945
946 AC_SUBST(GPGKEYS_MAILTO)
947
948 #
949 # Construct a printable name of the OS
950 #
951 case "${host}" in
952     *-mingw32*)
953         PRINTABLE_OS_NAME="MingW32"
954         ;;
955     *-*-cygwin*)
956         PRINTABLE_OS_NAME="Cygwin"
957         ;;
958     i?86-emx-os2 | i?86-*-os2*emx )
959         PRINTABLE_OS_NAME="OS/2"
960         ;;
961     i?86-*-msdosdjgpp*)
962         PRINTABLE_OS_NAME="MSDOS/DJGPP"
963         try_dynload=no
964         ;;
965     *-linux*)
966         PRINTABLE_OS_NAME="GNU/Linux"
967         ;;
968     *)
969         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
970         ;;
971 esac
972 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
973                    [A human readable text with the name of the OS])
974
975
976 #
977 # Checking for iconv
978 #
979 AM_ICONV
980
981
982 #
983 # Check for gettext
984 #
985 # This is "GNU gnupg" - The project-id script from gettext
986 #                       needs this string
987 #
988 AC_MSG_NOTICE([checking for gettext])
989 AM_PO_SUBDIRS
990 AM_GNU_GETTEXT_VERSION([0.17])
991 if test "$try_gettext" = yes; then
992   AM_GNU_GETTEXT([external],[need-ngettext])
993
994   # gettext requires some extra checks.  These really should be part of
995   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
996   # function checks to here.
997
998   AC_CHECK_FUNCS(strchr)
999 else
1000   USE_NLS=no
1001   USE_INCLUDED_LIBINTL=no
1002   BUILD_INCLUDED_LIBINTL=no
1003   POSUB=po
1004   AC_SUBST(USE_NLS)
1005   AC_SUBST(USE_INCLUDED_LIBINTL)
1006   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1007   AC_SUBST(POSUB)
1008 fi
1009
1010 # We use HAVE_LANGINFO_CODESET in a couple of places.
1011 AM_LANGINFO_CODESET
1012
1013 # Checks required for our use locales
1014 gt_LC_MESSAGES
1015
1016
1017 #
1018 # SELinux support
1019 #
1020 if test "$selinux_support" = yes ; then
1021   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1022 fi
1023
1024
1025 #
1026 # Checks for header files.
1027 #
1028 AC_MSG_NOTICE([checking for header files])
1029 AC_HEADER_STDC
1030 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h])
1031 AC_CHECK_HEADERS([pty.h utmp.h pwd.h inttypes.h])
1032 AC_HEADER_TIME
1033
1034
1035 #
1036 # Checks for typedefs, structures, and compiler characteristics.
1037 #
1038 AC_MSG_NOTICE([checking for system characteristics])
1039 AC_C_CONST
1040 AC_C_INLINE
1041 AC_C_VOLATILE
1042 AC_TYPE_SIZE_T
1043 AC_TYPE_MODE_T
1044 AC_TYPE_SIGNAL
1045 AC_DECL_SYS_SIGLIST
1046
1047 gl_HEADER_SYS_SOCKET
1048 gl_TYPE_SOCKLEN_T
1049
1050 AC_ARG_ENABLE(endian-check,
1051               AC_HELP_STRING([--disable-endian-check],
1052               [disable the endian check and trust the OS provided macros]),
1053               endiancheck=$enableval,endiancheck=yes)
1054
1055 if test x"$endiancheck" = xyes ; then
1056   GNUPG_CHECK_ENDIAN
1057 fi
1058
1059 # fixme: we should get rid of the byte type
1060 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1061 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1062 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1063 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1064 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1065
1066 AC_CHECK_SIZEOF(unsigned short)
1067 AC_CHECK_SIZEOF(unsigned int)
1068 AC_CHECK_SIZEOF(unsigned long)
1069 AC_CHECK_SIZEOF(unsigned long long)
1070 AC_CHECK_SIZEOF(time_t,,[[
1071 #include <stdio.h>
1072 #if TIME_WITH_SYS_TIME
1073 # include <sys/time.h>
1074 # include <time.h>
1075 #else
1076 # if HAVE_SYS_TIME_H
1077 #  include <sys/time.h>
1078 # else
1079 #  include <time.h>
1080 # endif
1081 #endif
1082 ]])
1083
1084
1085 # Ensure that we have UINT64_C before we bother to check for uint64_t
1086 # Fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
1087 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
1088    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <inttypes.h>]],
1089                                       [[uint64_t foo=UINT64_C(42);]])],
1090                                       [gnupg_cv_uint64_c_works=yes],
1091                                       [gnupg_cv_uint64_c_works=no]   ))
1092 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
1093    AC_CHECK_SIZEOF(uint64_t)
1094 fi
1095
1096 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1097    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1098    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1099     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1100 fi
1101
1102
1103 #
1104 # Checks for library functions.
1105 #
1106 AC_MSG_NOTICE([checking for library functions])
1107 AC_CHECK_DECLS(getpagesize)
1108 AC_FUNC_FSEEKO
1109 AC_FUNC_VPRINTF
1110 AC_FUNC_FORK
1111 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap])
1112 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r])
1113 AC_CHECK_FUNCS([unsetenv fcntl ftruncate inet_ntop])
1114 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1115 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1116 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe stat getaddrinfo])
1117 AC_CHECK_FUNCS([ttyname rand ftello fsync stat])
1118
1119 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1120
1121 #
1122 # These are needed by libjnlib - fixme: we should use a jnlib.m4
1123 # Note:  We already checked pwd.h.
1124 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol])
1125 AC_CHECK_FUNCS([memrchr isascii timegm getrusage setrlimit stat setlocale])
1126 AC_CHECK_FUNCS([flockfile funlockfile fopencookie funopen getpwnam getpwuid])
1127
1128 #
1129 # gnulib checks
1130 #
1131 gl_SOURCE_BASE([gl])
1132 gl_M4_BASE([gl/m4])
1133 gl_MODULES([setenv mkdtemp xsize strpbrk])
1134 gl_INIT
1135
1136
1137 #
1138 # W32 specific test
1139 #
1140 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1141
1142 #
1143 # Sanity check regex.  Tests adapted from mutt.
1144 #
1145 AC_MSG_CHECKING([whether regular expression support is requested])
1146 AC_ARG_ENABLE(regex,
1147   AC_HELP_STRING([--disable-regex],
1148     [do not handle regular expressions in trust signatures]),
1149   use_regex=$enableval, use_regex=yes)
1150 AC_MSG_RESULT($use_regex)
1151
1152 if test "$use_regex" = yes ; then
1153   _cppflags="${CPPFLAGS}"
1154   _ldflags="${LDFLAGS}"
1155   AC_ARG_WITH(regex,
1156      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1157       [
1158       if test -d "$withval" ; then
1159         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1160         LDFLAGS="${LDFLAGS} -L$withval/lib"
1161       fi
1162       ],withval="")
1163
1164   # Does the system have regex functions at all?
1165   AC_SEARCH_LIBS([regcomp], [regex])
1166   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1167
1168   if test $gnupg_cv_have_regex = no; then
1169     use_regex=no
1170   else
1171     if test x"$cross_compiling" = xyes; then
1172       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1173     else
1174       AC_CACHE_CHECK([whether your system's regexp library is broken],
1175        [gnupg_cv_regex_broken],
1176        AC_TRY_RUN([
1177 #include <unistd.h>
1178 #include <regex.h>
1179 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1180        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1181
1182       if test $gnupg_cv_regex_broken = yes; then
1183         AC_MSG_WARN([your regex is broken - disabling regex use])
1184         use_regex=no
1185       fi
1186     fi
1187   fi
1188   CPPFLAGS="${_cppflags}"
1189   LDFLAGS="${_ldflags}"
1190 fi
1191
1192 if test "$use_regex" != yes ; then
1193   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1194 fi
1195 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1196
1197
1198
1199 #
1200 # Do we have zlib? Must do it here because Solaris failed
1201 # when compiling a conftest (due to the "-lz" from LIBS).
1202 # Note that we combine zlib and bzlib2 in ZLIBS.
1203 #
1204 _cppflags="${CPPFLAGS}"
1205 _ldflags="${LDFLAGS}"
1206 AC_ARG_WITH(zlib,
1207   [  --with-zlib=DIR         use libz in DIR],[
1208     if test -d "$withval"; then
1209       CPPFLAGS="${CPPFLAGS} -I$withval/include"
1210       LDFLAGS="${LDFLAGS} -L$withval/lib"
1211     fi
1212   ])
1213
1214 AC_CHECK_HEADER(zlib.h,
1215       AC_CHECK_LIB(z, deflateInit2_,
1216        ZLIBS="-lz",
1217        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1218        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1219
1220 #
1221 # Check whether we can support bzip2
1222 #
1223 if test "$use_bzip2" = yes ; then
1224   _cppflags="${CPPFLAGS}"
1225   _ldflags="${LDFLAGS}"
1226   AC_ARG_WITH(bzip2,
1227      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1228       [
1229       if test -d "$withval" ; then
1230         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1231         LDFLAGS="${LDFLAGS} -L$withval/lib"
1232       fi
1233       ],withval="")
1234
1235   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1236   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1237   # woefully out of date.
1238   if test "$withval" != no ; then
1239      AC_CHECK_HEADER(bzlib.h,
1240         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1241           [
1242           have_bz2=yes
1243           ZLIBS="$ZLIBS -lbz2"
1244           AC_DEFINE(HAVE_BZIP2,1,
1245                   [Defined if the bz2 compression library is available])
1246           ],
1247           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1248           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1249   fi
1250 fi
1251 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1252 AC_SUBST(ZLIBS)
1253
1254
1255 # Check for readline support
1256 GNUPG_CHECK_READLINE
1257
1258
1259 if test "$development_version" = yes; then
1260     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1261             [Defined if this is not a regular release])
1262 fi
1263
1264 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1265
1266 GNUPG_CHECK_GNUMAKE
1267
1268 # Add some extra libs here so that previous tests don't fail for
1269 # mysterious reasons - the final link step should bail out.
1270 # W32SOCKLIBS is also defined so that if can be used for tools not
1271 # requiring any network stuff but linking to code in libcommon which
1272 # tracks in winsock stuff (e.g. init_common_subsystems.
1273 if test "$have_w32_system" = yes; then
1274    W32SOCKLIBS="-lws2_32"
1275    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1276 fi
1277
1278 AC_SUBST(NETLIBS)
1279 AC_SUBST(W32SOCKLIBS)
1280
1281 #
1282 # Setup gcc specific options
1283 #
1284 AC_MSG_NOTICE([checking for cc features])
1285 if test "$GCC" = yes; then
1286     # Note that it is okay to use CFLAGS here because this are just
1287     # warning options and the user should have a chance of overriding
1288     # them.
1289     if test "$USE_MAINTAINER_MODE" = "yes"; then
1290         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1291         CFLAGS="$CFLAGS -Wformat -Wno-format-y2k -Wformat-security"
1292         AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1293         _gcc_cflags_save=$CFLAGS
1294         CFLAGS="-Wno-missing-field-initializers"
1295         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1296                           [_gcc_wopt=yes],[_gcc_wopt=no])
1297         AC_MSG_RESULT($_gcc_wopt)
1298         CFLAGS=$_gcc_cflags_save;
1299         if test x"$_gcc_wopt" = xyes ; then
1300           CFLAGS="$CFLAGS -W -Wno-sign-compare -Wno-missing-field-initializers"
1301         fi
1302         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1303         _gcc_cflags_save=$CFLAGS
1304         CFLAGS="-Wdeclaration-after-statement"
1305         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1306                           [_gcc_wopt=yes],[_gcc_wopt=no])
1307         AC_MSG_RESULT($_gcc_wopt)
1308         CFLAGS=$_gcc_cflags_save;
1309         if test x"$_gcc_wopt" = xyes ; then
1310           CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1311         fi
1312     else
1313         CFLAGS="$CFLAGS -Wall"
1314     fi
1315
1316     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1317     _gcc_cflags_save=$CFLAGS
1318     CFLAGS="-Wno-pointer-sign"
1319     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],[_gcc_psign=yes],[_gcc_psign=no])
1320     AC_MSG_RESULT($_gcc_psign)
1321     CFLAGS=$_gcc_cflags_save;
1322     if test x"$_gcc_psign" = xyes ; then
1323        CFLAGS="$CFLAGS -Wno-pointer-sign"
1324     fi
1325
1326     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1327     _gcc_cflags_save=$CFLAGS
1328     CFLAGS="-Wpointer-arith"
1329     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],[_gcc_psign=yes],[_gcc_psign=no])
1330     AC_MSG_RESULT($_gcc_psign)
1331     CFLAGS=$_gcc_cflags_save;
1332     if test x"$_gcc_psign" = xyes ; then
1333        CFLAGS="$CFLAGS -Wpointer-arith"
1334     fi
1335 fi
1336
1337
1338 #
1339 # This is handy for debugging so the compiler doesn't rearrange
1340 # things and eliminate variables.
1341 #
1342 AC_ARG_ENABLE(optimization,
1343    AC_HELP_STRING([--disable-optimization],
1344                   [disable compiler optimization]),
1345                   [if test $enableval = no ; then
1346                       CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]]//'`
1347                    fi])
1348
1349 #
1350 # Prepare building of estream
1351 #
1352 estream_INIT
1353
1354
1355 #
1356 # Decide what to build
1357 #
1358 if test "$have_adns" = "yes"; then
1359   AC_SUBST(GPGKEYS_KDNS, "gpg2keys_kdns$EXEEXT")
1360 fi
1361
1362
1363 missing_pth=no
1364 if test $have_ksba = no; then
1365   build_gpgsm=no
1366   build_scdaemon=no
1367 fi
1368
1369 build_agent_threaded=""
1370 if test "$build_agent" = "yes"; then
1371   if test $have_pth = no; then
1372      build_agent_threaded="(not multi-threaded)"
1373      missing_pth=yes
1374   fi
1375 fi
1376
1377 build_scdaemon_extra=""
1378 if test "$build_scdaemon" = "yes"; then
1379   tmp=""
1380   if test $have_pth = no; then
1381      build_scdaemon_extra="not multi-threaded"
1382      tmp=", "
1383      missing_pth=yes
1384   fi
1385   if test $have_libusb = no; then
1386      build_scdaemon_extra="${tmp}without internal CCID driver"
1387      tmp=", "
1388   fi
1389   if test -n "$build_scdaemon_extra"; then
1390      build_scdaemon_extra="(${build_scdaemon_extra})"
1391   fi
1392 fi
1393
1394
1395 if test "$build_agent_only" = "yes" ; then
1396   build_gpg=no
1397   build_gpgsm=no
1398   build_scdaemon=no
1399   build_tools=no
1400   build_doc=no
1401 fi
1402
1403
1404 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1405 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1406 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1407 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1408 AM_CONDITIONAL(BUILD_TOOLS, test "$build_tools" = "yes")
1409 AM_CONDITIONAL(BUILD_DOC,   test "$build_doc" = "yes")
1410 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1411 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1412
1413 AM_CONDITIONAL(RUN_GPG_TESTS,
1414         test x$cross_compiling = xno -a "$build_gpg" = yes )
1415
1416
1417 #
1418 # Provide information about the build.
1419 #
1420 BUILD_REVISION="mym4_revision"
1421 AC_SUBST(BUILD_REVISION)
1422 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1423                    [GIT commit id revision used to build this package])
1424
1425 changequote(,)dnl
1426 BUILD_FILEVERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./;s/\./,/g'`
1427 changequote([,])dnl
1428 BUILD_FILEVERSION="${BUILD_FILEVERSION}mym4_revision_dec"
1429 AC_SUBST(BUILD_FILEVERSION)
1430
1431 BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1432 AC_SUBST(BUILD_TIMESTAMP)
1433 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1434                    [The time this package was configured for a build])
1435 BUILD_HOSTNAME="$ac_hostname"
1436 AC_SUBST(BUILD_HOSTNAME)
1437
1438
1439 #
1440 # Print errors here so that they are visible all
1441 # together and the user can acquire them all together.
1442 #
1443 die=no
1444 if test "$have_gpg_error" = "no"; then
1445    die=yes
1446    AC_MSG_NOTICE([[
1447 ***
1448 *** You need libgpg-error to build this program.
1449 **  This library is for example available at
1450 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1451 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1452 ***]])
1453 fi
1454 if test "$have_libgcrypt" = "no"; then
1455    die=yes
1456    AC_MSG_NOTICE([[
1457 ***
1458 *** You need libgcrypt to build this program.
1459 **  This library is for example available at
1460 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1461 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API is required.)
1462 ***]])
1463 fi
1464 if test "$have_libassuan" = "no"; then
1465    die=yes
1466    AC_MSG_NOTICE([[
1467 ***
1468 *** You need libassuan to build this program.
1469 *** This library is for example available at
1470 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1471 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1472 ***]])
1473 fi
1474 if test "$have_ksba" = "no"; then
1475     AC_MSG_NOTICE([[
1476 ***
1477 *** You need libksba to build this program.
1478 *** This library is for example available at
1479 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1480 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1481 ***]])
1482 fi
1483 if test "$missing_pth" = "yes"; then
1484     AC_MSG_NOTICE([[
1485 ***
1486 *** It is now required to build with support for the
1487 *** GNU Portable Threads Library (Pth). Please install this
1488 *** library first.  The library is for example available at
1489 ***   ftp://ftp.gnu.org/gnu/pth/
1490 *** On a Debian GNU/Linux system you can install it using
1491 ***   apt-get install libpth-dev
1492 *** To build GnuPG for Windows you need to use the W32PTH
1493 *** package; available at:
1494 ***   ftp://ftp.g10code.com/g10code/w32pth/
1495 ***]])
1496    die=yes
1497 fi
1498
1499 if test "$die" = "yes"; then
1500     AC_MSG_ERROR([[
1501 ***
1502 *** Required libraries not found. Please consult the above messages
1503 *** and install them before running configure again.
1504 ***]])
1505 fi
1506
1507
1508
1509 AC_CONFIG_FILES([ m4/Makefile
1510 Makefile
1511 po/Makefile.in
1512 gl/Makefile
1513 include/Makefile
1514 jnlib/Makefile
1515 common/Makefile
1516 common/w32info-rc.h
1517 kbx/Makefile
1518 g10/Makefile
1519 sm/Makefile
1520 agent/Makefile
1521 scd/Makefile
1522 keyserver/Makefile
1523 keyserver/gpg2keys_mailto
1524 keyserver/gpg2keys_test
1525 tools/gpg-zip
1526 tools/Makefile
1527 doc/Makefile
1528 tests/Makefile
1529 tests/openpgp/Makefile
1530 tests/pkits/Makefile
1531 ])
1532 AC_OUTPUT
1533
1534
1535 echo "
1536         GnuPG v${VERSION} has been configured as follows:
1537
1538         Revision:  mym4_revision  (mym4_revision_dec)
1539         Platform:  $PRINTABLE_OS_NAME ($host)
1540
1541         OpenPGP:   $build_gpg
1542         S/MIME:    $build_gpgsm
1543         Agent:     $build_agent $build_agent_threaded
1544         Smartcard: $build_scdaemon $build_scdaemon_extra
1545         Gpgtar:    $build_gpgtar
1546
1547         Protect tool:      $show_gnupg_protect_tool_pgm
1548         Default agent:     $show_gnupg_agent_pgm
1549         Default pinentry:  $show_gnupg_pinentry_pgm
1550         Default scdaemon:  $show_gnupg_scdaemon_pgm
1551         Default dirmngr:   $show_gnupg_dirmngr_pgm
1552 "
1553 if test x"$use_regex" != xyes ; then
1554 echo "
1555         Warning: No regular expression support available.
1556                  OpenPGP trust signatures won't work.
1557                  gpg-check-pattern will not be build.
1558 "
1559 fi