Merged jnlib into common.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005,
3 #               2006, 2007, 2008, 2009 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.10"
23
24 # Remember to change the version number immediately *after* a release.
25 # Set my_issvn to "yes" for non-released code.  Remember to run an
26 # "svn up" and "autogen.sh" right before creating a distribution.
27 m4_define([my_version], [2.1.0])
28 m4_define([my_issvn], [yes])
29
30 m4_define([svn_revision], m4_esyscmd([printf "%d" $(svn info 2>/dev/null \
31           | sed -n '/^Revision:/ s/[^0-9]//gp'|head -1)]))
32 AC_INIT([gnupg], 
33         [my_version[]m4_if(my_issvn,[yes],[-svn[]svn_revision])],
34         [http://bugs.gnupg.org])
35 # Set development_version to yes if the minor number is odd or you
36 # feel that the default check for a development version is not
37 # sufficient.
38 development_version=no
39
40 NEED_GPG_ERROR_VERSION=1.4
41
42 NEED_LIBGCRYPT_API=1
43 NEED_LIBGCRYPT_VERSION=1.4.0
44
45 NEED_LIBASSUAN_API=2
46 NEED_LIBASSUAN_VERSION=2.0.0
47
48 NEED_KSBA_API=1
49 NEED_KSBA_VERSION=1.0.2
50
51
52 PACKAGE=$PACKAGE_NAME
53 PACKAGE_GT=${PACKAGE_NAME}2
54 VERSION=$PACKAGE_VERSION
55
56 AC_CONFIG_AUX_DIR(scripts)
57 AC_CONFIG_SRCDIR(sm/gpgsm.c)
58 AM_CONFIG_HEADER(config.h)
59 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
60 AC_CANONICAL_HOST
61 AB_INIT
62
63 AC_GNU_SOURCE
64
65 # Some status variables.
66 have_gpg_error=no
67 have_libgcrypt=no 
68 have_libassuan=no
69 have_ksba=no
70 have_pth=no
71 have_libusb=no
72 have_adns=no
73
74 use_bzip2=yes
75 use_exec=yes
76 disable_keyserver_path=no
77 use_ccid_driver=yes
78
79 GNUPG_BUILD_PROGRAM(gpg, yes)
80 GNUPG_BUILD_PROGRAM(gpgsm, yes)
81 GNUPG_BUILD_PROGRAM(agent, yes)
82 GNUPG_BUILD_PROGRAM(scdaemon, yes)
83 GNUPG_BUILD_PROGRAM(g13, yes)
84 GNUPG_BUILD_PROGRAM(tools, yes)
85 GNUPG_BUILD_PROGRAM(doc, yes)
86 GNUPG_BUILD_PROGRAM(symcryptrun, no)
87
88 AC_SUBST(PACKAGE)
89 AC_SUBST(PACKAGE_GT)
90 AC_SUBST(VERSION)
91 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
92 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
93                                 [Name of this package for gettext])
94 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
95 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
96                                         [Bug report address])
97 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
98                                        [Required version of Libgcrypt])
99 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
100                                        [Required version of Libksba])
101
102
103
104 # The default is to use the modules from this package and the few
105 # other packages in a standard place; i.e where this package gets
106 # installed.  With these options it is possible to override these
107 # ${prefix} depended values with fixed paths, which can't be replaced
108 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
109 AC_ARG_WITH(agent-pgm,
110     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
111           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
112 AC_SUBST(GNUPG_AGENT_PGM)
113 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
114 show_gnupg_agent_pgm="(default)"
115 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
116
117 AC_ARG_WITH(pinentry-pgm,
118     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
119           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
120 AC_SUBST(GNUPG_PINENTRY_PGM)
121 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
122 show_gnupg_pinentry_pgm="(default)"
123 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
124
125
126 AC_ARG_WITH(scdaemon-pgm,
127     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
128           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
129 AC_SUBST(GNUPG_SCDAEMON_PGM)
130 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
131 show_gnupg_scdaemon_pgm="(default)"
132 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
133
134
135 AC_ARG_WITH(dirmngr-pgm,
136     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
137           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
138 AC_SUBST(GNUPG_DIRMNGR_PGM)
139 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
140 show_gnupg_dirmngr_pgm="(default)"
141 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
142
143 AC_ARG_WITH(protect-tool-pgm,
144     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
145           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
146 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
147 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
148 show_gnupg_protect_tool_pgm="(default)"
149 test -n "$GNUPG_PROTECT_TOOL_PGM" \
150       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
151
152
153 # Some folks want to use only the agent from this packet.  Make it
154 # easier for them by providing the configure option
155 # --enable-only-agent.
156 AC_ARG_ENABLE(agent-only,
157     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
158     build_agent_only=$enableval)
159
160 # SELinux support includes tracking of sensitive files to avoid
161 # leaking their contents through processing these files by gpg itself
162 AC_MSG_CHECKING([whether SELinux support is requested])
163 AC_ARG_ENABLE(selinux-support,
164               AC_HELP_STRING([--enable-selinux-support],
165                              [enable SELinux support]),
166               selinux_support=$enableval, selinux_support=no)
167 AC_MSG_RESULT($selinux_support)
168
169 # Allow disabling of bzib2 support.
170 # It is defined only after we confirm the library is available later
171 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
172 AC_ARG_ENABLE(bzip2,
173    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
174    use_bzip2=$enableval)
175 AC_MSG_RESULT($use_bzip2)
176
177 # Configure option to allow or disallow execution of external
178 # programs, like a photo viewer.
179 AC_MSG_CHECKING([whether to enable external program execution])
180 AC_ARG_ENABLE(exec,
181     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
182     use_exec=$enableval)
183 AC_MSG_RESULT($use_exec)
184 if test "$use_exec" = no ; then
185     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
186 fi
187
188 if test "$use_exec" = yes ; then
189   AC_MSG_CHECKING([whether to enable photo ID viewing])
190   AC_ARG_ENABLE(photo-viewers,
191       [  --disable-photo-viewers disable photo ID viewers],
192       [if test "$enableval" = no ; then
193          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
194       fi],enableval=yes)
195   gnupg_cv_enable_photo_viewers=$enableval
196   AC_MSG_RESULT($enableval)
197
198   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
199     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
200     AC_ARG_WITH(photo-viewer,
201         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
202         [if test "$withval" = yes ; then
203            withval=no
204         elif test "$withval" != no ; then
205            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
206                             [if set, restrict photo-viewer to this])
207         fi],withval=no)
208     AC_MSG_RESULT($withval)
209   fi
210
211   AC_MSG_CHECKING([whether to enable external keyserver helpers])
212   AC_ARG_ENABLE(keyserver-helpers,
213       [  --disable-keyserver-helpers  disable all external keyserver support],
214       [if test "$enableval" = no ; then
215          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
216                   [define to disable keyserver helpers])
217       fi],enableval=yes)
218   gnupg_cv_enable_keyserver_helpers=$enableval
219   AC_MSG_RESULT($enableval)
220
221   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
222     # LDAP is defined only after we confirm the library is available later
223     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
224     AC_ARG_ENABLE(ldap,
225       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
226       try_ldap=$enableval, try_ldap=yes)
227     AC_MSG_RESULT($try_ldap)
228
229     AC_MSG_CHECKING([whether HKP keyserver support is requested])
230     AC_ARG_ENABLE(hkp,
231       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
232       try_hkp=$enableval, try_hkp=yes)
233     AC_MSG_RESULT($try_hkp)
234
235     AC_MSG_CHECKING([whether finger key fetching support is requested])
236     AC_ARG_ENABLE(finger,
237       AC_HELP_STRING([--disable-finger],
238         [disable finger key fetching interface only]),
239       try_finger=$enableval, try_finger=yes)
240     AC_MSG_RESULT($try_finger)
241
242     AC_MSG_CHECKING([whether generic object key fetching support is requested])
243     AC_ARG_ENABLE(generic,
244       AC_HELP_STRING([--disable-generic],
245         [disable generic object key fetching interface only]),
246       try_generic=$enableval, try_generic=yes)
247     AC_MSG_RESULT($try_generic)
248
249     AC_MSG_CHECKING([whether email keyserver support is requested])
250     AC_ARG_ENABLE(mailto,
251       AC_HELP_STRING([--enable-mailto],
252         [enable email keyserver interface only]),
253       try_mailto=$enableval, try_mailto=no)
254     AC_MSG_RESULT($try_mailto)
255     fi
256
257     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
258     AC_ARG_ENABLE(keyserver-path,
259       AC_HELP_STRING([--disable-keyserver-path],
260         [disable the exec-path option for keyserver helpers]),
261       [if test "$enableval" = no ; then
262          disable_keyserver_path=yes
263       fi],enableval=yes)
264     AC_MSG_RESULT($enableval)
265   fi
266
267
268 #
269 # Check for the key/uid cache size.  This can't be zero, but can be
270 # pretty small on embedded systems.  This is used for the gpg part.
271 #
272 AC_MSG_CHECKING([for the size of the key and uid cache])
273 AC_ARG_ENABLE(key-cache,
274         AC_HELP_STRING([--enable-key-cache=SIZE],
275                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
276 if test "$enableval" = "no"; then
277    enableval=5
278 elif test "$enableval" = "yes" || test "$enableval" = ""; then
279    enableval=4096
280 fi
281 changequote(,)dnl
282 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
283 changequote([,])dnl
284 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
285    AC_MSG_ERROR([invalid key-cache size])
286 fi
287 AC_MSG_RESULT($key_cache_size)
288 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
289                   [Size of the key and UID caches])
290
291
292
293 #
294 # Check whether we want to use Linux capabilities
295 #
296 AC_MSG_CHECKING([whether use of capabilities is requested])
297 AC_ARG_WITH(capabilities,
298     [  --with-capabilities     use linux capabilities [default=no]],
299 [use_capabilities="$withval"],[use_capabilities=no])
300 AC_MSG_RESULT($use_capabilities)
301
302
303 #
304 # Allow disabling of internal CCID support.
305 # It is defined only after we confirm the library is available later
306 #
307 AC_MSG_CHECKING([whether to enable the internal CCID driver])
308 AC_ARG_ENABLE(ccid-driver,
309               AC_HELP_STRING([--disable-ccid-driver],
310                              [disable the internal CCID driver]),
311               use_ccid_driver=$enableval)
312 AC_MSG_RESULT($use_ccid_driver)
313
314
315 #
316 # To avoid double inclusion of config.h which might happen at some
317 # places, we add the usual double inclusion protection at the top of
318 # config.h.
319 #
320 AH_TOP([
321 #ifndef GNUPG_CONFIG_H_INCLUDED
322 #define GNUPG_CONFIG_H_INCLUDED
323 ])
324
325 #
326 # Stuff which goes at the bottom of config.h.
327 #
328 AH_BOTTOM([
329 /* This is the major version number of GnuPG so that
330    source included files can test for this.  Note, that
331    we use 2 here even for GnuPG 1.9.x. */
332 #define GNUPG_MAJOR_VERSION 2
333
334 /* Now to separate file name parts.
335    Please note that the string version must not contain more
336    than one character because the code assumes strlen()==1 */
337 #ifdef HAVE_DOSISH_SYSTEM
338 #define DIRSEP_C '\\'
339 #define DIRSEP_S "\\"
340 #define EXTSEP_C '.'
341 #define EXTSEP_S "."
342 #define PATHSEP_C ';'
343 #define PATHSEP_S ";"
344 #define EXEEXT_S ".exe"
345 #else
346 #define DIRSEP_C '/'
347 #define DIRSEP_S "/"
348 #define EXTSEP_C '.'
349 #define EXTSEP_S "."
350 #define PATHSEP_C ':'
351 #define PATHSEP_S ":"
352 #define EXEEXT_S ""
353 #endif
354
355 /* This is the same as VERSION, but should be overridden if the
356    platform cannot handle things like dots '.' in filenames. Set
357    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
358    uses for dots and dashes. */
359 #define SAFE_VERSION VERSION
360 #define SAFE_VERSION_DOT  '.'
361 #define SAFE_VERSION_DASH '-'
362
363 /* Some global constants. */
364 #ifdef HAVE_DRIVE_LETTERS
365 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
366 #elif defined(__VMS)
367 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg" 
368 #else
369 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
370 #endif 
371 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
372
373 /* For some systems (DOS currently), we hardcode the path here.  For
374    POSIX systems the values are constructed by the Makefiles, so that
375    the values may be overridden by the make invocations; this is to
376    comply with the GNU coding standards. */
377 #ifdef HAVE_DRIVE_LETTERS
378  /* FIXME: We need to use a function to determine these values depending 
379     on the actual installation directory. */
380 #define GNUPG_BINDIR      "c:\\gnupg"
381 #define GNUPG_LIBEXECDIR  "c:\\gnupg"
382 #define GNUPG_LIBDIR      "c:\\gnupg"
383 #define GNUPG_DATADIR     "c:\\gnupg"
384 #define GNUPG_SYSCONFDIR  "c:\\gnupg"
385 #endif
386
387 /* Derive some other constants. */
388 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
389 #define EXEC_TEMPFILE_ONLY
390 #endif
391
392
393 /* We didn't define endianness above, so get it from OS macros.  This
394    is intended for making fat binary builds on OS X. */
395 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
396 #if defined(__BIG_ENDIAN__)
397 #define BIG_ENDIAN_HOST 1
398 #elif defined(__LITTLE_ENDIAN__)
399 #define LITTLE_ENDIAN_HOST 1
400 #else
401 #error "No endianness found"
402 #endif
403 #endif
404
405
406 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
407    ldap_start_tls_s because that is the actual symbol used in the
408    library.  winldap.h redefines it to our commonly used value,
409    thus we define our usual macro here.  */
410 #ifdef HAVE_LDAP_START_TLS_SA
411 # ifndef HAVE_LDAP_START_TLS_S
412 #  define HAVE_LDAP_START_TLS_S 1
413 # endif
414 #endif
415
416
417 /* Tell libgcrypt not to use its own libgpg-error implementation. */
418 #define USE_LIBGPG_ERROR 1
419
420 /* We use jnlib, so tell other modules about it.  */
421 #define HAVE_JNLIB_LOGGING 1
422
423 /* Our HTTP code is used in estream mode.  */
424 #define HTTP_USE_ESTREAM 1
425
426 /* Under W32 we do an explicit socket initialization, thus we need to
427    avoid the on-demand initialization which would also install an atexit
428    handler.  */
429 #define HTTP_NO_WSASTARTUP
430
431 /* We always include support for the OpenPGP card.  */
432 #define ENABLE_CARD_SUPPORT 1
433
434 /* We explicitly need to disable PTH's soft mapping as Debian
435    currently enables it by default for no reason. */
436 #define PTH_SYSCALL_SOFT 0
437
438 /* We want to use the libgcrypt provided memory allocation for
439    asprintf.  */
440 #define _ESTREAM_PRINTF_MALLOC        gcry_malloc
441 #define _ESTREAM_PRINTF_FREE          gcry_free
442 #define _ESTREAM_PRINTF_EXTRA_INCLUDE "../common/util.h"
443
444 /* Under Windows we use the gettext code from libgpg-error.  */
445 #define GPG_ERR_ENABLE_GETTEXT_MACROS
446
447 #endif /*GNUPG_CONFIG_H_INCLUDED*/
448 ])
449
450
451 AM_MAINTAINER_MODE
452
453 # Checks for programs.
454 AC_MSG_NOTICE([checking for programs])
455 AC_PROG_MAKE_SET
456 AM_SANITY_CHECK
457 missing_dir=`cd $ac_aux_dir && pwd`
458 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
459 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
460 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
461 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
462 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
463 AC_PROG_AWK
464 AC_PROG_CC
465 AC_PROG_CPP
466 AM_PROG_CC_C_O
467 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
468   AC_MSG_ERROR([[No C-89 compiler found]])
469 fi
470 AC_PROG_INSTALL
471 AC_PROG_LN_S
472 AC_PROG_RANLIB
473 AC_CHECK_TOOL(AR, ar, :)
474 AC_PATH_PROG(PERL,"perl")
475 AC_CHECK_TOOL(WINDRES, windres, :)
476 AC_ISC_POSIX
477 gl_EARLY
478 AC_SYS_LARGEFILE
479 GNUPG_CHECK_FAQPROG
480 GNUPG_CHECK_USTAR
481
482 # We need to compile and run a program on the build machine.  A
483 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
484 # the AC archive is broken for autoconf 2.57.  Given that tehre is no
485 # newer version of that macro, we assume that it is also broken for
486 # autoconf 2.61 and thus we use a simple but usually sufficient
487 # approach.
488 AC_MSG_CHECKING(for cc for build)
489 if test "$cross_compiling" = "yes"; then
490   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
491 else
492   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
493 fi
494 AC_MSG_RESULT($CC_FOR_BUILD)
495 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
496
497
498
499 try_gettext=yes
500 have_dosish_system=no
501 have_w32_system=no
502 have_w32ce_system=no
503 use_simple_gettext=no
504 case "${host}" in
505     *-mingw32*)
506         # special stuff for Windoze NT
507         ac_cv_have_dev_random=no
508         AC_DEFINE(USE_ONLY_8DOT3,1,
509                   [set this to limit filenames to the 8.3 format])
510         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
511                   [defined if we must run on a stupid file system])
512         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
513                   [because the Unix gettext has too much overhead on
514                    MingW32 systems and these systems lack Posix functions,
515                    we use a simplified version of gettext])
516         disable_keyserver_path=yes
517         have_dosish_system=yes
518         have_w32_system=yes
519         case "${host}" in *-mingw32ce*) have_w32ce_system=yes ;; esac
520         try_gettext="no"
521         use_simple_gettext=yes
522         ;;
523     i?86-emx-os2 | i?86-*-os2*emx )
524         # OS/2 with the EMX environment
525         ac_cv_have_dev_random=no
526         AC_DEFINE(HAVE_DRIVE_LETTERS)
527         have_dosish_system=yes
528         try_gettext="no"
529         ;;
530
531     i?86-*-msdosdjgpp*)
532         # DOS with the DJGPP environment
533         ac_cv_have_dev_random=no
534         AC_DEFINE(HAVE_DRIVE_LETTERS)
535         have_dosish_system=yes
536         try_gettext="no"
537         ;;
538
539     *-*-freebsd*)
540        # FreeBSD
541        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
542        LDFLAGS="$LDFLAGS -L/usr/local/lib"
543        ;;
544
545     *-*-hpux*)
546         if test -z "$GCC" ; then
547             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
548         fi
549         ;;
550     *-dec-osf4*)
551         if test -z "$GCC" ; then
552             # Suppress all warnings
553             # to get rid of the unsigned/signed char mismatch warnings.
554             CFLAGS="$CFLAGS -w"
555         fi
556         ;;
557     *-dec-osf5*)
558         if test -z "$GCC" ; then
559             # Use the newer compiler `-msg_disable ptrmismatch1' to
560             # get rid of the unsigned/signed char mismatch warnings.
561             # Using this may hide other pointer mismatch warnings, but
562             # it at least lets other warning classes through
563             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
564         fi
565         ;;
566     m68k-atari-mint)
567         ;;
568     *)
569        ;;
570 esac
571
572 if test "$have_dosish_system" = yes; then
573    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
574              [Defined if we run on some of the PCDOS like systems 
575               (DOS, Windoze. OS/2) with special properties like
576               no file modes])
577 fi
578 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
579
580 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
581
582 if test "$have_w32_system" = yes; then
583    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
584    if test "$have_w32ce_system" = yes; then
585       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
586    fi
587 fi
588 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
589 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
590
591 if test "$disable_keyserver_path" = yes; then
592     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
593               [Defined to disable exec-path for keyserver helpers])
594 fi
595
596 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
597 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
598
599 if test x"$try_hkp" = xyes ; then
600   AC_SUBST(GPGKEYS_HKP,"gpg2keys_hkp$EXEEXT")
601 fi
602
603 if test x"$try_finger" = xyes ; then
604   AC_SUBST(GPGKEYS_FINGER,"gpg2keys_finger$EXEEXT")
605 fi
606
607
608
609 #
610 # Checks for libraries.
611 #
612 AC_MSG_NOTICE([checking for libraries])
613
614
615 #
616 # libgpg-error is a library with error codes shared between GnuPG
617 # related projects.
618 #
619 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
620                   have_gpg_error=yes,have_gpg_error=no)
621
622
623 #
624 # Libgcrypt is our generic crypto library
625 #
626 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
627         have_libgcrypt=yes,have_libgcrypt=no)
628
629
630 #
631 # libassuan is used for IPC
632 #
633 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
634                   have_libassuan=yes,have_libassuan=no)
635 if test "$have_libassuan" = "yes"; then
636   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
637                      [version of the libassuan library])
638 fi
639
640
641
642 #
643 # libksba is our X.509 support library
644 #
645 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
646
647
648 #
649 # libusb allows us to use the integrated CCID smartcard reader driver.
650 #
651 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
652 if test "$use_ccid_driver" = yes ; then
653   AC_CHECK_LIB(usb, usb_bulk_write,
654                 [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
655                   AC_DEFINE(HAVE_LIBUSB,1,
656                            [defined if libusb is available])
657                   have_libusb=yes
658                ])
659   AC_CHECK_FUNCS(usb_create_match)
660 fi
661 AC_SUBST(LIBUSB_LIBS)
662
663 #
664 # Check wether it is necessary to link against libdl.
665 #
666 gnupg_dlopen_save_libs="$LIBS"
667 LIBS=""
668 AC_SEARCH_LIBS(dlopen, c dl,,,)
669 DL_LIBS=$LIBS
670 AC_SUBST(DL_LIBS)
671 LIBS="$gnupg_dlopen_save_libs"
672
673 # Checks for g13
674
675 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
676 AC_DEFINE_UNQUOTED(ENCFS,
677         "${ENCFS}", [defines the filename of the encfs program])
678
679 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
680 AC_DEFINE_UNQUOTED(FUSERMOUNT,
681         "${FUSERMOUNT}", [defines the filename of the fusermount program])
682
683 #
684 # Checks for symcryptrun:
685 #
686
687 # libutil has openpty() and login_tty().
688 AC_CHECK_LIB(util, openpty,
689               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
690                 AC_DEFINE(HAVE_LIBUTIL,1,
691                          [defined if libutil is available])
692              ])
693 AC_SUBST(LIBUTIL_LIBS)
694
695 # shred is used to clean temporary plain text files.
696 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
697 AC_DEFINE_UNQUOTED(SHRED,
698         "${SHRED}", [defines the filename of the shred program])
699
700
701 #
702 # Check whether the GNU Pth library is available
703 # Note, that we include a Pth emulation for W32.
704 #
705 GNUPG_PATH_PTH
706 if test "$have_pth" = "yes"; then
707   AC_DEFINE(USE_GNU_PTH, 1,
708               [Defined if the GNU Portable Thread Library should be used])
709 else
710   AC_MSG_WARN([[
711 ***
712 *** To support concurrent access to the gpg-agent and the SCdaemon
713 *** we need the support of the GNU Portable Threads Library.
714 *** Download it from ftp://ftp.gnu.org/gnu/pth/
715 *** On a Debian GNU/Linux system you might want to try 
716 ***   apt-get install libpth-dev
717 ***]])
718 fi
719
720
721 AC_MSG_NOTICE([checking for networking options])
722
723 #
724 # Must check for network library requirements before doing link tests
725 # for ldap, for example. If ldap libs are static (or dynamic and without
726 # ELF runtime link paths), then link will fail and LDAP support won't
727 # be detected.
728 #
729 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
730         [NETLIBS="-lnsl $NETLIBS"]))
731 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
732         [NETLIBS="-lsocket $NETLIBS"]))
733
734
735 #
736 # Check for ADNS.
737 #
738 _cppflags="${CPPFLAGS}"
739 _ldflags="${LDFLAGS}"
740 AC_ARG_WITH(adns,
741             AC_HELP_STRING([--with-adns=DIR],
742                            [look for the adns library in DIR]),
743             [if test -d "$withval"; then
744                CPPFLAGS="${CPPFLAGS} -I$withval/include"
745                LDFLAGS="${LDFLAGS} -L$withval/lib"
746              fi])
747 if test "$with_adns" != "no"; then
748   AC_CHECK_HEADERS(adns.h,
749                 AC_CHECK_LIB(adns, adns_init,
750                              [have_adns=yes],
751                              [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}]),
752                 [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}])
753 fi
754 if test "$have_adns" = "yes"; then
755   ADNSLIBS="-ladns" 
756 fi
757 AC_SUBST(ADNSLIBS)
758 # Newer adns versions feature a free function to be used under W32.
759 AC_CHECK_FUNCS(adns_free)
760
761
762
763 #
764 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
765 #
766 if test x"$try_hkp" = xyes || test x"$try_http" = xyes ; then
767   AC_ARG_ENABLE(dns-srv,
768      AC_HELP_STRING([--disable-dns-srv],
769                     [disable the use of DNS SRV in HKP and HTTP]),
770                 use_dns_srv=$enableval,use_dns_srv=yes)
771 fi
772
773 AC_ARG_ENABLE(dns-pka,
774    AC_HELP_STRING([--disable-dns-pka],
775         [disable the use of PKA records in DNS]),
776    use_dns_pka=$enableval,use_dns_pka=yes)
777
778 AC_ARG_ENABLE(dns-cert,
779    AC_HELP_STRING([--disable-dns-cert],
780         [disable the use of CERT records in DNS]),
781    use_dns_cert=$enableval,use_dns_cert=yes)
782
783 if test x"$use_dns_pka" = xyes || test x"$use_dns_srv" = xyes \
784    || test x"$use_dns_cert" = xyes; then
785   _dns_save_libs=$LIBS
786   LIBS=""
787   # the double underscore thing is a glibc-ism?
788   AC_SEARCH_LIBS(res_query,resolv bind,,
789                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
790   AC_SEARCH_LIBS(dn_expand,resolv bind,,
791                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
792   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
793                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
794
795   if test x"$have_resolver" != xno ; then
796
797     # Make sure that the BIND 4 resolver interface is workable before
798     # enabling any code that calls it.  At some point I'll rewrite the
799     # code to use the BIND 8 resolver API.
800     # We might also want to use adns instead.  Problem with ADNS is that
801     # it does not support v6.
802
803     AC_MSG_CHECKING([whether the resolver is usable])
804     AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
805 #include <netinet/in.h>
806 #include <arpa/nameser.h>
807 #include <resolv.h>],
808 [[unsigned char answer[PACKETSZ];
809   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
810   dn_skipname(0,0); 
811   dn_expand(0,0,0,0,0);
812 ]])],have_resolver=yes,have_resolver=no)
813     AC_MSG_RESULT($have_resolver)
814
815     # This is Apple-specific and somewhat bizarre as they changed the
816     # define in bind 8 for some reason.
817
818     if test x"$have_resolver" != xyes ; then
819        AC_MSG_CHECKING(
820              [whether I can make the resolver usable with BIND_8_COMPAT])
821        AC_LINK_IFELSE([AC_LANG_PROGRAM([#define BIND_8_COMPAT
822 #include <sys/types.h>
823 #include <netinet/in.h>
824 #include <arpa/nameser.h>
825 #include <resolv.h>],
826 [[unsigned char answer[PACKETSZ];
827   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
828   dn_skipname(0,0); dn_expand(0,0,0,0,0);
829 ]])],[have_resolver=yes ; need_compat=yes])
830        AC_MSG_RESULT($have_resolver)
831     fi
832   fi
833
834   if test x"$have_resolver" = xyes ; then
835      DNSLIBS=$LIBS
836
837      if test x"$use_dns_srv" = xyes ; then
838         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
839      fi
840
841      if test x"$use_dns_pka" = xyes ; then
842         AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
843      fi
844
845      if test x"$use_dns_cert" = xyes ; then
846         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
847      fi
848
849      if test x"$need_compat" = xyes ; then
850         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
851      fi
852   else
853      # If we have no resolver library but ADNS (e.g. under W32) enable the
854      # code parts which can be used with ADNS.
855      if test x"$have_adns" = xyes ; then
856         DNSLIBS="$ADNSLIBS"
857         AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
858
859         if test x"$use_dns_srv" = xyes ; then
860            AC_DEFINE(USE_DNS_SRV,1)
861         fi
862
863         if test x"$use_dns_pka" = xyes ; then
864            AC_DEFINE(USE_DNS_PKA,1)
865         fi
866
867         if test x"$use_dns_cert" = xyes ; then
868            AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
869         fi
870      else
871         use_dns_srv=no
872         use_dns_pka=no
873         use_dns_cert=no
874      fi
875   fi
876
877   LIBS=$_dns_save_libs
878 fi
879
880 AC_SUBST(DNSLIBS)
881
882 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
883
884
885 #
886 # Check for LDAP
887 #
888 if test "$try_ldap" = yes ; then
889    GNUPG_CHECK_LDAP($NETLIBS)
890 fi
891
892 #
893 # Check for curl.  We fake the curl API if libcurl isn't installed.
894 # We require 7.10 or later as we use curl_version_info().
895 #
896 LIBCURL_CHECK_CONFIG([yes],[7.10],,[fake_curl=yes])
897 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
898
899 # Generic, for us, means curl
900
901 if test x"$try_generic" = xyes ; then
902    AC_SUBST(GPGKEYS_CURL,"gpg2keys_curl$EXEEXT")
903 fi
904
905 #
906 # Check for sendmail
907 #
908 # This isn't necessarily sendmail itself, but anything that gives a
909 # sendmail-ish interface to the outside world.  That includes Exim,
910 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
911 if test "$try_mailto" = yes ; then
912   AC_ARG_WITH(mailprog,
913       AC_HELP_STRING([--with-mailprog=NAME],
914                      [use "NAME -t" for mail transport]),
915              ,with_mailprog=yes)
916
917   if test x"$with_mailprog" = xyes ; then
918     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
919     if test "$ac_cv_path_SENDMAIL" ; then
920       GPGKEYS_MAILTO="gpg2keys_mailto"
921     fi
922   elif test x"$with_mailprog" != xno ; then
923     AC_MSG_CHECKING([for a mail transport program])
924     AC_SUBST(SENDMAIL,$with_mailprog)
925     AC_MSG_RESULT($with_mailprog)
926     GPGKEYS_MAILTO="gpg2keys_mailto"
927   fi
928 fi
929
930 AC_SUBST(GPGKEYS_MAILTO)
931
932 #
933 # Construct a printable name of the OS
934 #
935 case "${host}" in
936     *-mingw32ce*)
937         PRINTABLE_OS_NAME="W32CE"
938         ;;
939     *-mingw32*)
940         PRINTABLE_OS_NAME="MingW32"
941         ;;
942     *-*-cygwin*)
943         PRINTABLE_OS_NAME="Cygwin"
944         ;;
945     i?86-emx-os2 | i?86-*-os2*emx )
946         PRINTABLE_OS_NAME="OS/2"
947         ;;
948     i?86-*-msdosdjgpp*)
949         PRINTABLE_OS_NAME="MSDOS/DJGPP"
950         try_dynload=no
951         ;;
952     *-linux*)
953         PRINTABLE_OS_NAME="GNU/Linux"
954         ;;
955     *)
956         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
957         ;;
958 esac
959 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
960                    [A human readable text with the name of the OS])
961
962
963 #
964 # Checking for iconv
965 #
966 AM_ICONV
967
968
969 #
970 # Check for gettext
971 #
972 # This is "GNU gnupg" - The project-id script from gettext
973 #                       needs this string
974 #
975 AC_MSG_NOTICE([checking for gettext])
976 AM_PO_SUBDIRS
977 AM_GNU_GETTEXT_VERSION([0.17])
978 if test "$try_gettext" = yes; then
979   AM_GNU_GETTEXT([external],[need-ngettext])
980
981   # gettext requires some extra checks.  These really should be part of
982   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
983   # function checks to here.
984
985   AC_CHECK_FUNCS(strchr)
986 else
987   USE_NLS=no
988   USE_INCLUDED_LIBINTL=no
989   BUILD_INCLUDED_LIBINTL=no
990   POSUB=po
991   AC_SUBST(USE_NLS)
992   AC_SUBST(USE_INCLUDED_LIBINTL)
993   AC_SUBST(BUILD_INCLUDED_LIBINTL)
994   AC_SUBST(POSUB)
995 fi
996
997 # We use HAVE_LANGINFO_CODESET in a couple of places.
998 AM_LANGINFO_CODESET
999
1000 # Checks required for our use locales
1001 gt_LC_MESSAGES
1002
1003
1004 #
1005 # SELinux support
1006 #
1007 if test "$selinux_support" = yes ; then
1008   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1009 fi
1010
1011
1012 #
1013 # Checks for header files.
1014 #
1015 AC_MSG_NOTICE([checking for header files])
1016 AC_HEADER_STDC
1017 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1018                   pty.h pwd.h inttypes.h signal.h])
1019 AC_HEADER_TIME
1020
1021
1022 #
1023 # Checks for typedefs, structures, and compiler characteristics.
1024 #
1025 AC_MSG_NOTICE([checking for system characteristics])
1026 AC_C_CONST
1027 AC_C_INLINE
1028 AC_C_VOLATILE
1029 AC_TYPE_SIZE_T
1030 AC_TYPE_MODE_T
1031 AC_TYPE_SIGNAL
1032 AC_DECL_SYS_SIGLIST
1033
1034 gl_HEADER_SYS_SOCKET
1035 gl_TYPE_SOCKLEN_T
1036
1037 AC_ARG_ENABLE(endian-check,
1038               AC_HELP_STRING([--disable-endian-check],
1039               [disable the endian check and trust the OS provided macros]),
1040               endiancheck=$enableval,endiancheck=yes)
1041
1042 if test x"$endiancheck" = xyes ; then
1043   GNUPG_CHECK_ENDIAN
1044 fi
1045
1046 # fixme: we should get rid of the byte type
1047 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1048 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1049 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1050 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1051 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1052
1053 AC_CHECK_SIZEOF(unsigned short)
1054 AC_CHECK_SIZEOF(unsigned int)
1055 AC_CHECK_SIZEOF(unsigned long)
1056 AC_CHECK_SIZEOF(unsigned long long)
1057 AC_CHECK_SIZEOF(time_t,,[[
1058 #include <stdio.h>
1059 #if TIME_WITH_SYS_TIME
1060 # include <sys/time.h>
1061 # include <time.h>
1062 #else
1063 # if HAVE_SYS_TIME_H
1064 #  include <sys/time.h>
1065 # else
1066 #  include <time.h>
1067 # endif
1068 #endif
1069 ]])
1070
1071
1072 # Ensure that we have UINT64_C before we bother to check for uint64_t
1073 # Fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
1074 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
1075    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
1076        uint64_t foo=UINT64_C(42);]),
1077      gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
1078 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
1079    AC_CHECK_SIZEOF(uint64_t)
1080 fi
1081
1082 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1083    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1084    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1085     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1086 fi
1087
1088
1089 #
1090 # Checks for library functions.
1091 #
1092 AC_MSG_NOTICE([checking for library functions])
1093 AC_CHECK_DECLS(getpagesize)
1094 AC_FUNC_FSEEKO
1095 AC_FUNC_VPRINTF
1096 AC_FUNC_FORK
1097 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap])
1098 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r])
1099 AC_CHECK_FUNCS([unsetenv fcntl ftruncate])
1100 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1101 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1102 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe stat getaddrinfo])
1103 AC_CHECK_FUNCS([ttyname rand ftello fsync])
1104
1105 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1106
1107 #
1108 # These are needed by the jnlib parts in common.
1109 # Note:  We already checked pwd.h.
1110 AC_CHECK_HEADERS([signal.h])
1111 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1112                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1113                 flockfile funlockfile fopencookie funopen getpwnam getpwuid \
1114                 getenv ])
1115
1116 #
1117 # gnulib checks
1118 #
1119 gl_SOURCE_BASE([gl])
1120 gl_M4_BASE([gl/m4])
1121 gl_MODULES([setenv mkdtemp xsize strpbrk])
1122 gl_INIT
1123
1124
1125 #
1126 # W32 specific test
1127 #
1128 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1129
1130 #
1131 # Sanity check regex.  Tests adapted from mutt.
1132 #
1133 AC_MSG_CHECKING([whether regular expression support is requested])
1134 AC_ARG_ENABLE(regex,
1135   AC_HELP_STRING([--disable-regex],
1136     [do not handle regular expressions in trust signatures]),
1137   use_regex=$enableval, use_regex=yes)
1138 AC_MSG_RESULT($use_regex)
1139
1140 if test "$use_regex" = yes ; then
1141   _cppflags="${CPPFLAGS}"
1142   _ldflags="${LDFLAGS}"
1143   AC_ARG_WITH(regex,
1144      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1145       [
1146       if test -d "$withval" ; then
1147         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1148         LDFLAGS="${LDFLAGS} -L$withval/lib"
1149       fi
1150       ],withval="")     
1151
1152   # Does the system have regex functions at all?
1153   AC_SEARCH_LIBS([regcomp], [regex])
1154   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1155
1156   if test $gnupg_cv_have_regex = no; then
1157     use_regex=no
1158   else
1159     if test x"$cross_compiling" = xyes; then
1160       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1161     else
1162       AC_CACHE_CHECK([whether your system's regexp library is broken],
1163        [gnupg_cv_regex_broken],
1164        AC_TRY_RUN([
1165 #include <unistd.h>
1166 #include <regex.h>
1167 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1168        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1169
1170       if test $gnupg_cv_regex_broken = yes; then
1171         AC_MSG_WARN([your regex is broken - disabling regex use])
1172         use_regex=no
1173       fi
1174     fi
1175   fi
1176   CPPFLAGS="${_cppflags}"
1177   LDFLAGS="${_ldflags}"
1178 fi
1179
1180 if test "$use_regex" != yes ; then
1181   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1182 fi
1183 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1184
1185
1186
1187 #
1188 # Do we have zlib? Must do it here because Solaris failed
1189 # when compiling a conftest (due to the "-lz" from LIBS).
1190 # Note that we combine zlib and bzlib2 in ZLIBS.
1191 #
1192 _cppflags="${CPPFLAGS}"
1193 _ldflags="${LDFLAGS}"
1194 AC_ARG_WITH(zlib,
1195   [  --with-zlib=DIR         use libz in DIR],[
1196     if test -d "$withval"; then
1197       CPPFLAGS="${CPPFLAGS} -I$withval/include"
1198       LDFLAGS="${LDFLAGS} -L$withval/lib"
1199     fi
1200   ])
1201
1202 AC_CHECK_HEADER(zlib.h,
1203       AC_CHECK_LIB(z, deflateInit2_,
1204        ZLIBS="-lz",
1205        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1206        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1207
1208 #
1209 # Check whether we can support bzip2
1210
1211 if test "$use_bzip2" = yes ; then
1212   _cppflags="${CPPFLAGS}"
1213   _ldflags="${LDFLAGS}"
1214   AC_ARG_WITH(bzip2,
1215      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1216       [
1217       if test -d "$withval" ; then
1218         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1219         LDFLAGS="${LDFLAGS} -L$withval/lib"
1220       fi
1221       ],withval="")
1222
1223   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1224   # required stdio.h to be included before bzlib.h, and Solaris 9 is 
1225   # woefully out of date.
1226   if test "$withval" != no ; then
1227      AC_CHECK_HEADER(bzlib.h,
1228         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1229           [
1230           have_bz2=yes
1231           ZLIBS="$ZLIBS -lbz2"
1232           AC_DEFINE(HAVE_BZIP2,1,
1233                   [Defined if the bz2 compression library is available])
1234           ],
1235           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1236           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1237   fi
1238 fi
1239 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1240 AC_SUBST(ZLIBS)
1241
1242
1243 # Check for readline support
1244 GNUPG_CHECK_READLINE
1245
1246 #
1247 # Allow users to append something to the version string without
1248 # flagging it as development version.  The user version parts is
1249 # considered everything after a dash. 
1250 #
1251 if test "$development_version" != yes; then
1252   changequote(,)dnl
1253   tmp_pat='[a-zA-Z]'
1254   changequote([,])dnl
1255   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1256     development_version=yes
1257   fi
1258 fi
1259 if test "$development_version" = yes; then
1260     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1261             [Defined if this is not a regular release])
1262 fi
1263
1264 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1265
1266 GNUPG_CHECK_GNUMAKE
1267
1268 # Add some extra libs here so that previous tests don't fail for
1269 # mysterious reasons - the final link step should bail out.
1270 # W32SOCKLIBS is also defined so that if can be used for tools not
1271 # requiring any network stuff but linking to code in libcommon which
1272 # tracks in winsock stuff (e.g. init_common_subsystems.
1273 if test "$have_w32_system" = yes; then
1274    W32SOCKLIBS="-lws2_32"
1275    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1276 fi
1277
1278 AC_SUBST(NETLIBS)
1279 AC_SUBST(W32SOCKLIBS)
1280
1281 #
1282 # Setup gcc specific options
1283 #
1284 AC_MSG_NOTICE([checking for cc features])
1285 if test "$GCC" = yes; then
1286     # Note that it is okay to use CFLAGS here because this are just
1287     # warning options and the user should have a chance of overriding
1288     # them.
1289     if test "$USE_MAINTAINER_MODE" = "yes"; then
1290         CFLAGS="$CFLAGS -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1291         CFLAGS="$CFLAGS -Wformat -Wno-format-y2k -Wformat-security"
1292         AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1293         _gcc_cflags_save=$CFLAGS
1294         CFLAGS="-Wno-missing-field-initializers"
1295         AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_wopt=yes,_gcc_wopt=no)
1296         AC_MSG_RESULT($_gcc_wopt)
1297         CFLAGS=$_gcc_cflags_save;
1298         if test x"$_gcc_wopt" = xyes ; then
1299           CFLAGS="$CFLAGS -W -Wno-sign-compare -Wno-missing-field-initializers"
1300         fi
1301         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1302         _gcc_cflags_save=$CFLAGS
1303         CFLAGS="-Wdeclaration-after-statement"
1304         AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_wopt=yes,_gcc_wopt=no)
1305         AC_MSG_RESULT($_gcc_wopt)
1306         CFLAGS=$_gcc_cflags_save;
1307         if test x"$_gcc_wopt" = xyes ; then
1308           CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1309         fi
1310     else
1311         CFLAGS="$CFLAGS -Wall"
1312     fi
1313
1314     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1315     _gcc_cflags_save=$CFLAGS
1316     CFLAGS="-Wno-pointer-sign"
1317     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1318     AC_MSG_RESULT($_gcc_psign)
1319     CFLAGS=$_gcc_cflags_save;
1320     if test x"$_gcc_psign" = xyes ; then
1321        CFLAGS="$CFLAGS -Wno-pointer-sign"
1322     fi
1323
1324     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1325     _gcc_cflags_save=$CFLAGS
1326     CFLAGS="-Wpointer-arith"
1327     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1328     AC_MSG_RESULT($_gcc_psign)
1329     CFLAGS=$_gcc_cflags_save;
1330     if test x"$_gcc_psign" = xyes ; then
1331        CFLAGS="$CFLAGS -Wpointer-arith"
1332     fi
1333 fi
1334
1335
1336 #
1337 # This is handy for debugging so the compiler doesn't rearrange
1338 # things and eliminate variables.
1339 #
1340 AC_ARG_ENABLE(optimization,
1341    AC_HELP_STRING([--disable-optimization],
1342                   [disable compiler optimization]),
1343                   [if test $enableval = no ; then
1344                       CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]]//'`
1345                    fi])
1346
1347 #
1348 # Prepare building of estream
1349 #
1350 estream_INIT
1351
1352
1353 #
1354 # Decide what to build
1355 #
1356 if test "$have_adns" = "yes"; then
1357   AC_SUBST(GPGKEYS_KDNS, "gpg2keys_kdns$EXEEXT")
1358 fi
1359
1360
1361 missing_pth=no
1362 if test $have_ksba = no; then
1363   build_gpgsm=no
1364   build_scdaemon=no
1365 fi
1366
1367 build_agent_threaded=""
1368 if test "$build_agent" = "yes"; then
1369   if test $have_pth = no; then
1370      build_agent_threaded="(not multi-threaded)"
1371      missing_pth=yes
1372   fi
1373 fi
1374
1375 build_scdaemon_extra=""
1376 if test "$build_scdaemon" = "yes"; then
1377   tmp=""
1378   if test $have_pth = no; then
1379      build_scdaemon_extra="not multi-threaded"
1380      tmp=", "
1381      missing_pth=yes
1382   fi
1383   if test $have_libusb = no; then
1384      build_scdaemon_extra="${tmp}without internal CCID driver"
1385      tmp=", "
1386   fi
1387   if test -n "$build_scdaemon_extra"; then
1388      build_scdaemon_extra="(${build_scdaemon_extra})"
1389   fi
1390 fi
1391
1392
1393 if test "$build_agent_only" = "yes" ; then
1394   build_gpg=no
1395   build_gpgsm=no
1396   build_scdaemon=no
1397   build_tools=no
1398   build_doc=no
1399 fi
1400
1401
1402 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1403 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1404 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1405 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1406 AM_CONDITIONAL(BUILD_G13,   test "$build_g13" = "yes")
1407 AM_CONDITIONAL(BUILD_TOOLS, test "$build_tools" = "yes")
1408 AM_CONDITIONAL(BUILD_DOC,   test "$build_doc" = "yes")
1409 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1410
1411 AM_CONDITIONAL(RUN_GPG_TESTS,
1412         test x$cross_compiling = xno -a "$build_gpg" = yes )
1413
1414
1415 #
1416 # Print errors here so that they are visible all
1417 # together and the user can acquire them all together.
1418 #
1419 die=no
1420 if test "$have_gpg_error" = "no"; then
1421    die=yes
1422    AC_MSG_NOTICE([[
1423 ***  
1424 *** You need libgpg-error to build this program.
1425 **  This library is for example available at
1426 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1427 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1428 ***]])
1429 fi
1430 if test "$have_libgcrypt" = "no"; then
1431    die=yes
1432    AC_MSG_NOTICE([[
1433 ***  
1434 *** You need libgcrypt to build this program.
1435 **  This library is for example available at
1436 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1437 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API is required.)
1438 ***]])
1439 fi
1440 if test "$have_libassuan" = "no"; then
1441    die=yes
1442    AC_MSG_NOTICE([[
1443 ***
1444 *** You need libassuan to build this program.
1445 *** This library is for example available at
1446 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1447 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1448 ***]])
1449 fi
1450 if test "$have_ksba" = "no"; then
1451     AC_MSG_NOTICE([[
1452 ***
1453 *** You need libksba to build this program.
1454 *** This library is for example available at
1455 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1456 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1457 ***]])
1458 fi
1459 if test "$missing_pth" = "yes"; then
1460     AC_MSG_NOTICE([[
1461 ***
1462 *** It is now required to build with support for the
1463 *** GNU Portable Threads Library (Pth). Please install this
1464 *** library first.  The library is for example available at
1465 ***   ftp://ftp.gnu.org/gnu/pth/
1466 *** On a Debian GNU/Linux system you can install it using 
1467 ***   apt-get install libpth-dev
1468 *** To build GnuPG for Windows you need to use the W32PTH
1469 *** package; available at:
1470 ***   ftp://ftp.g10code.com/g10code/w32pth/
1471 ***]])
1472    die=yes
1473 fi
1474
1475 if test "$die" = "yes"; then
1476     AC_MSG_ERROR([[
1477 ***
1478 *** Required libraries not found. Please consult the above messages
1479 *** and install them before running configure again.
1480 ***]])
1481 fi
1482
1483
1484
1485 AC_CONFIG_FILES([ m4/Makefile 
1486 Makefile
1487 po/Makefile.in
1488 gl/Makefile
1489 include/Makefile
1490 common/Makefile
1491 kbx/Makefile
1492 g10/Makefile
1493 sm/Makefile
1494 agent/Makefile
1495 scd/Makefile
1496 g13/Makefile
1497 keyserver/Makefile
1498 keyserver/gpg2keys_mailto
1499 keyserver/gpg2keys_test
1500 tools/gpg-zip
1501 tools/Makefile
1502 doc/Makefile
1503 tests/Makefile
1504 tests/openpgp/Makefile
1505 tests/pkits/Makefile
1506 ])
1507 AC_OUTPUT
1508
1509
1510 echo "
1511         GnuPG v${VERSION} has been configured as follows:
1512         
1513         Platform:  $PRINTABLE_OS_NAME ($host)
1514
1515         OpenPGP:   $build_gpg
1516         S/MIME:    $build_gpgsm
1517         Agent:     $build_agent $build_agent_threaded
1518         Smartcard: $build_scdaemon $build_scdaemon_extra
1519         G13:       $build_g13
1520
1521
1522         Protect tool:      $show_gnupg_protect_tool_pgm
1523         Default agent:     $show_gnupg_agent_pgm
1524         Default pinentry:  $show_gnupg_pinentry_pgm
1525         Default scdaemon:  $show_gnupg_scdaemon_pgm
1526         Default dirmngr:   $show_gnupg_dirmngr_pgm
1527 "
1528 if test x"$use_regex" != xyes ; then
1529 echo "
1530         Warning: No regular expression support available.
1531                  OpenPGP trust signatures won't work.
1532                  gpg-check-pattern will not be build.
1533 "
1534 fi