g10: Add TOFU support.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998-2012 Free Software Foundation, Inc.
3 # Copyright (C) 1998-2015 Werner Koch
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.14"
23
24 # To build a release you need to create a tag with the version number
25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
26 # bump the version number immediately *after* the release and do
27 # another commit and push so that the git magic is able to work.
28 m4_define([mym4_package],[gnupg])
29 m4_define([mym4_major], [2])
30 m4_define([mym4_minor], [1])
31 m4_define([mym4_micro], [10])
32
33 # To start a new development series, i.e a new major or minor number
34 # you need to mark an arbitrary commit before the first beta release
35 # with an annotated tag.  For example the 2.1 branch starts off with
36 # the tag "gnupg-2.1-base".  This is used as the base for counting
37 # beta numbers before the first release of a series.
38
39 # Below is m4 magic to extract and compute the git revision number,
40 # the decimalized short revision number, a beta version string and a
41 # flag indicating a development version (mym4_isbeta).  Note that the
42 # m4 processing is done by autoconf and not during the configure run.
43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
49 m4_esyscmd([echo ]mym4_version[>VERSION])
50 AC_INIT([mym4_package],[mym4_version], [http://bugs.gnupg.org])
51
52 NEED_GPG_ERROR_VERSION=1.16
53
54 NEED_LIBGCRYPT_API=1
55 NEED_LIBGCRYPT_VERSION=1.6.0
56
57 NEED_LIBASSUAN_API=2
58 NEED_LIBASSUAN_VERSION=2.1.0
59
60 NEED_KSBA_API=1
61 NEED_KSBA_VERSION=1.2.0
62
63 NEED_NTBTLS_API=1
64 NEED_NTBTLS_VERSION=0.1.0
65
66 NEED_NPTH_API=1
67 NEED_NPTH_VERSION=0.91
68
69
70 NEED_GNUTLS_VERSION=3.0
71
72
73 development_version=mym4_isbeta
74 PACKAGE=$PACKAGE_NAME
75 PACKAGE_GT=${PACKAGE_NAME}2
76 VERSION=$PACKAGE_VERSION
77
78 AC_CONFIG_AUX_DIR([build-aux])
79 AC_CONFIG_SRCDIR([sm/gpgsm.c])
80 AC_CONFIG_HEADER([config.h])
81 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
82 AC_CANONICAL_HOST
83 AB_INIT
84
85 AC_GNU_SOURCE
86
87 # Some status variables.
88 have_gpg_error=no
89 have_libgcrypt=no
90 have_libassuan=no
91 have_ksba=no
92 have_ntbtls=no
93 have_gnutls=no
94 have_npth=no
95 have_libusb=no
96 have_adns=no
97 gnupg_have_ldap="n/a"
98
99 use_zip=yes
100 use_bzip2=yes
101 use_exec=yes
102 use_trust_models=yes
103 card_support=yes
104 use_ccid_driver=yes
105 dirmngr_auto_start=yes
106 use_tls_library=no
107 large_secmem=no
108
109 GNUPG_BUILD_PROGRAM(gpg, yes)
110 GNUPG_BUILD_PROGRAM(gpgsm, yes)
111 # The agent is a required part and can't be disabled anymore.
112 build_agent=yes
113 GNUPG_BUILD_PROGRAM(scdaemon, yes)
114 GNUPG_BUILD_PROGRAM(g13, yes)
115 GNUPG_BUILD_PROGRAM(dirmngr, yes)
116 GNUPG_BUILD_PROGRAM(tools, yes)
117 GNUPG_BUILD_PROGRAM(doc, yes)
118 GNUPG_BUILD_PROGRAM(symcryptrun, no)
119 GNUPG_BUILD_PROGRAM(gpgtar, yes)
120
121 AC_SUBST(PACKAGE)
122 AC_SUBST(PACKAGE_GT)
123 AC_SUBST(VERSION)
124 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
125 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
126                                 [Name of this package for gettext])
127 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
128 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
129                                         [Bug report address])
130 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
131                                        [Required version of Libgcrypt])
132 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
133                                        [Required version of Libksba])
134 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
135                                        [Required version of NTBTLS])
136
137
138
139 # The default is to use the modules from this package and the few
140 # other packages in a standard place; i.e where this package gets
141 # installed.  With these options it is possible to override these
142 # ${prefix} depended values with fixed paths, which can't be replaced
143 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
144 AC_ARG_WITH(agent-pgm,
145     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
146           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
147 AC_SUBST(GNUPG_AGENT_PGM)
148 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
149 show_gnupg_agent_pgm="(default)"
150 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
151
152 AC_ARG_WITH(pinentry-pgm,
153     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
154           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
155 AC_SUBST(GNUPG_PINENTRY_PGM)
156 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
157 show_gnupg_pinentry_pgm="(default)"
158 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
159
160
161 AC_ARG_WITH(scdaemon-pgm,
162     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
163           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
164 AC_SUBST(GNUPG_SCDAEMON_PGM)
165 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
166 show_gnupg_scdaemon_pgm="(default)"
167 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
168
169
170 AC_ARG_WITH(dirmngr-pgm,
171     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
172           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
173 AC_SUBST(GNUPG_DIRMNGR_PGM)
174 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
175 show_gnupg_dirmngr_pgm="(default)"
176 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
177
178 AC_ARG_WITH(protect-tool-pgm,
179     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
180           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
181 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
182 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
183 show_gnupg_protect_tool_pgm="(default)"
184 test -n "$GNUPG_PROTECT_TOOL_PGM" \
185       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
186
187 AC_ARG_WITH(dirmngr-ldap-pgm,
188     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmnge ldap wrapper)],
189           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
190 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
191 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
192 show_gnupg_dirmngr_ldap_pgm="(default)"
193 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
194       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
195
196 #
197 # On some platforms gpg2 is usually installed as gpg without using a
198 # symlink.  For correct operation of gpgconf it needs to know the
199 # installed name of gpg.  This option sets "gpg2"'s installed name to
200 # just "gpg".  Note that it might be required to rename gpg2 to gpg
201 # manually after the build process.
202 #
203 AC_ARG_ENABLE(gpg2-is-gpg,
204     AC_HELP_STRING([--enable-gpg2-is-gpg],[Set installed name of gpg2 to gpg]),
205     gpg2_is_gpg=$enableval)
206 if test "$gpg2_is_gpg" = "yes"; then
207    name_of_installed_gpg=gpg
208 else
209    name_of_installed_gpg=gpg2
210 fi
211 AC_DEFINE_UNQUOTED(NAME_OF_INSTALLED_GPG, "$name_of_installed_gpg",
212                    [The name of the installed GPG tool])
213
214
215 # SELinux support includes tracking of sensitive files to avoid
216 # leaking their contents through processing these files by gpg itself
217 AC_MSG_CHECKING([whether SELinux support is requested])
218 AC_ARG_ENABLE(selinux-support,
219               AC_HELP_STRING([--enable-selinux-support],
220                              [enable SELinux support]),
221               selinux_support=$enableval, selinux_support=no)
222 AC_MSG_RESULT($selinux_support)
223
224
225 AC_MSG_CHECKING([whether to allocate extra secure memory])
226 AC_ARG_ENABLE(large-secmem,
227               AC_HELP_STRING([--enable-large-secmem],
228                              [allocate extra secure memory]),
229               large_secmem=$enableval, large_secmem=no)
230 AC_MSG_RESULT($large_secmem)
231 if test "$large_secmem" = yes ; then
232    SECMEM_BUFFER_SIZE=65536
233 else
234    SECMEM_BUFFER_SIZE=32768
235 fi
236 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
237                    [Size of secure memory buffer])
238
239 AC_MSG_CHECKING([whether to enable trust models])
240 AC_ARG_ENABLE(trust-models,
241               AC_HELP_STRING([--disable-trust-models],
242                              [disable all trust models except "always"]),
243               use_trust_models=$enableval)
244 AC_MSG_RESULT($use_trust_models)
245 if test "$use_trust_models" = no ; then
246     AC_DEFINE(NO_TRUST_MODELS, 1,
247              [Define to include only trust-model always])
248 fi
249
250
251 #
252 # Options to disable algorithm
253 #
254
255 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
256 # Elgamal is a MUST algorithm
257 # DSA is a MUST algorithm
258 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
259 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
260 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
261
262 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
263 # 3DES is a MUST algorithm
264 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
265 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
266 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
267 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
268 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
269 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
270 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
271 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
272 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
273
274 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
275 # SHA1 is a MUST algorithm
276 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
277 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
278 # SHA256 is a MUST algorithm for GnuPG.
279 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
280 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
281
282
283 # Allow disabling of zip support.
284 # This is in general not a good idea because according to rfc4880 OpenPGP
285 # implementations SHOULD support ZLIB.
286 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
287 AC_ARG_ENABLE(zip,
288    AC_HELP_STRING([--disable-zip],
289                   [disable the ZIP and ZLIB compression algorithm]),
290    use_zip=$enableval)
291 AC_MSG_RESULT($use_zip)
292
293 # Allow disabling of bzib2 support.
294 # It is defined only after we confirm the library is available later
295 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
296 AC_ARG_ENABLE(bzip2,
297    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
298    use_bzip2=$enableval)
299 AC_MSG_RESULT($use_bzip2)
300
301 # Configure option to allow or disallow execution of external
302 # programs, like a photo viewer.
303 AC_MSG_CHECKING([whether to enable external program execution])
304 AC_ARG_ENABLE(exec,
305     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
306     use_exec=$enableval)
307 AC_MSG_RESULT($use_exec)
308 if test "$use_exec" = no ; then
309     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
310 fi
311
312 if test "$use_exec" = yes ; then
313   AC_MSG_CHECKING([whether to enable photo ID viewing])
314   AC_ARG_ENABLE(photo-viewers,
315       [  --disable-photo-viewers disable photo ID viewers],
316       [if test "$enableval" = no ; then
317          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
318       fi],enableval=yes)
319   gnupg_cv_enable_photo_viewers=$enableval
320   AC_MSG_RESULT($enableval)
321
322   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
323     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
324     AC_ARG_WITH(photo-viewer,
325         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
326         [if test "$withval" = yes ; then
327            withval=no
328         elif test "$withval" != no ; then
329            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
330                             [if set, restrict photo-viewer to this])
331         fi],withval=no)
332     AC_MSG_RESULT($withval)
333   fi
334 fi
335
336
337 #
338 # Check for the key/uid cache size.  This can't be zero, but can be
339 # pretty small on embedded systems.  This is used for the gpg part.
340 #
341 AC_MSG_CHECKING([for the size of the key and uid cache])
342 AC_ARG_ENABLE(key-cache,
343         AC_HELP_STRING([--enable-key-cache=SIZE],
344                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
345 if test "$enableval" = "no"; then
346    enableval=5
347 elif test "$enableval" = "yes" || test "$enableval" = ""; then
348    enableval=4096
349 fi
350 changequote(,)dnl
351 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
352 changequote([,])dnl
353 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
354    AC_MSG_ERROR([invalid key-cache size])
355 fi
356 AC_MSG_RESULT($key_cache_size)
357 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
358                   [Size of the key and UID caches])
359
360
361
362 #
363 # Check whether we want to use Linux capabilities
364 #
365 AC_MSG_CHECKING([whether use of capabilities is requested])
366 AC_ARG_WITH(capabilities,
367     [  --with-capabilities     use linux capabilities [default=no]],
368 [use_capabilities="$withval"],[use_capabilities=no])
369 AC_MSG_RESULT($use_capabilities)
370
371 #
372 # Check whether to disable the card support
373 AC_MSG_CHECKING([whether smartcard support is requested])
374 AC_ARG_ENABLE(card-support,
375               AC_HELP_STRING([--disable-card-support],
376                              [disable smartcard support]),
377               card_support=$enableval)
378 AC_MSG_RESULT($card_support)
379 if test "$card_support" = yes ; then
380   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
381 else
382   build_scdaemon=no
383 fi
384
385 #
386 # Allow disabling of internal CCID support.
387 # It is defined only after we confirm the library is available later
388 #
389 AC_MSG_CHECKING([whether to enable the internal CCID driver])
390 AC_ARG_ENABLE(ccid-driver,
391               AC_HELP_STRING([--disable-ccid-driver],
392                              [disable the internal CCID driver]),
393               use_ccid_driver=$enableval)
394 AC_MSG_RESULT($use_ccid_driver)
395
396 AC_MSG_CHECKING([whether to auto start dirmngr])
397 AC_ARG_ENABLE(dirmngr-auto-start,
398               AC_HELP_STRING([--disable-dirmngr-auto-start],
399                              [disable auto starting of the dirmngr]),
400               dirmngr_auto_start=$enableval)
401 AC_MSG_RESULT($dirmngr_auto_start)
402 if test "$dirmngr_auto_start" = yes ; then
403     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
404               [Define to enable auto starting of the dirmngr])
405 fi
406
407
408 #
409 # To avoid double inclusion of config.h which might happen at some
410 # places, we add the usual double inclusion protection at the top of
411 # config.h.
412 #
413 AH_TOP([
414 #ifndef GNUPG_CONFIG_H_INCLUDED
415 #define GNUPG_CONFIG_H_INCLUDED
416 ])
417
418 #
419 # Stuff which goes at the bottom of config.h.
420 #
421 AH_BOTTOM([
422 /* This is the major version number of GnuPG so that
423    source included files can test for this.  Note, that
424    we use 2 here even for GnuPG 1.9.x. */
425 #define GNUPG_MAJOR_VERSION 2
426
427 /* Now to separate file name parts.
428    Please note that the string version must not contain more
429    than one character because the code assumes strlen()==1 */
430 #ifdef HAVE_DOSISH_SYSTEM
431 #define DIRSEP_C '\\'
432 #define DIRSEP_S "\\"
433 #define EXTSEP_C '.'
434 #define EXTSEP_S "."
435 #define PATHSEP_C ';'
436 #define PATHSEP_S ";"
437 #define EXEEXT_S ".exe"
438 #else
439 #define DIRSEP_C '/'
440 #define DIRSEP_S "/"
441 #define EXTSEP_C '.'
442 #define EXTSEP_S "."
443 #define PATHSEP_C ':'
444 #define PATHSEP_S ":"
445 #define EXEEXT_S ""
446 #endif
447
448 /* This is the same as VERSION, but should be overridden if the
449    platform cannot handle things like dots '.' in filenames. Set
450    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
451    uses for dots and dashes. */
452 #define SAFE_VERSION VERSION
453 #define SAFE_VERSION_DOT  '.'
454 #define SAFE_VERSION_DASH '-'
455
456 /* Some global constants. */
457 #ifdef HAVE_DOSISH_SYSTEM
458 # ifdef HAVE_DRIVE_LETTERS
459 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
460 # else
461 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
462 # endif
463 #elif defined(__VMS)
464 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
465 #else
466 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
467 #endif
468 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
469 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
470
471 /* For some systems (DOS currently), we hardcode the path here.  For
472    POSIX systems the values are constructed by the Makefiles, so that
473    the values may be overridden by the make invocations; this is to
474    comply with the GNU coding standards.  Note that these values are
475    only defaults.  */
476 #ifdef HAVE_DOSISH_SYSTEM
477 # ifdef HAVE_DRIVE_LETTERS
478 #  define GNUPG_BINDIR      "c:\\gnupg"
479 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
480 #  define GNUPG_LIBDIR      "c:\\gnupg"
481 #  define GNUPG_DATADIR     "c:\\gnupg"
482 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
483 # else
484 #  define GNUPG_BINDIR      "\\gnupg"
485 #  define GNUPG_LIBEXECDIR  "\\gnupg"
486 #  define GNUPG_LIBDIR      "\\gnupg"
487 #  define GNUPG_DATADIR     "\\gnupg"
488 #  define GNUPG_SYSCONFDIR  "\\gnupg"
489 # endif
490 #endif
491
492 /* Derive some other constants. */
493 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
494 #define EXEC_TEMPFILE_ONLY
495 #endif
496
497
498 /* We didn't define endianness above, so get it from OS macros.  This
499    is intended for making fat binary builds on OS X. */
500 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
501 #if defined(__BIG_ENDIAN__)
502 #define BIG_ENDIAN_HOST 1
503 #elif defined(__LITTLE_ENDIAN__)
504 #define LITTLE_ENDIAN_HOST 1
505 #else
506 #error "No endianness found"
507 #endif
508 #endif
509
510
511 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
512    ldap_start_tls_s because that is the actual symbol used in the
513    library.  winldap.h redefines it to our commonly used value,
514    thus we define our usual macro here.  */
515 #ifdef HAVE_LDAP_START_TLS_SA
516 # ifndef HAVE_LDAP_START_TLS_S
517 #  define HAVE_LDAP_START_TLS_S 1
518 # endif
519 #endif
520
521 /* Provide the es_ macro for estream.  */
522 #define GPGRT_ENABLE_ES_MACROS 1
523
524 /* Tell libgcrypt not to use its own libgpg-error implementation. */
525 #define USE_LIBGPG_ERROR 1
526
527 /* Tell Libgcrypt not to include deprecated definitions.  */
528 #define GCRYPT_NO_DEPRECATED 1
529
530 /* Our HTTP code is used in estream mode.  */
531 #define HTTP_USE_ESTREAM 1
532
533 /* Under W32 we do an explicit socket initialization, thus we need to
534    avoid the on-demand initialization which would also install an atexit
535    handler.  */
536 #define HTTP_NO_WSASTARTUP
537
538 /* Under Windows we use the gettext code from libgpg-error.  */
539 #define GPG_ERR_ENABLE_GETTEXT_MACROS
540
541 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
542 #define GPG_ERR_ENABLE_ERRNO_MACROS
543
544 #endif /*GNUPG_CONFIG_H_INCLUDED*/
545 ])
546
547
548 AM_MAINTAINER_MODE
549 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
550
551 # Checks for programs.
552 AC_MSG_NOTICE([checking for programs])
553 AC_PROG_MAKE_SET
554 AM_SANITY_CHECK
555 missing_dir=`cd $ac_aux_dir && pwd`
556 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
557 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
558 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
559 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
560 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
561 AM_SILENT_RULES
562 AC_PROG_AWK
563 AC_PROG_CC
564 AC_PROG_CPP
565 AM_PROG_CC_C_O
566 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
567   AC_MSG_ERROR([[No C-89 compiler found]])
568 fi
569 AC_PROG_INSTALL
570 AC_PROG_LN_S
571 AC_PROG_RANLIB
572 AC_CHECK_TOOL(AR, ar, :)
573 AC_PATH_PROG(PERL,"perl")
574 AC_CHECK_TOOL(WINDRES, windres, :)
575 AC_ISC_POSIX
576 AC_SYS_LARGEFILE
577 GNUPG_CHECK_USTAR
578
579 # We need to compile and run a program on the build machine.  A
580 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
581 # the AC archive is broken for autoconf 2.57.  Given that there is no
582 # newer version of that macro, we assume that it is also broken for
583 # autoconf 2.61 and thus we use a simple but usually sufficient
584 # approach.
585 AC_MSG_CHECKING(for cc for build)
586 if test "$cross_compiling" = "yes"; then
587   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
588 else
589   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
590 fi
591 AC_MSG_RESULT($CC_FOR_BUILD)
592 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
593
594
595
596 try_gettext=yes
597 require_iconv=yes
598 have_dosish_system=no
599 have_w32_system=no
600 have_w32ce_system=no
601 have_android_system=no
602 run_tests=yes
603 use_simple_gettext=no
604 use_ldapwrapper=yes
605 mmap_needed=yes
606 case "${host}" in
607     *-mingw32*)
608         # special stuff for Windoze NT
609         ac_cv_have_dev_random=no
610         AC_DEFINE(USE_ONLY_8DOT3,1,
611                   [Set this to limit filenames to the 8.3 format])
612         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
613                   [Because the Unix gettext has too much overhead on
614                    MingW32 systems and these systems lack Posix functions,
615                    we use a simplified version of gettext])
616         have_dosish_system=yes
617         have_w32_system=yes
618         run_tests=no
619         use_ldapwrapper=no  # Fixme: Do this only for CE.
620         case "${host}" in
621           *-mingw32ce*)
622             have_w32ce_system=yes
623             ;;
624           *)
625             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
626                       [Defined if the OS supports drive letters.])
627             ;;
628         esac
629         try_gettext="no"
630         use_simple_gettext=yes
631         mmap_needed=no
632         ;;
633     i?86-emx-os2 | i?86-*-os2*emx )
634         # OS/2 with the EMX environment
635         ac_cv_have_dev_random=no
636         AC_DEFINE(HAVE_DRIVE_LETTERS)
637         have_dosish_system=yes
638         try_gettext="no"
639         ;;
640
641     i?86-*-msdosdjgpp*)
642         # DOS with the DJGPP environment
643         ac_cv_have_dev_random=no
644         AC_DEFINE(HAVE_DRIVE_LETTERS)
645         have_dosish_system=yes
646         try_gettext="no"
647         ;;
648
649     *-*-hpux*)
650         if test -z "$GCC" ; then
651             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
652         fi
653         ;;
654     *-dec-osf4*)
655         if test -z "$GCC" ; then
656             # Suppress all warnings
657             # to get rid of the unsigned/signed char mismatch warnings.
658             CFLAGS="$CFLAGS -w"
659         fi
660         ;;
661     *-dec-osf5*)
662         if test -z "$GCC" ; then
663             # Use the newer compiler `-msg_disable ptrmismatch1' to
664             # get rid of the unsigned/signed char mismatch warnings.
665             # Using this may hide other pointer mismatch warnings, but
666             # it at least lets other warning classes through
667             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
668         fi
669         ;;
670     m68k-atari-mint)
671         ;;
672     *-linux-androideabi)
673         have_android_system=yes
674         # Android is fully utf-8 and we do not want to use iconv to
675         # keeps things simple
676         require_iconv=no
677         run_tests=no
678         ;;
679     *)
680        ;;
681 esac
682
683 if test "$have_dosish_system" = yes; then
684    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
685              [Defined if we run on some of the PCDOS like systems
686               (DOS, Windoze. OS/2) with special properties like
687               no file modes, case insensitive file names and preferred
688               use of backslashes as directory name separators.])
689 fi
690 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
691
692 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
693
694 if test "$have_w32_system" = yes; then
695    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
696    if test "$have_w32ce_system" = yes; then
697       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
698    fi
699 fi
700 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
701 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
702
703 if test "$have_android_system" = yes; then
704    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
705 fi
706 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
707
708 if test "$run_tests" = yes; then
709    AC_DEFINE(RUN_TESTS,1, [Defined if we should run the tests])
710 fi
711 AM_CONDITIONAL(RUN_TESTS, test "$run_tests" = yes)
712
713
714 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
715 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
716
717
718 #
719 # Checks for libraries.
720 #
721 AC_MSG_NOTICE([checking for libraries])
722
723
724 #
725 # libgpg-error is a library with error codes shared between GnuPG
726 # related projects.
727 #
728 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
729                   have_gpg_error=yes,have_gpg_error=no)
730
731
732 #
733 # Libgcrypt is our generic crypto library
734 #
735 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
736         have_libgcrypt=yes,have_libgcrypt=no)
737
738
739 #
740 # libassuan is used for IPC
741 #
742 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
743                   have_libassuan=yes,have_libassuan=no)
744 if test "$have_libassuan" = "yes"; then
745   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
746                      [version of the libassuan library])
747 fi
748
749
750
751 #
752 # libksba is our X.509 support library
753 #
754 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
755
756
757 #
758 # libusb allows us to use the integrated CCID smartcard reader driver.
759 #
760 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
761 if test "$use_ccid_driver" = yes ; then
762   AC_CHECK_LIB(usb, usb_bulk_write,
763                 [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
764                   AC_DEFINE(HAVE_LIBUSB,1,
765                            [defined if libusb is available])
766                   have_libusb=yes
767                ])
768   AC_CHECK_FUNCS(usb_create_match)
769 fi
770 AC_SUBST(LIBUSB_LIBS)
771
772 #
773 # Check wether it is necessary to link against libdl.
774 # (For example to load libpcsclite)
775 #
776 gnupg_dlopen_save_libs="$LIBS"
777 LIBS=""
778 AC_SEARCH_LIBS(dlopen, c dl,,,)
779 DL_LIBS=$LIBS
780 AC_SUBST(DL_LIBS)
781 LIBS="$gnupg_dlopen_save_libs"
782
783 # Checks for g10
784
785 PKG_CHECK_MODULES(SQLITE3, sqlite3)
786 AC_SUBST(SQLITE3_CFLAGS)
787 AC_SUBST(SQLITE3_LIBS)
788
789 # Checks for g13
790
791 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
792 AC_DEFINE_UNQUOTED(ENCFS,
793         "${ENCFS}", [defines the filename of the encfs program])
794
795 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
796 AC_DEFINE_UNQUOTED(FUSERMOUNT,
797         "${FUSERMOUNT}", [defines the filename of the fusermount program])
798
799
800 # Checks for dirmngr
801
802
803 #
804 # Checks for symcryptrun:
805 #
806
807 # libutil has openpty() and login_tty().
808 AC_CHECK_LIB(util, openpty,
809               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
810                 AC_DEFINE(HAVE_LIBUTIL,1,
811                          [defined if libutil is available])
812              ])
813 AC_SUBST(LIBUTIL_LIBS)
814
815 # shred is used to clean temporary plain text files.
816 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
817 AC_DEFINE_UNQUOTED(SHRED,
818         "${SHRED}", [defines the filename of the shred program])
819
820
821 #
822 # Check whether the nPth library is available
823 #
824 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
825 if test "$have_npth" = "yes"; then
826   AC_DEFINE(HAVE_NPTH, 1,
827               [Defined if the New Portable Thread Library is available])
828   AC_DEFINE(USE_NPTH, 1,
829               [Defined if support for nPth is requested and nPth is available])
830 else
831   AC_MSG_WARN([[
832 ***
833 *** To support concurrent access for example in gpg-agent and the SCdaemon
834 *** we need the support of the New Portable Threads Library.
835 ***]])
836 fi
837
838
839 #
840 # NTBTLS is our TLS library.  If it is not available fallback to
841 # GNUTLS.
842 #
843 AC_ARG_ENABLE(ntbtls,
844               AC_HELP_STRING([--disable-ntbtls],
845                              [disable the use of NTBTLS as TLS library]),
846               try_ntbtls=$enableval, try_ntbtls=yes)
847 if test x"$try_ntbtls" = xyes ; then
848   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
849                  [have_ntbtls=yes],[have_ntbtls=no])
850 fi
851 if test "$have_ntbtls" = yes ; then
852    use_tls_library=ntbtls
853    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
854 else
855   AC_ARG_ENABLE(gnutls,
856                 AC_HELP_STRING([--disable-gnutls],
857                                [disable GNUTLS as fallback TLS library]),
858                 try_gnutls=$enableval, try_gnutls=yes)
859   if test x"$try_gnutls" = xyes ; then
860     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
861                                    [have_gnutls=yes],
862                                    [have_gnutls=no])
863   fi
864   if test "$have_gnutls" = "yes"; then
865     AC_SUBST([LIBGNUTLS_CFLAGS])
866     AC_SUBST([LIBGNUTLS_LIBS])
867     use_tls_library=gnutls
868     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
869   else
870     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
871     AC_MSG_WARN([[
872 ***
873 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
874 ***
875 *** $tmp]])
876   fi
877 fi
878
879
880 AC_MSG_NOTICE([checking for networking options])
881
882 #
883 # Must check for network library requirements before doing link tests
884 # for ldap, for example. If ldap libs are static (or dynamic and without
885 # ELF runtime link paths), then link will fail and LDAP support won't
886 # be detected.
887 #
888 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
889         [NETLIBS="-lnsl $NETLIBS"]))
890 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
891         [NETLIBS="-lsocket $NETLIBS"]))
892
893
894 #
895 # Check for ADNS.
896 #
897 _cppflags="${CPPFLAGS}"
898 _ldflags="${LDFLAGS}"
899 AC_ARG_WITH(adns,
900             AC_HELP_STRING([--with-adns=DIR],
901                            [look for the adns library in DIR]),
902             [if test -d "$withval"; then
903                CPPFLAGS="${CPPFLAGS} -I$withval/include"
904                LDFLAGS="${LDFLAGS} -L$withval/lib"
905              fi])
906 if test "$with_adns" != "no"; then
907   AC_CHECK_HEADERS(adns.h,
908                 AC_CHECK_LIB(adns, adns_free,
909                              [have_adns=yes],
910                              [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}]),
911                              [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}])
912 fi
913 if test "$have_adns" = "yes"; then
914   ADNSLIBS="-ladns"
915 fi
916
917
918 #
919 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
920 #
921 AC_ARG_ENABLE(dns-srv,
922               AC_HELP_STRING([--disable-dns-srv],
923                              [disable the use of DNS SRV in HKP and HTTP]),
924               use_dns_srv=$enableval,use_dns_srv=yes)
925
926 AC_ARG_ENABLE(dns-cert,
927    AC_HELP_STRING([--disable-dns-cert],
928         [disable the use of CERT records in DNS]),
929    use_dns_cert=$enableval,use_dns_cert=yes)
930
931 if test x"$use_dns_srv" = xyes || test x"$use_dns_cert" = xyes; then
932   _dns_save_libs=$LIBS
933   LIBS=""
934   # the double underscore thing is a glibc-ism?
935   AC_SEARCH_LIBS(res_query,resolv bind,,
936                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
937   AC_SEARCH_LIBS(dn_expand,resolv bind,,
938                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
939   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
940                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
941
942   if test x"$have_resolver" != xno ; then
943
944     # Make sure that the BIND 4 resolver interface is workable before
945     # enabling any code that calls it.  At some point I'll rewrite the
946     # code to use the BIND 8 resolver API.
947     # We might also want to use adns instead.  Problem with ADNS is that
948     # it does not support v6.
949
950     AC_MSG_CHECKING([whether the resolver is usable])
951     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
952 #include <netinet/in.h>
953 #include <arpa/nameser.h>
954 #include <resolv.h>]],
955 [[unsigned char answer[PACKETSZ];
956   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
957   dn_skipname(0,0);
958   dn_expand(0,0,0,0,0);
959 ]])],have_resolver=yes,have_resolver=no)
960     AC_MSG_RESULT($have_resolver)
961
962     # This is Apple-specific and somewhat bizarre as they changed the
963     # define in bind 8 for some reason.
964
965     if test x"$have_resolver" != xyes ; then
966        AC_MSG_CHECKING(
967              [whether I can make the resolver usable with BIND_8_COMPAT])
968        AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
969 #include <sys/types.h>
970 #include <netinet/in.h>
971 #include <arpa/nameser.h>
972 #include <resolv.h>]],
973 [[unsigned char answer[PACKETSZ];
974   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
975   dn_skipname(0,0); dn_expand(0,0,0,0,0);
976 ]])],[have_resolver=yes ; need_compat=yes])
977        AC_MSG_RESULT($have_resolver)
978     fi
979   fi
980
981   if test x"$have_resolver" = xyes ; then
982      DNSLIBS=$LIBS
983
984      if test x"$use_dns_srv" = xyes ; then
985         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
986      fi
987
988      if test x"$use_dns_cert" = xyes ; then
989         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
990      fi
991
992      if test x"$need_compat" = xyes ; then
993         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
994      fi
995   else
996      # If we have no resolver library but ADNS (e.g. under W32) enable the
997      # code parts which can be used with ADNS.
998      if test x"$have_adns" = xyes ; then
999         DNSLIBS="$ADNSLIBS"
1000         AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
1001
1002         if test x"$use_dns_srv" = xyes ; then
1003            AC_DEFINE(USE_DNS_SRV,1)
1004         fi
1005
1006         if test x"$use_dns_cert" = xyes ; then
1007            AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
1008         fi
1009      else
1010         use_dns_srv=no
1011         use_dns_cert=no
1012      fi
1013   fi
1014
1015   LIBS=$_dns_save_libs
1016 fi
1017
1018 AC_SUBST(DNSLIBS)
1019
1020 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
1021
1022
1023 #
1024 # Check for LDAP
1025 #
1026 # Note that running the check changes the variable
1027 # gnupg_have_ldap from "n/a" to "no" or "yes".
1028
1029 AC_ARG_ENABLE(ldap,
1030     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1031     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1032
1033 if test "$gnupg_have_ldap" != "no" ; then
1034   if test "$build_dirmngr" = "yes" ; then
1035      GNUPG_CHECK_LDAP($NETLIBS)
1036      AC_CHECK_LIB(lber, ber_free,
1037                   [ LBER_LIBS="$LBER_LIBS -llber"
1038                     AC_DEFINE(HAVE_LBER,1,
1039                              [defined if liblber is available])
1040                     have_lber=yes
1041                  ])
1042   fi
1043 fi
1044 AC_SUBST(LBER_LIBS)
1045 if test "$gnupg_have_ldap" = "no"; then
1046     AC_MSG_WARN([[
1047 ***
1048 *** Building without LDAP support.
1049 *** No CRL access or X.509 certificate search available.
1050 ***]])
1051 fi
1052
1053 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1054 if test "$gnupg_have_ldap" = yes ; then
1055   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1056 else
1057  use_ldapwrapper=no
1058 fi
1059
1060 if test "$use_ldapwrapper" = yes; then
1061    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1062 fi
1063 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1064
1065
1066
1067
1068 #
1069 # Check for sendmail
1070 #
1071 # This isn't necessarily sendmail itself, but anything that gives a
1072 # sendmail-ish interface to the outside world.  That includes Exim,
1073 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1074 AC_ARG_WITH(mailprog,
1075       AC_HELP_STRING([--with-mailprog=NAME],
1076                      [use "NAME -t" for mail transport]),
1077              ,with_mailprog=yes)
1078 if test x"$with_mailprog" = xyes ; then
1079     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1080 elif test x"$with_mailprog" != xno ; then
1081     AC_MSG_CHECKING([for a mail transport program])
1082     AC_SUBST(SENDMAIL,$with_mailprog)
1083     AC_MSG_RESULT($with_mailprog)
1084 fi
1085
1086
1087 #
1088 # Construct a printable name of the OS
1089 #
1090 case "${host}" in
1091     *-mingw32ce*)
1092         PRINTABLE_OS_NAME="W32CE"
1093         ;;
1094     *-mingw32*)
1095         PRINTABLE_OS_NAME="MingW32"
1096         ;;
1097     *-*-cygwin*)
1098         PRINTABLE_OS_NAME="Cygwin"
1099         ;;
1100     i?86-emx-os2 | i?86-*-os2*emx )
1101         PRINTABLE_OS_NAME="OS/2"
1102         ;;
1103     i?86-*-msdosdjgpp*)
1104         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1105         try_dynload=no
1106         ;;
1107     *-linux*)
1108         PRINTABLE_OS_NAME="GNU/Linux"
1109         ;;
1110     *)
1111         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1112         ;;
1113 esac
1114 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1115                    [A human readable text with the name of the OS])
1116
1117
1118 #
1119 # Checking for iconv
1120 #
1121 if test "$require_iconv" = yes; then
1122   AM_ICONV
1123 else
1124   LIBICONV=
1125   LTLIBICONV=
1126   AC_SUBST(LIBICONV)
1127   AC_SUBST(LTLIBICONV)
1128 fi
1129
1130
1131 #
1132 # Check for gettext
1133 #
1134 # This is "GNU gnupg" - The project-id script from gettext
1135 #                       needs this string
1136 #
1137 AC_MSG_NOTICE([checking for gettext])
1138 AM_PO_SUBDIRS
1139 AM_GNU_GETTEXT_VERSION([0.17])
1140 if test "$try_gettext" = yes; then
1141   AM_GNU_GETTEXT([external],[need-ngettext])
1142
1143   # gettext requires some extra checks.  These really should be part of
1144   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1145   # function checks to here.
1146
1147   AC_CHECK_FUNCS(strchr)
1148 else
1149   USE_NLS=no
1150   USE_INCLUDED_LIBINTL=no
1151   BUILD_INCLUDED_LIBINTL=no
1152   POSUB=po
1153   AC_SUBST(USE_NLS)
1154   AC_SUBST(USE_INCLUDED_LIBINTL)
1155   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1156   AC_SUBST(POSUB)
1157 fi
1158
1159 # We use HAVE_LANGINFO_CODESET in a couple of places.
1160 AM_LANGINFO_CODESET
1161
1162 # Checks required for our use of locales
1163 gt_LC_MESSAGES
1164
1165
1166 #
1167 # SELinux support
1168 #
1169 if test "$selinux_support" = yes ; then
1170   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1171 fi
1172
1173
1174 #
1175 # Checks for header files.
1176 #
1177 AC_MSG_NOTICE([checking for header files])
1178 AC_HEADER_STDC
1179 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1180                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h     \
1181                   signal.h])
1182 AC_HEADER_TIME
1183
1184
1185 #
1186 # Checks for typedefs, structures, and compiler characteristics.
1187 #
1188 AC_MSG_NOTICE([checking for system characteristics])
1189 AC_C_CONST
1190 AC_C_INLINE
1191 AC_C_VOLATILE
1192 AC_TYPE_SIZE_T
1193 AC_TYPE_MODE_T
1194 AC_TYPE_SIGNAL
1195 AC_DECL_SYS_SIGLIST
1196
1197 gl_HEADER_SYS_SOCKET
1198 gl_TYPE_SOCKLEN_T
1199
1200 AC_SEARCH_LIBS([inet_addr], [nsl])
1201
1202 AC_ARG_ENABLE(endian-check,
1203               AC_HELP_STRING([--disable-endian-check],
1204               [disable the endian check and trust the OS provided macros]),
1205               endiancheck=$enableval,endiancheck=yes)
1206
1207 if test x"$endiancheck" = xyes ; then
1208   GNUPG_CHECK_ENDIAN
1209 fi
1210
1211 # fixme: we should get rid of the byte type
1212 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1213 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1214 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1215 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1216 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1217
1218 AC_CHECK_SIZEOF(unsigned short)
1219 AC_CHECK_SIZEOF(unsigned int)
1220 AC_CHECK_SIZEOF(unsigned long)
1221 AC_CHECK_SIZEOF(unsigned long long)
1222 AC_HEADER_TIME
1223 AC_CHECK_SIZEOF(time_t,,[[
1224 #include <stdio.h>
1225 #if TIME_WITH_SYS_TIME
1226 # include <sys/time.h>
1227 # include <time.h>
1228 #else
1229 # if HAVE_SYS_TIME_H
1230 #  include <sys/time.h>
1231 # else
1232 #  include <time.h>
1233 # endif
1234 #endif
1235 ]])
1236 GNUPG_TIME_T_UNSIGNED
1237
1238
1239 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1240    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1241    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1242     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1243 fi
1244
1245
1246 #
1247 # Checks for library functions.
1248 #
1249 AC_MSG_NOTICE([checking for library functions])
1250 AC_CHECK_DECLS(getpagesize)
1251 AC_FUNC_FSEEKO
1252 AC_FUNC_VPRINTF
1253 AC_FUNC_FORK
1254 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1255 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1256 AC_CHECK_FUNCS([setenv unsetenv fcntl ftruncate inet_ntop])
1257 AC_CHECK_FUNCS([canonicalize_file_name])
1258 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1259 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1260 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1261 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1262 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1263                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1264                 flockfile funlockfile fopencookie funopen getpwnam getpwuid \
1265                 getenv inet_pton strpbrk])
1266
1267 if test "$have_android_system" = yes; then
1268    # On Android ttyname is a stub but prints an error message.
1269    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1270              [Defined if ttyname does not work properly])
1271 fi
1272
1273 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1274
1275 # Dirmngr requires mmap on Unix systems.
1276 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1277   AC_MSG_ERROR([[Sorry, the current implemenation requires mmap.]])
1278 fi
1279
1280 #
1281 # W32 specific test
1282 #
1283 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1284
1285 #
1286 # Sanity check regex.  Tests adapted from mutt.
1287 #
1288 AC_MSG_CHECKING([whether regular expression support is requested])
1289 AC_ARG_ENABLE(regex,
1290   AC_HELP_STRING([--disable-regex],
1291     [do not handle regular expressions in trust signatures]),
1292   use_regex=$enableval, use_regex=yes)
1293 AC_MSG_RESULT($use_regex)
1294
1295 if test "$use_regex" = yes ; then
1296   _cppflags="${CPPFLAGS}"
1297   _ldflags="${LDFLAGS}"
1298   AC_ARG_WITH(regex,
1299      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1300       [
1301       if test -d "$withval" ; then
1302         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1303         LDFLAGS="${LDFLAGS} -L$withval/lib"
1304       fi
1305       ],withval="")
1306
1307   # Does the system have regex functions at all?
1308   AC_SEARCH_LIBS([regcomp], [regex])
1309   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1310
1311   if test $gnupg_cv_have_regex = no; then
1312     use_regex=no
1313   else
1314     if test x"$cross_compiling" = xyes; then
1315       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1316     else
1317       AC_CACHE_CHECK([whether your system's regexp library is broken],
1318        [gnupg_cv_regex_broken],
1319        AC_TRY_RUN([
1320 #include <unistd.h>
1321 #include <regex.h>
1322 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1323        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1324
1325       if test $gnupg_cv_regex_broken = yes; then
1326         AC_MSG_WARN([your regex is broken - disabling regex use])
1327         use_regex=no
1328       fi
1329     fi
1330   fi
1331   CPPFLAGS="${_cppflags}"
1332   LDFLAGS="${_ldflags}"
1333 fi
1334
1335 if test "$use_regex" != yes ; then
1336   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1337 fi
1338 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1339
1340
1341
1342 #
1343 # Do we have zlib? Must do it here because Solaris failed
1344 # when compiling a conftest (due to the "-lz" from LIBS).
1345 # Note that we combine zlib and bzlib2 in ZLIBS.
1346 #
1347 if test "$use_zip" = yes ; then
1348   _cppflags="${CPPFLAGS}"
1349   _ldflags="${LDFLAGS}"
1350   AC_ARG_WITH(zlib,
1351     [  --with-zlib=DIR         use libz in DIR],[
1352       if test -d "$withval"; then
1353         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1354         LDFLAGS="${LDFLAGS} -L$withval/lib"
1355       fi
1356     ])
1357
1358   AC_CHECK_HEADER(zlib.h,
1359      AC_CHECK_LIB(z, deflateInit2_,
1360        [
1361        ZLIBS="-lz"
1362        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1363        ],
1364        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1365        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1366 fi
1367
1368
1369 #
1370 # Check whether we can support bzip2
1371 #
1372 if test "$use_bzip2" = yes ; then
1373   _cppflags="${CPPFLAGS}"
1374   _ldflags="${LDFLAGS}"
1375   AC_ARG_WITH(bzip2,
1376      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1377       [
1378       if test -d "$withval" ; then
1379         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1380         LDFLAGS="${LDFLAGS} -L$withval/lib"
1381       fi
1382       ],withval="")
1383
1384   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1385   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1386   # woefully out of date.
1387   if test "$withval" != no ; then
1388      AC_CHECK_HEADER(bzlib.h,
1389         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1390           [
1391           have_bz2=yes
1392           ZLIBS="$ZLIBS -lbz2"
1393           AC_DEFINE(HAVE_BZIP2,1,
1394                   [Defined if the bz2 compression library is available])
1395           ],
1396           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1397           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1398   fi
1399 fi
1400 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1401 AC_SUBST(ZLIBS)
1402
1403
1404 # Check for readline support
1405 GNUPG_CHECK_READLINE
1406
1407
1408 if test "$development_version" = yes; then
1409     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1410             [Defined if this is not a regular release])
1411 fi
1412
1413 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1414
1415 GNUPG_CHECK_GNUMAKE
1416
1417 # Add some extra libs here so that previous tests don't fail for
1418 # mysterious reasons - the final link step should bail out.
1419 # W32SOCKLIBS is also defined so that if can be used for tools not
1420 # requiring any network stuff but linking to code in libcommon which
1421 # tracks in winsock stuff (e.g. init_common_subsystems).
1422 if test "$have_w32_system" = yes; then
1423    if test "$have_w32ce_system" = yes; then
1424      W32SOCKLIBS="-lws2"
1425    else
1426      W32SOCKLIBS="-lws2_32"
1427    fi
1428    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1429 fi
1430
1431 AC_SUBST(NETLIBS)
1432 AC_SUBST(W32SOCKLIBS)
1433
1434 #
1435 # Setup gcc specific options
1436 #
1437 AC_MSG_NOTICE([checking for cc features])
1438 if test "$GCC" = yes; then
1439     # Check whether gcc does not emit a diagnositc for unknow -Wno-*
1440     # options.  This is the case for gcc >= 4.6
1441     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1442     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1443 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1444 #kickerror
1445 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1446     AC_MSG_RESULT($_gcc_silent_wno)
1447
1448     # Note that it is okay to use CFLAGS here because these are just
1449     # warning options and the user should have a chance of overriding
1450     # them.
1451     if test "$USE_MAINTAINER_MODE" = "yes"; then
1452         CFLAGS="$CFLAGS -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1453         CFLAGS="$CFLAGS -Wformat -Wno-format-y2k -Wformat-security"
1454         if test x"$_gcc_silent_wno" = xyes ; then
1455           _gcc_wopt=yes
1456         else
1457           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1458           _gcc_cflags_save=$CFLAGS
1459           CFLAGS="-Wno-missing-field-initializers"
1460           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1461                             [_gcc_wopt=yes],[_gcc_wopt=no])
1462           AC_MSG_RESULT($_gcc_wopt)
1463           CFLAGS=$_gcc_cflags_save;
1464         fi
1465         if test x"$_gcc_wopt" = xyes ; then
1466           CFLAGS="$CFLAGS -W -Wno-sign-compare -Wno-missing-field-initializers"
1467         fi
1468
1469         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1470         _gcc_cflags_save=$CFLAGS
1471         CFLAGS="-Wdeclaration-after-statement"
1472         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1473         AC_MSG_RESULT($_gcc_wopt)
1474         CFLAGS=$_gcc_cflags_save;
1475         if test x"$_gcc_wopt" = xyes ; then
1476           CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1477         fi
1478     else
1479         CFLAGS="$CFLAGS -Wall"
1480     fi
1481
1482     if test x"$_gcc_silent_wno" = xyes ; then
1483       _gcc_psign=yes
1484     else
1485       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1486       _gcc_cflags_save=$CFLAGS
1487       CFLAGS="-Wno-pointer-sign"
1488       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1489                         [_gcc_psign=yes],[_gcc_psign=no])
1490       AC_MSG_RESULT($_gcc_psign)
1491       CFLAGS=$_gcc_cflags_save;
1492     fi
1493     if test x"$_gcc_psign" = xyes ; then
1494        CFLAGS="$CFLAGS -Wno-pointer-sign"
1495     fi
1496
1497     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1498     _gcc_cflags_save=$CFLAGS
1499     CFLAGS="-Wpointer-arith"
1500     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1501     AC_MSG_RESULT($_gcc_psign)
1502     CFLAGS=$_gcc_cflags_save;
1503     if test x"$_gcc_psign" = xyes ; then
1504        CFLAGS="$CFLAGS -Wpointer-arith"
1505     fi
1506 fi
1507
1508
1509 #
1510 # This is handy for debugging so the compiler doesn't rearrange
1511 # things and eliminate variables.
1512 #
1513 AC_ARG_ENABLE(optimization,
1514    AC_HELP_STRING([--disable-optimization],
1515                   [disable compiler optimization]),
1516                   [if test $enableval = no ; then
1517                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1518                    fi])
1519
1520 #
1521 # Decide what to build
1522 #
1523
1524 build_scdaemon_extra=""
1525 if test "$build_scdaemon" = "yes"; then
1526   if test $have_libusb = no; then
1527      build_scdaemon_extra="without internal CCID driver"
1528   fi
1529   if test -n "$build_scdaemon_extra"; then
1530      build_scdaemon_extra="(${build_scdaemon_extra})"
1531   fi
1532 fi
1533
1534
1535 #
1536 # Set variables for use by automake makefiles.
1537 #
1538 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1539 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1540 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1541 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1542 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1543 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1544 AM_CONDITIONAL(BUILD_TOOLS,       test "$build_tools" = "yes")
1545 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1546 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1547 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1548
1549 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1550 AM_CONDITIONAL(NO_TRUST_MODELS, test "$use_trust_models" = no)
1551
1552 AM_CONDITIONAL(RUN_GPG_TESTS,
1553                test x$cross_compiling = xno -a "$build_gpg" = yes )
1554
1555 #
1556 # Set some defines for use gpgconf.
1557 #
1558 if test "$build_gpg" = yes ; then
1559     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1560 fi
1561 if test "$build_gpgsm" = yes ; then
1562     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1563 fi
1564 if test "$build_agent" = yes ; then
1565     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1566 fi
1567 if test "$build_scdaemon" = yes ; then
1568     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1569 fi
1570 if test "$build_dirmngr" = yes ; then
1571     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if SCDAEMON is to be build])
1572 fi
1573 if test "$build_g13" = yes ; then
1574     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1575 fi
1576
1577
1578 #
1579 # Define Name strings
1580 #
1581 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1582
1583 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1584 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1585
1586 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1587 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1588
1589 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1590 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1591                                         [The displayed name of gpg-agent])
1592
1593 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1594 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1595                                        [The displayed name of scdaemon])
1596
1597 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1598 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1599                                       [The displayed name of dirmngr])
1600
1601 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1602 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1603
1604 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1605 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1606                                       [The displayed name of gpgconf])
1607
1608 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1609
1610 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1611                    [The name of the agent socket])
1612 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1613                    [The name of the agent socket for ssh])
1614 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1615                    [The name of the dirmngr info envvar])
1616 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1617                    [The name of the SCdaemon socket])
1618 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1619                    [The name of the dirmngr socket])
1620
1621 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1622
1623 if test "$have_w32_system" = yes; then
1624   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "\\\\Software\\\\GNU\\\\GnuPG",
1625                      [The directory part of the W32 registry keys])
1626 fi
1627
1628
1629 #
1630 # Provide information about the build.
1631 #
1632 BUILD_REVISION="mym4_revision"
1633 AC_SUBST(BUILD_REVISION)
1634 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1635                    [GIT commit id revision used to build this package])
1636
1637 changequote(,)dnl
1638 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1639 changequote([,])dnl
1640 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1641 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1642 AC_SUBST(BUILD_VERSION)
1643 AC_SUBST(BUILD_FILEVERSION)
1644
1645 AC_ARG_ENABLE([build-timestamp],
1646   AC_HELP_STRING([--enable-build-timestamp],
1647                  [set an explicit build timestamp for reproducibility.
1648                   (default is the current time in ISO-8601 format)]),
1649      [if test "$enableval" = "yes"; then
1650         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1651       else
1652         BUILD_TIMESTAMP="$enableval"
1653       fi],
1654      [BUILD_TIMESTAMP="<none>"])
1655 AC_SUBST(BUILD_TIMESTAMP)
1656 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1657                    [The time this package was configured for a build])
1658 BUILD_HOSTNAME="$ac_hostname"
1659 AC_SUBST(BUILD_HOSTNAME)
1660
1661
1662 #
1663 # Print errors here so that they are visible all
1664 # together and the user can acquire them all together.
1665 #
1666 die=no
1667 if test "$have_gpg_error" = "no"; then
1668    die=yes
1669    AC_MSG_NOTICE([[
1670 ***
1671 *** You need libgpg-error to build this program.
1672 **  This library is for example available at
1673 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1674 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1675 ***]])
1676 fi
1677 if test "$have_libgcrypt" = "no"; then
1678    die=yes
1679    AC_MSG_NOTICE([[
1680 ***
1681 *** You need libgcrypt to build this program.
1682 **  This library is for example available at
1683 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1684 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1685 ***]])
1686 fi
1687 if test "$have_libassuan" = "no"; then
1688    die=yes
1689    AC_MSG_NOTICE([[
1690 ***
1691 *** You need libassuan to build this program.
1692 *** This library is for example available at
1693 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1694 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1695 ***]])
1696 fi
1697 if test "$have_ksba" = "no"; then
1698     die=yes
1699     AC_MSG_NOTICE([[
1700 ***
1701 *** You need libksba to build this program.
1702 *** This library is for example available at
1703 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1704 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1705 ***]])
1706 fi
1707 if test "$gnupg_have_ldap" = yes; then
1708   if test "$have_w32ce_system" = yes; then
1709     AC_MSG_NOTICE([[
1710 *** Note that CeGCC might be broken, a package fixing this is:
1711 ***    http://files.kolab.org/local/windows-ce/
1712 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1713 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1714 ***]])
1715    fi
1716 fi
1717 if test "$have_npth" = "no"; then
1718     die=yes
1719     AC_MSG_NOTICE([[
1720 ***
1721 *** It is now required to build with support for the
1722 *** New Portable Threads Library (nPth). Please install this
1723 *** library first.  The library is for example available at
1724 ***   ftp://ftp.gnupg.org/gcrypt/npth/
1725 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1726 ***]])
1727 fi
1728
1729 if test "$require_iconv" = yes; then
1730   if test "$am_func_iconv" != yes; then
1731     die=yes
1732     AC_MSG_NOTICE([[
1733 ***
1734 *** The system does not provide a working iconv function.  Please
1735 *** install a suitable library; for example GNU Libiconv which is
1736 *** available at:
1737 ***   http://ftp.gnu.org/gnu/libiconv/
1738 ***]])
1739   fi
1740 fi
1741
1742 if test "$die" = "yes"; then
1743     AC_MSG_ERROR([[
1744 ***
1745 *** Required libraries not found. Please consult the above messages
1746 *** and install them before running configure again.
1747 ***]])
1748 fi
1749
1750
1751
1752 AC_CONFIG_FILES([ m4/Makefile
1753 Makefile
1754 po/Makefile.in
1755 common/Makefile
1756 common/w32info-rc.h
1757 kbx/Makefile
1758 g10/Makefile
1759 sm/Makefile
1760 agent/Makefile
1761 scd/Makefile
1762 g13/Makefile
1763 dirmngr/Makefile
1764 tools/gpg-zip
1765 tools/Makefile
1766 doc/Makefile
1767 tests/Makefile
1768 tests/openpgp/Makefile
1769 tests/pkits/Makefile
1770 g10/gpg.w32-manifest
1771 ])
1772
1773
1774 AC_OUTPUT
1775
1776
1777 echo "
1778         GnuPG v${VERSION} has been configured as follows:
1779
1780         Revision:  mym4_revision  (mym4_revision_dec)
1781         Platform:  $PRINTABLE_OS_NAME ($host)
1782
1783         OpenPGP:   $build_gpg
1784         S/MIME:    $build_gpgsm
1785         Agent:     $build_agent
1786         Smartcard: $build_scdaemon $build_scdaemon_extra
1787         G13:       $build_g13
1788         Dirmngr:   $build_dirmngr
1789         Gpgtar:    $build_gpgtar
1790
1791         Protect tool:      $show_gnupg_protect_tool_pgm
1792         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
1793         Default agent:     $show_gnupg_agent_pgm
1794         Default pinentry:  $show_gnupg_pinentry_pgm
1795         Default scdaemon:  $show_gnupg_scdaemon_pgm
1796         Default dirmngr:   $show_gnupg_dirmngr_pgm
1797
1798         Dirmngr auto start:  $dirmngr_auto_start
1799         Readline support:    $gnupg_cv_have_readline
1800         LDAP support:        $gnupg_have_ldap
1801         DNS SRV support:     $use_dns_srv
1802         TLS support:         $use_tls_library
1803 "
1804 if test x"$use_regex" != xyes ; then
1805 echo "
1806         Warning: No regular expression support available.
1807                  OpenPGP trust signatures won't work.
1808                  gpg-check-pattern will not be built.
1809 "
1810 fi
1811 if test "x${gpg_config_script_warn}" != x; then
1812 cat <<G10EOF
1813         Warning: Mismatches between the target platform and the
1814                  to be used libraries have been detected for:
1815                   ${gpg_config_script_warn}
1816                  Please check above for more warning messages.
1817
1818 G10EOF
1819 fi