2003-09-28 Timo Schulz <twoaday@freakmail.de>
[gnupg.git] / configure.ac
1 dnl Configure.ac script for GnuPG
2 dnl Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 dnl               2003 Free Software Foundation, Inc.
4 dnl
5 dnl This file is part of GnuPG.
6 dnl
7 dnl GnuPG is free software; you can redistribute it and/or modify
8 dnl it under the terms of the GNU General Public License as published by
9 dnl the Free Software Foundation; either version 2 of the License, or
10 dnl (at your option) any later version.
11 dnl 
12 dnl GnuPG is distributed in the hope that it will be useful,
13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 dnl GNU General Public License for more details.
16 dnl 
17 dnl You should have received a copy of the GNU General Public License
18 dnl along with this program; if not, write to the Free Software
19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20 dnl
21 dnl (Process this file with autoconf to produce a configure script.)
22 dnlAC_REVISION($Revision$)dnl
23
24 AC_PREREQ(2.52)
25
26 # Remember to change the version number immediately *after* a release
27 # and remove the "-cvs" or "rc" suffix immediately *before* a release.
28 AC_INIT(gnupg, 1.3.3-cvs, bug-gnupg@gnu.org)
29 # Set development_version to yes if the minor number is odd or you
30 # feel that the default check for a development version is not
31 # sufficient.
32 development_version=yes
33
34 ALL_LINGUAS="de"
35
36 AC_CONFIG_AUX_DIR(scripts)
37 AC_CONFIG_SRCDIR(g10/g10.c)
38 AC_CANONICAL_TARGET()
39 AM_INIT_AUTOMAKE
40 AM_CONFIG_HEADER(config.h)
41
42 AC_GNU_SOURCE
43
44 dnl
45 dnl  Check for random module options
46 dnl
47 AC_MSG_CHECKING([which random module to use])
48 AC_ARG_ENABLE(static-rnd,
49     [  --enable-static-rnd=[egd|unix|linux|auto]  ],
50 [use_static_rnd=$enableval], [use_static_rnd=default] )
51
52 if test "$use_static_rnd" = no; then
53     use_static_rnd=default
54 fi
55
56 case "$use_static_rnd" in
57     egd | linux | unix | default )
58       AC_MSG_RESULT($use_static_rnd)
59       ;;
60     auto )
61       AC_MSG_RESULT(automagically selected at runtime)
62       ;;
63     * )
64       AC_MSG_RESULT(invalid argument)
65       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
66       ;;
67 esac
68
69 AC_ARG_WITH(egd-socket,
70     [  --with-egd-socket=NAME  use NAME for the EGD socket],
71             egd_socket_name="$withval", egd_socket_name="" )
72 AC_DEFINE_UNQUOTED(EGD_SOCKET_NAME, "$egd_socket_name",
73                    [Define if you don't want the default EGD socket name.
74                     For details see cipher/rndegd.c])
75
76
77 dnl
78 dnl See whether the user wants to disable checking for /dev/random
79
80 AC_MSG_CHECKING([whether use of /dev/random is requested])
81 AC_ARG_ENABLE(dev-random,
82 [  --disable-dev-random    disable the use of dev random],
83     try_dev_random=$enableval, try_dev_random=yes)
84 AC_MSG_RESULT($try_dev_random)
85
86
87 dnl
88 dnl  Check other options
89 dnl
90
91 AC_MSG_CHECKING([whether assembler modules are requested])
92 AC_ARG_ENABLE(asm,
93 [  --disable-asm           do not use assembler modules],
94      try_asm_modules=$enableval, try_asm_modules=yes)
95 AC_MSG_RESULT($try_asm_modules)
96
97 AC_MSG_CHECKING([whether memory guard is requested])
98 AC_ARG_ENABLE(m-guard,
99     [  --enable-m-guard        enable memory guard facility],
100     use_m_guard=$enableval, use_m_guard=no)
101 AC_MSG_RESULT($use_m_guard)
102 if test "$use_m_guard" = yes ; then
103     AC_DEFINE(M_GUARD,1,[Define to use the (obsolete) malloc guarding feature])
104 fi
105
106 AC_MSG_CHECKING([whether OpenPGP card support is requested])
107 AC_ARG_ENABLE(card-support,
108     [  --enable-card-support   enable OpenPGP card support],
109     card_support=$enableval, card_support=no)
110 AC_MSG_RESULT($card_support)
111 if test "$card_support" = yes ; then
112     AC_DEFINE(ENABLE_CARD_SUPPORT,1,
113              [Define to include the OpenPGP card support])
114 fi
115
116 dnl See if we are disabling any algorithms or features for a smaller
117 dnl binary
118
119 try_dynload=no
120
121 use_idea=yes
122 use_cast5=yes
123 use_blowfish=yes
124 use_aes=yes
125 use_twofish=yes
126 use_sha256=yes
127 use_sha512=yes
128 use_exec=yes
129
130 AC_ARG_ENABLE(minimal,
131    AC_HELP_STRING([--enable-minimal],[build the smallest gpg binary possible]),
132    use_idea=no
133    use_cast5=no
134    use_blowfish=no
135    use_aes=no
136    use_twofish=no
137    use_sha256=no
138    use_sha512=no
139    use_exec=no)
140
141 AC_MSG_CHECKING([whether to enable the IDEA cipher])
142 AC_ARG_ENABLE(idea,
143    AC_HELP_STRING([--disable-idea],[disable the IDEA cipher]),
144    use_idea=$enableval)
145 AC_MSG_RESULT($use_idea)
146 if test x"$use_idea" = xyes ; then
147    AC_DEFINE(USE_IDEA,1,[Define to include the IDEA cipher])
148
149 # We don't need idea but some people claim that they need it for
150 # research etc., so we allow to place an idea source code into the
151 # cipher directory and statically link it if available, otherwise we
152 # link to a stub.  We don't use AC_CHECK_FILE to avoid caching.
153
154    AC_MSG_CHECKING([for idea cipher module])
155    tmp=""
156    if test -f $srcdir/cipher/idea.c; then 
157       IDEA_O=idea.o
158       tmp=idea
159    else
160       IDEA_O=idea-stub.o
161       tmp=no
162       try_dynload=yes
163    fi
164    AC_SUBST(IDEA_O)
165    AC_MSG_RESULT($tmp)
166 fi
167
168 AC_MSG_CHECKING([whether to enable the CAST5 cipher])
169 AC_ARG_ENABLE(cast5,
170    AC_HELP_STRING([--disable-cast5],[disable the CAST5 cipher]),
171    use_cast5=$enableval)
172 AC_MSG_RESULT($use_cast5)
173 if test x"$use_cast5" = xyes ; then
174    AC_DEFINE(USE_CAST5,1,[Define to include the CAST5 cipher])
175 fi
176
177 AC_MSG_CHECKING([whether to enable the BLOWFISH cipher])
178 AC_ARG_ENABLE(blowfish,
179    AC_HELP_STRING([--disable-blowfish],[disable the BLOWFISH cipher]),
180    use_blowfish=$enableval)
181 AC_MSG_RESULT($use_blowfish)
182 if test x"$use_blowfish" = xyes ; then
183    AC_DEFINE(USE_BLOWFISH,1,[Define to include the BLOWFISH cipher])
184 fi
185
186 AC_MSG_CHECKING([whether to enable the AES ciphers])
187 AC_ARG_ENABLE(aes,
188    AC_HELP_STRING([--disable-aes],[disable the AES, AES192, and AES256 ciphers]),
189    use_aes=$enableval)
190 AC_MSG_RESULT($use_aes)
191 if test x"$use_aes" = xyes ; then
192    AC_DEFINE(USE_AES,1,[Define to include the AES, AES192, and AES256 ciphers])
193 fi
194
195 AC_MSG_CHECKING([whether to enable the TWOFISH cipher])
196 AC_ARG_ENABLE(twofish,
197    AC_HELP_STRING([--disable-twofish],[disable the TWOFISH cipher]),
198    use_twofish=$enableval)
199 AC_MSG_RESULT($use_twofish)
200 if test x"$use_twofish" = xyes ; then
201    AC_DEFINE(USE_TWOFISH,1,[Define to include the TWOFISH cipher])
202 fi
203
204 AC_MSG_CHECKING([whether to enable the SHA-256 digest])
205 AC_ARG_ENABLE(sha256,
206    AC_HELP_STRING([--disable-sha256],[disable the SHA-256 digest]),
207    use_sha256=$enableval)
208 AC_MSG_RESULT($use_sha256)
209 if test x"$use_sha256" = xyes ; then
210    AC_DEFINE(USE_SHA256,1,[Define to include the SHA-256 digest])
211 fi
212
213 dnl SHA512 is defined only after we confirm 64-bit support later
214 AC_MSG_CHECKING([whether to enable the SHA-384 and SHA-512 digests])
215 AC_ARG_ENABLE(sha512,
216    AC_HELP_STRING([--disable-sha512],[disable the SHA-384 and SHA-512 digests]),
217    use_sha512=$enableval)
218 AC_MSG_RESULT($use_sha512)
219
220 AC_MSG_CHECKING([whether to enable external program execution])
221 AC_ARG_ENABLE(exec,
222     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
223     use_exec=$enableval)
224 AC_MSG_RESULT($use_exec)
225 if test "$use_exec" = no ; then
226     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
227 fi
228
229 if test "$use_exec" = yes ; then
230   AC_MSG_CHECKING([whether to enable photo ID viewing])
231   AC_ARG_ENABLE(photo-viewers,
232       [  --disable-photo-viewers disable photo ID viewers],
233       [if test "$enableval" = no ; then
234          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
235       fi],enableval=yes)
236   gnupg_cv_enable_photo_viewers=$enableval
237   AC_MSG_RESULT($enableval)
238
239   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
240     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
241     AC_ARG_WITH(photo-viewer,
242         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
243         [if test "$withval" = yes ; then
244            withval=no
245         elif test "$withval" != no ; then
246            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
247                             [if set, restrict photo-viewer to this])
248         fi],withval=no)
249     AC_MSG_RESULT($withval)
250   fi
251
252   AC_MSG_CHECKING([whether to enable external keyserver helpers])
253   AC_ARG_ENABLE(keyserver-helpers,
254       [  --disable-keyserver-helpers  disable all external keyserver support],
255       [if test "$enableval" = no ; then
256          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
257                   [define to disable keyserver helpers])
258       fi],enableval=yes)
259   gnupg_cv_enable_keyserver_helpers=$enableval
260   AC_MSG_RESULT($enableval)
261
262   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
263     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
264     AC_ARG_ENABLE(ldap,
265     [  --disable-ldap          disable LDAP keyserver interface],
266         try_ldap=$enableval, try_ldap=yes)
267     AC_MSG_RESULT($try_ldap)
268
269     AC_MSG_CHECKING([whether HKP keyserver support is requested])
270     AC_ARG_ENABLE(hkp,
271     [  --disable-hkp           disable HKP keyserver interface],
272         try_hkp=$enableval, try_hkp=yes)
273     AC_MSG_RESULT($try_hkp)
274
275     AC_MSG_CHECKING([whether email keyserver support is requested])
276     AC_ARG_ENABLE(mailto,
277     [  --disable-mailto        disable email keyserver interface],
278         try_mailto=$enableval, try_mailto=yes)
279     AC_MSG_RESULT($try_mailto)
280     fi
281
282     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
283     AC_ARG_ENABLE(keyserver-path,
284         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
285         [if test "$enableval" = no ; then
286          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
287         fi],enableval=yes)
288     AC_MSG_RESULT($enableval)
289   fi
290
291 AC_MSG_CHECKING([whether the included zlib is requested])
292 AC_ARG_WITH(included-zlib,
293     [  --with-included-zlib    use the zlib code included here],
294 [g10_force_zlib=yes], [g10_force_zlib=no] )
295 AC_MSG_RESULT($g10_force_zlib)
296
297 dnl
298 dnl Check whether we want to use Linux capabilities
299 dnl
300 AC_MSG_CHECKING([whether use of capabilities is requested])
301 AC_ARG_WITH(capabilities,
302     [  --with-capabilities     use linux capabilities [default=no]],
303 [use_capabilities="$withval"],[use_capabilities=no])
304 AC_MSG_RESULT($use_capabilities)
305
306
307 AH_BOTTOM([
308 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
309 #define EXEC_TEMPFILE_ONLY
310 #endif
311
312 #include "g10defs.h"
313 ])
314
315
316 AM_MAINTAINER_MODE
317
318 dnl Checks for programs.
319
320 AC_PROG_MAKE_SET
321 AM_SANITY_CHECK
322 missing_dir=`cd $ac_aux_dir && pwd`
323 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
324 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
325 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
326 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
327 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
328 AC_PROG_CC
329 AC_PROG_CPP
330 AC_PROG_RANLIB
331 AC_CHECK_TOOL(AR, ar, :)
332 AC_PATH_PROG(PERL,"perl")
333 AC_ISC_POSIX
334 AC_SYS_LARGEFILE
335 AC_PROG_INSTALL
336 AC_PROG_AWK
337 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
338 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
339 GNUPG_CHECK_FAQPROG
340 GNUPG_CHECK_DOCBOOK_TO_TEXI
341
342 MPI_OPT_FLAGS=""
343
344
345 try_gettext=yes
346 have_dosish_system=no
347 case "${target}" in
348     *-*-mingw32*)
349         # special stuff for Windoze NT
350         ac_cv_have_dev_random=no
351         AC_DEFINE(USE_ONLY_8DOT3,1,
352                   [set this to limit filenames to the 8.3 format])
353         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
354                   [defined if we must run on a stupid file system])
355         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
356                   [because the Unix gettext has too much overhead on
357                    MingW32 systems and these systems lack Posix functions,
358                    we use a simplified version of gettext])
359         have_dosish_system=yes
360         try_gettext="no"
361         ;;
362     i?86-emx-os2 | i?86-*-os2*emx )
363         # OS/2 with the EMX environment
364         ac_cv_have_dev_random=no
365         AC_DEFINE(HAVE_DRIVE_LETTERS)
366         have_dosish_system=yes
367         try_gettext="no"
368         ;;
369
370     i?86-*-msdosdjgpp*)
371         # DOS with the DJGPP environment
372         ac_cv_have_dev_random=no
373         AC_DEFINE(HAVE_DRIVE_LETTERS)
374         have_dosish_system=yes
375         try_gettext="no"
376         ;;
377
378     *-*-freebsd*)
379        # FreeBSD
380        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
381        LDFLAGS="$LDFLAGS -L/usr/local/lib"
382        ;;
383
384     *-*-hpux*)
385         if test -z "$GCC" ; then
386             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
387         fi
388         ;;
389     *-dec-osf4*)
390         if test -z "$GCC" ; then
391             # Suppress all warnings
392             # to get rid of the unsigned/signed char mismatch warnings.
393             CFLAGS="$CFLAGS -w"
394         fi
395         ;;
396     *-dec-osf5*)
397         if test -z "$GCC" ; then
398             # Use the newer compiler `-msg_disable ptrmismatch' to
399             # get rid of the unsigned/signed char mismatch warnings.
400             # Using this may hide other pointer mismatch warnings, but
401             # it at least lets other warning classes through
402             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
403         fi
404         ;;
405     m68k-atari-mint)
406         ;;
407     *)
408        ;;
409 esac
410
411 if test "$have_dosish_system" = yes; then
412    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
413              [defined if we run on some of the PCDOS like systems 
414               (DOS, Windoze. OS/2) with special properties like
415               no file modes])
416 fi
417 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
418
419 AC_SUBST(MPI_OPT_FLAGS)
420 GNUPG_SYS_SYMBOL_UNDERSCORE
421
422 dnl This needs to go after AC_PROG_CC so that $EXEEXT is defined
423 if test "$try_hkp" = yes ; then
424   AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
425 fi
426
427 dnl Must check for network library requirements before doing link tests
428 dnl for ldap, for example. If ldap libs are static (or dynamic and without
429 dnl ELF runtime link paths), then link will fail and LDAP support won't
430 dnl be detected.
431
432 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
433         [NETLIBS="-lnsl $NETLIBS"]))
434 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
435         [NETLIBS="-lsocket $NETLIBS"]))
436
437 dnl Now try for the resolver functions so we can use DNS SRV
438
439 AC_ARG_ENABLE(dns-srv,
440    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
441    use_dns_srv=$enableval,use_dns_srv=yes)
442
443 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
444   _srv_save_libs=$LIBS
445   LIBS=""
446   # the double underscore thing is a glibc-ism?
447   AC_SEARCH_LIBS(res_query,resolv bind,,
448                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
449   AC_SEARCH_LIBS(dn_expand,resolv bind,,
450                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
451   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
452                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
453
454   if test x"$use_dns_srv" = xyes ; then
455      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
456      SRVLIBS=$LIBS
457   else
458      AC_MSG_WARN([Resolver functions not found.  Disabling DNS SRV.])
459   fi
460   LIBS=$_srv_save_libs
461 fi
462
463 AC_SUBST(SRVLIBS)
464
465 # Try and link a LDAP test program to weed out unusable LDAP
466 # libraries.  -lldap [-llber [-lresolv]] is for OpenLDAP.  OpenLDAP in
467 # general is terrible with creating weird dependencies.  If all else
468 # fails, the user can play guess-the-dependency by using something
469 # like ./configure LDAPLIBS="-Lfoo -lbar"
470
471 if test "$try_ldap" = yes ; then
472   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
473     _ldap_save_libs=$LIBS
474     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
475
476     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
477     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
478                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
479     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
480
481     if test $gnupg_cv_func_ldap_init = no; then
482       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
483       AC_TRY_LINK([#include <lber.h>
484 #include <ldap.h>],[ldap_open("foobar",1234);],
485          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
486       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
487     fi
488
489     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
490        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
491     fi
492
493     if test "$gnupg_cv_func_ldap_init" = yes || \
494         test "$gnupg_cv_func_ldaplber_init" = yes ; then
495        LDAPLIBS=$MY_LDAPLIBS
496        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
497
498        AC_MSG_CHECKING([whether LDAP supports ldap_get_option])
499
500        if test "$gnupg_cv_func_ldap_init" = yes ; then
501           AC_TRY_LINK([#include <ldap.h>],
502              [ldap_get_option((void *)0,0,(void *)0);],
503              [gnupg_cv_func_ldap_get_option=yes],
504              [gnupg_cv_func_ldap_get_option=no])
505         else
506           AC_TRY_LINK([#include <lber.h>
507 #include <ldap.h>],[ldap_get_option((void *)0,0,(void *)0);],
508              [gnupg_cv_func_ldap_get_option=yes],
509              [gnupg_cv_func_ldap_get_option=no])
510        fi
511
512        AC_MSG_RESULT([$gnupg_cv_func_ldap_get_option])
513
514        if test "$gnupg_cv_func_ldap_get_option" = yes ; then
515           AC_DEFINE(HAVE_LDAP_GET_OPTION,1,[Define if the LDAP library has ldap_get_option])
516        else
517           AC_MSG_CHECKING([whether LDAP supports ld_errno])
518
519           if test "$gnupg_cv_func_ldap_init" = yes ; then
520             AC_TRY_COMPILE([#include <ldap.h>],
521                [LDAP *ldap; ldap->ld_errno;],
522                [gnupg_cv_func_ldap_ld_errno=yes],
523                [gnupg_cv_func_ldap_ld_errno=no])
524            else
525             AC_TRY_LINK([#include <lber.h>
526 #include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
527                [gnupg_cv_func_ldap_ld_errno=yes],
528                [gnupg_cv_func_ldap_ld_errno=no])
529           fi
530
531           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
532
533           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
534              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
535           fi
536        fi
537     fi
538
539     LIBS=$_ldap_save_libs
540
541     if test "$GPGKEYS_LDAP" != "" ; then break; fi
542   done
543 fi
544
545 AC_SUBST(GPGKEYS_LDAP)
546 AC_SUBST(LDAPLIBS)
547
548 dnl This isn't necessarily sendmail itself, but anything that gives a
549 dnl sendmail-ish interface to the outside world.  That includes qmail,
550 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
551
552 if test "$try_mailto" = yes ; then
553   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
554
555   if test "$with_mailprog" = yes ; then
556     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
557     if test "$ac_cv_path_SENDMAIL" ; then
558       GPGKEYS_MAILTO="gpgkeys_mailto"
559     fi
560   elif test "$with_mailprog" != no ; then
561     AC_MSG_CHECKING([for a mail transport program])
562     AC_SUBST(SENDMAIL,$with_mailprog)
563     AC_MSG_RESULT($with_mailprog)
564     GPGKEYS_MAILTO="gpgkeys_mailto"
565   fi
566 fi
567
568 AC_SUBST(GPGKEYS_MAILTO)
569
570 case "${target}" in
571     *-*-mingw32*)
572         PRINTABLE_OS_NAME="MingW32"
573         ;;
574     *-*-cygwin*)
575         PRINTABLE_OS_NAME="Cygwin"
576         ;;
577     i?86-emx-os2 | i?86-*-os2*emx )
578         PRINTABLE_OS_NAME="OS/2"
579         ;;
580     i?86-*-msdosdjgpp*)
581         PRINTABLE_OS_NAME="MSDOS/DJGPP"
582         try_dynload=no
583         ;;
584     *-linux*)
585         PRINTABLE_OS_NAME="GNU/Linux"
586         ;;
587 dnl let that after linux to avoid gnu-linux problems
588     *-gnu*)
589         PRINTABLE_OS_NAME="GNU/Hurd"
590         ;;
591     *)
592         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
593         ;;
594 esac
595 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
596                    [A human readable text with the name of the OS])
597
598
599 #
600 # 1. Set names of random devices
601 #
602 NAME_OF_DEV_RANDOM="/dev/random"
603 NAME_OF_DEV_URANDOM="/dev/urandom"
604 case "${target}" in
605     *-openbsd*)
606         NAME_OF_DEV_RANDOM="/dev/srandom"
607         NAME_OF_DEV_URANDOM="/dev/urandom"
608         ;;
609 esac
610 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM",
611                    [defined to the name of the strong random device])
612 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM",
613                    [defined to the name of the weaker random device])
614 AC_SUBST(MPI_OPT_FLAGS)
615
616
617 dnl Checks for libraries.
618
619 if test "$try_gettext" = yes; then
620   AM_GNU_GETTEXT(,[need-ngettext])
621
622   # gettext requires some extra checks.  These really should be part of
623   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
624   # function checks to here.
625
626   AC_CHECK_FUNCS(strchr)
627 else
628   USE_NLS=no
629   USE_INCLUDED_LIBINTL=no
630   BUILD_INCLUDED_LIBINTL=no
631   AC_SUBST(USE_NLS)
632   AC_SUBST(USE_INCLUDED_LIBINTL)
633   AC_SUBST(BUILD_INCLUDED_LIBINTL)
634 fi
635
636 if test "$try_dynload" = yes ; then
637   AC_CHECK_FUNC(dlopen,,AC_CHECK_LIB(dl,dlopen,found_dlopen=yes))
638   if test x"$found_dlopen" = "xyes" ; then
639     AC_DEFINE(USE_DYNAMIC_LINKING,1,[define to enable the use of extensions])
640     AC_DEFINE(HAVE_DL_DLOPEN,1,
641               [Defined when the dlopen function family is available])
642     AC_SUBST(DLLIBS,"-ldl")
643   fi
644 else
645   AC_MSG_CHECKING(for dynamic loading)
646   AC_MSG_RESULT(has been disabled)
647 fi
648
649
650 dnl Checks for header files.
651 AC_HEADER_STDC
652 AC_CHECK_HEADERS(unistd.h langinfo.h termio.h locale.h getopt.h)
653
654 dnl Checks for typedefs, structures, and compiler characteristics.
655 AC_C_CONST
656 AC_C_INLINE
657 AC_C_VOLATILE
658 AC_TYPE_SIZE_T
659 AC_TYPE_MODE_T
660 AC_TYPE_SIGNAL
661 AC_DECL_SYS_SIGLIST
662
663 GNUPG_CHECK_ENDIAN
664
665 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
666 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
667 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
668 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
669 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
670
671 AC_CHECK_SIZEOF(unsigned short)
672 AC_CHECK_SIZEOF(unsigned int)
673 AC_CHECK_SIZEOF(unsigned long)
674 AC_CHECK_SIZEOF(unsigned long long)
675
676 # Ensure that we have UINT64_C before we bother to check for uint64_t
677 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
678    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
679 uint64_t foo=UINT64_C(42);]),gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
680
681 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
682    AC_CHECK_SIZEOF(uint64_t)
683 fi
684
685 if test "$ac_cv_sizeof_unsigned_short" = "0" \
686    || test "$ac_cv_sizeof_unsigned_int" = "0" \
687    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
688     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
689 fi
690
691 dnl Do we have any 64-bit data types?
692 if test "$ac_cv_sizeof_unsigned_int" != "8" \
693    && test "$ac_cv_sizeof_unsigned_long" != "8" \
694    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
695    && test x"$ac_cv_sizeof_uint64_t" != "x8"; then
696     AC_MSG_WARN([No 64-bit types.  Disabling SHA-384 and SHA-512])
697 else
698   if test x"$use_sha512" = xyes ; then
699      AC_SUBST(SHA512_O,sha512.o)
700      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
701   fi
702 fi
703
704 dnl Checks for library functions.
705 AC_FUNC_FSEEKO
706 AC_FUNC_VPRINTF
707 AC_FUNC_FORK
708 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
709 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times)
710 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
711 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
712 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat getaddrinfo)
713 AC_REPLACE_FUNCS(mkdtemp)
714 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
715
716 # See if getopt is in libiberty.  This is of course not optimal since
717 # it might be somewhere other than libiberty, but does cover the
718 # mingw32 case.
719
720 AC_CHECK_FUNC(getopt,,AC_CHECK_LIB(iberty,getopt,AC_SUBST(GETOPT,"-liberty")))
721
722 #
723 # check for gethrtime and run a testprogram to see whether
724 # it is broken.  It has been reported that some Solaris and HP UX systems 
725 # raise an SIGILL
726 #
727 AC_CACHE_CHECK([for gethrtime], 
728                [gnupg_cv_func_gethrtime],
729                [AC_TRY_LINK([#include <sys/times.h>],[
730                    hrtime_t tv;
731                    tv = gethrtime();
732                  ],
733                  [gnupg_cv_func_gethrtime=yes],
734                  [gnupg_cv_func_gethrtime=no])
735                ])
736 if test $gnupg_cv_func_gethrtime = yes; then
737      AC_DEFINE([HAVE_GETHRTIME], 1,
738                [Define if you have the `gethrtime(2)' function.])
739      AC_CACHE_CHECK([whether gethrtime is broken], 
740                [gnupg_cv_func_broken_gethrtime],
741                [AC_TRY_RUN([
742                    #include <sys/times.h>
743                    int main () {
744                    hrtime_t tv;
745                    tv = gethrtime(); 
746                  }
747                  ],
748                  [gnupg_cv_func_broken_gethrtime=no],
749                  [gnupg_cv_func_broken_gethrtime=yes],
750                  [gnupg_cv_func_broken_gethrtime=assume-no])
751                 ])
752     if test $gnupg_cv_func_broken_gethrtime = yes; then
753       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
754       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
755     fi
756 fi
757      
758
759 GNUPG_CHECK_MLOCK
760 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
761
762 dnl
763 dnl Check whether we can use Linux capabilities as requested
764 dnl
765 if test "$use_capabilities" = "yes" ; then
766 use_capabilities=no
767 AC_CHECK_HEADERS(sys/capability.h)
768 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
769   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
770   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
771      AC_DEFINE(USE_CAPABILITIES,1,
772                [define if capabilities should be used])
773      AC_SUBST(CAPLIBS,"-lcap")
774      use_capabilities=yes
775   fi
776 fi
777 if test "$use_capabilities" = "no" ; then
778     AC_MSG_WARN([[
779 ***
780 *** The use of capabilities on this system is not possible.
781 *** You need a recent Linux kernel and some patches:
782 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
783 ***   fcap-module-990613.tar.gz     (kernel module)
784 ***   libcap-1.92.tar.gz            (user mode library and utilities)
785 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
786 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
787 ***]])
788 fi
789 fi
790
791
792 GNUPG_CHECK_IPC
793 if test "$ac_cv_header_sys_shm_h" = "yes"; then
794   AC_DEFINE(USE_SHM_COPROCESSING,1,
795             [define if the shared memory interface should be made available])
796 fi
797
798 dnl
799 dnl check whether we have a random device
800 dnl
801 if test "$try_dev_random" = yes ; then
802     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
803     [if test -r "$NAME_OF_DEV_RANDOM" && test -r "$NAME_OF_DEV_URANDOM" ; then
804       ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
805     if test "$ac_cv_have_dev_random" = yes; then
806         AC_DEFINE(HAVE_DEV_RANDOM,1,
807                  [defined if the system supports a random device] )
808     fi
809 else
810     AC_MSG_CHECKING(for random device)
811     ac_cv_have_dev_random=no
812     AC_MSG_RESULT(has been disabled)
813 fi
814
815
816 dnl
817 dnl Figure out the default random module.
818 dnl
819 random_modules=""
820 if test "$use_static_rnd" = default; then
821      if test "$ac_cv_have_dev_random" = yes; then
822         random_modules="rndlinux"
823      else
824          case "${target}" in
825             *-*-mingw32*|*-*-cygwin*)
826                 random_modules="rndw32"
827                 ;;
828             i?86-emx-os2|i?86-*-os2*emx)
829                 random_modules="rndos2"
830                 ;;
831             m68k-atari-mint)
832                 random_modules="rndatari"
833                 ;;
834             i?86-*-msdosdjgpp*)
835                 :
836                 ;;
837             *)
838                 random_modules="rndlinux rndegd rndunix"
839                 AC_DEFINE(USE_ALL_RANDOM_MODULES, 1, 
840                           [Allow to select random modules at runtime.])
841                 ;;
842          esac
843      fi
844 else
845   if test "$use_static_rnd" = auto; then
846      random_modules="rndlinux rndegd rndunix"
847      AC_DEFINE(USE_ALL_RANDOM_MODULES, 1)
848   else
849      random_modules="rnd$use_static_rnd";
850   fi
851 fi
852
853 if test -z "$random_modules"; then
854    AC_MSG_ERROR(no random module available)
855 fi
856 print_egd_warning=no
857 for rndmod in $random_modules "" ; do
858   case "$rndmod" in
859     rndlinux)
860          AC_DEFINE(USE_RNDLINUX,1, 
861                   [Defined if the /dev/random based RNG should be used.])
862          ;;
863     rndunix)
864          AC_DEFINE(USE_RNDUNIX,1, 
865                   [Defined if the default Unix RNG should be used.])
866          print_egd_warning=yes
867           ;;
868     rndegd)
869          AC_DEFINE(USE_RNDEGD,1, 
870                   [Defined if the EGD based RNG should be used.])
871          ;;
872     rndw32)
873          AC_DEFINE(USE_RNDW32,1, 
874                   [Defined if the Windows specific RNG should be used.])
875         ;;
876    esac
877 done
878
879 dnl setup assembler stuff
880 AC_MSG_CHECKING(for mpi assembler functions)
881 if test -f $srcdir/mpi/config.links ; then
882     . $srcdir/mpi/config.links
883     AC_CONFIG_LINKS("$mpi_ln_list")
884     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
885     ac_cv_mpi_sflags="$mpi_sflags"
886     ac_cv_mpi_config_done="yes"
887     AC_MSG_RESULT(done)
888 else
889     AC_MSG_RESULT(failed)
890     AC_MSG_ERROR([mpi/config.links missing!])
891 fi
892 MPI_EXTRA_ASM_OBJS=""
893 show_extraasm=""
894 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
895 for i in $ac_cv_mpi_extra_asm_modules; do
896     show_extraasm="$show_extraasm $i"
897     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
898 done
899 fi
900 AC_SUBST(MPI_EXTRA_ASM_OBJS)
901 MPI_SFLAGS="$ac_cv_mpi_sflags"
902 AC_SUBST(MPI_SFLAGS)
903
904 # Sanity check regex.  Tests adapted from mutt.
905
906 AC_MSG_CHECKING([whether regular expression support is requested])
907 AC_ARG_ENABLE(regex,
908 [  --disable-regex         do not handle regular expressions in trust sigs],
909      use_regex=$enableval, use_regex=yes)
910 AC_MSG_RESULT($use_regex)
911
912 if test "$use_regex" = yes ; then
913   AC_MSG_CHECKING([whether the included regex lib is requested])
914   AC_ARG_WITH(included-regex,
915       [  --with-included-regex   use the included GNU regex library],
916       [gnupg_cv_included_regex=yes],[gnupg_cv_included_regex=no])
917   AC_MSG_RESULT($gnupg_cv_included_regex)
918
919   if test $gnupg_cv_included_regex = no ; then
920      # Does the system have regex functions at all?
921      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
922                            gnupg_cv_included_regex=yes)
923   fi
924
925   if test $gnupg_cv_included_regex = no ; then
926      AC_CACHE_CHECK([whether your system's regexp library is broken],
927        [gnupg_cv_regex_broken],
928        AC_TRY_RUN([
929 #include <unistd.h>
930 #include <regex.h>
931 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
932        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
933
934      if test $gnupg_cv_regex_broken = yes ; then
935       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
936       gnupg_cv_included_regex=yes
937      fi
938   fi
939
940   if test $gnupg_cv_included_regex = yes; then
941      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
942      AC_SUBST(REGEX_O,regex.o)
943   fi
944 else
945
946   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
947 fi
948
949 dnl Do we have zlib? Must do it here because Solaris failed
950 dnl when compiling a conftest (due to the "-lz" from LIBS).
951 use_local_zlib=yes
952 if test "$g10_force_zlib" = "yes"; then
953   :
954 else
955   _cppflags="${CPPFLAGS}"
956   _ldflags="${LDFLAGS}"
957
958   AC_ARG_WITH(zlib,
959   [  --with-zlib=DIR         use libz in DIR],[
960     if test -d "$withval"; then
961       CPPFLAGS="${CPPFLAGS} -I$withval/include"
962       LDFLAGS="${LDFLAGS} -L$withval/lib"
963     fi
964   ])
965
966   AC_CHECK_HEADER(zlib.h,
967       AC_CHECK_LIB(z, deflateInit2_,
968        use_local_zlib=no
969        ZLIBS="-lz",
970        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
971        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
972 fi
973
974 if test "$use_local_zlib" = yes ; then
975     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
976     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
977     ZLIBS="../zlib/libzlib.a"
978 else
979     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
980 fi
981 AC_SUBST(ZLIBS)
982
983
984 #
985 # libusb allows us to use the integrated CCID smartcard reader driver.
986 #
987 # Note, that we need the CVS (unstable) version. 
988 #
989 LIBUSB_LIBS=""
990 if test "$card_support" = yes; then
991     AC_CHECK_LIB(usb, usb_find_device,
992                  [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
993                    AC_DEFINE(HAVE_LIBUSB,1,
994                    [defined if libusb is available])
995                  ])
996 fi
997 AC_SUBST(LIBUSB_LIBS)
998
999
1000
1001 # Allow users to append something to the version string without
1002 # flagging it as development version.  The user version parts is
1003 # considered everything after a dash. 
1004 if test "$development_version" != yes; then
1005   changequote(,)dnl
1006   tmp_pat='[a-zA-Z]'
1007   changequote([,])dnl
1008   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1009     development_version=yes
1010   fi
1011 fi
1012 if test "$development_version" = yes; then
1013     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1014             [Defined if this is not a regular release])
1015 fi
1016
1017 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1018
1019 GNUPG_CHECK_GNUMAKE
1020
1021 # add some extra libs here so that previous tests don't fail for
1022 # mysterious reasons - the final link step should bail out. 
1023 case "${target}" in
1024     *-*-mingw32*)
1025 dnl      NETLIBS="$NETLIBS -lwsock32"
1026         W32LIBS="-lwsock32"
1027         ;;
1028     *)
1029        ;;
1030 esac
1031
1032 AC_SUBST(NETLIBS)
1033 AC_SUBST(W32LIBS)
1034
1035 if test "$GCC" = yes; then
1036     if test "$USE_MAINTAINER_MODE" = "yes"; then
1037         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1038     else
1039         CFLAGS="$CFLAGS -Wall"
1040     fi
1041 fi
1042
1043
1044 if test "$print_egd_warning" = yes; then
1045   AC_MSG_WARN([[
1046 ***
1047 *** The performance of the UNIX random gatherer module is not very good
1048 *** and it does not keep the entropy pool over multiple invocations of
1049 *** GnuPG.  The suggested way to overcome this problem is to use the
1050 ***
1051 ***               Entropy Gathering Daemon (EGD)
1052 ***
1053 *** which provides a entropy source for the whole system.  It is written
1054 *** in Perl and available at the GnuPG FTP servers.  For more information
1055 *** consult the GnuPG webpages:
1056 ***
1057 ***           http://www.gnupg.org/download/#EGD
1058 ***
1059 *** You may want to run ./configure with --enable-static-rnd=egd or
1060 *** --enable-static-rnd=auto to use it.
1061 ***]])
1062 fi
1063
1064 # Note the \\\\ for backslashes.  Autoconf eats one layer, leaving \\
1065
1066 AC_CONFIG_COMMANDS(g10defs.h,[[
1067 cat >g10defs.tmp <<G10EOF
1068 /* Generated automatically by configure */
1069 #ifdef HAVE_DRIVE_LETTERS
1070 #define G10_LOCALEDIR     "c:\\\\lib\\\\gnupg\\\\locale"
1071 #define GNUPG_LIBDIR      "c:\\\\lib\\\\gnupg"
1072 #define GNUPG_LIBEXECDIR  "c:\\\\lib\\\\gnupg"
1073 #define GNUPG_DATADIR     "c:\\\\lib\\\\gnupg"
1074 #define GNUPG_HOMEDIR     "c:\\\\gnupg"
1075 #else
1076 #define G10_LOCALEDIR     "${datadir}/locale"
1077 #define GNUPG_LIBDIR      "${libdir}/gnupg"
1078 #define GNUPG_DATADIR     "${datadir}/gnupg"
1079 #ifdef __VMS
1080 #define GNUPG_HOMEDIR "/SYS\$LOGIN/gnupg" 
1081 #else
1082 #define GNUPG_HOMEDIR "~/.gnupg" 
1083 #endif
1084 #endif
1085 /* those are here to be redefined by handcrafted g10defs.h.
1086    Please note that the string version must not contain more
1087    than one character because the using code assumes strlen()==1 */
1088 #ifdef HAVE_DOSISH_SYSTEM
1089 #define DIRSEP_C '\\\\'
1090 #define EXTSEP_C '.'
1091 #define DIRSEP_S "\\\\"
1092 #define EXTSEP_S "."
1093 #else
1094 #define DIRSEP_C '/'
1095 #define EXTSEP_C '.'
1096 #define DIRSEP_S "/"
1097 #define EXTSEP_S "."
1098 #endif
1099 /* This is the same as VERSION, but should be overridden if the
1100    platform cannot handle things like dots '.' in filenames. */
1101 #define SAFE_VERSION VERSION
1102 G10EOF
1103 cat mpi/mpi-asm-defs.h >>g10defs.tmp 
1104 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
1105     echo "g10defs.h is unchanged"
1106     rm -f g10defs.tmp
1107 else
1108     rm -f g10defs.h
1109     mv g10defs.tmp g10defs.h
1110     echo "g10defs.h created"
1111 fi
1112 ]],[[
1113 prefix=$prefix
1114 exec_prefix=$exec_prefix
1115 libdir=$libdir
1116 libexecdir=$libexecdir
1117 datadir=$datadir
1118 DATADIRNAME=$DATADIRNAME
1119 ]])
1120
1121
1122 AC_CONFIG_FILES([
1123 Makefile
1124 intl/Makefile
1125 po/Makefile.in
1126 util/Makefile
1127 mpi/Makefile
1128 cipher/Makefile
1129 g10/Makefile
1130 keyserver/Makefile
1131 keyserver/gpgkeys_mailto
1132 keyserver/gpgkeys_test
1133 doc/Makefile
1134 tools/Makefile
1135 zlib/Makefile
1136 checks/Makefile
1137 ])
1138 AC_OUTPUT
1139
1140 # Give some feedback
1141 echo
1142 echo   "                Configured for: $PRINTABLE_OS_NAME ($target)"
1143 if test -n "$show_extraasm"; then
1144   echo "  Extra cpu specific functions:$show_extraasm"
1145 fi
1146 echo