* trustlist.c (read_list): Allow colons in the fingerprint.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 1.9
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 #               2003, 2004 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 2 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, write to the Free Software
19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20
21 # Process this file with autoconf to produce a configure script.
22 AC_PREREQ(2.52)
23 min_automake_version="1.7.6"
24
25 # Version number: Remember to change it immediately *after* a release.
26 #                 Add a "-cvs" prefix for non-released code.
27 AC_INIT(gnupg, 1.9.10, gnupg-devel@gnupg.org)
28 # Set development_version to yes if the minor number is odd or you
29 # feel that the default check for a development version is not
30 # sufficient.
31 development_version=yes
32 NEED_GPG_ERROR_VERSION=0.7
33
34 NEED_LIBGCRYPT_API=1
35 NEED_LIBGCRYPT_VERSION=1.1.94
36
37 NEED_LIBASSUAN_VERSION=0.6.6
38
39 NEED_KSBA_VERSION=0.9.7
40
41 NEED_OPENSC_VERSION=0.8.0
42
43
44
45 PACKAGE=$PACKAGE_NAME
46 PACKAGE_GT=${PACKAGE_NAME}2
47 VERSION=$PACKAGE_VERSION
48
49 AC_CONFIG_AUX_DIR(scripts)
50 AC_CONFIG_SRCDIR(sm/gpgsm.c)
51 AM_CONFIG_HEADER(config.h)
52 AC_CANONICAL_TARGET()
53 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
54
55 AC_GNU_SOURCE
56
57 # Some status variables to give feedback at the end of a configure run
58 have_gpg_error=no
59 have_libgcrypt=no 
60 have_libassuan=no
61 have_ksba=no
62 have_opensc=no
63 have_pth=no
64
65 GNUPG_BUILD_PROGRAM(gpg, yes)
66 GNUPG_BUILD_PROGRAM(gpgsm, yes)
67 GNUPG_BUILD_PROGRAM(agent, yes)
68 GNUPG_BUILD_PROGRAM(scdaemon, yes)
69
70
71 AC_SUBST(PACKAGE)
72 AC_SUBST(PACKAGE_GT)
73 AC_SUBST(VERSION)
74 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
75 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
76                                 [Name of this package for gettext])
77 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
78 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
79                                         [Bug report address])
80 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
81                                        [Required version of Libgcrypt])
82 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
83                                        [Required version of Libksba])
84
85
86
87 # The default is to use the modules from this package and the few
88 # other packages in a standard place; i.e where this package gets
89 # installed.  With these options it is possible to override these
90 # ${prefix} depended values with fixed paths, which can't be replaced
91 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
92 AC_ARG_WITH(agent-pgm,
93     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
94           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
95 AC_SUBST(GNUPG_AGENT_PGM)
96 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
97 show_gnupg_agent_pgm="(default)"
98 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
99
100 AC_ARG_WITH(pinentry-pgm,
101     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
102           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
103 AC_SUBST(GNUPG_PINENTRY_PGM)
104 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
105 show_gnupg_pinentry_pgm="(default)"
106 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
107
108
109 AC_ARG_WITH(scdaemon-pgm,
110     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
111           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
112 AC_SUBST(GNUPG_SCDAEMON_PGM)
113 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
114 show_gnupg_scdaemon_pgm="(default)"
115 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
116
117
118 AC_ARG_WITH(dirmngr-pgm,
119     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
120           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
121 AC_SUBST(GNUPG_DIRMNGR_PGM)
122 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
123 show_gnupg_dirmngr_pgm="(default)"
124 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
125
126 AC_ARG_WITH(protect-tool-pgm,
127     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
128           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
129 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
130 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
131 show_gnupg_protect_tool_pgm="(default)"
132 test -n "$GNUPG_PROTECT_TOOL_PGM" \
133       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
134
135
136 # Some folks want to use only the agent form this packet.  Make it
137 # easier for them by providing the configure option
138 # --enable-only-agent.
139 AC_ARG_ENABLE(agent-only,
140     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
141     build_agent_only=$enableval)
142
143
144 # Configure option to allow ot disallow execution of external
145 # programs, like a photo viewer.
146 AC_MSG_CHECKING([whether to enable external program execution])
147 AC_ARG_ENABLE(exec,
148     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
149     use_exec=$enableval)
150 AC_MSG_RESULT($use_exec)
151 if test "$use_exec" = no ; then
152     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
153 fi
154
155 if test "$use_exec" = yes ; then
156   AC_MSG_CHECKING([whether to enable photo ID viewing])
157   AC_ARG_ENABLE(photo-viewers,
158       [  --disable-photo-viewers disable photo ID viewers],
159       [if test "$enableval" = no ; then
160          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
161       fi],enableval=yes)
162   gnupg_cv_enable_photo_viewers=$enableval
163   AC_MSG_RESULT($enableval)
164
165   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
166     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
167     AC_ARG_WITH(photo-viewer,
168         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
169         [if test "$withval" = yes ; then
170            withval=no
171         elif test "$withval" != no ; then
172            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
173                             [if set, restrict photo-viewer to this])
174         fi],withval=no)
175     AC_MSG_RESULT($withval)
176   fi
177
178   AC_MSG_CHECKING([whether to enable external keyserver helpers])
179   AC_ARG_ENABLE(keyserver-helpers,
180       [  --disable-keyserver-helpers  disable all external keyserver support],
181       [if test "$enableval" = no ; then
182          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
183                   [define to disable keyserver helpers])
184       fi],enableval=yes)
185   gnupg_cv_enable_keyserver_helpers=$enableval
186   AC_MSG_RESULT($enableval)
187
188   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
189     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
190     AC_ARG_ENABLE(ldap,
191     [  --disable-ldap          disable LDAP keyserver interface],
192         try_ldap=$enableval, try_ldap=yes)
193     AC_MSG_RESULT($try_ldap)
194
195     AC_MSG_CHECKING([whether HKP keyserver support is requested])
196     AC_ARG_ENABLE(hkp,
197     [  --disable-hkp           disable HKP keyserver interface],
198         try_hkp=$enableval, try_hkp=yes)
199     AC_MSG_RESULT($try_hkp)
200
201     if test "$try_hkp" = yes ; then
202       AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
203     fi
204
205     AC_MSG_CHECKING([whether email keyserver support is requested])
206     AC_ARG_ENABLE(mailto,
207     [  --disable-mailto        disable email keyserver interface],
208         try_mailto=$enableval, try_mailto=yes)
209     AC_MSG_RESULT($try_mailto)
210     fi
211
212     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
213     AC_ARG_ENABLE(keyserver-path,
214         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
215         [if test "$enableval" = no ; then
216          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
217         fi],enableval=yes)
218     AC_MSG_RESULT($enableval)
219   fi
220
221 AC_MSG_CHECKING([whether the included zlib is requested])
222 AC_ARG_WITH(included-zlib,
223     [  --with-included-zlib    use the zlib code included here],
224 [g10_force_zlib=yes], [g10_force_zlib=no] )
225 AC_MSG_RESULT($g10_force_zlib)
226
227 dnl
228 dnl Check whether we want to use Linux capabilities
229 dnl
230 AC_MSG_CHECKING([whether use of capabilities is requested])
231 AC_ARG_WITH(capabilities,
232     [  --with-capabilities     use linux capabilities [default=no]],
233 [use_capabilities="$withval"],[use_capabilities=no])
234 AC_MSG_RESULT($use_capabilities)
235
236
237 AH_BOTTOM([
238 /* Some global constants. */
239 #ifdef HAVE_DRIVE_LETTERS
240 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
241 #elif defined(__VMS)
242 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg" 
243 #else
244 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
245 #endif 
246 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
247
248 /* Tell libgcrypt not to use its own libgpg-error implementation. */
249 #define USE_LIBGPG_ERROR 1
250
251 /* This is the major version number of GnuPG so that
252    source included files can test for this.  Note, that\
253    we use 2 here even for GnuPG 1.9.x. */
254 #define GNUPG_MAJOR_VERSION 2
255
256 /* Now to separate file name parts.
257    Please note that the string version must not contain more
258    than one character because the code assumes strlen()==1 */
259 #ifdef HAVE_DOSISH_SYSTEM
260 #define DIRSEP_C '\\'
261 #define EXTSEP_C '.'
262 #define DIRSEP_S "\\"
263 #define EXTSEP_S "."
264 #else
265 #define DIRSEP_C '/'
266 #define EXTSEP_C '.'
267 #define DIRSEP_S "/"
268 #define EXTSEP_S "."
269 #endif
270
271 /* This is the same as VERSION, but should be overridden if the
272    platform cannot handle things like dots '.' in filenames. Set
273    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
274    uses for dots and dashes. */
275 #define SAFE_VERSION VERSION
276 #define SAFE_VERSION_DOT  '.'
277 #define SAFE_VERSION_DASH '-'
278
279 /* For some systems (DOS currently), we hardcode the path here.  For
280    POSIX systems the values are constructed by the Makefiles, so that
281    the values may be overridden by the make invocations; this is to
282    comply with the GNU coding standards. */
283 #ifdef HAVE_DRIVE_LETTERS
284 #define GNUPG_BINDIR      "c:\\gnupg"
285 #define GNUPG_LIBEXECDIR  "c:\\lib\\gnupg"
286 #define GNUPG_LIBDIR      "c:\\lib\\gnupg"
287 #define GNUPG_DATADIR     "c:\\lib\\gnupg"
288 #endif
289
290 /* Setup the hardwired names of modules. */
291 #ifndef GNUPG_DEFAULT_AGENT
292 #define GNUPG_DEFAULT_AGENT    ( GNUPG_BINDIR DIRSEP_S "gpg-agent" )
293 #endif
294 #ifndef GNUPG_DEFAULT_PINENTRY
295 #define GNUPG_DEFAULT_PINENTRY ( GNUPG_BINDIR DIRSEP_S "pinentry" )
296 #endif
297 #ifndef GNUPG_DEFAULT_SCDAEMON
298 #define GNUPG_DEFAULT_SCDAEMON ( GNUPG_BINDIR DIRSEP_S "scdaemon" )
299 #endif
300 #ifndef GNUPG_DEFAULT_DIRMNGR
301 #define GNUPG_DEFAULT_DIRMNGR  ( GNUPG_BINDIR DIRSEP_S "dirmngr" )
302 #endif
303 #ifndef GNUPG_DEFAULT_PROTECT_TOOL
304 #define GNUPG_DEFAULT_PROTECT_TOOL \
305                     ( GNUPG_LIBEXECDIR DIRSEP_S "gpg-protect-tool" )
306 #endif
307
308
309 /* Derive some other constants. */
310 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
311 #define EXEC_TEMPFILE_ONLY
312 #endif
313
314 ])
315
316 AM_MAINTAINER_MODE
317
318 # Checks for programs.
319 AC_PROG_MAKE_SET
320 AM_SANITY_CHECK
321 missing_dir=`cd $ac_aux_dir && pwd`
322 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
323 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
324 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
325 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
326 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
327 AC_PROG_AWK
328 AC_PROG_CC
329 AC_PROG_CPP
330 AC_PROG_INSTALL
331 AC_PROG_LN_S
332 AC_PROG_MAKE_SET
333 AC_PROG_RANLIB
334 AC_CHECK_TOOL(AR, ar, :)
335 AC_PATH_PROG(PERL,"perl")
336 AC_ISC_POSIX
337 AC_SYS_LARGEFILE
338 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
339 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
340 GNUPG_CHECK_FAQPROG
341 GNUPG_CHECK_DOCBOOK_TO_TEXI
342
343
344 try_gettext=yes
345 have_dosish_system=no
346 case "${target}" in
347     *-*-mingw32*)
348         # special stuff for Windoze NT
349         ac_cv_have_dev_random=no
350         AC_DEFINE(USE_ONLY_8DOT3,1,
351                   [set this to limit filenames to the 8.3 format])
352         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
353                   [defined if we must run on a stupid file system])
354         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
355                   [because the Unix gettext has too much overhead on
356                    MingW32 systems and these systems lack Posix functions,
357                    we use a simplified version of gettext])
358         have_dosish_system=yes
359         try_gettext="no"
360         ;;
361     i?86-emx-os2 | i?86-*-os2*emx )
362         # OS/2 with the EMX environment
363         ac_cv_have_dev_random=no
364         AC_DEFINE(HAVE_DRIVE_LETTERS)
365         have_dosish_system=yes
366         try_gettext="no"
367         ;;
368
369     i?86-*-msdosdjgpp*)
370         # DOS with the DJGPP environment
371         ac_cv_have_dev_random=no
372         AC_DEFINE(HAVE_DRIVE_LETTERS)
373         have_dosish_system=yes
374         try_gettext="no"
375         ;;
376
377     *-*-freebsd*)
378        # FreeBSD
379        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
380        LDFLAGS="$LDFLAGS -L/usr/local/lib"
381        ;;
382
383     *-*-hpux*)
384         if test -z "$GCC" ; then
385             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
386         fi
387         ;;
388     *-dec-osf4*)
389         if test -z "$GCC" ; then
390             # Suppress all warnings
391             # to get rid of the unsigned/signed char mismatch warnings.
392             CFLAGS="$CFLAGS -w"
393         fi
394         ;;
395     *-dec-osf5*)
396         if test -z "$GCC" ; then
397             # Use the newer compiler `-msg_disable ptrmismatch' to
398             # get rid of the unsigned/signed char mismatch warnings.
399             # Using this may hide other pointer mismatch warnings, but
400             # it at least lets other warning classes through
401             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
402         fi
403         ;;
404     m68k-atari-mint)
405         ;;
406     *)
407        ;;
408 esac
409
410 if test "$have_dosish_system" = yes; then
411    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
412              [defined if we run on some of the PCDOS like systems 
413               (DOS, Windoze. OS/2) with special properties like
414               no file modes])
415 fi
416 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
417
418
419 #
420 # Checks for libraries.
421 #
422
423
424 #
425 # libgpg-error is a library with error codes shared between GnuPG
426 # related projects.
427 #
428 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
429                   have_gpg_error=yes,have_gpg_error=no)
430
431
432 #
433 # Libgcrypt is our generic crypto library
434 #
435 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
436         have_libgcrypt=yes,have_libgcrypt=no)
437
438
439 #
440 # libassuan is used for IPC
441 #
442 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_VERSION",
443                   have_libassuan=yes,have_libassuan=no)
444
445
446 #
447 # libksba is our X.509 support library
448 #
449 AM_PATH_KSBA("$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
450
451 #
452 # libusb allows us to use the integrated CCID smartcard reader driver.
453 #
454 # Note, that we need the CVS version.  FIXME: libusb should have a
455 # regular check as the other libraries do.
456 #
457 AC_CHECK_LIB(usb, usb_find_device,
458               [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
459                 AC_DEFINE(HAVE_LIBUSB,1,
460                          [defined if libusb is available])
461              ])
462 AC_SUBST(LIBUSB_LIBS)
463
464
465 #
466 # OpenSC is needed by the SCdaemon - if it is not availbale we can only
467 # build a limited SCdaemon
468 #
469 AM_PATH_OPENSC("$NEED_OPENSC_VERSION",have_opensc=yes,have_opensc=no)
470 if test $have_opensc = yes; then
471   AC_DEFINE(HAVE_OPENSC,1,
472             [defined if the OpenSC library is available])
473 fi
474
475 #
476 # Check whether the (highly desirable) GNU Pth library is available
477 #
478 AC_ARG_WITH(pth-prefix,
479             AC_HELP_STRING([--with-pth-prefix=PFX],
480                            [prefix where GNU Pth is installed (optional)]),
481      pth_config_prefix="$withval", pth_config_prefix="")
482 if test x$pth_config_prefix != x ; then
483    PTH_CONFIG="$pth_config_prefix/bin/pth-config"
484 fi
485 AC_PATH_PROG(PTH_CONFIG, pth-config, no)
486 if test "$PTH_CONFIG" = "no"; then
487     AC_MSG_WARN([[
488 ***
489 *** To support concurrent access to the gpg-agent and the SCdaemon
490 *** we need the support of the GNU Portable Threads Library.
491 *** Download it from ftp://ftp.gnu.org/gnu/pth/
492 *** On a Debian GNU/Linux system you might want to try 
493 ***   apt-get install libpth-dev
494 ***]])
495 else
496   GNUPG_PTH_VERSION_CHECK(1.3.7)
497   if test $have_pth = yes; then      
498      PTH_CFLAGS=`$PTH_CONFIG --cflags`
499      PTH_LIBS=`$PTH_CONFIG --ldflags`
500      PTH_LIBS="$PTH_LIBS `$PTH_CONFIG --libs`"
501      AC_DEFINE(USE_GNU_PTH, 1,
502               [Defined if the GNU Portable Thread Library should be used])
503   fi
504 fi
505 AC_SUBST(PTH_CFLAGS)
506 AC_SUBST(PTH_LIBS)
507
508 AC_ARG_ENABLE(threads,
509     AC_HELP_STRING([--disable-threads],[allow building without Pth support]);
510     
511 )
512
513
514 dnl Must check for network library requirements before doing link tests
515 dnl for ldap, for example. If ldap libs are static (or dynamic and without
516 dnl ELF runtime link paths), then link will fail and LDAP support won't
517 dnl be detected.
518
519 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
520         [NETLIBS="-lnsl $NETLIBS"]))
521 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
522         [NETLIBS="-lsocket $NETLIBS"]))
523
524 dnl Now try for the resolver functions so we can use DNS SRV
525
526 AC_ARG_ENABLE(dns-srv,
527    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
528    use_dns_srv=$enableval,use_dns_srv=yes)
529
530 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
531   _srv_save_libs=$LIBS
532   LIBS=""
533   # the double underscore thing is a glibc-ism?
534   AC_SEARCH_LIBS(res_query,resolv bind,,
535                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
536   AC_SEARCH_LIBS(dn_expand,resolv bind,,
537                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
538   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
539                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
540
541   if test x"$use_dns_srv" = xyes ; then
542      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
543      SRVLIBS=$LIBS
544   else
545      AC_MSG_WARN([Resolver functions not found.  Disabling DNS SRV.])
546   fi
547   LIBS=$_srv_save_libs
548 fi
549
550 AC_SUBST(SRVLIBS)
551
552 # Try and link a LDAP test program to weed out unusable LDAP
553 # libraries.  -lldap [-llber [-lresolv]] is for OpenLDAP.  OpenLDAP in
554 # general is terrible with creating weird dependencies.  If all else
555 # fails, the user can play guess-the-dependency by using something
556 # like ./configure LDAPLIBS="-Lfoo -lbar"
557
558 if test "$try_ldap" = yes ; then
559   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
560     _ldap_save_libs=$LIBS
561     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
562
563     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
564     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
565                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
566     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
567
568     if test $gnupg_cv_func_ldap_init = no; then
569       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
570       AC_TRY_LINK([#include <lber.h>
571 #include <ldap.h>],[ldap_open("foobar",1234);],
572          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
573       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
574     fi
575
576     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
577        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
578     fi
579
580     if test "$gnupg_cv_func_ldap_init" = yes || \
581         test "$gnupg_cv_func_ldaplber_init" = yes ; then
582        LDAPLIBS=$MY_LDAPLIBS
583        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
584
585        AC_MSG_CHECKING([whether LDAP supports ldap_get_option])
586
587        if test "$gnupg_cv_func_ldap_init" = yes ; then
588           AC_TRY_LINK([#include <ldap.h>],
589              [ldap_get_option((void *)0,0,(void *)0);],
590              [gnupg_cv_func_ldap_get_option=yes],
591              [gnupg_cv_func_ldap_get_option=no])
592         else
593           AC_TRY_LINK([#include <lber.h>
594 #include <ldap.h>],[ldap_get_option((void *)0,0,(void *)0);],
595              [gnupg_cv_func_ldap_get_option=yes],
596              [gnupg_cv_func_ldap_get_option=no])
597        fi
598
599        AC_MSG_RESULT([$gnupg_cv_func_ldap_get_option])
600
601        if test "$gnupg_cv_func_ldap_get_option" = yes ; then
602           AC_DEFINE(HAVE_LDAP_GET_OPTION,1,[Define if the LDAP library has ldap_get_option])
603        else
604           AC_MSG_CHECKING([whether LDAP supports ld_errno])
605
606           if test "$gnupg_cv_func_ldap_init" = yes ; then
607             AC_TRY_COMPILE([#include <ldap.h>],
608                [LDAP *ldap; ldap->ld_errno;],
609                [gnupg_cv_func_ldap_ld_errno=yes],
610                [gnupg_cv_func_ldap_ld_errno=no])
611            else
612             AC_TRY_LINK([#include <lber.h>
613 #include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
614                [gnupg_cv_func_ldap_ld_errno=yes],
615                [gnupg_cv_func_ldap_ld_errno=no])
616           fi
617
618           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
619
620           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
621              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
622           fi
623        fi
624     fi
625
626     LIBS=$_ldap_save_libs
627
628     if test "$GPGKEYS_LDAP" != "" ; then break; fi
629   done
630 fi
631
632 AC_SUBST(GPGKEYS_LDAP)
633 AC_SUBST(LDAPLIBS)
634
635 dnl This isn't necessarily sendmail itself, but anything that gives a
636 dnl sendmail-ish interface to the outside world.  That includes qmail,
637 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
638
639 if test "$try_mailto" = yes ; then
640   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
641
642   if test "$with_mailprog" = yes ; then
643     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
644     if test "$ac_cv_path_SENDMAIL" ; then
645       GPGKEYS_MAILTO="gpgkeys_mailto"
646     fi
647   elif test "$with_mailprog" != no ; then
648     AC_MSG_CHECKING([for a mail transport program])
649     AC_SUBST(SENDMAIL,$with_mailprog)
650     AC_MSG_RESULT($with_mailprog)
651     GPGKEYS_MAILTO="gpgkeys_mailto"
652   fi
653 fi
654
655 AC_SUBST(GPGKEYS_MAILTO)
656
657 case "${target}" in
658     *-*-mingw32*)
659         PRINTABLE_OS_NAME="MingW32"
660         ;;
661     *-*-cygwin*)
662         PRINTABLE_OS_NAME="Cygwin"
663         ;;
664     i?86-emx-os2 | i?86-*-os2*emx )
665         PRINTABLE_OS_NAME="OS/2"
666         ;;
667     i?86-*-msdosdjgpp*)
668         PRINTABLE_OS_NAME="MSDOS/DJGPP"
669         try_dynload=no
670         ;;
671     *-linux*)
672         PRINTABLE_OS_NAME="GNU/Linux"
673         ;;
674     *)
675         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
676         ;;
677 esac
678 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
679                    [A human readable text with the name of the OS])
680
681
682 AM_GNU_GETTEXT_VERSION(0.12.1)
683 if test "$try_gettext" = yes; then
684   AM_GNU_GETTEXT(,[need-ngettext])
685
686   # gettext requires some extra checks.  These really should be part of
687   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
688   # function checks to here.
689
690   AC_CHECK_FUNCS(strchr)
691 else
692   USE_NLS=no
693   USE_INCLUDED_LIBINTL=no
694   BUILD_INCLUDED_LIBINTL=no
695   AC_SUBST(USE_NLS)
696   AC_SUBST(USE_INCLUDED_LIBINTL)
697   AC_SUBST(BUILD_INCLUDED_LIBINTL)
698 fi
699
700 # Checks for header files.
701 AC_HEADER_STDC
702 AC_CHECK_HEADERS(string.h unistd.h langinfo.h termio.h locale.h)
703
704 # Checks for typedefs, structures, and compiler characteristics.
705 AC_C_CONST
706 AC_C_INLINE
707 AC_TYPE_SIZE_T
708 AC_TYPE_SIGNAL
709 AC_DECL_SYS_SIGLIST
710
711 GNUPG_CHECK_ENDIAN
712
713 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
714 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
715 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
716 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
717 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
718
719 AC_CHECK_SIZEOF(unsigned short)
720 AC_CHECK_SIZEOF(unsigned int)
721 AC_CHECK_SIZEOF(unsigned long)
722 AC_CHECK_SIZEOF(unsigned long long)
723 # Ensure that we have UINT64_C before we bother to check for uint64_t
724 # fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
725 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
726    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
727 uint64_t foo=UINT64_C(42);]),gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
728 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
729    AC_CHECK_SIZEOF(uint64_t)
730 fi
731  
732
733
734
735 if test "$ac_cv_sizeof_unsigned_short" = "0" \
736    || test "$ac_cv_sizeof_unsigned_int" = "0" \
737    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
738     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
739 fi
740
741 dnl Do we have any 64-bit data types?
742 if test "$ac_cv_sizeof_unsigned_int" != "8" \
743    && test "$ac_cv_sizeof_unsigned_long" != "8" \
744    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
745    && test "$ac_cv_sizeof_uint64_t" != "8"; then
746     AC_MSG_WARN([No 64-bit types.  Disabling SHA-384, and SHA-512])
747 else
748   if test x"$use_sha512" = xyes ; then
749      AC_SUBST(SHA512_O,sha512.o)
750      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
751   fi
752 fi
753
754 # fixme: do we really need this - it should be encapsulated in libassuan
755 GNUPG_SYS_SO_PEERCRED
756
757 # Checks for library functions.
758 AC_FUNC_FSEEKO
759 AC_FUNC_VPRINTF
760 AC_FUNC_FORK
761 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
762 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times gmtime_r)
763 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
764 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
765 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat getaddrinfo)
766
767 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
768
769 # These are needed by libjnlib - fixme: we should have macros for them
770 AC_CHECK_FUNCS(memicmp stpcpy strlwr strtoul memmove stricmp strtol)
771 AC_CHECK_FUNCS(getrusage setrlimit stat setlocale)
772 AC_CHECK_FUNCS(flockfile funlockfile fopencookie funopen)
773
774 AC_REPLACE_FUNCS(vasprintf)
775 AC_REPLACE_FUNCS(mkdtemp)
776 AC_REPLACE_FUNCS(fseeko ftello)
777 AC_REPLACE_FUNCS(isascii)
778 AC_REPLACE_FUNCS(putc_unlocked)
779
780
781
782
783 #
784 # check for gethrtime and run a testprogram to see whether
785 # it is broken.  It has been reported that some Solaris and HP UX systems 
786 # raise an SIGILL
787 #
788 #  fixme: Do we need this - iirc, this is only used by libgcrypt.
789 #
790 AC_CACHE_CHECK([for gethrtime], 
791                [gnupg_cv_func_gethrtime],
792                [AC_TRY_LINK([#include <sys/times.h>],[
793                    hrtime_t tv;
794                    tv = gethrtime();
795                  ],
796                  [gnupg_cv_func_gethrtime=yes],
797                  [gnupg_cv_func_gethrtime=no])
798                ])
799 if test $gnupg_cv_func_gethrtime = yes; then
800      AC_DEFINE([HAVE_GETHRTIME], 1,
801                [Define if you have the `gethrtime(2)' function.])
802      AC_CACHE_CHECK([whether gethrtime is broken], 
803                [gnupg_cv_func_broken_gethrtime],
804                [AC_TRY_RUN([
805                    #include <sys/times.h>
806                    int main () {
807                    hrtime_t tv;
808                    tv = gethrtime(); 
809                  }
810                  ],
811                  [gnupg_cv_func_broken_gethrtime=no],
812                  [gnupg_cv_func_broken_gethrtime=yes],
813                  [gnupg_cv_func_broken_gethrtime=assume-no])
814                 ])
815     if test $gnupg_cv_func_broken_gethrtime = yes; then
816       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
817       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
818     fi
819 fi
820      
821
822 GNUPG_CHECK_MLOCK
823 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
824
825 dnl
826 dnl Check whether we can use Linux capabilities as requested
827 dnl
828 #  fixme: Still required?
829 #
830 if test "$use_capabilities" = "yes" ; then
831 use_capabilities=no
832 AC_CHECK_HEADERS(sys/capability.h)
833 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
834   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
835   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
836      AC_DEFINE(USE_CAPABILITIES,1,
837                [define if capabilities should be used])
838      AC_SUBST(CAPLIBS,"-lcap")
839      use_capabilities=yes
840   fi
841 fi
842 if test "$use_capabilities" = "no" ; then
843     AC_MSG_WARN([[
844 ***
845 *** The use of capabilities on this system is not possible.
846 *** You need a recent Linux kernel and some patches:
847 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
848 ***   fcap-module-990613.tar.gz     (kernel module)
849 ***   libcap-1.92.tar.gz            (user mode library and utilities)
850 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
851 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
852 ***]])
853 fi
854 fi
855
856
857 # Sanity check regex.  Tests adapted from mutt.
858
859 AC_MSG_CHECKING([whether regular expression support is requested])
860 AC_ARG_ENABLE(regex,
861 [  --disable-regex         do not handle regular expressions in trust sigs],
862      use_regex=$enableval, use_regex=yes)
863 AC_MSG_RESULT($use_regex)
864
865 if test "$use_regex" = yes ; then
866   AC_MSG_CHECKING([whether the included regex lib is requested])
867   AC_ARG_WITH(included-regex,
868       [  --with-included-regex   use the included GNU regex library],
869       [gnupg_cv_included_regex=yes],[gnupg_cv_included_regex=no])
870   AC_MSG_RESULT($gnupg_cv_included_regex)
871
872   if test $gnupg_cv_included_regex = no ; then
873      # Does the system have regex functions at all?
874      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
875                            gnupg_cv_included_regex=yes)
876   fi
877
878   if test $gnupg_cv_included_regex = no ; then
879      AC_CACHE_CHECK([whether your system's regexp library is broken],
880        [gnupg_cv_regex_broken],
881        AC_TRY_RUN([
882 #include <unistd.h>
883 #include <regex.h>
884 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
885        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
886
887      if test $gnupg_cv_regex_broken = yes ; then
888       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
889       gnupg_cv_included_regex=yes
890      fi
891   fi
892
893   if test $gnupg_cv_included_regex = yes; then
894      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
895      AC_SUBST(REGEX_O,regex.o)
896   fi
897 else
898
899   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
900 fi
901
902 dnl Do we have zlib? Must do it here because Solaris failed
903 dnl when compiling a conftest (due to the "-lz" from LIBS).
904 use_local_zlib=yes
905 if test "$g10_force_zlib" = "yes"; then
906   :
907 else
908   _cppflags="${CPPFLAGS}"
909   _ldflags="${LDFLAGS}"
910
911   AC_ARG_WITH(zlib,
912   [  --with-zlib=DIR         use libz in DIR],[
913     if test -d "$withval"; then
914       CPPFLAGS="${CPPFLAGS} -I$withval/include"
915       LDFLAGS="${LDFLAGS} -L$withval/lib"
916     fi
917   ])
918
919   AC_CHECK_HEADER(zlib.h,
920       AC_CHECK_LIB(z, deflateInit2_,
921        use_local_zlib=no
922        LIBS="$LIBS -lz",
923        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
924        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
925 fi
926  
927 if test "$use_local_zlib" = yes ; then
928     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
929     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
930     ZLIBS="../zlib/libzlib.a"
931 else
932     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
933     ZLIBS=
934 fi
935 AC_SUBST(ZLIBS)
936
937 # Allow users to append something to the version string without
938 # flagging it as development version.  The user version parts is
939 # considered everything after a dash. 
940 if test "$development_version" != yes; then
941   changequote(,)dnl
942   tmp_pat='[a-zA-Z]'
943   changequote([,])dnl
944   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
945     development_version=yes
946   fi
947 fi
948 if test "$development_version" = yes; then
949     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
950             [Defined if this is not a regular release])
951 fi
952
953 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
954
955 GNUPG_CHECK_GNUMAKE
956
957 # add some extra libs here so that previous tests don't fail for
958 # mysterious reasons - the final link step should bail out. 
959 case "${target}" in
960     *-*-mingw32*)
961         W32LIBS="-lwsock32"
962         ;;
963     *)
964        ;;
965 esac
966
967
968 if test "$GCC" = yes; then
969     if test "$USE_MAINTAINER_MODE" = "yes"; then
970         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
971         CFLAGS="$CFLAGS -Wformat-nonliteral"
972     else
973         CFLAGS="$CFLAGS -Wall"
974     fi
975 fi
976
977 AC_SUBST(NETLIBS)
978 AC_SUBST(W32LIBS)
979
980
981 # We use jnlib, so tell other modules about it
982 AC_DEFINE(HAVE_JNLIB_LOGGING, 1,
983           [Defined if jnlib style logging functions are available])
984
985
986
987 #
988 # Decide what to build
989 #
990 missing_pth=no
991 if test $have_ksba = no; then
992   build_gpgsm=no
993   build_scdaemon=no
994 fi
995
996 build_agent_threaded=""
997 if test "$build_agent" = "yes"; then
998   if test $have_pth = no; then
999      build_agent_threaded="(not multi-threaded)"
1000      missing_pth=yes
1001   fi
1002 fi
1003
1004 build_scdaemon_extra=""
1005 if test "$build_scdaemon" = "yes"; then
1006   tmp=""
1007   if test $have_pth = no; then
1008      build_scdaemon_extra="not multi-threaded"
1009      tmp=", "
1010      missing_pth=yes
1011   fi
1012   if test $have_opensc = no; then
1013      build_scdaemon_extra="${build_scdaemon_extra}${tmp}no pkcs#15"
1014      tmp=", "
1015   fi      
1016   if test -n "$build_scdaemon_extra"; then
1017      build_scdaemon_extra="(${build_scdaemon_extra})"
1018   fi
1019 fi
1020
1021 if test "$build_agent_only" = "yes" ; then
1022   build_gpg=no
1023   build_gpgsm=no
1024   build_scdaemon=no
1025 fi
1026
1027 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1028 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1029 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1030 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1031
1032
1033
1034 #
1035 # Print errors here so that they are visible all
1036 # together and the user can acquire them all together.
1037 #
1038 die=no
1039 if test "$have_gpg_error" = "no"; then
1040    die=yes
1041    AC_MSG_NOTICE([[
1042 ***  
1043 *** You need libgpg-error to build this program.
1044 **  This library is for example available at
1045 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libgpg-error
1046 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1047 ***]])
1048 fi
1049 if test "$have_libgcrypt" = "no"; then
1050    die=yes
1051    AC_MSG_NOTICE([[
1052 ***  
1053 *** You need libgcrypt to build this program.
1054 **  This library is for example available at
1055 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libgcrypt/
1056 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API) is required.)
1057 ***]])
1058 fi
1059 if test "$have_libassuan" = "no"; then
1060    die=yes
1061    AC_MSG_NOTICE([[
1062 ***
1063 *** You need libassuan to build this program.
1064 *** This library is for example available at
1065 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libassuan/
1066 *** (at least version $NEED_LIBASSUAN_VERSION is required).
1067 ***]])
1068 fi
1069 if test "$have_ksba" = "no"; then
1070     AC_MSG_NOTICE([[
1071 ***
1072 *** You need libksba to build this program.
1073 *** This library is for example available at
1074 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libksba/
1075 *** (at least version $NEED_KSBA_VERSION is required).
1076 ***]])
1077 fi
1078 if test "$missing_pth" = "yes"; then
1079     AC_MSG_NOTICE([[
1080 ***
1081 *** It is strongly suggested to build with support for the
1082 *** GNU Portable Threads Library (Pth). Please install this
1083 *** library first or use --disable-threads to allow building
1084 *** anyway.  The library is for example available at
1085 ***   ftp://ftp.gnu.org/gnu/pth/
1086 *** On a Debian GNU/Linux system you can install it using 
1087 ***   apt-get install libpth-dev
1088 ***]])
1089   if test "$enable_threads" != "no"; then
1090      die=yes
1091   fi
1092 fi
1093
1094 if test "$die" = "yes"; then
1095     AC_MSG_ERROR([[
1096 ***
1097 *** Required libraries not found. Please consult the above messages
1098 *** and install them before running configure again.
1099 ***]])
1100 fi
1101
1102
1103
1104 AC_CONFIG_FILES([ m4/Makefile 
1105 Makefile
1106 po/Makefile.in
1107 intl/Makefile
1108 jnlib/Makefile
1109 common/Makefile
1110 kbx/Makefile
1111 g10/Makefile
1112 sm/Makefile
1113 agent/Makefile
1114 scd/Makefile
1115 tools/Makefile
1116 doc/Makefile
1117 tests/Makefile
1118 ])
1119 AC_OUTPUT
1120
1121
1122
1123
1124 echo "
1125         GnuPG v${VERSION} has been configured as follows:
1126         
1127         Platform:  $PRINTABLE_OS_NAME ($target)
1128
1129         OpenPGP:   $build_gpg
1130         S/MIME:    $build_gpgsm
1131         Agent:     $build_agent $build_agent_threaded
1132         Smartcard: $build_scdaemon $build_scdaemon_extra
1133
1134         Protect tool:     $show_gnupg_protect_tool_pgm
1135         Default agent:    $show_gnupg_agent_pgm
1136         Default pinentry: $show_gnupg_pinentry_pgm
1137         Default scdaemon: $show_gnupg_scdaemon_pgm
1138         Default dirmngr:  $show_gnupg_dirmngr_pgm
1139 "
1140