A whole bunch of changes to allow building for Windows.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.0
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005,
3 #               2006, 2007 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 2 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, write to the Free Software
19 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301,
20 # USA.
21
22 # Process this file with autoconf to produce a configure script.
23 AC_PREREQ(2.61)
24 min_automake_version="1.10"
25
26 # Remember to change the version number immediately *after* a release.
27 # Set my_issvn to "yes" for non-released code.  Remember to run an
28 # "svn up" and "autogen.sh" right before creating a distribution.
29 m4_define([my_version], [2.0.5])
30 m4_define([my_issvn], [yes])
31
32
33 m4_define([svn_revision], m4_esyscmd([echo -n $( (svn info 2>/dev/null \
34             || echo 'Revision: 0')|sed -n '/^Revision:/ {s/[^0-9]//gp;q;}')]))
35 AC_INIT([gnupg], my_version[]m4_if(my_issvn,[yes],[-svn[]svn_revision]),
36         [bug-gnupg@gnupg.org])
37 # Set development_version to yes if the minor number is odd or you
38 # feel that the default check for a development version is not
39 # sufficient.
40 development_version=no
41
42 NEED_GPG_ERROR_VERSION=1.4
43
44 NEED_LIBGCRYPT_API=1
45 NEED_LIBGCRYPT_VERSION=1.2.2
46
47 NEED_LIBASSUAN_API=1
48 NEED_LIBASSUAN_VERSION=0.9.3
49
50 NEED_KSBA_API=1
51 NEED_KSBA_VERSION=1.0.0
52
53
54 PACKAGE=$PACKAGE_NAME
55 PACKAGE_GT=${PACKAGE_NAME}2
56 VERSION=$PACKAGE_VERSION
57
58 AC_CONFIG_AUX_DIR(scripts)
59 AC_CONFIG_SRCDIR(sm/gpgsm.c)
60 AM_CONFIG_HEADER(config.h)
61 AC_CANONICAL_TARGET()
62 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
63 AB_INIT
64
65 AC_GNU_SOURCE
66
67 # Some status variables.
68 have_gpg_error=no
69 have_libgcrypt=no 
70 have_libassuan=no
71 have_ksba=no
72 have_pth=no
73 have_libusb=no
74
75 use_bzip2=yes
76 use_exec=yes
77 disable_keyserver_path=no
78
79
80 GNUPG_BUILD_PROGRAM(gpg, yes)
81 GNUPG_BUILD_PROGRAM(gpgsm, yes)
82 GNUPG_BUILD_PROGRAM(agent, yes)
83 GNUPG_BUILD_PROGRAM(scdaemon, yes)
84 GNUPG_BUILD_PROGRAM(tools, yes)
85 GNUPG_BUILD_PROGRAM(doc, yes)
86 GNUPG_BUILD_PROGRAM(symcryptrun, no)
87
88 AC_SUBST(PACKAGE)
89 AC_SUBST(PACKAGE_GT)
90 AC_SUBST(VERSION)
91 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
92 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
93                                 [Name of this package for gettext])
94 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
95 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
96                                         [Bug report address])
97 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
98                                        [Required version of Libgcrypt])
99 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
100                                        [Required version of Libksba])
101
102
103
104 # The default is to use the modules from this package and the few
105 # other packages in a standard place; i.e where this package gets
106 # installed.  With these options it is possible to override these
107 # ${prefix} depended values with fixed paths, which can't be replaced
108 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
109 AC_ARG_WITH(agent-pgm,
110     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
111           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
112 AC_SUBST(GNUPG_AGENT_PGM)
113 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
114 show_gnupg_agent_pgm="(default)"
115 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
116
117 AC_ARG_WITH(pinentry-pgm,
118     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
119           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
120 AC_SUBST(GNUPG_PINENTRY_PGM)
121 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
122 show_gnupg_pinentry_pgm="(default)"
123 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
124
125
126 AC_ARG_WITH(scdaemon-pgm,
127     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
128           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
129 AC_SUBST(GNUPG_SCDAEMON_PGM)
130 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
131 show_gnupg_scdaemon_pgm="(default)"
132 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
133
134
135 AC_ARG_WITH(dirmngr-pgm,
136     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
137           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
138 AC_SUBST(GNUPG_DIRMNGR_PGM)
139 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
140 show_gnupg_dirmngr_pgm="(default)"
141 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
142
143 AC_ARG_WITH(protect-tool-pgm,
144     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
145           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
146 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
147 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
148 show_gnupg_protect_tool_pgm="(default)"
149 test -n "$GNUPG_PROTECT_TOOL_PGM" \
150       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
151
152
153 # Some folks want to use only the agent from this packet.  Make it
154 # easier for them by providing the configure option
155 # --enable-only-agent.
156 AC_ARG_ENABLE(agent-only,
157     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
158     build_agent_only=$enableval)
159
160 # SELinux support includes tracking of sensitive files to avoid
161 # leaking their contents through processing these files by gpg itself
162 AC_MSG_CHECKING([whether SELinux support is requested])
163 AC_ARG_ENABLE(selinux-support,
164               AC_HELP_STRING([--enable-selinux-support],
165                              [enable SELinux support]),
166               selinux_support=$enableval, selinux_support=no)
167 AC_MSG_RESULT($selinux_support)
168
169 # Allow disabling of bzib2 support.
170 # It is defined only after we confirm the library is available later
171 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
172 AC_ARG_ENABLE(bzip2,
173    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
174    use_bzip2=$enableval)
175 AC_MSG_RESULT($use_bzip2)
176
177
178 # Configure option to allow or disallow execution of external
179 # programs, like a photo viewer.
180 AC_MSG_CHECKING([whether to enable external program execution])
181 AC_ARG_ENABLE(exec,
182     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
183     use_exec=$enableval)
184 AC_MSG_RESULT($use_exec)
185 if test "$use_exec" = no ; then
186     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
187 fi
188
189 if test "$use_exec" = yes ; then
190   AC_MSG_CHECKING([whether to enable photo ID viewing])
191   AC_ARG_ENABLE(photo-viewers,
192       [  --disable-photo-viewers disable photo ID viewers],
193       [if test "$enableval" = no ; then
194          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
195       fi],enableval=yes)
196   gnupg_cv_enable_photo_viewers=$enableval
197   AC_MSG_RESULT($enableval)
198
199   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
200     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
201     AC_ARG_WITH(photo-viewer,
202         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
203         [if test "$withval" = yes ; then
204            withval=no
205         elif test "$withval" != no ; then
206            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
207                             [if set, restrict photo-viewer to this])
208         fi],withval=no)
209     AC_MSG_RESULT($withval)
210   fi
211
212   AC_MSG_CHECKING([whether to enable external keyserver helpers])
213   AC_ARG_ENABLE(keyserver-helpers,
214       [  --disable-keyserver-helpers  disable all external keyserver support],
215       [if test "$enableval" = no ; then
216          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
217                   [define to disable keyserver helpers])
218       fi],enableval=yes)
219   gnupg_cv_enable_keyserver_helpers=$enableval
220   AC_MSG_RESULT($enableval)
221
222   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
223     # LDAP is defined only after we confirm the library is available later
224     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
225     AC_ARG_ENABLE(ldap,
226       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
227       try_ldap=$enableval, try_ldap=yes)
228     AC_MSG_RESULT($try_ldap)
229
230     AC_MSG_CHECKING([whether HKP keyserver support is requested])
231     AC_ARG_ENABLE(hkp,
232       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
233       try_hkp=$enableval, try_hkp=yes)
234     AC_MSG_RESULT($try_hkp)
235
236     AC_MSG_CHECKING([whether finger key fetching support is requested])
237     AC_ARG_ENABLE(finger,
238       AC_HELP_STRING([--disable-finger],
239         [disable finger key fetching interface only]),
240       try_finger=$enableval, try_finger=yes)
241     AC_MSG_RESULT($try_finger)
242
243     AC_MSG_CHECKING([whether generic object key fetching support is requested])
244     AC_ARG_ENABLE(generic,
245       AC_HELP_STRING([--disable-generic],
246         [disable generic object key fetching interface only]),
247       try_generic=$enableval, try_generic=yes)
248     AC_MSG_RESULT($try_generic)
249
250     AC_MSG_CHECKING([whether email keyserver support is requested])
251     AC_ARG_ENABLE(mailto,
252       AC_HELP_STRING([--enable-mailto],
253         [enable email keyserver interface only]),
254       try_mailto=$enableval, try_mailto=no)
255     AC_MSG_RESULT($try_mailto)
256     fi
257
258     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
259     AC_ARG_ENABLE(keyserver-path,
260       AC_HELP_STRING([--disable-keyserver-path],
261         [disable the exec-path option for keyserver helpers]),
262       [if test "$enableval" = no ; then
263          disable_keyserver_path=yes
264       fi],enableval=yes)
265     AC_MSG_RESULT($enableval)
266   fi
267
268
269 #
270 # Check for the key/uid cache size.  This can't be zero, but can be
271 # pretty small on embedded systems.  This is used for the gpg part.
272 #
273 AC_MSG_CHECKING([for the size of the key and uid cache])
274 AC_ARG_ENABLE(key-cache,
275         AC_HELP_STRING([--enable-key-cache=SIZE],
276                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
277 if test "$enableval" = "no"; then
278    enableval=5
279 elif test "$enableval" = "yes" || test "$enableval" = ""; then
280    enableval=4096
281 fi
282 changequote(,)dnl
283 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
284 changequote([,])dnl
285 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
286    AC_MSG_ERROR([invalid key-cache size])
287 fi
288 AC_MSG_RESULT($key_cache_size)
289 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
290                   [Size of the key and UID caches])
291
292
293
294 #
295 # Check whether we want to use Linux capabilities
296 #
297 AC_MSG_CHECKING([whether use of capabilities is requested])
298 AC_ARG_WITH(capabilities,
299     [  --with-capabilities     use linux capabilities [default=no]],
300 [use_capabilities="$withval"],[use_capabilities=no])
301 AC_MSG_RESULT($use_capabilities)
302
303 #
304 # To avoid double inclusion of config.h which might happen at some
305 # places, we add the usual double inclusion protection at the top of
306 # config.h.
307 #
308 AH_TOP([
309 #ifndef GNUPG_CONFIG_H_INCLUDED
310 #define GNUPG_CONFIG_H_INCLUDED
311 ])
312
313 #
314 # Stuff which goes at the bottom of config.h.
315 #
316 AH_BOTTOM([
317 /* This is the major version number of GnuPG so that
318    source included files can test for this.  Note, that
319    we use 2 here even for GnuPG 1.9.x. */
320 #define GNUPG_MAJOR_VERSION 2
321
322 /* Now to separate file name parts.
323    Please note that the string version must not contain more
324    than one character because the code assumes strlen()==1 */
325 #ifdef HAVE_DOSISH_SYSTEM
326 #define DIRSEP_C '\\'
327 #define DIRSEP_S "\\"
328 #define EXTSEP_C '.'
329 #define EXTSEP_S "."
330 #define PATHSEP_C ';'
331 #define PATHSEP_S ";"
332 #define EXEEXT_S ".exe"
333 #else
334 #define DIRSEP_C '/'
335 #define DIRSEP_S "/"
336 #define EXTSEP_C '.'
337 #define EXTSEP_S "."
338 #define PATHSEP_C ':'
339 #define PATHSEP_S ":"
340 #define EXEEXT_S ""
341 #endif
342
343 /* This is the same as VERSION, but should be overridden if the
344    platform cannot handle things like dots '.' in filenames. Set
345    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
346    uses for dots and dashes. */
347 #define SAFE_VERSION VERSION
348 #define SAFE_VERSION_DOT  '.'
349 #define SAFE_VERSION_DASH '-'
350
351 /* Some global constants. */
352 #ifdef HAVE_DRIVE_LETTERS
353 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
354 #elif defined(__VMS)
355 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg" 
356 #else
357 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
358 #endif 
359 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
360
361 /* For some systems (DOS currently), we hardcode the path here.  For
362    POSIX systems the values are constructed by the Makefiles, so that
363    the values may be overridden by the make invocations; this is to
364    comply with the GNU coding standards. */
365 #ifdef HAVE_DRIVE_LETTERS
366  /* FIXME: We need to use a function to determine these values depending 
367     on the actual installation directory. */
368 #define GNUPG_BINDIR      "c:\\gnupg"
369 #define GNUPG_LIBEXECDIR  "c:\\gnupg"
370 #define GNUPG_LIBDIR      "c:\\gnupg"
371 #define GNUPG_DATADIR     "c:\\gnupg"
372 #define GNUPG_SYSCONFDIR  "c:\\gnupg"
373 #endif
374
375 /* Derive some other constants. */
376 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
377 #define EXEC_TEMPFILE_ONLY
378 #endif
379
380
381 /* We didn't define endianness above, so get it from OS macros.  This
382    is intended for making fat binary builds on OS X. */
383 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
384 #if defined(__BIG_ENDIAN__)
385 #define BIG_ENDIAN_HOST 1
386 #elif defined(__LITTLE_ENDIAN__)
387 #define LITTLE_ENDIAN_HOST 1
388 #else
389 #error "No endianness found"
390 #endif
391 #endif
392
393
394 /* Tell libgcrypt not to use its own libgpg-error implementation. */
395 #define USE_LIBGPG_ERROR 1
396
397 /* We use jnlib, so tell other modules about it.  */
398 #define HAVE_JNLIB_LOGGING 1
399
400 /* Our HTTP code is used in estream mode.  */
401 #define HTTP_USE_ESTREAM 1
402
403 /* Under W32 we do an explicit socket initialization, thus we need to
404    avoid the on-demand initialization which would also install an atexit
405    handler.  */
406 #define HTTP_NO_WSASTARTUP
407
408 /* We always include support for the OpenPGP card.  */
409 #define ENABLE_CARD_SUPPORT 1
410
411 /* We don't want the old assuan codes anymore. */
412 #define _ASSUAN_ONLY_GPG_ERRORS 1
413
414 /* We explicitly need to disable PTH's soft mapping as Debian
415    currently enables it by default for no reason. */
416 #define PTH_SYSCALL_SOFT 0
417
418 /* We want to use the libgcrypt provided memory allocation for
419    asprintf.  */
420 #define _ESTREAM_PRINTF_MALLOC        gcry_malloc
421 #define _ESTREAM_PRINTF_FREE          gcry_free
422 #define _ESTREAM_PRINTF_EXTRA_INCLUDE "util.h"
423
424 #endif /*GNUPG_CONFIG_H_INCLUDED*/
425 ])
426
427
428 AM_MAINTAINER_MODE
429
430 # Checks for programs.
431 AC_MSG_NOTICE([checking for programs])
432 AC_PROG_MAKE_SET
433 AM_SANITY_CHECK
434 missing_dir=`cd $ac_aux_dir && pwd`
435 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
436 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
437 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
438 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
439 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
440 AC_PROG_AWK
441 AC_PROG_CC
442 AC_PROG_CPP
443 AM_PROG_CC_C_O
444 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
445   AC_MSG_ERROR([[No C-89 compiler found]])
446 fi
447 AC_PROG_INSTALL
448 AC_PROG_LN_S
449 AC_PROG_RANLIB
450 AC_CHECK_TOOL(AR, ar, :)
451 AC_PATH_PROG(PERL,"perl")
452 AC_CHECK_TOOL(WINDRES, windres, :)
453 AC_ISC_POSIX
454 gl_EARLY
455 AC_SYS_LARGEFILE
456 GNUPG_CHECK_FAQPROG
457 GNUPG_CHECK_USTAR
458
459 # We need to compile and run a program on the build machine.  A
460 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
461 # the AC archive is broken for autoconf 2.57.  Given that tehre is no
462 # newer version of that macro, we assume that it is also broken for
463 # autoconf 2.61 and thus we use a simple but usually sufficient
464 # approach.
465 AC_MSG_CHECKING(for cc for build)
466 if test "$cross_compiling" = "yes"; then
467   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
468 else
469   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
470 fi
471 AC_MSG_RESULT($CC_FOR_BUILD)
472 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
473
474
475
476 try_gettext=yes
477 have_dosish_system=no
478 have_w32_system=no
479 use_simple_gettext=no
480 case "${host}" in
481     *-mingw32*)
482         # special stuff for Windoze NT
483         ac_cv_have_dev_random=no
484         AC_DEFINE(USE_ONLY_8DOT3,1,
485                   [set this to limit filenames to the 8.3 format])
486         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
487                   [defined if we must run on a stupid file system])
488         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
489                   [because the Unix gettext has too much overhead on
490                    MingW32 systems and these systems lack Posix functions,
491                    we use a simplified version of gettext])
492         disable_keyserver_path=yes
493         have_dosish_system=yes
494         have_w32_system=yes
495         try_gettext="no"
496         use_simple_gettext=yes
497         ;;
498     i?86-emx-os2 | i?86-*-os2*emx )
499         # OS/2 with the EMX environment
500         ac_cv_have_dev_random=no
501         AC_DEFINE(HAVE_DRIVE_LETTERS)
502         have_dosish_system=yes
503         try_gettext="no"
504         ;;
505
506     i?86-*-msdosdjgpp*)
507         # DOS with the DJGPP environment
508         ac_cv_have_dev_random=no
509         AC_DEFINE(HAVE_DRIVE_LETTERS)
510         have_dosish_system=yes
511         try_gettext="no"
512         ;;
513
514     *-*-freebsd*)
515        # FreeBSD
516        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
517        LDFLAGS="$LDFLAGS -L/usr/local/lib"
518        ;;
519
520     *-*-hpux*)
521         if test -z "$GCC" ; then
522             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
523         fi
524         ;;
525     *-dec-osf4*)
526         if test -z "$GCC" ; then
527             # Suppress all warnings
528             # to get rid of the unsigned/signed char mismatch warnings.
529             CFLAGS="$CFLAGS -w"
530         fi
531         ;;
532     *-dec-osf5*)
533         if test -z "$GCC" ; then
534             # Use the newer compiler `-msg_disable ptrmismatch1' to
535             # get rid of the unsigned/signed char mismatch warnings.
536             # Using this may hide other pointer mismatch warnings, but
537             # it at least lets other warning classes through
538             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
539         fi
540         ;;
541     m68k-atari-mint)
542         ;;
543     *)
544        ;;
545 esac
546
547 if test "$have_dosish_system" = yes; then
548    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
549              [Defined if we run on some of the PCDOS like systems 
550               (DOS, Windoze. OS/2) with special properties like
551               no file modes])
552 fi
553 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
554
555 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
556
557 if test "$have_w32_system" = yes; then
558    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
559 fi
560 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
561
562 if test "$disable_keyserver_path" = yes; then
563     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
564               [Defined to disable exec-path for keyserver helpers])
565 fi
566
567 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
568 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
569
570 if test x"$try_hkp" = xyes ; then
571   AC_SUBST(GPGKEYS_HKP,"gpg2keys_hkp$EXEEXT")
572 fi
573
574 if test x"$try_finger" = xyes ; then
575   AC_SUBST(GPGKEYS_FINGER,"gpg2keys_finger$EXEEXT")
576 fi
577
578
579
580 #
581 # Checks for libraries.
582 #
583 AC_MSG_NOTICE([checking for libraries])
584
585
586 #
587 # libgpg-error is a library with error codes shared between GnuPG
588 # related projects.
589 #
590 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
591                   have_gpg_error=yes,have_gpg_error=no)
592
593
594 #
595 # Libgcrypt is our generic crypto library
596 #
597 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
598         have_libgcrypt=yes,have_libgcrypt=no)
599
600
601 #
602 # libassuan is used for IPC
603 #
604 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
605                   have_libassuan=yes,have_libassuan=no)
606 if test "$have_libassuan" = "yes"; then
607   have_libassuan=no
608   AM_PATH_LIBASSUAN_PTH("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
609                         have_libassuan=yes,have_libassuan=no)
610   AM_CHECK_LIBASSUAN("$NEED_LIBASSUAN_API:1.0.1",
611        [AC_DEFINE(HAVE_ASSUAN_SET_IO_MONITOR, 1,
612          [Define to 1 if you have the `assuan_set_io_monitor' function.])],)  
613 fi
614
615
616
617 #
618 # libksba is our X.509 support library
619 #
620 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
621
622
623 #
624 # libusb allows us to use the integrated CCID smartcard reader driver.
625 #
626 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
627 AC_CHECK_LIB(usb, usb_bulk_write,
628               [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
629                 AC_DEFINE(HAVE_LIBUSB,1,
630                          [defined if libusb is available])
631                 have_libusb=yes
632              ])
633 AC_SUBST(LIBUSB_LIBS)
634 AC_CHECK_FUNCS(usb_create_match)
635
636 #
637 # Check wether it is necessary to link against libdl.
638 #
639 gnupg_dlopen_save_libs="$LIBS"
640 LIBS=""
641 AC_SEARCH_LIBS(dlopen, c dl,,,)
642 DL_LIBS=$LIBS
643 AC_SUBST(DL_LIBS)
644 LIBS="$gnupg_dlopen_save_libs"
645
646 #
647 # Checks for symcryptrun:
648 #
649
650 # libutil has openpty() and login_tty().
651 AC_CHECK_LIB(util, openpty,
652               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
653                 AC_DEFINE(HAVE_LIBUTIL,1,
654                          [defined if libutil is available])
655              ])
656 AC_SUBST(LIBUTIL_LIBS)
657
658 # shred is used to clean temporary plain text files.
659 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
660 AC_DEFINE_UNQUOTED(SHRED,
661         "${SHRED}", [defines the filename of the shred program])
662
663
664
665 #
666 # Check whether the GNU Pth library is available
667 # Note, that we include a Pth emulation for W32.
668 #
669 GNUPG_PATH_PTH
670 if test "$have_pth" = "yes"; then
671   AC_DEFINE(USE_GNU_PTH, 1,
672               [Defined if the GNU Portable Thread Library should be used])
673 else
674   AC_MSG_WARN([[
675 ***
676 *** To support concurrent access to the gpg-agent and the SCdaemon
677 *** we need the support of the GNU Portable Threads Library.
678 *** Download it from ftp://ftp.gnu.org/gnu/pth/
679 *** On a Debian GNU/Linux system you might want to try 
680 ***   apt-get install libpth-dev
681 ***]])
682 fi
683
684
685 AC_MSG_NOTICE([checking for networking options])
686
687 #
688 # Must check for network library requirements before doing link tests
689 # for ldap, for example. If ldap libs are static (or dynamic and without
690 # ELF runtime link paths), then link will fail and LDAP support won't
691 # be detected.
692 #
693 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
694         [NETLIBS="-lnsl $NETLIBS"]))
695 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
696         [NETLIBS="-lsocket $NETLIBS"]))
697
698 #
699 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
700 #
701 if test x"$try_hkp" = xyes || test x"$try_http" = xyes ; then
702   AC_ARG_ENABLE(dns-srv,
703      AC_HELP_STRING([--disable-dns-srv],
704                     [disable the use of DNS SRV in HKP and HTTP]),
705                 use_dns_srv=$enableval,use_dns_srv=yes)
706 fi
707
708 AC_ARG_ENABLE(dns-pka,
709    AC_HELP_STRING([--disable-dns-pka],
710         [disable the use of PKA records in DNS]),
711    use_dns_pka=$enableval,use_dns_pka=yes)
712
713 AC_ARG_ENABLE(dns-cert,
714    AC_HELP_STRING([--disable-dns-cert],
715         [disable the use of CERT records in DNS]),
716    use_dns_cert=$enableval,use_dns_cert=yes)
717
718 if test x"$use_dns_pka" = xyes || test x"$use_dns_srv" = xyes \
719    || test x"$use_dns_cert" = xyes; then
720   _dns_save_libs=$LIBS
721   LIBS=""
722   # the double underscore thing is a glibc-ism?
723   AC_SEARCH_LIBS(res_query,resolv bind,,
724                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
725   AC_SEARCH_LIBS(dn_expand,resolv bind,,
726                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
727   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
728                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
729
730   if test x"$have_resolver" != xno ; then
731
732     # Make sure that the BIND 4 resolver interface is workable before
733     # enabling any code that calls it.  At some point I'll rewrite the
734     # code to use the BIND 8 resolver API.
735
736     AC_MSG_CHECKING([whether the resolver is usable])
737     AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
738 #include <netinet/in.h>
739 #include <arpa/nameser.h>
740 #include <resolv.h>],
741 [[unsigned char answer[PACKETSZ];
742   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
743   dn_skipname(0,0); 
744   dn_expand(0,0,0,0,0);
745 ]])],have_resolver=yes,have_resolver=no)
746     AC_MSG_RESULT($have_resolver)
747
748     # This is Apple-specific and somewhat bizarre as they changed the
749     # define in bind 8 for some reason.
750
751     if test x"$have_resolver" != xyes ; then
752        AC_MSG_CHECKING(
753              [whether I can make the resolver usable with BIND_8_COMPAT])
754        AC_LINK_IFELSE([AC_LANG_PROGRAM([#define BIND_8_COMPAT
755 #include <sys/types.h>
756 #include <netinet/in.h>
757 #include <arpa/nameser.h>
758 #include <resolv.h>],
759 [[unsigned char answer[PACKETSZ];
760   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
761   dn_skipname(0,0); dn_expand(0,0,0,0,0);
762 ]])],[have_resolver=yes ; need_compat=yes])
763        AC_MSG_RESULT($have_resolver)
764     fi
765   fi
766
767   if test x"$have_resolver" = xyes ; then
768      DNSLIBS=$LIBS
769
770      if test x"$use_dns_srv" = xyes ; then
771         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
772      fi
773
774      if test x"$use_dns_pka" = xyes ; then
775         AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
776      fi
777
778      if test x"$use_dns_cert" = xyes ; then
779         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
780      fi
781
782      if test x"$need_compat" = xyes ; then
783         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
784      fi
785   else
786      use_dns_srv=no
787      use_dns_pka=no
788      use_dns_cert=no
789   fi
790
791   LIBS=$_dns_save_libs
792 fi
793
794 AC_SUBST(DNSLIBS)
795
796 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
797
798 #
799 # Check for LDAP
800 #
801 if test "$try_ldap" = yes ; then
802    GNUPG_CHECK_LDAP($NETLIBS)
803 fi
804
805 #
806 # Check for curl.  We fake the curl API if libcurl isn't installed.
807 #
808 LIBCURL_CHECK_CONFIG([yes],,,[fake_curl=yes])
809 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
810
811 # Generic, for us, means curl
812
813 if test x"$try_generic" = xyes ; then
814    AC_SUBST(GPGKEYS_CURL,"gpg2keys_curl$EXEEXT")
815 fi
816
817 #
818 # Check for sendmail
819 #
820 # This isn't necessarily sendmail itself, but anything that gives a
821 # sendmail-ish interface to the outside world.  That includes Exim,
822 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
823 if test "$try_mailto" = yes ; then
824   AC_ARG_WITH(mailprog,
825       AC_HELP_STRING([--with-mailprog=NAME],
826                      [use "NAME -t" for mail transport]),
827              ,with_mailprog=yes)
828
829   if test x"$with_mailprog" = xyes ; then
830     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
831     if test "$ac_cv_path_SENDMAIL" ; then
832       GPGKEYS_MAILTO="gpg2keys_mailto"
833     fi
834   elif test x"$with_mailprog" != xno ; then
835     AC_MSG_CHECKING([for a mail transport program])
836     AC_SUBST(SENDMAIL,$with_mailprog)
837     AC_MSG_RESULT($with_mailprog)
838     GPGKEYS_MAILTO="gpg2keys_mailto"
839   fi
840 fi
841
842 AC_SUBST(GPGKEYS_MAILTO)
843
844 #
845 # Construct a printable name of the OS
846 #
847 case "${host}" in
848     *-mingw32*)
849         PRINTABLE_OS_NAME="MingW32"
850         ;;
851     *-*-cygwin*)
852         PRINTABLE_OS_NAME="Cygwin"
853         ;;
854     i?86-emx-os2 | i?86-*-os2*emx )
855         PRINTABLE_OS_NAME="OS/2"
856         ;;
857     i?86-*-msdosdjgpp*)
858         PRINTABLE_OS_NAME="MSDOS/DJGPP"
859         try_dynload=no
860         ;;
861     *-linux*)
862         PRINTABLE_OS_NAME="GNU/Linux"
863         ;;
864     *)
865         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
866         ;;
867 esac
868 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
869                    [A human readable text with the name of the OS])
870
871
872 #
873 # Check for gettext
874 #
875 AC_MSG_NOTICE([checking for gettext])
876 AM_GNU_GETTEXT_VERSION([0.16.1])
877 if test "$try_gettext" = yes; then
878   AM_GNU_GETTEXT(,[need-ngettext])
879
880   # gettext requires some extra checks.  These really should be part of
881   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
882   # function checks to here.
883
884   AC_CHECK_FUNCS(strchr)
885 else
886   USE_NLS=no
887   USE_INCLUDED_LIBINTL=no
888   BUILD_INCLUDED_LIBINTL=no
889   AC_SUBST(USE_NLS)
890   AC_SUBST(USE_INCLUDED_LIBINTL)
891   AC_SUBST(BUILD_INCLUDED_LIBINTL)
892 fi
893
894
895 #
896 # SELinux support
897 #
898 if test "$selinux_support" = yes ; then
899   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
900 fi
901
902
903 #
904 # Checks for header files.
905 #
906 AC_MSG_NOTICE([checking for header files])
907 AC_HEADER_STDC
908 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h])
909 AC_CHECK_HEADERS([pty.h pwd.h inttypes.h])
910 AC_HEADER_TIME
911
912
913 #
914 # Checks for typedefs, structures, and compiler characteristics.
915 #
916 AC_MSG_NOTICE([checking for system characteristics])
917 AC_C_CONST
918 AC_C_INLINE
919 AC_C_VOLATILE
920 AC_TYPE_SIZE_T
921 AC_TYPE_MODE_T
922 AC_TYPE_SIGNAL
923 AC_DECL_SYS_SIGLIST
924
925 AC_ARG_ENABLE(endian-check,
926               AC_HELP_STRING([--disable-endian-check],
927               [disable the endian check and trust the OS provided macros]),
928               endiancheck=$enableval,endiancheck=yes)
929
930 if test x"$endiancheck" = xyes ; then
931   GNUPG_CHECK_ENDIAN
932 fi
933
934 # fixme: we should get rid of the byte type
935 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
936 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
937 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
938 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
939 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
940
941 AC_CHECK_SIZEOF(unsigned short)
942 AC_CHECK_SIZEOF(unsigned int)
943 AC_CHECK_SIZEOF(unsigned long)
944 AC_CHECK_SIZEOF(unsigned long long)
945 AC_CHECK_SIZEOF(time_t,,[[
946 #include <stdio.h>
947 #if TIME_WITH_SYS_TIME
948 # include <sys/time.h>
949 # include <time.h>
950 #else
951 # if HAVE_SYS_TIME_H
952 #  include <sys/time.h>
953 # else
954 #  include <time.h>
955 # endif
956 #endif
957 ]])
958
959
960 # Ensure that we have UINT64_C before we bother to check for uint64_t
961 # Fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
962 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
963    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
964        uint64_t foo=UINT64_C(42);]),
965      gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
966 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
967    AC_CHECK_SIZEOF(uint64_t)
968 fi
969
970 if test "$ac_cv_sizeof_unsigned_short" = "0" \
971    || test "$ac_cv_sizeof_unsigned_int" = "0" \
972    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
973     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
974 fi
975
976
977 #
978 # Checks for library functions.
979 #
980 AC_MSG_NOTICE([checking for library functions])
981 AC_CHECK_DECLS(getpagesize)
982 AC_FUNC_FSEEKO
983 AC_FUNC_VPRINTF
984 AC_FUNC_FORK
985 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap])
986 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r])
987 AC_CHECK_FUNCS([unsetenv getpwnam getpwuid fcntl ftruncate])
988 AC_CHECK_FUNCS([gettimeofday getrusage setrlimit clock_gettime])
989 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
990 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe stat getaddrinfo])
991 AC_CHECK_FUNCS([ttyname rand ftello])
992
993 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
994
995 #
996 # These are needed by libjnlib - fixme: we should use a jnlib.m4
997 #
998 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol])
999 AC_CHECK_FUNCS([memrchr isascii timegm getrusage setrlimit stat setlocale])
1000 AC_CHECK_FUNCS([flockfile funlockfile fopencookie funopen])
1001
1002 #
1003 # gnulib checks
1004 #
1005 gl_SOURCE_BASE([gl])
1006 gl_M4_BASE([gl/m4])
1007 gl_MODULES([setenv mkdtemp xsize strpbrk])
1008 gl_INIT
1009
1010
1011 #
1012 # W32 specific test
1013 #
1014 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1015
1016
1017 #
1018 # Sanity check regex.  Tests adapted from mutt.
1019 # FIXME: We should use the the regex from gnulib
1020 #
1021 AC_MSG_CHECKING([whether regular expression support is requested])
1022 AC_ARG_ENABLE(regex,
1023   AC_HELP_STRING([--disable-regex],
1024     [do not handle regular expressions in trust signatures]),
1025   use_regex=$enableval, use_regex=yes)
1026 AC_MSG_RESULT($use_regex)
1027
1028 if test "$use_regex" = yes ; then
1029   AC_MSG_CHECKING([whether the included regex lib is requested])
1030   AC_ARG_WITH(included-regex,
1031       [  --with-included-regex   use the included GNU regex library],
1032       [gnupg_cv_included_regex="$withval"],[gnupg_cv_included_regex=no])
1033   AC_MSG_RESULT($gnupg_cv_included_regex)
1034
1035   if test $gnupg_cv_included_regex = no ; then
1036      # Does the system have regex functions at all?
1037      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
1038                            gnupg_cv_included_regex=yes)
1039   fi
1040
1041   if test $gnupg_cv_included_regex = no ; then
1042      AC_CACHE_CHECK([whether your system's regexp library is broken],
1043        [gnupg_cv_regex_broken],
1044        AC_TRY_RUN([
1045 #include <unistd.h>
1046 #include <regex.h>
1047 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1048        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1049
1050      if test $gnupg_cv_regex_broken = yes ; then
1051       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
1052       gnupg_cv_included_regex=yes
1053      fi
1054   fi
1055
1056   if test $gnupg_cv_included_regex = yes; then
1057      AC_DEFINE(USE_INTERNAL_REGEX,1,[ Define if you want to use the included regex lib ])
1058   fi
1059 else
1060   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
1061 fi
1062
1063 AM_CONDITIONAL(USE_INTERNAL_REGEX, test x"$gnupg_cv_included_regex" = xyes)
1064
1065
1066
1067 #
1068 # Do we have zlib? Must do it here because Solaris failed
1069 # when compiling a conftest (due to the "-lz" from LIBS).
1070 # Note that we combine zlib and bzlib2 in ZLIBS.
1071 #
1072 _cppflags="${CPPFLAGS}"
1073 _ldflags="${LDFLAGS}"
1074 AC_ARG_WITH(zlib,
1075   [  --with-zlib=DIR         use libz in DIR],[
1076     if test -d "$withval"; then
1077       CPPFLAGS="${CPPFLAGS} -I$withval/include"
1078       LDFLAGS="${LDFLAGS} -L$withval/lib"
1079     fi
1080   ])
1081
1082 AC_CHECK_HEADER(zlib.h,
1083       AC_CHECK_LIB(z, deflateInit2_,
1084        ZLIBS="-lz",
1085        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1086        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1087
1088 #
1089 # Check whether we can support bzip2
1090
1091 if test "$use_bzip2" = yes ; then
1092   _cppflags="${CPPFLAGS}"
1093   _ldflags="${LDFLAGS}"
1094   AC_ARG_WITH(bzip2,
1095      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1096       [
1097       if test -d "$withval" ; then
1098         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1099         LDFLAGS="${LDFLAGS} -L$withval/lib"
1100       fi
1101       ],withval="")
1102
1103   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1104   # required stdio.h to be included before bzlib.h, and Solaris 9 is 
1105   # woefully out of date.
1106   if test "$withval" != no ; then
1107      AC_CHECK_HEADER(bzlib.h,
1108         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1109           [
1110           have_bz2=yes
1111           ZLIBS="$ZLIBS -lbz2"
1112           AC_DEFINE(HAVE_BZIP2,1,
1113                   [Defined if the bz2 compression library is available])
1114           ],
1115           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1116           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1117   fi
1118 fi
1119 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1120 AC_SUBST(ZLIBS)
1121
1122
1123 # Check for readline support
1124 GNUPG_CHECK_READLINE
1125
1126 # See wether we want to run the long test suite.
1127 AC_ARG_WITH(pkits-tests,
1128     AC_HELP_STRING([--with-pkits-tests],[run the PKITS based tests]),
1129     [run_pkits_tests=$withval], [run_pkits_tests=no])
1130 AM_CONDITIONAL(RUN_PKITS_TESTS, test "$run_pkits_tests" = "yes")
1131
1132 #
1133 # Allow users to append something to the version string without
1134 # flagging it as development version.  The user version parts is
1135 # considered everything after a dash. 
1136 #
1137 if test "$development_version" != yes; then
1138   changequote(,)dnl
1139   tmp_pat='[a-zA-Z]'
1140   changequote([,])dnl
1141   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1142     development_version=yes
1143   fi
1144 fi
1145 if test "$development_version" = yes; then
1146     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1147             [Defined if this is not a regular release])
1148 fi
1149
1150 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1151
1152 GNUPG_CHECK_GNUMAKE
1153
1154 # Add some extra libs here so that previous tests don't fail for
1155 # mysterious reasons - the final link step should bail out. 
1156 if test "$have_w32_system" = yes; then
1157    NETLIBS="${NETLIBS} -lwsock32"
1158 fi
1159
1160 AC_SUBST(NETLIBS)
1161
1162
1163 #
1164 # Setup gcc specific options
1165 #
1166 AC_MSG_NOTICE([checking for cc features])
1167 if test "$GCC" = yes; then
1168     # Note that it is okay to use CFLAGS here because this are just
1169     # warning options and the user should have a chance of overriding
1170     # them.
1171     if test "$USE_MAINTAINER_MODE" = "yes"; then
1172         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1173         CFLAGS="$CFLAGS -Wformat -Wno-format-y2k -Wformat-security"
1174     else
1175         CFLAGS="$CFLAGS -Wall"
1176     fi
1177
1178     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1179     _gcc_cflags_save=$CFLAGS
1180     CFLAGS="-Wno-pointer-sign"
1181     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1182     AC_MSG_RESULT($_gcc_psign)
1183     CFLAGS=$_gcc_cflags_save;
1184     if test x"$_gcc_psign" = xyes ; then
1185        CFLAGS="$CFLAGS -Wno-pointer-sign"
1186     fi
1187
1188     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1189     _gcc_cflags_save=$CFLAGS
1190     CFLAGS="-Wpointer-arith"
1191     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1192     AC_MSG_RESULT($_gcc_psign)
1193     CFLAGS=$_gcc_cflags_save;
1194     if test x"$_gcc_psign" = xyes ; then
1195        CFLAGS="$CFLAGS -Wpointer-arith"
1196     fi
1197 fi
1198
1199
1200 #
1201 # This is handy for debugging so the compiler doesn't rearrange
1202 # things and eliminate variables.
1203 #
1204 AC_ARG_ENABLE(optimization,
1205    AC_HELP_STRING([--disable-optimization],
1206                   [disable compiler optimization]),
1207                   [if test $enableval = no ; then
1208                       CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]]//'`
1209                    fi])
1210
1211 #
1212 # Prepare building of estream
1213 #
1214 estream_INIT
1215
1216
1217 #
1218 # Decide what to build
1219 #
1220 missing_pth=no
1221 if test $have_ksba = no; then
1222   build_gpgsm=no
1223   build_scdaemon=no
1224 fi
1225
1226 build_agent_threaded=""
1227 if test "$build_agent" = "yes"; then
1228   if test $have_pth = no; then
1229      build_agent_threaded="(not multi-threaded)"
1230      missing_pth=yes
1231   fi
1232 fi
1233
1234 build_scdaemon_extra=""
1235 if test "$build_scdaemon" = "yes"; then
1236   tmp=""
1237   if test $have_pth = no; then
1238      build_scdaemon_extra="not multi-threaded"
1239      tmp=", "
1240      missing_pth=yes
1241   fi
1242   if test $have_libusb = no; then
1243      build_scdaemon_extra="${tmp}without internal CCID driver"
1244      tmp=", "
1245   fi
1246   if test -n "$build_scdaemon_extra"; then
1247      build_scdaemon_extra="(${build_scdaemon_extra})"
1248   fi
1249 fi
1250
1251
1252 if test "$build_agent_only" = "yes" ; then
1253   build_gpg=no
1254   build_gpgsm=no
1255   build_scdaemon=no
1256   build_tools=no
1257   build_doc=no
1258 fi
1259
1260
1261 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1262 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1263 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1264 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1265 AM_CONDITIONAL(BUILD_TOOLS, test "$build_tools" = "yes")
1266 AM_CONDITIONAL(BUILD_DOC,   test "$build_doc" = "yes")
1267 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1268
1269 AM_CONDITIONAL(RUN_GPG_TESTS,
1270         test x$cross_compiling = xno -a "$build_gpg" = yes )
1271
1272
1273 #
1274 # Print errors here so that they are visible all
1275 # together and the user can acquire them all together.
1276 #
1277 die=no
1278 if test "$have_gpg_error" = "no"; then
1279    die=yes
1280    AC_MSG_NOTICE([[
1281 ***  
1282 *** You need libgpg-error to build this program.
1283 **  This library is for example available at
1284 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1285 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1286 ***]])
1287 fi
1288 if test "$have_libgcrypt" = "no"; then
1289    die=yes
1290    AC_MSG_NOTICE([[
1291 ***  
1292 *** You need libgcrypt to build this program.
1293 **  This library is for example available at
1294 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1295 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API is required.)
1296 ***]])
1297 fi
1298 if test "$have_libassuan" = "no"; then
1299    die=yes
1300    AC_MSG_NOTICE([[
1301 ***
1302 *** You need libassuan with Pth support to build this program.
1303 *** This library is for example available at
1304 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1305 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1306 ***]])
1307 fi
1308 if test "$have_ksba" = "no"; then
1309     AC_MSG_NOTICE([[
1310 ***
1311 *** You need libksba to build this program.
1312 *** This library is for example available at
1313 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1314 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1315 ***]])
1316 fi
1317 if test "$missing_pth" = "yes"; then
1318     AC_MSG_NOTICE([[
1319 ***
1320 *** It is now required to build with support for the
1321 *** GNU Portable Threads Library (Pth). Please install this
1322 *** library first.  The library is for example available at
1323 ***   ftp://ftp.gnu.org/gnu/pth/
1324 *** On a Debian GNU/Linux system you can install it using 
1325 ***   apt-get install libpth-dev
1326 *** To build GnuPG for Windows you need to use the W32PTH
1327 *** package; available at:
1328 ***   ftp://ftp.g10code.com/g10code/w32pth/
1329 ***]])
1330    die=yes
1331 fi
1332
1333 if test "$die" = "yes"; then
1334     AC_MSG_ERROR([[
1335 ***
1336 *** Required libraries not found. Please consult the above messages
1337 *** and install them before running configure again.
1338 ***]])
1339 fi
1340
1341
1342
1343 AC_CONFIG_FILES([ m4/Makefile 
1344 Makefile
1345 po/Makefile.in
1346 intl/Makefile
1347 gl/Makefile
1348 include/Makefile
1349 jnlib/Makefile
1350 common/Makefile
1351 kbx/Makefile
1352 g10/Makefile
1353 sm/Makefile
1354 agent/Makefile
1355 scd/Makefile
1356 keyserver/Makefile
1357 keyserver/gpg2keys_mailto
1358 keyserver/gpg2keys_test
1359 tools/gpg-zip
1360 tools/Makefile
1361 doc/Makefile
1362 tests/Makefile
1363 tests/openpgp/Makefile
1364 ])
1365 AC_OUTPUT
1366
1367 #tests/pkits/Makefile
1368
1369
1370
1371
1372 echo "
1373         GnuPG v${VERSION} has been configured as follows:
1374         
1375         Platform:  $PRINTABLE_OS_NAME ($host)
1376
1377         OpenPGP:   $build_gpg
1378         S/MIME:    $build_gpgsm
1379         Agent:     $build_agent $build_agent_threaded
1380         Smartcard: $build_scdaemon $build_scdaemon_extra
1381
1382         Protect tool:      $show_gnupg_protect_tool_pgm
1383         Default agent:     $show_gnupg_agent_pgm
1384         Default pinentry:  $show_gnupg_pinentry_pgm
1385         Default scdaemon:  $show_gnupg_scdaemon_pgm
1386         Default dirmngr:   $show_gnupg_dirmngr_pgm
1387
1388         PKITS based tests: $run_pkits_tests
1389 "
1390