* configure.ac (HAVE_DOSISH_SYSTEM): New automake conditional.
[gnupg.git] / configure.ac
1 dnl Configure.ac script for GnuPG
2 dnl Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 dnl               2003 Free Software Foundation, Inc.
4 dnl
5 dnl This file is part of GnuPG.
6 dnl
7 dnl GnuPG is free software; you can redistribute it and/or modify
8 dnl it under the terms of the GNU General Public License as published by
9 dnl the Free Software Foundation; either version 2 of the License, or
10 dnl (at your option) any later version.
11 dnl 
12 dnl GnuPG is distributed in the hope that it will be useful,
13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 dnl GNU General Public License for more details.
16 dnl 
17 dnl You should have received a copy of the GNU General Public License
18 dnl along with this program; if not, write to the Free Software
19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20 dnl
21 dnl (Process this file with autoconf to produce a configure script.)
22 dnlAC_REVISION($Revision$)dnl
23
24 AC_PREREQ(2.52)
25
26 # Remember to change the version number immediately *after* a release
27 # and remove the "-cvs" or "rc" suffix immediately *before* a release.
28 AC_INIT(gnupg, 1.3.2-cvs, bug-gnupg@gnu.org)
29 # Set development_version to yes if the minor number is odd or you
30 # feel that the default check for a development version is not
31 # sufficient.
32 development_version=yes
33
34 ALL_LINGUAS="de"
35
36 PACKAGE=$PACKAGE_NAME
37 VERSION=$PACKAGE_VERSION
38
39 AC_CONFIG_AUX_DIR(scripts)
40 AC_CONFIG_SRCDIR(g10/g10.c)
41 AC_CANONICAL_TARGET()
42 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
43 AM_CONFIG_HEADER(config.h)
44
45 AC_SUBST(PACKAGE)
46 AC_SUBST(VERSION)
47 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
48 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
49 AC_DEFINE(_GNU_SOURCE,1,[Some tests rely on this (stpcpy) and it should be used for new programs anyway])
50
51 dnl
52 dnl  Check for random module options
53 dnl
54 AC_MSG_CHECKING([which random module to use])
55 AC_ARG_ENABLE(static-rnd,
56     [  --enable-static-rnd=[egd|unix|linux|auto]  ],
57 [use_static_rnd=$enableval], [use_static_rnd=default] )
58
59 if test "$use_static_rnd" = no; then
60     use_static_rnd=default
61 fi
62
63 case "$use_static_rnd" in
64     egd | linux | unix | default )
65       AC_MSG_RESULT($use_static_rnd)
66       ;;
67     auto )
68       AC_MSG_RESULT(automagically selected at runtime)
69       ;;
70     * )
71       AC_MSG_RESULT(invalid argument)
72       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
73       ;;
74 esac
75
76 AC_ARG_WITH(egd-socket,
77     [  --with-egd-socket=NAME  use NAME for the EGD socket],
78             egd_socket_name="$withval", egd_socket_name="" )
79 AC_DEFINE_UNQUOTED(EGD_SOCKET_NAME, "$egd_socket_name",
80                    [Define if you don't want the default EGD socket name.
81                     For details see cipher/rndegd.c])
82
83
84 dnl
85 dnl See whether the user wants to disable checking for /dev/random
86
87 AC_MSG_CHECKING([whether use of /dev/random is requested])
88 AC_ARG_ENABLE(dev-random,
89 [  --disable-dev-random    disable the use of dev random],
90     try_dev_random=$enableval, try_dev_random=yes)
91 AC_MSG_RESULT($try_dev_random)
92
93
94 dnl
95 dnl  Check other options
96 dnl
97
98 AC_MSG_CHECKING([whether assembler modules are requested])
99 AC_ARG_ENABLE(asm,
100 [  --disable-asm           do not use assembler modules],
101      try_asm_modules=$enableval, try_asm_modules=yes)
102 AC_MSG_RESULT($try_asm_modules)
103
104 AC_MSG_CHECKING([whether memory guard is requested])
105 AC_ARG_ENABLE(m-guard,
106     [  --enable-m-guard        enable memory guard facility],
107     use_m_guard=$enableval, use_m_guard=no)
108 AC_MSG_RESULT($use_m_guard)
109 if test "$use_m_guard" = yes ; then
110     AC_DEFINE(M_GUARD,1,[Define to use the (obsolete) malloc guarding feature])
111 fi
112
113 dnl See if we are disabling any algorithms or features for a smaller
114 dnl binary
115
116 try_dynload=no
117
118 use_idea=yes
119 use_cast5=yes
120 use_blowfish=yes
121 use_aes=yes
122 use_twofish=yes
123 use_tiger192=yes
124 use_sha256=yes
125 use_sha512=yes
126 use_exec=yes
127
128 AC_ARG_ENABLE(minimal,
129    AC_HELP_STRING([--enable-minimal],[build the smallest gpg binary possible]),
130    use_idea=no
131    use_cast5=no
132    use_blowfish=no
133    use_aes=no
134    use_twofish=no
135    use_tiger192=no
136    use_sha256=no
137    use_sha512=no
138    use_exec=no)
139
140 AC_MSG_CHECKING([whether to enable the IDEA cipher])
141 AC_ARG_ENABLE(idea,
142    AC_HELP_STRING([--disable-idea],[disable the IDEA cipher]),
143    use_idea=$enableval)
144 AC_MSG_RESULT($use_idea)
145 if test x"$use_idea" = xyes ; then
146    AC_DEFINE(USE_IDEA,1,[Define to include the IDEA cipher])
147
148 # We don't need idea but some people claim that they need it for
149 # research etc., so we allow to place an idea source code into the
150 # cipher directory and statically link it if available, otherwise we
151 # link to a stub.  We don't use AC_CHECK_FILE to avoid caching.
152
153    AC_MSG_CHECKING([for idea cipher module])
154    tmp=""
155    if test -f $srcdir/cipher/idea.c; then 
156       IDEA_O=idea.o
157       tmp=idea
158    else
159       IDEA_O=idea-stub.o
160       tmp=no
161       try_dynload=yes
162    fi
163    AC_SUBST(IDEA_O)
164    AC_MSG_RESULT($tmp)
165 fi
166
167 AC_MSG_CHECKING([whether to enable the CAST5 cipher])
168 AC_ARG_ENABLE(cast5,
169    AC_HELP_STRING([--disable-cast5],[disable the CAST5 cipher]),
170    use_cast5=$enableval)
171 AC_MSG_RESULT($use_cast5)
172 if test x"$use_cast5" = xyes ; then
173    AC_DEFINE(USE_CAST5,1,[Define to include the CAST5 cipher])
174 fi
175
176 AC_MSG_CHECKING([whether to enable the BLOWFISH cipher])
177 AC_ARG_ENABLE(blowfish,
178    AC_HELP_STRING([--disable-blowfish],[disable the BLOWFISH cipher]),
179    use_blowfish=$enableval)
180 AC_MSG_RESULT($use_blowfish)
181 if test x"$use_blowfish" = xyes ; then
182    AC_DEFINE(USE_BLOWFISH,1,[Define to include the BLOWFISH cipher])
183 fi
184
185 AC_MSG_CHECKING([whether to enable the AES ciphers])
186 AC_ARG_ENABLE(aes,
187    AC_HELP_STRING([--disable-aes],[disable the AES, AES192, and AES256 ciphers]),
188    use_aes=$enableval)
189 AC_MSG_RESULT($use_aes)
190 if test x"$use_aes" = xyes ; then
191    AC_DEFINE(USE_AES,1,[Define to include the AES, AES192, and AES256 ciphers])
192 fi
193
194 AC_MSG_CHECKING([whether to enable the TWOFISH cipher])
195 AC_ARG_ENABLE(twofish,
196    AC_HELP_STRING([--disable-twofish],[disable the TWOFISH cipher]),
197    use_twofish=$enableval)
198 AC_MSG_RESULT($use_twofish)
199 if test x"$use_twofish" = xyes ; then
200    AC_DEFINE(USE_TWOFISH,1,[Define to include the TWOFISH cipher])
201 fi
202
203 dnl TIGER192 is defined only after we confirm 64-bit support later
204 AC_MSG_CHECKING([whether to enable the TIGER/192 digest])
205 AC_ARG_ENABLE(tiger192,
206    AC_HELP_STRING([--disable-tiger192],[disable the TIGER/192 digest]),
207    use_tiger192=$enableval)
208 AC_MSG_RESULT($use_tiger192)
209
210 AC_MSG_CHECKING([whether to enable the SHA-256 digest])
211 AC_ARG_ENABLE(sha256,
212    AC_HELP_STRING([--disable-sha256],[disable the SHA-256 digest]),
213    use_sha256=$enableval)
214 AC_MSG_RESULT($use_sha256)
215 if test x"$use_sha256" = xyes ; then
216    AC_DEFINE(USE_SHA256,1,[Define to include the SHA-256 digest])
217 fi
218
219 dnl SHA512 is defined only after we confirm 64-bit support later
220 AC_MSG_CHECKING([whether to enable the SHA-384 and SHA-512 digests])
221 AC_ARG_ENABLE(sha512,
222    AC_HELP_STRING([--disable-sha512],[disable the SHA-384 and SHA-512 digests]),
223    use_sha512=$enableval)
224 AC_MSG_RESULT($use_sha512)
225
226 AC_MSG_CHECKING([whether to enable external program execution])
227 AC_ARG_ENABLE(exec,
228     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
229     use_exec=$enableval)
230 AC_MSG_RESULT($use_exec)
231 if test "$use_exec" = no ; then
232     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
233 fi
234
235 if test "$use_exec" = yes ; then
236   AC_MSG_CHECKING([whether to enable photo ID viewing])
237   AC_ARG_ENABLE(photo-viewers,
238       [  --disable-photo-viewers disable photo ID viewers],
239       [if test "$enableval" = no ; then
240          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
241       fi],enableval=yes)
242   gnupg_cv_enable_photo_viewers=$enableval
243   AC_MSG_RESULT($enableval)
244
245   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
246     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
247     AC_ARG_WITH(photo-viewer,
248         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
249         [if test "$withval" = yes ; then
250            withval=no
251         elif test "$withval" != no ; then
252            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
253                             [if set, restrict photo-viewer to this])
254         fi],withval=no)
255     AC_MSG_RESULT($withval)
256   fi
257
258   AC_MSG_CHECKING([whether to enable external keyserver helpers])
259   AC_ARG_ENABLE(keyserver-helpers,
260       [  --disable-keyserver-helpers  disable all external keyserver support],
261       [if test "$enableval" = no ; then
262          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
263                   [define to disable keyserver helpers])
264       fi],enableval=yes)
265   gnupg_cv_enable_keyserver_helpers=$enableval
266   AC_MSG_RESULT($enableval)
267
268   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
269     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
270     AC_ARG_ENABLE(ldap,
271     [  --disable-ldap          disable LDAP keyserver interface],
272         try_ldap=$enableval, try_ldap=yes)
273     AC_MSG_RESULT($try_ldap)
274
275     AC_MSG_CHECKING([whether HKP keyserver support is requested])
276     AC_ARG_ENABLE(hkp,
277     [  --disable-hkp           disable HKP keyserver interface],
278         try_hkp=$enableval, try_hkp=yes)
279     AC_MSG_RESULT($try_hkp)
280
281     if test "$try_hkp" = yes ; then
282       AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
283     fi
284
285     AC_MSG_CHECKING([whether email keyserver support is requested])
286     AC_ARG_ENABLE(mailto,
287     [  --disable-mailto        disable email keyserver interface],
288         try_mailto=$enableval, try_mailto=yes)
289     AC_MSG_RESULT($try_mailto)
290     fi
291
292     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
293     AC_ARG_ENABLE(keyserver-path,
294         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
295         [if test "$enableval" = no ; then
296          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
297         fi],enableval=yes)
298     AC_MSG_RESULT($enableval)
299   fi
300
301 AC_MSG_CHECKING([whether the included zlib is requested])
302 AC_ARG_WITH(included-zlib,
303     [  --with-included-zlib    use the zlib code included here],
304 [g10_force_zlib=yes], [g10_force_zlib=no] )
305 AC_MSG_RESULT($g10_force_zlib)
306
307 dnl
308 dnl Check whether we want to use Linux capabilities
309 dnl
310 AC_MSG_CHECKING([whether use of capabilities is requested])
311 AC_ARG_WITH(capabilities,
312     [  --with-capabilities     use linux capabilities [default=no]],
313 [use_capabilities="$withval"],[use_capabilities=no])
314 AC_MSG_RESULT($use_capabilities)
315
316
317 AH_BOTTOM([
318 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
319 #define EXEC_TEMPFILE_ONLY
320 #endif
321
322 #include "g10defs.h"
323 ])
324
325
326 AM_MAINTAINER_MODE
327
328 dnl Checks for programs.
329
330 AC_PROG_MAKE_SET
331 AM_SANITY_CHECK
332 missing_dir=`cd $ac_aux_dir && pwd`
333 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
334 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
335 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
336 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
337 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
338 AC_PROG_CC
339 AC_PROG_CPP
340 AC_PROG_RANLIB
341 AC_CHECK_TOOL(AR, ar, :)
342 AC_PATH_PROG(PERL,"perl")
343 AC_ISC_POSIX
344 AC_SYS_LARGEFILE
345 AC_PROG_INSTALL
346 AC_PROG_AWK
347 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
348 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
349 GNUPG_CHECK_FAQPROG
350 GNUPG_CHECK_DOCBOOK_TO_TEXI
351
352 MPI_OPT_FLAGS=""
353
354
355 try_gettext=yes
356 have_dosish_system=no
357 case "${target}" in
358     *-*-mingw32*)
359         # special stuff for Windoze NT
360         ac_cv_have_dev_random=no
361         AC_DEFINE(USE_ONLY_8DOT3,1,
362                   [set this to limit filenames to the 8.3 format])
363         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
364                   [defined if we must run on a stupid file system])
365         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
366                   [because the Unix gettext has too much overhead on
367                    MingW32 systems and these systems lack Posix functions,
368                    we use a simplified version of gettext])
369         have_dosish_system=yes
370         try_gettext="no"
371         ;;
372     i?86-emx-os2 | i?86-*-os2*emx )
373         # OS/2 with the EMX environment
374         ac_cv_have_dev_random=no
375         AC_DEFINE(HAVE_DRIVE_LETTERS)
376         have_dosish_system=yes
377         try_gettext="no"
378         ;;
379
380     i?86-*-msdosdjgpp*)
381         # DOS with the DJGPP environment
382         ac_cv_have_dev_random=no
383         AC_DEFINE(HAVE_DRIVE_LETTERS)
384         have_dosish_system=yes
385         try_gettext="no"
386         ;;
387
388     *-*-freebsd*)
389        # FreeBSD
390        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
391        LDFLAGS="$LDFLAGS -L/usr/local/lib"
392        ;;
393
394     *-*-hpux*)
395         if test -z "$GCC" ; then
396             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
397         fi
398         ;;
399     *-dec-osf4*)
400         if test -z "$GCC" ; then
401             # Suppress all warnings
402             # to get rid of the unsigned/signed char mismatch warnings.
403             CFLAGS="$CFLAGS -w"
404         fi
405         ;;
406     *-dec-osf5*)
407         if test -z "$GCC" ; then
408             # Use the newer compiler `-msg_disable ptrmismatch' to
409             # get rid of the unsigned/signed char mismatch warnings.
410             # Using this may hide other pointer mismatch warnings, but
411             # it at least lets other warning classes through
412             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
413         fi
414         ;;
415     m68k-atari-mint)
416         ;;
417     *)
418        ;;
419 esac
420
421 if test "$have_dosish_system" = yes; then
422    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
423              [defined if we run on some of the PCDOS like systems 
424               (DOS, Windoze. OS/2) with special properties like
425               no file modes])
426 fi
427 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
428
429 AC_SUBST(MPI_OPT_FLAGS)
430 GNUPG_SYS_SYMBOL_UNDERSCORE
431
432 dnl Must check for network library requirements before doing link tests
433 dnl for ldap, for example. If ldap libs are static (or dynamic and without
434 dnl ELF runtime link paths), then link will fail and LDAP support won't
435 dnl be detected.
436
437 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
438         [NETLIBS="-lnsl $NETLIBS"]))
439 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
440         [NETLIBS="-lsocket $NETLIBS"]))
441
442 dnl Now try for the resolver functions so we can use DNS SRV
443
444 AC_ARG_ENABLE(dns-srv,
445    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
446    use_dns_srv=$enableval,use_dns_srv=yes)
447
448 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
449   _srv_save_libs=$LIBS
450   LIBS=""
451   # the double underscore thing is a glibc-ism?
452   AC_SEARCH_LIBS(res_query,resolv bind,,
453                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
454   AC_SEARCH_LIBS(dn_expand,resolv bind,,
455                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
456   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
457                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
458
459   if test x"$use_dns_srv" = xyes ; then
460      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
461      SRVLIBS=$LIBS
462   else
463      AC_MSG_WARN([Resolver functions not found.  Disabling DNS SRV.])
464   fi
465   LIBS=$_srv_save_libs
466 fi
467
468 AC_SUBST(SRVLIBS)
469
470 # Try and link a LDAP test program to weed out unusable LDAP
471 # libraries.  -lldap [-llber [-lresolv]] is for OpenLDAP.  OpenLDAP in
472 # general is terrible with creating weird dependencies.  If all else
473 # fails, the user can play guess-the-dependency by using something
474 # like ./configure LDAPLIBS="-Lfoo -lbar"
475
476 if test "$try_ldap" = yes ; then
477   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
478     _ldap_save_libs=$LIBS
479     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
480
481     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
482     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
483                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
484     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
485
486     if test $gnupg_cv_func_ldap_init = no; then
487       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
488       AC_TRY_LINK([#include <lber.h>
489 #include <ldap.h>],[ldap_open("foobar",1234);],
490          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
491       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
492     fi
493
494     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
495        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
496     fi
497
498     if test "$gnupg_cv_func_ldap_init" = yes || \
499         test "$gnupg_cv_func_ldaplber_init" = yes ; then
500        LDAPLIBS=$MY_LDAPLIBS
501        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
502
503        AC_MSG_CHECKING([whether LDAP supports ldap_get_option])
504
505        if test "$gnupg_cv_func_ldap_init" = yes ; then
506           AC_TRY_LINK([#include <ldap.h>],
507              [ldap_get_option((void *)0,0,(void *)0);],
508              [gnupg_cv_func_ldap_get_option=yes],
509              [gnupg_cv_func_ldap_get_option=no])
510         else
511           AC_TRY_LINK([#include <lber.h>
512 #include <ldap.h>],[ldap_get_option((void *)0,0,(void *)0);],
513              [gnupg_cv_func_ldap_get_option=yes],
514              [gnupg_cv_func_ldap_get_option=no])
515        fi
516
517        AC_MSG_RESULT([$gnupg_cv_func_ldap_get_option])
518
519        if test "$gnupg_cv_func_ldap_get_option" = yes ; then
520           AC_DEFINE(HAVE_LDAP_GET_OPTION,1,[Define if the LDAP library has ldap_get_option])
521        else
522           AC_MSG_CHECKING([whether LDAP supports ld_errno])
523
524           if test "$gnupg_cv_func_ldap_init" = yes ; then
525             AC_TRY_COMPILE([#include <ldap.h>],
526                [LDAP *ldap; ldap->ld_errno;],
527                [gnupg_cv_func_ldap_ld_errno=yes],
528                [gnupg_cv_func_ldap_ld_errno=no])
529            else
530             AC_TRY_LINK([#include <lber.h>
531 #include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
532                [gnupg_cv_func_ldap_ld_errno=yes],
533                [gnupg_cv_func_ldap_ld_errno=no])
534           fi
535
536           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
537
538           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
539              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
540           fi
541        fi
542     fi
543
544     LIBS=$_ldap_save_libs
545
546     if test "$GPGKEYS_LDAP" != "" ; then break; fi
547   done
548 fi
549
550 AC_SUBST(GPGKEYS_LDAP)
551 AC_SUBST(LDAPLIBS)
552
553 dnl This isn't necessarily sendmail itself, but anything that gives a
554 dnl sendmail-ish interface to the outside world.  That includes qmail,
555 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
556
557 if test "$try_mailto" = yes ; then
558   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
559
560   if test "$with_mailprog" = yes ; then
561     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
562     if test "$ac_cv_path_SENDMAIL" ; then
563       GPGKEYS_MAILTO="gpgkeys_mailto"
564     fi
565   elif test "$with_mailprog" != no ; then
566     AC_MSG_CHECKING([for a mail transport program])
567     AC_SUBST(SENDMAIL,$with_mailprog)
568     AC_MSG_RESULT($with_mailprog)
569     GPGKEYS_MAILTO="gpgkeys_mailto"
570   fi
571 fi
572
573 AC_SUBST(GPGKEYS_MAILTO)
574
575 case "${target}" in
576     *-*-mingw32*)
577         PRINTABLE_OS_NAME="MingW32"
578         ;;
579     *-*-cygwin*)
580         PRINTABLE_OS_NAME="Cygwin"
581         ;;
582     i?86-emx-os2 | i?86-*-os2*emx )
583         PRINTABLE_OS_NAME="OS/2"
584         ;;
585     i?86-*-msdosdjgpp*)
586         PRINTABLE_OS_NAME="MSDOS/DJGPP"
587         try_dynload=no
588         ;;
589     *-linux*)
590         PRINTABLE_OS_NAME="GNU/Linux"
591         ;;
592 dnl let that after linux to avoid gnu-linux problems
593     *-gnu*)
594         PRINTABLE_OS_NAME="GNU/Hurd"
595         ;;
596     *)
597         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
598         ;;
599 esac
600 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
601                    [A human readable text with the name of the OS])
602
603
604 #
605 # 1. Set names of random devices
606 #
607 NAME_OF_DEV_RANDOM="/dev/random"
608 NAME_OF_DEV_URANDOM="/dev/urandom"
609 case "${target}" in
610     *-openbsd*)
611         NAME_OF_DEV_RANDOM="/dev/srandom"
612         NAME_OF_DEV_URANDOM="/dev/urandom"
613         ;;
614 esac
615 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM",
616                    [defined to the name of the strong random device])
617 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM",
618                    [defined to the name of the weaker random device])
619 AC_SUBST(MPI_OPT_FLAGS)
620
621
622 dnl Checks for libraries.
623
624 if test "$try_gettext" = yes; then
625   AM_GNU_GETTEXT
626 else
627   USE_NLS=no
628   USE_INCLUDED_LIBINTL=no
629   BUILD_INCLUDED_LIBINTL=no
630   AC_SUBST(USE_NLS)
631   AC_SUBST(USE_INCLUDED_LIBINTL)
632   AC_SUBST(BUILD_INCLUDED_LIBINTL)
633 fi
634
635
636 if test "$try_dynload" = yes ; then
637   AC_CHECK_LIB(dl,dlopen)
638   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
639     AC_DEFINE(USE_DYNAMIC_LINKING,1,
640               [define to enable the use of extensions])
641     AC_DEFINE(HAVE_DL_DLOPEN,1,
642               [Defined when the dlopen function family is available])
643   else
644     AC_CHECK_FUNCS(dlopen)
645     if test "$ac_cv_func_dlopen" = "yes"; then
646       AC_DEFINE(USE_DYNAMIC_LINKING)
647       AC_DEFINE(HAVE_DL_DLOPEN)
648     fi
649   fi
650 else
651   AC_MSG_CHECKING(for dynamic loading)
652   DYNLINK_LDFLAGS=
653   DYNLINK_MOD_CFLAGS=
654   AC_MSG_RESULT(has been disabled)
655 fi
656
657 dnl Checks for header files.
658 AC_HEADER_STDC
659 AC_CHECK_HEADERS(unistd.h langinfo.h termio.h locale.h)
660
661 dnl Checks for typedefs, structures, and compiler characteristics.
662 AC_C_CONST
663 AC_C_INLINE
664 AC_C_VOLATILE
665 AC_TYPE_SIZE_T
666 AC_TYPE_MODE_T
667 AC_TYPE_SIGNAL
668 AC_DECL_SYS_SIGLIST
669
670 GNUPG_CHECK_ENDIAN
671
672 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
673 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
674 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
675 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
676 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
677
678 AC_CHECK_SIZEOF(unsigned short)
679 AC_CHECK_SIZEOF(unsigned int)
680 AC_CHECK_SIZEOF(unsigned long)
681 AC_CHECK_SIZEOF(unsigned long long)
682 AC_CHECK_SIZEOF(uint64_t)
683
684 if test "$ac_cv_sizeof_unsigned_short" = "0" \
685    || test "$ac_cv_sizeof_unsigned_int" = "0" \
686    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
687     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
688 fi
689
690 dnl Do we have any 64-bit data types?
691 if test "$ac_cv_sizeof_unsigned_int" != "8" \
692    && test "$ac_cv_sizeof_unsigned_long" != "8" \
693    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
694    && test "$ac_cv_sizeof_uint64_t" != "8"; then
695     AC_MSG_WARN([No 64-bit types.  Disabling TIGER/192, SHA-384, and SHA-512])
696 else
697   if test x"$use_tiger192" = xyes ; then
698      AC_SUBST(TIGER_O,tiger.o)
699      AC_DEFINE(USE_TIGER192,1,[Define to include the TIGER/192 digest])
700
701      AC_MSG_CHECKING([whether to enable old-style TIGER/192 digest support])
702      AC_ARG_ENABLE(old-tiger,
703         [  --enable-old-tiger      enable old-style TIGER/192 digest support],
704         old_tiger=$enableval, old_tiger=no)
705      AC_MSG_RESULT($old_tiger)
706      if test "$old_tiger" = yes ; then
707         AC_DEFINE(USE_OLD_TIGER,1,[Define to use the old fake OID for TIGER/192 digest support])
708      fi
709   fi
710   if test x"$use_sha512" = xyes ; then
711      AC_SUBST(SHA512_O,sha512.o)
712      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
713   fi
714 fi
715
716 dnl Checks for library functions.
717 AC_FUNC_FSEEKO
718 AC_FUNC_VPRINTF
719 AC_FUNC_FORK
720 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
721 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid)
722 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
723 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
724 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat)
725 AC_REPLACE_FUNCS(mkdtemp)
726
727 #
728 # check for gethrtime and run a testprogram to see whether
729 # it is broken.  It has been reported that some Solaris and HP UX systems 
730 # raise an SIGILL
731 #
732 AC_CACHE_CHECK([for gethrtime], 
733                [gnupg_cv_func_gethrtime],
734                [AC_TRY_LINK([#include <sys/times.h>],[
735                    hrtime_t tv;
736                    tv = gethrtime();
737                  ],
738                  [gnupg_cv_func_gethrtime=yes],
739                  [gnupg_cv_func_gethrtime=no])
740                ])
741 if test $gnupg_cv_func_gethrtime = yes; then
742      AC_DEFINE([HAVE_GETHRTIME], 1,
743                [Define if you have the `gethrtime(2)' function.])
744      AC_CACHE_CHECK([whether gethrtime is broken], 
745                [gnupg_cv_func_broken_gethrtime],
746                [AC_TRY_RUN([
747                    #include <sys/times.h>
748                    int main () {
749                    hrtime_t tv;
750                    tv = gethrtime(); 
751                  }
752                  ],
753                  [gnupg_cv_func_broken_gethrtime=no],
754                  [gnupg_cv_func_broken_gethrtime=yes],
755                  [gnupg_cv_func_broken_gethrtime=assume-no])
756                 ])
757     if test $gnupg_cv_func_broken_gethrtime = yes; then
758       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
759       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
760     fi
761 fi
762      
763
764 GNUPG_CHECK_MLOCK
765 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
766
767 dnl
768 dnl Check whether we can use Linux capabilities as requested
769 dnl
770 if test "$use_capabilities" = "yes" ; then
771 use_capabilities=no
772 AC_CHECK_HEADERS(sys/capability.h)
773 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
774   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
775   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
776      AC_DEFINE(USE_CAPABILITIES,1,
777                [define if capabilities should be used])
778      AC_SUBST(CAPLIBS,"-lcap")
779      use_capabilities=yes
780   fi
781 fi
782 if test "$use_capabilities" = "no" ; then
783     AC_MSG_WARN([[
784 ***
785 *** The use of capabilities on this system is not possible.
786 *** You need a recent Linux kernel and some patches:
787 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
788 ***   fcap-module-990613.tar.gz     (kernel module)
789 ***   libcap-1.92.tar.gz            (user mode library and utilities)
790 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
791 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
792 ***]])
793 fi
794 fi
795
796
797 GNUPG_CHECK_IPC
798 if test "$ac_cv_header_sys_shm_h" = "yes"; then
799   AC_DEFINE(USE_SHM_COPROCESSING,1,
800             [define if the shared memory interface should be made available])
801 fi
802
803 dnl
804 dnl check whether we have a random device
805 dnl
806 if test "$try_dev_random" = yes ; then
807     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
808     [if test -r "$NAME_OF_DEV_RANDOM" && test -r "$NAME_OF_DEV_URANDOM" ; then
809       ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
810     if test "$ac_cv_have_dev_random" = yes; then
811         AC_DEFINE(HAVE_DEV_RANDOM,1,
812                  [defined if the system supports a random device] )
813     fi
814 else
815     AC_MSG_CHECKING(for random device)
816     ac_cv_have_dev_random=no
817     AC_MSG_RESULT(has been disabled)
818 fi
819
820
821 dnl
822 dnl Figure out the default random module.
823 dnl
824 random_modules=""
825 if test "$use_static_rnd" = default; then
826      if test "$ac_cv_have_dev_random" = yes; then
827         random_modules="rndlinux"
828      else
829          case "${target}" in
830             *-*-mingw32*|*-*-cygwin*)
831                 random_modules="rndw32"
832                 ;;
833             i?86-emx-os2|i?86-*-os2*emx)
834                 random_modules="rndos2"
835                 ;;
836             m68k-atari-mint)
837                 random_modules="rndatari"
838                 ;;
839             i?86-*-msdosdjgpp*)
840                 :
841                 ;;
842             *)
843                 random_modules="rndlinux rndegd rndunix"
844                 AC_DEFINE(USE_ALL_RANDOM_MODULES, 1, 
845                           [Allow to select random modules at runtime.])
846                 ;;
847          esac
848      fi
849 else
850   if test "$use_static_rnd" = auto; then
851      random_modules="rndlinux rndegd rndunix"
852      AC_DEFINE(USE_ALL_RANDOM_MODULES, 1)
853   else
854      random_modules="rnd$use_static_rnd";
855   fi
856 fi
857
858 if test -z "$random_modules"; then
859    AC_MSG_ERROR(no random module available)
860 fi
861 print_egd_warning=no
862 for rndmod in $random_modules "" ; do
863   case "$rndmod" in
864     rndlinux)
865          AC_DEFINE(USE_RNDLINUX,1, 
866                   [Defined if the /dev/random based RNG should be used.])
867          ;;
868     rndunix)
869          AC_DEFINE(USE_RNDUNIX,1, 
870                   [Defined if the default Unix RNG should be used.])
871          print_egd_warning=yes
872           ;;
873     rndegd)
874          AC_DEFINE(USE_RNDEGD,1, 
875                   [Defined if the EGD based RNG should be used.])
876          EGDLIBS=$NETLIBS
877          AC_SUBST(EGDLIBS)
878          ;;
879     rndw32)
880          AC_DEFINE(USE_RNDW32,1, 
881                   [Defined if the Windows specific RNG should be used.])
882         ;;
883    esac
884 done
885
886 dnl setup assembler stuff
887 AC_MSG_CHECKING(for mpi assembler functions)
888 if test -f $srcdir/mpi/config.links ; then
889     . $srcdir/mpi/config.links
890     AC_CONFIG_LINKS("$mpi_ln_list")
891     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
892     ac_cv_mpi_sflags="$mpi_sflags"
893     ac_cv_mpi_config_done="yes"
894     AC_MSG_RESULT(done)
895 else
896     AC_MSG_RESULT(failed)
897     AC_MSG_ERROR([mpi/config.links missing!])
898 fi
899 MPI_EXTRA_ASM_OBJS=""
900 show_extraasm=""
901 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
902 for i in $ac_cv_mpi_extra_asm_modules; do
903     show_extraasm="$show_extraasm $i"
904     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
905 done
906 fi
907 AC_SUBST(MPI_EXTRA_ASM_OBJS)
908 MPI_SFLAGS="$ac_cv_mpi_sflags"
909 AC_SUBST(MPI_SFLAGS)
910
911 # Sanity check regex.  Tests adapted from mutt.
912
913 AC_MSG_CHECKING([whether regular expression support is requested])
914 AC_ARG_ENABLE(regex,
915 [  --disable-regex         do not handle regular expressions in trust sigs],
916      use_regex=$enableval, use_regex=yes)
917 AC_MSG_RESULT($use_regex)
918
919 if test "$use_regex" = yes ; then
920   AC_MSG_CHECKING([whether the included regex lib is requested])
921   AC_ARG_WITH(included-regex,
922       [  --with-included-regex   use the included GNU regex library],
923       [gnupg_cv_included_regex=yes],[gnupg_cv_included_regex=no])
924   AC_MSG_RESULT($gnupg_cv_included_regex)
925
926   if test $gnupg_cv_included_regex = no ; then
927      # Does the system have regex functions at all?
928      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
929                            gnupg_cv_included_regex=yes)
930   fi
931
932   if test $gnupg_cv_included_regex = no ; then
933      AC_CACHE_CHECK([whether your system's regexp library is broken],
934        [gnupg_cv_regex_broken],
935        AC_TRY_RUN([
936 #include <unistd.h>
937 #include <regex.h>
938 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
939        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
940
941      if test $gnupg_cv_regex_broken = yes ; then
942       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
943       gnupg_cv_included_regex=yes
944      fi
945   fi
946
947   if test $gnupg_cv_included_regex = yes; then
948      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
949      AC_SUBST(REGEX_O,regex.o)
950   fi
951 else
952
953   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
954 fi
955
956 dnl Do we have zlib? Must do it here because Solaris failed
957 dnl when compiling a conftest (due to the "-lz" from LIBS).
958 use_local_zlib=yes
959 if test "$g10_force_zlib" = "yes"; then
960   :
961 else
962   _cppflags="${CPPFLAGS}"
963   _ldflags="${LDFLAGS}"
964
965   AC_ARG_WITH(zlib,
966   [  --with-zlib=DIR         use libz in DIR],[
967     if test -d "$withval"; then
968       CPPFLAGS="${CPPFLAGS} -I$withval/include"
969       LDFLAGS="${LDFLAGS} -L$withval/lib"
970     fi
971   ])
972
973   AC_CHECK_HEADER(zlib.h,
974       AC_CHECK_LIB(z, deflateInit2_,
975        use_local_zlib=no
976        LIBS="$LIBS -lz",
977        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
978        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
979 fi
980  
981 if test "$use_local_zlib" = yes ; then
982     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
983     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
984     ZLIBS="../zlib/libzlib.a"
985 else
986     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
987     ZLIBS=
988 fi
989 AC_SUBST(ZLIBS)
990
991
992 # Allow users to append something to the version string without
993 # flagging it as development version.  The user version parts is
994 # considered everything after a dash. 
995 if test "$development_version" != yes; then
996   changequote(,)dnl
997   tmp_pat='[a-zA-Z]'
998   changequote([,])dnl
999   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1000     development_version=yes
1001   fi
1002 fi
1003 if test "$development_version" = yes; then
1004     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1005             [Defined if this is not a regular release])
1006 fi
1007
1008 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1009
1010 GNUPG_CHECK_GNUMAKE
1011
1012 # add some extra libs here so that previous tests don't fail for
1013 # mysterious reasons - the final link step should bail out. 
1014 case "${target}" in
1015     *-*-mingw32*)
1016         LIBS="$LIBS -lwsock32"
1017         ;;
1018     *)
1019        ;;
1020 esac
1021
1022
1023 if test "$GCC" = yes; then
1024     if test "$USE_MAINTAINER_MODE" = "yes"; then
1025         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1026     else
1027         CFLAGS="$CFLAGS -Wall"
1028     fi
1029 fi
1030
1031 AC_SUBST(NETLIBS)
1032
1033
1034 if test "$print_egd_warning" = yes; then
1035   AC_MSG_WARN([[
1036 ***
1037 *** The performance of the UNIX random gatherer module is not very good
1038 *** and it does not keep the entropy pool over multiple invocations of
1039 *** GnuPG.  The suggested way to overcome this problem is to use the
1040 ***
1041 ***               Entropy Gathering Daemon (EGD)
1042 ***
1043 *** which provides a entropy source for the whole system.  It is written
1044 *** in Perl and available at the GnuPG FTP servers.  For more information
1045 *** consult the GnuPG webpages:
1046 ***
1047 ***           http://www.gnupg.org/download.html#egd
1048 ***
1049 *** You may want to run ./configure with --enable-static-rnd=egd to use it.
1050 ***]])
1051 fi
1052
1053 # Note the \\\\ for backslashes.  Autoconf eats one layer, leaving \\
1054
1055 AC_CONFIG_COMMANDS(g10defs.h,[[
1056 cat >g10defs.tmp <<G10EOF
1057 /* Generated automatically by configure */
1058 #ifdef HAVE_DRIVE_LETTERS
1059   #define G10_LOCALEDIR     "c:\\\\lib\\\\gnupg\\\\locale"
1060   #define GNUPG_LIBDIR      "c:\\\\lib\\\\gnupg"
1061   #define GNUPG_LIBEXECDIR  "c:\\\\lib\\\\gnupg"
1062   #define GNUPG_DATADIR     "c:\\\\lib\\\\gnupg"
1063   #define GNUPG_HOMEDIR     "c:\\\\gnupg"
1064 #else
1065   #define G10_LOCALEDIR     "${datadir}/locale"
1066   #define GNUPG_LIBDIR      "${libdir}/gnupg"
1067   #define GNUPG_DATADIR     "${datadir}/gnupg"
1068   #ifdef __VMS
1069     #define GNUPG_HOMEDIR "/SYS\$LOGIN/gnupg" 
1070   #else
1071     #define GNUPG_HOMEDIR "~/.gnupg" 
1072   #endif
1073 #endif
1074 /* those are here to be redefined by handcrafted g10defs.h.
1075    Please note that the string version must not contain more
1076    than one character because the using code assumes strlen()==1 */
1077 #ifdef HAVE_DOSISH_SYSTEM
1078 #define DIRSEP_C '\\\\'
1079 #define EXTSEP_C '.'
1080 #define DIRSEP_S "\\\\"
1081 #define EXTSEP_S "."
1082 #else
1083 #define DIRSEP_C '/'
1084 #define EXTSEP_C '.'
1085 #define DIRSEP_S "/"
1086 #define EXTSEP_S "."
1087 #endif
1088 G10EOF
1089 cat mpi/mpi-asm-defs.h >>g10defs.tmp 
1090 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
1091     echo "g10defs.h is unchanged"
1092     rm -f g10defs.tmp
1093 else
1094     rm -f g10defs.h
1095     mv g10defs.tmp g10defs.h
1096     echo "g10defs.h created"
1097 fi
1098 ]],[[
1099 prefix=$prefix
1100 exec_prefix=$exec_prefix
1101 libdir=$libdir
1102 libexecdir=$libexecdir
1103 datadir=$datadir
1104 DATADIRNAME=$DATADIRNAME
1105 ]])
1106
1107
1108 AC_CONFIG_FILES([
1109 Makefile
1110 intl/Makefile
1111 po/Makefile.in
1112 util/Makefile
1113 mpi/Makefile
1114 cipher/Makefile
1115 g10/Makefile
1116 keyserver/Makefile
1117 keyserver/gpgkeys_mailto
1118 keyserver/gpgkeys_test
1119 doc/Makefile
1120 tools/Makefile
1121 zlib/Makefile
1122 checks/Makefile
1123 ])
1124 AC_OUTPUT
1125
1126 # Give some feedback
1127 echo
1128 echo   "                Configured for: $PRINTABLE_OS_NAME ($target)"
1129 if test -n "$show_extraasm"; then
1130   echo "  Extra cpu specific functions:$show_extraasm"
1131 fi
1132 echo