* acinclude.m4 (GNUPG_CHECK_ENDIAN): When crosscompiling assume
[gnupg.git] / configure.ac
1 dnl Configure.ac script for GnuPG
2 dnl Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 dnl               2003 Free Software Foundation, Inc.
4 dnl
5 dnl This file is part of GnuPG.
6 dnl
7 dnl GnuPG is free software; you can redistribute it and/or modify
8 dnl it under the terms of the GNU General Public License as published by
9 dnl the Free Software Foundation; either version 2 of the License, or
10 dnl (at your option) any later version.
11 dnl 
12 dnl GnuPG is distributed in the hope that it will be useful,
13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 dnl GNU General Public License for more details.
16 dnl 
17 dnl You should have received a copy of the GNU General Public License
18 dnl along with this program; if not, write to the Free Software
19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20 dnl
21 dnl (Process this file with autoconf to produce a configure script.)
22 dnlAC_REVISION($Revision$)dnl
23
24 AC_PREREQ(2.52)
25
26 # Remember to change the version number immediately *after* a release
27 # and remove the "-cvs" or "rc" suffix immediately *before* a release.
28 AC_INIT(gnupg, 1.3.2-cvs, bug-gnupg@gnu.org)
29 # Set development_version to yes if the minor number is odd or you
30 # feel that the default check for a development version is not
31 # sufficient.
32 development_version=yes
33
34 ALL_LINGUAS="de"
35
36 PACKAGE=$PACKAGE_NAME
37 VERSION=$PACKAGE_VERSION
38
39 AC_CONFIG_AUX_DIR(scripts)
40 AC_CONFIG_SRCDIR(g10/g10.c)
41 AC_CANONICAL_TARGET()
42 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
43 AM_CONFIG_HEADER(config.h)
44
45 AC_SUBST(PACKAGE)
46 AC_SUBST(VERSION)
47 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
48 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
49 AC_DEFINE(_GNU_SOURCE,1,[Some tests rely on this (stpcpy) and it should be used for new programs anyway])
50
51 dnl
52 dnl  Check for random module options
53 dnl
54 AC_MSG_CHECKING([which random module to use])
55 AC_ARG_ENABLE(static-rnd,
56     [  --enable-static-rnd=[egd|unix|linux|auto]  ],
57 [use_static_rnd=$enableval], [use_static_rnd=default] )
58
59 if test "$use_static_rnd" = no; then
60     use_static_rnd=default
61 fi
62
63 case "$use_static_rnd" in
64     egd | linux | unix | default )
65       AC_MSG_RESULT($use_static_rnd)
66       ;;
67     auto )
68       AC_MSG_RESULT(automagically selected at runtime)
69       ;;
70     * )
71       AC_MSG_RESULT(invalid argument)
72       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
73       ;;
74 esac
75
76 AC_ARG_WITH(egd-socket,
77     [  --with-egd-socket=NAME  use NAME for the EGD socket],
78             egd_socket_name="$withval", egd_socket_name="" )
79 AC_DEFINE_UNQUOTED(EGD_SOCKET_NAME, "$egd_socket_name",
80                    [Define if you don't want the default EGD socket name.
81                     For details see cipher/rndegd.c])
82
83
84 dnl
85 dnl See whether the user wants to disable checking for /dev/random
86
87 AC_MSG_CHECKING([whether use of /dev/random is requested])
88 AC_ARG_ENABLE(dev-random,
89 [  --disable-dev-random    disable the use of dev random],
90     try_dev_random=$enableval, try_dev_random=yes)
91 AC_MSG_RESULT($try_dev_random)
92
93
94 dnl
95 dnl  Check other options
96 dnl
97
98 AC_MSG_CHECKING([whether assembler modules are requested])
99 AC_ARG_ENABLE(asm,
100 [  --disable-asm           do not use assembler modules],
101      try_asm_modules=$enableval, try_asm_modules=yes)
102 AC_MSG_RESULT($try_asm_modules)
103
104 AC_MSG_CHECKING([whether memory guard is requested])
105 AC_ARG_ENABLE(m-guard,
106     [  --enable-m-guard        enable memory guard facility],
107     use_m_guard=$enableval, use_m_guard=no)
108 AC_MSG_RESULT($use_m_guard)
109 if test "$use_m_guard" = yes ; then
110     AC_DEFINE(M_GUARD,1,[Define to use the (obsolete) malloc guarding feature])
111 fi
112
113 dnl See if we are disabling any algorithms or features for a smaller
114 dnl binary
115
116 try_dynload=no
117
118 use_idea=yes
119 use_cast5=yes
120 use_blowfish=yes
121 use_aes=yes
122 use_twofish=yes
123 use_tiger192=yes
124 use_sha256=yes
125 use_sha512=yes
126 use_exec=yes
127
128 AC_ARG_ENABLE(minimal,
129    AC_HELP_STRING([--enable-minimal],[build the smallest gpg binary possible]),
130    use_idea=no
131    use_cast5=no
132    use_blowfish=no
133    use_aes=no
134    use_twofish=no
135    use_tiger192=no
136    use_sha256=no
137    use_sha512=no
138    use_exec=no)
139
140 AC_MSG_CHECKING([whether to enable the IDEA cipher])
141 AC_ARG_ENABLE(idea,
142    AC_HELP_STRING([--disable-idea],[disable the IDEA cipher]),
143    use_idea=$enableval)
144 AC_MSG_RESULT($use_idea)
145 if test x"$use_idea" = xyes ; then
146    AC_DEFINE(USE_IDEA,1,[Define to include the IDEA cipher])
147
148 # We don't need idea but some people claim that they need it for
149 # research etc., so we allow to place an idea source code into the
150 # cipher directory and statically link it if available, otherwise we
151 # link to a stub.  We don't use AC_CHECK_FILE to avoid caching.
152
153    AC_MSG_CHECKING([for idea cipher module])
154    tmp=""
155    if test -f $srcdir/cipher/idea.c; then 
156       IDEA_O=idea.o
157       tmp=idea
158    else
159       IDEA_O=idea-stub.o
160       tmp=no
161       try_dynload=yes
162    fi
163    AC_SUBST(IDEA_O)
164    AC_MSG_RESULT($tmp)
165 fi
166
167 AC_MSG_CHECKING([whether to enable the CAST5 cipher])
168 AC_ARG_ENABLE(cast5,
169    AC_HELP_STRING([--disable-cast5],[disable the CAST5 cipher]),
170    use_cast5=$enableval)
171 AC_MSG_RESULT($use_cast5)
172 if test x"$use_cast5" = xyes ; then
173    AC_DEFINE(USE_CAST5,1,[Define to include the CAST5 cipher])
174 fi
175
176 AC_MSG_CHECKING([whether to enable the BLOWFISH cipher])
177 AC_ARG_ENABLE(blowfish,
178    AC_HELP_STRING([--disable-blowfish],[disable the BLOWFISH cipher]),
179    use_blowfish=$enableval)
180 AC_MSG_RESULT($use_blowfish)
181 if test x"$use_blowfish" = xyes ; then
182    AC_DEFINE(USE_BLOWFISH,1,[Define to include the BLOWFISH cipher])
183 fi
184
185 AC_MSG_CHECKING([whether to enable the AES ciphers])
186 AC_ARG_ENABLE(aes,
187    AC_HELP_STRING([--disable-aes],[disable the AES, AES192, and AES256 ciphers]),
188    use_aes=$enableval)
189 AC_MSG_RESULT($use_aes)
190 if test x"$use_aes" = xyes ; then
191    AC_DEFINE(USE_AES,1,[Define to include the AES, AES192, and AES256 ciphers])
192 fi
193
194 AC_MSG_CHECKING([whether to enable the TWOFISH cipher])
195 AC_ARG_ENABLE(twofish,
196    AC_HELP_STRING([--disable-twofish],[disable the TWOFISH cipher]),
197    use_twofish=$enableval)
198 AC_MSG_RESULT($use_twofish)
199 if test x"$use_twofish" = xyes ; then
200    AC_DEFINE(USE_TWOFISH,1,[Define to include the TWOFISH cipher])
201 fi
202
203 dnl TIGER192 is defined only after we confirm 64-bit support later
204 AC_MSG_CHECKING([whether to enable the TIGER/192 digest])
205 AC_ARG_ENABLE(tiger192,
206    AC_HELP_STRING([--disable-tiger192],[disable the TIGER/192 digest]),
207    use_tiger192=$enableval)
208 AC_MSG_RESULT($use_tiger192)
209
210 AC_MSG_CHECKING([whether to enable the SHA-256 digest])
211 AC_ARG_ENABLE(sha256,
212    AC_HELP_STRING([--disable-sha256],[disable the SHA-256 digest]),
213    use_sha256=$enableval)
214 AC_MSG_RESULT($use_sha256)
215 if test x"$use_sha256" = xyes ; then
216    AC_DEFINE(USE_SHA256,1,[Define to include the SHA-256 digest])
217 fi
218
219 dnl SHA512 is defined only after we confirm 64-bit support later
220 AC_MSG_CHECKING([whether to enable the SHA-384 and SHA-512 digests])
221 AC_ARG_ENABLE(sha512,
222    AC_HELP_STRING([--disable-sha512],[disable the SHA-384 and SHA-512 digests]),
223    use_sha512=$enableval)
224 AC_MSG_RESULT($use_sha512)
225
226 AC_MSG_CHECKING([whether to enable external program execution])
227 AC_ARG_ENABLE(exec,
228     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
229     use_exec=$enableval)
230 AC_MSG_RESULT($use_exec)
231 if test "$use_exec" = no ; then
232     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
233 fi
234
235 if test "$use_exec" = yes ; then
236   AC_MSG_CHECKING([whether to enable photo ID viewing])
237   AC_ARG_ENABLE(photo-viewers,
238       [  --disable-photo-viewers disable photo ID viewers],
239       [if test "$enableval" = no ; then
240          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
241       fi],enableval=yes)
242   gnupg_cv_enable_photo_viewers=$enableval
243   AC_MSG_RESULT($enableval)
244
245   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
246     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
247     AC_ARG_WITH(photo-viewer,
248         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
249         [if test "$withval" = yes ; then
250            withval=no
251         elif test "$withval" != no ; then
252            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
253                             [if set, restrict photo-viewer to this])
254         fi],withval=no)
255     AC_MSG_RESULT($withval)
256   fi
257
258   AC_MSG_CHECKING([whether to enable external keyserver helpers])
259   AC_ARG_ENABLE(keyserver-helpers,
260       [  --disable-keyserver-helpers  disable all external keyserver support],
261       [if test "$enableval" = no ; then
262          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
263                   [define to disable keyserver helpers])
264       fi],enableval=yes)
265   gnupg_cv_enable_keyserver_helpers=$enableval
266   AC_MSG_RESULT($enableval)
267
268   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
269     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
270     AC_ARG_ENABLE(ldap,
271     [  --disable-ldap          disable LDAP keyserver interface],
272         try_ldap=$enableval, try_ldap=yes)
273     AC_MSG_RESULT($try_ldap)
274
275     AC_MSG_CHECKING([whether HKP keyserver support is requested])
276     AC_ARG_ENABLE(hkp,
277     [  --disable-hkp           disable HKP keyserver interface],
278         try_hkp=$enableval, try_hkp=yes)
279     AC_MSG_RESULT($try_hkp)
280
281     if test "$try_hkp" = yes ; then
282       AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
283     fi
284
285     AC_MSG_CHECKING([whether email keyserver support is requested])
286     AC_ARG_ENABLE(mailto,
287     [  --disable-mailto        disable email keyserver interface],
288         try_mailto=$enableval, try_mailto=yes)
289     AC_MSG_RESULT($try_mailto)
290     fi
291
292     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
293     AC_ARG_ENABLE(keyserver-path,
294         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
295         [if test "$enableval" = no ; then
296          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
297         fi],enableval=yes)
298     AC_MSG_RESULT($enableval)
299   fi
300
301 AC_MSG_CHECKING([whether the included zlib is requested])
302 AC_ARG_WITH(included-zlib,
303     [  --with-included-zlib    use the zlib code included here],
304 [g10_force_zlib=yes], [g10_force_zlib=no] )
305 AC_MSG_RESULT($g10_force_zlib)
306
307 dnl
308 dnl Check whether we want to use Linux capabilities
309 dnl
310 AC_MSG_CHECKING([whether use of capabilities is requested])
311 AC_ARG_WITH(capabilities,
312     [  --with-capabilities     use linux capabilities [default=no]],
313 [use_capabilities="$withval"],[use_capabilities=no])
314 AC_MSG_RESULT($use_capabilities)
315
316
317 AH_BOTTOM([
318 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
319 #define EXEC_TEMPFILE_ONLY
320 #endif
321
322 #include "g10defs.h"
323 ])
324
325
326 AM_MAINTAINER_MODE
327
328 dnl Checks for programs.
329
330 AC_PROG_MAKE_SET
331 AM_SANITY_CHECK
332 missing_dir=`cd $ac_aux_dir && pwd`
333 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
334 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
335 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
336 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
337 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
338 AC_PROG_CC
339 AC_PROG_CPP
340 AC_PROG_RANLIB
341 AC_CHECK_TOOL(AR, ar, :)
342 AC_PATH_PROG(PERL,"perl")
343 AC_ISC_POSIX
344 AC_SYS_LARGEFILE
345 AC_PROG_INSTALL
346 AC_PROG_AWK
347 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
348 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
349 GNUPG_CHECK_FAQPROG
350 GNUPG_CHECK_DOCBOOK_TO_TEXI
351
352 MPI_OPT_FLAGS=""
353
354
355 try_gettext=yes
356 case "${target}" in
357     *-*-mingw32*)
358         # special stuff for Windoze NT
359         ac_cv_have_dev_random=no
360         AC_DEFINE(USE_ONLY_8DOT3,1,
361                   [set this to limit filenames to the 8.3 format])
362         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
363                   [defined if we must run on a stupid file system])
364         AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
365                   [defined if we run on some of the PCDOS like systems 
366                    (DOS, Windoze. OS/2) with special properties like
367                     no file modes])
368         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
369                   [because the Unix gettext has too much overhead on
370                    MingW32 systems and these systems lack Posix functions,
371                    we use a simplified version of gettext])
372         try_gettext="no"
373         ;;
374     i?86-emx-os2 | i?86-*-os2*emx )
375         # OS/2 with the EMX environment
376         ac_cv_have_dev_random=no
377         AC_DEFINE(HAVE_DRIVE_LETTERS)
378         AC_DEFINE(HAVE_DOSISH_SYSTEM)
379         try_gettext="no"
380         ;;
381
382     i?86-*-msdosdjgpp*)
383         # DOS with the DJGPP environment
384         ac_cv_have_dev_random=no
385         AC_DEFINE(HAVE_DRIVE_LETTERS)
386         AC_DEFINE(HAVE_DOSISH_SYSTEM)
387         try_gettext="no"
388         ;;
389
390     *-*-freebsd*)
391        # FreeBSD
392        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
393        LDFLAGS="$LDFLAGS -L/usr/local/lib"
394        ;;
395
396     *-*-hpux*)
397         if test -z "$GCC" ; then
398             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
399         fi
400         ;;
401     *-dec-osf4*)
402         if test -z "$GCC" ; then
403             # Suppress all warnings
404             # to get rid of the unsigned/signed char mismatch warnings.
405             CFLAGS="$CFLAGS -w"
406         fi
407         ;;
408     *-dec-osf5*)
409         if test -z "$GCC" ; then
410             # Use the newer compiler `-msg_disable ptrmismatch' to
411             # get rid of the unsigned/signed char mismatch warnings.
412             # Using this may hide other pointer mismatch warnings, but
413             # it at least lets other warning classes through
414             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
415         fi
416         ;;
417     m68k-atari-mint)
418         ;;
419     *)
420        ;;
421 esac
422
423 AC_SUBST(MPI_OPT_FLAGS)
424 GNUPG_SYS_SYMBOL_UNDERSCORE
425
426 dnl Must check for network library requirements before doing link tests
427 dnl for ldap, for example. If ldap libs are static (or dynamic and without
428 dnl ELF runtime link paths), then link will fail and LDAP support won't
429 dnl be detected.
430
431 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
432         [NETLIBS="-lnsl $NETLIBS"]))
433 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
434         [NETLIBS="-lsocket $NETLIBS"]))
435
436 dnl Now try for the resolver functions so we can use DNS SRV
437
438 AC_ARG_ENABLE(dns-srv,
439    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
440    use_dns_srv=$enableval,use_dns_srv=yes)
441
442 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
443   AC_CHECK_FUNC(res_query)
444   # the double underscore thing is a glibc-ism?
445   if test $ac_cv_func_res_query = no ; then 
446      AC_CHECK_FUNC(__res_query)
447      ac_cv_func_res_query=$ac_cv_func___res_query
448   fi
449   if test $ac_cv_func_res_query = no ; then 
450      AC_CHECK_LIB(resolv,res_query)
451      ac_cv_func_res_query=$ac_cv_lib_resolv_res_query
452      srvlib="-lresolv"
453   fi
454   if test $ac_cv_func_res_query = no ; then 
455      AC_CHECK_LIB(resolv,__res_query)
456      ac_cv_func_res_query=$ac_cv_lib_resolv___res_query
457      srvlib="-lresolv"
458   fi
459   if test $ac_cv_func_res_query = no ; then 
460      AC_CHECK_LIB(bind,res_query)
461      ac_cv_func_res_query=$ac_cv_lib_bind_res_query
462      srvlib="-lbind"
463   fi
464   if test $ac_cv_func_res_query = no ; then 
465      AC_CHECK_LIB(bind,__res_query)
466      ac_cv_func_res_query=$ac_cv_lib_bind___res_query
467      srvlib="-lbind"
468   fi
469   # we assume if we can find res_query, we can also use the dn_expand
470   # and dn_skipname functions.
471   if test x"$ac_cv_func_res_query" = xyes ; then
472      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
473      SRVLIBS=$srvlib
474   fi
475 fi
476
477 AC_SUBST(SRVLIBS)
478
479 # Try and link a LDAP test program to weed out unusable LDAP
480 # libraries.  -lldap [-llber [-lresolv]] is for OpenLDAP.  OpenLDAP in
481 # general is terrible with creating weird dependencies.  If all else
482 # fails, the user can play guess-the-dependency by using something
483 # like ./configure LDAPLIBS="-Lfoo -lbar"
484
485 if test "$try_ldap" = yes ; then
486   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
487     _ldap_save_libs=$LIBS
488     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
489
490     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
491     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
492                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
493     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
494
495     if test $gnupg_cv_func_ldap_init = no; then
496       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
497       AC_TRY_LINK([#include <lber.h>
498 #include <ldap.h>],[ldap_open("foobar",1234);],
499          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
500       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
501     fi
502
503     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
504        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
505     fi
506
507     if test "$gnupg_cv_func_ldap_init" = yes || \
508         test "$gnupg_cv_func_ldaplber_init" = yes ; then
509        LDAPLIBS=$MY_LDAPLIBS
510        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
511
512        AC_MSG_CHECKING([whether LDAP supports ldap_get_option])
513
514        if test "$gnupg_cv_func_ldap_init" = yes ; then
515           AC_TRY_LINK([#include <ldap.h>],
516              [ldap_get_option((void *)0,0,(void *)0);],
517              [gnupg_cv_func_ldap_get_option=yes],
518              [gnupg_cv_func_ldap_get_option=no])
519         else
520           AC_TRY_LINK([#include <lber.h>
521 #include <ldap.h>],[ldap_get_option((void *)0,0,(void *)0);],
522              [gnupg_cv_func_ldap_get_option=yes],
523              [gnupg_cv_func_ldap_get_option=no])
524        fi
525
526        AC_MSG_RESULT([$gnupg_cv_func_ldap_get_option])
527
528        if test "$gnupg_cv_func_ldap_get_option" = yes ; then
529           AC_DEFINE(HAVE_LDAP_GET_OPTION,1,[Define if the LDAP library has ldap_get_option])
530        else
531           AC_MSG_CHECKING([whether LDAP supports ld_errno])
532
533           if test "$gnupg_cv_func_ldap_init" = yes ; then
534             AC_TRY_COMPILE([#include <ldap.h>],
535                [LDAP *ldap; ldap->ld_errno;],
536                [gnupg_cv_func_ldap_ld_errno=yes],
537                [gnupg_cv_func_ldap_ld_errno=no])
538            else
539             AC_TRY_LINK([#include <lber.h>
540 #include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
541                [gnupg_cv_func_ldap_ld_errno=yes],
542                [gnupg_cv_func_ldap_ld_errno=no])
543           fi
544
545           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
546
547           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
548              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
549           fi
550        fi
551     fi
552
553     LIBS=$_ldap_save_libs
554
555     if test "$GPGKEYS_LDAP" != "" ; then break; fi
556   done
557 fi
558
559 AC_SUBST(GPGKEYS_LDAP)
560 AC_SUBST(LDAPLIBS)
561
562 dnl This isn't necessarily sendmail itself, but anything that gives a
563 dnl sendmail-ish interface to the outside world.  That includes qmail,
564 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
565
566 if test "$try_mailto" = yes ; then
567   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
568
569   if test "$with_mailprog" = yes ; then
570     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
571     if test "$ac_cv_path_SENDMAIL" ; then
572       GPGKEYS_MAILTO="gpgkeys_mailto"
573     fi
574   elif test "$with_mailprog" != no ; then
575     AC_MSG_CHECKING([for a mail transport program])
576     AC_SUBST(SENDMAIL,$with_mailprog)
577     AC_MSG_RESULT($with_mailprog)
578     GPGKEYS_MAILTO="gpgkeys_mailto"
579   fi
580 fi
581
582 AC_SUBST(GPGKEYS_MAILTO)
583
584 case "${target}" in
585     *-*-mingw32*)
586         PRINTABLE_OS_NAME="MingW32"
587         ;;
588     *-*-cygwin*)
589         PRINTABLE_OS_NAME="Cygwin"
590         ;;
591     i?86-emx-os2 | i?86-*-os2*emx )
592         PRINTABLE_OS_NAME="OS/2"
593         ;;
594     i?86-*-msdosdjgpp*)
595         PRINTABLE_OS_NAME="MSDOS/DJGPP"
596         try_dynload=no
597         ;;
598     *-linux*)
599         PRINTABLE_OS_NAME="GNU/Linux"
600         ;;
601 dnl let that after linux to avoid gnu-linux problems
602     *-gnu*)
603         PRINTABLE_OS_NAME="GNU/Hurd"
604         ;;
605     *)
606         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
607         ;;
608 esac
609 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
610                    [A human readable text with the name of the OS])
611
612
613 #
614 # 1. Set names of random devices
615 #
616 NAME_OF_DEV_RANDOM="/dev/random"
617 NAME_OF_DEV_URANDOM="/dev/urandom"
618 case "${target}" in
619     *-openbsd*)
620         NAME_OF_DEV_RANDOM="/dev/srandom"
621         NAME_OF_DEV_URANDOM="/dev/urandom"
622         ;;
623 esac
624 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM",
625                    [defined to the name of the strong random device])
626 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM",
627                    [defined to the name of the weaker random device])
628 AC_SUBST(MPI_OPT_FLAGS)
629
630
631 dnl Checks for libraries.
632
633 if test "$try_gettext" = yes; then
634   AM_GNU_GETTEXT
635 else
636   USE_NLS=no
637   USE_INCLUDED_LIBINTL=no
638   BUILD_INCLUDED_LIBINTL=no
639   AC_SUBST(USE_NLS)
640   AC_SUBST(USE_INCLUDED_LIBINTL)
641   AC_SUBST(BUILD_INCLUDED_LIBINTL)
642 fi
643
644
645 if test "$try_dynload" = yes ; then
646   AC_CHECK_LIB(dl,dlopen)
647   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
648     AC_DEFINE(USE_DYNAMIC_LINKING,1,
649               [define to enable the use of extensions])
650     AC_DEFINE(HAVE_DL_DLOPEN,1,
651               [Defined when the dlopen function family is available])
652   else
653     AC_CHECK_FUNCS(dlopen)
654     if test "$ac_cv_func_dlopen" = "yes"; then
655       AC_DEFINE(USE_DYNAMIC_LINKING)
656       AC_DEFINE(HAVE_DL_DLOPEN)
657     fi
658   fi
659 else
660   AC_MSG_CHECKING(for dynamic loading)
661   DYNLINK_LDFLAGS=
662   DYNLINK_MOD_CFLAGS=
663   AC_MSG_RESULT(has been disabled)
664 fi
665
666 dnl Checks for header files.
667 AC_HEADER_STDC
668 AC_CHECK_HEADERS(unistd.h langinfo.h termio.h locale.h)
669
670 dnl Checks for typedefs, structures, and compiler characteristics.
671 AC_C_CONST
672 AC_C_INLINE
673 AC_C_VOLATILE
674 AC_TYPE_SIZE_T
675 AC_TYPE_MODE_T
676 AC_TYPE_SIGNAL
677 AC_DECL_SYS_SIGLIST
678
679 GNUPG_CHECK_ENDIAN
680
681 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
682 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
683 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
684 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
685 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
686
687 AC_CHECK_SIZEOF(unsigned short)
688 AC_CHECK_SIZEOF(unsigned int)
689 AC_CHECK_SIZEOF(unsigned long)
690 AC_CHECK_SIZEOF(unsigned long long)
691 AC_CHECK_SIZEOF(uint64_t)
692
693 if test "$ac_cv_sizeof_unsigned_short" = "0" \
694    || test "$ac_cv_sizeof_unsigned_int" = "0" \
695    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
696     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
697 fi
698
699 dnl Do we have any 64-bit data types?
700 if test "$ac_cv_sizeof_unsigned_int" != "8" \
701    && test "$ac_cv_sizeof_unsigned_long" != "8" \
702    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
703    && test "$ac_cv_sizeof_uint64_t" != "8"; then
704     AC_MSG_WARN([No 64-bit types.  Disabling TIGER/192, SHA-384, and SHA-512])
705 else
706   if test x"$use_tiger192" = xyes ; then
707      AC_SUBST(TIGER_O,tiger.o)
708      AC_DEFINE(USE_TIGER192,1,[Define to include the TIGER/192 digest])
709
710      AC_MSG_CHECKING([whether to enable old-style TIGER/192 digest support])
711      AC_ARG_ENABLE(old-tiger,
712         [  --enable-old-tiger      enable old-style TIGER/192 digest support],
713         old_tiger=$enableval, old_tiger=no)
714      AC_MSG_RESULT($old_tiger)
715      if test "$old_tiger" = yes ; then
716         AC_DEFINE(USE_OLD_TIGER,1,[Define to use the old fake OID for TIGER/192 digest support])
717      fi
718   fi
719   if test x"$use_sha512" = xyes ; then
720      AC_SUBST(SHA512_O,sha512.o)
721      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
722   fi
723 fi
724
725 dnl Checks for library functions.
726 AC_FUNC_FSEEKO
727 AC_FUNC_VPRINTF
728 AC_FUNC_FORK
729 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
730 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid)
731 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
732 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
733 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat)
734 AC_REPLACE_FUNCS(mkdtemp)
735
736 #
737 # check for gethrtime and run a testprogram to see whether
738 # it is broken.  It has been reported that some Solaris and HP UX systems 
739 # raise an SIGILL
740 #
741 AC_CACHE_CHECK([for gethrtime], 
742                [gnupg_cv_func_gethrtime],
743                [AC_TRY_LINK([#include <sys/times.h>],[
744                    hrtime_t tv;
745                    tv = gethrtime();
746                  ],
747                  [gnupg_cv_func_gethrtime=yes],
748                  [gnupg_cv_func_gethrtime=no])
749                ])
750 if test $gnupg_cv_func_gethrtime = yes; then
751      AC_DEFINE([HAVE_GETHRTIME], 1,
752                [Define if you have the `gethrtime(2)' function.])
753      AC_CACHE_CHECK([whether gethrtime is broken], 
754                [gnupg_cv_func_broken_gethrtime],
755                [AC_TRY_RUN([
756                    #include <sys/times.h>
757                    int main () {
758                    hrtime_t tv;
759                    tv = gethrtime(); 
760                  }
761                  ],
762                  [gnupg_cv_func_broken_gethrtime=no],
763                  [gnupg_cv_func_broken_gethrtime=yes],
764                  [gnupg_cv_func_broken_gethrtime=assume-no])
765                 ])
766     if test $gnupg_cv_func_broken_gethrtime = yes; then
767       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
768       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
769     fi
770 fi
771      
772
773 GNUPG_CHECK_MLOCK
774 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
775
776 dnl
777 dnl Check whether we can use Linux capabilities as requested
778 dnl
779 if test "$use_capabilities" = "yes" ; then
780 use_capabilities=no
781 AC_CHECK_HEADERS(sys/capability.h)
782 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
783   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
784   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
785      AC_DEFINE(USE_CAPABILITIES,1,
786                [define if capabilities should be used])
787      AC_SUBST(CAPLIBS,"-lcap")
788      use_capabilities=yes
789   fi
790 fi
791 if test "$use_capabilities" = "no" ; then
792     AC_MSG_WARN([[
793 ***
794 *** The use of capabilities on this system is not possible.
795 *** You need a recent Linux kernel and some patches:
796 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
797 ***   fcap-module-990613.tar.gz     (kernel module)
798 ***   libcap-1.92.tar.gz            (user mode library and utilities)
799 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
800 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
801 ***]])
802 fi
803 fi
804
805
806 GNUPG_CHECK_IPC
807 if test "$ac_cv_header_sys_shm_h" = "yes"; then
808   AC_DEFINE(USE_SHM_COPROCESSING,1,
809             [define if the shared memory interface should be made available])
810 fi
811
812 dnl
813 dnl check whether we have a random device
814 dnl
815 if test "$try_dev_random" = yes ; then
816     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
817     [if test -r "$NAME_OF_DEV_RANDOM" && test -r "$NAME_OF_DEV_URANDOM" ; then
818       ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
819     if test "$ac_cv_have_dev_random" = yes; then
820         AC_DEFINE(HAVE_DEV_RANDOM,1,
821                  [defined if the system supports a random device] )
822     fi
823 else
824     AC_MSG_CHECKING(for random device)
825     ac_cv_have_dev_random=no
826     AC_MSG_RESULT(has been disabled)
827 fi
828
829
830 dnl
831 dnl Figure out the default random module.
832 dnl
833 random_modules=""
834 if test "$use_static_rnd" = default; then
835      if test "$ac_cv_have_dev_random" = yes; then
836         random_modules="rndlinux"
837      else
838          case "${target}" in
839             *-*-mingw32*|*-*-cygwin*)
840                 random_modules="rndw32"
841                 ;;
842             i?86-emx-os2|i?86-*-os2*emx)
843                 random_modules="rndos2"
844                 ;;
845             m68k-atari-mint)
846                 random_modules="rndatari"
847                 ;;
848             i?86-*-msdosdjgpp*)
849                 :
850                 ;;
851             *)
852                 random_modules="rndlinux rndegd rndunix"
853                 AC_DEFINE(USE_ALL_RANDOM_MODULES, 1, 
854                           [Allow to select random modules at runtime.])
855                 ;;
856          esac
857      fi
858 else
859   if test "$use_static_rnd" = auto; then
860      random_modules="rndlinux rndegd rndunix"
861      AC_DEFINE(USE_ALL_RANDOM_MODULES, 1)
862   else
863      random_modules="rnd$use_static_rnd";
864   fi
865 fi
866
867 if test -z "$random_modules"; then
868    AC_MSG_ERROR(no random module available)
869 fi
870 print_egd_warning=no
871 for rndmod in $random_modules "" ; do
872   case "$rndmod" in
873     rndlinux)
874          AC_DEFINE(USE_RNDLINUX,1, 
875                   [Defined if the /dev/random based RNG should be used.])
876          ;;
877     rndunix)
878          AC_DEFINE(USE_RNDUNIX,1, 
879                   [Defined if the default Unix RNG should be used.])
880          print_egd_warning=yes
881           ;;
882     rndegd)
883          AC_DEFINE(USE_RNDEGD,1, 
884                   [Defined if the EGD based RNG should be used.])
885          EGDLIBS=$NETLIBS
886          AC_SUBST(EGDLIBS)
887          ;;
888     rndw32)
889          AC_DEFINE(USE_RNDW32,1, 
890                   [Defined if the Windows specific RNG should be used.])
891         ;;
892    esac
893 done
894
895 dnl setup assembler stuff
896 AC_MSG_CHECKING(for mpi assembler functions)
897 if test -f $srcdir/mpi/config.links ; then
898     . $srcdir/mpi/config.links
899     AC_CONFIG_LINKS("$mpi_ln_list")
900     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
901     ac_cv_mpi_sflags="$mpi_sflags"
902     ac_cv_mpi_config_done="yes"
903     AC_MSG_RESULT(done)
904 else
905     AC_MSG_RESULT(failed)
906     AC_MSG_ERROR([mpi/config.links missing!])
907 fi
908 MPI_EXTRA_ASM_OBJS=""
909 show_extraasm=""
910 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
911 for i in $ac_cv_mpi_extra_asm_modules; do
912     show_extraasm="$show_extraasm $i"
913     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
914 done
915 fi
916 AC_SUBST(MPI_EXTRA_ASM_OBJS)
917 MPI_SFLAGS="$ac_cv_mpi_sflags"
918 AC_SUBST(MPI_SFLAGS)
919
920 # Sanity check regex.  Tests adapted from mutt.
921
922 AC_MSG_CHECKING([whether regular expression support is requested])
923 AC_ARG_ENABLE(regex,
924 [  --disable-regex         do not handle regular expressions in trust sigs],
925      use_regex=$enableval, use_regex=yes)
926 AC_MSG_RESULT($use_regex)
927
928 if test "$use_regex" = yes ; then
929   AC_MSG_CHECKING([whether the included regex lib is requested])
930   AC_ARG_WITH(included-regex,
931       [  --with-included-regex   use the included GNU regex library],
932       [gnupg_cv_included_regex=yes],[gnupg_cv_included_regex=no])
933   AC_MSG_RESULT($gnupg_cv_included_regex)
934
935   if test $gnupg_cv_included_regex = no ; then
936      # Does the system have regex functions at all?
937      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
938                            gnupg_cv_included_regex=yes)
939   fi
940
941   if test $gnupg_cv_included_regex = no ; then
942      AC_CACHE_CHECK([whether your system's regexp library is broken],
943        [gnupg_cv_regex_broken],
944        AC_TRY_RUN([
945 #include <unistd.h>
946 #include <regex.h>
947 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
948        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
949
950      if test $gnupg_cv_regex_broken = yes ; then
951       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
952       gnupg_cv_included_regex=yes
953      fi
954   fi
955
956   if test $gnupg_cv_included_regex = yes; then
957      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
958      AC_SUBST(REGEX_O,regex.o)
959   fi
960 else
961
962   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
963 fi
964
965 dnl Do we have zlib? Must do it here because Solaris failed
966 dnl when compiling a conftest (due to the "-lz" from LIBS).
967 use_local_zlib=yes
968 if test "$g10_force_zlib" = "yes"; then
969   :
970 else
971   _cppflags="${CPPFLAGS}"
972   _ldflags="${LDFLAGS}"
973
974   AC_ARG_WITH(zlib,
975   [  --with-zlib=DIR         use libz in DIR],[
976     if test -d "$withval"; then
977       CPPFLAGS="${CPPFLAGS} -I$withval/include"
978       LDFLAGS="${LDFLAGS} -L$withval/lib"
979     fi
980   ])
981
982   AC_CHECK_HEADER(zlib.h,
983       AC_CHECK_LIB(z, deflateInit2_,
984        use_local_zlib=no
985        LIBS="$LIBS -lz",
986        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
987        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
988 fi
989  
990 if test "$use_local_zlib" = yes ; then
991     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
992     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
993     ZLIBS="../zlib/libzlib.a"
994 else
995     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
996     ZLIBS=
997 fi
998 AC_SUBST(ZLIBS)
999
1000
1001 # Allow users to append something to the version string without
1002 # flagging it as development version.  The user version parts is
1003 # considered everything after a dash. 
1004 if test "$development_version" != yes; then
1005   changequote(,)dnl
1006   tmp_pat='[a-zA-Z]'
1007   changequote([,])dnl
1008   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1009     development_version=yes
1010   fi
1011 fi
1012 if test "$development_version" = yes; then
1013     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1014             [Defined if this is not a regular release])
1015 fi
1016
1017 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1018
1019 GNUPG_CHECK_GNUMAKE
1020
1021 # add some extra libs here so that previous tests don't fail for
1022 # mysterious reasons - the final link step should bail out. 
1023 case "${target}" in
1024     *-*-mingw32*)
1025         LIBS="$LIBS -lwsock32"
1026         ;;
1027     *)
1028        ;;
1029 esac
1030
1031
1032 if test "$GCC" = yes; then
1033     if test "$USE_MAINTAINER_MODE" = "yes"; then
1034         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1035     else
1036         CFLAGS="$CFLAGS -Wall"
1037     fi
1038 fi
1039
1040 AC_SUBST(NETLIBS)
1041
1042
1043 if test "$print_egd_warning" = yes; then
1044   AC_MSG_WARN([[
1045 ***
1046 *** The performance of the UNIX random gatherer module is not very good
1047 *** and it does not keep the entropy pool over multiple invocations of
1048 *** GnuPG.  The suggested way to overcome this problem is to use the
1049 ***
1050 ***               Entropy Gathering Daemon (EGD)
1051 ***
1052 *** which provides a entropy source for the whole system.  It is written
1053 *** in Perl and available at the GnuPG FTP servers.  For more information
1054 *** consult the GnuPG webpages:
1055 ***
1056 ***           http://www.gnupg.org/download.html#egd
1057 ***
1058 *** You may want to run ./configure with --enable-static-rnd=egd to use it.
1059 ***]])
1060 fi
1061
1062 # Note the \\\\ for backslashes.  Autoconf eats one layer, leaving \\
1063
1064 AC_CONFIG_COMMANDS(g10defs.h,[[
1065 cat >g10defs.tmp <<G10EOF
1066 /* Generated automatically by configure */
1067 #ifdef HAVE_DRIVE_LETTERS
1068   #define G10_LOCALEDIR     "c:\\\\lib\\\\gnupg\\\\locale"
1069   #define GNUPG_LIBDIR      "c:\\\\lib\\\\gnupg"
1070   #define GNUPG_LIBEXECDIR  "c:\\\\lib\\\\gnupg"
1071   #define GNUPG_DATADIR     "c:\\\\lib\\\\gnupg"
1072   #define GNUPG_HOMEDIR     "c:\\\\gnupg"
1073 #else
1074   #define G10_LOCALEDIR     "${datadir}/locale"
1075   #define GNUPG_LIBDIR      "${libdir}/gnupg"
1076   #define GNUPG_DATADIR     "${datadir}/gnupg"
1077   #ifdef __VMS
1078     #define GNUPG_HOMEDIR "/SYS\$LOGIN/gnupg" 
1079   #else
1080     #define GNUPG_HOMEDIR "~/.gnupg" 
1081   #endif
1082 #endif
1083 /* those are here to be redefined by handcrafted g10defs.h.
1084    Please note that the string version must not contain more
1085    than one character because the using code assumes strlen()==1 */
1086 #ifdef HAVE_DOSISH_SYSTEM
1087 #define DIRSEP_C '\\\\'
1088 #define EXTSEP_C '.'
1089 #define DIRSEP_S "\\\\"
1090 #define EXTSEP_S "."
1091 #else
1092 #define DIRSEP_C '/'
1093 #define EXTSEP_C '.'
1094 #define DIRSEP_S "/"
1095 #define EXTSEP_S "."
1096 #endif
1097 G10EOF
1098 cat mpi/mpi-asm-defs.h >>g10defs.tmp 
1099 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
1100     echo "g10defs.h is unchanged"
1101     rm -f g10defs.tmp
1102 else
1103     rm -f g10defs.h
1104     mv g10defs.tmp g10defs.h
1105     echo "g10defs.h created"
1106 fi
1107 ]],[[
1108 prefix=$prefix
1109 exec_prefix=$exec_prefix
1110 libdir=$libdir
1111 libexecdir=$libexecdir
1112 datadir=$datadir
1113 DATADIRNAME=$DATADIRNAME
1114 ]])
1115
1116
1117 AC_CONFIG_FILES([
1118 Makefile
1119 intl/Makefile
1120 po/Makefile.in
1121 util/Makefile
1122 mpi/Makefile
1123 cipher/Makefile
1124 g10/Makefile
1125 keyserver/Makefile
1126 keyserver/gpgkeys_mailto
1127 keyserver/gpgkeys_test
1128 doc/Makefile
1129 tools/Makefile
1130 zlib/Makefile
1131 checks/Makefile
1132 ])
1133 AC_OUTPUT
1134
1135 # Give some feedback
1136 echo
1137 echo   "                Configured for: $PRINTABLE_OS_NAME ($target)"
1138 if test -n "$show_extraasm"; then
1139   echo "  Extra cpu specific functions:$show_extraasm"
1140 fi
1141 echo