a9975bf698e5a278c2766351bcf7b8049e7c61da
[gnupg.git] / configure.in
1 dnl
2 dnl Configure template for GNUPG
3 dnl
4 dnl (Process this file with autoconf to produce a configure script.)
5 AC_REVISION($Revision$)dnl
6
7 dnl Must reset CDPATH so that bash's cd does not print to stdout
8 CDPATH=
9
10 AC_INIT(g10/g10.c)
11 AC_CONFIG_AUX_DIR(scripts)
12 AM_CONFIG_HEADER(config.h)
13
14
15 VERSION=`cat $srcdir/VERSION`
16 PACKAGE=gnupg
17 ALL_LINGUAS="de es_ES fr it pl pt_BR ru"
18 AC_SUBST(VERSION)
19 AC_SUBST(PACKAGE)
20 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
21 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
22
23 AC_MSG_CHECKING([whether use of /dev/random is requested])
24 AC_ARG_ENABLE(dev-random,
25 [  --disable-dev-random    disable the use of dev random],
26     try_dev_random=$enableval, try_dev_random=yes)
27 AC_MSG_RESULT($try_dev_random)
28
29 AC_MSG_CHECKING([whether use of extensions is requested])
30 AC_ARG_ENABLE(dynload,
31 [  --disable-dynload       disable use of extensions],
32     try_dynload=$enableval, try_dynload=yes)
33 AC_MSG_RESULT($try_dynload)
34
35 AC_MSG_CHECKING([whether assembler modules are requested])
36 AC_ARG_ENABLE(asm,
37 [  --disable-asm           do not use assembler modules],
38      try_asm_modules=$enableval, try_asm_modules=yes)
39 AC_MSG_RESULT($try_asm_modules)
40
41 AC_MSG_CHECKING([whether memory debugging is requested])
42 AC_ARG_ENABLE(m-debug,
43 [  --enable-m-debug        enable debugging of memory allocation],
44 use_m_debug=$enableval, use_m_debug=no)
45 AC_MSG_RESULT($use_m_debug)
46 if test "$use_m_debug" = yes; then
47     AC_DEFINE(M_DEBUG)
48     use_m_guard=yes
49 else
50     AC_MSG_CHECKING([whether memory guard is requested])
51     AC_ARG_ENABLE(m-guard,
52     [  --enable-m-guard        enable memory guard facility],
53     use_m_guard=$enableval, use_m_guard=no)
54     AC_MSG_RESULT($use_m_guard)
55 fi
56 if test "$use_m_guard" = yes ; then
57     AC_DEFINE(M_GUARD)
58     CFLAGS="$CFLAGS -g"
59 else
60     CFLAGS="$CFLAGS -O2"
61 fi
62
63
64 AC_MSG_CHECKING([whether included zlib is requested])
65 AC_ARG_WITH(included-zlib,
66     [  --with-included-zlib    use the zlib code included here],
67 [g10_force_zlib=yes], [g10_force_zlib=no] )
68 AC_MSG_RESULT($g10_force_zlib)
69
70 dnl Checks for programs.
71
72 AC_CANONICAL_SYSTEM
73 AC_ARG_PROGRAM
74 AC_PROG_MAKE_SET
75 AM_SANITY_CHECK
76 missing_dir=`cd $ac_aux_dir && pwd`
77 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
78 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
79 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
80 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
81 dnl AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
82 AC_PROG_CC
83 AC_PROG_CPP
84 AC_ISC_POSIX
85 AC_PROG_RANLIB
86 AC_PROG_INSTALL
87 dnl AC_CYGWIN32
88
89
90 if test "$GCC" = yes; then
91     CFLAGS="$CFLAGS -Wall"
92 fi
93
94 case "${target}" in
95     i386--mingw32)
96         # special stuff for Windoze NT
97         cross_compiling=yes
98         CC="i386--mingw32-gcc"
99         CPP="i386--mingw32-gcc -E"
100         RANLIB="i386--mingw32-ranlib"
101         ac_cv_have_dev_random=no
102         AC_DEFINE(USE_RNDW32)
103         AC_DEFINE(USE_ONLY_8DOT3)
104         AC_DEFINE(HAVE_DRIVE_LETTERS)
105         ;;
106     *-*-hpux*)
107         if test -z "$GCC" ; then
108             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
109         fi
110         ;;
111     m68k-atari-mint)
112         ;;
113     *)
114        ;;
115 esac
116
117
118 GNUPG_CHECK_PIC
119 GNUPG_CHECK_RDYNAMIC
120 if test "$NO_PIC" = yes; then
121     try_dynload=no
122 fi
123
124
125 case "${target}" in
126     i386--mingw32)
127         PRINTABLE_OS_NAME="MingW32"
128         ;;
129     *-linux*)
130         PRINTABLE_OS_NAME="GNU/Linux"
131         ;;
132     *)
133         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
134         ;;
135 esac
136 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME")
137
138 dnl  Fixme: Are these the best flags for OpenBSD????
139 case "${target}" in
140     *-openbsd*)
141         NAME_OF_DEV_RANDOM="/dev/srandom"
142         NAME_OF_DEV_URANDOM="/dev/urandom"
143         DYNLINK_MOD_CFLAGS="-shared -rdynamic -fpic -Wl,-Bshareable -Wl,-x"
144         ;;
145     *)
146         NAME_OF_DEV_RANDOM="/dev/random"
147         NAME_OF_DEV_URANDOM="/dev/urandom"
148         DYNLINK_MOD_CFLAGS="-shared $CFLAGS_PIC -lc"
149         ;;
150 esac
151 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM")
152 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM")
153
154
155 dnl Checks for libraries.
156
157 AM_GNU_GETTEXT
158
159 AC_CHECK_LIB(gdbm,gdbm_firstkey)
160
161
162 if test "$try_dynload" = yes ; then
163   AC_CHECK_LIB(dl,dlopen)
164   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
165     AC_DEFINE(USE_DYNAMIC_LINKING)
166     AC_DEFINE(HAVE_DL_DLOPEN)
167     DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
168     use_gnupg_extensions=yes
169   else
170     AC_CHECK_LIB(c,dlopen)
171     if test "$ac_cv_lib_c_dlopen" = "yes"; then
172       AC_DEFINE(USE_DYNAMIC_LINKING)
173       AC_DEFINE(HAVE_DL_DLOPEN)
174       DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
175       dnl fixme: this is probably false but it should
176       dnl work for freebsd
177       AC_DEFINE(DLSYM_NEEDS_UNDERSCORE)
178       use_gnupg_extensions=yes
179     else
180       AC_CHECK_LIB(dld,dld_link)
181       if test "$ac_cv_lib_dld_dld_link" = "yes"; then
182         AC_DEFINE(USE_DYNAMIC_LINKING)
183         AC_DEFINE(HAVE_DLD_DLD_LINK)
184         DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
185         use_gnupg_extensions=yes
186       fi
187     fi
188   fi
189 else
190   AC_MSG_CHECKING(for dynamic loading)
191   DYNLINK_LDFLAGS=
192   DYNLINK_MOD_CFLAGS=
193   use_gnupg_extensions=no
194   AC_MSG_RESULT(has been disabled)
195 fi
196
197 AM_CONDITIONAL(ENABLE_GNUPG_EXTENSIONS, test "$use_gnupg_extensions" = yes )
198 AC_SUBST(DYNLINK_LDFLAGS)
199 AC_SUBST(DYNLINK_MOD_CFLAGS)
200
201
202 dnl Checks for header files.
203 AC_HEADER_STDC
204 AC_CHECK_HEADERS(unistd.h)
205
206
207 dnl Checks for typedefs, structures, and compiler characteristics.
208 AC_C_CONST
209 AC_C_INLINE
210 AC_TYPE_SIZE_T
211 AC_TYPE_SIGNAL
212 AC_DECL_SYS_SIGLIST
213
214 GNUPG_CHECK_ENDIAN
215
216
217 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
218 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
219 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
220 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
221 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
222
223 AC_CHECK_SIZEOF(unsigned short, 2)
224 AC_CHECK_SIZEOF(unsigned int, 4)
225 AC_CHECK_SIZEOF(unsigned long, 4)
226
227 if test "$ac_cv_sizeof_unsigned_short" = "0" \
228    || test "$ac_cv_sizeof_unsigned_int" = "0" \
229    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
230     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
231 fi
232
233
234
235 dnl Checks for library functions.
236 AC_FUNC_VPRINTF
237 AC_CHECK_FUNCS(strerror stpcpy strlwr tcgetattr rand strtoul mmap)
238 AC_CHECK_FUNCS(memmove gettimeofday getrusage gethrtime setrlimit)
239 AC_CHECK_FUNCS(memicmp atexit raise getpagesize strftime)
240
241 GNUPG_CHECK_MLOCK
242
243 GNUPG_CHECK_IPC
244 if test "$ac_cv_header_sys_shm_h" = "yes"; then
245   AC_DEFINE(USE_SHM_COPROCESSING)
246 fi
247
248 dnl check whether we have a random device
249 if test "$try_dev_random" = yes ; then
250 AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
251 [if test -c "$NAME_OF_DEV_RANDOM" && test -c "$NAME_OF_DEV_URANDOM" ; then
252   ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
253 if test "$ac_cv_have_dev_random" = yes; then
254     AC_DEFINE(HAVE_DEV_RANDOM)
255     AC_DEFINE(USE_RNDLINUX)
256 fi
257 else
258     AC_MSG_CHECKING(for random device)
259     ac_cv_have_dev_random=no
260     AC_MSG_RESULT(has been disabled)
261 fi
262
263
264 dnl
265 dnl Figure how to link the random modules
266 dnl
267 if test "$ac_cv_have_dev_random" = yes; then
268     AC_DEFINE(USE_RNDLINUX)
269     STATIC_RANDOM_OBJS="rndlinux.o"
270     DYNAMIC_RANDOM_MODS=""
271 else
272     case "${target}" in
273         i386--mingw32)
274             AC_DEFINE(USE_RNDW32)
275             STATIC_RANDOM_OBJS=""
276             DYNAMIC_RANDOM_MODS=""
277             ;;
278         m68k-atari-mint)
279             AC_DEFINE(USE_RNDATARI)
280             STATIC_RANDOM_OBJS=""
281             DYNAMIC_RANDOM_MODS=""
282             ;;
283         *)
284             AC_DEFINE(USE_RNDUNIX)
285             STATIC_RANDOM_OBJS="rndunix.o"
286             DYNAMIC_RANDOM_MODS=""
287            ;;
288     esac
289 fi
290
291 AC_SUBST(STATIC_RANDOM_OBJS)
292 AC_SUBST(DYNAMIC_RANDOM_MODS)
293
294
295 dnl
296 dnl Figure how to link the cipher modules
297 dnl
298 dnl (form now these are only dynamic)
299 STATIC_CIPHER_OBJS=""
300 DYNAMIC_CIPHER_MODS="twofish tiger"
301 AC_SUBST(STATIC_CIPHER_OBJS)
302 AC_SUBST(DYNAMIC_CIPHER_MODS)
303
304
305
306 dnl setup assembler stuff
307 AC_MSG_CHECKING(for mpi assembler functions)
308 if test -f $srcdir/mpi/config.links ; then
309     . $srcdir/mpi/config.links
310     GNUPG_LINK_FILES($mpi_ln_src, $mpi_ln_dst)
311     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
312     ac_cv_mpi_sflags="$mpi_sflags"
313     ac_cv_mpi_config_done="yes"
314     AC_MSG_RESULT(done)
315 else
316     AC_MSG_RESULT(failed)
317     AC_MSG_ERROR([mpi/config.links missing!])
318 fi
319 MPI_EXTRA_ASM_OBJS=""
320 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
321 GNUPG_MSG_PRINT([mpi extra asm functions:])
322 for i in $ac_cv_mpi_extra_asm_modules; do
323     GNUPG_MSG_PRINT([$i])
324     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
325 done
326 AC_MSG_RESULT()
327 fi
328 AC_SUBST(MPI_EXTRA_ASM_OBJS)
329 MPI_SFLAGS="$ac_cv_mpi_sflags"
330 AC_SUBST(MPI_SFLAGS)
331
332 dnl Do we have zlib? Must do it here because Solaris failed
333 dnl when compiling a conftest (due to the "-lz" from LIBS).
334 if test "$g10_force_zlib" = "yes"; then
335     ZLIBS="../zlib/libzlib.a"
336     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
337     GNUPG_LINK_FILES(zlib/zlib.h, zlib.h )
338     GNUPG_LINK_FILES(zlib/zconf.h, zconf.h )
339 else
340 AC_CHECK_HEADERS(zlib.h)
341 if test "$ac_cv_header_zlib_h" = yes ; then
342     LIBS="$LIBS -lz"
343     ZLIBS=
344     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
345 else
346     ZLIBS="../zlib/libzlib.a"
347     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
348     GNUPG_LINK_FILES(zlib/zlib.h, zlib.h )
349     GNUPG_LINK_FILES(zlib/zconf.h, zconf.h )
350 fi
351 fi
352 AC_SUBST(ZLIBS)
353
354 GNUPG_DO_LINK_FILES
355
356
357 AC_OUTPUT([
358 Makefile
359 intl/Makefile
360 po/Makefile.in
361 util/Makefile
362 mpi/Makefile
363 cipher/Makefile
364 g10/Makefile
365 doc/Makefile
366 tools/Makefile
367 zlib/Makefile
368 checks/Makefile
369 ])
370
371 dnl *-*wedit:notab*-*  Please keep this as the last line.