* NEWS: Note --symmetric --encrypt and the improved config file search.
[gnupg.git] / configure.ac
1 dnl Configure.ac script for GnuPG
2 dnl Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 dnl               2003 Free Software Foundation, Inc.
4 dnl
5 dnl This file is part of GnuPG.
6 dnl
7 dnl GnuPG is free software; you can redistribute it and/or modify
8 dnl it under the terms of the GNU General Public License as published by
9 dnl the Free Software Foundation; either version 2 of the License, or
10 dnl (at your option) any later version.
11 dnl 
12 dnl GnuPG is distributed in the hope that it will be useful,
13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 dnl GNU General Public License for more details.
16 dnl 
17 dnl You should have received a copy of the GNU General Public License
18 dnl along with this program; if not, write to the Free Software
19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20 dnl
21 dnl (Process this file with autoconf to produce a configure script.)
22 dnlAC_REVISION($Revision$)dnl
23
24 AC_PREREQ(2.57)
25
26 # Remember to change the version number immediately *after* a release
27 # and remove the "-cvs" or "rc" suffix immediately *before* a release.
28 AC_INIT(gnupg, 1.3.4-cvs, bug-gnupg@gnu.org)
29 # Set development_version to yes if the minor number is odd or you
30 # feel that the default check for a development version is not
31 # sufficient.
32 development_version=yes
33
34 AC_CONFIG_AUX_DIR(scripts)
35 AC_CONFIG_SRCDIR(g10/g10.c)
36 AC_CANONICAL_TARGET()
37 AM_INIT_AUTOMAKE
38 AM_CONFIG_HEADER(config.h)
39
40 AC_GNU_SOURCE
41
42 dnl
43 dnl  Check for random module options
44 dnl
45 AC_MSG_CHECKING([which random module to use])
46 AC_ARG_ENABLE(static-rnd,
47     [  --enable-static-rnd=[egd|unix|linux|auto]  ],
48 [use_static_rnd=$enableval], [use_static_rnd=default] )
49
50 if test "$use_static_rnd" = no; then
51     use_static_rnd=default
52 fi
53
54 case "$use_static_rnd" in
55     egd | linux | unix | default )
56       AC_MSG_RESULT($use_static_rnd)
57       ;;
58     auto )
59       AC_MSG_RESULT(automagically selected at runtime)
60       ;;
61     * )
62       AC_MSG_RESULT(invalid argument)
63       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
64       ;;
65 esac
66
67 AC_ARG_WITH(egd-socket,
68     [  --with-egd-socket=NAME  use NAME for the EGD socket],
69             egd_socket_name="$withval", egd_socket_name="" )
70 AC_DEFINE_UNQUOTED(EGD_SOCKET_NAME, "$egd_socket_name",
71                    [Define if you don't want the default EGD socket name.
72                     For details see cipher/rndegd.c])
73
74
75 dnl
76 dnl See whether the user wants to disable checking for /dev/random
77
78 AC_MSG_CHECKING([whether use of /dev/random is requested])
79 AC_ARG_ENABLE(dev-random,
80 [  --disable-dev-random    disable the use of dev random],
81     try_dev_random=$enableval, try_dev_random=yes)
82 AC_MSG_RESULT($try_dev_random)
83
84
85 dnl
86 dnl  Check other options
87 dnl
88
89 AC_MSG_CHECKING([whether assembler modules are requested])
90 AC_ARG_ENABLE(asm,
91 [  --disable-asm           do not use assembler modules],
92      try_asm_modules=$enableval, try_asm_modules=yes)
93 AC_MSG_RESULT($try_asm_modules)
94
95 AC_MSG_CHECKING([whether memory guard is requested])
96 AC_ARG_ENABLE(m-guard,
97     [  --enable-m-guard        enable memory guard facility],
98     use_m_guard=$enableval, use_m_guard=no)
99 AC_MSG_RESULT($use_m_guard)
100 if test "$use_m_guard" = yes ; then
101     AC_DEFINE(M_GUARD,1,[Define to use the (obsolete) malloc guarding feature])
102 fi
103
104 AC_MSG_CHECKING([whether OpenPGP card support is requested])
105 AC_ARG_ENABLE(card-support,
106     [  --enable-card-support   enable OpenPGP card support],
107     card_support=$enableval, card_support=no)
108 AC_MSG_RESULT($card_support)
109
110 dnl See if we are disabling any algorithms or features for a smaller
111 dnl binary
112
113 try_extensions=no
114
115 use_idea=yes
116 use_cast5=yes
117 use_blowfish=yes
118 use_aes=yes
119 use_twofish=yes
120 use_sha256=yes
121 use_sha512=yes
122 use_exec=yes
123
124 AC_ARG_ENABLE(minimal,
125    AC_HELP_STRING([--enable-minimal],[build the smallest gpg binary possible]),
126    use_idea=no
127    use_cast5=no
128    use_blowfish=no
129    use_aes=no
130    use_twofish=no
131    use_sha256=no
132    use_sha512=no
133    use_exec=no)
134
135 AC_MSG_CHECKING([whether to enable the IDEA cipher])
136 AC_ARG_ENABLE(idea,
137    AC_HELP_STRING([--disable-idea],[disable the IDEA cipher]),
138    use_idea=$enableval)
139 AC_MSG_RESULT($use_idea)
140 if test x"$use_idea" = xyes ; then
141    AC_DEFINE(USE_IDEA,1,[Define to include the IDEA cipher])
142
143 # We don't need idea but some people claim that they need it for
144 # research etc., so we allow to place an idea source code into the
145 # cipher directory and statically link it if available, otherwise we
146 # link to a stub.  We don't use AC_CHECK_FILE to avoid caching.
147
148    AC_MSG_CHECKING([for idea cipher module])
149    tmp=""
150    if test -f $srcdir/cipher/idea.c; then 
151       IDEA_O=idea.o
152       tmp=idea
153    else
154       IDEA_O=idea-stub.o
155       tmp=no
156       try_extensions=yes
157    fi
158    AC_SUBST(IDEA_O)
159    AC_MSG_RESULT($tmp)
160 fi
161
162 AC_MSG_CHECKING([whether to enable the CAST5 cipher])
163 AC_ARG_ENABLE(cast5,
164    AC_HELP_STRING([--disable-cast5],[disable the CAST5 cipher]),
165    use_cast5=$enableval)
166 AC_MSG_RESULT($use_cast5)
167 if test x"$use_cast5" = xyes ; then
168    AC_DEFINE(USE_CAST5,1,[Define to include the CAST5 cipher])
169 fi
170
171 AC_MSG_CHECKING([whether to enable the BLOWFISH cipher])
172 AC_ARG_ENABLE(blowfish,
173    AC_HELP_STRING([--disable-blowfish],[disable the BLOWFISH cipher]),
174    use_blowfish=$enableval)
175 AC_MSG_RESULT($use_blowfish)
176 if test x"$use_blowfish" = xyes ; then
177    AC_DEFINE(USE_BLOWFISH,1,[Define to include the BLOWFISH cipher])
178 fi
179
180 AC_MSG_CHECKING([whether to enable the AES ciphers])
181 AC_ARG_ENABLE(aes,
182    AC_HELP_STRING([--disable-aes],[disable the AES, AES192, and AES256 ciphers]),
183    use_aes=$enableval)
184 AC_MSG_RESULT($use_aes)
185 if test x"$use_aes" = xyes ; then
186    AC_DEFINE(USE_AES,1,[Define to include the AES, AES192, and AES256 ciphers])
187 fi
188
189 AC_MSG_CHECKING([whether to enable the TWOFISH cipher])
190 AC_ARG_ENABLE(twofish,
191    AC_HELP_STRING([--disable-twofish],[disable the TWOFISH cipher]),
192    use_twofish=$enableval)
193 AC_MSG_RESULT($use_twofish)
194 if test x"$use_twofish" = xyes ; then
195    AC_DEFINE(USE_TWOFISH,1,[Define to include the TWOFISH cipher])
196 fi
197
198 AC_MSG_CHECKING([whether to enable the SHA-256 digest])
199 AC_ARG_ENABLE(sha256,
200    AC_HELP_STRING([--disable-sha256],[disable the SHA-256 digest]),
201    use_sha256=$enableval)
202 AC_MSG_RESULT($use_sha256)
203 if test x"$use_sha256" = xyes ; then
204    AC_DEFINE(USE_SHA256,1,[Define to include the SHA-256 digest])
205 fi
206
207 dnl SHA512 is defined only after we confirm 64-bit support later
208 AC_MSG_CHECKING([whether to enable the SHA-384 and SHA-512 digests])
209 AC_ARG_ENABLE(sha512,
210    AC_HELP_STRING([--disable-sha512],[disable the SHA-384 and SHA-512 digests]),
211    use_sha512=$enableval)
212 AC_MSG_RESULT($use_sha512)
213
214 AC_MSG_CHECKING([whether to enable external program execution])
215 AC_ARG_ENABLE(exec,
216     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
217     use_exec=$enableval)
218 AC_MSG_RESULT($use_exec)
219 if test "$use_exec" = no ; then
220     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
221 fi
222
223 if test "$use_exec" = yes ; then
224   AC_MSG_CHECKING([whether to enable photo ID viewing])
225   AC_ARG_ENABLE(photo-viewers,
226       [  --disable-photo-viewers disable photo ID viewers],
227       [if test "$enableval" = no ; then
228          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
229       fi],enableval=yes)
230   gnupg_cv_enable_photo_viewers=$enableval
231   AC_MSG_RESULT($enableval)
232
233   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
234     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
235     AC_ARG_WITH(photo-viewer,
236         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
237         [if test "$withval" = yes ; then
238            withval=no
239         elif test "$withval" != no ; then
240            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
241                             [if set, restrict photo-viewer to this])
242         fi],withval=no)
243     AC_MSG_RESULT($withval)
244   fi
245
246   AC_MSG_CHECKING([whether to enable external keyserver helpers])
247   AC_ARG_ENABLE(keyserver-helpers,
248       [  --disable-keyserver-helpers  disable all external keyserver support],
249       [if test "$enableval" = no ; then
250          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
251                   [define to disable keyserver helpers])
252       fi],enableval=yes)
253   gnupg_cv_enable_keyserver_helpers=$enableval
254   AC_MSG_RESULT($enableval)
255
256   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
257     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
258     AC_ARG_ENABLE(ldap,
259     [  --disable-ldap          disable LDAP keyserver interface],
260         try_ldap=$enableval, try_ldap=yes)
261     AC_MSG_RESULT($try_ldap)
262
263     AC_MSG_CHECKING([whether HKP keyserver support is requested])
264     AC_ARG_ENABLE(hkp,
265     [  --disable-hkp           disable HKP keyserver interface],
266         try_hkp=$enableval, try_hkp=yes)
267     AC_MSG_RESULT($try_hkp)
268
269     AC_MSG_CHECKING([whether email keyserver support is requested])
270     AC_ARG_ENABLE(mailto,
271     [  --disable-mailto        disable email keyserver interface],
272         try_mailto=$enableval, try_mailto=yes)
273     AC_MSG_RESULT($try_mailto)
274     fi
275
276     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
277     AC_ARG_ENABLE(keyserver-path,
278         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
279         [if test "$enableval" = no ; then
280          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
281         fi],enableval=yes)
282     AC_MSG_RESULT($enableval)
283   fi
284
285 AC_MSG_CHECKING([whether the included zlib is requested])
286 AC_ARG_WITH(included-zlib,
287     [  --with-included-zlib    use the zlib code included here],
288 [g10_force_zlib=yes], [g10_force_zlib=no] )
289 AC_MSG_RESULT($g10_force_zlib)
290
291 dnl
292 dnl Check whether we want to use Linux capabilities
293 dnl
294 AC_MSG_CHECKING([whether use of capabilities is requested])
295 AC_ARG_WITH(capabilities,
296     [  --with-capabilities     use linux capabilities [default=no]],
297 [use_capabilities="$withval"],[use_capabilities=no])
298 AC_MSG_RESULT($use_capabilities)
299
300
301 AH_BOTTOM([
302 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
303 #define EXEC_TEMPFILE_ONLY
304 #endif
305
306 /* This is the major version number of GnuPG so that
307    source included files can test for this. */
308 #define GNUPG_MAJOR_VERSION 1
309
310 #include "g10defs.h"
311 ])
312
313
314 AM_MAINTAINER_MODE
315
316 dnl Checks for programs.
317
318 AC_PROG_MAKE_SET
319 AM_SANITY_CHECK
320 missing_dir=`cd $ac_aux_dir && pwd`
321 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
322 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
323 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
324 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
325 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
326 AC_PROG_CC
327 AC_PROG_CPP
328 AC_PROG_RANLIB
329 AC_CHECK_TOOL(AR, ar, :)
330 AC_PATH_PROG(PERL,"perl")
331 AC_ISC_POSIX
332 AC_SYS_LARGEFILE
333 AC_PROG_INSTALL
334 AC_PROG_AWK
335 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
336 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
337 GNUPG_CHECK_FAQPROG
338 GNUPG_CHECK_DOCBOOK_TO_TEXI
339
340 MPI_OPT_FLAGS=""
341
342
343 try_gettext=yes
344 have_dosish_system=no
345 need_dlopen=yes
346 case "${target}" in
347     *-*-mingw32*)
348         # special stuff for Windoze NT
349         ac_cv_have_dev_random=no
350         AC_DEFINE(USE_ONLY_8DOT3,1,
351                   [set this to limit filenames to the 8.3 format])
352         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
353                   [defined if we must run on a stupid file system])
354         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
355                   [because the Unix gettext has too much overhead on
356                    MingW32 systems and these systems lack Posix functions,
357                    we use a simplified version of gettext])
358         have_dosish_system=yes
359         need_dlopen=no
360         try_gettext="no"
361         ;;
362     i?86-emx-os2 | i?86-*-os2*emx )
363         # OS/2 with the EMX environment
364         ac_cv_have_dev_random=no
365         AC_DEFINE(HAVE_DRIVE_LETTERS)
366         have_dosish_system=yes
367         try_gettext="no"
368         ;;
369
370     i?86-*-msdosdjgpp*)
371         # DOS with the DJGPP environment
372         ac_cv_have_dev_random=no
373         AC_DEFINE(HAVE_DRIVE_LETTERS)
374         have_dosish_system=yes
375         try_gettext="no"
376         ;;
377
378     *-*-freebsd*)
379        # FreeBSD
380        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
381        LDFLAGS="$LDFLAGS -L/usr/local/lib"
382        ;;
383
384     *-*-hpux*)
385         if test -z "$GCC" ; then
386             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
387         fi
388         ;;
389     *-dec-osf4*)
390         if test -z "$GCC" ; then
391             # Suppress all warnings
392             # to get rid of the unsigned/signed char mismatch warnings.
393             CFLAGS="$CFLAGS -w"
394         fi
395         ;;
396     *-dec-osf5*)
397         if test -z "$GCC" ; then
398             # Use the newer compiler `-msg_disable ptrmismatch' to
399             # get rid of the unsigned/signed char mismatch warnings.
400             # Using this may hide other pointer mismatch warnings, but
401             # it at least lets other warning classes through
402             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
403         fi
404         ;;
405     m68k-atari-mint)
406         ;;
407     *)
408        ;;
409 esac
410
411 if test "$have_dosish_system" = yes; then
412    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
413              [defined if we run on some of the PCDOS like systems 
414               (DOS, Windoze. OS/2) with special properties like
415               no file modes])
416 fi
417 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
418
419 AC_SUBST(MPI_OPT_FLAGS)
420 GNUPG_SYS_SYMBOL_UNDERSCORE
421
422 dnl This needs to go after AC_PROG_CC so that $EXEEXT is defined
423 if test "$try_hkp" = yes ; then
424   AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
425 fi
426
427 dnl Must check for network library requirements before doing link tests
428 dnl for ldap, for example. If ldap libs are static (or dynamic and without
429 dnl ELF runtime link paths), then link will fail and LDAP support won't
430 dnl be detected.
431
432 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
433         [NETLIBS="-lnsl $NETLIBS"]))
434 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
435         [NETLIBS="-lsocket $NETLIBS"]))
436
437 dnl Now try for the resolver functions so we can use DNS SRV
438
439 AC_ARG_ENABLE(dns-srv,
440    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
441    use_dns_srv=$enableval,use_dns_srv=yes)
442
443 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
444   _srv_save_libs=$LIBS
445   LIBS=""
446   # the double underscore thing is a glibc-ism?
447   AC_SEARCH_LIBS(res_query,resolv bind,,
448                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
449   AC_SEARCH_LIBS(dn_expand,resolv bind,,
450                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
451   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
452                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
453
454   if test x"$use_dns_srv" = xyes ; then
455      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
456      SRVLIBS=$LIBS
457   else
458      AC_MSG_WARN([Resolver functions not found.  Disabling DNS SRV.])
459   fi
460   LIBS=$_srv_save_libs
461 fi
462
463 AC_SUBST(SRVLIBS)
464
465 # Try and link a LDAP test program to weed out unusable LDAP
466 # libraries.  -lldap [-llber [-lresolv]] is for OpenLDAP.  OpenLDAP in
467 # general is terrible with creating weird dependencies.  If all else
468 # fails, the user can play guess-the-dependency by using something
469 # like ./configure LDAPLIBS="-Lfoo -lbar"
470
471 if test "$try_ldap" = yes ; then
472   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
473     _ldap_save_libs=$LIBS
474     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
475
476     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
477     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
478                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
479     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
480
481     if test $gnupg_cv_func_ldap_init = no; then
482       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
483       AC_TRY_LINK([#include <lber.h>
484 #include <ldap.h>],[ldap_open("foobar",1234);],
485          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
486       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
487     fi
488
489     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
490        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
491     fi
492
493     if test "$gnupg_cv_func_ldap_init" = yes || \
494         test "$gnupg_cv_func_ldaplber_init" = yes ; then
495        LDAPLIBS=$MY_LDAPLIBS
496        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
497
498        AC_MSG_CHECKING([whether LDAP supports ldap_get_option])
499
500        if test "$gnupg_cv_func_ldap_init" = yes ; then
501           AC_TRY_LINK([#include <ldap.h>],
502              [ldap_get_option((void *)0,0,(void *)0);],
503              [gnupg_cv_func_ldap_get_option=yes],
504              [gnupg_cv_func_ldap_get_option=no])
505         else
506           AC_TRY_LINK([#include <lber.h>
507 #include <ldap.h>],[ldap_get_option((void *)0,0,(void *)0);],
508              [gnupg_cv_func_ldap_get_option=yes],
509              [gnupg_cv_func_ldap_get_option=no])
510        fi
511
512        AC_MSG_RESULT([$gnupg_cv_func_ldap_get_option])
513
514        if test "$gnupg_cv_func_ldap_get_option" = yes ; then
515           AC_DEFINE(HAVE_LDAP_GET_OPTION,1,[Define if the LDAP library has ldap_get_option])
516        else
517           AC_MSG_CHECKING([whether LDAP supports ld_errno])
518
519           if test "$gnupg_cv_func_ldap_init" = yes ; then
520             AC_TRY_COMPILE([#include <ldap.h>],
521                [LDAP *ldap; ldap->ld_errno;],
522                [gnupg_cv_func_ldap_ld_errno=yes],
523                [gnupg_cv_func_ldap_ld_errno=no])
524            else
525             AC_TRY_LINK([#include <lber.h>
526 #include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
527                [gnupg_cv_func_ldap_ld_errno=yes],
528                [gnupg_cv_func_ldap_ld_errno=no])
529           fi
530
531           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
532
533           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
534              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
535           fi
536        fi
537     fi
538
539     LIBS=$_ldap_save_libs
540
541     if test "$GPGKEYS_LDAP" != "" ; then break; fi
542   done
543 fi
544
545 AC_SUBST(GPGKEYS_LDAP)
546 AC_SUBST(LDAPLIBS)
547
548 dnl This isn't necessarily sendmail itself, but anything that gives a
549 dnl sendmail-ish interface to the outside world.  That includes qmail,
550 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
551
552 if test "$try_mailto" = yes ; then
553   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
554
555   if test "$with_mailprog" = yes ; then
556     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
557     if test "$ac_cv_path_SENDMAIL" ; then
558       GPGKEYS_MAILTO="gpgkeys_mailto"
559     fi
560   elif test "$with_mailprog" != no ; then
561     AC_MSG_CHECKING([for a mail transport program])
562     AC_SUBST(SENDMAIL,$with_mailprog)
563     AC_MSG_RESULT($with_mailprog)
564     GPGKEYS_MAILTO="gpgkeys_mailto"
565   fi
566 fi
567
568 AC_SUBST(GPGKEYS_MAILTO)
569
570 case "${target}" in
571     *-*-mingw32*)
572         PRINTABLE_OS_NAME="MingW32"
573         ;;
574     *-*-cygwin*)
575         PRINTABLE_OS_NAME="Cygwin"
576         ;;
577     i?86-emx-os2 | i?86-*-os2*emx )
578         PRINTABLE_OS_NAME="OS/2"
579         ;;
580     i?86-*-msdosdjgpp*)
581         PRINTABLE_OS_NAME="MSDOS/DJGPP"
582         try_extensions=no
583         ;;
584     *-linux*)
585         PRINTABLE_OS_NAME="GNU/Linux"
586         ;;
587     *)
588         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
589         ;;
590 esac
591 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
592                    [A human readable text with the name of the OS])
593
594
595 #
596 # 1. Set names of random devices
597 #
598 NAME_OF_DEV_RANDOM="/dev/random"
599 NAME_OF_DEV_URANDOM="/dev/urandom"
600 case "${target}" in
601     *-openbsd*)
602         NAME_OF_DEV_RANDOM="/dev/srandom"
603         NAME_OF_DEV_URANDOM="/dev/urandom"
604         ;;
605 esac
606 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM",
607                    [defined to the name of the strong random device])
608 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM",
609                    [defined to the name of the weaker random device])
610 AC_SUBST(MPI_OPT_FLAGS)
611
612
613 dnl Checks for libraries.
614
615 if test "$try_gettext" = yes; then
616   AM_GNU_GETTEXT(,[need-ngettext])
617
618   # gettext requires some extra checks.  These really should be part of
619   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
620   # function checks to here.
621
622   AC_CHECK_FUNCS(strchr)
623 else
624   USE_NLS=no
625   USE_INCLUDED_LIBINTL=no
626   BUILD_INCLUDED_LIBINTL=no
627   AC_SUBST(USE_NLS)
628   AC_SUBST(USE_INCLUDED_LIBINTL)
629   AC_SUBST(BUILD_INCLUDED_LIBINTL)
630 fi
631
632 if test "$try_extensions" = yes || test x"$card_support" = xyes ; then
633   if test "$need_dlopen" = yes; then
634     _dl_save_libs=$LIBS
635     LIBS=""
636     AC_SEARCH_LIBS(dlopen,dl,found_dlopen=yes)
637     if test x"$found_dlopen" = "xyes" ; then
638       AC_DEFINE(HAVE_DL_DLOPEN,1,
639                 [Defined when the dlopen function family is available])
640       DLLIBS=$LIBS
641     else
642       if test "$try_extensions" = yes ; then
643          AC_MSG_WARN([dlopen not found.  Disabling extensions.])
644          try_extensions=no
645       fi
646   
647       if test "$card_support" = yes ; then
648          AC_MSG_WARN([dlopen not found.  Disabling OpenPGP card support.])
649          card_support=no
650       fi
651     fi
652     LIBS=$_dl_save_libs
653   fi
654 fi
655
656 AC_SUBST(DLLIBS)
657
658 if test "$card_support" = yes ; then
659   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include OpenPGP card support])
660 fi
661
662 if test "$try_extensions" = yes ; then
663   AC_DEFINE(USE_DYNAMIC_LINKING,1,[Define to enable the use of extensions])
664 fi
665
666 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
667
668 dnl Checks for header files.
669 AC_HEADER_STDC
670 AC_CHECK_HEADERS(unistd.h langinfo.h termio.h locale.h getopt.h)
671
672 dnl Checks for typedefs, structures, and compiler characteristics.
673 AC_C_CONST
674 AC_C_INLINE
675 AC_C_VOLATILE
676 AC_TYPE_SIZE_T
677 AC_TYPE_MODE_T
678 AC_TYPE_SIGNAL
679 AC_DECL_SYS_SIGLIST
680
681 GNUPG_CHECK_ENDIAN
682
683 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
684 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
685 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
686 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
687 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
688
689 AC_CHECK_SIZEOF(unsigned short)
690 AC_CHECK_SIZEOF(unsigned int)
691 AC_CHECK_SIZEOF(unsigned long)
692 AC_CHECK_SIZEOF(unsigned long long)
693
694 # Ensure that we have UINT64_C before we bother to check for uint64_t
695 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
696    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
697 uint64_t foo=UINT64_C(42);]),gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
698
699 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
700    AC_CHECK_SIZEOF(uint64_t)
701 fi
702
703 if test "$ac_cv_sizeof_unsigned_short" = "0" \
704    || test "$ac_cv_sizeof_unsigned_int" = "0" \
705    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
706     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
707 fi
708
709 dnl Do we have any 64-bit data types?
710 if test "$ac_cv_sizeof_unsigned_int" != "8" \
711    && test "$ac_cv_sizeof_unsigned_long" != "8" \
712    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
713    && test x"$ac_cv_sizeof_uint64_t" != "x8"; then
714     AC_MSG_WARN([No 64-bit types.  Disabling SHA-384 and SHA-512])
715 else
716   if test x"$use_sha512" = xyes ; then
717      AC_SUBST(SHA512_O,sha512.o)
718      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
719   fi
720 fi
721
722 dnl Checks for library functions.
723 AC_FUNC_FSEEKO
724 AC_FUNC_VPRINTF
725 AC_FUNC_FORK
726 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
727 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times)
728 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
729 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
730 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat getaddrinfo)
731 AC_REPLACE_FUNCS(mkdtemp)
732 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
733
734 # See if getopt is in libiberty.  This is of course not optimal since
735 # it might be somewhere other than libiberty, but does cover the
736 # mingw32 case.
737
738 AC_CHECK_FUNC(getopt,,AC_CHECK_LIB(iberty,getopt,AC_SUBST(GETOPT,"-liberty")))
739
740 #
741 # check for gethrtime and run a testprogram to see whether
742 # it is broken.  It has been reported that some Solaris and HP UX systems 
743 # raise an SIGILL
744 #
745 AC_CACHE_CHECK([for gethrtime], 
746                [gnupg_cv_func_gethrtime],
747                [AC_TRY_LINK([#include <sys/times.h>],[
748                    hrtime_t tv;
749                    tv = gethrtime();
750                  ],
751                  [gnupg_cv_func_gethrtime=yes],
752                  [gnupg_cv_func_gethrtime=no])
753                ])
754 if test $gnupg_cv_func_gethrtime = yes; then
755      AC_DEFINE([HAVE_GETHRTIME], 1,
756                [Define if you have the `gethrtime(2)' function.])
757      AC_CACHE_CHECK([whether gethrtime is broken], 
758                [gnupg_cv_func_broken_gethrtime],
759                [AC_TRY_RUN([
760                    #include <sys/times.h>
761                    int main () {
762                    hrtime_t tv;
763                    tv = gethrtime(); 
764                  }
765                  ],
766                  [gnupg_cv_func_broken_gethrtime=no],
767                  [gnupg_cv_func_broken_gethrtime=yes],
768                  [gnupg_cv_func_broken_gethrtime=assume-no])
769                 ])
770     if test $gnupg_cv_func_broken_gethrtime = yes; then
771       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
772       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
773     fi
774 fi
775      
776
777 GNUPG_CHECK_MLOCK
778 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
779
780 dnl
781 dnl Check whether we can use Linux capabilities as requested
782 dnl
783 if test "$use_capabilities" = "yes" ; then
784 use_capabilities=no
785 AC_CHECK_HEADERS(sys/capability.h)
786 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
787   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
788   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
789      AC_DEFINE(USE_CAPABILITIES,1,
790                [define if capabilities should be used])
791      AC_SUBST(CAPLIBS,"-lcap")
792      use_capabilities=yes
793   fi
794 fi
795 if test "$use_capabilities" = "no" ; then
796     AC_MSG_WARN([[
797 ***
798 *** The use of capabilities on this system is not possible.
799 *** You need a recent Linux kernel and some patches:
800 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
801 ***   fcap-module-990613.tar.gz     (kernel module)
802 ***   libcap-1.92.tar.gz            (user mode library and utilities)
803 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
804 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
805 ***]])
806 fi
807 fi
808
809
810 GNUPG_CHECK_IPC
811 if test "$ac_cv_header_sys_shm_h" = "yes"; then
812   AC_DEFINE(USE_SHM_COPROCESSING,1,
813             [define if the shared memory interface should be made available])
814 fi
815
816 dnl
817 dnl check whether we have a random device
818 dnl
819 if test "$try_dev_random" = yes ; then
820     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
821     [if test -r "$NAME_OF_DEV_RANDOM" && test -r "$NAME_OF_DEV_URANDOM" ; then
822       ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
823     if test "$ac_cv_have_dev_random" = yes; then
824         AC_DEFINE(HAVE_DEV_RANDOM,1,
825                  [defined if the system supports a random device] )
826     fi
827 else
828     AC_MSG_CHECKING(for random device)
829     ac_cv_have_dev_random=no
830     AC_MSG_RESULT(has been disabled)
831 fi
832
833
834 dnl
835 dnl Figure out the default random module.
836 dnl
837 random_modules=""
838 if test "$use_static_rnd" = default; then
839      if test "$ac_cv_have_dev_random" = yes; then
840         random_modules="rndlinux"
841      else
842          case "${target}" in
843             *-*-mingw32*|*-*-cygwin*)
844                 random_modules="rndw32"
845                 ;;
846             i?86-emx-os2|i?86-*-os2*emx)
847                 random_modules="rndos2"
848                 ;;
849             m68k-atari-mint)
850                 random_modules="rndatari"
851                 ;;
852             i?86-*-msdosdjgpp*)
853                 :
854                 ;;
855             *)
856                 random_modules="rndlinux rndegd rndunix"
857                 AC_DEFINE(USE_ALL_RANDOM_MODULES, 1, 
858                           [Allow to select random modules at runtime.])
859                 ;;
860          esac
861      fi
862 else
863   if test "$use_static_rnd" = auto; then
864      random_modules="rndlinux rndegd rndunix"
865      AC_DEFINE(USE_ALL_RANDOM_MODULES, 1)
866   else
867      random_modules="rnd$use_static_rnd";
868   fi
869 fi
870
871 if test -z "$random_modules"; then
872    AC_MSG_ERROR(no random module available)
873 fi
874 print_egd_warning=no
875 for rndmod in $random_modules "" ; do
876   case "$rndmod" in
877     rndlinux)
878          AC_DEFINE(USE_RNDLINUX,1, 
879                   [Defined if the /dev/random based RNG should be used.])
880          ;;
881     rndunix)
882          AC_DEFINE(USE_RNDUNIX,1, 
883                   [Defined if the default Unix RNG should be used.])
884          print_egd_warning=yes
885           ;;
886     rndegd)
887          AC_DEFINE(USE_RNDEGD,1, 
888                   [Defined if the EGD based RNG should be used.])
889          ;;
890     rndw32)
891          AC_DEFINE(USE_RNDW32,1, 
892                   [Defined if the Windows specific RNG should be used.])
893         ;;
894    esac
895 done
896
897 dnl setup assembler stuff
898 AC_MSG_CHECKING(for mpi assembler functions)
899 if test -f $srcdir/mpi/config.links ; then
900     . $srcdir/mpi/config.links
901     AC_CONFIG_LINKS("$mpi_ln_list")
902     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
903     ac_cv_mpi_sflags="$mpi_sflags"
904     ac_cv_mpi_config_done="yes"
905     AC_MSG_RESULT(done)
906 else
907     AC_MSG_RESULT(failed)
908     AC_MSG_ERROR([mpi/config.links missing!])
909 fi
910 MPI_EXTRA_ASM_OBJS=""
911 show_extraasm=""
912 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
913 for i in $ac_cv_mpi_extra_asm_modules; do
914     show_extraasm="$show_extraasm $i"
915     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
916 done
917 fi
918 AC_SUBST(MPI_EXTRA_ASM_OBJS)
919 MPI_SFLAGS="$ac_cv_mpi_sflags"
920 AC_SUBST(MPI_SFLAGS)
921
922 # Sanity check regex.  Tests adapted from mutt.
923
924 AC_MSG_CHECKING([whether regular expression support is requested])
925 AC_ARG_ENABLE(regex,
926 [  --disable-regex         do not handle regular expressions in trust sigs],
927      use_regex=$enableval, use_regex=yes)
928 AC_MSG_RESULT($use_regex)
929
930 if test "$use_regex" = yes ; then
931   AC_MSG_CHECKING([whether the included regex lib is requested])
932   AC_ARG_WITH(included-regex,
933       [  --with-included-regex   use the included GNU regex library],
934       [gnupg_cv_included_regex=yes],[gnupg_cv_included_regex=no])
935   AC_MSG_RESULT($gnupg_cv_included_regex)
936
937   if test $gnupg_cv_included_regex = no ; then
938      # Does the system have regex functions at all?
939      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
940                            gnupg_cv_included_regex=yes)
941   fi
942
943   if test $gnupg_cv_included_regex = no ; then
944      AC_CACHE_CHECK([whether your system's regexp library is broken],
945        [gnupg_cv_regex_broken],
946        AC_TRY_RUN([
947 #include <unistd.h>
948 #include <regex.h>
949 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
950        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
951
952      if test $gnupg_cv_regex_broken = yes ; then
953       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
954       gnupg_cv_included_regex=yes
955      fi
956   fi
957
958   if test $gnupg_cv_included_regex = yes; then
959      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
960      AC_SUBST(REGEX_O,regex.o)
961   fi
962 else
963
964   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
965 fi
966
967 dnl Do we have zlib? Must do it here because Solaris failed
968 dnl when compiling a conftest (due to the "-lz" from LIBS).
969 use_local_zlib=yes
970 if test "$g10_force_zlib" = "yes"; then
971   :
972 else
973   _cppflags="${CPPFLAGS}"
974   _ldflags="${LDFLAGS}"
975
976   AC_ARG_WITH(zlib,
977   [  --with-zlib=DIR         use libz in DIR],[
978     if test -d "$withval"; then
979       CPPFLAGS="${CPPFLAGS} -I$withval/include"
980       LDFLAGS="${LDFLAGS} -L$withval/lib"
981     fi
982   ])
983
984   AC_CHECK_HEADER(zlib.h,
985       AC_CHECK_LIB(z, deflateInit2_,
986        use_local_zlib=no
987        ZLIBS="-lz",
988        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
989        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
990 fi
991
992 if test "$use_local_zlib" = yes ; then
993     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
994     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
995     ZLIBS="../zlib/libzlib.a"
996 else
997     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
998 fi
999 AC_SUBST(ZLIBS)
1000
1001
1002 #
1003 # libusb allows us to use the integrated CCID smartcard reader driver.
1004 #
1005 # Note, that we need the CVS (unstable) version. 
1006 #
1007 LIBUSB_LIBS=""
1008 if test "$card_support" = yes; then
1009     AC_CHECK_LIB(usb, usb_find_device,
1010                  [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
1011                    AC_DEFINE(HAVE_LIBUSB,1,
1012                    [defined if libusb is available])
1013                  ])
1014 fi
1015 AC_SUBST(LIBUSB_LIBS)
1016
1017
1018
1019 # Allow users to append something to the version string without
1020 # flagging it as development version.  The user version parts is
1021 # considered everything after a dash. 
1022 if test "$development_version" != yes; then
1023   changequote(,)dnl
1024   tmp_pat='[a-zA-Z]'
1025   changequote([,])dnl
1026   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1027     development_version=yes
1028   fi
1029 fi
1030 if test "$development_version" = yes; then
1031     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1032             [Defined if this is not a regular release])
1033 fi
1034
1035 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1036
1037 GNUPG_CHECK_GNUMAKE
1038
1039 # add some extra libs here so that previous tests don't fail for
1040 # mysterious reasons - the final link step should bail out. 
1041 case "${target}" in
1042     *-*-mingw32*)
1043 dnl      NETLIBS="$NETLIBS -lwsock32"
1044         W32LIBS="-lwsock32"
1045         ;;
1046     *)
1047        ;;
1048 esac
1049
1050 AC_SUBST(NETLIBS)
1051 AC_SUBST(W32LIBS)
1052
1053 if test "$GCC" = yes; then
1054     if test "$USE_MAINTAINER_MODE" = "yes"; then
1055         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1056     else
1057         CFLAGS="$CFLAGS -Wall"
1058     fi
1059 fi
1060
1061
1062 if test "$print_egd_warning" = yes; then
1063   AC_MSG_WARN([[
1064 ***
1065 *** The performance of the UNIX random gatherer module is not very good
1066 *** and it does not keep the entropy pool over multiple invocations of
1067 *** GnuPG.  The suggested way to overcome this problem is to use the
1068 ***
1069 ***               Entropy Gathering Daemon (EGD)
1070 ***
1071 *** which provides a entropy source for the whole system.  It is written
1072 *** in Perl and available at the GnuPG FTP servers.  For more information
1073 *** consult the GnuPG webpages:
1074 ***
1075 ***           http://www.gnupg.org/download/#EGD
1076 ***
1077 *** You may want to run ./configure with --enable-static-rnd=egd or
1078 *** --enable-static-rnd=auto to use it.
1079 ***]])
1080 fi
1081
1082 # Note the \\\\ for backslashes.  Autoconf eats one layer, leaving \\
1083
1084 AC_CONFIG_COMMANDS(g10defs.h,[[
1085 cat >g10defs.tmp <<G10EOF
1086 /* Generated automatically by configure */
1087 #ifdef HAVE_DRIVE_LETTERS
1088 #define G10_LOCALEDIR     "c:\\\\lib\\\\gnupg\\\\locale"
1089 #define GNUPG_LIBDIR      "c:\\\\lib\\\\gnupg"
1090 #define GNUPG_LIBEXECDIR  "c:\\\\lib\\\\gnupg"
1091 #define GNUPG_DATADIR     "c:\\\\lib\\\\gnupg"
1092 #define GNUPG_HOMEDIR     "c:\\\\gnupg"
1093 #else
1094 #define G10_LOCALEDIR     "${datadir}/locale"
1095 #define GNUPG_LIBDIR      "${libdir}/gnupg"
1096 #define GNUPG_DATADIR     "${datadir}/gnupg"
1097 #ifdef __VMS
1098 #define GNUPG_HOMEDIR "/SYS\$LOGIN/gnupg" 
1099 #else
1100 #define GNUPG_HOMEDIR "~/.gnupg" 
1101 #endif
1102 #endif
1103 /* those are here to be redefined by handcrafted g10defs.h.
1104    Please note that the string version must not contain more
1105    than one character because the using code assumes strlen()==1 */
1106 #ifdef HAVE_DOSISH_SYSTEM
1107 #define DIRSEP_C '\\\\'
1108 #define EXTSEP_C '.'
1109 #define DIRSEP_S "\\\\"
1110 #define EXTSEP_S "."
1111 #else
1112 #define DIRSEP_C '/'
1113 #define EXTSEP_C '.'
1114 #define DIRSEP_S "/"
1115 #define EXTSEP_S "."
1116 #endif
1117 /* This is the same as VERSION, but should be overridden if the
1118    platform cannot handle things like dots'.' in filenames.  Set
1119    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
1120    uses for dots and dashes. */
1121 #define SAFE_VERSION      VERSION
1122 #define SAFE_VERSION_DOT  '.'
1123 #define SAFE_VERSION_DASH '-'
1124 G10EOF
1125 cat mpi/mpi-asm-defs.h >>g10defs.tmp 
1126 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
1127     echo "g10defs.h is unchanged"
1128     rm -f g10defs.tmp
1129 else
1130     rm -f g10defs.h
1131     mv g10defs.tmp g10defs.h
1132     echo "g10defs.h created"
1133 fi
1134 ]],[[
1135 prefix=$prefix
1136 exec_prefix=$exec_prefix
1137 libdir=$libdir
1138 libexecdir=$libexecdir
1139 datadir=$datadir
1140 DATADIRNAME=$DATADIRNAME
1141 ]])
1142
1143
1144 AC_CONFIG_FILES([
1145 Makefile
1146 m4/Makefile
1147 intl/Makefile
1148 po/Makefile.in
1149 util/Makefile
1150 mpi/Makefile
1151 cipher/Makefile
1152 g10/Makefile
1153 keyserver/Makefile
1154 keyserver/gpgkeys_mailto
1155 keyserver/gpgkeys_test
1156 doc/Makefile
1157 tools/Makefile
1158 zlib/Makefile
1159 checks/Makefile
1160 ])
1161 AC_OUTPUT
1162
1163 # Give some feedback
1164 echo
1165 echo   "                Configured for: $PRINTABLE_OS_NAME ($target)"
1166 if test -n "$show_extraasm"; then
1167   echo "  Extra cpu specific functions:$show_extraasm"
1168 fi
1169 echo