f3bb2b643255fbb9b4ef6b700b57ac103ab0a64c
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.0
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005,
3 #               2006, 2007, 2008 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.10"
23
24 # Remember to change the version number immediately *after* a release.
25 # Set my_issvn to "yes" for non-released code.  Remember to run an
26 # "svn up" and "autogen.sh" right before creating a distribution.
27 m4_define([my_version], [2.0.14])
28 m4_define([my_issvn], [yes])
29
30 m4_define([svn_revision], m4_esyscmd([printf "%d" $(svn info 2>/dev/null \
31           | sed -n '/^Revision:/ s/[^0-9]//gp'|head -1)]))
32 AC_INIT([gnupg], 
33         [my_version[]m4_if(my_issvn,[yes],[-svn[]svn_revision])],
34         [http://bugs.gnupg.org])
35 # Set development_version to yes if the minor number is odd or you
36 # feel that the default check for a development version is not
37 # sufficient.
38 development_version=no
39
40 NEED_GPG_ERROR_VERSION=1.4
41
42 NEED_LIBGCRYPT_API=1
43 NEED_LIBGCRYPT_VERSION=1.4.0
44
45 NEED_LIBASSUAN_API=1
46 NEED_LIBASSUAN_VERSION=1.0.4
47
48 NEED_KSBA_API=1
49 NEED_KSBA_VERSION=1.0.2
50
51
52 PACKAGE=$PACKAGE_NAME
53 PACKAGE_GT=${PACKAGE_NAME}2
54 VERSION=$PACKAGE_VERSION
55
56 AC_CONFIG_AUX_DIR(scripts)
57 AC_CONFIG_SRCDIR(sm/gpgsm.c)
58 AM_CONFIG_HEADER(config.h)
59 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
60 AC_CANONICAL_HOST
61 AB_INIT
62
63 AC_GNU_SOURCE
64
65 # Some status variables.
66 have_gpg_error=no
67 have_libgcrypt=no 
68 have_libassuan=no
69 have_ksba=no
70 have_pth=no
71 have_libusb=no
72 have_adns=no
73
74 use_bzip2=yes
75 use_exec=yes
76 disable_keyserver_path=no
77
78
79 GNUPG_BUILD_PROGRAM(gpg, yes)
80 GNUPG_BUILD_PROGRAM(gpgsm, yes)
81 GNUPG_BUILD_PROGRAM(agent, yes)
82 GNUPG_BUILD_PROGRAM(scdaemon, yes)
83 GNUPG_BUILD_PROGRAM(tools, yes)
84 GNUPG_BUILD_PROGRAM(doc, yes)
85 GNUPG_BUILD_PROGRAM(symcryptrun, no)
86
87 AC_SUBST(PACKAGE)
88 AC_SUBST(PACKAGE_GT)
89 AC_SUBST(VERSION)
90 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
91 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
92                                 [Name of this package for gettext])
93 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
94 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
95                                         [Bug report address])
96 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
97                                        [Required version of Libgcrypt])
98 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
99                                        [Required version of Libksba])
100
101
102
103 # The default is to use the modules from this package and the few
104 # other packages in a standard place; i.e where this package gets
105 # installed.  With these options it is possible to override these
106 # ${prefix} depended values with fixed paths, which can't be replaced
107 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
108 AC_ARG_WITH(agent-pgm,
109     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
110           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
111 AC_SUBST(GNUPG_AGENT_PGM)
112 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
113 show_gnupg_agent_pgm="(default)"
114 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
115
116 AC_ARG_WITH(pinentry-pgm,
117     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
118           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
119 AC_SUBST(GNUPG_PINENTRY_PGM)
120 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
121 show_gnupg_pinentry_pgm="(default)"
122 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
123
124
125 AC_ARG_WITH(scdaemon-pgm,
126     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
127           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
128 AC_SUBST(GNUPG_SCDAEMON_PGM)
129 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
130 show_gnupg_scdaemon_pgm="(default)"
131 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
132
133
134 AC_ARG_WITH(dirmngr-pgm,
135     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
136           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
137 AC_SUBST(GNUPG_DIRMNGR_PGM)
138 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
139 show_gnupg_dirmngr_pgm="(default)"
140 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
141
142 AC_ARG_WITH(protect-tool-pgm,
143     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
144           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
145 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
146 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
147 show_gnupg_protect_tool_pgm="(default)"
148 test -n "$GNUPG_PROTECT_TOOL_PGM" \
149       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
150
151
152 # Some folks want to use only the agent from this packet.  Make it
153 # easier for them by providing the configure option
154 # --enable-only-agent.
155 AC_ARG_ENABLE(agent-only,
156     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
157     build_agent_only=$enableval)
158
159 # SELinux support includes tracking of sensitive files to avoid
160 # leaking their contents through processing these files by gpg itself
161 AC_MSG_CHECKING([whether SELinux support is requested])
162 AC_ARG_ENABLE(selinux-support,
163               AC_HELP_STRING([--enable-selinux-support],
164                              [enable SELinux support]),
165               selinux_support=$enableval, selinux_support=no)
166 AC_MSG_RESULT($selinux_support)
167
168 # Allow disabling of bzib2 support.
169 # It is defined only after we confirm the library is available later
170 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
171 AC_ARG_ENABLE(bzip2,
172    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
173    use_bzip2=$enableval)
174 AC_MSG_RESULT($use_bzip2)
175
176 # Configure option to allow or disallow execution of external
177 # programs, like a photo viewer.
178 AC_MSG_CHECKING([whether to enable external program execution])
179 AC_ARG_ENABLE(exec,
180     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
181     use_exec=$enableval)
182 AC_MSG_RESULT($use_exec)
183 if test "$use_exec" = no ; then
184     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
185 fi
186
187 if test "$use_exec" = yes ; then
188   AC_MSG_CHECKING([whether to enable photo ID viewing])
189   AC_ARG_ENABLE(photo-viewers,
190       [  --disable-photo-viewers disable photo ID viewers],
191       [if test "$enableval" = no ; then
192          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
193       fi],enableval=yes)
194   gnupg_cv_enable_photo_viewers=$enableval
195   AC_MSG_RESULT($enableval)
196
197   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
198     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
199     AC_ARG_WITH(photo-viewer,
200         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
201         [if test "$withval" = yes ; then
202            withval=no
203         elif test "$withval" != no ; then
204            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
205                             [if set, restrict photo-viewer to this])
206         fi],withval=no)
207     AC_MSG_RESULT($withval)
208   fi
209
210   AC_MSG_CHECKING([whether to enable external keyserver helpers])
211   AC_ARG_ENABLE(keyserver-helpers,
212       [  --disable-keyserver-helpers  disable all external keyserver support],
213       [if test "$enableval" = no ; then
214          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
215                   [define to disable keyserver helpers])
216       fi],enableval=yes)
217   gnupg_cv_enable_keyserver_helpers=$enableval
218   AC_MSG_RESULT($enableval)
219
220   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
221     # LDAP is defined only after we confirm the library is available later
222     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
223     AC_ARG_ENABLE(ldap,
224       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
225       try_ldap=$enableval, try_ldap=yes)
226     AC_MSG_RESULT($try_ldap)
227
228     AC_MSG_CHECKING([whether HKP keyserver support is requested])
229     AC_ARG_ENABLE(hkp,
230       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
231       try_hkp=$enableval, try_hkp=yes)
232     AC_MSG_RESULT($try_hkp)
233
234     AC_MSG_CHECKING([whether finger key fetching support is requested])
235     AC_ARG_ENABLE(finger,
236       AC_HELP_STRING([--disable-finger],
237         [disable finger key fetching interface only]),
238       try_finger=$enableval, try_finger=yes)
239     AC_MSG_RESULT($try_finger)
240
241     AC_MSG_CHECKING([whether generic object key fetching support is requested])
242     AC_ARG_ENABLE(generic,
243       AC_HELP_STRING([--disable-generic],
244         [disable generic object key fetching interface only]),
245       try_generic=$enableval, try_generic=yes)
246     AC_MSG_RESULT($try_generic)
247
248     AC_MSG_CHECKING([whether email keyserver support is requested])
249     AC_ARG_ENABLE(mailto,
250       AC_HELP_STRING([--enable-mailto],
251         [enable email keyserver interface only]),
252       try_mailto=$enableval, try_mailto=no)
253     AC_MSG_RESULT($try_mailto)
254     fi
255
256     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
257     AC_ARG_ENABLE(keyserver-path,
258       AC_HELP_STRING([--disable-keyserver-path],
259         [disable the exec-path option for keyserver helpers]),
260       [if test "$enableval" = no ; then
261          disable_keyserver_path=yes
262       fi],enableval=yes)
263     AC_MSG_RESULT($enableval)
264   fi
265
266
267 #
268 # Check for the key/uid cache size.  This can't be zero, but can be
269 # pretty small on embedded systems.  This is used for the gpg part.
270 #
271 AC_MSG_CHECKING([for the size of the key and uid cache])
272 AC_ARG_ENABLE(key-cache,
273         AC_HELP_STRING([--enable-key-cache=SIZE],
274                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
275 if test "$enableval" = "no"; then
276    enableval=5
277 elif test "$enableval" = "yes" || test "$enableval" = ""; then
278    enableval=4096
279 fi
280 changequote(,)dnl
281 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
282 changequote([,])dnl
283 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
284    AC_MSG_ERROR([invalid key-cache size])
285 fi
286 AC_MSG_RESULT($key_cache_size)
287 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
288                   [Size of the key and UID caches])
289
290
291
292 #
293 # Check whether we want to use Linux capabilities
294 #
295 AC_MSG_CHECKING([whether use of capabilities is requested])
296 AC_ARG_WITH(capabilities,
297     [  --with-capabilities     use linux capabilities [default=no]],
298 [use_capabilities="$withval"],[use_capabilities=no])
299 AC_MSG_RESULT($use_capabilities)
300
301 #
302 # To avoid double inclusion of config.h which might happen at some
303 # places, we add the usual double inclusion protection at the top of
304 # config.h.
305 #
306 AH_TOP([
307 #ifndef GNUPG_CONFIG_H_INCLUDED
308 #define GNUPG_CONFIG_H_INCLUDED
309 ])
310
311 #
312 # Stuff which goes at the bottom of config.h.
313 #
314 AH_BOTTOM([
315 /* This is the major version number of GnuPG so that
316    source included files can test for this.  Note, that
317    we use 2 here even for GnuPG 1.9.x. */
318 #define GNUPG_MAJOR_VERSION 2
319
320 /* Now to separate file name parts.
321    Please note that the string version must not contain more
322    than one character because the code assumes strlen()==1 */
323 #ifdef HAVE_DOSISH_SYSTEM
324 #define DIRSEP_C '\\'
325 #define DIRSEP_S "\\"
326 #define EXTSEP_C '.'
327 #define EXTSEP_S "."
328 #define PATHSEP_C ';'
329 #define PATHSEP_S ";"
330 #define EXEEXT_S ".exe"
331 #else
332 #define DIRSEP_C '/'
333 #define DIRSEP_S "/"
334 #define EXTSEP_C '.'
335 #define EXTSEP_S "."
336 #define PATHSEP_C ':'
337 #define PATHSEP_S ":"
338 #define EXEEXT_S ""
339 #endif
340
341 /* This is the same as VERSION, but should be overridden if the
342    platform cannot handle things like dots '.' in filenames. Set
343    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
344    uses for dots and dashes. */
345 #define SAFE_VERSION VERSION
346 #define SAFE_VERSION_DOT  '.'
347 #define SAFE_VERSION_DASH '-'
348
349 /* Some global constants. */
350 #ifdef HAVE_DRIVE_LETTERS
351 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
352 #elif defined(__VMS)
353 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg" 
354 #else
355 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
356 #endif 
357 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
358
359 /* For some systems (DOS currently), we hardcode the path here.  For
360    POSIX systems the values are constructed by the Makefiles, so that
361    the values may be overridden by the make invocations; this is to
362    comply with the GNU coding standards. */
363 #ifdef HAVE_DRIVE_LETTERS
364  /* FIXME: We need to use a function to determine these values depending 
365     on the actual installation directory. */
366 #define GNUPG_BINDIR      "c:\\gnupg"
367 #define GNUPG_LIBEXECDIR  "c:\\gnupg"
368 #define GNUPG_LIBDIR      "c:\\gnupg"
369 #define GNUPG_DATADIR     "c:\\gnupg"
370 #define GNUPG_SYSCONFDIR  "c:\\gnupg"
371 #endif
372
373 /* Derive some other constants. */
374 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
375 #define EXEC_TEMPFILE_ONLY
376 #endif
377
378
379 /* We didn't define endianness above, so get it from OS macros.  This
380    is intended for making fat binary builds on OS X. */
381 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
382 #if defined(__BIG_ENDIAN__)
383 #define BIG_ENDIAN_HOST 1
384 #elif defined(__LITTLE_ENDIAN__)
385 #define LITTLE_ENDIAN_HOST 1
386 #else
387 #error "No endianness found"
388 #endif
389 #endif
390
391
392 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
393    ldap_start_tls_s because that is the actual symbol used in the
394    library.  winldap.h redefines it to our commonly used value,
395    thus we define our usual macro here.  */
396 #ifdef HAVE_LDAP_START_TLS_SA
397 # ifndef HAVE_LDAP_START_TLS_S
398 #  define HAVE_LDAP_START_TLS_S 1
399 # endif
400 #endif
401
402
403 /* Tell libgcrypt not to use its own libgpg-error implementation. */
404 #define USE_LIBGPG_ERROR 1
405
406 /* We use jnlib, so tell other modules about it.  */
407 #define HAVE_JNLIB_LOGGING 1
408
409 /* Our HTTP code is used in estream mode.  */
410 #define HTTP_USE_ESTREAM 1
411
412 /* Under W32 we do an explicit socket initialization, thus we need to
413    avoid the on-demand initialization which would also install an atexit
414    handler.  */
415 #define HTTP_NO_WSASTARTUP
416
417 /* We always include support for the OpenPGP card.  */
418 #define ENABLE_CARD_SUPPORT 1
419
420 /* We don't want the old assuan codes anymore. */
421 #define _ASSUAN_ONLY_GPG_ERRORS 1
422
423 /* We explicitly need to disable PTH's soft mapping as Debian
424    currently enables it by default for no reason. */
425 #define PTH_SYSCALL_SOFT 0
426
427 /* We want to use the libgcrypt provided memory allocation for
428    asprintf.  */
429 #define _ESTREAM_PRINTF_MALLOC        gcry_malloc
430 #define _ESTREAM_PRINTF_FREE          gcry_free
431 #define _ESTREAM_PRINTF_EXTRA_INCLUDE "util.h"
432
433 #endif /*GNUPG_CONFIG_H_INCLUDED*/
434 ])
435
436
437 AM_MAINTAINER_MODE
438
439 # Checks for programs.
440 AC_MSG_NOTICE([checking for programs])
441 AC_PROG_MAKE_SET
442 AM_SANITY_CHECK
443 missing_dir=`cd $ac_aux_dir && pwd`
444 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
445 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
446 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
447 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
448 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
449 AC_PROG_AWK
450 AC_PROG_CC
451 AC_PROG_CPP
452 AM_PROG_CC_C_O
453 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
454   AC_MSG_ERROR([[No C-89 compiler found]])
455 fi
456 AC_PROG_INSTALL
457 AC_PROG_LN_S
458 AC_PROG_RANLIB
459 AC_CHECK_TOOL(AR, ar, :)
460 AC_PATH_PROG(PERL,"perl")
461 AC_CHECK_TOOL(WINDRES, windres, :)
462 AC_ISC_POSIX
463 gl_EARLY
464 AC_SYS_LARGEFILE
465 GNUPG_CHECK_FAQPROG
466 GNUPG_CHECK_USTAR
467
468 # We need to compile and run a program on the build machine.  A
469 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
470 # the AC archive is broken for autoconf 2.57.  Given that tehre is no
471 # newer version of that macro, we assume that it is also broken for
472 # autoconf 2.61 and thus we use a simple but usually sufficient
473 # approach.
474 AC_MSG_CHECKING(for cc for build)
475 if test "$cross_compiling" = "yes"; then
476   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
477 else
478   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
479 fi
480 AC_MSG_RESULT($CC_FOR_BUILD)
481 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
482
483
484
485 try_gettext=yes
486 have_dosish_system=no
487 have_w32_system=no
488 use_simple_gettext=no
489 case "${host}" in
490     *-mingw32*)
491         # special stuff for Windoze NT
492         ac_cv_have_dev_random=no
493         AC_DEFINE(USE_ONLY_8DOT3,1,
494                   [set this to limit filenames to the 8.3 format])
495         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
496                   [defined if we must run on a stupid file system])
497         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
498                   [because the Unix gettext has too much overhead on
499                    MingW32 systems and these systems lack Posix functions,
500                    we use a simplified version of gettext])
501         disable_keyserver_path=yes
502         have_dosish_system=yes
503         have_w32_system=yes
504         try_gettext="no"
505         use_simple_gettext=yes
506         ;;
507     i?86-emx-os2 | i?86-*-os2*emx )
508         # OS/2 with the EMX environment
509         ac_cv_have_dev_random=no
510         AC_DEFINE(HAVE_DRIVE_LETTERS)
511         have_dosish_system=yes
512         try_gettext="no"
513         ;;
514
515     i?86-*-msdosdjgpp*)
516         # DOS with the DJGPP environment
517         ac_cv_have_dev_random=no
518         AC_DEFINE(HAVE_DRIVE_LETTERS)
519         have_dosish_system=yes
520         try_gettext="no"
521         ;;
522
523     *-*-freebsd*)
524        # FreeBSD
525        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
526        LDFLAGS="$LDFLAGS -L/usr/local/lib"
527        ;;
528
529     *-*-hpux*)
530         if test -z "$GCC" ; then
531             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
532         fi
533         ;;
534     *-dec-osf4*)
535         if test -z "$GCC" ; then
536             # Suppress all warnings
537             # to get rid of the unsigned/signed char mismatch warnings.
538             CFLAGS="$CFLAGS -w"
539         fi
540         ;;
541     *-dec-osf5*)
542         if test -z "$GCC" ; then
543             # Use the newer compiler `-msg_disable ptrmismatch1' to
544             # get rid of the unsigned/signed char mismatch warnings.
545             # Using this may hide other pointer mismatch warnings, but
546             # it at least lets other warning classes through
547             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
548         fi
549         ;;
550     m68k-atari-mint)
551         ;;
552     *)
553        ;;
554 esac
555
556 if test "$have_dosish_system" = yes; then
557    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
558              [Defined if we run on some of the PCDOS like systems 
559               (DOS, Windoze. OS/2) with special properties like
560               no file modes])
561 fi
562 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
563
564 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
565
566 if test "$have_w32_system" = yes; then
567    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
568 fi
569 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
570
571 if test "$disable_keyserver_path" = yes; then
572     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
573               [Defined to disable exec-path for keyserver helpers])
574 fi
575
576 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
577 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
578
579 if test x"$try_hkp" = xyes ; then
580   AC_SUBST(GPGKEYS_HKP,"gpg2keys_hkp$EXEEXT")
581 fi
582
583 if test x"$try_finger" = xyes ; then
584   AC_SUBST(GPGKEYS_FINGER,"gpg2keys_finger$EXEEXT")
585 fi
586
587
588
589 #
590 # Checks for libraries.
591 #
592 AC_MSG_NOTICE([checking for libraries])
593
594
595 #
596 # libgpg-error is a library with error codes shared between GnuPG
597 # related projects.
598 #
599 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
600                   have_gpg_error=yes,have_gpg_error=no)
601
602
603 #
604 # Libgcrypt is our generic crypto library
605 #
606 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
607         have_libgcrypt=yes,have_libgcrypt=no)
608
609
610 #
611 # libassuan is used for IPC
612 #
613 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
614                   have_libassuan=yes,have_libassuan=no)
615 if test "$have_libassuan" = "yes"; then
616   have_libassuan=no
617   AM_PATH_LIBASSUAN_PTH("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
618                         have_libassuan=yes,have_libassuan=no)
619   AM_CHECK_LIBASSUAN("$NEED_LIBASSUAN_API:1.0.1",
620        [AC_DEFINE(HAVE_ASSUAN_SET_IO_MONITOR, 1,
621          [Define to 1 if you have the `assuan_set_io_monitor' function.])],)  
622   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
623             [version of the libbassuan library])
624 fi
625
626
627
628 #
629 # libksba is our X.509 support library
630 #
631 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
632
633
634 #
635 # libusb allows us to use the integrated CCID smartcard reader driver.
636 #
637 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
638 AC_CHECK_LIB(usb, usb_bulk_write,
639               [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
640                 AC_DEFINE(HAVE_LIBUSB,1,
641                          [defined if libusb is available])
642                 have_libusb=yes
643              ])
644 AC_SUBST(LIBUSB_LIBS)
645 AC_CHECK_FUNCS(usb_create_match)
646
647 #
648 # Check wether it is necessary to link against libdl.
649 #
650 gnupg_dlopen_save_libs="$LIBS"
651 LIBS=""
652 AC_SEARCH_LIBS(dlopen, c dl,,,)
653 DL_LIBS=$LIBS
654 AC_SUBST(DL_LIBS)
655 LIBS="$gnupg_dlopen_save_libs"
656
657 #
658 # Checks for symcryptrun:
659 #
660
661 # libutil has openpty() and login_tty().
662 AC_CHECK_LIB(util, openpty,
663               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
664                 AC_DEFINE(HAVE_LIBUTIL,1,
665                          [defined if libutil is available])
666              ])
667 AC_SUBST(LIBUTIL_LIBS)
668
669 # shred is used to clean temporary plain text files.
670 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
671 AC_DEFINE_UNQUOTED(SHRED,
672         "${SHRED}", [defines the filename of the shred program])
673
674
675
676 #
677 # Check whether the GNU Pth library is available
678 # Note, that we include a Pth emulation for W32.
679 #
680 GNUPG_PATH_PTH
681 if test "$have_pth" = "yes"; then
682   AC_DEFINE(USE_GNU_PTH, 1,
683               [Defined if the GNU Portable Thread Library should be used])
684 else
685   AC_MSG_WARN([[
686 ***
687 *** To support concurrent access to the gpg-agent and the SCdaemon
688 *** we need the support of the GNU Portable Threads Library.
689 *** Download it from ftp://ftp.gnu.org/gnu/pth/
690 *** On a Debian GNU/Linux system you might want to try 
691 ***   apt-get install libpth-dev
692 ***]])
693 fi
694
695
696 AC_MSG_NOTICE([checking for networking options])
697
698 #
699 # Must check for network library requirements before doing link tests
700 # for ldap, for example. If ldap libs are static (or dynamic and without
701 # ELF runtime link paths), then link will fail and LDAP support won't
702 # be detected.
703 #
704 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
705         [NETLIBS="-lnsl $NETLIBS"]))
706 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
707         [NETLIBS="-lsocket $NETLIBS"]))
708
709
710 #
711 # Check for ADNS.
712 #
713 _cppflags="${CPPFLAGS}"
714 _ldflags="${LDFLAGS}"
715 AC_ARG_WITH(adns,
716             AC_HELP_STRING([--with-adns=DIR],
717                            [look for the adns library in DIR]),
718             [if test -d "$withval"; then
719                CPPFLAGS="${CPPFLAGS} -I$withval/include"
720                LDFLAGS="${LDFLAGS} -L$withval/lib"
721              fi])
722 if test "$with_adns" != "no"; then
723   AC_CHECK_HEADERS(adns.h,
724                 AC_CHECK_LIB(adns, adns_init,
725                              [have_adns=yes],
726                              [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}]),
727                 [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}])
728 fi
729 if test "$have_adns" = "yes"; then
730   ADNSLIBS="-ladns" 
731 fi
732 AC_SUBST(ADNSLIBS)
733 # Newer adns versions feature a free function to be used under W32.
734 AC_CHECK_FUNCS(adns_free)
735
736
737 #
738 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
739 #
740 if test x"$try_hkp" = xyes || test x"$try_http" = xyes ; then
741   AC_ARG_ENABLE(dns-srv,
742      AC_HELP_STRING([--disable-dns-srv],
743                     [disable the use of DNS SRV in HKP and HTTP]),
744                 use_dns_srv=$enableval,use_dns_srv=yes)
745 fi
746
747 AC_ARG_ENABLE(dns-pka,
748    AC_HELP_STRING([--disable-dns-pka],
749         [disable the use of PKA records in DNS]),
750    use_dns_pka=$enableval,use_dns_pka=yes)
751
752 AC_ARG_ENABLE(dns-cert,
753    AC_HELP_STRING([--disable-dns-cert],
754         [disable the use of CERT records in DNS]),
755    use_dns_cert=$enableval,use_dns_cert=yes)
756
757 if test x"$use_dns_pka" = xyes || test x"$use_dns_srv" = xyes \
758    || test x"$use_dns_cert" = xyes; then
759   _dns_save_libs=$LIBS
760   LIBS=""
761   # the double underscore thing is a glibc-ism?
762   AC_SEARCH_LIBS(res_query,resolv bind,,
763                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
764   AC_SEARCH_LIBS(dn_expand,resolv bind,,
765                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
766   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
767                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
768
769   if test x"$have_resolver" != xno ; then
770
771     # Make sure that the BIND 4 resolver interface is workable before
772     # enabling any code that calls it.  At some point I'll rewrite the
773     # code to use the BIND 8 resolver API.
774     # We might also want to use adns instead.  Problem with ADNS is that
775     # it does not support v6.
776
777     AC_MSG_CHECKING([whether the resolver is usable])
778     AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
779 #include <netinet/in.h>
780 #include <arpa/nameser.h>
781 #include <resolv.h>],
782 [[unsigned char answer[PACKETSZ];
783   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
784   dn_skipname(0,0); 
785   dn_expand(0,0,0,0,0);
786 ]])],have_resolver=yes,have_resolver=no)
787     AC_MSG_RESULT($have_resolver)
788
789     # This is Apple-specific and somewhat bizarre as they changed the
790     # define in bind 8 for some reason.
791
792     if test x"$have_resolver" != xyes ; then
793        AC_MSG_CHECKING(
794              [whether I can make the resolver usable with BIND_8_COMPAT])
795        AC_LINK_IFELSE([AC_LANG_PROGRAM([#define BIND_8_COMPAT
796 #include <sys/types.h>
797 #include <netinet/in.h>
798 #include <arpa/nameser.h>
799 #include <resolv.h>],
800 [[unsigned char answer[PACKETSZ];
801   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
802   dn_skipname(0,0); dn_expand(0,0,0,0,0);
803 ]])],[have_resolver=yes ; need_compat=yes])
804        AC_MSG_RESULT($have_resolver)
805     fi
806   fi
807
808   if test x"$have_resolver" = xyes ; then
809      DNSLIBS=$LIBS
810
811      if test x"$use_dns_srv" = xyes ; then
812         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
813      fi
814
815      if test x"$use_dns_pka" = xyes ; then
816         AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
817      fi
818
819      if test x"$use_dns_cert" = xyes ; then
820         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
821      fi
822
823      if test x"$need_compat" = xyes ; then
824         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
825      fi
826   else
827      # If we have no resolver library but ADNS (e.g. under W32) enable the
828      # code parts which can be used with ADNS.
829      use_dns_cert=no
830      if test x"$have_adns" = xyes ; then
831         DNSLIBS="$ADNSLIBS"
832         AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
833
834         if test x"$use_dns_srv" = xyes ; then
835            AC_DEFINE(USE_DNS_SRV,1)
836         fi
837
838         if test x"$use_dns_pka" = xyes ; then
839            AC_DEFINE(USE_DNS_PKA,1)
840         fi
841      else
842         use_dns_srv=no
843         use_dns_pka=no
844      fi
845   fi
846
847   LIBS=$_dns_save_libs
848 fi
849
850 AC_SUBST(DNSLIBS)
851
852 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
853
854
855 #
856 # Check for LDAP
857 #
858 if test "$try_ldap" = yes ; then
859    GNUPG_CHECK_LDAP($NETLIBS)
860 fi
861
862 #
863 # Check for curl.  We fake the curl API if libcurl isn't installed.
864 # We require 7.10 or later as we use curl_version_info().
865 #
866 LIBCURL_CHECK_CONFIG([yes],[7.10],,[fake_curl=yes])
867 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
868
869 # Generic, for us, means curl
870
871 if test x"$try_generic" = xyes ; then
872    AC_SUBST(GPGKEYS_CURL,"gpg2keys_curl$EXEEXT")
873 fi
874
875 #
876 # Check for sendmail
877 #
878 # This isn't necessarily sendmail itself, but anything that gives a
879 # sendmail-ish interface to the outside world.  That includes Exim,
880 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
881 if test "$try_mailto" = yes ; then
882   AC_ARG_WITH(mailprog,
883       AC_HELP_STRING([--with-mailprog=NAME],
884                      [use "NAME -t" for mail transport]),
885              ,with_mailprog=yes)
886
887   if test x"$with_mailprog" = xyes ; then
888     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
889     if test "$ac_cv_path_SENDMAIL" ; then
890       GPGKEYS_MAILTO="gpg2keys_mailto"
891     fi
892   elif test x"$with_mailprog" != xno ; then
893     AC_MSG_CHECKING([for a mail transport program])
894     AC_SUBST(SENDMAIL,$with_mailprog)
895     AC_MSG_RESULT($with_mailprog)
896     GPGKEYS_MAILTO="gpg2keys_mailto"
897   fi
898 fi
899
900 AC_SUBST(GPGKEYS_MAILTO)
901
902 #
903 # Construct a printable name of the OS
904 #
905 case "${host}" in
906     *-mingw32*)
907         PRINTABLE_OS_NAME="MingW32"
908         ;;
909     *-*-cygwin*)
910         PRINTABLE_OS_NAME="Cygwin"
911         ;;
912     i?86-emx-os2 | i?86-*-os2*emx )
913         PRINTABLE_OS_NAME="OS/2"
914         ;;
915     i?86-*-msdosdjgpp*)
916         PRINTABLE_OS_NAME="MSDOS/DJGPP"
917         try_dynload=no
918         ;;
919     *-linux*)
920         PRINTABLE_OS_NAME="GNU/Linux"
921         ;;
922     *)
923         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
924         ;;
925 esac
926 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
927                    [A human readable text with the name of the OS])
928
929
930 #
931 # Checking for iconv
932 #
933 AM_ICONV
934
935
936 #
937 # Check for gettext
938 #
939 # This is "GNU gnupg" - The project-id script from gettext
940 #                       needs this string
941 #
942 AC_MSG_NOTICE([checking for gettext])
943 AM_PO_SUBDIRS
944 AM_GNU_GETTEXT_VERSION([0.17])
945 if test "$try_gettext" = yes; then
946   AM_GNU_GETTEXT([external],[need-ngettext])
947
948   # gettext requires some extra checks.  These really should be part of
949   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
950   # function checks to here.
951
952   AC_CHECK_FUNCS(strchr)
953 else
954   USE_NLS=no
955   USE_INCLUDED_LIBINTL=no
956   BUILD_INCLUDED_LIBINTL=no
957   POSUB=po
958   AC_SUBST(USE_NLS)
959   AC_SUBST(USE_INCLUDED_LIBINTL)
960   AC_SUBST(BUILD_INCLUDED_LIBINTL)
961   AC_SUBST(POSUB)
962 fi
963
964 # We use HAVE_LANGINFO_CODESET in a couple of places.
965 AM_LANGINFO_CODESET
966
967 # Checks required for our use locales
968 gt_LC_MESSAGES
969
970
971 #
972 # SELinux support
973 #
974 if test "$selinux_support" = yes ; then
975   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
976 fi
977
978
979 #
980 # Checks for header files.
981 #
982 AC_MSG_NOTICE([checking for header files])
983 AC_HEADER_STDC
984 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h])
985 AC_CHECK_HEADERS([pty.h pwd.h inttypes.h])
986 AC_HEADER_TIME
987
988
989 #
990 # Checks for typedefs, structures, and compiler characteristics.
991 #
992 AC_MSG_NOTICE([checking for system characteristics])
993 AC_C_CONST
994 AC_C_INLINE
995 AC_C_VOLATILE
996 AC_TYPE_SIZE_T
997 AC_TYPE_MODE_T
998 AC_TYPE_SIGNAL
999 AC_DECL_SYS_SIGLIST
1000
1001 gl_HEADER_SYS_SOCKET
1002 gl_TYPE_SOCKLEN_T
1003
1004 AC_ARG_ENABLE(endian-check,
1005               AC_HELP_STRING([--disable-endian-check],
1006               [disable the endian check and trust the OS provided macros]),
1007               endiancheck=$enableval,endiancheck=yes)
1008
1009 if test x"$endiancheck" = xyes ; then
1010   GNUPG_CHECK_ENDIAN
1011 fi
1012
1013 # fixme: we should get rid of the byte type
1014 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1015 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1016 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1017 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1018 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1019
1020 AC_CHECK_SIZEOF(unsigned short)
1021 AC_CHECK_SIZEOF(unsigned int)
1022 AC_CHECK_SIZEOF(unsigned long)
1023 AC_CHECK_SIZEOF(unsigned long long)
1024 AC_CHECK_SIZEOF(time_t,,[[
1025 #include <stdio.h>
1026 #if TIME_WITH_SYS_TIME
1027 # include <sys/time.h>
1028 # include <time.h>
1029 #else
1030 # if HAVE_SYS_TIME_H
1031 #  include <sys/time.h>
1032 # else
1033 #  include <time.h>
1034 # endif
1035 #endif
1036 ]])
1037
1038
1039 # Ensure that we have UINT64_C before we bother to check for uint64_t
1040 # Fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
1041 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
1042    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
1043        uint64_t foo=UINT64_C(42);]),
1044      gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
1045 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
1046    AC_CHECK_SIZEOF(uint64_t)
1047 fi
1048
1049 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1050    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1051    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1052     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1053 fi
1054
1055
1056 #
1057 # Checks for library functions.
1058 #
1059 AC_MSG_NOTICE([checking for library functions])
1060 AC_CHECK_DECLS(getpagesize)
1061 AC_FUNC_FSEEKO
1062 AC_FUNC_VPRINTF
1063 AC_FUNC_FORK
1064 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap])
1065 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r])
1066 AC_CHECK_FUNCS([unsetenv fcntl ftruncate])
1067 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1068 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1069 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe stat getaddrinfo])
1070 AC_CHECK_FUNCS([ttyname rand ftello fsync])
1071
1072 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1073
1074 #
1075 # These are needed by libjnlib - fixme: we should use a jnlib.m4
1076 # Note:  We already checked pwd.h.
1077 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol])
1078 AC_CHECK_FUNCS([memrchr isascii timegm getrusage setrlimit stat setlocale])
1079 AC_CHECK_FUNCS([flockfile funlockfile fopencookie funopen getpwnam getpwuid])
1080
1081 #
1082 # gnulib checks
1083 #
1084 gl_SOURCE_BASE([gl])
1085 gl_M4_BASE([gl/m4])
1086 gl_MODULES([setenv mkdtemp xsize strpbrk])
1087 gl_INIT
1088
1089
1090 #
1091 # W32 specific test
1092 #
1093 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1094
1095 #
1096 # Sanity check regex.  Tests adapted from mutt.
1097 #
1098 AC_MSG_CHECKING([whether regular expression support is requested])
1099 AC_ARG_ENABLE(regex,
1100   AC_HELP_STRING([--disable-regex],
1101     [do not handle regular expressions in trust signatures]),
1102   use_regex=$enableval, use_regex=yes)
1103 AC_MSG_RESULT($use_regex)
1104
1105 if test "$use_regex" = yes ; then
1106   _cppflags="${CPPFLAGS}"
1107   _ldflags="${LDFLAGS}"
1108   AC_ARG_WITH(regex,
1109      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1110       [
1111       if test -d "$withval" ; then
1112         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1113         LDFLAGS="${LDFLAGS} -L$withval/lib"
1114       fi
1115       ],withval="")     
1116
1117   # Does the system have regex functions at all?
1118   AC_SEARCH_LIBS([regcomp], [regex])
1119   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1120
1121   if test $gnupg_cv_have_regex = no; then
1122     use_regex=no
1123   else
1124     if test x"$cross_compiling" = xyes; then
1125       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1126     else
1127       AC_CACHE_CHECK([whether your system's regexp library is broken],
1128        [gnupg_cv_regex_broken],
1129        AC_TRY_RUN([
1130 #include <unistd.h>
1131 #include <regex.h>
1132 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1133        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1134
1135       if test $gnupg_cv_regex_broken = yes; then
1136         AC_MSG_WARN([your regex is broken - disabling regex use])
1137         use_regex=no
1138       fi
1139     fi
1140   fi
1141   CPPFLAGS="${_cppflags}"
1142   LDFLAGS="${_ldflags}"
1143 fi
1144
1145 if test "$use_regex" != yes ; then
1146   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1147 fi
1148 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1149
1150
1151
1152 #
1153 # Do we have zlib? Must do it here because Solaris failed
1154 # when compiling a conftest (due to the "-lz" from LIBS).
1155 # Note that we combine zlib and bzlib2 in ZLIBS.
1156 #
1157 _cppflags="${CPPFLAGS}"
1158 _ldflags="${LDFLAGS}"
1159 AC_ARG_WITH(zlib,
1160   [  --with-zlib=DIR         use libz in DIR],[
1161     if test -d "$withval"; then
1162       CPPFLAGS="${CPPFLAGS} -I$withval/include"
1163       LDFLAGS="${LDFLAGS} -L$withval/lib"
1164     fi
1165   ])
1166
1167 AC_CHECK_HEADER(zlib.h,
1168       AC_CHECK_LIB(z, deflateInit2_,
1169        ZLIBS="-lz",
1170        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1171        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1172
1173 #
1174 # Check whether we can support bzip2
1175
1176 if test "$use_bzip2" = yes ; then
1177   _cppflags="${CPPFLAGS}"
1178   _ldflags="${LDFLAGS}"
1179   AC_ARG_WITH(bzip2,
1180      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1181       [
1182       if test -d "$withval" ; then
1183         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1184         LDFLAGS="${LDFLAGS} -L$withval/lib"
1185       fi
1186       ],withval="")
1187
1188   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1189   # required stdio.h to be included before bzlib.h, and Solaris 9 is 
1190   # woefully out of date.
1191   if test "$withval" != no ; then
1192      AC_CHECK_HEADER(bzlib.h,
1193         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1194           [
1195           have_bz2=yes
1196           ZLIBS="$ZLIBS -lbz2"
1197           AC_DEFINE(HAVE_BZIP2,1,
1198                   [Defined if the bz2 compression library is available])
1199           ],
1200           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1201           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1202   fi
1203 fi
1204 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1205 AC_SUBST(ZLIBS)
1206
1207
1208 # Check for readline support
1209 GNUPG_CHECK_READLINE
1210
1211 #
1212 # Allow users to append something to the version string without
1213 # flagging it as development version.  The user version parts is
1214 # considered everything after a dash. 
1215 #
1216 if test "$development_version" != yes; then
1217   changequote(,)dnl
1218   tmp_pat='[a-zA-Z]'
1219   changequote([,])dnl
1220   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1221     development_version=yes
1222   fi
1223 fi
1224 if test "$development_version" = yes; then
1225     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1226             [Defined if this is not a regular release])
1227 fi
1228
1229 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1230
1231 GNUPG_CHECK_GNUMAKE
1232
1233 # Add some extra libs here so that previous tests don't fail for
1234 # mysterious reasons - the final link step should bail out.
1235 # W32SOCKLIBS is also defined so that if can be used for tools not
1236 # requiring any network stuff but linking to code in libcommon which
1237 # tracks in winsock stuff (e.g. init_common_subsystems.
1238 if test "$have_w32_system" = yes; then
1239    W32SOCKLIBS="-lws2_32"
1240    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1241 fi
1242
1243 AC_SUBST(NETLIBS)
1244 AC_SUBST(W32SOCKLIBS)
1245
1246 #
1247 # Setup gcc specific options
1248 #
1249 AC_MSG_NOTICE([checking for cc features])
1250 if test "$GCC" = yes; then
1251     # Note that it is okay to use CFLAGS here because this are just
1252     # warning options and the user should have a chance of overriding
1253     # them.
1254     if test "$USE_MAINTAINER_MODE" = "yes"; then
1255         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1256         CFLAGS="$CFLAGS -Wformat -Wno-format-y2k -Wformat-security"
1257         AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1258         _gcc_cflags_save=$CFLAGS
1259         CFLAGS="-Wno-missing-field-initializers"
1260         AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_wopt=yes,_gcc_wopt=no)
1261         AC_MSG_RESULT($_gcc_wopt)
1262         CFLAGS=$_gcc_cflags_save;
1263         if test x"$_gcc_wopt" = xyes ; then
1264           CFLAGS="$CFLAGS -W -Wno-sign-compare -Wno-missing-field-initializers"
1265         fi
1266         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1267         _gcc_cflags_save=$CFLAGS
1268         CFLAGS="-Wdeclaration-after-statement"
1269         AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_wopt=yes,_gcc_wopt=no)
1270         AC_MSG_RESULT($_gcc_wopt)
1271         CFLAGS=$_gcc_cflags_save;
1272         if test x"$_gcc_wopt" = xyes ; then
1273           CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1274         fi
1275     else
1276         CFLAGS="$CFLAGS -Wall"
1277     fi
1278
1279     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1280     _gcc_cflags_save=$CFLAGS
1281     CFLAGS="-Wno-pointer-sign"
1282     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1283     AC_MSG_RESULT($_gcc_psign)
1284     CFLAGS=$_gcc_cflags_save;
1285     if test x"$_gcc_psign" = xyes ; then
1286        CFLAGS="$CFLAGS -Wno-pointer-sign"
1287     fi
1288
1289     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1290     _gcc_cflags_save=$CFLAGS
1291     CFLAGS="-Wpointer-arith"
1292     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1293     AC_MSG_RESULT($_gcc_psign)
1294     CFLAGS=$_gcc_cflags_save;
1295     if test x"$_gcc_psign" = xyes ; then
1296        CFLAGS="$CFLAGS -Wpointer-arith"
1297     fi
1298 fi
1299
1300
1301 #
1302 # This is handy for debugging so the compiler doesn't rearrange
1303 # things and eliminate variables.
1304 #
1305 AC_ARG_ENABLE(optimization,
1306    AC_HELP_STRING([--disable-optimization],
1307                   [disable compiler optimization]),
1308                   [if test $enableval = no ; then
1309                       CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]]//'`
1310                    fi])
1311
1312 #
1313 # Prepare building of estream
1314 #
1315 estream_INIT
1316
1317
1318 #
1319 # Decide what to build
1320 #
1321 if test "$have_adns" = "yes"; then
1322   AC_SUBST(GPGKEYS_KDNS, "gpg2keys_kdns$EXEEXT")
1323 fi
1324
1325
1326 missing_pth=no
1327 if test $have_ksba = no; then
1328   build_gpgsm=no
1329   build_scdaemon=no
1330 fi
1331
1332 build_agent_threaded=""
1333 if test "$build_agent" = "yes"; then
1334   if test $have_pth = no; then
1335      build_agent_threaded="(not multi-threaded)"
1336      missing_pth=yes
1337   fi
1338 fi
1339
1340 build_scdaemon_extra=""
1341 if test "$build_scdaemon" = "yes"; then
1342   tmp=""
1343   if test $have_pth = no; then
1344      build_scdaemon_extra="not multi-threaded"
1345      tmp=", "
1346      missing_pth=yes
1347   fi
1348   if test $have_libusb = no; then
1349      build_scdaemon_extra="${tmp}without internal CCID driver"
1350      tmp=", "
1351   fi
1352   if test -n "$build_scdaemon_extra"; then
1353      build_scdaemon_extra="(${build_scdaemon_extra})"
1354   fi
1355 fi
1356
1357
1358 if test "$build_agent_only" = "yes" ; then
1359   build_gpg=no
1360   build_gpgsm=no
1361   build_scdaemon=no
1362   build_tools=no
1363   build_doc=no
1364 fi
1365
1366
1367 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1368 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1369 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1370 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1371 AM_CONDITIONAL(BUILD_TOOLS, test "$build_tools" = "yes")
1372 AM_CONDITIONAL(BUILD_DOC,   test "$build_doc" = "yes")
1373 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1374
1375 AM_CONDITIONAL(RUN_GPG_TESTS,
1376         test x$cross_compiling = xno -a "$build_gpg" = yes )
1377
1378
1379 #
1380 # Print errors here so that they are visible all
1381 # together and the user can acquire them all together.
1382 #
1383 die=no
1384 if test "$have_gpg_error" = "no"; then
1385    die=yes
1386    AC_MSG_NOTICE([[
1387 ***  
1388 *** You need libgpg-error to build this program.
1389 **  This library is for example available at
1390 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1391 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1392 ***]])
1393 fi
1394 if test "$have_libgcrypt" = "no"; then
1395    die=yes
1396    AC_MSG_NOTICE([[
1397 ***  
1398 *** You need libgcrypt to build this program.
1399 **  This library is for example available at
1400 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1401 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API is required.)
1402 ***]])
1403 fi
1404 if test "$have_libassuan" = "no"; then
1405    die=yes
1406    AC_MSG_NOTICE([[
1407 ***
1408 *** You need libassuan with Pth support to build this program.
1409 *** This library is for example available at
1410 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1411 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1412 ***]])
1413 fi
1414 if test "$have_ksba" = "no"; then
1415     AC_MSG_NOTICE([[
1416 ***
1417 *** You need libksba to build this program.
1418 *** This library is for example available at
1419 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1420 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1421 ***]])
1422 fi
1423 if test "$missing_pth" = "yes"; then
1424     AC_MSG_NOTICE([[
1425 ***
1426 *** It is now required to build with support for the
1427 *** GNU Portable Threads Library (Pth). Please install this
1428 *** library first.  The library is for example available at
1429 ***   ftp://ftp.gnu.org/gnu/pth/
1430 *** On a Debian GNU/Linux system you can install it using 
1431 ***   apt-get install libpth-dev
1432 *** To build GnuPG for Windows you need to use the W32PTH
1433 *** package; available at:
1434 ***   ftp://ftp.g10code.com/g10code/w32pth/
1435 ***]])
1436    die=yes
1437 fi
1438
1439 if test "$die" = "yes"; then
1440     AC_MSG_ERROR([[
1441 ***
1442 *** Required libraries not found. Please consult the above messages
1443 *** and install them before running configure again.
1444 ***]])
1445 fi
1446
1447
1448
1449 AC_CONFIG_FILES([ m4/Makefile 
1450 Makefile
1451 po/Makefile.in
1452 gl/Makefile
1453 include/Makefile
1454 jnlib/Makefile
1455 common/Makefile
1456 kbx/Makefile
1457 g10/Makefile
1458 sm/Makefile
1459 agent/Makefile
1460 scd/Makefile
1461 keyserver/Makefile
1462 keyserver/gpg2keys_mailto
1463 keyserver/gpg2keys_test
1464 tools/gpg-zip
1465 tools/Makefile
1466 doc/Makefile
1467 tests/Makefile
1468 tests/openpgp/Makefile
1469 tests/pkits/Makefile
1470 ])
1471 AC_OUTPUT
1472
1473
1474 echo "
1475         GnuPG v${VERSION} has been configured as follows:
1476         
1477         Platform:  $PRINTABLE_OS_NAME ($host)
1478
1479         OpenPGP:   $build_gpg
1480         S/MIME:    $build_gpgsm
1481         Agent:     $build_agent $build_agent_threaded
1482         Smartcard: $build_scdaemon $build_scdaemon_extra
1483
1484         Protect tool:      $show_gnupg_protect_tool_pgm
1485         Default agent:     $show_gnupg_agent_pgm
1486         Default pinentry:  $show_gnupg_pinentry_pgm
1487         Default scdaemon:  $show_gnupg_scdaemon_pgm
1488         Default dirmngr:   $show_gnupg_dirmngr_pgm
1489 "
1490 if test x"$use_regex" != xyes ; then
1491 echo "
1492         Warning: No regular expression support available.
1493                  OpenPGP trust signatures won't work.
1494                  gpg-check-pattern will not be build.
1495 "
1496 fi