Require Libgcrypt 1.6
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007,
3 #               2008, 2009, 2010, 2011, 2012 Free Software Foundation, Inc.
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.10"
23
24 # To build a release you need to create a tag with the version number
25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
26 # bump the version number immediately *after* the release and do
27 # another commit and push so that the git magic is able to work.
28 m4_define([mym4_version], [2.1.0])
29
30 # Below is m4 magic to extract and compute the git revision number,
31 # the decimalized short revision number, a beta version string and a
32 # flag indicating a development version (mym4_isgit).  Note that the
33 # m4 processing is done by autoconf and not during the configure run.
34 m4_define([mym4_revision],
35           m4_esyscmd([git rev-parse --short HEAD | tr -d '\n\r']))
36 m4_define([mym4_revision_dec],
37           m4_esyscmd_s([echo $((0x$(echo ]mym4_revision[|head -c 4)))]))
38 m4_define([mym4_betastring],
39           m4_esyscmd_s([git describe --match 'gnupg-2.[0-9].*[0-9]' --long|\
40                         awk -F- '$3!=0{print"-beta"$3}']))
41 m4_define([mym4_isgit],m4_if(mym4_betastring,[],[no],[yes]))
42 m4_define([mym4_full_version],[mym4_version[]mym4_betastring])
43
44 AC_INIT([gnupg],[mym4_full_version], [http://bugs.gnupg.org])
45
46 NEED_GPG_ERROR_VERSION=1.11
47
48 NEED_LIBGCRYPT_API=1
49 NEED_LIBGCRYPT_VERSION=1.6.0
50
51 NEED_LIBASSUAN_API=2
52 NEED_LIBASSUAN_VERSION=2.1.0
53
54 NEED_KSBA_API=1
55 NEED_KSBA_VERSION=1.2.0
56
57 NEED_NPTH_API=1
58 NEED_NPTH_VERSION=0.91
59
60
61 development_version=mym4_isgit
62 PACKAGE=$PACKAGE_NAME
63 PACKAGE_GT=${PACKAGE_NAME}2
64 VERSION=$PACKAGE_VERSION
65
66 AC_CONFIG_AUX_DIR([scripts])
67 AC_CONFIG_SRCDIR([sm/gpgsm.c])
68 AC_CONFIG_HEADER([config.h])
69 # Note: For automake 1.13 add the option
70 #          serial-tests
71 AM_INIT_AUTOMAKE([dist-bzip2 no-dist-gzip])
72 AC_CANONICAL_HOST
73 AB_INIT
74
75 AC_GNU_SOURCE
76
77 # Some status variables.
78 have_gpg_error=no
79 have_libgcrypt=no
80 have_libassuan=no
81 have_ksba=no
82 have_npth=no
83 have_libusb=no
84 have_adns=no
85
86 use_zip=yes
87 use_bzip2=yes
88 use_exec=yes
89 disable_keyserver_path=no
90 use_ccid_driver=yes
91 use_standard_socket=yes
92 dirmngr_auto_start=no
93
94 try_ks_ldap=no
95
96 GNUPG_BUILD_PROGRAM(gpg, yes)
97 GNUPG_BUILD_PROGRAM(gpgsm, yes)
98 GNUPG_BUILD_PROGRAM(agent, yes)
99 GNUPG_BUILD_PROGRAM(scdaemon, yes)
100 GNUPG_BUILD_PROGRAM(g13, yes)
101 GNUPG_BUILD_PROGRAM(dirmngr, yes)
102 GNUPG_BUILD_PROGRAM(tools, yes)
103 GNUPG_BUILD_PROGRAM(doc, yes)
104 GNUPG_BUILD_PROGRAM(symcryptrun, no)
105 GNUPG_BUILD_PROGRAM(gpgtar, no)
106
107 AC_SUBST(PACKAGE)
108 AC_SUBST(PACKAGE_GT)
109 AC_SUBST(VERSION)
110 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
111 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
112                                 [Name of this package for gettext])
113 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
114 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
115                                         [Bug report address])
116 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
117                                        [Required version of Libgcrypt])
118 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
119                                        [Required version of Libksba])
120
121
122
123 # The default is to use the modules from this package and the few
124 # other packages in a standard place; i.e where this package gets
125 # installed.  With these options it is possible to override these
126 # ${prefix} depended values with fixed paths, which can't be replaced
127 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
128 AC_ARG_WITH(agent-pgm,
129     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
130           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
131 AC_SUBST(GNUPG_AGENT_PGM)
132 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
133 show_gnupg_agent_pgm="(default)"
134 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
135
136 AC_ARG_WITH(pinentry-pgm,
137     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
138           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
139 AC_SUBST(GNUPG_PINENTRY_PGM)
140 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
141 show_gnupg_pinentry_pgm="(default)"
142 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
143
144
145 AC_ARG_WITH(scdaemon-pgm,
146     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
147           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
148 AC_SUBST(GNUPG_SCDAEMON_PGM)
149 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
150 show_gnupg_scdaemon_pgm="(default)"
151 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
152
153
154 AC_ARG_WITH(dirmngr-pgm,
155     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
156           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
157 AC_SUBST(GNUPG_DIRMNGR_PGM)
158 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
159 show_gnupg_dirmngr_pgm="(default)"
160 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
161
162 AC_ARG_WITH(protect-tool-pgm,
163     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
164           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
165 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
166 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
167 show_gnupg_protect_tool_pgm="(default)"
168 test -n "$GNUPG_PROTECT_TOOL_PGM" \
169       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
170
171 AC_ARG_WITH(dirmngr-ldap-pgm,
172     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmnge ldap wrapper)],
173           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
174 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
175 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
176 show_gnupg_dirmngr_ldap_pgm="(default)"
177 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
178       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
179
180 #
181 # On some platforms gpg2 is usually installed as gpg without using a
182 # symlink.  For correct operation of gpgconf it needs to know the
183 # installed name of gpg.  This option sets "gpg2"'s installed name to
184 # just "gpg".  Note that it might be required to rename gpg2 to gpg
185 # manually after the build process.
186 #
187 AC_ARG_ENABLE(gpg2-is-gpg,
188     AC_HELP_STRING([--enable-gpg2-is-gpg],[Set installed name of gpg2 to gpg]),
189     gpg2_is_gpg=$enableval)
190 if test "$gpg2_is_gpg" = "yes"; then
191    name_of_installed_gpg=gpg
192 else
193    name_of_installed_gpg=gpg2
194 fi
195 AC_DEFINE_UNQUOTED(NAME_OF_INSTALLED_GPG, "$name_of_installed_gpg",
196                    [The name of the installed GPG tool])
197
198
199 # Some folks want to use only the agent from this packet.  Make it
200 # easier for them by providing the configure option
201 # --enable-only-agent.
202 AC_ARG_ENABLE(agent-only,
203     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
204     build_agent_only=$enableval)
205
206 # SELinux support includes tracking of sensitive files to avoid
207 # leaking their contents through processing these files by gpg itself
208 AC_MSG_CHECKING([whether SELinux support is requested])
209 AC_ARG_ENABLE(selinux-support,
210               AC_HELP_STRING([--enable-selinux-support],
211                              [enable SELinux support]),
212               selinux_support=$enableval, selinux_support=no)
213 AC_MSG_RESULT($selinux_support)
214
215 # Allow disabling of zip support.
216 # This is in general not a good idea because according to rfc4880 OpenPGP
217 # implementations SHOULD support ZLIB.
218 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
219 AC_ARG_ENABLE(zip,
220    AC_HELP_STRING([--disable-zip],
221                   [disable the ZIP and ZLIB compression algorithm]),
222    use_zip=$enableval)
223 AC_MSG_RESULT($use_zip)
224
225 # Allow disabling of bzib2 support.
226 # It is defined only after we confirm the library is available later
227 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
228 AC_ARG_ENABLE(bzip2,
229    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
230    use_bzip2=$enableval)
231 AC_MSG_RESULT($use_bzip2)
232
233 # Configure option to allow or disallow execution of external
234 # programs, like a photo viewer.
235 AC_MSG_CHECKING([whether to enable external program execution])
236 AC_ARG_ENABLE(exec,
237     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
238     use_exec=$enableval)
239 AC_MSG_RESULT($use_exec)
240 if test "$use_exec" = no ; then
241     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
242 fi
243
244 if test "$use_exec" = yes ; then
245   AC_MSG_CHECKING([whether to enable photo ID viewing])
246   AC_ARG_ENABLE(photo-viewers,
247       [  --disable-photo-viewers disable photo ID viewers],
248       [if test "$enableval" = no ; then
249          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
250       fi],enableval=yes)
251   gnupg_cv_enable_photo_viewers=$enableval
252   AC_MSG_RESULT($enableval)
253
254   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
255     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
256     AC_ARG_WITH(photo-viewer,
257         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
258         [if test "$withval" = yes ; then
259            withval=no
260         elif test "$withval" != no ; then
261            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
262                             [if set, restrict photo-viewer to this])
263         fi],withval=no)
264     AC_MSG_RESULT($withval)
265   fi
266
267   AC_MSG_CHECKING([whether to enable external keyserver helpers])
268   AC_ARG_ENABLE(keyserver-helpers,
269       [  --disable-keyserver-helpers  disable all external keyserver support],
270       [if test "$enableval" = no ; then
271          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
272                   [define to disable keyserver helpers])
273       fi],enableval=yes)
274   gnupg_cv_enable_keyserver_helpers=$enableval
275   AC_MSG_RESULT($enableval)
276
277   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
278     # LDAP is defined only after we confirm the library is available later
279     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
280     AC_ARG_ENABLE(ldap,
281       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
282       try_ks_ldap=$enableval, try_ks_ldap=yes)
283     AC_MSG_RESULT($try_ks_ldap)
284
285     AC_MSG_CHECKING([whether HKP keyserver support is requested])
286     AC_ARG_ENABLE(hkp,
287       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
288       try_hkp=$enableval, try_hkp=yes)
289     AC_MSG_RESULT($try_hkp)
290
291     AC_MSG_CHECKING([whether finger key fetching support is requested])
292     AC_ARG_ENABLE(finger,
293       AC_HELP_STRING([--disable-finger],
294         [disable finger key fetching interface only]),
295       try_finger=$enableval, try_finger=yes)
296     AC_MSG_RESULT($try_finger)
297
298     AC_MSG_CHECKING([whether generic object key fetching support is requested])
299     AC_ARG_ENABLE(generic,
300       AC_HELP_STRING([--disable-generic],
301         [disable generic object key fetching interface only]),
302       try_generic=$enableval, try_generic=yes)
303     AC_MSG_RESULT($try_generic)
304
305     AC_MSG_CHECKING([whether email keyserver support is requested])
306     AC_ARG_ENABLE(mailto,
307       AC_HELP_STRING([--enable-mailto],
308         [enable email keyserver interface only]),
309       try_mailto=$enableval, try_mailto=no)
310     AC_MSG_RESULT($try_mailto)
311   fi
312
313   AC_MSG_CHECKING([whether keyserver exec-path is enabled])
314   AC_ARG_ENABLE(keyserver-path,
315       AC_HELP_STRING([--disable-keyserver-path],
316         [disable the exec-path option for keyserver helpers]),
317       [if test "$enableval" = no ; then
318          disable_keyserver_path=yes
319       fi],enableval=yes)
320   AC_MSG_RESULT($enableval)
321 fi
322
323
324 #
325 # Check for the key/uid cache size.  This can't be zero, but can be
326 # pretty small on embedded systems.  This is used for the gpg part.
327 #
328 AC_MSG_CHECKING([for the size of the key and uid cache])
329 AC_ARG_ENABLE(key-cache,
330         AC_HELP_STRING([--enable-key-cache=SIZE],
331                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
332 if test "$enableval" = "no"; then
333    enableval=5
334 elif test "$enableval" = "yes" || test "$enableval" = ""; then
335    enableval=4096
336 fi
337 changequote(,)dnl
338 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
339 changequote([,])dnl
340 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
341    AC_MSG_ERROR([invalid key-cache size])
342 fi
343 AC_MSG_RESULT($key_cache_size)
344 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
345                   [Size of the key and UID caches])
346
347
348
349 #
350 # Check whether we want to use Linux capabilities
351 #
352 AC_MSG_CHECKING([whether use of capabilities is requested])
353 AC_ARG_WITH(capabilities,
354     [  --with-capabilities     use linux capabilities [default=no]],
355 [use_capabilities="$withval"],[use_capabilities=no])
356 AC_MSG_RESULT($use_capabilities)
357
358
359 #
360 # Allow disabling of internal CCID support.
361 # It is defined only after we confirm the library is available later
362 #
363 AC_MSG_CHECKING([whether to enable the internal CCID driver])
364 AC_ARG_ENABLE(ccid-driver,
365               AC_HELP_STRING([--disable-ccid-driver],
366                              [disable the internal CCID driver]),
367               use_ccid_driver=$enableval)
368 AC_MSG_RESULT($use_ccid_driver)
369
370 #
371 # Dirmngr is nowadays a system service and thus it usually does no
372 # make sense to start it as needed.  However on some systems this is
373 # possible; this option enable the feature.
374 #
375 AC_MSG_CHECKING([whether to auto start dirmngr])
376 AC_ARG_ENABLE(dirmngr-auto-start,
377               AC_HELP_STRING([--enable-dirmngr-auto-start],
378                              [enable auto starting of the dirmngr]),
379               dirmngr_auto_start=$enableval)
380 AC_MSG_RESULT($dirmngr_auto_start)
381 if test "$dirmngr_auto_start" = yes ; then
382     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
383               [Define to enable auto starting of the dirmngr])
384 fi
385
386
387 #
388 # To avoid double inclusion of config.h which might happen at some
389 # places, we add the usual double inclusion protection at the top of
390 # config.h.
391 #
392 AH_TOP([
393 #ifndef GNUPG_CONFIG_H_INCLUDED
394 #define GNUPG_CONFIG_H_INCLUDED
395 ])
396
397 #
398 # Stuff which goes at the bottom of config.h.
399 #
400 AH_BOTTOM([
401 /* This is the major version number of GnuPG so that
402    source included files can test for this.  Note, that
403    we use 2 here even for GnuPG 1.9.x. */
404 #define GNUPG_MAJOR_VERSION 2
405
406 /* Now to separate file name parts.
407    Please note that the string version must not contain more
408    than one character because the code assumes strlen()==1 */
409 #ifdef HAVE_DOSISH_SYSTEM
410 #define DIRSEP_C '\\'
411 #define DIRSEP_S "\\"
412 #define EXTSEP_C '.'
413 #define EXTSEP_S "."
414 #define PATHSEP_C ';'
415 #define PATHSEP_S ";"
416 #define EXEEXT_S ".exe"
417 #else
418 #define DIRSEP_C '/'
419 #define DIRSEP_S "/"
420 #define EXTSEP_C '.'
421 #define EXTSEP_S "."
422 #define PATHSEP_C ':'
423 #define PATHSEP_S ":"
424 #define EXEEXT_S ""
425 #endif
426
427 /* This is the same as VERSION, but should be overridden if the
428    platform cannot handle things like dots '.' in filenames. Set
429    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
430    uses for dots and dashes. */
431 #define SAFE_VERSION VERSION
432 #define SAFE_VERSION_DOT  '.'
433 #define SAFE_VERSION_DASH '-'
434
435 /* Some global constants. */
436 #ifdef HAVE_DOSISH_SYSTEM
437 # ifdef HAVE_DRIVE_LETTERS
438 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
439 # else
440 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
441 # endif
442 #elif defined(__VMS)
443 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
444 #else
445 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
446 #endif
447 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
448
449 /* For some systems (DOS currently), we hardcode the path here.  For
450    POSIX systems the values are constructed by the Makefiles, so that
451    the values may be overridden by the make invocations; this is to
452    comply with the GNU coding standards.  Note that these values are
453    only defaults.  */
454 #ifdef HAVE_DOSISH_SYSTEM
455 # ifdef HAVE_DRIVE_LETTERS
456 #  define GNUPG_BINDIR      "c:\\gnupg"
457 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
458 #  define GNUPG_LIBDIR      "c:\\gnupg"
459 #  define GNUPG_DATADIR     "c:\\gnupg"
460 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
461 # else
462 #  define GNUPG_BINDIR      "\\gnupg"
463 #  define GNUPG_LIBEXECDIR  "\\gnupg"
464 #  define GNUPG_LIBDIR      "\\gnupg"
465 #  define GNUPG_DATADIR     "\\gnupg"
466 #  define GNUPG_SYSCONFDIR  "\\gnupg"
467 # endif
468 #endif
469
470 /* Derive some other constants. */
471 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
472 #define EXEC_TEMPFILE_ONLY
473 #endif
474
475
476 /* We didn't define endianness above, so get it from OS macros.  This
477    is intended for making fat binary builds on OS X. */
478 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
479 #if defined(__BIG_ENDIAN__)
480 #define BIG_ENDIAN_HOST 1
481 #elif defined(__LITTLE_ENDIAN__)
482 #define LITTLE_ENDIAN_HOST 1
483 #else
484 #error "No endianness found"
485 #endif
486 #endif
487
488
489 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
490    ldap_start_tls_s because that is the actual symbol used in the
491    library.  winldap.h redefines it to our commonly used value,
492    thus we define our usual macro here.  */
493 #ifdef HAVE_LDAP_START_TLS_SA
494 # ifndef HAVE_LDAP_START_TLS_S
495 #  define HAVE_LDAP_START_TLS_S 1
496 # endif
497 #endif
498
499
500 /* Tell libgcrypt not to use its own libgpg-error implementation. */
501 #define USE_LIBGPG_ERROR 1
502
503 /* Tell Libgcrypt not to include deprecated definitions.  */
504 #define GCRYPT_NO_DEPRECATED 1
505
506 /* We use jnlib, so tell other modules about it.  */
507 #define HAVE_JNLIB_LOGGING 1
508
509 /* Our HTTP code is used in estream mode.  */
510 #define HTTP_USE_ESTREAM 1
511
512 /* Under W32 we do an explicit socket initialization, thus we need to
513    avoid the on-demand initialization which would also install an atexit
514    handler.  */
515 #define HTTP_NO_WSASTARTUP
516
517 /* We always include support for the OpenPGP card.  */
518 #define ENABLE_CARD_SUPPORT 1
519
520 /* We want to use the libgcrypt provided memory allocation for
521    asprintf.  */
522 #define _ESTREAM_PRINTF_REALLOC       gcry_realloc
523 #define _ESTREAM_PRINTF_EXTRA_INCLUDE "../common/util.h"
524
525 /* Under Windows we use the gettext code from libgpg-error.  */
526 #define GPG_ERR_ENABLE_GETTEXT_MACROS
527
528 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
529 #define GPG_ERR_ENABLE_ERRNO_MACROS
530
531 #endif /*GNUPG_CONFIG_H_INCLUDED*/
532 ])
533
534
535 AM_MAINTAINER_MODE
536
537 # Checks for programs.
538 AC_MSG_NOTICE([checking for programs])
539 AC_PROG_MAKE_SET
540 AM_SANITY_CHECK
541 missing_dir=`cd $ac_aux_dir && pwd`
542 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
543 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
544 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
545 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
546 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
547 AC_PROG_AWK
548 AC_PROG_CC
549 AC_PROG_CPP
550 AM_PROG_CC_C_O
551 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
552   AC_MSG_ERROR([[No C-89 compiler found]])
553 fi
554 AC_PROG_INSTALL
555 AC_PROG_LN_S
556 AC_PROG_RANLIB
557 AC_CHECK_TOOL(AR, ar, :)
558 AC_PATH_PROG(PERL,"perl")
559 AC_CHECK_TOOL(WINDRES, windres, :)
560 AC_ISC_POSIX
561 gl_EARLY
562 AC_SYS_LARGEFILE
563 GNUPG_CHECK_USTAR
564
565 # We need to compile and run a program on the build machine.  A
566 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
567 # the AC archive is broken for autoconf 2.57.  Given that there is no
568 # newer version of that macro, we assume that it is also broken for
569 # autoconf 2.61 and thus we use a simple but usually sufficient
570 # approach.
571 AC_MSG_CHECKING(for cc for build)
572 if test "$cross_compiling" = "yes"; then
573   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
574 else
575   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
576 fi
577 AC_MSG_RESULT($CC_FOR_BUILD)
578 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
579
580
581
582 try_gettext=yes
583 have_dosish_system=no
584 have_w32_system=no
585 have_w32ce_system=no
586 have_android_system=no
587 run_tests=yes
588 use_simple_gettext=no
589 use_ldapwrapper=yes
590 mmap_needed=yes
591 case "${host}" in
592     *-mingw32*)
593         # special stuff for Windoze NT
594         ac_cv_have_dev_random=no
595         AC_DEFINE(USE_ONLY_8DOT3,1,
596                   [Set this to limit filenames to the 8.3 format])
597         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
598                   [Because the Unix gettext has too much overhead on
599                    MingW32 systems and these systems lack Posix functions,
600                    we use a simplified version of gettext])
601         disable_keyserver_path=yes
602         have_dosish_system=yes
603         have_w32_system=yes
604         run_tests=no
605         use_ldapwrapper=no  # Fixme: Do this only for CE.
606         case "${host}" in
607           *-mingw32ce*)
608             have_w32ce_system=yes
609             ;;
610           *)
611             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
612                       [Defined if the OS supports drive letters.])
613             ;;
614         esac
615         try_gettext="no"
616         use_simple_gettext=yes
617         mmap_needed=no
618         ;;
619     i?86-emx-os2 | i?86-*-os2*emx )
620         # OS/2 with the EMX environment
621         ac_cv_have_dev_random=no
622         AC_DEFINE(HAVE_DRIVE_LETTERS)
623         have_dosish_system=yes
624         try_gettext="no"
625         ;;
626
627     i?86-*-msdosdjgpp*)
628         # DOS with the DJGPP environment
629         ac_cv_have_dev_random=no
630         AC_DEFINE(HAVE_DRIVE_LETTERS)
631         have_dosish_system=yes
632         try_gettext="no"
633         ;;
634
635     *-*-hpux*)
636         if test -z "$GCC" ; then
637             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
638         fi
639         ;;
640     *-dec-osf4*)
641         if test -z "$GCC" ; then
642             # Suppress all warnings
643             # to get rid of the unsigned/signed char mismatch warnings.
644             CFLAGS="$CFLAGS -w"
645         fi
646         ;;
647     *-dec-osf5*)
648         if test -z "$GCC" ; then
649             # Use the newer compiler `-msg_disable ptrmismatch1' to
650             # get rid of the unsigned/signed char mismatch warnings.
651             # Using this may hide other pointer mismatch warnings, but
652             # it at least lets other warning classes through
653             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
654         fi
655         ;;
656     m68k-atari-mint)
657         ;;
658     *-linux-androideabi)
659         have_android_system=yes
660         run_tests=no
661         ;;
662     *)
663        ;;
664 esac
665
666 if test "$have_dosish_system" = yes; then
667    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
668              [Defined if we run on some of the PCDOS like systems
669               (DOS, Windoze. OS/2) with special properties like
670               no file modes, case insensitive file names and preferred
671               use of backslashes as directory name separators.])
672 fi
673 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
674
675 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
676
677 if test "$have_w32_system" = yes; then
678    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
679    if test "$have_w32ce_system" = yes; then
680       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
681    fi
682 fi
683 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
684 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
685
686 if test "$have_android_system" = yes; then
687    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
688 fi
689 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
690
691 if test "$run_tests" = yes; then
692    AC_DEFINE(RUN_TESTS,1, [Defined if we should run the tests])
693 fi
694 AM_CONDITIONAL(RUN_TESTS, test "$run_tests" = yes)
695
696 if test "$use_ldapwrapper" = yes; then
697    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
698 fi
699 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
700
701 if test "$disable_keyserver_path" = yes; then
702     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
703               [Defined to disable exec-path for keyserver helpers])
704 fi
705
706 #
707 # Allows enabling the use of a standard socket by default This is
708 # gpg-agent's option --[no-]use-standard-socket.  For Windows we force
709 # the use of this.
710 #
711 AC_MSG_CHECKING([whether to use a standard socket by default])
712 AC_ARG_ENABLE(standard-socket,
713               AC_HELP_STRING([--disable-standard-socket],
714                              [don't use a standard socket by default]),
715               use_standard_socket=$enableval)
716 tmp=""
717 if test "$use_standard_socket" != yes; then
718   if test "$have_w32_system" = yes; then
719     use_standard_socket=yes
720     tmp=" (forced)"
721   fi
722 fi
723 AC_MSG_RESULT($use_standard_socket$tmp)
724 if test "$use_standard_socket" = yes; then
725   AC_DEFINE(USE_STANDARD_SOCKET,1,
726             [Use the standard socket for the agent by default])
727 fi
728
729
730 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
731 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
732
733 if test x"$try_hkp" = xyes ; then
734   AC_SUBST(GPGKEYS_HKP,"gpg2keys_hkp$EXEEXT")
735 fi
736
737 if test x"$try_finger" = xyes ; then
738   AC_SUBST(GPGKEYS_FINGER,"gpg2keys_finger$EXEEXT")
739 fi
740
741
742
743 #
744 # Checks for libraries.
745 #
746 AC_MSG_NOTICE([checking for libraries])
747
748
749 #
750 # libgpg-error is a library with error codes shared between GnuPG
751 # related projects.
752 #
753 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
754                   have_gpg_error=yes,have_gpg_error=no)
755
756
757 #
758 # Libgcrypt is our generic crypto library
759 #
760 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
761         have_libgcrypt=yes,have_libgcrypt=no)
762
763
764 #
765 # libassuan is used for IPC
766 #
767 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
768                   have_libassuan=yes,have_libassuan=no)
769 if test "$have_libassuan" = "yes"; then
770   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
771                      [version of the libassuan library])
772 fi
773
774
775
776 #
777 # libksba is our X.509 support library
778 #
779 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
780
781
782 #
783 # libusb allows us to use the integrated CCID smartcard reader driver.
784 #
785 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
786 if test "$use_ccid_driver" = yes ; then
787   AC_CHECK_LIB(usb, usb_bulk_write,
788                 [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
789                   AC_DEFINE(HAVE_LIBUSB,1,
790                            [defined if libusb is available])
791                   have_libusb=yes
792                ])
793   AC_CHECK_FUNCS(usb_create_match)
794 fi
795 AC_SUBST(LIBUSB_LIBS)
796
797 #
798 # Check wether it is necessary to link against libdl.
799 #
800 gnupg_dlopen_save_libs="$LIBS"
801 LIBS=""
802 AC_SEARCH_LIBS(dlopen, c dl,,,)
803 DL_LIBS=$LIBS
804 AC_SUBST(DL_LIBS)
805 LIBS="$gnupg_dlopen_save_libs"
806
807 # Checks for g13
808
809 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
810 AC_DEFINE_UNQUOTED(ENCFS,
811         "${ENCFS}", [defines the filename of the encfs program])
812
813 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
814 AC_DEFINE_UNQUOTED(FUSERMOUNT,
815         "${FUSERMOUNT}", [defines the filename of the fusermount program])
816
817
818 # Checks for dirmngr
819
820
821 #
822 # Checks for symcryptrun:
823 #
824
825 # libutil has openpty() and login_tty().
826 AC_CHECK_LIB(util, openpty,
827               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
828                 AC_DEFINE(HAVE_LIBUTIL,1,
829                          [defined if libutil is available])
830              ])
831 AC_SUBST(LIBUTIL_LIBS)
832
833 # shred is used to clean temporary plain text files.
834 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
835 AC_DEFINE_UNQUOTED(SHRED,
836         "${SHRED}", [defines the filename of the shred program])
837
838
839 #
840 # Check whether the nPth library is available
841 #
842 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
843 if test "$have_npth" = "yes"; then
844   # We define this macro because some code parts require it.
845   AC_DEFINE(USE_NPTH, 1,
846               [Defined if the New Portable Thread Library is available])
847 else
848   AC_MSG_WARN([[
849 ***
850 *** To support concurrent access for example in gpg-agent and the SCdaemon
851 *** we need the support of the New Portable Threads Library.
852 ***]])
853 fi
854
855
856 AC_MSG_NOTICE([checking for networking options])
857
858 #
859 # Must check for network library requirements before doing link tests
860 # for ldap, for example. If ldap libs are static (or dynamic and without
861 # ELF runtime link paths), then link will fail and LDAP support won't
862 # be detected.
863 #
864 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
865         [NETLIBS="-lnsl $NETLIBS"]))
866 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
867         [NETLIBS="-lsocket $NETLIBS"]))
868
869
870 #
871 # Check for ADNS.
872 #
873 _cppflags="${CPPFLAGS}"
874 _ldflags="${LDFLAGS}"
875 AC_ARG_WITH(adns,
876             AC_HELP_STRING([--with-adns=DIR],
877                            [look for the adns library in DIR]),
878             [if test -d "$withval"; then
879                CPPFLAGS="${CPPFLAGS} -I$withval/include"
880                LDFLAGS="${LDFLAGS} -L$withval/lib"
881              fi])
882 if test "$with_adns" != "no"; then
883   AC_CHECK_HEADERS(adns.h,
884                 AC_CHECK_LIB(adns, adns_init,
885                              [have_adns=yes],
886                              [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}]),
887                 [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}])
888 fi
889 if test "$have_adns" = "yes"; then
890   ADNSLIBS="-ladns"
891 fi
892 AC_SUBST(ADNSLIBS)
893 # Newer adns versions feature a free function to be used under W32.
894 AC_CHECK_FUNCS(adns_free)
895
896
897
898 #
899 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
900 #
901 if test x"$try_hkp" = xyes || test x"$try_http" = xyes ; then
902   AC_ARG_ENABLE(dns-srv,
903      AC_HELP_STRING([--disable-dns-srv],
904                     [disable the use of DNS SRV in HKP and HTTP]),
905                 use_dns_srv=$enableval,use_dns_srv=yes)
906 fi
907
908 AC_ARG_ENABLE(dns-pka,
909    AC_HELP_STRING([--disable-dns-pka],
910         [disable the use of PKA records in DNS]),
911    use_dns_pka=$enableval,use_dns_pka=yes)
912
913 AC_ARG_ENABLE(dns-cert,
914    AC_HELP_STRING([--disable-dns-cert],
915         [disable the use of CERT records in DNS]),
916    use_dns_cert=$enableval,use_dns_cert=yes)
917
918 if test x"$use_dns_pka" = xyes || test x"$use_dns_srv" = xyes \
919    || test x"$use_dns_cert" = xyes; then
920   _dns_save_libs=$LIBS
921   LIBS=""
922   # the double underscore thing is a glibc-ism?
923   AC_SEARCH_LIBS(res_query,resolv bind,,
924                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
925   AC_SEARCH_LIBS(dn_expand,resolv bind,,
926                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
927   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
928                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
929
930   if test x"$have_resolver" != xno ; then
931
932     # Make sure that the BIND 4 resolver interface is workable before
933     # enabling any code that calls it.  At some point I'll rewrite the
934     # code to use the BIND 8 resolver API.
935     # We might also want to use adns instead.  Problem with ADNS is that
936     # it does not support v6.
937
938     AC_MSG_CHECKING([whether the resolver is usable])
939     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
940 #include <netinet/in.h>
941 #include <arpa/nameser.h>
942 #include <resolv.h>]],
943 [[unsigned char answer[PACKETSZ];
944   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
945   dn_skipname(0,0);
946   dn_expand(0,0,0,0,0);
947 ]])],have_resolver=yes,have_resolver=no)
948     AC_MSG_RESULT($have_resolver)
949
950     # This is Apple-specific and somewhat bizarre as they changed the
951     # define in bind 8 for some reason.
952
953     if test x"$have_resolver" != xyes ; then
954        AC_MSG_CHECKING(
955              [whether I can make the resolver usable with BIND_8_COMPAT])
956        AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
957 #include <sys/types.h>
958 #include <netinet/in.h>
959 #include <arpa/nameser.h>
960 #include <resolv.h>]],
961 [[unsigned char answer[PACKETSZ];
962   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
963   dn_skipname(0,0); dn_expand(0,0,0,0,0);
964 ]])],[have_resolver=yes ; need_compat=yes])
965        AC_MSG_RESULT($have_resolver)
966     fi
967   fi
968
969   if test x"$have_resolver" = xyes ; then
970      DNSLIBS=$LIBS
971
972      if test x"$use_dns_srv" = xyes ; then
973         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
974      fi
975
976      if test x"$use_dns_pka" = xyes ; then
977         AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
978      fi
979
980      if test x"$use_dns_cert" = xyes ; then
981         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
982      fi
983
984      if test x"$need_compat" = xyes ; then
985         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
986      fi
987   else
988      # If we have no resolver library but ADNS (e.g. under W32) enable the
989      # code parts which can be used with ADNS.
990      if test x"$have_adns" = xyes ; then
991         DNSLIBS="$ADNSLIBS"
992         AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
993
994         if test x"$use_dns_srv" = xyes ; then
995            AC_DEFINE(USE_DNS_SRV,1)
996         fi
997
998         if test x"$use_dns_pka" = xyes ; then
999            AC_DEFINE(USE_DNS_PKA,1)
1000         fi
1001
1002         if test x"$use_dns_cert" = xyes ; then
1003            AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
1004         fi
1005      else
1006         use_dns_srv=no
1007         use_dns_pka=no
1008         use_dns_cert=no
1009      fi
1010   fi
1011
1012   LIBS=$_dns_save_libs
1013 fi
1014
1015 AC_SUBST(DNSLIBS)
1016
1017 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
1018
1019
1020 #
1021 # Check for LDAP
1022 #
1023 if test "$try_ks_ldap" = yes || test "$build_dirmngr" = "yes" ; then
1024    GNUPG_CHECK_LDAP($NETLIBS)
1025    AC_CHECK_LIB(lber, ber_free,
1026                 [ LBER_LIBS="$LBER_LIBS -llber"
1027                   AC_DEFINE(HAVE_LBER,1,
1028                            [defined if liblber is available])
1029                   have_lber=yes
1030                ])
1031 fi
1032 AC_SUBST(LBER_LIBS)
1033
1034 #
1035 # Check for curl.  We fake the curl API if libcurl isn't installed.
1036 # We require 7.10 or later as we use curl_version_info().
1037 #
1038 LIBCURL_CHECK_CONFIG([yes],[7.10],,[fake_curl=yes])
1039 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
1040
1041 # Generic, for us, means curl
1042
1043 if test x"$try_generic" = xyes ; then
1044    AC_SUBST(GPGKEYS_CURL,"gpg2keys_curl$EXEEXT")
1045 fi
1046
1047 #
1048 # Check for sendmail
1049 #
1050 # This isn't necessarily sendmail itself, but anything that gives a
1051 # sendmail-ish interface to the outside world.  That includes Exim,
1052 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1053 if test "$try_mailto" = yes ; then
1054   AC_ARG_WITH(mailprog,
1055       AC_HELP_STRING([--with-mailprog=NAME],
1056                      [use "NAME -t" for mail transport]),
1057              ,with_mailprog=yes)
1058
1059   if test x"$with_mailprog" = xyes ; then
1060     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1061     if test "$ac_cv_path_SENDMAIL" ; then
1062       GPGKEYS_MAILTO="gpg2keys_mailto"
1063     fi
1064   elif test x"$with_mailprog" != xno ; then
1065     AC_MSG_CHECKING([for a mail transport program])
1066     AC_SUBST(SENDMAIL,$with_mailprog)
1067     AC_MSG_RESULT($with_mailprog)
1068     GPGKEYS_MAILTO="gpg2keys_mailto"
1069   fi
1070 fi
1071
1072 AC_SUBST(GPGKEYS_MAILTO)
1073
1074 #
1075 # Construct a printable name of the OS
1076 #
1077 case "${host}" in
1078     *-mingw32ce*)
1079         PRINTABLE_OS_NAME="W32CE"
1080         ;;
1081     *-mingw32*)
1082         PRINTABLE_OS_NAME="MingW32"
1083         ;;
1084     *-*-cygwin*)
1085         PRINTABLE_OS_NAME="Cygwin"
1086         ;;
1087     i?86-emx-os2 | i?86-*-os2*emx )
1088         PRINTABLE_OS_NAME="OS/2"
1089         ;;
1090     i?86-*-msdosdjgpp*)
1091         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1092         try_dynload=no
1093         ;;
1094     *-linux*)
1095         PRINTABLE_OS_NAME="GNU/Linux"
1096         ;;
1097     *)
1098         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1099         ;;
1100 esac
1101 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1102                    [A human readable text with the name of the OS])
1103
1104
1105 #
1106 # Checking for iconv
1107 #
1108 AM_ICONV
1109
1110
1111 #
1112 # Check for gettext
1113 #
1114 # This is "GNU gnupg" - The project-id script from gettext
1115 #                       needs this string
1116 #
1117 AC_MSG_NOTICE([checking for gettext])
1118 AM_PO_SUBDIRS
1119 AM_GNU_GETTEXT_VERSION([0.17])
1120 if test "$try_gettext" = yes; then
1121   AM_GNU_GETTEXT([external],[need-ngettext])
1122
1123   # gettext requires some extra checks.  These really should be part of
1124   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1125   # function checks to here.
1126
1127   AC_CHECK_FUNCS(strchr)
1128 else
1129   USE_NLS=no
1130   USE_INCLUDED_LIBINTL=no
1131   BUILD_INCLUDED_LIBINTL=no
1132   POSUB=po
1133   AC_SUBST(USE_NLS)
1134   AC_SUBST(USE_INCLUDED_LIBINTL)
1135   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1136   AC_SUBST(POSUB)
1137 fi
1138
1139 # We use HAVE_LANGINFO_CODESET in a couple of places.
1140 AM_LANGINFO_CODESET
1141
1142 # Checks required for our use locales
1143 gt_LC_MESSAGES
1144
1145
1146 #
1147 # SELinux support
1148 #
1149 if test "$selinux_support" = yes ; then
1150   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1151 fi
1152
1153
1154 #
1155 # Checks for header files.
1156 #
1157 AC_MSG_NOTICE([checking for header files])
1158 AC_HEADER_STDC
1159 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1160                   pty.h utmp.h pwd.h inttypes.h signal.h])
1161 AC_HEADER_TIME
1162
1163
1164 #
1165 # Checks for typedefs, structures, and compiler characteristics.
1166 #
1167 AC_MSG_NOTICE([checking for system characteristics])
1168 AC_C_CONST
1169 AC_C_INLINE
1170 AC_C_VOLATILE
1171 AC_TYPE_SIZE_T
1172 AC_TYPE_MODE_T
1173 AC_TYPE_SIGNAL
1174 AC_DECL_SYS_SIGLIST
1175
1176 gl_HEADER_SYS_SOCKET
1177 gl_TYPE_SOCKLEN_T
1178
1179 AC_SEARCH_LIBS([inet_addr], [nsl])
1180
1181 AC_ARG_ENABLE(endian-check,
1182               AC_HELP_STRING([--disable-endian-check],
1183               [disable the endian check and trust the OS provided macros]),
1184               endiancheck=$enableval,endiancheck=yes)
1185
1186 if test x"$endiancheck" = xyes ; then
1187   GNUPG_CHECK_ENDIAN
1188 fi
1189
1190 # fixme: we should get rid of the byte type
1191 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1192 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1193 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1194 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1195 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1196
1197 AC_CHECK_SIZEOF(unsigned short)
1198 AC_CHECK_SIZEOF(unsigned int)
1199 AC_CHECK_SIZEOF(unsigned long)
1200 AC_CHECK_SIZEOF(unsigned long long)
1201 AC_HEADER_TIME
1202 AC_CHECK_SIZEOF(time_t,,[[
1203 #include <stdio.h>
1204 #if TIME_WITH_SYS_TIME
1205 # include <sys/time.h>
1206 # include <time.h>
1207 #else
1208 # if HAVE_SYS_TIME_H
1209 #  include <sys/time.h>
1210 # else
1211 #  include <time.h>
1212 # endif
1213 #endif
1214 ]])
1215 GNUPG_TIME_T_UNSIGNED
1216
1217
1218 # Ensure that we have UINT64_C before we bother to check for uint64_t
1219 # Fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
1220 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
1221    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <inttypes.h>]],
1222        [[uint64_t foo=UINT64_C(42);]])],
1223      gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
1224 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
1225    AC_CHECK_SIZEOF(uint64_t)
1226 fi
1227
1228 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1229    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1230    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1231     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1232 fi
1233
1234
1235 #
1236 # Checks for library functions.
1237 #
1238 AC_MSG_NOTICE([checking for library functions])
1239 AC_CHECK_DECLS(getpagesize)
1240 AC_FUNC_FSEEKO
1241 AC_FUNC_VPRINTF
1242 AC_FUNC_FORK
1243 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1244 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1245 AC_CHECK_FUNCS([unsetenv fcntl ftruncate canonicalize_file_name])
1246 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1247 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1248 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1249 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1250
1251 if test "$have_android_system" = yes; then
1252    # On Android ttyname is a stub but prints an error message.
1253    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1254              [Defined if ttyname does not work properly])
1255 fi
1256
1257 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1258
1259 # Dirmngr requires mmap on Unix systems.
1260 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1261   AC_MSG_ERROR([[Sorry, the current implemenation requires mmap.]])
1262 fi
1263
1264 #
1265 # These are needed by the jnlib parts in common.
1266 # Note:  We already checked pwd.h.
1267 AC_CHECK_HEADERS([signal.h])
1268 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1269                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1270                 flockfile funlockfile fopencookie funopen getpwnam getpwuid \
1271                 getenv inet_pton])
1272 # end jnlib checks.
1273
1274
1275
1276 #
1277 # gnulib checks
1278 #
1279 gl_SOURCE_BASE([gl])
1280 gl_M4_BASE([gl/m4])
1281 gl_MODULES([setenv mkdtemp xsize strpbrk])
1282 gl_INIT
1283
1284
1285 #
1286 # W32 specific test
1287 #
1288 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1289
1290 #
1291 # Sanity check regex.  Tests adapted from mutt.
1292 #
1293 AC_MSG_CHECKING([whether regular expression support is requested])
1294 AC_ARG_ENABLE(regex,
1295   AC_HELP_STRING([--disable-regex],
1296     [do not handle regular expressions in trust signatures]),
1297   use_regex=$enableval, use_regex=yes)
1298 AC_MSG_RESULT($use_regex)
1299
1300 if test "$use_regex" = yes ; then
1301   _cppflags="${CPPFLAGS}"
1302   _ldflags="${LDFLAGS}"
1303   AC_ARG_WITH(regex,
1304      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1305       [
1306       if test -d "$withval" ; then
1307         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1308         LDFLAGS="${LDFLAGS} -L$withval/lib"
1309       fi
1310       ],withval="")
1311
1312   # Does the system have regex functions at all?
1313   AC_SEARCH_LIBS([regcomp], [regex])
1314   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1315
1316   if test $gnupg_cv_have_regex = no; then
1317     use_regex=no
1318   else
1319     if test x"$cross_compiling" = xyes; then
1320       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1321     else
1322       AC_CACHE_CHECK([whether your system's regexp library is broken],
1323        [gnupg_cv_regex_broken],
1324        AC_TRY_RUN([
1325 #include <unistd.h>
1326 #include <regex.h>
1327 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1328        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1329
1330       if test $gnupg_cv_regex_broken = yes; then
1331         AC_MSG_WARN([your regex is broken - disabling regex use])
1332         use_regex=no
1333       fi
1334     fi
1335   fi
1336   CPPFLAGS="${_cppflags}"
1337   LDFLAGS="${_ldflags}"
1338 fi
1339
1340 if test "$use_regex" != yes ; then
1341   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1342 fi
1343 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1344
1345
1346
1347 #
1348 # Do we have zlib? Must do it here because Solaris failed
1349 # when compiling a conftest (due to the "-lz" from LIBS).
1350 # Note that we combine zlib and bzlib2 in ZLIBS.
1351 #
1352 if test "$use_zip" = yes ; then
1353   _cppflags="${CPPFLAGS}"
1354   _ldflags="${LDFLAGS}"
1355   AC_ARG_WITH(zlib,
1356     [  --with-zlib=DIR         use libz in DIR],[
1357       if test -d "$withval"; then
1358         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1359         LDFLAGS="${LDFLAGS} -L$withval/lib"
1360       fi
1361     ])
1362
1363   AC_CHECK_HEADER(zlib.h,
1364         AC_CHECK_LIB(z, deflateInit2_,
1365          ZLIBS="-lz",
1366          CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1367          CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1368
1369   AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1370 fi
1371
1372
1373 #
1374 # Check whether we can support bzip2
1375 #
1376 if test "$use_bzip2" = yes ; then
1377   _cppflags="${CPPFLAGS}"
1378   _ldflags="${LDFLAGS}"
1379   AC_ARG_WITH(bzip2,
1380      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1381       [
1382       if test -d "$withval" ; then
1383         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1384         LDFLAGS="${LDFLAGS} -L$withval/lib"
1385       fi
1386       ],withval="")
1387
1388   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1389   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1390   # woefully out of date.
1391   if test "$withval" != no ; then
1392      AC_CHECK_HEADER(bzlib.h,
1393         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1394           [
1395           have_bz2=yes
1396           ZLIBS="$ZLIBS -lbz2"
1397           AC_DEFINE(HAVE_BZIP2,1,
1398                   [Defined if the bz2 compression library is available])
1399           ],
1400           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1401           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1402   fi
1403 fi
1404 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1405 AC_SUBST(ZLIBS)
1406
1407
1408 # Check for readline support
1409 GNUPG_CHECK_READLINE
1410
1411
1412 if test "$development_version" = yes; then
1413     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1414             [Defined if this is not a regular release])
1415 fi
1416
1417 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1418
1419 GNUPG_CHECK_GNUMAKE
1420
1421 # Add some extra libs here so that previous tests don't fail for
1422 # mysterious reasons - the final link step should bail out.
1423 # W32SOCKLIBS is also defined so that if can be used for tools not
1424 # requiring any network stuff but linking to code in libcommon which
1425 # tracks in winsock stuff (e.g. init_common_subsystems).
1426 if test "$have_w32_system" = yes; then
1427    if test "$have_w32ce_system" = yes; then
1428      W32SOCKLIBS="-lws2"
1429    else
1430      W32SOCKLIBS="-lws2_32"
1431    fi
1432    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1433 fi
1434
1435 AC_SUBST(NETLIBS)
1436 AC_SUBST(W32SOCKLIBS)
1437
1438 #
1439 # Setup gcc specific options
1440 #
1441 AC_MSG_NOTICE([checking for cc features])
1442 if test "$GCC" = yes; then
1443     # Note that it is okay to use CFLAGS here because this are just
1444     # warning options and the user should have a chance of overriding
1445     # them.
1446     if test "$USE_MAINTAINER_MODE" = "yes"; then
1447         CFLAGS="$CFLAGS -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1448         CFLAGS="$CFLAGS -Wformat -Wno-format-y2k -Wformat-security"
1449         AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1450         _gcc_cflags_save=$CFLAGS
1451         CFLAGS="-Wno-missing-field-initializers"
1452         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1453         AC_MSG_RESULT($_gcc_wopt)
1454         CFLAGS=$_gcc_cflags_save;
1455         if test x"$_gcc_wopt" = xyes ; then
1456           CFLAGS="$CFLAGS -W -Wno-sign-compare -Wno-missing-field-initializers"
1457         fi
1458         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1459         _gcc_cflags_save=$CFLAGS
1460         CFLAGS="-Wdeclaration-after-statement"
1461         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1462         AC_MSG_RESULT($_gcc_wopt)
1463         CFLAGS=$_gcc_cflags_save;
1464         if test x"$_gcc_wopt" = xyes ; then
1465           CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1466         fi
1467     else
1468         CFLAGS="$CFLAGS -Wall"
1469     fi
1470
1471     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1472     _gcc_cflags_save=$CFLAGS
1473     CFLAGS="-Wno-pointer-sign"
1474     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1475     AC_MSG_RESULT($_gcc_psign)
1476     CFLAGS=$_gcc_cflags_save;
1477     if test x"$_gcc_psign" = xyes ; then
1478        CFLAGS="$CFLAGS -Wno-pointer-sign"
1479     fi
1480
1481     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1482     _gcc_cflags_save=$CFLAGS
1483     CFLAGS="-Wpointer-arith"
1484     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1485     AC_MSG_RESULT($_gcc_psign)
1486     CFLAGS=$_gcc_cflags_save;
1487     if test x"$_gcc_psign" = xyes ; then
1488        CFLAGS="$CFLAGS -Wpointer-arith"
1489     fi
1490 fi
1491
1492
1493 #
1494 # This is handy for debugging so the compiler doesn't rearrange
1495 # things and eliminate variables.
1496 #
1497 AC_ARG_ENABLE(optimization,
1498    AC_HELP_STRING([--disable-optimization],
1499                   [disable compiler optimization]),
1500                   [if test $enableval = no ; then
1501                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1502                    fi])
1503
1504 #
1505 # Prepare building of estream
1506 #
1507 estream_INIT
1508
1509
1510 #
1511 # Decide what to build
1512 #
1513 if test "$have_adns" = "yes"; then
1514   AC_SUBST(GPGKEYS_KDNS, "gpg2keys_kdns$EXEEXT")
1515 fi
1516
1517
1518 build_scdaemon_extra=""
1519 if test "$build_scdaemon" = "yes"; then
1520   if test $have_libusb = no; then
1521      build_scdaemon_extra="without internal CCID driver"
1522   fi
1523   if test -n "$build_scdaemon_extra"; then
1524      build_scdaemon_extra="(${build_scdaemon_extra})"
1525   fi
1526 fi
1527
1528
1529 if test "$build_agent_only" = "yes" ; then
1530   build_gpg=no
1531   build_gpgsm=no
1532   build_scdaemon=no
1533   build_tools=no
1534   build_doc=no
1535 fi
1536
1537 #
1538 # Set variables for use by th automake makefile.
1539 #
1540 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1541 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1542 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1543 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1544 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1545 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1546 AM_CONDITIONAL(BUILD_TOOLS,       test "$build_tools" = "yes")
1547 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1548 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1549 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1550
1551 AM_CONDITIONAL(RUN_GPG_TESTS,
1552                test x$cross_compiling = xno -a "$build_gpg" = yes )
1553
1554 #
1555 # Set some defines for use gpgconf.
1556 #
1557 if test "$build_gpg" = yes ; then
1558     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1559 fi
1560 if test "$build_gpgsm" = yes ; then
1561     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1562 fi
1563 if test "$build_agent" = yes ; then
1564     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1565 fi
1566 if test "$build_scdaemon" = yes ; then
1567     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1568 fi
1569 if test "$build_dirmngr" = yes ; then
1570     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if SCDAEMON is to be build])
1571 fi
1572 if test "$build_g13" = yes ; then
1573     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1574 fi
1575
1576
1577
1578 #
1579 # Provide information about the build.
1580 #
1581 BUILD_REVISION="mym4_revision"
1582 AC_SUBST(BUILD_REVISION)
1583 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1584                    [GIT commit id revision used to build this package])
1585
1586 changequote(,)dnl
1587 BUILD_FILEVERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./;s/\./,/g'`
1588 changequote([,])dnl
1589 BUILD_FILEVERSION="${BUILD_FILEVERSION}mym4_revision_dec"
1590 AC_SUBST(BUILD_FILEVERSION)
1591
1592 BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1593 AC_SUBST(BUILD_TIMESTAMP)
1594 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1595                    [The time this package was configured for a build])
1596 BUILD_HOSTNAME="$ac_hostname"
1597 AC_SUBST(BUILD_HOSTNAME)
1598
1599
1600 #
1601 # Print errors here so that they are visible all
1602 # together and the user can acquire them all together.
1603 #
1604 die=no
1605 if test "$have_gpg_error" = "no"; then
1606    die=yes
1607    AC_MSG_NOTICE([[
1608 ***
1609 *** You need libgpg-error to build this program.
1610 **  This library is for example available at
1611 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1612 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1613 ***]])
1614 fi
1615 if test "$have_libgcrypt" = "no"; then
1616    die=yes
1617    AC_MSG_NOTICE([[
1618 ***
1619 *** You need libgcrypt to build this program.
1620 **  This library is for example available at
1621 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1622 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1623 ***]])
1624 fi
1625 if test "$have_libassuan" = "no"; then
1626    die=yes
1627    AC_MSG_NOTICE([[
1628 ***
1629 *** You need libassuan to build this program.
1630 *** This library is for example available at
1631 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1632 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1633 ***]])
1634 fi
1635 if test "$have_ksba" = "no"; then
1636     die=yes
1637     AC_MSG_NOTICE([[
1638 ***
1639 *** You need libksba to build this program.
1640 *** This library is for example available at
1641 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1642 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1643 ***]])
1644 fi
1645 if test "$gnupg_have_ldap" = "no"; then
1646     die=yes
1647     AC_MSG_NOTICE([[
1648 ***
1649 *** You need a LDAP library to build this program.
1650 *** Check out
1651 ***    http://www.openldap.org
1652 *** for a suitable implementation.
1653 ***]])
1654    if test "$have_w32ce_system" = yes; then
1655     AC_MSG_NOTICE([[
1656 *** Note that CeGCC might be broken, a package fixing this is:
1657 ***    http://files.kolab.org/local/windows-ce/
1658 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1659 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1660 ***]])
1661    fi
1662 fi
1663 if test "$have_npth" = "no"; then
1664     die=yes
1665     AC_MSG_NOTICE([[
1666 ***
1667 *** It is now required to build with support for the
1668 *** New Portable Threads Library (nPth). Please install this
1669 *** library first.  The library is for example available at
1670 ***   ftp://ftp.gnupg.org/gcrypt/npth/
1671 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1672 ***]])
1673 fi
1674
1675 if test "$die" = "yes"; then
1676     AC_MSG_ERROR([[
1677 ***
1678 *** Required libraries not found. Please consult the above messages
1679 *** and install them before running configure again.
1680 ***]])
1681 fi
1682
1683
1684
1685 AC_CONFIG_FILES([ m4/Makefile
1686 Makefile
1687 po/Makefile.in
1688 gl/Makefile
1689 include/Makefile
1690 common/Makefile
1691 common/w32info-rc.h
1692 kbx/Makefile
1693 g10/Makefile
1694 sm/Makefile
1695 agent/Makefile
1696 scd/Makefile
1697 g13/Makefile
1698 dirmngr/Makefile
1699 tools/gpg-zip
1700 tools/Makefile
1701 doc/Makefile
1702 tests/Makefile
1703 tests/openpgp/Makefile
1704 tests/pkits/Makefile
1705 ])
1706 #keyserver/Makefile
1707 #keyserver/gpg2keys_mailto
1708 #keyserver/gpg2keys_test
1709
1710
1711 AC_OUTPUT
1712
1713
1714 echo "
1715         GnuPG v${VERSION} has been configured as follows:
1716
1717         Revision:  mym4_revision  (mym4_revision_dec)
1718         Platform:  $PRINTABLE_OS_NAME ($host)
1719
1720         OpenPGP:   $build_gpg
1721         S/MIME:    $build_gpgsm
1722         Agent:     $build_agent
1723         Smartcard: $build_scdaemon $build_scdaemon_extra
1724         G13:       $build_g13
1725         Dirmngr:   $build_dirmngr
1726         Gpgtar:    $build_gpgtar
1727
1728         Protect tool:      $show_gnupg_protect_tool_pgm
1729         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
1730         Default agent:     $show_gnupg_agent_pgm
1731         Default pinentry:  $show_gnupg_pinentry_pgm
1732         Default scdaemon:  $show_gnupg_scdaemon_pgm
1733         Default dirmngr:   $show_gnupg_dirmngr_pgm
1734
1735         Use standard socket: $use_standard_socket
1736         Dirmngr auto start:  $dirmngr_auto_start
1737 "
1738 if test x"$use_regex" != xyes ; then
1739 echo "
1740         Warning: No regular expression support available.
1741                  OpenPGP trust signatures won't work.
1742                  gpg-check-pattern will not be build.
1743 "
1744 fi