* configure.ac (DLLIBS): Work properly on platforms where dlopen and
[gnupg.git] / configure.ac
1 dnl Configure.ac script for GnuPG
2 dnl Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 dnl               2003 Free Software Foundation, Inc.
4 dnl
5 dnl This file is part of GnuPG.
6 dnl
7 dnl GnuPG is free software; you can redistribute it and/or modify
8 dnl it under the terms of the GNU General Public License as published by
9 dnl the Free Software Foundation; either version 2 of the License, or
10 dnl (at your option) any later version.
11 dnl 
12 dnl GnuPG is distributed in the hope that it will be useful,
13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 dnl GNU General Public License for more details.
16 dnl 
17 dnl You should have received a copy of the GNU General Public License
18 dnl along with this program; if not, write to the Free Software
19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20 dnl
21 dnl (Process this file with autoconf to produce a configure script.)
22 dnlAC_REVISION($Revision$)dnl
23
24 AC_PREREQ(2.52)
25
26 # Remember to change the version number immediately *after* a release
27 # and remove the "-cvs" or "rc" suffix immediately *before* a release.
28 AC_INIT(gnupg, 1.3.4-cvs, bug-gnupg@gnu.org)
29 # Set development_version to yes if the minor number is odd or you
30 # feel that the default check for a development version is not
31 # sufficient.
32 development_version=yes
33
34 ALL_LINGUAS="de"
35
36 AC_CONFIG_AUX_DIR(scripts)
37 AC_CONFIG_SRCDIR(g10/g10.c)
38 AC_CANONICAL_TARGET()
39 AM_INIT_AUTOMAKE
40 AM_CONFIG_HEADER(config.h)
41
42 AC_GNU_SOURCE
43
44 dnl
45 dnl  Check for random module options
46 dnl
47 AC_MSG_CHECKING([which random module to use])
48 AC_ARG_ENABLE(static-rnd,
49     [  --enable-static-rnd=[egd|unix|linux|auto]  ],
50 [use_static_rnd=$enableval], [use_static_rnd=default] )
51
52 if test "$use_static_rnd" = no; then
53     use_static_rnd=default
54 fi
55
56 case "$use_static_rnd" in
57     egd | linux | unix | default )
58       AC_MSG_RESULT($use_static_rnd)
59       ;;
60     auto )
61       AC_MSG_RESULT(automagically selected at runtime)
62       ;;
63     * )
64       AC_MSG_RESULT(invalid argument)
65       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
66       ;;
67 esac
68
69 AC_ARG_WITH(egd-socket,
70     [  --with-egd-socket=NAME  use NAME for the EGD socket],
71             egd_socket_name="$withval", egd_socket_name="" )
72 AC_DEFINE_UNQUOTED(EGD_SOCKET_NAME, "$egd_socket_name",
73                    [Define if you don't want the default EGD socket name.
74                     For details see cipher/rndegd.c])
75
76
77 dnl
78 dnl See whether the user wants to disable checking for /dev/random
79
80 AC_MSG_CHECKING([whether use of /dev/random is requested])
81 AC_ARG_ENABLE(dev-random,
82 [  --disable-dev-random    disable the use of dev random],
83     try_dev_random=$enableval, try_dev_random=yes)
84 AC_MSG_RESULT($try_dev_random)
85
86
87 dnl
88 dnl  Check other options
89 dnl
90
91 AC_MSG_CHECKING([whether assembler modules are requested])
92 AC_ARG_ENABLE(asm,
93 [  --disable-asm           do not use assembler modules],
94      try_asm_modules=$enableval, try_asm_modules=yes)
95 AC_MSG_RESULT($try_asm_modules)
96
97 AC_MSG_CHECKING([whether memory guard is requested])
98 AC_ARG_ENABLE(m-guard,
99     [  --enable-m-guard        enable memory guard facility],
100     use_m_guard=$enableval, use_m_guard=no)
101 AC_MSG_RESULT($use_m_guard)
102 if test "$use_m_guard" = yes ; then
103     AC_DEFINE(M_GUARD,1,[Define to use the (obsolete) malloc guarding feature])
104 fi
105
106 AC_MSG_CHECKING([whether OpenPGP card support is requested])
107 AC_ARG_ENABLE(card-support,
108     [  --enable-card-support   enable OpenPGP card support],
109     card_support=$enableval, card_support=no)
110 AC_MSG_RESULT($card_support)
111
112 dnl See if we are disabling any algorithms or features for a smaller
113 dnl binary
114
115 try_extensions=no
116
117 use_idea=yes
118 use_cast5=yes
119 use_blowfish=yes
120 use_aes=yes
121 use_twofish=yes
122 use_sha256=yes
123 use_sha512=yes
124 use_exec=yes
125
126 AC_ARG_ENABLE(minimal,
127    AC_HELP_STRING([--enable-minimal],[build the smallest gpg binary possible]),
128    use_idea=no
129    use_cast5=no
130    use_blowfish=no
131    use_aes=no
132    use_twofish=no
133    use_sha256=no
134    use_sha512=no
135    use_exec=no)
136
137 AC_MSG_CHECKING([whether to enable the IDEA cipher])
138 AC_ARG_ENABLE(idea,
139    AC_HELP_STRING([--disable-idea],[disable the IDEA cipher]),
140    use_idea=$enableval)
141 AC_MSG_RESULT($use_idea)
142 if test x"$use_idea" = xyes ; then
143    AC_DEFINE(USE_IDEA,1,[Define to include the IDEA cipher])
144
145 # We don't need idea but some people claim that they need it for
146 # research etc., so we allow to place an idea source code into the
147 # cipher directory and statically link it if available, otherwise we
148 # link to a stub.  We don't use AC_CHECK_FILE to avoid caching.
149
150    AC_MSG_CHECKING([for idea cipher module])
151    tmp=""
152    if test -f $srcdir/cipher/idea.c; then 
153       IDEA_O=idea.o
154       tmp=idea
155    else
156       IDEA_O=idea-stub.o
157       tmp=no
158       try_extensions=yes
159    fi
160    AC_SUBST(IDEA_O)
161    AC_MSG_RESULT($tmp)
162 fi
163
164 AC_MSG_CHECKING([whether to enable the CAST5 cipher])
165 AC_ARG_ENABLE(cast5,
166    AC_HELP_STRING([--disable-cast5],[disable the CAST5 cipher]),
167    use_cast5=$enableval)
168 AC_MSG_RESULT($use_cast5)
169 if test x"$use_cast5" = xyes ; then
170    AC_DEFINE(USE_CAST5,1,[Define to include the CAST5 cipher])
171 fi
172
173 AC_MSG_CHECKING([whether to enable the BLOWFISH cipher])
174 AC_ARG_ENABLE(blowfish,
175    AC_HELP_STRING([--disable-blowfish],[disable the BLOWFISH cipher]),
176    use_blowfish=$enableval)
177 AC_MSG_RESULT($use_blowfish)
178 if test x"$use_blowfish" = xyes ; then
179    AC_DEFINE(USE_BLOWFISH,1,[Define to include the BLOWFISH cipher])
180 fi
181
182 AC_MSG_CHECKING([whether to enable the AES ciphers])
183 AC_ARG_ENABLE(aes,
184    AC_HELP_STRING([--disable-aes],[disable the AES, AES192, and AES256 ciphers]),
185    use_aes=$enableval)
186 AC_MSG_RESULT($use_aes)
187 if test x"$use_aes" = xyes ; then
188    AC_DEFINE(USE_AES,1,[Define to include the AES, AES192, and AES256 ciphers])
189 fi
190
191 AC_MSG_CHECKING([whether to enable the TWOFISH cipher])
192 AC_ARG_ENABLE(twofish,
193    AC_HELP_STRING([--disable-twofish],[disable the TWOFISH cipher]),
194    use_twofish=$enableval)
195 AC_MSG_RESULT($use_twofish)
196 if test x"$use_twofish" = xyes ; then
197    AC_DEFINE(USE_TWOFISH,1,[Define to include the TWOFISH cipher])
198 fi
199
200 AC_MSG_CHECKING([whether to enable the SHA-256 digest])
201 AC_ARG_ENABLE(sha256,
202    AC_HELP_STRING([--disable-sha256],[disable the SHA-256 digest]),
203    use_sha256=$enableval)
204 AC_MSG_RESULT($use_sha256)
205 if test x"$use_sha256" = xyes ; then
206    AC_DEFINE(USE_SHA256,1,[Define to include the SHA-256 digest])
207 fi
208
209 dnl SHA512 is defined only after we confirm 64-bit support later
210 AC_MSG_CHECKING([whether to enable the SHA-384 and SHA-512 digests])
211 AC_ARG_ENABLE(sha512,
212    AC_HELP_STRING([--disable-sha512],[disable the SHA-384 and SHA-512 digests]),
213    use_sha512=$enableval)
214 AC_MSG_RESULT($use_sha512)
215
216 AC_MSG_CHECKING([whether to enable external program execution])
217 AC_ARG_ENABLE(exec,
218     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
219     use_exec=$enableval)
220 AC_MSG_RESULT($use_exec)
221 if test "$use_exec" = no ; then
222     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
223 fi
224
225 if test "$use_exec" = yes ; then
226   AC_MSG_CHECKING([whether to enable photo ID viewing])
227   AC_ARG_ENABLE(photo-viewers,
228       [  --disable-photo-viewers disable photo ID viewers],
229       [if test "$enableval" = no ; then
230          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
231       fi],enableval=yes)
232   gnupg_cv_enable_photo_viewers=$enableval
233   AC_MSG_RESULT($enableval)
234
235   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
236     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
237     AC_ARG_WITH(photo-viewer,
238         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
239         [if test "$withval" = yes ; then
240            withval=no
241         elif test "$withval" != no ; then
242            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
243                             [if set, restrict photo-viewer to this])
244         fi],withval=no)
245     AC_MSG_RESULT($withval)
246   fi
247
248   AC_MSG_CHECKING([whether to enable external keyserver helpers])
249   AC_ARG_ENABLE(keyserver-helpers,
250       [  --disable-keyserver-helpers  disable all external keyserver support],
251       [if test "$enableval" = no ; then
252          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
253                   [define to disable keyserver helpers])
254       fi],enableval=yes)
255   gnupg_cv_enable_keyserver_helpers=$enableval
256   AC_MSG_RESULT($enableval)
257
258   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
259     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
260     AC_ARG_ENABLE(ldap,
261     [  --disable-ldap          disable LDAP keyserver interface],
262         try_ldap=$enableval, try_ldap=yes)
263     AC_MSG_RESULT($try_ldap)
264
265     AC_MSG_CHECKING([whether HKP keyserver support is requested])
266     AC_ARG_ENABLE(hkp,
267     [  --disable-hkp           disable HKP keyserver interface],
268         try_hkp=$enableval, try_hkp=yes)
269     AC_MSG_RESULT($try_hkp)
270
271     AC_MSG_CHECKING([whether email keyserver support is requested])
272     AC_ARG_ENABLE(mailto,
273     [  --disable-mailto        disable email keyserver interface],
274         try_mailto=$enableval, try_mailto=yes)
275     AC_MSG_RESULT($try_mailto)
276     fi
277
278     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
279     AC_ARG_ENABLE(keyserver-path,
280         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
281         [if test "$enableval" = no ; then
282          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
283         fi],enableval=yes)
284     AC_MSG_RESULT($enableval)
285   fi
286
287 AC_MSG_CHECKING([whether the included zlib is requested])
288 AC_ARG_WITH(included-zlib,
289     [  --with-included-zlib    use the zlib code included here],
290 [g10_force_zlib=yes], [g10_force_zlib=no] )
291 AC_MSG_RESULT($g10_force_zlib)
292
293 dnl
294 dnl Check whether we want to use Linux capabilities
295 dnl
296 AC_MSG_CHECKING([whether use of capabilities is requested])
297 AC_ARG_WITH(capabilities,
298     [  --with-capabilities     use linux capabilities [default=no]],
299 [use_capabilities="$withval"],[use_capabilities=no])
300 AC_MSG_RESULT($use_capabilities)
301
302
303 AH_BOTTOM([
304 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
305 #define EXEC_TEMPFILE_ONLY
306 #endif
307
308 /* This is the major version number of GnuPG so that
309    source included files can test for this. */
310 #define GNUPG_MAJOR_VERSION 1
311
312 #include "g10defs.h"
313 ])
314
315
316 AM_MAINTAINER_MODE
317
318 dnl Checks for programs.
319
320 AC_PROG_MAKE_SET
321 AM_SANITY_CHECK
322 missing_dir=`cd $ac_aux_dir && pwd`
323 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
324 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
325 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
326 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
327 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
328 AC_PROG_CC
329 AC_PROG_CPP
330 AC_PROG_RANLIB
331 AC_CHECK_TOOL(AR, ar, :)
332 AC_PATH_PROG(PERL,"perl")
333 AC_ISC_POSIX
334 AC_SYS_LARGEFILE
335 AC_PROG_INSTALL
336 AC_PROG_AWK
337 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
338 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
339 GNUPG_CHECK_FAQPROG
340 GNUPG_CHECK_DOCBOOK_TO_TEXI
341
342 MPI_OPT_FLAGS=""
343
344
345 try_gettext=yes
346 have_dosish_system=no
347 need_dlopen=yes
348 case "${target}" in
349     *-*-mingw32*)
350         # special stuff for Windoze NT
351         ac_cv_have_dev_random=no
352         AC_DEFINE(USE_ONLY_8DOT3,1,
353                   [set this to limit filenames to the 8.3 format])
354         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
355                   [defined if we must run on a stupid file system])
356         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
357                   [because the Unix gettext has too much overhead on
358                    MingW32 systems and these systems lack Posix functions,
359                    we use a simplified version of gettext])
360         have_dosish_system=yes
361         need_dlopen=no
362         try_gettext="no"
363         ;;
364     i?86-emx-os2 | i?86-*-os2*emx )
365         # OS/2 with the EMX environment
366         ac_cv_have_dev_random=no
367         AC_DEFINE(HAVE_DRIVE_LETTERS)
368         have_dosish_system=yes
369         try_gettext="no"
370         ;;
371
372     i?86-*-msdosdjgpp*)
373         # DOS with the DJGPP environment
374         ac_cv_have_dev_random=no
375         AC_DEFINE(HAVE_DRIVE_LETTERS)
376         have_dosish_system=yes
377         try_gettext="no"
378         ;;
379
380     *-*-freebsd*)
381        # FreeBSD
382        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
383        LDFLAGS="$LDFLAGS -L/usr/local/lib"
384        ;;
385
386     *-*-hpux*)
387         if test -z "$GCC" ; then
388             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
389         fi
390         ;;
391     *-dec-osf4*)
392         if test -z "$GCC" ; then
393             # Suppress all warnings
394             # to get rid of the unsigned/signed char mismatch warnings.
395             CFLAGS="$CFLAGS -w"
396         fi
397         ;;
398     *-dec-osf5*)
399         if test -z "$GCC" ; then
400             # Use the newer compiler `-msg_disable ptrmismatch' to
401             # get rid of the unsigned/signed char mismatch warnings.
402             # Using this may hide other pointer mismatch warnings, but
403             # it at least lets other warning classes through
404             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
405         fi
406         ;;
407     m68k-atari-mint)
408         ;;
409     *)
410        ;;
411 esac
412
413 if test "$have_dosish_system" = yes; then
414    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
415              [defined if we run on some of the PCDOS like systems 
416               (DOS, Windoze. OS/2) with special properties like
417               no file modes])
418 fi
419 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
420
421 AC_SUBST(MPI_OPT_FLAGS)
422 GNUPG_SYS_SYMBOL_UNDERSCORE
423
424 dnl This needs to go after AC_PROG_CC so that $EXEEXT is defined
425 if test "$try_hkp" = yes ; then
426   AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
427 fi
428
429 dnl Must check for network library requirements before doing link tests
430 dnl for ldap, for example. If ldap libs are static (or dynamic and without
431 dnl ELF runtime link paths), then link will fail and LDAP support won't
432 dnl be detected.
433
434 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
435         [NETLIBS="-lnsl $NETLIBS"]))
436 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
437         [NETLIBS="-lsocket $NETLIBS"]))
438
439 dnl Now try for the resolver functions so we can use DNS SRV
440
441 AC_ARG_ENABLE(dns-srv,
442    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
443    use_dns_srv=$enableval,use_dns_srv=yes)
444
445 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
446   _srv_save_libs=$LIBS
447   LIBS=""
448   # the double underscore thing is a glibc-ism?
449   AC_SEARCH_LIBS(res_query,resolv bind,,
450                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
451   AC_SEARCH_LIBS(dn_expand,resolv bind,,
452                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
453   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
454                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
455
456   if test x"$use_dns_srv" = xyes ; then
457      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
458      SRVLIBS=$LIBS
459   else
460      AC_MSG_WARN([Resolver functions not found.  Disabling DNS SRV.])
461   fi
462   LIBS=$_srv_save_libs
463 fi
464
465 AC_SUBST(SRVLIBS)
466
467 # Try and link a LDAP test program to weed out unusable LDAP
468 # libraries.  -lldap [-llber [-lresolv]] is for OpenLDAP.  OpenLDAP in
469 # general is terrible with creating weird dependencies.  If all else
470 # fails, the user can play guess-the-dependency by using something
471 # like ./configure LDAPLIBS="-Lfoo -lbar"
472
473 if test "$try_ldap" = yes ; then
474   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
475     _ldap_save_libs=$LIBS
476     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
477
478     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
479     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
480                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
481     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
482
483     if test $gnupg_cv_func_ldap_init = no; then
484       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
485       AC_TRY_LINK([#include <lber.h>
486 #include <ldap.h>],[ldap_open("foobar",1234);],
487          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
488       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
489     fi
490
491     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
492        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
493     fi
494
495     if test "$gnupg_cv_func_ldap_init" = yes || \
496         test "$gnupg_cv_func_ldaplber_init" = yes ; then
497        LDAPLIBS=$MY_LDAPLIBS
498        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
499
500        AC_MSG_CHECKING([whether LDAP supports ldap_get_option])
501
502        if test "$gnupg_cv_func_ldap_init" = yes ; then
503           AC_TRY_LINK([#include <ldap.h>],
504              [ldap_get_option((void *)0,0,(void *)0);],
505              [gnupg_cv_func_ldap_get_option=yes],
506              [gnupg_cv_func_ldap_get_option=no])
507         else
508           AC_TRY_LINK([#include <lber.h>
509 #include <ldap.h>],[ldap_get_option((void *)0,0,(void *)0);],
510              [gnupg_cv_func_ldap_get_option=yes],
511              [gnupg_cv_func_ldap_get_option=no])
512        fi
513
514        AC_MSG_RESULT([$gnupg_cv_func_ldap_get_option])
515
516        if test "$gnupg_cv_func_ldap_get_option" = yes ; then
517           AC_DEFINE(HAVE_LDAP_GET_OPTION,1,[Define if the LDAP library has ldap_get_option])
518        else
519           AC_MSG_CHECKING([whether LDAP supports ld_errno])
520
521           if test "$gnupg_cv_func_ldap_init" = yes ; then
522             AC_TRY_COMPILE([#include <ldap.h>],
523                [LDAP *ldap; ldap->ld_errno;],
524                [gnupg_cv_func_ldap_ld_errno=yes],
525                [gnupg_cv_func_ldap_ld_errno=no])
526            else
527             AC_TRY_LINK([#include <lber.h>
528 #include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
529                [gnupg_cv_func_ldap_ld_errno=yes],
530                [gnupg_cv_func_ldap_ld_errno=no])
531           fi
532
533           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
534
535           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
536              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
537           fi
538        fi
539     fi
540
541     LIBS=$_ldap_save_libs
542
543     if test "$GPGKEYS_LDAP" != "" ; then break; fi
544   done
545 fi
546
547 AC_SUBST(GPGKEYS_LDAP)
548 AC_SUBST(LDAPLIBS)
549
550 dnl This isn't necessarily sendmail itself, but anything that gives a
551 dnl sendmail-ish interface to the outside world.  That includes qmail,
552 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
553
554 if test "$try_mailto" = yes ; then
555   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
556
557   if test "$with_mailprog" = yes ; then
558     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
559     if test "$ac_cv_path_SENDMAIL" ; then
560       GPGKEYS_MAILTO="gpgkeys_mailto"
561     fi
562   elif test "$with_mailprog" != no ; then
563     AC_MSG_CHECKING([for a mail transport program])
564     AC_SUBST(SENDMAIL,$with_mailprog)
565     AC_MSG_RESULT($with_mailprog)
566     GPGKEYS_MAILTO="gpgkeys_mailto"
567   fi
568 fi
569
570 AC_SUBST(GPGKEYS_MAILTO)
571
572 case "${target}" in
573     *-*-mingw32*)
574         PRINTABLE_OS_NAME="MingW32"
575         ;;
576     *-*-cygwin*)
577         PRINTABLE_OS_NAME="Cygwin"
578         ;;
579     i?86-emx-os2 | i?86-*-os2*emx )
580         PRINTABLE_OS_NAME="OS/2"
581         ;;
582     i?86-*-msdosdjgpp*)
583         PRINTABLE_OS_NAME="MSDOS/DJGPP"
584         try_extensions=no
585         ;;
586     *-linux*)
587         PRINTABLE_OS_NAME="GNU/Linux"
588         ;;
589     *)
590         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
591         ;;
592 esac
593 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
594                    [A human readable text with the name of the OS])
595
596
597 #
598 # 1. Set names of random devices
599 #
600 NAME_OF_DEV_RANDOM="/dev/random"
601 NAME_OF_DEV_URANDOM="/dev/urandom"
602 case "${target}" in
603     *-openbsd*)
604         NAME_OF_DEV_RANDOM="/dev/srandom"
605         NAME_OF_DEV_URANDOM="/dev/urandom"
606         ;;
607 esac
608 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM",
609                    [defined to the name of the strong random device])
610 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM",
611                    [defined to the name of the weaker random device])
612 AC_SUBST(MPI_OPT_FLAGS)
613
614
615 dnl Checks for libraries.
616
617 if test "$try_gettext" = yes; then
618   AM_GNU_GETTEXT(,[need-ngettext])
619
620   # gettext requires some extra checks.  These really should be part of
621   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
622   # function checks to here.
623
624   AC_CHECK_FUNCS(strchr)
625 else
626   USE_NLS=no
627   USE_INCLUDED_LIBINTL=no
628   BUILD_INCLUDED_LIBINTL=no
629   AC_SUBST(USE_NLS)
630   AC_SUBST(USE_INCLUDED_LIBINTL)
631   AC_SUBST(BUILD_INCLUDED_LIBINTL)
632 fi
633
634 if test "$try_extensions" = yes || test x"$card_support" = xyes ; then
635   if test "$need_dlopen" = yes; then
636     _dl_save_libs=$LIBS
637     LIBS=""
638     AC_SEARCH_LIBS(dlopen,dl,found_dlopen=yes)
639     if test x"$found_dlopen" = "xyes" ; then
640       AC_DEFINE(HAVE_DL_DLOPEN,1,
641                 [Defined when the dlopen function family is available])
642       DLLIBS=$LIBS
643     else
644       if test "$try_extensions" = yes ; then
645          AC_MSG_WARN([dlopen not found.  Disabling extensions.])
646          try_extensions=no
647       fi
648   
649       if test "$card_support" = yes ; then
650          AC_MSG_WARN([dlopen not found.  Disabling OpenPGP card support.])
651          card_support=no
652       fi
653     fi
654     LIBS=$_dl_save_libs
655   fi
656 fi
657
658 AC_SUBST(DLLIBS)
659
660 if test "$card_support" = yes ; then
661   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include OpenPGP card support])
662 fi
663
664 if test "$try_extensions" = yes ; then
665   AC_DEFINE(USE_DYNAMIC_LINKING,1,[Define to enable the use of extensions])
666 fi
667
668 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
669
670 dnl Checks for header files.
671 AC_HEADER_STDC
672 AC_CHECK_HEADERS(unistd.h langinfo.h termio.h locale.h getopt.h)
673
674 dnl Checks for typedefs, structures, and compiler characteristics.
675 AC_C_CONST
676 AC_C_INLINE
677 AC_C_VOLATILE
678 AC_TYPE_SIZE_T
679 AC_TYPE_MODE_T
680 AC_TYPE_SIGNAL
681 AC_DECL_SYS_SIGLIST
682
683 GNUPG_CHECK_ENDIAN
684
685 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
686 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
687 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
688 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
689 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
690
691 AC_CHECK_SIZEOF(unsigned short)
692 AC_CHECK_SIZEOF(unsigned int)
693 AC_CHECK_SIZEOF(unsigned long)
694 AC_CHECK_SIZEOF(unsigned long long)
695
696 # Ensure that we have UINT64_C before we bother to check for uint64_t
697 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
698    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
699 uint64_t foo=UINT64_C(42);]),gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
700
701 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
702    AC_CHECK_SIZEOF(uint64_t)
703 fi
704
705 if test "$ac_cv_sizeof_unsigned_short" = "0" \
706    || test "$ac_cv_sizeof_unsigned_int" = "0" \
707    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
708     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
709 fi
710
711 dnl Do we have any 64-bit data types?
712 if test "$ac_cv_sizeof_unsigned_int" != "8" \
713    && test "$ac_cv_sizeof_unsigned_long" != "8" \
714    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
715    && test x"$ac_cv_sizeof_uint64_t" != "x8"; then
716     AC_MSG_WARN([No 64-bit types.  Disabling SHA-384 and SHA-512])
717 else
718   if test x"$use_sha512" = xyes ; then
719      AC_SUBST(SHA512_O,sha512.o)
720      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
721   fi
722 fi
723
724 dnl Checks for library functions.
725 AC_FUNC_FSEEKO
726 AC_FUNC_VPRINTF
727 AC_FUNC_FORK
728 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
729 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times)
730 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
731 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
732 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat getaddrinfo)
733 AC_REPLACE_FUNCS(mkdtemp)
734 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
735
736 # See if getopt is in libiberty.  This is of course not optimal since
737 # it might be somewhere other than libiberty, but does cover the
738 # mingw32 case.
739
740 AC_CHECK_FUNC(getopt,,AC_CHECK_LIB(iberty,getopt,AC_SUBST(GETOPT,"-liberty")))
741
742 #
743 # check for gethrtime and run a testprogram to see whether
744 # it is broken.  It has been reported that some Solaris and HP UX systems 
745 # raise an SIGILL
746 #
747 AC_CACHE_CHECK([for gethrtime], 
748                [gnupg_cv_func_gethrtime],
749                [AC_TRY_LINK([#include <sys/times.h>],[
750                    hrtime_t tv;
751                    tv = gethrtime();
752                  ],
753                  [gnupg_cv_func_gethrtime=yes],
754                  [gnupg_cv_func_gethrtime=no])
755                ])
756 if test $gnupg_cv_func_gethrtime = yes; then
757      AC_DEFINE([HAVE_GETHRTIME], 1,
758                [Define if you have the `gethrtime(2)' function.])
759      AC_CACHE_CHECK([whether gethrtime is broken], 
760                [gnupg_cv_func_broken_gethrtime],
761                [AC_TRY_RUN([
762                    #include <sys/times.h>
763                    int main () {
764                    hrtime_t tv;
765                    tv = gethrtime(); 
766                  }
767                  ],
768                  [gnupg_cv_func_broken_gethrtime=no],
769                  [gnupg_cv_func_broken_gethrtime=yes],
770                  [gnupg_cv_func_broken_gethrtime=assume-no])
771                 ])
772     if test $gnupg_cv_func_broken_gethrtime = yes; then
773       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
774       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
775     fi
776 fi
777      
778
779 GNUPG_CHECK_MLOCK
780 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
781
782 dnl
783 dnl Check whether we can use Linux capabilities as requested
784 dnl
785 if test "$use_capabilities" = "yes" ; then
786 use_capabilities=no
787 AC_CHECK_HEADERS(sys/capability.h)
788 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
789   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
790   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
791      AC_DEFINE(USE_CAPABILITIES,1,
792                [define if capabilities should be used])
793      AC_SUBST(CAPLIBS,"-lcap")
794      use_capabilities=yes
795   fi
796 fi
797 if test "$use_capabilities" = "no" ; then
798     AC_MSG_WARN([[
799 ***
800 *** The use of capabilities on this system is not possible.
801 *** You need a recent Linux kernel and some patches:
802 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
803 ***   fcap-module-990613.tar.gz     (kernel module)
804 ***   libcap-1.92.tar.gz            (user mode library and utilities)
805 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
806 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
807 ***]])
808 fi
809 fi
810
811
812 GNUPG_CHECK_IPC
813 if test "$ac_cv_header_sys_shm_h" = "yes"; then
814   AC_DEFINE(USE_SHM_COPROCESSING,1,
815             [define if the shared memory interface should be made available])
816 fi
817
818 dnl
819 dnl check whether we have a random device
820 dnl
821 if test "$try_dev_random" = yes ; then
822     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
823     [if test -r "$NAME_OF_DEV_RANDOM" && test -r "$NAME_OF_DEV_URANDOM" ; then
824       ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
825     if test "$ac_cv_have_dev_random" = yes; then
826         AC_DEFINE(HAVE_DEV_RANDOM,1,
827                  [defined if the system supports a random device] )
828     fi
829 else
830     AC_MSG_CHECKING(for random device)
831     ac_cv_have_dev_random=no
832     AC_MSG_RESULT(has been disabled)
833 fi
834
835
836 dnl
837 dnl Figure out the default random module.
838 dnl
839 random_modules=""
840 if test "$use_static_rnd" = default; then
841      if test "$ac_cv_have_dev_random" = yes; then
842         random_modules="rndlinux"
843      else
844          case "${target}" in
845             *-*-mingw32*|*-*-cygwin*)
846                 random_modules="rndw32"
847                 ;;
848             i?86-emx-os2|i?86-*-os2*emx)
849                 random_modules="rndos2"
850                 ;;
851             m68k-atari-mint)
852                 random_modules="rndatari"
853                 ;;
854             i?86-*-msdosdjgpp*)
855                 :
856                 ;;
857             *)
858                 random_modules="rndlinux rndegd rndunix"
859                 AC_DEFINE(USE_ALL_RANDOM_MODULES, 1, 
860                           [Allow to select random modules at runtime.])
861                 ;;
862          esac
863      fi
864 else
865   if test "$use_static_rnd" = auto; then
866      random_modules="rndlinux rndegd rndunix"
867      AC_DEFINE(USE_ALL_RANDOM_MODULES, 1)
868   else
869      random_modules="rnd$use_static_rnd";
870   fi
871 fi
872
873 if test -z "$random_modules"; then
874    AC_MSG_ERROR(no random module available)
875 fi
876 print_egd_warning=no
877 for rndmod in $random_modules "" ; do
878   case "$rndmod" in
879     rndlinux)
880          AC_DEFINE(USE_RNDLINUX,1, 
881                   [Defined if the /dev/random based RNG should be used.])
882          ;;
883     rndunix)
884          AC_DEFINE(USE_RNDUNIX,1, 
885                   [Defined if the default Unix RNG should be used.])
886          print_egd_warning=yes
887           ;;
888     rndegd)
889          AC_DEFINE(USE_RNDEGD,1, 
890                   [Defined if the EGD based RNG should be used.])
891          ;;
892     rndw32)
893          AC_DEFINE(USE_RNDW32,1, 
894                   [Defined if the Windows specific RNG should be used.])
895         ;;
896    esac
897 done
898
899 dnl setup assembler stuff
900 AC_MSG_CHECKING(for mpi assembler functions)
901 if test -f $srcdir/mpi/config.links ; then
902     . $srcdir/mpi/config.links
903     AC_CONFIG_LINKS("$mpi_ln_list")
904     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
905     ac_cv_mpi_sflags="$mpi_sflags"
906     ac_cv_mpi_config_done="yes"
907     AC_MSG_RESULT(done)
908 else
909     AC_MSG_RESULT(failed)
910     AC_MSG_ERROR([mpi/config.links missing!])
911 fi
912 MPI_EXTRA_ASM_OBJS=""
913 show_extraasm=""
914 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
915 for i in $ac_cv_mpi_extra_asm_modules; do
916     show_extraasm="$show_extraasm $i"
917     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
918 done
919 fi
920 AC_SUBST(MPI_EXTRA_ASM_OBJS)
921 MPI_SFLAGS="$ac_cv_mpi_sflags"
922 AC_SUBST(MPI_SFLAGS)
923
924 # Sanity check regex.  Tests adapted from mutt.
925
926 AC_MSG_CHECKING([whether regular expression support is requested])
927 AC_ARG_ENABLE(regex,
928 [  --disable-regex         do not handle regular expressions in trust sigs],
929      use_regex=$enableval, use_regex=yes)
930 AC_MSG_RESULT($use_regex)
931
932 if test "$use_regex" = yes ; then
933   AC_MSG_CHECKING([whether the included regex lib is requested])
934   AC_ARG_WITH(included-regex,
935       [  --with-included-regex   use the included GNU regex library],
936       [gnupg_cv_included_regex=yes],[gnupg_cv_included_regex=no])
937   AC_MSG_RESULT($gnupg_cv_included_regex)
938
939   if test $gnupg_cv_included_regex = no ; then
940      # Does the system have regex functions at all?
941      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
942                            gnupg_cv_included_regex=yes)
943   fi
944
945   if test $gnupg_cv_included_regex = no ; then
946      AC_CACHE_CHECK([whether your system's regexp library is broken],
947        [gnupg_cv_regex_broken],
948        AC_TRY_RUN([
949 #include <unistd.h>
950 #include <regex.h>
951 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
952        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
953
954      if test $gnupg_cv_regex_broken = yes ; then
955       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
956       gnupg_cv_included_regex=yes
957      fi
958   fi
959
960   if test $gnupg_cv_included_regex = yes; then
961      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
962      AC_SUBST(REGEX_O,regex.o)
963   fi
964 else
965
966   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
967 fi
968
969 dnl Do we have zlib? Must do it here because Solaris failed
970 dnl when compiling a conftest (due to the "-lz" from LIBS).
971 use_local_zlib=yes
972 if test "$g10_force_zlib" = "yes"; then
973   :
974 else
975   _cppflags="${CPPFLAGS}"
976   _ldflags="${LDFLAGS}"
977
978   AC_ARG_WITH(zlib,
979   [  --with-zlib=DIR         use libz in DIR],[
980     if test -d "$withval"; then
981       CPPFLAGS="${CPPFLAGS} -I$withval/include"
982       LDFLAGS="${LDFLAGS} -L$withval/lib"
983     fi
984   ])
985
986   AC_CHECK_HEADER(zlib.h,
987       AC_CHECK_LIB(z, deflateInit2_,
988        use_local_zlib=no
989        ZLIBS="-lz",
990        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
991        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
992 fi
993
994 if test "$use_local_zlib" = yes ; then
995     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
996     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
997     ZLIBS="../zlib/libzlib.a"
998 else
999     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
1000 fi
1001 AC_SUBST(ZLIBS)
1002
1003
1004 #
1005 # libusb allows us to use the integrated CCID smartcard reader driver.
1006 #
1007 # Note, that we need the CVS (unstable) version. 
1008 #
1009 LIBUSB_LIBS=""
1010 if test "$card_support" = yes; then
1011     AC_CHECK_LIB(usb, usb_find_device,
1012                  [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
1013                    AC_DEFINE(HAVE_LIBUSB,1,
1014                    [defined if libusb is available])
1015                  ])
1016 fi
1017 AC_SUBST(LIBUSB_LIBS)
1018
1019
1020
1021 # Allow users to append something to the version string without
1022 # flagging it as development version.  The user version parts is
1023 # considered everything after a dash. 
1024 if test "$development_version" != yes; then
1025   changequote(,)dnl
1026   tmp_pat='[a-zA-Z]'
1027   changequote([,])dnl
1028   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1029     development_version=yes
1030   fi
1031 fi
1032 if test "$development_version" = yes; then
1033     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1034             [Defined if this is not a regular release])
1035 fi
1036
1037 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1038
1039 GNUPG_CHECK_GNUMAKE
1040
1041 # add some extra libs here so that previous tests don't fail for
1042 # mysterious reasons - the final link step should bail out. 
1043 case "${target}" in
1044     *-*-mingw32*)
1045 dnl      NETLIBS="$NETLIBS -lwsock32"
1046         W32LIBS="-lwsock32"
1047         ;;
1048     *)
1049        ;;
1050 esac
1051
1052 AC_SUBST(NETLIBS)
1053 AC_SUBST(W32LIBS)
1054
1055 if test "$GCC" = yes; then
1056     if test "$USE_MAINTAINER_MODE" = "yes"; then
1057         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1058     else
1059         CFLAGS="$CFLAGS -Wall"
1060     fi
1061 fi
1062
1063
1064 if test "$print_egd_warning" = yes; then
1065   AC_MSG_WARN([[
1066 ***
1067 *** The performance of the UNIX random gatherer module is not very good
1068 *** and it does not keep the entropy pool over multiple invocations of
1069 *** GnuPG.  The suggested way to overcome this problem is to use the
1070 ***
1071 ***               Entropy Gathering Daemon (EGD)
1072 ***
1073 *** which provides a entropy source for the whole system.  It is written
1074 *** in Perl and available at the GnuPG FTP servers.  For more information
1075 *** consult the GnuPG webpages:
1076 ***
1077 ***           http://www.gnupg.org/download/#EGD
1078 ***
1079 *** You may want to run ./configure with --enable-static-rnd=egd or
1080 *** --enable-static-rnd=auto to use it.
1081 ***]])
1082 fi
1083
1084 # Note the \\\\ for backslashes.  Autoconf eats one layer, leaving \\
1085
1086 AC_CONFIG_COMMANDS(g10defs.h,[[
1087 cat >g10defs.tmp <<G10EOF
1088 /* Generated automatically by configure */
1089 #ifdef HAVE_DRIVE_LETTERS
1090 #define G10_LOCALEDIR     "c:\\\\lib\\\\gnupg\\\\locale"
1091 #define GNUPG_LIBDIR      "c:\\\\lib\\\\gnupg"
1092 #define GNUPG_LIBEXECDIR  "c:\\\\lib\\\\gnupg"
1093 #define GNUPG_DATADIR     "c:\\\\lib\\\\gnupg"
1094 #define GNUPG_HOMEDIR     "c:\\\\gnupg"
1095 #else
1096 #define G10_LOCALEDIR     "${datadir}/locale"
1097 #define GNUPG_LIBDIR      "${libdir}/gnupg"
1098 #define GNUPG_DATADIR     "${datadir}/gnupg"
1099 #ifdef __VMS
1100 #define GNUPG_HOMEDIR "/SYS\$LOGIN/gnupg" 
1101 #else
1102 #define GNUPG_HOMEDIR "~/.gnupg" 
1103 #endif
1104 #endif
1105 /* those are here to be redefined by handcrafted g10defs.h.
1106    Please note that the string version must not contain more
1107    than one character because the using code assumes strlen()==1 */
1108 #ifdef HAVE_DOSISH_SYSTEM
1109 #define DIRSEP_C '\\\\'
1110 #define EXTSEP_C '.'
1111 #define DIRSEP_S "\\\\"
1112 #define EXTSEP_S "."
1113 #else
1114 #define DIRSEP_C '/'
1115 #define EXTSEP_C '.'
1116 #define DIRSEP_S "/"
1117 #define EXTSEP_S "."
1118 #endif
1119 /* This is the same as VERSION, but should be overridden if the
1120    platform cannot handle things like dots '.' in filenames. */
1121 #define SAFE_VERSION VERSION
1122 G10EOF
1123 cat mpi/mpi-asm-defs.h >>g10defs.tmp 
1124 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
1125     echo "g10defs.h is unchanged"
1126     rm -f g10defs.tmp
1127 else
1128     rm -f g10defs.h
1129     mv g10defs.tmp g10defs.h
1130     echo "g10defs.h created"
1131 fi
1132 ]],[[
1133 prefix=$prefix
1134 exec_prefix=$exec_prefix
1135 libdir=$libdir
1136 libexecdir=$libexecdir
1137 datadir=$datadir
1138 DATADIRNAME=$DATADIRNAME
1139 ]])
1140
1141
1142 AC_CONFIG_FILES([
1143 Makefile
1144 intl/Makefile
1145 po/Makefile.in
1146 util/Makefile
1147 mpi/Makefile
1148 cipher/Makefile
1149 g10/Makefile
1150 keyserver/Makefile
1151 keyserver/gpgkeys_mailto
1152 keyserver/gpgkeys_test
1153 doc/Makefile
1154 tools/Makefile
1155 zlib/Makefile
1156 checks/Makefile
1157 ])
1158 AC_OUTPUT
1159
1160 # Give some feedback
1161 echo
1162 echo   "                Configured for: $PRINTABLE_OS_NAME ($target)"
1163 if test -n "$show_extraasm"; then
1164   echo "  Extra cpu specific functions:$show_extraasm"
1165 fi
1166 echo