Fix various build warnings reported by Joe Vender on MinGW.
[gnupg.git] / configure.ac
1 dnl configure.ac script for GnuPG
2 dnl Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004,
3 dnl               2005 Free Software Foundation, Inc.
4 dnl
5 dnl This file is part of GnuPG.
6 dnl
7 dnl GnuPG is free software; you can redistribute it and/or modify
8 dnl it under the terms of the GNU General Public License as published by
9 dnl the Free Software Foundation; either version 2 of the License, or
10 dnl (at your option) any later version.
11 dnl 
12 dnl GnuPG is distributed in the hope that it will be useful,
13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 dnl GNU General Public License for more details.
16 dnl 
17 dnl You should have received a copy of the GNU General Public License
18 dnl along with this program; if not, write to the Free Software
19 dnl Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, 
20 dnl MA 02110-1301, USA
21 dnl
22 dnl (Process this file with autoconf to produce a configure script.)
23
24 AC_PREREQ(2.59)
25 min_automake_version="1.9.3"
26
27 # Remember to change the version number immediately *after* a release
28 # and remove the "-cvs" or "rc" suffix immediately *before* a release.
29 AC_INIT(gnupg, 1.4.3-cvs, bug-gnupg@gnu.org)
30 # Set development_version to yes if the minor number is odd or you
31 # feel that the default check for a development version is not
32 # sufficient.
33 development_version=no
34
35 AC_CONFIG_AUX_DIR(scripts)
36 AC_CONFIG_SRCDIR(g10/gpg.c)
37 AC_CANONICAL_HOST
38 AM_INIT_AUTOMAKE([std-options])
39 AM_CONFIG_HEADER(config.h)
40
41 AC_GNU_SOURCE
42
43 dnl
44 dnl  Check for random module options
45 dnl
46 AC_MSG_CHECKING([which random module to use])
47 AC_ARG_ENABLE(static-rnd,
48     [  --enable-static-rnd=[egd|unix|linux|auto]  ],
49 [use_static_rnd=$enableval], [use_static_rnd=default] )
50
51 if test "$use_static_rnd" = no; then
52     use_static_rnd=default
53 fi
54
55 case "$use_static_rnd" in
56     egd | linux | unix | default )
57       AC_MSG_RESULT($use_static_rnd)
58       ;;
59     auto )
60       AC_MSG_RESULT(automagically selected at runtime)
61       ;;
62     * )
63       AC_MSG_RESULT(invalid argument)
64       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
65       ;;
66 esac
67
68 AC_ARG_WITH(egd-socket,
69     [  --with-egd-socket=NAME  use NAME for the EGD socket],
70             egd_socket_name="$withval", egd_socket_name="" )
71 AC_DEFINE_UNQUOTED(EGD_SOCKET_NAME, "$egd_socket_name",
72                    [Define if you don't want the default EGD socket name.
73                     For details see cipher/rndegd.c])
74
75
76 dnl
77 dnl See whether the user wants to disable checking for /dev/random
78
79 AC_MSG_CHECKING([whether use of /dev/random is requested])
80 AC_ARG_ENABLE(dev-random,
81 [  --disable-dev-random    disable the use of dev random],
82     try_dev_random=$enableval, try_dev_random=yes)
83 AC_MSG_RESULT($try_dev_random)
84
85
86 dnl
87 dnl  Check other options
88 dnl
89
90 AC_MSG_CHECKING([whether assembler modules are requested])
91 AC_ARG_ENABLE(asm,
92 [  --disable-asm           do not use assembler modules],
93      try_asm_modules=$enableval, try_asm_modules=yes)
94 AC_MSG_RESULT($try_asm_modules)
95
96 AC_MSG_CHECKING([whether memory guard is requested])
97 AC_ARG_ENABLE(m-guard,
98     [  --enable-m-guard        enable memory guard facility],
99     use_m_guard=$enableval, use_m_guard=no)
100 AC_MSG_RESULT($use_m_guard)
101 if test "$use_m_guard" = yes ; then
102     AC_DEFINE(M_GUARD,1,[Define to use the (obsolete) malloc guarding feature])
103 fi
104
105 # We don't have a test to check whether as(1) knows about the
106 # non executable stack option.  Thus we provide an option to enable
107 # it.
108 AC_MSG_CHECKING([whether non excutable stack support is requested])
109 AC_ARG_ENABLE(noexecstack,
110               AC_HELP_STRING([--enable-noexecstack],
111                              [enable non executable stack support (gcc only)]),
112               noexecstack_support=$enableval, noexecstack_support=no)
113 AC_MSG_RESULT($noexecstack_support)
114
115 # SELinux support includes tracking of sensitive files to avoid
116 # leaking their contents through processing these files by gpg itself
117 AC_MSG_CHECKING([whether SELinux support is requested])
118 AC_ARG_ENABLE(selinux-support,
119               AC_HELP_STRING([--enable-selinux-support],
120                              [enable SELinux support]),
121               selinux_support=$enableval, selinux_support=no)
122 AC_MSG_RESULT($selinux_support)
123
124
125 AC_MSG_CHECKING([whether the new iconv based code is requested])
126 AC_ARG_ENABLE(gnupg-iconv,
127               AC_HELP_STRING([--disable-gnupg-iconv],
128                              [disable the new iconv code]),
129               gnupg_use_iconv=$enableval, gnupg_use_iconv=yes)
130 AC_MSG_RESULT($gnupg_use_iconv)
131
132 dnl See if we are disabling any algorithms or features for a smaller
133 dnl binary
134
135 try_extensions=no
136
137 use_rsa=yes
138 use_idea=yes
139 use_cast5=yes
140 use_blowfish=yes
141 use_aes=yes
142 use_twofish=yes
143 use_sha256=yes
144 use_sha512=yes
145 use_bzip2=yes
146 use_exec=yes
147 card_support=yes
148 agent_support=yes
149 disable_keyserver_path=no
150
151 AC_ARG_ENABLE(minimal,
152    AC_HELP_STRING([--enable-minimal],[build the smallest gpg binary possible]),
153    use_rsa=no
154    use_idea=no
155    use_cast5=no
156    use_blowfish=no
157    use_aes=no
158    use_twofish=no
159    use_sha256=no
160    use_sha512=no
161    use_bzip2=no
162    use_exec=no
163    card_support=no
164    agent_support=no)
165
166
167 AC_MSG_CHECKING([whether OpenPGP card support is requested])
168 AC_ARG_ENABLE(card-support,
169               AC_HELP_STRING([--disable-card-support],
170                              [disable OpenPGP card support]),
171               card_support=$enableval)
172 AC_MSG_RESULT($card_support)
173
174
175 # Note that we may later disable the agent support based on the platform.
176 AC_MSG_CHECKING([whether gpg-agent support is requested])
177 AC_ARG_ENABLE(agent-support,
178               AC_HELP_STRING([--disable-agent-support],
179                              [disable gpg-agent support]),
180               agent_support=$enableval)
181 AC_MSG_RESULT($agent_support)
182
183
184 AC_MSG_CHECKING([whether to enable the RSA public key algorithm])
185 AC_ARG_ENABLE(rsa,
186    AC_HELP_STRING([--disable-rsa],[disable the RSA public key algorithm]),
187    use_rsa=$enableval)
188 AC_MSG_RESULT($use_rsa)
189 if test x"$use_rsa" = xyes ; then
190    AC_DEFINE(USE_RSA,1,[Define to include the RSA public key algorithm])
191 fi
192
193 AC_MSG_CHECKING([whether to enable the IDEA cipher])
194 AC_ARG_ENABLE(idea,
195    AC_HELP_STRING([--disable-idea],[disable the IDEA cipher]),
196    use_idea=$enableval)
197 AC_MSG_RESULT($use_idea)
198 if test x"$use_idea" = xyes ; then
199    AC_DEFINE(USE_IDEA,1,[Define to include the IDEA cipher])
200
201 # We don't need idea but some people claim that they need it for
202 # research etc., so we allow to place an idea source code into the
203 # cipher directory and statically link it if available, otherwise we
204 # link to a stub.  We don't use AC_CHECK_FILE to avoid caching.
205
206    AC_MSG_CHECKING([for idea cipher module])
207    tmp=""
208    if test -f $srcdir/cipher/idea.c; then 
209       IDEA_O=idea.o
210       tmp=idea
211    else
212       IDEA_O=idea-stub.o
213       tmp=no
214       try_extensions=yes
215    fi
216    AC_SUBST(IDEA_O)
217    AC_MSG_RESULT($tmp)
218 fi
219
220 AC_MSG_CHECKING([whether to enable the CAST5 cipher])
221 AC_ARG_ENABLE(cast5,
222    AC_HELP_STRING([--disable-cast5],[disable the CAST5 cipher]),
223    use_cast5=$enableval)
224 AC_MSG_RESULT($use_cast5)
225 if test x"$use_cast5" = xyes ; then
226    AC_DEFINE(USE_CAST5,1,[Define to include the CAST5 cipher])
227 fi
228
229 AC_MSG_CHECKING([whether to enable the BLOWFISH cipher])
230 AC_ARG_ENABLE(blowfish,
231    AC_HELP_STRING([--disable-blowfish],[disable the BLOWFISH cipher]),
232    use_blowfish=$enableval)
233 AC_MSG_RESULT($use_blowfish)
234 if test x"$use_blowfish" = xyes ; then
235    AC_DEFINE(USE_BLOWFISH,1,[Define to include the BLOWFISH cipher])
236 fi
237
238 AC_MSG_CHECKING([whether to enable the AES ciphers])
239 AC_ARG_ENABLE(aes,
240    AC_HELP_STRING([--disable-aes],[disable the AES, AES192, and AES256 ciphers]),
241    use_aes=$enableval)
242 AC_MSG_RESULT($use_aes)
243 if test x"$use_aes" = xyes ; then
244    AC_DEFINE(USE_AES,1,[Define to include the AES, AES192, and AES256 ciphers])
245 fi
246
247 AC_MSG_CHECKING([whether to enable the TWOFISH cipher])
248 AC_ARG_ENABLE(twofish,
249    AC_HELP_STRING([--disable-twofish],[disable the TWOFISH cipher]),
250    use_twofish=$enableval)
251 AC_MSG_RESULT($use_twofish)
252 if test x"$use_twofish" = xyes ; then
253    AC_DEFINE(USE_TWOFISH,1,[Define to include the TWOFISH cipher])
254 fi
255
256 AC_MSG_CHECKING([whether to enable the SHA-256 digest])
257 AC_ARG_ENABLE(sha256,
258    AC_HELP_STRING([--disable-sha256],[disable the SHA-256 digest]),
259    use_sha256=$enableval)
260 AC_MSG_RESULT($use_sha256)
261 if test x"$use_sha256" = xyes ; then
262    AC_DEFINE(USE_SHA256,1,[Define to include the SHA-256 digest])
263 fi
264
265 dnl SHA512 is defined only after we confirm 64-bit support later
266 AC_MSG_CHECKING([whether to enable the SHA-384 and SHA-512 digests])
267 AC_ARG_ENABLE(sha512,
268    AC_HELP_STRING([--disable-sha512],[disable the SHA-384 and SHA-512 digests]),
269    use_sha512=$enableval)
270 AC_MSG_RESULT($use_sha512)
271
272 dnl BZLIB is defined only after we confirm the library is available later
273 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
274 AC_ARG_ENABLE(bzip2,
275    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
276    use_bzip2=$enableval)
277 AC_MSG_RESULT($use_bzip2)
278
279 AC_MSG_CHECKING([whether to enable external program execution])
280 AC_ARG_ENABLE(exec,
281     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
282     use_exec=$enableval)
283 AC_MSG_RESULT($use_exec)
284 if test "$use_exec" = no ; then
285     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
286 fi
287
288 if test "$use_exec" = yes ; then
289   AC_MSG_CHECKING([whether to enable photo ID viewing])
290   AC_ARG_ENABLE(photo-viewers,
291       [  --disable-photo-viewers disable photo ID viewers],
292       [if test "$enableval" = no ; then
293          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
294       fi],enableval=yes)
295   gnupg_cv_enable_photo_viewers=$enableval
296   AC_MSG_RESULT($enableval)
297
298   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
299     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
300     AC_ARG_WITH(photo-viewer,
301         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
302         [if test "$withval" = yes ; then
303            withval=no
304         elif test "$withval" != no ; then
305            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
306                             [if set, restrict photo-viewer to this])
307         fi],withval=no)
308     AC_MSG_RESULT($withval)
309   fi
310
311   AC_MSG_CHECKING([whether to enable external keyserver helpers])
312   AC_ARG_ENABLE(keyserver-helpers,
313       [  --disable-keyserver-helpers  disable all external keyserver support],
314       [if test "$enableval" = no ; then
315          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
316                   [define to disable keyserver helpers])
317       fi],enableval=yes)
318   gnupg_cv_enable_keyserver_helpers=$enableval
319   AC_MSG_RESULT($enableval)
320
321   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
322 dnl LDAP is defined only after we confirm the library is available later
323     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
324     AC_ARG_ENABLE(ldap,
325       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
326       try_ldap=$enableval, try_ldap=yes)
327     AC_MSG_RESULT($try_ldap)
328
329     AC_MSG_CHECKING([whether HKP keyserver support is requested])
330     AC_ARG_ENABLE(hkp,
331       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
332       try_hkp=$enableval, try_hkp=yes)
333     AC_MSG_RESULT($try_hkp)
334
335     AC_MSG_CHECKING([whether finger key fetching support is requested])
336     AC_ARG_ENABLE(finger,
337       AC_HELP_STRING([--disable-finger],
338         [disable finger key fetching interface only]),
339       try_finger=$enableval, try_finger=yes)
340     AC_MSG_RESULT($try_finger)
341
342     AC_MSG_CHECKING([whether email keyserver support is requested])
343     AC_ARG_ENABLE(mailto,
344       AC_HELP_STRING([--enable-mailto],
345         [enable email keyserver interface only]),
346       try_mailto=$enableval, try_mailto=no)
347     AC_MSG_RESULT($try_mailto)
348     fi
349
350     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
351     AC_ARG_ENABLE(keyserver-path,
352       AC_HELP_STRING([--disable-keyserver-path],
353         [disable the exec-path option for keyserver helpers]),
354       [if test "$enableval" = no ; then
355          disable_keyserver_path=yes
356       fi],enableval=yes)
357     AC_MSG_RESULT($enableval)
358   fi
359
360 AC_MSG_CHECKING([whether the included zlib is requested])
361 AC_ARG_WITH(included-zlib,
362     [  --with-included-zlib    use the zlib code included here],
363 [g10_force_zlib="$withval"], [g10_force_zlib=no] )
364 AC_MSG_RESULT($g10_force_zlib)
365
366 dnl
367 dnl Check for the key/uid cache size.  This can't be zero, but can be
368 dnl pretty small on embedded systems.
369 dnl
370 AC_MSG_CHECKING([for the size of the key and uid cache])
371 AC_ARG_ENABLE(key-cache,
372         AC_HELP_STRING([--enable-key-cache=SIZE],[Set key cache to SIZE (default 4096)]),,enableval=4096)
373
374 if test "$enableval" = "no"; then
375    enableval=5
376 elif test "$enableval" = "yes" || test "$enableval" = ""; then
377    enableval=4096
378 fi
379
380 changequote(,)dnl
381 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
382 changequote([,])dnl
383
384 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
385    AC_MSG_ERROR([invalid key-cache size])
386 fi
387
388 AC_MSG_RESULT($key_cache_size)
389 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,[Size of the key and UID caches])
390
391 dnl
392 dnl Check whether we want to use Linux capabilities
393 dnl
394 AC_MSG_CHECKING([whether use of capabilities is requested])
395 AC_ARG_WITH(capabilities,
396     [  --with-capabilities     use linux capabilities [default=no]],
397 [use_capabilities="$withval"],[use_capabilities=no])
398 AC_MSG_RESULT($use_capabilities)
399
400 # To avoid double inclusion of config.h which might happen at some
401 # places, we add the usual double inclusion protection.
402 AH_TOP([
403 #ifndef GNUPG_CONFIG_H_INCLUDED
404 #define GNUPG_CONFIG_H_INCLUDED
405 ])
406
407 AH_BOTTOM([
408 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
409 #define EXEC_TEMPFILE_ONLY
410 #endif
411
412 /* This is the major version number of GnuPG so that
413    source included files can test for this. */
414 #define GNUPG_MAJOR_VERSION 1
415
416 #include "g10defs.h"
417
418 #endif /*GNUPG_CONFIG_H_INCLUDED*/
419 ])
420
421 AM_MAINTAINER_MODE
422
423 dnl Checks for programs.
424
425 AC_PROG_MAKE_SET
426 AM_SANITY_CHECK
427 missing_dir=`cd $ac_aux_dir && pwd`
428 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
429 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
430 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
431 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
432 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
433 AC_PROG_CC
434 AC_PROG_CPP
435 AC_PROG_RANLIB
436 AC_CHECK_TOOL(AR, ar, :)
437 AC_PATH_PROG(PERL,"perl")
438 AC_ISC_POSIX
439 AC_SYS_LARGEFILE
440 AC_PROG_INSTALL
441 AC_PROG_AWK
442 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
443 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
444 GNUPG_CHECK_FAQPROG
445 GNUPG_CHECK_DOCBOOK_TO_TEXI
446 GNUPG_CHECK_USTAR
447
448 MPI_OPT_FLAGS=""
449
450 try_gettext=yes
451 have_dosish_system=no
452 need_dlopen=yes
453 case "${host}" in
454     *-mingw32*)
455         # special stuff for Windoze NT
456         ac_cv_have_dev_random=no
457         AC_DEFINE(USE_ONLY_8DOT3,1,
458                   [set this to limit filenames to the 8.3 format])
459         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
460                   [defined if we must run on a stupid file system])
461         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
462                   [because the Unix gettext has too much overhead on
463                    MingW32 systems and these systems lack Posix functions,
464                    we use a simplified version of gettext])
465         AC_DEFINE(HAVE_W32_SYSTEM,1,
466                   [Defined if we run on a W32 API based system])
467         disable_keyserver_path=yes
468         have_dosish_system=yes
469         need_dlopen=no
470         try_gettext="no"
471         agent_support=no
472         ;;
473     i?86-emx-os2 | i?86-*-os2*emx )
474         # OS/2 with the EMX environment
475         ac_cv_have_dev_random=no
476         AC_DEFINE(HAVE_DRIVE_LETTERS)
477         have_dosish_system=yes
478         try_gettext="no"
479         agent_support=no
480         ;;
481
482     i?86-*-msdosdjgpp*)
483         # DOS with the DJGPP environment
484         ac_cv_have_dev_random=no
485         AC_DEFINE(HAVE_DRIVE_LETTERS)
486         have_dosish_system=yes
487         try_gettext="no"
488         agent_support=no
489         ;;
490
491     *-*-hpux*)
492         if test -z "$GCC" ; then
493             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
494         fi
495         ;;
496     *-dec-osf4*)
497         if test -z "$GCC" ; then
498             # Suppress all warnings
499             # to get rid of the unsigned/signed char mismatch warnings.
500             CFLAGS="$CFLAGS -w"
501         fi
502         ;;
503     *-dec-osf5*)
504         if test -z "$GCC" ; then
505             # Use the newer compiler `-msg_disable ptrmismatch' to
506             # get rid of the unsigned/signed char mismatch warnings.
507             # Using this may hide other pointer mismatch warnings, but
508             # it at least lets other warning classes through
509             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
510         fi
511         ;;
512     m68k-atari-mint)
513         ;;
514     *)
515        ;;
516 esac
517
518 if test "$have_dosish_system" = yes; then
519    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
520              [defined if we run on some of the PCDOS like systems 
521               (DOS, Windoze. OS/2) with special properties like
522               no file modes])
523 fi
524 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
525
526 if test "$disable_keyserver_path" = yes; then
527     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
528               [define to disable exec-path for keyserver helpers])
529 fi
530
531 AC_SUBST(MPI_OPT_FLAGS)
532 GNUPG_SYS_SYMBOL_UNDERSCORE
533
534 dnl These need to go after AC_PROG_CC so that $EXEEXT is defined
535 if test x"$try_hkp" = xyes ; then
536   AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
537 fi
538
539 if test x"$try_finger" = xyes ; then
540   AC_SUBST(GPGKEYS_FINGER,"gpgkeys_finger$EXEEXT")
541 fi
542
543 dnl Must check for network library requirements before doing link tests
544 dnl for ldap, for example. If ldap libs are static (or dynamic and without
545 dnl ELF runtime link paths), then link will fail and LDAP support won't
546 dnl be detected.
547
548 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
549         [NETLIBS="-lnsl $NETLIBS"]))
550 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
551         [NETLIBS="-lsocket $NETLIBS"]))
552
553 dnl Now try for the resolver functions so we can use DNS SRV and our 
554 dnl PKA feature.
555
556 AC_ARG_ENABLE(dns-srv,
557    AC_HELP_STRING([--disable-dns-srv],
558         [disable the use of DNS SRV in HKP and HTTP]),
559    use_dns_srv=$enableval,use_dns_srv=yes)
560
561 if (test x"$try_hkp" = xyes || test x"$try_http" = xyes) && test x"$use_dns_srv" = xyes ; then
562   _srv_save_libs=$LIBS
563   LIBS=""
564   # the double underscore thing is a glibc-ism?
565   AC_SEARCH_LIBS(res_query,resolv bind,,
566                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
567   AC_SEARCH_LIBS(dn_expand,resolv bind,,
568                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
569   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
570                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
571
572   if test x"$use_dns_srv" = xyes ; then
573
574     # Make sure that the BIND 4 resolver interface is workable before
575     # enabling SRVs.  At some point I'll rewrite the code to use the
576     # BIND 8 resolver API.
577
578     AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
579 #include <netinet/in.h>
580 #include <arpa/nameser.h>
581 #include <resolv.h>],
582 [[unsigned char answer[PACKETSZ]; res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);]])],,use_dns_srv=no)
583   fi
584
585   if test x"$use_dns_srv" = xyes ; then
586      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
587      SRVLIBS=$LIBS
588      AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
589   fi
590
591   LIBS=$_srv_save_libs
592 fi
593
594 AC_SUBST(SRVLIBS)
595
596 # Check for LDAP
597
598 if test "$try_ldap" = yes ; then
599    GNUPG_CHECK_LDAP($NETLIBS)
600 fi
601
602 # Which keyserver helpers are we building?
603
604 AC_ARG_ENABLE(old-keyserver-helpers,
605    AC_HELP_STRING([--enable-old-keyserver-helpers],[enable old keyserver helpers]),old_ks=$enableval,old_ks=no)
606
607 if test "$old_ks" = yes ; then
608    AC_SUBST(GPGKEYS_HTTP,"gpgkeys_http$EXEEXT")
609 else
610    LIBCURL_CHECK_CONFIG([yes],,[with_curl=yes],[fake_curl=yes])
611    AC_SUBST(GPGKEYS_CURL,"gpgkeys_curl$EXEEXT")
612 fi
613
614 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
615 AM_CONDITIONAL(WITH_CURL,test x"$with_curl" = xyes || test x"$fake_curl" = xyes)
616
617 if test x"$fake_curl" = xyes ; then
618    AC_DEFINE(FAKE_CURL,1,[define to fake the libcurl API internally])
619 fi
620
621 dnl This isn't necessarily sendmail itself, but anything that gives a
622 dnl sendmail-ish interface to the outside world.  That includes qmail,
623 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
624
625 if test "$try_mailto" = yes ; then
626   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
627
628   if test "$with_mailprog" = yes ; then
629     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
630     if test "$ac_cv_path_SENDMAIL" ; then
631       GPGKEYS_MAILTO="gpgkeys_mailto"
632     fi
633   elif test "$with_mailprog" != no ; then
634     AC_MSG_CHECKING([for a mail transport program])
635     AC_SUBST(SENDMAIL,$with_mailprog)
636     AC_MSG_RESULT($with_mailprog)
637     GPGKEYS_MAILTO="gpgkeys_mailto"
638   fi
639 fi
640
641 AC_SUBST(GPGKEYS_MAILTO)
642
643 case "${host}" in
644     *-mingw32*)
645         PRINTABLE_OS_NAME="MingW32"
646         ;;
647     *-*-cygwin*)
648         PRINTABLE_OS_NAME="Cygwin"
649         ;;
650     i?86-emx-os2 | i?86-*-os2*emx )
651         PRINTABLE_OS_NAME="OS/2"
652         ;;
653     i?86-*-msdosdjgpp*)
654         PRINTABLE_OS_NAME="MSDOS/DJGPP"
655         try_extensions=no
656         ;;
657     *-linux*)
658         PRINTABLE_OS_NAME="GNU/Linux"
659         ;;
660     *)
661         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
662         ;;
663 esac
664 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
665                    [A human readable text with the name of the OS])
666
667
668 #
669 # 1. Set names of random devices
670 #
671 NAME_OF_DEV_RANDOM="/dev/random"
672 NAME_OF_DEV_URANDOM="/dev/urandom"
673 case "${host}" in
674     *-openbsd*)
675         NAME_OF_DEV_RANDOM="/dev/srandom"
676         NAME_OF_DEV_URANDOM="/dev/urandom"
677         ;;
678 esac
679 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM",
680                    [defined to the name of the strong random device])
681 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM",
682                    [defined to the name of the weaker random device])
683 AC_SUBST(MPI_OPT_FLAGS)
684
685
686 dnl Checks for libraries.
687
688 AM_GNU_GETTEXT_VERSION(0.14.1)
689 if test "$try_gettext" = yes; then
690   AM_GNU_GETTEXT(,[need-ngettext])
691
692   # gettext requires some extra checks.  These really should be part of
693   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
694   # function checks to here.
695
696   AC_CHECK_FUNCS(strchr)
697 else
698   USE_NLS=no
699   USE_INCLUDED_LIBINTL=no
700   BUILD_INCLUDED_LIBINTL=no
701   AC_SUBST(USE_NLS)
702   AC_SUBST(USE_INCLUDED_LIBINTL)
703   AC_SUBST(BUILD_INCLUDED_LIBINTL)
704   AM_PO_SUBDIRS
705 fi
706
707 if test "$try_extensions" = yes || test x"$card_support" = xyes ; then
708   if test "$need_dlopen" = yes; then
709     _dl_save_libs=$LIBS
710     LIBS=""
711     AC_SEARCH_LIBS(dlopen,dl,found_dlopen=yes)
712     if test x"$found_dlopen" = "xyes" ; then
713       AC_DEFINE(HAVE_DL_DLOPEN,1,
714                 [Defined when the dlopen function family is available])
715       DLLIBS=$LIBS
716     else
717       if test "$try_extensions" = yes ; then
718          AC_MSG_NOTICE([dlopen not found.  Disabling extensions.])
719          try_extensions=no
720       fi
721   
722       if test "$card_support" = yes ; then
723          AC_MSG_WARN([dlopen not found.  Disabling OpenPGP card support.])
724          card_support=no
725       fi
726     fi
727     LIBS=$_dl_save_libs
728   fi
729 fi
730
731 AC_SUBST(DLLIBS)
732
733 if test "$card_support" = yes ; then
734   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include OpenPGP card support])
735 fi
736
737 if test "$agent_support" = yes ; then
738   AC_DEFINE(ENABLE_AGENT_SUPPORT,1,[Define to include gpg-agent support])
739 fi
740
741 if test "$try_extensions" = yes ; then
742   AC_DEFINE(USE_DYNAMIC_LINKING,1,[Define to enable the use of extensions])
743 fi
744
745 if test "$selinux_support" = yes ; then
746   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
747 fi
748
749 if test "$gnupg_use_iconv" = yes ; then
750   AC_DEFINE(USE_GNUPG_ICONV,1,[Define to use the new iconv based code])
751 fi
752
753 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
754 AM_CONDITIONAL(ENABLE_AGENT_SUPPORT, test "$agent_support" = yes)
755
756 dnl Checks for header files.
757 AC_HEADER_STDC
758 AC_CHECK_HEADERS([unistd.h langinfo.h termio.h locale.h getopt.h pwd.h])
759
760 # Note that we do not check for iconv here because this is done anyway
761 # by the gettext checks and thus it allows us to disable the use of
762 # iconv by using --disable-nls.
763
764 dnl Checks for typedefs, structures, and compiler characteristics.
765 AC_C_CONST
766 AC_C_INLINE
767 AC_C_VOLATILE
768 AC_TYPE_SIZE_T
769 AC_TYPE_MODE_T
770 AC_TYPE_SIGNAL
771 AC_DECL_SYS_SIGLIST
772
773 GNUPG_CHECK_ENDIAN
774
775 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
776 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
777 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
778 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
779 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
780
781 AC_CHECK_SIZEOF(unsigned short)
782 AC_CHECK_SIZEOF(unsigned int)
783 AC_CHECK_SIZEOF(unsigned long)
784 AC_CHECK_SIZEOF(unsigned long long)
785
786 # Ensure that we have UINT64_C before we bother to check for uint64_t
787 gt_HEADER_INTTYPES_H
788 AC_CACHE_CHECK([for UINT64_C], [gnupg_cv_uint64_c_works],
789                AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
790 uint64_t foo=UINT64_C(42);]),gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
791
792 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
793    AC_CHECK_SIZEOF(uint64_t)
794 fi
795
796 if test "$ac_cv_sizeof_unsigned_short" = "0" \
797    || test "$ac_cv_sizeof_unsigned_int" = "0" \
798    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
799     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
800 fi
801
802 dnl Do we have any 64-bit data types?
803 if test "$ac_cv_sizeof_unsigned_int" != "8" \
804    && test "$ac_cv_sizeof_unsigned_long" != "8" \
805    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
806    && test x"$ac_cv_sizeof_uint64_t" != "x8"; then
807     AC_MSG_NOTICE([No 64-bit types.  Disabling SHA-384 and SHA-512.])
808 else
809   if test x"$use_sha512" = xyes ; then
810      AC_SUBST(SHA512_O,sha512.o)
811      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
812   fi
813 fi
814
815 dnl Checks for library functions.
816 AC_CHECK_DECLS(getpagesize)
817 AC_FUNC_FSEEKO
818 AC_FUNC_VPRINTF
819 AC_FUNC_FORK
820 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
821 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times unsetenv getpwnam getpwuid)
822 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
823 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
824 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat getaddrinfo)
825 AC_REPLACE_FUNCS(mkdtemp timegm isascii memrchr)
826
827 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
828
829 # See if getopt is in libiberty.  This is of course not optimal since
830 # it might be somewhere other than libiberty, but does cover the
831 # mingw32 case.
832
833 AC_CHECK_FUNC(getopt,,AC_CHECK_LIB(iberty,getopt,AC_SUBST(GETOPT,"-liberty")))
834
835 #
836 # check for gethrtime and run a testprogram to see whether
837 # it is broken.  It has been reported that some Solaris and HP UX systems 
838 # raise an SIGILL
839 #
840 AC_CACHE_CHECK([for gethrtime], 
841                [gnupg_cv_func_gethrtime],
842                [AC_TRY_LINK([#include <sys/times.h>],[
843                    hrtime_t tv;
844                    tv = gethrtime();
845                  ],
846                  [gnupg_cv_func_gethrtime=yes],
847                  [gnupg_cv_func_gethrtime=no])
848                ])
849 if test $gnupg_cv_func_gethrtime = yes; then
850      AC_DEFINE([HAVE_GETHRTIME], 1,
851                [Define if you have the `gethrtime(2)' function.])
852      AC_CACHE_CHECK([whether gethrtime is broken], 
853                [gnupg_cv_func_broken_gethrtime],
854                [AC_TRY_RUN([
855                    #include <sys/times.h>
856                    int main () {
857                    hrtime_t tv;
858                    tv = gethrtime(); 
859                  }
860                  ],
861                  [gnupg_cv_func_broken_gethrtime=no],
862                  [gnupg_cv_func_broken_gethrtime=yes],
863                  [gnupg_cv_func_broken_gethrtime=assume-no])
864                 ])
865     if test $gnupg_cv_func_broken_gethrtime = yes; then
866       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
867       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
868     fi
869 fi
870      
871
872 GNUPG_CHECK_MLOCK
873 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
874
875 dnl
876 dnl Check whether we can use Linux capabilities as requested
877 dnl
878 if test "$use_capabilities" = "yes" ; then
879
880 AC_MSG_WARN([[
881 ***
882 *** WARNING: using capabilities with GnuPG is experimental code!
883 ***]])
884
885 use_capabilities=no
886 AC_CHECK_HEADERS(sys/capability.h)
887 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
888   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
889   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
890      AC_DEFINE(USE_CAPABILITIES,1,
891                [define if capabilities should be used])
892      AC_SUBST(CAPLIBS,"-lcap")
893      use_capabilities=yes
894   fi
895 fi
896 if test "$use_capabilities" = "no" ; then
897     AC_MSG_WARN([[
898 ***
899 *** The use of capabilities on this system is not possible.
900 *** You need a recent Linux kernel and some patches:
901 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
902 ***   fcap-module-990613.tar.gz     (kernel module)
903 ***   libcap-1.92.tar.gz            (user mode library and utilities)
904 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
905 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
906 ***]])
907 fi
908 fi
909
910
911 GNUPG_CHECK_IPC
912 if test "$ac_cv_header_sys_shm_h" = "yes"; then
913   AC_DEFINE(USE_SHM_COPROCESSING,1,
914             [define if the shared memory interface should be made available])
915 fi
916
917 dnl
918 dnl check whether we have a random device
919 dnl
920 if test "$try_dev_random" = yes ; then
921     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
922     [if test -r "$NAME_OF_DEV_RANDOM" && test -r "$NAME_OF_DEV_URANDOM" ; then
923       ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
924     if test "$ac_cv_have_dev_random" = yes; then
925         AC_DEFINE(HAVE_DEV_RANDOM,1,
926                  [defined if the system supports a random device] )
927     fi
928 else
929     AC_MSG_CHECKING(for random device)
930     ac_cv_have_dev_random=no
931     AC_MSG_RESULT(has been disabled)
932 fi
933
934
935 dnl
936 dnl Figure out the default random module.
937 dnl
938 random_modules=""
939 if test "$use_static_rnd" = default; then
940      if test "$ac_cv_have_dev_random" = yes; then
941         random_modules="rndlinux"
942      else
943          case "${host}" in
944             *-mingw32*|*-*-cygwin*)
945                 random_modules="rndw32"
946                 ;;
947             i?86-emx-os2|i?86-*-os2*emx)
948                 random_modules="rndos2"
949                 ;;
950             m68k-atari-mint)
951                 random_modules="rndatari"
952                 ;;
953             i?86-*-msdosdjgpp*)
954                 :
955                 ;;
956             *)
957                 random_modules="rndlinux rndegd rndunix"
958                 AC_DEFINE(USE_ALL_RANDOM_MODULES, 1, 
959                           [Allow to select random modules at runtime.])
960                 ;;
961          esac
962      fi
963 else
964   if test "$use_static_rnd" = auto; then
965      random_modules="rndlinux rndegd rndunix"
966      AC_DEFINE(USE_ALL_RANDOM_MODULES, 1)
967   else
968      random_modules="rnd$use_static_rnd";
969   fi
970 fi
971
972 if test -z "$random_modules"; then
973    AC_MSG_ERROR(no random module available)
974 fi
975 print_egd_warning=no
976 for rndmod in $random_modules "" ; do
977   case "$rndmod" in
978     rndlinux)
979          AC_DEFINE(USE_RNDLINUX,1, 
980                   [Defined if the /dev/random based RNG should be used.])
981          ;;
982     rndunix)
983          AC_DEFINE(USE_RNDUNIX,1, 
984                   [Defined if the default Unix RNG should be used.])
985          print_egd_warning=yes
986           ;;
987     rndegd)
988          AC_DEFINE(USE_RNDEGD,1, 
989                   [Defined if the EGD based RNG should be used.])
990          ;;
991     rndw32)
992          AC_DEFINE(USE_RNDW32,1, 
993                   [Defined if the Windows specific RNG should be used.])
994         ;;
995    esac
996 done
997
998 dnl setup assembler stuff
999 AC_MSG_CHECKING(for mpi assembler functions)
1000 if test -f $srcdir/mpi/config.links ; then
1001     . $srcdir/mpi/config.links
1002     AC_CONFIG_LINKS("$mpi_ln_list")
1003     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
1004     ac_cv_mpi_sflags="$mpi_sflags"
1005     ac_cv_mpi_config_done="yes"
1006     AC_MSG_RESULT(done)
1007 else
1008     AC_MSG_RESULT(failed)
1009     AC_MSG_ERROR([mpi/config.links missing!])
1010 fi
1011 MPI_EXTRA_ASM_OBJS=""
1012 show_extraasm=""
1013 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
1014 for i in $ac_cv_mpi_extra_asm_modules; do
1015     show_extraasm="$show_extraasm $i"
1016     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
1017 done
1018 fi
1019 AC_SUBST(MPI_EXTRA_ASM_OBJS)
1020 MPI_SFLAGS="$ac_cv_mpi_sflags"
1021 AC_SUBST(MPI_SFLAGS)
1022
1023 # Sanity check regex.  Tests adapted from mutt.
1024
1025 AC_MSG_CHECKING([whether regular expression support is requested])
1026 AC_ARG_ENABLE(regex,
1027   AC_HELP_STRING([--disable-regex],
1028     [do not handle regular expressions in trust signatures]),
1029   use_regex=$enableval, use_regex=yes)
1030 AC_MSG_RESULT($use_regex)
1031
1032 if test "$use_regex" = yes ; then
1033   AC_MSG_CHECKING([whether the included regex lib is requested])
1034   AC_ARG_WITH(included-regex,
1035       [  --with-included-regex   use the included GNU regex library],
1036       [gnupg_cv_included_regex="$withval"],[gnupg_cv_included_regex=no])
1037   AC_MSG_RESULT($gnupg_cv_included_regex)
1038
1039   if test $gnupg_cv_included_regex = no ; then
1040      # Does the system have regex functions at all?
1041      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
1042                            gnupg_cv_included_regex=yes)
1043   fi
1044
1045   if test $gnupg_cv_included_regex = no ; then
1046      AC_CACHE_CHECK([whether your system's regexp library is broken],
1047        [gnupg_cv_regex_broken],
1048        AC_TRY_RUN([
1049 #include <unistd.h>
1050 #include <regex.h>
1051 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1052        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1053
1054      if test $gnupg_cv_regex_broken = yes ; then
1055       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
1056       gnupg_cv_included_regex=yes
1057      fi
1058   fi
1059
1060   if test $gnupg_cv_included_regex = yes; then
1061      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
1062      AC_SUBST(REGEX_O,regex.o)
1063   fi
1064 else
1065
1066   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
1067 fi
1068
1069 dnl Do we have zlib? Must do it here because Solaris failed
1070 dnl when compiling a conftest (due to the "-lz" from LIBS).
1071 use_local_zlib=yes
1072 if test "$g10_force_zlib" = "yes"; then
1073   :
1074 else
1075   _cppflags="${CPPFLAGS}"
1076   _ldflags="${LDFLAGS}"
1077
1078   AC_ARG_WITH(zlib,
1079   [  --with-zlib=DIR         use libz in DIR],[
1080     if test -d "$withval"; then
1081       CPPFLAGS="${CPPFLAGS} -I$withval/include"
1082       LDFLAGS="${LDFLAGS} -L$withval/lib"
1083     fi
1084   ])
1085
1086   AC_CHECK_HEADER(zlib.h,
1087       AC_CHECK_LIB(z, deflateInit2_,
1088        use_local_zlib=no
1089        ZLIBS="-lz",
1090        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1091        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1092 fi
1093
1094 if test "$use_local_zlib" = yes ; then
1095     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
1096     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
1097     ZLIBS="../zlib/libzlib.a"
1098 else
1099     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
1100 fi
1101
1102 if test "$use_bzip2" = yes ; then
1103   _cppflags="${CPPFLAGS}"
1104   _ldflags="${LDFLAGS}"
1105   AC_ARG_WITH(bzip2,
1106      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1107       [
1108       if test -d "$withval" ; then
1109         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1110         LDFLAGS="${LDFLAGS} -L$withval/lib"
1111       fi
1112       ],withval="")
1113
1114 # Checking alongside stdio.h as an early version of bzip2 (1.0)
1115 # required stdio.h to be included before bzlib.h, and Solaris 9 is
1116 # woefully out of date.
1117
1118   if test "$withval" != no ; then
1119      AC_CHECK_HEADER(bzlib.h,
1120         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1121           [
1122           have_bz2=yes
1123           ZLIBS="$ZLIBS -lbz2"
1124           AC_DEFINE(HAVE_BZIP2,1,
1125                   [Defined if the bz2 compression library is available])
1126           ],
1127           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1128           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1129   fi
1130 fi
1131
1132 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1133 AC_SUBST(ZLIBS)
1134
1135 # libusb allows us to use the integrated CCID smartcard reader driver.
1136 GNUPG_CHECK_LIBUSB
1137
1138 # Check for readline support
1139 GNUPG_CHECK_READLINE
1140
1141 # Allow users to append something to the version string without
1142 # flagging it as development version.  The user version parts is
1143 # considered everything after a dash. 
1144 if test "$development_version" != yes; then
1145   changequote(,)dnl
1146   tmp_pat='[a-zA-Z]'
1147   changequote([,])dnl
1148   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1149     development_version=yes
1150   fi
1151 fi
1152 if test "$development_version" = yes; then
1153     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1154             [Defined if this is not a regular release])
1155 fi
1156
1157 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1158
1159
1160 # add some extra libs here so that previous tests don't fail for
1161 # mysterious reasons - the final link step should bail out. 
1162 case "${host}" in
1163     *-mingw32*)
1164 dnl      NETLIBS="$NETLIBS -lwsock32"
1165         W32LIBS="-lwsock32"
1166         ;;
1167     *)
1168        ;;
1169 esac
1170
1171 AC_SUBST(NETLIBS)
1172 AC_SUBST(W32LIBS)
1173
1174 # Special options used with gcc.
1175 if test "$GCC" = yes; then
1176     # Note that it is okay to use CFLAGS here because this are just
1177     # warning options and the user should have a chance of overriding
1178     #them.
1179     if test "$USE_MAINTAINER_MODE" = "yes"; then
1180         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1181         CFLAGS="$CFLAGS -Wformat-nonliteral"
1182     else
1183         CFLAGS="$CFLAGS -Wall"
1184     fi
1185
1186     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1187
1188     _gcc_cflags_save=$CFLAGS
1189     CFLAGS="-Wno-pointer-sign"
1190
1191     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1192     AC_MSG_RESULT($_gcc_psign)
1193
1194     CFLAGS=$_gcc_cflags_save;
1195
1196     if test x"$_gcc_psign" = xyes ; then
1197        CFLAGS="$CFLAGS -Wno-pointer-sign"
1198     fi
1199
1200     # Non exec stack hack.  Fixme: Write a test to check whether as
1201     # can cope with it and use the enable-noexecstack option only to
1202     # disable it in case it is required on sime platforms.
1203     if test "$noexecstack_support" = yes; then
1204         NOEXECSTACK_FLAGS="-Wa,--noexecstack"
1205     fi
1206 fi
1207 AC_SUBST(NOEXECSTACK_FLAGS)
1208
1209
1210 if test "$print_egd_warning" = yes; then
1211   AC_MSG_WARN([[
1212 ***
1213 *** The performance of the UNIX random gatherer module is not very good
1214 *** and it does not keep the entropy pool over multiple invocations of
1215 *** GnuPG.  The suggested way to overcome this problem is to use the
1216 ***
1217 ***               Entropy Gathering Daemon (EGD)
1218 ***
1219 *** which provides a entropy source for the whole system.  It is written
1220 *** in Perl and available at the GnuPG FTP servers.  For more information
1221 *** consult the GnuPG webpages:
1222 ***
1223 ***           http://www.gnupg.org/download/#EGD
1224 ***
1225 *** You may want to run ./configure with --enable-static-rnd=egd or
1226 *** --enable-static-rnd=auto to use it.
1227 ***]])
1228 fi
1229
1230 # Note the \\\\ for backslashes.  Autoconf eats one layer, leaving \\
1231
1232 AC_CONFIG_COMMANDS(g10defs.h,[[
1233 cat >g10defs.tmp <<G10EOF
1234 /* Generated automatically by configure */
1235 #ifdef HAVE_DRIVE_LETTERS
1236 #define G10_LOCALEDIR     "c:\\\\lib\\\\gnupg\\\\locale"
1237 #define GNUPG_LIBDIR      "c:\\\\lib\\\\gnupg"
1238 #define GNUPG_LIBEXECDIR  "c:\\\\lib\\\\gnupg"
1239 #define GNUPG_DATADIR     "c:\\\\lib\\\\gnupg"
1240 #define GNUPG_HOMEDIR     "c:\\\\gnupg"
1241 #else
1242 #define G10_LOCALEDIR     "${datadir}/locale"
1243 #define GNUPG_LIBDIR      "${libdir}/gnupg"
1244 #define GNUPG_DATADIR     "${datadir}/gnupg"
1245 #ifdef __VMS
1246 #define GNUPG_HOMEDIR "/SYS\$LOGIN/gnupg" 
1247 #else
1248 #define GNUPG_HOMEDIR "~/.gnupg" 
1249 #endif
1250 #endif
1251 /* those are here to be redefined by handcrafted g10defs.h.
1252    Please note that the string version must not contain more
1253    than one character because the using code assumes strlen()==1 */
1254 #ifdef HAVE_DOSISH_SYSTEM
1255 #define DIRSEP_C '\\\\'
1256 #define EXTSEP_C '.'
1257 #define DIRSEP_S "\\\\"
1258 #define EXTSEP_S "."
1259 #define PATHSEP_C ';'
1260 #define PATHSEP_S ";"
1261 #else
1262 #define DIRSEP_C '/'
1263 #define EXTSEP_C '.'
1264 #define DIRSEP_S "/"
1265 #define EXTSEP_S "."
1266 #define PATHSEP_C ':'
1267 #define PATHSEP_S ":"
1268 #endif
1269 /* This is the same as VERSION, but should be overridden if the
1270    platform cannot handle things like dots'.' in filenames.  Set
1271    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
1272    uses for dots and dashes. */
1273 #define SAFE_VERSION      VERSION
1274 #define SAFE_VERSION_DOT  '.'
1275 #define SAFE_VERSION_DASH '-'
1276 G10EOF
1277 cat mpi/mpi-asm-defs.h >>g10defs.tmp 
1278 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
1279     echo "g10defs.h is unchanged"
1280     rm -f g10defs.tmp
1281 else
1282     rm -f g10defs.h
1283     mv g10defs.tmp g10defs.h
1284     echo "g10defs.h created"
1285 fi
1286 ]],[[
1287 prefix=$prefix
1288 exec_prefix=$exec_prefix
1289 libdir=$libdir
1290 libexecdir=$libexecdir
1291 datadir=$datadir
1292 DATADIRNAME=$DATADIRNAME
1293 ]])
1294
1295
1296 AC_CONFIG_FILES([
1297 Makefile
1298 m4/Makefile
1299 intl/Makefile
1300 po/Makefile.in
1301 util/Makefile
1302 mpi/Makefile
1303 cipher/Makefile
1304 g10/Makefile
1305 keyserver/Makefile
1306 keyserver/gpgkeys_mailto
1307 keyserver/gpgkeys_test
1308 doc/Makefile
1309 tools/Makefile
1310 tools/gpg-zip
1311 zlib/Makefile
1312 checks/Makefile
1313 ])
1314 AC_OUTPUT
1315
1316 # Give some feedback
1317 echo
1318 echo   "                Configured for: $PRINTABLE_OS_NAME ($host)"
1319 if test -n "$show_extraasm"; then
1320   echo "  Extra cpu specific functions:$show_extraasm"
1321 fi
1322 echo