Support a git revision string
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.0
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005,
3 #               2006, 2007, 2008, 2010 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.10"
23
24 # Remember to change the version number immediately *after* a release.
25 # Set my_issvn to "yes" for non-released code.  Remember to run an
26 # "svn up" and "autogen.sh" right before creating a distribution.
27 m4_define([my_version], [2.0.17])
28 m4_define([my_issvn], [yes])
29
30 m4_define([svn_revision], m4_esyscmd([printf "%d" $(svn info 2>/dev/null \
31           | sed -n '/^Revision:/ s/[^0-9]//gp'|head -1)]))
32 m4_define([git_revision], m4_esyscmd([git branch -v 2>/dev/null \
33           | awk '/^\* / {printf "%s",$3}']))
34 AC_INIT([gnupg], 
35         [my_version[]m4_if(my_issvn,[yes],
36         [m4_if(git_revision,[],[-svn[]svn_revision],[-git[]git_revision])])],
37         [http://bugs.gnupg.org])
38 # Set development_version to yes if the minor number is odd or you
39 # feel that the default check for a development version is not
40 # sufficient.
41 development_version=no
42
43 NEED_GPG_ERROR_VERSION=1.7
44
45 NEED_LIBGCRYPT_API=1
46 NEED_LIBGCRYPT_VERSION=1.4.0
47
48 NEED_LIBASSUAN_API=2
49 NEED_LIBASSUAN_VERSION=2.0.0
50
51 NEED_KSBA_API=1
52 NEED_KSBA_VERSION=1.0.7
53
54
55 PACKAGE=$PACKAGE_NAME
56 PACKAGE_GT=${PACKAGE_NAME}2
57 VERSION=$PACKAGE_VERSION
58
59 AC_CONFIG_AUX_DIR(scripts)
60 AC_CONFIG_SRCDIR(sm/gpgsm.c)
61 AM_CONFIG_HEADER(config.h)
62 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
63 AC_CANONICAL_HOST
64 AB_INIT
65
66 AC_GNU_SOURCE
67
68 # Some status variables.
69 have_gpg_error=no
70 have_libgcrypt=no 
71 have_libassuan=no
72 have_ksba=no
73 have_pth=no
74 have_libusb=no
75 have_adns=no
76
77 use_bzip2=yes
78 use_exec=yes
79 disable_keyserver_path=no
80 use_ccid_driver=yes
81 use_standard_socket=no
82
83 GNUPG_BUILD_PROGRAM(gpg, yes)
84 GNUPG_BUILD_PROGRAM(gpgsm, yes)
85 GNUPG_BUILD_PROGRAM(agent, yes)
86 GNUPG_BUILD_PROGRAM(scdaemon, yes)
87 GNUPG_BUILD_PROGRAM(tools, yes)
88 GNUPG_BUILD_PROGRAM(doc, yes)
89 GNUPG_BUILD_PROGRAM(symcryptrun, no)
90
91 AC_SUBST(PACKAGE)
92 AC_SUBST(PACKAGE_GT)
93 AC_SUBST(VERSION)
94 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
95 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
96                                 [Name of this package for gettext])
97 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
98 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
99                                         [Bug report address])
100 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
101                                        [Required version of Libgcrypt])
102 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
103                                        [Required version of Libksba])
104
105
106
107 # The default is to use the modules from this package and the few
108 # other packages in a standard place; i.e where this package gets
109 # installed.  With these options it is possible to override these
110 # ${prefix} depended values with fixed paths, which can't be replaced
111 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
112 AC_ARG_WITH(agent-pgm,
113     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
114           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
115 AC_SUBST(GNUPG_AGENT_PGM)
116 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
117 show_gnupg_agent_pgm="(default)"
118 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
119
120 AC_ARG_WITH(pinentry-pgm,
121     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
122           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
123 AC_SUBST(GNUPG_PINENTRY_PGM)
124 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
125 show_gnupg_pinentry_pgm="(default)"
126 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
127
128
129 AC_ARG_WITH(scdaemon-pgm,
130     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
131           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
132 AC_SUBST(GNUPG_SCDAEMON_PGM)
133 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
134 show_gnupg_scdaemon_pgm="(default)"
135 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
136
137
138 AC_ARG_WITH(dirmngr-pgm,
139     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
140           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
141 AC_SUBST(GNUPG_DIRMNGR_PGM)
142 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
143 show_gnupg_dirmngr_pgm="(default)"
144 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
145
146 AC_ARG_WITH(protect-tool-pgm,
147     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
148           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
149 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
150 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
151 show_gnupg_protect_tool_pgm="(default)"
152 test -n "$GNUPG_PROTECT_TOOL_PGM" \
153       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
154
155
156 # Some folks want to use only the agent from this packet.  Make it
157 # easier for them by providing the configure option
158 # --enable-only-agent.
159 AC_ARG_ENABLE(agent-only,
160     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
161     build_agent_only=$enableval)
162
163 # SELinux support includes tracking of sensitive files to avoid
164 # leaking their contents through processing these files by gpg itself
165 AC_MSG_CHECKING([whether SELinux support is requested])
166 AC_ARG_ENABLE(selinux-support,
167               AC_HELP_STRING([--enable-selinux-support],
168                              [enable SELinux support]),
169               selinux_support=$enableval, selinux_support=no)
170 AC_MSG_RESULT($selinux_support)
171
172 # Allow disabling of bzib2 support.
173 # It is defined only after we confirm the library is available later
174 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
175 AC_ARG_ENABLE(bzip2,
176    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
177    use_bzip2=$enableval)
178 AC_MSG_RESULT($use_bzip2)
179
180 # Configure option to allow or disallow execution of external
181 # programs, like a photo viewer.
182 AC_MSG_CHECKING([whether to enable external program execution])
183 AC_ARG_ENABLE(exec,
184     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
185     use_exec=$enableval)
186 AC_MSG_RESULT($use_exec)
187 if test "$use_exec" = no ; then
188     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
189 fi
190
191 if test "$use_exec" = yes ; then
192   AC_MSG_CHECKING([whether to enable photo ID viewing])
193   AC_ARG_ENABLE(photo-viewers,
194       [  --disable-photo-viewers disable photo ID viewers],
195       [if test "$enableval" = no ; then
196          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
197       fi],enableval=yes)
198   gnupg_cv_enable_photo_viewers=$enableval
199   AC_MSG_RESULT($enableval)
200
201   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
202     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
203     AC_ARG_WITH(photo-viewer,
204         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
205         [if test "$withval" = yes ; then
206            withval=no
207         elif test "$withval" != no ; then
208            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
209                             [if set, restrict photo-viewer to this])
210         fi],withval=no)
211     AC_MSG_RESULT($withval)
212   fi
213
214   AC_MSG_CHECKING([whether to enable external keyserver helpers])
215   AC_ARG_ENABLE(keyserver-helpers,
216       [  --disable-keyserver-helpers  disable all external keyserver support],
217       [if test "$enableval" = no ; then
218          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
219                   [define to disable keyserver helpers])
220       fi],enableval=yes)
221   gnupg_cv_enable_keyserver_helpers=$enableval
222   AC_MSG_RESULT($enableval)
223
224   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
225     # LDAP is defined only after we confirm the library is available later
226     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
227     AC_ARG_ENABLE(ldap,
228       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
229       try_ldap=$enableval, try_ldap=yes)
230     AC_MSG_RESULT($try_ldap)
231
232     AC_MSG_CHECKING([whether HKP keyserver support is requested])
233     AC_ARG_ENABLE(hkp,
234       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
235       try_hkp=$enableval, try_hkp=yes)
236     AC_MSG_RESULT($try_hkp)
237
238     AC_MSG_CHECKING([whether finger key fetching support is requested])
239     AC_ARG_ENABLE(finger,
240       AC_HELP_STRING([--disable-finger],
241         [disable finger key fetching interface only]),
242       try_finger=$enableval, try_finger=yes)
243     AC_MSG_RESULT($try_finger)
244
245     AC_MSG_CHECKING([whether generic object key fetching support is requested])
246     AC_ARG_ENABLE(generic,
247       AC_HELP_STRING([--disable-generic],
248         [disable generic object key fetching interface only]),
249       try_generic=$enableval, try_generic=yes)
250     AC_MSG_RESULT($try_generic)
251
252     AC_MSG_CHECKING([whether email keyserver support is requested])
253     AC_ARG_ENABLE(mailto,
254       AC_HELP_STRING([--enable-mailto],
255         [enable email keyserver interface only]),
256       try_mailto=$enableval, try_mailto=no)
257     AC_MSG_RESULT($try_mailto)
258   fi
259
260   AC_MSG_CHECKING([whether keyserver exec-path is enabled])
261   AC_ARG_ENABLE(keyserver-path,
262       AC_HELP_STRING([--disable-keyserver-path],
263            [disable the exec-path option for keyserver helpers]),
264            [if test "$enableval" = no ; then
265               disable_keyserver_path=yes
266            fi],enableval=yes)
267   AC_MSG_RESULT($enableval)
268 fi
269
270
271 #
272 # Check for the key/uid cache size.  This can't be zero, but can be
273 # pretty small on embedded systems.  This is used for the gpg part.
274 #
275 AC_MSG_CHECKING([for the size of the key and uid cache])
276 AC_ARG_ENABLE(key-cache,
277         AC_HELP_STRING([--enable-key-cache=SIZE],
278                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
279 if test "$enableval" = "no"; then
280    enableval=5
281 elif test "$enableval" = "yes" || test "$enableval" = ""; then
282    enableval=4096
283 fi
284 changequote(,)dnl
285 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
286 changequote([,])dnl
287 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
288    AC_MSG_ERROR([invalid key-cache size])
289 fi
290 AC_MSG_RESULT($key_cache_size)
291 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
292                   [Size of the key and UID caches])
293
294
295
296 #
297 # Check whether we want to use Linux capabilities
298 #
299 AC_MSG_CHECKING([whether use of capabilities is requested])
300 AC_ARG_WITH(capabilities,
301     [  --with-capabilities     use linux capabilities [default=no]],
302 [use_capabilities="$withval"],[use_capabilities=no])
303 AC_MSG_RESULT($use_capabilities)
304
305
306 #
307 # Allow disabling of internal CCID support.
308 # It is defined only after we confirm the library is available later
309 #
310 AC_MSG_CHECKING([whether to enable the internal CCID driver])
311 AC_ARG_ENABLE(ccid-driver,
312               AC_HELP_STRING([--disable-ccid-driver],
313                              [disable the internal CCID driver]),
314               use_ccid_driver=$enableval)
315 AC_MSG_RESULT($use_ccid_driver)
316
317
318 #
319 # To avoid double inclusion of config.h which might happen at some
320 # places, we add the usual double inclusion protection at the top of
321 # config.h.
322 #
323 AH_TOP([
324 #ifndef GNUPG_CONFIG_H_INCLUDED
325 #define GNUPG_CONFIG_H_INCLUDED
326 ])
327
328 #
329 # Stuff which goes at the bottom of config.h.
330 #
331 AH_BOTTOM([
332 /* This is the major version number of GnuPG so that
333    source included files can test for this.  Note, that
334    we use 2 here even for GnuPG 1.9.x. */
335 #define GNUPG_MAJOR_VERSION 2
336
337 /* Now to separate file name parts.
338    Please note that the string version must not contain more
339    than one character because the code assumes strlen()==1 */
340 #ifdef HAVE_DOSISH_SYSTEM
341 #define DIRSEP_C '\\'
342 #define DIRSEP_S "\\"
343 #define EXTSEP_C '.'
344 #define EXTSEP_S "."
345 #define PATHSEP_C ';'
346 #define PATHSEP_S ";"
347 #define EXEEXT_S ".exe"
348 #else
349 #define DIRSEP_C '/'
350 #define DIRSEP_S "/"
351 #define EXTSEP_C '.'
352 #define EXTSEP_S "."
353 #define PATHSEP_C ':'
354 #define PATHSEP_S ":"
355 #define EXEEXT_S ""
356 #endif
357
358 /* This is the same as VERSION, but should be overridden if the
359    platform cannot handle things like dots '.' in filenames. Set
360    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
361    uses for dots and dashes. */
362 #define SAFE_VERSION VERSION
363 #define SAFE_VERSION_DOT  '.'
364 #define SAFE_VERSION_DASH '-'
365
366 /* Some global constants. */
367 #ifdef HAVE_DRIVE_LETTERS
368 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
369 #elif defined(__VMS)
370 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg" 
371 #else
372 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
373 #endif 
374 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
375
376 /* For some systems (DOS currently), we hardcode the path here.  For
377    POSIX systems the values are constructed by the Makefiles, so that
378    the values may be overridden by the make invocations; this is to
379    comply with the GNU coding standards. */
380 #ifdef HAVE_DRIVE_LETTERS
381  /* FIXME: We need to use a function to determine these values depending 
382     on the actual installation directory. */
383 #define GNUPG_BINDIR      "c:\\gnupg"
384 #define GNUPG_LIBEXECDIR  "c:\\gnupg"
385 #define GNUPG_LIBDIR      "c:\\gnupg"
386 #define GNUPG_DATADIR     "c:\\gnupg"
387 #define GNUPG_SYSCONFDIR  "c:\\gnupg"
388 #endif
389
390 /* Derive some other constants. */
391 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
392 #define EXEC_TEMPFILE_ONLY
393 #endif
394
395
396 /* We didn't define endianness above, so get it from OS macros.  This
397    is intended for making fat binary builds on OS X. */
398 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
399 #if defined(__BIG_ENDIAN__)
400 #define BIG_ENDIAN_HOST 1
401 #elif defined(__LITTLE_ENDIAN__)
402 #define LITTLE_ENDIAN_HOST 1
403 #else
404 #error "No endianness found"
405 #endif
406 #endif
407
408
409 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
410    ldap_start_tls_s because that is the actual symbol used in the
411    library.  winldap.h redefines it to our commonly used value,
412    thus we define our usual macro here.  */
413 #ifdef HAVE_LDAP_START_TLS_SA
414 # ifndef HAVE_LDAP_START_TLS_S
415 #  define HAVE_LDAP_START_TLS_S 1
416 # endif
417 #endif
418
419
420 /* Tell libgcrypt not to use its own libgpg-error implementation. */
421 #define USE_LIBGPG_ERROR 1
422
423 /* We use jnlib, so tell other modules about it.  */
424 #define HAVE_JNLIB_LOGGING 1
425
426 /* Our HTTP code is used in estream mode.  */
427 #define HTTP_USE_ESTREAM 1
428
429 /* Under W32 we do an explicit socket initialization, thus we need to
430    avoid the on-demand initialization which would also install an atexit
431    handler.  */
432 #define HTTP_NO_WSASTARTUP
433
434 /* We always include support for the OpenPGP card.  */
435 #define ENABLE_CARD_SUPPORT 1
436
437 /* We don't want the old assuan codes anymore. */
438 #define _ASSUAN_ONLY_GPG_ERRORS 1
439
440 /* We explicitly need to disable PTH's soft mapping as Debian
441    currently enables it by default for no reason. */
442 #define PTH_SYSCALL_SOFT 0
443
444 /* We want to use the libgcrypt provided memory allocation for
445    asprintf.  */
446 #define _ESTREAM_PRINTF_MALLOC        gcry_malloc
447 #define _ESTREAM_PRINTF_FREE          gcry_free
448 #define _ESTREAM_PRINTF_EXTRA_INCLUDE "util.h"
449
450 #endif /*GNUPG_CONFIG_H_INCLUDED*/
451 ])
452
453
454 AM_MAINTAINER_MODE
455
456 # Checks for programs.
457 AC_MSG_NOTICE([checking for programs])
458 AC_PROG_MAKE_SET
459 AM_SANITY_CHECK
460 missing_dir=`cd $ac_aux_dir && pwd`
461 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
462 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
463 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
464 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
465 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
466 AC_PROG_AWK
467 AC_PROG_CC
468 AC_PROG_CPP
469 AM_PROG_CC_C_O
470 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
471   AC_MSG_ERROR([[No C-89 compiler found]])
472 fi
473 AC_PROG_INSTALL
474 AC_PROG_LN_S
475 AC_PROG_RANLIB
476 AC_CHECK_TOOL(AR, ar, :)
477 AC_PATH_PROG(PERL,"perl")
478 AC_CHECK_TOOL(WINDRES, windres, :)
479 AC_ISC_POSIX
480 gl_EARLY
481 AC_SYS_LARGEFILE
482 GNUPG_CHECK_FAQPROG
483 GNUPG_CHECK_USTAR
484
485 # We need to compile and run a program on the build machine.  A
486 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
487 # the AC archive is broken for autoconf 2.57.  Given that tehre is no
488 # newer version of that macro, we assume that it is also broken for
489 # autoconf 2.61 and thus we use a simple but usually sufficient
490 # approach.
491 AC_MSG_CHECKING(for cc for build)
492 if test "$cross_compiling" = "yes"; then
493   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
494 else
495   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
496 fi
497 AC_MSG_RESULT($CC_FOR_BUILD)
498 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
499
500
501
502 try_gettext=yes
503 have_dosish_system=no
504 have_w32_system=no
505 use_simple_gettext=no
506 case "${host}" in
507     *-mingw32*)
508         # special stuff for Windoze NT
509         ac_cv_have_dev_random=no
510         AC_DEFINE(USE_ONLY_8DOT3,1,
511                   [set this to limit filenames to the 8.3 format])
512         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
513                   [defined if we must run on a stupid file system])
514         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
515                   [because the Unix gettext has too much overhead on
516                    MingW32 systems and these systems lack Posix functions,
517                    we use a simplified version of gettext])
518         disable_keyserver_path=yes
519         have_dosish_system=yes
520         have_w32_system=yes
521         try_gettext="no"
522         use_simple_gettext=yes
523         ;;
524     i?86-emx-os2 | i?86-*-os2*emx )
525         # OS/2 with the EMX environment
526         ac_cv_have_dev_random=no
527         AC_DEFINE(HAVE_DRIVE_LETTERS)
528         have_dosish_system=yes
529         try_gettext="no"
530         ;;
531
532     i?86-*-msdosdjgpp*)
533         # DOS with the DJGPP environment
534         ac_cv_have_dev_random=no
535         AC_DEFINE(HAVE_DRIVE_LETTERS)
536         have_dosish_system=yes
537         try_gettext="no"
538         ;;
539
540     *-*-freebsd*)
541        # FreeBSD
542        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
543        LDFLAGS="$LDFLAGS -L/usr/local/lib"
544        ;;
545
546     *-*-hpux*)
547         if test -z "$GCC" ; then
548             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
549         fi
550         ;;
551     *-dec-osf4*)
552         if test -z "$GCC" ; then
553             # Suppress all warnings
554             # to get rid of the unsigned/signed char mismatch warnings.
555             CFLAGS="$CFLAGS -w"
556         fi
557         ;;
558     *-dec-osf5*)
559         if test -z "$GCC" ; then
560             # Use the newer compiler `-msg_disable ptrmismatch1' to
561             # get rid of the unsigned/signed char mismatch warnings.
562             # Using this may hide other pointer mismatch warnings, but
563             # it at least lets other warning classes through
564             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
565         fi
566         ;;
567     m68k-atari-mint)
568         ;;
569     *)
570        ;;
571 esac
572
573 if test "$have_dosish_system" = yes; then
574    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
575              [Defined if we run on some of the PCDOS like systems 
576               (DOS, Windoze. OS/2) with special properties like
577               no file modes])
578 fi
579 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
580
581 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
582
583 if test "$have_w32_system" = yes; then
584    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
585 fi
586 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
587
588 if test "$disable_keyserver_path" = yes; then
589     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
590               [Defined to disable exec-path for keyserver helpers])
591 fi
592
593 #
594 # Allows enabling the use of a standard socket by default This is
595 # gpg-agent's option --[no-]use-standard-socket.  For Windows we force
596 # the use of this.
597 #
598 AC_MSG_CHECKING([whether to use a standard socket by default])
599 AC_ARG_ENABLE(standard-socket,
600               AC_HELP_STRING([--enable-standard-socket],
601                              [use a standard socket for the agent by default]),
602               use_standard_socket=$enableval)
603 tmp=""
604 if test "$use_standard_socket" != yes; then
605   if test "$have_w32_system" = yes; then
606     use_standard_socket=yes
607     tmp=" (forced)"
608   fi
609 fi
610 AC_MSG_RESULT($use_standard_socket$tmp)
611 if test "$use_standard_socket" = yes; then
612   AC_DEFINE(USE_STANDARD_SOCKET,1,
613             [Use a standard socket for the agent by default])
614 fi
615
616
617 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
618 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
619
620 if test x"$try_hkp" = xyes ; then
621   AC_SUBST(GPGKEYS_HKP,"gpg2keys_hkp$EXEEXT")
622 fi
623
624 if test x"$try_finger" = xyes ; then
625   AC_SUBST(GPGKEYS_FINGER,"gpg2keys_finger$EXEEXT")
626 fi
627
628
629
630 #
631 # Checks for libraries.
632 #
633 AC_MSG_NOTICE([checking for libraries])
634
635
636 #
637 # libgpg-error is a library with error codes shared between GnuPG
638 # related projects.
639 #
640 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
641                   have_gpg_error=yes,have_gpg_error=no)
642
643
644 #
645 # Libgcrypt is our generic crypto library
646 #
647 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
648         have_libgcrypt=yes,have_libgcrypt=no)
649
650
651 #
652 # libassuan is used for IPC
653 #
654 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
655                   have_libassuan=yes,have_libassuan=no)
656 if test "$have_libassuan" = "yes"; then
657   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
658             [version of the libbassuan library])
659 fi
660
661
662
663 #
664 # libksba is our X.509 support library
665 #
666 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
667
668
669 #
670 # libusb allows us to use the integrated CCID smartcard reader driver.
671 #
672 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
673 if test "$use_ccid_driver" = yes ; then
674   AC_CHECK_LIB(usb, usb_bulk_write,
675                 [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
676                   AC_DEFINE(HAVE_LIBUSB,1,
677                            [defined if libusb is available])
678                   have_libusb=yes
679                ])
680   AC_CHECK_FUNCS(usb_create_match)
681 fi
682 AC_SUBST(LIBUSB_LIBS)
683
684 #
685 # Check wether it is necessary to link against libdl.
686 #
687 gnupg_dlopen_save_libs="$LIBS"
688 LIBS=""
689 AC_SEARCH_LIBS(dlopen, c dl,,,)
690 DL_LIBS=$LIBS
691 AC_SUBST(DL_LIBS)
692 LIBS="$gnupg_dlopen_save_libs"
693
694 #
695 # Checks for symcryptrun:
696 #
697
698 # libutil has openpty() and login_tty().
699 AC_CHECK_LIB(util, openpty,
700               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
701                 AC_DEFINE(HAVE_LIBUTIL,1,
702                          [defined if libutil is available])
703              ])
704 AC_SUBST(LIBUTIL_LIBS)
705
706 # shred is used to clean temporary plain text files.
707 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
708 AC_DEFINE_UNQUOTED(SHRED,
709         "${SHRED}", [defines the filename of the shred program])
710
711
712
713 #
714 # Check whether the GNU Pth library is available
715 # Note, that we include a Pth emulation for W32.
716 #
717 GNUPG_PATH_PTH
718 if test "$have_pth" = "yes"; then
719   AC_DEFINE(USE_GNU_PTH, 1,
720               [Defined if the GNU Portable Thread Library should be used])
721 else
722   AC_MSG_WARN([[
723 ***
724 *** To support concurrent access to the gpg-agent and the SCdaemon
725 *** we need the support of the GNU Portable Threads Library.
726 *** Download it from ftp://ftp.gnu.org/gnu/pth/
727 *** On a Debian GNU/Linux system you might want to try 
728 ***   apt-get install libpth-dev
729 ***]])
730 fi
731
732
733 AC_MSG_NOTICE([checking for networking options])
734
735 #
736 # Must check for network library requirements before doing link tests
737 # for ldap, for example. If ldap libs are static (or dynamic and without
738 # ELF runtime link paths), then link will fail and LDAP support won't
739 # be detected.
740 #
741 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
742         [NETLIBS="-lnsl $NETLIBS"]))
743 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
744         [NETLIBS="-lsocket $NETLIBS"]))
745
746
747 #
748 # Check for ADNS.
749 #
750 _cppflags="${CPPFLAGS}"
751 _ldflags="${LDFLAGS}"
752 AC_ARG_WITH(adns,
753             AC_HELP_STRING([--with-adns=DIR],
754                            [look for the adns library in DIR]),
755             [if test -d "$withval"; then
756                CPPFLAGS="${CPPFLAGS} -I$withval/include"
757                LDFLAGS="${LDFLAGS} -L$withval/lib"
758              fi])
759 if test "$with_adns" != "no"; then
760   AC_CHECK_HEADERS(adns.h,
761                 AC_CHECK_LIB(adns, adns_init,
762                              [have_adns=yes],
763                              [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}]),
764                 [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}])
765 fi
766 if test "$have_adns" = "yes"; then
767   ADNSLIBS="-ladns" 
768 fi
769 AC_SUBST(ADNSLIBS)
770 # Newer adns versions feature a free function to be used under W32.
771 AC_CHECK_FUNCS(adns_free)
772
773
774 #
775 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
776 #
777 if test x"$try_hkp" = xyes || test x"$try_http" = xyes ; then
778   AC_ARG_ENABLE(dns-srv,
779      AC_HELP_STRING([--disable-dns-srv],
780                     [disable the use of DNS SRV in HKP and HTTP]),
781                 use_dns_srv=$enableval,use_dns_srv=yes)
782 fi
783
784 AC_ARG_ENABLE(dns-pka,
785    AC_HELP_STRING([--disable-dns-pka],
786         [disable the use of PKA records in DNS]),
787    use_dns_pka=$enableval,use_dns_pka=yes)
788
789 AC_ARG_ENABLE(dns-cert,
790    AC_HELP_STRING([--disable-dns-cert],
791         [disable the use of CERT records in DNS]),
792    use_dns_cert=$enableval,use_dns_cert=yes)
793
794 if test x"$use_dns_pka" = xyes || test x"$use_dns_srv" = xyes \
795    || test x"$use_dns_cert" = xyes; then
796   _dns_save_libs=$LIBS
797   LIBS=""
798   # the double underscore thing is a glibc-ism?
799   AC_SEARCH_LIBS(res_query,resolv bind,,
800                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
801   AC_SEARCH_LIBS(dn_expand,resolv bind,,
802                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
803   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
804                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
805
806   if test x"$have_resolver" != xno ; then
807
808     # Make sure that the BIND 4 resolver interface is workable before
809     # enabling any code that calls it.  At some point I'll rewrite the
810     # code to use the BIND 8 resolver API.
811     # We might also want to use adns instead.  Problem with ADNS is that
812     # it does not support v6.
813
814     AC_MSG_CHECKING([whether the resolver is usable])
815     AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
816 #include <netinet/in.h>
817 #include <arpa/nameser.h>
818 #include <resolv.h>],
819 [[unsigned char answer[PACKETSZ];
820   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
821   dn_skipname(0,0); 
822   dn_expand(0,0,0,0,0);
823 ]])],have_resolver=yes,have_resolver=no)
824     AC_MSG_RESULT($have_resolver)
825
826     # This is Apple-specific and somewhat bizarre as they changed the
827     # define in bind 8 for some reason.
828
829     if test x"$have_resolver" != xyes ; then
830        AC_MSG_CHECKING(
831              [whether I can make the resolver usable with BIND_8_COMPAT])
832        AC_LINK_IFELSE([AC_LANG_PROGRAM([#define BIND_8_COMPAT
833 #include <sys/types.h>
834 #include <netinet/in.h>
835 #include <arpa/nameser.h>
836 #include <resolv.h>],
837 [[unsigned char answer[PACKETSZ];
838   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
839   dn_skipname(0,0); dn_expand(0,0,0,0,0);
840 ]])],[have_resolver=yes ; need_compat=yes])
841        AC_MSG_RESULT($have_resolver)
842     fi
843   fi
844
845   if test x"$have_resolver" = xyes ; then
846      DNSLIBS=$LIBS
847
848      if test x"$use_dns_srv" = xyes ; then
849         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
850      fi
851
852      if test x"$use_dns_pka" = xyes ; then
853         AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
854      fi
855
856      if test x"$use_dns_cert" = xyes ; then
857         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
858      fi
859
860      if test x"$need_compat" = xyes ; then
861         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
862      fi
863   else
864      # If we have no resolver library but ADNS (e.g. under W32) enable the
865      # code parts which can be used with ADNS.
866      if test x"$have_adns" = xyes ; then
867         DNSLIBS="$ADNSLIBS"
868         AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
869
870         if test x"$use_dns_srv" = xyes ; then
871            AC_DEFINE(USE_DNS_SRV,1)
872         fi
873
874         if test x"$use_dns_pka" = xyes ; then
875            AC_DEFINE(USE_DNS_PKA,1)
876         fi
877
878         if test x"$use_dns_cert" = xyes ; then
879            AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
880         fi
881      else
882         use_dns_srv=no
883         use_dns_pka=no
884         use_dns_cert=no
885      fi
886   fi
887
888   LIBS=$_dns_save_libs
889 fi
890
891 AC_SUBST(DNSLIBS)
892
893 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
894
895
896 #
897 # Check for LDAP
898 #
899 if test "$try_ldap" = yes ; then
900    GNUPG_CHECK_LDAP($NETLIBS)
901 fi
902
903 #
904 # Check for curl.  We fake the curl API if libcurl isn't installed.
905 # We require 7.10 or later as we use curl_version_info().
906 #
907 LIBCURL_CHECK_CONFIG([yes],[7.10],,[fake_curl=yes])
908 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
909
910 # Generic, for us, means curl
911
912 if test x"$try_generic" = xyes ; then
913    AC_SUBST(GPGKEYS_CURL,"gpg2keys_curl$EXEEXT")
914 fi
915
916 #
917 # Check for sendmail
918 #
919 # This isn't necessarily sendmail itself, but anything that gives a
920 # sendmail-ish interface to the outside world.  That includes Exim,
921 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
922 if test "$try_mailto" = yes ; then
923   AC_ARG_WITH(mailprog,
924       AC_HELP_STRING([--with-mailprog=NAME],
925                      [use "NAME -t" for mail transport]),
926              ,with_mailprog=yes)
927
928   if test x"$with_mailprog" = xyes ; then
929     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
930     if test "$ac_cv_path_SENDMAIL" ; then
931       GPGKEYS_MAILTO="gpg2keys_mailto"
932     fi
933   elif test x"$with_mailprog" != xno ; then
934     AC_MSG_CHECKING([for a mail transport program])
935     AC_SUBST(SENDMAIL,$with_mailprog)
936     AC_MSG_RESULT($with_mailprog)
937     GPGKEYS_MAILTO="gpg2keys_mailto"
938   fi
939 fi
940
941 AC_SUBST(GPGKEYS_MAILTO)
942
943 #
944 # Construct a printable name of the OS
945 #
946 case "${host}" in
947     *-mingw32*)
948         PRINTABLE_OS_NAME="MingW32"
949         ;;
950     *-*-cygwin*)
951         PRINTABLE_OS_NAME="Cygwin"
952         ;;
953     i?86-emx-os2 | i?86-*-os2*emx )
954         PRINTABLE_OS_NAME="OS/2"
955         ;;
956     i?86-*-msdosdjgpp*)
957         PRINTABLE_OS_NAME="MSDOS/DJGPP"
958         try_dynload=no
959         ;;
960     *-linux*)
961         PRINTABLE_OS_NAME="GNU/Linux"
962         ;;
963     *)
964         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
965         ;;
966 esac
967 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
968                    [A human readable text with the name of the OS])
969
970
971 #
972 # Checking for iconv
973 #
974 AM_ICONV
975
976
977 #
978 # Check for gettext
979 #
980 # This is "GNU gnupg" - The project-id script from gettext
981 #                       needs this string
982 #
983 AC_MSG_NOTICE([checking for gettext])
984 AM_PO_SUBDIRS
985 AM_GNU_GETTEXT_VERSION([0.17])
986 if test "$try_gettext" = yes; then
987   AM_GNU_GETTEXT([external],[need-ngettext])
988
989   # gettext requires some extra checks.  These really should be part of
990   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
991   # function checks to here.
992
993   AC_CHECK_FUNCS(strchr)
994 else
995   USE_NLS=no
996   USE_INCLUDED_LIBINTL=no
997   BUILD_INCLUDED_LIBINTL=no
998   POSUB=po
999   AC_SUBST(USE_NLS)
1000   AC_SUBST(USE_INCLUDED_LIBINTL)
1001   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1002   AC_SUBST(POSUB)
1003 fi
1004
1005 # We use HAVE_LANGINFO_CODESET in a couple of places.
1006 AM_LANGINFO_CODESET
1007
1008 # Checks required for our use locales
1009 gt_LC_MESSAGES
1010
1011
1012 #
1013 # SELinux support
1014 #
1015 if test "$selinux_support" = yes ; then
1016   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1017 fi
1018
1019
1020 #
1021 # Checks for header files.
1022 #
1023 AC_MSG_NOTICE([checking for header files])
1024 AC_HEADER_STDC
1025 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h])
1026 AC_CHECK_HEADERS([pty.h pwd.h inttypes.h])
1027 AC_HEADER_TIME
1028
1029
1030 #
1031 # Checks for typedefs, structures, and compiler characteristics.
1032 #
1033 AC_MSG_NOTICE([checking for system characteristics])
1034 AC_C_CONST
1035 AC_C_INLINE
1036 AC_C_VOLATILE
1037 AC_TYPE_SIZE_T
1038 AC_TYPE_MODE_T
1039 AC_TYPE_SIGNAL
1040 AC_DECL_SYS_SIGLIST
1041
1042 gl_HEADER_SYS_SOCKET
1043 gl_TYPE_SOCKLEN_T
1044
1045 AC_ARG_ENABLE(endian-check,
1046               AC_HELP_STRING([--disable-endian-check],
1047               [disable the endian check and trust the OS provided macros]),
1048               endiancheck=$enableval,endiancheck=yes)
1049
1050 if test x"$endiancheck" = xyes ; then
1051   GNUPG_CHECK_ENDIAN
1052 fi
1053
1054 # fixme: we should get rid of the byte type
1055 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1056 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1057 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1058 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1059 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1060
1061 AC_CHECK_SIZEOF(unsigned short)
1062 AC_CHECK_SIZEOF(unsigned int)
1063 AC_CHECK_SIZEOF(unsigned long)
1064 AC_CHECK_SIZEOF(unsigned long long)
1065 AC_CHECK_SIZEOF(time_t,,[[
1066 #include <stdio.h>
1067 #if TIME_WITH_SYS_TIME
1068 # include <sys/time.h>
1069 # include <time.h>
1070 #else
1071 # if HAVE_SYS_TIME_H
1072 #  include <sys/time.h>
1073 # else
1074 #  include <time.h>
1075 # endif
1076 #endif
1077 ]])
1078
1079
1080 # Ensure that we have UINT64_C before we bother to check for uint64_t
1081 # Fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
1082 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
1083    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
1084        uint64_t foo=UINT64_C(42);]),
1085      gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
1086 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
1087    AC_CHECK_SIZEOF(uint64_t)
1088 fi
1089
1090 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1091    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1092    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1093     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1094 fi
1095
1096
1097 #
1098 # Checks for library functions.
1099 #
1100 AC_MSG_NOTICE([checking for library functions])
1101 AC_CHECK_DECLS(getpagesize)
1102 AC_FUNC_FSEEKO
1103 AC_FUNC_VPRINTF
1104 AC_FUNC_FORK
1105 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap])
1106 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r])
1107 AC_CHECK_FUNCS([unsetenv fcntl ftruncate])
1108 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1109 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1110 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe stat getaddrinfo])
1111 AC_CHECK_FUNCS([ttyname rand ftello fsync])
1112
1113 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1114
1115 #
1116 # These are needed by libjnlib - fixme: we should use a jnlib.m4
1117 # Note:  We already checked pwd.h.
1118 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol])
1119 AC_CHECK_FUNCS([memrchr isascii timegm getrusage setrlimit stat setlocale])
1120 AC_CHECK_FUNCS([flockfile funlockfile fopencookie funopen getpwnam getpwuid])
1121
1122 #
1123 # gnulib checks
1124 #
1125 gl_SOURCE_BASE([gl])
1126 gl_M4_BASE([gl/m4])
1127 gl_MODULES([setenv mkdtemp xsize strpbrk])
1128 gl_INIT
1129
1130
1131 #
1132 # W32 specific test
1133 #
1134 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1135
1136 #
1137 # Sanity check regex.  Tests adapted from mutt.
1138 #
1139 AC_MSG_CHECKING([whether regular expression support is requested])
1140 AC_ARG_ENABLE(regex,
1141   AC_HELP_STRING([--disable-regex],
1142     [do not handle regular expressions in trust signatures]),
1143   use_regex=$enableval, use_regex=yes)
1144 AC_MSG_RESULT($use_regex)
1145
1146 if test "$use_regex" = yes ; then
1147   _cppflags="${CPPFLAGS}"
1148   _ldflags="${LDFLAGS}"
1149   AC_ARG_WITH(regex,
1150      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1151       [
1152       if test -d "$withval" ; then
1153         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1154         LDFLAGS="${LDFLAGS} -L$withval/lib"
1155       fi
1156       ],withval="")     
1157
1158   # Does the system have regex functions at all?
1159   AC_SEARCH_LIBS([regcomp], [regex])
1160   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1161
1162   if test $gnupg_cv_have_regex = no; then
1163     use_regex=no
1164   else
1165     if test x"$cross_compiling" = xyes; then
1166       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1167     else
1168       AC_CACHE_CHECK([whether your system's regexp library is broken],
1169        [gnupg_cv_regex_broken],
1170        AC_TRY_RUN([
1171 #include <unistd.h>
1172 #include <regex.h>
1173 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1174        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1175
1176       if test $gnupg_cv_regex_broken = yes; then
1177         AC_MSG_WARN([your regex is broken - disabling regex use])
1178         use_regex=no
1179       fi
1180     fi
1181   fi
1182   CPPFLAGS="${_cppflags}"
1183   LDFLAGS="${_ldflags}"
1184 fi
1185
1186 if test "$use_regex" != yes ; then
1187   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1188 fi
1189 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1190
1191
1192
1193 #
1194 # Do we have zlib? Must do it here because Solaris failed
1195 # when compiling a conftest (due to the "-lz" from LIBS).
1196 # Note that we combine zlib and bzlib2 in ZLIBS.
1197 #
1198 _cppflags="${CPPFLAGS}"
1199 _ldflags="${LDFLAGS}"
1200 AC_ARG_WITH(zlib,
1201   [  --with-zlib=DIR         use libz in DIR],[
1202     if test -d "$withval"; then
1203       CPPFLAGS="${CPPFLAGS} -I$withval/include"
1204       LDFLAGS="${LDFLAGS} -L$withval/lib"
1205     fi
1206   ])
1207
1208 AC_CHECK_HEADER(zlib.h,
1209       AC_CHECK_LIB(z, deflateInit2_,
1210        ZLIBS="-lz",
1211        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1212        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1213
1214 #
1215 # Check whether we can support bzip2
1216
1217 if test "$use_bzip2" = yes ; then
1218   _cppflags="${CPPFLAGS}"
1219   _ldflags="${LDFLAGS}"
1220   AC_ARG_WITH(bzip2,
1221      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1222       [
1223       if test -d "$withval" ; then
1224         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1225         LDFLAGS="${LDFLAGS} -L$withval/lib"
1226       fi
1227       ],withval="")
1228
1229   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1230   # required stdio.h to be included before bzlib.h, and Solaris 9 is 
1231   # woefully out of date.
1232   if test "$withval" != no ; then
1233      AC_CHECK_HEADER(bzlib.h,
1234         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1235           [
1236           have_bz2=yes
1237           ZLIBS="$ZLIBS -lbz2"
1238           AC_DEFINE(HAVE_BZIP2,1,
1239                   [Defined if the bz2 compression library is available])
1240           ],
1241           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1242           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1243   fi
1244 fi
1245 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1246 AC_SUBST(ZLIBS)
1247
1248
1249 # Check for readline support
1250 GNUPG_CHECK_READLINE
1251
1252 #
1253 # Allow users to append something to the version string without
1254 # flagging it as development version.  The user version parts is
1255 # considered everything after a dash. 
1256 #
1257 if test "$development_version" != yes; then
1258   changequote(,)dnl
1259   tmp_pat='[a-zA-Z]'
1260   changequote([,])dnl
1261   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1262     development_version=yes
1263   fi
1264 fi
1265 if test "$development_version" = yes; then
1266     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1267             [Defined if this is not a regular release])
1268 fi
1269
1270 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1271
1272 GNUPG_CHECK_GNUMAKE
1273
1274 # Add some extra libs here so that previous tests don't fail for
1275 # mysterious reasons - the final link step should bail out.
1276 # W32SOCKLIBS is also defined so that if can be used for tools not
1277 # requiring any network stuff but linking to code in libcommon which
1278 # tracks in winsock stuff (e.g. init_common_subsystems.
1279 if test "$have_w32_system" = yes; then
1280    W32SOCKLIBS="-lws2_32"
1281    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1282 fi
1283
1284 AC_SUBST(NETLIBS)
1285 AC_SUBST(W32SOCKLIBS)
1286
1287 #
1288 # Setup gcc specific options
1289 #
1290 AC_MSG_NOTICE([checking for cc features])
1291 if test "$GCC" = yes; then
1292     # Note that it is okay to use CFLAGS here because this are just
1293     # warning options and the user should have a chance of overriding
1294     # them.
1295     if test "$USE_MAINTAINER_MODE" = "yes"; then
1296         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1297         CFLAGS="$CFLAGS -Wformat -Wno-format-y2k -Wformat-security"
1298         AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1299         _gcc_cflags_save=$CFLAGS
1300         CFLAGS="-Wno-missing-field-initializers"
1301         AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_wopt=yes,_gcc_wopt=no)
1302         AC_MSG_RESULT($_gcc_wopt)
1303         CFLAGS=$_gcc_cflags_save;
1304         if test x"$_gcc_wopt" = xyes ; then
1305           CFLAGS="$CFLAGS -W -Wno-sign-compare -Wno-missing-field-initializers"
1306         fi
1307         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1308         _gcc_cflags_save=$CFLAGS
1309         CFLAGS="-Wdeclaration-after-statement"
1310         AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_wopt=yes,_gcc_wopt=no)
1311         AC_MSG_RESULT($_gcc_wopt)
1312         CFLAGS=$_gcc_cflags_save;
1313         if test x"$_gcc_wopt" = xyes ; then
1314           CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1315         fi
1316     else
1317         CFLAGS="$CFLAGS -Wall"
1318     fi
1319
1320     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1321     _gcc_cflags_save=$CFLAGS
1322     CFLAGS="-Wno-pointer-sign"
1323     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1324     AC_MSG_RESULT($_gcc_psign)
1325     CFLAGS=$_gcc_cflags_save;
1326     if test x"$_gcc_psign" = xyes ; then
1327        CFLAGS="$CFLAGS -Wno-pointer-sign"
1328     fi
1329
1330     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1331     _gcc_cflags_save=$CFLAGS
1332     CFLAGS="-Wpointer-arith"
1333     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1334     AC_MSG_RESULT($_gcc_psign)
1335     CFLAGS=$_gcc_cflags_save;
1336     if test x"$_gcc_psign" = xyes ; then
1337        CFLAGS="$CFLAGS -Wpointer-arith"
1338     fi
1339 fi
1340
1341
1342 #
1343 # This is handy for debugging so the compiler doesn't rearrange
1344 # things and eliminate variables.
1345 #
1346 AC_ARG_ENABLE(optimization,
1347    AC_HELP_STRING([--disable-optimization],
1348                   [disable compiler optimization]),
1349                   [if test $enableval = no ; then
1350                       CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]]//'`
1351                    fi])
1352
1353 #
1354 # Prepare building of estream
1355 #
1356 estream_INIT
1357
1358
1359 #
1360 # Decide what to build
1361 #
1362 if test "$have_adns" = "yes"; then
1363   AC_SUBST(GPGKEYS_KDNS, "gpg2keys_kdns$EXEEXT")
1364 fi
1365
1366
1367 missing_pth=no
1368 if test $have_ksba = no; then
1369   build_gpgsm=no
1370   build_scdaemon=no
1371 fi
1372
1373 build_agent_threaded=""
1374 if test "$build_agent" = "yes"; then
1375   if test $have_pth = no; then
1376      build_agent_threaded="(not multi-threaded)"
1377      missing_pth=yes
1378   fi
1379 fi
1380
1381 build_scdaemon_extra=""
1382 if test "$build_scdaemon" = "yes"; then
1383   tmp=""
1384   if test $have_pth = no; then
1385      build_scdaemon_extra="not multi-threaded"
1386      tmp=", "
1387      missing_pth=yes
1388   fi
1389   if test $have_libusb = no; then
1390      build_scdaemon_extra="${tmp}without internal CCID driver"
1391      tmp=", "
1392   fi
1393   if test -n "$build_scdaemon_extra"; then
1394      build_scdaemon_extra="(${build_scdaemon_extra})"
1395   fi
1396 fi
1397
1398
1399 if test "$build_agent_only" = "yes" ; then
1400   build_gpg=no
1401   build_gpgsm=no
1402   build_scdaemon=no
1403   build_tools=no
1404   build_doc=no
1405 fi
1406
1407
1408 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1409 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1410 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1411 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1412 AM_CONDITIONAL(BUILD_TOOLS, test "$build_tools" = "yes")
1413 AM_CONDITIONAL(BUILD_DOC,   test "$build_doc" = "yes")
1414 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1415
1416 AM_CONDITIONAL(RUN_GPG_TESTS,
1417         test x$cross_compiling = xno -a "$build_gpg" = yes )
1418
1419
1420 #
1421 # Print errors here so that they are visible all
1422 # together and the user can acquire them all together.
1423 #
1424 die=no
1425 if test "$have_gpg_error" = "no"; then
1426    die=yes
1427    AC_MSG_NOTICE([[
1428 ***  
1429 *** You need libgpg-error to build this program.
1430 **  This library is for example available at
1431 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1432 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1433 ***]])
1434 fi
1435 if test "$have_libgcrypt" = "no"; then
1436    die=yes
1437    AC_MSG_NOTICE([[
1438 ***  
1439 *** You need libgcrypt to build this program.
1440 **  This library is for example available at
1441 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1442 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API is required.)
1443 ***]])
1444 fi
1445 if test "$have_libassuan" = "no"; then
1446    die=yes
1447    AC_MSG_NOTICE([[
1448 ***
1449 *** You need libassuan to build this program.
1450 *** This library is for example available at
1451 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1452 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1453 ***]])
1454 fi
1455 if test "$have_ksba" = "no"; then
1456     AC_MSG_NOTICE([[
1457 ***
1458 *** You need libksba to build this program.
1459 *** This library is for example available at
1460 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1461 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1462 ***]])
1463 fi
1464 if test "$missing_pth" = "yes"; then
1465     AC_MSG_NOTICE([[
1466 ***
1467 *** It is now required to build with support for the
1468 *** GNU Portable Threads Library (Pth). Please install this
1469 *** library first.  The library is for example available at
1470 ***   ftp://ftp.gnu.org/gnu/pth/
1471 *** On a Debian GNU/Linux system you can install it using 
1472 ***   apt-get install libpth-dev
1473 *** To build GnuPG for Windows you need to use the W32PTH
1474 *** package; available at:
1475 ***   ftp://ftp.g10code.com/g10code/w32pth/
1476 ***]])
1477    die=yes
1478 fi
1479
1480 if test "$die" = "yes"; then
1481     AC_MSG_ERROR([[
1482 ***
1483 *** Required libraries not found. Please consult the above messages
1484 *** and install them before running configure again.
1485 ***]])
1486 fi
1487
1488
1489
1490 AC_CONFIG_FILES([ m4/Makefile 
1491 Makefile
1492 po/Makefile.in
1493 gl/Makefile
1494 include/Makefile
1495 jnlib/Makefile
1496 common/Makefile
1497 kbx/Makefile
1498 g10/Makefile
1499 sm/Makefile
1500 agent/Makefile
1501 scd/Makefile
1502 keyserver/Makefile
1503 keyserver/gpg2keys_mailto
1504 keyserver/gpg2keys_test
1505 tools/gpg-zip
1506 tools/Makefile
1507 doc/Makefile
1508 tests/Makefile
1509 tests/openpgp/Makefile
1510 tests/pkits/Makefile
1511 ])
1512 AC_OUTPUT
1513
1514
1515 echo "
1516         GnuPG v${VERSION} has been configured as follows:
1517         
1518         Platform:  $PRINTABLE_OS_NAME ($host)
1519
1520         OpenPGP:   $build_gpg
1521         S/MIME:    $build_gpgsm
1522         Agent:     $build_agent $build_agent_threaded
1523         Smartcard: $build_scdaemon $build_scdaemon_extra
1524
1525         Protect tool:      $show_gnupg_protect_tool_pgm
1526         Default agent:     $show_gnupg_agent_pgm
1527         Default pinentry:  $show_gnupg_pinentry_pgm
1528         Default scdaemon:  $show_gnupg_scdaemon_pgm
1529         Default dirmngr:   $show_gnupg_dirmngr_pgm
1530 "
1531 if test x"$use_regex" != xyes ; then
1532 echo "
1533         Warning: No regular expression support available.
1534                  OpenPGP trust signatures won't work.
1535                  gpg-check-pattern will not be build.
1536 "
1537 fi