common/
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005,
3 #               2006, 2007, 2008, 2009 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.10"
23
24 # Remember to change the version number immediately *after* a release.
25 # Set my_issvn to "yes" for non-released code.  Remember to run an
26 # "svn up" and "autogen.sh" right before creating a distribution.
27 m4_define([my_version], [2.1.0])
28 m4_define([my_issvn], [yes])
29
30 m4_define([svn_revision], m4_esyscmd([printf "%d" $(svn info 2>/dev/null \
31           | sed -n '/^Revision:/ s/[^0-9]//gp'|head -1)]))
32 AC_INIT([gnupg], 
33         [my_version[]m4_if(my_issvn,[yes],[-svn[]svn_revision])],
34         [http://bugs.gnupg.org])
35 # Set development_version to yes if the minor number is odd or you
36 # feel that the default check for a development version is not
37 # sufficient.
38 development_version=no
39
40 NEED_GPG_ERROR_VERSION=1.4
41
42 NEED_LIBGCRYPT_API=1
43 NEED_LIBGCRYPT_VERSION=1.4.0
44
45 NEED_LIBASSUAN_API=2
46 NEED_LIBASSUAN_VERSION=1.1.0
47
48 NEED_KSBA_API=1
49 NEED_KSBA_VERSION=1.0.2
50
51
52 PACKAGE=$PACKAGE_NAME
53 PACKAGE_GT=${PACKAGE_NAME}2
54 VERSION=$PACKAGE_VERSION
55
56 AC_CONFIG_AUX_DIR(scripts)
57 AC_CONFIG_SRCDIR(sm/gpgsm.c)
58 AM_CONFIG_HEADER(config.h)
59 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
60 AC_CANONICAL_HOST
61 AB_INIT
62
63 AC_GNU_SOURCE
64
65 # Some status variables.
66 have_gpg_error=no
67 have_libgcrypt=no 
68 have_libassuan=no
69 have_ksba=no
70 have_pth=no
71 have_libusb=no
72 have_adns=no
73
74 use_bzip2=yes
75 use_exec=yes
76 disable_keyserver_path=no
77
78
79 GNUPG_BUILD_PROGRAM(gpg, yes)
80 GNUPG_BUILD_PROGRAM(gpgsm, yes)
81 GNUPG_BUILD_PROGRAM(agent, yes)
82 GNUPG_BUILD_PROGRAM(scdaemon, yes)
83 GNUPG_BUILD_PROGRAM(g13, yes)
84 GNUPG_BUILD_PROGRAM(tools, yes)
85 GNUPG_BUILD_PROGRAM(doc, yes)
86 GNUPG_BUILD_PROGRAM(symcryptrun, no)
87
88 AC_SUBST(PACKAGE)
89 AC_SUBST(PACKAGE_GT)
90 AC_SUBST(VERSION)
91 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
92 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
93                                 [Name of this package for gettext])
94 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
95 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
96                                         [Bug report address])
97 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
98                                        [Required version of Libgcrypt])
99 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
100                                        [Required version of Libksba])
101
102
103
104 # The default is to use the modules from this package and the few
105 # other packages in a standard place; i.e where this package gets
106 # installed.  With these options it is possible to override these
107 # ${prefix} depended values with fixed paths, which can't be replaced
108 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
109 AC_ARG_WITH(agent-pgm,
110     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
111           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
112 AC_SUBST(GNUPG_AGENT_PGM)
113 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
114 show_gnupg_agent_pgm="(default)"
115 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
116
117 AC_ARG_WITH(pinentry-pgm,
118     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
119           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
120 AC_SUBST(GNUPG_PINENTRY_PGM)
121 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
122 show_gnupg_pinentry_pgm="(default)"
123 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
124
125
126 AC_ARG_WITH(scdaemon-pgm,
127     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
128           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
129 AC_SUBST(GNUPG_SCDAEMON_PGM)
130 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
131 show_gnupg_scdaemon_pgm="(default)"
132 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
133
134
135 AC_ARG_WITH(dirmngr-pgm,
136     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
137           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
138 AC_SUBST(GNUPG_DIRMNGR_PGM)
139 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
140 show_gnupg_dirmngr_pgm="(default)"
141 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
142
143 AC_ARG_WITH(protect-tool-pgm,
144     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
145           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
146 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
147 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
148 show_gnupg_protect_tool_pgm="(default)"
149 test -n "$GNUPG_PROTECT_TOOL_PGM" \
150       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
151
152
153 # Some folks want to use only the agent from this packet.  Make it
154 # easier for them by providing the configure option
155 # --enable-only-agent.
156 AC_ARG_ENABLE(agent-only,
157     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
158     build_agent_only=$enableval)
159
160 # SELinux support includes tracking of sensitive files to avoid
161 # leaking their contents through processing these files by gpg itself
162 AC_MSG_CHECKING([whether SELinux support is requested])
163 AC_ARG_ENABLE(selinux-support,
164               AC_HELP_STRING([--enable-selinux-support],
165                              [enable SELinux support]),
166               selinux_support=$enableval, selinux_support=no)
167 AC_MSG_RESULT($selinux_support)
168
169 # Allow disabling of bzib2 support.
170 # It is defined only after we confirm the library is available later
171 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
172 AC_ARG_ENABLE(bzip2,
173    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
174    use_bzip2=$enableval)
175 AC_MSG_RESULT($use_bzip2)
176
177 # Configure option to allow or disallow execution of external
178 # programs, like a photo viewer.
179 AC_MSG_CHECKING([whether to enable external program execution])
180 AC_ARG_ENABLE(exec,
181     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
182     use_exec=$enableval)
183 AC_MSG_RESULT($use_exec)
184 if test "$use_exec" = no ; then
185     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
186 fi
187
188 if test "$use_exec" = yes ; then
189   AC_MSG_CHECKING([whether to enable photo ID viewing])
190   AC_ARG_ENABLE(photo-viewers,
191       [  --disable-photo-viewers disable photo ID viewers],
192       [if test "$enableval" = no ; then
193          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
194       fi],enableval=yes)
195   gnupg_cv_enable_photo_viewers=$enableval
196   AC_MSG_RESULT($enableval)
197
198   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
199     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
200     AC_ARG_WITH(photo-viewer,
201         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
202         [if test "$withval" = yes ; then
203            withval=no
204         elif test "$withval" != no ; then
205            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
206                             [if set, restrict photo-viewer to this])
207         fi],withval=no)
208     AC_MSG_RESULT($withval)
209   fi
210
211   AC_MSG_CHECKING([whether to enable external keyserver helpers])
212   AC_ARG_ENABLE(keyserver-helpers,
213       [  --disable-keyserver-helpers  disable all external keyserver support],
214       [if test "$enableval" = no ; then
215          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
216                   [define to disable keyserver helpers])
217       fi],enableval=yes)
218   gnupg_cv_enable_keyserver_helpers=$enableval
219   AC_MSG_RESULT($enableval)
220
221   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
222     # LDAP is defined only after we confirm the library is available later
223     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
224     AC_ARG_ENABLE(ldap,
225       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
226       try_ldap=$enableval, try_ldap=yes)
227     AC_MSG_RESULT($try_ldap)
228
229     AC_MSG_CHECKING([whether HKP keyserver support is requested])
230     AC_ARG_ENABLE(hkp,
231       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
232       try_hkp=$enableval, try_hkp=yes)
233     AC_MSG_RESULT($try_hkp)
234
235     AC_MSG_CHECKING([whether finger key fetching support is requested])
236     AC_ARG_ENABLE(finger,
237       AC_HELP_STRING([--disable-finger],
238         [disable finger key fetching interface only]),
239       try_finger=$enableval, try_finger=yes)
240     AC_MSG_RESULT($try_finger)
241
242     AC_MSG_CHECKING([whether generic object key fetching support is requested])
243     AC_ARG_ENABLE(generic,
244       AC_HELP_STRING([--disable-generic],
245         [disable generic object key fetching interface only]),
246       try_generic=$enableval, try_generic=yes)
247     AC_MSG_RESULT($try_generic)
248
249     AC_MSG_CHECKING([whether email keyserver support is requested])
250     AC_ARG_ENABLE(mailto,
251       AC_HELP_STRING([--enable-mailto],
252         [enable email keyserver interface only]),
253       try_mailto=$enableval, try_mailto=no)
254     AC_MSG_RESULT($try_mailto)
255     fi
256
257     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
258     AC_ARG_ENABLE(keyserver-path,
259       AC_HELP_STRING([--disable-keyserver-path],
260         [disable the exec-path option for keyserver helpers]),
261       [if test "$enableval" = no ; then
262          disable_keyserver_path=yes
263       fi],enableval=yes)
264     AC_MSG_RESULT($enableval)
265   fi
266
267
268 #
269 # Check for the key/uid cache size.  This can't be zero, but can be
270 # pretty small on embedded systems.  This is used for the gpg part.
271 #
272 AC_MSG_CHECKING([for the size of the key and uid cache])
273 AC_ARG_ENABLE(key-cache,
274         AC_HELP_STRING([--enable-key-cache=SIZE],
275                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
276 if test "$enableval" = "no"; then
277    enableval=5
278 elif test "$enableval" = "yes" || test "$enableval" = ""; then
279    enableval=4096
280 fi
281 changequote(,)dnl
282 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
283 changequote([,])dnl
284 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
285    AC_MSG_ERROR([invalid key-cache size])
286 fi
287 AC_MSG_RESULT($key_cache_size)
288 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
289                   [Size of the key and UID caches])
290
291
292
293 #
294 # Check whether we want to use Linux capabilities
295 #
296 AC_MSG_CHECKING([whether use of capabilities is requested])
297 AC_ARG_WITH(capabilities,
298     [  --with-capabilities     use linux capabilities [default=no]],
299 [use_capabilities="$withval"],[use_capabilities=no])
300 AC_MSG_RESULT($use_capabilities)
301
302 #
303 # To avoid double inclusion of config.h which might happen at some
304 # places, we add the usual double inclusion protection at the top of
305 # config.h.
306 #
307 AH_TOP([
308 #ifndef GNUPG_CONFIG_H_INCLUDED
309 #define GNUPG_CONFIG_H_INCLUDED
310 ])
311
312 #
313 # Stuff which goes at the bottom of config.h.
314 #
315 AH_BOTTOM([
316 /* This is the major version number of GnuPG so that
317    source included files can test for this.  Note, that
318    we use 2 here even for GnuPG 1.9.x. */
319 #define GNUPG_MAJOR_VERSION 2
320
321 /* Now to separate file name parts.
322    Please note that the string version must not contain more
323    than one character because the code assumes strlen()==1 */
324 #ifdef HAVE_DOSISH_SYSTEM
325 #define DIRSEP_C '\\'
326 #define DIRSEP_S "\\"
327 #define EXTSEP_C '.'
328 #define EXTSEP_S "."
329 #define PATHSEP_C ';'
330 #define PATHSEP_S ";"
331 #define EXEEXT_S ".exe"
332 #else
333 #define DIRSEP_C '/'
334 #define DIRSEP_S "/"
335 #define EXTSEP_C '.'
336 #define EXTSEP_S "."
337 #define PATHSEP_C ':'
338 #define PATHSEP_S ":"
339 #define EXEEXT_S ""
340 #endif
341
342 /* This is the same as VERSION, but should be overridden if the
343    platform cannot handle things like dots '.' in filenames. Set
344    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
345    uses for dots and dashes. */
346 #define SAFE_VERSION VERSION
347 #define SAFE_VERSION_DOT  '.'
348 #define SAFE_VERSION_DASH '-'
349
350 /* Some global constants. */
351 #ifdef HAVE_DRIVE_LETTERS
352 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
353 #elif defined(__VMS)
354 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg" 
355 #else
356 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
357 #endif 
358 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
359
360 /* For some systems (DOS currently), we hardcode the path here.  For
361    POSIX systems the values are constructed by the Makefiles, so that
362    the values may be overridden by the make invocations; this is to
363    comply with the GNU coding standards. */
364 #ifdef HAVE_DRIVE_LETTERS
365  /* FIXME: We need to use a function to determine these values depending 
366     on the actual installation directory. */
367 #define GNUPG_BINDIR      "c:\\gnupg"
368 #define GNUPG_LIBEXECDIR  "c:\\gnupg"
369 #define GNUPG_LIBDIR      "c:\\gnupg"
370 #define GNUPG_DATADIR     "c:\\gnupg"
371 #define GNUPG_SYSCONFDIR  "c:\\gnupg"
372 #endif
373
374 /* Derive some other constants. */
375 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
376 #define EXEC_TEMPFILE_ONLY
377 #endif
378
379
380 /* We didn't define endianness above, so get it from OS macros.  This
381    is intended for making fat binary builds on OS X. */
382 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
383 #if defined(__BIG_ENDIAN__)
384 #define BIG_ENDIAN_HOST 1
385 #elif defined(__LITTLE_ENDIAN__)
386 #define LITTLE_ENDIAN_HOST 1
387 #else
388 #error "No endianness found"
389 #endif
390 #endif
391
392
393 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
394    ldap_start_tls_s because that is the actual symbol used in the
395    library.  winldap.h redefines it to our commonly used value,
396    thus we define our usual macro here.  */
397 #ifdef HAVE_LDAP_START_TLS_SA
398 # ifndef HAVE_LDAP_START_TLS_S
399 #  define HAVE_LDAP_START_TLS_S 1
400 # endif
401 #endif
402
403
404 /* Tell libgcrypt not to use its own libgpg-error implementation. */
405 #define USE_LIBGPG_ERROR 1
406
407 /* We use jnlib, so tell other modules about it.  */
408 #define HAVE_JNLIB_LOGGING 1
409
410 /* Our HTTP code is used in estream mode.  */
411 #define HTTP_USE_ESTREAM 1
412
413 /* Under W32 we do an explicit socket initialization, thus we need to
414    avoid the on-demand initialization which would also install an atexit
415    handler.  */
416 #define HTTP_NO_WSASTARTUP
417
418 /* We always include support for the OpenPGP card.  */
419 #define ENABLE_CARD_SUPPORT 1
420
421 /* We explicitly need to disable PTH's soft mapping as Debian
422    currently enables it by default for no reason. */
423 #define PTH_SYSCALL_SOFT 0
424
425 /* We want to use the libgcrypt provided memory allocation for
426    asprintf.  */
427 #define _ESTREAM_PRINTF_MALLOC        gcry_malloc
428 #define _ESTREAM_PRINTF_FREE          gcry_free
429 #define _ESTREAM_PRINTF_EXTRA_INCLUDE "util.h"
430
431 #endif /*GNUPG_CONFIG_H_INCLUDED*/
432 ])
433
434
435 AM_MAINTAINER_MODE
436
437 # Checks for programs.
438 AC_MSG_NOTICE([checking for programs])
439 AC_PROG_MAKE_SET
440 AM_SANITY_CHECK
441 missing_dir=`cd $ac_aux_dir && pwd`
442 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
443 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
444 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
445 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
446 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
447 AC_PROG_AWK
448 AC_PROG_CC
449 AC_PROG_CPP
450 AM_PROG_CC_C_O
451 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
452   AC_MSG_ERROR([[No C-89 compiler found]])
453 fi
454 AC_PROG_INSTALL
455 AC_PROG_LN_S
456 AC_PROG_RANLIB
457 AC_CHECK_TOOL(AR, ar, :)
458 AC_PATH_PROG(PERL,"perl")
459 AC_CHECK_TOOL(WINDRES, windres, :)
460 AC_ISC_POSIX
461 gl_EARLY
462 AC_SYS_LARGEFILE
463 GNUPG_CHECK_FAQPROG
464 GNUPG_CHECK_USTAR
465
466 # We need to compile and run a program on the build machine.  A
467 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
468 # the AC archive is broken for autoconf 2.57.  Given that tehre is no
469 # newer version of that macro, we assume that it is also broken for
470 # autoconf 2.61 and thus we use a simple but usually sufficient
471 # approach.
472 AC_MSG_CHECKING(for cc for build)
473 if test "$cross_compiling" = "yes"; then
474   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
475 else
476   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
477 fi
478 AC_MSG_RESULT($CC_FOR_BUILD)
479 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
480
481
482
483 try_gettext=yes
484 have_dosish_system=no
485 have_w32_system=no
486 use_simple_gettext=no
487 case "${host}" in
488     *-mingw32*)
489         # special stuff for Windoze NT
490         ac_cv_have_dev_random=no
491         AC_DEFINE(USE_ONLY_8DOT3,1,
492                   [set this to limit filenames to the 8.3 format])
493         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
494                   [defined if we must run on a stupid file system])
495         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
496                   [because the Unix gettext has too much overhead on
497                    MingW32 systems and these systems lack Posix functions,
498                    we use a simplified version of gettext])
499         disable_keyserver_path=yes
500         have_dosish_system=yes
501         have_w32_system=yes
502         try_gettext="no"
503         use_simple_gettext=yes
504         ;;
505     i?86-emx-os2 | i?86-*-os2*emx )
506         # OS/2 with the EMX environment
507         ac_cv_have_dev_random=no
508         AC_DEFINE(HAVE_DRIVE_LETTERS)
509         have_dosish_system=yes
510         try_gettext="no"
511         ;;
512
513     i?86-*-msdosdjgpp*)
514         # DOS with the DJGPP environment
515         ac_cv_have_dev_random=no
516         AC_DEFINE(HAVE_DRIVE_LETTERS)
517         have_dosish_system=yes
518         try_gettext="no"
519         ;;
520
521     *-*-freebsd*)
522        # FreeBSD
523        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
524        LDFLAGS="$LDFLAGS -L/usr/local/lib"
525        ;;
526
527     *-*-hpux*)
528         if test -z "$GCC" ; then
529             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
530         fi
531         ;;
532     *-dec-osf4*)
533         if test -z "$GCC" ; then
534             # Suppress all warnings
535             # to get rid of the unsigned/signed char mismatch warnings.
536             CFLAGS="$CFLAGS -w"
537         fi
538         ;;
539     *-dec-osf5*)
540         if test -z "$GCC" ; then
541             # Use the newer compiler `-msg_disable ptrmismatch1' to
542             # get rid of the unsigned/signed char mismatch warnings.
543             # Using this may hide other pointer mismatch warnings, but
544             # it at least lets other warning classes through
545             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
546         fi
547         ;;
548     m68k-atari-mint)
549         ;;
550     *)
551        ;;
552 esac
553
554 if test "$have_dosish_system" = yes; then
555    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
556              [Defined if we run on some of the PCDOS like systems 
557               (DOS, Windoze. OS/2) with special properties like
558               no file modes])
559 fi
560 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
561
562 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
563
564 if test "$have_w32_system" = yes; then
565    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
566 fi
567 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
568
569 if test "$disable_keyserver_path" = yes; then
570     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
571               [Defined to disable exec-path for keyserver helpers])
572 fi
573
574 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
575 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
576
577 if test x"$try_hkp" = xyes ; then
578   AC_SUBST(GPGKEYS_HKP,"gpg2keys_hkp$EXEEXT")
579 fi
580
581 if test x"$try_finger" = xyes ; then
582   AC_SUBST(GPGKEYS_FINGER,"gpg2keys_finger$EXEEXT")
583 fi
584
585
586
587 #
588 # Checks for libraries.
589 #
590 AC_MSG_NOTICE([checking for libraries])
591
592
593 #
594 # libgpg-error is a library with error codes shared between GnuPG
595 # related projects.
596 #
597 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
598                   have_gpg_error=yes,have_gpg_error=no)
599
600
601 #
602 # Libgcrypt is our generic crypto library
603 #
604 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
605         have_libgcrypt=yes,have_libgcrypt=no)
606
607
608 #
609 # libassuan is used for IPC
610 #
611 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
612                   have_libassuan=yes,have_libassuan=no)
613 if test "$have_libassuan" = "yes"; then
614   have_libassuan=no
615   AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
616                     have_libassuan=yes,have_libassuan=no)       
617   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
618                      [version of the libassuan library])
619 fi
620
621
622
623 #
624 # libksba is our X.509 support library
625 #
626 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
627
628
629 #
630 # libusb allows us to use the integrated CCID smartcard reader driver.
631 #
632 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
633 AC_CHECK_LIB(usb, usb_bulk_write,
634               [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
635                 AC_DEFINE(HAVE_LIBUSB,1,
636                          [defined if libusb is available])
637                 have_libusb=yes
638              ])
639 AC_SUBST(LIBUSB_LIBS)
640 AC_CHECK_FUNCS(usb_create_match)
641
642 #
643 # Check wether it is necessary to link against libdl.
644 #
645 gnupg_dlopen_save_libs="$LIBS"
646 LIBS=""
647 AC_SEARCH_LIBS(dlopen, c dl,,,)
648 DL_LIBS=$LIBS
649 AC_SUBST(DL_LIBS)
650 LIBS="$gnupg_dlopen_save_libs"
651
652 # Checks for g13
653
654 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
655 AC_DEFINE_UNQUOTED(ENCFS,
656         "${ENCFS}", [defines the filename of the encfs program])
657
658 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
659 AC_DEFINE_UNQUOTED(FUSERMOUNT,
660         "${FUSERMOUNT}", [defines the filename of the fusermount program])
661
662 #
663 # Checks for symcryptrun:
664 #
665
666 # libutil has openpty() and login_tty().
667 AC_CHECK_LIB(util, openpty,
668               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
669                 AC_DEFINE(HAVE_LIBUTIL,1,
670                          [defined if libutil is available])
671              ])
672 AC_SUBST(LIBUTIL_LIBS)
673
674 # shred is used to clean temporary plain text files.
675 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
676 AC_DEFINE_UNQUOTED(SHRED,
677         "${SHRED}", [defines the filename of the shred program])
678
679
680 #
681 # Check whether the GNU Pth library is available
682 # Note, that we include a Pth emulation for W32.
683 #
684 GNUPG_PATH_PTH
685 if test "$have_pth" = "yes"; then
686   AC_DEFINE(USE_GNU_PTH, 1,
687               [Defined if the GNU Portable Thread Library should be used])
688 else
689   AC_MSG_WARN([[
690 ***
691 *** To support concurrent access to the gpg-agent and the SCdaemon
692 *** we need the support of the GNU Portable Threads Library.
693 *** Download it from ftp://ftp.gnu.org/gnu/pth/
694 *** On a Debian GNU/Linux system you might want to try 
695 ***   apt-get install libpth-dev
696 ***]])
697 fi
698
699
700 AC_MSG_NOTICE([checking for networking options])
701
702 #
703 # Must check for network library requirements before doing link tests
704 # for ldap, for example. If ldap libs are static (or dynamic and without
705 # ELF runtime link paths), then link will fail and LDAP support won't
706 # be detected.
707 #
708 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
709         [NETLIBS="-lnsl $NETLIBS"]))
710 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
711         [NETLIBS="-lsocket $NETLIBS"]))
712
713
714 #
715 # Check for ADNS.
716 #
717 _cppflags="${CPPFLAGS}"
718 _ldflags="${LDFLAGS}"
719 AC_ARG_WITH(adns,
720             AC_HELP_STRING([--with-adns=DIR],
721                            [look for the adns library in DIR]),
722             [if test -d "$withval"; then
723                CPPFLAGS="${CPPFLAGS} -I$withval/include"
724                LDFLAGS="${LDFLAGS} -L$withval/lib"
725              fi])
726 if test "$with_adns" != "no"; then
727   AC_CHECK_HEADERS(adns.h,
728                 AC_CHECK_LIB(adns, adns_init,
729                              [have_adns=yes],
730                              [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}]),
731                 [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}])
732 fi
733 if test "$have_adns" = "yes"; then
734   ADNSLIBS="-ladns" 
735 fi
736 AC_SUBST(ADNSLIBS)
737 # Newer adns versions feature a free function to be used under W32.
738 AC_CHECK_FUNCS(adns_free)
739
740
741
742 #
743 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
744 #
745 if test x"$try_hkp" = xyes || test x"$try_http" = xyes ; then
746   AC_ARG_ENABLE(dns-srv,
747      AC_HELP_STRING([--disable-dns-srv],
748                     [disable the use of DNS SRV in HKP and HTTP]),
749                 use_dns_srv=$enableval,use_dns_srv=yes)
750 fi
751
752 AC_ARG_ENABLE(dns-pka,
753    AC_HELP_STRING([--disable-dns-pka],
754         [disable the use of PKA records in DNS]),
755    use_dns_pka=$enableval,use_dns_pka=yes)
756
757 AC_ARG_ENABLE(dns-cert,
758    AC_HELP_STRING([--disable-dns-cert],
759         [disable the use of CERT records in DNS]),
760    use_dns_cert=$enableval,use_dns_cert=yes)
761
762 if test x"$use_dns_pka" = xyes || test x"$use_dns_srv" = xyes \
763    || test x"$use_dns_cert" = xyes; then
764   _dns_save_libs=$LIBS
765   LIBS=""
766   # the double underscore thing is a glibc-ism?
767   AC_SEARCH_LIBS(res_query,resolv bind,,
768                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
769   AC_SEARCH_LIBS(dn_expand,resolv bind,,
770                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
771   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
772                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
773
774   if test x"$have_resolver" != xno ; then
775
776     # Make sure that the BIND 4 resolver interface is workable before
777     # enabling any code that calls it.  At some point I'll rewrite the
778     # code to use the BIND 8 resolver API.
779     # We might also want to use adns instead.  Problem with ADNS is that
780     # it does not support v6.
781
782     AC_MSG_CHECKING([whether the resolver is usable])
783     AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
784 #include <netinet/in.h>
785 #include <arpa/nameser.h>
786 #include <resolv.h>],
787 [[unsigned char answer[PACKETSZ];
788   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
789   dn_skipname(0,0); 
790   dn_expand(0,0,0,0,0);
791 ]])],have_resolver=yes,have_resolver=no)
792     AC_MSG_RESULT($have_resolver)
793
794     # This is Apple-specific and somewhat bizarre as they changed the
795     # define in bind 8 for some reason.
796
797     if test x"$have_resolver" != xyes ; then
798        AC_MSG_CHECKING(
799              [whether I can make the resolver usable with BIND_8_COMPAT])
800        AC_LINK_IFELSE([AC_LANG_PROGRAM([#define BIND_8_COMPAT
801 #include <sys/types.h>
802 #include <netinet/in.h>
803 #include <arpa/nameser.h>
804 #include <resolv.h>],
805 [[unsigned char answer[PACKETSZ];
806   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
807   dn_skipname(0,0); dn_expand(0,0,0,0,0);
808 ]])],[have_resolver=yes ; need_compat=yes])
809        AC_MSG_RESULT($have_resolver)
810     fi
811   fi
812
813   if test x"$have_resolver" = xyes ; then
814      DNSLIBS=$LIBS
815
816      if test x"$use_dns_srv" = xyes ; then
817         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
818      fi
819
820      if test x"$use_dns_pka" = xyes ; then
821         AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
822      fi
823
824      if test x"$use_dns_cert" = xyes ; then
825         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
826      fi
827
828      if test x"$need_compat" = xyes ; then
829         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
830      fi
831   else
832      # If we have no resolver library but ADNS (e.g. under W32) enable the
833      # code parts which can be used with ADNS.
834      use_dns_cert=no
835      if test x"$have_adns" = xyes ; then
836         DNSLIBS="$ADNSLIBS"
837         AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
838
839         if test x"$use_dns_srv" = xyes ; then
840            AC_DEFINE(USE_DNS_SRV,1)
841         fi
842
843         if test x"$use_dns_pka" = xyes ; then
844            AC_DEFINE(USE_DNS_PKA,1)
845         fi
846      else
847         use_dns_srv=no
848         use_dns_pka=no
849      fi
850   fi
851
852   LIBS=$_dns_save_libs
853 fi
854
855 AC_SUBST(DNSLIBS)
856
857 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
858
859
860 #
861 # Check for LDAP
862 #
863 if test "$try_ldap" = yes ; then
864    GNUPG_CHECK_LDAP($NETLIBS)
865 fi
866
867 #
868 # Check for curl.  We fake the curl API if libcurl isn't installed.
869 # We require 7.10 or later as we use curl_version_info().
870 #
871 LIBCURL_CHECK_CONFIG([yes],[7.10],,[fake_curl=yes])
872 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
873
874 # Generic, for us, means curl
875
876 if test x"$try_generic" = xyes ; then
877    AC_SUBST(GPGKEYS_CURL,"gpg2keys_curl$EXEEXT")
878 fi
879
880 #
881 # Check for sendmail
882 #
883 # This isn't necessarily sendmail itself, but anything that gives a
884 # sendmail-ish interface to the outside world.  That includes Exim,
885 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
886 if test "$try_mailto" = yes ; then
887   AC_ARG_WITH(mailprog,
888       AC_HELP_STRING([--with-mailprog=NAME],
889                      [use "NAME -t" for mail transport]),
890              ,with_mailprog=yes)
891
892   if test x"$with_mailprog" = xyes ; then
893     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
894     if test "$ac_cv_path_SENDMAIL" ; then
895       GPGKEYS_MAILTO="gpg2keys_mailto"
896     fi
897   elif test x"$with_mailprog" != xno ; then
898     AC_MSG_CHECKING([for a mail transport program])
899     AC_SUBST(SENDMAIL,$with_mailprog)
900     AC_MSG_RESULT($with_mailprog)
901     GPGKEYS_MAILTO="gpg2keys_mailto"
902   fi
903 fi
904
905 AC_SUBST(GPGKEYS_MAILTO)
906
907 #
908 # Construct a printable name of the OS
909 #
910 case "${host}" in
911     *-mingw32*)
912         PRINTABLE_OS_NAME="MingW32"
913         ;;
914     *-*-cygwin*)
915         PRINTABLE_OS_NAME="Cygwin"
916         ;;
917     i?86-emx-os2 | i?86-*-os2*emx )
918         PRINTABLE_OS_NAME="OS/2"
919         ;;
920     i?86-*-msdosdjgpp*)
921         PRINTABLE_OS_NAME="MSDOS/DJGPP"
922         try_dynload=no
923         ;;
924     *-linux*)
925         PRINTABLE_OS_NAME="GNU/Linux"
926         ;;
927     *)
928         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
929         ;;
930 esac
931 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
932                    [A human readable text with the name of the OS])
933
934
935 #
936 # Checking for iconv
937 #
938 AM_ICONV
939
940
941 #
942 # Check for gettext
943 #
944 # This is "GNU gnupg" - The project-id script from gettext
945 #                       needs this string
946 #
947 AC_MSG_NOTICE([checking for gettext])
948 AM_PO_SUBDIRS
949 AM_GNU_GETTEXT_VERSION([0.17])
950 if test "$try_gettext" = yes; then
951   AM_GNU_GETTEXT([external],[need-ngettext])
952
953   # gettext requires some extra checks.  These really should be part of
954   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
955   # function checks to here.
956
957   AC_CHECK_FUNCS(strchr)
958 else
959   USE_NLS=no
960   USE_INCLUDED_LIBINTL=no
961   BUILD_INCLUDED_LIBINTL=no
962   POSUB=po
963   AC_SUBST(USE_NLS)
964   AC_SUBST(USE_INCLUDED_LIBINTL)
965   AC_SUBST(BUILD_INCLUDED_LIBINTL)
966   AC_SUBST(POSUB)
967 fi
968
969 # We use HAVE_LANGINFO_CODESET in a couple of places.
970 AM_LANGINFO_CODESET
971
972 # Checks required for our use locales
973 gt_LC_MESSAGES
974
975
976 #
977 # SELinux support
978 #
979 if test "$selinux_support" = yes ; then
980   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
981 fi
982
983
984 #
985 # Checks for header files.
986 #
987 AC_MSG_NOTICE([checking for header files])
988 AC_HEADER_STDC
989 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h])
990 AC_CHECK_HEADERS([pty.h pwd.h inttypes.h])
991 AC_HEADER_TIME
992
993
994 #
995 # Checks for typedefs, structures, and compiler characteristics.
996 #
997 AC_MSG_NOTICE([checking for system characteristics])
998 AC_C_CONST
999 AC_C_INLINE
1000 AC_C_VOLATILE
1001 AC_TYPE_SIZE_T
1002 AC_TYPE_MODE_T
1003 AC_TYPE_SIGNAL
1004 AC_DECL_SYS_SIGLIST
1005
1006 gl_HEADER_SYS_SOCKET
1007 gl_TYPE_SOCKLEN_T
1008
1009 AC_ARG_ENABLE(endian-check,
1010               AC_HELP_STRING([--disable-endian-check],
1011               [disable the endian check and trust the OS provided macros]),
1012               endiancheck=$enableval,endiancheck=yes)
1013
1014 if test x"$endiancheck" = xyes ; then
1015   GNUPG_CHECK_ENDIAN
1016 fi
1017
1018 # fixme: we should get rid of the byte type
1019 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1020 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1021 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1022 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1023 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1024
1025 AC_CHECK_SIZEOF(unsigned short)
1026 AC_CHECK_SIZEOF(unsigned int)
1027 AC_CHECK_SIZEOF(unsigned long)
1028 AC_CHECK_SIZEOF(unsigned long long)
1029 AC_CHECK_SIZEOF(time_t,,[[
1030 #include <stdio.h>
1031 #if TIME_WITH_SYS_TIME
1032 # include <sys/time.h>
1033 # include <time.h>
1034 #else
1035 # if HAVE_SYS_TIME_H
1036 #  include <sys/time.h>
1037 # else
1038 #  include <time.h>
1039 # endif
1040 #endif
1041 ]])
1042
1043
1044 # Ensure that we have UINT64_C before we bother to check for uint64_t
1045 # Fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
1046 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
1047    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
1048        uint64_t foo=UINT64_C(42);]),
1049      gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
1050 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
1051    AC_CHECK_SIZEOF(uint64_t)
1052 fi
1053
1054 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1055    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1056    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1057     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1058 fi
1059
1060
1061 #
1062 # Checks for library functions.
1063 #
1064 AC_MSG_NOTICE([checking for library functions])
1065 AC_CHECK_DECLS(getpagesize)
1066 AC_FUNC_FSEEKO
1067 AC_FUNC_VPRINTF
1068 AC_FUNC_FORK
1069 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap])
1070 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r])
1071 AC_CHECK_FUNCS([unsetenv fcntl ftruncate])
1072 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1073 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1074 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe stat getaddrinfo])
1075 AC_CHECK_FUNCS([ttyname rand ftello fsync])
1076
1077 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1078
1079 #
1080 # These are needed by libjnlib - fixme: we should use a jnlib.m4
1081 # Note:  We already checked pwd.h.
1082 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol])
1083 AC_CHECK_FUNCS([memrchr isascii timegm getrusage setrlimit stat setlocale])
1084 AC_CHECK_FUNCS([flockfile funlockfile fopencookie funopen getpwnam getpwuid])
1085
1086 #
1087 # gnulib checks
1088 #
1089 gl_SOURCE_BASE([gl])
1090 gl_M4_BASE([gl/m4])
1091 gl_MODULES([setenv mkdtemp xsize strpbrk])
1092 gl_INIT
1093
1094
1095 #
1096 # W32 specific test
1097 #
1098 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1099
1100 #
1101 # Sanity check regex.  Tests adapted from mutt.
1102 #
1103 AC_MSG_CHECKING([whether regular expression support is requested])
1104 AC_ARG_ENABLE(regex,
1105   AC_HELP_STRING([--disable-regex],
1106     [do not handle regular expressions in trust signatures]),
1107   use_regex=$enableval, use_regex=yes)
1108 AC_MSG_RESULT($use_regex)
1109
1110 if test "$use_regex" = yes ; then
1111   _cppflags="${CPPFLAGS}"
1112   _ldflags="${LDFLAGS}"
1113   AC_ARG_WITH(regex,
1114      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1115       [
1116       if test -d "$withval" ; then
1117         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1118         LDFLAGS="${LDFLAGS} -L$withval/lib"
1119       fi
1120       ],withval="")     
1121
1122   # Does the system have regex functions at all?
1123   AC_SEARCH_LIBS([regcomp], [regex])
1124   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1125
1126   if test $gnupg_cv_have_regex = no; then
1127     use_regex=no
1128   else
1129     if test x"$cross_compiling" = xyes; then
1130       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1131     else
1132       AC_CACHE_CHECK([whether your system's regexp library is broken],
1133        [gnupg_cv_regex_broken],
1134        AC_TRY_RUN([
1135 #include <unistd.h>
1136 #include <regex.h>
1137 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1138        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1139
1140       if test $gnupg_cv_regex_broken = yes; then
1141         AC_MSG_WARN([your regex is broken - disabling regex use])
1142         use_regex=no
1143       fi
1144     fi
1145   fi
1146   CPPFLAGS="${_cppflags}"
1147   LDFLAGS="${_ldflags}"
1148 fi
1149
1150 if test "$use_regex" != yes ; then
1151   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1152 fi
1153 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1154
1155
1156
1157 #
1158 # Do we have zlib? Must do it here because Solaris failed
1159 # when compiling a conftest (due to the "-lz" from LIBS).
1160 # Note that we combine zlib and bzlib2 in ZLIBS.
1161 #
1162 _cppflags="${CPPFLAGS}"
1163 _ldflags="${LDFLAGS}"
1164 AC_ARG_WITH(zlib,
1165   [  --with-zlib=DIR         use libz in DIR],[
1166     if test -d "$withval"; then
1167       CPPFLAGS="${CPPFLAGS} -I$withval/include"
1168       LDFLAGS="${LDFLAGS} -L$withval/lib"
1169     fi
1170   ])
1171
1172 AC_CHECK_HEADER(zlib.h,
1173       AC_CHECK_LIB(z, deflateInit2_,
1174        ZLIBS="-lz",
1175        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1176        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1177
1178 #
1179 # Check whether we can support bzip2
1180
1181 if test "$use_bzip2" = yes ; then
1182   _cppflags="${CPPFLAGS}"
1183   _ldflags="${LDFLAGS}"
1184   AC_ARG_WITH(bzip2,
1185      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1186       [
1187       if test -d "$withval" ; then
1188         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1189         LDFLAGS="${LDFLAGS} -L$withval/lib"
1190       fi
1191       ],withval="")
1192
1193   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1194   # required stdio.h to be included before bzlib.h, and Solaris 9 is 
1195   # woefully out of date.
1196   if test "$withval" != no ; then
1197      AC_CHECK_HEADER(bzlib.h,
1198         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1199           [
1200           have_bz2=yes
1201           ZLIBS="$ZLIBS -lbz2"
1202           AC_DEFINE(HAVE_BZIP2,1,
1203                   [Defined if the bz2 compression library is available])
1204           ],
1205           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1206           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1207   fi
1208 fi
1209 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1210 AC_SUBST(ZLIBS)
1211
1212
1213 # Check for readline support
1214 GNUPG_CHECK_READLINE
1215
1216 #
1217 # Allow users to append something to the version string without
1218 # flagging it as development version.  The user version parts is
1219 # considered everything after a dash. 
1220 #
1221 if test "$development_version" != yes; then
1222   changequote(,)dnl
1223   tmp_pat='[a-zA-Z]'
1224   changequote([,])dnl
1225   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1226     development_version=yes
1227   fi
1228 fi
1229 if test "$development_version" = yes; then
1230     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1231             [Defined if this is not a regular release])
1232 fi
1233
1234 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1235
1236 GNUPG_CHECK_GNUMAKE
1237
1238 # Add some extra libs here so that previous tests don't fail for
1239 # mysterious reasons - the final link step should bail out.
1240 # W32SOCKLIBS is also defined so that if can be used for tools not
1241 # requiring any network stuff but linking to code in libcommon which
1242 # tracks in winsock stuff (e.g. init_common_subsystems.
1243 if test "$have_w32_system" = yes; then
1244    W32SOCKLIBS="-lws2_32"
1245    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1246 fi
1247
1248 AC_SUBST(NETLIBS)
1249 AC_SUBST(W32SOCKLIBS)
1250
1251 #
1252 # Setup gcc specific options
1253 #
1254 AC_MSG_NOTICE([checking for cc features])
1255 if test "$GCC" = yes; then
1256     # Note that it is okay to use CFLAGS here because this are just
1257     # warning options and the user should have a chance of overriding
1258     # them.
1259     if test "$USE_MAINTAINER_MODE" = "yes"; then
1260         CFLAGS="$CFLAGS -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1261         CFLAGS="$CFLAGS -Wformat -Wno-format-y2k -Wformat-security"
1262         AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1263         _gcc_cflags_save=$CFLAGS
1264         CFLAGS="-Wno-missing-field-initializers"
1265         AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_wopt=yes,_gcc_wopt=no)
1266         AC_MSG_RESULT($_gcc_wopt)
1267         CFLAGS=$_gcc_cflags_save;
1268         if test x"$_gcc_wopt" = xyes ; then
1269           CFLAGS="$CFLAGS -W -Wno-sign-compare -Wno-missing-field-initializers"
1270         fi
1271         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1272         _gcc_cflags_save=$CFLAGS
1273         CFLAGS="-Wdeclaration-after-statement"
1274         AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_wopt=yes,_gcc_wopt=no)
1275         AC_MSG_RESULT($_gcc_wopt)
1276         CFLAGS=$_gcc_cflags_save;
1277         if test x"$_gcc_wopt" = xyes ; then
1278           CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1279         fi
1280     else
1281         CFLAGS="$CFLAGS -Wall"
1282     fi
1283
1284     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1285     _gcc_cflags_save=$CFLAGS
1286     CFLAGS="-Wno-pointer-sign"
1287     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1288     AC_MSG_RESULT($_gcc_psign)
1289     CFLAGS=$_gcc_cflags_save;
1290     if test x"$_gcc_psign" = xyes ; then
1291        CFLAGS="$CFLAGS -Wno-pointer-sign"
1292     fi
1293
1294     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1295     _gcc_cflags_save=$CFLAGS
1296     CFLAGS="-Wpointer-arith"
1297     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1298     AC_MSG_RESULT($_gcc_psign)
1299     CFLAGS=$_gcc_cflags_save;
1300     if test x"$_gcc_psign" = xyes ; then
1301        CFLAGS="$CFLAGS -Wpointer-arith"
1302     fi
1303 fi
1304
1305
1306 #
1307 # This is handy for debugging so the compiler doesn't rearrange
1308 # things and eliminate variables.
1309 #
1310 AC_ARG_ENABLE(optimization,
1311    AC_HELP_STRING([--disable-optimization],
1312                   [disable compiler optimization]),
1313                   [if test $enableval = no ; then
1314                       CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]]//'`
1315                    fi])
1316
1317 #
1318 # Prepare building of estream
1319 #
1320 estream_INIT
1321
1322
1323 #
1324 # Decide what to build
1325 #
1326 if test "$have_adns" = "yes"; then
1327   AC_SUBST(GPGKEYS_KDNS, "gpg2keys_kdns$EXEEXT")
1328 fi
1329
1330
1331 missing_pth=no
1332 if test $have_ksba = no; then
1333   build_gpgsm=no
1334   build_scdaemon=no
1335 fi
1336
1337 build_agent_threaded=""
1338 if test "$build_agent" = "yes"; then
1339   if test $have_pth = no; then
1340      build_agent_threaded="(not multi-threaded)"
1341      missing_pth=yes
1342   fi
1343 fi
1344
1345 build_scdaemon_extra=""
1346 if test "$build_scdaemon" = "yes"; then
1347   tmp=""
1348   if test $have_pth = no; then
1349      build_scdaemon_extra="not multi-threaded"
1350      tmp=", "
1351      missing_pth=yes
1352   fi
1353   if test $have_libusb = no; then
1354      build_scdaemon_extra="${tmp}without internal CCID driver"
1355      tmp=", "
1356   fi
1357   if test -n "$build_scdaemon_extra"; then
1358      build_scdaemon_extra="(${build_scdaemon_extra})"
1359   fi
1360 fi
1361
1362
1363 if test "$build_agent_only" = "yes" ; then
1364   build_gpg=no
1365   build_gpgsm=no
1366   build_scdaemon=no
1367   build_tools=no
1368   build_doc=no
1369 fi
1370
1371
1372 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1373 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1374 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1375 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1376 AM_CONDITIONAL(BUILD_G13,   test "$build_g13" = "yes")
1377 AM_CONDITIONAL(BUILD_TOOLS, test "$build_tools" = "yes")
1378 AM_CONDITIONAL(BUILD_DOC,   test "$build_doc" = "yes")
1379 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1380
1381 AM_CONDITIONAL(RUN_GPG_TESTS,
1382         test x$cross_compiling = xno -a "$build_gpg" = yes )
1383
1384
1385 #
1386 # Print errors here so that they are visible all
1387 # together and the user can acquire them all together.
1388 #
1389 die=no
1390 if test "$have_gpg_error" = "no"; then
1391    die=yes
1392    AC_MSG_NOTICE([[
1393 ***  
1394 *** You need libgpg-error to build this program.
1395 **  This library is for example available at
1396 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1397 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1398 ***]])
1399 fi
1400 if test "$have_libgcrypt" = "no"; then
1401    die=yes
1402    AC_MSG_NOTICE([[
1403 ***  
1404 *** You need libgcrypt to build this program.
1405 **  This library is for example available at
1406 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1407 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API is required.)
1408 ***]])
1409 fi
1410 if test "$have_libassuan" = "no"; then
1411    die=yes
1412    AC_MSG_NOTICE([[
1413 ***
1414 *** You need libassuan to build this program.
1415 *** This library is for example available at
1416 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1417 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1418 ***]])
1419 fi
1420 if test "$have_ksba" = "no"; then
1421     AC_MSG_NOTICE([[
1422 ***
1423 *** You need libksba to build this program.
1424 *** This library is for example available at
1425 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1426 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1427 ***]])
1428 fi
1429 if test "$missing_pth" = "yes"; then
1430     AC_MSG_NOTICE([[
1431 ***
1432 *** It is now required to build with support for the
1433 *** GNU Portable Threads Library (Pth). Please install this
1434 *** library first.  The library is for example available at
1435 ***   ftp://ftp.gnu.org/gnu/pth/
1436 *** On a Debian GNU/Linux system you can install it using 
1437 ***   apt-get install libpth-dev
1438 *** To build GnuPG for Windows you need to use the W32PTH
1439 *** package; available at:
1440 ***   ftp://ftp.g10code.com/g10code/w32pth/
1441 ***]])
1442    die=yes
1443 fi
1444
1445 if test "$die" = "yes"; then
1446     AC_MSG_ERROR([[
1447 ***
1448 *** Required libraries not found. Please consult the above messages
1449 *** and install them before running configure again.
1450 ***]])
1451 fi
1452
1453
1454
1455 AC_CONFIG_FILES([ m4/Makefile 
1456 Makefile
1457 po/Makefile.in
1458 gl/Makefile
1459 include/Makefile
1460 jnlib/Makefile
1461 common/Makefile
1462 kbx/Makefile
1463 g10/Makefile
1464 sm/Makefile
1465 agent/Makefile
1466 scd/Makefile
1467 g13/Makefile
1468 keyserver/Makefile
1469 keyserver/gpg2keys_mailto
1470 keyserver/gpg2keys_test
1471 tools/gpg-zip
1472 tools/Makefile
1473 doc/Makefile
1474 tests/Makefile
1475 tests/openpgp/Makefile
1476 tests/pkits/Makefile
1477 ])
1478 AC_OUTPUT
1479
1480
1481 echo "
1482         GnuPG v${VERSION} has been configured as follows:
1483         
1484         Platform:  $PRINTABLE_OS_NAME ($host)
1485
1486         OpenPGP:   $build_gpg
1487         S/MIME:    $build_gpgsm
1488         Agent:     $build_agent $build_agent_threaded
1489         Smartcard: $build_scdaemon $build_scdaemon_extra
1490         G13:       $build_g13
1491
1492
1493         Protect tool:      $show_gnupg_protect_tool_pgm
1494         Default agent:     $show_gnupg_agent_pgm
1495         Default pinentry:  $show_gnupg_pinentry_pgm
1496         Default scdaemon:  $show_gnupg_scdaemon_pgm
1497         Default dirmngr:   $show_gnupg_dirmngr_pgm
1498 "
1499 if test x"$use_regex" != xyes ; then
1500 echo "
1501         Warning: No regular expression support available.
1502                  OpenPGP trust signatures won't work.
1503                  gpg-check-pattern will not be build.
1504 "
1505 fi