* configure.ac: Look for res_query so we can use DNS SRV, and add
[gnupg.git] / configure.ac
1 dnl Configure.ac script for GnuPG
2 dnl Copyright (C) 1998, 1999, 2000, 2001, 2002 Free Software Foundation, Inc.
3 dnl
4 dnl This file is part of GnuPG.
5 dnl
6 dnl GnuPG is free software; you can redistribute it and/or modify
7 dnl it under the terms of the GNU General Public License as published by
8 dnl the Free Software Foundation; either version 2 of the License, or
9 dnl (at your option) any later version.
10 dnl 
11 dnl GnuPG is distributed in the hope that it will be useful,
12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 dnl GNU General Public License for more details.
15 dnl 
16 dnl You should have received a copy of the GNU General Public License
17 dnl along with this program; if not, write to the Free Software
18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
19 dnl
20 dnl (Process this file with autoconf to produce a configure script.)
21 dnlAC_REVISION($Revision$)dnl
22
23 AC_PREREQ(2.52)
24
25 # Remember to change the version number immediately *after* a release
26 # and remove the "-cvs" or "rc" suffix immediately *before* a release.
27 AC_INIT(gnupg, 1.3.2-cvs, bug-gnupg@gnu.org)
28 # Set development_version to yes if the minor number is odd or you
29 # feel that the default check for a development version is not
30 # sufficient.
31 development_version=yes
32
33 ALL_LINGUAS="de"
34
35 PACKAGE=$PACKAGE_NAME
36 VERSION=$PACKAGE_VERSION
37
38 AC_CONFIG_AUX_DIR(scripts)
39 AC_CONFIG_SRCDIR(g10/g10.c)
40 AC_CANONICAL_TARGET()
41 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
42 AM_CONFIG_HEADER(config.h)
43
44 AC_SUBST(PACKAGE)
45 AC_SUBST(VERSION)
46 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
47 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
48 AC_DEFINE(_GNU_SOURCE,1,[Some tests rely on this (stpcpy) and it should be used for new programs anyway])
49
50 dnl
51 dnl  Check for random module options
52 dnl
53 AC_MSG_CHECKING([which random module to use])
54 AC_ARG_ENABLE(static-rnd,
55     [  --enable-static-rnd=[egd|unix|linux|auto]  ],
56 [use_static_rnd=$enableval], [use_static_rnd=default] )
57
58 if test "$use_static_rnd" = no; then
59     use_static_rnd=default
60 fi
61
62 case "$use_static_rnd" in
63     egd | linux | unix | default )
64       AC_MSG_RESULT($use_static_rnd)
65       ;;
66     auto )
67       AC_MSG_RESULT(automagically selected at runtime)
68       ;;
69     * )
70       AC_MSG_RESULT(invalid argument)
71       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
72       ;;
73 esac
74
75 AC_ARG_WITH(egd-socket,
76     [  --with-egd-socket=NAME  use NAME for the EGD socket],
77             egd_socket_name="$withval", egd_socket_name="" )
78 AC_DEFINE_UNQUOTED(EGD_SOCKET_NAME, "$egd_socket_name",
79                    [Define if you don't want the default EGD socket name.
80                     For details see cipher/rndegd.c])
81
82
83 dnl
84 dnl See whether the user wants to disable checking for /dev/random
85
86 AC_MSG_CHECKING([whether use of /dev/random is requested])
87 AC_ARG_ENABLE(dev-random,
88 [  --disable-dev-random    disable the use of dev random],
89     try_dev_random=$enableval, try_dev_random=yes)
90 AC_MSG_RESULT($try_dev_random)
91
92
93 dnl
94 dnl  Check other options
95 dnl
96
97 AC_MSG_CHECKING([whether assembler modules are requested])
98 AC_ARG_ENABLE(asm,
99 [  --disable-asm           do not use assembler modules],
100      try_asm_modules=$enableval, try_asm_modules=yes)
101 AC_MSG_RESULT($try_asm_modules)
102
103 AC_MSG_CHECKING([whether memory guard is requested])
104 AC_ARG_ENABLE(m-guard,
105     [  --enable-m-guard        enable memory guard facility],
106     use_m_guard=$enableval, use_m_guard=no)
107 AC_MSG_RESULT($use_m_guard)
108 if test "$use_m_guard" = yes ; then
109     AC_DEFINE(M_GUARD,1,[Define to use the (obsolete) malloc guarding feature])
110 fi
111
112 dnl See if we are disabling any algorithms or features for a smaller
113 dnl binary
114
115 try_dynload=no
116
117 use_idea=yes
118 use_cast5=yes
119 use_blowfish=yes
120 use_aes=yes
121 use_twofish=yes
122 use_tiger192=yes
123 use_sha256=yes
124 use_sha512=yes
125 use_exec=yes
126
127 AC_ARG_ENABLE(minimal,
128    AC_HELP_STRING([--enable-minimal],[build the smallest gpg binary possible]),
129    use_idea=no
130    use_cast5=no
131    use_blowfish=no
132    use_aes=no
133    use_twofish=no
134    use_tiger192=no
135    use_sha256=no
136    use_sha512=no
137    use_exec=no)
138
139 AC_MSG_CHECKING([whether to enable the IDEA cipher])
140 AC_ARG_ENABLE(idea,
141    AC_HELP_STRING([--disable-idea],[disable the IDEA cipher]),
142    use_idea=$enableval)
143 AC_MSG_RESULT($use_idea)
144 if test x"$use_idea" = xyes ; then
145    AC_DEFINE(USE_IDEA,1,[Define to include the IDEA cipher])
146
147 # We don't need idea but some people claim that they need it for
148 # research etc., so we allow to place an idea source code into the
149 # cipher directory and statically link it if available, otherwise we
150 # link to a stub.  We don't use AC_CHECK_FILE to avoid caching.
151
152    AC_MSG_CHECKING([for idea cipher module])
153    tmp=""
154    if test -f $srcdir/cipher/idea.c; then 
155       IDEA_O=idea.o
156       tmp=idea
157    else
158       IDEA_O=idea-stub.o
159       tmp=no
160       try_dynload=yes
161    fi
162    AC_SUBST(IDEA_O)
163    AC_MSG_RESULT($tmp)
164 fi
165
166 AC_MSG_CHECKING([whether to enable the CAST5 cipher])
167 AC_ARG_ENABLE(cast5,
168    AC_HELP_STRING([--disable-cast5],[disable the CAST5 cipher]),
169    use_cast5=$enableval)
170 AC_MSG_RESULT($use_cast5)
171 if test x"$use_cast5" = xyes ; then
172    AC_DEFINE(USE_CAST5,1,[Define to include the CAST5 cipher])
173 fi
174
175 AC_MSG_CHECKING([whether to enable the BLOWFISH cipher])
176 AC_ARG_ENABLE(blowfish,
177    AC_HELP_STRING([--disable-blowfish],[disable the BLOWFISH cipher]),
178    use_blowfish=$enableval)
179 AC_MSG_RESULT($use_blowfish)
180 if test x"$use_blowfish" = xyes ; then
181    AC_DEFINE(USE_BLOWFISH,1,[Define to include the BLOWFISH cipher])
182 fi
183
184 AC_MSG_CHECKING([whether to enable the AES ciphers])
185 AC_ARG_ENABLE(aes,
186    AC_HELP_STRING([--disable-aes],[disable the AES, AES192, and AES256 ciphers]),
187    use_aes=$enableval)
188 AC_MSG_RESULT($use_aes)
189 if test x"$use_aes" = xyes ; then
190    AC_DEFINE(USE_AES,1,[Define to include the AES, AES192, and AES256 ciphers])
191 fi
192
193 AC_MSG_CHECKING([whether to enable the TWOFISH cipher])
194 AC_ARG_ENABLE(twofish,
195    AC_HELP_STRING([--disable-twofish],[disable the TWOFISH cipher]),
196    use_twofish=$enableval)
197 AC_MSG_RESULT($use_twofish)
198 if test x"$use_twofish" = xyes ; then
199    AC_DEFINE(USE_TWOFISH,1,[Define to include the TWOFISH cipher])
200 fi
201
202 dnl TIGER192 is defined only after we confirm 64-bit support later
203 AC_MSG_CHECKING([whether to enable the TIGER/192 digest])
204 AC_ARG_ENABLE(tiger192,
205    AC_HELP_STRING([--disable-tiger192],[disable the TIGER/192 digest]),
206    use_tiger192=$enableval)
207 AC_MSG_RESULT($use_tiger192)
208
209 AC_MSG_CHECKING([whether to enable the SHA-256 digest])
210 AC_ARG_ENABLE(sha256,
211    AC_HELP_STRING([--disable-sha256],[disable the SHA-256 digest]),
212    use_sha256=$enableval)
213 AC_MSG_RESULT($use_sha256)
214 if test x"$use_sha256" = xyes ; then
215    AC_DEFINE(USE_SHA256,1,[Define to include the SHA-256 digest])
216 fi
217
218 dnl SHA512 is defined only after we confirm 64-bit support later
219 AC_MSG_CHECKING([whether to enable the SHA-384 and SHA-512 digests])
220 AC_ARG_ENABLE(sha512,
221    AC_HELP_STRING([--disable-sha512],[disable the SHA-384 and SHA-512 digests]),
222    use_sha512=$enableval)
223 AC_MSG_RESULT($use_sha512)
224
225 AC_MSG_CHECKING([whether to enable external program execution])
226 AC_ARG_ENABLE(exec,
227     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
228     use_exec=$enableval)
229 AC_MSG_RESULT($use_exec)
230 if test "$use_exec" = no ; then
231     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
232 fi
233
234 if test "$use_exec" = yes ; then
235   AC_MSG_CHECKING([whether to enable photo ID viewing])
236   AC_ARG_ENABLE(photo-viewers,
237       [  --disable-photo-viewers disable photo ID viewers],
238       [if test "$enableval" = no ; then
239          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
240       fi],enableval=yes)
241   gnupg_cv_enable_photo_viewers=$enableval
242   AC_MSG_RESULT($enableval)
243
244   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
245     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
246     AC_ARG_WITH(photo-viewer,
247         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
248         [if test "$withval" = yes ; then
249            withval=no
250         elif test "$withval" != no ; then
251            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
252                             [if set, restrict photo-viewer to this])
253         fi],withval=no)
254     AC_MSG_RESULT($withval)
255   fi
256
257   AC_MSG_CHECKING([whether to enable external keyserver helpers])
258   AC_ARG_ENABLE(keyserver-helpers,
259       [  --disable-keyserver-helpers  disable all external keyserver support],
260       [if test "$enableval" = no ; then
261          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
262                   [define to disable keyserver helpers])
263       fi],enableval=yes)
264   gnupg_cv_enable_keyserver_helpers=$enableval
265   AC_MSG_RESULT($enableval)
266
267   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
268     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
269     AC_ARG_ENABLE(ldap,
270     [  --disable-ldap          disable LDAP keyserver interface],
271         try_ldap=$enableval, try_ldap=yes)
272     AC_MSG_RESULT($try_ldap)
273
274     AC_MSG_CHECKING([whether HKP keyserver support is requested])
275     AC_ARG_ENABLE(hkp,
276     [  --disable-hkp           disable HKP keyserver interface],
277         try_hkp=$enableval, try_hkp=yes)
278     AC_MSG_RESULT($try_hkp)
279
280     if test "$try_hkp" = yes ; then
281       AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
282     fi
283
284     AC_MSG_CHECKING([whether email keyserver support is requested])
285     AC_ARG_ENABLE(mailto,
286     [  --disable-mailto        disable email keyserver interface],
287         try_mailto=$enableval, try_mailto=yes)
288     AC_MSG_RESULT($try_mailto)
289     fi
290
291     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
292     AC_ARG_ENABLE(keyserver-path,
293         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
294         [if test "$enableval" = no ; then
295          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
296         fi],enableval=yes)
297     AC_MSG_RESULT($enableval)
298   fi
299
300 AC_MSG_CHECKING([whether the included zlib is requested])
301 AC_ARG_WITH(included-zlib,
302     [  --with-included-zlib    use the zlib code included here],
303 [g10_force_zlib=yes], [g10_force_zlib=no] )
304 AC_MSG_RESULT($g10_force_zlib)
305
306 dnl
307 dnl Check whether we want to use Linux capabilities
308 dnl
309 AC_MSG_CHECKING([whether use of capabilities is requested])
310 AC_ARG_WITH(capabilities,
311     [  --with-capabilities     use linux capabilities [default=no]],
312 [use_capabilities="$withval"],[use_capabilities=no])
313 AC_MSG_RESULT($use_capabilities)
314
315
316 AH_BOTTOM([
317 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
318 #define EXEC_TEMPFILE_ONLY
319 #endif
320
321 #include "g10defs.h"
322 ])
323
324
325 AM_MAINTAINER_MODE
326
327 dnl Checks for programs.
328
329 AC_PROG_MAKE_SET
330 AM_SANITY_CHECK
331 missing_dir=`cd $ac_aux_dir && pwd`
332 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
333 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
334 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
335 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
336 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
337 AC_PROG_CC
338 AC_PROG_CPP
339 AC_PATH_PROG(PERL,"perl")
340 AC_ISC_POSIX
341 AC_SYS_LARGEFILE
342 AC_PROG_INSTALL
343 AC_PROG_AWK
344 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
345 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
346 GNUPG_CHECK_FAQPROG
347 GNUPG_CHECK_DOCBOOK_TO_TEXI
348
349 MPI_OPT_FLAGS=""
350
351
352 try_gettext=yes
353 case "${target}" in
354     *-*-mingw32*)
355         # special stuff for Windoze NT
356         ac_cv_have_dev_random=no
357         AC_DEFINE(USE_ONLY_8DOT3,1,
358                   [set this to limit filenames to the 8.3 format])
359         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
360                   [defined if we must run on a stupid file system])
361         AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
362                   [defined if we run on some of the PCDOS like systems 
363                    (DOS, Windoze. OS/2) with special properties like
364                     no file modes])
365         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
366                   [because the Unix gettext has too much overhead on
367                    MingW32 systems and these systems lack Posix functions,
368                    we use a simplified version of gettext])
369         try_gettext="no"
370         ;;
371     i?86-emx-os2 | i?86-*-os2*emx )
372         # OS/2 with the EMX environment
373         ac_cv_have_dev_random=no
374         AC_DEFINE(HAVE_DRIVE_LETTERS)
375         AC_DEFINE(HAVE_DOSISH_SYSTEM)
376         try_gettext="no"
377         ;;
378
379     i?86-*-msdosdjgpp*)
380         # DOS with the DJGPP environment
381         ac_cv_have_dev_random=no
382         AC_DEFINE(HAVE_DRIVE_LETTERS)
383         AC_DEFINE(HAVE_DOSISH_SYSTEM)
384         try_gettext="no"
385         ;;
386
387     *-*-freebsd*)
388        # FreeBSD
389        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
390        LDFLAGS="$LDFLAGS -L/usr/local/lib"
391        ;;
392
393     *-*-hpux*)
394         if test -z "$GCC" ; then
395             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
396         fi
397         ;;
398     *-dec-osf4*)
399         if test -z "$GCC" ; then
400             # Suppress all warnings
401             # to get rid of the unsigned/signed char mismatch warnings.
402             CFLAGS="$CFLAGS -w"
403         fi
404         ;;
405     *-dec-osf5*)
406         if test -z "$GCC" ; then
407             # Use the newer compiler `-msg_disable ptrmismatch' to
408             # get rid of the unsigned/signed char mismatch warnings.
409             # Using this may hide other pointer mismatch warnings, but
410             # it at least lets other warning classes through
411             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
412         fi
413         ;;
414     m68k-atari-mint)
415         ;;
416     *)
417        ;;
418 esac
419
420 AC_SUBST(MPI_OPT_FLAGS)
421 GNUPG_SYS_SYMBOL_UNDERSCORE
422
423 dnl Must check for network library requirements before doing link tests
424 dnl for ldap, for example. If ldap libs are static (or dynamic and without
425 dnl ELF runtime link paths), then link will fail and LDAP support won't
426 dnl be detected.
427
428 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
429         [NETLIBS="-lnsl $NETLIBS"]))
430 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
431         [NETLIBS="-lsocket $NETLIBS"]))
432
433 dnl Now try for the resolver functions so we can use DNS SRV
434
435 AC_ARG_ENABLE(dns-srv,
436    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
437    use_dns_srv=$enableval,use_dns_srv=yes)
438
439 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
440   AC_CHECK_FUNC(res_query)
441   # the double underscore thing is a glibc-ism?
442   if test $ac_cv_func_res_query = no ; then 
443      AC_CHECK_FUNC(__res_query)
444      ac_cv_func_res_query=$ac_cv_func___res_query
445   fi
446   if test $ac_cv_func_res_query = no ; then 
447      AC_CHECK_LIB(resolv,res_query)
448      ac_cv_func_res_query=$ac_cv_lib_resolv_res_query
449      srvlib="-lresolv"
450   fi
451   if test $ac_cv_func_res_query = no ; then 
452      AC_CHECK_LIB(resolv,__res_query)
453      ac_cv_func_res_query=$ac_cv_lib_resolv___res_query
454      srvlib="-lresolv"
455   fi
456   if test $ac_cv_func_res_query = no ; then 
457      AC_CHECK_LIB(bind,res_query)
458      ac_cv_func_res_query=$ac_cv_lib_bind_res_query
459      srvlib="-lbind"
460   fi
461   if test $ac_cv_func_res_query = no ; then 
462      AC_CHECK_LIB(bind,__res_query)
463      ac_cv_func_res_query=$ac_cv_lib_bind___res_query
464      srvlib="-lbind"
465   fi
466   # we assume if we can find res_query, we can also use the dn_expand
467   # and dn_skipname functions.
468   if test x"$ac_cv_func_res_query" = xyes ; then
469      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
470      SRVLIBS=$srvlib
471   fi
472 fi
473
474 AC_SUBST(SRVLIBS)
475
476 # Try and link a LDAP test program to weed out unusable LDAP
477 # libraries.  -lldap [-llber [-lresolv]] is for OpenLDAP.  OpenLDAP in
478 # general is terrible with creating weird dependencies.  If all else
479 # fails, the user can play guess-the-dependency by using something
480 # like ./configure LDAPLIBS="-Lfoo -lbar"
481
482 if test "$try_ldap" = yes ; then
483   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
484     _ldap_save_libs=$LIBS
485     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
486
487     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
488     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
489                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
490     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
491
492     if test $gnupg_cv_func_ldap_init = no; then
493       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
494       AC_TRY_LINK([#include <lber.h>
495 #include <ldap.h>],[ldap_open("foobar",1234);],
496          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
497       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
498     fi
499
500     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
501        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
502     fi
503
504     if test "$gnupg_cv_func_ldap_init" = yes || \
505         test "$gnupg_cv_func_ldaplber_init" = yes ; then
506        LDAPLIBS=$MY_LDAPLIBS
507        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
508
509        AC_MSG_CHECKING([whether LDAP supports ldap_get_option])
510
511        if test "$gnupg_cv_func_ldap_init" = yes ; then
512           AC_TRY_LINK([#include <ldap.h>],
513              [ldap_get_option((void *)0,0,(void *)0);],
514              [gnupg_cv_func_ldap_get_option=yes],
515              [gnupg_cv_func_ldap_get_option=no])
516         else
517           AC_TRY_LINK([#include <lber.h>
518 #include <ldap.h>],[ldap_get_option((void *)0,0,(void *)0);],
519              [gnupg_cv_func_ldap_get_option=yes],
520              [gnupg_cv_func_ldap_get_option=no])
521        fi
522
523        AC_MSG_RESULT([$gnupg_cv_func_ldap_get_option])
524
525        if test "$gnupg_cv_func_ldap_get_option" = yes ; then
526           AC_DEFINE(HAVE_LDAP_GET_OPTION,1,[Define if the LDAP library has ldap_get_option])
527        else
528           AC_MSG_CHECKING([whether LDAP supports ld_errno])
529
530           if test "$gnupg_cv_func_ldap_init" = yes ; then
531             AC_TRY_COMPILE([#include <ldap.h>],
532                [LDAP *ldap; ldap->ld_errno;],
533                [gnupg_cv_func_ldap_ld_errno=yes],
534                [gnupg_cv_func_ldap_ld_errno=no])
535            else
536             AC_TRY_LINK([#include <lber.h>
537 #include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
538                [gnupg_cv_func_ldap_ld_errno=yes],
539                [gnupg_cv_func_ldap_ld_errno=no])
540           fi
541
542           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
543
544           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
545              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
546           fi
547        fi
548     fi
549
550     LIBS=$_ldap_save_libs
551
552     if test "$GPGKEYS_LDAP" != "" ; then break; fi
553   done
554 fi
555
556 AC_SUBST(GPGKEYS_LDAP)
557 AC_SUBST(LDAPLIBS)
558
559 dnl This isn't necessarily sendmail itself, but anything that gives a
560 dnl sendmail-ish interface to the outside world.  That includes qmail,
561 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
562
563 if test "$try_mailto" = yes ; then
564   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
565
566   if test "$with_mailprog" = yes ; then
567     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
568     if test "$ac_cv_path_SENDMAIL" ; then
569       GPGKEYS_MAILTO="gpgkeys_mailto"
570     fi
571   elif test "$with_mailprog" != no ; then
572     AC_MSG_CHECKING([for a mail transport program])
573     AC_SUBST(SENDMAIL,$with_mailprog)
574     AC_MSG_RESULT($with_mailprog)
575     GPGKEYS_MAILTO="gpgkeys_mailto"
576   fi
577 fi
578
579 AC_SUBST(GPGKEYS_MAILTO)
580
581 case "${target}" in
582     *-*-mingw32*)
583         PRINTABLE_OS_NAME="MingW32"
584         ;;
585     *-*-cygwin*)
586         PRINTABLE_OS_NAME="Cygwin"
587         ;;
588     i?86-emx-os2 | i?86-*-os2*emx )
589         PRINTABLE_OS_NAME="OS/2"
590         ;;
591     i?86-*-msdosdjgpp*)
592         PRINTABLE_OS_NAME="MSDOS/DJGPP"
593         try_dynload=no
594         ;;
595     *-linux*)
596         PRINTABLE_OS_NAME="GNU/Linux"
597         ;;
598 dnl let that after linux to avoid gnu-linux problems
599     *-gnu*)
600         PRINTABLE_OS_NAME="GNU/Hurd"
601         ;;
602     *)
603         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
604         ;;
605 esac
606 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
607                    [A human readable text with the name of the OS])
608
609
610 #
611 # 1. Set names of random devices
612 #
613 NAME_OF_DEV_RANDOM="/dev/random"
614 NAME_OF_DEV_URANDOM="/dev/urandom"
615 case "${target}" in
616     *-openbsd*)
617         NAME_OF_DEV_RANDOM="/dev/srandom"
618         NAME_OF_DEV_URANDOM="/dev/urandom"
619         ;;
620 esac
621 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM",
622                    [defined to the name of the strong random device])
623 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM",
624                    [defined to the name of the weaker random device])
625 AC_SUBST(MPI_OPT_FLAGS)
626
627
628 dnl Checks for libraries.
629
630 if test "$try_gettext" = yes; then
631   AM_GNU_GETTEXT
632 else
633   USE_NLS=no
634   USE_INCLUDED_LIBINTL=no
635   BUILD_INCLUDED_LIBINTL=no
636   AC_SUBST(USE_NLS)
637   AC_SUBST(USE_INCLUDED_LIBINTL)
638   AC_SUBST(BUILD_INCLUDED_LIBINTL)
639 fi
640
641
642 if test "$try_dynload" = yes ; then
643   AC_CHECK_LIB(dl,dlopen)
644   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
645     AC_DEFINE(USE_DYNAMIC_LINKING,1,
646               [define to enable the use of extensions])
647     AC_DEFINE(HAVE_DL_DLOPEN,1,
648               [Defined when the dlopen function family is available])
649   else
650     AC_CHECK_FUNCS(dlopen)
651     if test "$ac_cv_func_dlopen" = "yes"; then
652       AC_DEFINE(USE_DYNAMIC_LINKING)
653       AC_DEFINE(HAVE_DL_DLOPEN)
654     fi
655   fi
656 else
657   AC_MSG_CHECKING(for dynamic loading)
658   DYNLINK_LDFLAGS=
659   DYNLINK_MOD_CFLAGS=
660   AC_MSG_RESULT(has been disabled)
661 fi
662
663 dnl Checks for header files.
664 AC_HEADER_STDC
665 AC_CHECK_HEADERS(unistd.h langinfo.h termio.h locale.h)
666
667 dnl Checks for typedefs, structures, and compiler characteristics.
668 AC_C_CONST
669 AC_C_INLINE
670 AC_C_VOLATILE
671 AC_TYPE_SIZE_T
672 AC_TYPE_MODE_T
673 AC_TYPE_SIGNAL
674 AC_DECL_SYS_SIGLIST
675
676 GNUPG_CHECK_ENDIAN
677
678 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
679 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
680 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
681 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
682 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
683
684 AC_CHECK_SIZEOF(unsigned short)
685 AC_CHECK_SIZEOF(unsigned int)
686 AC_CHECK_SIZEOF(unsigned long)
687 AC_CHECK_SIZEOF(unsigned long long)
688 AC_CHECK_SIZEOF(uint64_t)
689
690 if test "$ac_cv_sizeof_unsigned_short" = "0" \
691    || test "$ac_cv_sizeof_unsigned_int" = "0" \
692    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
693     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
694 fi
695
696 dnl Do we have any 64-bit data types?
697 if test "$ac_cv_sizeof_unsigned_int" != "8" \
698    && test "$ac_cv_sizeof_unsigned_long" != "8" \
699    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
700    && test "$ac_cv_sizeof_uint64_t" != "8"; then
701     AC_MSG_WARN([No 64-bit types.  Disabling TIGER/192, SHA-384, and SHA-512])
702 else
703   if test x"$use_tiger192" = xyes ; then
704      AC_SUBST(TIGER_O,tiger.o)
705      AC_DEFINE(USE_TIGER192,1,[Define to include the TIGER/192 digest])
706
707      AC_MSG_CHECKING([whether to enable old-style TIGER/192 digest support])
708      AC_ARG_ENABLE(old-tiger,
709         [  --enable-old-tiger      enable old-style TIGER/192 digest support],
710         old_tiger=$enableval, old_tiger=no)
711      AC_MSG_RESULT($old_tiger)
712      if test "$old_tiger" = yes ; then
713         AC_DEFINE(USE_OLD_TIGER,1,[Define to use the old fake OID for TIGER/192 digest support])
714      fi
715   fi
716   if test x"$use_sha512" = xyes ; then
717      AC_SUBST(SHA512_O,sha512.o)
718      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
719   fi
720 fi
721
722 dnl Checks for library functions.
723 AC_FUNC_FSEEKO
724 AC_FUNC_VPRINTF
725 AC_FUNC_FORK
726 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
727 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid)
728 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
729 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
730 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat)
731 AC_REPLACE_FUNCS(mkdtemp)
732
733 #
734 # check for gethrtime and run a testprogram to see whether
735 # it is broken.  It has been reported that some Solaris and HP UX systems 
736 # raise an SIGILL
737 #
738 AC_CACHE_CHECK([for gethrtime], 
739                [gnupg_cv_func_gethrtime],
740                [AC_TRY_LINK([#include <sys/times.h>],[
741                    hrtime_t tv;
742                    tv = gethrtime();
743                  ],
744                  [gnupg_cv_func_gethrtime=yes],
745                  [gnupg_cv_func_gethrtime=no])
746                ])
747 if test $gnupg_cv_func_gethrtime = yes; then
748      AC_DEFINE([HAVE_GETHRTIME], 1,
749                [Define if you have the `gethrtime(2)' function.])
750      AC_CACHE_CHECK([whether gethrtime is broken], 
751                [gnupg_cv_func_broken_gethrtime],
752                [AC_TRY_RUN([
753                    #include <sys/times.h>
754                    int main () {
755                    hrtime_t tv;
756                    tv = gethrtime(); 
757                  }
758                  ],
759                  [gnupg_cv_func_broken_gethrtime=no],
760                  [gnupg_cv_func_broken_gethrtime=yes],
761                  [gnupg_cv_func_broken_gethrtime=assume-no])
762                 ])
763     if test $gnupg_cv_func_broken_gethrtime = yes; then
764       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
765       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
766     fi
767 fi
768      
769
770 GNUPG_CHECK_MLOCK
771 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
772
773 dnl
774 dnl Check whether we can use Linux capabilities as requested
775 dnl
776 if test "$use_capabilities" = "yes" ; then
777 use_capabilities=no
778 AC_CHECK_HEADERS(sys/capability.h)
779 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
780   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
781   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
782      AC_DEFINE(USE_CAPABILITIES,1,
783                [define if capabilities should be used])
784      AC_SUBST(CAPLIBS,"-lcap")
785      use_capabilities=yes
786   fi
787 fi
788 if test "$use_capabilities" = "no" ; then
789     AC_MSG_WARN([[
790 ***
791 *** The use of capabilities on this system is not possible.
792 *** You need a recent Linux kernel and some patches:
793 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
794 ***   fcap-module-990613.tar.gz     (kernel module)
795 ***   libcap-1.92.tar.gz            (user mode library and utilities)
796 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
797 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
798 ***]])
799 fi
800 fi
801
802
803 GNUPG_CHECK_IPC
804 if test "$ac_cv_header_sys_shm_h" = "yes"; then
805   AC_DEFINE(USE_SHM_COPROCESSING,1,
806             [define if the shared memory interface should be made available])
807 fi
808
809 dnl
810 dnl check whether we have a random device
811 dnl
812 if test "$try_dev_random" = yes ; then
813     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
814     [if test -r "$NAME_OF_DEV_RANDOM" && test -r "$NAME_OF_DEV_URANDOM" ; then
815       ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
816     if test "$ac_cv_have_dev_random" = yes; then
817         AC_DEFINE(HAVE_DEV_RANDOM,1,
818                  [defined if the system supports a random device] )
819     fi
820 else
821     AC_MSG_CHECKING(for random device)
822     ac_cv_have_dev_random=no
823     AC_MSG_RESULT(has been disabled)
824 fi
825
826
827 dnl
828 dnl Figure out the default random module.
829 dnl
830 random_modules=""
831 if test "$use_static_rnd" = default; then
832      if test "$ac_cv_have_dev_random" = yes; then
833         random_modules="rndlinux"
834      else
835          case "${target}" in
836             *-*-mingw32*|*-*-cygwin*)
837                 random_modules="rndw32"
838                 ;;
839             i?86-emx-os2|i?86-*-os2*emx)
840                 random_modules="rndos2"
841                 ;;
842             m68k-atari-mint)
843                 random_modules="rndatari"
844                 ;;
845             i?86-*-msdosdjgpp*)
846                 :
847                 ;;
848             *)
849                 random_modules="rndlinux rndegd rndunix"
850                 AC_DEFINE(USE_ALL_RANDOM_MODULES, 1, 
851                           [Allow to select random modules at runtime.])
852                 ;;
853          esac
854      fi
855 else
856   if test "$use_static_rnd" = auto; then
857      random_modules="rndlinux rndegd rndunix"
858      AC_DEFINE(USE_ALL_RANDOM_MODULES, 1)
859   else
860      random_modules="rnd$use_static_rnd";
861   fi
862 fi
863
864 if test -z "$random_modules"; then
865    AC_MSG_ERROR(no random module available)
866 fi
867 print_egd_warning=no
868 for rndmod in $random_modules "" ; do
869   case "$rndmod" in
870     rndlinux)
871          AC_DEFINE(USE_RNDLINUX,1, 
872                   [Defined if the /dev/random based RNG should be used.])
873          ;;
874     rndunix)
875          AC_DEFINE(USE_RNDUNIX,1, 
876                   [Defined if the default Unix RNG should be used.])
877          print_egd_warning=yes
878           ;;
879     rndegd)
880          AC_DEFINE(USE_RNDEGD,1, 
881                   [Defined if the EGD based RNG should be used.])
882          EGDLIBS=$NETLIBS
883          AC_SUBST(EGDLIBS)
884          ;;
885     rndw32)
886          AC_DEFINE(USE_RNDW32,1, 
887                   [Defined if the Windows specific RNG should be used.])
888         ;;
889    esac
890 done
891
892 dnl setup assembler stuff
893 AC_MSG_CHECKING(for mpi assembler functions)
894 if test -f $srcdir/mpi/config.links ; then
895     . $srcdir/mpi/config.links
896     AC_CONFIG_LINKS("$mpi_ln_list")
897     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
898     ac_cv_mpi_sflags="$mpi_sflags"
899     ac_cv_mpi_config_done="yes"
900     AC_MSG_RESULT(done)
901 else
902     AC_MSG_RESULT(failed)
903     AC_MSG_ERROR([mpi/config.links missing!])
904 fi
905 MPI_EXTRA_ASM_OBJS=""
906 show_extraasm=""
907 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
908 for i in $ac_cv_mpi_extra_asm_modules; do
909     show_extraasm="$show_extraasm $i"
910     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
911 done
912 fi
913 AC_SUBST(MPI_EXTRA_ASM_OBJS)
914 MPI_SFLAGS="$ac_cv_mpi_sflags"
915 AC_SUBST(MPI_SFLAGS)
916
917 # Sanity check regex.  Tests adapted from mutt.
918
919 AC_MSG_CHECKING([whether regular expression support is requested])
920 AC_ARG_ENABLE(regex,
921 [  --disable-regex         do not handle regular expressions in trust sigs],
922      use_regex=$enableval, use_regex=yes)
923 AC_MSG_RESULT($use_regex)
924
925 if test "$use_regex" = yes ; then
926   AC_MSG_CHECKING([whether the included regex lib is requested])
927   AC_ARG_WITH(included-regex,
928       [  --with-included-regex   use the included GNU regex library],
929       [gnupg_cv_included_regex=yes],[gnupg_cv_included_regex=no])
930   AC_MSG_RESULT($gnupg_cv_included_regex)
931
932   if test $gnupg_cv_included_regex = no ; then
933      # Does the system have regex functions at all?
934      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
935                            gnupg_cv_included_regex=yes)
936   fi
937
938   if test $gnupg_cv_included_regex = no ; then
939      AC_CACHE_CHECK([whether your system's regexp library is broken],
940        [gnupg_cv_regex_broken],
941        AC_TRY_RUN([
942 #include <unistd.h>
943 #include <regex.h>
944 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
945        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
946
947      if test $gnupg_cv_regex_broken = yes ; then
948       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
949       gnupg_cv_included_regex=yes
950      fi
951   fi
952
953   if test $gnupg_cv_included_regex = yes; then
954      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
955      AC_SUBST(REGEX_O,regex.o)
956   fi
957 else
958
959   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
960 fi
961
962 dnl Do we have zlib? Must do it here because Solaris failed
963 dnl when compiling a conftest (due to the "-lz" from LIBS).
964 use_local_zlib=yes
965 if test "$g10_force_zlib" = "yes"; then
966   :
967 else
968   _cppflags="${CPPFLAGS}"
969   _ldflags="${LDFLAGS}"
970
971   AC_ARG_WITH(zlib,
972   [  --with-zlib=DIR         use libz in DIR],[
973     if test -d "$withval"; then
974       CPPFLAGS="${CPPFLAGS} -I$withval/include"
975       LDFLAGS="${LDFLAGS} -L$withval/lib"
976     fi
977   ])
978
979   AC_CHECK_HEADER(zlib.h,
980       AC_CHECK_LIB(z, deflateInit2_,
981        use_local_zlib=no
982        LIBS="$LIBS -lz",
983        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
984        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
985 fi
986  
987 if test "$use_local_zlib" = yes ; then
988     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
989     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
990     ZLIBS="../zlib/libzlib.a"
991 else
992     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
993     ZLIBS=
994 fi
995 AC_SUBST(ZLIBS)
996
997
998 # Allow users to append something to the version string without
999 # flagging it as development version.  The user version parts is
1000 # considered everything after a dash. 
1001 if test "$development_version" != yes; then
1002   changequote(,)dnl
1003   tmp_pat='[a-zA-Z]'
1004   changequote([,])dnl
1005   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1006     development_version=yes
1007   fi
1008 fi
1009 if test "$development_version" = yes; then
1010     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1011             [Defined if this is not a regular release])
1012 fi
1013
1014 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1015
1016 GNUPG_CHECK_GNUMAKE
1017
1018 # add some extra libs here so that previous tests don't fail for
1019 # mysterious reasons - the final link step should bail out. 
1020 case "${target}" in
1021     *-*-mingw32*)
1022         LIBS="$LIBS -lwsock32"
1023         ;;
1024     *)
1025        ;;
1026 esac
1027
1028
1029 if test "$GCC" = yes; then
1030     if test "$USE_MAINTAINER_MODE" = "yes"; then
1031         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1032     else
1033         CFLAGS="$CFLAGS -Wall"
1034     fi
1035 fi
1036
1037 AC_SUBST(NETLIBS)
1038
1039
1040 if test "$print_egd_warning" = yes; then
1041   AC_MSG_WARN([[
1042 ***
1043 *** The performance of the UNIX random gatherer module is not very good
1044 *** and it does not keep the entropy pool over multiple invocations of
1045 *** GnuPG.  The suggested way to overcome this problem is to use the
1046 ***
1047 ***               Entropy Gathering Daemon (EGD)
1048 ***
1049 *** which provides a entropy source for the whole system.  It is written
1050 *** in Perl and available at the GnuPG FTP servers.  For more information
1051 *** consult the GnuPG webpages:
1052 ***
1053 ***           http://www.gnupg.org/download.html#egd
1054 ***
1055 *** You may want to run ./configure with --enable-static-rnd=egd to use it.
1056 ***]])
1057 fi
1058
1059 # Note the \\\\ for backslashes.  Autoconf eats one layer, leaving \\
1060
1061 AC_CONFIG_COMMANDS(g10defs.h,[[
1062 cat >g10defs.tmp <<G10EOF
1063 /* Generated automatically by configure */
1064 #ifdef HAVE_DRIVE_LETTERS
1065   #define G10_LOCALEDIR     "c:\\\\lib\\\\gnupg\\\\locale"
1066   #define GNUPG_LIBDIR      "c:\\\\lib\\\\gnupg"
1067   #define GNUPG_LIBEXECDIR  "c:\\\\lib\\\\gnupg"
1068   #define GNUPG_DATADIR     "c:\\\\lib\\\\gnupg"
1069   #define GNUPG_HOMEDIR     "c:\\\\gnupg"
1070 #else
1071   #define G10_LOCALEDIR     "${datadir}/locale"
1072   #define GNUPG_LIBDIR      "${libdir}/gnupg"
1073   #define GNUPG_DATADIR     "${datadir}/gnupg"
1074   #ifdef __VMS
1075     #define GNUPG_HOMEDIR "/SYS\$LOGIN/gnupg" 
1076   #else
1077     #define GNUPG_HOMEDIR "~/.gnupg" 
1078   #endif
1079 #endif
1080 /* those are here to be redefined by handcrafted g10defs.h.
1081    Please note that the string version must not contain more
1082    than one character because the using code assumes strlen()==1 */
1083 #ifdef HAVE_DOSISH_SYSTEM
1084 #define DIRSEP_C '\\\\'
1085 #define EXTSEP_C '.'
1086 #define DIRSEP_S "\\\\"
1087 #define EXTSEP_S "."
1088 #else
1089 #define DIRSEP_C '/'
1090 #define EXTSEP_C '.'
1091 #define DIRSEP_S "/"
1092 #define EXTSEP_S "."
1093 #endif
1094 G10EOF
1095 cat mpi/mpi-asm-defs.h >>g10defs.tmp 
1096 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
1097     echo "g10defs.h is unchanged"
1098     rm -f g10defs.tmp
1099 else
1100     rm -f g10defs.h
1101     mv g10defs.tmp g10defs.h
1102     echo "g10defs.h created"
1103 fi
1104 ]],[[
1105 prefix=$prefix
1106 exec_prefix=$exec_prefix
1107 libdir=$libdir
1108 libexecdir=$libexecdir
1109 datadir=$datadir
1110 DATADIRNAME=$DATADIRNAME
1111 ]])
1112
1113
1114 AC_CONFIG_FILES([
1115 Makefile
1116 intl/Makefile
1117 po/Makefile.in
1118 util/Makefile
1119 mpi/Makefile
1120 cipher/Makefile
1121 g10/Makefile
1122 keyserver/Makefile
1123 keyserver/gpgkeys_mailto
1124 keyserver/gpgkeys_test
1125 doc/Makefile
1126 tools/Makefile
1127 zlib/Makefile
1128 checks/Makefile
1129 ])
1130 AC_OUTPUT
1131
1132 # Give some feedback
1133 echo
1134 echo   "                Configured for: $PRINTABLE_OS_NAME ($target)"
1135 if test -n "$show_extraasm"; then
1136   echo "  Extra cpu specific functions:$show_extraasm"
1137 fi
1138 echo