* app.c (select_application): Fixed serial number extraction and
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 1.9
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 #               2003, 2004 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 2 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, write to the Free Software
19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20
21 # Process this file with autoconf to produce a configure script.
22 AC_PREREQ(2.52)
23 min_automake_version="1.7.6"
24
25 # Version number: Remember to change it immediately *after* a release.
26 #                 Add a "-cvs" prefix for non-released code.
27 AC_INIT(gnupg, 1.9.11-cvs, gnupg-devel@gnupg.org)
28 # Set development_version to yes if the minor number is odd or you
29 # feel that the default check for a development version is not
30 # sufficient.
31 development_version=yes
32 NEED_GPG_ERROR_VERSION=0.7
33
34 NEED_LIBGCRYPT_API=1
35 NEED_LIBGCRYPT_VERSION=1.1.94
36
37 NEED_LIBASSUAN_VERSION=0.6.6
38
39 NEED_KSBA_VERSION=0.9.7
40
41 NEED_OPENSC_VERSION=0.8.0
42
43
44
45 PACKAGE=$PACKAGE_NAME
46 PACKAGE_GT=${PACKAGE_NAME}2
47 VERSION=$PACKAGE_VERSION
48
49 AC_CONFIG_AUX_DIR(scripts)
50 AC_CONFIG_SRCDIR(sm/gpgsm.c)
51 AM_CONFIG_HEADER(config.h)
52 AC_CANONICAL_TARGET()
53 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
54
55 AC_GNU_SOURCE
56
57 # Some status variables to give feedback at the end of a configure run
58 have_gpg_error=no
59 have_libgcrypt=no 
60 have_libassuan=no
61 have_ksba=no
62 have_opensc=no
63 have_pth=no
64
65 GNUPG_BUILD_PROGRAM(gpg, yes)
66 GNUPG_BUILD_PROGRAM(gpgsm, yes)
67 GNUPG_BUILD_PROGRAM(agent, yes)
68 GNUPG_BUILD_PROGRAM(scdaemon, yes)
69
70
71 AC_SUBST(PACKAGE)
72 AC_SUBST(PACKAGE_GT)
73 AC_SUBST(VERSION)
74 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
75 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
76                                 [Name of this package for gettext])
77 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
78 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
79                                         [Bug report address])
80 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
81                                        [Required version of Libgcrypt])
82 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
83                                        [Required version of Libksba])
84
85
86
87 # The default is to use the modules from this package and the few
88 # other packages in a standard place; i.e where this package gets
89 # installed.  With these options it is possible to override these
90 # ${prefix} depended values with fixed paths, which can't be replaced
91 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
92 AC_ARG_WITH(agent-pgm,
93     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
94           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
95 AC_SUBST(GNUPG_AGENT_PGM)
96 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
97 show_gnupg_agent_pgm="(default)"
98 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
99
100 AC_ARG_WITH(pinentry-pgm,
101     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
102           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
103 AC_SUBST(GNUPG_PINENTRY_PGM)
104 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
105 show_gnupg_pinentry_pgm="(default)"
106 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
107
108
109 AC_ARG_WITH(scdaemon-pgm,
110     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
111           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
112 AC_SUBST(GNUPG_SCDAEMON_PGM)
113 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
114 show_gnupg_scdaemon_pgm="(default)"
115 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
116
117
118 AC_ARG_WITH(dirmngr-pgm,
119     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
120           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
121 AC_SUBST(GNUPG_DIRMNGR_PGM)
122 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
123 show_gnupg_dirmngr_pgm="(default)"
124 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
125
126 AC_ARG_WITH(protect-tool-pgm,
127     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
128           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
129 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
130 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
131 show_gnupg_protect_tool_pgm="(default)"
132 test -n "$GNUPG_PROTECT_TOOL_PGM" \
133       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
134
135
136 # Some folks want to use only the agent form this packet.  Make it
137 # easier for them by providing the configure option
138 # --enable-only-agent.
139 AC_ARG_ENABLE(agent-only,
140     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
141     build_agent_only=$enableval)
142
143
144 # Configure option to allow ot disallow execution of external
145 # programs, like a photo viewer.
146 AC_MSG_CHECKING([whether to enable external program execution])
147 AC_ARG_ENABLE(exec,
148     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
149     use_exec=$enableval)
150 AC_MSG_RESULT($use_exec)
151 if test "$use_exec" = no ; then
152     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
153 fi
154
155 if test "$use_exec" = yes ; then
156   AC_MSG_CHECKING([whether to enable photo ID viewing])
157   AC_ARG_ENABLE(photo-viewers,
158       [  --disable-photo-viewers disable photo ID viewers],
159       [if test "$enableval" = no ; then
160          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
161       fi],enableval=yes)
162   gnupg_cv_enable_photo_viewers=$enableval
163   AC_MSG_RESULT($enableval)
164
165   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
166     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
167     AC_ARG_WITH(photo-viewer,
168         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
169         [if test "$withval" = yes ; then
170            withval=no
171         elif test "$withval" != no ; then
172            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
173                             [if set, restrict photo-viewer to this])
174         fi],withval=no)
175     AC_MSG_RESULT($withval)
176   fi
177
178   AC_MSG_CHECKING([whether to enable external keyserver helpers])
179   AC_ARG_ENABLE(keyserver-helpers,
180       [  --disable-keyserver-helpers  disable all external keyserver support],
181       [if test "$enableval" = no ; then
182          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
183                   [define to disable keyserver helpers])
184       fi],enableval=yes)
185   gnupg_cv_enable_keyserver_helpers=$enableval
186   AC_MSG_RESULT($enableval)
187
188   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
189     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
190     AC_ARG_ENABLE(ldap,
191     [  --disable-ldap          disable LDAP keyserver interface],
192         try_ldap=$enableval, try_ldap=yes)
193     AC_MSG_RESULT($try_ldap)
194
195     AC_MSG_CHECKING([whether HKP keyserver support is requested])
196     AC_ARG_ENABLE(hkp,
197     [  --disable-hkp           disable HKP keyserver interface],
198         try_hkp=$enableval, try_hkp=yes)
199     AC_MSG_RESULT($try_hkp)
200
201     if test "$try_hkp" = yes ; then
202       AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
203     fi
204
205     AC_MSG_CHECKING([whether email keyserver support is requested])
206     AC_ARG_ENABLE(mailto,
207     [  --disable-mailto        disable email keyserver interface],
208         try_mailto=$enableval, try_mailto=yes)
209     AC_MSG_RESULT($try_mailto)
210     fi
211
212     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
213     AC_ARG_ENABLE(keyserver-path,
214         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
215         [if test "$enableval" = no ; then
216          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
217         fi],enableval=yes)
218     AC_MSG_RESULT($enableval)
219   fi
220
221 AC_MSG_CHECKING([whether the included zlib is requested])
222 AC_ARG_WITH(included-zlib,
223     [  --with-included-zlib    use the zlib code included here],
224 [g10_force_zlib=yes], [g10_force_zlib=no] )
225 AC_MSG_RESULT($g10_force_zlib)
226
227 dnl
228 dnl Check whether we want to use Linux capabilities
229 dnl
230 AC_MSG_CHECKING([whether use of capabilities is requested])
231 AC_ARG_WITH(capabilities,
232     [  --with-capabilities     use linux capabilities [default=no]],
233 [use_capabilities="$withval"],[use_capabilities=no])
234 AC_MSG_RESULT($use_capabilities)
235
236
237 AH_BOTTOM([
238 /* Some global constants. */
239 #ifdef HAVE_DRIVE_LETTERS
240 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
241 #elif defined(__VMS)
242 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg" 
243 #else
244 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
245 #endif 
246 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
247
248 /* Tell libgcrypt not to use its own libgpg-error implementation. */
249 #define USE_LIBGPG_ERROR 1
250
251 /* This is the major version number of GnuPG so that
252    source included files can test for this.  Note, that\
253    we use 2 here even for GnuPG 1.9.x. */
254 #define GNUPG_MAJOR_VERSION 2
255
256 /* Now to separate file name parts.
257    Please note that the string version must not contain more
258    than one character because the code assumes strlen()==1 */
259 #ifdef HAVE_DOSISH_SYSTEM
260 #define DIRSEP_C '\\'
261 #define EXTSEP_C '.'
262 #define DIRSEP_S "\\"
263 #define EXTSEP_S "."
264 #else
265 #define DIRSEP_C '/'
266 #define EXTSEP_C '.'
267 #define DIRSEP_S "/"
268 #define EXTSEP_S "."
269 #endif
270
271 /* This is the same as VERSION, but should be overridden if the
272    platform cannot handle things like dots '.' in filenames. Set
273    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
274    uses for dots and dashes. */
275 #define SAFE_VERSION VERSION
276 #define SAFE_VERSION_DOT  '.'
277 #define SAFE_VERSION_DASH '-'
278
279 /* For some systems (DOS currently), we hardcode the path here.  For
280    POSIX systems the values are constructed by the Makefiles, so that
281    the values may be overridden by the make invocations; this is to
282    comply with the GNU coding standards. */
283 #ifdef HAVE_DRIVE_LETTERS
284 #define GNUPG_BINDIR      "c:\\gnupg"
285 #define GNUPG_LIBEXECDIR  "c:\\lib\\gnupg"
286 #define GNUPG_LIBDIR      "c:\\lib\\gnupg"
287 #define GNUPG_DATADIR     "c:\\lib\\gnupg"
288 #endif
289
290 /* Setup the hardwired names of modules. */
291 #ifndef GNUPG_DEFAULT_AGENT
292 #define GNUPG_DEFAULT_AGENT    ( GNUPG_BINDIR DIRSEP_S "gpg-agent" )
293 #endif
294 #ifndef GNUPG_DEFAULT_PINENTRY
295 #define GNUPG_DEFAULT_PINENTRY ( GNUPG_BINDIR DIRSEP_S "pinentry" )
296 #endif
297 #ifndef GNUPG_DEFAULT_SCDAEMON
298 #define GNUPG_DEFAULT_SCDAEMON ( GNUPG_BINDIR DIRSEP_S "scdaemon" )
299 #endif
300 #ifndef GNUPG_DEFAULT_DIRMNGR
301 #define GNUPG_DEFAULT_DIRMNGR  ( GNUPG_BINDIR DIRSEP_S "dirmngr" )
302 #endif
303 #ifndef GNUPG_DEFAULT_PROTECT_TOOL
304 #define GNUPG_DEFAULT_PROTECT_TOOL \
305                     ( GNUPG_LIBEXECDIR DIRSEP_S "gpg-protect-tool" )
306 #endif
307
308
309 /* Derive some other constants. */
310 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
311 #define EXEC_TEMPFILE_ONLY
312 #endif
313
314 ])
315
316 AM_MAINTAINER_MODE
317
318 # Checks for programs.
319 AC_PROG_MAKE_SET
320 AM_SANITY_CHECK
321 missing_dir=`cd $ac_aux_dir && pwd`
322 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
323 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
324 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
325 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
326 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
327 AC_PROG_AWK
328 AC_PROG_CC
329 AC_PROG_CPP
330 AC_PROG_INSTALL
331 AC_PROG_LN_S
332 AC_PROG_MAKE_SET
333 AC_PROG_RANLIB
334 AC_CHECK_TOOL(AR, ar, :)
335 AC_PATH_PROG(PERL,"perl")
336 AC_ISC_POSIX
337 AC_SYS_LARGEFILE
338 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
339 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
340 GNUPG_CHECK_FAQPROG
341 GNUPG_CHECK_DOCBOOK_TO_TEXI
342
343
344 try_gettext=yes
345 have_dosish_system=no
346 case "${target}" in
347     *-*-mingw32*)
348         # special stuff for Windoze NT
349         ac_cv_have_dev_random=no
350         AC_DEFINE(USE_ONLY_8DOT3,1,
351                   [set this to limit filenames to the 8.3 format])
352         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
353                   [defined if we must run on a stupid file system])
354         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
355                   [because the Unix gettext has too much overhead on
356                    MingW32 systems and these systems lack Posix functions,
357                    we use a simplified version of gettext])
358         have_dosish_system=yes
359         try_gettext="no"
360         ;;
361     i?86-emx-os2 | i?86-*-os2*emx )
362         # OS/2 with the EMX environment
363         ac_cv_have_dev_random=no
364         AC_DEFINE(HAVE_DRIVE_LETTERS)
365         have_dosish_system=yes
366         try_gettext="no"
367         ;;
368
369     i?86-*-msdosdjgpp*)
370         # DOS with the DJGPP environment
371         ac_cv_have_dev_random=no
372         AC_DEFINE(HAVE_DRIVE_LETTERS)
373         have_dosish_system=yes
374         try_gettext="no"
375         ;;
376
377     *-*-freebsd*)
378        # FreeBSD
379        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
380        LDFLAGS="$LDFLAGS -L/usr/local/lib"
381        ;;
382
383     *-*-hpux*)
384         if test -z "$GCC" ; then
385             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
386         fi
387         ;;
388     *-dec-osf4*)
389         if test -z "$GCC" ; then
390             # Suppress all warnings
391             # to get rid of the unsigned/signed char mismatch warnings.
392             CFLAGS="$CFLAGS -w"
393         fi
394         ;;
395     *-dec-osf5*)
396         if test -z "$GCC" ; then
397             # Use the newer compiler `-msg_disable ptrmismatch' to
398             # get rid of the unsigned/signed char mismatch warnings.
399             # Using this may hide other pointer mismatch warnings, but
400             # it at least lets other warning classes through
401             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
402         fi
403         ;;
404     m68k-atari-mint)
405         ;;
406     *)
407        ;;
408 esac
409
410 if test "$have_dosish_system" = yes; then
411    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
412              [defined if we run on some of the PCDOS like systems 
413               (DOS, Windoze. OS/2) with special properties like
414               no file modes])
415 fi
416 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
417
418
419 #
420 # Checks for libraries.
421 #
422
423
424 #
425 # libgpg-error is a library with error codes shared between GnuPG
426 # related projects.
427 #
428 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
429                   have_gpg_error=yes,have_gpg_error=no)
430
431
432 #
433 # Libgcrypt is our generic crypto library
434 #
435 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
436         have_libgcrypt=yes,have_libgcrypt=no)
437
438
439 #
440 # libassuan is used for IPC
441 #
442 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_VERSION",
443                   have_libassuan=yes,have_libassuan=no)
444
445
446 #
447 # libksba is our X.509 support library
448 #
449 AM_PATH_KSBA("$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
450
451 #
452 # libusb allows us to use the integrated CCID smartcard reader driver.
453 #
454 AC_CHECK_LIB(usb, usb_bulk_write,
455               [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
456                 AC_DEFINE(HAVE_LIBUSB,1,
457                          [defined if libusb is available])
458              ])
459 AC_SUBST(LIBUSB_LIBS)
460 AC_CHECK_FUNCS(usb_create_match)
461
462 #
463 # Check wether it is necessary to link against libdl.
464 #
465 LIBS=""
466 AC_SEARCH_LIBS(dlopen, c dl,,,)
467 DL_LIBS=$LIBS
468 AC_SUBST(DL_LIBS)
469
470 #
471 # OpenSC is needed by the SCdaemon - if it is not availbale we can only
472 # build a limited SCdaemon
473 #
474 AM_PATH_OPENSC("$NEED_OPENSC_VERSION",have_opensc=yes,have_opensc=no)
475 if test $have_opensc = yes; then
476   AC_DEFINE(HAVE_OPENSC,1,
477             [defined if the OpenSC library is available])
478 fi
479 AM_CONDITIONAL(HAVE_OPENSC, test "$have_opensc" = "yes")
480
481 #
482 # Check whether the (highly desirable) GNU Pth library is available
483 #
484 AC_ARG_WITH(pth-prefix,
485             AC_HELP_STRING([--with-pth-prefix=PFX],
486                            [prefix where GNU Pth is installed (optional)]),
487      pth_config_prefix="$withval", pth_config_prefix="")
488 if test x$pth_config_prefix != x ; then
489    PTH_CONFIG="$pth_config_prefix/bin/pth-config"
490 fi
491 AC_PATH_PROG(PTH_CONFIG, pth-config, no)
492 if test "$PTH_CONFIG" = "no"; then
493     AC_MSG_WARN([[
494 ***
495 *** To support concurrent access to the gpg-agent and the SCdaemon
496 *** we need the support of the GNU Portable Threads Library.
497 *** Download it from ftp://ftp.gnu.org/gnu/pth/
498 *** On a Debian GNU/Linux system you might want to try 
499 ***   apt-get install libpth-dev
500 ***]])
501 else
502   GNUPG_PTH_VERSION_CHECK(1.3.7)
503   if test $have_pth = yes; then      
504      PTH_CFLAGS=`$PTH_CONFIG --cflags`
505      PTH_LIBS=`$PTH_CONFIG --ldflags`
506      PTH_LIBS="$PTH_LIBS `$PTH_CONFIG --libs`"
507      AC_DEFINE(USE_GNU_PTH, 1,
508               [Defined if the GNU Portable Thread Library should be used])
509   fi
510 fi
511 AC_SUBST(PTH_CFLAGS)
512 AC_SUBST(PTH_LIBS)
513
514 AC_ARG_ENABLE(threads,
515     AC_HELP_STRING([--disable-threads],[allow building without Pth support]);
516     
517 )
518
519
520 dnl Must check for network library requirements before doing link tests
521 dnl for ldap, for example. If ldap libs are static (or dynamic and without
522 dnl ELF runtime link paths), then link will fail and LDAP support won't
523 dnl be detected.
524
525 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
526         [NETLIBS="-lnsl $NETLIBS"]))
527 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
528         [NETLIBS="-lsocket $NETLIBS"]))
529
530 dnl Now try for the resolver functions so we can use DNS SRV
531
532 AC_ARG_ENABLE(dns-srv,
533    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
534    use_dns_srv=$enableval,use_dns_srv=yes)
535
536 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
537   _srv_save_libs=$LIBS
538   LIBS=""
539   # the double underscore thing is a glibc-ism?
540   AC_SEARCH_LIBS(res_query,resolv bind,,
541                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
542   AC_SEARCH_LIBS(dn_expand,resolv bind,,
543                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
544   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
545                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
546
547   if test x"$use_dns_srv" = xyes ; then
548      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
549      SRVLIBS=$LIBS
550   else
551      AC_MSG_WARN([Resolver functions not found.  Disabling DNS SRV.])
552   fi
553   LIBS=$_srv_save_libs
554 fi
555
556 AC_SUBST(SRVLIBS)
557
558 # Try and link a LDAP test program to weed out unusable LDAP
559 # libraries.  -lldap [-llber [-lresolv]] is for OpenLDAP.  OpenLDAP in
560 # general is terrible with creating weird dependencies.  If all else
561 # fails, the user can play guess-the-dependency by using something
562 # like ./configure LDAPLIBS="-Lfoo -lbar"
563
564 if test "$try_ldap" = yes ; then
565   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
566     _ldap_save_libs=$LIBS
567     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
568
569     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
570     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
571                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
572     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
573
574     if test $gnupg_cv_func_ldap_init = no; then
575       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
576       AC_TRY_LINK([#include <lber.h>
577 #include <ldap.h>],[ldap_open("foobar",1234);],
578          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
579       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
580     fi
581
582     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
583        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
584     fi
585
586     if test "$gnupg_cv_func_ldap_init" = yes || \
587         test "$gnupg_cv_func_ldaplber_init" = yes ; then
588        LDAPLIBS=$MY_LDAPLIBS
589        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
590
591        AC_MSG_CHECKING([whether LDAP supports ldap_get_option])
592
593        if test "$gnupg_cv_func_ldap_init" = yes ; then
594           AC_TRY_LINK([#include <ldap.h>],
595              [ldap_get_option((void *)0,0,(void *)0);],
596              [gnupg_cv_func_ldap_get_option=yes],
597              [gnupg_cv_func_ldap_get_option=no])
598         else
599           AC_TRY_LINK([#include <lber.h>
600 #include <ldap.h>],[ldap_get_option((void *)0,0,(void *)0);],
601              [gnupg_cv_func_ldap_get_option=yes],
602              [gnupg_cv_func_ldap_get_option=no])
603        fi
604
605        AC_MSG_RESULT([$gnupg_cv_func_ldap_get_option])
606
607        if test "$gnupg_cv_func_ldap_get_option" = yes ; then
608           AC_DEFINE(HAVE_LDAP_GET_OPTION,1,[Define if the LDAP library has ldap_get_option])
609        else
610           AC_MSG_CHECKING([whether LDAP supports ld_errno])
611
612           if test "$gnupg_cv_func_ldap_init" = yes ; then
613             AC_TRY_COMPILE([#include <ldap.h>],
614                [LDAP *ldap; ldap->ld_errno;],
615                [gnupg_cv_func_ldap_ld_errno=yes],
616                [gnupg_cv_func_ldap_ld_errno=no])
617            else
618             AC_TRY_LINK([#include <lber.h>
619 #include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
620                [gnupg_cv_func_ldap_ld_errno=yes],
621                [gnupg_cv_func_ldap_ld_errno=no])
622           fi
623
624           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
625
626           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
627              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
628           fi
629        fi
630     fi
631
632     LIBS=$_ldap_save_libs
633
634     if test "$GPGKEYS_LDAP" != "" ; then break; fi
635   done
636 fi
637
638 AC_SUBST(GPGKEYS_LDAP)
639 AC_SUBST(LDAPLIBS)
640
641 dnl This isn't necessarily sendmail itself, but anything that gives a
642 dnl sendmail-ish interface to the outside world.  That includes qmail,
643 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
644
645 if test "$try_mailto" = yes ; then
646   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
647
648   if test "$with_mailprog" = yes ; then
649     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
650     if test "$ac_cv_path_SENDMAIL" ; then
651       GPGKEYS_MAILTO="gpgkeys_mailto"
652     fi
653   elif test "$with_mailprog" != no ; then
654     AC_MSG_CHECKING([for a mail transport program])
655     AC_SUBST(SENDMAIL,$with_mailprog)
656     AC_MSG_RESULT($with_mailprog)
657     GPGKEYS_MAILTO="gpgkeys_mailto"
658   fi
659 fi
660
661 AC_SUBST(GPGKEYS_MAILTO)
662
663 case "${target}" in
664     *-*-mingw32*)
665         PRINTABLE_OS_NAME="MingW32"
666         ;;
667     *-*-cygwin*)
668         PRINTABLE_OS_NAME="Cygwin"
669         ;;
670     i?86-emx-os2 | i?86-*-os2*emx )
671         PRINTABLE_OS_NAME="OS/2"
672         ;;
673     i?86-*-msdosdjgpp*)
674         PRINTABLE_OS_NAME="MSDOS/DJGPP"
675         try_dynload=no
676         ;;
677     *-linux*)
678         PRINTABLE_OS_NAME="GNU/Linux"
679         ;;
680     *)
681         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
682         ;;
683 esac
684 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
685                    [A human readable text with the name of the OS])
686
687
688 AM_GNU_GETTEXT_VERSION(0.12.1)
689 if test "$try_gettext" = yes; then
690   AM_GNU_GETTEXT(,[need-ngettext])
691
692   # gettext requires some extra checks.  These really should be part of
693   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
694   # function checks to here.
695
696   AC_CHECK_FUNCS(strchr)
697 else
698   USE_NLS=no
699   USE_INCLUDED_LIBINTL=no
700   BUILD_INCLUDED_LIBINTL=no
701   AC_SUBST(USE_NLS)
702   AC_SUBST(USE_INCLUDED_LIBINTL)
703   AC_SUBST(BUILD_INCLUDED_LIBINTL)
704 fi
705
706 # Checks for header files.
707 AC_HEADER_STDC
708 AC_CHECK_HEADERS(string.h unistd.h langinfo.h termio.h locale.h)
709
710 # Checks for typedefs, structures, and compiler characteristics.
711 AC_C_CONST
712 AC_C_INLINE
713 AC_TYPE_SIZE_T
714 AC_TYPE_SIGNAL
715 AC_DECL_SYS_SIGLIST
716
717 GNUPG_CHECK_ENDIAN
718
719 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
720 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
721 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
722 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
723 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
724
725 AC_CHECK_SIZEOF(unsigned short)
726 AC_CHECK_SIZEOF(unsigned int)
727 AC_CHECK_SIZEOF(unsigned long)
728 AC_CHECK_SIZEOF(unsigned long long)
729 # Ensure that we have UINT64_C before we bother to check for uint64_t
730 # fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
731 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
732    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
733 uint64_t foo=UINT64_C(42);]),gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
734 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
735    AC_CHECK_SIZEOF(uint64_t)
736 fi
737  
738
739
740
741 if test "$ac_cv_sizeof_unsigned_short" = "0" \
742    || test "$ac_cv_sizeof_unsigned_int" = "0" \
743    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
744     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
745 fi
746
747 dnl Do we have any 64-bit data types?
748 if test "$ac_cv_sizeof_unsigned_int" != "8" \
749    && test "$ac_cv_sizeof_unsigned_long" != "8" \
750    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
751    && test "$ac_cv_sizeof_uint64_t" != "8"; then
752     AC_MSG_WARN([No 64-bit types.  Disabling SHA-384, and SHA-512])
753 else
754   if test x"$use_sha512" = xyes ; then
755      AC_SUBST(SHA512_O,sha512.o)
756      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
757   fi
758 fi
759
760 # fixme: do we really need this - it should be encapsulated in libassuan
761 GNUPG_SYS_SO_PEERCRED
762
763 # Checks for library functions.
764 AC_FUNC_FSEEKO
765 AC_FUNC_VPRINTF
766 AC_FUNC_FORK
767 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
768 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times gmtime_r)
769 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
770 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
771 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat getaddrinfo)
772
773 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
774
775 # These are needed by libjnlib - fixme: we should have macros for them
776 AC_CHECK_FUNCS(memicmp stpcpy strlwr strtoul memmove stricmp strtol)
777 AC_CHECK_FUNCS(getrusage setrlimit stat setlocale)
778 AC_CHECK_FUNCS(flockfile funlockfile fopencookie funopen)
779
780 AC_REPLACE_FUNCS(vasprintf)
781 AC_REPLACE_FUNCS(mkdtemp)
782 AC_REPLACE_FUNCS(fseeko ftello)
783 AC_REPLACE_FUNCS(isascii)
784 AC_REPLACE_FUNCS(putc_unlocked)
785
786
787
788
789 #
790 # check for gethrtime and run a testprogram to see whether
791 # it is broken.  It has been reported that some Solaris and HP UX systems 
792 # raise an SIGILL
793 #
794 #  fixme: Do we need this - iirc, this is only used by libgcrypt.
795 #
796 AC_CACHE_CHECK([for gethrtime], 
797                [gnupg_cv_func_gethrtime],
798                [AC_TRY_LINK([#include <sys/times.h>],[
799                    hrtime_t tv;
800                    tv = gethrtime();
801                  ],
802                  [gnupg_cv_func_gethrtime=yes],
803                  [gnupg_cv_func_gethrtime=no])
804                ])
805 if test $gnupg_cv_func_gethrtime = yes; then
806      AC_DEFINE([HAVE_GETHRTIME], 1,
807                [Define if you have the `gethrtime(2)' function.])
808      AC_CACHE_CHECK([whether gethrtime is broken], 
809                [gnupg_cv_func_broken_gethrtime],
810                [AC_TRY_RUN([
811                    #include <sys/times.h>
812                    int main () {
813                    hrtime_t tv;
814                    tv = gethrtime(); 
815                  }
816                  ],
817                  [gnupg_cv_func_broken_gethrtime=no],
818                  [gnupg_cv_func_broken_gethrtime=yes],
819                  [gnupg_cv_func_broken_gethrtime=assume-no])
820                 ])
821     if test $gnupg_cv_func_broken_gethrtime = yes; then
822       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
823       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
824     fi
825 fi
826      
827
828 GNUPG_CHECK_MLOCK
829 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
830
831 dnl
832 dnl Check whether we can use Linux capabilities as requested
833 dnl
834 #  fixme: Still required?
835 #
836 if test "$use_capabilities" = "yes" ; then
837 use_capabilities=no
838 AC_CHECK_HEADERS(sys/capability.h)
839 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
840   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
841   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
842      AC_DEFINE(USE_CAPABILITIES,1,
843                [define if capabilities should be used])
844      AC_SUBST(CAPLIBS,"-lcap")
845      use_capabilities=yes
846   fi
847 fi
848 if test "$use_capabilities" = "no" ; then
849     AC_MSG_WARN([[
850 ***
851 *** The use of capabilities on this system is not possible.
852 *** You need a recent Linux kernel and some patches:
853 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
854 ***   fcap-module-990613.tar.gz     (kernel module)
855 ***   libcap-1.92.tar.gz            (user mode library and utilities)
856 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
857 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
858 ***]])
859 fi
860 fi
861
862
863 # Sanity check regex.  Tests adapted from mutt.
864
865 AC_MSG_CHECKING([whether regular expression support is requested])
866 AC_ARG_ENABLE(regex,
867 [  --disable-regex         do not handle regular expressions in trust sigs],
868      use_regex=$enableval, use_regex=yes)
869 AC_MSG_RESULT($use_regex)
870
871 if test "$use_regex" = yes ; then
872   AC_MSG_CHECKING([whether the included regex lib is requested])
873   AC_ARG_WITH(included-regex,
874       [  --with-included-regex   use the included GNU regex library],
875       [gnupg_cv_included_regex=yes],[gnupg_cv_included_regex=no])
876   AC_MSG_RESULT($gnupg_cv_included_regex)
877
878   if test $gnupg_cv_included_regex = no ; then
879      # Does the system have regex functions at all?
880      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
881                            gnupg_cv_included_regex=yes)
882   fi
883
884   if test $gnupg_cv_included_regex = no ; then
885      AC_CACHE_CHECK([whether your system's regexp library is broken],
886        [gnupg_cv_regex_broken],
887        AC_TRY_RUN([
888 #include <unistd.h>
889 #include <regex.h>
890 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
891        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
892
893      if test $gnupg_cv_regex_broken = yes ; then
894       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
895       gnupg_cv_included_regex=yes
896      fi
897   fi
898
899   if test $gnupg_cv_included_regex = yes; then
900      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
901      AC_SUBST(REGEX_O,regex.o)
902   fi
903 else
904
905   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
906 fi
907
908 dnl Do we have zlib? Must do it here because Solaris failed
909 dnl when compiling a conftest (due to the "-lz" from LIBS).
910 use_local_zlib=yes
911 if test "$g10_force_zlib" = "yes"; then
912   :
913 else
914   _cppflags="${CPPFLAGS}"
915   _ldflags="${LDFLAGS}"
916
917   AC_ARG_WITH(zlib,
918   [  --with-zlib=DIR         use libz in DIR],[
919     if test -d "$withval"; then
920       CPPFLAGS="${CPPFLAGS} -I$withval/include"
921       LDFLAGS="${LDFLAGS} -L$withval/lib"
922     fi
923   ])
924
925   AC_CHECK_HEADER(zlib.h,
926       AC_CHECK_LIB(z, deflateInit2_,
927        use_local_zlib=no
928        LIBS="$LIBS -lz",
929        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
930        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
931 fi
932  
933 if test "$use_local_zlib" = yes ; then
934     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
935     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
936     ZLIBS="../zlib/libzlib.a"
937 else
938     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
939     ZLIBS=
940 fi
941 AC_SUBST(ZLIBS)
942
943
944 # See wether we want to run the long test suite.
945 AC_ARG_WITH(pkits-tests,
946     AC_HELP_STRING([--with-pkits-tests],[run the PKITS based tests]),
947     [run_pkits_tests=$withval], [run_pkits_tests=no])
948 AM_CONDITIONAL(RUN_PKITS_TESTS, test "$run_pkits_tests" = "yes")
949
950
951 # Allow users to append something to the version string without
952 # flagging it as development version.  The user version parts is
953 # considered everything after a dash. 
954 if test "$development_version" != yes; then
955   changequote(,)dnl
956   tmp_pat='[a-zA-Z]'
957   changequote([,])dnl
958   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
959     development_version=yes
960   fi
961 fi
962 if test "$development_version" = yes; then
963     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
964             [Defined if this is not a regular release])
965 fi
966
967 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
968
969 GNUPG_CHECK_GNUMAKE
970
971 # add some extra libs here so that previous tests don't fail for
972 # mysterious reasons - the final link step should bail out. 
973 case "${target}" in
974     *-*-mingw32*)
975         W32LIBS="-lwsock32"
976         ;;
977     *)
978        ;;
979 esac
980
981
982 if test "$GCC" = yes; then
983     if test "$USE_MAINTAINER_MODE" = "yes"; then
984         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
985         CFLAGS="$CFLAGS -Wformat-nonliteral"
986     else
987         CFLAGS="$CFLAGS -Wall"
988     fi
989 fi
990
991 AC_SUBST(NETLIBS)
992 AC_SUBST(W32LIBS)
993
994
995 # We use jnlib, so tell other modules about it
996 AC_DEFINE(HAVE_JNLIB_LOGGING, 1,
997           [Defined if jnlib style logging functions are available])
998
999
1000
1001 #
1002 # Decide what to build
1003 #
1004 missing_pth=no
1005 if test $have_ksba = no; then
1006   build_gpgsm=no
1007   build_scdaemon=no
1008 fi
1009
1010 build_agent_threaded=""
1011 if test "$build_agent" = "yes"; then
1012   if test $have_pth = no; then
1013      build_agent_threaded="(not multi-threaded)"
1014      missing_pth=yes
1015   fi
1016 fi
1017
1018 build_scdaemon_extra=""
1019 if test "$build_scdaemon" = "yes"; then
1020   tmp=""
1021   if test $have_pth = no; then
1022      build_scdaemon_extra="not multi-threaded"
1023      tmp=", "
1024      missing_pth=yes
1025   fi
1026   if test $have_opensc = no; then
1027      build_scdaemon_extra="${build_scdaemon_extra}${tmp}no pkcs#15"
1028      tmp=", "
1029   fi      
1030   if test -n "$build_scdaemon_extra"; then
1031      build_scdaemon_extra="(${build_scdaemon_extra})"
1032   fi
1033 fi
1034
1035 if test "$build_agent_only" = "yes" ; then
1036   build_gpg=no
1037   build_gpgsm=no
1038   build_scdaemon=no
1039 fi
1040
1041 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1042 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1043 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1044 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1045
1046
1047
1048 #
1049 # Print errors here so that they are visible all
1050 # together and the user can acquire them all together.
1051 #
1052 die=no
1053 if test "$have_gpg_error" = "no"; then
1054    die=yes
1055    AC_MSG_NOTICE([[
1056 ***  
1057 *** You need libgpg-error to build this program.
1058 **  This library is for example available at
1059 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libgpg-error
1060 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1061 ***]])
1062 fi
1063 if test "$have_libgcrypt" = "no"; then
1064    die=yes
1065    AC_MSG_NOTICE([[
1066 ***  
1067 *** You need libgcrypt to build this program.
1068 **  This library is for example available at
1069 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libgcrypt/
1070 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API) is required.)
1071 ***]])
1072 fi
1073 if test "$have_libassuan" = "no"; then
1074    die=yes
1075    AC_MSG_NOTICE([[
1076 ***
1077 *** You need libassuan to build this program.
1078 *** This library is for example available at
1079 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libassuan/
1080 *** (at least version $NEED_LIBASSUAN_VERSION is required).
1081 ***]])
1082 fi
1083 if test "$have_ksba" = "no"; then
1084     AC_MSG_NOTICE([[
1085 ***
1086 *** You need libksba to build this program.
1087 *** This library is for example available at
1088 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libksba/
1089 *** (at least version $NEED_KSBA_VERSION is required).
1090 ***]])
1091 fi
1092 if test "$missing_pth" = "yes"; then
1093     AC_MSG_NOTICE([[
1094 ***
1095 *** It is strongly suggested to build with support for the
1096 *** GNU Portable Threads Library (Pth). Please install this
1097 *** library first or use --disable-threads to allow building
1098 *** anyway.  The library is for example available at
1099 ***   ftp://ftp.gnu.org/gnu/pth/
1100 *** On a Debian GNU/Linux system you can install it using 
1101 ***   apt-get install libpth-dev
1102 ***]])
1103   if test "$enable_threads" != "no"; then
1104      die=yes
1105   fi
1106 fi
1107
1108 if test "$die" = "yes"; then
1109     AC_MSG_ERROR([[
1110 ***
1111 *** Required libraries not found. Please consult the above messages
1112 *** and install them before running configure again.
1113 ***]])
1114 fi
1115
1116
1117
1118 AC_CONFIG_FILES([ m4/Makefile 
1119 Makefile
1120 po/Makefile.in
1121 intl/Makefile
1122 jnlib/Makefile
1123 common/Makefile
1124 kbx/Makefile
1125 g10/Makefile
1126 sm/Makefile
1127 agent/Makefile
1128 scd/Makefile
1129 tools/Makefile
1130 doc/Makefile
1131 tests/Makefile
1132 tests/pkits/Makefile
1133 ])
1134 AC_OUTPUT
1135
1136
1137
1138
1139 echo "
1140         GnuPG v${VERSION} has been configured as follows:
1141         
1142         Platform:  $PRINTABLE_OS_NAME ($target)
1143
1144         OpenPGP:   $build_gpg
1145         S/MIME:    $build_gpgsm
1146         Agent:     $build_agent $build_agent_threaded
1147         Smartcard: $build_scdaemon $build_scdaemon_extra
1148
1149         Protect tool:      $show_gnupg_protect_tool_pgm
1150         Default agent:     $show_gnupg_agent_pgm
1151         Default pinentry:  $show_gnupg_pinentry_pgm
1152         Default scdaemon:  $show_gnupg_scdaemon_pgm
1153         Default dirmngr:   $show_gnupg_dirmngr_pgm
1154
1155         PKITS based tests: $run_pkits_tests
1156 "
1157