tools: More portable for openpty use.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998-2012 Free Software Foundation, Inc.
3 # Copyright (C) 1998-2016 Werner Koch
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <https://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.14"
23
24 # To build a release you need to create a tag with the version number
25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
26 # bump the version number immediately *after* the release and do
27 # another commit and push so that the git magic is able to work.
28 m4_define([mym4_package],[gnupg])
29 m4_define([mym4_major], [2])
30 m4_define([mym4_minor], [1])
31 m4_define([mym4_micro], [20])
32
33 # To start a new development series, i.e a new major or minor number
34 # you need to mark an arbitrary commit before the first beta release
35 # with an annotated tag.  For example the 2.1 branch starts off with
36 # the tag "gnupg-2.1-base".  This is used as the base for counting
37 # beta numbers before the first release of a series.
38
39 # Below is m4 magic to extract and compute the git revision number,
40 # the decimalized short revision number, a beta version string and a
41 # flag indicating a development version (mym4_isbeta).  Note that the
42 # m4 processing is done by autoconf and not during the configure run.
43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
49 m4_esyscmd([echo ]mym4_version[>VERSION])
50 AC_INIT([mym4_package],[mym4_version], [https://bugs.gnupg.org])
51
52 NEED_GPG_ERROR_VERSION=1.24
53
54 NEED_LIBGCRYPT_API=1
55 NEED_LIBGCRYPT_VERSION=1.7.0
56
57 NEED_LIBASSUAN_API=2
58 NEED_LIBASSUAN_VERSION=2.4.3
59
60 NEED_KSBA_API=1
61 NEED_KSBA_VERSION=1.3.4
62
63 NEED_NTBTLS_API=1
64 NEED_NTBTLS_VERSION=0.1.0
65
66 NEED_NPTH_API=1
67 NEED_NPTH_VERSION=1.2
68
69
70 NEED_GNUTLS_VERSION=3.0
71
72 NEED_SQLITE_VERSION=3.7
73
74 development_version=mym4_isbeta
75 PACKAGE=$PACKAGE_NAME
76 PACKAGE_GT=${PACKAGE_NAME}2
77 VERSION=$PACKAGE_VERSION
78
79 AC_CONFIG_AUX_DIR([build-aux])
80 AC_CONFIG_SRCDIR([sm/gpgsm.c])
81 AC_CONFIG_HEADER([config.h])
82 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
83 AC_CANONICAL_HOST
84 AB_INIT
85
86 AC_GNU_SOURCE
87
88 # Before we do anything with the C compiler, we first save the user's
89 # CFLAGS (they are restored at the end of the configure script).  This
90 # is because some configure checks don't work with -Werror, but we'd
91 # like to use -Werror with our build.
92 CFLAGS_orig=$CFLAGS
93 CFLAGS=
94
95 # Some status variables.
96 have_gpg_error=no
97 have_libgcrypt=no
98 have_libassuan=no
99 have_ksba=no
100 have_ntbtls=no
101 have_gnutls=no
102 have_sqlite=no
103 have_npth=no
104 have_libusb=no
105 have_system_resolver=no
106 gnupg_have_ldap="n/a"
107
108 use_zip=yes
109 use_bzip2=yes
110 use_exec=yes
111 use_trust_models=yes
112 use_tofu=yes
113 use_libdns=yes
114 card_support=yes
115 use_ccid_driver=auto
116 dirmngr_auto_start=yes
117 use_tls_library=no
118 large_secmem=no
119 show_tor_support=no
120
121
122 GNUPG_BUILD_PROGRAM(gpg, yes)
123 GNUPG_BUILD_PROGRAM(gpgsm, yes)
124 # The agent is a required part and can't be disabled anymore.
125 build_agent=yes
126 GNUPG_BUILD_PROGRAM(scdaemon, yes)
127 GNUPG_BUILD_PROGRAM(g13, no)
128 GNUPG_BUILD_PROGRAM(dirmngr, yes)
129 GNUPG_BUILD_PROGRAM(tools, yes)
130 GNUPG_BUILD_PROGRAM(doc, yes)
131 GNUPG_BUILD_PROGRAM(symcryptrun, no)
132 # We use gpgtar to unpack test data, hence we always build it.  If the
133 # user opts out, we simply don't install it.
134 GNUPG_BUILD_PROGRAM(gpgtar, yes)
135 GNUPG_BUILD_PROGRAM(wks-tools, no)
136
137 AC_SUBST(PACKAGE)
138 AC_SUBST(PACKAGE_GT)
139 AC_SUBST(VERSION)
140 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
141 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
142                                 [Name of this package for gettext])
143 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
144 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
145                                         [Bug report address])
146 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
147                                        [Required version of Libgcrypt])
148 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
149                                        [Required version of Libksba])
150 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
151                                        [Required version of NTBTLS])
152
153
154
155 # The default is to use the modules from this package and the few
156 # other packages in a standard place; i.e where this package gets
157 # installed.  With these options it is possible to override these
158 # ${prefix} depended values with fixed paths, which can't be replaced
159 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
160 AC_ARG_WITH(agent-pgm,
161     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
162           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
163 AC_SUBST(GNUPG_AGENT_PGM)
164 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
165 show_gnupg_agent_pgm="(default)"
166 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
167
168 AC_ARG_WITH(pinentry-pgm,
169     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
170           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
171 AC_SUBST(GNUPG_PINENTRY_PGM)
172 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
173 show_gnupg_pinentry_pgm="(default)"
174 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
175
176
177 AC_ARG_WITH(scdaemon-pgm,
178     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
179           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
180 AC_SUBST(GNUPG_SCDAEMON_PGM)
181 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
182 show_gnupg_scdaemon_pgm="(default)"
183 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
184
185
186 AC_ARG_WITH(dirmngr-pgm,
187     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
188           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
189 AC_SUBST(GNUPG_DIRMNGR_PGM)
190 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
191 show_gnupg_dirmngr_pgm="(default)"
192 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
193
194 AC_ARG_WITH(protect-tool-pgm,
195     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
196           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
197 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
198 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
199 show_gnupg_protect_tool_pgm="(default)"
200 test -n "$GNUPG_PROTECT_TOOL_PGM" \
201       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
202
203 AC_ARG_WITH(dirmngr-ldap-pgm,
204     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmngr ldap wrapper)],
205           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
206 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
207 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
208 show_gnupg_dirmngr_ldap_pgm="(default)"
209 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
210       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
211
212 #
213 # On some platforms gpg2 is usually installed as gpg without using a
214 # symlink.  For correct operation of gpgconf it needs to know the
215 # installed name of gpg.  This option sets "gpg2"'s installed name to
216 # just "gpg".  Note that it might be required to rename gpg2 to gpg
217 # manually after the build process.
218 #
219 AC_ARG_ENABLE(gpg2-is-gpg,
220     AC_HELP_STRING([--enable-gpg2-is-gpg],[Set installed name of gpg2 to gpg]),
221     gpg2_is_gpg=$enableval)
222 if test "$gpg2_is_gpg" != "yes"; then
223    AC_DEFINE(USE_GPG2_HACK, 1, [Define to install gpg as gpg2])
224 fi
225 AM_CONDITIONAL(USE_GPG2_HACK, test "$gpg2_is_gpg" != "yes")
226
227
228 # SELinux support includes tracking of sensitive files to avoid
229 # leaking their contents through processing these files by gpg itself
230 AC_MSG_CHECKING([whether SELinux support is requested])
231 AC_ARG_ENABLE(selinux-support,
232               AC_HELP_STRING([--enable-selinux-support],
233                              [enable SELinux support]),
234               selinux_support=$enableval, selinux_support=no)
235 AC_MSG_RESULT($selinux_support)
236
237
238 AC_MSG_CHECKING([whether to allocate extra secure memory])
239 AC_ARG_ENABLE(large-secmem,
240               AC_HELP_STRING([--enable-large-secmem],
241                              [allocate extra secure memory]),
242               large_secmem=$enableval, large_secmem=no)
243 AC_MSG_RESULT($large_secmem)
244 if test "$large_secmem" = yes ; then
245    SECMEM_BUFFER_SIZE=65536
246 else
247    SECMEM_BUFFER_SIZE=32768
248 fi
249 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
250                    [Size of secure memory buffer])
251
252 AC_MSG_CHECKING([whether to enable trust models])
253 AC_ARG_ENABLE(trust-models,
254               AC_HELP_STRING([--disable-trust-models],
255                              [disable all trust models except "always"]),
256               use_trust_models=$enableval)
257 AC_MSG_RESULT($use_trust_models)
258 if test "$use_trust_models" = no ; then
259     AC_DEFINE(NO_TRUST_MODELS, 1,
260              [Define to include only trust-model always])
261 fi
262
263 AC_MSG_CHECKING([whether to enable TOFU])
264 AC_ARG_ENABLE(tofu,
265                 AC_HELP_STRING([--disable-tofu],
266                                [disable the TOFU trust model]),
267               use_tofu=$enableval, use_tofu=$use_trust_models)
268 AC_MSG_RESULT($use_tofu)
269 if test "$use_trust_models" = no && test "$use_tofu" = yes; then
270     AC_MSG_ERROR([both --disable-trust-models and --enable-tofu given])
271 fi
272
273 AC_MSG_CHECKING([whether to enable libdns])
274 AC_ARG_ENABLE(libdns,
275                 AC_HELP_STRING([--disable-libdns],
276                                [do not build with libdns support]),
277               use_libdns=$enableval, use_libdns=yes)
278 AC_MSG_RESULT($use_libdns)
279 if test x"$use_libdns" = xyes ; then
280     AC_DEFINE(USE_LIBDNS, 1, [Build with integrated libdns support])
281 fi
282 AM_CONDITIONAL(USE_LIBDNS, test "$use_libdns" = yes)
283
284
285 #
286 # Options to disable algorithm
287 #
288
289 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
290 # Elgamal is a MUST algorithm
291 # DSA is a MUST algorithm
292 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
293 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
294 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
295
296 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
297 # 3DES is a MUST algorithm
298 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
299 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
300 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
301 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
302 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
303 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
304 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
305 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
306 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
307
308 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
309 # SHA1 is a MUST algorithm
310 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
311 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
312 # SHA256 is a MUST algorithm for GnuPG.
313 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
314 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
315
316
317 # Allow disabling of zip support.
318 # This is in general not a good idea because according to rfc4880 OpenPGP
319 # implementations SHOULD support ZLIB.
320 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
321 AC_ARG_ENABLE(zip,
322    AC_HELP_STRING([--disable-zip],
323                   [disable the ZIP and ZLIB compression algorithm]),
324    use_zip=$enableval)
325 AC_MSG_RESULT($use_zip)
326
327 # Allow disabling of bzib2 support.
328 # It is defined only after we confirm the library is available later
329 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
330 AC_ARG_ENABLE(bzip2,
331    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
332    use_bzip2=$enableval)
333 AC_MSG_RESULT($use_bzip2)
334
335 # Configure option to allow or disallow execution of external
336 # programs, like a photo viewer.
337 AC_MSG_CHECKING([whether to enable external program execution])
338 AC_ARG_ENABLE(exec,
339     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
340     use_exec=$enableval)
341 AC_MSG_RESULT($use_exec)
342 if test "$use_exec" = no ; then
343     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
344 fi
345
346 if test "$use_exec" = yes ; then
347   AC_MSG_CHECKING([whether to enable photo ID viewing])
348   AC_ARG_ENABLE(photo-viewers,
349       [  --disable-photo-viewers disable photo ID viewers],
350       [if test "$enableval" = no ; then
351          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
352       fi],enableval=yes)
353   gnupg_cv_enable_photo_viewers=$enableval
354   AC_MSG_RESULT($enableval)
355
356   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
357     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
358     AC_ARG_WITH(photo-viewer,
359         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
360         [if test "$withval" = yes ; then
361            withval=no
362         elif test "$withval" != no ; then
363            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
364                             [if set, restrict photo-viewer to this])
365         fi],withval=no)
366     AC_MSG_RESULT($withval)
367   fi
368 fi
369
370
371 #
372 # Check for the key/uid cache size.  This can't be zero, but can be
373 # pretty small on embedded systems.  This is used for the gpg part.
374 #
375 AC_MSG_CHECKING([for the size of the key and uid cache])
376 AC_ARG_ENABLE(key-cache,
377         AC_HELP_STRING([--enable-key-cache=SIZE],
378                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
379 if test "$enableval" = "no"; then
380    enableval=5
381 elif test "$enableval" = "yes" || test "$enableval" = ""; then
382    enableval=4096
383 fi
384 changequote(,)dnl
385 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
386 changequote([,])dnl
387 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
388    AC_MSG_ERROR([invalid key-cache size])
389 fi
390 AC_MSG_RESULT($key_cache_size)
391 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
392                   [Size of the key and UID caches])
393
394
395
396 #
397 # Check whether we want to use Linux capabilities
398 #
399 AC_MSG_CHECKING([whether use of capabilities is requested])
400 AC_ARG_WITH(capabilities,
401     [  --with-capabilities     use linux capabilities [default=no]],
402 [use_capabilities="$withval"],[use_capabilities=no])
403 AC_MSG_RESULT($use_capabilities)
404
405 #
406 # Check whether to disable the card support
407 AC_MSG_CHECKING([whether smartcard support is requested])
408 AC_ARG_ENABLE(card-support,
409               AC_HELP_STRING([--disable-card-support],
410                              [disable smartcard support]),
411               card_support=$enableval)
412 AC_MSG_RESULT($card_support)
413 if test "$card_support" = yes ; then
414   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
415 else
416   build_scdaemon=no
417 fi
418
419 #
420 # Allow disabling of internal CCID support.
421 # It is defined only after we confirm the library is available later
422 #
423 AC_MSG_CHECKING([whether to enable the internal CCID driver])
424 AC_ARG_ENABLE(ccid-driver,
425               AC_HELP_STRING([--disable-ccid-driver],
426                              [disable the internal CCID driver]),
427               use_ccid_driver=$enableval)
428 AC_MSG_RESULT($use_ccid_driver)
429
430 AC_MSG_CHECKING([whether to auto start dirmngr])
431 AC_ARG_ENABLE(dirmngr-auto-start,
432               AC_HELP_STRING([--disable-dirmngr-auto-start],
433                              [disable auto starting of the dirmngr]),
434               dirmngr_auto_start=$enableval)
435 AC_MSG_RESULT($dirmngr_auto_start)
436 if test "$dirmngr_auto_start" = yes ; then
437     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
438               [Define to enable auto starting of the dirmngr])
439 fi
440
441
442 #
443 # To avoid double inclusion of config.h which might happen at some
444 # places, we add the usual double inclusion protection at the top of
445 # config.h.
446 #
447 AH_TOP([
448 #ifndef GNUPG_CONFIG_H_INCLUDED
449 #define GNUPG_CONFIG_H_INCLUDED
450 ])
451
452 #
453 # Stuff which goes at the bottom of config.h.
454 #
455 AH_BOTTOM([
456 /* This is the major version number of GnuPG so that
457    source included files can test for this.  Note, that
458    we use 2 here even for GnuPG 1.9.x. */
459 #define GNUPG_MAJOR_VERSION 2
460
461 /* Now to separate file name parts.
462    Please note that the string version must not contain more
463    than one character because the code assumes strlen()==1 */
464 #ifdef HAVE_DOSISH_SYSTEM
465 #define DIRSEP_C '\\'
466 #define DIRSEP_S "\\"
467 #define EXTSEP_C '.'
468 #define EXTSEP_S "."
469 #define PATHSEP_C ';'
470 #define PATHSEP_S ";"
471 #define EXEEXT_S ".exe"
472 #else
473 #define DIRSEP_C '/'
474 #define DIRSEP_S "/"
475 #define EXTSEP_C '.'
476 #define EXTSEP_S "."
477 #define PATHSEP_C ':'
478 #define PATHSEP_S ":"
479 #define EXEEXT_S ""
480 #endif
481
482 /* This is the same as VERSION, but should be overridden if the
483    platform cannot handle things like dots '.' in filenames. Set
484    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
485    uses for dots and dashes. */
486 #define SAFE_VERSION VERSION
487 #define SAFE_VERSION_DOT  '.'
488 #define SAFE_VERSION_DASH '-'
489
490 /* Some global constants. */
491 #ifdef HAVE_DOSISH_SYSTEM
492 # ifdef HAVE_DRIVE_LETTERS
493 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
494 # else
495 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
496 # endif
497 #elif defined(__VMS)
498 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
499 #else
500 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
501 #endif
502 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
503 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
504
505 /* For some systems (DOS currently), we hardcode the path here.  For
506    POSIX systems the values are constructed by the Makefiles, so that
507    the values may be overridden by the make invocations; this is to
508    comply with the GNU coding standards.  Note that these values are
509    only defaults.  */
510 #ifdef HAVE_DOSISH_SYSTEM
511 # ifdef HAVE_DRIVE_LETTERS
512 #  define GNUPG_BINDIR      "c:\\gnupg"
513 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
514 #  define GNUPG_LIBDIR      "c:\\gnupg"
515 #  define GNUPG_DATADIR     "c:\\gnupg"
516 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
517 # else
518 #  define GNUPG_BINDIR      "\\gnupg"
519 #  define GNUPG_LIBEXECDIR  "\\gnupg"
520 #  define GNUPG_LIBDIR      "\\gnupg"
521 #  define GNUPG_DATADIR     "\\gnupg"
522 #  define GNUPG_SYSCONFDIR  "\\gnupg"
523 # endif
524 #endif
525
526 /* Derive some other constants. */
527 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
528 #define EXEC_TEMPFILE_ONLY
529 #endif
530
531
532 /* We didn't define endianness above, so get it from OS macros.  This
533    is intended for making fat binary builds on OS X. */
534 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
535 #if defined(__BIG_ENDIAN__)
536 #define BIG_ENDIAN_HOST 1
537 #elif defined(__LITTLE_ENDIAN__)
538 #define LITTLE_ENDIAN_HOST 1
539 #else
540 #error "No endianness found"
541 #endif
542 #endif
543
544
545 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
546    ldap_start_tls_s because that is the actual symbol used in the
547    library.  winldap.h redefines it to our commonly used value,
548    thus we define our usual macro here.  */
549 #ifdef HAVE_LDAP_START_TLS_SA
550 # ifndef HAVE_LDAP_START_TLS_S
551 #  define HAVE_LDAP_START_TLS_S 1
552 # endif
553 #endif
554
555 /* Provide the es_ macro for estream.  */
556 #define GPGRT_ENABLE_ES_MACROS 1
557
558 /* Tell libgcrypt not to use its own libgpg-error implementation. */
559 #define USE_LIBGPG_ERROR 1
560
561 /* Tell Libgcrypt not to include deprecated definitions.  */
562 #define GCRYPT_NO_DEPRECATED 1
563
564 /* Our HTTP code is used in estream mode.  */
565 #define HTTP_USE_ESTREAM 1
566
567 /* Under W32 we do an explicit socket initialization, thus we need to
568    avoid the on-demand initialization which would also install an atexit
569    handler.  */
570 #define HTTP_NO_WSASTARTUP
571
572 /* Under Windows we use the gettext code from libgpg-error.  */
573 #define GPG_ERR_ENABLE_GETTEXT_MACROS
574
575 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
576 #define GPG_ERR_ENABLE_ERRNO_MACROS
577
578 #endif /*GNUPG_CONFIG_H_INCLUDED*/
579 ])
580
581
582 AM_MAINTAINER_MODE
583 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
584
585 # Checks for programs.
586 AC_MSG_NOTICE([checking for programs])
587 AC_PROG_MAKE_SET
588 AM_SANITY_CHECK
589 missing_dir=`cd $ac_aux_dir && pwd`
590 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
591 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
592 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
593 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
594 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
595 AM_SILENT_RULES
596 AC_PROG_AWK
597 AC_PROG_CC
598 AC_PROG_CPP
599 AM_PROG_CC_C_O
600 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
601   AC_MSG_ERROR([[No C-89 compiler found]])
602 fi
603 AC_PROG_INSTALL
604 AC_PROG_LN_S
605 AC_PROG_RANLIB
606 AC_CHECK_TOOL(AR, ar, :)
607 AC_PATH_PROG(PERL,"perl")
608 AC_CHECK_TOOL(WINDRES, windres, :)
609 AC_ISC_POSIX
610 AC_SYS_LARGEFILE
611 GNUPG_CHECK_USTAR
612
613
614 # We need to compile and run a program on the build machine.  A
615 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
616 # the AC archive is broken for autoconf 2.57.  Given that there is no
617 # newer version of that macro, we assume that it is also broken for
618 # autoconf 2.61 and thus we use a simple but usually sufficient
619 # approach.
620 AC_MSG_CHECKING(for cc for build)
621 if test "$cross_compiling" = "yes"; then
622   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
623 else
624   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
625 fi
626 AC_MSG_RESULT($CC_FOR_BUILD)
627 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
628
629 # We need to call this macro because other pkg-config macros are
630 # not always used.
631 PKG_PROG_PKG_CONFIG
632
633
634 try_gettext=yes
635 require_iconv=yes
636 have_dosish_system=no
637 have_w32_system=no
638 have_w32ce_system=no
639 have_android_system=no
640 use_simple_gettext=no
641 use_ldapwrapper=yes
642 mmap_needed=yes
643 case "${host}" in
644     *-mingw32*)
645         # special stuff for Windoze NT
646         ac_cv_have_dev_random=no
647         AC_DEFINE(USE_ONLY_8DOT3,1,
648                   [Set this to limit filenames to the 8.3 format])
649         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
650                   [Because the Unix gettext has too much overhead on
651                    MingW32 systems and these systems lack Posix functions,
652                    we use a simplified version of gettext])
653         have_dosish_system=yes
654         have_w32_system=yes
655         require_iconv=no
656         use_ldapwrapper=no  # Fixme: Do this only for CE.
657         case "${host}" in
658           *-mingw32ce*)
659             have_w32ce_system=yes
660             ;;
661           *)
662             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
663                       [Defined if the OS supports drive letters.])
664             ;;
665         esac
666         try_gettext="no"
667         use_simple_gettext=yes
668         mmap_needed=no
669         ;;
670     i?86-emx-os2 | i?86-*-os2*emx )
671         # OS/2 with the EMX environment
672         ac_cv_have_dev_random=no
673         AC_DEFINE(HAVE_DRIVE_LETTERS)
674         have_dosish_system=yes
675         try_gettext="no"
676         ;;
677
678     i?86-*-msdosdjgpp*)
679         # DOS with the DJGPP environment
680         ac_cv_have_dev_random=no
681         AC_DEFINE(HAVE_DRIVE_LETTERS)
682         have_dosish_system=yes
683         try_gettext="no"
684         ;;
685
686     *-*-hpux*)
687         if test -z "$GCC" ; then
688             CFLAGS="-Ae -D_HPUX_SOURCE $CFLAGS"
689         fi
690         ;;
691     *-dec-osf4*)
692         if test -z "$GCC" ; then
693             # Suppress all warnings
694             # to get rid of the unsigned/signed char mismatch warnings.
695             CFLAGS="-w $CFLAGS"
696         fi
697         ;;
698     *-dec-osf5*)
699         if test -z "$GCC" ; then
700             # Use the newer compiler `-msg_disable ptrmismatch1' to
701             # get rid of the unsigned/signed char mismatch warnings.
702             # Using this may hide other pointer mismatch warnings, but
703             # it at least lets other warning classes through
704             CFLAGS="-msg_disable ptrmismatch1 $CFLAGS"
705         fi
706         ;;
707     m68k-atari-mint)
708         ;;
709     *-linux-android*)
710         have_android_system=yes
711         # Android is fully utf-8 and we do not want to use iconv to
712         # keeps things simple
713         require_iconv=no
714         ;;
715     *)
716        ;;
717 esac
718
719 if test "$have_dosish_system" = yes; then
720    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
721              [Defined if we run on some of the PCDOS like systems
722               (DOS, Windoze. OS/2) with special properties like
723               no file modes, case insensitive file names and preferred
724               use of backslashes as directory name separators.])
725 fi
726 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
727
728 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
729
730 if test "$have_w32_system" = yes; then
731    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
732    if test "$have_w32ce_system" = yes; then
733       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
734    fi
735 fi
736 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
737 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
738
739 if test "$have_android_system" = yes; then
740    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
741 fi
742 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
743
744
745 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
746 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
747
748
749 #
750 # Checks for libraries.
751 #
752 AC_MSG_NOTICE([checking for libraries])
753
754
755 #
756 # libgpg-error is a library with error codes shared between GnuPG
757 # related projects.
758 #
759 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
760                   have_gpg_error=yes,have_gpg_error=no)
761
762
763 #
764 # Libgcrypt is our generic crypto library
765 #
766 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
767         have_libgcrypt=yes,have_libgcrypt=no)
768
769
770 #
771 # libassuan is used for IPC
772 #
773 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
774                   have_libassuan=yes,have_libassuan=no)
775 if test "$have_libassuan" = "yes"; then
776   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
777                      [version of the libassuan library])
778   show_tor_support="only .onion"
779 fi
780
781
782 #
783 # libksba is our X.509 support library
784 #
785 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
786
787
788 #
789 # libusb allows us to use the integrated CCID smartcard reader driver.
790 #
791 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
792 if test "$use_ccid_driver" = auto || test "$use_ccid_driver" = yes; then
793    case "${host}" in
794      *-mingw32*)
795        LIBUSB_NAME=
796        LIBUSB_LIBS=
797        LIBUSB_CPPFLAGS=
798        ;;
799      *-*-darwin*)
800        LIBUSB_NAME=usb-1.0
801        LIBUSB_LIBS="-Wl,-framework,CoreFoundation -Wl,-framework,IOKit"
802        ;;
803      *-*-freebsd*)
804        # FreeBSD has a native 1.0 compatible library by -lusb.
805        LIBUSB_NAME=usb
806        LIBUSB_LIBS=
807        ;;
808      *)
809        LIBUSB_NAME=usb-1.0
810        LIBUSB_LIBS=
811        ;;
812    esac
813 fi
814 if test x"$LIBUSB_NAME" != x ; then
815    AC_CHECK_LIB($LIBUSB_NAME, libusb_init,
816                 [ LIBUSB_LIBS="-l$LIBUSB_NAME $LIBUSB_LIBS"
817                   have_libusb=yes ])
818    AC_MSG_CHECKING([libusb include dir])
819    usb_incdir_found="no"
820    for _incdir in "" "/usr/include/libusb-1.0" "/usr/local/include/libusb-1.0"; do
821      _libusb_save_cppflags=$CPPFLAGS
822      if test -n "${_incdir}"; then
823        CPPFLAGS="-I${_incdir} ${CPPFLAGS}"
824      fi
825      AC_PREPROC_IFELSE([AC_LANG_SOURCE([[@%:@include <libusb.h>]])],
826      [usb_incdir=${_incdir}; usb_incdir_found="yes"], [])
827      CPPFLAGS=${_libusb_save_cppflags}
828      if test "$usb_incdir_found" = "yes"; then
829        break
830      fi
831    done
832    if test "$usb_incdir_found" = "yes"; then
833      AC_MSG_RESULT([${usb_incdir}])
834    else
835      AC_MSG_RESULT([not found])
836      usb_incdir=""
837      have_libusb=no
838      if test "$use_ccid_driver" != yes; then
839        use_ccid_driver=no
840      fi
841      LIBUSB_LIBS=""
842    fi
843
844    if test "$have_libusb" = yes; then
845      AC_DEFINE(HAVE_LIBUSB,1, [defined if libusb is available])
846    fi
847    if test x"$usb_incdir" = x; then
848      LIBUSB_CPPFLAGS=""
849    else
850      LIBUSB_CPPFLAGS="-I${usb_incdir}"
851    fi
852 fi
853 AC_SUBST(LIBUSB_LIBS)
854 AC_SUBST(LIBUSB_CPPFLAGS)
855
856 #
857 # Check wether it is necessary to link against libdl.
858 # (For example to load libpcsclite)
859 #
860 gnupg_dlopen_save_libs="$LIBS"
861 LIBS=""
862 AC_SEARCH_LIBS(dlopen, c dl,,,)
863 DL_LIBS=$LIBS
864 AC_SUBST(DL_LIBS)
865 LIBS="$gnupg_dlopen_save_libs"
866
867
868 # Checks for g10
869
870 AC_ARG_ENABLE(sqlite,
871                 AC_HELP_STRING([--disable-sqlite],
872                                [disable the use of SQLITE]),
873               try_sqlite=$enableval, try_sqlite=yes)
874
875 if test x"$use_tofu" = xyes ; then
876   if test x"$try_sqlite" = xyes ; then
877     PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $NEED_SQLITE_VERSION],
878                                  [have_sqlite=yes],
879                                  [have_sqlite=no])
880   fi
881   if test "$have_sqlite" = "yes"; then
882     :
883     AC_SUBST([SQLITE3_CFLAGS])
884     AC_SUBST([SQLITE3_LIBS])
885   else
886     use_tofu=no
887     tmp=$(echo "$SQLITE3_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
888     AC_MSG_WARN([[
889 ***
890 *** Building without SQLite support - TOFU disabled
891 ***
892 *** $tmp]])
893   fi
894 fi
895
896 AM_CONDITIONAL(SQLITE3, test "$have_sqlite" = "yes")
897
898 if test x"$use_tofu" = xyes ; then
899     AC_DEFINE(USE_TOFU, 1, [Enable to build the TOFU code])
900 fi
901
902
903 # Checks for g13
904
905 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
906 AC_DEFINE_UNQUOTED(ENCFS,
907         "${ENCFS}", [defines the filename of the encfs program])
908
909 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
910 AC_DEFINE_UNQUOTED(FUSERMOUNT,
911         "${FUSERMOUNT}", [defines the filename of the fusermount program])
912
913
914 # Checks for dirmngr
915
916
917 #
918 # Checks for symcryptrun:
919 #
920
921 # libutil has openpty() and login_tty().
922 AC_CHECK_LIB(util, openpty,
923               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
924                 AC_DEFINE(HAVE_LIBUTIL,1,
925                          [defined if libutil is available])
926              ])
927 AC_SUBST(LIBUTIL_LIBS)
928
929 # shred is used to clean temporary plain text files.
930 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
931 AC_DEFINE_UNQUOTED(SHRED,
932         "${SHRED}", [defines the filename of the shred program])
933
934
935 #
936 # Check whether the nPth library is available
937 #
938 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
939 if test "$have_npth" = "yes"; then
940   AC_DEFINE(HAVE_NPTH, 1,
941               [Defined if the New Portable Thread Library is available])
942   AC_DEFINE(USE_NPTH, 1,
943               [Defined if support for nPth is requested and nPth is available])
944 else
945   AC_MSG_WARN([[
946 ***
947 *** To support concurrent access for example in gpg-agent and the SCdaemon
948 *** we need the support of the New Portable Threads Library.
949 ***]])
950 fi
951
952
953 #
954 # NTBTLS is our TLS library.  If it is not available fallback to
955 # GNUTLS.
956 #
957 AC_ARG_ENABLE(ntbtls,
958               AC_HELP_STRING([--disable-ntbtls],
959                              [disable the use of NTBTLS as TLS library]),
960               try_ntbtls=$enableval, try_ntbtls=yes)
961 if test x"$try_ntbtls" = xyes ; then
962   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
963                  [have_ntbtls=yes],[have_ntbtls=no])
964 fi
965 if test "$have_ntbtls" = yes ; then
966    use_tls_library=ntbtls
967    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
968 else
969   AC_ARG_ENABLE(gnutls,
970                 AC_HELP_STRING([--disable-gnutls],
971                                [disable GNUTLS as fallback TLS library]),
972                 try_gnutls=$enableval, try_gnutls=yes)
973   if test x"$try_gnutls" = xyes ; then
974     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
975                                    [have_gnutls=yes],
976                                    [have_gnutls=no])
977   fi
978   if test "$have_gnutls" = "yes"; then
979     AC_SUBST([LIBGNUTLS_CFLAGS])
980     AC_SUBST([LIBGNUTLS_LIBS])
981     use_tls_library=gnutls
982     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
983   else
984     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
985     AC_MSG_WARN([[
986 ***
987 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
988 ***
989 *** $tmp]])
990   fi
991 fi
992
993 #
994 # Allow to set a fixed trust store file for system provided certificates.
995 #
996 AC_ARG_WITH([default-trust-store-file],
997             [AC_HELP_STRING([--with-default-trust-store-file=FILE],
998                             [Use FILE as system trust store])],
999             default_trust_store_file="$withval",
1000             default_trust_store_file="")
1001 if test x"$default_trust_store_file" = xno;then
1002   default_trust_store_file=""
1003 fi
1004 if test x"$default_trust_store_file" != x ; then
1005   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
1006     ["$default_trust_store_file"], [Use as default system trust store file])
1007 fi
1008
1009
1010 AC_MSG_NOTICE([checking for networking options])
1011
1012 #
1013 # Must check for network library requirements before doing link tests
1014 # for ldap, for example. If ldap libs are static (or dynamic and without
1015 # ELF runtime link paths), then link will fail and LDAP support won't
1016 # be detected.
1017 #
1018 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
1019         [NETLIBS="-lnsl $NETLIBS"]))
1020 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
1021         [NETLIBS="-lsocket $NETLIBS"]))
1022
1023
1024 #
1025 # Check standard resolver functions.
1026 #
1027 if test "$build_dirmngr" = "yes"; then
1028   _dns_save_libs=$LIBS
1029   LIBS=""
1030
1031   # Find the system resolver which can always be enabled with
1032   # the dirmngr option --standard-resolver.
1033
1034   # the double underscore thing is a glibc-ism?
1035   AC_SEARCH_LIBS(res_query,resolv bind,,
1036                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
1037   AC_SEARCH_LIBS(dn_expand,resolv bind,,
1038                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
1039
1040   # macOS renames dn_skipname into res_9_dn_skipname in <resolv.h>,
1041   # and for some reason fools us into believing we don't need
1042   # -lresolv even if we do.  Since the test program checking for the
1043   # symbol does not include <resolv.h>, we need to check for the
1044   # renamed symbol explicitly.
1045   AC_SEARCH_LIBS(res_9_dn_skipname,resolv bind,,
1046       AC_SEARCH_LIBS(dn_skipname,resolv bind,,
1047           AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no)))
1048
1049   if test x"$have_resolver" != xno ; then
1050
1051       # Make sure that the BIND 4 resolver interface is workable before
1052       # enabling any code that calls it.  At some point I'll rewrite the
1053       # code to use the BIND 8 resolver API.
1054       # We might also want to use libdns instead.
1055
1056     AC_MSG_CHECKING([whether the resolver is usable])
1057     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1058 #include <netinet/in.h>
1059 #include <arpa/nameser.h>
1060 #include <resolv.h>]],
1061 [[unsigned char answer[PACKETSZ];
1062   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1063   dn_skipname(0,0);
1064   dn_expand(0,0,0,0,0);
1065 ]])],have_resolver=yes,have_resolver=no)
1066     AC_MSG_RESULT($have_resolver)
1067
1068     # This is Apple-specific and somewhat bizarre as they changed the
1069     # define in bind 8 for some reason.
1070
1071     if test x"$have_resolver" != xyes ; then
1072       AC_MSG_CHECKING(
1073            [whether I can make the resolver usable with BIND_8_COMPAT])
1074       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
1075 #include <sys/types.h>
1076 #include <netinet/in.h>
1077 #include <arpa/nameser.h>
1078 #include <resolv.h>]],
1079 [[unsigned char answer[PACKETSZ];
1080   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1081   dn_skipname(0,0); dn_expand(0,0,0,0,0);
1082 ]])],[have_resolver=yes ; need_compat=yes])
1083       AC_MSG_RESULT($have_resolver)
1084     fi
1085   fi
1086
1087   if test x"$have_resolver" = xyes ; then
1088     AC_DEFINE(HAVE_SYSTEM_RESOLVER,1,[The system's resolver is usable.])
1089     DNSLIBS="$DNSLIBS $LIBS"
1090     if test x"$need_compat" = xyes ; then
1091       AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
1092     fi
1093     if test "$use_libdns" = yes; then
1094      show_tor_support=yes
1095     fi
1096   elif test "$use_libdns" = yes; then
1097     show_tor_support=yes
1098   else
1099     AC_MSG_WARN([[
1100 ***
1101 *** The system's DNS resolver is not usable.
1102 *** Dirmngr functionality is limited.
1103 ***]])
1104     show_tor_support="${show_tor_support} (no system resolver)"
1105   fi
1106
1107   if test "$have_w32_system" = yes; then
1108     if test "$use_libdns" = yes; then
1109       DNSLIBS="$DNSLIBS -liphlpapi"
1110     fi
1111   fi
1112
1113   LIBS=$_dns_save_libs
1114 fi
1115
1116 AC_SUBST(DNSLIBS)
1117
1118
1119 #
1120 # Check for LDAP
1121 #
1122 # Note that running the check changes the variable
1123 # gnupg_have_ldap from "n/a" to "no" or "yes".
1124
1125 AC_ARG_ENABLE(ldap,
1126     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1127     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1128
1129 if test "$gnupg_have_ldap" != "no" ; then
1130   if test "$build_dirmngr" = "yes" ; then
1131      GNUPG_CHECK_LDAP($NETLIBS)
1132      AC_CHECK_LIB(lber, ber_free,
1133                   [ LBER_LIBS="$LBER_LIBS -llber"
1134                     AC_DEFINE(HAVE_LBER,1,
1135                              [defined if liblber is available])
1136                     have_lber=yes
1137                  ])
1138   fi
1139 fi
1140 AC_SUBST(LBER_LIBS)
1141 if test "$gnupg_have_ldap" = "no"; then
1142     AC_MSG_WARN([[
1143 ***
1144 *** Building without LDAP support.
1145 *** No CRL access or X.509 certificate search available.
1146 ***]])
1147 fi
1148
1149 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1150 if test "$gnupg_have_ldap" = yes ; then
1151   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1152 else
1153  use_ldapwrapper=no
1154 fi
1155
1156 if test "$use_ldapwrapper" = yes; then
1157    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1158 fi
1159 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1160
1161
1162
1163
1164 #
1165 # Check for sendmail
1166 #
1167 # This isn't necessarily sendmail itself, but anything that gives a
1168 # sendmail-ish interface to the outside world.  That includes Exim,
1169 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1170 AC_ARG_WITH(mailprog,
1171       AC_HELP_STRING([--with-mailprog=NAME],
1172                      [use "NAME -t" for mail transport]),
1173              ,with_mailprog=yes)
1174 if test x"$with_mailprog" = xyes ; then
1175     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1176 elif test x"$with_mailprog" != xno ; then
1177     AC_MSG_CHECKING([for a mail transport program])
1178     AC_SUBST(SENDMAIL,$with_mailprog)
1179     AC_MSG_RESULT($with_mailprog)
1180 fi
1181
1182
1183 #
1184 # Construct a printable name of the OS
1185 #
1186 case "${host}" in
1187     *-mingw32ce*)
1188         PRINTABLE_OS_NAME="W32CE"
1189         ;;
1190     *-mingw32*)
1191         PRINTABLE_OS_NAME="MingW32"
1192         ;;
1193     *-*-cygwin*)
1194         PRINTABLE_OS_NAME="Cygwin"
1195         ;;
1196     i?86-emx-os2 | i?86-*-os2*emx )
1197         PRINTABLE_OS_NAME="OS/2"
1198         ;;
1199     i?86-*-msdosdjgpp*)
1200         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1201         try_dynload=no
1202         ;;
1203     *-linux*)
1204         PRINTABLE_OS_NAME="GNU/Linux"
1205         ;;
1206     *)
1207         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1208         ;;
1209 esac
1210 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1211                    [A human readable text with the name of the OS])
1212
1213
1214 #
1215 # Checking for iconv
1216 #
1217 if test "$require_iconv" = yes; then
1218   AM_ICONV
1219 else
1220   LIBICONV=
1221   LTLIBICONV=
1222   AC_SUBST(LIBICONV)
1223   AC_SUBST(LTLIBICONV)
1224 fi
1225
1226
1227 #
1228 # Check for gettext
1229 #
1230 # This is "GNU gnupg" - The project-id script from gettext
1231 #                       needs this string
1232 #
1233 AC_MSG_NOTICE([checking for gettext])
1234 AM_PO_SUBDIRS
1235 AM_GNU_GETTEXT_VERSION([0.17])
1236 if test "$try_gettext" = yes; then
1237   AM_GNU_GETTEXT([external],[need-ngettext])
1238
1239   # gettext requires some extra checks.  These really should be part of
1240   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1241   # function checks to here.
1242
1243   AC_CHECK_FUNCS(strchr)
1244 else
1245   USE_NLS=no
1246   USE_INCLUDED_LIBINTL=no
1247   BUILD_INCLUDED_LIBINTL=no
1248   POSUB=po
1249   AC_SUBST(USE_NLS)
1250   AC_SUBST(USE_INCLUDED_LIBINTL)
1251   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1252   AC_SUBST(POSUB)
1253 fi
1254
1255 # We use HAVE_LANGINFO_CODESET in a couple of places.
1256 AM_LANGINFO_CODESET
1257
1258 # Checks required for our use of locales
1259 gt_LC_MESSAGES
1260
1261
1262 #
1263 # SELinux support
1264 #
1265 if test "$selinux_support" = yes ; then
1266   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1267 fi
1268
1269
1270 #
1271 # Checks for header files.
1272 #
1273 AC_MSG_NOTICE([checking for header files])
1274 AC_HEADER_STDC
1275 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1276                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h     \
1277                   stdint.h signal.h util.h libutil.h termios.h])
1278
1279 AC_HEADER_TIME
1280
1281
1282 #
1283 # Checks for typedefs, structures, and compiler characteristics.
1284 #
1285 AC_MSG_NOTICE([checking for system characteristics])
1286 AC_C_CONST
1287 AC_C_INLINE
1288 AC_C_VOLATILE
1289 AC_TYPE_SIZE_T
1290 AC_TYPE_MODE_T
1291 AC_TYPE_SIGNAL
1292 AC_DECL_SYS_SIGLIST
1293
1294 gl_HEADER_SYS_SOCKET
1295 gl_TYPE_SOCKLEN_T
1296
1297 AC_SEARCH_LIBS([inet_addr], [nsl])
1298
1299 AC_ARG_ENABLE(endian-check,
1300               AC_HELP_STRING([--disable-endian-check],
1301               [disable the endian check and trust the OS provided macros]),
1302               endiancheck=$enableval,endiancheck=yes)
1303
1304 if test x"$endiancheck" = xyes ; then
1305   GNUPG_CHECK_ENDIAN
1306 fi
1307
1308 # fixme: we should get rid of the byte type
1309 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1310 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1311 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1312 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1313 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1314
1315 AC_CHECK_SIZEOF(unsigned short)
1316 AC_CHECK_SIZEOF(unsigned int)
1317 AC_CHECK_SIZEOF(unsigned long)
1318 AC_CHECK_SIZEOF(unsigned long long)
1319 AC_HEADER_TIME
1320 AC_CHECK_SIZEOF(time_t,,[[
1321 #include <stdio.h>
1322 #if TIME_WITH_SYS_TIME
1323 # include <sys/time.h>
1324 # include <time.h>
1325 #else
1326 # if HAVE_SYS_TIME_H
1327 #  include <sys/time.h>
1328 # else
1329 #  include <time.h>
1330 # endif
1331 #endif
1332 ]])
1333 GNUPG_TIME_T_UNSIGNED
1334
1335
1336 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1337    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1338    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1339     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1340 fi
1341
1342
1343 #
1344 # Checks for library functions.
1345 #
1346 AC_MSG_NOTICE([checking for library functions])
1347 AC_CHECK_DECLS(getpagesize)
1348 AC_FUNC_FSEEKO
1349 AC_FUNC_VPRINTF
1350 AC_FUNC_FORK
1351 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1352 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1353 AC_CHECK_FUNCS([setenv unsetenv fcntl ftruncate inet_ntop])
1354 AC_CHECK_FUNCS([canonicalize_file_name])
1355 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1356 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1357 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1358 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1359 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1360                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1361                 flockfile funlockfile getpwnam getpwuid \
1362                 getenv inet_pton strpbrk])
1363
1364 # On some systems (e.g. Solaris) nanosleep requires linking to librl.
1365 # Given that we use nanosleep only as an optimization over a select
1366 # based wait function we want it only if it is available in libc.
1367 _save_libs="$LIBS"
1368 AC_SEARCH_LIBS([nanosleep], [],
1369                [AC_DEFINE(HAVE_NANOSLEEP,1,
1370                 [Define to 1 if you have the `nanosleep' function in libc.])])
1371 LIBS="$_save_libs"
1372
1373
1374 # See whether libc supports the Linux inotify interface
1375 case "${host}" in
1376     *-*-linux*)
1377         AC_CHECK_FUNCS([inotify_init])
1378         ;;
1379 esac
1380
1381
1382 if test "$have_android_system" = yes; then
1383    # On Android ttyname is a stub but prints an error message.
1384    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1385              [Defined if ttyname does not work properly])
1386 fi
1387
1388 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1389
1390 # Dirmngr requires mmap on Unix systems.
1391 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1392   AC_MSG_ERROR([[Sorry, the current implemenation requires mmap.]])
1393 fi
1394
1395
1396 #
1397 # Check for the getsockopt SO_PEERCRED
1398 # (This has been copied from libassuan)
1399 #
1400 AC_MSG_CHECKING(for SO_PEERCRED)
1401 AC_CACHE_VAL(gnupg_cv_sys_so_peercred,
1402       [AC_TRY_COMPILE([#include <sys/socket.h>],
1403          [struct ucred cr;
1404           int cl = sizeof cr;
1405           getsockopt (1, SOL_SOCKET, SO_PEERCRED, &cr, &cl);],
1406           gnupg_cv_sys_so_peercred=yes,
1407           gnupg_cv_sys_so_peercred=no)
1408        ])
1409 AC_MSG_RESULT($gnupg_cv_sys_so_peercred)
1410
1411 if test $gnupg_cv_sys_so_peercred = yes; then
1412   AC_DEFINE(HAVE_SO_PEERCRED, 1,
1413             [Defined if SO_PEERCRED is supported (Linux specific)])
1414 else
1415   # Check for the getsockopt LOCAL_PEEREID (NetBSD)
1416   AC_MSG_CHECKING(for LOCAL_PEEREID)
1417   AC_CACHE_VAL(gnupg_cv_sys_so_local_peereid,
1418       [AC_TRY_COMPILE([#include <sys/socket.>
1419          #include <sys/un.h>],
1420          [struct unpcbid unp;
1421           int unpl = sizeof unp;
1422           getsockopt (1, SOL_SOCKET, LOCAL_PEEREID, &unp, &unpl);],
1423           gnupg_cv_sys_so_local_peereid=yes,
1424           gnupg_cv_sys_so_local_peereid=no)
1425        ])
1426   AC_MSG_RESULT($gnupg_cv_sys_so_local_peereid)
1427
1428   if test $gnupg_cv_sys_so_local_peereid = yes; then
1429     AC_DEFINE(HAVE_LOCAL_PEEREID, 1,
1430               [Defined if LOCAL_PEEREID is supported (NetBSD specific)])
1431   else
1432     # (Open)Solaris
1433     AC_CHECK_FUNCS([getpeerucred], AC_CHECK_HEADERS([ucred.h]))
1434     if test $ac_cv_func_getpeerucred != yes; then
1435         # FreeBSD
1436         AC_CHECK_FUNCS([getpeereid])
1437     fi
1438   fi
1439 fi
1440
1441
1442 #
1443 # W32 specific test
1444 #
1445 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1446
1447 #
1448 # Sanity check regex.  Tests adapted from mutt.
1449 #
1450 AC_MSG_CHECKING([whether regular expression support is requested])
1451 AC_ARG_ENABLE(regex,
1452   AC_HELP_STRING([--disable-regex],
1453     [do not handle regular expressions in trust signatures]),
1454   use_regex=$enableval, use_regex=yes)
1455 AC_MSG_RESULT($use_regex)
1456
1457 if test "$use_regex" = yes ; then
1458   _cppflags="${CPPFLAGS}"
1459   _ldflags="${LDFLAGS}"
1460   AC_ARG_WITH(regex,
1461      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1462       [
1463       if test -d "$withval" ; then
1464         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1465         LDFLAGS="${LDFLAGS} -L$withval/lib"
1466       fi
1467       ],withval="")
1468
1469   # Does the system have regex functions at all?
1470   AC_SEARCH_LIBS([regcomp], [regex])
1471   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1472
1473   if test $gnupg_cv_have_regex = no; then
1474     use_regex=no
1475   else
1476     if test x"$cross_compiling" = xyes; then
1477       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1478     else
1479       AC_CACHE_CHECK([whether your system's regexp library is broken],
1480        [gnupg_cv_regex_broken],
1481        AC_TRY_RUN([
1482 #include <unistd.h>
1483 #include <regex.h>
1484 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1485        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1486
1487       if test $gnupg_cv_regex_broken = yes; then
1488         AC_MSG_WARN([your regex is broken - disabling regex use])
1489         use_regex=no
1490       fi
1491     fi
1492   fi
1493   CPPFLAGS="${_cppflags}"
1494   LDFLAGS="${_ldflags}"
1495 fi
1496
1497 if test "$use_regex" != yes ; then
1498   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1499 fi
1500 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1501
1502
1503
1504 #
1505 # Do we have zlib? Must do it here because Solaris failed
1506 # when compiling a conftest (due to the "-lz" from LIBS).
1507 # Note that we combine zlib and bzlib2 in ZLIBS.
1508 #
1509 if test "$use_zip" = yes ; then
1510   _cppflags="${CPPFLAGS}"
1511   _ldflags="${LDFLAGS}"
1512   AC_ARG_WITH(zlib,
1513     [  --with-zlib=DIR         use libz in DIR],[
1514       if test -d "$withval"; then
1515         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1516         LDFLAGS="${LDFLAGS} -L$withval/lib"
1517       fi
1518     ])
1519
1520   AC_CHECK_HEADER(zlib.h,
1521      AC_CHECK_LIB(z, deflateInit2_,
1522        [
1523        ZLIBS="-lz"
1524        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1525        ],
1526        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1527        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1528 fi
1529
1530
1531 #
1532 # Check whether we can support bzip2
1533 #
1534 if test "$use_bzip2" = yes ; then
1535   _cppflags="${CPPFLAGS}"
1536   _ldflags="${LDFLAGS}"
1537   AC_ARG_WITH(bzip2,
1538      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1539       [
1540       if test -d "$withval" ; then
1541         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1542         LDFLAGS="${LDFLAGS} -L$withval/lib"
1543       fi
1544       ],withval="")
1545
1546   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1547   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1548   # woefully out of date.
1549   if test "$withval" != no ; then
1550      AC_CHECK_HEADER(bzlib.h,
1551         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1552           [
1553           have_bz2=yes
1554           ZLIBS="$ZLIBS -lbz2"
1555           AC_DEFINE(HAVE_BZIP2,1,
1556                   [Defined if the bz2 compression library is available])
1557           ],
1558           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1559           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1560   fi
1561 fi
1562 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1563 AC_SUBST(ZLIBS)
1564
1565
1566 # Check for readline support
1567 GNUPG_CHECK_READLINE
1568
1569
1570 if test "$development_version" = yes; then
1571     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1572             [Defined if this is not a regular release])
1573 fi
1574
1575 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1576
1577 GNUPG_CHECK_GNUMAKE
1578
1579 # Add some extra libs here so that previous tests don't fail for
1580 # mysterious reasons - the final link step should bail out.
1581 # W32SOCKLIBS is also defined so that if can be used for tools not
1582 # requiring any network stuff but linking to code in libcommon which
1583 # tracks in winsock stuff (e.g. init_common_subsystems).
1584 if test "$have_w32_system" = yes; then
1585    if test "$have_w32ce_system" = yes; then
1586      W32SOCKLIBS="-lws2"
1587    else
1588      W32SOCKLIBS="-lws2_32"
1589    fi
1590    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1591 fi
1592
1593 AC_SUBST(NETLIBS)
1594 AC_SUBST(W32SOCKLIBS)
1595
1596 #
1597 # Setup gcc specific options
1598 #
1599 USE_C99_CFLAGS=
1600 AC_MSG_NOTICE([checking for cc features])
1601 if test "$GCC" = yes; then
1602     mycflags=
1603     mycflags_save=$CFLAGS
1604
1605     # Check whether gcc does not emit a diagnositc for unknow -Wno-*
1606     # options.  This is the case for gcc >= 4.6
1607     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1608     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1609 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1610 #kickerror
1611 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1612     AC_MSG_RESULT($_gcc_silent_wno)
1613
1614     # Note that it is okay to use CFLAGS here because these are just
1615     # warning options and the user should have a chance of overriding
1616     # them.
1617     if test "$USE_MAINTAINER_MODE" = "yes"; then
1618         mycflags="$mycflags -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1619         mycflags="$mycflags -Wformat -Wno-format-y2k -Wformat-security"
1620         if test x"$_gcc_silent_wno" = xyes ; then
1621           _gcc_wopt=yes
1622         else
1623           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1624           CFLAGS="-Wno-missing-field-initializers"
1625           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1626                             [_gcc_wopt=yes],[_gcc_wopt=no])
1627           AC_MSG_RESULT($_gcc_wopt)
1628         fi
1629         if test x"$_gcc_wopt" = xyes ; then
1630           mycflags="$mycflags -W -Wno-sign-compare"
1631           mycflags="$mycflags -Wno-missing-field-initializers"
1632         fi
1633
1634         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1635         CFLAGS="-Wdeclaration-after-statement"
1636         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1637         AC_MSG_RESULT($_gcc_wopt)
1638         if test x"$_gcc_wopt" = xyes ; then
1639           mycflags="$mycflags -Wdeclaration-after-statement"
1640         fi
1641
1642         AC_MSG_CHECKING([if gcc supports -Wlogical-op and -Wvla])
1643         CFLAGS="-Wlogical-op -Wvla"
1644         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1645         AC_MSG_RESULT($_gcc_wopt)
1646         if test x"$_gcc_wopt" = xyes ; then
1647           mycflags="$mycflags -Wlogical-op -Wvla"
1648         fi
1649
1650     else
1651         mycflags="$mycflags -Wall"
1652     fi
1653
1654     if test x"$_gcc_silent_wno" = xyes ; then
1655       _gcc_psign=yes
1656     else
1657       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1658       CFLAGS="-Wno-pointer-sign"
1659       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1660                         [_gcc_psign=yes],[_gcc_psign=no])
1661       AC_MSG_RESULT($_gcc_psign)
1662     fi
1663     if test x"$_gcc_psign" = xyes ; then
1664        mycflags="$mycflags -Wno-pointer-sign"
1665     fi
1666
1667     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1668     CFLAGS="-Wpointer-arith"
1669     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1670     AC_MSG_RESULT($_gcc_psign)
1671     if test x"$_gcc_psign" = xyes ; then
1672        mycflags="$mycflags -Wpointer-arith"
1673     fi
1674
1675     CFLAGS="$mycflags $mycflags_save"
1676     if test "$use_libdns" = yes; then
1677        # dirmngr/dns.{c,h} require C99 and GNU extensions.  */
1678        USE_C99_CFLAGS="-std=gnu99"
1679     fi
1680 fi
1681
1682 AC_SUBST(USE_C99_CFLAGS)
1683
1684
1685 #
1686 # This is handy for debugging so the compiler doesn't rearrange
1687 # things and eliminate variables.
1688 #
1689 AC_ARG_ENABLE(optimization,
1690    AC_HELP_STRING([--disable-optimization],
1691                   [disable compiler optimization]),
1692                   [if test $enableval = no ; then
1693                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1694                    fi])
1695
1696 #
1697 # We do not want support for the GNUPG_BUILDDIR environment variable
1698 # in a released version.  However, our regression tests suite requires
1699 # this and thus we build with support for it during "make distcheck".
1700 # This configure option implements this along with the top Makefile's
1701 # AM_DISTCHECK_CONFIGURE_FLAGS.
1702 #
1703 gnupg_builddir_envvar=no
1704 AC_ARG_ENABLE(gnupg-builddir-envvar,,
1705               gnupg_builddir_envvar=$enableval)
1706 if test x"$gnupg_builddir_envvar" = x"yes"; then
1707    AC_DEFINE(ENABLE_GNUPG_BUILDDIR_ENVVAR, 1,
1708       [This is only used with "make distcheck"])
1709 fi
1710
1711 #
1712 # Add user CFLAGS.
1713 #
1714 CFLAGS="$CFLAGS $CFLAGS_orig"
1715
1716 #
1717 # Decide what to build
1718 #
1719
1720 build_scdaemon_extra=""
1721 if test "$build_scdaemon" = "yes"; then
1722   if test $have_libusb = no; then
1723      build_scdaemon_extra="without internal CCID driver"
1724   fi
1725   if test -n "$build_scdaemon_extra"; then
1726      build_scdaemon_extra="(${build_scdaemon_extra})"
1727   fi
1728 fi
1729
1730
1731 #
1732 # Set variables for use by automake makefiles.
1733 #
1734 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1735 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1736 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1737 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1738 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1739 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1740 AM_CONDITIONAL(BUILD_TOOLS,       test "$build_tools" = "yes")
1741 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1742 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1743 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1744 AM_CONDITIONAL(BUILD_WKS_TOOLS,   test "$build_wks_tools" = "yes")
1745
1746 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1747 AM_CONDITIONAL(NO_TRUST_MODELS,     test "$use_trust_models" = no)
1748 AM_CONDITIONAL(USE_TOFU,            test "$use_tofu" = yes)
1749
1750 #
1751 # Set some defines for use gpgconf.
1752 #
1753 if test "$build_gpg" = yes ; then
1754     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1755 fi
1756 if test "$build_gpgsm" = yes ; then
1757     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1758 fi
1759 if test "$build_agent" = yes ; then
1760     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1761 fi
1762 if test "$build_scdaemon" = yes ; then
1763     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1764 fi
1765 if test "$build_dirmngr" = yes ; then
1766     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if SCDAEMON is to be build])
1767 fi
1768 if test "$build_g13" = yes ; then
1769     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1770 fi
1771
1772
1773 #
1774 # Define Name strings
1775 #
1776 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1777
1778 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1779 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1780
1781 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1782 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1783
1784 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1785 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1786                                         [The displayed name of gpg-agent])
1787
1788 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1789 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1790                                        [The displayed name of scdaemon])
1791
1792 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1793 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1794                                       [The displayed name of dirmngr])
1795
1796 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1797 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1798
1799 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1800 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1801                                       [The displayed name of gpgconf])
1802
1803 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1804
1805 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1806                    [The name of the agent socket])
1807 AC_DEFINE_UNQUOTED(GPG_AGENT_EXTRA_SOCK_NAME, "S.gpg-agent.extra",
1808                    [The name of the agent socket for remote access])
1809 AC_DEFINE_UNQUOTED(GPG_AGENT_BROWSER_SOCK_NAME, "S.gpg-agent.browser",
1810                    [The name of the agent socket for browsers])
1811 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1812                    [The name of the agent socket for ssh])
1813 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1814                    [The name of the dirmngr info envvar])
1815 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1816                    [The name of the SCdaemon socket])
1817 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1818                    [The name of the dirmngr socket])
1819 AC_DEFINE_UNQUOTED(DIRMNGR_DEFAULT_KEYSERVER,
1820                    "hkps://hkps.pool.sks-keyservers.net",
1821       [The default keyserver for dirmngr to use, if none is explicitly given])
1822
1823 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1824
1825 if test "$have_w32_system" = yes; then
1826   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "\\\\Software\\\\GNU\\\\GnuPG",
1827                      [The directory part of the W32 registry keys])
1828 fi
1829
1830
1831 #
1832 # Provide information about the build.
1833 #
1834 BUILD_REVISION="mym4_revision"
1835 AC_SUBST(BUILD_REVISION)
1836 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1837                    [GIT commit id revision used to build this package])
1838
1839 changequote(,)dnl
1840 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1841 changequote([,])dnl
1842 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1843 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1844 AC_SUBST(BUILD_VERSION)
1845 AC_SUBST(BUILD_FILEVERSION)
1846
1847 AC_ARG_ENABLE([build-timestamp],
1848   AC_HELP_STRING([--enable-build-timestamp],
1849                  [set an explicit build timestamp for reproducibility.
1850                   (default is the current time in ISO-8601 format)]),
1851      [if test "$enableval" = "yes"; then
1852         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1853       else
1854         BUILD_TIMESTAMP="$enableval"
1855       fi
1856       BUILD_HOSTNAME="$ac_hostname"],
1857      [BUILD_TIMESTAMP="<none>"
1858       BUILD_HOSTNAME="<anon>"])
1859 AC_SUBST(BUILD_TIMESTAMP)
1860 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1861                    [The time this package was configured for a build])
1862 AC_SUBST(BUILD_HOSTNAME)
1863
1864
1865 #
1866 # Print errors here so that they are visible all
1867 # together and the user can acquire them all together.
1868 #
1869 die=no
1870 if test "$have_gpg_error" = "no"; then
1871    die=yes
1872    AC_MSG_NOTICE([[
1873 ***
1874 *** You need libgpg-error to build this program.
1875 **  This library is for example available at
1876 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1877 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1878 ***]])
1879 fi
1880 if test "$have_libgcrypt" = "no"; then
1881    die=yes
1882    AC_MSG_NOTICE([[
1883 ***
1884 *** You need libgcrypt to build this program.
1885 **  This library is for example available at
1886 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1887 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1888 ***]])
1889 fi
1890 if test "$have_libassuan" = "no"; then
1891    die=yes
1892    AC_MSG_NOTICE([[
1893 ***
1894 *** You need libassuan to build this program.
1895 *** This library is for example available at
1896 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1897 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1898 ***]])
1899 fi
1900 if test "$have_ksba" = "no"; then
1901     die=yes
1902     AC_MSG_NOTICE([[
1903 ***
1904 *** You need libksba to build this program.
1905 *** This library is for example available at
1906 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1907 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1908 ***]])
1909 fi
1910 if test "$gnupg_have_ldap" = yes; then
1911   if test "$have_w32ce_system" = yes; then
1912     AC_MSG_NOTICE([[
1913 *** Note that CeGCC might be broken, a package fixing this is:
1914 ***    http://files.kolab.org/local/windows-ce/
1915 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1916 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1917 ***]])
1918    fi
1919 fi
1920 if test "$have_npth" = "no"; then
1921     die=yes
1922     AC_MSG_NOTICE([[
1923 ***
1924 *** It is now required to build with support for the
1925 *** New Portable Threads Library (nPth). Please install this
1926 *** library first.  The library is for example available at
1927 ***   ftp://ftp.gnupg.org/gcrypt/npth/
1928 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1929 ***]])
1930 fi
1931
1932 if test "$require_iconv" = yes; then
1933   if test "$am_func_iconv" != yes; then
1934     die=yes
1935     AC_MSG_NOTICE([[
1936 ***
1937 *** The system does not provide a working iconv function.  Please
1938 *** install a suitable library; for example GNU Libiconv which is
1939 *** available at:
1940 ***   http://ftp.gnu.org/gnu/libiconv/
1941 ***]])
1942   fi
1943 fi
1944
1945 if test "$use_ccid_driver" = yes; then
1946   if test "$have_libusb" != yes; then
1947     die=yes
1948     AC_MSG_NOTICE([[
1949 ***
1950 *** You need libusb to build the internal ccid driver.  Please
1951 *** install a libusb suitable for your system.
1952 ***]])
1953   fi
1954 fi
1955
1956 if test "$die" = "yes"; then
1957     AC_MSG_ERROR([[
1958 ***
1959 *** Required libraries not found. Please consult the above messages
1960 *** and install them before running configure again.
1961 ***]])
1962 fi
1963
1964
1965
1966 AC_CONFIG_FILES([ m4/Makefile
1967 Makefile
1968 po/Makefile.in
1969 common/Makefile
1970 common/w32info-rc.h
1971 kbx/Makefile
1972 g10/Makefile
1973 sm/Makefile
1974 agent/Makefile
1975 scd/Makefile
1976 g13/Makefile
1977 dirmngr/Makefile
1978 tools/gpg-zip
1979 tools/Makefile
1980 doc/Makefile
1981 tests/Makefile
1982 tests/gpgscm/Makefile
1983 tests/openpgp/Makefile
1984 tests/migrations/Makefile
1985 tests/gpgsm/Makefile
1986 tests/gpgme/Makefile
1987 tests/pkits/Makefile
1988 g10/gpg.w32-manifest
1989 ])
1990
1991
1992 AC_OUTPUT
1993
1994
1995 echo "
1996         GnuPG v${VERSION} has been configured as follows:
1997
1998         Revision:  mym4_revision  (mym4_revision_dec)
1999         Platform:  $PRINTABLE_OS_NAME ($host)
2000
2001         OpenPGP:   $build_gpg
2002         S/MIME:    $build_gpgsm
2003         Agent:     $build_agent
2004         Smartcard: $build_scdaemon $build_scdaemon_extra
2005         G13:       $build_g13
2006         Dirmngr:   $build_dirmngr
2007         Gpgtar:    $build_gpgtar
2008         WKS tools: $build_wks_tools
2009
2010         Protect tool:      $show_gnupg_protect_tool_pgm
2011         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
2012         Default agent:     $show_gnupg_agent_pgm
2013         Default pinentry:  $show_gnupg_pinentry_pgm
2014         Default scdaemon:  $show_gnupg_scdaemon_pgm
2015         Default dirmngr:   $show_gnupg_dirmngr_pgm
2016
2017         Dirmngr auto start:  $dirmngr_auto_start
2018         Readline support:    $gnupg_cv_have_readline
2019         LDAP support:        $gnupg_have_ldap
2020         TLS support:         $use_tls_library
2021         TOFU support:        $use_tofu
2022         Tor support:         $show_tor_support
2023 "
2024 if test x"$use_regex" != xyes ; then
2025 echo "
2026         Warning: No regular expression support available.
2027                  OpenPGP trust signatures won't work.
2028                  gpg-check-pattern will not be built.
2029 "
2030 fi
2031 if test "x${gpg_config_script_warn}" != x; then
2032 cat <<G10EOF
2033         Warning: Mismatches between the target platform and the
2034                  to be used libraries have been detected for:
2035                   ${gpg_config_script_warn}
2036                  Please check above for more warning messages.
2037
2038 G10EOF
2039 fi