Makefile.am: Link to iconv for jnlib dependency. (OSX)
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 1.9
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 #               2003, 2004, 2005, 2006 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 2 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, write to the Free Software
19 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301,
20 # USA.
21
22 # Process this file with autoconf to produce a configure script.
23 AC_PREREQ(2.59)
24 min_automake_version="1.9.3"
25
26 # Remember to change the version number immediately *after* a release.
27 # Set my_issvn to "yes" for non-released code.  Remember to run an
28 # "svn up" and "autogen.sh" right before creating a distribution.
29 m4_define([my_version], [2.0.2])
30 m4_define([my_issvn], [yes])
31
32
33 m4_define([svn_revision], m4_esyscmd([echo -n $( (svn info 2>/dev/null \
34             || echo 'Revision: 0')|sed -n '/^Revision:/ {s/[^0-9]//gp;q;}')]))
35 AC_INIT([gnupg], my_version[]m4_if(my_issvn,[yes],[-svn[]svn_revision]),
36         [bug-gnupg@gnupg.org])
37 # Set development_version to yes if the minor number is odd or you
38 # feel that the default check for a development version is not
39 # sufficient.
40 development_version=no
41
42 NEED_GPG_ERROR_VERSION=1.4
43
44 NEED_LIBGCRYPT_API=1
45 NEED_LIBGCRYPT_VERSION=1.2.0
46
47 NEED_LIBASSUAN_API=1
48 NEED_LIBASSUAN_VERSION=0.9.3
49
50 NEED_KSBA_API=1
51 NEED_KSBA_VERSION=1.0.0
52
53
54 PACKAGE=$PACKAGE_NAME
55 PACKAGE_GT=${PACKAGE_NAME}2
56 VERSION=$PACKAGE_VERSION
57
58 AC_CONFIG_AUX_DIR(scripts)
59 AC_CONFIG_SRCDIR(sm/gpgsm.c)
60 AM_CONFIG_HEADER(config.h)
61 AC_CANONICAL_TARGET()
62 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
63 AB_INIT
64
65 AC_GNU_SOURCE
66
67 # Some status variables.
68 have_gpg_error=no
69 have_libgcrypt=no 
70 have_libassuan=no
71 have_ksba=no
72 have_pth=no
73 have_libusb=no
74
75 use_bzip2=yes
76 use_exec=yes
77 disable_keyserver_path=no
78
79
80 GNUPG_BUILD_PROGRAM(gpg, yes)
81 GNUPG_BUILD_PROGRAM(gpgsm, yes)
82 GNUPG_BUILD_PROGRAM(agent, yes)
83 GNUPG_BUILD_PROGRAM(scdaemon, yes)
84 GNUPG_BUILD_PROGRAM(tools, yes)
85 GNUPG_BUILD_PROGRAM(doc, yes)
86 GNUPG_BUILD_PROGRAM(symcryptrun, no)
87
88 AC_SUBST(PACKAGE)
89 AC_SUBST(PACKAGE_GT)
90 AC_SUBST(VERSION)
91 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
92 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
93                                 [Name of this package for gettext])
94 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
95 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
96                                         [Bug report address])
97 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
98                                        [Required version of Libgcrypt])
99 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
100                                        [Required version of Libksba])
101
102
103
104 # The default is to use the modules from this package and the few
105 # other packages in a standard place; i.e where this package gets
106 # installed.  With these options it is possible to override these
107 # ${prefix} depended values with fixed paths, which can't be replaced
108 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
109 AC_ARG_WITH(agent-pgm,
110     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
111           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
112 AC_SUBST(GNUPG_AGENT_PGM)
113 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
114 show_gnupg_agent_pgm="(default)"
115 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
116
117 AC_ARG_WITH(pinentry-pgm,
118     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
119           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
120 AC_SUBST(GNUPG_PINENTRY_PGM)
121 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
122 show_gnupg_pinentry_pgm="(default)"
123 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
124
125
126 AC_ARG_WITH(scdaemon-pgm,
127     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
128           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
129 AC_SUBST(GNUPG_SCDAEMON_PGM)
130 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
131 show_gnupg_scdaemon_pgm="(default)"
132 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
133
134
135 AC_ARG_WITH(dirmngr-pgm,
136     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
137           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
138 AC_SUBST(GNUPG_DIRMNGR_PGM)
139 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
140 show_gnupg_dirmngr_pgm="(default)"
141 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
142
143 AC_ARG_WITH(protect-tool-pgm,
144     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
145           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
146 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
147 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
148 show_gnupg_protect_tool_pgm="(default)"
149 test -n "$GNUPG_PROTECT_TOOL_PGM" \
150       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
151
152
153 # Some folks want to use only the agent from this packet.  Make it
154 # easier for them by providing the configure option
155 # --enable-only-agent.
156 AC_ARG_ENABLE(agent-only,
157     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
158     build_agent_only=$enableval)
159
160 # SELinux support includes tracking of sensitive files to avoid
161 # leaking their contents through processing these files by gpg itself
162 AC_MSG_CHECKING([whether SELinux support is requested])
163 AC_ARG_ENABLE(selinux-support,
164               AC_HELP_STRING([--enable-selinux-support],
165                              [enable SELinux support]),
166               selinux_support=$enableval, selinux_support=no)
167 AC_MSG_RESULT($selinux_support)
168
169 # Allow disabling of bzib2 support.
170 # It is defined only after we confirm the library is available later
171 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
172 AC_ARG_ENABLE(bzip2,
173    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
174    use_bzip2=$enableval)
175 AC_MSG_RESULT($use_bzip2)
176
177
178 # Configure option to allow or disallow execution of external
179 # programs, like a photo viewer.
180 AC_MSG_CHECKING([whether to enable external program execution])
181 AC_ARG_ENABLE(exec,
182     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
183     use_exec=$enableval)
184 AC_MSG_RESULT($use_exec)
185 if test "$use_exec" = no ; then
186     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
187 fi
188
189 if test "$use_exec" = yes ; then
190   AC_MSG_CHECKING([whether to enable photo ID viewing])
191   AC_ARG_ENABLE(photo-viewers,
192       [  --disable-photo-viewers disable photo ID viewers],
193       [if test "$enableval" = no ; then
194          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
195       fi],enableval=yes)
196   gnupg_cv_enable_photo_viewers=$enableval
197   AC_MSG_RESULT($enableval)
198
199   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
200     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
201     AC_ARG_WITH(photo-viewer,
202         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
203         [if test "$withval" = yes ; then
204            withval=no
205         elif test "$withval" != no ; then
206            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
207                             [if set, restrict photo-viewer to this])
208         fi],withval=no)
209     AC_MSG_RESULT($withval)
210   fi
211
212   AC_MSG_CHECKING([whether to enable external keyserver helpers])
213   AC_ARG_ENABLE(keyserver-helpers,
214       [  --disable-keyserver-helpers  disable all external keyserver support],
215       [if test "$enableval" = no ; then
216          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
217                   [define to disable keyserver helpers])
218       fi],enableval=yes)
219   gnupg_cv_enable_keyserver_helpers=$enableval
220   AC_MSG_RESULT($enableval)
221
222   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
223     # LDAP is defined only after we confirm the library is available later
224     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
225     AC_ARG_ENABLE(ldap,
226       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
227       try_ldap=$enableval, try_ldap=yes)
228     AC_MSG_RESULT($try_ldap)
229
230     AC_MSG_CHECKING([whether HKP keyserver support is requested])
231     AC_ARG_ENABLE(hkp,
232       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
233       try_hkp=$enableval, try_hkp=yes)
234     AC_MSG_RESULT($try_hkp)
235
236     AC_MSG_CHECKING([whether finger key fetching support is requested])
237     AC_ARG_ENABLE(finger,
238       AC_HELP_STRING([--disable-finger],
239         [disable finger key fetching interface only]),
240       try_finger=$enableval, try_finger=yes)
241     AC_MSG_RESULT($try_finger)
242
243     AC_MSG_CHECKING([whether generic object key fetching support is requested])
244     AC_ARG_ENABLE(generic,
245       AC_HELP_STRING([--disable-generic],
246         [disable generic object key fetching interface only]),
247       try_generic=$enableval, try_generic=yes)
248     AC_MSG_RESULT($try_generic)
249
250     AC_MSG_CHECKING([whether email keyserver support is requested])
251     AC_ARG_ENABLE(mailto,
252       AC_HELP_STRING([--enable-mailto],
253         [enable email keyserver interface only]),
254       try_mailto=$enableval, try_mailto=no)
255     AC_MSG_RESULT($try_mailto)
256     fi
257
258     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
259     AC_ARG_ENABLE(keyserver-path,
260       AC_HELP_STRING([--disable-keyserver-path],
261         [disable the exec-path option for keyserver helpers]),
262       [if test "$enableval" = no ; then
263          disable_keyserver_path=yes
264       fi],enableval=yes)
265     AC_MSG_RESULT($enableval)
266   fi
267
268
269 #
270 # Check for the key/uid cache size.  This can't be zero, but can be
271 # pretty small on embedded systems.  This is used for the gpg part.
272 #
273 AC_MSG_CHECKING([for the size of the key and uid cache])
274 AC_ARG_ENABLE(key-cache,
275         AC_HELP_STRING([--enable-key-cache=SIZE],
276                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
277 if test "$enableval" = "no"; then
278    enableval=5
279 elif test "$enableval" = "yes" || test "$enableval" = ""; then
280    enableval=4096
281 fi
282 changequote(,)dnl
283 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
284 changequote([,])dnl
285 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
286    AC_MSG_ERROR([invalid key-cache size])
287 fi
288 AC_MSG_RESULT($key_cache_size)
289 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
290                   [Size of the key and UID caches])
291
292
293
294 #
295 # Check whether we want to use Linux capabilities
296 #
297 AC_MSG_CHECKING([whether use of capabilities is requested])
298 AC_ARG_WITH(capabilities,
299     [  --with-capabilities     use linux capabilities [default=no]],
300 [use_capabilities="$withval"],[use_capabilities=no])
301 AC_MSG_RESULT($use_capabilities)
302
303 #
304 # To avoid double inclusion of config.h which might happen at some
305 # places, we add the usual double inclusion protection at the top of
306 # config.h.
307 #
308 AH_TOP([
309 #ifndef GNUPG_CONFIG_H_INCLUDED
310 #define GNUPG_CONFIG_H_INCLUDED
311 ])
312
313 #
314 # Stuff which goes at the bottom of config.h.
315 #
316 AH_BOTTOM([
317 /* This is the major version number of GnuPG so that
318    source included files can test for this.  Note, that
319    we use 2 here even for GnuPG 1.9.x. */
320 #define GNUPG_MAJOR_VERSION 2
321
322 /* Now to separate file name parts.
323    Please note that the string version must not contain more
324    than one character because the code assumes strlen()==1 */
325 #ifdef HAVE_DOSISH_SYSTEM
326 #define DIRSEP_C '\\'
327 #define DIRSEP_S "\\"
328 #define EXTSEP_C '.'
329 #define EXTSEP_S "."
330 #define PATHSEP_C ';'
331 #define PATHSEP_S ";"
332 #define EXEEXT_S ".exe"
333 #else
334 #define DIRSEP_C '/'
335 #define DIRSEP_S "/"
336 #define EXTSEP_C '.'
337 #define EXTSEP_S "."
338 #define PATHSEP_C ':'
339 #define PATHSEP_S ":"
340 #define EXEEXT_S ""
341 #endif
342
343 /* This is the same as VERSION, but should be overridden if the
344    platform cannot handle things like dots '.' in filenames. Set
345    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
346    uses for dots and dashes. */
347 #define SAFE_VERSION VERSION
348 #define SAFE_VERSION_DOT  '.'
349 #define SAFE_VERSION_DASH '-'
350
351 /* Some global constants. */
352 #ifdef HAVE_DRIVE_LETTERS
353 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
354 #elif defined(__VMS)
355 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg" 
356 #else
357 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
358 #endif 
359 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
360
361 /* For some systems (DOS currently), we hardcode the path here.  For
362    POSIX systems the values are constructed by the Makefiles, so that
363    the values may be overridden by the make invocations; this is to
364    comply with the GNU coding standards. */
365 #ifdef HAVE_DRIVE_LETTERS
366 #define GNUPG_BINDIR      "c:\\gnupg"
367 #define GNUPG_LIBEXECDIR  "c:\\gnupg"
368 #define GNUPG_LIBDIR      "c:\\gnupg"
369 #define GNUPG_DATADIR     "c:\\gnupg"
370 #endif
371
372 /* Setup the hardwired names of modules. */
373 #ifndef GNUPG_DEFAULT_AGENT
374 #define GNUPG_DEFAULT_AGENT    ( GNUPG_BINDIR DIRSEP_S "gpg-agent" EXEEXT_S )
375 #endif
376 #ifndef GNUPG_DEFAULT_PINENTRY
377 #define GNUPG_DEFAULT_PINENTRY ( GNUPG_BINDIR DIRSEP_S "pinentry" EXEEXT_S )
378 #endif
379 #ifndef GNUPG_DEFAULT_SCDAEMON
380 #define GNUPG_DEFAULT_SCDAEMON ( GNUPG_BINDIR DIRSEP_S "scdaemon" EXEEXT_S )
381 #endif
382 #ifndef GNUPG_DEFAULT_DIRMNGR
383 #define GNUPG_DEFAULT_DIRMNGR  ( GNUPG_BINDIR DIRSEP_S "dirmngr" EXEEXT_S )
384 #endif
385 #ifndef GNUPG_DEFAULT_PROTECT_TOOL
386 #define GNUPG_DEFAULT_PROTECT_TOOL \
387                     ( GNUPG_LIBEXECDIR DIRSEP_S "gpg-protect-tool" EXEEXT_S )
388 #endif
389
390
391 /* Derive some other constants. */
392 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
393 #define EXEC_TEMPFILE_ONLY
394 #endif
395
396
397 /* We didn't define endianness above, so get it from OS macros.  This
398    is intended for making fat binary builds on OS X. */
399 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
400 #if defined(__BIG_ENDIAN__)
401 #define BIG_ENDIAN_HOST 1
402 #elif defined(__LITTLE_ENDIAN__)
403 #define LITTLE_ENDIAN_HOST 1
404 #else
405 #error "No endianness found"
406 #endif
407 #endif
408
409
410 /* Tell libgcrypt not to use its own libgpg-error implementation. */
411 #define USE_LIBGPG_ERROR 1
412
413 /* We use jnlib, so tell other modules about it.  */
414 #define HAVE_JNLIB_LOGGING 1
415
416 /* Our HTTP code is used in estream mode.  */
417 #define HTTP_USE_ESTREAM 1
418
419 /* We always include support for the OpenPGP card.  */
420 #define ENABLE_CARD_SUPPORT 1
421
422 /* We don't want the old assuan codes anymore. */
423 #define _ASSUAN_ONLY_GPG_ERRORS 1
424
425 /* We explicitly need to disable PTH's soft mapping as Debian
426    currently enables it by default for no reason. */
427 #define PTH_SYSCALL_SOFT 0
428
429
430 #endif /*GNUPG_CONFIG_H_INCLUDED*/
431 ])
432
433
434 AM_MAINTAINER_MODE
435
436 # Checks for programs.
437 AC_PROG_MAKE_SET
438 AM_SANITY_CHECK
439 missing_dir=`cd $ac_aux_dir && pwd`
440 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
441 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
442 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
443 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
444 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
445 AC_PROG_AWK
446 AC_PROG_CC
447 AC_PROG_CPP
448 AC_PROG_INSTALL
449 AC_PROG_LN_S
450 AC_PROG_RANLIB
451 AC_CHECK_TOOL(AR, ar, :)
452 AC_PATH_PROG(PERL,"perl")
453 AC_ISC_POSIX
454 gl_EARLY
455 AC_SYS_LARGEFILE
456 GNUPG_CHECK_FAQPROG
457 GNUPG_CHECK_USTAR
458
459
460 try_gettext=yes
461 have_dosish_system=no
462 have_w32_system=no
463 use_simple_gettext=no
464 case "${host}" in
465     *-mingw32*)
466         # special stuff for Windoze NT
467         ac_cv_have_dev_random=no
468         AC_DEFINE(USE_ONLY_8DOT3,1,
469                   [set this to limit filenames to the 8.3 format])
470         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
471                   [defined if we must run on a stupid file system])
472         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
473                   [because the Unix gettext has too much overhead on
474                    MingW32 systems and these systems lack Posix functions,
475                    we use a simplified version of gettext])
476         disable_keyserver_path=yes
477         have_dosish_system=yes
478         have_w32_system=yes
479         try_gettext="no"
480         use_simple_gettext=yes
481         ;;
482     i?86-emx-os2 | i?86-*-os2*emx )
483         # OS/2 with the EMX environment
484         ac_cv_have_dev_random=no
485         AC_DEFINE(HAVE_DRIVE_LETTERS)
486         have_dosish_system=yes
487         try_gettext="no"
488         ;;
489
490     i?86-*-msdosdjgpp*)
491         # DOS with the DJGPP environment
492         ac_cv_have_dev_random=no
493         AC_DEFINE(HAVE_DRIVE_LETTERS)
494         have_dosish_system=yes
495         try_gettext="no"
496         ;;
497
498     *-*-freebsd*)
499        # FreeBSD
500        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
501        LDFLAGS="$LDFLAGS -L/usr/local/lib"
502        ;;
503
504     *-*-hpux*)
505         if test -z "$GCC" ; then
506             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
507         fi
508         ;;
509     *-dec-osf4*)
510         if test -z "$GCC" ; then
511             # Suppress all warnings
512             # to get rid of the unsigned/signed char mismatch warnings.
513             CFLAGS="$CFLAGS -w"
514         fi
515         ;;
516     *-dec-osf5*)
517         if test -z "$GCC" ; then
518             # Use the newer compiler `-msg_disable ptrmismatch1' to
519             # get rid of the unsigned/signed char mismatch warnings.
520             # Using this may hide other pointer mismatch warnings, but
521             # it at least lets other warning classes through
522             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
523         fi
524         ;;
525     m68k-atari-mint)
526         ;;
527     *)
528        ;;
529 esac
530
531 if test "$have_dosish_system" = yes; then
532    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
533              [Defined if we run on some of the PCDOS like systems 
534               (DOS, Windoze. OS/2) with special properties like
535               no file modes])
536 fi
537 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
538
539 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
540
541 if test "$have_w32_system" = yes; then
542    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
543 fi
544 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
545
546 if test "$disable_keyserver_path" = yes; then
547     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
548               [Defined to disable exec-path for keyserver helpers])
549 fi
550
551 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
552 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
553
554 if test x"$try_hkp" = xyes ; then
555   AC_SUBST(GPGKEYS_HKP,"gpg2keys_hkp$EXEEXT")
556 fi
557
558 if test x"$try_finger" = xyes ; then
559   AC_SUBST(GPGKEYS_FINGER,"gpg2keys_finger$EXEEXT")
560 fi
561
562
563
564 #
565 # Checks for libraries.
566 #
567
568
569 #
570 # libgpg-error is a library with error codes shared between GnuPG
571 # related projects.
572 #
573 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
574                   have_gpg_error=yes,have_gpg_error=no)
575
576
577 #
578 # Libgcrypt is our generic crypto library
579 #
580 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
581         have_libgcrypt=yes,have_libgcrypt=no)
582
583
584 #
585 # libassuan is used for IPC
586 #
587 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
588                   have_libassuan=yes,have_libassuan=no)
589 if test "$have_libassuan" = "yes"; then
590   have_libassuan=no
591   AM_PATH_LIBASSUAN_PTH("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
592                         have_libassuan=yes,have_libassuan=no)
593   AM_CHECK_LIBASSUAN("$NEED_LIBASSUAN_API:1.0.1",
594        [AC_DEFINE(HAVE_ASSUAN_SET_IO_MONITOR, 1,
595          [Define to 1 if you have the `assuan_set_io_monitor' function.])],)  
596 fi
597
598
599
600 #
601 # libksba is our X.509 support library
602 #
603 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
604
605
606 #
607 # libusb allows us to use the integrated CCID smartcard reader driver.
608 #
609 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
610 AC_CHECK_LIB(usb, usb_bulk_write,
611               [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
612                 AC_DEFINE(HAVE_LIBUSB,1,
613                          [defined if libusb is available])
614                 have_libusb=yes
615              ])
616 AC_SUBST(LIBUSB_LIBS)
617 AC_CHECK_FUNCS(usb_create_match)
618
619 #
620 # Check wether it is necessary to link against libdl.
621 #
622 gnupg_dlopen_save_libs="$LIBS"
623 LIBS=""
624 AC_SEARCH_LIBS(dlopen, c dl,,,)
625 DL_LIBS=$LIBS
626 AC_SUBST(DL_LIBS)
627 LIBS="$gnupg_dlopen_save_libs"
628
629 #
630 # Checks for symcryptrun:
631 #
632
633 # libutil has openpty() and login_tty().
634 AC_CHECK_LIB(util, openpty,
635               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
636                 AC_DEFINE(HAVE_LIBUTIL,1,
637                          [defined if libutil is available])
638              ])
639 AC_SUBST(LIBUTIL_LIBS)
640
641 # shred is used to clean temporary plain text files.
642 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
643 AC_DEFINE_UNQUOTED(SHRED,
644         "${SHRED}", [defines the filename of the shred program])
645
646
647
648 #
649 # Check whether the GNU Pth library is available
650 # Note, that we include a Pth emulation for W32.
651 #
652 GNUPG_PATH_PTH
653 if test "$have_pth" = "yes"; then
654   AC_DEFINE(USE_GNU_PTH, 1,
655               [Defined if the GNU Portable Thread Library should be used])
656 else
657   AC_MSG_WARN([[
658 ***
659 *** To support concurrent access to the gpg-agent and the SCdaemon
660 *** we need the support of the GNU Portable Threads Library.
661 *** Download it from ftp://ftp.gnu.org/gnu/pth/
662 *** On a Debian GNU/Linux system you might want to try 
663 ***   apt-get install libpth-dev
664 ***]])
665 fi
666
667
668
669 #
670 # Must check for network library requirements before doing link tests
671 # for ldap, for example. If ldap libs are static (or dynamic and without
672 # ELF runtime link paths), then link will fail and LDAP support won't
673 # be detected.
674 #
675 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
676         [NETLIBS="-lnsl $NETLIBS"]))
677 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
678         [NETLIBS="-lsocket $NETLIBS"]))
679
680 #
681 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
682 #
683 if test x"$try_hkp" = xyes || test x"$try_http" = xyes ; then
684   AC_ARG_ENABLE(dns-srv,
685      AC_HELP_STRING([--disable-dns-srv],
686                     [disable the use of DNS SRV in HKP and HTTP]),
687                 use_dns_srv=$enableval,use_dns_srv=yes)
688 fi
689
690 AC_ARG_ENABLE(dns-pka,
691    AC_HELP_STRING([--disable-dns-pka],
692         [disable the use of PKA records in DNS]),
693    use_dns_pka=$enableval,use_dns_pka=yes)
694
695 AC_ARG_ENABLE(dns-cert,
696    AC_HELP_STRING([--disable-dns-cert],
697         [disable the use of CERT records in DNS]),
698    use_dns_cert=$enableval,use_dns_cert=yes)
699
700 if test x"$use_dns_pka" = xyes || test x"$use_dns_srv" = xyes \
701    || test x"$use_dns_cert" = xyes; then
702   _dns_save_libs=$LIBS
703   LIBS=""
704   # the double underscore thing is a glibc-ism?
705   AC_SEARCH_LIBS(res_query,resolv bind,,
706                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
707   AC_SEARCH_LIBS(dn_expand,resolv bind,,
708                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
709   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
710                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
711
712   if test x"$have_resolver" != xno ; then
713
714     # Make sure that the BIND 4 resolver interface is workable before
715     # enabling any code that calls it.  At some point I'll rewrite the
716     # code to use the BIND 8 resolver API.
717
718     AC_MSG_CHECKING([whether the resolver is usable])
719     AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
720 #include <netinet/in.h>
721 #include <arpa/nameser.h>
722 #include <resolv.h>],
723 [[unsigned char answer[PACKETSZ];
724   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
725   dn_skipname(0,0); 
726   dn_expand(0,0,0,0,0);
727 ]])],have_resolver=yes,have_resolver=no)
728     AC_MSG_RESULT($have_resolver)
729
730     # This is Apple-specific and somewhat bizarre as they changed the
731     # define in bind 8 for some reason.
732
733     if test x"$have_resolver" != xyes ; then
734        AC_MSG_CHECKING(
735              [whether I can make the resolver usable with BIND_8_COMPAT])
736        AC_LINK_IFELSE([AC_LANG_PROGRAM([#define BIND_8_COMPAT
737 #include <sys/types.h>
738 #include <netinet/in.h>
739 #include <arpa/nameser.h>
740 #include <resolv.h>],
741 [[unsigned char answer[PACKETSZ];
742   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
743   dn_skipname(0,0); dn_expand(0,0,0,0,0);
744 ]])],[have_resolver=yes ; need_compat=yes])
745        AC_MSG_RESULT($have_resolver)
746     fi
747   fi
748
749   if test x"$have_resolver" = xyes ; then
750      DNSLIBS=$LIBS
751
752      if test x"$use_dns_srv" = xyes ; then
753         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
754      fi
755
756      if test x"$use_dns_pka" = xyes ; then
757         AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
758      fi
759
760      if test x"$use_dns_cert" = xyes ; then
761         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
762      fi
763
764      if test x"$need_compat" = xyes ; then
765         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
766      fi
767   else
768      use_dns_srv=no
769      use_dns_pka=no
770      use_dns_cert=no
771   fi
772
773   LIBS=$_dns_save_libs
774 fi
775
776 AC_SUBST(DNSLIBS)
777
778 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
779
780 #
781 # Check for LDAP
782 #
783 if test "$try_ldap" = yes ; then
784    GNUPG_CHECK_LDAP($NETLIBS)
785 fi
786
787 #
788 # Check for curl.  We fake the curl API if libcurl isn't installed.
789 #
790 LIBCURL_CHECK_CONFIG([yes],,,[fake_curl=yes])
791 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
792
793 # Generic, for us, means curl
794
795 if test x"$try_generic" = xyes ; then
796    AC_SUBST(GPGKEYS_CURL,"gpg2keys_curl$EXEEXT")
797 fi
798
799 #
800 # Check for sendmail
801 #
802 # This isn't necessarily sendmail itself, but anything that gives a
803 # sendmail-ish interface to the outside world.  That includes Exim,
804 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
805 if test "$try_mailto" = yes ; then
806   AC_ARG_WITH(mailprog,
807       AC_HELP_STRING([--with-mailprog=NAME],
808                      [use "NAME -t" for mail transport]),
809              ,with_mailprog=yes)
810
811   if test x"$with_mailprog" = xyes ; then
812     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
813     if test "$ac_cv_path_SENDMAIL" ; then
814       GPGKEYS_MAILTO="gpg2keys_mailto"
815     fi
816   elif test x"$with_mailprog" != xno ; then
817     AC_MSG_CHECKING([for a mail transport program])
818     AC_SUBST(SENDMAIL,$with_mailprog)
819     AC_MSG_RESULT($with_mailprog)
820     GPGKEYS_MAILTO="gpg2keys_mailto"
821   fi
822 fi
823
824 AC_SUBST(GPGKEYS_MAILTO)
825
826 #
827 # Construct a printable name of the OS
828 #
829 case "${host}" in
830     *-mingw32*)
831         PRINTABLE_OS_NAME="MingW32"
832         ;;
833     *-*-cygwin*)
834         PRINTABLE_OS_NAME="Cygwin"
835         ;;
836     i?86-emx-os2 | i?86-*-os2*emx )
837         PRINTABLE_OS_NAME="OS/2"
838         ;;
839     i?86-*-msdosdjgpp*)
840         PRINTABLE_OS_NAME="MSDOS/DJGPP"
841         try_dynload=no
842         ;;
843     *-linux*)
844         PRINTABLE_OS_NAME="GNU/Linux"
845         ;;
846     *)
847         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
848         ;;
849 esac
850 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
851                    [A human readable text with the name of the OS])
852
853
854 #
855 # Check for gettext
856 #
857 AM_GNU_GETTEXT_VERSION([0.15])
858 if test "$try_gettext" = yes; then
859   AM_GNU_GETTEXT(,[need-ngettext])
860
861   # gettext requires some extra checks.  These really should be part of
862   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
863   # function checks to here.
864
865   AC_CHECK_FUNCS(strchr)
866 else
867   USE_NLS=no
868   USE_INCLUDED_LIBINTL=no
869   BUILD_INCLUDED_LIBINTL=no
870   AC_SUBST(USE_NLS)
871   AC_SUBST(USE_INCLUDED_LIBINTL)
872   AC_SUBST(BUILD_INCLUDED_LIBINTL)
873 fi
874
875
876 #
877 # SELinux support
878 #
879 if test "$selinux_support" = yes ; then
880   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
881 fi
882
883
884 #
885 # Checks for header files.
886 #
887 AC_HEADER_STDC
888 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h])
889 AC_CHECK_HEADERS([pty.h pwd.h inttypes.h])
890 AC_HEADER_TIME
891
892
893 #
894 # Checks for typedefs, structures, and compiler characteristics.
895 #
896 AC_C_CONST
897 AC_C_INLINE
898 AC_C_VOLATILE
899 AC_TYPE_SIZE_T
900 AC_TYPE_MODE_T
901 AC_TYPE_SIGNAL
902 AC_DECL_SYS_SIGLIST
903
904 AC_ARG_ENABLE(endian-check,
905               AC_HELP_STRING([--disable-endian-check],
906               [disable the endian check and trust the OS provided macros]),
907               endiancheck=$enableval,endiancheck=yes)
908
909 if test x"$endiancheck" = xyes ; then
910   GNUPG_CHECK_ENDIAN
911 fi
912
913 # fixme: we should get rid of the byte type
914 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
915 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
916 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
917 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
918 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
919
920 AC_CHECK_SIZEOF(unsigned short)
921 AC_CHECK_SIZEOF(unsigned int)
922 AC_CHECK_SIZEOF(unsigned long)
923 AC_CHECK_SIZEOF(unsigned long long)
924 AC_CHECK_SIZEOF(time_t,,[[
925 #include <stdio.h>
926 #if TIME_WITH_SYS_TIME
927 # include <sys/time.h>
928 # include <time.h>
929 #else
930 # if HAVE_SYS_TIME_H
931 #  include <sys/time.h>
932 # else
933 #  include <time.h>
934 # endif
935 #endif
936 ]])
937
938
939 # Ensure that we have UINT64_C before we bother to check for uint64_t
940 # Fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
941 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
942    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
943        uint64_t foo=UINT64_C(42);]),
944      gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
945 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
946    AC_CHECK_SIZEOF(uint64_t)
947 fi
948
949 if test "$ac_cv_sizeof_unsigned_short" = "0" \
950    || test "$ac_cv_sizeof_unsigned_int" = "0" \
951    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
952     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
953 fi
954
955
956 #
957 # Checks for library functions.
958 #
959 AC_CHECK_DECLS(getpagesize)
960 AC_FUNC_FSEEKO
961 AC_FUNC_VPRINTF
962 AC_FUNC_FORK
963 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap])
964 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r])
965 AC_CHECK_FUNCS([unsetenv getpwnam getpwuid fcntl ftruncate])
966 AC_CHECK_FUNCS([gettimeofday getrusage setrlimit clock_gettime])
967 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
968 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe stat getaddrinfo])
969 AC_CHECK_FUNCS([ttyname rand ftello])
970
971 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
972
973 #
974 # These are needed by libjnlib - fixme: we should use a jnlib.m4
975 #
976 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol])
977 AC_CHECK_FUNCS([memrchr isascii timegm getrusage setrlimit stat setlocale])
978 AC_CHECK_FUNCS([flockfile funlockfile fopencookie funopen])
979
980 #
981 # gnulib checks
982 #
983 gl_SOURCE_BASE([gl])
984 gl_M4_BASE([gl/m4])
985 gl_MODULES([setenv mkdtemp vasprintf xsize])
986 gl_INIT
987
988
989
990 #
991 # W32 specific test
992 #
993 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
994
995
996 #
997 # Sanity check regex.  Tests adapted from mutt.
998 # FIXME: We should use the the regex from gnulib
999 #
1000 AC_MSG_CHECKING([whether regular expression support is requested])
1001 AC_ARG_ENABLE(regex,
1002   AC_HELP_STRING([--disable-regex],
1003     [do not handle regular expressions in trust signatures]),
1004   use_regex=$enableval, use_regex=yes)
1005 AC_MSG_RESULT($use_regex)
1006
1007 if test "$use_regex" = yes ; then
1008   AC_MSG_CHECKING([whether the included regex lib is requested])
1009   AC_ARG_WITH(included-regex,
1010       [  --with-included-regex   use the included GNU regex library],
1011       [gnupg_cv_included_regex="$withval"],[gnupg_cv_included_regex=no])
1012   AC_MSG_RESULT($gnupg_cv_included_regex)
1013
1014   if test $gnupg_cv_included_regex = no ; then
1015      # Does the system have regex functions at all?
1016      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
1017                            gnupg_cv_included_regex=yes)
1018   fi
1019
1020   if test $gnupg_cv_included_regex = no ; then
1021      AC_CACHE_CHECK([whether your system's regexp library is broken],
1022        [gnupg_cv_regex_broken],
1023        AC_TRY_RUN([
1024 #include <unistd.h>
1025 #include <regex.h>
1026 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1027        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1028
1029      if test $gnupg_cv_regex_broken = yes ; then
1030       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
1031       gnupg_cv_included_regex=yes
1032      fi
1033   fi
1034
1035   if test $gnupg_cv_included_regex = yes; then
1036      AC_DEFINE(USE_INTERNAL_REGEX,1,[ Define if you want to use the included regex lib ])
1037   fi
1038 else
1039   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
1040 fi
1041
1042 AM_CONDITIONAL(USE_INTERNAL_REGEX, test x"$gnupg_cv_included_regex" = xyes)
1043
1044
1045
1046 #
1047 # Do we have zlib? Must do it here because Solaris failed
1048 # when compiling a conftest (due to the "-lz" from LIBS).
1049 # Note that we combine zlib and bzlib2 in ZLIBS.
1050 #
1051 _cppflags="${CPPFLAGS}"
1052 _ldflags="${LDFLAGS}"
1053 AC_ARG_WITH(zlib,
1054   [  --with-zlib=DIR         use libz in DIR],[
1055     if test -d "$withval"; then
1056       CPPFLAGS="${CPPFLAGS} -I$withval/include"
1057       LDFLAGS="${LDFLAGS} -L$withval/lib"
1058     fi
1059   ])
1060
1061 AC_CHECK_HEADER(zlib.h,
1062       AC_CHECK_LIB(z, deflateInit2_,
1063        ZLIBS="-lz",
1064        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1065        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1066
1067 #
1068 # Check whether we can support bzip2
1069
1070 if test "$use_bzip2" = yes ; then
1071   _cppflags="${CPPFLAGS}"
1072   _ldflags="${LDFLAGS}"
1073   AC_ARG_WITH(bzip2,
1074      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1075       [
1076       if test -d "$withval" ; then
1077         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1078         LDFLAGS="${LDFLAGS} -L$withval/lib"
1079       fi
1080       ],withval="")
1081
1082   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1083   # required stdio.h to be included before bzlib.h, and Solaris 9 is 
1084   # woefully out of date.
1085   if test "$withval" != no ; then
1086      AC_CHECK_HEADER(bzlib.h,
1087         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1088           [
1089           have_bz2=yes
1090           ZLIBS="$ZLIBS -lbz2"
1091           AC_DEFINE(HAVE_BZIP2,1,
1092                   [Defined if the bz2 compression library is available])
1093           ],
1094           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1095           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1096   fi
1097 fi
1098 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1099 AC_SUBST(ZLIBS)
1100
1101
1102 # Check for readline support
1103 GNUPG_CHECK_READLINE
1104
1105 # See wether we want to run the long test suite.
1106 AC_ARG_WITH(pkits-tests,
1107     AC_HELP_STRING([--with-pkits-tests],[run the PKITS based tests]),
1108     [run_pkits_tests=$withval], [run_pkits_tests=no])
1109 AM_CONDITIONAL(RUN_PKITS_TESTS, test "$run_pkits_tests" = "yes")
1110
1111 #
1112 # Allow users to append something to the version string without
1113 # flagging it as development version.  The user version parts is
1114 # considered everything after a dash. 
1115 #
1116 if test "$development_version" != yes; then
1117   changequote(,)dnl
1118   tmp_pat='[a-zA-Z]'
1119   changequote([,])dnl
1120   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1121     development_version=yes
1122   fi
1123 fi
1124 if test "$development_version" = yes; then
1125     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1126             [Defined if this is not a regular release])
1127 fi
1128
1129 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1130
1131 GNUPG_CHECK_GNUMAKE
1132
1133 # Add some extra libs here so that previous tests don't fail for
1134 # mysterious reasons - the final link step should bail out. 
1135 if test "$have_w32_system" = yes; then
1136    NETLIBS="${NETLIBS} -lwsock32"
1137 fi
1138
1139 AC_SUBST(NETLIBS)
1140
1141
1142 #
1143 # Setup gcc specific options
1144 #
1145 if test "$GCC" = yes; then
1146     # Note that it is okay to use CFLAGS here because this are just
1147     # warning options and the user should have a chance of overriding
1148     # them.
1149     if test "$USE_MAINTAINER_MODE" = "yes"; then
1150         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1151         CFLAGS="$CFLAGS -Wno-format-y2k -Wformat-security -Wformat-nonliteral"
1152     else
1153         CFLAGS="$CFLAGS -Wall"
1154     fi
1155
1156     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1157     _gcc_cflags_save=$CFLAGS
1158     CFLAGS="-Wno-pointer-sign"
1159     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1160     AC_MSG_RESULT($_gcc_psign)
1161     CFLAGS=$_gcc_cflags_save;
1162     if test x"$_gcc_psign" = xyes ; then
1163        CFLAGS="$CFLAGS -Wno-pointer-sign"
1164     fi
1165 fi
1166
1167
1168 #
1169 # This is handy for debugging so the compiler doesn't rearrange
1170 # things and eliminate variables.
1171 #
1172 AC_ARG_ENABLE(optimization,
1173    AC_HELP_STRING([--disable-optimization],
1174                   [disable compiler optimization]),
1175                   [if test $enableval = no ; then
1176                       CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]]//'`
1177                    fi])
1178
1179 #
1180 # For W32 we need to use our Pth emulation code
1181 #
1182 if test "$have_w32_system" = yes; then
1183   AC_CONFIG_LINKS(pth.h:jnlib/w32-pth.h)
1184 fi
1185
1186
1187 #
1188 # Decide what to build
1189 #
1190 missing_pth=no
1191 if test $have_ksba = no; then
1192   build_gpgsm=no
1193   build_scdaemon=no
1194 fi
1195
1196 build_agent_threaded=""
1197 if test "$build_agent" = "yes"; then
1198   if test $have_pth = no; then
1199      build_agent_threaded="(not multi-threaded)"
1200      missing_pth=yes
1201   fi
1202 fi
1203
1204 build_scdaemon_extra=""
1205 if test "$build_scdaemon" = "yes"; then
1206   tmp=""
1207   if test $have_pth = no; then
1208      build_scdaemon_extra="not multi-threaded"
1209      tmp=", "
1210      missing_pth=yes
1211   fi
1212   if test $have_libusb = no; then
1213      build_scdaemon_extra="${tmp}without internal CCID driver"
1214      tmp=", "
1215   fi
1216   if test -n "$build_scdaemon_extra"; then
1217      build_scdaemon_extra="(${build_scdaemon_extra})"
1218   fi
1219 fi
1220
1221
1222 if test "$build_agent_only" = "yes" ; then
1223   build_gpg=no
1224   build_gpgsm=no
1225   build_scdaemon=no
1226   build_tools=no
1227   build_doc=no
1228 fi
1229
1230
1231 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1232 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1233 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1234 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1235 AM_CONDITIONAL(BUILD_TOOLS, test "$build_tools" = "yes")
1236 AM_CONDITIONAL(BUILD_DOC,   test "$build_doc" = "yes")
1237 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1238
1239 AM_CONDITIONAL(RUN_GPG_TESTS,
1240         test x$cross_compiling = xno -a "$build_gpg" = yes )
1241
1242
1243 #
1244 # Print errors here so that they are visible all
1245 # together and the user can acquire them all together.
1246 #
1247 die=no
1248 if test "$have_gpg_error" = "no"; then
1249    die=yes
1250    AC_MSG_NOTICE([[
1251 ***  
1252 *** You need libgpg-error to build this program.
1253 **  This library is for example available at
1254 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1255 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1256 ***]])
1257 fi
1258 if test "$have_libgcrypt" = "no"; then
1259    die=yes
1260    AC_MSG_NOTICE([[
1261 ***  
1262 *** You need libgcrypt to build this program.
1263 **  This library is for example available at
1264 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1265 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API is required.)
1266 ***]])
1267 fi
1268 if test "$have_libassuan" = "no"; then
1269    die=yes
1270    AC_MSG_NOTICE([[
1271 ***
1272 *** You need libassuan with Pth support to build this program.
1273 *** This library is for example available at
1274 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1275 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1276 ***]])
1277 fi
1278 if test "$have_ksba" = "no"; then
1279     AC_MSG_NOTICE([[
1280 ***
1281 *** You need libksba to build this program.
1282 *** This library is for example available at
1283 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1284 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1285 ***]])
1286 fi
1287 if test "$missing_pth" = "yes"; then
1288     AC_MSG_NOTICE([[
1289 ***
1290 *** It is now required to build with support for the
1291 *** GNU Portable Threads Library (Pth). Please install this
1292 *** library first.  The library is for example available at
1293 ***   ftp://ftp.gnu.org/gnu/pth/
1294 *** On a Debian GNU/Linux system you can install it using 
1295 ***   apt-get install libpth-dev
1296 ***]])
1297    die=yes
1298 fi
1299
1300 if test "$die" = "yes"; then
1301     AC_MSG_ERROR([[
1302 ***
1303 *** Required libraries not found. Please consult the above messages
1304 *** and install them before running configure again.
1305 ***]])
1306 fi
1307
1308
1309
1310 AC_CONFIG_FILES([ m4/Makefile 
1311 Makefile
1312 po/Makefile.in
1313 intl/Makefile
1314 gl/Makefile
1315 include/Makefile
1316 jnlib/Makefile
1317 common/Makefile
1318 kbx/Makefile
1319 g10/Makefile
1320 sm/Makefile
1321 agent/Makefile
1322 scd/Makefile
1323 keyserver/Makefile
1324 keyserver/gpgkeys_mailto
1325 keyserver/gpgkeys_test
1326 tools/gpg-zip
1327 tools/Makefile
1328 doc/Makefile
1329 tests/Makefile
1330 tests/openpgp/Makefile
1331 ])
1332 AC_OUTPUT
1333
1334 #tests/pkits/Makefile
1335
1336
1337
1338
1339 echo "
1340         GnuPG v${VERSION} has been configured as follows:
1341         
1342         Platform:  $PRINTABLE_OS_NAME ($host)
1343
1344         OpenPGP:   $build_gpg
1345         S/MIME:    $build_gpgsm
1346         Agent:     $build_agent $build_agent_threaded
1347         Smartcard: $build_scdaemon $build_scdaemon_extra
1348
1349         Protect tool:      $show_gnupg_protect_tool_pgm
1350         Default agent:     $show_gnupg_agent_pgm
1351         Default pinentry:  $show_gnupg_pinentry_pgm
1352         Default scdaemon:  $show_gnupg_scdaemon_pgm
1353         Default dirmngr:   $show_gnupg_dirmngr_pgm
1354
1355         PKITS based tests: $run_pkits_tests
1356 "
1357