* configure.ac: configure.ac: Check for sigset_t and struct sigaction.
[gnupg.git] / configure.ac
1 dnl Configure.ac script for GnuPG
2 dnl Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 dnl               2003 Free Software Foundation, Inc.
4 dnl
5 dnl This file is part of GnuPG.
6 dnl
7 dnl GnuPG is free software; you can redistribute it and/or modify
8 dnl it under the terms of the GNU General Public License as published by
9 dnl the Free Software Foundation; either version 2 of the License, or
10 dnl (at your option) any later version.
11 dnl 
12 dnl GnuPG is distributed in the hope that it will be useful,
13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 dnl GNU General Public License for more details.
16 dnl 
17 dnl You should have received a copy of the GNU General Public License
18 dnl along with this program; if not, write to the Free Software
19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20 dnl
21 dnl (Process this file with autoconf to produce a configure script.)
22 dnlAC_REVISION($Revision$)dnl
23
24 AC_PREREQ(2.52)
25
26 # Remember to change the version number immediately *after* a release
27 # and remove the "-cvs" or "rc" suffix immediately *before* a release.
28 AC_INIT(gnupg, 1.3.3-cvs, bug-gnupg@gnu.org)
29 # Set development_version to yes if the minor number is odd or you
30 # feel that the default check for a development version is not
31 # sufficient.
32 development_version=yes
33
34 ALL_LINGUAS="de"
35
36 AC_CONFIG_AUX_DIR(scripts)
37 AC_CONFIG_SRCDIR(g10/g10.c)
38 AC_CANONICAL_TARGET()
39 AM_INIT_AUTOMAKE
40 AM_CONFIG_HEADER(config.h)
41
42 AC_GNU_SOURCE
43
44 dnl
45 dnl  Check for random module options
46 dnl
47 AC_MSG_CHECKING([which random module to use])
48 AC_ARG_ENABLE(static-rnd,
49     [  --enable-static-rnd=[egd|unix|linux|auto]  ],
50 [use_static_rnd=$enableval], [use_static_rnd=default] )
51
52 if test "$use_static_rnd" = no; then
53     use_static_rnd=default
54 fi
55
56 case "$use_static_rnd" in
57     egd | linux | unix | default )
58       AC_MSG_RESULT($use_static_rnd)
59       ;;
60     auto )
61       AC_MSG_RESULT(automagically selected at runtime)
62       ;;
63     * )
64       AC_MSG_RESULT(invalid argument)
65       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
66       ;;
67 esac
68
69 AC_ARG_WITH(egd-socket,
70     [  --with-egd-socket=NAME  use NAME for the EGD socket],
71             egd_socket_name="$withval", egd_socket_name="" )
72 AC_DEFINE_UNQUOTED(EGD_SOCKET_NAME, "$egd_socket_name",
73                    [Define if you don't want the default EGD socket name.
74                     For details see cipher/rndegd.c])
75
76
77 dnl
78 dnl See whether the user wants to disable checking for /dev/random
79
80 AC_MSG_CHECKING([whether use of /dev/random is requested])
81 AC_ARG_ENABLE(dev-random,
82 [  --disable-dev-random    disable the use of dev random],
83     try_dev_random=$enableval, try_dev_random=yes)
84 AC_MSG_RESULT($try_dev_random)
85
86
87 dnl
88 dnl  Check other options
89 dnl
90
91 AC_MSG_CHECKING([whether assembler modules are requested])
92 AC_ARG_ENABLE(asm,
93 [  --disable-asm           do not use assembler modules],
94      try_asm_modules=$enableval, try_asm_modules=yes)
95 AC_MSG_RESULT($try_asm_modules)
96
97 AC_MSG_CHECKING([whether memory guard is requested])
98 AC_ARG_ENABLE(m-guard,
99     [  --enable-m-guard        enable memory guard facility],
100     use_m_guard=$enableval, use_m_guard=no)
101 AC_MSG_RESULT($use_m_guard)
102 if test "$use_m_guard" = yes ; then
103     AC_DEFINE(M_GUARD,1,[Define to use the (obsolete) malloc guarding feature])
104 fi
105
106 dnl See if we are disabling any algorithms or features for a smaller
107 dnl binary
108
109 try_dynload=no
110
111 use_idea=yes
112 use_cast5=yes
113 use_blowfish=yes
114 use_aes=yes
115 use_twofish=yes
116 use_tiger192=no
117 use_old_tiger192=no
118 use_sha256=yes
119 use_sha512=yes
120 use_exec=yes
121
122 AC_ARG_ENABLE(minimal,
123    AC_HELP_STRING([--enable-minimal],[build the smallest gpg binary possible]),
124    use_idea=no
125    use_cast5=no
126    use_blowfish=no
127    use_aes=no
128    use_twofish=no
129    use_sha256=no
130    use_sha512=no
131    use_exec=no)
132
133 AC_MSG_CHECKING([whether to enable the IDEA cipher])
134 AC_ARG_ENABLE(idea,
135    AC_HELP_STRING([--disable-idea],[disable the IDEA cipher]),
136    use_idea=$enableval)
137 AC_MSG_RESULT($use_idea)
138 if test x"$use_idea" = xyes ; then
139    AC_DEFINE(USE_IDEA,1,[Define to include the IDEA cipher])
140
141 # We don't need idea but some people claim that they need it for
142 # research etc., so we allow to place an idea source code into the
143 # cipher directory and statically link it if available, otherwise we
144 # link to a stub.  We don't use AC_CHECK_FILE to avoid caching.
145
146    AC_MSG_CHECKING([for idea cipher module])
147    tmp=""
148    if test -f $srcdir/cipher/idea.c; then 
149       IDEA_O=idea.o
150       tmp=idea
151    else
152       IDEA_O=idea-stub.o
153       tmp=no
154       try_dynload=yes
155    fi
156    AC_SUBST(IDEA_O)
157    AC_MSG_RESULT($tmp)
158 fi
159
160 AC_MSG_CHECKING([whether to enable the CAST5 cipher])
161 AC_ARG_ENABLE(cast5,
162    AC_HELP_STRING([--disable-cast5],[disable the CAST5 cipher]),
163    use_cast5=$enableval)
164 AC_MSG_RESULT($use_cast5)
165 if test x"$use_cast5" = xyes ; then
166    AC_DEFINE(USE_CAST5,1,[Define to include the CAST5 cipher])
167 fi
168
169 AC_MSG_CHECKING([whether to enable the BLOWFISH cipher])
170 AC_ARG_ENABLE(blowfish,
171    AC_HELP_STRING([--disable-blowfish],[disable the BLOWFISH cipher]),
172    use_blowfish=$enableval)
173 AC_MSG_RESULT($use_blowfish)
174 if test x"$use_blowfish" = xyes ; then
175    AC_DEFINE(USE_BLOWFISH,1,[Define to include the BLOWFISH cipher])
176 fi
177
178 AC_MSG_CHECKING([whether to enable the AES ciphers])
179 AC_ARG_ENABLE(aes,
180    AC_HELP_STRING([--disable-aes],[disable the AES, AES192, and AES256 ciphers]),
181    use_aes=$enableval)
182 AC_MSG_RESULT($use_aes)
183 if test x"$use_aes" = xyes ; then
184    AC_DEFINE(USE_AES,1,[Define to include the AES, AES192, and AES256 ciphers])
185 fi
186
187 AC_MSG_CHECKING([whether to enable the TWOFISH cipher])
188 AC_ARG_ENABLE(twofish,
189    AC_HELP_STRING([--disable-twofish],[disable the TWOFISH cipher]),
190    use_twofish=$enableval)
191 AC_MSG_RESULT($use_twofish)
192 if test x"$use_twofish" = xyes ; then
193    AC_DEFINE(USE_TWOFISH,1,[Define to include the TWOFISH cipher])
194 fi
195
196 dnl this is because the stable branch calls it just "tiger".
197 AC_ARG_ENABLE(tiger,,use_tiger192=$enableval)
198 AC_ARG_ENABLE(old-tiger,,use_old_tiger192=$enableval)
199
200 dnl TIGER192 is actually defined only after we confirm 64-bit support
201 dnl later
202 AC_MSG_CHECKING([whether to enable the nonstandard TIGER/192 digest])
203 AC_ARG_ENABLE(tiger192,
204    AC_HELP_STRING([--enable-tiger192],[enable the nonstandard TIGER/192 digest]),
205    use_tiger192=$enableval)
206 AC_MSG_RESULT($use_tiger192)
207
208 AC_MSG_CHECKING([whether to enable old-style nonstandard TIGER/192 digest support])
209 AC_ARG_ENABLE(old-tiger192,
210    AC_HELP_STRING([--enable-old-tiger192],[enable old-style nonstandard TIGER/192 digest support]),
211    use_old_tiger=$enableval)
212 AC_MSG_RESULT($use_old_tiger192)
213
214 if test x"$use_tiger192" = xyes || test x"$use_old_tiger192" = xyes ; then
215    AC_MSG_WARN([[
216 ***
217 *** The TIGER/192 digest is in the process of being removed from the
218 *** OpenPGP standard.  While it hasn't been removed from GnuPG yet, it
219 *** will be removed in a future version.  For the sake of future
220 *** compatibility, please do not use this digest.
221 ***]])
222 fi
223
224 AC_MSG_CHECKING([whether to enable the SHA-256 digest])
225 AC_ARG_ENABLE(sha256,
226    AC_HELP_STRING([--disable-sha256],[disable the SHA-256 digest]),
227    use_sha256=$enableval)
228 AC_MSG_RESULT($use_sha256)
229 if test x"$use_sha256" = xyes ; then
230    AC_DEFINE(USE_SHA256,1,[Define to include the SHA-256 digest])
231 fi
232
233 dnl SHA512 is defined only after we confirm 64-bit support later
234 AC_MSG_CHECKING([whether to enable the SHA-384 and SHA-512 digests])
235 AC_ARG_ENABLE(sha512,
236    AC_HELP_STRING([--disable-sha512],[disable the SHA-384 and SHA-512 digests]),
237    use_sha512=$enableval)
238 AC_MSG_RESULT($use_sha512)
239
240 AC_MSG_CHECKING([whether to enable external program execution])
241 AC_ARG_ENABLE(exec,
242     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
243     use_exec=$enableval)
244 AC_MSG_RESULT($use_exec)
245 if test "$use_exec" = no ; then
246     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
247 fi
248
249 if test "$use_exec" = yes ; then
250   AC_MSG_CHECKING([whether to enable photo ID viewing])
251   AC_ARG_ENABLE(photo-viewers,
252       [  --disable-photo-viewers disable photo ID viewers],
253       [if test "$enableval" = no ; then
254          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
255       fi],enableval=yes)
256   gnupg_cv_enable_photo_viewers=$enableval
257   AC_MSG_RESULT($enableval)
258
259   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
260     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
261     AC_ARG_WITH(photo-viewer,
262         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
263         [if test "$withval" = yes ; then
264            withval=no
265         elif test "$withval" != no ; then
266            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
267                             [if set, restrict photo-viewer to this])
268         fi],withval=no)
269     AC_MSG_RESULT($withval)
270   fi
271
272   AC_MSG_CHECKING([whether to enable external keyserver helpers])
273   AC_ARG_ENABLE(keyserver-helpers,
274       [  --disable-keyserver-helpers  disable all external keyserver support],
275       [if test "$enableval" = no ; then
276          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
277                   [define to disable keyserver helpers])
278       fi],enableval=yes)
279   gnupg_cv_enable_keyserver_helpers=$enableval
280   AC_MSG_RESULT($enableval)
281
282   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
283     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
284     AC_ARG_ENABLE(ldap,
285     [  --disable-ldap          disable LDAP keyserver interface],
286         try_ldap=$enableval, try_ldap=yes)
287     AC_MSG_RESULT($try_ldap)
288
289     AC_MSG_CHECKING([whether HKP keyserver support is requested])
290     AC_ARG_ENABLE(hkp,
291     [  --disable-hkp           disable HKP keyserver interface],
292         try_hkp=$enableval, try_hkp=yes)
293     AC_MSG_RESULT($try_hkp)
294
295     AC_MSG_CHECKING([whether email keyserver support is requested])
296     AC_ARG_ENABLE(mailto,
297     [  --disable-mailto        disable email keyserver interface],
298         try_mailto=$enableval, try_mailto=yes)
299     AC_MSG_RESULT($try_mailto)
300     fi
301
302     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
303     AC_ARG_ENABLE(keyserver-path,
304         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
305         [if test "$enableval" = no ; then
306          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
307         fi],enableval=yes)
308     AC_MSG_RESULT($enableval)
309   fi
310
311 AC_MSG_CHECKING([whether the included zlib is requested])
312 AC_ARG_WITH(included-zlib,
313     [  --with-included-zlib    use the zlib code included here],
314 [g10_force_zlib=yes], [g10_force_zlib=no] )
315 AC_MSG_RESULT($g10_force_zlib)
316
317 dnl
318 dnl Check whether we want to use Linux capabilities
319 dnl
320 AC_MSG_CHECKING([whether use of capabilities is requested])
321 AC_ARG_WITH(capabilities,
322     [  --with-capabilities     use linux capabilities [default=no]],
323 [use_capabilities="$withval"],[use_capabilities=no])
324 AC_MSG_RESULT($use_capabilities)
325
326
327 AH_BOTTOM([
328 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
329 #define EXEC_TEMPFILE_ONLY
330 #endif
331
332 #include "g10defs.h"
333 ])
334
335
336 AM_MAINTAINER_MODE
337
338 dnl Checks for programs.
339
340 AC_PROG_MAKE_SET
341 AM_SANITY_CHECK
342 missing_dir=`cd $ac_aux_dir && pwd`
343 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
344 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
345 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
346 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
347 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
348 AC_PROG_CC
349 AC_PROG_CPP
350 AC_PROG_RANLIB
351 AC_CHECK_TOOL(AR, ar, :)
352 AC_PATH_PROG(PERL,"perl")
353 AC_ISC_POSIX
354 AC_SYS_LARGEFILE
355 AC_PROG_INSTALL
356 AC_PROG_AWK
357 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
358 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
359 GNUPG_CHECK_FAQPROG
360 GNUPG_CHECK_DOCBOOK_TO_TEXI
361
362 MPI_OPT_FLAGS=""
363
364
365 try_gettext=yes
366 have_dosish_system=no
367 case "${target}" in
368     *-*-mingw32*)
369         # special stuff for Windoze NT
370         ac_cv_have_dev_random=no
371         AC_DEFINE(USE_ONLY_8DOT3,1,
372                   [set this to limit filenames to the 8.3 format])
373         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
374                   [defined if we must run on a stupid file system])
375         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
376                   [because the Unix gettext has too much overhead on
377                    MingW32 systems and these systems lack Posix functions,
378                    we use a simplified version of gettext])
379         have_dosish_system=yes
380         try_gettext="no"
381         ;;
382     i?86-emx-os2 | i?86-*-os2*emx )
383         # OS/2 with the EMX environment
384         ac_cv_have_dev_random=no
385         AC_DEFINE(HAVE_DRIVE_LETTERS)
386         have_dosish_system=yes
387         try_gettext="no"
388         ;;
389
390     i?86-*-msdosdjgpp*)
391         # DOS with the DJGPP environment
392         ac_cv_have_dev_random=no
393         AC_DEFINE(HAVE_DRIVE_LETTERS)
394         have_dosish_system=yes
395         try_gettext="no"
396         ;;
397
398     *-*-freebsd*)
399        # FreeBSD
400        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
401        LDFLAGS="$LDFLAGS -L/usr/local/lib"
402        ;;
403
404     *-*-hpux*)
405         if test -z "$GCC" ; then
406             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
407         fi
408         ;;
409     *-dec-osf4*)
410         if test -z "$GCC" ; then
411             # Suppress all warnings
412             # to get rid of the unsigned/signed char mismatch warnings.
413             CFLAGS="$CFLAGS -w"
414         fi
415         ;;
416     *-dec-osf5*)
417         if test -z "$GCC" ; then
418             # Use the newer compiler `-msg_disable ptrmismatch' to
419             # get rid of the unsigned/signed char mismatch warnings.
420             # Using this may hide other pointer mismatch warnings, but
421             # it at least lets other warning classes through
422             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
423         fi
424         ;;
425     m68k-atari-mint)
426         ;;
427     *)
428        ;;
429 esac
430
431 if test "$have_dosish_system" = yes; then
432    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
433              [defined if we run on some of the PCDOS like systems 
434               (DOS, Windoze. OS/2) with special properties like
435               no file modes])
436 fi
437 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
438
439 AC_SUBST(MPI_OPT_FLAGS)
440 GNUPG_SYS_SYMBOL_UNDERSCORE
441
442 dnl This needs to go after AC_PROG_CC so that $EXEEXT is defined
443 if test "$try_hkp" = yes ; then
444   AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
445 fi
446
447 dnl Must check for network library requirements before doing link tests
448 dnl for ldap, for example. If ldap libs are static (or dynamic and without
449 dnl ELF runtime link paths), then link will fail and LDAP support won't
450 dnl be detected.
451
452 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
453         [NETLIBS="-lnsl $NETLIBS"]))
454 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
455         [NETLIBS="-lsocket $NETLIBS"]))
456
457 dnl Now try for the resolver functions so we can use DNS SRV
458
459 AC_ARG_ENABLE(dns-srv,
460    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
461    use_dns_srv=$enableval,use_dns_srv=yes)
462
463 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
464   _srv_save_libs=$LIBS
465   LIBS=""
466   # the double underscore thing is a glibc-ism?
467   AC_SEARCH_LIBS(res_query,resolv bind,,
468                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
469   AC_SEARCH_LIBS(dn_expand,resolv bind,,
470                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
471   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
472                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
473
474   if test x"$use_dns_srv" = xyes ; then
475      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
476      SRVLIBS=$LIBS
477   else
478      AC_MSG_WARN([Resolver functions not found.  Disabling DNS SRV.])
479   fi
480   LIBS=$_srv_save_libs
481 fi
482
483 AC_SUBST(SRVLIBS)
484
485 # Try and link a LDAP test program to weed out unusable LDAP
486 # libraries.  -lldap [-llber [-lresolv]] is for OpenLDAP.  OpenLDAP in
487 # general is terrible with creating weird dependencies.  If all else
488 # fails, the user can play guess-the-dependency by using something
489 # like ./configure LDAPLIBS="-Lfoo -lbar"
490
491 if test "$try_ldap" = yes ; then
492   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
493     _ldap_save_libs=$LIBS
494     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
495
496     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
497     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
498                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
499     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
500
501     if test $gnupg_cv_func_ldap_init = no; then
502       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
503       AC_TRY_LINK([#include <lber.h>
504 #include <ldap.h>],[ldap_open("foobar",1234);],
505          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
506       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
507     fi
508
509     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
510        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
511     fi
512
513     if test "$gnupg_cv_func_ldap_init" = yes || \
514         test "$gnupg_cv_func_ldaplber_init" = yes ; then
515        LDAPLIBS=$MY_LDAPLIBS
516        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
517
518        AC_MSG_CHECKING([whether LDAP supports ldap_get_option])
519
520        if test "$gnupg_cv_func_ldap_init" = yes ; then
521           AC_TRY_LINK([#include <ldap.h>],
522              [ldap_get_option((void *)0,0,(void *)0);],
523              [gnupg_cv_func_ldap_get_option=yes],
524              [gnupg_cv_func_ldap_get_option=no])
525         else
526           AC_TRY_LINK([#include <lber.h>
527 #include <ldap.h>],[ldap_get_option((void *)0,0,(void *)0);],
528              [gnupg_cv_func_ldap_get_option=yes],
529              [gnupg_cv_func_ldap_get_option=no])
530        fi
531
532        AC_MSG_RESULT([$gnupg_cv_func_ldap_get_option])
533
534        if test "$gnupg_cv_func_ldap_get_option" = yes ; then
535           AC_DEFINE(HAVE_LDAP_GET_OPTION,1,[Define if the LDAP library has ldap_get_option])
536        else
537           AC_MSG_CHECKING([whether LDAP supports ld_errno])
538
539           if test "$gnupg_cv_func_ldap_init" = yes ; then
540             AC_TRY_COMPILE([#include <ldap.h>],
541                [LDAP *ldap; ldap->ld_errno;],
542                [gnupg_cv_func_ldap_ld_errno=yes],
543                [gnupg_cv_func_ldap_ld_errno=no])
544            else
545             AC_TRY_LINK([#include <lber.h>
546 #include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
547                [gnupg_cv_func_ldap_ld_errno=yes],
548                [gnupg_cv_func_ldap_ld_errno=no])
549           fi
550
551           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
552
553           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
554              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
555           fi
556        fi
557     fi
558
559     LIBS=$_ldap_save_libs
560
561     if test "$GPGKEYS_LDAP" != "" ; then break; fi
562   done
563 fi
564
565 AC_SUBST(GPGKEYS_LDAP)
566 AC_SUBST(LDAPLIBS)
567
568 dnl This isn't necessarily sendmail itself, but anything that gives a
569 dnl sendmail-ish interface to the outside world.  That includes qmail,
570 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
571
572 if test "$try_mailto" = yes ; then
573   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
574
575   if test "$with_mailprog" = yes ; then
576     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
577     if test "$ac_cv_path_SENDMAIL" ; then
578       GPGKEYS_MAILTO="gpgkeys_mailto"
579     fi
580   elif test "$with_mailprog" != no ; then
581     AC_MSG_CHECKING([for a mail transport program])
582     AC_SUBST(SENDMAIL,$with_mailprog)
583     AC_MSG_RESULT($with_mailprog)
584     GPGKEYS_MAILTO="gpgkeys_mailto"
585   fi
586 fi
587
588 AC_SUBST(GPGKEYS_MAILTO)
589
590 case "${target}" in
591     *-*-mingw32*)
592         PRINTABLE_OS_NAME="MingW32"
593         ;;
594     *-*-cygwin*)
595         PRINTABLE_OS_NAME="Cygwin"
596         ;;
597     i?86-emx-os2 | i?86-*-os2*emx )
598         PRINTABLE_OS_NAME="OS/2"
599         ;;
600     i?86-*-msdosdjgpp*)
601         PRINTABLE_OS_NAME="MSDOS/DJGPP"
602         try_dynload=no
603         ;;
604     *-linux*)
605         PRINTABLE_OS_NAME="GNU/Linux"
606         ;;
607 dnl let that after linux to avoid gnu-linux problems
608     *-gnu*)
609         PRINTABLE_OS_NAME="GNU/Hurd"
610         ;;
611     *)
612         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
613         ;;
614 esac
615 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
616                    [A human readable text with the name of the OS])
617
618
619 #
620 # 1. Set names of random devices
621 #
622 NAME_OF_DEV_RANDOM="/dev/random"
623 NAME_OF_DEV_URANDOM="/dev/urandom"
624 case "${target}" in
625     *-openbsd*)
626         NAME_OF_DEV_RANDOM="/dev/srandom"
627         NAME_OF_DEV_URANDOM="/dev/urandom"
628         ;;
629 esac
630 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM",
631                    [defined to the name of the strong random device])
632 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM",
633                    [defined to the name of the weaker random device])
634 AC_SUBST(MPI_OPT_FLAGS)
635
636
637 dnl Checks for libraries.
638
639 if test "$try_gettext" = yes; then
640   AM_GNU_GETTEXT(,[need-ngettext])
641
642   # gettext requires some extra checks.  These really should be part of
643   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
644   # function checks to here.
645
646   AC_CHECK_FUNCS(strchr)
647 else
648   USE_NLS=no
649   USE_INCLUDED_LIBINTL=no
650   BUILD_INCLUDED_LIBINTL=no
651   AC_SUBST(USE_NLS)
652   AC_SUBST(USE_INCLUDED_LIBINTL)
653   AC_SUBST(BUILD_INCLUDED_LIBINTL)
654 fi
655
656 if test "$try_dynload" = yes ; then
657   AC_CHECK_FUNC(dlopen,,AC_CHECK_LIB(dl,dlopen,found_dlopen=yes))
658   if test x"$found_dlopen" = "xyes" ; then
659     AC_DEFINE(USE_DYNAMIC_LINKING,1,[define to enable the use of extensions])
660     AC_DEFINE(HAVE_DL_DLOPEN,1,
661               [Defined when the dlopen function family is available])
662     AC_SUBST(DLLIBS,"-ldl")
663   fi
664 else
665   AC_MSG_CHECKING(for dynamic loading)
666   AC_MSG_RESULT(has been disabled)
667 fi
668
669
670 dnl Checks for header files.
671 AC_HEADER_STDC
672 AC_CHECK_HEADERS(unistd.h langinfo.h termio.h locale.h getopt.h)
673
674 dnl Checks for typedefs, structures, and compiler characteristics.
675 AC_C_CONST
676 AC_C_INLINE
677 AC_C_VOLATILE
678 AC_TYPE_SIZE_T
679 AC_TYPE_MODE_T
680 AC_TYPE_SIGNAL
681 AC_DECL_SYS_SIGLIST
682
683 GNUPG_CHECK_ENDIAN
684
685 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
686 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
687 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
688 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
689 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
690
691 AC_CHECK_SIZEOF(unsigned short)
692 AC_CHECK_SIZEOF(unsigned int)
693 AC_CHECK_SIZEOF(unsigned long)
694 AC_CHECK_SIZEOF(unsigned long long)
695 AC_CHECK_SIZEOF(uint64_t)
696
697 if test "$ac_cv_sizeof_unsigned_short" = "0" \
698    || test "$ac_cv_sizeof_unsigned_int" = "0" \
699    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
700     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
701 fi
702
703 dnl Do we have any 64-bit data types?
704 if test "$ac_cv_sizeof_unsigned_int" != "8" \
705    && test "$ac_cv_sizeof_unsigned_long" != "8" \
706    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
707    && test "$ac_cv_sizeof_uint64_t" != "8"; then
708     AC_MSG_WARN([No 64-bit types.  Disabling TIGER/192, SHA-384, and SHA-512])
709 else
710   if test x"$use_tiger192" = xyes ; then
711      AC_SUBST(TIGER_O,tiger.o)
712      AC_DEFINE(USE_TIGER192,1,[Define to include the TIGER/192 digest])
713   fi
714
715   if test "$use_old_tiger192" = yes ; then
716      AC_SUBST(TIGER_O,tiger.o)
717      AC_DEFINE(USE_TIGER192,1,[Define to include the TIGER/192 digest])
718      AC_DEFINE(USE_OLD_TIGER,1,[Define to use the old fake OID for TIGER/192 digest support])
719   fi
720
721   if test x"$use_sha512" = xyes ; then
722      AC_SUBST(SHA512_O,sha512.o)
723      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
724   fi
725 fi
726
727 dnl Checks for library functions.
728 AC_FUNC_FSEEKO
729 AC_FUNC_VPRINTF
730 AC_FUNC_FORK
731 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
732 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times)
733 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
734 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
735 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat)
736 AC_REPLACE_FUNCS(mkdtemp)
737 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
738
739 # See if getopt is in libiberty.  This is of course not optimal since
740 # it might be somewhere other than libiberty, but does cover the
741 # mingw32 case.
742
743 AC_CHECK_FUNC(getopt,,AC_CHECK_LIB(iberty,getopt,AC_SUBST(GETOPT,"-liberty")))
744
745 #
746 # check for gethrtime and run a testprogram to see whether
747 # it is broken.  It has been reported that some Solaris and HP UX systems 
748 # raise an SIGILL
749 #
750 AC_CACHE_CHECK([for gethrtime], 
751                [gnupg_cv_func_gethrtime],
752                [AC_TRY_LINK([#include <sys/times.h>],[
753                    hrtime_t tv;
754                    tv = gethrtime();
755                  ],
756                  [gnupg_cv_func_gethrtime=yes],
757                  [gnupg_cv_func_gethrtime=no])
758                ])
759 if test $gnupg_cv_func_gethrtime = yes; then
760      AC_DEFINE([HAVE_GETHRTIME], 1,
761                [Define if you have the `gethrtime(2)' function.])
762      AC_CACHE_CHECK([whether gethrtime is broken], 
763                [gnupg_cv_func_broken_gethrtime],
764                [AC_TRY_RUN([
765                    #include <sys/times.h>
766                    int main () {
767                    hrtime_t tv;
768                    tv = gethrtime(); 
769                  }
770                  ],
771                  [gnupg_cv_func_broken_gethrtime=no],
772                  [gnupg_cv_func_broken_gethrtime=yes],
773                  [gnupg_cv_func_broken_gethrtime=assume-no])
774                 ])
775     if test $gnupg_cv_func_broken_gethrtime = yes; then
776       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
777       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
778     fi
779 fi
780      
781
782 GNUPG_CHECK_MLOCK
783 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
784
785 dnl
786 dnl Check whether we can use Linux capabilities as requested
787 dnl
788 if test "$use_capabilities" = "yes" ; then
789 use_capabilities=no
790 AC_CHECK_HEADERS(sys/capability.h)
791 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
792   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
793   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
794      AC_DEFINE(USE_CAPABILITIES,1,
795                [define if capabilities should be used])
796      AC_SUBST(CAPLIBS,"-lcap")
797      use_capabilities=yes
798   fi
799 fi
800 if test "$use_capabilities" = "no" ; then
801     AC_MSG_WARN([[
802 ***
803 *** The use of capabilities on this system is not possible.
804 *** You need a recent Linux kernel and some patches:
805 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
806 ***   fcap-module-990613.tar.gz     (kernel module)
807 ***   libcap-1.92.tar.gz            (user mode library and utilities)
808 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
809 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
810 ***]])
811 fi
812 fi
813
814
815 GNUPG_CHECK_IPC
816 if test "$ac_cv_header_sys_shm_h" = "yes"; then
817   AC_DEFINE(USE_SHM_COPROCESSING,1,
818             [define if the shared memory interface should be made available])
819 fi
820
821 dnl
822 dnl check whether we have a random device
823 dnl
824 if test "$try_dev_random" = yes ; then
825     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
826     [if test -r "$NAME_OF_DEV_RANDOM" && test -r "$NAME_OF_DEV_URANDOM" ; then
827       ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
828     if test "$ac_cv_have_dev_random" = yes; then
829         AC_DEFINE(HAVE_DEV_RANDOM,1,
830                  [defined if the system supports a random device] )
831     fi
832 else
833     AC_MSG_CHECKING(for random device)
834     ac_cv_have_dev_random=no
835     AC_MSG_RESULT(has been disabled)
836 fi
837
838
839 dnl
840 dnl Figure out the default random module.
841 dnl
842 random_modules=""
843 if test "$use_static_rnd" = default; then
844      if test "$ac_cv_have_dev_random" = yes; then
845         random_modules="rndlinux"
846      else
847          case "${target}" in
848             *-*-mingw32*|*-*-cygwin*)
849                 random_modules="rndw32"
850                 ;;
851             i?86-emx-os2|i?86-*-os2*emx)
852                 random_modules="rndos2"
853                 ;;
854             m68k-atari-mint)
855                 random_modules="rndatari"
856                 ;;
857             i?86-*-msdosdjgpp*)
858                 :
859                 ;;
860             *)
861                 random_modules="rndlinux rndegd rndunix"
862                 AC_DEFINE(USE_ALL_RANDOM_MODULES, 1, 
863                           [Allow to select random modules at runtime.])
864                 ;;
865          esac
866      fi
867 else
868   if test "$use_static_rnd" = auto; then
869      random_modules="rndlinux rndegd rndunix"
870      AC_DEFINE(USE_ALL_RANDOM_MODULES, 1)
871   else
872      random_modules="rnd$use_static_rnd";
873   fi
874 fi
875
876 if test -z "$random_modules"; then
877    AC_MSG_ERROR(no random module available)
878 fi
879 print_egd_warning=no
880 for rndmod in $random_modules "" ; do
881   case "$rndmod" in
882     rndlinux)
883          AC_DEFINE(USE_RNDLINUX,1, 
884                   [Defined if the /dev/random based RNG should be used.])
885          ;;
886     rndunix)
887          AC_DEFINE(USE_RNDUNIX,1, 
888                   [Defined if the default Unix RNG should be used.])
889          print_egd_warning=yes
890           ;;
891     rndegd)
892          AC_DEFINE(USE_RNDEGD,1, 
893                   [Defined if the EGD based RNG should be used.])
894          EGDLIBS=$NETLIBS
895          AC_SUBST(EGDLIBS)
896          ;;
897     rndw32)
898          AC_DEFINE(USE_RNDW32,1, 
899                   [Defined if the Windows specific RNG should be used.])
900         ;;
901    esac
902 done
903
904 dnl setup assembler stuff
905 AC_MSG_CHECKING(for mpi assembler functions)
906 if test -f $srcdir/mpi/config.links ; then
907     . $srcdir/mpi/config.links
908     AC_CONFIG_LINKS("$mpi_ln_list")
909     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
910     ac_cv_mpi_sflags="$mpi_sflags"
911     ac_cv_mpi_config_done="yes"
912     AC_MSG_RESULT(done)
913 else
914     AC_MSG_RESULT(failed)
915     AC_MSG_ERROR([mpi/config.links missing!])
916 fi
917 MPI_EXTRA_ASM_OBJS=""
918 show_extraasm=""
919 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
920 for i in $ac_cv_mpi_extra_asm_modules; do
921     show_extraasm="$show_extraasm $i"
922     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
923 done
924 fi
925 AC_SUBST(MPI_EXTRA_ASM_OBJS)
926 MPI_SFLAGS="$ac_cv_mpi_sflags"
927 AC_SUBST(MPI_SFLAGS)
928
929 # Sanity check regex.  Tests adapted from mutt.
930
931 AC_MSG_CHECKING([whether regular expression support is requested])
932 AC_ARG_ENABLE(regex,
933 [  --disable-regex         do not handle regular expressions in trust sigs],
934      use_regex=$enableval, use_regex=yes)
935 AC_MSG_RESULT($use_regex)
936
937 if test "$use_regex" = yes ; then
938   AC_MSG_CHECKING([whether the included regex lib is requested])
939   AC_ARG_WITH(included-regex,
940       [  --with-included-regex   use the included GNU regex library],
941       [gnupg_cv_included_regex=yes],[gnupg_cv_included_regex=no])
942   AC_MSG_RESULT($gnupg_cv_included_regex)
943
944   if test $gnupg_cv_included_regex = no ; then
945      # Does the system have regex functions at all?
946      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
947                            gnupg_cv_included_regex=yes)
948   fi
949
950   if test $gnupg_cv_included_regex = no ; then
951      AC_CACHE_CHECK([whether your system's regexp library is broken],
952        [gnupg_cv_regex_broken],
953        AC_TRY_RUN([
954 #include <unistd.h>
955 #include <regex.h>
956 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
957        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
958
959      if test $gnupg_cv_regex_broken = yes ; then
960       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
961       gnupg_cv_included_regex=yes
962      fi
963   fi
964
965   if test $gnupg_cv_included_regex = yes; then
966      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
967      AC_SUBST(REGEX_O,regex.o)
968   fi
969 else
970
971   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
972 fi
973
974 dnl Do we have zlib? Must do it here because Solaris failed
975 dnl when compiling a conftest (due to the "-lz" from LIBS).
976 use_local_zlib=yes
977 if test "$g10_force_zlib" = "yes"; then
978   :
979 else
980   _cppflags="${CPPFLAGS}"
981   _ldflags="${LDFLAGS}"
982
983   AC_ARG_WITH(zlib,
984   [  --with-zlib=DIR         use libz in DIR],[
985     if test -d "$withval"; then
986       CPPFLAGS="${CPPFLAGS} -I$withval/include"
987       LDFLAGS="${LDFLAGS} -L$withval/lib"
988     fi
989   ])
990
991   AC_CHECK_HEADER(zlib.h,
992       AC_CHECK_LIB(z, deflateInit2_,
993        use_local_zlib=no
994        ZLIBS="-lz",
995        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
996        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
997 fi
998
999 if test "$use_local_zlib" = yes ; then
1000     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
1001     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
1002     ZLIBS="../zlib/libzlib.a"
1003 else
1004     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
1005 fi
1006 AC_SUBST(ZLIBS)
1007
1008
1009 # Allow users to append something to the version string without
1010 # flagging it as development version.  The user version parts is
1011 # considered everything after a dash. 
1012 if test "$development_version" != yes; then
1013   changequote(,)dnl
1014   tmp_pat='[a-zA-Z]'
1015   changequote([,])dnl
1016   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1017     development_version=yes
1018   fi
1019 fi
1020 if test "$development_version" = yes; then
1021     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1022             [Defined if this is not a regular release])
1023 fi
1024
1025 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1026
1027 GNUPG_CHECK_GNUMAKE
1028
1029 # add some extra libs here so that previous tests don't fail for
1030 # mysterious reasons - the final link step should bail out. 
1031 case "${target}" in
1032     *-*-mingw32*)
1033 dnl      NETLIBS="$NETLIBS -lwsock32"
1034         W32LIBS="-lwsock32"
1035         ;;
1036     *)
1037        ;;
1038 esac
1039
1040 AC_SUBST(NETLIBS)
1041 AC_SUBST(W32LIBS)
1042
1043 if test "$GCC" = yes; then
1044     if test "$USE_MAINTAINER_MODE" = "yes"; then
1045         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1046     else
1047         CFLAGS="$CFLAGS -Wall"
1048     fi
1049 fi
1050
1051
1052 if test "$print_egd_warning" = yes; then
1053   AC_MSG_WARN([[
1054 ***
1055 *** The performance of the UNIX random gatherer module is not very good
1056 *** and it does not keep the entropy pool over multiple invocations of
1057 *** GnuPG.  The suggested way to overcome this problem is to use the
1058 ***
1059 ***               Entropy Gathering Daemon (EGD)
1060 ***
1061 *** which provides a entropy source for the whole system.  It is written
1062 *** in Perl and available at the GnuPG FTP servers.  For more information
1063 *** consult the GnuPG webpages:
1064 ***
1065 ***           http://www.gnupg.org/download/#EGD
1066 ***
1067 *** You may want to run ./configure with --enable-static-rnd=egd or
1068 *** --enable-static-rnd=auto to use it.
1069 ***]])
1070 fi
1071
1072 # Note the \\\\ for backslashes.  Autoconf eats one layer, leaving \\
1073
1074 AC_CONFIG_COMMANDS(g10defs.h,[[
1075 cat >g10defs.tmp <<G10EOF
1076 /* Generated automatically by configure */
1077 #ifdef HAVE_DRIVE_LETTERS
1078 #define G10_LOCALEDIR     "c:\\\\lib\\\\gnupg\\\\locale"
1079 #define GNUPG_LIBDIR      "c:\\\\lib\\\\gnupg"
1080 #define GNUPG_LIBEXECDIR  "c:\\\\lib\\\\gnupg"
1081 #define GNUPG_DATADIR     "c:\\\\lib\\\\gnupg"
1082 #define GNUPG_HOMEDIR     "c:\\\\gnupg"
1083 #else
1084 #define G10_LOCALEDIR     "${datadir}/locale"
1085 #define GNUPG_LIBDIR      "${libdir}/gnupg"
1086 #define GNUPG_DATADIR     "${datadir}/gnupg"
1087 #ifdef __VMS
1088 #define GNUPG_HOMEDIR "/SYS\$LOGIN/gnupg" 
1089 #else
1090 #define GNUPG_HOMEDIR "~/.gnupg" 
1091 #endif
1092 #endif
1093 /* those are here to be redefined by handcrafted g10defs.h.
1094    Please note that the string version must not contain more
1095    than one character because the using code assumes strlen()==1 */
1096 #ifdef HAVE_DOSISH_SYSTEM
1097 #define DIRSEP_C '\\\\'
1098 #define EXTSEP_C '.'
1099 #define DIRSEP_S "\\\\"
1100 #define EXTSEP_S "."
1101 #else
1102 #define DIRSEP_C '/'
1103 #define EXTSEP_C '.'
1104 #define DIRSEP_S "/"
1105 #define EXTSEP_S "."
1106 #endif
1107 /* This is the same as VERSION, but should be overridden if the
1108    platform cannot handle things like dots '.' in filenames. */
1109 #define SAFE_VERSION VERSION
1110 G10EOF
1111 cat mpi/mpi-asm-defs.h >>g10defs.tmp 
1112 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
1113     echo "g10defs.h is unchanged"
1114     rm -f g10defs.tmp
1115 else
1116     rm -f g10defs.h
1117     mv g10defs.tmp g10defs.h
1118     echo "g10defs.h created"
1119 fi
1120 ]],[[
1121 prefix=$prefix
1122 exec_prefix=$exec_prefix
1123 libdir=$libdir
1124 libexecdir=$libexecdir
1125 datadir=$datadir
1126 DATADIRNAME=$DATADIRNAME
1127 ]])
1128
1129
1130 AC_CONFIG_FILES([
1131 Makefile
1132 intl/Makefile
1133 po/Makefile.in
1134 util/Makefile
1135 mpi/Makefile
1136 cipher/Makefile
1137 g10/Makefile
1138 keyserver/Makefile
1139 keyserver/gpgkeys_mailto
1140 keyserver/gpgkeys_test
1141 doc/Makefile
1142 tools/Makefile
1143 zlib/Makefile
1144 checks/Makefile
1145 ])
1146 AC_OUTPUT
1147
1148 # Give some feedback
1149 echo
1150 echo   "                Configured for: $PRINTABLE_OS_NAME ($target)"
1151 if test -n "$show_extraasm"; then
1152   echo "  Extra cpu specific functions:$show_extraasm"
1153 fi
1154 echo