Document --limit-card-insert-tries.
[gnupg.git] / configure.ac
1 dnl configure.ac script for GnuPG
2 dnl Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004,
3 dnl               2005 Free Software Foundation, Inc.
4 dnl
5 dnl This file is part of GnuPG.
6 dnl
7 dnl GnuPG is free software; you can redistribute it and/or modify
8 dnl it under the terms of the GNU General Public License as published by
9 dnl the Free Software Foundation; either version 2 of the License, or
10 dnl (at your option) any later version.
11 dnl 
12 dnl GnuPG is distributed in the hope that it will be useful,
13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 dnl GNU General Public License for more details.
16 dnl 
17 dnl You should have received a copy of the GNU General Public License
18 dnl along with this program; if not, write to the Free Software
19 dnl Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, 
20 dnl MA 02110-1301, USA
21 dnl
22 dnl (Process this file with autoconf to produce a configure script.)
23
24 AC_PREREQ(2.59)
25 min_automake_version="1.9.3"
26
27 # Remember to change the version number immediately *after* a release
28 # and remove the "-cvs" or "rc" suffix immediately *before* a release.
29 AC_INIT(gnupg, 1.4.2-cvs, bug-gnupg@gnu.org)
30 # Set development_version to yes if the minor number is odd or you
31 # feel that the default check for a development version is not
32 # sufficient.
33 development_version=no
34
35 AC_CONFIG_AUX_DIR(scripts)
36 AC_CONFIG_SRCDIR(g10/g10.c)
37 AC_CANONICAL_HOST
38 AM_INIT_AUTOMAKE([std-options])
39 AM_CONFIG_HEADER(config.h)
40
41 AC_GNU_SOURCE
42
43 dnl
44 dnl  Check for random module options
45 dnl
46 AC_MSG_CHECKING([which random module to use])
47 AC_ARG_ENABLE(static-rnd,
48     [  --enable-static-rnd=[egd|unix|linux|auto]  ],
49 [use_static_rnd=$enableval], [use_static_rnd=default] )
50
51 if test "$use_static_rnd" = no; then
52     use_static_rnd=default
53 fi
54
55 case "$use_static_rnd" in
56     egd | linux | unix | default )
57       AC_MSG_RESULT($use_static_rnd)
58       ;;
59     auto )
60       AC_MSG_RESULT(automagically selected at runtime)
61       ;;
62     * )
63       AC_MSG_RESULT(invalid argument)
64       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
65       ;;
66 esac
67
68 AC_ARG_WITH(egd-socket,
69     [  --with-egd-socket=NAME  use NAME for the EGD socket],
70             egd_socket_name="$withval", egd_socket_name="" )
71 AC_DEFINE_UNQUOTED(EGD_SOCKET_NAME, "$egd_socket_name",
72                    [Define if you don't want the default EGD socket name.
73                     For details see cipher/rndegd.c])
74
75
76 dnl
77 dnl See whether the user wants to disable checking for /dev/random
78
79 AC_MSG_CHECKING([whether use of /dev/random is requested])
80 AC_ARG_ENABLE(dev-random,
81 [  --disable-dev-random    disable the use of dev random],
82     try_dev_random=$enableval, try_dev_random=yes)
83 AC_MSG_RESULT($try_dev_random)
84
85
86 dnl
87 dnl  Check other options
88 dnl
89
90 AC_MSG_CHECKING([whether assembler modules are requested])
91 AC_ARG_ENABLE(asm,
92 [  --disable-asm           do not use assembler modules],
93      try_asm_modules=$enableval, try_asm_modules=yes)
94 AC_MSG_RESULT($try_asm_modules)
95
96 AC_MSG_CHECKING([whether memory guard is requested])
97 AC_ARG_ENABLE(m-guard,
98     [  --enable-m-guard        enable memory guard facility],
99     use_m_guard=$enableval, use_m_guard=no)
100 AC_MSG_RESULT($use_m_guard)
101 if test "$use_m_guard" = yes ; then
102     AC_DEFINE(M_GUARD,1,[Define to use the (obsolete) malloc guarding feature])
103 fi
104
105 # We don't have a test to check whetyer as(1) knows about the
106 # non executable stackioption.  Thus we provide an option to enable
107 # it.
108 AC_MSG_CHECKING([whether non excutable stack support is requested])
109 AC_ARG_ENABLE(noexecstack,
110               AC_HELP_STRING([--enable-noexecstack],
111                              [enable non executable stack support (gcc only)]),
112               noexecstack_support=$enableval, noexecstack_support=no)
113 AC_MSG_RESULT($noexecstack_support)
114
115 # SELinux support includes tracking of sensitive files to avoid
116 # leaking their contents through processing these files by gpg itself
117 AC_MSG_CHECKING([whether SELinux support is requested])
118 AC_ARG_ENABLE(selinux-support,
119               AC_HELP_STRING([--enable-selinux-support],
120                              [enable SELinux support]),
121               selinux_support=$enableval, selinux_support=no)
122 AC_MSG_RESULT($selinux_support)
123
124
125 AC_MSG_CHECKING([whether the new iconv based code is requested])
126 AC_ARG_ENABLE(gnupg-iconv,
127               AC_HELP_STRING([--disable-gnupg-iconv],
128                              [disable the new iconv code]),
129               gnupg_use_iconv=$enableval, gnupg_use_iconv=yes)
130 AC_MSG_RESULT($gnupg_use_iconv)
131
132 AC_MSG_CHECKING([whether to enable the experimental backsigs code])
133 AC_ARG_ENABLE(backsigs,
134               AC_HELP_STRING([--enable-backsigs],
135                              [enable the experimental backsigs code]),
136               do_backsigs=$enableval, do_backsigs=no)
137 AC_MSG_RESULT($do_backsigs)
138
139 dnl See if we are disabling any algorithms or features for a smaller
140 dnl binary
141
142 try_extensions=no
143
144 use_rsa=yes
145 use_idea=yes
146 use_cast5=yes
147 use_blowfish=yes
148 use_aes=yes
149 use_twofish=yes
150 use_sha256=yes
151 use_sha512=yes
152 use_bzip2=yes
153 use_exec=yes
154 card_support=yes
155 agent_support=yes
156 disable_keyserver_path=no
157
158 AC_ARG_ENABLE(minimal,
159    AC_HELP_STRING([--enable-minimal],[build the smallest gpg binary possible]),
160    use_rsa=no
161    use_idea=no
162    use_cast5=no
163    use_blowfish=no
164    use_aes=no
165    use_twofish=no
166    use_sha256=no
167    use_sha512=no
168    use_bzip2=no
169    use_exec=no
170    card_support=no
171    agent_support=no)
172
173
174 AC_MSG_CHECKING([whether OpenPGP card support is requested])
175 AC_ARG_ENABLE(card-support,
176               AC_HELP_STRING([--disable-card-support],
177                              [disable OpenPGP card support]),
178               card_support=$enableval)
179 AC_MSG_RESULT($card_support)
180
181
182 # Note that we may later disable the agent support based on the platform.
183 AC_MSG_CHECKING([whether gpg-agent support is requested])
184 AC_ARG_ENABLE(agent-support,
185               AC_HELP_STRING([--disable-agent-support],
186                              [disable gpg-agent support]),
187               agent_support=$enableval)
188 AC_MSG_RESULT($agent_support)
189
190
191 AC_MSG_CHECKING([whether to enable the RSA public key algorithm])
192 AC_ARG_ENABLE(rsa,
193    AC_HELP_STRING([--disable-rsa],[disable the RSA public key algorithm]),
194    use_rsa=$enableval)
195 AC_MSG_RESULT($use_rsa)
196 if test x"$use_rsa" = xyes ; then
197    AC_DEFINE(USE_RSA,1,[Define to include the RSA public key algorithm])
198 fi
199
200 AC_MSG_CHECKING([whether to enable the IDEA cipher])
201 AC_ARG_ENABLE(idea,
202    AC_HELP_STRING([--disable-idea],[disable the IDEA cipher]),
203    use_idea=$enableval)
204 AC_MSG_RESULT($use_idea)
205 if test x"$use_idea" = xyes ; then
206    AC_DEFINE(USE_IDEA,1,[Define to include the IDEA cipher])
207
208 # We don't need idea but some people claim that they need it for
209 # research etc., so we allow to place an idea source code into the
210 # cipher directory and statically link it if available, otherwise we
211 # link to a stub.  We don't use AC_CHECK_FILE to avoid caching.
212
213    AC_MSG_CHECKING([for idea cipher module])
214    tmp=""
215    if test -f $srcdir/cipher/idea.c; then 
216       IDEA_O=idea.o
217       tmp=idea
218    else
219       IDEA_O=idea-stub.o
220       tmp=no
221       try_extensions=yes
222    fi
223    AC_SUBST(IDEA_O)
224    AC_MSG_RESULT($tmp)
225 fi
226
227 AC_MSG_CHECKING([whether to enable the CAST5 cipher])
228 AC_ARG_ENABLE(cast5,
229    AC_HELP_STRING([--disable-cast5],[disable the CAST5 cipher]),
230    use_cast5=$enableval)
231 AC_MSG_RESULT($use_cast5)
232 if test x"$use_cast5" = xyes ; then
233    AC_DEFINE(USE_CAST5,1,[Define to include the CAST5 cipher])
234 fi
235
236 AC_MSG_CHECKING([whether to enable the BLOWFISH cipher])
237 AC_ARG_ENABLE(blowfish,
238    AC_HELP_STRING([--disable-blowfish],[disable the BLOWFISH cipher]),
239    use_blowfish=$enableval)
240 AC_MSG_RESULT($use_blowfish)
241 if test x"$use_blowfish" = xyes ; then
242    AC_DEFINE(USE_BLOWFISH,1,[Define to include the BLOWFISH cipher])
243 fi
244
245 AC_MSG_CHECKING([whether to enable the AES ciphers])
246 AC_ARG_ENABLE(aes,
247    AC_HELP_STRING([--disable-aes],[disable the AES, AES192, and AES256 ciphers]),
248    use_aes=$enableval)
249 AC_MSG_RESULT($use_aes)
250 if test x"$use_aes" = xyes ; then
251    AC_DEFINE(USE_AES,1,[Define to include the AES, AES192, and AES256 ciphers])
252 fi
253
254 AC_MSG_CHECKING([whether to enable the TWOFISH cipher])
255 AC_ARG_ENABLE(twofish,
256    AC_HELP_STRING([--disable-twofish],[disable the TWOFISH cipher]),
257    use_twofish=$enableval)
258 AC_MSG_RESULT($use_twofish)
259 if test x"$use_twofish" = xyes ; then
260    AC_DEFINE(USE_TWOFISH,1,[Define to include the TWOFISH cipher])
261 fi
262
263 AC_MSG_CHECKING([whether to enable the SHA-256 digest])
264 AC_ARG_ENABLE(sha256,
265    AC_HELP_STRING([--disable-sha256],[disable the SHA-256 digest]),
266    use_sha256=$enableval)
267 AC_MSG_RESULT($use_sha256)
268 if test x"$use_sha256" = xyes ; then
269    AC_DEFINE(USE_SHA256,1,[Define to include the SHA-256 digest])
270 fi
271
272 dnl SHA512 is defined only after we confirm 64-bit support later
273 AC_MSG_CHECKING([whether to enable the SHA-384 and SHA-512 digests])
274 AC_ARG_ENABLE(sha512,
275    AC_HELP_STRING([--disable-sha512],[disable the SHA-384 and SHA-512 digests]),
276    use_sha512=$enableval)
277 AC_MSG_RESULT($use_sha512)
278
279 dnl BZLIB is defined only after we confirm the library is available later
280 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
281 AC_ARG_ENABLE(bzip2,
282    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
283    use_bzip2=$enableval)
284 AC_MSG_RESULT($use_bzip2)
285
286 AC_MSG_CHECKING([whether to enable external program execution])
287 AC_ARG_ENABLE(exec,
288     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
289     use_exec=$enableval)
290 AC_MSG_RESULT($use_exec)
291 if test "$use_exec" = no ; then
292     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
293 fi
294
295 if test "$use_exec" = yes ; then
296   AC_MSG_CHECKING([whether to enable photo ID viewing])
297   AC_ARG_ENABLE(photo-viewers,
298       [  --disable-photo-viewers disable photo ID viewers],
299       [if test "$enableval" = no ; then
300          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
301       fi],enableval=yes)
302   gnupg_cv_enable_photo_viewers=$enableval
303   AC_MSG_RESULT($enableval)
304
305   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
306     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
307     AC_ARG_WITH(photo-viewer,
308         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
309         [if test "$withval" = yes ; then
310            withval=no
311         elif test "$withval" != no ; then
312            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
313                             [if set, restrict photo-viewer to this])
314         fi],withval=no)
315     AC_MSG_RESULT($withval)
316   fi
317
318   AC_MSG_CHECKING([whether to enable external keyserver helpers])
319   AC_ARG_ENABLE(keyserver-helpers,
320       [  --disable-keyserver-helpers  disable all external keyserver support],
321       [if test "$enableval" = no ; then
322          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
323                   [define to disable keyserver helpers])
324       fi],enableval=yes)
325   gnupg_cv_enable_keyserver_helpers=$enableval
326   AC_MSG_RESULT($enableval)
327
328   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
329 dnl LDAP is defined only after we confirm the library is available later
330     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
331     AC_ARG_ENABLE(ldap,
332       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
333       try_ldap=$enableval, try_ldap=yes)
334     AC_MSG_RESULT($try_ldap)
335
336     AC_MSG_CHECKING([whether HKP keyserver support is requested])
337     AC_ARG_ENABLE(hkp,
338       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
339       try_hkp=$enableval, try_hkp=yes)
340     AC_MSG_RESULT($try_hkp)
341
342     AC_MSG_CHECKING([whether HTTP key fetching support is requested])
343     AC_ARG_ENABLE(http,
344       AC_HELP_STRING([--disable-http],[disable HTTP key fetching interface]),
345       try_http=$enableval, try_http=yes)
346     AC_MSG_RESULT($try_http)
347
348     AC_MSG_CHECKING([whether finger key fetching support is requested])
349     AC_ARG_ENABLE(finger,
350       AC_HELP_STRING([--disable-finger],
351         [disable finger key fetching interface only]),
352       try_finger=$enableval, try_finger=yes)
353     AC_MSG_RESULT($try_finger)
354
355     AC_MSG_CHECKING([whether ftp key fetching support is requested])
356     AC_ARG_ENABLE(ftp,
357       AC_HELP_STRING([--disable-ftp],
358         [disable ftp key fetching interface only]),
359       try_ftp=$enableval, try_ftp=yes)
360     AC_MSG_RESULT($try_ftp)
361
362     AC_MSG_CHECKING([whether email keyserver support is requested])
363     AC_ARG_ENABLE(mailto,
364       AC_HELP_STRING([--enable-mailto],
365         [enable email keyserver interface only]),
366       try_mailto=$enableval, try_mailto=no)
367     AC_MSG_RESULT($try_mailto)
368     fi
369
370     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
371     AC_ARG_ENABLE(keyserver-path,
372       AC_HELP_STRING([--disable-keyserver-path],
373         [disable the exec-path option for keyserver helpers]),
374       [if test "$enableval" = no ; then
375          disable_keyserver_path=yes
376       fi],enableval=yes)
377     AC_MSG_RESULT($enableval)
378   fi
379
380 AC_MSG_CHECKING([whether the included zlib is requested])
381 AC_ARG_WITH(included-zlib,
382     [  --with-included-zlib    use the zlib code included here],
383 [g10_force_zlib="$withval"], [g10_force_zlib=no] )
384 AC_MSG_RESULT($g10_force_zlib)
385
386 dnl
387 dnl Check for the key/uid cache size.  This can't be zero, but can be
388 dnl pretty small on embedded systems.
389 dnl
390 AC_MSG_CHECKING([for the size of the key and uid cache])
391 AC_ARG_ENABLE(key-cache,
392         AC_HELP_STRING([--enable-key-cache=SIZE],[Set key cache to SIZE (default 4096)]),,enableval=4096)
393
394 if test "$enableval" = "no"; then
395    enableval=5
396 elif test "$enableval" = "yes" || test "$enableval" = ""; then
397    enableval=4096
398 fi
399
400 changequote(,)dnl
401 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
402 changequote([,])dnl
403
404 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
405    AC_MSG_ERROR([invalid key-cache size])
406 fi
407
408 AC_MSG_RESULT($key_cache_size)
409 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,[Size of the key and UID caches])
410
411 dnl
412 dnl Check whether we want to use Linux capabilities
413 dnl
414 AC_MSG_CHECKING([whether use of capabilities is requested])
415 AC_ARG_WITH(capabilities,
416     [  --with-capabilities     use linux capabilities [default=no]],
417 [use_capabilities="$withval"],[use_capabilities=no])
418 AC_MSG_RESULT($use_capabilities)
419
420 # To avoid double inclusion of config.h which might happen at some
421 # places, we add the usual double inclusion protection.
422 AH_TOP([
423 #ifndef GNUPG_CONFIG_H_INCLUDED
424 #define GNUPG_CONFIG_H_INCLUDED
425 ])
426
427 AH_BOTTOM([
428 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
429 #define EXEC_TEMPFILE_ONLY
430 #endif
431
432 /* This is the major version number of GnuPG so that
433    source included files can test for this. */
434 #define GNUPG_MAJOR_VERSION 1
435
436 #include "g10defs.h"
437
438 #endif /*GNUPG_CONFIG_H_INCLUDED*/
439 ])
440
441
442 AM_MAINTAINER_MODE
443
444 dnl Checks for programs.
445
446 AC_PROG_MAKE_SET
447 AM_SANITY_CHECK
448 missing_dir=`cd $ac_aux_dir && pwd`
449 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
450 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
451 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
452 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
453 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
454 AC_PROG_CC
455 AC_PROG_CPP
456 AC_PROG_RANLIB
457 AC_CHECK_TOOL(AR, ar, :)
458 AC_PATH_PROG(PERL,"perl")
459 AC_ISC_POSIX
460 AC_SYS_LARGEFILE
461 AC_PROG_INSTALL
462 AC_PROG_AWK
463 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
464 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
465 GNUPG_CHECK_FAQPROG
466 GNUPG_CHECK_DOCBOOK_TO_TEXI
467
468 MPI_OPT_FLAGS=""
469
470 try_gettext=yes
471 have_dosish_system=no
472 need_dlopen=yes
473 case "${host}" in
474     *-mingw32*)
475         # special stuff for Windoze NT
476         ac_cv_have_dev_random=no
477         AC_DEFINE(USE_ONLY_8DOT3,1,
478                   [set this to limit filenames to the 8.3 format])
479         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
480                   [defined if we must run on a stupid file system])
481         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
482                   [because the Unix gettext has too much overhead on
483                    MingW32 systems and these systems lack Posix functions,
484                    we use a simplified version of gettext])
485         AC_DEFINE(HAVE_W32_SYSTEM,1,
486                   [Defined if we run on a W32 API based system])
487         disable_keyserver_path=yes
488         have_dosish_system=yes
489         need_dlopen=no
490         try_gettext="no"
491         agent_support=no
492         ;;
493     i?86-emx-os2 | i?86-*-os2*emx )
494         # OS/2 with the EMX environment
495         ac_cv_have_dev_random=no
496         AC_DEFINE(HAVE_DRIVE_LETTERS)
497         have_dosish_system=yes
498         try_gettext="no"
499         agent_support=no
500         ;;
501
502     i?86-*-msdosdjgpp*)
503         # DOS with the DJGPP environment
504         ac_cv_have_dev_random=no
505         AC_DEFINE(HAVE_DRIVE_LETTERS)
506         have_dosish_system=yes
507         try_gettext="no"
508         agent_support=no
509         ;;
510
511     *-*-freebsd*)
512        # FreeBSD
513        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
514        LDFLAGS="$LDFLAGS -L/usr/local/lib"
515        ;;
516
517     *-*-hpux*)
518         if test -z "$GCC" ; then
519             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
520         fi
521         ;;
522     *-dec-osf4*)
523         if test -z "$GCC" ; then
524             # Suppress all warnings
525             # to get rid of the unsigned/signed char mismatch warnings.
526             CFLAGS="$CFLAGS -w"
527         fi
528         ;;
529     *-dec-osf5*)
530         if test -z "$GCC" ; then
531             # Use the newer compiler `-msg_disable ptrmismatch' to
532             # get rid of the unsigned/signed char mismatch warnings.
533             # Using this may hide other pointer mismatch warnings, but
534             # it at least lets other warning classes through
535             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
536         fi
537         ;;
538     m68k-atari-mint)
539         ;;
540     *)
541        ;;
542 esac
543
544 if test "$have_dosish_system" = yes; then
545    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
546              [defined if we run on some of the PCDOS like systems 
547               (DOS, Windoze. OS/2) with special properties like
548               no file modes])
549 fi
550 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
551
552 if test "$disable_keyserver_path" = yes; then
553     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
554               [define to disable exec-path for keyserver helpers])
555 fi
556
557 AC_SUBST(MPI_OPT_FLAGS)
558 GNUPG_SYS_SYMBOL_UNDERSCORE
559
560 dnl These need to go after AC_PROG_CC so that $EXEEXT is defined
561 if test x"$try_hkp" = xyes ; then
562   AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
563 fi
564
565 if test x"$try_finger" = xyes ; then
566   AC_SUBST(GPGKEYS_FINGER,"gpgkeys_finger$EXEEXT")
567 fi
568
569 dnl Must check for network library requirements before doing link tests
570 dnl for ldap, for example. If ldap libs are static (or dynamic and without
571 dnl ELF runtime link paths), then link will fail and LDAP support won't
572 dnl be detected.
573
574 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
575         [NETLIBS="-lnsl $NETLIBS"]))
576 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
577         [NETLIBS="-lsocket $NETLIBS"]))
578
579 dnl Now try for the resolver functions so we can use DNS SRV
580
581 AC_ARG_ENABLE(dns-srv,
582    AC_HELP_STRING([--disable-dns-srv],
583         [disable the use of DNS SRV in HKP and HTTP]),
584    use_dns_srv=$enableval,use_dns_srv=yes)
585
586 if (test x"$try_hkp" = xyes || test x"$try_http" = xyes) && test x"$use_dns_srv" = xyes ; then
587   _srv_save_libs=$LIBS
588   LIBS=""
589   # the double underscore thing is a glibc-ism?
590   AC_SEARCH_LIBS(res_query,resolv bind,,
591                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
592   AC_SEARCH_LIBS(dn_expand,resolv bind,,
593                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
594   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
595                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
596
597   if test x"$use_dns_srv" = xyes ; then
598
599     # Make sure that the BIND 4 resolver interface is workable before
600     # enabling SRVs.  At some point I'll rewrite the code to use the
601     # BIND 8 resolver API.
602
603     AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
604 #include <netinet/in.h>
605 #include <arpa/nameser.h>
606 #include <resolv.h>],
607 [[unsigned char answer[PACKETSZ]; res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);]])],,use_dns_srv=no)
608   fi
609
610   if test x"$use_dns_srv" = xyes ; then
611      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
612      SRVLIBS=$LIBS
613   fi
614
615   LIBS=$_srv_save_libs
616 fi
617
618 AC_SUBST(SRVLIBS)
619
620 # Check for LDAP
621
622 if test "$try_ldap" = yes ; then
623    GNUPG_CHECK_LDAP($NETLIBS)
624 fi
625
626 # Special hack to test curl
627
628 AC_ARG_ENABLE(fake-curl,
629    AC_HELP_STRING([--enable-fake-curl],[enable EXPERIMENTAL no-curl HTTP code]),fake_curl=$enableval,fake_curl=no)
630
631 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
632
633 if test x"$fake_curl" = xyes ; then
634    libcurl_protocol_HTTP=yes
635 else
636    # If we have neither FTP or HTTP defined, then don't bother to check
637    # for curl.
638    if test x"$try_hkp" = xyes || test x"$try_ftp" = xyes || test x"$try_http" = xyes ; then
639       LIBCURL_CHECK_CONFIG([no],,[with_curl=yes])
640    fi
641 fi
642
643 AM_CONDITIONAL(WITH_CURL,test x"$with_curl" = xyes || test x"$fake_curl" = xyes)
644
645 # Are we doing HTTP?
646
647 if test x"$try_http" = xyes ; then
648    if test x$libcurl_protocol_HTTP = xyes ; then
649       AC_SUBST(GPGKEYS_CURL,"gpgkeys_curl$EXEEXT")
650       AC_DEFINE(HTTP_VIA_LIBCURL,1,[Define if HTTP is handled via libcurl])
651       if test x$libcurl_protocol_HTTPS = xyes ; then
652          AC_DEFINE(HTTPS_VIA_LIBCURL,1,[Define if HTTPS is handled via libcurl])
653       fi
654    else
655       AC_SUBST(GPGKEYS_HTTP,"gpgkeys_http$EXEEXT")
656    fi
657 fi
658
659 # Are we doing FTP?  We only do FTP if we have libcurl.
660
661 if test x"$try_ftp" = xyes && test x$libcurl_protocol_FTP = xyes ; then
662    AC_SUBST(GPGKEYS_CURL,"gpgkeys_curl$EXEEXT")
663    AC_DEFINE(FTP_VIA_LIBCURL,1,[Define if FTP is handled via libcurl])
664    if test x$libcurl_protocol_FTPS = xyes ; then
665       AC_DEFINE(FTPS_VIA_LIBCURL,1,[Define if FTPS is handled via libcurl])
666    fi
667 fi
668
669 dnl This isn't necessarily sendmail itself, but anything that gives a
670 dnl sendmail-ish interface to the outside world.  That includes qmail,
671 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
672
673 if test "$try_mailto" = yes ; then
674   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
675
676   if test "$with_mailprog" = yes ; then
677     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
678     if test "$ac_cv_path_SENDMAIL" ; then
679       GPGKEYS_MAILTO="gpgkeys_mailto"
680     fi
681   elif test "$with_mailprog" != no ; then
682     AC_MSG_CHECKING([for a mail transport program])
683     AC_SUBST(SENDMAIL,$with_mailprog)
684     AC_MSG_RESULT($with_mailprog)
685     GPGKEYS_MAILTO="gpgkeys_mailto"
686   fi
687 fi
688
689 AC_SUBST(GPGKEYS_MAILTO)
690
691 case "${host}" in
692     *-mingw32*)
693         PRINTABLE_OS_NAME="MingW32"
694         ;;
695     *-*-cygwin*)
696         PRINTABLE_OS_NAME="Cygwin"
697         ;;
698     i?86-emx-os2 | i?86-*-os2*emx )
699         PRINTABLE_OS_NAME="OS/2"
700         ;;
701     i?86-*-msdosdjgpp*)
702         PRINTABLE_OS_NAME="MSDOS/DJGPP"
703         try_extensions=no
704         ;;
705     *-linux*)
706         PRINTABLE_OS_NAME="GNU/Linux"
707         ;;
708     *)
709         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
710         ;;
711 esac
712 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
713                    [A human readable text with the name of the OS])
714
715
716 #
717 # 1. Set names of random devices
718 #
719 NAME_OF_DEV_RANDOM="/dev/random"
720 NAME_OF_DEV_URANDOM="/dev/urandom"
721 case "${host}" in
722     *-openbsd*)
723         NAME_OF_DEV_RANDOM="/dev/srandom"
724         NAME_OF_DEV_URANDOM="/dev/urandom"
725         ;;
726 esac
727 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM",
728                    [defined to the name of the strong random device])
729 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM",
730                    [defined to the name of the weaker random device])
731 AC_SUBST(MPI_OPT_FLAGS)
732
733
734 dnl Checks for libraries.
735
736 AM_GNU_GETTEXT_VERSION(0.14.1)
737 if test "$try_gettext" = yes; then
738   AM_GNU_GETTEXT(,[need-ngettext])
739
740   # gettext requires some extra checks.  These really should be part of
741   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
742   # function checks to here.
743
744   AC_CHECK_FUNCS(strchr)
745 else
746   USE_NLS=no
747   USE_INCLUDED_LIBINTL=no
748   BUILD_INCLUDED_LIBINTL=no
749   AC_SUBST(USE_NLS)
750   AC_SUBST(USE_INCLUDED_LIBINTL)
751   AC_SUBST(BUILD_INCLUDED_LIBINTL)
752 fi
753
754 if test "$try_extensions" = yes || test x"$card_support" = xyes ; then
755   if test "$need_dlopen" = yes; then
756     _dl_save_libs=$LIBS
757     LIBS=""
758     AC_SEARCH_LIBS(dlopen,dl,found_dlopen=yes)
759     if test x"$found_dlopen" = "xyes" ; then
760       AC_DEFINE(HAVE_DL_DLOPEN,1,
761                 [Defined when the dlopen function family is available])
762       DLLIBS=$LIBS
763     else
764       if test "$try_extensions" = yes ; then
765          AC_MSG_NOTICE([dlopen not found.  Disabling extensions.])
766          try_extensions=no
767       fi
768   
769       if test "$card_support" = yes ; then
770          AC_MSG_WARN([dlopen not found.  Disabling OpenPGP card support.])
771          card_support=no
772       fi
773     fi
774     LIBS=$_dl_save_libs
775   fi
776 fi
777
778 AC_SUBST(DLLIBS)
779
780 if test "$card_support" = yes ; then
781   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include OpenPGP card support])
782 fi
783
784 if test "$agent_support" = yes ; then
785   AC_DEFINE(ENABLE_AGENT_SUPPORT,1,[Define to include gpg-agent support])
786 fi
787
788 if test "$try_extensions" = yes ; then
789   AC_DEFINE(USE_DYNAMIC_LINKING,1,[Define to enable the use of extensions])
790 fi
791
792 if test "$selinux_support" = yes ; then
793   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
794 fi
795
796 if test "$gnupg_use_iconv" = yes ; then
797   AC_DEFINE(USE_GNUPG_ICONV,1,[Define to use the new iconv based code])
798 fi
799
800 if test "$do_backsigs" = yes ; then
801   AC_DEFINE(DO_BACKSIGS,1,[Define to enable the experimental backsigs code])
802 fi
803
804 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
805 AM_CONDITIONAL(ENABLE_AGENT_SUPPORT, test "$agent_support" = yes)
806
807 dnl Checks for header files.
808 AC_HEADER_STDC
809 AC_CHECK_HEADERS([unistd.h langinfo.h termio.h locale.h getopt.h])
810
811 # Note that we do not check for iconv here because this is done anyway
812 # by the gettext checks and thus it allows us to disable the use of
813 # iconv by using --disable-nls.
814
815 dnl Checks for typedefs, structures, and compiler characteristics.
816 AC_C_CONST
817 AC_C_INLINE
818 AC_C_VOLATILE
819 AC_TYPE_SIZE_T
820 AC_TYPE_MODE_T
821 AC_TYPE_SIGNAL
822 AC_DECL_SYS_SIGLIST
823
824 GNUPG_CHECK_ENDIAN
825
826 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
827 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
828 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
829 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
830 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
831
832 AC_CHECK_SIZEOF(unsigned short)
833 AC_CHECK_SIZEOF(unsigned int)
834 AC_CHECK_SIZEOF(unsigned long)
835 AC_CHECK_SIZEOF(unsigned long long)
836
837 # Ensure that we have UINT64_C before we bother to check for uint64_t
838 gt_HEADER_INTTYPES_H
839 AC_CACHE_CHECK([for UINT64_C], [gnupg_cv_uint64_c_works],
840                AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
841 uint64_t foo=UINT64_C(42);]),gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
842
843 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
844    AC_CHECK_SIZEOF(uint64_t)
845 fi
846
847 if test "$ac_cv_sizeof_unsigned_short" = "0" \
848    || test "$ac_cv_sizeof_unsigned_int" = "0" \
849    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
850     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
851 fi
852
853 dnl Do we have any 64-bit data types?
854 if test "$ac_cv_sizeof_unsigned_int" != "8" \
855    && test "$ac_cv_sizeof_unsigned_long" != "8" \
856    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
857    && test x"$ac_cv_sizeof_uint64_t" != "x8"; then
858     AC_MSG_NOTICE([No 64-bit types.  Disabling SHA-384 and SHA-512.])
859 else
860   if test x"$use_sha512" = xyes ; then
861      AC_SUBST(SHA512_O,sha512.o)
862      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
863   fi
864 fi
865
866 dnl Checks for library functions.
867 AC_FUNC_FSEEKO
868 AC_FUNC_VPRINTF
869 AC_FUNC_FORK
870 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
871 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times unsetenv)
872 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
873 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
874 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat getaddrinfo)
875 AC_REPLACE_FUNCS(mkdtemp timegm isascii memrchr)
876
877 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
878
879 # See if getopt is in libiberty.  This is of course not optimal since
880 # it might be somewhere other than libiberty, but does cover the
881 # mingw32 case.
882
883 AC_CHECK_FUNC(getopt,,AC_CHECK_LIB(iberty,getopt,AC_SUBST(GETOPT,"-liberty")))
884
885 #
886 # check for gethrtime and run a testprogram to see whether
887 # it is broken.  It has been reported that some Solaris and HP UX systems 
888 # raise an SIGILL
889 #
890 AC_CACHE_CHECK([for gethrtime], 
891                [gnupg_cv_func_gethrtime],
892                [AC_TRY_LINK([#include <sys/times.h>],[
893                    hrtime_t tv;
894                    tv = gethrtime();
895                  ],
896                  [gnupg_cv_func_gethrtime=yes],
897                  [gnupg_cv_func_gethrtime=no])
898                ])
899 if test $gnupg_cv_func_gethrtime = yes; then
900      AC_DEFINE([HAVE_GETHRTIME], 1,
901                [Define if you have the `gethrtime(2)' function.])
902      AC_CACHE_CHECK([whether gethrtime is broken], 
903                [gnupg_cv_func_broken_gethrtime],
904                [AC_TRY_RUN([
905                    #include <sys/times.h>
906                    int main () {
907                    hrtime_t tv;
908                    tv = gethrtime(); 
909                  }
910                  ],
911                  [gnupg_cv_func_broken_gethrtime=no],
912                  [gnupg_cv_func_broken_gethrtime=yes],
913                  [gnupg_cv_func_broken_gethrtime=assume-no])
914                 ])
915     if test $gnupg_cv_func_broken_gethrtime = yes; then
916       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
917       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
918     fi
919 fi
920      
921
922 GNUPG_CHECK_MLOCK
923 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
924
925 dnl
926 dnl Check whether we can use Linux capabilities as requested
927 dnl
928 if test "$use_capabilities" = "yes" ; then
929
930 AC_MSG_WARN([[
931 ***
932 *** WARNING: using capabilities with GnuPG is experimental code!
933 ***]])
934
935 use_capabilities=no
936 AC_CHECK_HEADERS(sys/capability.h)
937 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
938   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
939   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
940      AC_DEFINE(USE_CAPABILITIES,1,
941                [define if capabilities should be used])
942      AC_SUBST(CAPLIBS,"-lcap")
943      use_capabilities=yes
944   fi
945 fi
946 if test "$use_capabilities" = "no" ; then
947     AC_MSG_WARN([[
948 ***
949 *** The use of capabilities on this system is not possible.
950 *** You need a recent Linux kernel and some patches:
951 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
952 ***   fcap-module-990613.tar.gz     (kernel module)
953 ***   libcap-1.92.tar.gz            (user mode library and utilities)
954 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
955 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
956 ***]])
957 fi
958 fi
959
960
961 GNUPG_CHECK_IPC
962 if test "$ac_cv_header_sys_shm_h" = "yes"; then
963   AC_DEFINE(USE_SHM_COPROCESSING,1,
964             [define if the shared memory interface should be made available])
965 fi
966
967 dnl
968 dnl check whether we have a random device
969 dnl
970 if test "$try_dev_random" = yes ; then
971     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
972     [if test -r "$NAME_OF_DEV_RANDOM" && test -r "$NAME_OF_DEV_URANDOM" ; then
973       ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
974     if test "$ac_cv_have_dev_random" = yes; then
975         AC_DEFINE(HAVE_DEV_RANDOM,1,
976                  [defined if the system supports a random device] )
977     fi
978 else
979     AC_MSG_CHECKING(for random device)
980     ac_cv_have_dev_random=no
981     AC_MSG_RESULT(has been disabled)
982 fi
983
984
985 dnl
986 dnl Figure out the default random module.
987 dnl
988 random_modules=""
989 if test "$use_static_rnd" = default; then
990      if test "$ac_cv_have_dev_random" = yes; then
991         random_modules="rndlinux"
992      else
993          case "${host}" in
994             *-mingw32*|*-*-cygwin*)
995                 random_modules="rndw32"
996                 ;;
997             i?86-emx-os2|i?86-*-os2*emx)
998                 random_modules="rndos2"
999                 ;;
1000             m68k-atari-mint)
1001                 random_modules="rndatari"
1002                 ;;
1003             i?86-*-msdosdjgpp*)
1004                 :
1005                 ;;
1006             *)
1007                 random_modules="rndlinux rndegd rndunix"
1008                 AC_DEFINE(USE_ALL_RANDOM_MODULES, 1, 
1009                           [Allow to select random modules at runtime.])
1010                 ;;
1011          esac
1012      fi
1013 else
1014   if test "$use_static_rnd" = auto; then
1015      random_modules="rndlinux rndegd rndunix"
1016      AC_DEFINE(USE_ALL_RANDOM_MODULES, 1)
1017   else
1018      random_modules="rnd$use_static_rnd";
1019   fi
1020 fi
1021
1022 if test -z "$random_modules"; then
1023    AC_MSG_ERROR(no random module available)
1024 fi
1025 print_egd_warning=no
1026 for rndmod in $random_modules "" ; do
1027   case "$rndmod" in
1028     rndlinux)
1029          AC_DEFINE(USE_RNDLINUX,1, 
1030                   [Defined if the /dev/random based RNG should be used.])
1031          ;;
1032     rndunix)
1033          AC_DEFINE(USE_RNDUNIX,1, 
1034                   [Defined if the default Unix RNG should be used.])
1035          print_egd_warning=yes
1036           ;;
1037     rndegd)
1038          AC_DEFINE(USE_RNDEGD,1, 
1039                   [Defined if the EGD based RNG should be used.])
1040          ;;
1041     rndw32)
1042          AC_DEFINE(USE_RNDW32,1, 
1043                   [Defined if the Windows specific RNG should be used.])
1044         ;;
1045    esac
1046 done
1047
1048 dnl setup assembler stuff
1049 AC_MSG_CHECKING(for mpi assembler functions)
1050 if test -f $srcdir/mpi/config.links ; then
1051     . $srcdir/mpi/config.links
1052     AC_CONFIG_LINKS("$mpi_ln_list")
1053     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
1054     ac_cv_mpi_sflags="$mpi_sflags"
1055     ac_cv_mpi_config_done="yes"
1056     AC_MSG_RESULT(done)
1057 else
1058     AC_MSG_RESULT(failed)
1059     AC_MSG_ERROR([mpi/config.links missing!])
1060 fi
1061 MPI_EXTRA_ASM_OBJS=""
1062 show_extraasm=""
1063 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
1064 for i in $ac_cv_mpi_extra_asm_modules; do
1065     show_extraasm="$show_extraasm $i"
1066     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
1067 done
1068 fi
1069 AC_SUBST(MPI_EXTRA_ASM_OBJS)
1070 MPI_SFLAGS="$ac_cv_mpi_sflags"
1071 AC_SUBST(MPI_SFLAGS)
1072
1073 # Sanity check regex.  Tests adapted from mutt.
1074
1075 AC_MSG_CHECKING([whether regular expression support is requested])
1076 AC_ARG_ENABLE(regex,
1077   AC_HELP_STRING([--disable-regex],
1078     [do not handle regular expressions in trust signatures]),
1079   use_regex=$enableval, use_regex=yes)
1080 AC_MSG_RESULT($use_regex)
1081
1082 if test "$use_regex" = yes ; then
1083   AC_MSG_CHECKING([whether the included regex lib is requested])
1084   AC_ARG_WITH(included-regex,
1085       [  --with-included-regex   use the included GNU regex library],
1086       [gnupg_cv_included_regex="$withval"],[gnupg_cv_included_regex=no])
1087   AC_MSG_RESULT($gnupg_cv_included_regex)
1088
1089   if test $gnupg_cv_included_regex = no ; then
1090      # Does the system have regex functions at all?
1091      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
1092                            gnupg_cv_included_regex=yes)
1093   fi
1094
1095   if test $gnupg_cv_included_regex = no ; then
1096      AC_CACHE_CHECK([whether your system's regexp library is broken],
1097        [gnupg_cv_regex_broken],
1098        AC_TRY_RUN([
1099 #include <unistd.h>
1100 #include <regex.h>
1101 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1102        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1103
1104      if test $gnupg_cv_regex_broken = yes ; then
1105       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
1106       gnupg_cv_included_regex=yes
1107      fi
1108   fi
1109
1110   if test $gnupg_cv_included_regex = yes; then
1111      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
1112      AC_SUBST(REGEX_O,regex.o)
1113   fi
1114 else
1115
1116   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
1117 fi
1118
1119 dnl Do we have zlib? Must do it here because Solaris failed
1120 dnl when compiling a conftest (due to the "-lz" from LIBS).
1121 use_local_zlib=yes
1122 if test "$g10_force_zlib" = "yes"; then
1123   :
1124 else
1125   _cppflags="${CPPFLAGS}"
1126   _ldflags="${LDFLAGS}"
1127
1128   AC_ARG_WITH(zlib,
1129   [  --with-zlib=DIR         use libz in DIR],[
1130     if test -d "$withval"; then
1131       CPPFLAGS="${CPPFLAGS} -I$withval/include"
1132       LDFLAGS="${LDFLAGS} -L$withval/lib"
1133     fi
1134   ])
1135
1136   AC_CHECK_HEADER(zlib.h,
1137       AC_CHECK_LIB(z, deflateInit2_,
1138        use_local_zlib=no
1139        ZLIBS="-lz",
1140        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1141        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1142 fi
1143
1144 if test "$use_local_zlib" = yes ; then
1145     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
1146     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
1147     ZLIBS="../zlib/libzlib.a"
1148 else
1149     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
1150 fi
1151
1152 if test "$use_bzip2" = yes ; then
1153   _cppflags="${CPPFLAGS}"
1154   _ldflags="${LDFLAGS}"
1155   AC_ARG_WITH(bzip2,
1156      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1157       [
1158       if test -d "$withval" ; then
1159         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1160         LDFLAGS="${LDFLAGS} -L$withval/lib"
1161       fi
1162       ],withval="")
1163
1164 # Checking alongside stdio.h as an early version of bzip2 (1.0)
1165 # required stdio.h to be included before bzlib.h, and Solaris 9 is
1166 # woefully out of date.
1167
1168   if test "$withval" != no ; then
1169      AC_CHECK_HEADER(bzlib.h,
1170         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1171           [
1172           have_bz2=yes
1173           ZLIBS="$ZLIBS -lbz2"
1174           AC_DEFINE(HAVE_BZIP2,1,
1175                   [Defined if the bz2 compression library is available])
1176           ],
1177           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1178           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1179   fi
1180 fi
1181
1182 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1183 AC_SUBST(ZLIBS)
1184
1185 # libusb allows us to use the integrated CCID smartcard reader driver.
1186 GNUPG_CHECK_LIBUSB
1187
1188 # Check for readline support
1189 GNUPG_CHECK_READLINE
1190
1191 # Allow users to append something to the version string without
1192 # flagging it as development version.  The user version parts is
1193 # considered everything after a dash. 
1194 if test "$development_version" != yes; then
1195   changequote(,)dnl
1196   tmp_pat='[a-zA-Z]'
1197   changequote([,])dnl
1198   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1199     development_version=yes
1200   fi
1201 fi
1202 if test "$development_version" = yes; then
1203     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1204             [Defined if this is not a regular release])
1205 fi
1206
1207 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1208
1209
1210 # add some extra libs here so that previous tests don't fail for
1211 # mysterious reasons - the final link step should bail out. 
1212 case "${host}" in
1213     *-mingw32*)
1214 dnl      NETLIBS="$NETLIBS -lwsock32"
1215         W32LIBS="-lwsock32"
1216         ;;
1217     *)
1218        ;;
1219 esac
1220
1221 AC_SUBST(NETLIBS)
1222 AC_SUBST(W32LIBS)
1223
1224 # Special options used with gcc.
1225 if test "$GCC" = yes; then
1226     # Note that it is okay to use CFLAGS here because this are just
1227     # warning options and the user should have a chance of overriding
1228     #them.
1229     if test "$USE_MAINTAINER_MODE" = "yes"; then
1230         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1231         CFLAGS="$CFLAGS -Wformat-nonliteral"
1232     else
1233         CFLAGS="$CFLAGS -Wall"
1234     fi
1235
1236     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1237
1238     _gcc_cflags_save=$CFLAGS
1239     CFLAGS="-Wno-pointer-sign"
1240
1241     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1242     AC_MSG_RESULT($_gcc_psign)
1243
1244     CFLAGS=$_gcc_cflags_save;
1245
1246     if test x"$_gcc_psign" = xyes ; then
1247        CFLAGS="$CFLAGS -Wno-pointer-sign"
1248     fi
1249
1250     # Non exec stack hack.  Fixme: Write a test to check whether as
1251     # can cope with it and use the enable-noexecstack option only to
1252     # disable it in case it is required on sime platforms.
1253     if test "$noexecstack_support" = yes; then
1254         NOEXECSTACK_FLAGS="-Wa,--noexecstack"
1255     fi
1256 fi
1257 AC_SUBST(NOEXECSTACK_FLAGS)
1258
1259
1260 if test "$print_egd_warning" = yes; then
1261   AC_MSG_WARN([[
1262 ***
1263 *** The performance of the UNIX random gatherer module is not very good
1264 *** and it does not keep the entropy pool over multiple invocations of
1265 *** GnuPG.  The suggested way to overcome this problem is to use the
1266 ***
1267 ***               Entropy Gathering Daemon (EGD)
1268 ***
1269 *** which provides a entropy source for the whole system.  It is written
1270 *** in Perl and available at the GnuPG FTP servers.  For more information
1271 *** consult the GnuPG webpages:
1272 ***
1273 ***           http://www.gnupg.org/download/#EGD
1274 ***
1275 *** You may want to run ./configure with --enable-static-rnd=egd or
1276 *** --enable-static-rnd=auto to use it.
1277 ***]])
1278 fi
1279
1280 # Note the \\\\ for backslashes.  Autoconf eats one layer, leaving \\
1281
1282 AC_CONFIG_COMMANDS(g10defs.h,[[
1283 cat >g10defs.tmp <<G10EOF
1284 /* Generated automatically by configure */
1285 #ifdef HAVE_DRIVE_LETTERS
1286 #define G10_LOCALEDIR     "c:\\\\lib\\\\gnupg\\\\locale"
1287 #define GNUPG_LIBDIR      "c:\\\\lib\\\\gnupg"
1288 #define GNUPG_LIBEXECDIR  "c:\\\\lib\\\\gnupg"
1289 #define GNUPG_DATADIR     "c:\\\\lib\\\\gnupg"
1290 #define GNUPG_HOMEDIR     "c:\\\\gnupg"
1291 #else
1292 #define G10_LOCALEDIR     "${datadir}/locale"
1293 #define GNUPG_LIBDIR      "${libdir}/gnupg"
1294 #define GNUPG_DATADIR     "${datadir}/gnupg"
1295 #ifdef __VMS
1296 #define GNUPG_HOMEDIR "/SYS\$LOGIN/gnupg" 
1297 #else
1298 #define GNUPG_HOMEDIR "~/.gnupg" 
1299 #endif
1300 #endif
1301 /* those are here to be redefined by handcrafted g10defs.h.
1302    Please note that the string version must not contain more
1303    than one character because the using code assumes strlen()==1 */
1304 #ifdef HAVE_DOSISH_SYSTEM
1305 #define DIRSEP_C '\\\\'
1306 #define EXTSEP_C '.'
1307 #define DIRSEP_S "\\\\"
1308 #define EXTSEP_S "."
1309 #define PATHSEP_C ';'
1310 #define PATHSEP_S ";"
1311 #else
1312 #define DIRSEP_C '/'
1313 #define EXTSEP_C '.'
1314 #define DIRSEP_S "/"
1315 #define EXTSEP_S "."
1316 #define PATHSEP_C ':'
1317 #define PATHSEP_S ":"
1318 #endif
1319 /* This is the same as VERSION, but should be overridden if the
1320    platform cannot handle things like dots'.' in filenames.  Set
1321    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
1322    uses for dots and dashes. */
1323 #define SAFE_VERSION      VERSION
1324 #define SAFE_VERSION_DOT  '.'
1325 #define SAFE_VERSION_DASH '-'
1326 G10EOF
1327 cat mpi/mpi-asm-defs.h >>g10defs.tmp 
1328 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
1329     echo "g10defs.h is unchanged"
1330     rm -f g10defs.tmp
1331 else
1332     rm -f g10defs.h
1333     mv g10defs.tmp g10defs.h
1334     echo "g10defs.h created"
1335 fi
1336 ]],[[
1337 prefix=$prefix
1338 exec_prefix=$exec_prefix
1339 libdir=$libdir
1340 libexecdir=$libexecdir
1341 datadir=$datadir
1342 DATADIRNAME=$DATADIRNAME
1343 ]])
1344
1345
1346 AC_CONFIG_FILES([
1347 Makefile
1348 m4/Makefile
1349 intl/Makefile
1350 po/Makefile.in
1351 util/Makefile
1352 mpi/Makefile
1353 cipher/Makefile
1354 g10/Makefile
1355 keyserver/Makefile
1356 keyserver/gpgkeys_mailto
1357 keyserver/gpgkeys_test
1358 doc/Makefile
1359 tools/Makefile
1360 zlib/Makefile
1361 checks/Makefile
1362 ])
1363 AC_OUTPUT
1364
1365 # Give some feedback
1366 echo
1367 echo   "                Configured for: $PRINTABLE_OS_NAME ($host)"
1368 if test -n "$show_extraasm"; then
1369   echo "  Extra cpu specific functions:$show_extraasm"
1370 fi
1371 echo