Some work on the dirmngr
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005,
3 #               2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.10"
23
24 # Remember to change the version number immediately *after* a release.
25 # Set my_issvn to "yes" for non-released code.  Remember to run an
26 # "svn up" and "autogen.sh" right before creating a distribution.
27 m4_define([my_version], [2.1.0])
28 m4_define([my_issvn], [yes])
29
30 m4_define([svn_revision], m4_esyscmd([printf "%d" $(svn info 2>/dev/null \
31           | sed -n '/^Revision:/ s/[^0-9]//gp'|head -1)]))
32 m4_define([git_revision], m4_esyscmd([git branch -v 2>/dev/null \
33           | awk '/^\* / {printf "%s",$3}']))
34 AC_INIT([gnupg], 
35         [my_version[]m4_if(my_issvn,[yes],
36         [m4_if(git_revision,[],[-svn[]svn_revision],[-git[]git_revision])])],
37         [http://bugs.gnupg.org])
38 # Set development_version to yes if the minor number is odd or you
39 # feel that the default check for a development version is not
40 # sufficient.
41 development_version=no
42
43 NEED_GPG_ERROR_VERSION=1.8
44
45 NEED_LIBGCRYPT_API=1
46 NEED_LIBGCRYPT_VERSION=1.4.0
47
48 NEED_LIBASSUAN_API=2
49 NEED_LIBASSUAN_VERSION=2.0.0
50
51 NEED_KSBA_API=1
52 NEED_KSBA_VERSION=1.0.2
53
54
55 PACKAGE=$PACKAGE_NAME
56 PACKAGE_GT=${PACKAGE_NAME}2
57 VERSION=$PACKAGE_VERSION
58
59 AC_CONFIG_AUX_DIR(scripts)
60 AC_CONFIG_SRCDIR(sm/gpgsm.c)
61 AM_CONFIG_HEADER(config.h)
62 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
63 AC_CANONICAL_HOST
64 AB_INIT
65
66 AC_GNU_SOURCE
67
68 # Some status variables.
69 have_gpg_error=no
70 have_libgcrypt=no 
71 have_libassuan=no
72 have_ksba=no
73 have_pth=no
74 have_libusb=no
75 have_adns=no
76
77 use_zip=yes
78 use_bzip2=yes
79 use_exec=yes
80 disable_keyserver_path=no
81 use_ccid_driver=yes
82 use_standard_socket=no
83
84 try_ks_ldap=no
85
86 GNUPG_BUILD_PROGRAM(gpg, yes)
87 GNUPG_BUILD_PROGRAM(gpgsm, yes)
88 GNUPG_BUILD_PROGRAM(agent, yes)
89 GNUPG_BUILD_PROGRAM(scdaemon, yes)
90 GNUPG_BUILD_PROGRAM(g13, yes)
91 GNUPG_BUILD_PROGRAM(dirmngr, yes)
92 GNUPG_BUILD_PROGRAM(tools, yes)
93 GNUPG_BUILD_PROGRAM(doc, yes)
94 GNUPG_BUILD_PROGRAM(symcryptrun, no)
95 GNUPG_BUILD_PROGRAM(gpgtar, no)
96
97 AC_SUBST(PACKAGE)
98 AC_SUBST(PACKAGE_GT)
99 AC_SUBST(VERSION)
100 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
101 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
102                                 [Name of this package for gettext])
103 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
104 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
105                                         [Bug report address])
106 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
107                                        [Required version of Libgcrypt])
108 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
109                                        [Required version of Libksba])
110
111
112
113 # The default is to use the modules from this package and the few
114 # other packages in a standard place; i.e where this package gets
115 # installed.  With these options it is possible to override these
116 # ${prefix} depended values with fixed paths, which can't be replaced
117 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
118 AC_ARG_WITH(agent-pgm,
119     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
120           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
121 AC_SUBST(GNUPG_AGENT_PGM)
122 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
123 show_gnupg_agent_pgm="(default)"
124 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
125
126 AC_ARG_WITH(pinentry-pgm,
127     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
128           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
129 AC_SUBST(GNUPG_PINENTRY_PGM)
130 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
131 show_gnupg_pinentry_pgm="(default)"
132 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
133
134
135 AC_ARG_WITH(scdaemon-pgm,
136     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
137           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
138 AC_SUBST(GNUPG_SCDAEMON_PGM)
139 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
140 show_gnupg_scdaemon_pgm="(default)"
141 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
142
143
144 AC_ARG_WITH(dirmngr-pgm,
145     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
146           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
147 AC_SUBST(GNUPG_DIRMNGR_PGM)
148 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
149 show_gnupg_dirmngr_pgm="(default)"
150 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
151
152 AC_ARG_WITH(protect-tool-pgm,
153     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
154           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
155 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
156 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
157 show_gnupg_protect_tool_pgm="(default)"
158 test -n "$GNUPG_PROTECT_TOOL_PGM" \
159       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
160
161 AC_ARG_WITH(dirmngr-ldap-pgm,
162     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmnge ldap wrapper)],
163           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
164 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
165 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
166 show_gnupg_dirmngr_ldap_pgm="(default)"
167 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
168       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
169
170
171 # Some folks want to use only the agent from this packet.  Make it
172 # easier for them by providing the configure option
173 # --enable-only-agent.
174 AC_ARG_ENABLE(agent-only,
175     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
176     build_agent_only=$enableval)
177
178 # SELinux support includes tracking of sensitive files to avoid
179 # leaking their contents through processing these files by gpg itself
180 AC_MSG_CHECKING([whether SELinux support is requested])
181 AC_ARG_ENABLE(selinux-support,
182               AC_HELP_STRING([--enable-selinux-support],
183                              [enable SELinux support]),
184               selinux_support=$enableval, selinux_support=no)
185 AC_MSG_RESULT($selinux_support)
186
187 # Allow disabling of zip support.
188 # This is in general not a good idea because according to rfc4880 OpenPGP
189 # implementations SHOULD support ZLIB.
190 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
191 AC_ARG_ENABLE(zip,
192    AC_HELP_STRING([--disable-zip],
193                   [disable the ZIP and ZLIB compression algorithm]),
194    use_zip=$enableval)
195 AC_MSG_RESULT($use_zip)
196
197 # Allow disabling of bzib2 support.
198 # It is defined only after we confirm the library is available later
199 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
200 AC_ARG_ENABLE(bzip2,
201    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
202    use_bzip2=$enableval)
203 AC_MSG_RESULT($use_bzip2)
204
205 # Configure option to allow or disallow execution of external
206 # programs, like a photo viewer.
207 AC_MSG_CHECKING([whether to enable external program execution])
208 AC_ARG_ENABLE(exec,
209     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
210     use_exec=$enableval)
211 AC_MSG_RESULT($use_exec)
212 if test "$use_exec" = no ; then
213     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
214 fi
215
216 if test "$use_exec" = yes ; then
217   AC_MSG_CHECKING([whether to enable photo ID viewing])
218   AC_ARG_ENABLE(photo-viewers,
219       [  --disable-photo-viewers disable photo ID viewers],
220       [if test "$enableval" = no ; then
221          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
222       fi],enableval=yes)
223   gnupg_cv_enable_photo_viewers=$enableval
224   AC_MSG_RESULT($enableval)
225
226   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
227     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
228     AC_ARG_WITH(photo-viewer,
229         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
230         [if test "$withval" = yes ; then
231            withval=no
232         elif test "$withval" != no ; then
233            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
234                             [if set, restrict photo-viewer to this])
235         fi],withval=no)
236     AC_MSG_RESULT($withval)
237   fi
238
239   AC_MSG_CHECKING([whether to enable external keyserver helpers])
240   AC_ARG_ENABLE(keyserver-helpers,
241       [  --disable-keyserver-helpers  disable all external keyserver support],
242       [if test "$enableval" = no ; then
243          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
244                   [define to disable keyserver helpers])
245       fi],enableval=yes)
246   gnupg_cv_enable_keyserver_helpers=$enableval
247   AC_MSG_RESULT($enableval)
248
249   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
250     # LDAP is defined only after we confirm the library is available later
251     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
252     AC_ARG_ENABLE(ldap,
253       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
254       try_ks_ldap=$enableval, try_ks_ldap=yes)
255     AC_MSG_RESULT($try_ks_ldap)
256
257     AC_MSG_CHECKING([whether HKP keyserver support is requested])
258     AC_ARG_ENABLE(hkp,
259       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
260       try_hkp=$enableval, try_hkp=yes)
261     AC_MSG_RESULT($try_hkp)
262
263     AC_MSG_CHECKING([whether finger key fetching support is requested])
264     AC_ARG_ENABLE(finger,
265       AC_HELP_STRING([--disable-finger],
266         [disable finger key fetching interface only]),
267       try_finger=$enableval, try_finger=yes)
268     AC_MSG_RESULT($try_finger)
269
270     AC_MSG_CHECKING([whether generic object key fetching support is requested])
271     AC_ARG_ENABLE(generic,
272       AC_HELP_STRING([--disable-generic],
273         [disable generic object key fetching interface only]),
274       try_generic=$enableval, try_generic=yes)
275     AC_MSG_RESULT($try_generic)
276
277     AC_MSG_CHECKING([whether email keyserver support is requested])
278     AC_ARG_ENABLE(mailto,
279       AC_HELP_STRING([--enable-mailto],
280         [enable email keyserver interface only]),
281       try_mailto=$enableval, try_mailto=no)
282     AC_MSG_RESULT($try_mailto)
283   fi
284
285   AC_MSG_CHECKING([whether keyserver exec-path is enabled])
286   AC_ARG_ENABLE(keyserver-path,
287       AC_HELP_STRING([--disable-keyserver-path],
288         [disable the exec-path option for keyserver helpers]),
289       [if test "$enableval" = no ; then
290          disable_keyserver_path=yes
291       fi],enableval=yes)
292   AC_MSG_RESULT($enableval)
293 fi
294
295
296 #
297 # Check for the key/uid cache size.  This can't be zero, but can be
298 # pretty small on embedded systems.  This is used for the gpg part.
299 #
300 AC_MSG_CHECKING([for the size of the key and uid cache])
301 AC_ARG_ENABLE(key-cache,
302         AC_HELP_STRING([--enable-key-cache=SIZE],
303                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
304 if test "$enableval" = "no"; then
305    enableval=5
306 elif test "$enableval" = "yes" || test "$enableval" = ""; then
307    enableval=4096
308 fi
309 changequote(,)dnl
310 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
311 changequote([,])dnl
312 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
313    AC_MSG_ERROR([invalid key-cache size])
314 fi
315 AC_MSG_RESULT($key_cache_size)
316 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
317                   [Size of the key and UID caches])
318
319
320
321 #
322 # Check whether we want to use Linux capabilities
323 #
324 AC_MSG_CHECKING([whether use of capabilities is requested])
325 AC_ARG_WITH(capabilities,
326     [  --with-capabilities     use linux capabilities [default=no]],
327 [use_capabilities="$withval"],[use_capabilities=no])
328 AC_MSG_RESULT($use_capabilities)
329
330
331 #
332 # Allow disabling of internal CCID support.
333 # It is defined only after we confirm the library is available later
334 #
335 AC_MSG_CHECKING([whether to enable the internal CCID driver])
336 AC_ARG_ENABLE(ccid-driver,
337               AC_HELP_STRING([--disable-ccid-driver],
338                              [disable the internal CCID driver]),
339               use_ccid_driver=$enableval)
340 AC_MSG_RESULT($use_ccid_driver)
341
342
343 #
344 # To avoid double inclusion of config.h which might happen at some
345 # places, we add the usual double inclusion protection at the top of
346 # config.h.
347 #
348 AH_TOP([
349 #ifndef GNUPG_CONFIG_H_INCLUDED
350 #define GNUPG_CONFIG_H_INCLUDED
351 ])
352
353 #
354 # Stuff which goes at the bottom of config.h.
355 #
356 AH_BOTTOM([
357 /* This is the major version number of GnuPG so that
358    source included files can test for this.  Note, that
359    we use 2 here even for GnuPG 1.9.x. */
360 #define GNUPG_MAJOR_VERSION 2
361
362 /* Now to separate file name parts.
363    Please note that the string version must not contain more
364    than one character because the code assumes strlen()==1 */
365 #ifdef HAVE_DOSISH_SYSTEM
366 #define DIRSEP_C '\\'
367 #define DIRSEP_S "\\"
368 #define EXTSEP_C '.'
369 #define EXTSEP_S "."
370 #define PATHSEP_C ';'
371 #define PATHSEP_S ";"
372 #define EXEEXT_S ".exe"
373 #else
374 #define DIRSEP_C '/'
375 #define DIRSEP_S "/"
376 #define EXTSEP_C '.'
377 #define EXTSEP_S "."
378 #define PATHSEP_C ':'
379 #define PATHSEP_S ":"
380 #define EXEEXT_S ""
381 #endif
382
383 /* This is the same as VERSION, but should be overridden if the
384    platform cannot handle things like dots '.' in filenames. Set
385    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
386    uses for dots and dashes. */
387 #define SAFE_VERSION VERSION
388 #define SAFE_VERSION_DOT  '.'
389 #define SAFE_VERSION_DASH '-'
390
391 /* Some global constants. */
392 #ifdef HAVE_DOSISH_SYSTEM
393 # ifdef HAVE_DRIVE_LETTERS
394 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
395 # else
396 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
397 # endif
398 #elif defined(__VMS)
399 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg" 
400 #else
401 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
402 #endif 
403 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
404
405 /* For some systems (DOS currently), we hardcode the path here.  For
406    POSIX systems the values are constructed by the Makefiles, so that
407    the values may be overridden by the make invocations; this is to
408    comply with the GNU coding standards.  Note that these values are
409    only defaults.  */
410 #ifdef HAVE_DOSISH_SYSTEM
411 # ifdef HAVE_DRIVE_LETTERS
412 #  define GNUPG_BINDIR      "c:\\gnupg"
413 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
414 #  define GNUPG_LIBDIR      "c:\\gnupg"
415 #  define GNUPG_DATADIR     "c:\\gnupg"
416 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
417 # else
418 #  define GNUPG_BINDIR      "\\gnupg"
419 #  define GNUPG_LIBEXECDIR  "\\gnupg"
420 #  define GNUPG_LIBDIR      "\\gnupg"
421 #  define GNUPG_DATADIR     "\\gnupg"
422 #  define GNUPG_SYSCONFDIR  "\\gnupg"
423 # endif
424 #endif
425
426 /* Derive some other constants. */
427 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
428 #define EXEC_TEMPFILE_ONLY
429 #endif
430
431
432 /* We didn't define endianness above, so get it from OS macros.  This
433    is intended for making fat binary builds on OS X. */
434 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
435 #if defined(__BIG_ENDIAN__)
436 #define BIG_ENDIAN_HOST 1
437 #elif defined(__LITTLE_ENDIAN__)
438 #define LITTLE_ENDIAN_HOST 1
439 #else
440 #error "No endianness found"
441 #endif
442 #endif
443
444
445 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
446    ldap_start_tls_s because that is the actual symbol used in the
447    library.  winldap.h redefines it to our commonly used value,
448    thus we define our usual macro here.  */
449 #ifdef HAVE_LDAP_START_TLS_SA
450 # ifndef HAVE_LDAP_START_TLS_S
451 #  define HAVE_LDAP_START_TLS_S 1
452 # endif
453 #endif
454
455
456 /* Tell libgcrypt not to use its own libgpg-error implementation. */
457 #define USE_LIBGPG_ERROR 1
458
459 /* We use jnlib, so tell other modules about it.  */
460 #define HAVE_JNLIB_LOGGING 1
461
462 /* Our HTTP code is used in estream mode.  */
463 #define HTTP_USE_ESTREAM 1
464
465 /* Under W32 we do an explicit socket initialization, thus we need to
466    avoid the on-demand initialization which would also install an atexit
467    handler.  */
468 #define HTTP_NO_WSASTARTUP
469
470 /* We always include support for the OpenPGP card.  */
471 /* Disabled for now ENABLE_CARD_SUPPORT 1 */
472
473 /* We explicitly need to disable PTH's soft mapping as Debian
474    currently enables it by default for no reason. */
475 #define PTH_SYSCALL_SOFT 0
476
477 /* We want to use the libgcrypt provided memory allocation for
478    asprintf.  */
479 #define _ESTREAM_PRINTF_MALLOC        gcry_malloc
480 #define _ESTREAM_PRINTF_FREE          gcry_free
481 #define _ESTREAM_PRINTF_EXTRA_INCLUDE "../common/util.h"
482
483 /* Under Windows we use the gettext code from libgpg-error.  */
484 #define GPG_ERR_ENABLE_GETTEXT_MACROS
485
486 #endif /*GNUPG_CONFIG_H_INCLUDED*/
487 ])
488
489
490 AM_MAINTAINER_MODE
491
492 # Checks for programs.
493 AC_MSG_NOTICE([checking for programs])
494 AC_PROG_MAKE_SET
495 AM_SANITY_CHECK
496 missing_dir=`cd $ac_aux_dir && pwd`
497 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
498 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
499 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
500 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
501 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
502 AC_PROG_AWK
503 AC_PROG_CC
504 AC_PROG_CPP
505 AM_PROG_CC_C_O
506 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
507   AC_MSG_ERROR([[No C-89 compiler found]])
508 fi
509 AC_PROG_INSTALL
510 AC_PROG_LN_S
511 AC_PROG_RANLIB
512 AC_CHECK_TOOL(AR, ar, :)
513 AC_PATH_PROG(PERL,"perl")
514 AC_CHECK_TOOL(WINDRES, windres, :)
515 AC_ISC_POSIX
516 gl_EARLY
517 AC_SYS_LARGEFILE
518 GNUPG_CHECK_FAQPROG
519 GNUPG_CHECK_USTAR
520
521 # We need to compile and run a program on the build machine.  A
522 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
523 # the AC archive is broken for autoconf 2.57.  Given that there is no
524 # newer version of that macro, we assume that it is also broken for
525 # autoconf 2.61 and thus we use a simple but usually sufficient
526 # approach.
527 AC_MSG_CHECKING(for cc for build)
528 if test "$cross_compiling" = "yes"; then
529   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
530 else
531   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
532 fi
533 AC_MSG_RESULT($CC_FOR_BUILD)
534 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
535
536
537
538 try_gettext=yes
539 have_dosish_system=no
540 have_w32_system=no
541 have_w32ce_system=no
542 use_simple_gettext=no
543 use_ldapwrapper=yes
544 mmap_needed=yes
545 case "${host}" in
546     *-mingw32*)
547         # special stuff for Windoze NT
548         ac_cv_have_dev_random=no
549         AC_DEFINE(USE_ONLY_8DOT3,1,
550                   [Set this to limit filenames to the 8.3 format])
551         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
552                   [Because the Unix gettext has too much overhead on
553                    MingW32 systems and these systems lack Posix functions,
554                    we use a simplified version of gettext])
555         disable_keyserver_path=yes
556         have_dosish_system=yes
557         have_w32_system=yes
558         use_ldapwrapper=no  # Fixme: Do this only for CE.
559         case "${host}" in 
560           *-mingw32ce*)
561             have_w32ce_system=yes
562             ;;
563           *)
564             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
565                       [Defined if the OS supports drive letters.])
566             ;;
567         esac
568         try_gettext="no"
569         use_simple_gettext=yes
570         mmap_needed=no
571         ;;
572     i?86-emx-os2 | i?86-*-os2*emx )
573         # OS/2 with the EMX environment
574         ac_cv_have_dev_random=no
575         AC_DEFINE(HAVE_DRIVE_LETTERS)
576         have_dosish_system=yes
577         try_gettext="no"
578         ;;
579
580     i?86-*-msdosdjgpp*)
581         # DOS with the DJGPP environment
582         ac_cv_have_dev_random=no
583         AC_DEFINE(HAVE_DRIVE_LETTERS)
584         have_dosish_system=yes
585         try_gettext="no"
586         ;;
587
588     *-*-freebsd*)
589        # FreeBSD
590        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
591        LDFLAGS="$LDFLAGS -L/usr/local/lib"
592        ;;
593
594     *-*-hpux*)
595         if test -z "$GCC" ; then
596             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
597         fi
598         ;;
599     *-dec-osf4*)
600         if test -z "$GCC" ; then
601             # Suppress all warnings
602             # to get rid of the unsigned/signed char mismatch warnings.
603             CFLAGS="$CFLAGS -w"
604         fi
605         ;;
606     *-dec-osf5*)
607         if test -z "$GCC" ; then
608             # Use the newer compiler `-msg_disable ptrmismatch1' to
609             # get rid of the unsigned/signed char mismatch warnings.
610             # Using this may hide other pointer mismatch warnings, but
611             # it at least lets other warning classes through
612             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
613         fi
614         ;;
615     m68k-atari-mint)
616         ;;
617     *)
618        ;;
619 esac
620
621 if test "$have_dosish_system" = yes; then
622    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
623              [Defined if we run on some of the PCDOS like systems 
624               (DOS, Windoze. OS/2) with special properties like
625               no file modes, case insensitive file names and preferred
626               use of backslashes as directory name separators.])
627 fi
628 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
629
630 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
631
632 if test "$have_w32_system" = yes; then
633    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
634    if test "$have_w32ce_system" = yes; then
635       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
636    fi
637 fi
638 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
639 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
640
641 if test "$use_ldapwrapper" = yes; then
642    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
643 fi
644 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
645
646 if test "$disable_keyserver_path" = yes; then
647     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
648               [Defined to disable exec-path for keyserver helpers])
649 fi
650
651 #
652 # Allows enabling the use of a standard socket by default This is
653 # gpg-agent's option --[no-]use-standard-socket.  For Windows we force
654 # the use of this.
655 #
656 AC_MSG_CHECKING([whether to use a standard socket by default])
657 AC_ARG_ENABLE(standard-socket,
658               AC_HELP_STRING([--enable-standard-socket],
659                              [use a standard socket for the agent by default]),
660               use_standard_socket=$enableval)
661 tmp=""
662 if test "$use_standard_socket" != yes; then
663   if test "$have_w32_system" = yes; then
664     use_standard_socket=yes
665     tmp=" (forced)"
666   fi
667 fi
668 AC_MSG_RESULT($use_standard_socket$tmp)
669 if test "$use_standard_socket" = yes; then
670   AC_DEFINE(USE_STANDARD_SOCKET,1,
671             [Use the standard socket for the agent by default])
672 fi
673
674
675 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
676 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
677
678 if test x"$try_hkp" = xyes ; then
679   AC_SUBST(GPGKEYS_HKP,"gpg2keys_hkp$EXEEXT")
680 fi
681
682 if test x"$try_finger" = xyes ; then
683   AC_SUBST(GPGKEYS_FINGER,"gpg2keys_finger$EXEEXT")
684 fi
685
686
687
688 #
689 # Checks for libraries.
690 #
691 AC_MSG_NOTICE([checking for libraries])
692
693
694 #
695 # libgpg-error is a library with error codes shared between GnuPG
696 # related projects.
697 #
698 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
699                   have_gpg_error=yes,have_gpg_error=no)
700
701
702 #
703 # Libgcrypt is our generic crypto library
704 #
705 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
706         have_libgcrypt=yes,have_libgcrypt=no)
707
708
709 #
710 # libassuan is used for IPC
711 #
712 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
713                   have_libassuan=yes,have_libassuan=no)
714 if test "$have_libassuan" = "yes"; then
715   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
716                      [version of the libassuan library])
717 fi
718
719
720
721 #
722 # libksba is our X.509 support library
723 #
724 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
725
726
727 #
728 # libusb allows us to use the integrated CCID smartcard reader driver.
729 #
730 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
731 if test "$use_ccid_driver" = yes ; then
732   AC_CHECK_LIB(usb, usb_bulk_write,
733                 [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
734                   AC_DEFINE(HAVE_LIBUSB,1,
735                            [defined if libusb is available])
736                   have_libusb=yes
737                ])
738   AC_CHECK_FUNCS(usb_create_match)
739 fi
740 AC_SUBST(LIBUSB_LIBS)
741
742 #
743 # Check wether it is necessary to link against libdl.
744 #
745 gnupg_dlopen_save_libs="$LIBS"
746 LIBS=""
747 AC_SEARCH_LIBS(dlopen, c dl,,,)
748 DL_LIBS=$LIBS
749 AC_SUBST(DL_LIBS)
750 LIBS="$gnupg_dlopen_save_libs"
751
752 # Checks for g13
753
754 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
755 AC_DEFINE_UNQUOTED(ENCFS,
756         "${ENCFS}", [defines the filename of the encfs program])
757
758 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
759 AC_DEFINE_UNQUOTED(FUSERMOUNT,
760         "${FUSERMOUNT}", [defines the filename of the fusermount program])
761
762
763 # Checks for dirmngr
764
765
766 #
767 # Checks for symcryptrun:
768 #
769
770 # libutil has openpty() and login_tty().
771 AC_CHECK_LIB(util, openpty,
772               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
773                 AC_DEFINE(HAVE_LIBUTIL,1,
774                          [defined if libutil is available])
775              ])
776 AC_SUBST(LIBUTIL_LIBS)
777
778 # shred is used to clean temporary plain text files.
779 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
780 AC_DEFINE_UNQUOTED(SHRED,
781         "${SHRED}", [defines the filename of the shred program])
782
783
784 #
785 # Check whether the GNU Pth library is available
786 # Note, that we include a Pth emulation for W32.
787 #
788 GNUPG_PATH_PTH
789 if test "$have_pth" = "yes"; then
790   AC_DEFINE(USE_GNU_PTH, 1,
791               [Defined if the GNU Portable Thread Library should be used])
792 else
793   AC_MSG_WARN([[
794 ***
795 *** To support concurrent access to the gpg-agent and the SCdaemon
796 *** we need the support of the GNU Portable Threads Library.
797 *** Download it from ftp://ftp.gnu.org/gnu/pth/
798 *** On a Debian GNU/Linux system you might want to try 
799 ***   apt-get install libpth-dev
800 ***]])
801 fi
802
803
804 AC_MSG_NOTICE([checking for networking options])
805
806 #
807 # Must check for network library requirements before doing link tests
808 # for ldap, for example. If ldap libs are static (or dynamic and without
809 # ELF runtime link paths), then link will fail and LDAP support won't
810 # be detected.
811 #
812 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
813         [NETLIBS="-lnsl $NETLIBS"]))
814 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
815         [NETLIBS="-lsocket $NETLIBS"]))
816
817
818 #
819 # Check for ADNS.
820 #
821 _cppflags="${CPPFLAGS}"
822 _ldflags="${LDFLAGS}"
823 AC_ARG_WITH(adns,
824             AC_HELP_STRING([--with-adns=DIR],
825                            [look for the adns library in DIR]),
826             [if test -d "$withval"; then
827                CPPFLAGS="${CPPFLAGS} -I$withval/include"
828                LDFLAGS="${LDFLAGS} -L$withval/lib"
829              fi])
830 if test "$with_adns" != "no"; then
831   AC_CHECK_HEADERS(adns.h,
832                 AC_CHECK_LIB(adns, adns_init,
833                              [have_adns=yes],
834                              [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}]),
835                 [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}])
836 fi
837 if test "$have_adns" = "yes"; then
838   ADNSLIBS="-ladns" 
839 fi
840 AC_SUBST(ADNSLIBS)
841 # Newer adns versions feature a free function to be used under W32.
842 AC_CHECK_FUNCS(adns_free)
843
844
845
846 #
847 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
848 #
849 if test x"$try_hkp" = xyes || test x"$try_http" = xyes ; then
850   AC_ARG_ENABLE(dns-srv,
851      AC_HELP_STRING([--disable-dns-srv],
852                     [disable the use of DNS SRV in HKP and HTTP]),
853                 use_dns_srv=$enableval,use_dns_srv=yes)
854 fi
855
856 AC_ARG_ENABLE(dns-pka,
857    AC_HELP_STRING([--disable-dns-pka],
858         [disable the use of PKA records in DNS]),
859    use_dns_pka=$enableval,use_dns_pka=yes)
860
861 AC_ARG_ENABLE(dns-cert,
862    AC_HELP_STRING([--disable-dns-cert],
863         [disable the use of CERT records in DNS]),
864    use_dns_cert=$enableval,use_dns_cert=yes)
865
866 if test x"$use_dns_pka" = xyes || test x"$use_dns_srv" = xyes \
867    || test x"$use_dns_cert" = xyes; then
868   _dns_save_libs=$LIBS
869   LIBS=""
870   # the double underscore thing is a glibc-ism?
871   AC_SEARCH_LIBS(res_query,resolv bind,,
872                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
873   AC_SEARCH_LIBS(dn_expand,resolv bind,,
874                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
875   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
876                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
877
878   if test x"$have_resolver" != xno ; then
879
880     # Make sure that the BIND 4 resolver interface is workable before
881     # enabling any code that calls it.  At some point I'll rewrite the
882     # code to use the BIND 8 resolver API.
883     # We might also want to use adns instead.  Problem with ADNS is that
884     # it does not support v6.
885
886     AC_MSG_CHECKING([whether the resolver is usable])
887     AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
888 #include <netinet/in.h>
889 #include <arpa/nameser.h>
890 #include <resolv.h>],
891 [[unsigned char answer[PACKETSZ];
892   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
893   dn_skipname(0,0); 
894   dn_expand(0,0,0,0,0);
895 ]])],have_resolver=yes,have_resolver=no)
896     AC_MSG_RESULT($have_resolver)
897
898     # This is Apple-specific and somewhat bizarre as they changed the
899     # define in bind 8 for some reason.
900
901     if test x"$have_resolver" != xyes ; then
902        AC_MSG_CHECKING(
903              [whether I can make the resolver usable with BIND_8_COMPAT])
904        AC_LINK_IFELSE([AC_LANG_PROGRAM([#define BIND_8_COMPAT
905 #include <sys/types.h>
906 #include <netinet/in.h>
907 #include <arpa/nameser.h>
908 #include <resolv.h>],
909 [[unsigned char answer[PACKETSZ];
910   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
911   dn_skipname(0,0); dn_expand(0,0,0,0,0);
912 ]])],[have_resolver=yes ; need_compat=yes])
913        AC_MSG_RESULT($have_resolver)
914     fi
915   fi
916
917   if test x"$have_resolver" = xyes ; then
918      DNSLIBS=$LIBS
919
920      if test x"$use_dns_srv" = xyes ; then
921         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
922      fi
923
924      if test x"$use_dns_pka" = xyes ; then
925         AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
926      fi
927
928      if test x"$use_dns_cert" = xyes ; then
929         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
930      fi
931
932      if test x"$need_compat" = xyes ; then
933         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
934      fi
935   else
936      # If we have no resolver library but ADNS (e.g. under W32) enable the
937      # code parts which can be used with ADNS.
938      if test x"$have_adns" = xyes ; then
939         DNSLIBS="$ADNSLIBS"
940         AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
941
942         if test x"$use_dns_srv" = xyes ; then
943            AC_DEFINE(USE_DNS_SRV,1)
944         fi
945
946         if test x"$use_dns_pka" = xyes ; then
947            AC_DEFINE(USE_DNS_PKA,1)
948         fi
949
950         if test x"$use_dns_cert" = xyes ; then
951            AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
952         fi
953      else
954         use_dns_srv=no
955         use_dns_pka=no
956         use_dns_cert=no
957      fi
958   fi
959
960   LIBS=$_dns_save_libs
961 fi
962
963 AC_SUBST(DNSLIBS)
964
965 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
966
967
968 #
969 # Check for LDAP
970 #
971 if test "$try_ks_ldap" = yes || test "$build_dirmngr" = "yes" ; then
972    GNUPG_CHECK_LDAP($NETLIBS)
973 fi
974
975 #
976 # Check for curl.  We fake the curl API if libcurl isn't installed.
977 # We require 7.10 or later as we use curl_version_info().
978 #
979 LIBCURL_CHECK_CONFIG([yes],[7.10],,[fake_curl=yes])
980 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
981
982 # Generic, for us, means curl
983
984 if test x"$try_generic" = xyes ; then
985    AC_SUBST(GPGKEYS_CURL,"gpg2keys_curl$EXEEXT")
986 fi
987
988 #
989 # Check for sendmail
990 #
991 # This isn't necessarily sendmail itself, but anything that gives a
992 # sendmail-ish interface to the outside world.  That includes Exim,
993 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
994 if test "$try_mailto" = yes ; then
995   AC_ARG_WITH(mailprog,
996       AC_HELP_STRING([--with-mailprog=NAME],
997                      [use "NAME -t" for mail transport]),
998              ,with_mailprog=yes)
999
1000   if test x"$with_mailprog" = xyes ; then
1001     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1002     if test "$ac_cv_path_SENDMAIL" ; then
1003       GPGKEYS_MAILTO="gpg2keys_mailto"
1004     fi
1005   elif test x"$with_mailprog" != xno ; then
1006     AC_MSG_CHECKING([for a mail transport program])
1007     AC_SUBST(SENDMAIL,$with_mailprog)
1008     AC_MSG_RESULT($with_mailprog)
1009     GPGKEYS_MAILTO="gpg2keys_mailto"
1010   fi
1011 fi
1012
1013 AC_SUBST(GPGKEYS_MAILTO)
1014
1015 #
1016 # Construct a printable name of the OS
1017 #
1018 case "${host}" in
1019     *-mingw32ce*)
1020         PRINTABLE_OS_NAME="W32CE"
1021         ;;
1022     *-mingw32*)
1023         PRINTABLE_OS_NAME="MingW32"
1024         ;;
1025     *-*-cygwin*)
1026         PRINTABLE_OS_NAME="Cygwin"
1027         ;;
1028     i?86-emx-os2 | i?86-*-os2*emx )
1029         PRINTABLE_OS_NAME="OS/2"
1030         ;;
1031     i?86-*-msdosdjgpp*)
1032         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1033         try_dynload=no
1034         ;;
1035     *-linux*)
1036         PRINTABLE_OS_NAME="GNU/Linux"
1037         ;;
1038     *)
1039         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1040         ;;
1041 esac
1042 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1043                    [A human readable text with the name of the OS])
1044
1045
1046 #
1047 # Checking for iconv
1048 #
1049 AM_ICONV
1050
1051
1052 #
1053 # Check for gettext
1054 #
1055 # This is "GNU gnupg" - The project-id script from gettext
1056 #                       needs this string
1057 #
1058 AC_MSG_NOTICE([checking for gettext])
1059 AM_PO_SUBDIRS
1060 AM_GNU_GETTEXT_VERSION([0.17])
1061 if test "$try_gettext" = yes; then
1062   AM_GNU_GETTEXT([external],[need-ngettext])
1063
1064   # gettext requires some extra checks.  These really should be part of
1065   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1066   # function checks to here.
1067
1068   AC_CHECK_FUNCS(strchr)
1069 else
1070   USE_NLS=no
1071   USE_INCLUDED_LIBINTL=no
1072   BUILD_INCLUDED_LIBINTL=no
1073   POSUB=po
1074   AC_SUBST(USE_NLS)
1075   AC_SUBST(USE_INCLUDED_LIBINTL)
1076   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1077   AC_SUBST(POSUB)
1078 fi
1079
1080 # We use HAVE_LANGINFO_CODESET in a couple of places.
1081 AM_LANGINFO_CODESET
1082
1083 # Checks required for our use locales
1084 gt_LC_MESSAGES
1085
1086
1087 #
1088 # SELinux support
1089 #
1090 if test "$selinux_support" = yes ; then
1091   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1092 fi
1093
1094
1095 #
1096 # Checks for header files.
1097 #
1098 AC_MSG_NOTICE([checking for header files])
1099 AC_HEADER_STDC
1100 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1101                   pty.h pwd.h inttypes.h signal.h])
1102 AC_HEADER_TIME
1103
1104
1105 #
1106 # Checks for typedefs, structures, and compiler characteristics.
1107 #
1108 AC_MSG_NOTICE([checking for system characteristics])
1109 AC_C_CONST
1110 AC_C_INLINE
1111 AC_C_VOLATILE
1112 AC_TYPE_SIZE_T
1113 AC_TYPE_MODE_T
1114 AC_TYPE_SIGNAL
1115 AC_DECL_SYS_SIGLIST
1116
1117 gl_HEADER_SYS_SOCKET
1118 gl_TYPE_SOCKLEN_T
1119
1120 AC_ARG_ENABLE(endian-check,
1121               AC_HELP_STRING([--disable-endian-check],
1122               [disable the endian check and trust the OS provided macros]),
1123               endiancheck=$enableval,endiancheck=yes)
1124
1125 if test x"$endiancheck" = xyes ; then
1126   GNUPG_CHECK_ENDIAN
1127 fi
1128
1129 # fixme: we should get rid of the byte type
1130 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1131 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1132 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1133 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1134 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1135
1136 AC_CHECK_SIZEOF(unsigned short)
1137 AC_CHECK_SIZEOF(unsigned int)
1138 AC_CHECK_SIZEOF(unsigned long)
1139 AC_CHECK_SIZEOF(unsigned long long)
1140 AC_CHECK_SIZEOF(time_t,,[[
1141 #include <stdio.h>
1142 #if TIME_WITH_SYS_TIME
1143 # include <sys/time.h>
1144 # include <time.h>
1145 #else
1146 # if HAVE_SYS_TIME_H
1147 #  include <sys/time.h>
1148 # else
1149 #  include <time.h>
1150 # endif
1151 #endif
1152 ]])
1153
1154
1155 # Ensure that we have UINT64_C before we bother to check for uint64_t
1156 # Fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
1157 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
1158    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
1159        uint64_t foo=UINT64_C(42);]),
1160      gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
1161 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
1162    AC_CHECK_SIZEOF(uint64_t)
1163 fi
1164
1165 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1166    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1167    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1168     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1169 fi
1170
1171
1172 #
1173 # Checks for library functions.
1174 #
1175 AC_MSG_NOTICE([checking for library functions])
1176 AC_CHECK_DECLS(getpagesize)
1177 AC_FUNC_FSEEKO
1178 AC_FUNC_VPRINTF
1179 AC_FUNC_FORK
1180 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1181 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1182 AC_CHECK_FUNCS([unsetenv fcntl ftruncate canonicalize_file_name])
1183 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1184 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1185 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1186 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1187
1188 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1189
1190 # Dirmngr requires mmap on Unix systems.
1191 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1192   AC_MSG_ERROR([[Sorry, the current implemenation requires mmap.]])
1193 fi
1194
1195 #
1196 # These are needed by the jnlib parts in common.
1197 # Note:  We already checked pwd.h.
1198 AC_CHECK_HEADERS([signal.h])
1199 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1200                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1201                 flockfile funlockfile fopencookie funopen getpwnam getpwuid \
1202                 getenv ])
1203 # end jnlib checks.
1204
1205
1206
1207 #
1208 # gnulib checks
1209 #
1210 gl_SOURCE_BASE([gl])
1211 gl_M4_BASE([gl/m4])
1212 gl_MODULES([setenv mkdtemp xsize strpbrk])
1213 gl_INIT
1214
1215
1216 #
1217 # W32 specific test
1218 #
1219 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1220
1221 #
1222 # Sanity check regex.  Tests adapted from mutt.
1223 #
1224 AC_MSG_CHECKING([whether regular expression support is requested])
1225 AC_ARG_ENABLE(regex,
1226   AC_HELP_STRING([--disable-regex],
1227     [do not handle regular expressions in trust signatures]),
1228   use_regex=$enableval, use_regex=yes)
1229 AC_MSG_RESULT($use_regex)
1230
1231 if test "$use_regex" = yes ; then
1232   _cppflags="${CPPFLAGS}"
1233   _ldflags="${LDFLAGS}"
1234   AC_ARG_WITH(regex,
1235      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1236       [
1237       if test -d "$withval" ; then
1238         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1239         LDFLAGS="${LDFLAGS} -L$withval/lib"
1240       fi
1241       ],withval="")     
1242
1243   # Does the system have regex functions at all?
1244   AC_SEARCH_LIBS([regcomp], [regex])
1245   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1246
1247   if test $gnupg_cv_have_regex = no; then
1248     use_regex=no
1249   else
1250     if test x"$cross_compiling" = xyes; then
1251       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1252     else
1253       AC_CACHE_CHECK([whether your system's regexp library is broken],
1254        [gnupg_cv_regex_broken],
1255        AC_TRY_RUN([
1256 #include <unistd.h>
1257 #include <regex.h>
1258 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1259        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1260
1261       if test $gnupg_cv_regex_broken = yes; then
1262         AC_MSG_WARN([your regex is broken - disabling regex use])
1263         use_regex=no
1264       fi
1265     fi
1266   fi
1267   CPPFLAGS="${_cppflags}"
1268   LDFLAGS="${_ldflags}"
1269 fi
1270
1271 if test "$use_regex" != yes ; then
1272   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1273 fi
1274 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1275
1276
1277
1278 #
1279 # Do we have zlib? Must do it here because Solaris failed
1280 # when compiling a conftest (due to the "-lz" from LIBS).
1281 # Note that we combine zlib and bzlib2 in ZLIBS.
1282 #
1283 if test "$use_zip" = yes ; then
1284   _cppflags="${CPPFLAGS}"
1285   _ldflags="${LDFLAGS}"
1286   AC_ARG_WITH(zlib,
1287     [  --with-zlib=DIR         use libz in DIR],[
1288       if test -d "$withval"; then
1289         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1290         LDFLAGS="${LDFLAGS} -L$withval/lib"
1291       fi
1292     ])
1293   
1294   AC_CHECK_HEADER(zlib.h,
1295         AC_CHECK_LIB(z, deflateInit2_,
1296          ZLIBS="-lz",
1297          CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1298          CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1299          
1300   AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1301 fi
1302
1303
1304 #
1305 # Check whether we can support bzip2
1306
1307 if test "$use_bzip2" = yes ; then
1308   _cppflags="${CPPFLAGS}"
1309   _ldflags="${LDFLAGS}"
1310   AC_ARG_WITH(bzip2,
1311      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1312       [
1313       if test -d "$withval" ; then
1314         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1315         LDFLAGS="${LDFLAGS} -L$withval/lib"
1316       fi
1317       ],withval="")
1318
1319   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1320   # required stdio.h to be included before bzlib.h, and Solaris 9 is 
1321   # woefully out of date.
1322   if test "$withval" != no ; then
1323      AC_CHECK_HEADER(bzlib.h,
1324         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1325           [
1326           have_bz2=yes
1327           ZLIBS="$ZLIBS -lbz2"
1328           AC_DEFINE(HAVE_BZIP2,1,
1329                   [Defined if the bz2 compression library is available])
1330           ],
1331           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1332           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1333   fi
1334 fi
1335 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1336 AC_SUBST(ZLIBS)
1337
1338
1339 # Check for readline support
1340 GNUPG_CHECK_READLINE
1341
1342 #
1343 # Allow users to append something to the version string without
1344 # flagging it as development version.  The user version parts is
1345 # considered everything after a dash. 
1346 #
1347 if test "$development_version" != yes; then
1348   changequote(,)dnl
1349   tmp_pat='[a-zA-Z]'
1350   changequote([,])dnl
1351   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1352     development_version=yes
1353   fi
1354 fi
1355 if test "$development_version" = yes; then
1356     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1357             [Defined if this is not a regular release])
1358 fi
1359
1360 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1361
1362 GNUPG_CHECK_GNUMAKE
1363
1364 # Add some extra libs here so that previous tests don't fail for
1365 # mysterious reasons - the final link step should bail out.
1366 # W32SOCKLIBS is also defined so that if can be used for tools not
1367 # requiring any network stuff but linking to code in libcommon which
1368 # tracks in winsock stuff (e.g. init_common_subsystems).
1369 if test "$have_w32_system" = yes; then
1370    if test "$have_w32ce_system" = yes; then
1371      W32SOCKLIBS="-lws2"
1372    else
1373      W32SOCKLIBS="-lws2_32"
1374    fi
1375    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1376 fi
1377
1378 AC_SUBST(NETLIBS)
1379 AC_SUBST(W32SOCKLIBS)
1380
1381 #
1382 # Setup gcc specific options
1383 #
1384 AC_MSG_NOTICE([checking for cc features])
1385 if test "$GCC" = yes; then
1386     # Note that it is okay to use CFLAGS here because this are just
1387     # warning options and the user should have a chance of overriding
1388     # them.
1389     if test "$USE_MAINTAINER_MODE" = "yes"; then
1390         CFLAGS="$CFLAGS -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1391         CFLAGS="$CFLAGS -Wformat -Wno-format-y2k -Wformat-security"
1392         AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1393         _gcc_cflags_save=$CFLAGS
1394         CFLAGS="-Wno-missing-field-initializers"
1395         AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_wopt=yes,_gcc_wopt=no)
1396         AC_MSG_RESULT($_gcc_wopt)
1397         CFLAGS=$_gcc_cflags_save;
1398         if test x"$_gcc_wopt" = xyes ; then
1399           CFLAGS="$CFLAGS -W -Wno-sign-compare -Wno-missing-field-initializers"
1400         fi
1401         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1402         _gcc_cflags_save=$CFLAGS
1403         CFLAGS="-Wdeclaration-after-statement"
1404         AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_wopt=yes,_gcc_wopt=no)
1405         AC_MSG_RESULT($_gcc_wopt)
1406         CFLAGS=$_gcc_cflags_save;
1407         if test x"$_gcc_wopt" = xyes ; then
1408           CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1409         fi
1410     else
1411         CFLAGS="$CFLAGS -Wall"
1412     fi
1413
1414     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1415     _gcc_cflags_save=$CFLAGS
1416     CFLAGS="-Wno-pointer-sign"
1417     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1418     AC_MSG_RESULT($_gcc_psign)
1419     CFLAGS=$_gcc_cflags_save;
1420     if test x"$_gcc_psign" = xyes ; then
1421        CFLAGS="$CFLAGS -Wno-pointer-sign"
1422     fi
1423
1424     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1425     _gcc_cflags_save=$CFLAGS
1426     CFLAGS="-Wpointer-arith"
1427     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1428     AC_MSG_RESULT($_gcc_psign)
1429     CFLAGS=$_gcc_cflags_save;
1430     if test x"$_gcc_psign" = xyes ; then
1431        CFLAGS="$CFLAGS -Wpointer-arith"
1432     fi
1433 fi
1434
1435
1436 #
1437 # This is handy for debugging so the compiler doesn't rearrange
1438 # things and eliminate variables.
1439 #
1440 AC_ARG_ENABLE(optimization,
1441    AC_HELP_STRING([--disable-optimization],
1442                   [disable compiler optimization]),
1443                   [if test $enableval = no ; then
1444                       CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]]//'`
1445                    fi])
1446
1447 #
1448 # Prepare building of estream
1449 #
1450 estream_INIT
1451
1452
1453 #
1454 # Decide what to build
1455 #
1456 if test "$have_adns" = "yes"; then
1457   AC_SUBST(GPGKEYS_KDNS, "gpg2keys_kdns$EXEEXT")
1458 fi
1459
1460
1461 missing_pth=no
1462 if test $have_ksba = no; then
1463   build_gpgsm=no
1464   build_scdaemon=no
1465 fi
1466
1467 build_agent_threaded=""
1468 if test "$build_agent" = "yes"; then
1469   if test $have_pth = no; then
1470      build_agent_threaded="(not multi-threaded)"
1471      missing_pth=yes
1472   fi
1473 fi
1474
1475 build_scdaemon_extra=""
1476 if test "$build_scdaemon" = "yes"; then
1477   tmp=""
1478   if test $have_pth = no; then
1479      build_scdaemon_extra="not multi-threaded"
1480      tmp=", "
1481      missing_pth=yes
1482   fi
1483   if test $have_libusb = no; then
1484      build_scdaemon_extra="${tmp}without internal CCID driver"
1485      tmp=", "
1486   fi
1487   if test -n "$build_scdaemon_extra"; then
1488      build_scdaemon_extra="(${build_scdaemon_extra})"
1489   fi
1490 fi
1491
1492
1493 if test "$build_agent_only" = "yes" ; then
1494   build_gpg=no
1495   build_gpgsm=no
1496   build_scdaemon=no
1497   build_tools=no
1498   build_doc=no
1499 fi
1500
1501
1502 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1503 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1504 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1505 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1506 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1507 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1508 AM_CONDITIONAL(BUILD_TOOLS,       test "$build_tools" = "yes")
1509 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1510 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1511 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1512
1513 AM_CONDITIONAL(RUN_GPG_TESTS,
1514                test x$cross_compiling = xno -a "$build_gpg" = yes )
1515
1516
1517 #
1518 # Print errors here so that they are visible all
1519 # together and the user can acquire them all together.
1520 #
1521 die=no
1522 if test "$have_gpg_error" = "no"; then
1523    die=yes
1524    AC_MSG_NOTICE([[
1525 ***  
1526 *** You need libgpg-error to build this program.
1527 **  This library is for example available at
1528 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1529 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1530 ***]])
1531 fi
1532 if test "$have_libgcrypt" = "no"; then
1533    die=yes
1534    AC_MSG_NOTICE([[
1535 ***  
1536 *** You need libgcrypt to build this program.
1537 **  This library is for example available at
1538 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1539 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API is required.)
1540 ***]])
1541 fi
1542 if test "$have_libassuan" = "no"; then
1543    die=yes
1544    AC_MSG_NOTICE([[
1545 ***
1546 *** You need libassuan to build this program.
1547 *** This library is for example available at
1548 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1549 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1550 ***]])
1551 fi
1552 if test "$have_ksba" = "no"; then
1553     AC_MSG_NOTICE([[
1554 ***
1555 *** You need libksba to build this program.
1556 *** This library is for example available at
1557 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1558 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1559 ***]])
1560 fi
1561 if test "$gnupg_have_ldap" = "no"; then
1562     die=yes
1563     AC_MSG_NOTICE([[
1564 ***
1565 *** You need a LDAP library to build this program.
1566 *** Check out 
1567 ***    http://www.openldap.org 
1568 *** for a suitable implementation. 
1569 ***]])
1570 fi
1571 if test "$missing_pth" = "yes"; then
1572     AC_MSG_NOTICE([[
1573 ***
1574 *** It is now required to build with support for the
1575 *** GNU Portable Threads Library (Pth). Please install this
1576 *** library first.  The library is for example available at
1577 ***   ftp://ftp.gnu.org/gnu/pth/
1578 *** On a Debian GNU/Linux system you can install it using 
1579 ***   apt-get install libpth-dev
1580 *** To build GnuPG for Windows you need to use the W32PTH
1581 *** package; available at:
1582 ***   ftp://ftp.g10code.com/g10code/w32pth/
1583 ***]])
1584    die=yes
1585 fi
1586
1587 if test "$die" = "yes"; then
1588     AC_MSG_ERROR([[
1589 ***
1590 *** Required libraries not found. Please consult the above messages
1591 *** and install them before running configure again.
1592 ***]])
1593 fi
1594
1595
1596
1597 AC_CONFIG_FILES([ m4/Makefile 
1598 Makefile
1599 po/Makefile.in
1600 gl/Makefile
1601 include/Makefile
1602 common/Makefile
1603 kbx/Makefile
1604 g10/Makefile
1605 sm/Makefile
1606 agent/Makefile
1607 scd/Makefile
1608 g13/Makefile
1609 dirmngr/Makefile
1610 keyserver/Makefile
1611 keyserver/gpg2keys_mailto
1612 keyserver/gpg2keys_test
1613 tools/gpg-zip
1614 tools/Makefile
1615 doc/Makefile
1616 tests/Makefile
1617 tests/openpgp/Makefile
1618 tests/pkits/Makefile
1619 ])
1620 AC_OUTPUT
1621
1622
1623 echo "
1624         GnuPG v${VERSION} has been configured as follows:
1625         
1626         Platform:  $PRINTABLE_OS_NAME ($host)
1627
1628         OpenPGP:   $build_gpg
1629         S/MIME:    $build_gpgsm
1630         Agent:     $build_agent $build_agent_threaded
1631         Smartcard: $build_scdaemon $build_scdaemon_extra
1632         G13:       $build_g13
1633         Dirmngr:   $build_dirmngr
1634         Gpgtar:    $build_gpgtar
1635
1636         Protect tool:      $show_gnupg_protect_tool_pgm
1637         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
1638         Default agent:     $show_gnupg_agent_pgm
1639         Default pinentry:  $show_gnupg_pinentry_pgm
1640         Default scdaemon:  $show_gnupg_scdaemon_pgm
1641         Default dirmngr:   $show_gnupg_dirmngr_pgm
1642
1643         Use standard socket: $use_standard_socket
1644 "
1645 if test x"$use_regex" != xyes ; then
1646 echo "
1647         Warning: No regular expression support available.
1648                  OpenPGP trust signatures won't work.
1649                  gpg-check-pattern will not be build.
1650 "
1651 fi