textual changes
[gnupg.git] / configure.in
1 dnl
2 dnl Configure template for GNUPG
3 dnl
4 dnl (Process this file with autoconf to produce a configure script.)
5
6 AC_INIT(g10/g10.c)
7 AC_CONFIG_AUX_DIR(scripts)
8 AM_CONFIG_HEADER(config.h)
9
10
11 if test "x$exec_prefix" = xNONE ; then
12     if test "x$prefix" = xNONE ; then
13         g10_prefix="$ac_default_prefix"
14     else
15         g10_prefix="$prefix"
16     fi
17 else
18     g10_prefix="$exec_prefix"
19 fi
20
21
22 VERSION=`cat $srcdir/VERSION`
23 PACKAGE=gnupg
24 ALL_LINGUAS="de it"
25 AC_SUBST(VERSION)
26 AC_SUBST(PACKAGE)
27 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
28 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
29
30 AC_ARG_ENABLE(dev-random,
31 [  --disable-dev-random    disable the use of dev random],
32     try_dev_random=$enableval, try_dev_random=yes)
33
34 AC_ARG_ENABLE(dynload,
35 [  --disable-dynload       disable dynamic loading],
36     try_dynload=$enableval, try_dynload=yes)
37
38 AC_MSG_CHECKING([whether memory debugging is requested])
39 AC_ARG_ENABLE(m-debug,
40 [  --enable-m-debug        enable debugging of memory allocation],
41 use_m_debug=$enableval, use_m_debug=no)
42 AC_MSG_RESULT($use_m_debug)
43 if test "$use_m_debug" = yes; then
44     AC_DEFINE(M_DEBUG)
45     use_m_guard=yes
46 else
47     AC_MSG_CHECKING([whether memory guard is requested])
48     AC_ARG_ENABLE(m-guard,
49     [  --disable-m-guard       disable memory guard facility],
50     use_m_guard=$enableval, use_m_guard=yes)
51     AC_MSG_RESULT($use_m_guard)
52 fi
53 if test "$use_m_guard" = yes ; then
54     AC_DEFINE(M_GUARD)
55     CFLAGS="-g -Wall"
56 else
57     CFLAGS="-O2 -Wall"
58 fi
59
60
61 AC_MSG_CHECKING([whether included zlib is requested])
62 AC_ARG_WITH(included-zlib,
63     [  --with-included-zlib    use the zlib code included here],
64 [g10_force_zlib=yes], [g10_force_zlib=no] )
65 AC_MSG_RESULT($g10_force_zlib)
66
67
68 AC_CANONICAL_SYSTEM
69 WK_CHECK_CACHE
70
71 dnl Checks for programs.
72
73 AC_PROG_MAKE_SET
74 AC_ARG_PROGRAM
75
76 missing_dir=`cd $ac_aux_dir && pwd`
77 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
78 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
79 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
80 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
81 dnl AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
82 AC_ISC_POSIX
83
84 case "${target}" in
85     i386--mingw32)
86         # special stuff for Windoze NT
87         cross_compiling=yes
88         CC="i386--mingw32-gcc"
89         CPP="i386--mingw32-gcc -E"
90         RANLIB="i386--mingw32-ranlib"
91         ac_cv_have_dev_random=no
92         AC_DEFINE(USE_RAND_W32)
93         GNUPG_LIBDIR="c:/lib/gnupg"
94         ;;
95     *)
96 AC_PROG_RANLIB
97 AC_PROG_INSTALL
98 AC_PROG_CC
99 AC_PROG_CPP
100         AC_DEFINE(USE_RAND_UNIX)
101         GNUPG_LIBDIR="$g10_prefix/lib/gnupg"
102        ;;
103 esac
104 AC_DEFINE_UNQUOTED(GNUPG_LIBDIR, "$GNUPG_LIBDIR")
105
106 case "${target}" in
107     i386--mingw32)
108         PRINTABLE_OS_NAME="MingW32"
109         ;;
110     *-linux*)
111         PRINTABLE_OS_NAME="GNU/Linux"
112         ;;
113     *)
114         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
115         ;;
116 esac
117 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME")
118
119 dnl Checks for libraries.
120
121
122 if test "$try_dynload" = yes ; then
123 AC_CHECK_LIB(dl,dlopen)
124 if test "$ac_cv_lib_dl_dlopen" = "yes"; then
125   AC_DEFINE(USE_DYNAMIC_LINKING)
126   AC_DEFINE(HAVE_DL_DLOPEN)
127   DYNLINK_LDFLAGS=-rdynamic
128   use_gnupg_extensions=yes
129 else
130 AC_CHECK_LIB(dld,dld_link)
131 if test "$ac_cv_lib_dld_dld_link" = "yes"; then
132   AC_DEFINE(USE_DYNAMIC_LINKING)
133   AC_DEFINE(HAVE_DLD_DLD_LINK)
134   DYNLINK_LDFLAGS=-rdynamic
135   use_gnupg_extensions=yes
136 fi
137 fi
138 else
139   AC_MSG_CHECKING(for dynamic loading)
140   DYNLINK_LDFLAGS=
141   use_gnupg_extensions=no
142   AC_MSG_RESULT(has been disabled)
143 fi
144
145 AM_CONDITIONAL(ENABLE_GNUPG_EXTENSIONS, test "$use_gnupg_extensions" = yes )
146 AC_SUBST(DYNLINK_LDFLAGS)
147
148 dnl Checks for header files.
149 AC_HEADER_STDC
150 AC_CHECK_HEADERS(unistd.h)
151
152
153
154 dnl Checks for typedefs, structures, and compiler characteristics.
155 AC_C_CONST
156 AC_C_INLINE
157 AC_TYPE_SIZE_T
158 AC_TYPE_SIGNAL
159 AC_DECL_SYS_SIGLIST
160
161 WK_CHECK_ENDIAN
162
163
164 WK_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
165 WK_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
166 WK_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
167 WK_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
168 WK_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
169
170 AC_CHECK_SIZEOF(unsigned short, 2)
171 AC_CHECK_SIZEOF(unsigned int, 4)
172 AC_CHECK_SIZEOF(unsigned long, 4)
173
174 if test "$ac_cv_sizeof_unsigned_short" = "0" \
175    || test "$ac_cv_sizeof_unsigned_int" = "0" \
176    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
177     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
178 fi
179
180
181
182 dnl Checks for library functions.
183 AC_FUNC_VPRINTF
184 AC_CHECK_FUNCS(strerror stpcpy strlwr tcgetattr rand strtoul mlock mmap)
185 AC_CHECK_FUNCS(memmove gettimeofday getrusage gethrtime)
186
187
188 dnl check whether we have a random device
189 if test "$try_dev_random" = yes ; then
190 AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
191 [if test -c /dev/random && test -c /dev/urandom ; then
192   ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
193 if test "$ac_cv_have_dev_random" = yes; then
194     AC_DEFINE(HAVE_DEV_RANDOM)
195 fi
196 else
197     AC_MSG_CHECKING(for random device)
198     ac_cv_have_dev_random=no
199     AC_MSG_RESULT(has been disabled)
200 fi
201
202
203
204
205 dnl setup assembler stuff
206 AC_MSG_CHECKING(for mpi assembler functions)
207 if test -f $srcdir/mpi/config.links ; then
208     . $srcdir/mpi/config.links
209     WK_LINK_FILES($mpi_ln_src, $mpi_ln_dst)
210     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
211     ac_cv_mpi_config_done="yes"
212     AC_MSG_RESULT(done)
213 else
214     AC_MSG_RESULT(failed)
215     AC_MSG_ERROR([mpi/config.links missing!])
216 fi
217 MPI_EXTRA_ASM_OBJS=""
218 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
219 WK_MSG_PRINT([mpi extra asm functions:])
220 for i in $ac_cv_mpi_extra_asm_modules; do
221     WK_MSG_PRINT([$i])
222     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
223 done
224 AC_MSG_RESULT()
225 fi
226 AC_SUBST(MPI_EXTRA_ASM_OBJS)
227
228 dnl Do we have zlib? Must do it here because Solaris failed
229 dnl when compiling a conftest (due to the "-lz" from LIBS).
230 if test "$g10_force_zlib" = "yes"; then
231     ZLIBS="../zlib/libzlib.a"
232     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
233     WK_LINK_FILES(zlib/zlib.h, zlib.h )
234     WK_LINK_FILES(zlib/zconf.h, zconf.h )
235 else
236 AC_CHECK_HEADERS(zlib.h)
237 if test "$ac_cv_header_zlib_h" = yes ; then
238     LIBS="$LIBS -lz"
239     ZLIBS=
240     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
241 else
242     ZLIBS="../zlib/libzlib.a"
243     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
244     WK_LINK_FILES(zlib/zlib.h, zlib.h )
245     WK_LINK_FILES(zlib/zconf.h, zconf.h )
246 fi
247 fi
248 AC_SUBST(ZLIBS)
249
250
251 AM_GNU_GETTEXT
252 G10_LOCALEDIR="$g10_prefix/$DATADIRNAME/locale"
253 AC_SUBST(G10_LOCALEDIR)
254 AC_DEFINE_UNQUOTED(G10_LOCALEDIR, "$G10_LOCALEDIR")
255 WK_LINK_FILES($nls_cv_header_libgt, $nls_cv_header_intl )
256
257 WK_DO_LINK_FILES
258
259 AC_OUTPUT([
260 Makefile
261 intl/Makefile
262 po/Makefile.in
263 util/Makefile
264 mpi/Makefile
265 cipher/Makefile
266 g10/Makefile
267 doc/Makefile
268 tools/Makefile
269 zlib/Makefile
270 checks/Makefile
271 ],[echo timestamp >stamp-h; sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile])
272