build: Improve CFLAGS handling.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998-2012 Free Software Foundation, Inc.
3 # Copyright (C) 1998-2016 Werner Koch
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <https://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.14"
23
24 # To build a release you need to create a tag with the version number
25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
26 # bump the version number immediately *after* the release and do
27 # another commit and push so that the git magic is able to work.
28 m4_define([mym4_package],[gnupg])
29 m4_define([mym4_major], [2])
30 m4_define([mym4_minor], [1])
31 m4_define([mym4_micro], [20])
32
33 # To start a new development series, i.e a new major or minor number
34 # you need to mark an arbitrary commit before the first beta release
35 # with an annotated tag.  For example the 2.1 branch starts off with
36 # the tag "gnupg-2.1-base".  This is used as the base for counting
37 # beta numbers before the first release of a series.
38
39 # Below is m4 magic to extract and compute the git revision number,
40 # the decimalized short revision number, a beta version string and a
41 # flag indicating a development version (mym4_isbeta).  Note that the
42 # m4 processing is done by autoconf and not during the configure run.
43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
49 m4_esyscmd([echo ]mym4_version[>VERSION])
50 AC_INIT([mym4_package],[mym4_version], [https://bugs.gnupg.org])
51
52 NEED_GPG_ERROR_VERSION=1.24
53
54 NEED_LIBGCRYPT_API=1
55 NEED_LIBGCRYPT_VERSION=1.7.0
56
57 NEED_LIBASSUAN_API=2
58 NEED_LIBASSUAN_VERSION=2.4.3
59
60 NEED_KSBA_API=1
61 NEED_KSBA_VERSION=1.3.4
62
63 NEED_NTBTLS_API=1
64 NEED_NTBTLS_VERSION=0.1.0
65
66 NEED_NPTH_API=1
67 NEED_NPTH_VERSION=1.2
68
69
70 NEED_GNUTLS_VERSION=3.0
71
72 NEED_SQLITE_VERSION=3.7
73
74 development_version=mym4_isbeta
75 PACKAGE=$PACKAGE_NAME
76 PACKAGE_GT=${PACKAGE_NAME}2
77 VERSION=$PACKAGE_VERSION
78
79 AC_CONFIG_AUX_DIR([build-aux])
80 AC_CONFIG_SRCDIR([sm/gpgsm.c])
81 AC_CONFIG_HEADER([config.h])
82 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
83 AC_CANONICAL_HOST
84 AB_INIT
85
86 AC_GNU_SOURCE
87
88 # Before we do anything with the C compiler, we first split the user's
89 # CFLAGS into two lists, one containing all flags matching '-Werror',
90 # and the other one containing all remaing flags. They are recombined
91 # at the end of the configure script.  This is because some configure
92 # checks don't work with -Werror, but we'd like to use -Werror with
93 # our build.
94 CFLAGS_werror="$(echo $CFLAGS | tr '[[:space:]]' '\n' | grep -e -Werror | tr '\n' ' ')"
95 CFLAGS="$(echo $CFLAGS | tr '[[:space:]]' '\n' | grep -v -e -Werror | tr '\n' ' ')"
96
97 # Some status variables.
98 have_gpg_error=no
99 have_libgcrypt=no
100 have_libassuan=no
101 have_ksba=no
102 have_ntbtls=no
103 have_gnutls=no
104 have_sqlite=no
105 have_npth=no
106 have_libusb=no
107 have_system_resolver=no
108 gnupg_have_ldap="n/a"
109
110 use_zip=yes
111 use_bzip2=yes
112 use_exec=yes
113 use_trust_models=yes
114 use_tofu=yes
115 use_libdns=yes
116 card_support=yes
117 use_ccid_driver=auto
118 dirmngr_auto_start=yes
119 use_tls_library=no
120 large_secmem=no
121 show_tor_support=no
122
123
124 GNUPG_BUILD_PROGRAM(gpg, yes)
125 GNUPG_BUILD_PROGRAM(gpgsm, yes)
126 # The agent is a required part and can't be disabled anymore.
127 build_agent=yes
128 GNUPG_BUILD_PROGRAM(scdaemon, yes)
129 GNUPG_BUILD_PROGRAM(g13, no)
130 GNUPG_BUILD_PROGRAM(dirmngr, yes)
131 GNUPG_BUILD_PROGRAM(tools, yes)
132 GNUPG_BUILD_PROGRAM(doc, yes)
133 GNUPG_BUILD_PROGRAM(symcryptrun, no)
134 # We use gpgtar to unpack test data, hence we always build it.  If the
135 # user opts out, we simply don't install it.
136 GNUPG_BUILD_PROGRAM(gpgtar, yes)
137 GNUPG_BUILD_PROGRAM(wks-tools, no)
138
139 AC_SUBST(PACKAGE)
140 AC_SUBST(PACKAGE_GT)
141 AC_SUBST(VERSION)
142 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
143 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
144                                 [Name of this package for gettext])
145 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
146 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
147                                         [Bug report address])
148 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
149                                        [Required version of Libgcrypt])
150 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
151                                        [Required version of Libksba])
152 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
153                                        [Required version of NTBTLS])
154
155
156
157 # The default is to use the modules from this package and the few
158 # other packages in a standard place; i.e where this package gets
159 # installed.  With these options it is possible to override these
160 # ${prefix} depended values with fixed paths, which can't be replaced
161 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
162 AC_ARG_WITH(agent-pgm,
163     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
164           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
165 AC_SUBST(GNUPG_AGENT_PGM)
166 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
167 show_gnupg_agent_pgm="(default)"
168 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
169
170 AC_ARG_WITH(pinentry-pgm,
171     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
172           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
173 AC_SUBST(GNUPG_PINENTRY_PGM)
174 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
175 show_gnupg_pinentry_pgm="(default)"
176 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
177
178
179 AC_ARG_WITH(scdaemon-pgm,
180     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
181           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
182 AC_SUBST(GNUPG_SCDAEMON_PGM)
183 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
184 show_gnupg_scdaemon_pgm="(default)"
185 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
186
187
188 AC_ARG_WITH(dirmngr-pgm,
189     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
190           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
191 AC_SUBST(GNUPG_DIRMNGR_PGM)
192 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
193 show_gnupg_dirmngr_pgm="(default)"
194 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
195
196 AC_ARG_WITH(protect-tool-pgm,
197     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
198           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
199 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
200 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
201 show_gnupg_protect_tool_pgm="(default)"
202 test -n "$GNUPG_PROTECT_TOOL_PGM" \
203       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
204
205 AC_ARG_WITH(dirmngr-ldap-pgm,
206     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmngr ldap wrapper)],
207           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
208 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
209 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
210 show_gnupg_dirmngr_ldap_pgm="(default)"
211 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
212       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
213
214 #
215 # On some platforms gpg2 is usually installed as gpg without using a
216 # symlink.  For correct operation of gpgconf it needs to know the
217 # installed name of gpg.  This option sets "gpg2"'s installed name to
218 # just "gpg".  Note that it might be required to rename gpg2 to gpg
219 # manually after the build process.
220 #
221 AC_ARG_ENABLE(gpg2-is-gpg,
222     AC_HELP_STRING([--enable-gpg2-is-gpg],[Set installed name of gpg2 to gpg]),
223     gpg2_is_gpg=$enableval)
224 if test "$gpg2_is_gpg" != "yes"; then
225    AC_DEFINE(USE_GPG2_HACK, 1, [Define to install gpg as gpg2])
226 fi
227 AM_CONDITIONAL(USE_GPG2_HACK, test "$gpg2_is_gpg" != "yes")
228
229
230 # SELinux support includes tracking of sensitive files to avoid
231 # leaking their contents through processing these files by gpg itself
232 AC_MSG_CHECKING([whether SELinux support is requested])
233 AC_ARG_ENABLE(selinux-support,
234               AC_HELP_STRING([--enable-selinux-support],
235                              [enable SELinux support]),
236               selinux_support=$enableval, selinux_support=no)
237 AC_MSG_RESULT($selinux_support)
238
239
240 AC_MSG_CHECKING([whether to allocate extra secure memory])
241 AC_ARG_ENABLE(large-secmem,
242               AC_HELP_STRING([--enable-large-secmem],
243                              [allocate extra secure memory]),
244               large_secmem=$enableval, large_secmem=no)
245 AC_MSG_RESULT($large_secmem)
246 if test "$large_secmem" = yes ; then
247    SECMEM_BUFFER_SIZE=65536
248 else
249    SECMEM_BUFFER_SIZE=32768
250 fi
251 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
252                    [Size of secure memory buffer])
253
254 AC_MSG_CHECKING([whether to enable trust models])
255 AC_ARG_ENABLE(trust-models,
256               AC_HELP_STRING([--disable-trust-models],
257                              [disable all trust models except "always"]),
258               use_trust_models=$enableval)
259 AC_MSG_RESULT($use_trust_models)
260 if test "$use_trust_models" = no ; then
261     AC_DEFINE(NO_TRUST_MODELS, 1,
262              [Define to include only trust-model always])
263 fi
264
265 AC_MSG_CHECKING([whether to enable TOFU])
266 AC_ARG_ENABLE(tofu,
267                 AC_HELP_STRING([--disable-tofu],
268                                [disable the TOFU trust model]),
269               use_tofu=$enableval, use_tofu=$use_trust_models)
270 AC_MSG_RESULT($use_tofu)
271 if test "$use_trust_models" = no && test "$use_tofu" = yes; then
272     AC_MSG_ERROR([both --disable-trust-models and --enable-tofu given])
273 fi
274
275 AC_MSG_CHECKING([whether to enable libdns])
276 AC_ARG_ENABLE(libdns,
277                 AC_HELP_STRING([--disable-libdns],
278                                [do not build with libdns support]),
279               use_libdns=$enableval, use_libdns=yes)
280 AC_MSG_RESULT($use_libdns)
281 if test x"$use_libdns" = xyes ; then
282     AC_DEFINE(USE_LIBDNS, 1, [Build with integrated libdns support])
283 fi
284 AM_CONDITIONAL(USE_LIBDNS, test "$use_libdns" = yes)
285
286
287 #
288 # Options to disable algorithm
289 #
290
291 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
292 # Elgamal is a MUST algorithm
293 # DSA is a MUST algorithm
294 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
295 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
296 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
297
298 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
299 # 3DES is a MUST algorithm
300 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
301 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
302 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
303 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
304 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
305 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
306 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
307 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
308 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
309
310 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
311 # SHA1 is a MUST algorithm
312 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
313 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
314 # SHA256 is a MUST algorithm for GnuPG.
315 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
316 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
317
318
319 # Allow disabling of zip support.
320 # This is in general not a good idea because according to rfc4880 OpenPGP
321 # implementations SHOULD support ZLIB.
322 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
323 AC_ARG_ENABLE(zip,
324    AC_HELP_STRING([--disable-zip],
325                   [disable the ZIP and ZLIB compression algorithm]),
326    use_zip=$enableval)
327 AC_MSG_RESULT($use_zip)
328
329 # Allow disabling of bzib2 support.
330 # It is defined only after we confirm the library is available later
331 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
332 AC_ARG_ENABLE(bzip2,
333    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
334    use_bzip2=$enableval)
335 AC_MSG_RESULT($use_bzip2)
336
337 # Configure option to allow or disallow execution of external
338 # programs, like a photo viewer.
339 AC_MSG_CHECKING([whether to enable external program execution])
340 AC_ARG_ENABLE(exec,
341     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
342     use_exec=$enableval)
343 AC_MSG_RESULT($use_exec)
344 if test "$use_exec" = no ; then
345     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
346 fi
347
348 if test "$use_exec" = yes ; then
349   AC_MSG_CHECKING([whether to enable photo ID viewing])
350   AC_ARG_ENABLE(photo-viewers,
351       [  --disable-photo-viewers disable photo ID viewers],
352       [if test "$enableval" = no ; then
353          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
354       fi],enableval=yes)
355   gnupg_cv_enable_photo_viewers=$enableval
356   AC_MSG_RESULT($enableval)
357
358   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
359     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
360     AC_ARG_WITH(photo-viewer,
361         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
362         [if test "$withval" = yes ; then
363            withval=no
364         elif test "$withval" != no ; then
365            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
366                             [if set, restrict photo-viewer to this])
367         fi],withval=no)
368     AC_MSG_RESULT($withval)
369   fi
370 fi
371
372
373 #
374 # Check for the key/uid cache size.  This can't be zero, but can be
375 # pretty small on embedded systems.  This is used for the gpg part.
376 #
377 AC_MSG_CHECKING([for the size of the key and uid cache])
378 AC_ARG_ENABLE(key-cache,
379         AC_HELP_STRING([--enable-key-cache=SIZE],
380                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
381 if test "$enableval" = "no"; then
382    enableval=5
383 elif test "$enableval" = "yes" || test "$enableval" = ""; then
384    enableval=4096
385 fi
386 changequote(,)dnl
387 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
388 changequote([,])dnl
389 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
390    AC_MSG_ERROR([invalid key-cache size])
391 fi
392 AC_MSG_RESULT($key_cache_size)
393 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
394                   [Size of the key and UID caches])
395
396
397
398 #
399 # Check whether we want to use Linux capabilities
400 #
401 AC_MSG_CHECKING([whether use of capabilities is requested])
402 AC_ARG_WITH(capabilities,
403     [  --with-capabilities     use linux capabilities [default=no]],
404 [use_capabilities="$withval"],[use_capabilities=no])
405 AC_MSG_RESULT($use_capabilities)
406
407 #
408 # Check whether to disable the card support
409 AC_MSG_CHECKING([whether smartcard support is requested])
410 AC_ARG_ENABLE(card-support,
411               AC_HELP_STRING([--disable-card-support],
412                              [disable smartcard support]),
413               card_support=$enableval)
414 AC_MSG_RESULT($card_support)
415 if test "$card_support" = yes ; then
416   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
417 else
418   build_scdaemon=no
419 fi
420
421 #
422 # Allow disabling of internal CCID support.
423 # It is defined only after we confirm the library is available later
424 #
425 AC_MSG_CHECKING([whether to enable the internal CCID driver])
426 AC_ARG_ENABLE(ccid-driver,
427               AC_HELP_STRING([--disable-ccid-driver],
428                              [disable the internal CCID driver]),
429               use_ccid_driver=$enableval)
430 AC_MSG_RESULT($use_ccid_driver)
431
432 AC_MSG_CHECKING([whether to auto start dirmngr])
433 AC_ARG_ENABLE(dirmngr-auto-start,
434               AC_HELP_STRING([--disable-dirmngr-auto-start],
435                              [disable auto starting of the dirmngr]),
436               dirmngr_auto_start=$enableval)
437 AC_MSG_RESULT($dirmngr_auto_start)
438 if test "$dirmngr_auto_start" = yes ; then
439     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
440               [Define to enable auto starting of the dirmngr])
441 fi
442
443
444 #
445 # To avoid double inclusion of config.h which might happen at some
446 # places, we add the usual double inclusion protection at the top of
447 # config.h.
448 #
449 AH_TOP([
450 #ifndef GNUPG_CONFIG_H_INCLUDED
451 #define GNUPG_CONFIG_H_INCLUDED
452 ])
453
454 #
455 # Stuff which goes at the bottom of config.h.
456 #
457 AH_BOTTOM([
458 /* This is the major version number of GnuPG so that
459    source included files can test for this.  Note, that
460    we use 2 here even for GnuPG 1.9.x. */
461 #define GNUPG_MAJOR_VERSION 2
462
463 /* Now to separate file name parts.
464    Please note that the string version must not contain more
465    than one character because the code assumes strlen()==1 */
466 #ifdef HAVE_DOSISH_SYSTEM
467 #define DIRSEP_C '\\'
468 #define DIRSEP_S "\\"
469 #define EXTSEP_C '.'
470 #define EXTSEP_S "."
471 #define PATHSEP_C ';'
472 #define PATHSEP_S ";"
473 #define EXEEXT_S ".exe"
474 #else
475 #define DIRSEP_C '/'
476 #define DIRSEP_S "/"
477 #define EXTSEP_C '.'
478 #define EXTSEP_S "."
479 #define PATHSEP_C ':'
480 #define PATHSEP_S ":"
481 #define EXEEXT_S ""
482 #endif
483
484 /* This is the same as VERSION, but should be overridden if the
485    platform cannot handle things like dots '.' in filenames. Set
486    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
487    uses for dots and dashes. */
488 #define SAFE_VERSION VERSION
489 #define SAFE_VERSION_DOT  '.'
490 #define SAFE_VERSION_DASH '-'
491
492 /* Some global constants. */
493 #ifdef HAVE_DOSISH_SYSTEM
494 # ifdef HAVE_DRIVE_LETTERS
495 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
496 # else
497 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
498 # endif
499 #elif defined(__VMS)
500 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
501 #else
502 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
503 #endif
504 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
505 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
506
507 /* For some systems (DOS currently), we hardcode the path here.  For
508    POSIX systems the values are constructed by the Makefiles, so that
509    the values may be overridden by the make invocations; this is to
510    comply with the GNU coding standards.  Note that these values are
511    only defaults.  */
512 #ifdef HAVE_DOSISH_SYSTEM
513 # ifdef HAVE_DRIVE_LETTERS
514 #  define GNUPG_BINDIR      "c:\\gnupg"
515 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
516 #  define GNUPG_LIBDIR      "c:\\gnupg"
517 #  define GNUPG_DATADIR     "c:\\gnupg"
518 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
519 # else
520 #  define GNUPG_BINDIR      "\\gnupg"
521 #  define GNUPG_LIBEXECDIR  "\\gnupg"
522 #  define GNUPG_LIBDIR      "\\gnupg"
523 #  define GNUPG_DATADIR     "\\gnupg"
524 #  define GNUPG_SYSCONFDIR  "\\gnupg"
525 # endif
526 #endif
527
528 /* Derive some other constants. */
529 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
530 #define EXEC_TEMPFILE_ONLY
531 #endif
532
533
534 /* We didn't define endianness above, so get it from OS macros.  This
535    is intended for making fat binary builds on OS X. */
536 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
537 #if defined(__BIG_ENDIAN__)
538 #define BIG_ENDIAN_HOST 1
539 #elif defined(__LITTLE_ENDIAN__)
540 #define LITTLE_ENDIAN_HOST 1
541 #else
542 #error "No endianness found"
543 #endif
544 #endif
545
546
547 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
548    ldap_start_tls_s because that is the actual symbol used in the
549    library.  winldap.h redefines it to our commonly used value,
550    thus we define our usual macro here.  */
551 #ifdef HAVE_LDAP_START_TLS_SA
552 # ifndef HAVE_LDAP_START_TLS_S
553 #  define HAVE_LDAP_START_TLS_S 1
554 # endif
555 #endif
556
557 /* Provide the es_ macro for estream.  */
558 #define GPGRT_ENABLE_ES_MACROS 1
559
560 /* Tell libgcrypt not to use its own libgpg-error implementation. */
561 #define USE_LIBGPG_ERROR 1
562
563 /* Tell Libgcrypt not to include deprecated definitions.  */
564 #define GCRYPT_NO_DEPRECATED 1
565
566 /* Our HTTP code is used in estream mode.  */
567 #define HTTP_USE_ESTREAM 1
568
569 /* Under W32 we do an explicit socket initialization, thus we need to
570    avoid the on-demand initialization which would also install an atexit
571    handler.  */
572 #define HTTP_NO_WSASTARTUP
573
574 /* Under Windows we use the gettext code from libgpg-error.  */
575 #define GPG_ERR_ENABLE_GETTEXT_MACROS
576
577 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
578 #define GPG_ERR_ENABLE_ERRNO_MACROS
579
580 #endif /*GNUPG_CONFIG_H_INCLUDED*/
581 ])
582
583
584 AM_MAINTAINER_MODE
585 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
586
587 # Checks for programs.
588 AC_MSG_NOTICE([checking for programs])
589 AC_PROG_MAKE_SET
590 AM_SANITY_CHECK
591 missing_dir=`cd $ac_aux_dir && pwd`
592 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
593 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
594 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
595 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
596 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
597 AM_SILENT_RULES
598 AC_PROG_AWK
599 AC_PROG_CC
600 AC_PROG_CPP
601 AM_PROG_CC_C_O
602 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
603   AC_MSG_ERROR([[No C-89 compiler found]])
604 fi
605 AC_PROG_INSTALL
606 AC_PROG_LN_S
607 AC_PROG_RANLIB
608 AC_CHECK_TOOL(AR, ar, :)
609 AC_PATH_PROG(PERL,"perl")
610 AC_CHECK_TOOL(WINDRES, windres, :)
611 AC_ISC_POSIX
612 AC_SYS_LARGEFILE
613 GNUPG_CHECK_USTAR
614
615
616 # We need to compile and run a program on the build machine.  A
617 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
618 # the AC archive is broken for autoconf 2.57.  Given that there is no
619 # newer version of that macro, we assume that it is also broken for
620 # autoconf 2.61 and thus we use a simple but usually sufficient
621 # approach.
622 AC_MSG_CHECKING(for cc for build)
623 if test "$cross_compiling" = "yes"; then
624   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
625 else
626   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
627 fi
628 AC_MSG_RESULT($CC_FOR_BUILD)
629 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
630
631 # We need to call this macro because other pkg-config macros are
632 # not always used.
633 PKG_PROG_PKG_CONFIG
634
635
636 try_gettext=yes
637 require_iconv=yes
638 have_dosish_system=no
639 have_w32_system=no
640 have_w32ce_system=no
641 have_android_system=no
642 use_simple_gettext=no
643 use_ldapwrapper=yes
644 mmap_needed=yes
645 case "${host}" in
646     *-mingw32*)
647         # special stuff for Windoze NT
648         ac_cv_have_dev_random=no
649         AC_DEFINE(USE_ONLY_8DOT3,1,
650                   [Set this to limit filenames to the 8.3 format])
651         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
652                   [Because the Unix gettext has too much overhead on
653                    MingW32 systems and these systems lack Posix functions,
654                    we use a simplified version of gettext])
655         have_dosish_system=yes
656         have_w32_system=yes
657         require_iconv=no
658         use_ldapwrapper=no  # Fixme: Do this only for CE.
659         case "${host}" in
660           *-mingw32ce*)
661             have_w32ce_system=yes
662             ;;
663           *)
664             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
665                       [Defined if the OS supports drive letters.])
666             ;;
667         esac
668         try_gettext="no"
669         use_simple_gettext=yes
670         mmap_needed=no
671         ;;
672     i?86-emx-os2 | i?86-*-os2*emx )
673         # OS/2 with the EMX environment
674         ac_cv_have_dev_random=no
675         AC_DEFINE(HAVE_DRIVE_LETTERS)
676         have_dosish_system=yes
677         try_gettext="no"
678         ;;
679
680     i?86-*-msdosdjgpp*)
681         # DOS with the DJGPP environment
682         ac_cv_have_dev_random=no
683         AC_DEFINE(HAVE_DRIVE_LETTERS)
684         have_dosish_system=yes
685         try_gettext="no"
686         ;;
687
688     *-*-hpux*)
689         if test -z "$GCC" ; then
690             CFLAGS="-Ae -D_HPUX_SOURCE $CFLAGS"
691         fi
692         ;;
693     *-dec-osf4*)
694         if test -z "$GCC" ; then
695             # Suppress all warnings
696             # to get rid of the unsigned/signed char mismatch warnings.
697             CFLAGS="-w $CFLAGS"
698         fi
699         ;;
700     *-dec-osf5*)
701         if test -z "$GCC" ; then
702             # Use the newer compiler `-msg_disable ptrmismatch1' to
703             # get rid of the unsigned/signed char mismatch warnings.
704             # Using this may hide other pointer mismatch warnings, but
705             # it at least lets other warning classes through
706             CFLAGS="-msg_disable ptrmismatch1 $CFLAGS"
707         fi
708         ;;
709     m68k-atari-mint)
710         ;;
711     *-linux-android*)
712         have_android_system=yes
713         # Android is fully utf-8 and we do not want to use iconv to
714         # keeps things simple
715         require_iconv=no
716         ;;
717     *)
718        ;;
719 esac
720
721 if test "$have_dosish_system" = yes; then
722    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
723              [Defined if we run on some of the PCDOS like systems
724               (DOS, Windoze. OS/2) with special properties like
725               no file modes, case insensitive file names and preferred
726               use of backslashes as directory name separators.])
727 fi
728 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
729
730 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
731
732 if test "$have_w32_system" = yes; then
733    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
734    if test "$have_w32ce_system" = yes; then
735       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
736    fi
737 fi
738 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
739 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
740
741 if test "$have_android_system" = yes; then
742    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
743 fi
744 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
745
746
747 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
748 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
749
750
751 #
752 # Checks for libraries.
753 #
754 AC_MSG_NOTICE([checking for libraries])
755
756
757 #
758 # libgpg-error is a library with error codes shared between GnuPG
759 # related projects.
760 #
761 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
762                   have_gpg_error=yes,have_gpg_error=no)
763
764
765 #
766 # Libgcrypt is our generic crypto library
767 #
768 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
769         have_libgcrypt=yes,have_libgcrypt=no)
770
771
772 #
773 # libassuan is used for IPC
774 #
775 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
776                   have_libassuan=yes,have_libassuan=no)
777 if test "$have_libassuan" = "yes"; then
778   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
779                      [version of the libassuan library])
780   show_tor_support="only .onion"
781 fi
782
783
784 #
785 # libksba is our X.509 support library
786 #
787 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
788
789
790 #
791 # libusb allows us to use the integrated CCID smartcard reader driver.
792 #
793 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
794 if test "$use_ccid_driver" = auto || test "$use_ccid_driver" = yes; then
795    case "${host}" in
796      *-mingw32*)
797        LIBUSB_NAME=
798        LIBUSB_LIBS=
799        LIBUSB_CPPFLAGS=
800        ;;
801      *-*-darwin*)
802        LIBUSB_NAME=usb-1.0
803        LIBUSB_LIBS="-Wl,-framework,CoreFoundation -Wl,-framework,IOKit"
804        ;;
805      *-*-freebsd*)
806        # FreeBSD has a native 1.0 compatible library by -lusb.
807        LIBUSB_NAME=usb
808        LIBUSB_LIBS=
809        ;;
810      *)
811        LIBUSB_NAME=usb-1.0
812        LIBUSB_LIBS=
813        ;;
814    esac
815 fi
816 if test x"$LIBUSB_NAME" != x ; then
817    AC_CHECK_LIB($LIBUSB_NAME, libusb_init,
818                 [ LIBUSB_LIBS="-l$LIBUSB_NAME $LIBUSB_LIBS"
819                   have_libusb=yes ])
820    AC_MSG_CHECKING([libusb include dir])
821    usb_incdir_found="no"
822    for _incdir in "" "/usr/include/libusb-1.0" "/usr/local/include/libusb-1.0"; do
823      _libusb_save_cppflags=$CPPFLAGS
824      if test -n "${_incdir}"; then
825        CPPFLAGS="-I${_incdir} ${CPPFLAGS}"
826      fi
827      AC_PREPROC_IFELSE([AC_LANG_SOURCE([[@%:@include <libusb.h>]])],
828      [usb_incdir=${_incdir}; usb_incdir_found="yes"], [])
829      CPPFLAGS=${_libusb_save_cppflags}
830      if test "$usb_incdir_found" = "yes"; then
831        break
832      fi
833    done
834    if test "$usb_incdir_found" = "yes"; then
835      AC_MSG_RESULT([${usb_incdir}])
836    else
837      AC_MSG_RESULT([not found])
838      usb_incdir=""
839      have_libusb=no
840      if test "$use_ccid_driver" != yes; then
841        use_ccid_driver=no
842      fi
843      LIBUSB_LIBS=""
844    fi
845
846    if test "$have_libusb" = yes; then
847      AC_DEFINE(HAVE_LIBUSB,1, [defined if libusb is available])
848    fi
849    if test x"$usb_incdir" = x; then
850      LIBUSB_CPPFLAGS=""
851    else
852      LIBUSB_CPPFLAGS="-I${usb_incdir}"
853    fi
854 fi
855 AC_SUBST(LIBUSB_LIBS)
856 AC_SUBST(LIBUSB_CPPFLAGS)
857
858 #
859 # Check wether it is necessary to link against libdl.
860 # (For example to load libpcsclite)
861 #
862 gnupg_dlopen_save_libs="$LIBS"
863 LIBS=""
864 AC_SEARCH_LIBS(dlopen, c dl,,,)
865 DL_LIBS=$LIBS
866 AC_SUBST(DL_LIBS)
867 LIBS="$gnupg_dlopen_save_libs"
868
869
870 # Checks for g10
871
872 AC_ARG_ENABLE(sqlite,
873                 AC_HELP_STRING([--disable-sqlite],
874                                [disable the use of SQLITE]),
875               try_sqlite=$enableval, try_sqlite=yes)
876
877 if test x"$use_tofu" = xyes ; then
878   if test x"$try_sqlite" = xyes ; then
879     PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $NEED_SQLITE_VERSION],
880                                  [have_sqlite=yes],
881                                  [have_sqlite=no])
882   fi
883   if test "$have_sqlite" = "yes"; then
884     :
885     AC_SUBST([SQLITE3_CFLAGS])
886     AC_SUBST([SQLITE3_LIBS])
887   else
888     use_tofu=no
889     tmp=$(echo "$SQLITE3_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
890     AC_MSG_WARN([[
891 ***
892 *** Building without SQLite support - TOFU disabled
893 ***
894 *** $tmp]])
895   fi
896 fi
897
898 AM_CONDITIONAL(SQLITE3, test "$have_sqlite" = "yes")
899
900 if test x"$use_tofu" = xyes ; then
901     AC_DEFINE(USE_TOFU, 1, [Enable to build the TOFU code])
902 fi
903
904
905 # Checks for g13
906
907 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
908 AC_DEFINE_UNQUOTED(ENCFS,
909         "${ENCFS}", [defines the filename of the encfs program])
910
911 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
912 AC_DEFINE_UNQUOTED(FUSERMOUNT,
913         "${FUSERMOUNT}", [defines the filename of the fusermount program])
914
915
916 # Checks for dirmngr
917
918
919 #
920 # Checks for symcryptrun:
921 #
922
923 # libutil has openpty() and login_tty().
924 AC_CHECK_LIB(util, openpty,
925               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
926                 AC_DEFINE(HAVE_LIBUTIL,1,
927                          [defined if libutil is available])
928              ])
929 AC_SUBST(LIBUTIL_LIBS)
930
931 # shred is used to clean temporary plain text files.
932 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
933 AC_DEFINE_UNQUOTED(SHRED,
934         "${SHRED}", [defines the filename of the shred program])
935
936
937 #
938 # Check whether the nPth library is available
939 #
940 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
941 if test "$have_npth" = "yes"; then
942   AC_DEFINE(HAVE_NPTH, 1,
943               [Defined if the New Portable Thread Library is available])
944   AC_DEFINE(USE_NPTH, 1,
945               [Defined if support for nPth is requested and nPth is available])
946 else
947   AC_MSG_WARN([[
948 ***
949 *** To support concurrent access for example in gpg-agent and the SCdaemon
950 *** we need the support of the New Portable Threads Library.
951 ***]])
952 fi
953
954
955 #
956 # NTBTLS is our TLS library.  If it is not available fallback to
957 # GNUTLS.
958 #
959 AC_ARG_ENABLE(ntbtls,
960               AC_HELP_STRING([--disable-ntbtls],
961                              [disable the use of NTBTLS as TLS library]),
962               try_ntbtls=$enableval, try_ntbtls=yes)
963 if test x"$try_ntbtls" = xyes ; then
964   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
965                  [have_ntbtls=yes],[have_ntbtls=no])
966 fi
967 if test "$have_ntbtls" = yes ; then
968    use_tls_library=ntbtls
969    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
970 else
971   AC_ARG_ENABLE(gnutls,
972                 AC_HELP_STRING([--disable-gnutls],
973                                [disable GNUTLS as fallback TLS library]),
974                 try_gnutls=$enableval, try_gnutls=yes)
975   if test x"$try_gnutls" = xyes ; then
976     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
977                                    [have_gnutls=yes],
978                                    [have_gnutls=no])
979   fi
980   if test "$have_gnutls" = "yes"; then
981     AC_SUBST([LIBGNUTLS_CFLAGS])
982     AC_SUBST([LIBGNUTLS_LIBS])
983     use_tls_library=gnutls
984     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
985   else
986     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
987     AC_MSG_WARN([[
988 ***
989 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
990 ***
991 *** $tmp]])
992   fi
993 fi
994
995 #
996 # Allow to set a fixed trust store file for system provided certificates.
997 #
998 AC_ARG_WITH([default-trust-store-file],
999             [AC_HELP_STRING([--with-default-trust-store-file=FILE],
1000                             [Use FILE as system trust store])],
1001             default_trust_store_file="$withval",
1002             default_trust_store_file="")
1003 if test x"$default_trust_store_file" = xno;then
1004   default_trust_store_file=""
1005 fi
1006 if test x"$default_trust_store_file" != x ; then
1007   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
1008     ["$default_trust_store_file"], [Use as default system trust store file])
1009 fi
1010
1011
1012 AC_MSG_NOTICE([checking for networking options])
1013
1014 #
1015 # Must check for network library requirements before doing link tests
1016 # for ldap, for example. If ldap libs are static (or dynamic and without
1017 # ELF runtime link paths), then link will fail and LDAP support won't
1018 # be detected.
1019 #
1020 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
1021         [NETLIBS="-lnsl $NETLIBS"]))
1022 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
1023         [NETLIBS="-lsocket $NETLIBS"]))
1024
1025
1026 #
1027 # Check standard resolver functions.
1028 #
1029 if test "$build_dirmngr" = "yes"; then
1030   _dns_save_libs=$LIBS
1031   LIBS=""
1032
1033   # Find the system resolver which can always be enabled with
1034   # the dirmngr option --standard-resolver.
1035
1036   # the double underscore thing is a glibc-ism?
1037   AC_SEARCH_LIBS(res_query,resolv bind,,
1038                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
1039   AC_SEARCH_LIBS(dn_expand,resolv bind,,
1040                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
1041
1042   # macOS renames dn_skipname into res_9_dn_skipname in <resolv.h>,
1043   # and for some reason fools us into believing we don't need
1044   # -lresolv even if we do.  Since the test program checking for the
1045   # symbol does not include <resolv.h>, we need to check for the
1046   # renamed symbol explicitly.
1047   AC_SEARCH_LIBS(res_9_dn_skipname,resolv bind,,
1048       AC_SEARCH_LIBS(dn_skipname,resolv bind,,
1049           AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no)))
1050
1051   if test x"$have_resolver" != xno ; then
1052
1053       # Make sure that the BIND 4 resolver interface is workable before
1054       # enabling any code that calls it.  At some point I'll rewrite the
1055       # code to use the BIND 8 resolver API.
1056       # We might also want to use libdns instead.
1057
1058     AC_MSG_CHECKING([whether the resolver is usable])
1059     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1060 #include <netinet/in.h>
1061 #include <arpa/nameser.h>
1062 #include <resolv.h>]],
1063 [[unsigned char answer[PACKETSZ];
1064   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1065   dn_skipname(0,0);
1066   dn_expand(0,0,0,0,0);
1067 ]])],have_resolver=yes,have_resolver=no)
1068     AC_MSG_RESULT($have_resolver)
1069
1070     # This is Apple-specific and somewhat bizarre as they changed the
1071     # define in bind 8 for some reason.
1072
1073     if test x"$have_resolver" != xyes ; then
1074       AC_MSG_CHECKING(
1075            [whether I can make the resolver usable with BIND_8_COMPAT])
1076       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
1077 #include <sys/types.h>
1078 #include <netinet/in.h>
1079 #include <arpa/nameser.h>
1080 #include <resolv.h>]],
1081 [[unsigned char answer[PACKETSZ];
1082   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1083   dn_skipname(0,0); dn_expand(0,0,0,0,0);
1084 ]])],[have_resolver=yes ; need_compat=yes])
1085       AC_MSG_RESULT($have_resolver)
1086     fi
1087   fi
1088
1089   if test x"$have_resolver" = xyes ; then
1090     AC_DEFINE(HAVE_SYSTEM_RESOLVER,1,[The system's resolver is usable.])
1091     DNSLIBS="$DNSLIBS $LIBS"
1092     if test x"$need_compat" = xyes ; then
1093       AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
1094     fi
1095     if test "$use_libdns" = yes; then
1096      show_tor_support=yes
1097     fi
1098   elif test "$use_libdns" = yes; then
1099     show_tor_support=yes
1100   else
1101     AC_MSG_WARN([[
1102 ***
1103 *** The system's DNS resolver is not usable.
1104 *** Dirmngr functionality is limited.
1105 ***]])
1106     show_tor_support="${show_tor_support} (no system resolver)"
1107   fi
1108
1109   if test "$have_w32_system" = yes; then
1110     if test "$use_libdns" = yes; then
1111       DNSLIBS="$DNSLIBS -liphlpapi"
1112     fi
1113   fi
1114
1115   LIBS=$_dns_save_libs
1116 fi
1117
1118 AC_SUBST(DNSLIBS)
1119
1120
1121 #
1122 # Check for LDAP
1123 #
1124 # Note that running the check changes the variable
1125 # gnupg_have_ldap from "n/a" to "no" or "yes".
1126
1127 AC_ARG_ENABLE(ldap,
1128     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1129     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1130
1131 if test "$gnupg_have_ldap" != "no" ; then
1132   if test "$build_dirmngr" = "yes" ; then
1133      GNUPG_CHECK_LDAP($NETLIBS)
1134      AC_CHECK_LIB(lber, ber_free,
1135                   [ LBER_LIBS="$LBER_LIBS -llber"
1136                     AC_DEFINE(HAVE_LBER,1,
1137                              [defined if liblber is available])
1138                     have_lber=yes
1139                  ])
1140   fi
1141 fi
1142 AC_SUBST(LBER_LIBS)
1143 if test "$gnupg_have_ldap" = "no"; then
1144     AC_MSG_WARN([[
1145 ***
1146 *** Building without LDAP support.
1147 *** No CRL access or X.509 certificate search available.
1148 ***]])
1149 fi
1150
1151 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1152 if test "$gnupg_have_ldap" = yes ; then
1153   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1154 else
1155  use_ldapwrapper=no
1156 fi
1157
1158 if test "$use_ldapwrapper" = yes; then
1159    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1160 fi
1161 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1162
1163
1164
1165
1166 #
1167 # Check for sendmail
1168 #
1169 # This isn't necessarily sendmail itself, but anything that gives a
1170 # sendmail-ish interface to the outside world.  That includes Exim,
1171 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1172 AC_ARG_WITH(mailprog,
1173       AC_HELP_STRING([--with-mailprog=NAME],
1174                      [use "NAME -t" for mail transport]),
1175              ,with_mailprog=yes)
1176 if test x"$with_mailprog" = xyes ; then
1177     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1178 elif test x"$with_mailprog" != xno ; then
1179     AC_MSG_CHECKING([for a mail transport program])
1180     AC_SUBST(SENDMAIL,$with_mailprog)
1181     AC_MSG_RESULT($with_mailprog)
1182 fi
1183
1184
1185 #
1186 # Construct a printable name of the OS
1187 #
1188 case "${host}" in
1189     *-mingw32ce*)
1190         PRINTABLE_OS_NAME="W32CE"
1191         ;;
1192     *-mingw32*)
1193         PRINTABLE_OS_NAME="MingW32"
1194         ;;
1195     *-*-cygwin*)
1196         PRINTABLE_OS_NAME="Cygwin"
1197         ;;
1198     i?86-emx-os2 | i?86-*-os2*emx )
1199         PRINTABLE_OS_NAME="OS/2"
1200         ;;
1201     i?86-*-msdosdjgpp*)
1202         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1203         try_dynload=no
1204         ;;
1205     *-linux*)
1206         PRINTABLE_OS_NAME="GNU/Linux"
1207         ;;
1208     *)
1209         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1210         ;;
1211 esac
1212 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1213                    [A human readable text with the name of the OS])
1214
1215
1216 #
1217 # Checking for iconv
1218 #
1219 if test "$require_iconv" = yes; then
1220   AM_ICONV
1221 else
1222   LIBICONV=
1223   LTLIBICONV=
1224   AC_SUBST(LIBICONV)
1225   AC_SUBST(LTLIBICONV)
1226 fi
1227
1228
1229 #
1230 # Check for gettext
1231 #
1232 # This is "GNU gnupg" - The project-id script from gettext
1233 #                       needs this string
1234 #
1235 AC_MSG_NOTICE([checking for gettext])
1236 AM_PO_SUBDIRS
1237 AM_GNU_GETTEXT_VERSION([0.17])
1238 if test "$try_gettext" = yes; then
1239   AM_GNU_GETTEXT([external],[need-ngettext])
1240
1241   # gettext requires some extra checks.  These really should be part of
1242   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1243   # function checks to here.
1244
1245   AC_CHECK_FUNCS(strchr)
1246 else
1247   USE_NLS=no
1248   USE_INCLUDED_LIBINTL=no
1249   BUILD_INCLUDED_LIBINTL=no
1250   POSUB=po
1251   AC_SUBST(USE_NLS)
1252   AC_SUBST(USE_INCLUDED_LIBINTL)
1253   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1254   AC_SUBST(POSUB)
1255 fi
1256
1257 # We use HAVE_LANGINFO_CODESET in a couple of places.
1258 AM_LANGINFO_CODESET
1259
1260 # Checks required for our use of locales
1261 gt_LC_MESSAGES
1262
1263
1264 #
1265 # SELinux support
1266 #
1267 if test "$selinux_support" = yes ; then
1268   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1269 fi
1270
1271
1272 #
1273 # Checks for header files.
1274 #
1275 AC_MSG_NOTICE([checking for header files])
1276 AC_HEADER_STDC
1277 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1278                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h     \
1279                   stdint.h signal.h util.h libutil.h termios.h \
1280                   ucred.h])
1281
1282 AC_HEADER_TIME
1283
1284
1285 #
1286 # Checks for typedefs, structures, and compiler characteristics.
1287 #
1288 AC_MSG_NOTICE([checking for system characteristics])
1289 AC_C_CONST
1290 AC_C_INLINE
1291 AC_C_VOLATILE
1292 AC_TYPE_SIZE_T
1293 AC_TYPE_MODE_T
1294 AC_TYPE_SIGNAL
1295 AC_DECL_SYS_SIGLIST
1296
1297 gl_HEADER_SYS_SOCKET
1298 gl_TYPE_SOCKLEN_T
1299
1300 AC_SEARCH_LIBS([inet_addr], [nsl])
1301
1302 AC_ARG_ENABLE(endian-check,
1303               AC_HELP_STRING([--disable-endian-check],
1304               [disable the endian check and trust the OS provided macros]),
1305               endiancheck=$enableval,endiancheck=yes)
1306
1307 if test x"$endiancheck" = xyes ; then
1308   GNUPG_CHECK_ENDIAN
1309 fi
1310
1311 # fixme: we should get rid of the byte type
1312 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1313 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1314 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1315 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1316 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1317
1318 AC_CHECK_SIZEOF(unsigned short)
1319 AC_CHECK_SIZEOF(unsigned int)
1320 AC_CHECK_SIZEOF(unsigned long)
1321 AC_CHECK_SIZEOF(unsigned long long)
1322 AC_HEADER_TIME
1323 AC_CHECK_SIZEOF(time_t,,[[
1324 #include <stdio.h>
1325 #if TIME_WITH_SYS_TIME
1326 # include <sys/time.h>
1327 # include <time.h>
1328 #else
1329 # if HAVE_SYS_TIME_H
1330 #  include <sys/time.h>
1331 # else
1332 #  include <time.h>
1333 # endif
1334 #endif
1335 ]])
1336 GNUPG_TIME_T_UNSIGNED
1337
1338
1339 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1340    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1341    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1342     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1343 fi
1344
1345
1346 #
1347 # Checks for library functions.
1348 #
1349 AC_MSG_NOTICE([checking for library functions])
1350 AC_CHECK_DECLS(getpagesize)
1351 AC_FUNC_FSEEKO
1352 AC_FUNC_VPRINTF
1353 AC_FUNC_FORK
1354 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1355 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1356 AC_CHECK_FUNCS([setenv unsetenv fcntl ftruncate inet_ntop])
1357 AC_CHECK_FUNCS([canonicalize_file_name])
1358 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1359 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1360 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1361 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1362 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1363                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1364                 flockfile funlockfile getpwnam getpwuid \
1365                 getenv inet_pton strpbrk])
1366
1367 # On some systems (e.g. Solaris) nanosleep requires linking to librl.
1368 # Given that we use nanosleep only as an optimization over a select
1369 # based wait function we want it only if it is available in libc.
1370 _save_libs="$LIBS"
1371 AC_SEARCH_LIBS([nanosleep], [],
1372                [AC_DEFINE(HAVE_NANOSLEEP,1,
1373                 [Define to 1 if you have the `nanosleep' function in libc.])])
1374 LIBS="$_save_libs"
1375
1376
1377 # See whether libc supports the Linux inotify interface
1378 case "${host}" in
1379     *-*-linux*)
1380         AC_CHECK_FUNCS([inotify_init])
1381         ;;
1382 esac
1383
1384
1385 if test "$have_android_system" = yes; then
1386    # On Android ttyname is a stub but prints an error message.
1387    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1388              [Defined if ttyname does not work properly])
1389 fi
1390
1391 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1392
1393 # Dirmngr requires mmap on Unix systems.
1394 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1395   AC_MSG_ERROR([[Sorry, the current implemenation requires mmap.]])
1396 fi
1397
1398
1399 #
1400 # Check for the getsockopt SO_PEERCRED, etc.
1401 #
1402 AC_CHECK_MEMBERS([struct ucred.pid, struct ucred.cr_pid, struct sockpeercred.pid], [], [], [#include <sys/types.h>
1403 #include <sys/socket.h> ])
1404
1405 # (Open)Solaris
1406 AC_CHECK_FUNCS([getpeerucred])
1407
1408
1409 #
1410 # W32 specific test
1411 #
1412 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1413
1414 #
1415 # Sanity check regex.  Tests adapted from mutt.
1416 #
1417 AC_MSG_CHECKING([whether regular expression support is requested])
1418 AC_ARG_ENABLE(regex,
1419   AC_HELP_STRING([--disable-regex],
1420     [do not handle regular expressions in trust signatures]),
1421   use_regex=$enableval, use_regex=yes)
1422 AC_MSG_RESULT($use_regex)
1423
1424 if test "$use_regex" = yes ; then
1425   _cppflags="${CPPFLAGS}"
1426   _ldflags="${LDFLAGS}"
1427   AC_ARG_WITH(regex,
1428      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1429       [
1430       if test -d "$withval" ; then
1431         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1432         LDFLAGS="${LDFLAGS} -L$withval/lib"
1433       fi
1434       ],withval="")
1435
1436   # Does the system have regex functions at all?
1437   AC_SEARCH_LIBS([regcomp], [regex])
1438   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1439
1440   if test $gnupg_cv_have_regex = no; then
1441     use_regex=no
1442   else
1443     if test x"$cross_compiling" = xyes; then
1444       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1445     else
1446       AC_CACHE_CHECK([whether your system's regexp library is broken],
1447        [gnupg_cv_regex_broken],
1448        AC_TRY_RUN([
1449 #include <unistd.h>
1450 #include <regex.h>
1451 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1452        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1453
1454       if test $gnupg_cv_regex_broken = yes; then
1455         AC_MSG_WARN([your regex is broken - disabling regex use])
1456         use_regex=no
1457       fi
1458     fi
1459   fi
1460   CPPFLAGS="${_cppflags}"
1461   LDFLAGS="${_ldflags}"
1462 fi
1463
1464 if test "$use_regex" != yes ; then
1465   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1466 fi
1467 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1468
1469
1470
1471 #
1472 # Do we have zlib? Must do it here because Solaris failed
1473 # when compiling a conftest (due to the "-lz" from LIBS).
1474 # Note that we combine zlib and bzlib2 in ZLIBS.
1475 #
1476 if test "$use_zip" = yes ; then
1477   _cppflags="${CPPFLAGS}"
1478   _ldflags="${LDFLAGS}"
1479   AC_ARG_WITH(zlib,
1480     [  --with-zlib=DIR         use libz in DIR],[
1481       if test -d "$withval"; then
1482         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1483         LDFLAGS="${LDFLAGS} -L$withval/lib"
1484       fi
1485     ])
1486
1487   AC_CHECK_HEADER(zlib.h,
1488      AC_CHECK_LIB(z, deflateInit2_,
1489        [
1490        ZLIBS="-lz"
1491        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1492        ],
1493        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1494        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1495 fi
1496
1497
1498 #
1499 # Check whether we can support bzip2
1500 #
1501 if test "$use_bzip2" = yes ; then
1502   _cppflags="${CPPFLAGS}"
1503   _ldflags="${LDFLAGS}"
1504   AC_ARG_WITH(bzip2,
1505      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1506       [
1507       if test -d "$withval" ; then
1508         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1509         LDFLAGS="${LDFLAGS} -L$withval/lib"
1510       fi
1511       ],withval="")
1512
1513   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1514   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1515   # woefully out of date.
1516   if test "$withval" != no ; then
1517      AC_CHECK_HEADER(bzlib.h,
1518         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1519           [
1520           have_bz2=yes
1521           ZLIBS="$ZLIBS -lbz2"
1522           AC_DEFINE(HAVE_BZIP2,1,
1523                   [Defined if the bz2 compression library is available])
1524           ],
1525           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1526           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1527   fi
1528 fi
1529 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1530 AC_SUBST(ZLIBS)
1531
1532
1533 # Check for readline support
1534 GNUPG_CHECK_READLINE
1535
1536
1537 if test "$development_version" = yes; then
1538     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1539             [Defined if this is not a regular release])
1540 fi
1541
1542 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1543
1544 GNUPG_CHECK_GNUMAKE
1545
1546 # Add some extra libs here so that previous tests don't fail for
1547 # mysterious reasons - the final link step should bail out.
1548 # W32SOCKLIBS is also defined so that if can be used for tools not
1549 # requiring any network stuff but linking to code in libcommon which
1550 # tracks in winsock stuff (e.g. init_common_subsystems).
1551 if test "$have_w32_system" = yes; then
1552    if test "$have_w32ce_system" = yes; then
1553      W32SOCKLIBS="-lws2"
1554    else
1555      W32SOCKLIBS="-lws2_32"
1556    fi
1557    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1558 fi
1559
1560 AC_SUBST(NETLIBS)
1561 AC_SUBST(W32SOCKLIBS)
1562
1563 #
1564 # Setup gcc specific options
1565 #
1566 USE_C99_CFLAGS=
1567 AC_MSG_NOTICE([checking for cc features])
1568 if test "$GCC" = yes; then
1569     mycflags=
1570     mycflags_save=$CFLAGS
1571
1572     # Check whether gcc does not emit a diagnositc for unknow -Wno-*
1573     # options.  This is the case for gcc >= 4.6
1574     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1575     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1576 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1577 #kickerror
1578 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1579     AC_MSG_RESULT($_gcc_silent_wno)
1580
1581     # Note that it is okay to use CFLAGS here because these are just
1582     # warning options and the user should have a chance of overriding
1583     # them.
1584     if test "$USE_MAINTAINER_MODE" = "yes"; then
1585         mycflags="$mycflags -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1586         mycflags="$mycflags -Wformat -Wno-format-y2k -Wformat-security"
1587         if test x"$_gcc_silent_wno" = xyes ; then
1588           _gcc_wopt=yes
1589         else
1590           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1591           CFLAGS="-Wno-missing-field-initializers"
1592           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1593                             [_gcc_wopt=yes],[_gcc_wopt=no])
1594           AC_MSG_RESULT($_gcc_wopt)
1595         fi
1596         if test x"$_gcc_wopt" = xyes ; then
1597           mycflags="$mycflags -W -Wno-sign-compare"
1598           mycflags="$mycflags -Wno-missing-field-initializers"
1599         fi
1600
1601         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1602         CFLAGS="-Wdeclaration-after-statement"
1603         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1604         AC_MSG_RESULT($_gcc_wopt)
1605         if test x"$_gcc_wopt" = xyes ; then
1606           mycflags="$mycflags -Wdeclaration-after-statement"
1607         fi
1608
1609         AC_MSG_CHECKING([if gcc supports -Wlogical-op and -Wvla])
1610         CFLAGS="-Wlogical-op -Wvla"
1611         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1612         AC_MSG_RESULT($_gcc_wopt)
1613         if test x"$_gcc_wopt" = xyes ; then
1614           mycflags="$mycflags -Wlogical-op -Wvla"
1615         fi
1616
1617     else
1618         mycflags="$mycflags -Wall"
1619     fi
1620
1621     if test x"$_gcc_silent_wno" = xyes ; then
1622       _gcc_psign=yes
1623     else
1624       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1625       CFLAGS="-Wno-pointer-sign"
1626       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1627                         [_gcc_psign=yes],[_gcc_psign=no])
1628       AC_MSG_RESULT($_gcc_psign)
1629     fi
1630     if test x"$_gcc_psign" = xyes ; then
1631        mycflags="$mycflags -Wno-pointer-sign"
1632     fi
1633
1634     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1635     CFLAGS="-Wpointer-arith"
1636     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1637     AC_MSG_RESULT($_gcc_psign)
1638     if test x"$_gcc_psign" = xyes ; then
1639        mycflags="$mycflags -Wpointer-arith"
1640     fi
1641
1642     CFLAGS="$mycflags $mycflags_save"
1643     if test "$use_libdns" = yes; then
1644        # dirmngr/dns.{c,h} require C99 and GNU extensions.  */
1645        USE_C99_CFLAGS="-std=gnu99"
1646     fi
1647 fi
1648
1649 AC_SUBST(USE_C99_CFLAGS)
1650
1651
1652 #
1653 # This is handy for debugging so the compiler doesn't rearrange
1654 # things and eliminate variables.
1655 #
1656 AC_ARG_ENABLE(optimization,
1657    AC_HELP_STRING([--disable-optimization],
1658                   [disable compiler optimization]),
1659                   [if test $enableval = no ; then
1660                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1661                    fi])
1662
1663 #
1664 # We do not want support for the GNUPG_BUILDDIR environment variable
1665 # in a released version.  However, our regression tests suite requires
1666 # this and thus we build with support for it during "make distcheck".
1667 # This configure option implements this along with the top Makefile's
1668 # AM_DISTCHECK_CONFIGURE_FLAGS.
1669 #
1670 gnupg_builddir_envvar=no
1671 AC_ARG_ENABLE(gnupg-builddir-envvar,,
1672               gnupg_builddir_envvar=$enableval)
1673 if test x"$gnupg_builddir_envvar" = x"yes"; then
1674    AC_DEFINE(ENABLE_GNUPG_BUILDDIR_ENVVAR, 1,
1675       [This is only used with "make distcheck"])
1676 fi
1677
1678 #
1679 # Add user CFLAGS.
1680 #
1681 CFLAGS="$CFLAGS $CFLAGS_werror"
1682
1683 #
1684 # Decide what to build
1685 #
1686
1687 build_scdaemon_extra=""
1688 if test "$build_scdaemon" = "yes"; then
1689   if test $have_libusb = no; then
1690      build_scdaemon_extra="without internal CCID driver"
1691   fi
1692   if test -n "$build_scdaemon_extra"; then
1693      build_scdaemon_extra="(${build_scdaemon_extra})"
1694   fi
1695 fi
1696
1697
1698 #
1699 # Set variables for use by automake makefiles.
1700 #
1701 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1702 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1703 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1704 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1705 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1706 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1707 AM_CONDITIONAL(BUILD_TOOLS,       test "$build_tools" = "yes")
1708 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1709 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1710 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1711 AM_CONDITIONAL(BUILD_WKS_TOOLS,   test "$build_wks_tools" = "yes")
1712
1713 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1714 AM_CONDITIONAL(NO_TRUST_MODELS,     test "$use_trust_models" = no)
1715 AM_CONDITIONAL(USE_TOFU,            test "$use_tofu" = yes)
1716
1717 #
1718 # Set some defines for use gpgconf.
1719 #
1720 if test "$build_gpg" = yes ; then
1721     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1722 fi
1723 if test "$build_gpgsm" = yes ; then
1724     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1725 fi
1726 if test "$build_agent" = yes ; then
1727     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1728 fi
1729 if test "$build_scdaemon" = yes ; then
1730     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1731 fi
1732 if test "$build_dirmngr" = yes ; then
1733     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if SCDAEMON is to be build])
1734 fi
1735 if test "$build_g13" = yes ; then
1736     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1737 fi
1738
1739
1740 #
1741 # Define Name strings
1742 #
1743 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1744
1745 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1746 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1747
1748 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1749 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1750
1751 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1752 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1753                                         [The displayed name of gpg-agent])
1754
1755 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1756 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1757                                        [The displayed name of scdaemon])
1758
1759 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1760 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1761                                       [The displayed name of dirmngr])
1762
1763 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1764 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1765
1766 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1767 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1768                                       [The displayed name of gpgconf])
1769
1770 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1771
1772 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1773                    [The name of the agent socket])
1774 AC_DEFINE_UNQUOTED(GPG_AGENT_EXTRA_SOCK_NAME, "S.gpg-agent.extra",
1775                    [The name of the agent socket for remote access])
1776 AC_DEFINE_UNQUOTED(GPG_AGENT_BROWSER_SOCK_NAME, "S.gpg-agent.browser",
1777                    [The name of the agent socket for browsers])
1778 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1779                    [The name of the agent socket for ssh])
1780 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1781                    [The name of the dirmngr info envvar])
1782 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1783                    [The name of the SCdaemon socket])
1784 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1785                    [The name of the dirmngr socket])
1786 AC_DEFINE_UNQUOTED(DIRMNGR_DEFAULT_KEYSERVER,
1787                    "hkps://hkps.pool.sks-keyservers.net",
1788       [The default keyserver for dirmngr to use, if none is explicitly given])
1789
1790 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1791
1792 if test "$have_w32_system" = yes; then
1793   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "\\\\Software\\\\GNU\\\\GnuPG",
1794                      [The directory part of the W32 registry keys])
1795 fi
1796
1797
1798 #
1799 # Provide information about the build.
1800 #
1801 BUILD_REVISION="mym4_revision"
1802 AC_SUBST(BUILD_REVISION)
1803 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1804                    [GIT commit id revision used to build this package])
1805
1806 changequote(,)dnl
1807 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1808 changequote([,])dnl
1809 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1810 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1811 AC_SUBST(BUILD_VERSION)
1812 AC_SUBST(BUILD_FILEVERSION)
1813
1814 AC_ARG_ENABLE([build-timestamp],
1815   AC_HELP_STRING([--enable-build-timestamp],
1816                  [set an explicit build timestamp for reproducibility.
1817                   (default is the current time in ISO-8601 format)]),
1818      [if test "$enableval" = "yes"; then
1819         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1820       else
1821         BUILD_TIMESTAMP="$enableval"
1822       fi
1823       BUILD_HOSTNAME="$ac_hostname"],
1824      [BUILD_TIMESTAMP="<none>"
1825       BUILD_HOSTNAME="<anon>"])
1826 AC_SUBST(BUILD_TIMESTAMP)
1827 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1828                    [The time this package was configured for a build])
1829 AC_SUBST(BUILD_HOSTNAME)
1830
1831
1832 #
1833 # Print errors here so that they are visible all
1834 # together and the user can acquire them all together.
1835 #
1836 die=no
1837 if test "$have_gpg_error" = "no"; then
1838    die=yes
1839    AC_MSG_NOTICE([[
1840 ***
1841 *** You need libgpg-error to build this program.
1842 **  This library is for example available at
1843 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1844 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1845 ***]])
1846 fi
1847 if test "$have_libgcrypt" = "no"; then
1848    die=yes
1849    AC_MSG_NOTICE([[
1850 ***
1851 *** You need libgcrypt to build this program.
1852 **  This library is for example available at
1853 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1854 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1855 ***]])
1856 fi
1857 if test "$have_libassuan" = "no"; then
1858    die=yes
1859    AC_MSG_NOTICE([[
1860 ***
1861 *** You need libassuan to build this program.
1862 *** This library is for example available at
1863 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1864 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1865 ***]])
1866 fi
1867 if test "$have_ksba" = "no"; then
1868     die=yes
1869     AC_MSG_NOTICE([[
1870 ***
1871 *** You need libksba to build this program.
1872 *** This library is for example available at
1873 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1874 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1875 ***]])
1876 fi
1877 if test "$gnupg_have_ldap" = yes; then
1878   if test "$have_w32ce_system" = yes; then
1879     AC_MSG_NOTICE([[
1880 *** Note that CeGCC might be broken, a package fixing this is:
1881 ***    http://files.kolab.org/local/windows-ce/
1882 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1883 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1884 ***]])
1885    fi
1886 fi
1887 if test "$have_npth" = "no"; then
1888     die=yes
1889     AC_MSG_NOTICE([[
1890 ***
1891 *** It is now required to build with support for the
1892 *** New Portable Threads Library (nPth). Please install this
1893 *** library first.  The library is for example available at
1894 ***   ftp://ftp.gnupg.org/gcrypt/npth/
1895 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1896 ***]])
1897 fi
1898
1899 if test "$require_iconv" = yes; then
1900   if test "$am_func_iconv" != yes; then
1901     die=yes
1902     AC_MSG_NOTICE([[
1903 ***
1904 *** The system does not provide a working iconv function.  Please
1905 *** install a suitable library; for example GNU Libiconv which is
1906 *** available at:
1907 ***   http://ftp.gnu.org/gnu/libiconv/
1908 ***]])
1909   fi
1910 fi
1911
1912 if test "$use_ccid_driver" = yes; then
1913   if test "$have_libusb" != yes; then
1914     die=yes
1915     AC_MSG_NOTICE([[
1916 ***
1917 *** You need libusb to build the internal ccid driver.  Please
1918 *** install a libusb suitable for your system.
1919 ***]])
1920   fi
1921 fi
1922
1923 if test "$die" = "yes"; then
1924     AC_MSG_ERROR([[
1925 ***
1926 *** Required libraries not found. Please consult the above messages
1927 *** and install them before running configure again.
1928 ***]])
1929 fi
1930
1931
1932
1933 AC_CONFIG_FILES([ m4/Makefile
1934 Makefile
1935 po/Makefile.in
1936 common/Makefile
1937 common/w32info-rc.h
1938 kbx/Makefile
1939 g10/Makefile
1940 sm/Makefile
1941 agent/Makefile
1942 scd/Makefile
1943 g13/Makefile
1944 dirmngr/Makefile
1945 tools/gpg-zip
1946 tools/Makefile
1947 doc/Makefile
1948 tests/Makefile
1949 tests/gpgscm/Makefile
1950 tests/openpgp/Makefile
1951 tests/migrations/Makefile
1952 tests/gpgsm/Makefile
1953 tests/gpgme/Makefile
1954 tests/pkits/Makefile
1955 g10/gpg.w32-manifest
1956 ])
1957
1958
1959 AC_OUTPUT
1960
1961
1962 echo "
1963         GnuPG v${VERSION} has been configured as follows:
1964
1965         Revision:  mym4_revision  (mym4_revision_dec)
1966         Platform:  $PRINTABLE_OS_NAME ($host)
1967
1968         OpenPGP:   $build_gpg
1969         S/MIME:    $build_gpgsm
1970         Agent:     $build_agent
1971         Smartcard: $build_scdaemon $build_scdaemon_extra
1972         G13:       $build_g13
1973         Dirmngr:   $build_dirmngr
1974         Gpgtar:    $build_gpgtar
1975         WKS tools: $build_wks_tools
1976
1977         Protect tool:      $show_gnupg_protect_tool_pgm
1978         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
1979         Default agent:     $show_gnupg_agent_pgm
1980         Default pinentry:  $show_gnupg_pinentry_pgm
1981         Default scdaemon:  $show_gnupg_scdaemon_pgm
1982         Default dirmngr:   $show_gnupg_dirmngr_pgm
1983
1984         Dirmngr auto start:  $dirmngr_auto_start
1985         Readline support:    $gnupg_cv_have_readline
1986         LDAP support:        $gnupg_have_ldap
1987         TLS support:         $use_tls_library
1988         TOFU support:        $use_tofu
1989         Tor support:         $show_tor_support
1990 "
1991 if test x"$use_regex" != xyes ; then
1992 echo "
1993         Warning: No regular expression support available.
1994                  OpenPGP trust signatures won't work.
1995                  gpg-check-pattern will not be built.
1996 "
1997 fi
1998 if test "x${gpg_config_script_warn}" != x; then
1999 cat <<G10EOF
2000         Warning: Mismatches between the target platform and the
2001                  to be used libraries have been detected for:
2002                   ${gpg_config_script_warn}
2003                  Please check above for more warning messages.
2004
2005 G10EOF
2006 fi