tests: Use gpgconf to stop the agent.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998-2012 Free Software Foundation, Inc.
3 # Copyright (C) 1998-2016 Werner Koch
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <https://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.14"
23
24 # To build a release you need to create a tag with the version number
25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
26 # bump the version number immediately *after* the release and do
27 # another commit and push so that the git magic is able to work.
28 m4_define([mym4_package],[gnupg])
29 m4_define([mym4_major], [2])
30 m4_define([mym4_minor], [1])
31 m4_define([mym4_micro], [20])
32
33 # To start a new development series, i.e a new major or minor number
34 # you need to mark an arbitrary commit before the first beta release
35 # with an annotated tag.  For example the 2.1 branch starts off with
36 # the tag "gnupg-2.1-base".  This is used as the base for counting
37 # beta numbers before the first release of a series.
38
39 # Below is m4 magic to extract and compute the git revision number,
40 # the decimalized short revision number, a beta version string and a
41 # flag indicating a development version (mym4_isbeta).  Note that the
42 # m4 processing is done by autoconf and not during the configure run.
43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
49 m4_esyscmd([echo ]mym4_version[>VERSION])
50 AC_INIT([mym4_package],[mym4_version], [https://bugs.gnupg.org])
51
52 NEED_GPG_ERROR_VERSION=1.24
53
54 NEED_LIBGCRYPT_API=1
55 NEED_LIBGCRYPT_VERSION=1.7.0
56
57 NEED_LIBASSUAN_API=2
58 NEED_LIBASSUAN_VERSION=2.4.3
59
60 NEED_KSBA_API=1
61 NEED_KSBA_VERSION=1.3.4
62
63 NEED_NTBTLS_API=1
64 NEED_NTBTLS_VERSION=0.1.0
65
66 NEED_NPTH_API=1
67 NEED_NPTH_VERSION=1.2
68
69
70 NEED_GNUTLS_VERSION=3.0
71
72 NEED_SQLITE_VERSION=3.7
73
74 development_version=mym4_isbeta
75 PACKAGE=$PACKAGE_NAME
76 PACKAGE_GT=${PACKAGE_NAME}2
77 VERSION=$PACKAGE_VERSION
78
79 AC_CONFIG_AUX_DIR([build-aux])
80 AC_CONFIG_SRCDIR([sm/gpgsm.c])
81 AC_CONFIG_HEADER([config.h])
82 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
83 AC_CANONICAL_HOST
84 AB_INIT
85
86 AC_GNU_SOURCE
87
88 # Before we do anything with the C compiler, we first save the user's
89 # CFLAGS (they are restored at the end of the configure script).  This
90 # is because some configure checks don't work with -Werror, but we'd
91 # like to use -Werror with our build.
92 CFLAGS_orig=$CFLAGS
93 CFLAGS=
94
95 # Some status variables.
96 have_gpg_error=no
97 have_libgcrypt=no
98 have_libassuan=no
99 have_ksba=no
100 have_ntbtls=no
101 have_gnutls=no
102 have_sqlite=no
103 have_npth=no
104 have_libusb=no
105 have_system_resolver=no
106 gnupg_have_ldap="n/a"
107
108 use_zip=yes
109 use_bzip2=yes
110 use_exec=yes
111 use_trust_models=yes
112 use_tofu=yes
113 use_libdns=yes
114 card_support=yes
115 use_ccid_driver=auto
116 dirmngr_auto_start=yes
117 use_tls_library=no
118 large_secmem=no
119 show_tor_support=no
120
121
122 GNUPG_BUILD_PROGRAM(gpg, yes)
123 GNUPG_BUILD_PROGRAM(gpgsm, yes)
124 # The agent is a required part and can't be disabled anymore.
125 build_agent=yes
126 GNUPG_BUILD_PROGRAM(scdaemon, yes)
127 GNUPG_BUILD_PROGRAM(g13, no)
128 GNUPG_BUILD_PROGRAM(dirmngr, yes)
129 GNUPG_BUILD_PROGRAM(doc, yes)
130 GNUPG_BUILD_PROGRAM(symcryptrun, no)
131 # We use gpgtar to unpack test data, hence we always build it.  If the
132 # user opts out, we simply don't install it.
133 GNUPG_BUILD_PROGRAM(gpgtar, yes)
134 GNUPG_BUILD_PROGRAM(wks-tools, no)
135
136 AC_SUBST(PACKAGE)
137 AC_SUBST(PACKAGE_GT)
138 AC_SUBST(VERSION)
139 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
140 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
141                                 [Name of this package for gettext])
142 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
143 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
144                                         [Bug report address])
145 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
146                                        [Required version of Libgcrypt])
147 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
148                                        [Required version of Libksba])
149 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
150                                        [Required version of NTBTLS])
151
152
153
154 # The default is to use the modules from this package and the few
155 # other packages in a standard place; i.e where this package gets
156 # installed.  With these options it is possible to override these
157 # ${prefix} depended values with fixed paths, which can't be replaced
158 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
159 AC_ARG_WITH(agent-pgm,
160     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
161           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
162 AC_SUBST(GNUPG_AGENT_PGM)
163 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
164 show_gnupg_agent_pgm="(default)"
165 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
166
167 AC_ARG_WITH(pinentry-pgm,
168     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
169           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
170 AC_SUBST(GNUPG_PINENTRY_PGM)
171 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
172 show_gnupg_pinentry_pgm="(default)"
173 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
174
175
176 AC_ARG_WITH(scdaemon-pgm,
177     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
178           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
179 AC_SUBST(GNUPG_SCDAEMON_PGM)
180 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
181 show_gnupg_scdaemon_pgm="(default)"
182 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
183
184
185 AC_ARG_WITH(dirmngr-pgm,
186     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
187           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
188 AC_SUBST(GNUPG_DIRMNGR_PGM)
189 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
190 show_gnupg_dirmngr_pgm="(default)"
191 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
192
193 AC_ARG_WITH(protect-tool-pgm,
194     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
195           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
196 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
197 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
198 show_gnupg_protect_tool_pgm="(default)"
199 test -n "$GNUPG_PROTECT_TOOL_PGM" \
200       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
201
202 AC_ARG_WITH(dirmngr-ldap-pgm,
203     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmngr ldap wrapper)],
204           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
205 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
206 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
207 show_gnupg_dirmngr_ldap_pgm="(default)"
208 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
209       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
210
211 #
212 # On some platforms gpg2 is usually installed as gpg without using a
213 # symlink.  For correct operation of gpgconf it needs to know the
214 # installed name of gpg.  This option sets "gpg2"'s installed name to
215 # just "gpg".  Note that it might be required to rename gpg2 to gpg
216 # manually after the build process.
217 #
218 AC_ARG_ENABLE(gpg2-is-gpg,
219     AC_HELP_STRING([--enable-gpg2-is-gpg],[Set installed name of gpg2 to gpg]),
220     gpg2_is_gpg=$enableval)
221 if test "$gpg2_is_gpg" != "yes"; then
222    AC_DEFINE(USE_GPG2_HACK, 1, [Define to install gpg as gpg2])
223 fi
224 AM_CONDITIONAL(USE_GPG2_HACK, test "$gpg2_is_gpg" != "yes")
225
226
227 # SELinux support includes tracking of sensitive files to avoid
228 # leaking their contents through processing these files by gpg itself
229 AC_MSG_CHECKING([whether SELinux support is requested])
230 AC_ARG_ENABLE(selinux-support,
231               AC_HELP_STRING([--enable-selinux-support],
232                              [enable SELinux support]),
233               selinux_support=$enableval, selinux_support=no)
234 AC_MSG_RESULT($selinux_support)
235
236
237 AC_MSG_CHECKING([whether to allocate extra secure memory])
238 AC_ARG_ENABLE(large-secmem,
239               AC_HELP_STRING([--enable-large-secmem],
240                              [allocate extra secure memory]),
241               large_secmem=$enableval, large_secmem=no)
242 AC_MSG_RESULT($large_secmem)
243 if test "$large_secmem" = yes ; then
244    SECMEM_BUFFER_SIZE=65536
245 else
246    SECMEM_BUFFER_SIZE=32768
247 fi
248 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
249                    [Size of secure memory buffer])
250
251 AC_MSG_CHECKING([whether to enable trust models])
252 AC_ARG_ENABLE(trust-models,
253               AC_HELP_STRING([--disable-trust-models],
254                              [disable all trust models except "always"]),
255               use_trust_models=$enableval)
256 AC_MSG_RESULT($use_trust_models)
257 if test "$use_trust_models" = no ; then
258     AC_DEFINE(NO_TRUST_MODELS, 1,
259              [Define to include only trust-model always])
260 fi
261
262 AC_MSG_CHECKING([whether to enable TOFU])
263 AC_ARG_ENABLE(tofu,
264                 AC_HELP_STRING([--disable-tofu],
265                                [disable the TOFU trust model]),
266               use_tofu=$enableval, use_tofu=$use_trust_models)
267 AC_MSG_RESULT($use_tofu)
268 if test "$use_trust_models" = no && test "$use_tofu" = yes; then
269     AC_MSG_ERROR([both --disable-trust-models and --enable-tofu given])
270 fi
271
272 AC_MSG_CHECKING([whether to enable libdns])
273 AC_ARG_ENABLE(libdns,
274                 AC_HELP_STRING([--disable-libdns],
275                                [do not build with libdns support]),
276               use_libdns=$enableval, use_libdns=yes)
277 AC_MSG_RESULT($use_libdns)
278 if test x"$use_libdns" = xyes ; then
279     AC_DEFINE(USE_LIBDNS, 1, [Build with integrated libdns support])
280 fi
281 AM_CONDITIONAL(USE_LIBDNS, test "$use_libdns" = yes)
282
283
284 #
285 # Options to disable algorithm
286 #
287
288 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
289 # Elgamal is a MUST algorithm
290 # DSA is a MUST algorithm
291 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
292 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
293 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
294
295 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
296 # 3DES is a MUST algorithm
297 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
298 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
299 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
300 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
301 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
302 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
303 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
304 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
305 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
306
307 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
308 # SHA1 is a MUST algorithm
309 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
310 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
311 # SHA256 is a MUST algorithm for GnuPG.
312 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
313 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
314
315
316 # Allow disabling of zip support.
317 # This is in general not a good idea because according to rfc4880 OpenPGP
318 # implementations SHOULD support ZLIB.
319 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
320 AC_ARG_ENABLE(zip,
321    AC_HELP_STRING([--disable-zip],
322                   [disable the ZIP and ZLIB compression algorithm]),
323    use_zip=$enableval)
324 AC_MSG_RESULT($use_zip)
325
326 # Allow disabling of bzib2 support.
327 # It is defined only after we confirm the library is available later
328 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
329 AC_ARG_ENABLE(bzip2,
330    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
331    use_bzip2=$enableval)
332 AC_MSG_RESULT($use_bzip2)
333
334 # Configure option to allow or disallow execution of external
335 # programs, like a photo viewer.
336 AC_MSG_CHECKING([whether to enable external program execution])
337 AC_ARG_ENABLE(exec,
338     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
339     use_exec=$enableval)
340 AC_MSG_RESULT($use_exec)
341 if test "$use_exec" = no ; then
342     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
343 fi
344
345 if test "$use_exec" = yes ; then
346   AC_MSG_CHECKING([whether to enable photo ID viewing])
347   AC_ARG_ENABLE(photo-viewers,
348       [  --disable-photo-viewers disable photo ID viewers],
349       [if test "$enableval" = no ; then
350          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
351       fi],enableval=yes)
352   gnupg_cv_enable_photo_viewers=$enableval
353   AC_MSG_RESULT($enableval)
354
355   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
356     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
357     AC_ARG_WITH(photo-viewer,
358         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
359         [if test "$withval" = yes ; then
360            withval=no
361         elif test "$withval" != no ; then
362            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
363                             [if set, restrict photo-viewer to this])
364         fi],withval=no)
365     AC_MSG_RESULT($withval)
366   fi
367 fi
368
369
370 #
371 # Check for the key/uid cache size.  This can't be zero, but can be
372 # pretty small on embedded systems.  This is used for the gpg part.
373 #
374 AC_MSG_CHECKING([for the size of the key and uid cache])
375 AC_ARG_ENABLE(key-cache,
376         AC_HELP_STRING([--enable-key-cache=SIZE],
377                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
378 if test "$enableval" = "no"; then
379    enableval=5
380 elif test "$enableval" = "yes" || test "$enableval" = ""; then
381    enableval=4096
382 fi
383 changequote(,)dnl
384 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
385 changequote([,])dnl
386 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
387    AC_MSG_ERROR([invalid key-cache size])
388 fi
389 AC_MSG_RESULT($key_cache_size)
390 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
391                   [Size of the key and UID caches])
392
393
394
395 #
396 # Check whether we want to use Linux capabilities
397 #
398 AC_MSG_CHECKING([whether use of capabilities is requested])
399 AC_ARG_WITH(capabilities,
400     [  --with-capabilities     use linux capabilities [default=no]],
401 [use_capabilities="$withval"],[use_capabilities=no])
402 AC_MSG_RESULT($use_capabilities)
403
404 #
405 # Check whether to disable the card support
406 AC_MSG_CHECKING([whether smartcard support is requested])
407 AC_ARG_ENABLE(card-support,
408               AC_HELP_STRING([--disable-card-support],
409                              [disable smartcard support]),
410               card_support=$enableval)
411 AC_MSG_RESULT($card_support)
412 if test "$card_support" = yes ; then
413   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
414 else
415   build_scdaemon=no
416 fi
417
418 #
419 # Allow disabling of internal CCID support.
420 # It is defined only after we confirm the library is available later
421 #
422 AC_MSG_CHECKING([whether to enable the internal CCID driver])
423 AC_ARG_ENABLE(ccid-driver,
424               AC_HELP_STRING([--disable-ccid-driver],
425                              [disable the internal CCID driver]),
426               use_ccid_driver=$enableval)
427 AC_MSG_RESULT($use_ccid_driver)
428
429 AC_MSG_CHECKING([whether to auto start dirmngr])
430 AC_ARG_ENABLE(dirmngr-auto-start,
431               AC_HELP_STRING([--disable-dirmngr-auto-start],
432                              [disable auto starting of the dirmngr]),
433               dirmngr_auto_start=$enableval)
434 AC_MSG_RESULT($dirmngr_auto_start)
435 if test "$dirmngr_auto_start" = yes ; then
436     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
437               [Define to enable auto starting of the dirmngr])
438 fi
439
440
441 #
442 # To avoid double inclusion of config.h which might happen at some
443 # places, we add the usual double inclusion protection at the top of
444 # config.h.
445 #
446 AH_TOP([
447 #ifndef GNUPG_CONFIG_H_INCLUDED
448 #define GNUPG_CONFIG_H_INCLUDED
449 ])
450
451 #
452 # Stuff which goes at the bottom of config.h.
453 #
454 AH_BOTTOM([
455 /* This is the major version number of GnuPG so that
456    source included files can test for this.  Note, that
457    we use 2 here even for GnuPG 1.9.x. */
458 #define GNUPG_MAJOR_VERSION 2
459
460 /* Now to separate file name parts.
461    Please note that the string version must not contain more
462    than one character because the code assumes strlen()==1 */
463 #ifdef HAVE_DOSISH_SYSTEM
464 #define DIRSEP_C '\\'
465 #define DIRSEP_S "\\"
466 #define EXTSEP_C '.'
467 #define EXTSEP_S "."
468 #define PATHSEP_C ';'
469 #define PATHSEP_S ";"
470 #define EXEEXT_S ".exe"
471 #else
472 #define DIRSEP_C '/'
473 #define DIRSEP_S "/"
474 #define EXTSEP_C '.'
475 #define EXTSEP_S "."
476 #define PATHSEP_C ':'
477 #define PATHSEP_S ":"
478 #define EXEEXT_S ""
479 #endif
480
481 /* This is the same as VERSION, but should be overridden if the
482    platform cannot handle things like dots '.' in filenames. Set
483    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
484    uses for dots and dashes. */
485 #define SAFE_VERSION VERSION
486 #define SAFE_VERSION_DOT  '.'
487 #define SAFE_VERSION_DASH '-'
488
489 /* Some global constants. */
490 #ifdef HAVE_DOSISH_SYSTEM
491 # ifdef HAVE_DRIVE_LETTERS
492 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
493 # else
494 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
495 # endif
496 #elif defined(__VMS)
497 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
498 #else
499 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
500 #endif
501 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
502 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
503
504 /* For some systems (DOS currently), we hardcode the path here.  For
505    POSIX systems the values are constructed by the Makefiles, so that
506    the values may be overridden by the make invocations; this is to
507    comply with the GNU coding standards.  Note that these values are
508    only defaults.  */
509 #ifdef HAVE_DOSISH_SYSTEM
510 # ifdef HAVE_DRIVE_LETTERS
511 #  define GNUPG_BINDIR      "c:\\gnupg"
512 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
513 #  define GNUPG_LIBDIR      "c:\\gnupg"
514 #  define GNUPG_DATADIR     "c:\\gnupg"
515 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
516 # else
517 #  define GNUPG_BINDIR      "\\gnupg"
518 #  define GNUPG_LIBEXECDIR  "\\gnupg"
519 #  define GNUPG_LIBDIR      "\\gnupg"
520 #  define GNUPG_DATADIR     "\\gnupg"
521 #  define GNUPG_SYSCONFDIR  "\\gnupg"
522 # endif
523 #endif
524
525 /* Derive some other constants. */
526 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
527 #define EXEC_TEMPFILE_ONLY
528 #endif
529
530
531 /* We didn't define endianness above, so get it from OS macros.  This
532    is intended for making fat binary builds on OS X. */
533 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
534 #if defined(__BIG_ENDIAN__)
535 #define BIG_ENDIAN_HOST 1
536 #elif defined(__LITTLE_ENDIAN__)
537 #define LITTLE_ENDIAN_HOST 1
538 #else
539 #error "No endianness found"
540 #endif
541 #endif
542
543
544 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
545    ldap_start_tls_s because that is the actual symbol used in the
546    library.  winldap.h redefines it to our commonly used value,
547    thus we define our usual macro here.  */
548 #ifdef HAVE_LDAP_START_TLS_SA
549 # ifndef HAVE_LDAP_START_TLS_S
550 #  define HAVE_LDAP_START_TLS_S 1
551 # endif
552 #endif
553
554 /* Provide the es_ macro for estream.  */
555 #define GPGRT_ENABLE_ES_MACROS 1
556
557 /* Tell libgcrypt not to use its own libgpg-error implementation. */
558 #define USE_LIBGPG_ERROR 1
559
560 /* Tell Libgcrypt not to include deprecated definitions.  */
561 #define GCRYPT_NO_DEPRECATED 1
562
563 /* Our HTTP code is used in estream mode.  */
564 #define HTTP_USE_ESTREAM 1
565
566 /* Under W32 we do an explicit socket initialization, thus we need to
567    avoid the on-demand initialization which would also install an atexit
568    handler.  */
569 #define HTTP_NO_WSASTARTUP
570
571 /* Under Windows we use the gettext code from libgpg-error.  */
572 #define GPG_ERR_ENABLE_GETTEXT_MACROS
573
574 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
575 #define GPG_ERR_ENABLE_ERRNO_MACROS
576
577 #endif /*GNUPG_CONFIG_H_INCLUDED*/
578 ])
579
580
581 AM_MAINTAINER_MODE
582 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
583
584 # Checks for programs.
585 AC_MSG_NOTICE([checking for programs])
586 AC_PROG_MAKE_SET
587 AM_SANITY_CHECK
588 missing_dir=`cd $ac_aux_dir && pwd`
589 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
590 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
591 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
592 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
593 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
594 AM_SILENT_RULES
595 AC_PROG_AWK
596 AC_PROG_CC
597 AC_PROG_CPP
598 AM_PROG_CC_C_O
599 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
600   AC_MSG_ERROR([[No C-89 compiler found]])
601 fi
602 AC_PROG_INSTALL
603 AC_PROG_LN_S
604 AC_PROG_RANLIB
605 AC_CHECK_TOOL(AR, ar, :)
606 AC_PATH_PROG(PERL,"perl")
607 AC_CHECK_TOOL(WINDRES, windres, :)
608 AC_ISC_POSIX
609 AC_SYS_LARGEFILE
610 GNUPG_CHECK_USTAR
611
612
613 # We need to compile and run a program on the build machine.  A
614 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
615 # the AC archive is broken for autoconf 2.57.  Given that there is no
616 # newer version of that macro, we assume that it is also broken for
617 # autoconf 2.61 and thus we use a simple but usually sufficient
618 # approach.
619 AC_MSG_CHECKING(for cc for build)
620 if test "$cross_compiling" = "yes"; then
621   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
622 else
623   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
624 fi
625 AC_MSG_RESULT($CC_FOR_BUILD)
626 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
627
628 # We need to call this macro because other pkg-config macros are
629 # not always used.
630 PKG_PROG_PKG_CONFIG
631
632
633 try_gettext=yes
634 require_iconv=yes
635 have_dosish_system=no
636 have_w32_system=no
637 have_w32ce_system=no
638 have_android_system=no
639 use_simple_gettext=no
640 use_ldapwrapper=yes
641 mmap_needed=yes
642 case "${host}" in
643     *-mingw32*)
644         # special stuff for Windoze NT
645         ac_cv_have_dev_random=no
646         AC_DEFINE(USE_ONLY_8DOT3,1,
647                   [Set this to limit filenames to the 8.3 format])
648         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
649                   [Because the Unix gettext has too much overhead on
650                    MingW32 systems and these systems lack Posix functions,
651                    we use a simplified version of gettext])
652         have_dosish_system=yes
653         have_w32_system=yes
654         require_iconv=no
655         use_ldapwrapper=no  # Fixme: Do this only for CE.
656         case "${host}" in
657           *-mingw32ce*)
658             have_w32ce_system=yes
659             ;;
660           *)
661             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
662                       [Defined if the OS supports drive letters.])
663             ;;
664         esac
665         try_gettext="no"
666         use_simple_gettext=yes
667         mmap_needed=no
668         ;;
669     i?86-emx-os2 | i?86-*-os2*emx )
670         # OS/2 with the EMX environment
671         ac_cv_have_dev_random=no
672         AC_DEFINE(HAVE_DRIVE_LETTERS)
673         have_dosish_system=yes
674         try_gettext="no"
675         ;;
676
677     i?86-*-msdosdjgpp*)
678         # DOS with the DJGPP environment
679         ac_cv_have_dev_random=no
680         AC_DEFINE(HAVE_DRIVE_LETTERS)
681         have_dosish_system=yes
682         try_gettext="no"
683         ;;
684
685     *-*-hpux*)
686         if test -z "$GCC" ; then
687             CFLAGS="-Ae -D_HPUX_SOURCE $CFLAGS"
688         fi
689         ;;
690     *-dec-osf4*)
691         if test -z "$GCC" ; then
692             # Suppress all warnings
693             # to get rid of the unsigned/signed char mismatch warnings.
694             CFLAGS="-w $CFLAGS"
695         fi
696         ;;
697     *-dec-osf5*)
698         if test -z "$GCC" ; then
699             # Use the newer compiler `-msg_disable ptrmismatch1' to
700             # get rid of the unsigned/signed char mismatch warnings.
701             # Using this may hide other pointer mismatch warnings, but
702             # it at least lets other warning classes through
703             CFLAGS="-msg_disable ptrmismatch1 $CFLAGS"
704         fi
705         ;;
706     m68k-atari-mint)
707         ;;
708     *-linux-android*)
709         have_android_system=yes
710         # Android is fully utf-8 and we do not want to use iconv to
711         # keeps things simple
712         require_iconv=no
713         ;;
714     *-apple-darwin*)
715         AC_DEFINE(_DARWIN_C_SOURCE, 900000L,
716                   Expose all libc features (__DARWIN_C_FULL).)
717         ;;
718     *)
719        ;;
720 esac
721
722 if test "$have_dosish_system" = yes; then
723    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
724              [Defined if we run on some of the PCDOS like systems
725               (DOS, Windoze. OS/2) with special properties like
726               no file modes, case insensitive file names and preferred
727               use of backslashes as directory name separators.])
728 fi
729 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
730
731 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
732
733 if test "$have_w32_system" = yes; then
734    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
735    if test "$have_w32ce_system" = yes; then
736       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
737    fi
738 fi
739 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
740 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
741
742 if test "$have_android_system" = yes; then
743    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
744 fi
745 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
746
747
748 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
749 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
750
751
752 #
753 # Checks for libraries.
754 #
755 AC_MSG_NOTICE([checking for libraries])
756
757
758 #
759 # libgpg-error is a library with error codes shared between GnuPG
760 # related projects.
761 #
762 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
763                   have_gpg_error=yes,have_gpg_error=no)
764
765
766 #
767 # Libgcrypt is our generic crypto library
768 #
769 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
770         have_libgcrypt=yes,have_libgcrypt=no)
771
772
773 #
774 # libassuan is used for IPC
775 #
776 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
777                   have_libassuan=yes,have_libassuan=no)
778 if test "$have_libassuan" = "yes"; then
779   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
780                      [version of the libassuan library])
781   show_tor_support="only .onion"
782 fi
783
784
785 #
786 # libksba is our X.509 support library
787 #
788 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
789
790
791 #
792 # libusb allows us to use the integrated CCID smartcard reader driver.
793 #
794 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
795 if test "$use_ccid_driver" = auto || test "$use_ccid_driver" = yes; then
796    case "${host}" in
797      *-mingw32*)
798        LIBUSB_NAME=
799        LIBUSB_LIBS=
800        LIBUSB_CPPFLAGS=
801        ;;
802      *-*-darwin*)
803        LIBUSB_NAME=usb-1.0
804        LIBUSB_LIBS="-Wl,-framework,CoreFoundation -Wl,-framework,IOKit"
805        ;;
806      *-*-freebsd*)
807        # FreeBSD has a native 1.0 compatible library by -lusb.
808        LIBUSB_NAME=usb
809        LIBUSB_LIBS=
810        ;;
811      *)
812        LIBUSB_NAME=usb-1.0
813        LIBUSB_LIBS=
814        ;;
815    esac
816 fi
817 if test x"$LIBUSB_NAME" != x ; then
818    AC_CHECK_LIB($LIBUSB_NAME, libusb_init,
819                 [ LIBUSB_LIBS="-l$LIBUSB_NAME $LIBUSB_LIBS"
820                   have_libusb=yes ])
821    AC_MSG_CHECKING([libusb include dir])
822    usb_incdir_found="no"
823    for _incdir in "" "/usr/include/libusb-1.0" "/usr/local/include/libusb-1.0"; do
824      _libusb_save_cppflags=$CPPFLAGS
825      if test -n "${_incdir}"; then
826        CPPFLAGS="-I${_incdir} ${CPPFLAGS}"
827      fi
828      AC_PREPROC_IFELSE([AC_LANG_SOURCE([[@%:@include <libusb.h>]])],
829      [usb_incdir=${_incdir}; usb_incdir_found="yes"], [])
830      CPPFLAGS=${_libusb_save_cppflags}
831      if test "$usb_incdir_found" = "yes"; then
832        break
833      fi
834    done
835    if test "$usb_incdir_found" = "yes"; then
836      AC_MSG_RESULT([${usb_incdir}])
837    else
838      AC_MSG_RESULT([not found])
839      usb_incdir=""
840      have_libusb=no
841      if test "$use_ccid_driver" != yes; then
842        use_ccid_driver=no
843      fi
844      LIBUSB_LIBS=""
845    fi
846
847    if test "$have_libusb" = yes; then
848      AC_DEFINE(HAVE_LIBUSB,1, [defined if libusb is available])
849    fi
850    if test x"$usb_incdir" = x; then
851      LIBUSB_CPPFLAGS=""
852    else
853      LIBUSB_CPPFLAGS="-I${usb_incdir}"
854    fi
855 fi
856 AC_SUBST(LIBUSB_LIBS)
857 AC_SUBST(LIBUSB_CPPFLAGS)
858
859 #
860 # Check wether it is necessary to link against libdl.
861 # (For example to load libpcsclite)
862 #
863 gnupg_dlopen_save_libs="$LIBS"
864 LIBS=""
865 AC_SEARCH_LIBS(dlopen, c dl,,,)
866 DL_LIBS=$LIBS
867 AC_SUBST(DL_LIBS)
868 LIBS="$gnupg_dlopen_save_libs"
869
870
871 # Checks for g10
872
873 AC_ARG_ENABLE(sqlite,
874                 AC_HELP_STRING([--disable-sqlite],
875                                [disable the use of SQLITE]),
876               try_sqlite=$enableval, try_sqlite=yes)
877
878 if test x"$use_tofu" = xyes ; then
879   if test x"$try_sqlite" = xyes ; then
880     PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $NEED_SQLITE_VERSION],
881                                  [have_sqlite=yes],
882                                  [have_sqlite=no])
883   fi
884   if test "$have_sqlite" = "yes"; then
885     :
886     AC_SUBST([SQLITE3_CFLAGS])
887     AC_SUBST([SQLITE3_LIBS])
888   else
889     use_tofu=no
890     tmp=$(echo "$SQLITE3_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
891     AC_MSG_WARN([[
892 ***
893 *** Building without SQLite support - TOFU disabled
894 ***
895 *** $tmp]])
896   fi
897 fi
898
899 AM_CONDITIONAL(SQLITE3, test "$have_sqlite" = "yes")
900
901 if test x"$use_tofu" = xyes ; then
902     AC_DEFINE(USE_TOFU, 1, [Enable to build the TOFU code])
903 fi
904
905
906 # Checks for g13
907
908 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
909 AC_DEFINE_UNQUOTED(ENCFS,
910         "${ENCFS}", [defines the filename of the encfs program])
911
912 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
913 AC_DEFINE_UNQUOTED(FUSERMOUNT,
914         "${FUSERMOUNT}", [defines the filename of the fusermount program])
915
916
917 # Checks for dirmngr
918
919
920 #
921 # Checks for symcryptrun:
922 #
923
924 # libutil has openpty() and login_tty().
925 AC_CHECK_LIB(util, openpty,
926               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
927                 AC_DEFINE(HAVE_LIBUTIL,1,
928                          [defined if libutil is available])
929              ])
930 AC_SUBST(LIBUTIL_LIBS)
931
932 # shred is used to clean temporary plain text files.
933 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
934 AC_DEFINE_UNQUOTED(SHRED,
935         "${SHRED}", [defines the filename of the shred program])
936
937
938 #
939 # Check whether the nPth library is available
940 #
941 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
942 if test "$have_npth" = "yes"; then
943   AC_DEFINE(HAVE_NPTH, 1,
944               [Defined if the New Portable Thread Library is available])
945   AC_DEFINE(USE_NPTH, 1,
946               [Defined if support for nPth is requested and nPth is available])
947 else
948   AC_MSG_WARN([[
949 ***
950 *** To support concurrent access for example in gpg-agent and the SCdaemon
951 *** we need the support of the New Portable Threads Library.
952 ***]])
953 fi
954
955
956 #
957 # NTBTLS is our TLS library.  If it is not available fallback to
958 # GNUTLS.
959 #
960 AC_ARG_ENABLE(ntbtls,
961               AC_HELP_STRING([--disable-ntbtls],
962                              [disable the use of NTBTLS as TLS library]),
963               try_ntbtls=$enableval, try_ntbtls=yes)
964 if test x"$try_ntbtls" = xyes ; then
965   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
966                  [have_ntbtls=yes],[have_ntbtls=no])
967 fi
968 if test "$have_ntbtls" = yes ; then
969    use_tls_library=ntbtls
970    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
971 else
972   AC_ARG_ENABLE(gnutls,
973                 AC_HELP_STRING([--disable-gnutls],
974                                [disable GNUTLS as fallback TLS library]),
975                 try_gnutls=$enableval, try_gnutls=yes)
976   if test x"$try_gnutls" = xyes ; then
977     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
978                                    [have_gnutls=yes],
979                                    [have_gnutls=no])
980   fi
981   if test "$have_gnutls" = "yes"; then
982     AC_SUBST([LIBGNUTLS_CFLAGS])
983     AC_SUBST([LIBGNUTLS_LIBS])
984     use_tls_library=gnutls
985     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
986   else
987     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
988     AC_MSG_WARN([[
989 ***
990 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
991 ***
992 *** $tmp]])
993   fi
994 fi
995
996 #
997 # Allow to set a fixed trust store file for system provided certificates.
998 #
999 AC_ARG_WITH([default-trust-store-file],
1000             [AC_HELP_STRING([--with-default-trust-store-file=FILE],
1001                             [Use FILE as system trust store])],
1002             default_trust_store_file="$withval",
1003             default_trust_store_file="")
1004 if test x"$default_trust_store_file" = xno;then
1005   default_trust_store_file=""
1006 fi
1007 if test x"$default_trust_store_file" != x ; then
1008   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
1009     ["$default_trust_store_file"], [Use as default system trust store file])
1010 fi
1011
1012
1013 AC_MSG_NOTICE([checking for networking options])
1014
1015 #
1016 # Must check for network library requirements before doing link tests
1017 # for ldap, for example. If ldap libs are static (or dynamic and without
1018 # ELF runtime link paths), then link will fail and LDAP support won't
1019 # be detected.
1020 #
1021 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
1022         [NETLIBS="-lnsl $NETLIBS"]))
1023 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
1024         [NETLIBS="-lsocket $NETLIBS"]))
1025
1026
1027 #
1028 # Check standard resolver functions.
1029 #
1030 if test "$build_dirmngr" = "yes"; then
1031   _dns_save_libs=$LIBS
1032   LIBS=""
1033
1034   # Find the system resolver which can always be enabled with
1035   # the dirmngr option --standard-resolver.
1036
1037   # the double underscore thing is a glibc-ism?
1038   AC_SEARCH_LIBS(res_query,resolv bind,,
1039                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
1040   AC_SEARCH_LIBS(dn_expand,resolv bind,,
1041                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
1042
1043   # macOS renames dn_skipname into res_9_dn_skipname in <resolv.h>,
1044   # and for some reason fools us into believing we don't need
1045   # -lresolv even if we do.  Since the test program checking for the
1046   # symbol does not include <resolv.h>, we need to check for the
1047   # renamed symbol explicitly.
1048   AC_SEARCH_LIBS(res_9_dn_skipname,resolv bind,,
1049       AC_SEARCH_LIBS(dn_skipname,resolv bind,,
1050           AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no)))
1051
1052   if test x"$have_resolver" != xno ; then
1053
1054       # Make sure that the BIND 4 resolver interface is workable before
1055       # enabling any code that calls it.  At some point I'll rewrite the
1056       # code to use the BIND 8 resolver API.
1057       # We might also want to use libdns instead.
1058
1059     AC_MSG_CHECKING([whether the resolver is usable])
1060     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1061 #include <netinet/in.h>
1062 #include <arpa/nameser.h>
1063 #include <resolv.h>]],
1064 [[unsigned char answer[PACKETSZ];
1065   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1066   dn_skipname(0,0);
1067   dn_expand(0,0,0,0,0);
1068 ]])],have_resolver=yes,have_resolver=no)
1069     AC_MSG_RESULT($have_resolver)
1070
1071     # This is Apple-specific and somewhat bizarre as they changed the
1072     # define in bind 8 for some reason.
1073
1074     if test x"$have_resolver" != xyes ; then
1075       AC_MSG_CHECKING(
1076            [whether I can make the resolver usable with BIND_8_COMPAT])
1077       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
1078 #include <sys/types.h>
1079 #include <netinet/in.h>
1080 #include <arpa/nameser.h>
1081 #include <resolv.h>]],
1082 [[unsigned char answer[PACKETSZ];
1083   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1084   dn_skipname(0,0); dn_expand(0,0,0,0,0);
1085 ]])],[have_resolver=yes ; need_compat=yes])
1086       AC_MSG_RESULT($have_resolver)
1087     fi
1088   fi
1089
1090   if test x"$have_resolver" = xyes ; then
1091     AC_DEFINE(HAVE_SYSTEM_RESOLVER,1,[The system's resolver is usable.])
1092     DNSLIBS="$DNSLIBS $LIBS"
1093     if test x"$need_compat" = xyes ; then
1094       AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
1095     fi
1096     if test "$use_libdns" = yes; then
1097      show_tor_support=yes
1098     fi
1099   elif test "$use_libdns" = yes; then
1100     show_tor_support=yes
1101   else
1102     AC_MSG_WARN([[
1103 ***
1104 *** The system's DNS resolver is not usable.
1105 *** Dirmngr functionality is limited.
1106 ***]])
1107     show_tor_support="${show_tor_support} (no system resolver)"
1108   fi
1109
1110   if test "$have_w32_system" = yes; then
1111     if test "$use_libdns" = yes; then
1112       DNSLIBS="$DNSLIBS -liphlpapi"
1113     fi
1114   fi
1115
1116   LIBS=$_dns_save_libs
1117 fi
1118
1119 AC_SUBST(DNSLIBS)
1120
1121
1122 #
1123 # Check for LDAP
1124 #
1125 # Note that running the check changes the variable
1126 # gnupg_have_ldap from "n/a" to "no" or "yes".
1127
1128 AC_ARG_ENABLE(ldap,
1129     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1130     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1131
1132 if test "$gnupg_have_ldap" != "no" ; then
1133   if test "$build_dirmngr" = "yes" ; then
1134      GNUPG_CHECK_LDAP($NETLIBS)
1135      AC_CHECK_LIB(lber, ber_free,
1136                   [ LBER_LIBS="$LBER_LIBS -llber"
1137                     AC_DEFINE(HAVE_LBER,1,
1138                              [defined if liblber is available])
1139                     have_lber=yes
1140                  ])
1141   fi
1142 fi
1143 AC_SUBST(LBER_LIBS)
1144 if test "$gnupg_have_ldap" = "no"; then
1145     AC_MSG_WARN([[
1146 ***
1147 *** Building without LDAP support.
1148 *** No CRL access or X.509 certificate search available.
1149 ***]])
1150 fi
1151
1152 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1153 if test "$gnupg_have_ldap" = yes ; then
1154   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1155 else
1156  use_ldapwrapper=no
1157 fi
1158
1159 if test "$use_ldapwrapper" = yes; then
1160    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1161 fi
1162 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1163
1164
1165
1166
1167 #
1168 # Check for sendmail
1169 #
1170 # This isn't necessarily sendmail itself, but anything that gives a
1171 # sendmail-ish interface to the outside world.  That includes Exim,
1172 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1173 AC_ARG_WITH(mailprog,
1174       AC_HELP_STRING([--with-mailprog=NAME],
1175                      [use "NAME -t" for mail transport]),
1176              ,with_mailprog=yes)
1177 if test x"$with_mailprog" = xyes ; then
1178     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1179 elif test x"$with_mailprog" != xno ; then
1180     AC_MSG_CHECKING([for a mail transport program])
1181     AC_SUBST(SENDMAIL,$with_mailprog)
1182     AC_MSG_RESULT($with_mailprog)
1183 fi
1184
1185
1186 #
1187 # Construct a printable name of the OS
1188 #
1189 case "${host}" in
1190     *-mingw32ce*)
1191         PRINTABLE_OS_NAME="W32CE"
1192         ;;
1193     *-mingw32*)
1194         PRINTABLE_OS_NAME="MingW32"
1195         ;;
1196     *-*-cygwin*)
1197         PRINTABLE_OS_NAME="Cygwin"
1198         ;;
1199     i?86-emx-os2 | i?86-*-os2*emx )
1200         PRINTABLE_OS_NAME="OS/2"
1201         ;;
1202     i?86-*-msdosdjgpp*)
1203         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1204         try_dynload=no
1205         ;;
1206     *-linux*)
1207         PRINTABLE_OS_NAME="GNU/Linux"
1208         ;;
1209     *)
1210         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1211         ;;
1212 esac
1213 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1214                    [A human readable text with the name of the OS])
1215
1216
1217 #
1218 # Checking for iconv
1219 #
1220 if test "$require_iconv" = yes; then
1221   AM_ICONV
1222 else
1223   LIBICONV=
1224   LTLIBICONV=
1225   AC_SUBST(LIBICONV)
1226   AC_SUBST(LTLIBICONV)
1227 fi
1228
1229
1230 #
1231 # Check for gettext
1232 #
1233 # This is "GNU gnupg" - The project-id script from gettext
1234 #                       needs this string
1235 #
1236 AC_MSG_NOTICE([checking for gettext])
1237 AM_PO_SUBDIRS
1238 AM_GNU_GETTEXT_VERSION([0.17])
1239 if test "$try_gettext" = yes; then
1240   AM_GNU_GETTEXT([external],[need-ngettext])
1241
1242   # gettext requires some extra checks.  These really should be part of
1243   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1244   # function checks to here.
1245
1246   AC_CHECK_FUNCS(strchr)
1247 else
1248   USE_NLS=no
1249   USE_INCLUDED_LIBINTL=no
1250   BUILD_INCLUDED_LIBINTL=no
1251   POSUB=po
1252   AC_SUBST(USE_NLS)
1253   AC_SUBST(USE_INCLUDED_LIBINTL)
1254   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1255   AC_SUBST(POSUB)
1256 fi
1257
1258 # We use HAVE_LANGINFO_CODESET in a couple of places.
1259 AM_LANGINFO_CODESET
1260
1261 # Checks required for our use of locales
1262 gt_LC_MESSAGES
1263
1264
1265 #
1266 # SELinux support
1267 #
1268 if test "$selinux_support" = yes ; then
1269   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1270 fi
1271
1272
1273 #
1274 # Checks for header files.
1275 #
1276 AC_MSG_NOTICE([checking for header files])
1277 AC_HEADER_STDC
1278 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1279                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h     \
1280                   stdint.h signal.h util.h libutil.h termios.h \
1281                   ucred.h])
1282
1283 AC_HEADER_TIME
1284
1285
1286 #
1287 # Checks for typedefs, structures, and compiler characteristics.
1288 #
1289 AC_MSG_NOTICE([checking for system characteristics])
1290 AC_C_CONST
1291 AC_C_INLINE
1292 AC_C_VOLATILE
1293 AC_TYPE_SIZE_T
1294 AC_TYPE_MODE_T
1295 AC_TYPE_SIGNAL
1296 AC_DECL_SYS_SIGLIST
1297
1298 gl_HEADER_SYS_SOCKET
1299 gl_TYPE_SOCKLEN_T
1300
1301 AC_SEARCH_LIBS([inet_addr], [nsl])
1302
1303 AC_ARG_ENABLE(endian-check,
1304               AC_HELP_STRING([--disable-endian-check],
1305               [disable the endian check and trust the OS provided macros]),
1306               endiancheck=$enableval,endiancheck=yes)
1307
1308 if test x"$endiancheck" = xyes ; then
1309   GNUPG_CHECK_ENDIAN
1310 fi
1311
1312 # fixme: we should get rid of the byte type
1313 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1314 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1315 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1316 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1317 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1318
1319 AC_CHECK_SIZEOF(unsigned short)
1320 AC_CHECK_SIZEOF(unsigned int)
1321 AC_CHECK_SIZEOF(unsigned long)
1322 AC_CHECK_SIZEOF(unsigned long long)
1323 AC_HEADER_TIME
1324 AC_CHECK_SIZEOF(time_t,,[[
1325 #include <stdio.h>
1326 #if TIME_WITH_SYS_TIME
1327 # include <sys/time.h>
1328 # include <time.h>
1329 #else
1330 # if HAVE_SYS_TIME_H
1331 #  include <sys/time.h>
1332 # else
1333 #  include <time.h>
1334 # endif
1335 #endif
1336 ]])
1337 GNUPG_TIME_T_UNSIGNED
1338
1339
1340 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1341    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1342    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1343     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1344 fi
1345
1346
1347 #
1348 # Checks for library functions.
1349 #
1350 AC_MSG_NOTICE([checking for library functions])
1351 AC_CHECK_DECLS(getpagesize)
1352 AC_FUNC_FSEEKO
1353 AC_FUNC_VPRINTF
1354 AC_FUNC_FORK
1355 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1356 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1357 AC_CHECK_FUNCS([setenv unsetenv fcntl ftruncate inet_ntop])
1358 AC_CHECK_FUNCS([canonicalize_file_name])
1359 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1360 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1361 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1362 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1363 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1364                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1365                 flockfile funlockfile getpwnam getpwuid \
1366                 getenv inet_pton strpbrk])
1367
1368 # On some systems (e.g. Solaris) nanosleep requires linking to librl.
1369 # Given that we use nanosleep only as an optimization over a select
1370 # based wait function we want it only if it is available in libc.
1371 _save_libs="$LIBS"
1372 AC_SEARCH_LIBS([nanosleep], [],
1373                [AC_DEFINE(HAVE_NANOSLEEP,1,
1374                 [Define to 1 if you have the `nanosleep' function in libc.])])
1375 LIBS="$_save_libs"
1376
1377
1378 # See whether libc supports the Linux inotify interface
1379 case "${host}" in
1380     *-*-linux*)
1381         AC_CHECK_FUNCS([inotify_init])
1382         ;;
1383 esac
1384
1385
1386 if test "$have_android_system" = yes; then
1387    # On Android ttyname is a stub but prints an error message.
1388    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1389              [Defined if ttyname does not work properly])
1390 fi
1391
1392 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1393
1394 # Dirmngr requires mmap on Unix systems.
1395 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1396   AC_MSG_ERROR([[Sorry, the current implemenation requires mmap.]])
1397 fi
1398
1399
1400 #
1401 # Check for the getsockopt SO_PEERCRED, etc.
1402 #
1403 AC_CHECK_MEMBERS([struct ucred.pid, struct ucred.cr_pid, struct sockpeercred.pid], [], [], [#include <sys/types.h>
1404 #include <sys/socket.h> ])
1405
1406 # (Open)Solaris
1407 AC_CHECK_FUNCS([getpeerucred])
1408
1409
1410 #
1411 # W32 specific test
1412 #
1413 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1414
1415 #
1416 # Sanity check regex.  Tests adapted from mutt.
1417 #
1418 AC_MSG_CHECKING([whether regular expression support is requested])
1419 AC_ARG_ENABLE(regex,
1420   AC_HELP_STRING([--disable-regex],
1421     [do not handle regular expressions in trust signatures]),
1422   use_regex=$enableval, use_regex=yes)
1423 AC_MSG_RESULT($use_regex)
1424
1425 if test "$use_regex" = yes ; then
1426   _cppflags="${CPPFLAGS}"
1427   _ldflags="${LDFLAGS}"
1428   AC_ARG_WITH(regex,
1429      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1430       [
1431       if test -d "$withval" ; then
1432         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1433         LDFLAGS="${LDFLAGS} -L$withval/lib"
1434       fi
1435       ],withval="")
1436
1437   # Does the system have regex functions at all?
1438   AC_SEARCH_LIBS([regcomp], [regex])
1439   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1440
1441   if test $gnupg_cv_have_regex = no; then
1442     use_regex=no
1443   else
1444     if test x"$cross_compiling" = xyes; then
1445       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1446     else
1447       AC_CACHE_CHECK([whether your system's regexp library is broken],
1448        [gnupg_cv_regex_broken],
1449        AC_TRY_RUN([
1450 #include <unistd.h>
1451 #include <regex.h>
1452 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1453        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1454
1455       if test $gnupg_cv_regex_broken = yes; then
1456         AC_MSG_WARN([your regex is broken - disabling regex use])
1457         use_regex=no
1458       fi
1459     fi
1460   fi
1461   CPPFLAGS="${_cppflags}"
1462   LDFLAGS="${_ldflags}"
1463 fi
1464
1465 if test "$use_regex" != yes ; then
1466   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1467 fi
1468 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1469
1470
1471
1472 #
1473 # Do we have zlib? Must do it here because Solaris failed
1474 # when compiling a conftest (due to the "-lz" from LIBS).
1475 # Note that we combine zlib and bzlib2 in ZLIBS.
1476 #
1477 if test "$use_zip" = yes ; then
1478   _cppflags="${CPPFLAGS}"
1479   _ldflags="${LDFLAGS}"
1480   AC_ARG_WITH(zlib,
1481     [  --with-zlib=DIR         use libz in DIR],[
1482       if test -d "$withval"; then
1483         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1484         LDFLAGS="${LDFLAGS} -L$withval/lib"
1485       fi
1486     ])
1487
1488   AC_CHECK_HEADER(zlib.h,
1489      AC_CHECK_LIB(z, deflateInit2_,
1490        [
1491        ZLIBS="-lz"
1492        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1493        ],
1494        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1495        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1496 fi
1497
1498
1499 #
1500 # Check whether we can support bzip2
1501 #
1502 if test "$use_bzip2" = yes ; then
1503   _cppflags="${CPPFLAGS}"
1504   _ldflags="${LDFLAGS}"
1505   AC_ARG_WITH(bzip2,
1506      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1507       [
1508       if test -d "$withval" ; then
1509         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1510         LDFLAGS="${LDFLAGS} -L$withval/lib"
1511       fi
1512       ],withval="")
1513
1514   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1515   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1516   # woefully out of date.
1517   if test "$withval" != no ; then
1518      AC_CHECK_HEADER(bzlib.h,
1519         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1520           [
1521           have_bz2=yes
1522           ZLIBS="$ZLIBS -lbz2"
1523           AC_DEFINE(HAVE_BZIP2,1,
1524                   [Defined if the bz2 compression library is available])
1525           ],
1526           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1527           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1528   fi
1529 fi
1530 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1531 AC_SUBST(ZLIBS)
1532
1533
1534 # Check for readline support
1535 GNUPG_CHECK_READLINE
1536
1537
1538 if test "$development_version" = yes; then
1539     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1540             [Defined if this is not a regular release])
1541 fi
1542
1543 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1544
1545 GNUPG_CHECK_GNUMAKE
1546
1547 # Add some extra libs here so that previous tests don't fail for
1548 # mysterious reasons - the final link step should bail out.
1549 # W32SOCKLIBS is also defined so that if can be used for tools not
1550 # requiring any network stuff but linking to code in libcommon which
1551 # tracks in winsock stuff (e.g. init_common_subsystems).
1552 if test "$have_w32_system" = yes; then
1553    if test "$have_w32ce_system" = yes; then
1554      W32SOCKLIBS="-lws2"
1555    else
1556      W32SOCKLIBS="-lws2_32"
1557    fi
1558    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1559 fi
1560
1561 AC_SUBST(NETLIBS)
1562 AC_SUBST(W32SOCKLIBS)
1563
1564 #
1565 # Setup gcc specific options
1566 #
1567 USE_C99_CFLAGS=
1568 AC_MSG_NOTICE([checking for cc features])
1569 if test "$GCC" = yes; then
1570     mycflags=
1571     mycflags_save=$CFLAGS
1572
1573     # Check whether gcc does not emit a diagnositc for unknow -Wno-*
1574     # options.  This is the case for gcc >= 4.6
1575     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1576     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1577 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1578 #kickerror
1579 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1580     AC_MSG_RESULT($_gcc_silent_wno)
1581
1582     # Note that it is okay to use CFLAGS here because these are just
1583     # warning options and the user should have a chance of overriding
1584     # them.
1585     if test "$USE_MAINTAINER_MODE" = "yes"; then
1586         mycflags="$mycflags -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1587         mycflags="$mycflags -Wformat -Wno-format-y2k -Wformat-security"
1588         if test x"$_gcc_silent_wno" = xyes ; then
1589           _gcc_wopt=yes
1590         else
1591           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1592           CFLAGS="-Wno-missing-field-initializers"
1593           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1594                             [_gcc_wopt=yes],[_gcc_wopt=no])
1595           AC_MSG_RESULT($_gcc_wopt)
1596         fi
1597         if test x"$_gcc_wopt" = xyes ; then
1598           mycflags="$mycflags -W -Wno-sign-compare"
1599           mycflags="$mycflags -Wno-missing-field-initializers"
1600         fi
1601
1602         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1603         CFLAGS="-Wdeclaration-after-statement"
1604         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1605         AC_MSG_RESULT($_gcc_wopt)
1606         if test x"$_gcc_wopt" = xyes ; then
1607           mycflags="$mycflags -Wdeclaration-after-statement"
1608         fi
1609
1610         AC_MSG_CHECKING([if gcc supports -Wlogical-op and -Wvla])
1611         CFLAGS="-Wlogical-op -Wvla"
1612         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1613         AC_MSG_RESULT($_gcc_wopt)
1614         if test x"$_gcc_wopt" = xyes ; then
1615           mycflags="$mycflags -Wlogical-op -Wvla"
1616         fi
1617
1618     else
1619         mycflags="$mycflags -Wall"
1620     fi
1621
1622     if test x"$_gcc_silent_wno" = xyes ; then
1623       _gcc_psign=yes
1624     else
1625       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1626       CFLAGS="-Wno-pointer-sign"
1627       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1628                         [_gcc_psign=yes],[_gcc_psign=no])
1629       AC_MSG_RESULT($_gcc_psign)
1630     fi
1631     if test x"$_gcc_psign" = xyes ; then
1632        mycflags="$mycflags -Wno-pointer-sign"
1633     fi
1634
1635     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1636     CFLAGS="-Wpointer-arith"
1637     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1638     AC_MSG_RESULT($_gcc_psign)
1639     if test x"$_gcc_psign" = xyes ; then
1640        mycflags="$mycflags -Wpointer-arith"
1641     fi
1642
1643     CFLAGS="$mycflags $mycflags_save"
1644     if test "$use_libdns" = yes; then
1645        # dirmngr/dns.{c,h} require C99 and GNU extensions.  */
1646        USE_C99_CFLAGS="-std=gnu99"
1647     fi
1648 fi
1649
1650 AC_SUBST(USE_C99_CFLAGS)
1651
1652
1653 #
1654 # This is handy for debugging so the compiler doesn't rearrange
1655 # things and eliminate variables.
1656 #
1657 AC_ARG_ENABLE(optimization,
1658    AC_HELP_STRING([--disable-optimization],
1659                   [disable compiler optimization]),
1660                   [if test $enableval = no ; then
1661                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1662                    fi])
1663
1664 #
1665 # We do not want support for the GNUPG_BUILDDIR environment variable
1666 # in a released version.  However, our regression tests suite requires
1667 # this and thus we build with support for it during "make distcheck".
1668 # This configure option implements this along with the top Makefile's
1669 # AM_DISTCHECK_CONFIGURE_FLAGS.
1670 #
1671 gnupg_builddir_envvar=no
1672 AC_ARG_ENABLE(gnupg-builddir-envvar,,
1673               gnupg_builddir_envvar=$enableval)
1674 if test x"$gnupg_builddir_envvar" = x"yes"; then
1675    AC_DEFINE(ENABLE_GNUPG_BUILDDIR_ENVVAR, 1,
1676       [This is only used with "make distcheck"])
1677 fi
1678
1679 #
1680 # Add user CFLAGS.
1681 #
1682 CFLAGS="$CFLAGS $CFLAGS_orig"
1683
1684 #
1685 # Decide what to build
1686 #
1687
1688 build_scdaemon_extra=""
1689 if test "$build_scdaemon" = "yes"; then
1690   if test $have_libusb = no; then
1691      build_scdaemon_extra="without internal CCID driver"
1692   fi
1693   if test -n "$build_scdaemon_extra"; then
1694      build_scdaemon_extra="(${build_scdaemon_extra})"
1695   fi
1696 fi
1697
1698
1699 #
1700 # Set variables for use by automake makefiles.
1701 #
1702 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1703 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1704 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1705 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1706 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1707 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1708 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1709 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1710 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1711 AM_CONDITIONAL(BUILD_WKS_TOOLS,   test "$build_wks_tools" = "yes")
1712
1713 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1714 AM_CONDITIONAL(NO_TRUST_MODELS,     test "$use_trust_models" = no)
1715 AM_CONDITIONAL(USE_TOFU,            test "$use_tofu" = yes)
1716
1717 #
1718 # Set some defines for use gpgconf.
1719 #
1720 if test "$build_gpg" = yes ; then
1721     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1722 fi
1723 if test "$build_gpgsm" = yes ; then
1724     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1725 fi
1726 if test "$build_agent" = yes ; then
1727     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1728 fi
1729 if test "$build_scdaemon" = yes ; then
1730     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1731 fi
1732 if test "$build_dirmngr" = yes ; then
1733     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if SCDAEMON is to be build])
1734 fi
1735 if test "$build_g13" = yes ; then
1736     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1737 fi
1738
1739
1740 #
1741 # Define Name strings
1742 #
1743 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1744
1745 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1746 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1747
1748 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1749 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1750
1751 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1752 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1753                                         [The displayed name of gpg-agent])
1754
1755 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1756 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1757                                        [The displayed name of scdaemon])
1758
1759 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1760 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1761                                       [The displayed name of dirmngr])
1762
1763 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1764 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1765
1766 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1767 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1768                                       [The displayed name of gpgconf])
1769
1770 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1771
1772 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1773                    [The name of the agent socket])
1774 AC_DEFINE_UNQUOTED(GPG_AGENT_EXTRA_SOCK_NAME, "S.gpg-agent.extra",
1775                    [The name of the agent socket for remote access])
1776 AC_DEFINE_UNQUOTED(GPG_AGENT_BROWSER_SOCK_NAME, "S.gpg-agent.browser",
1777                    [The name of the agent socket for browsers])
1778 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1779                    [The name of the agent socket for ssh])
1780 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1781                    [The name of the dirmngr info envvar])
1782 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1783                    [The name of the SCdaemon socket])
1784 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1785                    [The name of the dirmngr socket])
1786 AC_DEFINE_UNQUOTED(DIRMNGR_DEFAULT_KEYSERVER,
1787                    "hkps://hkps.pool.sks-keyservers.net",
1788       [The default keyserver for dirmngr to use, if none is explicitly given])
1789
1790 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1791
1792 if test "$have_w32_system" = yes; then
1793   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "\\\\Software\\\\GNU\\\\GnuPG",
1794                      [The directory part of the W32 registry keys])
1795 fi
1796
1797
1798 #
1799 # Provide information about the build.
1800 #
1801 BUILD_REVISION="mym4_revision"
1802 AC_SUBST(BUILD_REVISION)
1803 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1804                    [GIT commit id revision used to build this package])
1805
1806 changequote(,)dnl
1807 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1808 changequote([,])dnl
1809 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1810 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1811 AC_SUBST(BUILD_VERSION)
1812 AC_SUBST(BUILD_FILEVERSION)
1813
1814 AC_ARG_ENABLE([build-timestamp],
1815   AC_HELP_STRING([--enable-build-timestamp],
1816                  [set an explicit build timestamp for reproducibility.
1817                   (default is the current time in ISO-8601 format)]),
1818      [if test "$enableval" = "yes"; then
1819         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1820       else
1821         BUILD_TIMESTAMP="$enableval"
1822       fi
1823       BUILD_HOSTNAME="$ac_hostname"],
1824      [BUILD_TIMESTAMP="<none>"
1825       BUILD_HOSTNAME="<anon>"])
1826 AC_SUBST(BUILD_TIMESTAMP)
1827 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1828                    [The time this package was configured for a build])
1829 AC_SUBST(BUILD_HOSTNAME)
1830
1831
1832 #
1833 # Print errors here so that they are visible all
1834 # together and the user can acquire them all together.
1835 #
1836 die=no
1837 if test "$have_gpg_error" = "no"; then
1838    die=yes
1839    AC_MSG_NOTICE([[
1840 ***
1841 *** You need libgpg-error to build this program.
1842 **  This library is for example available at
1843 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1844 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1845 ***]])
1846 fi
1847 if test "$have_libgcrypt" = "no"; then
1848    die=yes
1849    AC_MSG_NOTICE([[
1850 ***
1851 *** You need libgcrypt to build this program.
1852 **  This library is for example available at
1853 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1854 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1855 ***]])
1856 fi
1857 if test "$have_libassuan" = "no"; then
1858    die=yes
1859    AC_MSG_NOTICE([[
1860 ***
1861 *** You need libassuan to build this program.
1862 *** This library is for example available at
1863 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1864 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1865 ***]])
1866 fi
1867 if test "$have_ksba" = "no"; then
1868     die=yes
1869     AC_MSG_NOTICE([[
1870 ***
1871 *** You need libksba to build this program.
1872 *** This library is for example available at
1873 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1874 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1875 ***]])
1876 fi
1877 if test "$gnupg_have_ldap" = yes; then
1878   if test "$have_w32ce_system" = yes; then
1879     AC_MSG_NOTICE([[
1880 *** Note that CeGCC might be broken, a package fixing this is:
1881 ***    http://files.kolab.org/local/windows-ce/
1882 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1883 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1884 ***]])
1885    fi
1886 fi
1887 if test "$have_npth" = "no"; then
1888     die=yes
1889     AC_MSG_NOTICE([[
1890 ***
1891 *** It is now required to build with support for the
1892 *** New Portable Threads Library (nPth). Please install this
1893 *** library first.  The library is for example available at
1894 ***   ftp://ftp.gnupg.org/gcrypt/npth/
1895 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1896 ***]])
1897 fi
1898
1899 if test "$require_iconv" = yes; then
1900   if test "$am_func_iconv" != yes; then
1901     die=yes
1902     AC_MSG_NOTICE([[
1903 ***
1904 *** The system does not provide a working iconv function.  Please
1905 *** install a suitable library; for example GNU Libiconv which is
1906 *** available at:
1907 ***   http://ftp.gnu.org/gnu/libiconv/
1908 ***]])
1909   fi
1910 fi
1911
1912 if test "$use_ccid_driver" = yes; then
1913   if test "$have_libusb" != yes; then
1914     die=yes
1915     AC_MSG_NOTICE([[
1916 ***
1917 *** You need libusb to build the internal ccid driver.  Please
1918 *** install a libusb suitable for your system.
1919 ***]])
1920   fi
1921 fi
1922
1923 if test "$die" = "yes"; then
1924     AC_MSG_ERROR([[
1925 ***
1926 *** Required libraries not found. Please consult the above messages
1927 *** and install them before running configure again.
1928 ***]])
1929 fi
1930
1931
1932
1933 AC_CONFIG_FILES([ m4/Makefile
1934 Makefile
1935 po/Makefile.in
1936 common/Makefile
1937 common/w32info-rc.h
1938 kbx/Makefile
1939 g10/Makefile
1940 sm/Makefile
1941 agent/Makefile
1942 scd/Makefile
1943 g13/Makefile
1944 dirmngr/Makefile
1945 tools/gpg-zip
1946 tools/Makefile
1947 doc/Makefile
1948 tests/Makefile
1949 tests/gpgscm/Makefile
1950 tests/openpgp/Makefile
1951 tests/migrations/Makefile
1952 tests/gpgsm/Makefile
1953 tests/gpgme/Makefile
1954 tests/pkits/Makefile
1955 g10/gpg.w32-manifest
1956 ])
1957
1958
1959 AC_OUTPUT
1960
1961
1962 echo "
1963         GnuPG v${VERSION} has been configured as follows:
1964
1965         Revision:  mym4_revision  (mym4_revision_dec)
1966         Platform:  $PRINTABLE_OS_NAME ($host)
1967
1968         OpenPGP:   $build_gpg
1969         S/MIME:    $build_gpgsm
1970         Agent:     $build_agent
1971         Smartcard: $build_scdaemon $build_scdaemon_extra
1972         G13:       $build_g13
1973         Dirmngr:   $build_dirmngr
1974         Gpgtar:    $build_gpgtar
1975         WKS tools: $build_wks_tools
1976
1977         Protect tool:      $show_gnupg_protect_tool_pgm
1978         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
1979         Default agent:     $show_gnupg_agent_pgm
1980         Default pinentry:  $show_gnupg_pinentry_pgm
1981         Default scdaemon:  $show_gnupg_scdaemon_pgm
1982         Default dirmngr:   $show_gnupg_dirmngr_pgm
1983
1984         Dirmngr auto start:  $dirmngr_auto_start
1985         Readline support:    $gnupg_cv_have_readline
1986         LDAP support:        $gnupg_have_ldap
1987         TLS support:         $use_tls_library
1988         TOFU support:        $use_tofu
1989         Tor support:         $show_tor_support
1990 "
1991 if test x"$use_regex" != xyes ; then
1992 echo "
1993         Warning: No regular expression support available.
1994                  OpenPGP trust signatures won't work.
1995                  gpg-check-pattern will not be built.
1996 "
1997 fi
1998 if test "x${gpg_config_script_warn}" != x; then
1999 cat <<G10EOF
2000         Warning: Mismatches between the target platform and the
2001                  to be used libraries have been detected for:
2002                   ${gpg_config_script_warn}
2003                  Please check above for more warning messages.
2004
2005 G10EOF
2006 fi