* configure.ac (gl_INIT): Add gnulib stuff.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 1.9
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 #               2003, 2004 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 2 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, write to the Free Software
19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20
21 # Process this file with autoconf to produce a configure script.
22 AC_PREREQ(2.52)
23 min_automake_version="1.9.3"
24
25 # Version number: Remember to change it immediately *after* a release.
26 #                 Add a "-cvs" prefix for non-released code.
27 AC_INIT(gnupg, 1.9.17-cvs, gnupg-devel@gnupg.org)
28 # Set development_version to yes if the minor number is odd or you
29 # feel that the default check for a development version is not
30 # sufficient.
31 development_version=yes
32 NEED_GPG_ERROR_VERSION=1.0
33
34 NEED_LIBGCRYPT_API=1
35 NEED_LIBGCRYPT_VERSION=1.1.94
36
37 NEED_LIBASSUAN_VERSION=0.6.9
38
39 NEED_KSBA_VERSION=0.9.11
40
41
42 PACKAGE=$PACKAGE_NAME
43 PACKAGE_GT=${PACKAGE_NAME}2
44 VERSION=$PACKAGE_VERSION
45
46 AC_CONFIG_AUX_DIR(scripts)
47 AC_CONFIG_SRCDIR(sm/gpgsm.c)
48 AM_CONFIG_HEADER(config.h)
49 AC_CANONICAL_TARGET()
50 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
51
52 AC_GNU_SOURCE
53
54 # Some status variables to give feedback at the end of a configure run
55 have_gpg_error=no
56 have_libgcrypt=no 
57 have_libassuan=no
58 have_ksba=no
59 have_pth=no
60
61 GNUPG_BUILD_PROGRAM(gpg, no)
62 GNUPG_BUILD_PROGRAM(gpgsm, yes)
63 GNUPG_BUILD_PROGRAM(agent, yes)
64 GNUPG_BUILD_PROGRAM(scdaemon, yes)
65 GNUPG_BUILD_PROGRAM(symcryptrun, no)
66
67
68 AC_SUBST(PACKAGE)
69 AC_SUBST(PACKAGE_GT)
70 AC_SUBST(VERSION)
71 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
72 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
73                                 [Name of this package for gettext])
74 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
75 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
76                                         [Bug report address])
77 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
78                                        [Required version of Libgcrypt])
79 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
80                                        [Required version of Libksba])
81
82
83
84 # The default is to use the modules from this package and the few
85 # other packages in a standard place; i.e where this package gets
86 # installed.  With these options it is possible to override these
87 # ${prefix} depended values with fixed paths, which can't be replaced
88 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
89 AC_ARG_WITH(agent-pgm,
90     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
91           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
92 AC_SUBST(GNUPG_AGENT_PGM)
93 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
94 show_gnupg_agent_pgm="(default)"
95 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
96
97 AC_ARG_WITH(pinentry-pgm,
98     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
99           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
100 AC_SUBST(GNUPG_PINENTRY_PGM)
101 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
102 show_gnupg_pinentry_pgm="(default)"
103 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
104
105
106 AC_ARG_WITH(scdaemon-pgm,
107     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
108           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
109 AC_SUBST(GNUPG_SCDAEMON_PGM)
110 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
111 show_gnupg_scdaemon_pgm="(default)"
112 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
113
114
115 AC_ARG_WITH(dirmngr-pgm,
116     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
117           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
118 AC_SUBST(GNUPG_DIRMNGR_PGM)
119 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
120 show_gnupg_dirmngr_pgm="(default)"
121 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
122
123 AC_ARG_WITH(protect-tool-pgm,
124     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
125           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
126 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
127 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
128 show_gnupg_protect_tool_pgm="(default)"
129 test -n "$GNUPG_PROTECT_TOOL_PGM" \
130       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
131
132
133
134 # Some folks want to use only the agent form this packet.  Make it
135 # easier for them by providing the configure option
136 # --enable-only-agent.
137 AC_ARG_ENABLE(agent-only,
138     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
139     build_agent_only=$enableval)
140
141
142 # Configure option to allow or disallow execution of external
143 # programs, like a photo viewer.
144 AC_MSG_CHECKING([whether to enable external program execution])
145 AC_ARG_ENABLE(exec,
146     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
147     use_exec=$enableval)
148 AC_MSG_RESULT($use_exec)
149 if test "$use_exec" = no ; then
150     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
151 fi
152
153 if test "$use_exec" = yes ; then
154   AC_MSG_CHECKING([whether to enable photo ID viewing])
155   AC_ARG_ENABLE(photo-viewers,
156       [  --disable-photo-viewers disable photo ID viewers],
157       [if test "$enableval" = no ; then
158          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
159       fi],enableval=yes)
160   gnupg_cv_enable_photo_viewers=$enableval
161   AC_MSG_RESULT($enableval)
162
163   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
164     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
165     AC_ARG_WITH(photo-viewer,
166         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
167         [if test "$withval" = yes ; then
168            withval=no
169         elif test "$withval" != no ; then
170            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
171                             [if set, restrict photo-viewer to this])
172         fi],withval=no)
173     AC_MSG_RESULT($withval)
174   fi
175
176   AC_MSG_CHECKING([whether to enable external keyserver helpers])
177   AC_ARG_ENABLE(keyserver-helpers,
178       [  --disable-keyserver-helpers  disable all external keyserver support],
179       [if test "$enableval" = no ; then
180          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
181                   [define to disable keyserver helpers])
182       fi],enableval=yes)
183   gnupg_cv_enable_keyserver_helpers=$enableval
184   AC_MSG_RESULT($enableval)
185
186   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
187     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
188     AC_ARG_ENABLE(ldap,
189     [  --disable-ldap          disable LDAP keyserver interface],
190         try_ldap=$enableval, try_ldap=yes)
191     AC_MSG_RESULT($try_ldap)
192
193     AC_MSG_CHECKING([whether HKP keyserver support is requested])
194     AC_ARG_ENABLE(hkp,
195     [  --disable-hkp           disable HKP keyserver interface],
196         try_hkp=$enableval, try_hkp=yes)
197     AC_MSG_RESULT($try_hkp)
198
199     if test "$try_hkp" = yes ; then
200       AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
201     fi
202
203     AC_MSG_CHECKING([whether email keyserver support is requested])
204     AC_ARG_ENABLE(mailto,
205     [  --disable-mailto        disable email keyserver interface],
206         try_mailto=$enableval, try_mailto=yes)
207     AC_MSG_RESULT($try_mailto)
208     fi
209
210     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
211     AC_ARG_ENABLE(keyserver-path,
212         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
213         [if test "$enableval" = no ; then
214          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
215         fi],enableval=yes)
216     AC_MSG_RESULT($enableval)
217   fi
218
219 dnl
220 dnl Check whether we want to use Linux capabilities
221 dnl
222 AC_MSG_CHECKING([whether use of capabilities is requested])
223 AC_ARG_WITH(capabilities,
224     [  --with-capabilities     use linux capabilities [default=no]],
225 [use_capabilities="$withval"],[use_capabilities=no])
226 AC_MSG_RESULT($use_capabilities)
227
228
229 AH_BOTTOM([
230 /* Some global constants. */
231 #ifdef HAVE_DRIVE_LETTERS
232 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
233 #elif defined(__VMS)
234 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg" 
235 #else
236 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
237 #endif 
238 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
239
240 /* Tell libgcrypt not to use its own libgpg-error implementation. */
241 #define USE_LIBGPG_ERROR 1
242
243 /* This is the major version number of GnuPG so that
244    source included files can test for this.  Note, that\
245    we use 2 here even for GnuPG 1.9.x. */
246 #define GNUPG_MAJOR_VERSION 2
247
248 /* Now to separate file name parts.
249    Please note that the string version must not contain more
250    than one character because the code assumes strlen()==1 */
251 #ifdef HAVE_DOSISH_SYSTEM
252 #define DIRSEP_C '\\'
253 #define DIRSEP_S "\\"
254 #define EXTSEP_C '.'
255 #define EXTSEP_S "."
256 #define PATHSEP_C ';'
257 #define PATHSEP_S ";"
258 #define EXEEXT_S ".exe"
259 #else
260 #define DIRSEP_C '/'
261 #define DIRSEP_S "/"
262 #define EXTSEP_C '.'
263 #define EXTSEP_S "."
264 #define PATHSEP_C ':'
265 #define PATHSEP_S ":"
266 #define EXEEXT_S ""
267 #endif
268
269 /* This is the same as VERSION, but should be overridden if the
270    platform cannot handle things like dots '.' in filenames. Set
271    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
272    uses for dots and dashes. */
273 #define SAFE_VERSION VERSION
274 #define SAFE_VERSION_DOT  '.'
275 #define SAFE_VERSION_DASH '-'
276
277 /* For some systems (DOS currently), we hardcode the path here.  For
278    POSIX systems the values are constructed by the Makefiles, so that
279    the values may be overridden by the make invocations; this is to
280    comply with the GNU coding standards. */
281 #ifdef HAVE_DRIVE_LETTERS
282 #define GNUPG_BINDIR      "c:\\gnupg"
283 #define GNUPG_LIBEXECDIR  "c:\\gnupg"
284 #define GNUPG_LIBDIR      "c:\\gnupg"
285 #define GNUPG_DATADIR     "c:\\gnupg"
286 #endif
287
288 /* Setup the hardwired names of modules. */
289 #ifndef GNUPG_DEFAULT_AGENT
290 #define GNUPG_DEFAULT_AGENT    ( GNUPG_BINDIR DIRSEP_S "gpg-agent" EXEEXT_S )
291 #endif
292 #ifndef GNUPG_DEFAULT_PINENTRY
293 #define GNUPG_DEFAULT_PINENTRY ( GNUPG_BINDIR DIRSEP_S "pinentry" EXEEXT_S )
294 #endif
295 #ifndef GNUPG_DEFAULT_SCDAEMON
296 #define GNUPG_DEFAULT_SCDAEMON ( GNUPG_BINDIR DIRSEP_S "scdaemon" EXEEXT_S )
297 #endif
298 #ifndef GNUPG_DEFAULT_DIRMNGR
299 #define GNUPG_DEFAULT_DIRMNGR  ( GNUPG_BINDIR DIRSEP_S "dirmngr" EXEEXT_S )
300 #endif
301 #ifndef GNUPG_DEFAULT_PROTECT_TOOL
302 #define GNUPG_DEFAULT_PROTECT_TOOL \
303                     ( GNUPG_LIBEXECDIR DIRSEP_S "gpg-protect-tool" EXEEXT_S )
304 #endif
305
306
307 /* Derive some other constants. */
308 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
309 #define EXEC_TEMPFILE_ONLY
310 #endif
311
312 /* Temporary hacks to avoid requring a libgpg-error update. */
313 #if !HAVE_DECL_GPG_ERR_LOCKED
314 #define GPG_ERR_LOCKED  173
315 #endif
316
317 ])
318
319 AM_MAINTAINER_MODE
320
321 # Checks for programs.
322 AC_PROG_MAKE_SET
323 AM_SANITY_CHECK
324 missing_dir=`cd $ac_aux_dir && pwd`
325 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
326 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
327 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
328 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
329 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
330 AC_PROG_AWK
331 AC_PROG_CC
332 AC_PROG_CPP
333 AC_PROG_INSTALL
334 AC_PROG_LN_S
335 AC_PROG_MAKE_SET
336 AC_PROG_RANLIB
337 AC_CHECK_TOOL(AR, ar, :)
338 AC_PATH_PROG(PERL,"perl")
339 AC_ISC_POSIX
340 gl_EARLY
341 AC_SYS_LARGEFILE
342 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
343 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
344 GNUPG_CHECK_FAQPROG
345 GNUPG_CHECK_DOCBOOK_TO_TEXI
346
347
348 try_gettext=yes
349 have_dosish_system=no
350 have_w32_system=no
351 case "${host}" in
352     *-mingw32*)
353         # special stuff for Windoze NT
354         ac_cv_have_dev_random=no
355         AC_DEFINE(USE_ONLY_8DOT3,1,
356                   [set this to limit filenames to the 8.3 format])
357         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
358                   [defined if we must run on a stupid file system])
359         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
360                   [because the Unix gettext has too much overhead on
361                    MingW32 systems and these systems lack Posix functions,
362                    we use a simplified version of gettext])
363         have_dosish_system=yes
364         have_w32_system=yes
365         try_gettext="no"
366         ;;
367     i?86-emx-os2 | i?86-*-os2*emx )
368         # OS/2 with the EMX environment
369         ac_cv_have_dev_random=no
370         AC_DEFINE(HAVE_DRIVE_LETTERS)
371         have_dosish_system=yes
372         try_gettext="no"
373         ;;
374
375     i?86-*-msdosdjgpp*)
376         # DOS with the DJGPP environment
377         ac_cv_have_dev_random=no
378         AC_DEFINE(HAVE_DRIVE_LETTERS)
379         have_dosish_system=yes
380         try_gettext="no"
381         ;;
382
383     *-*-freebsd*)
384        # FreeBSD
385        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
386        LDFLAGS="$LDFLAGS -L/usr/local/lib"
387        ;;
388
389     *-*-hpux*)
390         if test -z "$GCC" ; then
391             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
392         fi
393         ;;
394     *-dec-osf4*)
395         if test -z "$GCC" ; then
396             # Suppress all warnings
397             # to get rid of the unsigned/signed char mismatch warnings.
398             CFLAGS="$CFLAGS -w"
399         fi
400         ;;
401     *-dec-osf5*)
402         if test -z "$GCC" ; then
403             # Use the newer compiler `-msg_disable ptrmismatch' to
404             # get rid of the unsigned/signed char mismatch warnings.
405             # Using this may hide other pointer mismatch warnings, but
406             # it at least lets other warning classes through
407             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
408         fi
409         ;;
410     m68k-atari-mint)
411         ;;
412     *)
413        ;;
414 esac
415
416 if test "$have_dosish_system" = yes; then
417    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
418              [Defined if we run on some of the PCDOS like systems 
419               (DOS, Windoze. OS/2) with special properties like
420               no file modes])
421 fi
422 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
423
424 if test "$have_w32_system" = yes; then
425    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
426 fi
427 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
428
429
430
431 #
432 # Checks for libraries.
433 #
434
435
436 #
437 # libgpg-error is a library with error codes shared between GnuPG
438 # related projects.
439 #
440 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
441                   have_gpg_error=yes,have_gpg_error=no)
442 _tmp_gpg_error_save_cflags="$CFLAGS"
443 CFLAGS="$CFLAGS $GPG_ERROR_CFLAGS"
444 AC_CHECK_DECLS(GPG_ERR_LOCKED,,,[#include <gpg-error.h>])
445 CFLAGS="${_tmp_gpg_error_save_cflags}"
446
447
448 #
449 # Libgcrypt is our generic crypto library
450 #
451 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
452         have_libgcrypt=yes,have_libgcrypt=no)
453
454
455 #
456 # libassuan is used for IPC
457 #
458 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_VERSION",
459                   have_libassuan=yes,have_libassuan=no)
460
461
462 #
463 # libksba is our X.509 support library
464 #
465 AM_PATH_KSBA("$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
466
467 #
468 # libusb allows us to use the integrated CCID smartcard reader driver.
469 #
470 AC_CHECK_LIB(usb, usb_bulk_write,
471               [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
472                 AC_DEFINE(HAVE_LIBUSB,1,
473                          [defined if libusb is available])
474              ])
475 AC_SUBST(LIBUSB_LIBS)
476 AC_CHECK_FUNCS(usb_create_match)
477
478 #
479 # Check wether it is necessary to link against libdl.
480 #
481 LIBS=""
482 AC_SEARCH_LIBS(dlopen, c dl,,,)
483 DL_LIBS=$LIBS
484 AC_SUBST(DL_LIBS)
485
486 #
487 # Checks for symcryptrun:
488 #
489
490 # libutil has openpty() and login_tty().
491 AC_CHECK_LIB(util, openpty,
492               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
493                 AC_DEFINE(HAVE_LIBUTIL,1,
494                          [defined if libutil is available])
495              ])
496 AC_SUBST(LIBUTIL_LIBS)
497
498 # shred is used to clean temporary plain text files.
499 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
500 AC_DEFINE_UNQUOTED(SHRED,
501         "${SHRED}", [defines the filename of the shred program])
502
503
504 #
505 # Check whether the (highly desirable) GNU Pth library is available
506 # Note, that we include a Pth emulation for W32.
507 #
508 AC_ARG_WITH(pth-prefix,
509             AC_HELP_STRING([--with-pth-prefix=PFX],
510                            [prefix where GNU Pth is installed (optional)]),
511      pth_config_prefix="$withval", pth_config_prefix="")
512 if test x$pth_config_prefix != x ; then
513    PTH_CONFIG="$pth_config_prefix/bin/pth-config"
514 fi
515 AC_PATH_PROG(PTH_CONFIG, pth-config, no)
516 if test "$have_w32_system" = no; then
517  if test "$PTH_CONFIG" = "no"; then
518     AC_MSG_WARN([[
519 ***
520 *** To support concurrent access to the gpg-agent and the SCdaemon
521 *** we need the support of the GNU Portable Threads Library.
522 *** Download it from ftp://ftp.gnu.org/gnu/pth/
523 *** On a Debian GNU/Linux system you might want to try 
524 ***   apt-get install libpth-dev
525 ***]])
526  else
527   GNUPG_PTH_VERSION_CHECK(1.3.7)
528   if test $have_pth = yes; then      
529      PTH_CFLAGS=`$PTH_CONFIG --cflags`
530      PTH_LIBS=`$PTH_CONFIG --ldflags`
531      PTH_LIBS="$PTH_LIBS `$PTH_CONFIG --libs`"
532      AC_DEFINE(USE_GNU_PTH, 1,
533               [Defined if the GNU Portable Thread Library should be used])
534   fi
535  fi
536 else 
537  have_pth=yes
538  PTH_CFLAGS=""
539  PTH_LIBS=""
540  AC_DEFINE(USE_GNU_PTH, 1)
541 fi
542 AC_SUBST(PTH_CFLAGS)
543 AC_SUBST(PTH_LIBS)
544
545
546 dnl Must check for network library requirements before doing link tests
547 dnl for ldap, for example. If ldap libs are static (or dynamic and without
548 dnl ELF runtime link paths), then link will fail and LDAP support won't
549 dnl be detected.
550
551 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
552         [NETLIBS="-lnsl $NETLIBS"]))
553 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
554         [NETLIBS="-lsocket $NETLIBS"]))
555
556 dnl Now try for the resolver functions so we can use DNS SRV
557
558 AC_ARG_ENABLE(dns-srv,
559    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
560    use_dns_srv=$enableval,use_dns_srv=yes)
561
562 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
563   _srv_save_libs=$LIBS
564   LIBS=""
565   # the double underscore thing is a glibc-ism?
566   AC_SEARCH_LIBS(res_query,resolv bind,,
567                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
568   AC_SEARCH_LIBS(dn_expand,resolv bind,,
569                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
570   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
571                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
572
573   if test x"$use_dns_srv" = xyes ; then
574      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
575      SRVLIBS=$LIBS
576   else
577      AC_MSG_WARN([Resolver functions not found.  Disabling DNS SRV.])
578   fi
579   LIBS=$_srv_save_libs
580 fi
581
582 AC_SUBST(SRVLIBS)
583
584 # Try and link a LDAP test program to weed out unusable LDAP
585 # libraries.  -lldap [-llber [-lresolv]] is for OpenLDAP.  OpenLDAP in
586 # general is terrible with creating weird dependencies.  If all else
587 # fails, the user can play guess-the-dependency by using something
588 # like ./configure LDAPLIBS="-Lfoo -lbar"
589
590 if test "$try_ldap" = yes ; then
591   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
592     _ldap_save_libs=$LIBS
593     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
594
595     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
596     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
597                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
598     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
599
600     if test $gnupg_cv_func_ldap_init = no; then
601       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
602       AC_TRY_LINK([#include <lber.h>
603 #include <ldap.h>],[ldap_open("foobar",1234);],
604          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
605       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
606     fi
607
608     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
609        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
610     fi
611
612     if test "$gnupg_cv_func_ldap_init" = yes || \
613         test "$gnupg_cv_func_ldaplber_init" = yes ; then
614        LDAPLIBS=$MY_LDAPLIBS
615        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
616
617        AC_MSG_CHECKING([whether LDAP supports ldap_get_option])
618
619        if test "$gnupg_cv_func_ldap_init" = yes ; then
620           AC_TRY_LINK([#include <ldap.h>],
621              [ldap_get_option((void *)0,0,(void *)0);],
622              [gnupg_cv_func_ldap_get_option=yes],
623              [gnupg_cv_func_ldap_get_option=no])
624         else
625           AC_TRY_LINK([#include <lber.h>
626 #include <ldap.h>],[ldap_get_option((void *)0,0,(void *)0);],
627              [gnupg_cv_func_ldap_get_option=yes],
628              [gnupg_cv_func_ldap_get_option=no])
629        fi
630
631        AC_MSG_RESULT([$gnupg_cv_func_ldap_get_option])
632
633        if test "$gnupg_cv_func_ldap_get_option" = yes ; then
634           AC_DEFINE(HAVE_LDAP_GET_OPTION,1,[Define if the LDAP library has ldap_get_option])
635        else
636           AC_MSG_CHECKING([whether LDAP supports ld_errno])
637
638           if test "$gnupg_cv_func_ldap_init" = yes ; then
639             AC_TRY_COMPILE([#include <ldap.h>],
640                [LDAP *ldap; ldap->ld_errno;],
641                [gnupg_cv_func_ldap_ld_errno=yes],
642                [gnupg_cv_func_ldap_ld_errno=no])
643            else
644             AC_TRY_LINK([#include <lber.h>
645 #include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
646                [gnupg_cv_func_ldap_ld_errno=yes],
647                [gnupg_cv_func_ldap_ld_errno=no])
648           fi
649
650           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
651
652           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
653              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
654           fi
655        fi
656     fi
657
658     LIBS=$_ldap_save_libs
659
660     if test "$GPGKEYS_LDAP" != "" ; then break; fi
661   done
662 fi
663
664 AC_SUBST(GPGKEYS_LDAP)
665 AC_SUBST(LDAPLIBS)
666
667 dnl This isn't necessarily sendmail itself, but anything that gives a
668 dnl sendmail-ish interface to the outside world.  That includes qmail,
669 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
670
671 if test "$try_mailto" = yes ; then
672   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
673
674   if test "$with_mailprog" = yes ; then
675     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
676     if test "$ac_cv_path_SENDMAIL" ; then
677       GPGKEYS_MAILTO="gpgkeys_mailto"
678     fi
679   elif test "$with_mailprog" != no ; then
680     AC_MSG_CHECKING([for a mail transport program])
681     AC_SUBST(SENDMAIL,$with_mailprog)
682     AC_MSG_RESULT($with_mailprog)
683     GPGKEYS_MAILTO="gpgkeys_mailto"
684   fi
685 fi
686
687 AC_SUBST(GPGKEYS_MAILTO)
688
689 case "${host}" in
690     *-mingw32*)
691         PRINTABLE_OS_NAME="MingW32"
692         ;;
693     *-*-cygwin*)
694         PRINTABLE_OS_NAME="Cygwin"
695         ;;
696     i?86-emx-os2 | i?86-*-os2*emx )
697         PRINTABLE_OS_NAME="OS/2"
698         ;;
699     i?86-*-msdosdjgpp*)
700         PRINTABLE_OS_NAME="MSDOS/DJGPP"
701         try_dynload=no
702         ;;
703     *-linux*)
704         PRINTABLE_OS_NAME="GNU/Linux"
705         ;;
706     *)
707         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
708         ;;
709 esac
710 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
711                    [A human readable text with the name of the OS])
712
713
714 AM_GNU_GETTEXT_VERSION(0.14.1)
715 if test "$try_gettext" = yes; then
716   AM_GNU_GETTEXT(,[need-ngettext])
717
718   # gettext requires some extra checks.  These really should be part of
719   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
720   # function checks to here.
721
722   AC_CHECK_FUNCS(strchr)
723 else
724   USE_NLS=no
725   USE_INCLUDED_LIBINTL=no
726   BUILD_INCLUDED_LIBINTL=no
727   AC_SUBST(USE_NLS)
728   AC_SUBST(USE_INCLUDED_LIBINTL)
729   AC_SUBST(BUILD_INCLUDED_LIBINTL)
730 fi
731
732 # Checks for header files.
733 AC_HEADER_STDC
734 AC_CHECK_HEADERS(string.h unistd.h langinfo.h termio.h locale.h)
735
736 # Checks for typedefs, structures, and compiler characteristics.
737 AC_C_CONST
738 AC_C_INLINE
739 AC_TYPE_SIZE_T
740 AC_TYPE_SIGNAL
741 AC_DECL_SYS_SIGLIST
742
743 GNUPG_CHECK_ENDIAN
744
745 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
746 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
747 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
748 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
749 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
750
751 AC_CHECK_SIZEOF(unsigned short)
752 AC_CHECK_SIZEOF(unsigned int)
753 AC_CHECK_SIZEOF(unsigned long)
754 AC_CHECK_SIZEOF(unsigned long long)
755 # Ensure that we have UINT64_C before we bother to check for uint64_t
756 # fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
757 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
758    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
759 uint64_t foo=UINT64_C(42);]),gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
760 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
761    AC_CHECK_SIZEOF(uint64_t)
762 fi
763  
764
765
766
767 if test "$ac_cv_sizeof_unsigned_short" = "0" \
768    || test "$ac_cv_sizeof_unsigned_int" = "0" \
769    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
770     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
771 fi
772
773 dnl Do we have any 64-bit data types?
774 if test "$ac_cv_sizeof_unsigned_int" != "8" \
775    && test "$ac_cv_sizeof_unsigned_long" != "8" \
776    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
777    && test "$ac_cv_sizeof_uint64_t" != "8"; then
778     AC_MSG_WARN([No 64-bit types.  Disabling SHA-384, and SHA-512])
779 else
780   if test x"$use_sha512" = xyes ; then
781      AC_SUBST(SHA512_O,sha512.o)
782      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
783   fi
784 fi
785
786 # fixme: do we really need this - it should be encapsulated in libassuan
787 GNUPG_SYS_SO_PEERCRED
788
789 # Checks for library functions.
790 AC_FUNC_FSEEKO
791 AC_FUNC_VPRINTF
792 AC_FUNC_FORK
793 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
794 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times gmtime_r)
795 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
796 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
797 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat getaddrinfo)
798 AC_CHECK_FUNCS(fseeko ftello ttyname isascii)
799
800 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
801
802 # gnulib checks
803 gl_SOURCE_BASE(gl)
804 gl_M4_BASE(gl/m4)
805 gl_MODULES(setenv strsep mkdtemp vasprintf xsize)
806 gl_INIT
807
808 # These are needed by libjnlib - fixme: we should have macros for them
809 AC_CHECK_FUNCS(memicmp stpcpy strlwr strtoul memmove stricmp strtol)
810 AC_CHECK_FUNCS(getrusage setrlimit stat setlocale)
811 AC_CHECK_FUNCS(flockfile funlockfile fopencookie funopen)
812
813
814 #
815 # check for gethrtime and run a testprogram to see whether
816 # it is broken.  It has been reported that some Solaris and HP UX systems 
817 # raise an SIGILL
818 #
819 #  fixme: Do we need this - iirc, this is only used by libgcrypt.
820 #
821 AC_CACHE_CHECK([for gethrtime], 
822                [gnupg_cv_func_gethrtime],
823                [AC_TRY_LINK([#include <sys/times.h>],[
824                    hrtime_t tv;
825                    tv = gethrtime();
826                  ],
827                  [gnupg_cv_func_gethrtime=yes],
828                  [gnupg_cv_func_gethrtime=no])
829                ])
830 if test $gnupg_cv_func_gethrtime = yes; then
831      AC_DEFINE([HAVE_GETHRTIME], 1,
832                [Define if you have the `gethrtime(2)' function.])
833      AC_CACHE_CHECK([whether gethrtime is broken], 
834                [gnupg_cv_func_broken_gethrtime],
835                [AC_TRY_RUN([
836                    #include <sys/times.h>
837                    int main () {
838                    hrtime_t tv;
839                    tv = gethrtime(); 
840                  }
841                  ],
842                  [gnupg_cv_func_broken_gethrtime=no],
843                  [gnupg_cv_func_broken_gethrtime=yes],
844                  [gnupg_cv_func_broken_gethrtime=assume-no])
845                 ])
846     if test $gnupg_cv_func_broken_gethrtime = yes; then
847       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
848       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
849     fi
850 fi
851      
852
853 GNUPG_CHECK_MLOCK
854 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
855
856 dnl
857 dnl Check whether we can use Linux capabilities as requested
858 dnl
859 #  fixme: Still required?
860 #
861 if test "$use_capabilities" = "yes" ; then
862 use_capabilities=no
863 AC_CHECK_HEADERS(sys/capability.h)
864 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
865   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
866   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
867      AC_DEFINE(USE_CAPABILITIES,1,
868                [define if capabilities should be used])
869      AC_SUBST(CAPLIBS,"-lcap")
870      use_capabilities=yes
871   fi
872 fi
873 if test "$use_capabilities" = "no" ; then
874     AC_MSG_WARN([[
875 ***
876 *** The use of capabilities on this system is not possible.
877 *** You need a recent Linux kernel and some patches:
878 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
879 ***   fcap-module-990613.tar.gz     (kernel module)
880 ***   libcap-1.92.tar.gz            (user mode library and utilities)
881 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
882 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
883 ***]])
884 fi
885 fi
886
887
888 # Sanity check regex.  Tests adapted from mutt.
889
890 AC_MSG_CHECKING([whether regular expression support is requested])
891 AC_ARG_ENABLE(regex,
892 [  --disable-regex         do not handle regular expressions in trust sigs],
893      use_regex=$enableval, use_regex=yes)
894 AC_MSG_RESULT($use_regex)
895
896 if test "$use_regex" = yes ; then
897   AC_MSG_CHECKING([whether the included regex lib is requested])
898   AC_ARG_WITH(included-regex,
899       [  --with-included-regex   use the included GNU regex library],
900       [gnupg_cv_included_regex="$withval"],[gnupg_cv_included_regex=no])
901   AC_MSG_RESULT($gnupg_cv_included_regex)
902
903   if test $gnupg_cv_included_regex = no ; then
904      # Does the system have regex functions at all?
905      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
906                            gnupg_cv_included_regex=yes)
907   fi
908
909   if test $gnupg_cv_included_regex = no ; then
910      AC_CACHE_CHECK([whether your system's regexp library is broken],
911        [gnupg_cv_regex_broken],
912        AC_TRY_RUN([
913 #include <unistd.h>
914 #include <regex.h>
915 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
916        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
917
918      if test $gnupg_cv_regex_broken = yes ; then
919       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
920       gnupg_cv_included_regex=yes
921      fi
922   fi
923
924   if test $gnupg_cv_included_regex = yes; then
925      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
926      AC_SUBST(REGEX_O,regex.o)
927   fi
928 else
929
930   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
931 fi
932
933 dnl Do we have zlib? Must do it here because Solaris failed
934 dnl when compiling a conftest (due to the "-lz" from LIBS).
935 _cppflags="${CPPFLAGS}"
936 _ldflags="${LDFLAGS}"
937
938 AC_ARG_WITH(zlib,
939   [  --with-zlib=DIR         use libz in DIR],[
940     if test -d "$withval"; then
941       CPPFLAGS="${CPPFLAGS} -I$withval/include"
942       LDFLAGS="${LDFLAGS} -L$withval/lib"
943     fi
944   ])
945
946 AC_CHECK_HEADER(zlib.h,
947       AC_CHECK_LIB(z, deflateInit2_,
948        LIBS="$LIBS -lz",
949        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
950        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
951  
952
953
954 # See wether we want to run the long test suite.
955 AC_ARG_WITH(pkits-tests,
956     AC_HELP_STRING([--with-pkits-tests],[run the PKITS based tests]),
957     [run_pkits_tests=$withval], [run_pkits_tests=no])
958 AM_CONDITIONAL(RUN_PKITS_TESTS, test "$run_pkits_tests" = "yes")
959
960
961 # Allow users to append something to the version string without
962 # flagging it as development version.  The user version parts is
963 # considered everything after a dash. 
964 if test "$development_version" != yes; then
965   changequote(,)dnl
966   tmp_pat='[a-zA-Z]'
967   changequote([,])dnl
968   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
969     development_version=yes
970   fi
971 fi
972 if test "$development_version" = yes; then
973     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
974             [Defined if this is not a regular release])
975 fi
976
977 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
978
979 GNUPG_CHECK_GNUMAKE
980
981 # Add some extra libs here so that previous tests don't fail for
982 # mysterious reasons - the final link step should bail out. 
983 if test "$have_w32_system" = yes; then
984    W32LIBS="-lwsock32"
985 fi
986
987
988 if test "$GCC" = yes; then
989     if test "$USE_MAINTAINER_MODE" = "yes"; then
990         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
991         CFLAGS="$CFLAGS -Wno-format-y2k -Wformat-security"
992     else
993         CFLAGS="$CFLAGS -Wall"
994     fi
995 fi
996
997 AC_SUBST(NETLIBS)
998 AC_SUBST(W32LIBS)
999
1000
1001 # We use jnlib, so tell other modules about it
1002 AC_DEFINE(HAVE_JNLIB_LOGGING, 1,
1003           [Defined if jnlib style logging functions are available])
1004
1005 # For W32 we need to use our Pth emulation code
1006 if test "$have_w32_system" = yes; then
1007   AC_CONFIG_LINKS(pth.h:jnlib/w32-pth.h)
1008 fi
1009
1010
1011 #
1012 # Decide what to build
1013 #
1014 missing_pth=no
1015 if test $have_ksba = no; then
1016   build_gpgsm=no
1017   build_scdaemon=no
1018 fi
1019
1020 build_agent_threaded=""
1021 if test "$build_agent" = "yes"; then
1022   if test $have_pth = no; then
1023      build_agent_threaded="(not multi-threaded)"
1024      missing_pth=yes
1025   fi
1026 fi
1027
1028 build_scdaemon_extra=""
1029 if test "$build_scdaemon" = "yes"; then
1030   tmp=""
1031   if test $have_pth = no; then
1032      build_scdaemon_extra="not multi-threaded"
1033      tmp=", "
1034      missing_pth=yes
1035   fi
1036   if test -n "$build_scdaemon_extra"; then
1037      build_scdaemon_extra="(${build_scdaemon_extra})"
1038   fi
1039 fi
1040
1041
1042 if test "$build_agent_only" = "yes" ; then
1043   build_gpg=no
1044   build_gpgsm=no
1045   build_scdaemon=no
1046 fi
1047
1048
1049 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1050 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1051 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1052 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1053 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1054
1055
1056
1057 #
1058 # Print errors here so that they are visible all
1059 # together and the user can acquire them all together.
1060 #
1061 die=no
1062 if test "$have_gpg_error" = "no"; then
1063    die=yes
1064    AC_MSG_NOTICE([[
1065 ***  
1066 *** You need libgpg-error to build this program.
1067 **  This library is for example available at
1068 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1069 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1070 ***]])
1071 fi
1072 if test "$have_libgcrypt" = "no"; then
1073    die=yes
1074    AC_MSG_NOTICE([[
1075 ***  
1076 *** You need libgcrypt to build this program.
1077 **  This library is for example available at
1078 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1079 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API) is required.)
1080 ***]])
1081 fi
1082 if test "$have_libassuan" = "no"; then
1083    die=yes
1084    AC_MSG_NOTICE([[
1085 ***
1086 *** You need libassuan to build this program.
1087 *** This library is for example available at
1088 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libassuan/
1089 *** (at least version $NEED_LIBASSUAN_VERSION is required).
1090 ***]])
1091 fi
1092 if test "$have_ksba" = "no"; then
1093     AC_MSG_NOTICE([[
1094 ***
1095 *** You need libksba to build this program.
1096 *** This library is for example available at
1097 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libksba/
1098 *** (at least version $NEED_KSBA_VERSION is required).
1099 ***]])
1100 fi
1101 if test "$missing_pth" = "yes"; then
1102     AC_MSG_NOTICE([[
1103 ***
1104 *** It is now required to build with support for the
1105 *** GNU Portable Threads Library (Pth). Please install this
1106 *** library first.  The library is for example available at
1107 ***   ftp://ftp.gnu.org/gnu/pth/
1108 *** On a Debian GNU/Linux system you can install it using 
1109 ***   apt-get install libpth-dev
1110 ***]])
1111    die=yes
1112 fi
1113
1114 if test "$die" = "yes"; then
1115     AC_MSG_ERROR([[
1116 ***
1117 *** Required libraries not found. Please consult the above messages
1118 *** and install them before running configure again.
1119 ***]])
1120 fi
1121
1122
1123
1124 AC_CONFIG_FILES([ m4/Makefile 
1125 Makefile
1126 po/Makefile.in
1127 intl/Makefile
1128 gl/Makefile
1129 jnlib/Makefile
1130 common/Makefile
1131 kbx/Makefile
1132 g10/Makefile
1133 sm/Makefile
1134 agent/Makefile
1135 scd/Makefile
1136 tools/Makefile
1137 doc/Makefile
1138 tests/Makefile
1139 ])
1140 AC_OUTPUT
1141
1142 #tests/pkits/Makefile
1143
1144
1145
1146
1147 echo "
1148         GnuPG v${VERSION} has been configured as follows:
1149         
1150         Platform:  $PRINTABLE_OS_NAME ($host)
1151
1152         OpenPGP:   $build_gpg
1153         S/MIME:    $build_gpgsm
1154         Agent:     $build_agent $build_agent_threaded
1155         Smartcard: $build_scdaemon $build_scdaemon_extra
1156
1157         Protect tool:      $show_gnupg_protect_tool_pgm
1158         Default agent:     $show_gnupg_agent_pgm
1159         Default pinentry:  $show_gnupg_pinentry_pgm
1160         Default scdaemon:  $show_gnupg_scdaemon_pgm
1161         Default dirmngr:   $show_gnupg_dirmngr_pgm
1162
1163         PKITS based tests: $run_pkits_tests
1164 "
1165