Removed some set but unused variables.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.0
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005,
3 #               2006, 2007, 2008, 2010, 2011 Free Software Foundation, Inc.
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.10"
23
24 # Remember to change the version number immediately *after* a release.
25 # Set my_issvn to "yes" for non-released code.  Remember to run an
26 # "svn up" and "autogen.sh" right before creating a distribution.
27 m4_define([my_version], [2.0.18])
28 m4_define([my_issvn], [yes])
29
30 m4_define([svn_revision], m4_esyscmd([printf "%d" $(svn info 2>/dev/null \
31           | sed -n '/^Revision:/ s/[^0-9]//gp'|head -1)]))
32 m4_define([git_revision], m4_esyscmd([git branch -v 2>/dev/null \
33           | awk '/^\* / {printf "%s",$3}']))
34 m4_define([my_full_version], [my_version[]m4_if(my_issvn,[yes],
35           [m4_if(git_revision,[],[-svn[]svn_revision],[-git[]git_revision])])])
36
37 AC_INIT([gnupg],[my_full_version],[http://bugs.gnupg.org])
38 # Set development_version to yes if the minor number is odd or you
39 # feel that the default check for a development version is not
40 # sufficient.
41 development_version=no
42
43 NEED_GPG_ERROR_VERSION=1.7
44
45 NEED_LIBGCRYPT_API=1
46 NEED_LIBGCRYPT_VERSION=1.4.0
47
48 NEED_LIBASSUAN_API=2
49 NEED_LIBASSUAN_VERSION=2.0.0
50
51 NEED_KSBA_API=1
52 NEED_KSBA_VERSION=1.0.7
53
54
55 PACKAGE=$PACKAGE_NAME
56 PACKAGE_GT=${PACKAGE_NAME}2
57 VERSION=$PACKAGE_VERSION
58
59 AC_CONFIG_AUX_DIR(scripts)
60 AC_CONFIG_SRCDIR(sm/gpgsm.c)
61 AM_CONFIG_HEADER(config.h)
62 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
63 AC_CANONICAL_HOST
64 AB_INIT
65
66 AC_GNU_SOURCE
67
68 # Some status variables.
69 have_gpg_error=no
70 have_libgcrypt=no
71 have_libassuan=no
72 have_ksba=no
73 have_pth=no
74 have_libusb=no
75 have_adns=no
76
77 use_bzip2=yes
78 use_exec=yes
79 disable_keyserver_path=no
80 use_ccid_driver=yes
81 use_standard_socket=no
82
83 GNUPG_BUILD_PROGRAM(gpg, yes)
84 GNUPG_BUILD_PROGRAM(gpgsm, yes)
85 GNUPG_BUILD_PROGRAM(agent, yes)
86 GNUPG_BUILD_PROGRAM(scdaemon, yes)
87 GNUPG_BUILD_PROGRAM(tools, yes)
88 GNUPG_BUILD_PROGRAM(doc, yes)
89 GNUPG_BUILD_PROGRAM(symcryptrun, no)
90 GNUPG_BUILD_PROGRAM(gpgtar, no)
91
92
93 AC_SUBST(PACKAGE)
94 AC_SUBST(PACKAGE_GT)
95 AC_SUBST(VERSION)
96 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
97 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
98                                 [Name of this package for gettext])
99 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
100 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
101                                         [Bug report address])
102 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
103                                        [Required version of Libgcrypt])
104 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
105                                        [Required version of Libksba])
106
107
108 # The default is to use the modules from this package and the few
109 # other packages in a standard place; i.e where this package gets
110 # installed.  With these options it is possible to override these
111 # ${prefix} depended values with fixed paths, which can't be replaced
112 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
113 AC_ARG_WITH(agent-pgm,
114     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
115           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
116 AC_SUBST(GNUPG_AGENT_PGM)
117 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
118 show_gnupg_agent_pgm="(default)"
119 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
120
121 AC_ARG_WITH(pinentry-pgm,
122     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
123           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
124 AC_SUBST(GNUPG_PINENTRY_PGM)
125 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
126 show_gnupg_pinentry_pgm="(default)"
127 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
128
129
130 AC_ARG_WITH(scdaemon-pgm,
131     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
132           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
133 AC_SUBST(GNUPG_SCDAEMON_PGM)
134 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
135 show_gnupg_scdaemon_pgm="(default)"
136 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
137
138
139 AC_ARG_WITH(dirmngr-pgm,
140     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
141           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
142 AC_SUBST(GNUPG_DIRMNGR_PGM)
143 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
144 show_gnupg_dirmngr_pgm="(default)"
145 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
146
147 AC_ARG_WITH(protect-tool-pgm,
148     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
149           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
150 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
151 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
152 show_gnupg_protect_tool_pgm="(default)"
153 test -n "$GNUPG_PROTECT_TOOL_PGM" \
154       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
155
156
157 # Some folks want to use only the agent from this packet.  Make it
158 # easier for them by providing the configure option
159 # --enable-only-agent.
160 AC_ARG_ENABLE(agent-only,
161     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
162     build_agent_only=$enableval)
163
164 # SELinux support includes tracking of sensitive files to avoid
165 # leaking their contents through processing these files by gpg itself
166 AC_MSG_CHECKING([whether SELinux support is requested])
167 AC_ARG_ENABLE(selinux-support,
168               AC_HELP_STRING([--enable-selinux-support],
169                              [enable SELinux support]),
170               selinux_support=$enableval, selinux_support=no)
171 AC_MSG_RESULT($selinux_support)
172
173 # Allow disabling of bzib2 support.
174 # It is defined only after we confirm the library is available later
175 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
176 AC_ARG_ENABLE(bzip2,
177    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
178    use_bzip2=$enableval)
179 AC_MSG_RESULT($use_bzip2)
180
181 # Configure option to allow or disallow execution of external
182 # programs, like a photo viewer.
183 AC_MSG_CHECKING([whether to enable external program execution])
184 AC_ARG_ENABLE(exec,
185     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
186     use_exec=$enableval)
187 AC_MSG_RESULT($use_exec)
188 if test "$use_exec" = no ; then
189     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
190 fi
191
192 if test "$use_exec" = yes ; then
193   AC_MSG_CHECKING([whether to enable photo ID viewing])
194   AC_ARG_ENABLE(photo-viewers,
195       [  --disable-photo-viewers disable photo ID viewers],
196       [if test "$enableval" = no ; then
197          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
198       fi],enableval=yes)
199   gnupg_cv_enable_photo_viewers=$enableval
200   AC_MSG_RESULT($enableval)
201
202   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
203     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
204     AC_ARG_WITH(photo-viewer,
205         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
206         [if test "$withval" = yes ; then
207            withval=no
208         elif test "$withval" != no ; then
209            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
210                             [if set, restrict photo-viewer to this])
211         fi],withval=no)
212     AC_MSG_RESULT($withval)
213   fi
214
215   AC_MSG_CHECKING([whether to enable external keyserver helpers])
216   AC_ARG_ENABLE(keyserver-helpers,
217       [  --disable-keyserver-helpers  disable all external keyserver support],
218       [if test "$enableval" = no ; then
219          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
220                   [define to disable keyserver helpers])
221       fi],enableval=yes)
222   gnupg_cv_enable_keyserver_helpers=$enableval
223   AC_MSG_RESULT($enableval)
224
225   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
226     # LDAP is defined only after we confirm the library is available later
227     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
228     AC_ARG_ENABLE(ldap,
229       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
230       try_ldap=$enableval, try_ldap=yes)
231     AC_MSG_RESULT($try_ldap)
232
233     AC_MSG_CHECKING([whether HKP keyserver support is requested])
234     AC_ARG_ENABLE(hkp,
235       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
236       try_hkp=$enableval, try_hkp=yes)
237     AC_MSG_RESULT($try_hkp)
238
239     AC_MSG_CHECKING([whether finger key fetching support is requested])
240     AC_ARG_ENABLE(finger,
241       AC_HELP_STRING([--disable-finger],
242         [disable finger key fetching interface only]),
243       try_finger=$enableval, try_finger=yes)
244     AC_MSG_RESULT($try_finger)
245
246     AC_MSG_CHECKING([whether generic object key fetching support is requested])
247     AC_ARG_ENABLE(generic,
248       AC_HELP_STRING([--disable-generic],
249         [disable generic object key fetching interface only]),
250       try_generic=$enableval, try_generic=yes)
251     AC_MSG_RESULT($try_generic)
252
253     AC_MSG_CHECKING([whether email keyserver support is requested])
254     AC_ARG_ENABLE(mailto,
255       AC_HELP_STRING([--enable-mailto],
256         [enable email keyserver interface only]),
257       try_mailto=$enableval, try_mailto=no)
258     AC_MSG_RESULT($try_mailto)
259   fi
260
261   AC_MSG_CHECKING([whether keyserver exec-path is enabled])
262   AC_ARG_ENABLE(keyserver-path,
263       AC_HELP_STRING([--disable-keyserver-path],
264            [disable the exec-path option for keyserver helpers]),
265            [if test "$enableval" = no ; then
266               disable_keyserver_path=yes
267            fi],enableval=yes)
268   AC_MSG_RESULT($enableval)
269 fi
270
271
272 #
273 # Check for the key/uid cache size.  This can't be zero, but can be
274 # pretty small on embedded systems.  This is used for the gpg part.
275 #
276 AC_MSG_CHECKING([for the size of the key and uid cache])
277 AC_ARG_ENABLE(key-cache,
278         AC_HELP_STRING([--enable-key-cache=SIZE],
279                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
280 if test "$enableval" = "no"; then
281    enableval=5
282 elif test "$enableval" = "yes" || test "$enableval" = ""; then
283    enableval=4096
284 fi
285 changequote(,)dnl
286 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
287 changequote([,])dnl
288 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
289    AC_MSG_ERROR([invalid key-cache size])
290 fi
291 AC_MSG_RESULT($key_cache_size)
292 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
293                   [Size of the key and UID caches])
294
295
296
297 #
298 # Check whether we want to use Linux capabilities
299 #
300 AC_MSG_CHECKING([whether use of capabilities is requested])
301 AC_ARG_WITH(capabilities,
302     [  --with-capabilities     use linux capabilities [default=no]],
303 [use_capabilities="$withval"],[use_capabilities=no])
304 AC_MSG_RESULT($use_capabilities)
305
306
307 #
308 # Allow disabling of internal CCID support.
309 # It is defined only after we confirm the library is available later
310 #
311 AC_MSG_CHECKING([whether to enable the internal CCID driver])
312 AC_ARG_ENABLE(ccid-driver,
313               AC_HELP_STRING([--disable-ccid-driver],
314                              [disable the internal CCID driver]),
315               use_ccid_driver=$enableval)
316 AC_MSG_RESULT($use_ccid_driver)
317
318
319 #
320 # To avoid double inclusion of config.h which might happen at some
321 # places, we add the usual double inclusion protection at the top of
322 # config.h.
323 #
324 AH_TOP([
325 #ifndef GNUPG_CONFIG_H_INCLUDED
326 #define GNUPG_CONFIG_H_INCLUDED
327 ])
328
329 #
330 # Stuff which goes at the bottom of config.h.
331 #
332 AH_BOTTOM([
333 /* This is the major version number of GnuPG so that
334    source included files can test for this.  Note, that
335    we use 2 here even for GnuPG 1.9.x. */
336 #define GNUPG_MAJOR_VERSION 2
337
338 /* Now to separate file name parts.
339    Please note that the string version must not contain more
340    than one character because the code assumes strlen()==1 */
341 #ifdef HAVE_DOSISH_SYSTEM
342 #define DIRSEP_C '\\'
343 #define DIRSEP_S "\\"
344 #define EXTSEP_C '.'
345 #define EXTSEP_S "."
346 #define PATHSEP_C ';'
347 #define PATHSEP_S ";"
348 #define EXEEXT_S ".exe"
349 #else
350 #define DIRSEP_C '/'
351 #define DIRSEP_S "/"
352 #define EXTSEP_C '.'
353 #define EXTSEP_S "."
354 #define PATHSEP_C ':'
355 #define PATHSEP_S ":"
356 #define EXEEXT_S ""
357 #endif
358
359 /* This is the same as VERSION, but should be overridden if the
360    platform cannot handle things like dots '.' in filenames. Set
361    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
362    uses for dots and dashes. */
363 #define SAFE_VERSION VERSION
364 #define SAFE_VERSION_DOT  '.'
365 #define SAFE_VERSION_DASH '-'
366
367 /* Some global constants. */
368 #ifdef HAVE_DRIVE_LETTERS
369 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
370 #elif defined(__VMS)
371 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg"
372 #else
373 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
374 #endif
375 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
376
377 /* For some systems (DOS currently), we hardcode the path here.  For
378    POSIX systems the values are constructed by the Makefiles, so that
379    the values may be overridden by the make invocations; this is to
380    comply with the GNU coding standards. */
381 #ifdef HAVE_DRIVE_LETTERS
382  /* FIXME: We need to use a function to determine these values depending
383     on the actual installation directory. */
384 #define GNUPG_BINDIR      "c:\\gnupg"
385 #define GNUPG_LIBEXECDIR  "c:\\gnupg"
386 #define GNUPG_LIBDIR      "c:\\gnupg"
387 #define GNUPG_DATADIR     "c:\\gnupg"
388 #define GNUPG_SYSCONFDIR  "c:\\gnupg"
389 #endif
390
391 /* Derive some other constants. */
392 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
393 #define EXEC_TEMPFILE_ONLY
394 #endif
395
396
397 /* We didn't define endianness above, so get it from OS macros.  This
398    is intended for making fat binary builds on OS X. */
399 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
400 #if defined(__BIG_ENDIAN__)
401 #define BIG_ENDIAN_HOST 1
402 #elif defined(__LITTLE_ENDIAN__)
403 #define LITTLE_ENDIAN_HOST 1
404 #else
405 #error "No endianness found"
406 #endif
407 #endif
408
409
410 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
411    ldap_start_tls_s because that is the actual symbol used in the
412    library.  winldap.h redefines it to our commonly used value,
413    thus we define our usual macro here.  */
414 #ifdef HAVE_LDAP_START_TLS_SA
415 # ifndef HAVE_LDAP_START_TLS_S
416 #  define HAVE_LDAP_START_TLS_S 1
417 # endif
418 #endif
419
420
421 /* Tell libgcrypt not to use its own libgpg-error implementation. */
422 #define USE_LIBGPG_ERROR 1
423
424 /* We use jnlib, so tell other modules about it.  */
425 #define HAVE_JNLIB_LOGGING 1
426
427 /* Our HTTP code is used in estream mode.  */
428 #define HTTP_USE_ESTREAM 1
429
430 /* Under W32 we do an explicit socket initialization, thus we need to
431    avoid the on-demand initialization which would also install an atexit
432    handler.  */
433 #define HTTP_NO_WSASTARTUP
434
435 /* We always include support for the OpenPGP card.  */
436 #define ENABLE_CARD_SUPPORT 1
437
438 /* We don't want the old assuan codes anymore. */
439 #define _ASSUAN_ONLY_GPG_ERRORS 1
440
441 /* We explicitly need to disable PTH's soft mapping as Debian
442    currently enables it by default for no reason. */
443 #define PTH_SYSCALL_SOFT 0
444
445 /* We want to use the libgcrypt provided memory allocation for
446    asprintf.  */
447 #define _ESTREAM_PRINTF_MALLOC        gcry_malloc
448 #define _ESTREAM_PRINTF_FREE          gcry_free
449 #define _ESTREAM_PRINTF_EXTRA_INCLUDE "util.h"
450
451 #endif /*GNUPG_CONFIG_H_INCLUDED*/
452 ])
453
454
455 AM_MAINTAINER_MODE
456
457 # Checks for programs.
458 AC_MSG_NOTICE([checking for programs])
459 AC_PROG_MAKE_SET
460 AM_SANITY_CHECK
461 missing_dir=`cd $ac_aux_dir && pwd`
462 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
463 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
464 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
465 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
466 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
467 AC_PROG_AWK
468 AC_PROG_CC
469 AC_PROG_CPP
470 AM_PROG_CC_C_O
471 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
472   AC_MSG_ERROR([[No C-89 compiler found]])
473 fi
474 AC_PROG_INSTALL
475 AC_PROG_LN_S
476 AC_PROG_RANLIB
477 AC_CHECK_TOOL(AR, ar, :)
478 AC_PATH_PROG(PERL,"perl")
479 AC_CHECK_TOOL(WINDRES, windres, :)
480 AC_ISC_POSIX
481 gl_EARLY
482 AC_SYS_LARGEFILE
483 GNUPG_CHECK_FAQPROG
484 GNUPG_CHECK_USTAR
485
486 # We need to compile and run a program on the build machine.  A
487 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
488 # the AC archive is broken for autoconf 2.57.  Given that tehre is no
489 # newer version of that macro, we assume that it is also broken for
490 # autoconf 2.61 and thus we use a simple but usually sufficient
491 # approach.
492 AC_MSG_CHECKING(for cc for build)
493 if test "$cross_compiling" = "yes"; then
494   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
495 else
496   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
497 fi
498 AC_MSG_RESULT($CC_FOR_BUILD)
499 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
500
501
502
503 try_gettext=yes
504 have_dosish_system=no
505 have_w32_system=no
506 use_simple_gettext=no
507 case "${host}" in
508     *-mingw32*)
509         # special stuff for Windoze NT
510         ac_cv_have_dev_random=no
511         AC_DEFINE(USE_ONLY_8DOT3,1,
512                   [set this to limit filenames to the 8.3 format])
513         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
514                   [defined if we must run on a stupid file system])
515         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
516                   [because the Unix gettext has too much overhead on
517                    MingW32 systems and these systems lack Posix functions,
518                    we use a simplified version of gettext])
519         disable_keyserver_path=yes
520         have_dosish_system=yes
521         have_w32_system=yes
522         try_gettext="no"
523         use_simple_gettext=yes
524         ;;
525     i?86-emx-os2 | i?86-*-os2*emx )
526         # OS/2 with the EMX environment
527         ac_cv_have_dev_random=no
528         AC_DEFINE(HAVE_DRIVE_LETTERS)
529         have_dosish_system=yes
530         try_gettext="no"
531         ;;
532
533     i?86-*-msdosdjgpp*)
534         # DOS with the DJGPP environment
535         ac_cv_have_dev_random=no
536         AC_DEFINE(HAVE_DRIVE_LETTERS)
537         have_dosish_system=yes
538         try_gettext="no"
539         ;;
540
541     *-*-freebsd*)
542        # FreeBSD
543        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
544        LDFLAGS="$LDFLAGS -L/usr/local/lib"
545        ;;
546
547     *-*-hpux*)
548         if test -z "$GCC" ; then
549             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
550         fi
551         ;;
552     *-dec-osf4*)
553         if test -z "$GCC" ; then
554             # Suppress all warnings
555             # to get rid of the unsigned/signed char mismatch warnings.
556             CFLAGS="$CFLAGS -w"
557         fi
558         ;;
559     *-dec-osf5*)
560         if test -z "$GCC" ; then
561             # Use the newer compiler `-msg_disable ptrmismatch1' to
562             # get rid of the unsigned/signed char mismatch warnings.
563             # Using this may hide other pointer mismatch warnings, but
564             # it at least lets other warning classes through
565             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
566         fi
567         ;;
568     m68k-atari-mint)
569         ;;
570     *)
571        ;;
572 esac
573
574 if test "$have_dosish_system" = yes; then
575    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
576              [Defined if we run on some of the PCDOS like systems
577               (DOS, Windoze. OS/2) with special properties like
578               no file modes])
579 fi
580 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
581
582 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
583
584 if test "$have_w32_system" = yes; then
585    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
586 fi
587 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
588
589 if test "$disable_keyserver_path" = yes; then
590     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
591               [Defined to disable exec-path for keyserver helpers])
592 fi
593
594 #
595 # Allows enabling the use of a standard socket by default This is
596 # gpg-agent's option --[no-]use-standard-socket.  For Windows we force
597 # the use of this.
598 #
599 AC_MSG_CHECKING([whether to use a standard socket by default])
600 AC_ARG_ENABLE(standard-socket,
601               AC_HELP_STRING([--enable-standard-socket],
602                              [use a standard socket for the agent by default]),
603               use_standard_socket=$enableval)
604 tmp=""
605 if test "$use_standard_socket" != yes; then
606   if test "$have_w32_system" = yes; then
607     use_standard_socket=yes
608     tmp=" (forced)"
609   fi
610 fi
611 AC_MSG_RESULT($use_standard_socket$tmp)
612 if test "$use_standard_socket" = yes; then
613   AC_DEFINE(USE_STANDARD_SOCKET,1,
614             [Use a standard socket for the agent by default])
615 fi
616
617
618 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
619 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
620
621 if test x"$try_hkp" = xyes ; then
622   AC_SUBST(GPGKEYS_HKP,"gpg2keys_hkp$EXEEXT")
623 fi
624
625 if test x"$try_finger" = xyes ; then
626   AC_SUBST(GPGKEYS_FINGER,"gpg2keys_finger$EXEEXT")
627 fi
628
629
630
631 #
632 # Checks for libraries.
633 #
634 AC_MSG_NOTICE([checking for libraries])
635
636
637 #
638 # libgpg-error is a library with error codes shared between GnuPG
639 # related projects.
640 #
641 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
642                   have_gpg_error=yes,have_gpg_error=no)
643
644
645 #
646 # Libgcrypt is our generic crypto library
647 #
648 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
649         have_libgcrypt=yes,have_libgcrypt=no)
650
651
652 #
653 # libassuan is used for IPC
654 #
655 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
656                   have_libassuan=yes,have_libassuan=no)
657 if test "$have_libassuan" = "yes"; then
658   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
659             [version of the libbassuan library])
660 fi
661
662
663
664 #
665 # libksba is our X.509 support library
666 #
667 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
668
669
670 #
671 # libusb allows us to use the integrated CCID smartcard reader driver.
672 #
673 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
674 if test "$use_ccid_driver" = yes ; then
675   AC_CHECK_LIB(usb, usb_bulk_write,
676                 [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
677                   AC_DEFINE(HAVE_LIBUSB,1,
678                            [defined if libusb is available])
679                   have_libusb=yes
680                ])
681   AC_CHECK_FUNCS(usb_create_match)
682 fi
683 AC_SUBST(LIBUSB_LIBS)
684
685 #
686 # Check wether it is necessary to link against libdl.
687 #
688 gnupg_dlopen_save_libs="$LIBS"
689 LIBS=""
690 AC_SEARCH_LIBS(dlopen, c dl,,,)
691 DL_LIBS=$LIBS
692 AC_SUBST(DL_LIBS)
693 LIBS="$gnupg_dlopen_save_libs"
694
695 #
696 # Checks for symcryptrun:
697 #
698
699 # libutil has openpty() and login_tty().
700 AC_CHECK_LIB(util, openpty,
701               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
702                 AC_DEFINE(HAVE_LIBUTIL,1,
703                          [defined if libutil is available])
704              ])
705 AC_SUBST(LIBUTIL_LIBS)
706
707 # shred is used to clean temporary plain text files.
708 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
709 AC_DEFINE_UNQUOTED(SHRED,
710         "${SHRED}", [defines the filename of the shred program])
711
712
713
714 #
715 # Check whether the GNU Pth library is available
716 # Note, that we include a Pth emulation for W32.
717 #
718 GNUPG_PATH_PTH
719 if test "$have_pth" = "yes"; then
720   AC_DEFINE(USE_GNU_PTH, 1,
721               [Defined if the GNU Portable Thread Library should be used])
722 else
723   AC_MSG_WARN([[
724 ***
725 *** To support concurrent access to the gpg-agent and the SCdaemon
726 *** we need the support of the GNU Portable Threads Library.
727 *** Download it from ftp://ftp.gnu.org/gnu/pth/
728 *** On a Debian GNU/Linux system you might want to try
729 ***   apt-get install libpth-dev
730 ***]])
731 fi
732
733
734 AC_MSG_NOTICE([checking for networking options])
735
736 #
737 # Must check for network library requirements before doing link tests
738 # for ldap, for example. If ldap libs are static (or dynamic and without
739 # ELF runtime link paths), then link will fail and LDAP support won't
740 # be detected.
741 #
742 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
743         [NETLIBS="-lnsl $NETLIBS"]))
744 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
745         [NETLIBS="-lsocket $NETLIBS"]))
746
747
748 #
749 # Check for ADNS.
750 #
751 _cppflags="${CPPFLAGS}"
752 _ldflags="${LDFLAGS}"
753 AC_ARG_WITH(adns,
754             AC_HELP_STRING([--with-adns=DIR],
755                            [look for the adns library in DIR]),
756             [if test -d "$withval"; then
757                CPPFLAGS="${CPPFLAGS} -I$withval/include"
758                LDFLAGS="${LDFLAGS} -L$withval/lib"
759              fi])
760 if test "$with_adns" != "no"; then
761   AC_CHECK_HEADERS(adns.h,
762                 AC_CHECK_LIB(adns, adns_init,
763                              [have_adns=yes],
764                              [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}]),
765                 [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}])
766 fi
767 if test "$have_adns" = "yes"; then
768   ADNSLIBS="-ladns"
769 fi
770 AC_SUBST(ADNSLIBS)
771 # Newer adns versions feature a free function to be used under W32.
772 AC_CHECK_FUNCS(adns_free)
773
774
775 #
776 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
777 #
778 if test x"$try_hkp" = xyes || test x"$try_http" = xyes ; then
779   AC_ARG_ENABLE(dns-srv,
780      AC_HELP_STRING([--disable-dns-srv],
781                     [disable the use of DNS SRV in HKP and HTTP]),
782                 use_dns_srv=$enableval,use_dns_srv=yes)
783 fi
784
785 AC_ARG_ENABLE(dns-pka,
786    AC_HELP_STRING([--disable-dns-pka],
787         [disable the use of PKA records in DNS]),
788    use_dns_pka=$enableval,use_dns_pka=yes)
789
790 AC_ARG_ENABLE(dns-cert,
791    AC_HELP_STRING([--disable-dns-cert],
792         [disable the use of CERT records in DNS]),
793    use_dns_cert=$enableval,use_dns_cert=yes)
794
795 if test x"$use_dns_pka" = xyes || test x"$use_dns_srv" = xyes \
796    || test x"$use_dns_cert" = xyes; then
797   _dns_save_libs=$LIBS
798   LIBS=""
799   # the double underscore thing is a glibc-ism?
800   AC_SEARCH_LIBS(res_query,resolv bind,,
801                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
802   AC_SEARCH_LIBS(dn_expand,resolv bind,,
803                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
804   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
805                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
806
807   if test x"$have_resolver" != xno ; then
808
809     # Make sure that the BIND 4 resolver interface is workable before
810     # enabling any code that calls it.  At some point I'll rewrite the
811     # code to use the BIND 8 resolver API.
812     # We might also want to use adns instead.  Problem with ADNS is that
813     # it does not support v6.
814
815     AC_MSG_CHECKING([whether the resolver is usable])
816     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
817 #include <netinet/in.h>
818 #include <arpa/nameser.h>
819 #include <resolv.h>]],
820 [[unsigned char answer[PACKETSZ];
821   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
822   dn_skipname(0,0);
823   dn_expand(0,0,0,0,0);
824 ]])],have_resolver=yes,have_resolver=no)
825     AC_MSG_RESULT($have_resolver)
826
827     # This is Apple-specific and somewhat bizarre as they changed the
828     # define in bind 8 for some reason.
829
830     if test x"$have_resolver" != xyes ; then
831        AC_MSG_CHECKING(
832              [whether I can make the resolver usable with BIND_8_COMPAT])
833        AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
834 #include <sys/types.h>
835 #include <netinet/in.h>
836 #include <arpa/nameser.h>
837 #include <resolv.h>]],
838 [[unsigned char answer[PACKETSZ];
839   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
840   dn_skipname(0,0); dn_expand(0,0,0,0,0);
841 ]])],[have_resolver=yes ; need_compat=yes])
842        AC_MSG_RESULT($have_resolver)
843     fi
844   fi
845
846   if test x"$have_resolver" = xyes ; then
847      DNSLIBS=$LIBS
848
849      if test x"$use_dns_srv" = xyes ; then
850         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
851      fi
852
853      if test x"$use_dns_pka" = xyes ; then
854         AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
855      fi
856
857      if test x"$use_dns_cert" = xyes ; then
858         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
859      fi
860
861      if test x"$need_compat" = xyes ; then
862         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
863      fi
864   else
865      # If we have no resolver library but ADNS (e.g. under W32) enable the
866      # code parts which can be used with ADNS.
867      if test x"$have_adns" = xyes ; then
868         DNSLIBS="$ADNSLIBS"
869         AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
870
871         if test x"$use_dns_srv" = xyes ; then
872            AC_DEFINE(USE_DNS_SRV,1)
873         fi
874
875         if test x"$use_dns_pka" = xyes ; then
876            AC_DEFINE(USE_DNS_PKA,1)
877         fi
878
879         if test x"$use_dns_cert" = xyes ; then
880            AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
881         fi
882      else
883         use_dns_srv=no
884         use_dns_pka=no
885         use_dns_cert=no
886      fi
887   fi
888
889   LIBS=$_dns_save_libs
890 fi
891
892 AC_SUBST(DNSLIBS)
893
894 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
895
896
897 #
898 # Check for LDAP
899 #
900 if test "$try_ldap" = yes ; then
901    GNUPG_CHECK_LDAP($NETLIBS)
902 fi
903
904 #
905 # Check for curl.  We fake the curl API if libcurl isn't installed.
906 # We require 7.10 or later as we use curl_version_info().
907 #
908 LIBCURL_CHECK_CONFIG([yes],[7.10],,[fake_curl=yes])
909 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
910
911 # Generic, for us, means curl
912
913 if test x"$try_generic" = xyes ; then
914    AC_SUBST(GPGKEYS_CURL,"gpg2keys_curl$EXEEXT")
915 fi
916
917 #
918 # Check for sendmail
919 #
920 # This isn't necessarily sendmail itself, but anything that gives a
921 # sendmail-ish interface to the outside world.  That includes Exim,
922 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
923 if test "$try_mailto" = yes ; then
924   AC_ARG_WITH(mailprog,
925       AC_HELP_STRING([--with-mailprog=NAME],
926                      [use "NAME -t" for mail transport]),
927              ,with_mailprog=yes)
928
929   if test x"$with_mailprog" = xyes ; then
930     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
931     if test "$ac_cv_path_SENDMAIL" ; then
932       GPGKEYS_MAILTO="gpg2keys_mailto"
933     fi
934   elif test x"$with_mailprog" != xno ; then
935     AC_MSG_CHECKING([for a mail transport program])
936     AC_SUBST(SENDMAIL,$with_mailprog)
937     AC_MSG_RESULT($with_mailprog)
938     GPGKEYS_MAILTO="gpg2keys_mailto"
939   fi
940 fi
941
942 AC_SUBST(GPGKEYS_MAILTO)
943
944 #
945 # Construct a printable name of the OS
946 #
947 case "${host}" in
948     *-mingw32*)
949         PRINTABLE_OS_NAME="MingW32"
950         ;;
951     *-*-cygwin*)
952         PRINTABLE_OS_NAME="Cygwin"
953         ;;
954     i?86-emx-os2 | i?86-*-os2*emx )
955         PRINTABLE_OS_NAME="OS/2"
956         ;;
957     i?86-*-msdosdjgpp*)
958         PRINTABLE_OS_NAME="MSDOS/DJGPP"
959         try_dynload=no
960         ;;
961     *-linux*)
962         PRINTABLE_OS_NAME="GNU/Linux"
963         ;;
964     *)
965         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
966         ;;
967 esac
968 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
969                    [A human readable text with the name of the OS])
970
971
972 #
973 # Checking for iconv
974 #
975 AM_ICONV
976
977
978 #
979 # Check for gettext
980 #
981 # This is "GNU gnupg" - The project-id script from gettext
982 #                       needs this string
983 #
984 AC_MSG_NOTICE([checking for gettext])
985 AM_PO_SUBDIRS
986 AM_GNU_GETTEXT_VERSION([0.17])
987 if test "$try_gettext" = yes; then
988   AM_GNU_GETTEXT([external],[need-ngettext])
989
990   # gettext requires some extra checks.  These really should be part of
991   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
992   # function checks to here.
993
994   AC_CHECK_FUNCS(strchr)
995 else
996   USE_NLS=no
997   USE_INCLUDED_LIBINTL=no
998   BUILD_INCLUDED_LIBINTL=no
999   POSUB=po
1000   AC_SUBST(USE_NLS)
1001   AC_SUBST(USE_INCLUDED_LIBINTL)
1002   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1003   AC_SUBST(POSUB)
1004 fi
1005
1006 # We use HAVE_LANGINFO_CODESET in a couple of places.
1007 AM_LANGINFO_CODESET
1008
1009 # Checks required for our use locales
1010 gt_LC_MESSAGES
1011
1012
1013 #
1014 # SELinux support
1015 #
1016 if test "$selinux_support" = yes ; then
1017   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1018 fi
1019
1020
1021 #
1022 # Checks for header files.
1023 #
1024 AC_MSG_NOTICE([checking for header files])
1025 AC_HEADER_STDC
1026 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h])
1027 AC_CHECK_HEADERS([pty.h utmp.h pwd.h inttypes.h])
1028 AC_HEADER_TIME
1029
1030
1031 #
1032 # Checks for typedefs, structures, and compiler characteristics.
1033 #
1034 AC_MSG_NOTICE([checking for system characteristics])
1035 AC_C_CONST
1036 AC_C_INLINE
1037 AC_C_VOLATILE
1038 AC_TYPE_SIZE_T
1039 AC_TYPE_MODE_T
1040 AC_TYPE_SIGNAL
1041 AC_DECL_SYS_SIGLIST
1042
1043 gl_HEADER_SYS_SOCKET
1044 gl_TYPE_SOCKLEN_T
1045
1046 AC_ARG_ENABLE(endian-check,
1047               AC_HELP_STRING([--disable-endian-check],
1048               [disable the endian check and trust the OS provided macros]),
1049               endiancheck=$enableval,endiancheck=yes)
1050
1051 if test x"$endiancheck" = xyes ; then
1052   GNUPG_CHECK_ENDIAN
1053 fi
1054
1055 # fixme: we should get rid of the byte type
1056 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1057 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1058 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1059 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1060 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1061
1062 AC_CHECK_SIZEOF(unsigned short)
1063 AC_CHECK_SIZEOF(unsigned int)
1064 AC_CHECK_SIZEOF(unsigned long)
1065 AC_CHECK_SIZEOF(unsigned long long)
1066 AC_CHECK_SIZEOF(time_t,,[[
1067 #include <stdio.h>
1068 #if TIME_WITH_SYS_TIME
1069 # include <sys/time.h>
1070 # include <time.h>
1071 #else
1072 # if HAVE_SYS_TIME_H
1073 #  include <sys/time.h>
1074 # else
1075 #  include <time.h>
1076 # endif
1077 #endif
1078 ]])
1079
1080
1081 # Ensure that we have UINT64_C before we bother to check for uint64_t
1082 # Fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
1083 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
1084    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <inttypes.h>]],
1085                                       [[uint64_t foo=UINT64_C(42);]])],
1086                                       [gnupg_cv_uint64_c_works=yes],
1087                                       [gnupg_cv_uint64_c_works=no]   ))
1088 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
1089    AC_CHECK_SIZEOF(uint64_t)
1090 fi
1091
1092 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1093    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1094    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1095     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1096 fi
1097
1098
1099 #
1100 # Checks for library functions.
1101 #
1102 AC_MSG_NOTICE([checking for library functions])
1103 AC_CHECK_DECLS(getpagesize)
1104 AC_FUNC_FSEEKO
1105 AC_FUNC_VPRINTF
1106 AC_FUNC_FORK
1107 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap])
1108 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r])
1109 AC_CHECK_FUNCS([unsetenv fcntl ftruncate])
1110 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1111 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1112 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe stat getaddrinfo])
1113 AC_CHECK_FUNCS([ttyname rand ftello fsync stat])
1114
1115 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1116
1117 #
1118 # These are needed by libjnlib - fixme: we should use a jnlib.m4
1119 # Note:  We already checked pwd.h.
1120 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol])
1121 AC_CHECK_FUNCS([memrchr isascii timegm getrusage setrlimit stat setlocale])
1122 AC_CHECK_FUNCS([flockfile funlockfile fopencookie funopen getpwnam getpwuid])
1123
1124 #
1125 # gnulib checks
1126 #
1127 gl_SOURCE_BASE([gl])
1128 gl_M4_BASE([gl/m4])
1129 gl_MODULES([setenv mkdtemp xsize strpbrk])
1130 gl_INIT
1131
1132
1133 #
1134 # W32 specific test
1135 #
1136 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1137
1138 #
1139 # Sanity check regex.  Tests adapted from mutt.
1140 #
1141 AC_MSG_CHECKING([whether regular expression support is requested])
1142 AC_ARG_ENABLE(regex,
1143   AC_HELP_STRING([--disable-regex],
1144     [do not handle regular expressions in trust signatures]),
1145   use_regex=$enableval, use_regex=yes)
1146 AC_MSG_RESULT($use_regex)
1147
1148 if test "$use_regex" = yes ; then
1149   _cppflags="${CPPFLAGS}"
1150   _ldflags="${LDFLAGS}"
1151   AC_ARG_WITH(regex,
1152      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1153       [
1154       if test -d "$withval" ; then
1155         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1156         LDFLAGS="${LDFLAGS} -L$withval/lib"
1157       fi
1158       ],withval="")
1159
1160   # Does the system have regex functions at all?
1161   AC_SEARCH_LIBS([regcomp], [regex])
1162   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1163
1164   if test $gnupg_cv_have_regex = no; then
1165     use_regex=no
1166   else
1167     if test x"$cross_compiling" = xyes; then
1168       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1169     else
1170       AC_CACHE_CHECK([whether your system's regexp library is broken],
1171        [gnupg_cv_regex_broken],
1172        AC_TRY_RUN([
1173 #include <unistd.h>
1174 #include <regex.h>
1175 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1176        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1177
1178       if test $gnupg_cv_regex_broken = yes; then
1179         AC_MSG_WARN([your regex is broken - disabling regex use])
1180         use_regex=no
1181       fi
1182     fi
1183   fi
1184   CPPFLAGS="${_cppflags}"
1185   LDFLAGS="${_ldflags}"
1186 fi
1187
1188 if test "$use_regex" != yes ; then
1189   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1190 fi
1191 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1192
1193
1194
1195 #
1196 # Do we have zlib? Must do it here because Solaris failed
1197 # when compiling a conftest (due to the "-lz" from LIBS).
1198 # Note that we combine zlib and bzlib2 in ZLIBS.
1199 #
1200 _cppflags="${CPPFLAGS}"
1201 _ldflags="${LDFLAGS}"
1202 AC_ARG_WITH(zlib,
1203   [  --with-zlib=DIR         use libz in DIR],[
1204     if test -d "$withval"; then
1205       CPPFLAGS="${CPPFLAGS} -I$withval/include"
1206       LDFLAGS="${LDFLAGS} -L$withval/lib"
1207     fi
1208   ])
1209
1210 AC_CHECK_HEADER(zlib.h,
1211       AC_CHECK_LIB(z, deflateInit2_,
1212        ZLIBS="-lz",
1213        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1214        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1215
1216 #
1217 # Check whether we can support bzip2
1218 #
1219 if test "$use_bzip2" = yes ; then
1220   _cppflags="${CPPFLAGS}"
1221   _ldflags="${LDFLAGS}"
1222   AC_ARG_WITH(bzip2,
1223      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1224       [
1225       if test -d "$withval" ; then
1226         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1227         LDFLAGS="${LDFLAGS} -L$withval/lib"
1228       fi
1229       ],withval="")
1230
1231   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1232   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1233   # woefully out of date.
1234   if test "$withval" != no ; then
1235      AC_CHECK_HEADER(bzlib.h,
1236         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1237           [
1238           have_bz2=yes
1239           ZLIBS="$ZLIBS -lbz2"
1240           AC_DEFINE(HAVE_BZIP2,1,
1241                   [Defined if the bz2 compression library is available])
1242           ],
1243           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1244           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1245   fi
1246 fi
1247 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1248 AC_SUBST(ZLIBS)
1249
1250
1251 # Check for readline support
1252 GNUPG_CHECK_READLINE
1253
1254 #
1255 # Allow users to append something to the version string without
1256 # flagging it as development version.  The user version parts is
1257 # considered everything after a dash.
1258 #
1259 if test "$development_version" != yes; then
1260   changequote(,)dnl
1261   tmp_pat='[a-zA-Z]'
1262   changequote([,])dnl
1263   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1264     development_version=yes
1265   fi
1266 fi
1267 if test "$development_version" = yes; then
1268     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1269             [Defined if this is not a regular release])
1270 fi
1271
1272 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1273
1274 GNUPG_CHECK_GNUMAKE
1275
1276 # Add some extra libs here so that previous tests don't fail for
1277 # mysterious reasons - the final link step should bail out.
1278 # W32SOCKLIBS is also defined so that if can be used for tools not
1279 # requiring any network stuff but linking to code in libcommon which
1280 # tracks in winsock stuff (e.g. init_common_subsystems.
1281 if test "$have_w32_system" = yes; then
1282    W32SOCKLIBS="-lws2_32"
1283    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1284 fi
1285
1286 AC_SUBST(NETLIBS)
1287 AC_SUBST(W32SOCKLIBS)
1288
1289 #
1290 # Setup gcc specific options
1291 #
1292 AC_MSG_NOTICE([checking for cc features])
1293 if test "$GCC" = yes; then
1294     # Note that it is okay to use CFLAGS here because this are just
1295     # warning options and the user should have a chance of overriding
1296     # them.
1297     if test "$USE_MAINTAINER_MODE" = "yes"; then
1298         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1299         CFLAGS="$CFLAGS -Wformat -Wno-format-y2k -Wformat-security"
1300         AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1301         _gcc_cflags_save=$CFLAGS
1302         CFLAGS="-Wno-missing-field-initializers"
1303         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1304                           [_gcc_wopt=yes],[_gcc_wopt=no])
1305         AC_MSG_RESULT($_gcc_wopt)
1306         CFLAGS=$_gcc_cflags_save;
1307         if test x"$_gcc_wopt" = xyes ; then
1308           CFLAGS="$CFLAGS -W -Wno-sign-compare -Wno-missing-field-initializers"
1309         fi
1310         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1311         _gcc_cflags_save=$CFLAGS
1312         CFLAGS="-Wdeclaration-after-statement"
1313         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1314                           [_gcc_wopt=yes],[_gcc_wopt=no])
1315         AC_MSG_RESULT($_gcc_wopt)
1316         CFLAGS=$_gcc_cflags_save;
1317         if test x"$_gcc_wopt" = xyes ; then
1318           CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1319         fi
1320     else
1321         CFLAGS="$CFLAGS -Wall"
1322     fi
1323
1324     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1325     _gcc_cflags_save=$CFLAGS
1326     CFLAGS="-Wno-pointer-sign"
1327     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],[_gcc_psign=yes],[_gcc_psign=no])
1328     AC_MSG_RESULT($_gcc_psign)
1329     CFLAGS=$_gcc_cflags_save;
1330     if test x"$_gcc_psign" = xyes ; then
1331        CFLAGS="$CFLAGS -Wno-pointer-sign"
1332     fi
1333
1334     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1335     _gcc_cflags_save=$CFLAGS
1336     CFLAGS="-Wpointer-arith"
1337     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],[_gcc_psign=yes],[_gcc_psign=no])
1338     AC_MSG_RESULT($_gcc_psign)
1339     CFLAGS=$_gcc_cflags_save;
1340     if test x"$_gcc_psign" = xyes ; then
1341        CFLAGS="$CFLAGS -Wpointer-arith"
1342     fi
1343 fi
1344
1345
1346 #
1347 # This is handy for debugging so the compiler doesn't rearrange
1348 # things and eliminate variables.
1349 #
1350 AC_ARG_ENABLE(optimization,
1351    AC_HELP_STRING([--disable-optimization],
1352                   [disable compiler optimization]),
1353                   [if test $enableval = no ; then
1354                       CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]]//'`
1355                    fi])
1356
1357 #
1358 # Prepare building of estream
1359 #
1360 estream_INIT
1361
1362
1363 #
1364 # Decide what to build
1365 #
1366 if test "$have_adns" = "yes"; then
1367   AC_SUBST(GPGKEYS_KDNS, "gpg2keys_kdns$EXEEXT")
1368 fi
1369
1370
1371 missing_pth=no
1372 if test $have_ksba = no; then
1373   build_gpgsm=no
1374   build_scdaemon=no
1375 fi
1376
1377 build_agent_threaded=""
1378 if test "$build_agent" = "yes"; then
1379   if test $have_pth = no; then
1380      build_agent_threaded="(not multi-threaded)"
1381      missing_pth=yes
1382   fi
1383 fi
1384
1385 build_scdaemon_extra=""
1386 if test "$build_scdaemon" = "yes"; then
1387   tmp=""
1388   if test $have_pth = no; then
1389      build_scdaemon_extra="not multi-threaded"
1390      tmp=", "
1391      missing_pth=yes
1392   fi
1393   if test $have_libusb = no; then
1394      build_scdaemon_extra="${tmp}without internal CCID driver"
1395      tmp=", "
1396   fi
1397   if test -n "$build_scdaemon_extra"; then
1398      build_scdaemon_extra="(${build_scdaemon_extra})"
1399   fi
1400 fi
1401
1402
1403 if test "$build_agent_only" = "yes" ; then
1404   build_gpg=no
1405   build_gpgsm=no
1406   build_scdaemon=no
1407   build_tools=no
1408   build_doc=no
1409 fi
1410
1411
1412 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1413 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1414 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1415 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1416 AM_CONDITIONAL(BUILD_TOOLS, test "$build_tools" = "yes")
1417 AM_CONDITIONAL(BUILD_DOC,   test "$build_doc" = "yes")
1418 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1419 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1420
1421 AM_CONDITIONAL(RUN_GPG_TESTS,
1422         test x$cross_compiling = xno -a "$build_gpg" = yes )
1423
1424
1425 #
1426 # Print errors here so that they are visible all
1427 # together and the user can acquire them all together.
1428 #
1429 die=no
1430 if test "$have_gpg_error" = "no"; then
1431    die=yes
1432    AC_MSG_NOTICE([[
1433 ***
1434 *** You need libgpg-error to build this program.
1435 **  This library is for example available at
1436 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1437 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1438 ***]])
1439 fi
1440 if test "$have_libgcrypt" = "no"; then
1441    die=yes
1442    AC_MSG_NOTICE([[
1443 ***
1444 *** You need libgcrypt to build this program.
1445 **  This library is for example available at
1446 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1447 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API is required.)
1448 ***]])
1449 fi
1450 if test "$have_libassuan" = "no"; then
1451    die=yes
1452    AC_MSG_NOTICE([[
1453 ***
1454 *** You need libassuan to build this program.
1455 *** This library is for example available at
1456 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1457 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1458 ***]])
1459 fi
1460 if test "$have_ksba" = "no"; then
1461     AC_MSG_NOTICE([[
1462 ***
1463 *** You need libksba to build this program.
1464 *** This library is for example available at
1465 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1466 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1467 ***]])
1468 fi
1469 if test "$missing_pth" = "yes"; then
1470     AC_MSG_NOTICE([[
1471 ***
1472 *** It is now required to build with support for the
1473 *** GNU Portable Threads Library (Pth). Please install this
1474 *** library first.  The library is for example available at
1475 ***   ftp://ftp.gnu.org/gnu/pth/
1476 *** On a Debian GNU/Linux system you can install it using
1477 ***   apt-get install libpth-dev
1478 *** To build GnuPG for Windows you need to use the W32PTH
1479 *** package; available at:
1480 ***   ftp://ftp.g10code.com/g10code/w32pth/
1481 ***]])
1482    die=yes
1483 fi
1484
1485 if test "$die" = "yes"; then
1486     AC_MSG_ERROR([[
1487 ***
1488 *** Required libraries not found. Please consult the above messages
1489 *** and install them before running configure again.
1490 ***]])
1491 fi
1492
1493
1494
1495 AC_CONFIG_FILES([ m4/Makefile
1496 Makefile
1497 po/Makefile.in
1498 gl/Makefile
1499 include/Makefile
1500 jnlib/Makefile
1501 common/Makefile
1502 kbx/Makefile
1503 g10/Makefile
1504 sm/Makefile
1505 agent/Makefile
1506 scd/Makefile
1507 keyserver/Makefile
1508 keyserver/gpg2keys_mailto
1509 keyserver/gpg2keys_test
1510 tools/gpg-zip
1511 tools/Makefile
1512 doc/Makefile
1513 tests/Makefile
1514 tests/openpgp/Makefile
1515 tests/pkits/Makefile
1516 ])
1517 AC_OUTPUT
1518
1519
1520 echo "
1521         GnuPG v${VERSION} has been configured as follows:
1522
1523         Platform:  $PRINTABLE_OS_NAME ($host)
1524
1525         OpenPGP:   $build_gpg
1526         S/MIME:    $build_gpgsm
1527         Agent:     $build_agent $build_agent_threaded
1528         Smartcard: $build_scdaemon $build_scdaemon_extra
1529         Gpgtar:    $build_gpgtar
1530
1531         Protect tool:      $show_gnupg_protect_tool_pgm
1532         Default agent:     $show_gnupg_agent_pgm
1533         Default pinentry:  $show_gnupg_pinentry_pgm
1534         Default scdaemon:  $show_gnupg_scdaemon_pgm
1535         Default dirmngr:   $show_gnupg_dirmngr_pgm
1536 "
1537 if test x"$use_regex" != xyes ; then
1538 echo "
1539         Warning: No regular expression support available.
1540                  OpenPGP trust signatures won't work.
1541                  gpg-check-pattern will not be build.
1542 "
1543 fi